configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl
  13 dnl Permission is hereby granted, free of charge, to any person obtaining a
  14 dnl copy of this software and associated documentation files (the "Software"),
  15 dnl to deal in the Software without restriction, including without limitation
  16 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  17 dnl and/or sell copies of the Software, and to permit persons to whom the
  18 dnl Software is furnished to do so, subject to the following conditions:
  19 dnl
  20 dnl The above copyright notice and this permission notice (including the next
  21 dnl paragraph) shall be included in all copies or substantial portions of the
  22 dnl Software.
  23 dnl
  24 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  25 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  26 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  27 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  28 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  29 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  30 dnl DEALINGS IN THE SOFTWARE.
  31 dnl
  32 dnl Process this file with autoconf to create configure.
  33
  34 AC_PREREQ([2.60])
  35
  36 dnl Tell the user about autoconf.html in the --help output
  37 m4_divert_once([HELP_END], [
  38 See docs/autoconf.html for more details on the options for Mesa.])
  39
  40 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  41 AC_INIT([Mesa], [MESA_VERSION],
  42     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  43 AC_CONFIG_AUX_DIR([bin])
  44 AC_CONFIG_MACRO_DIR([m4])
  45 AC_CANONICAL_SYSTEM
  46 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  47
  48 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  49 case "$host_os" in
  50 mingw*)
  51     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  52     ;;
  53 esac
  54
  55 # Support silent build rules, requires at least automake-1.11. Disable
  56 # by either passing --disable-silent-rules to configure or passing V=1
  57 # to make
  58 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  59     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  60
  61 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  62
  63 dnl Set internal versions
  64 OSMESA_VERSION=8
  65 AC_SUBST([OSMESA_VERSION])
  66 OPENCL_VERSION=1
  67 AC_SUBST([OPENCL_VERSION])
  68
  69 # The idea is that libdrm is distributed as one cohesive package, even
  70 # though it is composed of multiple libraries. However some drivers
  71 # may have different version requirements than others. This list
  72 # codifies which drivers need which version of libdrm. Any libdrm
  73 # version dependencies in non-driver-specific code should be reflected
  74 # in the first entry.
  75 LIBDRM_REQUIRED=2.4.75
  76 LIBDRM_RADEON_REQUIRED=2.4.71
  77 LIBDRM_AMDGPU_REQUIRED=2.4.91
  78 LIBDRM_INTEL_REQUIRED=2.4.75
  79 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  80 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  81 LIBDRM_FREEDRENO_REQUIRED=2.4.92
  82 LIBDRM_ETNAVIV_REQUIRED=2.4.89
  83 LIBDRM_VC4_REQUIRED=2.4.89
  84
  85 dnl Versions for external dependencies
  86 DRI2PROTO_REQUIRED=2.8
  87 GLPROTO_REQUIRED=1.4.14
  88 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  89 LIBOMXIL_TIZONIA_REQUIRED=0.10.0
  90 LIBVA_REQUIRED=0.39.0
  91 VDPAU_REQUIRED=1.1
  92 WAYLAND_REQUIRED=1.11
  93 WAYLAND_EGL_BACKEND_REQUIRED=3
  94 WAYLAND_PROTOCOLS_REQUIRED=1.8
  95 XCB_REQUIRED=1.9.3
  96 XCBDRI2_REQUIRED=1.8
  97 XCBDRI3_MODIFIERS_REQUIRED=1.13
  98 XCBGLX_REQUIRED=1.8.1
  99 XCBPRESENT_MODIFIERS_REQUIRED=1.13
 100 XDAMAGE_REQUIRED=1.1
 101 XSHMFENCE_REQUIRED=1.1
 102 XVMC_REQUIRED=1.0.6
 103 PYTHON_MAKO_REQUIRED=0.8.0
 104 LIBSENSORS_REQUIRED=4.0.0
 105 ZLIB_REQUIRED=1.2.3
 106
 107 dnl LLVM versions
 108 LLVM_REQUIRED_GALLIUM=3.3.0
 109 LLVM_REQUIRED_OPENCL=3.9.0
 110 LLVM_REQUIRED_R600=3.9.0
 111 LLVM_REQUIRED_RADEONSI=5.0.0
 112 LLVM_REQUIRED_RADV=5.0.0
 113 LLVM_REQUIRED_SWR=5.0.0
 114
 115 dnl Check for progs
 116 AC_PROG_CPP
 117 AC_PROG_CC
 118 AC_PROG_CXX
 119 dnl add this here, so the help for this environmnet variable is close to
 120 dnl other CC/CXX flags related help
 121 AC_ARG_VAR([CXX11_CXXFLAGS], [Compiler flag to enable C++11 support (only needed if not
 122                               enabled by default and different  from -std=c++11)])
 123 AM_PROG_CC_C_O
 124 AC_PROG_GREP
 125 AC_PROG_NM
 126 AM_PROG_AS
 127 AX_CHECK_GNU_MAKE
 128 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 129 AC_PROG_SED
 130 AC_PROG_MKDIR_P
 131
 132 AC_SYS_LARGEFILE
 133
 134
 135 LT_PREREQ([2.2])
 136 LT_INIT([disable-static])
 137
 138 AC_CHECK_PROG(RM, rm, [rm -f])
 139
 140 AX_PROG_BISON([],
 141               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 142                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 143 AX_PROG_FLEX([],
 144              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 145                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 146
 147 AC_CHECK_PROG(INDENT, indent, indent, cat)
 148 if test "x$INDENT" != "xcat"; then
 149     # Only GNU indent is supported
 150     INDENT_VERSION=`indent --version | grep GNU`
 151     if test $? -eq 0; then
 152        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 153     else
 154        INDENT="cat"
 155     fi
 156 fi
 157
 158 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 159
 160 if test -z "$PYTHON2"; then
 161     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 162         AC_MSG_ERROR([Python not found - unable to generate sources])
 163     fi
 164 else
 165     if test "x$acv_mako_found" = xno; then
 166         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 167             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 168         fi
 169     fi
 170 fi
 171
 172 AC_PROG_INSTALL
 173
 174 dnl We need a POSIX shell for parts of the build. Assume we have one
 175 dnl in most cases.
 176 case "$host_os" in
 177 solaris*)
 178     # Solaris /bin/sh is too old/non-POSIX compliant
 179     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 180     SHELL="$POSIX_SHELL"
 181     ;;
 182 esac
 183
 184 dnl clang is mostly GCC-compatible, but its version is much lower,
 185 dnl so we have to check for it.
 186 AC_MSG_CHECKING([if compiling with clang])
 187
 188 AC_COMPILE_IFELSE(
 189 [AC_LANG_PROGRAM([], [[
 190 #ifndef __clang__
 191        not clang
 192 #endif
 193 ]])],
 194 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 195
 196 AC_MSG_RESULT([$acv_mesa_CLANG])
 197
 198 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 199 dnl versions are explictly not supported.
 200 GEN_ASM_OFFSETS=no
 201 USE_GNU99=no
 202 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 203     AC_MSG_CHECKING([whether gcc version is sufficient])
 204     major=0
 205     minor=0
 206
 207     GCC_VERSION=`$CC -dumpversion`
 208     if test $? -eq 0; then
 209         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 210         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 211     fi
 212
 213     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 214         AC_MSG_RESULT([no])
 215         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 216     else
 217         AC_MSG_RESULT([yes])
 218     fi
 219
 220     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 221         USE_GNU99=yes
 222     fi
 223     if test "x$cross_compiling" = xyes; then
 224         GEN_ASM_OFFSETS=yes
 225     fi
 226 fi
 227
 228 dnl We don't support building Mesa with Sun C compiler
 229 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 230 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 231 if test "x$SUNCC" = xyes; then
 232     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 233 fi
 234
 235 dnl Check for compiler builtins
 236 AX_GCC_BUILTIN([__builtin_bswap32])
 237 AX_GCC_BUILTIN([__builtin_bswap64])
 238 AX_GCC_BUILTIN([__builtin_clz])
 239 AX_GCC_BUILTIN([__builtin_clzll])
 240 AX_GCC_BUILTIN([__builtin_ctz])
 241 AX_GCC_BUILTIN([__builtin_expect])
 242 AX_GCC_BUILTIN([__builtin_ffs])
 243 AX_GCC_BUILTIN([__builtin_ffsll])
 244 AX_GCC_BUILTIN([__builtin_popcount])
 245 AX_GCC_BUILTIN([__builtin_popcountll])
 246 AX_GCC_BUILTIN([__builtin_unreachable])
 247
 248 AX_GCC_FUNC_ATTRIBUTE([const])
 249 AX_GCC_FUNC_ATTRIBUTE([flatten])
 250 AX_GCC_FUNC_ATTRIBUTE([format])
 251 AX_GCC_FUNC_ATTRIBUTE([malloc])
 252 AX_GCC_FUNC_ATTRIBUTE([packed])
 253 AX_GCC_FUNC_ATTRIBUTE([pure])
 254 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 255 AX_GCC_FUNC_ATTRIBUTE([unused])
 256 AX_GCC_FUNC_ATTRIBUTE([visibility])
 257 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 258 AX_GCC_FUNC_ATTRIBUTE([weak])
 259 AX_GCC_FUNC_ATTRIBUTE([alias])
 260 AX_GCC_FUNC_ATTRIBUTE([noreturn])
 261
 262 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 263
 264 dnl Make sure the pkg-config macros are defined
 265 m4_ifndef([PKG_PROG_PKG_CONFIG],
 266     [m4_fatal([Could not locate the pkg-config autoconf macros.
 267   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 268   are in a different location, try setting the environment variable
 269   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 270 PKG_PROG_PKG_CONFIG()
 271
 272 dnl LIB_DIR - library basename
 273 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 274 AC_SUBST([LIB_DIR])
 275
 276 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 277 _SAVE_LDFLAGS="$LDFLAGS"
 278 _SAVE_CPPFLAGS="$CPPFLAGS"
 279
 280 dnl Compiler macros
 281 DEFINES="-D__STDC_CONSTANT_MACROS -D__STDC_FORMAT_MACROS -D__STDC_LIMIT_MACROS"
 282 AC_SUBST([DEFINES])
 283 android=no
 284 case "$host_os" in
 285 *-android*)
 286     android=yes
 287     ;;
 288 linux*|*-gnu*|gnu*|cygwin*)
 289     DEFINES="$DEFINES -D_GNU_SOURCE"
 290     ;;
 291 solaris*)
 292     DEFINES="$DEFINES -DSVR4"
 293     ;;
 294 esac
 295
 296 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 297
 298 dnl
 299 dnl Check compiler flags
 300 dnl
 301 AX_CHECK_COMPILE_FLAG([-Wall],                                 [CFLAGS="$CFLAGS -Wall"])
 302 AX_CHECK_COMPILE_FLAG([-Werror=implicit-function-declaration], [CFLAGS="$CFLAGS -Werror=implicit-function-declaration"])
 303 AX_CHECK_COMPILE_FLAG([-Werror=missing-prototypes],            [CFLAGS="$CFLAGS -Werror=missing-prototypes"])
 304 AX_CHECK_COMPILE_FLAG([-Wmissing-prototypes],                  [CFLAGS="$CFLAGS -Wmissing-prototypes"])
 305 dnl Dylan Baker: gcc and clang always accepr -Wno-*, hence check for the original warning, then set the no-* flag
 306 AX_CHECK_COMPILE_FLAG([-Wmissing-field-initializers],          [CFLAGS="$CFLAGS -Wno-missing-field-initializers"])
 307 AX_CHECK_COMPILE_FLAG([-fno-math-errno],                       [CFLAGS="$CFLAGS -fno-math-errno"])
 308
 309 AX_CHECK_COMPILE_FLAG([-fno-trapping-math],                    [CFLAGS="$CFLAGS -fno-trapping-math"])
 310 AX_CHECK_COMPILE_FLAG([-fvisibility=hidden],                   [VISIBILITY_CFLAGS="-fvisibility=hidden"])
 311
 312 dnl
 313 dnl Check C++ compiler flags
 314 dnl
 315 AC_LANG_PUSH([C++])
 316 AX_CHECK_COMPILE_FLAG([-Wall],                                 [CXXFLAGS="$CXXFLAGS -Wall"])
 317 AX_CHECK_COMPILE_FLAG([-fno-math-errno],                       [CXXFLAGS="$CXXFLAGS -fno-math-errno"])
 318 AX_CHECK_COMPILE_FLAG([-fno-trapping-math],                    [CXXFLAGS="$CXXFLAGS -fno-trapping-math"])
 319 AX_CHECK_COMPILE_FLAG([-fvisibility=hidden],                   [VISIBILITY_CXXFLAGS="-fvisibility=hidden"])
 320 AX_CHECK_COMPILE_FLAG([-Wmissing-field-initializers],          [CXXFLAGS="$CXXFLAGS -Wno-missing-field-initializers"])
 321 AC_LANG_POP([C++])
 322
 323 # Flags to help ensure that certain portions of the code -- and only those
 324 # portions -- can be built with MSVC:
 325 # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 326 # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 327 #   supports most of C99)
 328 # - the rest has no compiler compiler restrictions
 329 AX_CHECK_COMPILE_FLAG([-Werror=pointer-arith],                 [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=pointer-arith"])
 330 AX_CHECK_COMPILE_FLAG([-Werror=vla],                           [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla"])
 331 AC_LANG_PUSH([C++])
 332 AX_CHECK_COMPILE_FLAG([-Werror=pointer-arith],                 [MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=pointer-arith"])
 333 AX_CHECK_COMPILE_FLAG([-Werror=vla],                           [MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla"])
 334 AC_LANG_POP([C++])
 335
 336 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 337 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 338
 339 if test "x$GCC" = xyes; then
 340     if test "x$USE_GNU99" = xyes; then
 341         CFLAGS="$CFLAGS -std=gnu99"
 342     else
 343         CFLAGS="$CFLAGS -std=c99"
 344     fi
 345 fi
 346
 347 dnl
 348 dnl Check whether C++11 is supported, if the environment variable
 349 dnl CXX11_CXXFLAGS is set it takes precedence.
 350 dnl
 351
 352 AC_LANG_PUSH([C++])
 353
 354 check_cxx11_available() {
 355     output_support=$1
 356     AC_COMPILE_IFELSE(
 357         [AC_LANG_PROGRAM([
 358              #if !(__cplusplus >= 201103L)
 359              #error
 360              #endif
 361              #include <tuple>
 362         ])
 363     ], [
 364          AC_MSG_RESULT(yes)
 365          cxx11_support=yes
 366     ], AC_MSG_RESULT(no))
 367     eval "$output_support=\$cxx11_support"
 368 }
 369
 370 HAVE_CXX11=no
 371 save_CXXFLAGS="$CXXFLAGS"
 372
 373 dnl If the user provides a flag to enable c++11, then we test only this
 374 if test "x$CXX11_CXXFLAGS" != "x"; then
 375    CXXFLAGS="$CXXFLAGS $CXX11_CXXFLAGS"
 376    AC_MSG_CHECKING(whether c++11 is enabled by via $CXX11_CXXFLAGS)
 377    check_cxx11_available HAVE_CXX11
 378 else
 379    dnl test whether c++11 is enabled by default
 380    AC_MSG_CHECKING(whether c++11 is enabled by default)
 381    check_cxx11_available HAVE_CXX11
 382
 383    dnl C++11 not enabled by default, test whether -std=c++11 does the job
 384    if test "x$HAVE_CXX11" != "xyes"; then
 385        CXX11_CXXFLAGS=-std=c++11
 386        CXXFLAGS="$CXXFLAGS $CXX11_CXXFLAGS"
 387        AC_MSG_CHECKING(whether c++11 is enabled by via $CXX11_CXXFLAGS)
 388        check_cxx11_available HAVE_CXX11
 389    fi
 390 fi
 391
 392 CXXFLAGS="$save_CXXFLAGS"
 393 AM_CONDITIONAL(HAVE_STD_CXX11, test "x$HAVE_CXX11" = "xyes")
 394 AC_SUBST(CXX11_CXXFLAGS)
 395 AC_LANG_POP([C++])
 396
 397 dnl even if the compiler appears to support it, using visibility attributes isn't
 398 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 399 case "$host_os" in
 400 cygwin*)
 401     VISIBILITY_CFLAGS=""
 402     VISIBILITY_CXXFLAGS=""
 403     ;;
 404 esac
 405
 406 AC_SUBST([VISIBILITY_CFLAGS])
 407 AC_SUBST([VISIBILITY_CXXFLAGS])
 408
 409 dnl For some reason, the test for -Wno-foo always succeeds with gcc, even if the
 410 dnl option is not supported. Hence, check for -Wfoo instead.
 411 AX_CHECK_COMPILE_FLAG([-Woverride-init],                    [WNO_OVERRIDE_INIT="$WNO_OVERRIDE_INIT -Wno-override-init"])         # gcc
 412 AX_CHECK_COMPILE_FLAG([-Winitializer-overrides],            [WNO_OVERRIDE_INIT="$WNO_OVERRIDE_INIT -Wno-initializer-overrides"]) # clang
 413 AC_SUBST([WNO_OVERRIDE_INIT])
 414
 415 dnl
 416 dnl Optional flags, check for compiler support
 417 dnl
 418 SSE41_CFLAGS="-msse4.1"
 419 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 420 dnl stack, but on x86-32 such alignment is not guaranteed.
 421 case "$target_cpu" in
 422 i?86)
 423     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 424     ;;
 425 esac
 426 save_CFLAGS="$CFLAGS"
 427 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 428 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 429 #include <smmintrin.h>
 430 int param;
 431 int main () {
 432     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 433     c = _mm_max_epu32(a, b);
 434     return _mm_cvtsi128_si32(c);
 435 }]])], SSE41_SUPPORTED=1)
 436 CFLAGS="$save_CFLAGS"
 437 if test "x$SSE41_SUPPORTED" = x1; then
 438     DEFINES="$DEFINES -DUSE_SSE41"
 439 fi
 440 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 441 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 442
 443 dnl Check for new-style atomic builtins. We first check without linking to
 444 dnl -latomic.
 445 AC_MSG_CHECKING(whether __atomic_load_n is supported)
 446 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 447 #include <stdint.h>
 448 int main() {
 449     struct {
 450         uint64_t *v;
 451     } x;
 452     return (int)__atomic_load_n(x.v, __ATOMIC_ACQUIRE) &
 453            (int)__atomic_add_fetch(x.v, (uint64_t)1, __ATOMIC_ACQ_REL);
 454 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=yes, GCC_ATOMIC_BUILTINS_SUPPORTED=no)
 455
 456 dnl If that didn't work, we try linking with -latomic, which is needed on some
 457 dnl platforms.
 458 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" != xyes; then
 459    save_LDFLAGS=$LDFLAGS
 460    LDFLAGS="$LDFLAGS -latomic"
 461    AC_LINK_IFELSE([AC_LANG_SOURCE([[
 462    #include <stdint.h>
 463    int main() {
 464         struct {
 465             uint64_t *v;
 466         } x;
 467         return (int)__atomic_load_n(x.v, __ATOMIC_ACQUIRE) &
 468                (int)__atomic_add_fetch(x.v, (uint64_t)1, __ATOMIC_ACQ_REL);
 469    }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=yes LIBATOMIC_LIBS="-latomic",
 470           GCC_ATOMIC_BUILTINS_SUPPORTED=no)
 471    LDFLAGS=$save_LDFLAGS
 472 fi
 473 AC_MSG_RESULT($GCC_ATOMIC_BUILTINS_SUPPORTED)
 474
 475 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = xyes; then
 476     DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
 477 fi
 478 AC_SUBST([LIBATOMIC_LIBS])
 479
 480 dnl Check if host supports 64-bit atomics
 481 dnl note that lack of support usually results in link (not compile) error
 482 AC_MSG_CHECKING(whether __sync_add_and_fetch_8 is supported)
 483 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 484 #include <stdint.h>
 485 uint64_t v;
 486 int main() {
 487     return __sync_add_and_fetch(&v, (uint64_t)1);
 488 }]])], GCC_64BIT_ATOMICS_SUPPORTED=yes, GCC_64BIT_ATOMICS_SUPPORTED=no)
 489 if test "x$GCC_64BIT_ATOMICS_SUPPORTED" != xyes; then
 490     DEFINES="$DEFINES -DMISSING_64BIT_ATOMICS"
 491 fi
 492 AC_MSG_RESULT($GCC_64BIT_ATOMICS_SUPPORTED)
 493
 494 dnl Check for Endianness
 495 AC_C_BIGENDIAN(
 496    little_endian=no,
 497    little_endian=yes,
 498    little_endian=no,
 499    little_endian=no
 500 )
 501
 502 dnl Check for POWER8 Architecture
 503 PWR8_CFLAGS="-mpower8-vector"
 504 have_pwr8_intrinsics=no
 505 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 506 save_CFLAGS=$CFLAGS
 507 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 508 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 509 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 510 #error "Need GCC >= 4.8 for sane POWER8 support"
 511 #endif
 512 #include <altivec.h>
 513 int main () {
 514     vector unsigned char r;
 515     vector unsigned int v = vec_splat_u32 (1);
 516     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 517     return 0;
 518 }]])], have_pwr8_intrinsics=yes)
 519 CFLAGS=$save_CFLAGS
 520
 521 AC_ARG_ENABLE(pwr8,
 522    [AS_HELP_STRING([--disable-pwr8],
 523                    [disable POWER8-specific instructions])],
 524    [enable_pwr8=$enableval], [enable_pwr8=auto])
 525
 526 if test "x$enable_pwr8" = xno ; then
 527    have_pwr8_intrinsics=disabled
 528 fi
 529
 530 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 531    DEFINES="$DEFINES -D_ARCH_PWR8"
 532    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 533    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 534 else
 535    PWR8_CFLAGS=
 536 fi
 537
 538 AC_MSG_RESULT($have_pwr8_intrinsics)
 539 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 540    AC_MSG_ERROR([POWER8 compiler support not detected])
 541 fi
 542
 543 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 544    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 545 fi
 546
 547 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 548
 549 dnl Can't have static and shared libraries, default to static if user
 550 dnl explicitly requested. If both disabled, set to static since shared
 551 dnl was explicitly requested.
 552 case "x$enable_static$enable_shared" in
 553 xyesyes)
 554     AC_MSG_ERROR([Cannot enable both static and shared. Building using --enable-shared is strongly recommended])
 555     ;;
 556 xnono)
 557     AC_MSG_ERROR([Cannot disable both static and shared. Building using --enable-shared is strongly recommended])
 558     ;;
 559 esac
 560
 561 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 562
 563 dnl
 564 dnl other compiler options
 565 dnl
 566 AC_ARG_ENABLE([debug],
 567     [AS_HELP_STRING([--enable-debug],
 568         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 569     [enable_debug="$enableval"],
 570     [enable_debug=no]
 571 )
 572
 573 AC_ARG_ENABLE([profile],
 574     [AS_HELP_STRING([--enable-profile],
 575         [enable profiling of code @<:@default=disabled@:>@])],
 576     [enable_profile="$enableval"],
 577     [enable_profile=no]
 578 )
 579
 580 AC_ARG_ENABLE([sanitize],
 581     [AS_HELP_STRING([--enable-sanitize@<:@=address|undefined@:>@],
 582         [enable code sanitizer @<:@default=disabled@:>@])],
 583     [enable_sanitize="$enableval"],
 584     [enable_sanitize=no])
 585
 586 if test "x$enable_profile" = xyes; then
 587     DEFINES="$DEFINES -DPROFILE"
 588     if test "x$GCC" = xyes; then
 589         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 590     fi
 591     if test "x$GXX" = xyes; then
 592         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 593     fi
 594 fi
 595
 596 if test "x$enable_debug" = xyes; then
 597     DEFINES="$DEFINES -DDEBUG"
 598     if test "x$enable_profile" = xyes; then
 599         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 600     fi
 601     if test "x$GCC" = xyes; then
 602         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 603             CFLAGS="$CFLAGS -g"
 604         fi
 605         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 606             CFLAGS="$CFLAGS -O0"
 607         fi
 608     fi
 609     if test "x$GXX" = xyes; then
 610         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 611             CXXFLAGS="$CXXFLAGS -g"
 612         fi
 613         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 614             CXXFLAGS="$CXXFLAGS -O0"
 615         fi
 616     fi
 617 else
 618    DEFINES="$DEFINES -DNDEBUG"
 619 fi
 620
 621 if test "x$enable_sanitize" != xno; then
 622     if test "x$enable_profile" = xyes; then
 623         AC_MSG_WARN([Sanitize and Profile are enabled at the same time])
 624     fi
 625
 626     CFLAGS="$CFLAGS -fsanitize=$enable_sanitize"
 627     CXXFLAGS="$CXXFLAGS -fsanitize=$enable_sanitize"
 628     LDFLAGS="$LDFLAGS -fsanitize=$enable_sanitize"
 629
 630     AC_LINK_IFELSE(
 631         [AC_LANG_SOURCE([int main(){return 0;}])],
 632         [],
 633         [AC_MSG_FAILURE([sanitize flags '$enable_sanitize' not supported])])
 634 fi
 635
 636 dnl
 637 dnl Check if linker supports -Bsymbolic
 638 dnl
 639 save_LDFLAGS=$LDFLAGS
 640 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 641 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 642 AC_LINK_IFELSE(
 643     [AC_LANG_SOURCE([int main() { return 0;}])],
 644     [AC_MSG_RESULT([yes])
 645         BSYMBOLIC="-Wl,-Bsymbolic";],
 646     [AC_MSG_RESULT([no])
 647         BSYMBOLIC="";])
 648 LDFLAGS=$save_LDFLAGS
 649
 650 AC_SUBST([BSYMBOLIC])
 651
 652 dnl
 653 dnl Check if linker supports garbage collection
 654 dnl
 655 save_LDFLAGS=$LDFLAGS
 656 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 657 AC_MSG_CHECKING([whether ld supports --gc-sections])
 658 AC_LINK_IFELSE(
 659     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 660     [AC_MSG_RESULT([yes])
 661         GC_SECTIONS="-Wl,--gc-sections";],
 662     [AC_MSG_RESULT([no])
 663         GC_SECTIONS="";])
 664 LDFLAGS=$save_LDFLAGS
 665
 666 AC_SUBST([GC_SECTIONS])
 667
 668 dnl
 669 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 670 dnl so when these flags are passed to ld via libtool the checks will fail
 671 dnl
 672 case "$host_os" in
 673 openbsd* | darwin* )
 674     LD_NO_UNDEFINED="" ;;
 675 *)
 676     if test "x$enable_sanitize" = xno; then
 677         LD_NO_UNDEFINED="-Wl,--no-undefined"
 678     else
 679         LD_NO_UNDEFINED=""
 680     fi
 681     ;;
 682 esac
 683
 684 AC_SUBST([LD_NO_UNDEFINED])
 685
 686 dnl
 687 dnl Check if linker supports version scripts
 688 dnl
 689 AC_MSG_CHECKING([if the linker supports version-scripts])
 690 save_LDFLAGS=$LDFLAGS
 691 LDFLAGS="$LDFLAGS -Wl,--version-script=$srcdir/build-support/conftest.map"
 692 AC_LINK_IFELSE(
 693     [AC_LANG_SOURCE([int main() { return 0;}])],
 694     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 695     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 696 LDFLAGS=$save_LDFLAGS
 697 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 698
 699 dnl
 700 dnl Check if linker supports dynamic list files
 701 dnl
 702 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 703 save_LDFLAGS=$LDFLAGS
 704 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=$srcdir/build-support/conftest.dyn"
 705 AC_LINK_IFELSE(
 706     [AC_LANG_SOURCE([int main() { return 0;}])],
 707     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 708     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 709 LDFLAGS=$save_LDFLAGS
 710 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 711
 712 dnl
 713 dnl OSX linker does not support build-id
 714 dnl
 715 case "$host_os" in
 716 darwin*)
 717     LD_BUILD_ID=""
 718     ;;
 719 *)
 720     LD_BUILD_ID="-Wl,--build-id=sha1"
 721     ;;
 722 esac
 723 AC_SUBST([LD_BUILD_ID])
 724
 725 dnl
 726 dnl compatibility symlinks
 727 dnl
 728 case "$host_os" in
 729 linux* )
 730     HAVE_COMPAT_SYMLINKS=yes ;;
 731 * )
 732     HAVE_COMPAT_SYMLINKS=no ;;
 733 esac
 734
 735 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 736
 737 dnl
 738 dnl library names
 739 dnl
 740 dnl Unfortunately we need to do a few things that libtool can't help us with,
 741 dnl so we need some knowledge of shared library filenames:
 742 dnl
 743 dnl LIB_EXT is the extension used when creating symlinks for alternate
 744 dnl filenames for a shared library which will be dynamically loaded
 745 dnl
 746 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 747 dnl the file for a shared library we wish to link with
 748 dnl
 749 case "$host_os" in
 750 darwin* )
 751     LIB_EXT='dylib'
 752     IMP_LIB_EXT=$LIB_EXT
 753     ;;
 754 cygwin* )
 755     LIB_EXT='dll'
 756     IMP_LIB_EXT='dll.a'
 757     ;;
 758 aix* )
 759     LIB_EXT='a'
 760     IMP_LIB_EXT=$LIB_EXT
 761     ;;
 762 * )
 763     LIB_EXT='so'
 764     IMP_LIB_EXT=$LIB_EXT
 765     ;;
 766 esac
 767
 768 AC_SUBST([LIB_EXT])
 769
 770 dnl
 771 dnl Arch/platform-specific settings
 772 dnl
 773 AC_ARG_ENABLE([asm],
 774     [AS_HELP_STRING([--disable-asm],
 775         [disable assembly usage @<:@default=enabled on supported platforms@:>@])],
 776     [enable_asm="$enableval"],
 777     [enable_asm=yes]
 778 )
 779 asm_arch=""
 780 AC_MSG_CHECKING([whether to enable assembly])
 781 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 782 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 783 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 784     case "$host_cpu" in
 785     i?86 | x86_64 | amd64)
 786         if test "x$host_cpu" != "x$target_cpu"; then
 787             enable_asm=no
 788             AC_MSG_RESULT([no, cross compiling])
 789         fi
 790         ;;
 791     esac
 792 fi
 793 # check for supported arches
 794 if test "x$enable_asm" = xyes; then
 795     case "$host_cpu" in
 796     i?86)
 797         case "$host_os" in
 798         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 799             asm_arch=x86
 800             ;;
 801         esac
 802         ;;
 803     x86_64|amd64)
 804         case "$host_os" in
 805         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 806             asm_arch=x86_64
 807             ;;
 808         esac
 809         ;;
 810     sparc*)
 811         case "$host_os" in
 812         linux*)
 813             asm_arch=sparc
 814             ;;
 815         esac
 816         ;;
 817     powerpc64le)
 818         case "$host_os" in
 819         linux*)
 820             asm_arch=ppc64le
 821             ;;
 822         esac
 823         ;;
 824     aarch64)
 825         case "$host_os" in
 826         linux*)
 827             asm_arch=aarch64
 828             ;;
 829         esac
 830         ;;
 831     arm)
 832         case "$host_os" in
 833         linux*)
 834             asm_arch=arm
 835             ;;
 836         esac
 837         ;;
 838     esac
 839
 840     case "$asm_arch" in
 841     x86)
 842         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 843         AC_MSG_RESULT([yes, x86])
 844         ;;
 845     x86_64|amd64)
 846         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 847         AC_MSG_RESULT([yes, x86_64])
 848         ;;
 849     sparc)
 850         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 851         AC_MSG_RESULT([yes, sparc])
 852         ;;
 853     ppc64le)
 854         DEFINES="$DEFINES -DUSE_PPC64LE_ASM"
 855         AC_MSG_RESULT([yes, ppc64le])
 856         ;;
 857     aarch64)
 858         DEFINES="$DEFINES -DUSE_AARCH64_ASM"
 859         AC_MSG_RESULT([yes, aarch64])
 860         ;;
 861     arm)
 862         DEFINES="$DEFINES -DUSE_ARM_ASM"
 863         AC_MSG_RESULT([yes, arm])
 864         ;;
 865     *)
 866         AC_MSG_RESULT([no, platform not supported])
 867         ;;
 868     esac
 869 fi
 870
 871 AC_HEADER_MAJOR
 872 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 873 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 874 AC_CHECK_HEADERS([endian.h])
 875 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 876 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 877 AC_CHECK_FUNC([timespec_get], [DEFINES="$DEFINES -DHAVE_TIMESPEC_GET"])
 878 AC_CHECK_FUNC([memfd_create], [DEFINES="$DEFINES -DHAVE_MEMFD_CREATE"])
 879
 880 AC_MSG_CHECKING([whether strtod has locale support])
 881 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 882     #define _GNU_SOURCE
 883     #include <stdlib.h>
 884     #include <locale.h>
 885     #ifdef HAVE_XLOCALE_H
 886     #include <xlocale.h>
 887     #endif
 888     int main() {
 889        locale_t loc = newlocale(LC_CTYPE_MASK, "C", NULL);
 890        const char *s = "1.0";
 891        char *end;
 892        double d = strtod_l(s, end, loc);
 893        float f = strtof_l(s, end, loc);
 894        freelocale(loc);
 895        return 0;
 896     }]])],
 897   [DEFINES="$DEFINES -DHAVE_STRTOD_L"];
 898    AC_MSG_RESULT([yes]),
 899    AC_MSG_RESULT([no]))
 900
 901 dnl Check to see if dlopen is in default libraries (like Solaris, which
 902 dnl has it in libc), or if libdl is needed to get it.
 903 AC_CHECK_FUNC([dlopen], [],
 904     [AC_CHECK_LIB([dl], [dlopen],
 905        [DLOPEN_LIBS="-ldl"])])
 906 AC_SUBST([DLOPEN_LIBS])
 907
 908 dnl Check if that library also has dladdr
 909 save_LIBS="$LIBS"
 910 LIBS="$LIBS $DLOPEN_LIBS"
 911 AC_CHECK_FUNCS([dladdr])
 912 LIBS="$save_LIBS"
 913
 914 AC_CHECK_FUNC([dl_iterate_phdr], [DEFINES="$DEFINES -DHAVE_DL_ITERATE_PHDR"])
 915
 916 case "$host_os" in
 917 darwin*)
 918     ;;
 919 *)
 920     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 921                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 922                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 923     AC_SUBST([CLOCK_LIB])
 924     ;;
 925 esac
 926
 927 dnl See if posix_memalign is available
 928 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 929
 930 dnl Check for zlib
 931 PKG_CHECK_MODULES([ZLIB], [zlib >= $ZLIB_REQUIRED])
 932 DEFINES="$DEFINES -DHAVE_ZLIB"
 933
 934 dnl Check for pthreads
 935 AX_PTHREAD
 936 if test "x$ax_pthread_ok" = xno; then
 937     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 938 fi
 939 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 940 dnl to -pthread, which causes problems if we need -lpthread to appear in
 941 dnl pkgconfig files.  Since Android doesn't have a pthread lib, this check
 942 dnl is not valid for that platform.
 943 if test "x$android" = xno; then
 944     test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 945 fi
 946 dnl According to the manual when using pthreads, one should add -pthread to
 947 dnl both compile and link-time arguments.
 948 dnl In practise that should be sufficient for all platforms, since any
 949 dnl platforms build with GCC and Clang support the flag.
 950 PTHREAD_LIBS="$PTHREAD_LIBS -pthread"
 951
 952 dnl pthread-stubs is mandatory on some BSD platforms, due to the nature of the
 953 dnl project. Even then there's a notable issue as described in the project README
 954 case "$host_os" in
 955 linux* | cygwin* | darwin* | solaris* | *-gnu* | gnu* | openbsd*)
 956     pthread_stubs_possible="no"
 957     ;;
 958 * )
 959     pthread_stubs_possible="yes"
 960     ;;
 961 esac
 962
 963 if test "x$pthread_stubs_possible" = xyes; then
 964     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs >= 0.4)
 965 fi
 966
 967 dnl Check for futex for fast inline simple_mtx_t.
 968 AC_CHECK_HEADER([linux/futex.h], [DEFINES="$DEFINES -DHAVE_LINUX_FUTEX_H"])
 969
 970 dnl SELinux awareness.
 971 AC_ARG_ENABLE([selinux],
 972     [AS_HELP_STRING([--enable-selinux],
 973         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 974     [MESA_SELINUX="$enableval"],
 975     [MESA_SELINUX=no])
 976 if test "x$enable_selinux" = "xyes"; then
 977     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 978         [AC_CHECK_HEADER([selinux/selinux.h],[],
 979                          [AC_MSG_ERROR([SELinux headers not found])])
 980          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 981                       [AC_MSG_ERROR([SELinux library not found])])
 982          SELINUX_LIBS="-lselinux"])
 983     DEFINES="$DEFINES -DMESA_SELINUX"
 984 fi
 985 AC_SUBST([SELINUX_CFLAGS])
 986 AC_SUBST([SELINUX_LIBS])
 987
 988 dnl
 989 dnl LLVM
 990 dnl
 991 AC_ARG_ENABLE([llvm-shared-libs],
 992     [AS_HELP_STRING([--enable-llvm-shared-libs],
 993         [link with LLVM shared libraries @<:@default=enabled@:>@])],
 994     [enable_llvm_shared_libs="$enableval"],
 995     [enable_llvm_shared_libs=yes])
 996
 997 AC_ARG_WITH([llvm-prefix],
 998     [AS_HELP_STRING([--with-llvm-prefix],
 999         [Prefix for LLVM installations in non-standard locations])],
1000     [llvm_prefix="$withval"],
1001     [llvm_prefix=''])
1002
1003 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
1004 if test "x$have_libelf" = xno; then
1005    LIBELF_LIBS=''
1006    LIBELF_CFLAGS=''
1007    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
1008    AC_SUBST([LIBELF_LIBS])
1009    AC_SUBST([LIBELF_CFLAGS])
1010 fi
1011
1012 if test -z "$LLVM_CONFIG"; then
1013     if test -n "$llvm_prefix"; then
1014         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1015     else
1016         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1017     fi
1018 fi
1019
1020 llvm_add_component() {
1021     new_llvm_component=$1
1022     driver_name=$2
1023
1024     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
1025         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
1026     else
1027         AC_MSG_ERROR([LLVM component '$new_llvm_component' not enabled in your LLVM build. Required by $driver_name.])
1028     fi
1029 }
1030
1031 llvm_add_optional_component() {
1032     new_llvm_component=$1
1033     driver_name=$2
1034
1035     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
1036         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
1037     fi
1038 }
1039
1040 llvm_add_default_components() {
1041     driver_name=$1
1042
1043     # Required default components
1044     llvm_add_component "bitwriter" $driver_name
1045     llvm_add_component "engine" $driver_name
1046     llvm_add_component "mcdisassembler" $driver_name
1047     llvm_add_component "mcjit" $driver_name
1048
1049     # Optional default components
1050     llvm_add_optional_component "inteljitevents" $driver_name
1051 }
1052
1053 llvm_add_target() {
1054     new_llvm_target=$1
1055     driver_name=$2
1056
1057     if $LLVM_CONFIG --targets-built | grep -iqw $new_llvm_target ; then
1058         llvm_add_component $new_llvm_target $driver_name
1059     else
1060         AC_MSG_ERROR([LLVM target '$new_llvm_target' not enabled in your LLVM build. Required by $driver_name.])
1061     fi
1062 }
1063
1064 # Call this inside ` ` to get the return value.
1065 # $1 is the llvm-config command with arguments.
1066 strip_unwanted_llvm_flags() {
1067     echo " `$1` " | sed -E \
1068         -e 's/[[[:space:]]]+-m[[^[:space:]]]*//g' \
1069         -e 's/[[[:space:]]]+-DNDEBUG[[[:space:]]]/ /g' \
1070         -e 's/[[[:space:]]]+-D_GNU_SOURCE[[[:space:]]]/ /g' \
1071         -e 's/[[[:space:]]]+-pedantic[[[:space:]]]/ /g' \
1072         -e 's/[[[:space:]]]+-W[[^[:space:]]]*//g' \
1073         -e 's/[[[:space:]]]+-O[[^[:space:]]]*//g' \
1074         -e 's/[[[:space:]]]+-g[[^[:space:]]]*//g' \
1075         -e 's/-fno-rtti[[[:space:]]]/-Fno-rtti /g' \
1076         -e 's/[[[:space:]]]+-f[[^[:space:]]]*//g' \
1077         -e 's/-Fno-rtti[[[:space:]]]/-fno-rtti /g' \
1078         -e 's/^[[[:space:]]]//' \
1079         -e 's/[[[:space:]]]$//'
1080 }
1081
1082 llvm_set_environment_variables() {
1083     if test "x$LLVM_CONFIG" != xno; then
1084         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1085         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1086         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1087         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1088
1089         # We need to respect LLVM_CPPFLAGS when compiling LLVM headers.
1090         save_CFLAGS="$CFLAGS"
1091         CFLAGS="$CFLAGS $LLVM_CPPFLAGS"
1092
1093         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1094             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1095         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1096             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1097         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
1098             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1099
1100         CFLAGS="$save_CFLAGS"
1101
1102         # Only needed for LLVM < 3.6.0
1103         if test -z "$LLVM_VERSION_PATCH"; then
1104             LLVM_VERSION_PATCH=0
1105         fi
1106
1107         LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1108
1109         FOUND_LLVM=yes
1110     else
1111         FOUND_LLVM=no
1112         LLVM_VERSION_INT=0
1113     fi
1114 }
1115
1116 require_llvm() {
1117     if test "x$enable_llvm" != "xyes"; then
1118         AC_MSG_ERROR([--enable-llvm is required when building $1])
1119     fi
1120 }
1121
1122 llvm_require_version() {
1123     require_llvm $2
1124
1125     llvm_target_version_major=`echo $1 | cut -d. -f1 | egrep -o '^[[0-9]]+'`
1126     llvm_target_version_minor=`echo $1 | cut -d. -f2 | egrep -o '^[[0-9]]+'`
1127     llvm_target_version_patch=`echo $1 | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1128
1129     if test "$LLVM_VERSION_MAJOR" -gt "$llvm_target_version_major"; then
1130         # major > required major
1131         #  --> OK
1132         return
1133     fi
1134
1135     if test "$LLVM_VERSION_MAJOR" -eq "$llvm_target_version_major"; then
1136         if test "$LLVM_VERSION_MINOR" -gt "$llvm_target_version_minor"; then
1137             # major = required major and
1138             # minor > required minor
1139             #  --> OK
1140             return
1141         else
1142             if test "$LLVM_VERSION_MINOR" -eq "$llvm_target_version_minor"; then
1143                 if test "$LLVM_VERSION_PATCH" -ge "$llvm_target_version_patch"; then
1144                     # major = required major and
1145                     # minor = required minor and
1146                     # patch >= required patch
1147                     #  --> OK
1148                     return
1149                 fi
1150             fi
1151         fi
1152     fi
1153
1154     AC_MSG_ERROR([LLVM $1 or newer is required for $2])
1155 }
1156
1157 radeon_llvm_check() {
1158     if test ${LLVM_VERSION_INT} -lt 307; then
1159         amdgpu_llvm_target_name='r600'
1160     else
1161         amdgpu_llvm_target_name='amdgpu'
1162     fi
1163
1164     llvm_require_version $*
1165
1166     llvm_add_target $amdgpu_llvm_target_name $2
1167
1168     llvm_add_default_components $2
1169     llvm_add_component "bitreader" $2
1170     llvm_add_component "ipo" $2
1171
1172     if test "x$have_libelf" != xyes; then
1173        AC_MSG_ERROR([$2 requires libelf when using llvm])
1174     fi
1175 }
1176
1177 llvm_set_environment_variables
1178
1179 AC_SUBST([LLVM_CFLAGS])
1180 AC_SUBST([LLVM_CXXFLAGS])
1181 AC_SUBST([LLVM_LIBS])
1182 AC_SUBST([LLVM_LDFLAGS])
1183 AC_SUBST([LLVM_INCLUDEDIR])
1184
1185 dnl
1186 dnl libunwind
1187 dnl
1188 PKG_CHECK_EXISTS(libunwind, [HAVE_LIBUNWIND=yes], [HAVE_LIBUNWIND=no])
1189 AC_ARG_ENABLE([libunwind],
1190     [AS_HELP_STRING([--enable-libunwind],
1191             [Use libunwind for backtracing (default: auto)])],
1192         [LIBUNWIND="$enableval"],
1193         [LIBUNWIND="$HAVE_LIBUNWIND"])
1194
1195 if test "x$LIBUNWIND" = "xyes"; then
1196     PKG_CHECK_MODULES(LIBUNWIND, libunwind)
1197     AC_DEFINE(HAVE_LIBUNWIND, 1, [Have libunwind support])
1198 fi
1199
1200
1201 dnl Options for APIs
1202 AC_ARG_ENABLE([opengl],
1203     [AS_HELP_STRING([--disable-opengl],
1204         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
1205     [enable_opengl="$enableval"],
1206     [enable_opengl=yes])
1207 AC_ARG_ENABLE([gles1],
1208     [AS_HELP_STRING([--disable-gles1],
1209         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
1210     [enable_gles1="$enableval"],
1211     [enable_gles1=yes])
1212 AC_ARG_ENABLE([gles2],
1213     [AS_HELP_STRING([--disable-gles2],
1214         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
1215     [enable_gles2="$enableval"],
1216     [enable_gles2=yes])
1217
1218 AC_ARG_ENABLE([dri],
1219     [AS_HELP_STRING([--enable-dri],
1220         [enable DRI modules @<:@default=enabled@:>@])],
1221     [enable_dri="$enableval"],
1222     [enable_dri=yes])
1223
1224 AC_ARG_ENABLE([gallium-extra-hud],
1225     [AS_HELP_STRING([--enable-gallium-extra-hud],
1226         [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
1227     [enable_gallium_extra_hud="$enableval"],
1228     [enable_gallium_extra_hud=no])
1229 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
1230 if test "x$enable_gallium_extra_hud" = xyes ; then
1231     DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
1232 fi
1233
1234 #TODO: no pkgconfig .pc available for libsensors.
1235 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
1236 AC_ARG_ENABLE([lmsensors],
1237     [AS_HELP_STRING([--enable-lmsensors],
1238         [enable HUD lmsensor support @<:@default=disabled@:>@])],
1239     [enable_lmsensors="$enableval"],
1240     [enable_lmsensors=no])
1241 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
1242 if test "x$enable_lmsensors" = xyes ; then
1243     DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
1244     LIBSENSORS_LIBS="-lsensors"
1245 else
1246     LIBSENSORS_LIBS=""
1247 fi
1248 AC_SUBST(LIBSENSORS_LIBS)
1249
1250 case "$host_os" in
1251 linux*)
1252     dri3_default=yes
1253     ;;
1254 *)
1255     dri3_default=no
1256     ;;
1257 esac
1258
1259 if test "x$enable_dri" = xno; then
1260     dri3_default=no
1261 fi
1262
1263 AC_ARG_ENABLE([dri3],
1264     [AS_HELP_STRING([--enable-dri3],
1265         [enable DRI3 @<:@default=auto@:>@])],
1266     [enable_dri3="$enableval"],
1267     [enable_dri3="$dri3_default"])
1268 AC_ARG_ENABLE([glx],
1269     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
1270         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
1271     [enable_glx="$enableval"],
1272     [enable_glx=yes])
1273 AC_ARG_ENABLE([osmesa],
1274     [AS_HELP_STRING([--enable-osmesa],
1275         [enable OSMesa library @<:@default=disabled@:>@])],
1276     [enable_osmesa="$enableval"],
1277     [enable_osmesa=no])
1278 AC_ARG_ENABLE([gallium-osmesa],
1279     [AS_HELP_STRING([--enable-gallium-osmesa],
1280         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
1281     [enable_gallium_osmesa="$enableval"],
1282     [enable_gallium_osmesa=no])
1283 AC_ARG_ENABLE([egl],
1284     [AS_HELP_STRING([--disable-egl],
1285         [disable EGL library @<:@default=enabled@:>@])],
1286     [enable_egl="$enableval"],
1287     [enable_egl=yes])
1288
1289 AC_ARG_ENABLE([xa],
1290     [AS_HELP_STRING([--enable-xa],
1291         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
1292     [enable_xa="$enableval"],
1293     [enable_xa=no])
1294 AC_ARG_ENABLE([gbm],
1295    [AS_HELP_STRING([--enable-gbm],
1296          [enable gbm library @<:@default=yes except cygwin and macOS@:>@])],
1297    [enable_gbm="$enableval"],
1298    [case "$host_os" in
1299        cygwin* | darwin*)
1300           enable_gbm=no
1301           ;;
1302        *)
1303           enable_gbm=yes
1304           ;;
1305     esac])
1306 AC_ARG_ENABLE([nine],
1307     [AS_HELP_STRING([--enable-nine],
1308         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
1309     [enable_nine="$enableval"],
1310     [enable_nine=no])
1311
1312 AC_ARG_ENABLE([xvmc],
1313    [AS_HELP_STRING([--enable-xvmc],
1314          [enable xvmc library @<:@default=auto@:>@])],
1315    [enable_xvmc="$enableval"],
1316    [enable_xvmc=auto])
1317 AC_ARG_ENABLE([vdpau],
1318    [AS_HELP_STRING([--enable-vdpau],
1319          [enable vdpau library @<:@default=auto@:>@])],
1320    [enable_vdpau="$enableval"],
1321    [enable_vdpau=auto])
1322 AC_ARG_ENABLE([omx],
1323    [AS_HELP_STRING([--enable-omx],
1324          [DEPRECATED: Use --enable-omx-bellagio or --enable-omx-tizonia instead @<:@default=auto@:>@])],
1325    [AC_MSG_ERROR([--enable-omx is deprecated. Use --enable-omx-bellagio or --enable-omx-tizonia instead.])],
1326    [])
1327 AC_ARG_ENABLE([omx-bellagio],
1328    [AS_HELP_STRING([--enable-omx-bellagio],
1329          [enable OpenMAX Bellagio library @<:@default=disabled@:>@])],
1330    [enable_omx_bellagio="$enableval"],
1331    [enable_omx_bellagio=no])
1332 AC_ARG_ENABLE([omx-tizonia],
1333    [AS_HELP_STRING([--enable-omx-tizonia],
1334          [enable OpenMAX Tizonia library @<:@default=disabled@:>@])],
1335    [enable_omx_tizonia="$enableval"],
1336    [enable_omx_tizonia=no])
1337 AC_ARG_ENABLE([va],
1338    [AS_HELP_STRING([--enable-va],
1339          [enable va library @<:@default=auto@:>@])],
1340    [enable_va="$enableval"],
1341    [enable_va=auto])
1342 AC_ARG_ENABLE([opencl],
1343    [AS_HELP_STRING([--enable-opencl],
1344          [enable OpenCL library @<:@default=disabled@:>@])],
1345    [enable_opencl="$enableval"],
1346    [enable_opencl=no])
1347 AC_ARG_ENABLE([opencl_icd],
1348    [AS_HELP_STRING([--enable-opencl-icd],
1349           [Build an OpenCL ICD library to be loaded by an ICD implementation
1350            @<:@default=enabled@:>@])],
1351     [enable_opencl_icd="$enableval"],
1352     [enable_opencl_icd=yes])
1353
1354 AC_ARG_ENABLE([gallium-tests],
1355     [AS_HELP_STRING([--enable-gallium-tests],
1356         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1357     [enable_gallium_tests="$enableval"],
1358     [enable_gallium_tests=no])
1359
1360 # Option for Gallium drivers
1361
1362 # Keep this in sync with the --with-gallium-drivers help string default value
1363 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1364
1365 AC_ARG_WITH([gallium-drivers],
1366     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1367         [comma delimited Gallium drivers list, e.g.
1368         "i915,nouveau,r300,r600,radeonsi,freedreno,pl111,svga,swrast,swr,tegra,v3d,vc4,virgl,etnaviv,imx"
1369         @<:@default=r300,r600,svga,swrast@:>@])],
1370     [with_gallium_drivers="$withval"],
1371     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1372
1373 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
1374 # here so that the script doesn't choke on an unknown driver name later.
1375 case "$with_gallium_drivers" in
1376     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1377     no) with_gallium_drivers='' ;;
1378 esac
1379
1380 if test "x$enable_opengl" = xno -a \
1381         "x$enable_gles1" = xno -a \
1382         "x$enable_gles2" = xno -a \
1383         "x$enable_nine" = xno -a \
1384         "x$enable_xa" = xno -a \
1385         "x$enable_xvmc" = xno -a \
1386         "x$enable_vdpau" = xno -a \
1387         "x$enable_omx_bellagio" = xno -a \
1388         "x$enable_omx_tizonia" = xno -a \
1389         "x$enable_va" = xno -a \
1390         "x$enable_opencl" = xno; then
1391     AC_MSG_ERROR([at least one API should be enabled])
1392 fi
1393
1394 if test "x$enable_omx_bellagio" = xyes -a \
1395         "x$enable_omx_tizonia" = xyes; then
1396    AC_MSG_ERROR([Can't enable both bellagio and tizonia at same time])
1397 fi
1398
1399 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1400 if test "x$enable_opengl" = xno -a \
1401         "x$enable_gles1" = xyes; then
1402     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1403 fi
1404
1405 if test "x$enable_opengl" = xno -a \
1406         "x$enable_gles2" = xyes; then
1407     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1408 fi
1409
1410 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1411 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1412 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1413 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1414                                         "x$enable_gles1" = xyes -o \
1415                                         "x$enable_gles2" = xyes)
1416 AM_CONDITIONAL(NEED_KHRPLATFORM, test "x$enable_egl" = xyes -o \
1417                                       "x$enable_gles1" = xyes -o \
1418                                       "x$enable_gles2" = xyes)
1419
1420 # Validate GLX options
1421 if test "x$enable_glx" = xyes; then
1422     if test "x$enable_dri" = xyes; then
1423         enable_glx=dri
1424     elif test -n "$with_gallium_drivers"; then
1425         enable_glx=gallium-xlib
1426     else
1427         enable_glx=xlib
1428     fi
1429 fi
1430 case "x$enable_glx" in
1431 xdri | xxlib | xgallium-xlib)
1432     # GLX requires OpenGL
1433     if test "x$enable_opengl" = xno; then
1434         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1435     fi
1436
1437     # Check individual dependencies
1438     case "x$enable_glx" in
1439     xdri)
1440         if test "x$enable_dri" = xno; then
1441             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1442         fi
1443         ;;
1444     xxlib)
1445         if test "x$enable_dri" = xyes; then
1446             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1447         fi
1448         ;;
1449     xgallium-xlib )
1450         if test "x$enable_dri" = xyes; then
1451             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1452         fi
1453         if test -z "$with_gallium_drivers"; then
1454             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1455         fi
1456         ;;
1457     esac
1458     ;;
1459 xno)
1460     ;;
1461 *)
1462     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1463     ;;
1464 esac
1465
1466 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1467 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1468 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1469 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1470
1471 DEFAULT_GL_LIB_NAME=GL
1472
1473 dnl
1474 dnl Libglvnd configuration
1475 dnl
1476 AC_ARG_ENABLE([libglvnd],
1477     [AS_HELP_STRING([--enable-libglvnd],
1478         [Build GLX and EGL for libglvnd @<:@default=disabled@:>@])],
1479     [enable_libglvnd="$enableval"],
1480     [enable_libglvnd=no])
1481 AM_CONDITIONAL(USE_LIBGLVND, test "x$enable_libglvnd" = xyes)
1482
1483 if test "x$enable_libglvnd" = xyes ; then
1484     case "x$enable_glx" in
1485     xxlib | xgallium-xlib )
1486         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1487         ;;
1488     esac
1489
1490     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.2.0)
1491     LIBGLVND_DATADIR=`$PKG_CONFIG --variable=datadir libglvnd`
1492     AC_SUBST([LIBGLVND_DATADIR])
1493
1494     DEFINES="${DEFINES} -DUSE_LIBGLVND=1"
1495     DEFAULT_GL_LIB_NAME=GLX_mesa
1496
1497     if test "x$enable_glx" = xno -a "x$enable_egl" = xno; then
1498         AC_MSG_ERROR([cannot build libglvnd without GLX or EGL])
1499     fi
1500 fi
1501
1502 AC_ARG_WITH([gl-lib-name],
1503   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
1504     [specify GL library name @<:@default=GL@:>@])],
1505   [GL_LIB=$withval],
1506   [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1507 AC_ARG_WITH([osmesa-lib-name],
1508   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
1509     [specify OSMesa library name @<:@default=OSMesa@:>@])],
1510   [OSMESA_LIB=$withval],
1511   [OSMESA_LIB=OSMesa])
1512 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1513 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
1514
1515 dnl
1516 dnl Mangled Mesa support
1517 dnl
1518 AC_ARG_ENABLE([mangling],
1519   [AS_HELP_STRING([--enable-mangling],
1520     [enable mangled symbols and library name @<:@default=disabled@:>@])],
1521   [enable_mangling="${enableval}"],
1522   [enable_mangling=no]
1523 )
1524 if test "x${enable_mangling}" = "xyes" ; then
1525   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
1526   GL_LIB="Mangled${GL_LIB}"
1527   OSMESA_LIB="Mangled${OSMESA_LIB}"
1528 fi
1529 AC_SUBST([GL_LIB])
1530 AC_SUBST([OSMESA_LIB])
1531
1532 # Check for libdrm
1533 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1534                   [have_libdrm=yes], [have_libdrm=no])
1535 if test "x$have_libdrm" = xyes; then
1536     DEFINES="$DEFINES -DHAVE_LIBDRM"
1537 fi
1538
1539 require_libdrm() {
1540     if test "x$have_libdrm" != xyes; then
1541        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1542     fi
1543 }
1544
1545
1546 # Select which platform-dependent DRI code gets built
1547 case "$host_os" in
1548 darwin*)
1549     dri_platform='apple' ;;
1550 cygwin*)
1551     dri_platform='windows' ;;
1552 gnu*)
1553     dri_platform='none' ;;
1554 *)
1555     dri_platform='drm' ;;
1556 esac
1557
1558 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1559     have_drisw_kms='yes'
1560 fi
1561
1562 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1563 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1564 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1565 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1566 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1567 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1568 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1569 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1570 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1571 AM_CONDITIONAL(HAVE_XLEASE, test "x$have_xlease" = xyes )
1572
1573 AC_ARG_ENABLE([shared-glapi],
1574     [AS_HELP_STRING([--enable-shared-glapi],
1575         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1576     [enable_shared_glapi="$enableval"],
1577     [enable_shared_glapi=yes])
1578
1579 case "x$enable_opengl$enable_gles1$enable_gles2" in
1580 x*yes*yes*)
1581     if test "x$enable_shared_glapi" = xno; then
1582         AC_MSG_ERROR([shared GLAPI required when building two or more of
1583                       the following APIs - opengl, gles1 gles2])
1584     fi
1585     ;;
1586 esac
1587
1588 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1589
1590 # Build the pipe-drivers as separate libraries/modules.
1591 # Do not touch this unless you know what you are doing.
1592 # XXX: Expose via configure option ?
1593 enable_shared_pipe_drivers=no
1594
1595 dnl
1596 dnl Driver specific build directories
1597 dnl
1598
1599 if test "x$enable_gallium_osmesa" = xyes; then
1600     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1601         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1602     fi
1603     if test "x$enable_osmesa" = xyes; then
1604         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1605     fi
1606 fi
1607
1608 require_dri_shared_libs_and_glapi() {
1609     if test "x$enable_static" = xyes; then
1610         AC_MSG_ERROR([$1 cannot be build as static library])
1611     fi
1612
1613     if test "x$enable_dri" != xyes; then
1614         # There is only a single backend which won't be build/used otherwise.
1615         # XXX: Revisit this as the egl/haiku is a thing.
1616         AC_MSG_ERROR([$1 requires --enable-dri])
1617     fi
1618
1619     if test "x$enable_shared_glapi" != xyes; then
1620         AC_MSG_ERROR([$1 requires --enable-shared-glapi])
1621     fi
1622 }
1623
1624 if test "x$enable_dri" = xyes; then
1625     require_dri_shared_libs_and_glapi "DRI"
1626
1627     # not a hard requirement as swrast does not depend on it
1628     if test "x$have_libdrm" = xyes; then
1629         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1630     fi
1631 fi
1632
1633 AC_ARG_ENABLE([driglx-direct],
1634     [AS_HELP_STRING([--disable-driglx-direct],
1635         [disable direct rendering in GLX and EGL for DRI \
1636             @<:@default=enabled@:>@])],
1637     [driglx_direct="$enableval"],
1638     [driglx_direct="yes"])
1639
1640 dnl
1641 dnl libGL configuration per driver
1642 dnl
1643 if test "x$enable_glx" != xno; then
1644     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1645 fi
1646 case "x$enable_glx" in
1647 xxlib | xgallium-xlib)
1648     # Xlib-based GLX
1649     dri_modules="x11 xext xcb"
1650     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1651     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1652     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1653     GL_LIB_DEPS="$XLIBGL_LIBS"
1654     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1655     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1656     ;;
1657 xdri)
1658     # DRI-based GLX
1659
1660     # find the DRI deps for libGL
1661     dri_modules="x11 xext xdamage >= $XDAMAGE_REQUIRED xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1662
1663     if test x"$driglx_direct" = xyes; then
1664         if test x"$dri_platform" = xdrm ; then
1665             DEFINES="$DEFINES -DGLX_USE_DRM"
1666             require_libdrm "Direct rendering"
1667
1668             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1669             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1670
1671             if test x"$enable_dri" = xyes; then
1672                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1673             fi
1674         fi
1675         if test x"$dri_platform" = xapple ; then
1676             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1677         fi
1678         if test x"$dri_platform" = xwindows ; then
1679             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1680         fi
1681     fi
1682
1683     # add xf86vidmode if available
1684     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1685     if test "$HAVE_XF86VIDMODE" = yes ; then
1686         dri_modules="$dri_modules xxf86vm"
1687     fi
1688
1689     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1690     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1691     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1692     GL_LIB_DEPS="$DRIGL_LIBS"
1693
1694     # need DRM libs, $PTHREAD_LIBS, etc.
1695     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1696     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1697     ;;
1698 esac
1699
1700 # This is outside the case (above) so that it is invoked even for non-GLX
1701 # builds.
1702 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1703
1704 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1705 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1706 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1707 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1708
1709 AC_SUBST([X11_INCLUDES])
1710 AC_SUBST([GL_LIB_DEPS])
1711 AC_SUBST([GL_PC_REQ_PRIV])
1712 AC_SUBST([GL_PC_LIB_PRIV])
1713 AC_SUBST([GL_PC_CFLAGS])
1714 AC_SUBST([DRI_PC_REQ_PRIV])
1715 AC_SUBST([GLESv1_CM_LIB_DEPS])
1716 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1717 AC_SUBST([GLESv2_LIB_DEPS])
1718 AC_SUBST([GLESv2_PC_LIB_PRIV])
1719
1720 AC_SUBST([HAVE_XF86VIDMODE])
1721
1722 dnl
1723 dnl More GLX setup
1724 dnl
1725 case "x$enable_glx" in
1726 xxlib | xgallium-xlib)
1727     DEFINES="$DEFINES -DUSE_XSHM"
1728     ;;
1729 xdri)
1730     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1731     if test "x$driglx_direct" = xyes; then
1732         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1733     fi
1734     ;;
1735 esac
1736
1737 dnl
1738 dnl TLS detection
1739 dnl
1740
1741 AC_ARG_ENABLE([glx-tls],
1742     [AS_HELP_STRING([--enable-glx-tls],
1743         [enable TLS support in GLX @<:@default=enabled@:>@])],
1744     [GLX_USE_TLS="$enableval"],
1745     [GLX_USE_TLS=yes])
1746 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1747
1748 if test "x$GLX_USE_TLS" = xyes; then
1749     DEFINES="$DEFINES -DGLX_USE_TLS"
1750 fi
1751
1752 dnl Read-only text section on x86 hardened platforms
1753 AC_ARG_ENABLE([glx-read-only-text],
1754     [AS_HELP_STRING([--enable-glx-read-only-text],
1755         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1756     [enable_glx_read_only_text="$enableval"],
1757     [enable_glx_read_only_text=no])
1758 if test "x$enable_glx_read_only_text" = xyes; then
1759     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1760 fi
1761
1762 dnl
1763 dnl DEPRECATED: EGL Platforms configuration
1764 dnl
1765 AC_ARG_WITH([egl-platforms],
1766     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1767         [DEPRECATED: use --with-platforms instead@<:@default=auto@:>@])],
1768     [with_egl_platforms="$withval"],
1769     [with_egl_platforms=auto])
1770
1771 if test "x$with_egl_platforms" = xauto; then
1772     with_egl_platforms="x11,surfaceless"
1773     if test "x$enable_gbm" = xyes; then
1774         with_egl_platforms="$with_egl_platforms,drm"
1775     fi
1776 else
1777     AC_MSG_WARN([--with-egl-platforms is deprecated. Use --with-platforms instead.])
1778 fi
1779
1780 dnl
1781 dnl Platforms configuration
1782 dnl
1783 AC_ARG_WITH([platforms],
1784     [AS_HELP_STRING([--with-platforms@<:@=DIRS...@:>@],
1785         [comma delimited native platforms libEGL/Vulkan/other supports, e.g.
1786         "x11,drm,wayland,surfaceless..." @<:@default=auto@:>@])],
1787     [with_platforms="$withval"],
1788     [with_platforms=auto])
1789
1790 # Reuse the autodetection rather than duplicating it.
1791 if test "x$with_platforms" = xauto; then
1792     with_platforms=$with_egl_platforms
1793 fi
1794
1795 # Do per platform setups and checks
1796 platforms=`IFS=', '; echo $with_platforms`
1797 for plat in $platforms; do
1798     case "$plat" in
1799     wayland)
1800
1801         PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= $WAYLAND_REQUIRED])
1802         PKG_CHECK_MODULES([WAYLAND_SERVER], [wayland-server >= $WAYLAND_REQUIRED])
1803         PKG_CHECK_MODULES([WAYLAND_PROTOCOLS], [wayland-protocols >= $WAYLAND_PROTOCOLS_REQUIRED])
1804         if test "x$enable_egl" = xyes; then
1805           PKG_CHECK_MODULES([WAYLAND_EGL], [wayland-egl-backend >= $WAYLAND_EGL_BACKEND_REQUIRED])
1806         fi
1807         WAYLAND_PROTOCOLS_DATADIR=`$PKG_CONFIG --variable=pkgdatadir wayland-protocols`
1808
1809         PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
1810                           WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
1811                           WAYLAND_SCANNER='')
1812         if test "x$WAYLAND_SCANNER" = x; then
1813             AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner], [:])
1814         fi
1815
1816         if test "x$WAYLAND_SCANNER" = "x:"; then
1817                 AC_MSG_ERROR([wayland-scanner is needed to compile the wayland platform])
1818         fi
1819         DEFINES="$DEFINES -DHAVE_WAYLAND_PLATFORM -DWL_HIDE_DEPRECATED"
1820         ;;
1821
1822     x11)
1823         PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1824         DEFINES="$DEFINES -DHAVE_X11_PLATFORM"
1825         ;;
1826
1827     drm)
1828         test "x$enable_gbm" = "xno" &&
1829                 AC_MSG_ERROR([EGL platform drm needs gbm])
1830         DEFINES="$DEFINES -DHAVE_DRM_PLATFORM"
1831         ;;
1832
1833     surfaceless)
1834         DEFINES="$DEFINES -DHAVE_SURFACELESS_PLATFORM"
1835         ;;
1836
1837     android)
1838         PKG_CHECK_MODULES([ANDROID], [cutils hardware sync])
1839         if test -n "$with_gallium_drivers"; then
1840             PKG_CHECK_MODULES([BACKTRACE], [backtrace])
1841         fi
1842         DEFINES="$DEFINES -DHAVE_ANDROID_PLATFORM"
1843         ;;
1844
1845     *)
1846         AC_MSG_ERROR([platform '$plat' does not exist])
1847         ;;
1848     esac
1849
1850     case "$plat" in
1851     wayland|drm|surfaceless)
1852         require_libdrm "Platform $plat"
1853         ;;
1854     esac
1855 done
1856 AC_SUBST([WAYLAND_PROTOCOLS_DATADIR])
1857
1858 if test "x$enable_glx" != xno; then
1859     if ! echo "$platforms" | grep -q 'x11'; then
1860         AC_MSG_ERROR([Building GLX without the x11 platform is not supported])
1861     fi
1862 fi
1863
1864 if test x"$enable_dri3" = xyes; then
1865     DEFINES="$DEFINES -DHAVE_DRI3"
1866
1867     dri3_modules="x11-xcb xcb >= $XCB_REQUIRED xcb-dri3 xcb-xfixes xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1868     PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1869     dri3_modifier_modules="xcb-dri3 >= $XCBDRI3_MODIFIERS_REQUIRED xcb-present >= $XCBPRESENT_MODIFIERS_REQUIRED"
1870     PKG_CHECK_MODULES([XCB_DRI3_MODIFIERS], [$dri3_modifier_modules], [have_dri3_modifiers=yes], [have_dri3_modifiers=no])
1871
1872     if test "x$have_dri3_modifiers" == xyes; then
1873         DEFINES="$DEFINES -DHAVE_DRI3_MODIFIERS"
1874     fi
1875 fi
1876
1877
1878 if echo "$platforms" | grep -q 'x11' && echo "$platforms" | grep -q 'drm'; then
1879     have_xlease=yes
1880 else
1881     have_xlease=no
1882 fi
1883
1884 if test x"$have_xlease" = xyes; then
1885     randr_modules="x11-xcb xcb-randr"
1886     PKG_CHECK_MODULES([XCB_RANDR], [$randr_modules])
1887     xlib_randr_modules="xrandr"
1888     PKG_CHECK_MODULES([XLIB_RANDR], [$xlib_randr_modules])
1889 fi
1890
1891 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$platforms" | grep -q 'x11')
1892 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$platforms" | grep -q 'wayland')
1893 AM_CONDITIONAL(HAVE_PLATFORM_DRM, echo "$platforms" | grep -q 'drm')
1894 AM_CONDITIONAL(HAVE_PLATFORM_SURFACELESS, echo "$platforms" | grep -q 'surfaceless')
1895 AM_CONDITIONAL(HAVE_PLATFORM_ANDROID, echo "$platforms" | grep -q 'android')
1896
1897 AC_ARG_ENABLE(xlib-lease,
1898     [AS_HELP_STRING([--enable-xlib-lease]
1899                     [enable VK_acquire_xlib_display using X leases])],
1900     [enable_xlib_lease=$enableval], [enable_xlib_lease=auto])
1901 case "x$enable_xlib_lease" in
1902 xyes)
1903     ;;
1904 xno)
1905     ;;
1906 *)
1907     if echo "$platforms" | grep -q 'x11' && echo "$platforms" | grep -q 'drm'; then
1908         enable_xlib_lease=yes
1909     else
1910         enable_xlib_lease=no
1911     fi
1912 esac
1913
1914 AM_CONDITIONAL(HAVE_XLIB_LEASE, test "x$enable_xlib_lease" = xyes)
1915
1916 dnl
1917 dnl More DRI setup
1918 dnl
1919 dnl Directory for DRI drivers
1920 AC_ARG_WITH([dri-driverdir],
1921     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1922         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1923     [DRI_DRIVER_INSTALL_DIR="$withval"],
1924     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1925 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1926 dnl Extra search path for DRI drivers
1927 AC_ARG_WITH([dri-searchpath],
1928     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1929         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1930     [DRI_DRIVER_SEARCH_DIR="$withval"],
1931     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1932 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1933 dnl Which drivers to build - default is chosen by platform
1934 AC_ARG_WITH([dri-drivers],
1935     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1936         [comma delimited classic DRI drivers list, e.g.
1937         "i915,i965,nouveau,radeon,r200,swrast" @<:@default=auto@:>@])],
1938     [with_dri_drivers="$withval"],
1939     [with_dri_drivers=auto])
1940
1941 if test "x$with_dri_drivers" = xauto; then
1942     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1943         with_dri_drivers="yes"
1944     else
1945         with_dri_drivers="no"
1946     fi
1947 fi
1948 if test "x$with_dri_drivers" = xno; then
1949     with_dri_drivers=''
1950 fi
1951
1952 # Check for expat
1953 PKG_CHECK_MODULES([EXPAT], [expat],,
1954     [PKG_CHECK_MODULES([EXPAT], [expat21])]
1955 )
1956
1957 dnl If $with_dri_drivers is yes, drivers will be added through
1958 dnl platform checks. Set DEFINES and LIB_DEPS
1959 if test "x$enable_dri" = xyes; then
1960     # Platform specific settings and drivers to build
1961     case "$host_os" in
1962     linux*)
1963         case "$host_cpu" in
1964         powerpc* | sparc*)
1965             # Build only the drivers for cards that exist on PowerPC/sparc
1966             if test "x$with_dri_drivers" = "xyes"; then
1967                 with_dri_drivers="r200 radeon swrast"
1968             fi
1969             ;;
1970         esac
1971         ;;
1972     cygwin*)
1973         if test "x$with_dri_drivers" = "xyes"; then
1974             with_dri_drivers="swrast"
1975         fi
1976         ;;
1977     darwin*)
1978         DEFINES="$DEFINES -DBUILDING_MESA"
1979         if test "x$with_dri_drivers" = "xyes"; then
1980             with_dri_drivers="swrast"
1981         fi
1982         ;;
1983     esac
1984
1985     # default drivers
1986     if test "x$with_dri_drivers" = "xyes"; then
1987         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1988     fi
1989
1990     # put all the necessary libs together
1991     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1992 fi
1993
1994 AC_SUBST([DRI_LIB_DEPS])
1995
1996 DRI_DIRS=''
1997 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1998 if test -n "$with_dri_drivers"; then
1999     if test "x$enable_opengl" != xyes; then
2000         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
2001     fi
2002
2003     dri_drivers=`IFS=', '; echo $with_dri_drivers`
2004     for driver in $dri_drivers; do
2005         DRI_DIRS="$DRI_DIRS $driver"
2006         case "x$driver" in
2007         xi915)
2008             require_libdrm "i915"
2009             HAVE_I915_DRI=yes
2010             PKG_CHECK_MODULES([I915], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2011             ;;
2012         xi965)
2013             require_libdrm "i965"
2014             HAVE_I965_DRI=yes
2015             ;;
2016         xnouveau)
2017             require_libdrm "nouveau"
2018             HAVE_NOUVEAU_DRI=yes
2019             PKG_CHECK_MODULES([NVVIEUX], [libdrm >= $LIBDRM_NVVIEUX_REQUIRED libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
2020             ;;
2021         xradeon)
2022             require_libdrm "radeon"
2023             HAVE_RADEON_DRI=yes;
2024             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2025             ;;
2026         xr200)
2027             require_libdrm "r200"
2028             HAVE_R200_DRI=yes
2029             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2030             ;;
2031         xswrast)
2032             HAVE_SWRAST_DRI=yes
2033             ;;
2034         *)
2035             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
2036             ;;
2037         esac
2038     done
2039     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2040 fi
2041
2042
2043 dnl
2044 dnl Gallium LLVM
2045 dnl Deprecated: kept for backwards compatibility
2046 dnl
2047 AC_ARG_ENABLE([gallium-llvm],
2048     [AS_HELP_STRING([--enable-gallium-llvm],
2049         [DEPRECATED: use --enable-llvm instead])],
2050     [enable_gallium_llvm="$enableval"],
2051     [enable_gallium_llvm=auto])
2052
2053 if test "x$enable_gallium_llvm" != xauto; then
2054    AC_MSG_WARN([The --enable-gallium-llvm option has been deprecated. Use --enable-llvm instead.])
2055    enable_llvm=$enable_gallium_llvm
2056 fi
2057
2058 dnl
2059 dnl LLVM
2060 dnl
2061 AC_ARG_ENABLE([llvm],
2062     [AS_HELP_STRING([--enable-llvm],
2063         [build with LLVM support @<:@default=enabled on x86/x86_64@:>@])],
2064     [enable_llvm="$enableval"],
2065     [enable_llvm=auto])
2066
2067 if test "x$enable_llvm" = xauto -a "x$FOUND_LLVM" = xyes; then
2068     if test "x$FOUND_LLVM" = xyes; then
2069         case "$host_cpu" in
2070         i*86|x86_64|amd64) enable_llvm=yes;;
2071         *) enable_llvm=no;;
2072         esac
2073     else
2074         enable_llvm=no
2075     fi
2076 fi
2077
2078 if test "x$enable_llvm" = xyes -a "x$FOUND_LLVM" = xno; then
2079     AC_MSG_ERROR([--enable-llvm selected but llvm-config is not found])
2080 fi
2081
2082 #
2083 # Vulkan driver configuration
2084 #
2085
2086 AC_ARG_WITH([vulkan-drivers],
2087     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
2088         [comma delimited Vulkan drivers list, e.g.
2089         "intel,radeon"
2090         @<:@default=no@:>@])],
2091     [with_vulkan_drivers="$withval"],
2092     [with_vulkan_drivers="no"])
2093
2094 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
2095 # here so that the script doesn't choke on an unknown driver name later.
2096 case "x$with_vulkan_drivers" in
2097     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
2098     xno) with_vulkan_drivers='' ;;
2099 esac
2100
2101 AC_ARG_WITH([vulkan-icddir],
2102     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
2103         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
2104     [VULKAN_ICD_INSTALL_DIR="$withval"],
2105     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
2106 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
2107
2108 require_x11_dri3() {
2109     if echo "$platforms" | grep -q 'x11'; then
2110         if test "x$enable_dri3" != xyes; then
2111             AC_MSG_ERROR([$1 Vulkan driver requires DRI3 when built with X11])
2112         fi
2113     fi
2114 }
2115
2116 if test -n "$with_vulkan_drivers"; then
2117     if test "x$ac_cv_func_dl_iterate_phdr" = xno; then
2118         AC_MSG_ERROR([Vulkan drivers require the dl_iterate_phdr function])
2119     fi
2120
2121     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
2122     for driver in $VULKAN_DRIVERS; do
2123         case "x$driver" in
2124         xintel)
2125             require_libdrm "ANV"
2126             require_x11_dri3 "ANV"
2127             HAVE_INTEL_VULKAN=yes
2128             ;;
2129         xradeon)
2130             require_libdrm "radv"
2131             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2132             radeon_llvm_check $LLVM_REQUIRED_RADV "radv"
2133             require_x11_dri3 "radv"
2134             if test "x$acv_mako_found" = xno; then
2135                 AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
2136             fi
2137             HAVE_RADEON_VULKAN=yes
2138             ;;
2139         *)
2140             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
2141             ;;
2142         esac
2143     done
2144     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
2145 fi
2146
2147
2148 DEFINES="$DEFINES -DENABLE_SHADER_CACHE"
2149 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
2150 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
2151                                   "x$enable_osmesa" = xyes -o \
2152                                   -n "$DRI_DIRS")
2153
2154 dnl
2155 dnl OSMesa configuration
2156 dnl
2157
2158 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
2159 AC_ARG_WITH([osmesa-bits],
2160     [AS_HELP_STRING([--with-osmesa-bits=BITS],
2161         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
2162     [osmesa_bits="$withval"],
2163     [osmesa_bits=8])
2164 if test "x$osmesa_bits" != x8; then
2165     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
2166         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
2167         osmesa_bits=8
2168     fi
2169 fi
2170 case "x$osmesa_bits" in
2171 x8)
2172     OSMESA_LIB="${OSMESA_LIB}"
2173     ;;
2174 x16|x32)
2175     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
2176     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
2177     ;;
2178 *)
2179     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
2180     ;;
2181 esac
2182
2183 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
2184     # only link libraries with osmesa if shared
2185     if test "$enable_static" = no; then
2186         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2187     else
2188         OSMESA_LIB_DEPS=""
2189     fi
2190     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2191 fi
2192
2193 AC_SUBST([OSMESA_LIB_DEPS])
2194 AC_SUBST([OSMESA_PC_REQ])
2195 AC_SUBST([OSMESA_PC_LIB_PRIV])
2196
2197 dnl
2198 dnl gbm configuration
2199 dnl
2200 if test "x$enable_gbm" = xyes; then
2201     require_dri_shared_libs_and_glapi "gbm"
2202 fi
2203 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
2204 # FINISHME: GBM has a number of dependencies which we should add below
2205 GBM_PC_REQ_PRIV=""
2206 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
2207 AC_SUBST([GBM_PC_REQ_PRIV])
2208 AC_SUBST([GBM_PC_LIB_PRIV])
2209
2210 dnl
2211 dnl EGL configuration
2212 dnl
2213
2214 if test "x$enable_egl" = xyes; then
2215     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
2216
2217     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
2218
2219     require_dri_shared_libs_and_glapi "egl"
2220 fi
2221 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
2222 AC_SUBST([EGL_LIB_DEPS])
2223
2224 gallium_st="mesa"
2225
2226 dnl
2227 dnl XA configuration
2228 dnl
2229 if test "x$enable_xa" = xyes; then
2230     if test "x$with_gallium_drivers" = xswrast; then
2231        AC_MSG_ERROR([
2232           Building xa requires at least one non swrast gallium driver.
2233           If you are looking to use libxatracker.so with the VMware driver,
2234           make sure to include svga in the gallium drivers list, apart from
2235           enabling XA.
2236           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
2237     fi
2238     gallium_st="$gallium_st xa"
2239 fi
2240 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
2241
2242 if echo $platforms | grep -q "x11"; then
2243     have_xvmc_platform=yes
2244 else
2245     have_xvmc_platform=no
2246 fi
2247
2248 if echo $platforms | grep -q "x11"; then
2249     have_vdpau_platform=yes
2250 else
2251     have_vdpau_platform=no
2252 fi
2253
2254 if echo $platforms | egrep -q "x11|drm"; then
2255     have_omx_platform=yes
2256 else
2257     have_omx_platform=no
2258 fi
2259
2260 if echo $platforms | egrep -q "x11|drm|wayland"; then
2261     have_va_platform=yes
2262 else
2263     have_va_platform=no
2264 fi
2265
2266 dnl
2267 dnl Gallium G3DVL configuration
2268 dnl
2269 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
2270     if test "x$enable_xvmc" = xauto -a "x$have_xvmc_platform" = xyes; then
2271         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
2272     fi
2273
2274     if test "x$enable_vdpau" = xauto -a "x$have_vdpau_platform" = xyes; then
2275         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
2276     fi
2277
2278     if test "x$enable_omx_bellagio" = xauto -a "x$have_omx_platform" = xyes; then
2279         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx_bellagio=yes], [enable_omx_bellagio=no])
2280     fi
2281
2282     if test "x$enable_omx_tizonia" = xauto -a "x$have_omx_platform" = xyes; then
2283        PKG_CHECK_EXISTS([libtizonia >= $LIBOMXIL_TIZONIA_REQUIRED], [enable_omx_tizonia=yes], [enable_omx_tizonia=no])
2284     fi
2285
2286     if test "x$enable_va" = xauto -a "x$have_va_platform" = xyes; then
2287         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
2288     fi
2289 fi
2290
2291 if test "x$enable_dri" = xyes -o \
2292         "x$enable_xvmc" = xyes -o \
2293         "x$enable_vdpau" = xyes -o \
2294         "x$enable_omx_bellagio" = xyes -o \
2295         "x$enable_omx_tizonia" = xyes -o \
2296         "x$enable_va" = xyes; then
2297     need_gallium_vl=yes
2298 fi
2299 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
2300
2301 if test "x$enable_xvmc" = xyes -o \
2302         "x$enable_vdpau" = xyes -o \
2303         "x$enable_omx_bellagio" = xyes -o \
2304         "x$enable_omx_tizonia" = xyes -o \
2305         "x$enable_va" = xyes; then
2306     if echo $platforms | grep -q "x11"; then
2307         PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2308     fi
2309     need_gallium_vl_winsys=yes
2310 fi
2311 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
2312
2313 if test "x$enable_xvmc" = xyes; then
2314     if test "x$have_xvmc_platform" != xyes; then
2315         AC_MSG_ERROR([XVMC requires the x11 platforms])
2316     fi
2317     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
2318     gallium_st="$gallium_st xvmc"
2319 fi
2320 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
2321
2322 if test "x$enable_vdpau" = xyes; then
2323     if test "x$have_vdpau_platform" != xyes; then
2324         AC_MSG_ERROR([VDPAU requires the x11 platforms])
2325     fi
2326     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
2327     gallium_st="$gallium_st vdpau"
2328     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
2329 fi
2330 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
2331
2332 if test "x$enable_omx_bellagio" = xyes; then
2333     if test "x$have_omx_platform" != xyes; then
2334         AC_MSG_ERROR([OMX requires at least one of the x11 or drm platforms])
2335     fi
2336     PKG_CHECK_MODULES([OMX_BELLAGIO], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
2337     gallium_st="$gallium_st omx_bellagio"
2338     AC_DEFINE([ENABLE_ST_OMX_BELLAGIO], 1, [Use Bellagio for OMX IL])
2339 else
2340     AC_DEFINE([ENABLE_ST_OMX_BELLAGIO], 0)
2341 fi
2342 AM_CONDITIONAL(HAVE_ST_OMX_BELLAGIO, test "x$enable_omx_bellagio" = xyes)
2343
2344 if test "x$enable_omx_tizonia" = xyes; then
2345     if test "x$have_omx_platform" != xyes; then
2346         AC_MSG_ERROR([OMX requires at least one of the x11 or drm platforms])
2347     fi
2348     PKG_CHECK_MODULES([OMX_TIZONIA],
2349                       [libtizonia >= $LIBOMXIL_TIZONIA_REQUIRED
2350                        tizilheaders >= $LIBOMXIL_TIZONIA_REQUIRED
2351                        libtizplatform >= $LIBOMXIL_TIZONIA_REQUIRED])
2352     gallium_st="$gallium_st omx_tizonia"
2353     AC_DEFINE([ENABLE_ST_OMX_TIZONIA], 1, [Use Tizoina for OMX IL])
2354 else
2355     AC_DEFINE([ENABLE_ST_OMX_TIZONIA], 0)
2356 fi
2357 AM_CONDITIONAL(HAVE_ST_OMX_TIZONIA, test "x$enable_omx_tizonia" = xyes)
2358
2359 if test "x$enable_va" = xyes; then
2360     if test "x$have_va_platform" != xyes; then
2361         AC_MSG_ERROR([VA requires at least one of the x11 drm or wayland platforms])
2362     fi
2363     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
2364     gallium_st="$gallium_st va"
2365 fi
2366 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
2367
2368 dnl
2369 dnl Nine Direct3D9 configuration
2370 dnl
2371 if test "x$enable_nine" = xyes; then
2372     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
2373         AC_MSG_ERROR([nine requires the gallium swrast driver])
2374     fi
2375     if test "x$with_gallium_drivers" = xswrast; then
2376         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
2377     fi
2378     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
2379         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
2380     fi
2381
2382     if test "x$enable_dri3" = xno; then
2383         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
2384     fi
2385
2386     gallium_st="$gallium_st nine"
2387 fi
2388 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
2389
2390 dnl
2391 dnl OpenCL configuration
2392 dnl
2393
2394 AC_ARG_WITH([clang-libdir],
2395    [AS_HELP_STRING([--with-clang-libdir],
2396          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
2397    [CLANG_LIBDIR="$withval"],
2398    [CLANG_LIBDIR=''])
2399
2400 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
2401
2402 if test "x$enable_opencl" = xyes; then
2403     if test -z "$with_gallium_drivers"; then
2404         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
2405     fi
2406
2407     if test "x$HAVE_CXX11" != "xyes"; then
2408        AC_MSG_ERROR([clover requires c++11 support])
2409     fi
2410
2411     if test "x$have_libclc" = xno; then
2412         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
2413                     Make sure the directory containing libclc.pc is specified in your
2414                     PKG_CONFIG_PATH environment variable.
2415                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
2416     else
2417         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
2418         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
2419         AC_SUBST([LIBCLC_INCLUDEDIR])
2420         AC_SUBST([LIBCLC_LIBEXECDIR])
2421     fi
2422
2423     gallium_st="$gallium_st clover"
2424
2425     if test "x$enable_opencl_icd" = xyes; then
2426         OPENCL_LIBNAME="MesaOpenCL"
2427     else
2428         OPENCL_LIBNAME="OpenCL"
2429     fi
2430
2431     if test "x$have_libelf" != xyes; then
2432        AC_MSG_ERROR([Clover requires libelf])
2433     fi
2434
2435     if test "x${ac_cv_cxx_compiler_gnu}" = xyes; then
2436         altivec_enabled=no
2437         AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2438         #if !defined(__VEC__) || !defined(__ALTIVEC__)
2439         #error "AltiVec not enabled"
2440         #endif
2441         ])], altivec_enabled=yes)
2442
2443         if test "$altivec_enabled" = yes; then
2444             CLOVER_STD_OVERRIDE="-std=gnu++11"
2445         fi
2446         AC_SUBST([CLOVER_STD_OVERRIDE])
2447     fi
2448
2449     llvm_require_version $LLVM_REQUIRED_OPENCL "opencl"
2450
2451     llvm_add_default_components "opencl"
2452     llvm_add_component "all-targets" "opencl"
2453     llvm_add_component "coverage" "opencl"
2454     llvm_add_component "linker" "opencl"
2455     llvm_add_component "instrumentation" "opencl"
2456     llvm_add_component "ipo" "opencl"
2457     llvm_add_component "irreader" "opencl"
2458     llvm_add_component "lto" "opencl"
2459     llvm_add_component "option" "opencl"
2460     llvm_add_component "objcarcopts" "opencl"
2461     llvm_add_component "profiledata" "opencl"
2462     llvm_add_optional_component "coroutines" "opencl"
2463
2464     dnl Check for Clang internal headers
2465     if test -z "$CLANG_LIBDIR"; then
2466         CLANG_LIBDIR=${LLVM_LIBDIR}
2467     fi
2468     CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2469     AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2470         [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2471 fi
2472 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2473 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2474 AC_SUBST([OPENCL_LIBNAME])
2475 AC_SUBST([CLANG_RESOURCE_DIR])
2476
2477 dnl
2478 dnl Gallium configuration
2479 dnl
2480 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2481
2482 # libEGL wants to default to the first platform specified in
2483 # ./configure.  parse that here.
2484 if test "x$platforms" != "x"; then
2485     FIRST_PLATFORM_CAPS=`echo $platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2486     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2487 else
2488     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2489 fi
2490
2491 AC_SUBST([EGL_NATIVE_PLATFORM])
2492 AC_SUBST([EGL_CFLAGS])
2493
2494 # If we don't have the X11 platform, set this define so we don't try to include
2495 # the X11 headers.
2496 if ! echo "$platforms" | grep -q 'x11'; then
2497     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2498     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2499 fi
2500
2501 dnl Directory for XVMC libs
2502 AC_ARG_WITH([xvmc-libdir],
2503     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2504         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2505     [XVMC_LIB_INSTALL_DIR="$withval"],
2506     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2507 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2508
2509 dnl
2510 dnl Gallium Tests
2511 dnl
2512 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2513
2514 dnl Directory for VDPAU libs
2515 AC_ARG_WITH([vdpau-libdir],
2516     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2517         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2518     [VDPAU_LIB_INSTALL_DIR="$withval"],
2519     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2520 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2521
2522 dnl Directory for OMX_BELLAGIO libs
2523
2524 AC_ARG_WITH([omx-bellagio-libdir],
2525     [AS_HELP_STRING([--with-omx-bellagio-libdir=DIR],
2526         [directory for the OMX_BELLAGIO libraries])],
2527     [OMX_BELLAGIO_LIB_INSTALL_DIR="$withval"],
2528     [OMX_BELLAGIO_LIB_INSTALL_DIR=`$PKG_CONFIG --exists libomxil-bellagio && \
2529                                    $PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2530 AC_SUBST([OMX_BELLAGIO_LIB_INSTALL_DIR])
2531
2532 dnl Directory for OMX_TIZONIA libs
2533
2534 AC_ARG_WITH([omx-tizonia-libdir],
2535     [AS_HELP_STRING([--with-omx-tizonia-libdir=DIR],
2536         [directory for the OMX_TIZONIA libraries])],
2537     [OMX_TIZONIA_LIB_INSTALL_DIR="$withval"],
2538     [OMX_TIZONIA_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libtizcore`])
2539 AC_SUBST([OMX_TIZONIA_LIB_INSTALL_DIR])
2540
2541 dnl Directory for VA libs
2542
2543 AC_ARG_WITH([va-libdir],
2544     [AS_HELP_STRING([--with-va-libdir=DIR],
2545         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2546     [VA_LIB_INSTALL_DIR="$withval"],
2547     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2548 AC_SUBST([VA_LIB_INSTALL_DIR])
2549
2550 AC_ARG_WITH([d3d-libdir],
2551     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2552         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2553     [D3D_DRIVER_INSTALL_DIR="$withval"],
2554     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2555 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2556
2557 dnl Architectures to build SWR library for
2558
2559 AC_ARG_WITH([swr-archs],
2560     [AS_HELP_STRING([--with-swr-archs@<:@=DIRS...@:>@],
2561         [comma delimited swr architectures list, e.g.
2562         "avx,avx2,knl,skx" @<:@default="avx,avx2"@:>@])],
2563     [with_swr_archs="$withval"],
2564     [with_swr_archs="avx,avx2"])
2565
2566 dnl
2567 dnl r300 doesn't strictly require LLVM, but for performance reasons we
2568 dnl highly recommend LLVM usage. So require it at least on x86 and x86_64
2569 dnl architectures.
2570 dnl
2571 r300_require_llvm() {
2572     case "$host" in *gnux32) return;; esac
2573     case "$host_cpu" in
2574     i*86|x86_64|amd64) require_llvm $1
2575         ;;
2576     esac
2577 }
2578
2579 dnl
2580 dnl DRM is needed by X, Wayland, and offscreen rendering.
2581 dnl Surfaceless is an alternative for the last one.
2582 dnl
2583 require_basic_egl() {
2584     case "$with_platforms" in
2585         *drm*|*surfaceless*|*android*)
2586             ;;
2587         *)
2588             AC_MSG_ERROR([$1 requires one of these:
2589                   1) --with-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2590                   2) --with-platforms=surfaceless (offscreen only)
2591                   3) --with-platforms=android (Android only)
2592                   Recommended options: drm,x11])
2593             ;;
2594     esac
2595 }
2596
2597 swr_require_cxx_feature_flags() {
2598     feature_name="$1"
2599     preprocessor_test="$2"
2600     option_list="$3"
2601     output_var="$4"
2602
2603     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2604     AC_LANG_PUSH([C++])
2605     save_CXXFLAGS="$CXXFLAGS"
2606     save_IFS="$IFS"
2607     IFS=","
2608     found=0
2609     for opts in $option_list
2610     do
2611         unset IFS
2612         CXXFLAGS="$opts $save_CXXFLAGS"
2613         AC_COMPILE_IFELSE(
2614             [AC_LANG_PROGRAM(
2615                 [   #if !($preprocessor_test)
2616                     #error
2617                     #endif
2618                 ])],
2619             [found=1; break],
2620             [])
2621         IFS=","
2622     done
2623     IFS="$save_IFS"
2624     CXXFLAGS="$save_CXXFLAGS"
2625     AC_LANG_POP([C++])
2626     if test $found -eq 1; then
2627         AC_MSG_RESULT([$opts])
2628         eval "$output_var=\$opts"
2629         return 0
2630     fi
2631     AC_MSG_RESULT([no])
2632     AC_MSG_ERROR([swr requires $feature_name support])
2633     return 1
2634 }
2635
2636 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2637 if test -n "$with_gallium_drivers"; then
2638     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2639     for driver in $gallium_drivers; do
2640         case "x$driver" in
2641         xsvga)
2642             HAVE_GALLIUM_SVGA=yes
2643             require_libdrm "svga"
2644             ;;
2645         xi915)
2646             HAVE_GALLIUM_I915=yes
2647             PKG_CHECK_MODULES([I915], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2648             require_libdrm "Gallium i915"
2649             ;;
2650         xr300)
2651             HAVE_GALLIUM_R300=yes
2652             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2653             require_libdrm "r300"
2654             r300_require_llvm "r300"
2655             ;;
2656         xr600)
2657             HAVE_GALLIUM_R600=yes
2658             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2659             require_libdrm "r600"
2660             if test "x$enable_llvm" = xyes; then
2661                 radeon_llvm_check $LLVM_REQUIRED_R600 "r600"
2662
2663                 llvm_add_component "asmparser" "r600"
2664                 llvm_add_component "bitreader" "r600"
2665             fi
2666             ;;
2667         xradeonsi)
2668             HAVE_GALLIUM_RADEONSI=yes
2669             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2670             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2671             require_libdrm "radeonsi"
2672             radeon_llvm_check $LLVM_REQUIRED_RADEONSI "radeonsi"
2673             if test "x$enable_egl" = xyes; then
2674                 require_basic_egl "radeonsi"
2675             fi
2676             ;;
2677         xnouveau)
2678             HAVE_GALLIUM_NOUVEAU=yes
2679             PKG_CHECK_MODULES([NOUVEAU], [libdrm >= $LIBDRM_NOUVEAU_REQUIRED libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2680             require_libdrm "nouveau"
2681             ;;
2682         xfreedreno)
2683             HAVE_GALLIUM_FREEDRENO=yes
2684             PKG_CHECK_MODULES([FREEDRENO], [libdrm >= $LIBDRM_FREEDRENO_REQUIRED libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2685             require_libdrm "freedreno"
2686             ;;
2687         xetnaviv)
2688             HAVE_GALLIUM_ETNAVIV=yes
2689             PKG_CHECK_MODULES([ETNAVIV], [libdrm >= $LIBDRM_ETNAVIV_REQUIRED libdrm_etnaviv >= $LIBDRM_ETNAVIV_REQUIRED])
2690             require_libdrm "etnaviv"
2691             ;;
2692        ximx)
2693             HAVE_GALLIUM_IMX=yes
2694             ;;
2695         xtegra)
2696             HAVE_GALLIUM_TEGRA=yes
2697             require_libdrm "tegra"
2698             ;;
2699         xswrast)
2700             HAVE_GALLIUM_SOFTPIPE=yes
2701             if test "x$enable_llvm" = xyes; then
2702                 HAVE_GALLIUM_LLVMPIPE=yes
2703             fi
2704             ;;
2705         xswr)
2706             llvm_require_version $LLVM_REQUIRED_SWR "swr"
2707
2708             if test "x$HAVE_CXX11" != "xyes"; then
2709                 AC_MSG_ERROR([swr requires c++11 support])
2710             fi
2711
2712             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2713                 ",-target-cpu=sandybridge,-mavx,-march=core-avx,-tp=sandybridge" \
2714                 SWR_AVX_CXXFLAGS
2715             AC_SUBST([SWR_AVX_CXXFLAGS])
2716
2717             swr_archs=`IFS=', '; echo $with_swr_archs`
2718             for arch in $swr_archs; do
2719                 case "x$arch" in
2720                 xavx)
2721                     HAVE_SWR_AVX=yes
2722                     ;;
2723                 xavx2)
2724                     swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2725                         ",-target-cpu=haswell,-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2,-tp=haswell" \
2726                         SWR_AVX2_CXXFLAGS
2727                     AC_SUBST([SWR_AVX2_CXXFLAGS])
2728                     HAVE_SWR_AVX2=yes
2729                     ;;
2730                 xknl)
2731                     swr_require_cxx_feature_flags "KNL" "defined(__AVX512F__) && defined(__AVX512ER__)" \
2732                         ",-target-cpu=mic-knl,-march=knl,-xMIC-AVX512" \
2733                         SWR_KNL_CXXFLAGS
2734                     AC_SUBST([SWR_KNL_CXXFLAGS])
2735                     HAVE_SWR_KNL=yes
2736                     ;;
2737                 xskx)
2738                     swr_require_cxx_feature_flags "SKX" "defined(__AVX512F__) && defined(__AVX512BW__)" \
2739                         ",-target-cpu=x86-skylake,-march=skylake-avx512,-xCORE-AVX512" \
2740                         SWR_SKX_CXXFLAGS
2741                     AC_SUBST([SWR_SKX_CXXFLAGS])
2742                     HAVE_SWR_SKX=yes
2743                     ;;
2744                 *)
2745                     AC_MSG_ERROR([unknown SWR build architecture '$arch'])
2746                     ;;
2747                 esac
2748             done
2749
2750             if test "x$HAVE_SWR_AVX" != xyes -a \
2751                     "x$HAVE_SWR_AVX2" != xyes -a \
2752                     "x$HAVE_SWR_KNL" != xyes -a \
2753                     "x$HAVE_SWR_SKX" != xyes; then
2754                AC_MSG_ERROR([swr enabled but no swr architectures selected])
2755             fi
2756
2757             # test if more than one swr arch configured
2758             if test `echo $swr_archs | wc -w` -eq 1; then
2759                 HAVE_SWR_BUILTIN=yes
2760             fi
2761
2762             HAVE_GALLIUM_SWR=yes
2763             ;;
2764         xvc4)
2765             HAVE_GALLIUM_VC4=yes
2766             PKG_CHECK_MODULES([VC4], [libdrm >= $LIBDRM_VC4_REQUIRED])
2767
2768             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2769                               [USE_VC4_SIMULATOR=yes;
2770                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2771                               [USE_VC4_SIMULATOR=no])
2772             ;;
2773         xv3d)
2774             HAVE_GALLIUM_V3D=yes
2775
2776             PKG_CHECK_MODULES([V3D_SIMULATOR], [v3dv3],
2777                               [USE_V3D_SIMULATOR=yes;
2778                                DEFINES="$DEFINES -DUSE_V3D_SIMULATOR"],
2779                               [USE_V3D_SIMULATOR=no])
2780             ;;
2781         xpl111)
2782             HAVE_GALLIUM_PL111=yes
2783             ;;
2784         xvirgl)
2785             HAVE_GALLIUM_VIRGL=yes
2786             require_libdrm "virgl"
2787             if test "x$enable_egl" = xyes; then
2788                 require_basic_egl "virgl"
2789             fi
2790             ;;
2791         *)
2792             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2793             ;;
2794         esac
2795     done
2796 fi
2797
2798 # XXX: Keep in sync with LLVM_REQUIRED_SWR
2799 AM_CONDITIONAL(SWR_INVALID_LLVM_VERSION, test "x$LLVM_VERSION" != x5.0.0 -a \
2800                                               "x$LLVM_VERSION" != x5.0.1 -a \
2801                                               "x$LLVM_VERSION" != x5.0.2)
2802
2803 if test "x$enable_llvm" = "xyes" -a "$with_gallium_drivers"; then
2804     llvm_require_version $LLVM_REQUIRED_GALLIUM "gallium"
2805     llvm_add_default_components "gallium"
2806 fi
2807
2808 AM_CONDITIONAL(HAVE_SWR_AVX, test "x$HAVE_SWR_AVX" = xyes)
2809 AM_CONDITIONAL(HAVE_SWR_AVX2, test "x$HAVE_SWR_AVX2" = xyes)
2810 AM_CONDITIONAL(HAVE_SWR_KNL, test "x$HAVE_SWR_KNL" = xyes)
2811 AM_CONDITIONAL(HAVE_SWR_SKX, test "x$HAVE_SWR_SKX" = xyes)
2812 AM_CONDITIONAL(HAVE_SWR_BUILTIN, test "x$HAVE_SWR_BUILTIN" = xyes)
2813
2814 dnl We need to validate some needed dependencies for renderonly drivers.
2815
2816 if test "x$HAVE_GALLIUM_ETNAVIV" != xyes -a "x$HAVE_GALLIUM_IMX" = xyes  ; then
2817     AC_MSG_ERROR([Building with imx requires etnaviv])
2818 fi
2819
2820 if test "x$HAVE_GALLIUM_VC4" != xyes -a "x$HAVE_GALLIUM_PL111" = xyes  ; then
2821     AC_MSG_ERROR([Building with pl111 requires vc4])
2822 fi
2823
2824 if test "x$HAVE_GALLIUM_NOUVEAU" != xyes -a "x$HAVE_GALLIUM_TEGRA" = xyes; then
2825     AC_MSG_ERROR([Building with tegra requires nouveau])
2826 fi
2827
2828 detect_old_buggy_llvm() {
2829     dnl llvm-config may not give the right answer when llvm is a built as a
2830     dnl single shared library, so we must work the library name out for
2831     dnl ourselves.
2832     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2833     dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2834     LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2835     AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2836
2837     if test "x$llvm_have_one_so" = xyes; then
2838         dnl LLVM was built using auto*, so there is only one shared object.
2839         LLVM_LIBS="-l$LLVM_SO_NAME"
2840     else
2841         dnl If LLVM was built with CMake, there will be one shared object per
2842         dnl component.
2843         AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2844                [AC_MSG_ERROR([Could not find llvm shared libraries:
2845                 Please make sure you have built llvm with the --enable-shared option
2846                 and that your llvm libraries are installed in $LLVM_LIBDIR
2847                 If you have installed your llvm libraries to a different directory you
2848                 can use the --with-llvm-prefix= configure flag to specify this directory.
2849                 NOTE: Mesa is attempting to use llvm shared libraries by default.
2850                 If you do not want to build with llvm shared libraries and instead want to
2851                 use llvm static libraries then add --disable-llvm-shared-libs to your configure
2852                 invocation and rebuild.])])
2853
2854         dnl We don't need to update LLVM_LIBS in this case because the LLVM
2855         dnl install uses a shared object for each component and we have
2856         dnl already added all of these objects to LLVM_LIBS.
2857     fi
2858 }
2859
2860 dnl
2861 dnl Set defines and buildtime variables only when using LLVM.
2862 dnl
2863 if test "x$enable_llvm" = xyes; then
2864     DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2865
2866     LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2867     LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
2868     LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2869
2870     dnl Set LLVM_LIBS - This is done after the driver configuration so
2871     dnl that drivers can add additional components to LLVM_COMPONENTS.
2872     dnl Previously, gallium drivers were updating LLVM_LIBS directly
2873     dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2874     dnl this was causing the same libraries to be appear multiple times
2875     dnl in LLVM_LIBS.
2876
2877     if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 9; then
2878         if test "x$enable_llvm_shared_libs" = xyes; then
2879             LLVM_LIBS="`$LLVM_CONFIG --link-shared --libs ${LLVM_COMPONENTS}`"
2880         else
2881             dnl Invoking llvm-config with both -libs and --system-libs produces the
2882             dnl two separate lines - each for the set of libraries.
2883                 dnl Call the program twice, effectively folding them into a single line.
2884             LLVM_LIBS="`$LLVM_CONFIG --link-static --libs ${LLVM_COMPONENTS}`"
2885             dnl We need to link to llvm system libs when using static libs
2886             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --link-static --system-libs`"
2887         fi
2888     else
2889         LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2890         if test "x$enable_llvm_shared_libs" = xyes; then
2891             detect_old_buggy_llvm
2892         else
2893             AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2894             dnl We need to link to llvm system libs when using static libs
2895             dnl However, only llvm 3.5+ provides --system-libs
2896             if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2897                 LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2898             fi
2899         fi
2900     fi
2901
2902     dnl The gallium-xlib GLX and gallium OSMesa targets directly embed the
2903     dnl swr/llvmpipe driver into the final binary.  Adding LLVM_LIBS results in
2904     dnl the LLVM library propagated in the Libs.private of the respective .pc
2905     dnl file which ensures complete dependency information when statically
2906     dnl linking.
2907     if test "x$enable_glx" == xgallium-xlib; then
2908         GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $LLVM_LIBS"
2909     fi
2910     if test "x$enable_gallium_osmesa" = xyes; then
2911         OSMESA_PC_LIB_PRIV="$OSMESA_PC_LIB_PRIV $LLVM_LIBS"
2912     fi
2913 fi
2914
2915 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2916 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2917 AM_CONDITIONAL(HAVE_GALLIUM_PL111, test "x$HAVE_GALLIUM_PL111" = xyes)
2918 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2919 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2920 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2921 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2922 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2923 AM_CONDITIONAL(HAVE_GALLIUM_ETNAVIV, test "x$HAVE_GALLIUM_ETNAVIV" = xyes)
2924 AM_CONDITIONAL(HAVE_GALLIUM_IMX, test "x$HAVE_GALLIUM_IMX" = xyes)
2925 AM_CONDITIONAL(HAVE_GALLIUM_TEGRA, test "x$HAVE_GALLIUM_TEGRA" = xyes)
2926 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2927 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2928 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2929 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2930                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2931                                          "x$HAVE_GALLIUM_SWR" = xyes)
2932 AM_CONDITIONAL(HAVE_GALLIUM_V3D, test "x$HAVE_GALLIUM_V3D" = xyes)
2933 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2934 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2935
2936 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2937
2938 if test "x$enable_dri" = xyes; then
2939     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2940 fi
2941
2942 if test "x$have_drisw_kms" = xyes; then
2943     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2944 fi
2945 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2946
2947 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2948 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2949 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2950 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2951 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2952 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2953
2954 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2955 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2956
2957 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2958                                       "x$HAVE_RADEON_VULKAN" = xyes)
2959
2960 AM_CONDITIONAL(HAVE_BROADCOM_DRIVERS, test "x$HAVE_GALLIUM_VC4" = xyes -o \
2961                                       "x$HAVE_GALLIUM_V3D" = xyes)
2962
2963 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2964                                         "x$HAVE_I965_DRI" = xyes)
2965
2966 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2967                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2968                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2969 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2970 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2971 AM_CONDITIONAL(HAVE_GALLIUM_LLVM, test "x$enable_llvm" = xyes)
2972 AM_CONDITIONAL(USE_V3D_SIMULATOR, test x$USE_V3D_SIMULATOR = xyes)
2973 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2974
2975 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2976 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2977 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2978 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
2979                                         "x$enable_gallium_osmesa" = xyes)
2980
2981 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2982 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2983 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2984 AM_CONDITIONAL(HAVE_PPC64LE_ASM, test "x$asm_arch" = xppc64le)
2985 AM_CONDITIONAL(HAVE_AARCH64_ASM, test "x$asm_arch" = xaarch64)
2986 AM_CONDITIONAL(HAVE_ARM_ASM, test "x$asm_arch" = xarm)
2987
2988 AC_SUBST([NINE_MAJOR], 1)
2989 AC_SUBST([NINE_MINOR], 0)
2990 AC_SUBST([NINE_PATCH], 0)
2991 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_PATCH")
2992
2993 AC_SUBST([VDPAU_MAJOR], 1)
2994 AC_SUBST([VDPAU_MINOR], 0)
2995
2996 if test "x$enable_va" = xyes; then
2997     VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2998     VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2999 fi
3000 AC_SUBST([VA_MAJOR], $VA_MAJOR)
3001 AC_SUBST([VA_MINOR], $VA_MINOR)
3002
3003 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
3004
3005 AC_SUBST([XVMC_MAJOR], 1)
3006 AC_SUBST([XVMC_MINOR], 0)
3007
3008 AC_SUBST([XA_MAJOR], 2)
3009 AC_SUBST([XA_MINOR], 4)
3010 AC_SUBST([XA_PATCH], 0)
3011 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_PATCH")
3012
3013 AC_ARG_ENABLE(valgrind,
3014               [AS_HELP_STRING([--enable-valgrind],
3015                              [Build mesa with valgrind support (default: auto)])],
3016                              [VALGRIND=$enableval], [VALGRIND=auto])
3017 if test "x$VALGRIND" != xno; then
3018     PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
3019 fi
3020 AC_MSG_CHECKING([whether to enable Valgrind support])
3021 if test "x$VALGRIND" = xauto; then
3022     VALGRIND="$have_valgrind"
3023 fi
3024
3025 if test "x$VALGRIND" = "xyes"; then
3026     if ! test "x$have_valgrind" = xyes; then
3027         AC_MSG_ERROR([Valgrind support required but not present])
3028     fi
3029     AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
3030 fi
3031
3032 AC_MSG_RESULT([$VALGRIND])
3033
3034 dnl Restore LDFLAGS and CPPFLAGS
3035 LDFLAGS="$_SAVE_LDFLAGS"
3036 CPPFLAGS="$_SAVE_CPPFLAGS"
3037
3038 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
3039 if test "x$acv_mesa_CLANG" = xyes; then
3040     CFLAGS="$CFLAGS -Qunused-arguments"
3041     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
3042 fi
3043
3044 dnl Add user CFLAGS and CXXFLAGS
3045 CFLAGS="$CFLAGS $USER_CFLAGS"
3046 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
3047
3048 dnl Substitute the config
3049 AC_CONFIG_FILES([Makefile
3050                  src/Makefile
3051                  src/amd/Makefile
3052                  src/amd/vulkan/Makefile
3053                  src/broadcom/Makefile
3054                  src/compiler/Makefile
3055                  src/egl/Makefile
3056                  src/egl/main/egl.pc
3057                  src/egl/wayland/wayland-drm/Makefile
3058                  src/gallium/Makefile
3059                  src/gallium/auxiliary/Makefile
3060                  src/gallium/auxiliary/pipe-loader/Makefile
3061                  src/gallium/drivers/freedreno/Makefile
3062                  src/gallium/drivers/i915/Makefile
3063                  src/gallium/drivers/llvmpipe/Makefile
3064                  src/gallium/drivers/nouveau/Makefile
3065                  src/gallium/drivers/pl111/Makefile
3066                  src/gallium/drivers/r300/Makefile
3067                  src/gallium/drivers/r600/Makefile
3068                  src/gallium/drivers/radeonsi/Makefile
3069                  src/gallium/drivers/softpipe/Makefile
3070                  src/gallium/drivers/svga/Makefile
3071                  src/gallium/drivers/swr/Makefile
3072                  src/gallium/drivers/tegra/Makefile
3073                  src/gallium/drivers/etnaviv/Makefile
3074                  src/gallium/drivers/imx/Makefile
3075                  src/gallium/drivers/v3d/Makefile
3076                  src/gallium/drivers/vc4/Makefile
3077                  src/gallium/drivers/virgl/Makefile
3078                  src/gallium/state_trackers/clover/Makefile
3079                  src/gallium/state_trackers/dri/Makefile
3080                  src/gallium/state_trackers/glx/xlib/Makefile
3081                  src/gallium/state_trackers/nine/Makefile
3082                  src/gallium/state_trackers/omx/Makefile
3083                  src/gallium/state_trackers/omx/bellagio/Makefile
3084                  src/gallium/state_trackers/omx/tizonia/Makefile
3085                  src/gallium/state_trackers/osmesa/Makefile
3086                  src/gallium/state_trackers/va/Makefile
3087                  src/gallium/state_trackers/vdpau/Makefile
3088                  src/gallium/state_trackers/xa/Makefile
3089                  src/gallium/state_trackers/xa/xa_tracker.h
3090                  src/gallium/state_trackers/xvmc/Makefile
3091                  src/gallium/targets/d3dadapter9/Makefile
3092                  src/gallium/targets/d3dadapter9/d3d.pc
3093                  src/gallium/targets/dri/Makefile
3094                  src/gallium/targets/libgl-xlib/Makefile
3095                  src/gallium/targets/omx/Makefile
3096                  src/gallium/targets/opencl/Makefile
3097                  src/gallium/targets/opencl/mesa.icd
3098                  src/gallium/targets/osmesa/Makefile
3099                  src/gallium/targets/osmesa/osmesa.pc
3100                  src/gallium/targets/pipe-loader/Makefile
3101                  src/gallium/targets/va/Makefile
3102                  src/gallium/targets/vdpau/Makefile
3103                  src/gallium/targets/xa/Makefile
3104                  src/gallium/targets/xa/xatracker.pc
3105                  src/gallium/targets/xvmc/Makefile
3106                  src/gallium/tests/trivial/Makefile
3107                  src/gallium/tests/unit/Makefile
3108                  src/gallium/winsys/etnaviv/drm/Makefile
3109                  src/gallium/winsys/imx/drm/Makefile
3110                  src/gallium/winsys/freedreno/drm/Makefile
3111                  src/gallium/winsys/i915/drm/Makefile
3112                  src/gallium/winsys/nouveau/drm/Makefile
3113                  src/gallium/winsys/pl111/drm/Makefile
3114                  src/gallium/winsys/radeon/drm/Makefile
3115                  src/gallium/winsys/amdgpu/drm/Makefile
3116                  src/gallium/winsys/svga/drm/Makefile
3117                  src/gallium/winsys/sw/dri/Makefile
3118                  src/gallium/winsys/sw/kms-dri/Makefile
3119                  src/gallium/winsys/sw/null/Makefile
3120                  src/gallium/winsys/sw/wrapper/Makefile
3121                  src/gallium/winsys/sw/xlib/Makefile
3122                  src/gallium/winsys/tegra/drm/Makefile
3123                  src/gallium/winsys/v3d/drm/Makefile
3124                  src/gallium/winsys/vc4/drm/Makefile
3125                  src/gallium/winsys/virgl/drm/Makefile
3126                  src/gallium/winsys/virgl/vtest/Makefile
3127                  src/gbm/Makefile
3128                  src/gbm/main/gbm.pc
3129                  src/glx/Makefile
3130                  src/glx/apple/Makefile
3131                  src/glx/tests/Makefile
3132                  src/glx/windows/Makefile
3133                  src/glx/windows/windowsdriproto.pc
3134                  src/gtest/Makefile
3135                  src/intel/Makefile
3136                  src/loader/Makefile
3137                  src/mapi/Makefile
3138                  src/mapi/es1api/glesv1_cm.pc
3139                  src/mapi/es2api/glesv2.pc
3140                  src/mapi/glapi/gen/Makefile
3141                  src/mesa/Makefile
3142                  src/mesa/gl.pc
3143                  src/mesa/drivers/dri/dri.pc
3144                  src/mesa/drivers/dri/common/Makefile
3145                  src/mesa/drivers/dri/i915/Makefile
3146                  src/mesa/drivers/dri/i965/Makefile
3147                  src/mesa/drivers/dri/Makefile
3148                  src/mesa/drivers/dri/nouveau/Makefile
3149                  src/mesa/drivers/dri/r200/Makefile
3150                  src/mesa/drivers/dri/radeon/Makefile
3151                  src/mesa/drivers/dri/swrast/Makefile
3152                  src/mesa/drivers/osmesa/Makefile
3153                  src/mesa/drivers/osmesa/osmesa.pc
3154                  src/mesa/drivers/x11/Makefile
3155                  src/mesa/main/tests/Makefile
3156                  src/mesa/state_tracker/tests/Makefile
3157                  src/util/Makefile
3158                  src/util/tests/hash_table/Makefile
3159                  src/util/tests/string_buffer/Makefile
3160                  src/util/tests/vma/Makefile
3161                  src/util/xmlpool/Makefile
3162                  src/vulkan/Makefile])
3163
3164 AC_OUTPUT
3165
3166 # Fix up dependencies in *.Plo files, where we changed the extension of a
3167 # source file
3168 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
3169
3170 rm -f src/compiler/spirv/spirv_info.lo
3171 echo "# dummy" > src/compiler/spirv/.deps/spirv_info.Plo
3172
3173 rm -f src/compiler/nir/.deps/nir_intrinsics.Plo
3174 echo "# dummy" > src/compiler/nir/.deps/nir_intrinsics.Plo
3175
3176 dnl
3177 dnl Output some configuration info for the user
3178 dnl
3179 echo ""
3180 echo "        prefix:          $prefix"
3181 echo "        exec_prefix:     $exec_prefix"
3182 echo "        libdir:          $libdir"
3183 echo "        includedir:      $includedir"
3184
3185 dnl API info
3186 echo ""
3187 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
3188
3189 dnl Driver info
3190 echo ""
3191 case "x$enable_osmesa$enable_gallium_osmesa" in
3192 xnoyes)
3193         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
3194         ;;
3195 xyesno)
3196         echo "        OSMesa:          lib$OSMESA_LIB"
3197         ;;
3198 xnono)
3199         echo "        OSMesa:          no"
3200         ;;
3201 esac
3202
3203 echo ""
3204 if test "x$enable_dri" != xno; then
3205         echo "        DRI platform:    $dri_platform"
3206         if test -z "$DRI_DIRS"; then
3207             echo "        DRI drivers:     no"
3208         else
3209             echo "        DRI drivers:     $DRI_DIRS"
3210         fi
3211         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
3212 fi
3213
3214 case "x$enable_glx" in
3215 xdri)
3216     echo "        GLX:             DRI-based"
3217     ;;
3218 xxlib)
3219     echo "        GLX:             Xlib-based"
3220     ;;
3221 xgallium-xlib)
3222     echo "        GLX:             Xlib-based (Gallium)"
3223     ;;
3224 *)
3225     echo "        GLX:             $enable_glx"
3226     ;;
3227 esac
3228
3229 dnl EGL
3230 echo ""
3231 echo "        EGL:             $enable_egl"
3232 if test "$enable_egl" = yes; then
3233
3234     egl_drivers=""
3235     if test "x$enable_dri" != "xno"; then
3236         egl_drivers="$egl_drivers builtin:egl_dri2"
3237     fi
3238     if test "x$enable_dri3" != "xno"; then
3239         egl_drivers="$egl_drivers builtin:egl_dri3"
3240     fi
3241
3242     echo "        EGL drivers:    $egl_drivers"
3243 fi
3244 if test "x$enable_gbm" = xyes; then
3245     echo "        GBM:             yes"
3246 else
3247     echo "        GBM:             no"
3248 fi
3249
3250     echo "        EGL/Vulkan/VL platforms:   $platforms"
3251
3252 # Vulkan
3253 echo ""
3254 if test "x$VULKAN_DRIVERS" != x; then
3255     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
3256     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
3257 else
3258     echo "        Vulkan drivers:  no"
3259 fi
3260
3261 echo ""
3262 if test "x$enable_llvm" = xyes; then
3263     echo "        llvm:            yes"
3264     echo "        llvm-config:     $LLVM_CONFIG"
3265     echo "        llvm-version:    $LLVM_VERSION"
3266 else
3267     echo "        llvm:            no"
3268 fi
3269
3270 echo ""
3271 if test -n "$with_gallium_drivers"; then
3272     echo "        Gallium drivers: $gallium_drivers"
3273     echo "        Gallium st:      $gallium_st"
3274 else
3275     echo "        Gallium:         no"
3276 fi
3277
3278 echo ""
3279 if test "x$enable_gallium_extra_hud" != xyes; then
3280     echo "        HUD extra stats: no"
3281 else
3282     echo "        HUD extra stats: yes"
3283 fi
3284
3285 if test "x$enable_lmsensors" != xyes; then
3286     echo "        HUD lmsensors:   no"
3287 else
3288     echo "        HUD lmsensors:   yes"
3289 fi
3290
3291 echo ""
3292 if test "x$HAVE_GALLIUM_SWR" != x; then
3293     if test "x$HAVE_SWR_BUILTIN" = xyes; then
3294         echo "        SWR archs:       $swr_archs (builtin)"
3295     else
3296         echo "        SWR archs:       $swr_archs"
3297     fi
3298 fi
3299
3300 dnl Libraries
3301 echo ""
3302 echo "        Shared libs:     $enable_shared"
3303 echo "        Static libs:     $enable_static"
3304 echo "        Shared-glapi:    $enable_shared_glapi"
3305
3306 dnl Compiler options
3307 # cleanup the CFLAGS/CXXFLAGS/LDFLAGS/DEFINES vars
3308 cflags=`echo $CFLAGS | \
3309     $SED 's/^ *//;s/  */ /;s/ *$//'`
3310 cxxflags=`echo $CXXFLAGS | \
3311     $SED 's/^ *//;s/  */ /;s/ *$//'`
3312 ldflags=`echo $LDFLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
3313 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
3314 echo ""
3315 echo "        CFLAGS:          $cflags"
3316 echo "        CXXFLAGS:        $cxxflags"
3317 echo "        CXX11_CXXFLAGS:  $CXX11_CXXFLAGS"
3318 echo "        LDFLAGS:         $ldflags"
3319 echo "        Macros:          $defines"
3320 echo ""
3321 if test "x$enable_llvm" = xyes; then
3322     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
3323     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
3324     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
3325     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
3326     echo ""
3327 fi
3328 echo "        PYTHON2:         $PYTHON2"
3329
3330 echo ""
3331 echo "        Run '${MAKE-make}' to build Mesa"
3332 echo ""