configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl
  13 dnl Permission is hereby granted, free of charge, to any person obtaining a
  14 dnl copy of this software and associated documentation files (the "Software"),
  15 dnl to deal in the Software without restriction, including without limitation
  16 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  17 dnl and/or sell copies of the Software, and to permit persons to whom the
  18 dnl Software is furnished to do so, subject to the following conditions:
  19 dnl
  20 dnl The above copyright notice and this permission notice (including the next
  21 dnl paragraph) shall be included in all copies or substantial portions of the
  22 dnl Software.
  23 dnl
  24 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  25 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  26 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  27 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  28 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  29 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  30 dnl DEALINGS IN THE SOFTWARE.
  31 dnl
  32 dnl Process this file with autoconf to create configure.
  33
  34 AC_PREREQ([2.60])
  35
  36 dnl Tell the user about autoconf.html in the --help output
  37 m4_divert_once([HELP_END], [
  38 See docs/autoconf.html for more details on the options for Mesa.])
  39
  40 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  41 AC_INIT([Mesa], [MESA_VERSION],
  42     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  43 AC_CONFIG_AUX_DIR([bin])
  44 AC_CONFIG_MACRO_DIR([m4])
  45 AC_CANONICAL_SYSTEM
  46 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  47
  48 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  49 case "$host_os" in
  50 mingw*)
  51     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  52     ;;
  53 esac
  54
  55 # Support silent build rules, requires at least automake-1.11. Disable
  56 # by either passing --disable-silent-rules to configure or passing V=1
  57 # to make
  58 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  59     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  60
  61 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  62
  63 dnl Set internal versions
  64 OSMESA_VERSION=8
  65 AC_SUBST([OSMESA_VERSION])
  66 OPENCL_VERSION=1
  67 AC_SUBST([OPENCL_VERSION])
  68
  69 # The idea is that libdrm is distributed as one cohesive package, even
  70 # though it is composed of multiple libraries. However some drivers
  71 # may have different version requirements than others. This list
  72 # codifies which drivers need which version of libdrm. Any libdrm
  73 # version dependencies in non-driver-specific code should be reflected
  74 # in the first entry.
  75 LIBDRM_REQUIRED=2.4.75
  76 LIBDRM_RADEON_REQUIRED=2.4.71
  77 LIBDRM_AMDGPU_REQUIRED=2.4.88
  78 LIBDRM_INTEL_REQUIRED=2.4.75
  79 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  80 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  81 LIBDRM_FREEDRENO_REQUIRED=2.4.74
  82 LIBDRM_ETNAVIV_REQUIRED=2.4.82
  83
  84 dnl Versions for external dependencies
  85 DRI2PROTO_REQUIRED=2.8
  86 GLPROTO_REQUIRED=1.4.14
  87 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  88 LIBVA_REQUIRED=0.38.0
  89 VDPAU_REQUIRED=1.1
  90 WAYLAND_REQUIRED=1.11
  91 WAYLAND_PROTOCOLS_REQUIRED=1.8
  92 XCB_REQUIRED=1.9.3
  93 XCBDRI2_REQUIRED=1.8
  94 XCBGLX_REQUIRED=1.8.1
  95 XDAMAGE_REQUIRED=1.1
  96 XSHMFENCE_REQUIRED=1.1
  97 XVMC_REQUIRED=1.0.6
  98 PYTHON_MAKO_REQUIRED=0.8.0
  99 LIBSENSORS_REQUIRED=4.0.0
 100 ZLIB_REQUIRED=1.2.3
 101
 102 dnl LLVM versions
 103 LLVM_REQUIRED_GALLIUM=3.3.0
 104 LLVM_REQUIRED_OPENCL=3.9.0
 105 LLVM_REQUIRED_R600=3.9.0
 106 LLVM_REQUIRED_RADEONSI=3.9.0
 107 LLVM_REQUIRED_RADV=3.9.0
 108 LLVM_REQUIRED_SWR=3.9.0
 109
 110 dnl Check for progs
 111 AC_PROG_CPP
 112 AC_PROG_CC
 113 AC_PROG_CXX
 114 dnl add this here, so the help for this environmnet variable is close to
 115 dnl other CC/CXX flags related help
 116 AC_ARG_VAR([CXX11_CXXFLAGS], [Compiler flag to enable C++11 support (only needed if not
 117                               enabled by default and different  from -std=c++11)])
 118 AM_PROG_CC_C_O
 119 AM_PROG_AS
 120 AX_CHECK_GNU_MAKE
 121 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 122 AC_PROG_SED
 123 AC_PROG_MKDIR_P
 124
 125 AC_SYS_LARGEFILE
 126
 127
 128 LT_PREREQ([2.2])
 129 LT_INIT([disable-static])
 130
 131 AC_CHECK_PROG(RM, rm, [rm -f])
 132
 133 AX_PROG_BISON([],
 134               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 135                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 136 AX_PROG_FLEX([],
 137              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 138                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 139
 140 AC_CHECK_PROG(INDENT, indent, indent, cat)
 141 if test "x$INDENT" != "xcat"; then
 142     # Only GNU indent is supported
 143     INDENT_VERSION=`indent --version | grep GNU`
 144     if test $? -eq 0; then
 145        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 146     else
 147        INDENT="cat"
 148     fi
 149 fi
 150
 151 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 152
 153 if test -z "$PYTHON2"; then
 154     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 155         AC_MSG_ERROR([Python not found - unable to generate sources])
 156     fi
 157 else
 158     if test "x$acv_mako_found" = xno; then
 159         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 160             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 161         fi
 162     fi
 163 fi
 164
 165 AC_PROG_INSTALL
 166
 167 dnl We need a POSIX shell for parts of the build. Assume we have one
 168 dnl in most cases.
 169 case "$host_os" in
 170 solaris*)
 171     # Solaris /bin/sh is too old/non-POSIX compliant
 172     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 173     SHELL="$POSIX_SHELL"
 174     ;;
 175 esac
 176
 177 dnl clang is mostly GCC-compatible, but its version is much lower,
 178 dnl so we have to check for it.
 179 AC_MSG_CHECKING([if compiling with clang])
 180
 181 AC_COMPILE_IFELSE(
 182 [AC_LANG_PROGRAM([], [[
 183 #ifndef __clang__
 184        not clang
 185 #endif
 186 ]])],
 187 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 188
 189 AC_MSG_RESULT([$acv_mesa_CLANG])
 190
 191 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 192 dnl versions are explictly not supported.
 193 GEN_ASM_OFFSETS=no
 194 USE_GNU99=no
 195 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 196     AC_MSG_CHECKING([whether gcc version is sufficient])
 197     major=0
 198     minor=0
 199
 200     GCC_VERSION=`$CC -dumpversion`
 201     if test $? -eq 0; then
 202         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 203         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 204     fi
 205
 206     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 207         AC_MSG_RESULT([no])
 208         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 209     else
 210         AC_MSG_RESULT([yes])
 211     fi
 212
 213     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 214         USE_GNU99=yes
 215     fi
 216     if test "x$cross_compiling" = xyes; then
 217         GEN_ASM_OFFSETS=yes
 218     fi
 219 fi
 220
 221 dnl We don't support building Mesa with Sun C compiler
 222 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 223 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 224 if test "x$SUNCC" = xyes; then
 225     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 226 fi
 227
 228 dnl Check for compiler builtins
 229 AX_GCC_BUILTIN([__builtin_bswap32])
 230 AX_GCC_BUILTIN([__builtin_bswap64])
 231 AX_GCC_BUILTIN([__builtin_clz])
 232 AX_GCC_BUILTIN([__builtin_clzll])
 233 AX_GCC_BUILTIN([__builtin_ctz])
 234 AX_GCC_BUILTIN([__builtin_expect])
 235 AX_GCC_BUILTIN([__builtin_ffs])
 236 AX_GCC_BUILTIN([__builtin_ffsll])
 237 AX_GCC_BUILTIN([__builtin_popcount])
 238 AX_GCC_BUILTIN([__builtin_popcountll])
 239 AX_GCC_BUILTIN([__builtin_unreachable])
 240
 241 AX_GCC_FUNC_ATTRIBUTE([const])
 242 AX_GCC_FUNC_ATTRIBUTE([flatten])
 243 AX_GCC_FUNC_ATTRIBUTE([format])
 244 AX_GCC_FUNC_ATTRIBUTE([malloc])
 245 AX_GCC_FUNC_ATTRIBUTE([packed])
 246 AX_GCC_FUNC_ATTRIBUTE([pure])
 247 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 248 AX_GCC_FUNC_ATTRIBUTE([unused])
 249 AX_GCC_FUNC_ATTRIBUTE([visibility])
 250 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 251 AX_GCC_FUNC_ATTRIBUTE([weak])
 252 AX_GCC_FUNC_ATTRIBUTE([alias])
 253
 254 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 255
 256 dnl Make sure the pkg-config macros are defined
 257 m4_ifndef([PKG_PROG_PKG_CONFIG],
 258     [m4_fatal([Could not locate the pkg-config autoconf macros.
 259   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 260   are in a different location, try setting the environment variable
 261   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 262 PKG_PROG_PKG_CONFIG()
 263
 264 dnl LIB_DIR - library basename
 265 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 266 AC_SUBST([LIB_DIR])
 267
 268 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 269 _SAVE_LDFLAGS="$LDFLAGS"
 270 _SAVE_CPPFLAGS="$CPPFLAGS"
 271
 272 dnl Compiler macros
 273 DEFINES="-D__STDC_CONSTANT_MACROS -D__STDC_FORMAT_MACROS -D__STDC_LIMIT_MACROS"
 274 AC_SUBST([DEFINES])
 275 android=no
 276 case "$host_os" in
 277 *-android*)
 278     android=yes
 279     ;;
 280 linux*|*-gnu*|gnu*|cygwin*)
 281     DEFINES="$DEFINES -D_GNU_SOURCE"
 282     ;;
 283 solaris*)
 284     DEFINES="$DEFINES -DSVR4"
 285     ;;
 286 esac
 287
 288 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 289
 290 dnl
 291 dnl Check compiler flags
 292 dnl
 293 AX_CHECK_COMPILE_FLAG([-Wall],                                 [CFLAGS="$CFLAGS -Wall"])
 294 AX_CHECK_COMPILE_FLAG([-Werror=implicit-function-declaration], [CFLAGS="$CFLAGS -Werror=implicit-function-declaration"])
 295 AX_CHECK_COMPILE_FLAG([-Werror=missing-prototypes],            [CFLAGS="$CFLAGS -Werror=missing-prototypes"])
 296 AX_CHECK_COMPILE_FLAG([-Wmissing-prototypes],                  [CFLAGS="$CFLAGS -Wmissing-prototypes"])
 297 AX_CHECK_COMPILE_FLAG([-fno-math-errno],                       [CFLAGS="$CFLAGS -fno-math-errno"])
 298 AX_CHECK_COMPILE_FLAG([-fno-trapping-math],                    [CFLAGS="$CFLAGS -fno-trapping-math"])
 299 AX_CHECK_COMPILE_FLAG([-fvisibility=hidden],                   [VISIBILITY_CFLAGS="-fvisibility=hidden"])
 300
 301 dnl
 302 dnl Check C++ compiler flags
 303 dnl
 304 AC_LANG_PUSH([C++])
 305 AX_CHECK_COMPILE_FLAG([-Wall],                                 [CXXFLAGS="$CXXFLAGS -Wall"])
 306 AX_CHECK_COMPILE_FLAG([-fno-math-errno],                       [CXXFLAGS="$CXXFLAGS -fno-math-errno"])
 307 AX_CHECK_COMPILE_FLAG([-fno-trapping-math],                    [CXXFLAGS="$CXXFLAGS -fno-trapping-math"])
 308 AX_CHECK_COMPILE_FLAG([-fvisibility=hidden],                   [VISIBILITY_CXXFLAGS="-fvisibility=hidden"])
 309 AC_LANG_POP([C++])
 310
 311 # Flags to help ensure that certain portions of the code -- and only those
 312 # portions -- can be built with MSVC:
 313 # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 314 # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 315 #   supports most of C99)
 316 # - the rest has no compiler compiler restrictions
 317 AX_CHECK_COMPILE_FLAG([-Werror=pointer-arith],                 [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=pointer-arith"])
 318 AX_CHECK_COMPILE_FLAG([-Werror=vla],                           [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla"])
 319 AC_LANG_PUSH([C++])
 320 AX_CHECK_COMPILE_FLAG([-Werror=pointer-arith],                 [MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=pointer-arith"])
 321 AX_CHECK_COMPILE_FLAG([-Werror=vla],                           [MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla"])
 322 AC_LANG_POP([C++])
 323
 324 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 325 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 326
 327 if test "x$GCC" = xyes; then
 328     if test "x$USE_GNU99" = xyes; then
 329         CFLAGS="$CFLAGS -std=gnu99"
 330     else
 331         CFLAGS="$CFLAGS -std=c99"
 332     fi
 333 fi
 334
 335 dnl
 336 dnl Check whether C++11 is supported, if the environment variable
 337 dnl CXX11_CXXFLAGS is set it takes precedence.
 338 dnl
 339
 340 AC_LANG_PUSH([C++])
 341
 342 check_cxx11_available() {
 343     output_support=$1
 344     AC_COMPILE_IFELSE(
 345         [AC_LANG_PROGRAM([
 346              #if !(__cplusplus >= 201103L)
 347              #error
 348              #endif
 349              #include <tuple>
 350         ])
 351     ], [
 352          AC_MSG_RESULT(yes)
 353          cxx11_support=yes
 354     ], AC_MSG_RESULT(no))
 355     eval "$output_support=\$cxx11_support"
 356 }
 357
 358 HAVE_CXX11=no
 359 save_CXXFLAGS="$CXXFLAGS"
 360
 361 dnl If the user provides a flag to enable c++11, then we test only this
 362 if test "x$CXX11_CXXFLAGS" != "x"; then
 363    CXXFLAGS="$CXXFLAGS $CXX11_CXXFLAGS"
 364    AC_MSG_CHECKING(whether c++11 is enabled by via $CXX11_CXXFLAGS)
 365    check_cxx11_available HAVE_CXX11
 366 else
 367    dnl test whether c++11 is enabled by default
 368    AC_MSG_CHECKING(whether c++11 is enabled by default)
 369    check_cxx11_available HAVE_CXX11
 370
 371    dnl C++11 not enabled by default, test whether -std=c++11 does the job
 372    if test "x$HAVE_CXX11" != "xyes"; then
 373        CXX11_CXXFLAGS=-std=c++11
 374        CXXFLAGS="$CXXFLAGS $CXX11_CXXFLAGS"
 375        AC_MSG_CHECKING(whether c++11 is enabled by via $CXX11_CXXFLAGS)
 376        check_cxx11_available HAVE_CXX11
 377    fi
 378 fi
 379
 380 CXXFLAGS="$save_CXXFLAGS"
 381 AM_CONDITIONAL(HAVE_STD_CXX11, test "x$HAVE_CXX11" = "xyes")
 382 AC_SUBST(CXX11_CXXFLAGS)
 383 AC_LANG_POP([C++])
 384
 385 dnl even if the compiler appears to support it, using visibility attributes isn't
 386 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 387 case "$host_os" in
 388 cygwin*)
 389     VISIBILITY_CFLAGS=""
 390     VISIBILITY_CXXFLAGS=""
 391     ;;
 392 esac
 393
 394 AC_SUBST([VISIBILITY_CFLAGS])
 395 AC_SUBST([VISIBILITY_CXXFLAGS])
 396
 397 AX_CHECK_COMPILE_FLAG([-Wno-override-init],                    [WNO_OVERRIDE_INIT="$WNO_OVERRIDE_INIT -Wno-override-init"])         # gcc
 398 AX_CHECK_COMPILE_FLAG([-Wno-initializer-overrides],            [WNO_OVERRIDE_INIT="$WNO_OVERRIDE_INIT -Wno-initializer-overrides"]) # clang
 399 AC_SUBST([WNO_OVERRIDE_INIT])
 400
 401 dnl
 402 dnl Optional flags, check for compiler support
 403 dnl
 404 SSE41_CFLAGS="-msse4.1"
 405 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 406 dnl stack, but on x86-32 such alignment is not guaranteed.
 407 case "$target_cpu" in
 408 i?86)
 409     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 410     ;;
 411 esac
 412 save_CFLAGS="$CFLAGS"
 413 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 414 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 415 #include <smmintrin.h>
 416 int param;
 417 int main () {
 418     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 419     c = _mm_max_epu32(a, b);
 420     return _mm_cvtsi128_si32(c);
 421 }]])], SSE41_SUPPORTED=1)
 422 CFLAGS="$save_CFLAGS"
 423 if test "x$SSE41_SUPPORTED" = x1; then
 424     DEFINES="$DEFINES -DUSE_SSE41"
 425 fi
 426 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 427 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 428
 429 dnl Check for new-style atomic builtins
 430 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 431 int main() {
 432     int n;
 433     return __atomic_load_n(&n, __ATOMIC_ACQUIRE);
 434 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=1)
 435 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = x1; then
 436     DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
 437     dnl On some platforms, new-style atomics need a helper library
 438     AC_MSG_CHECKING(whether -latomic is needed)
 439     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 440     #include <stdint.h>
 441     uint64_t v;
 442     int main() {
 443         return (int)__atomic_load_n(&v, __ATOMIC_ACQUIRE);
 444     }]])], GCC_ATOMIC_BUILTINS_NEED_LIBATOMIC=no, GCC_ATOMIC_BUILTINS_NEED_LIBATOMIC=yes)
 445     AC_MSG_RESULT($GCC_ATOMIC_BUILTINS_NEED_LIBATOMIC)
 446     if test "x$GCC_ATOMIC_BUILTINS_NEED_LIBATOMIC" = xyes; then
 447         LIBATOMIC_LIBS="-latomic"
 448     fi
 449 fi
 450 AM_CONDITIONAL([GCC_ATOMIC_BUILTINS_SUPPORTED], [test x$GCC_ATOMIC_BUILTINS_SUPPORTED = x1])
 451 AC_SUBST([LIBATOMIC_LIBS])
 452
 453 dnl Check if host supports 64-bit atomics
 454 dnl note that lack of support usually results in link (not compile) error
 455 AC_MSG_CHECKING(whether __sync_add_and_fetch_8 is supported)
 456 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 457 #include <stdint.h>
 458 uint64_t v;
 459 int main() {
 460     return __sync_add_and_fetch(&v, (uint64_t)1);
 461 }]])], GCC_64BIT_ATOMICS_SUPPORTED=yes, GCC_64BIT_ATOMICS_SUPPORTED=no)
 462 if test "x$GCC_64BIT_ATOMICS_SUPPORTED" != xyes; then
 463     DEFINES="$DEFINES -DMISSING_64BIT_ATOMICS"
 464 fi
 465 AC_MSG_RESULT($GCC_64BIT_ATOMICS_SUPPORTED)
 466
 467 dnl Check for Endianness
 468 AC_C_BIGENDIAN(
 469    little_endian=no,
 470    little_endian=yes,
 471    little_endian=no,
 472    little_endian=no
 473 )
 474
 475 dnl Check for POWER8 Architecture
 476 PWR8_CFLAGS="-mpower8-vector"
 477 have_pwr8_intrinsics=no
 478 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 479 save_CFLAGS=$CFLAGS
 480 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 481 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 482 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 483 #error "Need GCC >= 4.8 for sane POWER8 support"
 484 #endif
 485 #include <altivec.h>
 486 int main () {
 487     vector unsigned char r;
 488     vector unsigned int v = vec_splat_u32 (1);
 489     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 490     return 0;
 491 }]])], have_pwr8_intrinsics=yes)
 492 CFLAGS=$save_CFLAGS
 493
 494 AC_ARG_ENABLE(pwr8,
 495    [AS_HELP_STRING([--disable-pwr8],
 496                    [disable POWER8-specific instructions])],
 497    [enable_pwr8=$enableval], [enable_pwr8=auto])
 498
 499 if test "x$enable_pwr8" = xno ; then
 500    have_pwr8_intrinsics=disabled
 501 fi
 502
 503 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 504    DEFINES="$DEFINES -D_ARCH_PWR8"
 505    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 506    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 507 else
 508    PWR8_CFLAGS=
 509 fi
 510
 511 AC_MSG_RESULT($have_pwr8_intrinsics)
 512 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 513    AC_MSG_ERROR([POWER8 compiler support not detected])
 514 fi
 515
 516 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 517    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 518 fi
 519
 520 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 521
 522 dnl Can't have static and shared libraries, default to static if user
 523 dnl explicitly requested. If both disabled, set to static since shared
 524 dnl was explicitly requested.
 525 case "x$enable_static$enable_shared" in
 526 xyesyes)
 527     AC_MSG_ERROR([Cannot enable both static and shared. Building using --enable-shared is strongly recommended])
 528     ;;
 529 xnono)
 530     AC_MSG_ERROR([Cannot disable both static and shared. Building using --enable-shared is strongly recommended])
 531     ;;
 532 esac
 533
 534 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 535
 536 dnl
 537 dnl other compiler options
 538 dnl
 539 AC_ARG_ENABLE([debug],
 540     [AS_HELP_STRING([--enable-debug],
 541         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 542     [enable_debug="$enableval"],
 543     [enable_debug=no]
 544 )
 545
 546 AC_ARG_ENABLE([profile],
 547     [AS_HELP_STRING([--enable-profile],
 548         [enable profiling of code @<:@default=disabled@:>@])],
 549     [enable_profile="$enableval"],
 550     [enable_profile=no]
 551 )
 552
 553 AC_ARG_ENABLE([sanitize],
 554     [AS_HELP_STRING([--enable-sanitize@<:@=address|undefined@:>@],
 555         [enable code sanitizer @<:@default=disabled@:>@])],
 556     [enable_sanitize="$enableval"],
 557     [enable_sanitize=no])
 558
 559 if test "x$enable_profile" = xyes; then
 560     DEFINES="$DEFINES -DPROFILE"
 561     if test "x$GCC" = xyes; then
 562         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 563     fi
 564     if test "x$GXX" = xyes; then
 565         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 566     fi
 567 fi
 568
 569 if test "x$enable_debug" = xyes; then
 570     DEFINES="$DEFINES -DDEBUG"
 571     if test "x$enable_profile" = xyes; then
 572         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 573     fi
 574     if test "x$GCC" = xyes; then
 575         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 576             CFLAGS="$CFLAGS -g"
 577         fi
 578         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 579             CFLAGS="$CFLAGS -O0"
 580         fi
 581     fi
 582     if test "x$GXX" = xyes; then
 583         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 584             CXXFLAGS="$CXXFLAGS -g"
 585         fi
 586         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 587             CXXFLAGS="$CXXFLAGS -O0"
 588         fi
 589     fi
 590 else
 591    DEFINES="$DEFINES -DNDEBUG"
 592 fi
 593
 594 if test "x$enable_sanitize" != xno; then
 595     if test "x$enable_profile" = xyes; then
 596         AC_MSG_WARN([Sanitize and Profile are enabled at the same time])
 597     fi
 598
 599     CFLAGS="$CFLAGS -fsanitize=$enable_sanitize"
 600     CXXFLAGS="$CXXFLAGS -fsanitize=$enable_sanitize"
 601     LDFLAGS="$LDFLAGS -fsanitize=$enable_sanitize"
 602
 603     AC_LINK_IFELSE(
 604         [AC_LANG_SOURCE([int main(){return 0;}])],
 605         [],
 606         [AC_MSG_FAILURE([sanitize flags '$enable_sanitize' not supported])])
 607 fi
 608
 609 dnl
 610 dnl Check if linker supports -Bsymbolic
 611 dnl
 612 save_LDFLAGS=$LDFLAGS
 613 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 614 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 615 AC_LINK_IFELSE(
 616     [AC_LANG_SOURCE([int main() { return 0;}])],
 617     [AC_MSG_RESULT([yes])
 618         BSYMBOLIC="-Wl,-Bsymbolic";],
 619     [AC_MSG_RESULT([no])
 620         BSYMBOLIC="";])
 621 LDFLAGS=$save_LDFLAGS
 622
 623 AC_SUBST([BSYMBOLIC])
 624
 625 dnl
 626 dnl Check if linker supports garbage collection
 627 dnl
 628 save_LDFLAGS=$LDFLAGS
 629 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 630 AC_MSG_CHECKING([whether ld supports --gc-sections])
 631 AC_LINK_IFELSE(
 632     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 633     [AC_MSG_RESULT([yes])
 634         GC_SECTIONS="-Wl,--gc-sections";],
 635     [AC_MSG_RESULT([no])
 636         GC_SECTIONS="";])
 637 LDFLAGS=$save_LDFLAGS
 638
 639 AC_SUBST([GC_SECTIONS])
 640
 641 dnl
 642 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 643 dnl so when these flags are passed to ld via libtool the checks will fail
 644 dnl
 645 case "$host_os" in
 646 openbsd* | darwin* )
 647     LD_NO_UNDEFINED="" ;;
 648 *)
 649     if test "x$enable_sanitize" = xno; then
 650         LD_NO_UNDEFINED="-Wl,--no-undefined"
 651     else
 652         LD_NO_UNDEFINED=""
 653     fi
 654     ;;
 655 esac
 656
 657 AC_SUBST([LD_NO_UNDEFINED])
 658
 659 dnl
 660 dnl Check if linker supports version scripts
 661 dnl
 662 AC_MSG_CHECKING([if the linker supports version-scripts])
 663 save_LDFLAGS=$LDFLAGS
 664 LDFLAGS="$LDFLAGS -Wl,--version-script=$srcdir/build-support/conftest.map"
 665 AC_LINK_IFELSE(
 666     [AC_LANG_SOURCE([int main() { return 0;}])],
 667     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 668     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 669 LDFLAGS=$save_LDFLAGS
 670 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 671
 672 dnl
 673 dnl Check if linker supports dynamic list files
 674 dnl
 675 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 676 save_LDFLAGS=$LDFLAGS
 677 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=$srcdir/build-support/conftest.dyn"
 678 AC_LINK_IFELSE(
 679     [AC_LANG_SOURCE([int main() { return 0;}])],
 680     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 681     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 682 LDFLAGS=$save_LDFLAGS
 683 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 684
 685 dnl
 686 dnl compatibility symlinks
 687 dnl
 688 case "$host_os" in
 689 linux* )
 690     HAVE_COMPAT_SYMLINKS=yes ;;
 691 * )
 692     HAVE_COMPAT_SYMLINKS=no ;;
 693 esac
 694
 695 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 696
 697 dnl
 698 dnl library names
 699 dnl
 700 dnl Unfortunately we need to do a few things that libtool can't help us with,
 701 dnl so we need some knowledge of shared library filenames:
 702 dnl
 703 dnl LIB_EXT is the extension used when creating symlinks for alternate
 704 dnl filenames for a shared library which will be dynamically loaded
 705 dnl
 706 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 707 dnl the file for a shared library we wish to link with
 708 dnl
 709 case "$host_os" in
 710 darwin* )
 711     LIB_EXT='dylib'
 712     IMP_LIB_EXT=$LIB_EXT
 713     ;;
 714 cygwin* )
 715     LIB_EXT='dll'
 716     IMP_LIB_EXT='dll.a'
 717     ;;
 718 aix* )
 719     LIB_EXT='a'
 720     IMP_LIB_EXT=$LIB_EXT
 721     ;;
 722 * )
 723     LIB_EXT='so'
 724     IMP_LIB_EXT=$LIB_EXT
 725     ;;
 726 esac
 727
 728 AC_SUBST([LIB_EXT])
 729
 730 dnl
 731 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 732 dnl
 733 AC_ARG_ENABLE([texture-float],
 734     [AS_HELP_STRING([--enable-texture-float],
 735         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 736     [enable_texture_float="$enableval"],
 737     [enable_texture_float=no]
 738 )
 739 if test "x$enable_texture_float" = xyes; then
 740     AC_MSG_WARN([Floating-point textures enabled.])
 741     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 742     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 743 fi
 744
 745 dnl
 746 dnl Arch/platform-specific settings
 747 dnl
 748 AC_ARG_ENABLE([asm],
 749     [AS_HELP_STRING([--disable-asm],
 750         [disable assembly usage @<:@default=enabled on supported platforms@:>@])],
 751     [enable_asm="$enableval"],
 752     [enable_asm=yes]
 753 )
 754 asm_arch=""
 755 AC_MSG_CHECKING([whether to enable assembly])
 756 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 757 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 758 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 759     case "$host_cpu" in
 760     i?86 | x86_64 | amd64)
 761         if test "x$host_cpu" != "x$target_cpu"; then
 762             enable_asm=no
 763             AC_MSG_RESULT([no, cross compiling])
 764         fi
 765         ;;
 766     esac
 767 fi
 768 # check for supported arches
 769 if test "x$enable_asm" = xyes; then
 770     case "$host_cpu" in
 771     i?86)
 772         case "$host_os" in
 773         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 774             asm_arch=x86
 775             ;;
 776         esac
 777         ;;
 778     x86_64|amd64)
 779         case "$host_os" in
 780         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 781             asm_arch=x86_64
 782             ;;
 783         esac
 784         ;;
 785     sparc*)
 786         case "$host_os" in
 787         linux*)
 788             asm_arch=sparc
 789             ;;
 790         esac
 791         ;;
 792     powerpc64le)
 793         case "$host_os" in
 794         linux*)
 795             asm_arch=ppc64le
 796             ;;
 797         esac
 798         ;;
 799     aarch64)
 800         case "$host_os" in
 801         linux*)
 802             asm_arch=aarch64
 803             ;;
 804         esac
 805         ;;
 806     arm)
 807         case "$host_os" in
 808         linux*)
 809             asm_arch=arm
 810             ;;
 811         esac
 812         ;;
 813     esac
 814
 815     case "$asm_arch" in
 816     x86)
 817         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 818         AC_MSG_RESULT([yes, x86])
 819         ;;
 820     x86_64|amd64)
 821         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 822         AC_MSG_RESULT([yes, x86_64])
 823         ;;
 824     sparc)
 825         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 826         AC_MSG_RESULT([yes, sparc])
 827         ;;
 828     ppc64le)
 829         DEFINES="$DEFINES -DUSE_PPC64LE_ASM"
 830         AC_MSG_RESULT([yes, ppc64le])
 831         ;;
 832     aarch64)
 833         DEFINES="$DEFINES -DUSE_AARCH64_ASM"
 834         AC_MSG_RESULT([yes, aarch64])
 835         ;;
 836     arm)
 837         DEFINES="$DEFINES -DUSE_ARM_ASM"
 838         AC_MSG_RESULT([yes, arm])
 839         ;;
 840     *)
 841         AC_MSG_RESULT([no, platform not supported])
 842         ;;
 843     esac
 844 fi
 845
 846 AC_HEADER_MAJOR
 847 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 848 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 849 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 850 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 851
 852 AC_MSG_CHECKING([whether strtod has locale support])
 853 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 854     #define _GNU_SOURCE
 855     #include <stdlib.h>
 856     #include <locale.h>
 857     #ifdef HAVE_XLOCALE_H
 858     #include <xlocale.h>
 859     #endif
 860     int main() {
 861        locale_t loc = newlocale(LC_CTYPE_MASK, "C", NULL);
 862        const char *s = "1.0";
 863        char *end;
 864        double d = strtod_l(s, end, loc);
 865        float f = strtof_l(s, end, loc);
 866        freelocale(loc);
 867        return 0;
 868     }]])],
 869   [DEFINES="$DEFINES -DHAVE_STRTOD_L"];
 870    AC_MSG_RESULT([yes]),
 871    AC_MSG_RESULT([no]))
 872
 873 dnl Check to see if dlopen is in default libraries (like Solaris, which
 874 dnl has it in libc), or if libdl is needed to get it.
 875 AC_CHECK_FUNC([dlopen], [],
 876     [AC_CHECK_LIB([dl], [dlopen],
 877        [DLOPEN_LIBS="-ldl"])])
 878 AC_SUBST([DLOPEN_LIBS])
 879
 880 dnl Check if that library also has dladdr
 881 save_LIBS="$LIBS"
 882 LIBS="$LIBS $DLOPEN_LIBS"
 883 AC_CHECK_FUNCS([dladdr])
 884 LIBS="$save_LIBS"
 885
 886 AC_CHECK_FUNC([dl_iterate_phdr], [DEFINES="$DEFINES -DHAVE_DL_ITERATE_PHDR"])
 887
 888 case "$host_os" in
 889 darwin*)
 890     ;;
 891 *)
 892     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 893                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 894                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 895     AC_SUBST([CLOCK_LIB])
 896     ;;
 897 esac
 898
 899 dnl See if posix_memalign is available
 900 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 901
 902 dnl Check for zlib
 903 PKG_CHECK_MODULES([ZLIB], [zlib >= $ZLIB_REQUIRED])
 904
 905 dnl Check for pthreads
 906 AX_PTHREAD
 907 if test "x$ax_pthread_ok" = xno; then
 908     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 909 fi
 910 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 911 dnl to -pthread, which causes problems if we need -lpthread to appear in
 912 dnl pkgconfig files.  Since Android doesn't have a pthread lib, this check
 913 dnl is not valid for that platform.
 914 if test "x$android" = xno; then
 915     test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 916 fi
 917 dnl According to the manual when using pthreads, one should add -pthread to
 918 dnl both compile and link-time arguments.
 919 dnl In practise that should be sufficient for all platforms, since any
 920 dnl platforms build with GCC and Clang support the flag.
 921 PTHREAD_LIBS="$PTHREAD_LIBS -pthread"
 922
 923 dnl pthread-stubs is mandatory on BSD platforms, due to the nature of the
 924 dnl project. Even then there's a notable issue as described in the project README
 925 case "$host_os" in
 926 linux* | cygwin* | darwin* | solaris* | *-gnu* | gnu*)
 927     pthread_stubs_possible="no"
 928     ;;
 929 * )
 930     pthread_stubs_possible="yes"
 931     ;;
 932 esac
 933
 934 if test "x$pthread_stubs_possible" = xyes; then
 935     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs >= 0.4)
 936 fi
 937
 938 dnl SELinux awareness.
 939 AC_ARG_ENABLE([selinux],
 940     [AS_HELP_STRING([--enable-selinux],
 941         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 942     [MESA_SELINUX="$enableval"],
 943     [MESA_SELINUX=no])
 944 if test "x$enable_selinux" = "xyes"; then
 945     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 946         [AC_CHECK_HEADER([selinux/selinux.h],[],
 947                          [AC_MSG_ERROR([SELinux headers not found])])
 948          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 949                       [AC_MSG_ERROR([SELinux library not found])])
 950          SELINUX_LIBS="-lselinux"])
 951     DEFINES="$DEFINES -DMESA_SELINUX"
 952 fi
 953 AC_SUBST([SELINUX_CFLAGS])
 954 AC_SUBST([SELINUX_LIBS])
 955
 956 dnl
 957 dnl LLVM
 958 dnl
 959 AC_ARG_ENABLE([llvm-shared-libs],
 960     [AS_HELP_STRING([--enable-llvm-shared-libs],
 961         [link with LLVM shared libraries @<:@default=enabled@:>@])],
 962     [enable_llvm_shared_libs="$enableval"],
 963     [enable_llvm_shared_libs=yes])
 964
 965 AC_ARG_WITH([llvm-prefix],
 966     [AS_HELP_STRING([--with-llvm-prefix],
 967         [Prefix for LLVM installations in non-standard locations])],
 968     [llvm_prefix="$withval"],
 969     [llvm_prefix=''])
 970
 971 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
 972 if test "x$have_libelf" = xno; then
 973    LIBELF_LIBS=''
 974    LIBELF_CFLAGS=''
 975    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
 976    AC_SUBST([LIBELF_LIBS])
 977    AC_SUBST([LIBELF_CFLAGS])
 978 fi
 979
 980 if test -z "$LLVM_CONFIG"; then
 981     if test -n "$llvm_prefix"; then
 982         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
 983     else
 984         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
 985     fi
 986 fi
 987
 988 llvm_add_component() {
 989     new_llvm_component=$1
 990     driver_name=$2
 991
 992     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
 993         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
 994     else
 995         AC_MSG_ERROR([LLVM component '$new_llvm_component' not enabled in your LLVM build. Required by $driver_name.])
 996     fi
 997 }
 998
 999 llvm_add_optional_component() {
1000     new_llvm_component=$1
1001     driver_name=$2
1002
1003     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
1004         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
1005     fi
1006 }
1007
1008 llvm_add_default_components() {
1009     driver_name=$1
1010
1011     # Required default components
1012     llvm_add_component "bitwriter" $driver_name
1013     llvm_add_component "engine" $driver_name
1014     llvm_add_component "mcdisassembler" $driver_name
1015     llvm_add_component "mcjit" $driver_name
1016
1017     # Optional default components
1018     llvm_add_optional_component "inteljitevents" $driver_name
1019 }
1020
1021 llvm_add_target() {
1022     new_llvm_target=$1
1023     driver_name=$2
1024
1025     if $LLVM_CONFIG --targets-built | grep -iqw $new_llvm_target ; then
1026         llvm_add_component $new_llvm_target $driver_name
1027     else
1028         AC_MSG_ERROR([LLVM target '$new_llvm_target' not enabled in your LLVM build. Required by $driver_name.])
1029     fi
1030 }
1031
1032 # Call this inside ` ` to get the return value.
1033 # $1 is the llvm-config command with arguments.
1034 strip_unwanted_llvm_flags() {
1035     echo " `$1` " | sed -E \
1036         -e 's/[[[:space:]]]+-m[[^[:space:]]]*//g' \
1037         -e 's/[[[:space:]]]+-DNDEBUG[[[:space:]]]/ /g' \
1038         -e 's/[[[:space:]]]+-D_GNU_SOURCE[[[:space:]]]/ /g' \
1039         -e 's/[[[:space:]]]+-pedantic[[[:space:]]]/ /g' \
1040         -e 's/[[[:space:]]]+-W[[^[:space:]]]*//g' \
1041         -e 's/[[[:space:]]]+-O[[^[:space:]]]*//g' \
1042         -e 's/[[[:space:]]]+-g[[^[:space:]]]*//g' \
1043         -e 's/-fno-rtti[[[:space:]]]/-Fno-rtti /g' \
1044         -e 's/[[[:space:]]]+-f[[^[:space:]]]*//g' \
1045         -e 's/-Fno-rtti[[[:space:]]]/-fno-rtti /g' \
1046         -e 's/^[[[:space:]]]//' \
1047         -e 's/[[[:space:]]]$//'
1048 }
1049
1050 llvm_set_environment_variables() {
1051     if test "x$LLVM_CONFIG" != xno; then
1052         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1053         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1054         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1055         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1056
1057         # We need to respect LLVM_CPPFLAGS when compiling LLVM headers.
1058         save_CFLAGS="$CFLAGS"
1059         CFLAGS="$CFLAGS $LLVM_CPPFLAGS"
1060
1061         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1062             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1063         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1064             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1065         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
1066             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1067
1068         CFLAGS="$save_CFLAGS"
1069
1070         # Only needed for LLVM < 3.6.0
1071         if test -z "$LLVM_VERSION_PATCH"; then
1072             LLVM_VERSION_PATCH=0
1073         fi
1074
1075         LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1076
1077         FOUND_LLVM=yes
1078     else
1079         FOUND_LLVM=no
1080         LLVM_VERSION_INT=0
1081     fi
1082 }
1083
1084 require_llvm() {
1085     if test "x$enable_llvm" != "xyes"; then
1086         AC_MSG_ERROR([--enable-llvm is required when building $1])
1087     fi
1088 }
1089
1090 llvm_require_version() {
1091     require_llvm $2
1092
1093     llvm_target_version_major=`echo $1 | cut -d. -f1 | egrep -o '^[[0-9]]+'`
1094     llvm_target_version_minor=`echo $1 | cut -d. -f2 | egrep -o '^[[0-9]]+'`
1095     llvm_target_version_patch=`echo $1 | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1096
1097     if test "$LLVM_VERSION_MAJOR" -gt "$llvm_target_version_major"; then
1098         # major > required major
1099         #  --> OK
1100         return
1101     fi
1102
1103     if test "$LLVM_VERSION_MAJOR" -eq "$llvm_target_version_major"; then
1104         if test "$LLVM_VERSION_MINOR" -gt "$llvm_target_version_minor"; then
1105             # major = required major and
1106             # minor > required minor
1107             #  --> OK
1108             return
1109         else
1110             if test "$LLVM_VERSION_MINOR" -eq "$llvm_target_version_minor"; then
1111                 if test "$LLVM_VERSION_PATCH" -ge "$llvm_target_version_patch"; then
1112                     # major = required major and
1113                     # minor = required minor and
1114                     # patch >= required patch
1115                     #  --> OK
1116                     return
1117                 fi
1118             fi
1119         fi
1120     fi
1121
1122     AC_MSG_ERROR([LLVM $1 or newer is required for $2])
1123 }
1124
1125 radeon_llvm_check() {
1126     if test ${LLVM_VERSION_INT} -lt 307; then
1127         amdgpu_llvm_target_name='r600'
1128     else
1129         amdgpu_llvm_target_name='amdgpu'
1130     fi
1131
1132     llvm_require_version $*
1133
1134     llvm_add_target $amdgpu_llvm_target_name $2
1135
1136     llvm_add_default_components $2
1137     llvm_add_component "bitreader" $2
1138     llvm_add_component "ipo" $2
1139
1140     if test "x$have_libelf" != xyes; then
1141        AC_MSG_ERROR([$2 requires libelf when using llvm])
1142     fi
1143 }
1144
1145 llvm_set_environment_variables
1146
1147 AC_SUBST([LLVM_CFLAGS])
1148 AC_SUBST([LLVM_CXXFLAGS])
1149 AC_SUBST([LLVM_LIBS])
1150 AC_SUBST([LLVM_LDFLAGS])
1151 AC_SUBST([LLVM_INCLUDEDIR])
1152
1153 dnl
1154 dnl libunwind
1155 dnl
1156 PKG_CHECK_EXISTS(libunwind, [HAVE_LIBUNWIND=yes], [HAVE_LIBUNWIND=no])
1157 AC_ARG_ENABLE([libunwind],
1158     [AS_HELP_STRING([--enable-libunwind],
1159             [Use libunwind for backtracing (default: auto)])],
1160         [LIBUNWIND="$enableval"],
1161         [LIBUNWIND="$HAVE_LIBUNWIND"])
1162
1163 if test "x$LIBUNWIND" = "xyes"; then
1164     PKG_CHECK_MODULES(LIBUNWIND, libunwind)
1165     AC_DEFINE(HAVE_LIBUNWIND, 1, [Have libunwind support])
1166 fi
1167
1168
1169 dnl Options for APIs
1170 AC_ARG_ENABLE([opengl],
1171     [AS_HELP_STRING([--disable-opengl],
1172         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
1173     [enable_opengl="$enableval"],
1174     [enable_opengl=yes])
1175 AC_ARG_ENABLE([gles1],
1176     [AS_HELP_STRING([--disable-gles1],
1177         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
1178     [enable_gles1="$enableval"],
1179     [enable_gles1=yes])
1180 AC_ARG_ENABLE([gles2],
1181     [AS_HELP_STRING([--disable-gles2],
1182         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
1183     [enable_gles2="$enableval"],
1184     [enable_gles2=yes])
1185
1186 AC_ARG_ENABLE([dri],
1187     [AS_HELP_STRING([--enable-dri],
1188         [enable DRI modules @<:@default=enabled@:>@])],
1189     [enable_dri="$enableval"],
1190     [enable_dri=yes])
1191
1192 AC_ARG_ENABLE([gallium-extra-hud],
1193     [AS_HELP_STRING([--enable-gallium-extra-hud],
1194         [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
1195     [enable_gallium_extra_hud="$enableval"],
1196     [enable_gallium_extra_hud=no])
1197 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
1198 if test "x$enable_gallium_extra_hud" = xyes ; then
1199     DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
1200 fi
1201
1202 #TODO: no pkgconfig .pc available for libsensors.
1203 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
1204 AC_ARG_ENABLE([lmsensors],
1205     [AS_HELP_STRING([--enable-lmsensors],
1206         [enable HUD lmsensor support @<:@default=disabled@:>@])],
1207     [enable_lmsensors="$enableval"],
1208     [enable_lmsensors=no])
1209 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
1210 if test "x$enable_lmsensors" = xyes ; then
1211     DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
1212     LIBSENSORS_LIBS="-lsensors"
1213 else
1214     LIBSENSORS_LIBS=""
1215 fi
1216 AC_SUBST(LIBSENSORS_LIBS)
1217
1218 case "$host_os" in
1219 linux*)
1220     dri3_default=yes
1221     ;;
1222 *)
1223     dri3_default=no
1224     ;;
1225 esac
1226
1227 if test "x$enable_dri" = xno; then
1228     dri3_default=no
1229 fi
1230
1231 AC_ARG_ENABLE([dri3],
1232     [AS_HELP_STRING([--enable-dri3],
1233         [enable DRI3 @<:@default=auto@:>@])],
1234     [enable_dri3="$enableval"],
1235     [enable_dri3="$dri3_default"])
1236 AC_ARG_ENABLE([glx],
1237     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
1238         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
1239     [enable_glx="$enableval"],
1240     [enable_glx=yes])
1241 AC_ARG_ENABLE([osmesa],
1242     [AS_HELP_STRING([--enable-osmesa],
1243         [enable OSMesa library @<:@default=disabled@:>@])],
1244     [enable_osmesa="$enableval"],
1245     [enable_osmesa=no])
1246 AC_ARG_ENABLE([gallium-osmesa],
1247     [AS_HELP_STRING([--enable-gallium-osmesa],
1248         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
1249     [enable_gallium_osmesa="$enableval"],
1250     [enable_gallium_osmesa=no])
1251 AC_ARG_ENABLE([egl],
1252     [AS_HELP_STRING([--disable-egl],
1253         [disable EGL library @<:@default=enabled@:>@])],
1254     [enable_egl="$enableval"],
1255     [enable_egl=yes])
1256
1257 AC_ARG_ENABLE([xa],
1258     [AS_HELP_STRING([--enable-xa],
1259         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
1260     [enable_xa="$enableval"],
1261     [enable_xa=no])
1262 AC_ARG_ENABLE([gbm],
1263    [AS_HELP_STRING([--enable-gbm],
1264          [enable gbm library @<:@default=yes except cygwin@:>@])],
1265    [enable_gbm="$enableval"],
1266    [case "$host_os" in
1267        cygwin*)
1268           enable_gbm=no
1269           ;;
1270        *)
1271           enable_gbm=yes
1272           ;;
1273     esac])
1274 AC_ARG_ENABLE([nine],
1275     [AS_HELP_STRING([--enable-nine],
1276         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
1277     [enable_nine="$enableval"],
1278     [enable_nine=no])
1279
1280 AC_ARG_ENABLE([xvmc],
1281    [AS_HELP_STRING([--enable-xvmc],
1282          [enable xvmc library @<:@default=auto@:>@])],
1283    [enable_xvmc="$enableval"],
1284    [enable_xvmc=auto])
1285 AC_ARG_ENABLE([vdpau],
1286    [AS_HELP_STRING([--enable-vdpau],
1287          [enable vdpau library @<:@default=auto@:>@])],
1288    [enable_vdpau="$enableval"],
1289    [enable_vdpau=auto])
1290 AC_ARG_ENABLE([omx],
1291    [AS_HELP_STRING([--enable-omx],
1292          [DEPRECATED: Use --enable-omx-bellagio instead @<:@default=auto@:>@])],
1293    [AC_MSG_ERROR([--enable-omx is deprecated. Use --enable-omx-bellagio instead.])],
1294    [])
1295 AC_ARG_ENABLE([omx-bellagio],
1296    [AS_HELP_STRING([--enable-omx-bellagio],
1297          [enable OpenMAX Bellagio library @<:@default=disabled@:>@])],
1298    [enable_omx_bellagio="$enableval"],
1299    [enable_omx_bellagio=no])
1300 AC_ARG_ENABLE([va],
1301    [AS_HELP_STRING([--enable-va],
1302          [enable va library @<:@default=auto@:>@])],
1303    [enable_va="$enableval"],
1304    [enable_va=auto])
1305 AC_ARG_ENABLE([opencl],
1306    [AS_HELP_STRING([--enable-opencl],
1307          [enable OpenCL library @<:@default=disabled@:>@])],
1308    [enable_opencl="$enableval"],
1309    [enable_opencl=no])
1310 AC_ARG_ENABLE([opencl_icd],
1311    [AS_HELP_STRING([--enable-opencl-icd],
1312           [Build an OpenCL ICD library to be loaded by an ICD implementation
1313            @<:@default=enabled@:>@])],
1314     [enable_opencl_icd="$enableval"],
1315     [enable_opencl_icd=yes])
1316
1317 AC_ARG_ENABLE([gallium-tests],
1318     [AS_HELP_STRING([--enable-gallium-tests],
1319         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1320     [enable_gallium_tests="$enableval"],
1321     [enable_gallium_tests=no])
1322
1323 # Option for Gallium drivers
1324
1325 # Keep this in sync with the --with-gallium-drivers help string default value
1326 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1327
1328 AC_ARG_WITH([gallium-drivers],
1329     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1330         [comma delimited Gallium drivers list, e.g.
1331         "i915,nouveau,r300,r600,radeonsi,freedreno,pl111,svga,swrast,swr,vc4,vc5,virgl,etnaviv,imx"
1332         @<:@default=r300,r600,svga,swrast@:>@])],
1333     [with_gallium_drivers="$withval"],
1334     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1335
1336 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
1337 # here so that the script doesn't choke on an unknown driver name later.
1338 case "$with_gallium_drivers" in
1339     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1340     no) with_gallium_drivers='' ;;
1341 esac
1342
1343 if test "x$enable_opengl" = xno -a \
1344         "x$enable_gles1" = xno -a \
1345         "x$enable_gles2" = xno -a \
1346         "x$enable_nine" = xno -a \
1347         "x$enable_xa" = xno -a \
1348         "x$enable_xvmc" = xno -a \
1349         "x$enable_vdpau" = xno -a \
1350         "x$enable_omx_bellagio" = xno -a \
1351         "x$enable_va" = xno -a \
1352         "x$enable_opencl" = xno; then
1353     AC_MSG_ERROR([at least one API should be enabled])
1354 fi
1355
1356 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1357 if test "x$enable_opengl" = xno -a \
1358         "x$enable_gles1" = xyes; then
1359     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1360 fi
1361
1362 if test "x$enable_opengl" = xno -a \
1363         "x$enable_gles2" = xyes; then
1364     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1365 fi
1366
1367 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1368 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1369 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1370 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1371                                         "x$enable_gles1" = xyes -o \
1372                                         "x$enable_gles2" = xyes)
1373 AM_CONDITIONAL(NEED_KHRPLATFORM, test "x$enable_egl" = xyes -o \
1374                                       "x$enable_gles1" = xyes -o \
1375                                       "x$enable_gles2" = xyes)
1376
1377 # Validate GLX options
1378 if test "x$enable_glx" = xyes; then
1379     if test "x$enable_dri" = xyes; then
1380         enable_glx=dri
1381     elif test -n "$with_gallium_drivers"; then
1382         enable_glx=gallium-xlib
1383     else
1384         enable_glx=xlib
1385     fi
1386 fi
1387 case "x$enable_glx" in
1388 xdri | xxlib | xgallium-xlib)
1389     # GLX requires OpenGL
1390     if test "x$enable_opengl" = xno; then
1391         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1392     fi
1393
1394     # Check individual dependencies
1395     case "x$enable_glx" in
1396     xdri)
1397         if test "x$enable_dri" = xno; then
1398             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1399         fi
1400         ;;
1401     xxlib)
1402         if test "x$enable_dri" = xyes; then
1403             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1404         fi
1405         ;;
1406     xgallium-xlib )
1407         if test "x$enable_dri" = xyes; then
1408             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1409         fi
1410         if test -z "$with_gallium_drivers"; then
1411             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1412         fi
1413         ;;
1414     esac
1415     ;;
1416 xno)
1417     ;;
1418 *)
1419     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1420     ;;
1421 esac
1422
1423 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1424 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1425 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1426 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1427
1428 DEFAULT_GL_LIB_NAME=GL
1429
1430 dnl
1431 dnl Libglvnd configuration
1432 dnl
1433 AC_ARG_ENABLE([libglvnd],
1434     [AS_HELP_STRING([--enable-libglvnd],
1435         [Build GLX and EGL for libglvnd @<:@default=disabled@:>@])],
1436     [enable_libglvnd="$enableval"],
1437     [enable_libglvnd=no])
1438 AM_CONDITIONAL(USE_LIBGLVND, test "x$enable_libglvnd" = xyes)
1439
1440 if test "x$enable_libglvnd" = xyes ; then
1441     case "x$enable_glx" in
1442     xxlib | xgallium-xlib )
1443         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1444         ;;
1445     esac
1446
1447     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.2.0)
1448     LIBGLVND_DATADIR=`$PKG_CONFIG --variable=datadir libglvnd`
1449     AC_SUBST([LIBGLVND_DATADIR])
1450
1451     DEFINES="${DEFINES} -DUSE_LIBGLVND=1"
1452     DEFAULT_GL_LIB_NAME=GLX_mesa
1453
1454     if test "x$enable_glx" = xno -a "x$enable_egl" = xno; then
1455         AC_MSG_ERROR([cannot build libglvnd without GLX or EGL])
1456     fi
1457 fi
1458
1459 AC_ARG_WITH([gl-lib-name],
1460   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
1461     [specify GL library name @<:@default=GL@:>@])],
1462   [GL_LIB=$withval],
1463   [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1464 AC_ARG_WITH([osmesa-lib-name],
1465   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
1466     [specify OSMesa library name @<:@default=OSMesa@:>@])],
1467   [OSMESA_LIB=$withval],
1468   [OSMESA_LIB=OSMesa])
1469 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1470 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
1471
1472 dnl
1473 dnl Mangled Mesa support
1474 dnl
1475 AC_ARG_ENABLE([mangling],
1476   [AS_HELP_STRING([--enable-mangling],
1477     [enable mangled symbols and library name @<:@default=disabled@:>@])],
1478   [enable_mangling="${enableval}"],
1479   [enable_mangling=no]
1480 )
1481 if test "x${enable_mangling}" = "xyes" ; then
1482   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
1483   GL_LIB="Mangled${GL_LIB}"
1484   OSMESA_LIB="Mangled${OSMESA_LIB}"
1485 fi
1486 AC_SUBST([GL_LIB])
1487 AC_SUBST([OSMESA_LIB])
1488
1489 # Check for libdrm
1490 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1491                   [have_libdrm=yes], [have_libdrm=no])
1492 if test "x$have_libdrm" = xyes; then
1493     DEFINES="$DEFINES -DHAVE_LIBDRM"
1494 fi
1495
1496 require_libdrm() {
1497     if test "x$have_libdrm" != xyes; then
1498        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1499     fi
1500 }
1501
1502
1503 # Select which platform-dependent DRI code gets built
1504 case "$host_os" in
1505 darwin*)
1506     dri_platform='apple' ;;
1507 cygwin*)
1508     dri_platform='windows' ;;
1509 gnu*)
1510     dri_platform='none' ;;
1511 *)
1512     dri_platform='drm' ;;
1513 esac
1514
1515 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1516     have_drisw_kms='yes'
1517 fi
1518
1519 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1520 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1521 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1522 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1523 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1524 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1525 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1526 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1527 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1528
1529 AC_ARG_ENABLE([shared-glapi],
1530     [AS_HELP_STRING([--enable-shared-glapi],
1531         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1532     [enable_shared_glapi="$enableval"],
1533     [enable_shared_glapi=yes])
1534
1535 case "x$enable_opengl$enable_gles1$enable_gles2" in
1536 x*yes*yes*)
1537     if test "x$enable_shared_glapi" = xno; then
1538         AC_MSG_ERROR([shared GLAPI required when building two or more of
1539                       the following APIs - opengl, gles1 gles2])
1540     fi
1541     ;;
1542 esac
1543
1544 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1545
1546 # Build the pipe-drivers as separate libraries/modules.
1547 # Do not touch this unless you know what you are doing.
1548 # XXX: Expose via configure option ?
1549 enable_shared_pipe_drivers=no
1550
1551 dnl
1552 dnl Driver specific build directories
1553 dnl
1554
1555 if test "x$enable_gallium_osmesa" = xyes; then
1556     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1557         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1558     fi
1559     if test "x$enable_osmesa" = xyes; then
1560         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1561     fi
1562 fi
1563
1564 require_dri_shared_libs_and_glapi() {
1565     if test "x$enable_static" = xyes; then
1566         AC_MSG_ERROR([$1 cannot be build as static library])
1567     fi
1568
1569     if test "x$enable_dri" != xyes; then
1570         # There is only a single backend which won't be build/used otherwise.
1571         # XXX: Revisit this as the egl/haiku is a thing.
1572         AC_MSG_ERROR([$1 requires --enable-dri])
1573     fi
1574
1575     if test "x$enable_shared_glapi" != xyes; then
1576         AC_MSG_ERROR([$1 requires --enable-shared-glapi])
1577     fi
1578 }
1579
1580 if test "x$enable_dri" = xyes; then
1581     require_dri_shared_libs_and_glapi "DRI"
1582
1583     # not a hard requirement as swrast does not depend on it
1584     if test "x$have_libdrm" = xyes; then
1585         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1586     fi
1587 fi
1588
1589 AC_ARG_ENABLE([driglx-direct],
1590     [AS_HELP_STRING([--disable-driglx-direct],
1591         [disable direct rendering in GLX and EGL for DRI \
1592             @<:@default=auto@:>@])],
1593     [driglx_direct="$enableval"],
1594     [driglx_direct="yes"])
1595
1596 dnl
1597 dnl libGL configuration per driver
1598 dnl
1599 if test "x$enable_glx" != xno; then
1600     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1601 fi
1602 case "x$enable_glx" in
1603 xxlib | xgallium-xlib)
1604     # Xlib-based GLX
1605     dri_modules="x11 xext xcb"
1606     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1607     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1608     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1609     GL_LIB_DEPS="$XLIBGL_LIBS"
1610     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1611     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1612     ;;
1613 xdri)
1614     # DRI-based GLX
1615
1616     # find the DRI deps for libGL
1617     dri_modules="x11 xext xdamage >= $XDAMAGE_REQUIRED xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1618
1619     if test x"$driglx_direct" = xyes; then
1620         if test x"$dri_platform" = xdrm ; then
1621             DEFINES="$DEFINES -DGLX_USE_DRM"
1622             require_libdrm "Direct rendering"
1623
1624             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1625             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1626
1627             if test x"$enable_dri" = xyes; then
1628                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1629             fi
1630         fi
1631         if test x"$dri_platform" = xapple ; then
1632             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1633         fi
1634         if test x"$dri_platform" = xwindows ; then
1635             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1636         fi
1637     fi
1638
1639     # add xf86vidmode if available
1640     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1641     if test "$HAVE_XF86VIDMODE" = yes ; then
1642         dri_modules="$dri_modules xxf86vm"
1643     fi
1644
1645     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1646     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1647     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1648     GL_LIB_DEPS="$DRIGL_LIBS"
1649
1650     # need DRM libs, $PTHREAD_LIBS, etc.
1651     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1652     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1653     ;;
1654 esac
1655
1656 # This is outside the case (above) so that it is invoked even for non-GLX
1657 # builds.
1658 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1659
1660 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1661 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1662 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1663 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1664
1665 AC_SUBST([X11_INCLUDES])
1666 AC_SUBST([GL_LIB_DEPS])
1667 AC_SUBST([GL_PC_REQ_PRIV])
1668 AC_SUBST([GL_PC_LIB_PRIV])
1669 AC_SUBST([GL_PC_CFLAGS])
1670 AC_SUBST([DRI_PC_REQ_PRIV])
1671 AC_SUBST([GLESv1_CM_LIB_DEPS])
1672 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1673 AC_SUBST([GLESv2_LIB_DEPS])
1674 AC_SUBST([GLESv2_PC_LIB_PRIV])
1675
1676 AC_SUBST([HAVE_XF86VIDMODE])
1677
1678 dnl
1679 dnl More GLX setup
1680 dnl
1681 case "x$enable_glx" in
1682 xxlib | xgallium-xlib)
1683     DEFINES="$DEFINES -DUSE_XSHM"
1684     ;;
1685 xdri)
1686     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1687     if test "x$driglx_direct" = xyes; then
1688         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1689     fi
1690     ;;
1691 esac
1692
1693 dnl
1694 dnl TLS detection
1695 dnl
1696
1697 AC_ARG_ENABLE([glx-tls],
1698     [AS_HELP_STRING([--enable-glx-tls],
1699         [enable TLS support in GLX @<:@default=enabled@:>@])],
1700     [GLX_USE_TLS="$enableval"],
1701     [GLX_USE_TLS=yes])
1702 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1703
1704 if test "x$GLX_USE_TLS" = xyes; then
1705     DEFINES="$DEFINES -DGLX_USE_TLS"
1706 fi
1707
1708 dnl Read-only text section on x86 hardened platforms
1709 AC_ARG_ENABLE([glx-read-only-text],
1710     [AS_HELP_STRING([--enable-glx-read-only-text],
1711         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1712     [enable_glx_read_only_text="$enableval"],
1713     [enable_glx_read_only_text=no])
1714 if test "x$enable_glx_read_only_text" = xyes; then
1715     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1716 fi
1717
1718 dnl
1719 dnl DEPRECATED: EGL Platforms configuration
1720 dnl
1721 AC_ARG_WITH([egl-platforms],
1722     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1723         [DEPRECATED: use --with-platforms instead@<:@default=auto@:>@])],
1724     [with_egl_platforms="$withval"],
1725     [with_egl_platforms=auto])
1726
1727 if test "x$with_egl_platforms" = xauto; then
1728     with_egl_platforms="x11,surfaceless"
1729     if test "x$enable_gbm" = xyes; then
1730         with_egl_platforms="$with_egl_platforms,drm"
1731     fi
1732 else
1733     AC_MSG_WARN([--with-egl-platforms is deprecated. Use --with-platforms instead.])
1734 fi
1735
1736 dnl
1737 dnl Platforms configuration
1738 dnl
1739 AC_ARG_WITH([platforms],
1740     [AS_HELP_STRING([--with-platforms@<:@=DIRS...@:>@],
1741         [comma delimited native platforms libEGL/Vulkan/other supports, e.g.
1742         "x11,drm,wayland,surfaceless..." @<:@default=auto@:>@])],
1743     [with_platforms="$withval"],
1744     [with_platforms=auto])
1745
1746 # Reuse the autodetection rather than duplicating it.
1747 if test "x$with_platforms" = xauto; then
1748     with_platforms=$with_egl_platforms
1749 fi
1750
1751 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
1752         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
1753         WAYLAND_SCANNER='')
1754 if test "x$WAYLAND_SCANNER" = x; then
1755     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner], [:])
1756 fi
1757
1758 PKG_CHECK_EXISTS([wayland-protocols >= $WAYLAND_PROTOCOLS_REQUIRED], [have_wayland_protocols=yes], [have_wayland_protocols=no])
1759 if test "x$have_wayland_protocols" = xyes; then
1760     ac_wayland_protocols_pkgdatadir=`$PKG_CONFIG --variable=pkgdatadir wayland-protocols`
1761 fi
1762 AC_SUBST(WAYLAND_PROTOCOLS_DATADIR, $ac_wayland_protocols_pkgdatadir)
1763
1764 # Do per platform setups and checks
1765 platforms=`IFS=', '; echo $with_platforms`
1766 for plat in $platforms; do
1767     case "$plat" in
1768     wayland)
1769
1770         PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= $WAYLAND_REQUIRED])
1771         PKG_CHECK_MODULES([WAYLAND_SERVER], [wayland-server >= $WAYLAND_REQUIRED])
1772
1773         if test "x$WAYLAND_SCANNER" = "x:"; then
1774                 AC_MSG_ERROR([wayland-scanner is needed to compile the wayland platform])
1775         fi
1776         if test "x$have_wayland_protocols" = xno; then
1777                 AC_MSG_ERROR([wayland-protocols >= $WAYLAND_PROTOCOLS_REQUIRED is needed to compile the wayland platform])
1778         fi
1779         DEFINES="$DEFINES -DHAVE_WAYLAND_PLATFORM -DWL_HIDE_DEPRECATED"
1780         ;;
1781
1782     x11)
1783         PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1784         DEFINES="$DEFINES -DHAVE_X11_PLATFORM"
1785         ;;
1786
1787     drm)
1788         test "x$enable_gbm" = "xno" &&
1789                 AC_MSG_ERROR([EGL platform drm needs gbm])
1790         DEFINES="$DEFINES -DHAVE_DRM_PLATFORM"
1791         ;;
1792
1793     surfaceless)
1794         DEFINES="$DEFINES -DHAVE_SURFACELESS_PLATFORM"
1795         ;;
1796
1797     android)
1798         PKG_CHECK_MODULES([ANDROID], [cutils hardware sync])
1799         DEFINES="$DEFINES -DHAVE_ANDROID_PLATFORM"
1800         ;;
1801
1802     *)
1803         AC_MSG_ERROR([platform '$plat' does not exist])
1804         ;;
1805     esac
1806
1807     case "$plat" in
1808     wayland|drm|surfaceless)
1809         require_libdrm "Platform $plat"
1810         ;;
1811     esac
1812 done
1813
1814 if test "x$enable_glx" != xno; then
1815     if ! echo "$platforms" | grep -q 'x11'; then
1816         AC_MSG_ERROR([Building GLX without the x11 platform is not supported])
1817     fi
1818 fi
1819
1820 if test x"$enable_dri3" = xyes; then
1821     DEFINES="$DEFINES -DHAVE_DRI3"
1822
1823     dri3_modules="x11-xcb xcb >= $XCB_REQUIRED xcb-dri3 xcb-xfixes xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1824     PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1825 fi
1826
1827 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$platforms" | grep -q 'x11')
1828 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$platforms" | grep -q 'wayland')
1829 AM_CONDITIONAL(HAVE_PLATFORM_DRM, echo "$platforms" | grep -q 'drm')
1830 AM_CONDITIONAL(HAVE_PLATFORM_SURFACELESS, echo "$platforms" | grep -q 'surfaceless')
1831 AM_CONDITIONAL(HAVE_PLATFORM_ANDROID, echo "$platforms" | grep -q 'android')
1832
1833 dnl
1834 dnl More DRI setup
1835 dnl
1836 dnl Directory for DRI drivers
1837 AC_ARG_WITH([dri-driverdir],
1838     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1839         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1840     [DRI_DRIVER_INSTALL_DIR="$withval"],
1841     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1842 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1843 dnl Extra search path for DRI drivers
1844 AC_ARG_WITH([dri-searchpath],
1845     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1846         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1847     [DRI_DRIVER_SEARCH_DIR="$withval"],
1848     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1849 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1850 dnl Which drivers to build - default is chosen by platform
1851 AC_ARG_WITH([dri-drivers],
1852     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1853         [comma delimited classic DRI drivers list, e.g.
1854         "i915,i965,nouveau,radeon,r200,swrast" @<:@default=auto@:>@])],
1855     [with_dri_drivers="$withval"],
1856     [with_dri_drivers=auto])
1857
1858 if test "x$with_dri_drivers" = xauto; then
1859     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1860         with_dri_drivers="yes"
1861     else
1862         with_dri_drivers="no"
1863     fi
1864 fi
1865 if test "x$with_dri_drivers" = xno; then
1866     with_dri_drivers=''
1867 fi
1868
1869 # Check for expat
1870 PKG_CHECK_MODULES([EXPAT], [expat],,
1871     [PKG_CHECK_MODULES([EXPAT], [expat21])]
1872 )
1873
1874 dnl If $with_dri_drivers is yes, drivers will be added through
1875 dnl platform checks. Set DEFINES and LIB_DEPS
1876 if test "x$enable_dri" = xyes; then
1877     # Platform specific settings and drivers to build
1878     case "$host_os" in
1879     linux*)
1880         case "$host_cpu" in
1881         powerpc* | sparc*)
1882             # Build only the drivers for cards that exist on PowerPC/sparc
1883             if test "x$with_dri_drivers" = "xyes"; then
1884                 with_dri_drivers="r200 radeon swrast"
1885             fi
1886             ;;
1887         esac
1888         ;;
1889     cygwin*)
1890         if test "x$with_dri_drivers" = "xyes"; then
1891             with_dri_drivers="swrast"
1892         fi
1893         ;;
1894     darwin*)
1895         DEFINES="$DEFINES -DBUILDING_MESA"
1896         if test "x$with_dri_drivers" = "xyes"; then
1897             with_dri_drivers="swrast"
1898         fi
1899         ;;
1900     esac
1901
1902     # default drivers
1903     if test "x$with_dri_drivers" = "xyes"; then
1904         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1905     fi
1906
1907     # put all the necessary libs together
1908     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1909 fi
1910
1911 AC_SUBST([DRI_LIB_DEPS])
1912
1913 DRI_DIRS=''
1914 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1915 if test -n "$with_dri_drivers"; then
1916     if test "x$enable_opengl" != xyes; then
1917         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1918     fi
1919
1920     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1921     for driver in $dri_drivers; do
1922         DRI_DIRS="$DRI_DIRS $driver"
1923         case "x$driver" in
1924         xi915)
1925             require_libdrm "i915"
1926             HAVE_I915_DRI=yes
1927             PKG_CHECK_MODULES([I915], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1928             ;;
1929         xi965)
1930             require_libdrm "i965"
1931             HAVE_I965_DRI=yes
1932             ;;
1933         xnouveau)
1934             require_libdrm "nouveau"
1935             HAVE_NOUVEAU_DRI=yes
1936             PKG_CHECK_MODULES([NVVIEUX], [libdrm >= $LIBDRM_NVVIEUX_REQUIRED libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1937             ;;
1938         xradeon)
1939             require_libdrm "radeon"
1940             HAVE_RADEON_DRI=yes;
1941             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1942             ;;
1943         xr200)
1944             require_libdrm "r200"
1945             HAVE_R200_DRI=yes
1946             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1947             ;;
1948         xswrast)
1949             HAVE_SWRAST_DRI=yes
1950             ;;
1951         *)
1952             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1953             ;;
1954         esac
1955     done
1956     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1957 fi
1958
1959
1960 dnl
1961 dnl Gallium LLVM
1962 dnl Deprecated: kept for backwards compatibility
1963 dnl
1964 AC_ARG_ENABLE([gallium-llvm],
1965     [AS_HELP_STRING([--enable-gallium-llvm],
1966         [DEPRECATED: use --enable-llvm instead])],
1967     [enable_gallium_llvm="$enableval"],
1968     [enable_gallium_llvm=auto])
1969
1970 if test "x$enable_gallium_llvm" != xauto; then
1971    AC_MSG_WARN([The --enable-gallium-llvm option has been deprecated. Use --enable-llvm instead.])
1972    enable_llvm=$enable_gallium_llvm
1973 fi
1974
1975 dnl
1976 dnl LLVM
1977 dnl
1978 AC_ARG_ENABLE([llvm],
1979     [AS_HELP_STRING([--enable-llvm],
1980         [build with LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1981     [enable_llvm="$enableval"],
1982     [enable_llvm=auto])
1983
1984 if test "x$enable_llvm" = xauto -a "x$FOUND_LLVM" = xyes; then
1985     if test "x$FOUND_LLVM" = xyes; then
1986         case "$host_cpu" in
1987         i*86|x86_64|amd64) enable_llvm=yes;;
1988         *) enable_llvm=no;;
1989         esac
1990     else
1991         enable_llvm=no
1992     fi
1993 fi
1994
1995 if test "x$enable_llvm" = xyes -a "x$FOUND_LLVM" = xno; then
1996     AC_MSG_ERROR([--enable-llvm selected but llvm-config is not found])
1997 fi
1998
1999 #
2000 # Vulkan driver configuration
2001 #
2002
2003 AC_ARG_WITH([vulkan-drivers],
2004     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
2005         [comma delimited Vulkan drivers list, e.g.
2006         "intel,radeon"
2007         @<:@default=no@:>@])],
2008     [with_vulkan_drivers="$withval"],
2009     [with_vulkan_drivers="no"])
2010
2011 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
2012 # here so that the script doesn't choke on an unknown driver name later.
2013 case "x$with_vulkan_drivers" in
2014     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
2015     xno) with_vulkan_drivers='' ;;
2016 esac
2017
2018 AC_ARG_WITH([vulkan-icddir],
2019     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
2020         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
2021     [VULKAN_ICD_INSTALL_DIR="$withval"],
2022     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
2023 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
2024
2025 require_x11_dri3() {
2026     if echo "$platforms" | grep -q 'x11'; then
2027         if test "x$enable_dri3" != xyes; then
2028             AC_MSG_ERROR([$1 Vulkan driver requires DRI3 when built with X11])
2029         fi
2030     fi
2031 }
2032
2033 if test -n "$with_vulkan_drivers"; then
2034     if test "x$ac_cv_func_dl_iterate_phdr" = xno; then
2035         AC_MSG_ERROR([Vulkan drivers require the dl_iterate_phdr function])
2036     fi
2037
2038     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
2039     for driver in $VULKAN_DRIVERS; do
2040         case "x$driver" in
2041         xintel)
2042             require_libdrm "ANV"
2043             require_x11_dri3 "ANV"
2044             HAVE_INTEL_VULKAN=yes
2045             ;;
2046         xradeon)
2047             require_libdrm "radv"
2048             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2049             radeon_llvm_check $LLVM_REQUIRED_RADV "radv"
2050             require_x11_dri3 "radv"
2051             HAVE_RADEON_VULKAN=yes
2052             ;;
2053         *)
2054             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
2055             ;;
2056         esac
2057     done
2058     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
2059 fi
2060
2061
2062 DEFINES="$DEFINES -DENABLE_SHADER_CACHE"
2063 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
2064 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
2065                                   "x$enable_osmesa" = xyes -o \
2066                                   -n "$DRI_DIRS")
2067
2068 dnl
2069 dnl OSMesa configuration
2070 dnl
2071
2072 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
2073 AC_ARG_WITH([osmesa-bits],
2074     [AS_HELP_STRING([--with-osmesa-bits=BITS],
2075         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
2076     [osmesa_bits="$withval"],
2077     [osmesa_bits=8])
2078 if test "x$osmesa_bits" != x8; then
2079     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
2080         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
2081         osmesa_bits=8
2082     fi
2083 fi
2084 case "x$osmesa_bits" in
2085 x8)
2086     OSMESA_LIB="${OSMESA_LIB}"
2087     ;;
2088 x16|x32)
2089     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
2090     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
2091     ;;
2092 *)
2093     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
2094     ;;
2095 esac
2096
2097 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
2098     # only link libraries with osmesa if shared
2099     if test "$enable_static" = no; then
2100         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2101     else
2102         OSMESA_LIB_DEPS=""
2103     fi
2104     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2105 fi
2106
2107 AC_SUBST([OSMESA_LIB_DEPS])
2108 AC_SUBST([OSMESA_PC_REQ])
2109 AC_SUBST([OSMESA_PC_LIB_PRIV])
2110
2111 dnl
2112 dnl gbm configuration
2113 dnl
2114 if test "x$enable_gbm" = xyes; then
2115     require_dri_shared_libs_and_glapi "gbm"
2116 fi
2117 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
2118 # FINISHME: GBM has a number of dependencies which we should add below
2119 GBM_PC_REQ_PRIV=""
2120 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
2121 AC_SUBST([GBM_PC_REQ_PRIV])
2122 AC_SUBST([GBM_PC_LIB_PRIV])
2123
2124 dnl
2125 dnl EGL configuration
2126 dnl
2127
2128 if test "x$enable_egl" = xyes; then
2129     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
2130
2131     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
2132
2133     require_dri_shared_libs_and_glapi "egl"
2134 fi
2135 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
2136 AC_SUBST([EGL_LIB_DEPS])
2137
2138 gallium_st="mesa"
2139
2140 dnl
2141 dnl XA configuration
2142 dnl
2143 if test "x$enable_xa" = xyes; then
2144     if test "x$with_gallium_drivers" = xswrast; then
2145        AC_MSG_ERROR([
2146           Building xa requires at least one non swrast gallium driver.
2147           If you are looking to use libxatracker.so with the VMware driver,
2148           make sure to include svga in the gallium drivers list, apart from
2149           enabling XA.
2150           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
2151     fi
2152     gallium_st="$gallium_st xa"
2153 fi
2154 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
2155
2156 if echo $platforms | grep -q "x11"; then
2157     have_xvmc_platform=yes
2158 else
2159     have_xvmc_platform=no
2160 fi
2161
2162 if echo $platforms | grep -q "x11"; then
2163     have_vdpau_platform=yes
2164 else
2165     have_vdpau_platform=no
2166 fi
2167
2168 if echo $platforms | grep -q "x11\|drm"; then
2169     have_omx_platform=yes
2170 else
2171     have_omx_platform=no
2172 fi
2173
2174 if echo $platforms | grep -q "x11\|drm\|wayland"; then
2175     have_va_platform=yes
2176 else
2177     have_va_platform=no
2178 fi
2179
2180 dnl
2181 dnl Gallium G3DVL configuration
2182 dnl
2183 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
2184     if test "x$enable_xvmc" = xauto -a "x$have_xvmc_platform" = xyes; then
2185         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
2186     fi
2187
2188     if test "x$enable_vdpau" = xauto -a "x$have_vdpau_platform" = xyes; then
2189         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
2190     fi
2191
2192     if test "x$enable_omx_bellagio" = xauto -a "x$have_omx_platform" = xyes; then
2193         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx_bellagio=yes], [enable_omx_bellagio=no])
2194     fi
2195
2196     if test "x$enable_va" = xauto -a "x$have_va_platform" = xyes; then
2197         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
2198     fi
2199 fi
2200
2201 if test "x$enable_dri" = xyes -o \
2202         "x$enable_xvmc" = xyes -o \
2203         "x$enable_vdpau" = xyes -o \
2204         "x$enable_omx_bellagio" = xyes -o \
2205         "x$enable_va" = xyes; then
2206     need_gallium_vl=yes
2207 fi
2208 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
2209
2210 if test "x$enable_xvmc" = xyes -o \
2211         "x$enable_vdpau" = xyes -o \
2212         "x$enable_omx_bellagio" = xyes -o \
2213         "x$enable_va" = xyes; then
2214     if echo $platforms | grep -q "x11"; then
2215         PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2216     fi
2217     need_gallium_vl_winsys=yes
2218 fi
2219 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
2220
2221 if test "x$enable_xvmc" = xyes; then
2222     if test "x$have_xvmc_platform" != xyes; then
2223         AC_MSG_ERROR([XVMC requires the x11 platforms])
2224     fi
2225     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
2226     gallium_st="$gallium_st xvmc"
2227 fi
2228 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
2229
2230 if test "x$enable_vdpau" = xyes; then
2231     if test "x$have_vdpau_platform" != xyes; then
2232         AC_MSG_ERROR([VDPAU requires the x11 platforms])
2233     fi
2234     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
2235     gallium_st="$gallium_st vdpau"
2236     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
2237 fi
2238 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
2239
2240 if test "x$enable_omx_bellagio" = xyes; then
2241     if test "x$have_omx_platform" != xyes; then
2242         AC_MSG_ERROR([OMX requires at least one of the x11 or drm platforms])
2243     fi
2244     PKG_CHECK_MODULES([OMX_BELLAGIO], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
2245     gallium_st="$gallium_st omx_bellagio"
2246 fi
2247 AM_CONDITIONAL(HAVE_ST_OMX_BELLAGIO, test "x$enable_omx_bellagio" = xyes)
2248
2249 if test "x$enable_va" = xyes; then
2250     if test "x$have_va_platform" != xyes; then
2251         AC_MSG_ERROR([VA requires at least one of the x11 drm or wayland platforms])
2252     fi
2253     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
2254     gallium_st="$gallium_st va"
2255 fi
2256 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
2257
2258 dnl
2259 dnl Nine Direct3D9 configuration
2260 dnl
2261 if test "x$enable_nine" = xyes; then
2262     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
2263         AC_MSG_ERROR([nine requires the gallium swrast driver])
2264     fi
2265     if test "x$with_gallium_drivers" = xswrast; then
2266         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
2267     fi
2268     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
2269         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
2270     fi
2271
2272     if test "x$enable_dri3" = xno; then
2273         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
2274     fi
2275
2276     gallium_st="$gallium_st nine"
2277 fi
2278 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
2279
2280 dnl
2281 dnl OpenCL configuration
2282 dnl
2283
2284 AC_ARG_WITH([clang-libdir],
2285    [AS_HELP_STRING([--with-clang-libdir],
2286          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
2287    [CLANG_LIBDIR="$withval"],
2288    [CLANG_LIBDIR=''])
2289
2290 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
2291
2292 if test "x$enable_opencl" = xyes; then
2293     if test -z "$with_gallium_drivers"; then
2294         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
2295     fi
2296
2297     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
2298         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
2299     fi
2300
2301     if test "x$have_libclc" = xno; then
2302         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
2303                     Make sure the directory containing libclc.pc is specified in your
2304                     PKG_CONFIG_PATH environment variable.
2305                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
2306     else
2307         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
2308         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
2309         AC_SUBST([LIBCLC_INCLUDEDIR])
2310         AC_SUBST([LIBCLC_LIBEXECDIR])
2311     fi
2312
2313     gallium_st="$gallium_st clover"
2314
2315     if test "x$enable_opencl_icd" = xyes; then
2316         OPENCL_LIBNAME="MesaOpenCL"
2317     else
2318         OPENCL_LIBNAME="OpenCL"
2319     fi
2320
2321     if test "x$have_libelf" != xyes; then
2322        AC_MSG_ERROR([Clover requires libelf])
2323     fi
2324
2325     if test "x${ac_cv_cxx_compiler_gnu}" = xyes; then
2326         altivec_enabled=no
2327         AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2328         #if !defined(__VEC__) || !defined(__ALTIVEC__)
2329         #error "AltiVec not enabled"
2330         #endif
2331         ])], altivec_enabled=yes)
2332
2333         if test "$altivec_enabled" = yes; then
2334             CLOVER_STD_OVERRIDE="-std=gnu++11"
2335         fi
2336         AC_SUBST([CLOVER_STD_OVERRIDE])
2337     fi
2338
2339     llvm_require_version $LLVM_REQUIRED_OPENCL "opencl"
2340
2341     llvm_add_default_components "opencl"
2342     llvm_add_component "all-targets" "opencl"
2343     llvm_add_component "coverage" "opencl"
2344     llvm_add_component "linker" "opencl"
2345     llvm_add_component "instrumentation" "opencl"
2346     llvm_add_component "ipo" "opencl"
2347     llvm_add_component "irreader" "opencl"
2348     llvm_add_component "lto" "opencl"
2349     llvm_add_component "option" "opencl"
2350     llvm_add_component "objcarcopts" "opencl"
2351     llvm_add_component "profiledata" "opencl"
2352     llvm_add_optional_component "coroutines" "opencl"
2353
2354     dnl Check for Clang internal headers
2355     if test -z "$CLANG_LIBDIR"; then
2356         CLANG_LIBDIR=${LLVM_LIBDIR}
2357     fi
2358     CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2359     AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2360         [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2361 fi
2362 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2363 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2364 AC_SUBST([OPENCL_LIBNAME])
2365 AC_SUBST([CLANG_RESOURCE_DIR])
2366
2367 dnl
2368 dnl Gallium configuration
2369 dnl
2370 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2371
2372 # libEGL wants to default to the first platform specified in
2373 # ./configure.  parse that here.
2374 if test "x$platforms" != "x"; then
2375     FIRST_PLATFORM_CAPS=`echo $platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2376     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2377 else
2378     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2379 fi
2380
2381 AC_SUBST([EGL_NATIVE_PLATFORM])
2382 AC_SUBST([EGL_CFLAGS])
2383
2384 # If we don't have the X11 platform, set this define so we don't try to include
2385 # the X11 headers.
2386 if ! echo "$platforms" | grep -q 'x11'; then
2387     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2388     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2389 fi
2390
2391 dnl Directory for XVMC libs
2392 AC_ARG_WITH([xvmc-libdir],
2393     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2394         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2395     [XVMC_LIB_INSTALL_DIR="$withval"],
2396     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2397 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2398
2399 dnl
2400 dnl Gallium Tests
2401 dnl
2402 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2403
2404 dnl Directory for VDPAU libs
2405 AC_ARG_WITH([vdpau-libdir],
2406     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2407         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2408     [VDPAU_LIB_INSTALL_DIR="$withval"],
2409     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2410 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2411
2412 dnl Directory for OMX_BELLAGIO libs
2413
2414 AC_ARG_WITH([omx-bellagio-libdir],
2415     [AS_HELP_STRING([--with-omx-bellagio-libdir=DIR],
2416         [directory for the OMX_BELLAGIO libraries])],
2417     [OMX_BELLAGIO_LIB_INSTALL_DIR="$withval"],
2418     [OMX_BELLAGIO_LIB_INSTALL_DIR=`$PKG_CONFIG --exists libomxil-bellagio && \
2419                                    $PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2420 AC_SUBST([OMX_BELLAGIO_LIB_INSTALL_DIR])
2421
2422 dnl Directory for VA libs
2423
2424 AC_ARG_WITH([va-libdir],
2425     [AS_HELP_STRING([--with-va-libdir=DIR],
2426         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2427     [VA_LIB_INSTALL_DIR="$withval"],
2428     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2429 AC_SUBST([VA_LIB_INSTALL_DIR])
2430
2431 AC_ARG_WITH([d3d-libdir],
2432     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2433         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2434     [D3D_DRIVER_INSTALL_DIR="$withval"],
2435     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2436 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2437
2438 dnl Architectures to build SWR library for
2439
2440 AC_ARG_WITH([swr-archs],
2441     [AS_HELP_STRING([--with-swr-archs@<:@=DIRS...@:>@],
2442         [comma delimited swr architectures list, e.g.
2443         "avx,avx2,knl,skx" @<:@default="avx,avx2"@:>@])],
2444     [with_swr_archs="$withval"],
2445     [with_swr_archs="avx,avx2"])
2446
2447 dnl
2448 dnl r300 doesn't strictly require LLVM, but for performance reasons we
2449 dnl highly recommend LLVM usage. So require it at least on x86 and x86_64
2450 dnl architectures.
2451 dnl
2452 r300_require_llvm() {
2453     case "$host" in *gnux32) return;; esac
2454     case "$host_cpu" in
2455     i*86|x86_64|amd64) require_llvm $1
2456         ;;
2457     esac
2458 }
2459
2460 dnl
2461 dnl DRM is needed by X, Wayland, and offscreen rendering.
2462 dnl Surfaceless is an alternative for the last one.
2463 dnl
2464 require_basic_egl() {
2465     case "$with_platforms" in
2466         *drm*|*surfaceless*|*android*)
2467             ;;
2468         *)
2469             AC_MSG_ERROR([$1 requires one of these:
2470                   1) --with-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2471                   2) --with-platforms=surfaceless (offscreen only)
2472                   3) --with-platforms=android (Android only)
2473                   Recommended options: drm,x11])
2474             ;;
2475     esac
2476 }
2477
2478 swr_require_cxx_feature_flags() {
2479     feature_name="$1"
2480     preprocessor_test="$2"
2481     option_list="$3"
2482     output_var="$4"
2483
2484     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2485     AC_LANG_PUSH([C++])
2486     save_CXXFLAGS="$CXXFLAGS"
2487     save_IFS="$IFS"
2488     IFS=","
2489     found=0
2490     for opts in $option_list
2491     do
2492         unset IFS
2493         CXXFLAGS="$opts $save_CXXFLAGS"
2494         AC_COMPILE_IFELSE(
2495             [AC_LANG_PROGRAM(
2496                 [   #if !($preprocessor_test)
2497                     #error
2498                     #endif
2499                 ])],
2500             [found=1; break],
2501             [])
2502         IFS=","
2503     done
2504     IFS="$save_IFS"
2505     CXXFLAGS="$save_CXXFLAGS"
2506     AC_LANG_POP([C++])
2507     if test $found -eq 1; then
2508         AC_MSG_RESULT([$opts])
2509         eval "$output_var=\$opts"
2510         return 0
2511     fi
2512     AC_MSG_RESULT([no])
2513     AC_MSG_ERROR([swr requires $feature_name support])
2514     return 1
2515 }
2516
2517 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2518 if test -n "$with_gallium_drivers"; then
2519     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2520     for driver in $gallium_drivers; do
2521         case "x$driver" in
2522         xsvga)
2523             HAVE_GALLIUM_SVGA=yes
2524             require_libdrm "svga"
2525             ;;
2526         xi915)
2527             HAVE_GALLIUM_I915=yes
2528             PKG_CHECK_MODULES([I915], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2529             require_libdrm "Gallium i915"
2530             ;;
2531         xr300)
2532             HAVE_GALLIUM_R300=yes
2533             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2534             require_libdrm "r300"
2535             r300_require_llvm "r300"
2536             ;;
2537         xr600)
2538             HAVE_GALLIUM_R600=yes
2539             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2540             require_libdrm "r600"
2541             if test "x$enable_llvm" = xyes; then
2542                 radeon_llvm_check $LLVM_REQUIRED_R600 "r600"
2543
2544                 llvm_add_component "asmparser" "r600"
2545                 llvm_add_component "bitreader" "r600"
2546             fi
2547             ;;
2548         xradeonsi)
2549             HAVE_GALLIUM_RADEONSI=yes
2550             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2551             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2552             require_libdrm "radeonsi"
2553             radeon_llvm_check $LLVM_REQUIRED_RADEONSI "radeonsi"
2554             if test "x$enable_egl" = xyes; then
2555                 require_basic_egl "radeonsi"
2556             fi
2557             ;;
2558         xnouveau)
2559             HAVE_GALLIUM_NOUVEAU=yes
2560             PKG_CHECK_MODULES([NOUVEAU], [libdrm >= $LIBDRM_NOUVEAU_REQUIRED libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2561             require_libdrm "nouveau"
2562             ;;
2563         xfreedreno)
2564             HAVE_GALLIUM_FREEDRENO=yes
2565             PKG_CHECK_MODULES([FREEDRENO], [libdrm >= $LIBDRM_FREEDRENO_REQUIRED libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2566             require_libdrm "freedreno"
2567             ;;
2568         xetnaviv)
2569             HAVE_GALLIUM_ETNAVIV=yes
2570             PKG_CHECK_MODULES([ETNAVIV], [libdrm >= $LIBDRM_ETNAVIV_REQUIRED libdrm_etnaviv >= $LIBDRM_ETNAVIV_REQUIRED])
2571             require_libdrm "etnaviv"
2572             ;;
2573        ximx)
2574             HAVE_GALLIUM_IMX=yes
2575             ;;
2576         xswrast)
2577             HAVE_GALLIUM_SOFTPIPE=yes
2578             if test "x$enable_llvm" = xyes; then
2579                 HAVE_GALLIUM_LLVMPIPE=yes
2580             fi
2581             ;;
2582         xswr)
2583             llvm_require_version $LLVM_REQUIRED_SWR "swr"
2584
2585             swr_require_cxx_feature_flags "C++11" "__cplusplus >= 201103L" \
2586                 ",-std=c++11" \
2587                 SWR_CXX11_CXXFLAGS
2588             AC_SUBST([SWR_CXX11_CXXFLAGS])
2589
2590             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2591                 ",-target-cpu=sandybridge,-mavx,-march=core-avx,-tp=sandybridge" \
2592                 SWR_AVX_CXXFLAGS
2593             AC_SUBST([SWR_AVX_CXXFLAGS])
2594
2595             swr_archs=`IFS=', '; echo $with_swr_archs`
2596             for arch in $swr_archs; do
2597                 case "x$arch" in
2598                 xavx)
2599                     HAVE_SWR_AVX=yes
2600                     ;;
2601                 xavx2)
2602                     swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2603                         ",-target-cpu=haswell,-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2,-tp=haswell" \
2604                         SWR_AVX2_CXXFLAGS
2605                     AC_SUBST([SWR_AVX2_CXXFLAGS])
2606                     HAVE_SWR_AVX2=yes
2607                     ;;
2608                 xknl)
2609                     swr_require_cxx_feature_flags "KNL" "defined(__AVX512F__) && defined(__AVX512ER__)" \
2610                         ",-target-cpu=mic-knl,-march=knl,-xMIC-AVX512" \
2611                         SWR_KNL_CXXFLAGS
2612                     AC_SUBST([SWR_KNL_CXXFLAGS])
2613                     HAVE_SWR_KNL=yes
2614                     ;;
2615                 xskx)
2616                     swr_require_cxx_feature_flags "SKX" "defined(__AVX512F__) && defined(__AVX512BW__)" \
2617                         ",-target-cpu=x86-skylake,-march=skylake-avx512,-xCORE-AVX512" \
2618                         SWR_SKX_CXXFLAGS
2619                     AC_SUBST([SWR_SKX_CXXFLAGS])
2620                     HAVE_SWR_SKX=yes
2621                     ;;
2622                 *)
2623                     AC_MSG_ERROR([unknown SWR build architecture '$arch'])
2624                     ;;
2625                 esac
2626             done
2627
2628             if test "x$HAVE_SWR_AVX" != xyes -a \
2629                     "x$HAVE_SWR_AVX2" != xyes -a \
2630                     "x$HAVE_SWR_KNL" != xyes -a \
2631                     "x$HAVE_SWR_SKX" != xyes; then
2632                AC_MSG_ERROR([swr enabled but no swr architectures selected])
2633             fi
2634
2635             HAVE_GALLIUM_SWR=yes
2636             ;;
2637         xvc4)
2638             HAVE_GALLIUM_VC4=yes
2639             require_libdrm "vc4"
2640
2641             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2642                               [USE_VC4_SIMULATOR=yes;
2643                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2644                               [USE_VC4_SIMULATOR=no])
2645             ;;
2646         xvc5)
2647             HAVE_GALLIUM_VC5=yes
2648
2649             PKG_CHECK_MODULES([VC5_SIMULATOR], [v3dv3],
2650                               [USE_VC5_SIMULATOR=yes;
2651                                DEFINES="$DEFINES -DUSE_VC5_SIMULATOR"],
2652                               [AC_MSG_ERROR([vc5 requires the simulator])])
2653             ;;
2654         xpl111)
2655             HAVE_GALLIUM_PL111=yes
2656             ;;
2657         xvirgl)
2658             HAVE_GALLIUM_VIRGL=yes
2659             require_libdrm "virgl"
2660             if test "x$enable_egl" = xyes; then
2661                 require_basic_egl "virgl"
2662             fi
2663             ;;
2664         *)
2665             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2666             ;;
2667         esac
2668     done
2669 fi
2670
2671 # XXX: Keep in sync with LLVM_REQUIRED_SWR
2672 AM_CONDITIONAL(SWR_INVALID_LLVM_VERSION, test "x$LLVM_VERSION" != x3.9.0 -a \
2673                                               "x$LLVM_VERSION" != x3.9.1)
2674
2675 if test "x$enable_llvm" = "xyes" -a "$with_gallium_drivers"; then
2676     llvm_require_version $LLVM_REQUIRED_GALLIUM "gallium"
2677     llvm_add_default_components "gallium"
2678 fi
2679
2680 AM_CONDITIONAL(HAVE_SWR_AVX, test "x$HAVE_SWR_AVX" = xyes)
2681 AM_CONDITIONAL(HAVE_SWR_AVX2, test "x$HAVE_SWR_AVX2" = xyes)
2682 AM_CONDITIONAL(HAVE_SWR_KNL, test "x$HAVE_SWR_KNL" = xyes)
2683 AM_CONDITIONAL(HAVE_SWR_SKX, test "x$HAVE_SWR_SKX" = xyes)
2684
2685 dnl We need to validate some needed dependencies for renderonly drivers.
2686
2687 if test "x$HAVE_GALLIUM_ETNAVIV" != xyes -a "x$HAVE_GALLIUM_IMX" = xyes  ; then
2688     AC_MSG_ERROR([Building with imx requires etnaviv])
2689 fi
2690
2691 if test "x$HAVE_GALLIUM_VC4" != xyes -a "x$HAVE_GALLIUM_PL111" = xyes  ; then
2692     AC_MSG_ERROR([Building with pl111 requires vc4])
2693 fi
2694
2695
2696 detect_old_buggy_llvm() {
2697     dnl llvm-config may not give the right answer when llvm is a built as a
2698     dnl single shared library, so we must work the library name out for
2699     dnl ourselves.
2700     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2701     dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2702     LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2703     AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2704
2705     if test "x$llvm_have_one_so" = xyes; then
2706         dnl LLVM was built using auto*, so there is only one shared object.
2707         LLVM_LIBS="-l$LLVM_SO_NAME"
2708     else
2709         dnl If LLVM was built with CMake, there will be one shared object per
2710         dnl component.
2711         AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2712                [AC_MSG_ERROR([Could not find llvm shared libraries:
2713                 Please make sure you have built llvm with the --enable-shared option
2714                 and that your llvm libraries are installed in $LLVM_LIBDIR
2715                 If you have installed your llvm libraries to a different directory you
2716                 can use the --with-llvm-prefix= configure flag to specify this directory.
2717                 NOTE: Mesa is attempting to use llvm shared libraries by default.
2718                 If you do not want to build with llvm shared libraries and instead want to
2719                 use llvm static libraries then add --disable-llvm-shared-libs to your configure
2720                 invocation and rebuild.])])
2721
2722         dnl We don't need to update LLVM_LIBS in this case because the LLVM
2723         dnl install uses a shared object for each component and we have
2724         dnl already added all of these objects to LLVM_LIBS.
2725     fi
2726 }
2727
2728 dnl
2729 dnl Set defines and buildtime variables only when using LLVM.
2730 dnl
2731 if test "x$enable_llvm" = xyes; then
2732     DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2733
2734     LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2735     LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
2736     LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2737
2738     dnl Set LLVM_LIBS - This is done after the driver configuration so
2739     dnl that drivers can add additional components to LLVM_COMPONENTS.
2740     dnl Previously, gallium drivers were updating LLVM_LIBS directly
2741     dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2742     dnl this was causing the same libraries to be appear multiple times
2743     dnl in LLVM_LIBS.
2744
2745     if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 9; then
2746         if test "x$enable_llvm_shared_libs" = xyes; then
2747             LLVM_LIBS="`$LLVM_CONFIG --link-shared --libs ${LLVM_COMPONENTS}`"
2748         else
2749             dnl Invoking llvm-config with both -libs and --system-libs produces the
2750             dnl two separate lines - each for the set of libraries.
2751                 dnl Call the program twice, effectively folding them into a single line.
2752             LLVM_LIBS="`$LLVM_CONFIG --link-static --libs ${LLVM_COMPONENTS}`"
2753             dnl We need to link to llvm system libs when using static libs
2754             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --link-static --system-libs`"
2755         fi
2756     else
2757         LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2758         if test "x$enable_llvm_shared_libs" = xyes; then
2759             detect_old_buggy_llvm
2760         else
2761             AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2762             dnl We need to link to llvm system libs when using static libs
2763             dnl However, only llvm 3.5+ provides --system-libs
2764             if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2765                 LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2766             fi
2767         fi
2768     fi
2769 fi
2770
2771 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2772 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2773 AM_CONDITIONAL(HAVE_GALLIUM_PL111, test "x$HAVE_GALLIUM_PL111" = xyes)
2774 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2775 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2776 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2777 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2778 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2779 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2780 AM_CONDITIONAL(HAVE_GALLIUM_ETNAVIV, test "x$HAVE_GALLIUM_ETNAVIV" = xyes)
2781 AM_CONDITIONAL(HAVE_GALLIUM_IMX, test "x$HAVE_GALLIUM_IMX" = xyes)
2782 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2783 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2784 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2785 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2786                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2787                                          "x$HAVE_GALLIUM_SWR" = xyes)
2788 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2789 AM_CONDITIONAL(HAVE_GALLIUM_VC5, test "x$HAVE_GALLIUM_VC5" = xyes)
2790 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2791
2792 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2793
2794 if test "x$enable_dri" = xyes; then
2795     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2796 fi
2797
2798 if test "x$have_drisw_kms" = xyes; then
2799     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2800 fi
2801 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2802
2803 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2804 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2805 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2806 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2807 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2808 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2809
2810 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2811 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2812
2813 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2814                                       "x$HAVE_RADEON_VULKAN" = xyes)
2815
2816 AM_CONDITIONAL(HAVE_BROADCOM_DRIVERS, test "x$HAVE_GALLIUM_VC4" = xyes -o \
2817                                       "x$HAVE_GALLIUM_VC5" = xyes)
2818
2819 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2820                                         "x$HAVE_I965_DRI" = xyes)
2821
2822 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2823                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2824                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2825 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2826 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2827 AM_CONDITIONAL(HAVE_GALLIUM_LLVM, test "x$enable_llvm" = xyes)
2828 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2829 AM_CONDITIONAL(USE_VC5_SIMULATOR, test x$USE_VC5_SIMULATOR = xyes)
2830
2831 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2832 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2833 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2834 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
2835                                         "x$enable_gallium_osmesa" = xyes)
2836
2837 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2838 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2839 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2840 AM_CONDITIONAL(HAVE_PPC64LE_ASM, test "x$asm_arch" = xppc64le)
2841 AM_CONDITIONAL(HAVE_AARCH64_ASM, test "x$asm_arch" = xaarch64)
2842 AM_CONDITIONAL(HAVE_ARM_ASM, test "x$asm_arch" = xarm)
2843
2844 AC_SUBST([NINE_MAJOR], 1)
2845 AC_SUBST([NINE_MINOR], 0)
2846 AC_SUBST([NINE_TINY], 0)
2847 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2848
2849 AC_SUBST([VDPAU_MAJOR], 1)
2850 AC_SUBST([VDPAU_MINOR], 0)
2851
2852 if test "x$enable_va" = xyes; then
2853     VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2854     VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2855 fi
2856 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2857 AC_SUBST([VA_MINOR], $VA_MINOR)
2858
2859 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
2860
2861 AC_SUBST([XVMC_MAJOR], 1)
2862 AC_SUBST([XVMC_MINOR], 0)
2863
2864 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2865 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2866 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2867 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2868
2869 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2870 AC_SUBST([XA_MINOR], $XA_MINOR)
2871 AC_SUBST([XA_TINY], $XA_TINY)
2872 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2873
2874 AC_ARG_ENABLE(valgrind,
2875               [AS_HELP_STRING([--enable-valgrind],
2876                              [Build mesa with valgrind support (default: auto)])],
2877                              [VALGRIND=$enableval], [VALGRIND=auto])
2878 if test "x$VALGRIND" != xno; then
2879     PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2880 fi
2881 AC_MSG_CHECKING([whether to enable Valgrind support])
2882 if test "x$VALGRIND" = xauto; then
2883     VALGRIND="$have_valgrind"
2884 fi
2885
2886 if test "x$VALGRIND" = "xyes"; then
2887     if ! test "x$have_valgrind" = xyes; then
2888         AC_MSG_ERROR([Valgrind support required but not present])
2889     fi
2890     AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2891 fi
2892
2893 AC_MSG_RESULT([$VALGRIND])
2894
2895 dnl Restore LDFLAGS and CPPFLAGS
2896 LDFLAGS="$_SAVE_LDFLAGS"
2897 CPPFLAGS="$_SAVE_CPPFLAGS"
2898
2899 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2900 if test "x$acv_mesa_CLANG" = xyes; then
2901     CFLAGS="$CFLAGS -Qunused-arguments"
2902     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2903 fi
2904
2905 dnl Add user CFLAGS and CXXFLAGS
2906 CFLAGS="$CFLAGS $USER_CFLAGS"
2907 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2908
2909 dnl Substitute the config
2910 AC_CONFIG_FILES([Makefile
2911                  src/Makefile
2912                  src/amd/Makefile
2913                  src/amd/vulkan/Makefile
2914                  src/broadcom/Makefile
2915                  src/compiler/Makefile
2916                  src/egl/Makefile
2917                  src/egl/main/egl.pc
2918                  src/egl/wayland/wayland-drm/Makefile
2919                  src/egl/wayland/wayland-egl/Makefile
2920                  src/egl/wayland/wayland-egl/wayland-egl.pc
2921                  src/gallium/Makefile
2922                  src/gallium/auxiliary/Makefile
2923                  src/gallium/auxiliary/pipe-loader/Makefile
2924                  src/gallium/drivers/freedreno/Makefile
2925                  src/gallium/drivers/ddebug/Makefile
2926                  src/gallium/drivers/i915/Makefile
2927                  src/gallium/drivers/llvmpipe/Makefile
2928                  src/gallium/drivers/noop/Makefile
2929                  src/gallium/drivers/nouveau/Makefile
2930                  src/gallium/drivers/pl111/Makefile
2931                  src/gallium/drivers/r300/Makefile
2932                  src/gallium/drivers/r600/Makefile
2933                  src/gallium/drivers/radeon/Makefile
2934                  src/gallium/drivers/radeonsi/Makefile
2935                  src/gallium/drivers/rbug/Makefile
2936                  src/gallium/drivers/softpipe/Makefile
2937                  src/gallium/drivers/svga/Makefile
2938                  src/gallium/drivers/swr/Makefile
2939                  src/gallium/drivers/trace/Makefile
2940                  src/gallium/drivers/etnaviv/Makefile
2941                  src/gallium/drivers/imx/Makefile
2942                  src/gallium/drivers/vc4/Makefile
2943                  src/gallium/drivers/vc5/Makefile
2944                  src/gallium/drivers/virgl/Makefile
2945                  src/gallium/state_trackers/clover/Makefile
2946                  src/gallium/state_trackers/dri/Makefile
2947                  src/gallium/state_trackers/glx/xlib/Makefile
2948                  src/gallium/state_trackers/nine/Makefile
2949                  src/gallium/state_trackers/omx_bellagio/Makefile
2950                  src/gallium/state_trackers/osmesa/Makefile
2951                  src/gallium/state_trackers/va/Makefile
2952                  src/gallium/state_trackers/vdpau/Makefile
2953                  src/gallium/state_trackers/xa/Makefile
2954                  src/gallium/state_trackers/xvmc/Makefile
2955                  src/gallium/targets/d3dadapter9/Makefile
2956                  src/gallium/targets/d3dadapter9/d3d.pc
2957                  src/gallium/targets/dri/Makefile
2958                  src/gallium/targets/libgl-xlib/Makefile
2959                  src/gallium/targets/omx-bellagio/Makefile
2960                  src/gallium/targets/opencl/Makefile
2961                  src/gallium/targets/opencl/mesa.icd
2962                  src/gallium/targets/osmesa/Makefile
2963                  src/gallium/targets/osmesa/osmesa.pc
2964                  src/gallium/targets/pipe-loader/Makefile
2965                  src/gallium/targets/va/Makefile
2966                  src/gallium/targets/vdpau/Makefile
2967                  src/gallium/targets/xa/Makefile
2968                  src/gallium/targets/xa/xatracker.pc
2969                  src/gallium/targets/xvmc/Makefile
2970                  src/gallium/tests/trivial/Makefile
2971                  src/gallium/tests/unit/Makefile
2972                  src/gallium/winsys/etnaviv/drm/Makefile
2973                  src/gallium/winsys/imx/drm/Makefile
2974                  src/gallium/winsys/freedreno/drm/Makefile
2975                  src/gallium/winsys/i915/drm/Makefile
2976                  src/gallium/winsys/nouveau/drm/Makefile
2977                  src/gallium/winsys/pl111/drm/Makefile
2978                  src/gallium/winsys/radeon/drm/Makefile
2979                  src/gallium/winsys/amdgpu/drm/Makefile
2980                  src/gallium/winsys/svga/drm/Makefile
2981                  src/gallium/winsys/sw/dri/Makefile
2982                  src/gallium/winsys/sw/kms-dri/Makefile
2983                  src/gallium/winsys/sw/null/Makefile
2984                  src/gallium/winsys/sw/wrapper/Makefile
2985                  src/gallium/winsys/sw/xlib/Makefile
2986                  src/gallium/winsys/vc4/drm/Makefile
2987                  src/gallium/winsys/vc5/drm/Makefile
2988                  src/gallium/winsys/virgl/drm/Makefile
2989                  src/gallium/winsys/virgl/vtest/Makefile
2990                  src/gbm/Makefile
2991                  src/gbm/main/gbm.pc
2992                  src/glx/Makefile
2993                  src/glx/apple/Makefile
2994                  src/glx/tests/Makefile
2995                  src/glx/windows/Makefile
2996                  src/glx/windows/windowsdriproto.pc
2997                  src/gtest/Makefile
2998                  src/intel/Makefile
2999                  src/loader/Makefile
3000                  src/mapi/Makefile
3001                  src/mapi/es1api/glesv1_cm.pc
3002                  src/mapi/es2api/glesv2.pc
3003                  src/mapi/glapi/gen/Makefile
3004                  src/mesa/Makefile
3005                  src/mesa/gl.pc
3006                  src/mesa/drivers/dri/dri.pc
3007                  src/mesa/drivers/dri/common/Makefile
3008                  src/mesa/drivers/dri/i915/Makefile
3009                  src/mesa/drivers/dri/i965/Makefile
3010                  src/mesa/drivers/dri/Makefile
3011                  src/mesa/drivers/dri/nouveau/Makefile
3012                  src/mesa/drivers/dri/r200/Makefile
3013                  src/mesa/drivers/dri/radeon/Makefile
3014                  src/mesa/drivers/dri/swrast/Makefile
3015                  src/mesa/drivers/osmesa/Makefile
3016                  src/mesa/drivers/osmesa/osmesa.pc
3017                  src/mesa/drivers/x11/Makefile
3018                  src/mesa/main/tests/Makefile
3019                  src/mesa/state_tracker/tests/Makefile
3020                  src/util/Makefile
3021                  src/util/tests/hash_table/Makefile
3022                  src/util/tests/string_buffer/Makefile
3023                  src/util/xmlpool/Makefile
3024                  src/vulkan/Makefile])
3025
3026 AC_OUTPUT
3027
3028 # Fix up dependencies in *.Plo files, where we changed the extension of a
3029 # source file
3030 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
3031
3032 rm -f src/compiler/spirv/spirv_info.lo
3033 echo "# dummy" > src/compiler/spirv/.deps/spirv_info.Plo
3034
3035 dnl
3036 dnl Output some configuration info for the user
3037 dnl
3038 echo ""
3039 echo "        prefix:          $prefix"
3040 echo "        exec_prefix:     $exec_prefix"
3041 echo "        libdir:          $libdir"
3042 echo "        includedir:      $includedir"
3043
3044 dnl API info
3045 echo ""
3046 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
3047
3048 dnl Driver info
3049 echo ""
3050 case "x$enable_osmesa$enable_gallium_osmesa" in
3051 xnoyes)
3052         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
3053         ;;
3054 xyesno)
3055         echo "        OSMesa:          lib$OSMESA_LIB"
3056         ;;
3057 xnono)
3058         echo "        OSMesa:          no"
3059         ;;
3060 esac
3061
3062 echo ""
3063 if test "x$enable_dri" != xno; then
3064         echo "        DRI platform:    $dri_platform"
3065         if test -z "$DRI_DIRS"; then
3066             echo "        DRI drivers:     no"
3067         else
3068             echo "        DRI drivers:     $DRI_DIRS"
3069         fi
3070         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
3071 fi
3072
3073 case "x$enable_glx" in
3074 xdri)
3075     echo "        GLX:             DRI-based"
3076     ;;
3077 xxlib)
3078     echo "        GLX:             Xlib-based"
3079     ;;
3080 xgallium-xlib)
3081     echo "        GLX:             Xlib-based (Gallium)"
3082     ;;
3083 *)
3084     echo "        GLX:             $enable_glx"
3085     ;;
3086 esac
3087
3088 dnl EGL
3089 echo ""
3090 echo "        EGL:             $enable_egl"
3091 if test "$enable_egl" = yes; then
3092
3093     egl_drivers=""
3094     if test "x$enable_dri" != "xno"; then
3095         egl_drivers="$egl_drivers builtin:egl_dri2"
3096     fi
3097     if test "x$enable_dri3" != "xno"; then
3098         egl_drivers="$egl_drivers builtin:egl_dri3"
3099     fi
3100
3101     echo "        EGL drivers:    $egl_drivers"
3102 fi
3103 if test "x$enable_gbm" = xyes; then
3104     echo "        GBM:             yes"
3105 else
3106     echo "        GBM:             no"
3107 fi
3108
3109     echo "        EGL/Vulkan/VL platforms:   $platforms"
3110
3111 # Vulkan
3112 echo ""
3113 if test "x$VULKAN_DRIVERS" != x; then
3114     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
3115     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
3116 else
3117     echo "        Vulkan drivers:  no"
3118 fi
3119
3120 echo ""
3121 if test "x$enable_llvm" = xyes; then
3122     echo "        llvm:            yes"
3123     echo "        llvm-config:     $LLVM_CONFIG"
3124     echo "        llvm-version:    $LLVM_VERSION"
3125 else
3126     echo "        llvm:            no"
3127 fi
3128
3129 echo ""
3130 if test -n "$with_gallium_drivers"; then
3131     echo "        Gallium drivers: $gallium_drivers"
3132     echo "        Gallium st:      $gallium_st"
3133 else
3134     echo "        Gallium:         no"
3135 fi
3136
3137 echo ""
3138 if test "x$enable_gallium_extra_hud" != xyes; then
3139     echo "        HUD extra stats: no"
3140 else
3141     echo "        HUD extra stats: yes"
3142 fi
3143
3144 if test "x$enable_lmsensors" != xyes; then
3145     echo "        HUD lmsensors:   no"
3146 else
3147     echo "        HUD lmsensors:   yes"
3148 fi
3149
3150 echo ""
3151 if test "x$HAVE_GALLIUM_SWR" != x; then
3152     echo "        SWR archs:       $swr_archs"
3153 fi
3154
3155 dnl Libraries
3156 echo ""
3157 echo "        Shared libs:     $enable_shared"
3158 echo "        Static libs:     $enable_static"
3159 echo "        Shared-glapi:    $enable_shared_glapi"
3160
3161 dnl Compiler options
3162 # cleanup the CFLAGS/CXXFLAGS/LDFLAGS/DEFINES vars
3163 cflags=`echo $CFLAGS | \
3164     $SED 's/^ *//;s/  */ /;s/ *$//'`
3165 cxxflags=`echo $CXXFLAGS | \
3166     $SED 's/^ *//;s/  */ /;s/ *$//'`
3167 ldflags=`echo $LDFLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
3168 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
3169 echo ""
3170 echo "        CFLAGS:          $cflags"
3171 echo "        CXXFLAGS:        $cxxflags"
3172 echo "        CXX11_CXXFLAGS:  $CXX11_CXXFLAGS"
3173 echo "        LDFLAGS:         $ldflags"
3174 echo "        Macros:          $defines"
3175 echo ""
3176 if test "x$enable_llvm" = xyes; then
3177     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
3178     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
3179     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
3180     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
3181     echo ""
3182 fi
3183 echo "        PYTHON2:         $PYTHON2"
3184
3185 echo ""
3186 echo "        Run '${MAKE-make}' to build Mesa"
3187 echo ""