configure.ac

   1 # intel-driver package version number
   2 m4_define([intel_driver_major_version], [1])
   3 m4_define([intel_driver_minor_version], [4])
   4 m4_define([intel_driver_micro_version], [2])
   5 m4_define([intel_driver_pre_version],   [1])
   6 m4_define([intel_driver_version],
   7           [intel_driver_major_version.intel_driver_minor_version.intel_driver_micro_version])
   8 m4_if(intel_driver_pre_version, [0], [], [
   9 m4_append([intel_driver_version], intel_driver_pre_version, [.pre])
  10 ])
  11
  12 # libva minimum version requirement
  13 m4_define([va_api_version], [0.36])
  14 m4_define([libva_package_version], [1.4.0])
  15
  16 # libdrm minimum version requirement
  17 m4_define([libdrm_version], [2.4.45])
  18
  19 AC_PREREQ([2.57])
  20 AC_INIT([intel_driver], [intel_driver_version], [haihao.xiang@intel.com],
  21         [libva-intel-driver])
  22 AC_CONFIG_SRCDIR([Makefile.am])
  23 AM_INIT_AUTOMAKE([1.9 tar-ustar])
  24
  25 AC_CONFIG_HEADERS([src/config.h])
  26
  27 INTEL_DRIVER_MAJOR_VERSION=intel_driver_major_version
  28 INTEL_DRIVER_MINOR_VERSION=intel_driver_minor_version
  29 INTEL_DRIVER_MICRO_VERSION=intel_driver_micro_version
  30 AC_DEFINE([INTEL_DRIVER_MAJOR_VERSION], [intel_driver_major_version], [Major version of the driver])
  31 AC_DEFINE([INTEL_DRIVER_MINOR_VERSION], [intel_driver_minor_version], [Minor version of the driver])
  32 AC_DEFINE([INTEL_DRIVER_MICRO_VERSION], [intel_driver_micro_version], [Micro version of the driver])
  33 AC_DEFINE([INTEL_DRIVER_PRE_VERSION], [intel_driver_pre_version], [Preversion of the driver])
  34
  35 INTEL_DRIVER_LT_LDFLAGS="-avoid-version"
  36 AC_SUBST(INTEL_DRIVER_LT_LDFLAGS)
  37
  38 dnl Use pretty build output with automake >= 1.11
  39 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [
  40     AM_DEFAULT_VERBOSITY=1
  41     AC_SUBST(AM_DEFAULT_VERBOSITY)
  42 ])
  43
  44 AC_ARG_ENABLE(drm,
  45     [AC_HELP_STRING([--enable-drm],
  46                     [build with VA/DRM API support @<:@default=yes@:>@])],
  47     [], [enable_drm="yes"])
  48
  49 AC_ARG_ENABLE(x11,
  50     [AC_HELP_STRING([--enable-x11],
  51                     [build with VA/X11 API support @<:@default=yes@:>@])],
  52     [], [enable_x11="yes"])
  53
  54 AC_ARG_ENABLE([wayland],
  55     [AC_HELP_STRING([--enable-wayland],
  56                     [build with VA/Wayland API support @<:@default=yes@:>@])],
  57     [], [enable_wayland="yes"])
  58
  59 AC_DISABLE_STATIC
  60 AC_PROG_LIBTOOL
  61 AC_PROG_CC
  62 AM_PROG_CC_C_O
  63
  64 AC_C_BIGENDIAN
  65 AC_HEADER_STDC
  66 AC_SYS_LARGEFILE
  67 AC_CHECK_LIB([m], [sin])
  68 AC_CHECK_FUNCS([log2f])
  69 AC_CHECK_PROGS([PYTHON2], [python2 python])
  70
  71 LIBVA_PACKAGE_VERSION=libva_package_version
  72 AC_SUBST(LIBVA_PACKAGE_VERSION)
  73
  74 dnl Check for recent enough DRM
  75 LIBDRM_VERSION=libdrm_version
  76 PKG_CHECK_MODULES([DRM], [libdrm >= $LIBDRM_VERSION])
  77 AC_SUBST(LIBDRM_VERSION)
  78
  79 dnl Check for gen4asm
  80 PKG_CHECK_MODULES(GEN4ASM, [intel-gen4asm >= 1.5], [gen4asm=yes], [gen4asm=no])
  81 AM_CONDITIONAL(HAVE_GEN4ASM, test x$gen4asm = xyes)
  82 AC_PATH_PROG([GEN4ASM], [intel-gen4asm])
  83
  84 dnl Check for git
  85 AC_ARG_VAR([GIT], [Path to git program, if any])
  86 AC_PATH_PROG([GIT], [git])
  87 AM_CONDITIONAL([HAVE_GIT], [test -n "$GIT"])
  88
  89 dnl Check for VA-API
  90 PKG_CHECK_MODULES(LIBVA_DEPS,     [libva >= va_api_version])
  91
  92 dnl Check for VA/DRM API
  93 USE_DRM="$enable_drm"
  94 if test "$USE_DRM" = "yes"; then
  95     PKG_CHECK_MODULES(LIBVA_DRM_DEPS, [libva-drm],
  96       [AC_DEFINE([HAVE_VA_DRM], [1], [Defined to 1 if VA/DRM API is enabled])],
  97       [USE_DRM="no"])
  98
  99     # Check for <drm_fourcc.h>
 100     if test "$USE_DRM" = "yes"; then
 101         saved_CPPFLAGS="$CPPFLAGS"
 102         CPPFLAGS="$CPPFLAGS $DRM_CFLAGS"
 103         AC_CHECK_HEADERS([drm_fourcc.h], [:], [USE_DRM="no"])
 104         CPPFLAGS="$saved_CPPFLAGS"
 105     fi
 106 fi
 107 AM_CONDITIONAL(USE_DRM, test "$USE_DRM" = "yes")
 108
 109 VA_VERSION=`$PKG_CONFIG --modversion libva`
 110 VA_MAJOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f1`
 111 VA_MINOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f2`
 112 VA_MICRO_VERSION=`echo "$VA_VERSION" | cut -d'.' -f3`
 113 VA_VERSION_STR="$VA_VERSION"
 114
 115 va_full_version_int=`expr ${VA_MAJOR_VERSION:-0} "*" 1000000 + \
 116                           ${VA_MINOR_VERSION:-0} "*" 10000   + \
 117                           ${VA_MICRO_VERSION:-0} "*" 100     + \
 118                           0`
 119 VA_DRIVER_INIT_FUNC="__vaDriverInit_${VA_MAJOR_VERSION}_${VA_MINOR_VERSION}"
 120 AC_DEFINE_UNQUOTED([VA_DRIVER_INIT_FUNC], [$VA_DRIVER_INIT_FUNC],
 121     [Define driver entry-point])
 122
 123 dnl Check for VA/DRM API
 124 USE_X11="$enable_x11"
 125 if test "$USE_X11" = "yes"; then
 126     PKG_CHECK_MODULES(LIBVA_X11_DEPS, [libva-x11],
 127       [AC_DEFINE([HAVE_VA_X11], [1], [Defined to 1 if VA/X11 API is enabled])],
 128       [USE_X11="no"])
 129 fi
 130 AM_CONDITIONAL(USE_X11, test "$USE_X11" = "yes")
 131
 132 dnl Check for VA-API drivers path
 133 AC_MSG_CHECKING([for VA drivers path])
 134 LIBVA_DRIVERS_PATH=`$PKG_CONFIG libva --variable driverdir`
 135 if test -z "$LIBVA_DRIVERS_PATH"; then
 136     LIBVA_DRIVERS_PATH="${libdir}/xorg/modules/drivers"
 137 fi
 138 AC_MSG_RESULT([$LIBVA_DRIVERS_PATH])
 139 AC_SUBST(LIBVA_DRIVERS_PATH)
 140
 141 # Check for EGL
 142 if test "$enable_wayland" = "yes"; then
 143     enable_egl="yes"
 144 fi
 145
 146 USE_EGL="no"
 147 if test "$enable_egl" = "yes"; then
 148     PKG_CHECK_MODULES([EGL], [egl], [USE_EGL="yes"], [USE_EGL="no"])
 149     saved_CPPFLAGS="$CPPFLAGS"
 150     saved_LIBS="$LIBS"
 151     CPPFLAGS="$CPPFLAGS $EGL_CFLAGS"
 152     LIBS="$LIBS $EGL_LIBS"
 153     AC_CHECK_HEADERS([EGL/egl.h], [:], [USE_EGL="no"])
 154     AC_CHECK_LIB([EGL], [eglGetDisplay], [:], [USE_EGL="no"])
 155     CPPFLAGS="$saved_CPPFLAGS"
 156     LIBS="$saved_LIBS"
 157 fi
 158 AM_CONDITIONAL(USE_EGL, test "$USE_EGL" = "yes")
 159
 160 # Check for Wayland
 161 USE_WAYLAND="no"
 162 if test "$enable_wayland" = "yes"; then
 163     PKG_CHECK_MODULES([WAYLAND], [wayland-client], [USE_WAYLAND="yes"], [:])
 164     PKG_CHECK_MODULES([LIBVA_WAYLAND_DEPS], [libva-wayland],
 165         [AC_DEFINE([HAVE_VA_WAYLAND], [1], [Defined to 1 if VA/Wayland API is enabled])],
 166         [USE_WAYLAND="no"])
 167 fi
 168 AM_CONDITIONAL(USE_WAYLAND, test "$USE_WAYLAND" = "yes")
 169
 170 m4_ifdef([WAYLAND_SCANNER_RULES],
 171     [WAYLAND_SCANNER_RULES(['$(top_builddir)/src/wayland'])],
 172     [wayland_scanner_rules=""; AC_SUBST(wayland_scanner_rules)])
 173
 174 AC_OUTPUT([
 175     Makefile
 176     debian.upstream/Makefile
 177     src/Makefile
 178     src/shaders/Makefile
 179     src/shaders/h264/Makefile
 180     src/shaders/h264/ildb/Makefile
 181     src/shaders/h264/mc/Makefile
 182     src/shaders/mpeg2/Makefile
 183     src/shaders/mpeg2/vld/Makefile
 184     src/shaders/post_processing/Makefile
 185     src/shaders/post_processing/gen5_6/Makefile
 186     src/shaders/post_processing/gen7/Makefile
 187     src/shaders/post_processing/gen75/Makefile
 188     src/shaders/post_processing/gen8/Makefile
 189     src/shaders/post_processing/gen9/Makefile
 190     src/shaders/render/Makefile
 191     src/shaders/utils/Makefile
 192     src/shaders/vme/Makefile
 193     src/wayland/Makefile
 194 ])
 195
 196 dnl Print summary
 197 BACKENDS=""
 198 AS_IF([test "$USE_DRM" = "yes"], [BACKENDS="$BACKENDS drm"])
 199 AS_IF([test "$USE_X11" = "yes"], [BACKENDS="$BACKENDS x11"])
 200 AS_IF([test "$USE_WAYLAND" = "yes"], [BACKENDS="$BACKENDS wayland"])
 201
 202 echo
 203 echo $PACKAGE configuration summary:
 204 echo
 205 echo VA-API version ................... : $VA_VERSION_STR
 206 echo VA-API drivers path .............. : $LIBVA_DRIVERS_PATH
 207 echo Windowing systems ................ : $BACKENDS
 208 echo