configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl
  13 dnl Permission is hereby granted, free of charge, to any person obtaining a
  14 dnl copy of this software and associated documentation files (the "Software"),
  15 dnl to deal in the Software without restriction, including without limitation
  16 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  17 dnl and/or sell copies of the Software, and to permit persons to whom the
  18 dnl Software is furnished to do so, subject to the following conditions:
  19 dnl
  20 dnl The above copyright notice and this permission notice (including the next
  21 dnl paragraph) shall be included in all copies or substantial portions of the
  22 dnl Software.
  23 dnl
  24 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  25 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  26 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  27 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  28 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  29 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  30 dnl DEALINGS IN THE SOFTWARE.
  31 dnl
  32 dnl Process this file with autoconf to create configure.
  33
  34 AC_PREREQ([2.60])
  35
  36 dnl Tell the user about autoconf.html in the --help output
  37 m4_divert_once([HELP_END], [
  38 See docs/autoconf.html for more details on the options for Mesa.])
  39
  40 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  41 AC_INIT([Mesa], [MESA_VERSION],
  42     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  43 AC_CONFIG_AUX_DIR([bin])
  44 AC_CONFIG_MACRO_DIR([m4])
  45 AC_CANONICAL_SYSTEM
  46 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  47
  48 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  49 case "$host_os" in
  50 mingw*)
  51     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  52     ;;
  53 esac
  54
  55 # Support silent build rules, requires at least automake-1.11. Disable
  56 # by either passing --disable-silent-rules to configure or passing V=1
  57 # to make
  58 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  59     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  60
  61 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  62
  63 dnl Set internal versions
  64 OSMESA_VERSION=8
  65 AC_SUBST([OSMESA_VERSION])
  66 OPENCL_VERSION=1
  67 AC_SUBST([OPENCL_VERSION])
  68
  69 # The idea is that libdrm is distributed as one cohesive package, even
  70 # though it is composed of multiple libraries. However some drivers
  71 # may have different version requirements than others. This list
  72 # codifies which drivers need which version of libdrm. Any libdrm
  73 # version dependencies in non-driver-specific code should be reflected
  74 # in the first entry.
  75 LIBDRM_REQUIRED=2.4.75
  76 LIBDRM_RADEON_REQUIRED=2.4.71
  77 LIBDRM_AMDGPU_REQUIRED=2.4.91
  78 LIBDRM_INTEL_REQUIRED=2.4.75
  79 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  80 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  81 LIBDRM_FREEDRENO_REQUIRED=2.4.92
  82 LIBDRM_ETNAVIV_REQUIRED=2.4.89
  83
  84 dnl Versions for external dependencies
  85 DRI2PROTO_REQUIRED=2.8
  86 GLPROTO_REQUIRED=1.4.14
  87 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  88 LIBOMXIL_TIZONIA_REQUIRED=0.10.0
  89 LIBVA_REQUIRED=0.39.0
  90 VDPAU_REQUIRED=1.1
  91 WAYLAND_REQUIRED=1.11
  92 WAYLAND_PROTOCOLS_REQUIRED=1.8
  93 XCB_REQUIRED=1.9.3
  94 XCBDRI2_REQUIRED=1.8
  95 XCBDRI3_MODIFIERS_REQUIRED=1.13
  96 XCBGLX_REQUIRED=1.8.1
  97 XCBPRESENT_MODIFIERS_REQUIRED=1.13
  98 XDAMAGE_REQUIRED=1.1
  99 XSHMFENCE_REQUIRED=1.1
 100 XVMC_REQUIRED=1.0.6
 101 PYTHON_MAKO_REQUIRED=0.8.0
 102 LIBSENSORS_REQUIRED=4.0.0
 103 ZLIB_REQUIRED=1.2.3
 104
 105 dnl LLVM versions
 106 LLVM_REQUIRED_GALLIUM=3.3.0
 107 LLVM_REQUIRED_OPENCL=3.9.0
 108 LLVM_REQUIRED_R600=3.9.0
 109 LLVM_REQUIRED_RADEONSI=4.0.0
 110 LLVM_REQUIRED_RADV=4.0.0
 111 LLVM_REQUIRED_SWR=4.0.0
 112
 113 dnl Check for progs
 114 AC_PROG_CPP
 115 AC_PROG_CC
 116 AC_PROG_CXX
 117 dnl add this here, so the help for this environmnet variable is close to
 118 dnl other CC/CXX flags related help
 119 AC_ARG_VAR([CXX11_CXXFLAGS], [Compiler flag to enable C++11 support (only needed if not
 120                               enabled by default and different  from -std=c++11)])
 121 AM_PROG_CC_C_O
 122 AC_PROG_GREP
 123 AC_PROG_NM
 124 AM_PROG_AS
 125 AX_CHECK_GNU_MAKE
 126 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 127 AC_PROG_SED
 128 AC_PROG_MKDIR_P
 129
 130 AC_SYS_LARGEFILE
 131
 132
 133 LT_PREREQ([2.2])
 134 LT_INIT([disable-static])
 135
 136 AC_CHECK_PROG(RM, rm, [rm -f])
 137
 138 AX_PROG_BISON([],
 139               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 140                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 141 AX_PROG_FLEX([],
 142              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 143                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 144
 145 AC_CHECK_PROG(INDENT, indent, indent, cat)
 146 if test "x$INDENT" != "xcat"; then
 147     # Only GNU indent is supported
 148     INDENT_VERSION=`indent --version | grep GNU`
 149     if test $? -eq 0; then
 150        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 151     else
 152        INDENT="cat"
 153     fi
 154 fi
 155
 156 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 157
 158 if test -z "$PYTHON2"; then
 159     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 160         AC_MSG_ERROR([Python not found - unable to generate sources])
 161     fi
 162 else
 163     if test "x$acv_mako_found" = xno; then
 164         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 165             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 166         fi
 167     fi
 168 fi
 169
 170 AC_PROG_INSTALL
 171
 172 dnl We need a POSIX shell for parts of the build. Assume we have one
 173 dnl in most cases.
 174 case "$host_os" in
 175 solaris*)
 176     # Solaris /bin/sh is too old/non-POSIX compliant
 177     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 178     SHELL="$POSIX_SHELL"
 179     ;;
 180 esac
 181
 182 dnl clang is mostly GCC-compatible, but its version is much lower,
 183 dnl so we have to check for it.
 184 AC_MSG_CHECKING([if compiling with clang])
 185
 186 AC_COMPILE_IFELSE(
 187 [AC_LANG_PROGRAM([], [[
 188 #ifndef __clang__
 189        not clang
 190 #endif
 191 ]])],
 192 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 193
 194 AC_MSG_RESULT([$acv_mesa_CLANG])
 195
 196 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 197 dnl versions are explictly not supported.
 198 GEN_ASM_OFFSETS=no
 199 USE_GNU99=no
 200 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 201     AC_MSG_CHECKING([whether gcc version is sufficient])
 202     major=0
 203     minor=0
 204
 205     GCC_VERSION=`$CC -dumpversion`
 206     if test $? -eq 0; then
 207         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 208         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 209     fi
 210
 211     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 212         AC_MSG_RESULT([no])
 213         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 214     else
 215         AC_MSG_RESULT([yes])
 216     fi
 217
 218     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 219         USE_GNU99=yes
 220     fi
 221     if test "x$cross_compiling" = xyes; then
 222         GEN_ASM_OFFSETS=yes
 223     fi
 224 fi
 225
 226 dnl We don't support building Mesa with Sun C compiler
 227 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 228 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 229 if test "x$SUNCC" = xyes; then
 230     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 231 fi
 232
 233 dnl Check for compiler builtins
 234 AX_GCC_BUILTIN([__builtin_bswap32])
 235 AX_GCC_BUILTIN([__builtin_bswap64])
 236 AX_GCC_BUILTIN([__builtin_clz])
 237 AX_GCC_BUILTIN([__builtin_clzll])
 238 AX_GCC_BUILTIN([__builtin_ctz])
 239 AX_GCC_BUILTIN([__builtin_expect])
 240 AX_GCC_BUILTIN([__builtin_ffs])
 241 AX_GCC_BUILTIN([__builtin_ffsll])
 242 AX_GCC_BUILTIN([__builtin_popcount])
 243 AX_GCC_BUILTIN([__builtin_popcountll])
 244 AX_GCC_BUILTIN([__builtin_unreachable])
 245
 246 AX_GCC_FUNC_ATTRIBUTE([const])
 247 AX_GCC_FUNC_ATTRIBUTE([flatten])
 248 AX_GCC_FUNC_ATTRIBUTE([format])
 249 AX_GCC_FUNC_ATTRIBUTE([malloc])
 250 AX_GCC_FUNC_ATTRIBUTE([packed])
 251 AX_GCC_FUNC_ATTRIBUTE([pure])
 252 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 253 AX_GCC_FUNC_ATTRIBUTE([unused])
 254 AX_GCC_FUNC_ATTRIBUTE([visibility])
 255 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 256 AX_GCC_FUNC_ATTRIBUTE([weak])
 257 AX_GCC_FUNC_ATTRIBUTE([alias])
 258 AX_GCC_FUNC_ATTRIBUTE([noreturn])
 259
 260 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 261
 262 dnl Make sure the pkg-config macros are defined
 263 m4_ifndef([PKG_PROG_PKG_CONFIG],
 264     [m4_fatal([Could not locate the pkg-config autoconf macros.
 265   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 266   are in a different location, try setting the environment variable
 267   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 268 PKG_PROG_PKG_CONFIG()
 269
 270 dnl LIB_DIR - library basename
 271 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 272 AC_SUBST([LIB_DIR])
 273
 274 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 275 _SAVE_LDFLAGS="$LDFLAGS"
 276 _SAVE_CPPFLAGS="$CPPFLAGS"
 277
 278 dnl Compiler macros
 279 DEFINES="-D__STDC_CONSTANT_MACROS -D__STDC_FORMAT_MACROS -D__STDC_LIMIT_MACROS"
 280 AC_SUBST([DEFINES])
 281 android=no
 282 case "$host_os" in
 283 *-android*)
 284     android=yes
 285     ;;
 286 linux*|*-gnu*|gnu*|cygwin*)
 287     DEFINES="$DEFINES -D_GNU_SOURCE"
 288     ;;
 289 solaris*)
 290     DEFINES="$DEFINES -DSVR4"
 291     ;;
 292 esac
 293
 294 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 295
 296 dnl
 297 dnl Check compiler flags
 298 dnl
 299 AX_CHECK_COMPILE_FLAG([-Wall],                                 [CFLAGS="$CFLAGS -Wall"])
 300 AX_CHECK_COMPILE_FLAG([-Werror=implicit-function-declaration], [CFLAGS="$CFLAGS -Werror=implicit-function-declaration"])
 301 AX_CHECK_COMPILE_FLAG([-Werror=missing-prototypes],            [CFLAGS="$CFLAGS -Werror=missing-prototypes"])
 302 AX_CHECK_COMPILE_FLAG([-Wmissing-prototypes],                  [CFLAGS="$CFLAGS -Wmissing-prototypes"])
 303 AX_CHECK_COMPILE_FLAG([-fno-math-errno],                       [CFLAGS="$CFLAGS -fno-math-errno"])
 304 AX_CHECK_COMPILE_FLAG([-fno-trapping-math],                    [CFLAGS="$CFLAGS -fno-trapping-math"])
 305 AX_CHECK_COMPILE_FLAG([-fvisibility=hidden],                   [VISIBILITY_CFLAGS="-fvisibility=hidden"])
 306
 307 dnl
 308 dnl Check C++ compiler flags
 309 dnl
 310 AC_LANG_PUSH([C++])
 311 AX_CHECK_COMPILE_FLAG([-Wall],                                 [CXXFLAGS="$CXXFLAGS -Wall"])
 312 AX_CHECK_COMPILE_FLAG([-fno-math-errno],                       [CXXFLAGS="$CXXFLAGS -fno-math-errno"])
 313 AX_CHECK_COMPILE_FLAG([-fno-trapping-math],                    [CXXFLAGS="$CXXFLAGS -fno-trapping-math"])
 314 AX_CHECK_COMPILE_FLAG([-fvisibility=hidden],                   [VISIBILITY_CXXFLAGS="-fvisibility=hidden"])
 315 AC_LANG_POP([C++])
 316
 317 # Flags to help ensure that certain portions of the code -- and only those
 318 # portions -- can be built with MSVC:
 319 # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 320 # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 321 #   supports most of C99)
 322 # - the rest has no compiler compiler restrictions
 323 AX_CHECK_COMPILE_FLAG([-Werror=pointer-arith],                 [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=pointer-arith"])
 324 AX_CHECK_COMPILE_FLAG([-Werror=vla],                           [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla"])
 325 AC_LANG_PUSH([C++])
 326 AX_CHECK_COMPILE_FLAG([-Werror=pointer-arith],                 [MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=pointer-arith"])
 327 AX_CHECK_COMPILE_FLAG([-Werror=vla],                           [MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla"])
 328 AC_LANG_POP([C++])
 329
 330 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 331 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 332
 333 if test "x$GCC" = xyes; then
 334     if test "x$USE_GNU99" = xyes; then
 335         CFLAGS="$CFLAGS -std=gnu99"
 336     else
 337         CFLAGS="$CFLAGS -std=c99"
 338     fi
 339 fi
 340
 341 dnl
 342 dnl Check whether C++11 is supported, if the environment variable
 343 dnl CXX11_CXXFLAGS is set it takes precedence.
 344 dnl
 345
 346 AC_LANG_PUSH([C++])
 347
 348 check_cxx11_available() {
 349     output_support=$1
 350     AC_COMPILE_IFELSE(
 351         [AC_LANG_PROGRAM([
 352              #if !(__cplusplus >= 201103L)
 353              #error
 354              #endif
 355              #include <tuple>
 356         ])
 357     ], [
 358          AC_MSG_RESULT(yes)
 359          cxx11_support=yes
 360     ], AC_MSG_RESULT(no))
 361     eval "$output_support=\$cxx11_support"
 362 }
 363
 364 HAVE_CXX11=no
 365 save_CXXFLAGS="$CXXFLAGS"
 366
 367 dnl If the user provides a flag to enable c++11, then we test only this
 368 if test "x$CXX11_CXXFLAGS" != "x"; then
 369    CXXFLAGS="$CXXFLAGS $CXX11_CXXFLAGS"
 370    AC_MSG_CHECKING(whether c++11 is enabled by via $CXX11_CXXFLAGS)
 371    check_cxx11_available HAVE_CXX11
 372 else
 373    dnl test whether c++11 is enabled by default
 374    AC_MSG_CHECKING(whether c++11 is enabled by default)
 375    check_cxx11_available HAVE_CXX11
 376
 377    dnl C++11 not enabled by default, test whether -std=c++11 does the job
 378    if test "x$HAVE_CXX11" != "xyes"; then
 379        CXX11_CXXFLAGS=-std=c++11
 380        CXXFLAGS="$CXXFLAGS $CXX11_CXXFLAGS"
 381        AC_MSG_CHECKING(whether c++11 is enabled by via $CXX11_CXXFLAGS)
 382        check_cxx11_available HAVE_CXX11
 383    fi
 384 fi
 385
 386 CXXFLAGS="$save_CXXFLAGS"
 387 AM_CONDITIONAL(HAVE_STD_CXX11, test "x$HAVE_CXX11" = "xyes")
 388 AC_SUBST(CXX11_CXXFLAGS)
 389 AC_LANG_POP([C++])
 390
 391 dnl even if the compiler appears to support it, using visibility attributes isn't
 392 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 393 case "$host_os" in
 394 cygwin*)
 395     VISIBILITY_CFLAGS=""
 396     VISIBILITY_CXXFLAGS=""
 397     ;;
 398 esac
 399
 400 AC_SUBST([VISIBILITY_CFLAGS])
 401 AC_SUBST([VISIBILITY_CXXFLAGS])
 402
 403 dnl For some reason, the test for -Wno-foo always succeeds with gcc, even if the
 404 dnl option is not supported. Hence, check for -Wfoo instead.
 405 AX_CHECK_COMPILE_FLAG([-Woverride-init],                    [WNO_OVERRIDE_INIT="$WNO_OVERRIDE_INIT -Wno-override-init"])         # gcc
 406 AX_CHECK_COMPILE_FLAG([-Winitializer-overrides],            [WNO_OVERRIDE_INIT="$WNO_OVERRIDE_INIT -Wno-initializer-overrides"]) # clang
 407 AC_SUBST([WNO_OVERRIDE_INIT])
 408
 409 dnl
 410 dnl Optional flags, check for compiler support
 411 dnl
 412 SSE41_CFLAGS="-msse4.1"
 413 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 414 dnl stack, but on x86-32 such alignment is not guaranteed.
 415 case "$target_cpu" in
 416 i?86)
 417     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 418     ;;
 419 esac
 420 save_CFLAGS="$CFLAGS"
 421 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 422 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 423 #include <smmintrin.h>
 424 int param;
 425 int main () {
 426     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 427     c = _mm_max_epu32(a, b);
 428     return _mm_cvtsi128_si32(c);
 429 }]])], SSE41_SUPPORTED=1)
 430 CFLAGS="$save_CFLAGS"
 431 if test "x$SSE41_SUPPORTED" = x1; then
 432     DEFINES="$DEFINES -DUSE_SSE41"
 433 fi
 434 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 435 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 436
 437 dnl Check for new-style atomic builtins. We first check without linking to
 438 dnl -latomic.
 439 AC_MSG_CHECKING(whether __atomic_load_n is supported)
 440 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 441 #include <stdint.h>
 442 int main() {
 443     struct {
 444         uint64_t *v;
 445     } x;
 446     return (int)__atomic_load_n(x.v, __ATOMIC_ACQUIRE);
 447 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=yes, GCC_ATOMIC_BUILTINS_SUPPORTED=no)
 448
 449 dnl If that didn't work, we try linking with -latomic, which is needed on some
 450 dnl platforms.
 451 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" != xyes; then
 452    save_LDFLAGS=$LDFLAGS
 453    LDFLAGS="$LDFLAGS -latomic"
 454    AC_LINK_IFELSE([AC_LANG_SOURCE([[
 455    #include <stdint.h>
 456    int main() {
 457         struct {
 458             uint64_t *v;
 459         } x;
 460         return (int)__atomic_load_n(x.v, __ATOMIC_ACQUIRE);
 461    }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=yes LIBATOMIC_LIBS="-latomic",
 462           GCC_ATOMIC_BUILTINS_SUPPORTED=no)
 463    LDFLAGS=$save_LDFLAGS
 464 fi
 465 AC_MSG_RESULT($GCC_ATOMIC_BUILTINS_SUPPORTED)
 466
 467 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = xyes; then
 468     DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
 469 fi
 470 AC_SUBST([LIBATOMIC_LIBS])
 471
 472 dnl Check if host supports 64-bit atomics
 473 dnl note that lack of support usually results in link (not compile) error
 474 AC_MSG_CHECKING(whether __sync_add_and_fetch_8 is supported)
 475 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 476 #include <stdint.h>
 477 uint64_t v;
 478 int main() {
 479     return __sync_add_and_fetch(&v, (uint64_t)1);
 480 }]])], GCC_64BIT_ATOMICS_SUPPORTED=yes, GCC_64BIT_ATOMICS_SUPPORTED=no)
 481 if test "x$GCC_64BIT_ATOMICS_SUPPORTED" != xyes; then
 482     DEFINES="$DEFINES -DMISSING_64BIT_ATOMICS"
 483 fi
 484 AC_MSG_RESULT($GCC_64BIT_ATOMICS_SUPPORTED)
 485
 486 dnl Check for Endianness
 487 AC_C_BIGENDIAN(
 488    little_endian=no,
 489    little_endian=yes,
 490    little_endian=no,
 491    little_endian=no
 492 )
 493
 494 dnl Check for POWER8 Architecture
 495 PWR8_CFLAGS="-mpower8-vector"
 496 have_pwr8_intrinsics=no
 497 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 498 save_CFLAGS=$CFLAGS
 499 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 500 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 501 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 502 #error "Need GCC >= 4.8 for sane POWER8 support"
 503 #endif
 504 #include <altivec.h>
 505 int main () {
 506     vector unsigned char r;
 507     vector unsigned int v = vec_splat_u32 (1);
 508     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 509     return 0;
 510 }]])], have_pwr8_intrinsics=yes)
 511 CFLAGS=$save_CFLAGS
 512
 513 AC_ARG_ENABLE(pwr8,
 514    [AS_HELP_STRING([--disable-pwr8],
 515                    [disable POWER8-specific instructions])],
 516    [enable_pwr8=$enableval], [enable_pwr8=auto])
 517
 518 if test "x$enable_pwr8" = xno ; then
 519    have_pwr8_intrinsics=disabled
 520 fi
 521
 522 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 523    DEFINES="$DEFINES -D_ARCH_PWR8"
 524    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 525    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 526 else
 527    PWR8_CFLAGS=
 528 fi
 529
 530 AC_MSG_RESULT($have_pwr8_intrinsics)
 531 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 532    AC_MSG_ERROR([POWER8 compiler support not detected])
 533 fi
 534
 535 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 536    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 537 fi
 538
 539 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 540
 541 dnl Can't have static and shared libraries, default to static if user
 542 dnl explicitly requested. If both disabled, set to static since shared
 543 dnl was explicitly requested.
 544 case "x$enable_static$enable_shared" in
 545 xyesyes)
 546     AC_MSG_ERROR([Cannot enable both static and shared. Building using --enable-shared is strongly recommended])
 547     ;;
 548 xnono)
 549     AC_MSG_ERROR([Cannot disable both static and shared. Building using --enable-shared is strongly recommended])
 550     ;;
 551 esac
 552
 553 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 554
 555 dnl
 556 dnl other compiler options
 557 dnl
 558 AC_ARG_ENABLE([debug],
 559     [AS_HELP_STRING([--enable-debug],
 560         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 561     [enable_debug="$enableval"],
 562     [enable_debug=no]
 563 )
 564
 565 AC_ARG_ENABLE([profile],
 566     [AS_HELP_STRING([--enable-profile],
 567         [enable profiling of code @<:@default=disabled@:>@])],
 568     [enable_profile="$enableval"],
 569     [enable_profile=no]
 570 )
 571
 572 AC_ARG_ENABLE([sanitize],
 573     [AS_HELP_STRING([--enable-sanitize@<:@=address|undefined@:>@],
 574         [enable code sanitizer @<:@default=disabled@:>@])],
 575     [enable_sanitize="$enableval"],
 576     [enable_sanitize=no])
 577
 578 if test "x$enable_profile" = xyes; then
 579     DEFINES="$DEFINES -DPROFILE"
 580     if test "x$GCC" = xyes; then
 581         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 582     fi
 583     if test "x$GXX" = xyes; then
 584         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 585     fi
 586 fi
 587
 588 if test "x$enable_debug" = xyes; then
 589     DEFINES="$DEFINES -DDEBUG"
 590     if test "x$enable_profile" = xyes; then
 591         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 592     fi
 593     if test "x$GCC" = xyes; then
 594         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 595             CFLAGS="$CFLAGS -g"
 596         fi
 597         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 598             CFLAGS="$CFLAGS -O0"
 599         fi
 600     fi
 601     if test "x$GXX" = xyes; then
 602         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 603             CXXFLAGS="$CXXFLAGS -g"
 604         fi
 605         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 606             CXXFLAGS="$CXXFLAGS -O0"
 607         fi
 608     fi
 609 else
 610    DEFINES="$DEFINES -DNDEBUG"
 611 fi
 612
 613 if test "x$enable_sanitize" != xno; then
 614     if test "x$enable_profile" = xyes; then
 615         AC_MSG_WARN([Sanitize and Profile are enabled at the same time])
 616     fi
 617
 618     CFLAGS="$CFLAGS -fsanitize=$enable_sanitize"
 619     CXXFLAGS="$CXXFLAGS -fsanitize=$enable_sanitize"
 620     LDFLAGS="$LDFLAGS -fsanitize=$enable_sanitize"
 621
 622     AC_LINK_IFELSE(
 623         [AC_LANG_SOURCE([int main(){return 0;}])],
 624         [],
 625         [AC_MSG_FAILURE([sanitize flags '$enable_sanitize' not supported])])
 626 fi
 627
 628 dnl
 629 dnl Check if linker supports -Bsymbolic
 630 dnl
 631 save_LDFLAGS=$LDFLAGS
 632 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 633 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 634 AC_LINK_IFELSE(
 635     [AC_LANG_SOURCE([int main() { return 0;}])],
 636     [AC_MSG_RESULT([yes])
 637         BSYMBOLIC="-Wl,-Bsymbolic";],
 638     [AC_MSG_RESULT([no])
 639         BSYMBOLIC="";])
 640 LDFLAGS=$save_LDFLAGS
 641
 642 AC_SUBST([BSYMBOLIC])
 643
 644 dnl
 645 dnl Check if linker supports garbage collection
 646 dnl
 647 save_LDFLAGS=$LDFLAGS
 648 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 649 AC_MSG_CHECKING([whether ld supports --gc-sections])
 650 AC_LINK_IFELSE(
 651     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 652     [AC_MSG_RESULT([yes])
 653         GC_SECTIONS="-Wl,--gc-sections";],
 654     [AC_MSG_RESULT([no])
 655         GC_SECTIONS="";])
 656 LDFLAGS=$save_LDFLAGS
 657
 658 AC_SUBST([GC_SECTIONS])
 659
 660 dnl
 661 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 662 dnl so when these flags are passed to ld via libtool the checks will fail
 663 dnl
 664 case "$host_os" in
 665 openbsd* | darwin* )
 666     LD_NO_UNDEFINED="" ;;
 667 *)
 668     if test "x$enable_sanitize" = xno; then
 669         LD_NO_UNDEFINED="-Wl,--no-undefined"
 670     else
 671         LD_NO_UNDEFINED=""
 672     fi
 673     ;;
 674 esac
 675
 676 AC_SUBST([LD_NO_UNDEFINED])
 677
 678 dnl
 679 dnl Check if linker supports version scripts
 680 dnl
 681 AC_MSG_CHECKING([if the linker supports version-scripts])
 682 save_LDFLAGS=$LDFLAGS
 683 LDFLAGS="$LDFLAGS -Wl,--version-script=$srcdir/build-support/conftest.map"
 684 AC_LINK_IFELSE(
 685     [AC_LANG_SOURCE([int main() { return 0;}])],
 686     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 687     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 688 LDFLAGS=$save_LDFLAGS
 689 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 690
 691 dnl
 692 dnl Check if linker supports dynamic list files
 693 dnl
 694 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 695 save_LDFLAGS=$LDFLAGS
 696 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=$srcdir/build-support/conftest.dyn"
 697 AC_LINK_IFELSE(
 698     [AC_LANG_SOURCE([int main() { return 0;}])],
 699     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 700     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 701 LDFLAGS=$save_LDFLAGS
 702 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 703
 704 dnl
 705 dnl OSX linker does not support build-id
 706 dnl
 707 case "$host_os" in
 708 darwin*)
 709     LD_BUILD_ID=""
 710     ;;
 711 *)
 712     LD_BUILD_ID="-Wl,--build-id=sha1"
 713     ;;
 714 esac
 715 AC_SUBST([LD_BUILD_ID])
 716
 717 dnl
 718 dnl compatibility symlinks
 719 dnl
 720 case "$host_os" in
 721 linux* )
 722     HAVE_COMPAT_SYMLINKS=yes ;;
 723 * )
 724     HAVE_COMPAT_SYMLINKS=no ;;
 725 esac
 726
 727 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 728
 729 dnl
 730 dnl library names
 731 dnl
 732 dnl Unfortunately we need to do a few things that libtool can't help us with,
 733 dnl so we need some knowledge of shared library filenames:
 734 dnl
 735 dnl LIB_EXT is the extension used when creating symlinks for alternate
 736 dnl filenames for a shared library which will be dynamically loaded
 737 dnl
 738 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 739 dnl the file for a shared library we wish to link with
 740 dnl
 741 case "$host_os" in
 742 darwin* )
 743     LIB_EXT='dylib'
 744     IMP_LIB_EXT=$LIB_EXT
 745     ;;
 746 cygwin* )
 747     LIB_EXT='dll'
 748     IMP_LIB_EXT='dll.a'
 749     ;;
 750 aix* )
 751     LIB_EXT='a'
 752     IMP_LIB_EXT=$LIB_EXT
 753     ;;
 754 * )
 755     LIB_EXT='so'
 756     IMP_LIB_EXT=$LIB_EXT
 757     ;;
 758 esac
 759
 760 AC_SUBST([LIB_EXT])
 761
 762 dnl
 763 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 764 dnl
 765 AC_ARG_ENABLE([texture-float],
 766     [AS_HELP_STRING([--enable-texture-float],
 767         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 768     [enable_texture_float="$enableval"],
 769     [enable_texture_float=no]
 770 )
 771 if test "x$enable_texture_float" = xyes; then
 772     AC_MSG_WARN([Floating-point textures enabled.])
 773     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 774     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 775 fi
 776
 777 dnl
 778 dnl Arch/platform-specific settings
 779 dnl
 780 AC_ARG_ENABLE([asm],
 781     [AS_HELP_STRING([--disable-asm],
 782         [disable assembly usage @<:@default=enabled on supported platforms@:>@])],
 783     [enable_asm="$enableval"],
 784     [enable_asm=yes]
 785 )
 786 asm_arch=""
 787 AC_MSG_CHECKING([whether to enable assembly])
 788 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 789 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 790 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 791     case "$host_cpu" in
 792     i?86 | x86_64 | amd64)
 793         if test "x$host_cpu" != "x$target_cpu"; then
 794             enable_asm=no
 795             AC_MSG_RESULT([no, cross compiling])
 796         fi
 797         ;;
 798     esac
 799 fi
 800 # check for supported arches
 801 if test "x$enable_asm" = xyes; then
 802     case "$host_cpu" in
 803     i?86)
 804         case "$host_os" in
 805         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 806             asm_arch=x86
 807             ;;
 808         esac
 809         ;;
 810     x86_64|amd64)
 811         case "$host_os" in
 812         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 813             asm_arch=x86_64
 814             ;;
 815         esac
 816         ;;
 817     sparc*)
 818         case "$host_os" in
 819         linux*)
 820             asm_arch=sparc
 821             ;;
 822         esac
 823         ;;
 824     powerpc64le)
 825         case "$host_os" in
 826         linux*)
 827             asm_arch=ppc64le
 828             ;;
 829         esac
 830         ;;
 831     aarch64)
 832         case "$host_os" in
 833         linux*)
 834             asm_arch=aarch64
 835             ;;
 836         esac
 837         ;;
 838     arm)
 839         case "$host_os" in
 840         linux*)
 841             asm_arch=arm
 842             ;;
 843         esac
 844         ;;
 845     esac
 846
 847     case "$asm_arch" in
 848     x86)
 849         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 850         AC_MSG_RESULT([yes, x86])
 851         ;;
 852     x86_64|amd64)
 853         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 854         AC_MSG_RESULT([yes, x86_64])
 855         ;;
 856     sparc)
 857         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 858         AC_MSG_RESULT([yes, sparc])
 859         ;;
 860     ppc64le)
 861         DEFINES="$DEFINES -DUSE_PPC64LE_ASM"
 862         AC_MSG_RESULT([yes, ppc64le])
 863         ;;
 864     aarch64)
 865         DEFINES="$DEFINES -DUSE_AARCH64_ASM"
 866         AC_MSG_RESULT([yes, aarch64])
 867         ;;
 868     arm)
 869         DEFINES="$DEFINES -DUSE_ARM_ASM"
 870         AC_MSG_RESULT([yes, arm])
 871         ;;
 872     *)
 873         AC_MSG_RESULT([no, platform not supported])
 874         ;;
 875     esac
 876 fi
 877
 878 AC_HEADER_MAJOR
 879 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 880 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 881 AC_CHECK_HEADERS([endian.h])
 882 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 883 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 884 AC_CHECK_FUNC([timespec_get], [DEFINES="$DEFINES -DHAVE_TIMESPEC_GET"])
 885 AC_CHECK_FUNC([memfd_create], [DEFINES="$DEFINES -DHAVE_MEMFD_CREATE"])
 886
 887 AC_MSG_CHECKING([whether strtod has locale support])
 888 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 889     #define _GNU_SOURCE
 890     #include <stdlib.h>
 891     #include <locale.h>
 892     #ifdef HAVE_XLOCALE_H
 893     #include <xlocale.h>
 894     #endif
 895     int main() {
 896        locale_t loc = newlocale(LC_CTYPE_MASK, "C", NULL);
 897        const char *s = "1.0";
 898        char *end;
 899        double d = strtod_l(s, end, loc);
 900        float f = strtof_l(s, end, loc);
 901        freelocale(loc);
 902        return 0;
 903     }]])],
 904   [DEFINES="$DEFINES -DHAVE_STRTOD_L"];
 905    AC_MSG_RESULT([yes]),
 906    AC_MSG_RESULT([no]))
 907
 908 dnl Check to see if dlopen is in default libraries (like Solaris, which
 909 dnl has it in libc), or if libdl is needed to get it.
 910 AC_CHECK_FUNC([dlopen], [],
 911     [AC_CHECK_LIB([dl], [dlopen],
 912        [DLOPEN_LIBS="-ldl"])])
 913 AC_SUBST([DLOPEN_LIBS])
 914
 915 dnl Check if that library also has dladdr
 916 save_LIBS="$LIBS"
 917 LIBS="$LIBS $DLOPEN_LIBS"
 918 AC_CHECK_FUNCS([dladdr])
 919 LIBS="$save_LIBS"
 920
 921 AC_CHECK_FUNC([dl_iterate_phdr], [DEFINES="$DEFINES -DHAVE_DL_ITERATE_PHDR"])
 922
 923 case "$host_os" in
 924 darwin*)
 925     ;;
 926 *)
 927     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 928                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 929                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 930     AC_SUBST([CLOCK_LIB])
 931     ;;
 932 esac
 933
 934 dnl See if posix_memalign is available
 935 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 936
 937 dnl Check for zlib
 938 PKG_CHECK_MODULES([ZLIB], [zlib >= $ZLIB_REQUIRED])
 939 DEFINES="$DEFINES -DHAVE_ZLIB"
 940
 941 dnl Check for pthreads
 942 AX_PTHREAD
 943 if test "x$ax_pthread_ok" = xno; then
 944     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 945 fi
 946 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 947 dnl to -pthread, which causes problems if we need -lpthread to appear in
 948 dnl pkgconfig files.  Since Android doesn't have a pthread lib, this check
 949 dnl is not valid for that platform.
 950 if test "x$android" = xno; then
 951     test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 952 fi
 953 dnl According to the manual when using pthreads, one should add -pthread to
 954 dnl both compile and link-time arguments.
 955 dnl In practise that should be sufficient for all platforms, since any
 956 dnl platforms build with GCC and Clang support the flag.
 957 PTHREAD_LIBS="$PTHREAD_LIBS -pthread"
 958
 959 dnl pthread-stubs is mandatory on some BSD platforms, due to the nature of the
 960 dnl project. Even then there's a notable issue as described in the project README
 961 case "$host_os" in
 962 linux* | cygwin* | darwin* | solaris* | *-gnu* | gnu* | openbsd*)
 963     pthread_stubs_possible="no"
 964     ;;
 965 * )
 966     pthread_stubs_possible="yes"
 967     ;;
 968 esac
 969
 970 if test "x$pthread_stubs_possible" = xyes; then
 971     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs >= 0.4)
 972 fi
 973
 974 dnl Check for futex for fast inline simple_mtx_t.
 975 AC_CHECK_HEADER([linux/futex.h], [DEFINES="$DEFINES -DHAVE_LINUX_FUTEX_H"])
 976
 977 dnl SELinux awareness.
 978 AC_ARG_ENABLE([selinux],
 979     [AS_HELP_STRING([--enable-selinux],
 980         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 981     [MESA_SELINUX="$enableval"],
 982     [MESA_SELINUX=no])
 983 if test "x$enable_selinux" = "xyes"; then
 984     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 985         [AC_CHECK_HEADER([selinux/selinux.h],[],
 986                          [AC_MSG_ERROR([SELinux headers not found])])
 987          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 988                       [AC_MSG_ERROR([SELinux library not found])])
 989          SELINUX_LIBS="-lselinux"])
 990     DEFINES="$DEFINES -DMESA_SELINUX"
 991 fi
 992 AC_SUBST([SELINUX_CFLAGS])
 993 AC_SUBST([SELINUX_LIBS])
 994
 995 dnl
 996 dnl LLVM
 997 dnl
 998 AC_ARG_ENABLE([llvm-shared-libs],
 999     [AS_HELP_STRING([--enable-llvm-shared-libs],
1000         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1001     [enable_llvm_shared_libs="$enableval"],
1002     [enable_llvm_shared_libs=yes])
1003
1004 AC_ARG_WITH([llvm-prefix],
1005     [AS_HELP_STRING([--with-llvm-prefix],
1006         [Prefix for LLVM installations in non-standard locations])],
1007     [llvm_prefix="$withval"],
1008     [llvm_prefix=''])
1009
1010 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
1011 if test "x$have_libelf" = xno; then
1012    LIBELF_LIBS=''
1013    LIBELF_CFLAGS=''
1014    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
1015    AC_SUBST([LIBELF_LIBS])
1016    AC_SUBST([LIBELF_CFLAGS])
1017 fi
1018
1019 if test -z "$LLVM_CONFIG"; then
1020     if test -n "$llvm_prefix"; then
1021         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1022     else
1023         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1024     fi
1025 fi
1026
1027 llvm_add_component() {
1028     new_llvm_component=$1
1029     driver_name=$2
1030
1031     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
1032         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
1033     else
1034         AC_MSG_ERROR([LLVM component '$new_llvm_component' not enabled in your LLVM build. Required by $driver_name.])
1035     fi
1036 }
1037
1038 llvm_add_optional_component() {
1039     new_llvm_component=$1
1040     driver_name=$2
1041
1042     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
1043         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
1044     fi
1045 }
1046
1047 llvm_add_default_components() {
1048     driver_name=$1
1049
1050     # Required default components
1051     llvm_add_component "bitwriter" $driver_name
1052     llvm_add_component "engine" $driver_name
1053     llvm_add_component "mcdisassembler" $driver_name
1054     llvm_add_component "mcjit" $driver_name
1055
1056     # Optional default components
1057     llvm_add_optional_component "inteljitevents" $driver_name
1058 }
1059
1060 llvm_add_target() {
1061     new_llvm_target=$1
1062     driver_name=$2
1063
1064     if $LLVM_CONFIG --targets-built | grep -iqw $new_llvm_target ; then
1065         llvm_add_component $new_llvm_target $driver_name
1066     else
1067         AC_MSG_ERROR([LLVM target '$new_llvm_target' not enabled in your LLVM build. Required by $driver_name.])
1068     fi
1069 }
1070
1071 # Call this inside ` ` to get the return value.
1072 # $1 is the llvm-config command with arguments.
1073 strip_unwanted_llvm_flags() {
1074     echo " `$1` " | sed -E \
1075         -e 's/[[[:space:]]]+-m[[^[:space:]]]*//g' \
1076         -e 's/[[[:space:]]]+-DNDEBUG[[[:space:]]]/ /g' \
1077         -e 's/[[[:space:]]]+-D_GNU_SOURCE[[[:space:]]]/ /g' \
1078         -e 's/[[[:space:]]]+-pedantic[[[:space:]]]/ /g' \
1079         -e 's/[[[:space:]]]+-W[[^[:space:]]]*//g' \
1080         -e 's/[[[:space:]]]+-O[[^[:space:]]]*//g' \
1081         -e 's/[[[:space:]]]+-g[[^[:space:]]]*//g' \
1082         -e 's/-fno-rtti[[[:space:]]]/-Fno-rtti /g' \
1083         -e 's/[[[:space:]]]+-f[[^[:space:]]]*//g' \
1084         -e 's/-Fno-rtti[[[:space:]]]/-fno-rtti /g' \
1085         -e 's/^[[[:space:]]]//' \
1086         -e 's/[[[:space:]]]$//'
1087 }
1088
1089 llvm_set_environment_variables() {
1090     if test "x$LLVM_CONFIG" != xno; then
1091         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1092         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1093         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1094         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1095
1096         # We need to respect LLVM_CPPFLAGS when compiling LLVM headers.
1097         save_CFLAGS="$CFLAGS"
1098         CFLAGS="$CFLAGS $LLVM_CPPFLAGS"
1099
1100         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1101             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1102         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1103             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1104         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
1105             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1106
1107         CFLAGS="$save_CFLAGS"
1108
1109         # Only needed for LLVM < 3.6.0
1110         if test -z "$LLVM_VERSION_PATCH"; then
1111             LLVM_VERSION_PATCH=0
1112         fi
1113
1114         LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1115
1116         FOUND_LLVM=yes
1117     else
1118         FOUND_LLVM=no
1119         LLVM_VERSION_INT=0
1120     fi
1121 }
1122
1123 require_llvm() {
1124     if test "x$enable_llvm" != "xyes"; then
1125         AC_MSG_ERROR([--enable-llvm is required when building $1])
1126     fi
1127 }
1128
1129 llvm_require_version() {
1130     require_llvm $2
1131
1132     llvm_target_version_major=`echo $1 | cut -d. -f1 | egrep -o '^[[0-9]]+'`
1133     llvm_target_version_minor=`echo $1 | cut -d. -f2 | egrep -o '^[[0-9]]+'`
1134     llvm_target_version_patch=`echo $1 | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1135
1136     if test "$LLVM_VERSION_MAJOR" -gt "$llvm_target_version_major"; then
1137         # major > required major
1138         #  --> OK
1139         return
1140     fi
1141
1142     if test "$LLVM_VERSION_MAJOR" -eq "$llvm_target_version_major"; then
1143         if test "$LLVM_VERSION_MINOR" -gt "$llvm_target_version_minor"; then
1144             # major = required major and
1145             # minor > required minor
1146             #  --> OK
1147             return
1148         else
1149             if test "$LLVM_VERSION_MINOR" -eq "$llvm_target_version_minor"; then
1150                 if test "$LLVM_VERSION_PATCH" -ge "$llvm_target_version_patch"; then
1151                     # major = required major and
1152                     # minor = required minor and
1153                     # patch >= required patch
1154                     #  --> OK
1155                     return
1156                 fi
1157             fi
1158         fi
1159     fi
1160
1161     AC_MSG_ERROR([LLVM $1 or newer is required for $2])
1162 }
1163
1164 radeon_llvm_check() {
1165     if test ${LLVM_VERSION_INT} -lt 307; then
1166         amdgpu_llvm_target_name='r600'
1167     else
1168         amdgpu_llvm_target_name='amdgpu'
1169     fi
1170
1171     llvm_require_version $*
1172
1173     llvm_add_target $amdgpu_llvm_target_name $2
1174
1175     llvm_add_default_components $2
1176     llvm_add_component "bitreader" $2
1177     llvm_add_component "ipo" $2
1178
1179     if test "x$have_libelf" != xyes; then
1180        AC_MSG_ERROR([$2 requires libelf when using llvm])
1181     fi
1182 }
1183
1184 llvm_set_environment_variables
1185
1186 AC_SUBST([LLVM_CFLAGS])
1187 AC_SUBST([LLVM_CXXFLAGS])
1188 AC_SUBST([LLVM_LIBS])
1189 AC_SUBST([LLVM_LDFLAGS])
1190 AC_SUBST([LLVM_INCLUDEDIR])
1191
1192 dnl
1193 dnl libunwind
1194 dnl
1195 PKG_CHECK_EXISTS(libunwind, [HAVE_LIBUNWIND=yes], [HAVE_LIBUNWIND=no])
1196 AC_ARG_ENABLE([libunwind],
1197     [AS_HELP_STRING([--enable-libunwind],
1198             [Use libunwind for backtracing (default: auto)])],
1199         [LIBUNWIND="$enableval"],
1200         [LIBUNWIND="$HAVE_LIBUNWIND"])
1201
1202 if test "x$LIBUNWIND" = "xyes"; then
1203     PKG_CHECK_MODULES(LIBUNWIND, libunwind)
1204     AC_DEFINE(HAVE_LIBUNWIND, 1, [Have libunwind support])
1205 fi
1206
1207
1208 dnl Options for APIs
1209 AC_ARG_ENABLE([opengl],
1210     [AS_HELP_STRING([--disable-opengl],
1211         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
1212     [enable_opengl="$enableval"],
1213     [enable_opengl=yes])
1214 AC_ARG_ENABLE([gles1],
1215     [AS_HELP_STRING([--disable-gles1],
1216         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
1217     [enable_gles1="$enableval"],
1218     [enable_gles1=yes])
1219 AC_ARG_ENABLE([gles2],
1220     [AS_HELP_STRING([--disable-gles2],
1221         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
1222     [enable_gles2="$enableval"],
1223     [enable_gles2=yes])
1224
1225 AC_ARG_ENABLE([dri],
1226     [AS_HELP_STRING([--enable-dri],
1227         [enable DRI modules @<:@default=enabled@:>@])],
1228     [enable_dri="$enableval"],
1229     [enable_dri=yes])
1230
1231 AC_ARG_ENABLE([gallium-extra-hud],
1232     [AS_HELP_STRING([--enable-gallium-extra-hud],
1233         [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
1234     [enable_gallium_extra_hud="$enableval"],
1235     [enable_gallium_extra_hud=no])
1236 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
1237 if test "x$enable_gallium_extra_hud" = xyes ; then
1238     DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
1239 fi
1240
1241 #TODO: no pkgconfig .pc available for libsensors.
1242 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
1243 AC_ARG_ENABLE([lmsensors],
1244     [AS_HELP_STRING([--enable-lmsensors],
1245         [enable HUD lmsensor support @<:@default=disabled@:>@])],
1246     [enable_lmsensors="$enableval"],
1247     [enable_lmsensors=no])
1248 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
1249 if test "x$enable_lmsensors" = xyes ; then
1250     DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
1251     LIBSENSORS_LIBS="-lsensors"
1252 else
1253     LIBSENSORS_LIBS=""
1254 fi
1255 AC_SUBST(LIBSENSORS_LIBS)
1256
1257 case "$host_os" in
1258 linux*)
1259     dri3_default=yes
1260     ;;
1261 *)
1262     dri3_default=no
1263     ;;
1264 esac
1265
1266 if test "x$enable_dri" = xno; then
1267     dri3_default=no
1268 fi
1269
1270 AC_ARG_ENABLE([dri3],
1271     [AS_HELP_STRING([--enable-dri3],
1272         [enable DRI3 @<:@default=auto@:>@])],
1273     [enable_dri3="$enableval"],
1274     [enable_dri3="$dri3_default"])
1275 AC_ARG_ENABLE([glx],
1276     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
1277         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
1278     [enable_glx="$enableval"],
1279     [enable_glx=yes])
1280 AC_ARG_ENABLE([osmesa],
1281     [AS_HELP_STRING([--enable-osmesa],
1282         [enable OSMesa library @<:@default=disabled@:>@])],
1283     [enable_osmesa="$enableval"],
1284     [enable_osmesa=no])
1285 AC_ARG_ENABLE([gallium-osmesa],
1286     [AS_HELP_STRING([--enable-gallium-osmesa],
1287         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
1288     [enable_gallium_osmesa="$enableval"],
1289     [enable_gallium_osmesa=no])
1290 AC_ARG_ENABLE([egl],
1291     [AS_HELP_STRING([--disable-egl],
1292         [disable EGL library @<:@default=enabled@:>@])],
1293     [enable_egl="$enableval"],
1294     [enable_egl=yes])
1295
1296 AC_ARG_ENABLE([xa],
1297     [AS_HELP_STRING([--enable-xa],
1298         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
1299     [enable_xa="$enableval"],
1300     [enable_xa=no])
1301 AC_ARG_ENABLE([gbm],
1302    [AS_HELP_STRING([--enable-gbm],
1303          [enable gbm library @<:@default=yes except cygwin and macOS@:>@])],
1304    [enable_gbm="$enableval"],
1305    [case "$host_os" in
1306        cygwin* | darwin*)
1307           enable_gbm=no
1308           ;;
1309        *)
1310           enable_gbm=yes
1311           ;;
1312     esac])
1313 AC_ARG_ENABLE([nine],
1314     [AS_HELP_STRING([--enable-nine],
1315         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
1316     [enable_nine="$enableval"],
1317     [enable_nine=no])
1318
1319 AC_ARG_ENABLE([xvmc],
1320    [AS_HELP_STRING([--enable-xvmc],
1321          [enable xvmc library @<:@default=auto@:>@])],
1322    [enable_xvmc="$enableval"],
1323    [enable_xvmc=auto])
1324 AC_ARG_ENABLE([vdpau],
1325    [AS_HELP_STRING([--enable-vdpau],
1326          [enable vdpau library @<:@default=auto@:>@])],
1327    [enable_vdpau="$enableval"],
1328    [enable_vdpau=auto])
1329 AC_ARG_ENABLE([omx],
1330    [AS_HELP_STRING([--enable-omx],
1331          [DEPRECATED: Use --enable-omx-bellagio or --enable-omx-tizonia instead @<:@default=auto@:>@])],
1332    [AC_MSG_ERROR([--enable-omx is deprecated. Use --enable-omx-bellagio or --enable-omx-tizonia instead.])],
1333    [])
1334 AC_ARG_ENABLE([omx-bellagio],
1335    [AS_HELP_STRING([--enable-omx-bellagio],
1336          [enable OpenMAX Bellagio library @<:@default=disabled@:>@])],
1337    [enable_omx_bellagio="$enableval"],
1338    [enable_omx_bellagio=no])
1339 AC_ARG_ENABLE([omx-tizonia],
1340    [AS_HELP_STRING([--enable-omx-tizonia],
1341          [enable OpenMAX Tizonia library @<:@default=disabled@:>@])],
1342    [enable_omx_tizonia="$enableval"],
1343    [enable_omx_tizonia=no])
1344 AC_ARG_ENABLE([va],
1345    [AS_HELP_STRING([--enable-va],
1346          [enable va library @<:@default=auto@:>@])],
1347    [enable_va="$enableval"],
1348    [enable_va=auto])
1349 AC_ARG_ENABLE([opencl],
1350    [AS_HELP_STRING([--enable-opencl],
1351          [enable OpenCL library @<:@default=disabled@:>@])],
1352    [enable_opencl="$enableval"],
1353    [enable_opencl=no])
1354 AC_ARG_ENABLE([opencl_icd],
1355    [AS_HELP_STRING([--enable-opencl-icd],
1356           [Build an OpenCL ICD library to be loaded by an ICD implementation
1357            @<:@default=enabled@:>@])],
1358     [enable_opencl_icd="$enableval"],
1359     [enable_opencl_icd=yes])
1360
1361 AC_ARG_ENABLE([gallium-tests],
1362     [AS_HELP_STRING([--enable-gallium-tests],
1363         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1364     [enable_gallium_tests="$enableval"],
1365     [enable_gallium_tests=no])
1366
1367 # Option for Gallium drivers
1368
1369 # Keep this in sync with the --with-gallium-drivers help string default value
1370 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1371
1372 AC_ARG_WITH([gallium-drivers],
1373     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1374         [comma delimited Gallium drivers list, e.g.
1375         "i915,nouveau,r300,r600,radeonsi,freedreno,pl111,svga,swrast,swr,tegra,v3d,vc4,virgl,etnaviv,imx"
1376         @<:@default=r300,r600,svga,swrast@:>@])],
1377     [with_gallium_drivers="$withval"],
1378     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1379
1380 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
1381 # here so that the script doesn't choke on an unknown driver name later.
1382 case "$with_gallium_drivers" in
1383     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1384     no) with_gallium_drivers='' ;;
1385 esac
1386
1387 if test "x$enable_opengl" = xno -a \
1388         "x$enable_gles1" = xno -a \
1389         "x$enable_gles2" = xno -a \
1390         "x$enable_nine" = xno -a \
1391         "x$enable_xa" = xno -a \
1392         "x$enable_xvmc" = xno -a \
1393         "x$enable_vdpau" = xno -a \
1394         "x$enable_omx_bellagio" = xno -a \
1395         "x$enable_omx_tizonia" = xno -a \
1396         "x$enable_va" = xno -a \
1397         "x$enable_opencl" = xno; then
1398     AC_MSG_ERROR([at least one API should be enabled])
1399 fi
1400
1401 if test "x$enable_omx_bellagio" = xyes -a \
1402         "x$enable_omx_tizonia" = xyes; then
1403    AC_MSG_ERROR([Can't enable both bellagio and tizonia at same time])
1404 fi
1405
1406 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1407 if test "x$enable_opengl" = xno -a \
1408         "x$enable_gles1" = xyes; then
1409     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1410 fi
1411
1412 if test "x$enable_opengl" = xno -a \
1413         "x$enable_gles2" = xyes; then
1414     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1415 fi
1416
1417 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1418 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1419 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1420 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1421                                         "x$enable_gles1" = xyes -o \
1422                                         "x$enable_gles2" = xyes)
1423 AM_CONDITIONAL(NEED_KHRPLATFORM, test "x$enable_egl" = xyes -o \
1424                                       "x$enable_gles1" = xyes -o \
1425                                       "x$enable_gles2" = xyes)
1426
1427 # Validate GLX options
1428 if test "x$enable_glx" = xyes; then
1429     if test "x$enable_dri" = xyes; then
1430         enable_glx=dri
1431     elif test -n "$with_gallium_drivers"; then
1432         enable_glx=gallium-xlib
1433     else
1434         enable_glx=xlib
1435     fi
1436 fi
1437 case "x$enable_glx" in
1438 xdri | xxlib | xgallium-xlib)
1439     # GLX requires OpenGL
1440     if test "x$enable_opengl" = xno; then
1441         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1442     fi
1443
1444     # Check individual dependencies
1445     case "x$enable_glx" in
1446     xdri)
1447         if test "x$enable_dri" = xno; then
1448             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1449         fi
1450         ;;
1451     xxlib)
1452         if test "x$enable_dri" = xyes; then
1453             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1454         fi
1455         ;;
1456     xgallium-xlib )
1457         if test "x$enable_dri" = xyes; then
1458             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1459         fi
1460         if test -z "$with_gallium_drivers"; then
1461             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1462         fi
1463         ;;
1464     esac
1465     ;;
1466 xno)
1467     ;;
1468 *)
1469     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1470     ;;
1471 esac
1472
1473 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1474 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1475 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1476 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1477
1478 DEFAULT_GL_LIB_NAME=GL
1479
1480 dnl
1481 dnl Libglvnd configuration
1482 dnl
1483 AC_ARG_ENABLE([libglvnd],
1484     [AS_HELP_STRING([--enable-libglvnd],
1485         [Build GLX and EGL for libglvnd @<:@default=disabled@:>@])],
1486     [enable_libglvnd="$enableval"],
1487     [enable_libglvnd=no])
1488 AM_CONDITIONAL(USE_LIBGLVND, test "x$enable_libglvnd" = xyes)
1489
1490 if test "x$enable_libglvnd" = xyes ; then
1491     case "x$enable_glx" in
1492     xxlib | xgallium-xlib )
1493         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1494         ;;
1495     esac
1496
1497     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.2.0)
1498     LIBGLVND_DATADIR=`$PKG_CONFIG --variable=datadir libglvnd`
1499     AC_SUBST([LIBGLVND_DATADIR])
1500
1501     DEFINES="${DEFINES} -DUSE_LIBGLVND=1"
1502     DEFAULT_GL_LIB_NAME=GLX_mesa
1503
1504     if test "x$enable_glx" = xno -a "x$enable_egl" = xno; then
1505         AC_MSG_ERROR([cannot build libglvnd without GLX or EGL])
1506     fi
1507 fi
1508
1509 AC_ARG_WITH([gl-lib-name],
1510   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
1511     [specify GL library name @<:@default=GL@:>@])],
1512   [GL_LIB=$withval],
1513   [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1514 AC_ARG_WITH([osmesa-lib-name],
1515   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
1516     [specify OSMesa library name @<:@default=OSMesa@:>@])],
1517   [OSMESA_LIB=$withval],
1518   [OSMESA_LIB=OSMesa])
1519 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1520 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
1521
1522 dnl
1523 dnl Mangled Mesa support
1524 dnl
1525 AC_ARG_ENABLE([mangling],
1526   [AS_HELP_STRING([--enable-mangling],
1527     [enable mangled symbols and library name @<:@default=disabled@:>@])],
1528   [enable_mangling="${enableval}"],
1529   [enable_mangling=no]
1530 )
1531 if test "x${enable_mangling}" = "xyes" ; then
1532   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
1533   GL_LIB="Mangled${GL_LIB}"
1534   OSMESA_LIB="Mangled${OSMESA_LIB}"
1535 fi
1536 AC_SUBST([GL_LIB])
1537 AC_SUBST([OSMESA_LIB])
1538
1539 # Check for libdrm
1540 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1541                   [have_libdrm=yes], [have_libdrm=no])
1542 if test "x$have_libdrm" = xyes; then
1543     DEFINES="$DEFINES -DHAVE_LIBDRM"
1544 fi
1545
1546 require_libdrm() {
1547     if test "x$have_libdrm" != xyes; then
1548        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1549     fi
1550 }
1551
1552
1553 # Select which platform-dependent DRI code gets built
1554 case "$host_os" in
1555 darwin*)
1556     dri_platform='apple' ;;
1557 cygwin*)
1558     dri_platform='windows' ;;
1559 gnu*)
1560     dri_platform='none' ;;
1561 *)
1562     dri_platform='drm' ;;
1563 esac
1564
1565 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1566     have_drisw_kms='yes'
1567 fi
1568
1569 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1570 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1571 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1572 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1573 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1574 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1575 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1576 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1577 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1578
1579 AC_ARG_ENABLE([shared-glapi],
1580     [AS_HELP_STRING([--enable-shared-glapi],
1581         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1582     [enable_shared_glapi="$enableval"],
1583     [enable_shared_glapi=yes])
1584
1585 case "x$enable_opengl$enable_gles1$enable_gles2" in
1586 x*yes*yes*)
1587     if test "x$enable_shared_glapi" = xno; then
1588         AC_MSG_ERROR([shared GLAPI required when building two or more of
1589                       the following APIs - opengl, gles1 gles2])
1590     fi
1591     ;;
1592 esac
1593
1594 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1595
1596 # Build the pipe-drivers as separate libraries/modules.
1597 # Do not touch this unless you know what you are doing.
1598 # XXX: Expose via configure option ?
1599 enable_shared_pipe_drivers=no
1600
1601 dnl
1602 dnl Driver specific build directories
1603 dnl
1604
1605 if test "x$enable_gallium_osmesa" = xyes; then
1606     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1607         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1608     fi
1609     if test "x$enable_osmesa" = xyes; then
1610         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1611     fi
1612 fi
1613
1614 require_dri_shared_libs_and_glapi() {
1615     if test "x$enable_static" = xyes; then
1616         AC_MSG_ERROR([$1 cannot be build as static library])
1617     fi
1618
1619     if test "x$enable_dri" != xyes; then
1620         # There is only a single backend which won't be build/used otherwise.
1621         # XXX: Revisit this as the egl/haiku is a thing.
1622         AC_MSG_ERROR([$1 requires --enable-dri])
1623     fi
1624
1625     if test "x$enable_shared_glapi" != xyes; then
1626         AC_MSG_ERROR([$1 requires --enable-shared-glapi])
1627     fi
1628 }
1629
1630 if test "x$enable_dri" = xyes; then
1631     require_dri_shared_libs_and_glapi "DRI"
1632
1633     # not a hard requirement as swrast does not depend on it
1634     if test "x$have_libdrm" = xyes; then
1635         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1636     fi
1637 fi
1638
1639 AC_ARG_ENABLE([driglx-direct],
1640     [AS_HELP_STRING([--disable-driglx-direct],
1641         [disable direct rendering in GLX and EGL for DRI \
1642             @<:@default=enabled@:>@])],
1643     [driglx_direct="$enableval"],
1644     [driglx_direct="yes"])
1645
1646 dnl
1647 dnl libGL configuration per driver
1648 dnl
1649 if test "x$enable_glx" != xno; then
1650     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1651 fi
1652 case "x$enable_glx" in
1653 xxlib | xgallium-xlib)
1654     # Xlib-based GLX
1655     dri_modules="x11 xext xcb"
1656     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1657     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1658     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1659     GL_LIB_DEPS="$XLIBGL_LIBS"
1660     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1661     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1662     ;;
1663 xdri)
1664     # DRI-based GLX
1665
1666     # find the DRI deps for libGL
1667     dri_modules="x11 xext xdamage >= $XDAMAGE_REQUIRED xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1668
1669     if test x"$driglx_direct" = xyes; then
1670         if test x"$dri_platform" = xdrm ; then
1671             DEFINES="$DEFINES -DGLX_USE_DRM"
1672             require_libdrm "Direct rendering"
1673
1674             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1675             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1676
1677             if test x"$enable_dri" = xyes; then
1678                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1679             fi
1680         fi
1681         if test x"$dri_platform" = xapple ; then
1682             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1683         fi
1684         if test x"$dri_platform" = xwindows ; then
1685             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1686         fi
1687     fi
1688
1689     # add xf86vidmode if available
1690     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1691     if test "$HAVE_XF86VIDMODE" = yes ; then
1692         dri_modules="$dri_modules xxf86vm"
1693     fi
1694
1695     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1696     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1697     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1698     GL_LIB_DEPS="$DRIGL_LIBS"
1699
1700     # need DRM libs, $PTHREAD_LIBS, etc.
1701     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1702     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1703     ;;
1704 esac
1705
1706 # This is outside the case (above) so that it is invoked even for non-GLX
1707 # builds.
1708 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1709
1710 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1711 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1712 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1713 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1714
1715 AC_SUBST([X11_INCLUDES])
1716 AC_SUBST([GL_LIB_DEPS])
1717 AC_SUBST([GL_PC_REQ_PRIV])
1718 AC_SUBST([GL_PC_LIB_PRIV])
1719 AC_SUBST([GL_PC_CFLAGS])
1720 AC_SUBST([DRI_PC_REQ_PRIV])
1721 AC_SUBST([GLESv1_CM_LIB_DEPS])
1722 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1723 AC_SUBST([GLESv2_LIB_DEPS])
1724 AC_SUBST([GLESv2_PC_LIB_PRIV])
1725
1726 AC_SUBST([HAVE_XF86VIDMODE])
1727
1728 dnl
1729 dnl More GLX setup
1730 dnl
1731 case "x$enable_glx" in
1732 xxlib | xgallium-xlib)
1733     DEFINES="$DEFINES -DUSE_XSHM"
1734     ;;
1735 xdri)
1736     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1737     if test "x$driglx_direct" = xyes; then
1738         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1739     fi
1740     ;;
1741 esac
1742
1743 dnl
1744 dnl TLS detection
1745 dnl
1746
1747 AC_ARG_ENABLE([glx-tls],
1748     [AS_HELP_STRING([--enable-glx-tls],
1749         [enable TLS support in GLX @<:@default=enabled@:>@])],
1750     [GLX_USE_TLS="$enableval"],
1751     [GLX_USE_TLS=yes])
1752 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1753
1754 if test "x$GLX_USE_TLS" = xyes; then
1755     DEFINES="$DEFINES -DGLX_USE_TLS"
1756 fi
1757
1758 dnl Read-only text section on x86 hardened platforms
1759 AC_ARG_ENABLE([glx-read-only-text],
1760     [AS_HELP_STRING([--enable-glx-read-only-text],
1761         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1762     [enable_glx_read_only_text="$enableval"],
1763     [enable_glx_read_only_text=no])
1764 if test "x$enable_glx_read_only_text" = xyes; then
1765     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1766 fi
1767
1768 dnl
1769 dnl DEPRECATED: EGL Platforms configuration
1770 dnl
1771 AC_ARG_WITH([egl-platforms],
1772     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1773         [DEPRECATED: use --with-platforms instead@<:@default=auto@:>@])],
1774     [with_egl_platforms="$withval"],
1775     [with_egl_platforms=auto])
1776
1777 if test "x$with_egl_platforms" = xauto; then
1778     with_egl_platforms="x11,surfaceless"
1779     if test "x$enable_gbm" = xyes; then
1780         with_egl_platforms="$with_egl_platforms,drm"
1781     fi
1782 else
1783     AC_MSG_WARN([--with-egl-platforms is deprecated. Use --with-platforms instead.])
1784 fi
1785
1786 dnl
1787 dnl Platforms configuration
1788 dnl
1789 AC_ARG_WITH([platforms],
1790     [AS_HELP_STRING([--with-platforms@<:@=DIRS...@:>@],
1791         [comma delimited native platforms libEGL/Vulkan/other supports, e.g.
1792         "x11,drm,wayland,surfaceless..." @<:@default=auto@:>@])],
1793     [with_platforms="$withval"],
1794     [with_platforms=auto])
1795
1796 # Reuse the autodetection rather than duplicating it.
1797 if test "x$with_platforms" = xauto; then
1798     with_platforms=$with_egl_platforms
1799 fi
1800
1801 # Do per platform setups and checks
1802 platforms=`IFS=', '; echo $with_platforms`
1803 for plat in $platforms; do
1804     case "$plat" in
1805     wayland)
1806
1807         PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= $WAYLAND_REQUIRED])
1808         PKG_CHECK_MODULES([WAYLAND_SERVER], [wayland-server >= $WAYLAND_REQUIRED])
1809         PKG_CHECK_MODULES([WAYLAND_PROTOCOLS], [wayland-protocols >= $WAYLAND_PROTOCOLS_REQUIRED])
1810         WAYLAND_PROTOCOLS_DATADIR=`$PKG_CONFIG --variable=pkgdatadir wayland-protocols`
1811
1812         PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
1813                           WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
1814                           WAYLAND_SCANNER='')
1815         if test "x$WAYLAND_SCANNER" = x; then
1816             AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner], [:])
1817         fi
1818
1819         if test "x$WAYLAND_SCANNER" = "x:"; then
1820                 AC_MSG_ERROR([wayland-scanner is needed to compile the wayland platform])
1821         fi
1822         DEFINES="$DEFINES -DHAVE_WAYLAND_PLATFORM -DWL_HIDE_DEPRECATED"
1823         ;;
1824
1825     x11)
1826         PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1827         DEFINES="$DEFINES -DHAVE_X11_PLATFORM"
1828         ;;
1829
1830     drm)
1831         test "x$enable_gbm" = "xno" &&
1832                 AC_MSG_ERROR([EGL platform drm needs gbm])
1833         DEFINES="$DEFINES -DHAVE_DRM_PLATFORM"
1834         ;;
1835
1836     surfaceless)
1837         DEFINES="$DEFINES -DHAVE_SURFACELESS_PLATFORM"
1838         ;;
1839
1840     android)
1841         PKG_CHECK_MODULES([ANDROID], [cutils hardware sync])
1842         DEFINES="$DEFINES -DHAVE_ANDROID_PLATFORM"
1843         ;;
1844
1845     *)
1846         AC_MSG_ERROR([platform '$plat' does not exist])
1847         ;;
1848     esac
1849
1850     case "$plat" in
1851     wayland|drm|surfaceless)
1852         require_libdrm "Platform $plat"
1853         ;;
1854     esac
1855 done
1856 AC_SUBST([WAYLAND_PROTOCOLS_DATADIR])
1857
1858 if test "x$enable_glx" != xno; then
1859     if ! echo "$platforms" | grep -q 'x11'; then
1860         AC_MSG_ERROR([Building GLX without the x11 platform is not supported])
1861     fi
1862 fi
1863
1864 if test x"$enable_dri3" = xyes; then
1865     DEFINES="$DEFINES -DHAVE_DRI3"
1866
1867     dri3_modules="x11-xcb xcb >= $XCB_REQUIRED xcb-dri3 xcb-xfixes xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1868     PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1869     dri3_modifier_modules="xcb-dri3 >= $XCBDRI3_MODIFIERS_REQUIRED xcb-present >= $XCBPRESENT_MODIFIERS_REQUIRED"
1870     PKG_CHECK_MODULES([XCB_DRI3_MODIFIERS], [$dri3_modifier_modules], [have_dri3_modifiers=yes], [have_dri3_modifiers=no])
1871
1872     if test "x$have_dri3_modifiers" == xyes; then
1873         DEFINES="$DEFINES -DHAVE_DRI3_MODIFIERS"
1874     fi
1875 fi
1876
1877 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$platforms" | grep -q 'x11')
1878 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$platforms" | grep -q 'wayland')
1879 AM_CONDITIONAL(HAVE_PLATFORM_DRM, echo "$platforms" | grep -q 'drm')
1880 AM_CONDITIONAL(HAVE_PLATFORM_SURFACELESS, echo "$platforms" | grep -q 'surfaceless')
1881 AM_CONDITIONAL(HAVE_PLATFORM_ANDROID, echo "$platforms" | grep -q 'android')
1882
1883 dnl
1884 dnl More DRI setup
1885 dnl
1886 dnl Directory for DRI drivers
1887 AC_ARG_WITH([dri-driverdir],
1888     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1889         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1890     [DRI_DRIVER_INSTALL_DIR="$withval"],
1891     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1892 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1893 dnl Extra search path for DRI drivers
1894 AC_ARG_WITH([dri-searchpath],
1895     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1896         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1897     [DRI_DRIVER_SEARCH_DIR="$withval"],
1898     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1899 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1900 dnl Which drivers to build - default is chosen by platform
1901 AC_ARG_WITH([dri-drivers],
1902     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1903         [comma delimited classic DRI drivers list, e.g.
1904         "i915,i965,nouveau,radeon,r200,swrast" @<:@default=auto@:>@])],
1905     [with_dri_drivers="$withval"],
1906     [with_dri_drivers=auto])
1907
1908 if test "x$with_dri_drivers" = xauto; then
1909     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1910         with_dri_drivers="yes"
1911     else
1912         with_dri_drivers="no"
1913     fi
1914 fi
1915 if test "x$with_dri_drivers" = xno; then
1916     with_dri_drivers=''
1917 fi
1918
1919 # Check for expat
1920 PKG_CHECK_MODULES([EXPAT], [expat],,
1921     [PKG_CHECK_MODULES([EXPAT], [expat21])]
1922 )
1923
1924 dnl If $with_dri_drivers is yes, drivers will be added through
1925 dnl platform checks. Set DEFINES and LIB_DEPS
1926 if test "x$enable_dri" = xyes; then
1927     # Platform specific settings and drivers to build
1928     case "$host_os" in
1929     linux*)
1930         case "$host_cpu" in
1931         powerpc* | sparc*)
1932             # Build only the drivers for cards that exist on PowerPC/sparc
1933             if test "x$with_dri_drivers" = "xyes"; then
1934                 with_dri_drivers="r200 radeon swrast"
1935             fi
1936             ;;
1937         esac
1938         ;;
1939     cygwin*)
1940         if test "x$with_dri_drivers" = "xyes"; then
1941             with_dri_drivers="swrast"
1942         fi
1943         ;;
1944     darwin*)
1945         DEFINES="$DEFINES -DBUILDING_MESA"
1946         if test "x$with_dri_drivers" = "xyes"; then
1947             with_dri_drivers="swrast"
1948         fi
1949         ;;
1950     esac
1951
1952     # default drivers
1953     if test "x$with_dri_drivers" = "xyes"; then
1954         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1955     fi
1956
1957     # put all the necessary libs together
1958     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1959 fi
1960
1961 AC_SUBST([DRI_LIB_DEPS])
1962
1963 DRI_DIRS=''
1964 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1965 if test -n "$with_dri_drivers"; then
1966     if test "x$enable_opengl" != xyes; then
1967         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1968     fi
1969
1970     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1971     for driver in $dri_drivers; do
1972         DRI_DIRS="$DRI_DIRS $driver"
1973         case "x$driver" in
1974         xi915)
1975             require_libdrm "i915"
1976             HAVE_I915_DRI=yes
1977             PKG_CHECK_MODULES([I915], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1978             ;;
1979         xi965)
1980             require_libdrm "i965"
1981             HAVE_I965_DRI=yes
1982             ;;
1983         xnouveau)
1984             require_libdrm "nouveau"
1985             HAVE_NOUVEAU_DRI=yes
1986             PKG_CHECK_MODULES([NVVIEUX], [libdrm >= $LIBDRM_NVVIEUX_REQUIRED libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1987             ;;
1988         xradeon)
1989             require_libdrm "radeon"
1990             HAVE_RADEON_DRI=yes;
1991             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1992             ;;
1993         xr200)
1994             require_libdrm "r200"
1995             HAVE_R200_DRI=yes
1996             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1997             ;;
1998         xswrast)
1999             HAVE_SWRAST_DRI=yes
2000             ;;
2001         *)
2002             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
2003             ;;
2004         esac
2005     done
2006     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2007 fi
2008
2009
2010 dnl
2011 dnl Gallium LLVM
2012 dnl Deprecated: kept for backwards compatibility
2013 dnl
2014 AC_ARG_ENABLE([gallium-llvm],
2015     [AS_HELP_STRING([--enable-gallium-llvm],
2016         [DEPRECATED: use --enable-llvm instead])],
2017     [enable_gallium_llvm="$enableval"],
2018     [enable_gallium_llvm=auto])
2019
2020 if test "x$enable_gallium_llvm" != xauto; then
2021    AC_MSG_WARN([The --enable-gallium-llvm option has been deprecated. Use --enable-llvm instead.])
2022    enable_llvm=$enable_gallium_llvm
2023 fi
2024
2025 dnl
2026 dnl LLVM
2027 dnl
2028 AC_ARG_ENABLE([llvm],
2029     [AS_HELP_STRING([--enable-llvm],
2030         [build with LLVM support @<:@default=enabled on x86/x86_64@:>@])],
2031     [enable_llvm="$enableval"],
2032     [enable_llvm=auto])
2033
2034 if test "x$enable_llvm" = xauto -a "x$FOUND_LLVM" = xyes; then
2035     if test "x$FOUND_LLVM" = xyes; then
2036         case "$host_cpu" in
2037         i*86|x86_64|amd64) enable_llvm=yes;;
2038         *) enable_llvm=no;;
2039         esac
2040     else
2041         enable_llvm=no
2042     fi
2043 fi
2044
2045 if test "x$enable_llvm" = xyes -a "x$FOUND_LLVM" = xno; then
2046     AC_MSG_ERROR([--enable-llvm selected but llvm-config is not found])
2047 fi
2048
2049 #
2050 # Vulkan driver configuration
2051 #
2052
2053 AC_ARG_WITH([vulkan-drivers],
2054     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
2055         [comma delimited Vulkan drivers list, e.g.
2056         "intel,radeon"
2057         @<:@default=no@:>@])],
2058     [with_vulkan_drivers="$withval"],
2059     [with_vulkan_drivers="no"])
2060
2061 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
2062 # here so that the script doesn't choke on an unknown driver name later.
2063 case "x$with_vulkan_drivers" in
2064     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
2065     xno) with_vulkan_drivers='' ;;
2066 esac
2067
2068 AC_ARG_WITH([vulkan-icddir],
2069     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
2070         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
2071     [VULKAN_ICD_INSTALL_DIR="$withval"],
2072     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
2073 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
2074
2075 require_x11_dri3() {
2076     if echo "$platforms" | grep -q 'x11'; then
2077         if test "x$enable_dri3" != xyes; then
2078             AC_MSG_ERROR([$1 Vulkan driver requires DRI3 when built with X11])
2079         fi
2080     fi
2081 }
2082
2083 if test -n "$with_vulkan_drivers"; then
2084     if test "x$ac_cv_func_dl_iterate_phdr" = xno; then
2085         AC_MSG_ERROR([Vulkan drivers require the dl_iterate_phdr function])
2086     fi
2087
2088     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
2089     for driver in $VULKAN_DRIVERS; do
2090         case "x$driver" in
2091         xintel)
2092             require_libdrm "ANV"
2093             require_x11_dri3 "ANV"
2094             HAVE_INTEL_VULKAN=yes
2095             ;;
2096         xradeon)
2097             require_libdrm "radv"
2098             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2099             radeon_llvm_check $LLVM_REQUIRED_RADV "radv"
2100             require_x11_dri3 "radv"
2101             HAVE_RADEON_VULKAN=yes
2102             ;;
2103         *)
2104             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
2105             ;;
2106         esac
2107     done
2108     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
2109 fi
2110
2111
2112 DEFINES="$DEFINES -DENABLE_SHADER_CACHE"
2113 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
2114 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
2115                                   "x$enable_osmesa" = xyes -o \
2116                                   -n "$DRI_DIRS")
2117
2118 dnl
2119 dnl OSMesa configuration
2120 dnl
2121
2122 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
2123 AC_ARG_WITH([osmesa-bits],
2124     [AS_HELP_STRING([--with-osmesa-bits=BITS],
2125         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
2126     [osmesa_bits="$withval"],
2127     [osmesa_bits=8])
2128 if test "x$osmesa_bits" != x8; then
2129     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
2130         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
2131         osmesa_bits=8
2132     fi
2133 fi
2134 case "x$osmesa_bits" in
2135 x8)
2136     OSMESA_LIB="${OSMESA_LIB}"
2137     ;;
2138 x16|x32)
2139     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
2140     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
2141     ;;
2142 *)
2143     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
2144     ;;
2145 esac
2146
2147 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
2148     # only link libraries with osmesa if shared
2149     if test "$enable_static" = no; then
2150         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2151     else
2152         OSMESA_LIB_DEPS=""
2153     fi
2154     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2155 fi
2156
2157 AC_SUBST([OSMESA_LIB_DEPS])
2158 AC_SUBST([OSMESA_PC_REQ])
2159 AC_SUBST([OSMESA_PC_LIB_PRIV])
2160
2161 dnl
2162 dnl gbm configuration
2163 dnl
2164 if test "x$enable_gbm" = xyes; then
2165     require_dri_shared_libs_and_glapi "gbm"
2166 fi
2167 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
2168 # FINISHME: GBM has a number of dependencies which we should add below
2169 GBM_PC_REQ_PRIV=""
2170 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
2171 AC_SUBST([GBM_PC_REQ_PRIV])
2172 AC_SUBST([GBM_PC_LIB_PRIV])
2173
2174 dnl
2175 dnl EGL configuration
2176 dnl
2177
2178 if test "x$enable_egl" = xyes; then
2179     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
2180
2181     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
2182
2183     require_dri_shared_libs_and_glapi "egl"
2184 fi
2185 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
2186 AC_SUBST([EGL_LIB_DEPS])
2187
2188 gallium_st="mesa"
2189
2190 dnl
2191 dnl XA configuration
2192 dnl
2193 if test "x$enable_xa" = xyes; then
2194     if test "x$with_gallium_drivers" = xswrast; then
2195        AC_MSG_ERROR([
2196           Building xa requires at least one non swrast gallium driver.
2197           If you are looking to use libxatracker.so with the VMware driver,
2198           make sure to include svga in the gallium drivers list, apart from
2199           enabling XA.
2200           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
2201     fi
2202     gallium_st="$gallium_st xa"
2203 fi
2204 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
2205
2206 if echo $platforms | grep -q "x11"; then
2207     have_xvmc_platform=yes
2208 else
2209     have_xvmc_platform=no
2210 fi
2211
2212 if echo $platforms | grep -q "x11"; then
2213     have_vdpau_platform=yes
2214 else
2215     have_vdpau_platform=no
2216 fi
2217
2218 if echo $platforms | grep -q "x11\|drm"; then
2219     have_omx_platform=yes
2220 else
2221     have_omx_platform=no
2222 fi
2223
2224 if echo $platforms | grep -q "x11\|drm\|wayland"; then
2225     have_va_platform=yes
2226 else
2227     have_va_platform=no
2228 fi
2229
2230 dnl
2231 dnl Gallium G3DVL configuration
2232 dnl
2233 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
2234     if test "x$enable_xvmc" = xauto -a "x$have_xvmc_platform" = xyes; then
2235         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
2236     fi
2237
2238     if test "x$enable_vdpau" = xauto -a "x$have_vdpau_platform" = xyes; then
2239         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
2240     fi
2241
2242     if test "x$enable_omx_bellagio" = xauto -a "x$have_omx_platform" = xyes; then
2243         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx_bellagio=yes], [enable_omx_bellagio=no])
2244     fi
2245
2246     if test "x$enable_omx_tizonia" = xauto -a "x$have_omx_platform" = xyes; then
2247        PKG_CHECK_EXISTS([libtizonia >= $LIBOMXIL_TIZONIA_REQUIRED], [enable_omx_tizonia=yes], [enable_omx_tizonia=no])
2248     fi
2249
2250     if test "x$enable_va" = xauto -a "x$have_va_platform" = xyes; then
2251         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
2252     fi
2253 fi
2254
2255 if test "x$enable_dri" = xyes -o \
2256         "x$enable_xvmc" = xyes -o \
2257         "x$enable_vdpau" = xyes -o \
2258         "x$enable_omx_bellagio" = xyes -o \
2259         "x$enable_omx_tizonia" = xyes -o \
2260         "x$enable_va" = xyes; then
2261     need_gallium_vl=yes
2262 fi
2263 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
2264
2265 if test "x$enable_xvmc" = xyes -o \
2266         "x$enable_vdpau" = xyes -o \
2267         "x$enable_omx_bellagio" = xyes -o \
2268         "x$enable_omx_tizonia" = xyes -o \
2269         "x$enable_va" = xyes; then
2270     if echo $platforms | grep -q "x11"; then
2271         PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2272     fi
2273     need_gallium_vl_winsys=yes
2274 fi
2275 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
2276
2277 if test "x$enable_xvmc" = xyes; then
2278     if test "x$have_xvmc_platform" != xyes; then
2279         AC_MSG_ERROR([XVMC requires the x11 platforms])
2280     fi
2281     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
2282     gallium_st="$gallium_st xvmc"
2283 fi
2284 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
2285
2286 if test "x$enable_vdpau" = xyes; then
2287     if test "x$have_vdpau_platform" != xyes; then
2288         AC_MSG_ERROR([VDPAU requires the x11 platforms])
2289     fi
2290     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
2291     gallium_st="$gallium_st vdpau"
2292     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
2293 fi
2294 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
2295
2296 if test "x$enable_omx_bellagio" = xyes; then
2297     if test "x$have_omx_platform" != xyes; then
2298         AC_MSG_ERROR([OMX requires at least one of the x11 or drm platforms])
2299     fi
2300     PKG_CHECK_MODULES([OMX_BELLAGIO], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
2301     gallium_st="$gallium_st omx_bellagio"
2302     AC_DEFINE([ENABLE_ST_OMX_BELLAGIO], 1, [Use Bellagio for OMX IL])
2303 else
2304     AC_DEFINE([ENABLE_ST_OMX_BELLAGIO], 0)
2305 fi
2306 AM_CONDITIONAL(HAVE_ST_OMX_BELLAGIO, test "x$enable_omx_bellagio" = xyes)
2307
2308 if test "x$enable_omx_tizonia" = xyes; then
2309     if test "x$have_omx_platform" != xyes; then
2310         AC_MSG_ERROR([OMX requires at least one of the x11 or drm platforms])
2311     fi
2312     PKG_CHECK_MODULES([OMX_TIZONIA],
2313                       [libtizonia >= $LIBOMXIL_TIZONIA_REQUIRED
2314                        tizilheaders >= $LIBOMXIL_TIZONIA_REQUIRED
2315                        libtizplatform >= $LIBOMXIL_TIZONIA_REQUIRED])
2316     gallium_st="$gallium_st omx_tizonia"
2317     AC_DEFINE([ENABLE_ST_OMX_TIZONIA], 1, [Use Tizoina for OMX IL])
2318 else
2319     AC_DEFINE([ENABLE_ST_OMX_TIZONIA], 0)
2320 fi
2321 AM_CONDITIONAL(HAVE_ST_OMX_TIZONIA, test "x$enable_omx_tizonia" = xyes)
2322
2323 if test "x$enable_va" = xyes; then
2324     if test "x$have_va_platform" != xyes; then
2325         AC_MSG_ERROR([VA requires at least one of the x11 drm or wayland platforms])
2326     fi
2327     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
2328     gallium_st="$gallium_st va"
2329 fi
2330 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
2331
2332 dnl
2333 dnl Nine Direct3D9 configuration
2334 dnl
2335 if test "x$enable_nine" = xyes; then
2336     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
2337         AC_MSG_ERROR([nine requires the gallium swrast driver])
2338     fi
2339     if test "x$with_gallium_drivers" = xswrast; then
2340         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
2341     fi
2342     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
2343         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
2344     fi
2345
2346     if test "x$enable_dri3" = xno; then
2347         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
2348     fi
2349
2350     gallium_st="$gallium_st nine"
2351 fi
2352 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
2353
2354 dnl
2355 dnl OpenCL configuration
2356 dnl
2357
2358 AC_ARG_WITH([clang-libdir],
2359    [AS_HELP_STRING([--with-clang-libdir],
2360          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
2361    [CLANG_LIBDIR="$withval"],
2362    [CLANG_LIBDIR=''])
2363
2364 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
2365
2366 if test "x$enable_opencl" = xyes; then
2367     if test -z "$with_gallium_drivers"; then
2368         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
2369     fi
2370
2371     if test "x$HAVE_CXX11" != "xyes"; then
2372        AC_MSG_ERROR([clover requires c++11 support])
2373     fi
2374
2375     if test "x$have_libclc" = xno; then
2376         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
2377                     Make sure the directory containing libclc.pc is specified in your
2378                     PKG_CONFIG_PATH environment variable.
2379                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
2380     else
2381         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
2382         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
2383         AC_SUBST([LIBCLC_INCLUDEDIR])
2384         AC_SUBST([LIBCLC_LIBEXECDIR])
2385     fi
2386
2387     gallium_st="$gallium_st clover"
2388
2389     if test "x$enable_opencl_icd" = xyes; then
2390         OPENCL_LIBNAME="MesaOpenCL"
2391     else
2392         OPENCL_LIBNAME="OpenCL"
2393     fi
2394
2395     if test "x$have_libelf" != xyes; then
2396        AC_MSG_ERROR([Clover requires libelf])
2397     fi
2398
2399     if test "x${ac_cv_cxx_compiler_gnu}" = xyes; then
2400         altivec_enabled=no
2401         AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2402         #if !defined(__VEC__) || !defined(__ALTIVEC__)
2403         #error "AltiVec not enabled"
2404         #endif
2405         ])], altivec_enabled=yes)
2406
2407         if test "$altivec_enabled" = yes; then
2408             CLOVER_STD_OVERRIDE="-std=gnu++11"
2409         fi
2410         AC_SUBST([CLOVER_STD_OVERRIDE])
2411     fi
2412
2413     llvm_require_version $LLVM_REQUIRED_OPENCL "opencl"
2414
2415     llvm_add_default_components "opencl"
2416     llvm_add_component "all-targets" "opencl"
2417     llvm_add_component "coverage" "opencl"
2418     llvm_add_component "linker" "opencl"
2419     llvm_add_component "instrumentation" "opencl"
2420     llvm_add_component "ipo" "opencl"
2421     llvm_add_component "irreader" "opencl"
2422     llvm_add_component "lto" "opencl"
2423     llvm_add_component "option" "opencl"
2424     llvm_add_component "objcarcopts" "opencl"
2425     llvm_add_component "profiledata" "opencl"
2426     llvm_add_optional_component "coroutines" "opencl"
2427
2428     dnl Check for Clang internal headers
2429     if test -z "$CLANG_LIBDIR"; then
2430         CLANG_LIBDIR=${LLVM_LIBDIR}
2431     fi
2432     CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2433     AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2434         [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2435 fi
2436 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2437 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2438 AC_SUBST([OPENCL_LIBNAME])
2439 AC_SUBST([CLANG_RESOURCE_DIR])
2440
2441 dnl
2442 dnl Gallium configuration
2443 dnl
2444 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2445
2446 # libEGL wants to default to the first platform specified in
2447 # ./configure.  parse that here.
2448 if test "x$platforms" != "x"; then
2449     FIRST_PLATFORM_CAPS=`echo $platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2450     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2451 else
2452     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2453 fi
2454
2455 AC_SUBST([EGL_NATIVE_PLATFORM])
2456 AC_SUBST([EGL_CFLAGS])
2457
2458 # If we don't have the X11 platform, set this define so we don't try to include
2459 # the X11 headers.
2460 if ! echo "$platforms" | grep -q 'x11'; then
2461     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2462     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2463 fi
2464
2465 dnl Directory for XVMC libs
2466 AC_ARG_WITH([xvmc-libdir],
2467     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2468         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2469     [XVMC_LIB_INSTALL_DIR="$withval"],
2470     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2471 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2472
2473 dnl
2474 dnl Gallium Tests
2475 dnl
2476 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2477
2478 dnl Directory for VDPAU libs
2479 AC_ARG_WITH([vdpau-libdir],
2480     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2481         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2482     [VDPAU_LIB_INSTALL_DIR="$withval"],
2483     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2484 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2485
2486 dnl Directory for OMX_BELLAGIO libs
2487
2488 AC_ARG_WITH([omx-bellagio-libdir],
2489     [AS_HELP_STRING([--with-omx-bellagio-libdir=DIR],
2490         [directory for the OMX_BELLAGIO libraries])],
2491     [OMX_BELLAGIO_LIB_INSTALL_DIR="$withval"],
2492     [OMX_BELLAGIO_LIB_INSTALL_DIR=`$PKG_CONFIG --exists libomxil-bellagio && \
2493                                    $PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2494 AC_SUBST([OMX_BELLAGIO_LIB_INSTALL_DIR])
2495
2496 dnl Directory for OMX_TIZONIA libs
2497
2498 AC_ARG_WITH([omx-tizonia-libdir],
2499     [AS_HELP_STRING([--with-omx-tizonia-libdir=DIR],
2500         [directory for the OMX_TIZONIA libraries])],
2501     [OMX_TIZONIA_LIB_INSTALL_DIR="$withval"],
2502     [OMX_TIZONIA_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libtizcore`])
2503 AC_SUBST([OMX_TIZONIA_LIB_INSTALL_DIR])
2504
2505 dnl Directory for VA libs
2506
2507 AC_ARG_WITH([va-libdir],
2508     [AS_HELP_STRING([--with-va-libdir=DIR],
2509         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2510     [VA_LIB_INSTALL_DIR="$withval"],
2511     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2512 AC_SUBST([VA_LIB_INSTALL_DIR])
2513
2514 AC_ARG_WITH([d3d-libdir],
2515     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2516         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2517     [D3D_DRIVER_INSTALL_DIR="$withval"],
2518     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2519 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2520
2521 dnl Architectures to build SWR library for
2522
2523 AC_ARG_WITH([swr-archs],
2524     [AS_HELP_STRING([--with-swr-archs@<:@=DIRS...@:>@],
2525         [comma delimited swr architectures list, e.g.
2526         "avx,avx2,knl,skx" @<:@default="avx,avx2"@:>@])],
2527     [with_swr_archs="$withval"],
2528     [with_swr_archs="avx,avx2"])
2529
2530 dnl
2531 dnl r300 doesn't strictly require LLVM, but for performance reasons we
2532 dnl highly recommend LLVM usage. So require it at least on x86 and x86_64
2533 dnl architectures.
2534 dnl
2535 r300_require_llvm() {
2536     case "$host" in *gnux32) return;; esac
2537     case "$host_cpu" in
2538     i*86|x86_64|amd64) require_llvm $1
2539         ;;
2540     esac
2541 }
2542
2543 dnl
2544 dnl DRM is needed by X, Wayland, and offscreen rendering.
2545 dnl Surfaceless is an alternative for the last one.
2546 dnl
2547 require_basic_egl() {
2548     case "$with_platforms" in
2549         *drm*|*surfaceless*|*android*)
2550             ;;
2551         *)
2552             AC_MSG_ERROR([$1 requires one of these:
2553                   1) --with-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2554                   2) --with-platforms=surfaceless (offscreen only)
2555                   3) --with-platforms=android (Android only)
2556                   Recommended options: drm,x11])
2557             ;;
2558     esac
2559 }
2560
2561 swr_require_cxx_feature_flags() {
2562     feature_name="$1"
2563     preprocessor_test="$2"
2564     option_list="$3"
2565     output_var="$4"
2566
2567     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2568     AC_LANG_PUSH([C++])
2569     save_CXXFLAGS="$CXXFLAGS"
2570     save_IFS="$IFS"
2571     IFS=","
2572     found=0
2573     for opts in $option_list
2574     do
2575         unset IFS
2576         CXXFLAGS="$opts $save_CXXFLAGS"
2577         AC_COMPILE_IFELSE(
2578             [AC_LANG_PROGRAM(
2579                 [   #if !($preprocessor_test)
2580                     #error
2581                     #endif
2582                 ])],
2583             [found=1; break],
2584             [])
2585         IFS=","
2586     done
2587     IFS="$save_IFS"
2588     CXXFLAGS="$save_CXXFLAGS"
2589     AC_LANG_POP([C++])
2590     if test $found -eq 1; then
2591         AC_MSG_RESULT([$opts])
2592         eval "$output_var=\$opts"
2593         return 0
2594     fi
2595     AC_MSG_RESULT([no])
2596     AC_MSG_ERROR([swr requires $feature_name support])
2597     return 1
2598 }
2599
2600 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2601 if test -n "$with_gallium_drivers"; then
2602     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2603     for driver in $gallium_drivers; do
2604         case "x$driver" in
2605         xsvga)
2606             HAVE_GALLIUM_SVGA=yes
2607             require_libdrm "svga"
2608             ;;
2609         xi915)
2610             HAVE_GALLIUM_I915=yes
2611             PKG_CHECK_MODULES([I915], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2612             require_libdrm "Gallium i915"
2613             ;;
2614         xr300)
2615             HAVE_GALLIUM_R300=yes
2616             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2617             require_libdrm "r300"
2618             r300_require_llvm "r300"
2619             ;;
2620         xr600)
2621             HAVE_GALLIUM_R600=yes
2622             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2623             require_libdrm "r600"
2624             if test "x$enable_llvm" = xyes; then
2625                 radeon_llvm_check $LLVM_REQUIRED_R600 "r600"
2626
2627                 llvm_add_component "asmparser" "r600"
2628                 llvm_add_component "bitreader" "r600"
2629             fi
2630             ;;
2631         xradeonsi)
2632             HAVE_GALLIUM_RADEONSI=yes
2633             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2634             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2635             require_libdrm "radeonsi"
2636             radeon_llvm_check $LLVM_REQUIRED_RADEONSI "radeonsi"
2637             if test "x$enable_egl" = xyes; then
2638                 require_basic_egl "radeonsi"
2639             fi
2640             ;;
2641         xnouveau)
2642             HAVE_GALLIUM_NOUVEAU=yes
2643             PKG_CHECK_MODULES([NOUVEAU], [libdrm >= $LIBDRM_NOUVEAU_REQUIRED libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2644             require_libdrm "nouveau"
2645             ;;
2646         xfreedreno)
2647             HAVE_GALLIUM_FREEDRENO=yes
2648             PKG_CHECK_MODULES([FREEDRENO], [libdrm >= $LIBDRM_FREEDRENO_REQUIRED libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2649             require_libdrm "freedreno"
2650             ;;
2651         xetnaviv)
2652             HAVE_GALLIUM_ETNAVIV=yes
2653             PKG_CHECK_MODULES([ETNAVIV], [libdrm >= $LIBDRM_ETNAVIV_REQUIRED libdrm_etnaviv >= $LIBDRM_ETNAVIV_REQUIRED])
2654             require_libdrm "etnaviv"
2655             ;;
2656        ximx)
2657             HAVE_GALLIUM_IMX=yes
2658             ;;
2659         xtegra)
2660             HAVE_GALLIUM_TEGRA=yes
2661             require_libdrm "tegra"
2662             ;;
2663         xswrast)
2664             HAVE_GALLIUM_SOFTPIPE=yes
2665             if test "x$enable_llvm" = xyes; then
2666                 HAVE_GALLIUM_LLVMPIPE=yes
2667             fi
2668             ;;
2669         xswr)
2670             llvm_require_version $LLVM_REQUIRED_SWR "swr"
2671
2672             if test "x$HAVE_CXX11" != "xyes"; then
2673                 AC_MSG_ERROR([swr requires c++11 support])
2674             fi
2675
2676             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2677                 ",-target-cpu=sandybridge,-mavx,-march=core-avx,-tp=sandybridge" \
2678                 SWR_AVX_CXXFLAGS
2679             AC_SUBST([SWR_AVX_CXXFLAGS])
2680
2681             swr_archs=`IFS=', '; echo $with_swr_archs`
2682             for arch in $swr_archs; do
2683                 case "x$arch" in
2684                 xavx)
2685                     HAVE_SWR_AVX=yes
2686                     ;;
2687                 xavx2)
2688                     swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2689                         ",-target-cpu=haswell,-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2,-tp=haswell" \
2690                         SWR_AVX2_CXXFLAGS
2691                     AC_SUBST([SWR_AVX2_CXXFLAGS])
2692                     HAVE_SWR_AVX2=yes
2693                     ;;
2694                 xknl)
2695                     swr_require_cxx_feature_flags "KNL" "defined(__AVX512F__) && defined(__AVX512ER__)" \
2696                         ",-target-cpu=mic-knl,-march=knl,-xMIC-AVX512" \
2697                         SWR_KNL_CXXFLAGS
2698                     AC_SUBST([SWR_KNL_CXXFLAGS])
2699                     HAVE_SWR_KNL=yes
2700                     ;;
2701                 xskx)
2702                     swr_require_cxx_feature_flags "SKX" "defined(__AVX512F__) && defined(__AVX512BW__)" \
2703                         ",-target-cpu=x86-skylake,-march=skylake-avx512,-xCORE-AVX512" \
2704                         SWR_SKX_CXXFLAGS
2705                     AC_SUBST([SWR_SKX_CXXFLAGS])
2706                     HAVE_SWR_SKX=yes
2707                     ;;
2708                 *)
2709                     AC_MSG_ERROR([unknown SWR build architecture '$arch'])
2710                     ;;
2711                 esac
2712             done
2713
2714             if test "x$HAVE_SWR_AVX" != xyes -a \
2715                     "x$HAVE_SWR_AVX2" != xyes -a \
2716                     "x$HAVE_SWR_KNL" != xyes -a \
2717                     "x$HAVE_SWR_SKX" != xyes; then
2718                AC_MSG_ERROR([swr enabled but no swr architectures selected])
2719             fi
2720
2721             # test if more than one swr arch configured
2722             if test `echo $swr_archs | wc -w` -eq 1; then
2723                 HAVE_SWR_BUILTIN=yes
2724             fi
2725
2726             HAVE_GALLIUM_SWR=yes
2727             ;;
2728         xvc4)
2729             HAVE_GALLIUM_VC4=yes
2730
2731             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2732                               [USE_VC4_SIMULATOR=yes;
2733                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2734                               [USE_VC4_SIMULATOR=no])
2735             ;;
2736         xv3d)
2737             HAVE_GALLIUM_V3D=yes
2738
2739             PKG_CHECK_MODULES([V3D_SIMULATOR], [v3dv3],
2740                               [USE_V3D_SIMULATOR=yes;
2741                                DEFINES="$DEFINES -DUSE_V3D_SIMULATOR"],
2742                               [USE_V3D_SIMULATOR=no])
2743             ;;
2744         xpl111)
2745             HAVE_GALLIUM_PL111=yes
2746             ;;
2747         xvirgl)
2748             HAVE_GALLIUM_VIRGL=yes
2749             require_libdrm "virgl"
2750             if test "x$enable_egl" = xyes; then
2751                 require_basic_egl "virgl"
2752             fi
2753             ;;
2754         *)
2755             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2756             ;;
2757         esac
2758     done
2759 fi
2760
2761 # XXX: Keep in sync with LLVM_REQUIRED_SWR
2762 AM_CONDITIONAL(SWR_INVALID_LLVM_VERSION, test "x$LLVM_VERSION" != x4.0.0 -a \
2763                                               "x$LLVM_VERSION" != x4.0.1)
2764
2765 if test "x$enable_llvm" = "xyes" -a "$with_gallium_drivers"; then
2766     llvm_require_version $LLVM_REQUIRED_GALLIUM "gallium"
2767     llvm_add_default_components "gallium"
2768 fi
2769
2770 AM_CONDITIONAL(HAVE_SWR_AVX, test "x$HAVE_SWR_AVX" = xyes)
2771 AM_CONDITIONAL(HAVE_SWR_AVX2, test "x$HAVE_SWR_AVX2" = xyes)
2772 AM_CONDITIONAL(HAVE_SWR_KNL, test "x$HAVE_SWR_KNL" = xyes)
2773 AM_CONDITIONAL(HAVE_SWR_SKX, test "x$HAVE_SWR_SKX" = xyes)
2774 AM_CONDITIONAL(HAVE_SWR_BUILTIN, test "x$HAVE_SWR_BUILTIN" = xyes)
2775
2776 dnl We need to validate some needed dependencies for renderonly drivers.
2777
2778 if test "x$HAVE_GALLIUM_ETNAVIV" != xyes -a "x$HAVE_GALLIUM_IMX" = xyes  ; then
2779     AC_MSG_ERROR([Building with imx requires etnaviv])
2780 fi
2781
2782 if test "x$HAVE_GALLIUM_VC4" != xyes -a "x$HAVE_GALLIUM_PL111" = xyes  ; then
2783     AC_MSG_ERROR([Building with pl111 requires vc4])
2784 fi
2785
2786 if test "x$HAVE_GALLIUM_NOUVEAU" != xyes -a "x$HAVE_GALLIUM_TEGRA" = xyes; then
2787     AC_MSG_ERROR([Building with tegra requires nouveau])
2788 fi
2789
2790 detect_old_buggy_llvm() {
2791     dnl llvm-config may not give the right answer when llvm is a built as a
2792     dnl single shared library, so we must work the library name out for
2793     dnl ourselves.
2794     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2795     dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2796     LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2797     AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2798
2799     if test "x$llvm_have_one_so" = xyes; then
2800         dnl LLVM was built using auto*, so there is only one shared object.
2801         LLVM_LIBS="-l$LLVM_SO_NAME"
2802     else
2803         dnl If LLVM was built with CMake, there will be one shared object per
2804         dnl component.
2805         AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2806                [AC_MSG_ERROR([Could not find llvm shared libraries:
2807                 Please make sure you have built llvm with the --enable-shared option
2808                 and that your llvm libraries are installed in $LLVM_LIBDIR
2809                 If you have installed your llvm libraries to a different directory you
2810                 can use the --with-llvm-prefix= configure flag to specify this directory.
2811                 NOTE: Mesa is attempting to use llvm shared libraries by default.
2812                 If you do not want to build with llvm shared libraries and instead want to
2813                 use llvm static libraries then add --disable-llvm-shared-libs to your configure
2814                 invocation and rebuild.])])
2815
2816         dnl We don't need to update LLVM_LIBS in this case because the LLVM
2817         dnl install uses a shared object for each component and we have
2818         dnl already added all of these objects to LLVM_LIBS.
2819     fi
2820 }
2821
2822 dnl
2823 dnl Set defines and buildtime variables only when using LLVM.
2824 dnl
2825 if test "x$enable_llvm" = xyes; then
2826     DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2827
2828     LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2829     LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
2830     LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2831
2832     dnl Set LLVM_LIBS - This is done after the driver configuration so
2833     dnl that drivers can add additional components to LLVM_COMPONENTS.
2834     dnl Previously, gallium drivers were updating LLVM_LIBS directly
2835     dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2836     dnl this was causing the same libraries to be appear multiple times
2837     dnl in LLVM_LIBS.
2838
2839     if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 9; then
2840         if test "x$enable_llvm_shared_libs" = xyes; then
2841             LLVM_LIBS="`$LLVM_CONFIG --link-shared --libs ${LLVM_COMPONENTS}`"
2842         else
2843             dnl Invoking llvm-config with both -libs and --system-libs produces the
2844             dnl two separate lines - each for the set of libraries.
2845                 dnl Call the program twice, effectively folding them into a single line.
2846             LLVM_LIBS="`$LLVM_CONFIG --link-static --libs ${LLVM_COMPONENTS}`"
2847             dnl We need to link to llvm system libs when using static libs
2848             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --link-static --system-libs`"
2849         fi
2850     else
2851         LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2852         if test "x$enable_llvm_shared_libs" = xyes; then
2853             detect_old_buggy_llvm
2854         else
2855             AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2856             dnl We need to link to llvm system libs when using static libs
2857             dnl However, only llvm 3.5+ provides --system-libs
2858             if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2859                 LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2860             fi
2861         fi
2862     fi
2863
2864     dnl The gallium-xlib GLX and gallium OSMesa targets directly embed the
2865     dnl swr/llvmpipe driver into the final binary.  Adding LLVM_LIBS results in
2866     dnl the LLVM library propagated in the Libs.private of the respective .pc
2867     dnl file which ensures complete dependency information when statically
2868     dnl linking.
2869     if test "x$enable_glx" == xgallium-xlib; then
2870         GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $LLVM_LIBS"
2871     fi
2872     if test "x$enable_gallium_osmesa" = xyes; then
2873         OSMESA_PC_LIB_PRIV="$OSMESA_PC_LIB_PRIV $LLVM_LIBS"
2874     fi
2875 fi
2876
2877 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2878 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2879 AM_CONDITIONAL(HAVE_GALLIUM_PL111, test "x$HAVE_GALLIUM_PL111" = xyes)
2880 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2881 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2882 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2883 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2884 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2885 AM_CONDITIONAL(HAVE_GALLIUM_ETNAVIV, test "x$HAVE_GALLIUM_ETNAVIV" = xyes)
2886 AM_CONDITIONAL(HAVE_GALLIUM_IMX, test "x$HAVE_GALLIUM_IMX" = xyes)
2887 AM_CONDITIONAL(HAVE_GALLIUM_TEGRA, test "x$HAVE_GALLIUM_TEGRA" = xyes)
2888 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2889 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2890 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2891 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2892                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2893                                          "x$HAVE_GALLIUM_SWR" = xyes)
2894 AM_CONDITIONAL(HAVE_GALLIUM_V3D, test "x$HAVE_GALLIUM_V3D" = xyes)
2895 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2896 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2897
2898 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2899
2900 if test "x$enable_dri" = xyes; then
2901     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2902 fi
2903
2904 if test "x$have_drisw_kms" = xyes; then
2905     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2906 fi
2907 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2908
2909 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2910 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2911 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2912 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2913 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2914 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2915
2916 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2917 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2918
2919 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2920                                       "x$HAVE_RADEON_VULKAN" = xyes)
2921
2922 AM_CONDITIONAL(HAVE_BROADCOM_DRIVERS, test "x$HAVE_GALLIUM_VC4" = xyes -o \
2923                                       "x$HAVE_GALLIUM_V3D" = xyes)
2924
2925 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2926                                         "x$HAVE_I965_DRI" = xyes)
2927
2928 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2929                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2930                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2931 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2932 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2933 AM_CONDITIONAL(HAVE_GALLIUM_LLVM, test "x$enable_llvm" = xyes)
2934 AM_CONDITIONAL(USE_V3D_SIMULATOR, test x$USE_V3D_SIMULATOR = xyes)
2935 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2936
2937 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2938 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2939 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2940 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
2941                                         "x$enable_gallium_osmesa" = xyes)
2942
2943 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2944 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2945 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2946 AM_CONDITIONAL(HAVE_PPC64LE_ASM, test "x$asm_arch" = xppc64le)
2947 AM_CONDITIONAL(HAVE_AARCH64_ASM, test "x$asm_arch" = xaarch64)
2948 AM_CONDITIONAL(HAVE_ARM_ASM, test "x$asm_arch" = xarm)
2949
2950 AC_SUBST([NINE_MAJOR], 1)
2951 AC_SUBST([NINE_MINOR], 0)
2952 AC_SUBST([NINE_PATCH], 0)
2953 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_PATCH")
2954
2955 AC_SUBST([VDPAU_MAJOR], 1)
2956 AC_SUBST([VDPAU_MINOR], 0)
2957
2958 if test "x$enable_va" = xyes; then
2959     VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2960     VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2961 fi
2962 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2963 AC_SUBST([VA_MINOR], $VA_MINOR)
2964
2965 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
2966
2967 AC_SUBST([XVMC_MAJOR], 1)
2968 AC_SUBST([XVMC_MINOR], 0)
2969
2970 AC_SUBST([XA_MAJOR], 2)
2971 AC_SUBST([XA_MINOR], 4)
2972 AC_SUBST([XA_PATCH], 0)
2973 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_PATCH")
2974
2975 AC_ARG_ENABLE(valgrind,
2976               [AS_HELP_STRING([--enable-valgrind],
2977                              [Build mesa with valgrind support (default: auto)])],
2978                              [VALGRIND=$enableval], [VALGRIND=auto])
2979 if test "x$VALGRIND" != xno; then
2980     PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2981 fi
2982 AC_MSG_CHECKING([whether to enable Valgrind support])
2983 if test "x$VALGRIND" = xauto; then
2984     VALGRIND="$have_valgrind"
2985 fi
2986
2987 if test "x$VALGRIND" = "xyes"; then
2988     if ! test "x$have_valgrind" = xyes; then
2989         AC_MSG_ERROR([Valgrind support required but not present])
2990     fi
2991     AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2992 fi
2993
2994 AC_MSG_RESULT([$VALGRIND])
2995
2996 dnl Restore LDFLAGS and CPPFLAGS
2997 LDFLAGS="$_SAVE_LDFLAGS"
2998 CPPFLAGS="$_SAVE_CPPFLAGS"
2999
3000 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
3001 if test "x$acv_mesa_CLANG" = xyes; then
3002     CFLAGS="$CFLAGS -Qunused-arguments"
3003     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
3004 fi
3005
3006 dnl Add user CFLAGS and CXXFLAGS
3007 CFLAGS="$CFLAGS $USER_CFLAGS"
3008 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
3009
3010 dnl Substitute the config
3011 AC_CONFIG_FILES([Makefile
3012                  src/Makefile
3013                  src/amd/Makefile
3014                  src/amd/vulkan/Makefile
3015                  src/broadcom/Makefile
3016                  src/compiler/Makefile
3017                  src/egl/Makefile
3018                  src/egl/main/egl.pc
3019                  src/egl/wayland/wayland-drm/Makefile
3020                  src/egl/wayland/wayland-egl/Makefile
3021                  src/egl/wayland/wayland-egl/wayland-egl.pc
3022                  src/gallium/Makefile
3023                  src/gallium/auxiliary/Makefile
3024                  src/gallium/auxiliary/pipe-loader/Makefile
3025                  src/gallium/drivers/freedreno/Makefile
3026                  src/gallium/drivers/i915/Makefile
3027                  src/gallium/drivers/llvmpipe/Makefile
3028                  src/gallium/drivers/nouveau/Makefile
3029                  src/gallium/drivers/pl111/Makefile
3030                  src/gallium/drivers/r300/Makefile
3031                  src/gallium/drivers/r600/Makefile
3032                  src/gallium/drivers/radeonsi/Makefile
3033                  src/gallium/drivers/softpipe/Makefile
3034                  src/gallium/drivers/svga/Makefile
3035                  src/gallium/drivers/swr/Makefile
3036                  src/gallium/drivers/tegra/Makefile
3037                  src/gallium/drivers/etnaviv/Makefile
3038                  src/gallium/drivers/imx/Makefile
3039                  src/gallium/drivers/v3d/Makefile
3040                  src/gallium/drivers/vc4/Makefile
3041                  src/gallium/drivers/virgl/Makefile
3042                  src/gallium/state_trackers/clover/Makefile
3043                  src/gallium/state_trackers/dri/Makefile
3044                  src/gallium/state_trackers/glx/xlib/Makefile
3045                  src/gallium/state_trackers/nine/Makefile
3046                  src/gallium/state_trackers/omx/Makefile
3047                  src/gallium/state_trackers/omx/bellagio/Makefile
3048                  src/gallium/state_trackers/omx/tizonia/Makefile
3049                  src/gallium/state_trackers/osmesa/Makefile
3050                  src/gallium/state_trackers/va/Makefile
3051                  src/gallium/state_trackers/vdpau/Makefile
3052                  src/gallium/state_trackers/xa/Makefile
3053                  src/gallium/state_trackers/xa/xa_tracker.h
3054                  src/gallium/state_trackers/xvmc/Makefile
3055                  src/gallium/targets/d3dadapter9/Makefile
3056                  src/gallium/targets/d3dadapter9/d3d.pc
3057                  src/gallium/targets/dri/Makefile
3058                  src/gallium/targets/libgl-xlib/Makefile
3059                  src/gallium/targets/omx/Makefile
3060                  src/gallium/targets/opencl/Makefile
3061                  src/gallium/targets/opencl/mesa.icd
3062                  src/gallium/targets/osmesa/Makefile
3063                  src/gallium/targets/osmesa/osmesa.pc
3064                  src/gallium/targets/pipe-loader/Makefile
3065                  src/gallium/targets/va/Makefile
3066                  src/gallium/targets/vdpau/Makefile
3067                  src/gallium/targets/xa/Makefile
3068                  src/gallium/targets/xa/xatracker.pc
3069                  src/gallium/targets/xvmc/Makefile
3070                  src/gallium/tests/trivial/Makefile
3071                  src/gallium/tests/unit/Makefile
3072                  src/gallium/winsys/etnaviv/drm/Makefile
3073                  src/gallium/winsys/imx/drm/Makefile
3074                  src/gallium/winsys/freedreno/drm/Makefile
3075                  src/gallium/winsys/i915/drm/Makefile
3076                  src/gallium/winsys/nouveau/drm/Makefile
3077                  src/gallium/winsys/pl111/drm/Makefile
3078                  src/gallium/winsys/radeon/drm/Makefile
3079                  src/gallium/winsys/amdgpu/drm/Makefile
3080                  src/gallium/winsys/svga/drm/Makefile
3081                  src/gallium/winsys/sw/dri/Makefile
3082                  src/gallium/winsys/sw/kms-dri/Makefile
3083                  src/gallium/winsys/sw/null/Makefile
3084                  src/gallium/winsys/sw/wrapper/Makefile
3085                  src/gallium/winsys/sw/xlib/Makefile
3086                  src/gallium/winsys/tegra/drm/Makefile
3087                  src/gallium/winsys/v3d/drm/Makefile
3088                  src/gallium/winsys/vc4/drm/Makefile
3089                  src/gallium/winsys/virgl/drm/Makefile
3090                  src/gallium/winsys/virgl/vtest/Makefile
3091                  src/gbm/Makefile
3092                  src/gbm/main/gbm.pc
3093                  src/glx/Makefile
3094                  src/glx/apple/Makefile
3095                  src/glx/tests/Makefile
3096                  src/glx/windows/Makefile
3097                  src/glx/windows/windowsdriproto.pc
3098                  src/gtest/Makefile
3099                  src/intel/Makefile
3100                  src/loader/Makefile
3101                  src/mapi/Makefile
3102                  src/mapi/es1api/glesv1_cm.pc
3103                  src/mapi/es2api/glesv2.pc
3104                  src/mapi/glapi/gen/Makefile
3105                  src/mesa/Makefile
3106                  src/mesa/gl.pc
3107                  src/mesa/drivers/dri/dri.pc
3108                  src/mesa/drivers/dri/common/Makefile
3109                  src/mesa/drivers/dri/i915/Makefile
3110                  src/mesa/drivers/dri/i965/Makefile
3111                  src/mesa/drivers/dri/Makefile
3112                  src/mesa/drivers/dri/nouveau/Makefile
3113                  src/mesa/drivers/dri/r200/Makefile
3114                  src/mesa/drivers/dri/radeon/Makefile
3115                  src/mesa/drivers/dri/swrast/Makefile
3116                  src/mesa/drivers/osmesa/Makefile
3117                  src/mesa/drivers/osmesa/osmesa.pc
3118                  src/mesa/drivers/x11/Makefile
3119                  src/mesa/main/tests/Makefile
3120                  src/mesa/state_tracker/tests/Makefile
3121                  src/util/Makefile
3122                  src/util/tests/hash_table/Makefile
3123                  src/util/tests/string_buffer/Makefile
3124                  src/util/xmlpool/Makefile
3125                  src/vulkan/Makefile])
3126
3127 AC_OUTPUT
3128
3129 # Fix up dependencies in *.Plo files, where we changed the extension of a
3130 # source file
3131 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
3132
3133 rm -f src/compiler/spirv/spirv_info.lo
3134 echo "# dummy" > src/compiler/spirv/.deps/spirv_info.Plo
3135
3136 rm -f src/compiler/nir/.deps/nir_intrinsics.Plo
3137 echo "# dummy" > src/compiler/nir/.deps/nir_intrinsics.Plo
3138
3139 dnl
3140 dnl Output some configuration info for the user
3141 dnl
3142 echo ""
3143 echo "        prefix:          $prefix"
3144 echo "        exec_prefix:     $exec_prefix"
3145 echo "        libdir:          $libdir"
3146 echo "        includedir:      $includedir"
3147
3148 dnl API info
3149 echo ""
3150 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
3151
3152 dnl Driver info
3153 echo ""
3154 case "x$enable_osmesa$enable_gallium_osmesa" in
3155 xnoyes)
3156         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
3157         ;;
3158 xyesno)
3159         echo "        OSMesa:          lib$OSMESA_LIB"
3160         ;;
3161 xnono)
3162         echo "        OSMesa:          no"
3163         ;;
3164 esac
3165
3166 echo ""
3167 if test "x$enable_dri" != xno; then
3168         echo "        DRI platform:    $dri_platform"
3169         if test -z "$DRI_DIRS"; then
3170             echo "        DRI drivers:     no"
3171         else
3172             echo "        DRI drivers:     $DRI_DIRS"
3173         fi
3174         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
3175 fi
3176
3177 case "x$enable_glx" in
3178 xdri)
3179     echo "        GLX:             DRI-based"
3180     ;;
3181 xxlib)
3182     echo "        GLX:             Xlib-based"
3183     ;;
3184 xgallium-xlib)
3185     echo "        GLX:             Xlib-based (Gallium)"
3186     ;;
3187 *)
3188     echo "        GLX:             $enable_glx"
3189     ;;
3190 esac
3191
3192 dnl EGL
3193 echo ""
3194 echo "        EGL:             $enable_egl"
3195 if test "$enable_egl" = yes; then
3196
3197     egl_drivers=""
3198     if test "x$enable_dri" != "xno"; then
3199         egl_drivers="$egl_drivers builtin:egl_dri2"
3200     fi
3201     if test "x$enable_dri3" != "xno"; then
3202         egl_drivers="$egl_drivers builtin:egl_dri3"
3203     fi
3204
3205     echo "        EGL drivers:    $egl_drivers"
3206 fi
3207 if test "x$enable_gbm" = xyes; then
3208     echo "        GBM:             yes"
3209 else
3210     echo "        GBM:             no"
3211 fi
3212
3213     echo "        EGL/Vulkan/VL platforms:   $platforms"
3214
3215 # Vulkan
3216 echo ""
3217 if test "x$VULKAN_DRIVERS" != x; then
3218     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
3219     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
3220 else
3221     echo "        Vulkan drivers:  no"
3222 fi
3223
3224 echo ""
3225 if test "x$enable_llvm" = xyes; then
3226     echo "        llvm:            yes"
3227     echo "        llvm-config:     $LLVM_CONFIG"
3228     echo "        llvm-version:    $LLVM_VERSION"
3229 else
3230     echo "        llvm:            no"
3231 fi
3232
3233 echo ""
3234 if test -n "$with_gallium_drivers"; then
3235     echo "        Gallium drivers: $gallium_drivers"
3236     echo "        Gallium st:      $gallium_st"
3237 else
3238     echo "        Gallium:         no"
3239 fi
3240
3241 echo ""
3242 if test "x$enable_gallium_extra_hud" != xyes; then
3243     echo "        HUD extra stats: no"
3244 else
3245     echo "        HUD extra stats: yes"
3246 fi
3247
3248 if test "x$enable_lmsensors" != xyes; then
3249     echo "        HUD lmsensors:   no"
3250 else
3251     echo "        HUD lmsensors:   yes"
3252 fi
3253
3254 echo ""
3255 if test "x$HAVE_GALLIUM_SWR" != x; then
3256     if test "x$HAVE_SWR_BUILTIN" = xyes; then
3257         echo "        SWR archs:       $swr_archs (builtin)"
3258     else
3259         echo "        SWR archs:       $swr_archs"
3260     fi
3261 fi
3262
3263 dnl Libraries
3264 echo ""
3265 echo "        Shared libs:     $enable_shared"
3266 echo "        Static libs:     $enable_static"
3267 echo "        Shared-glapi:    $enable_shared_glapi"
3268
3269 dnl Compiler options
3270 # cleanup the CFLAGS/CXXFLAGS/LDFLAGS/DEFINES vars
3271 cflags=`echo $CFLAGS | \
3272     $SED 's/^ *//;s/  */ /;s/ *$//'`
3273 cxxflags=`echo $CXXFLAGS | \
3274     $SED 's/^ *//;s/  */ /;s/ *$//'`
3275 ldflags=`echo $LDFLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
3276 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
3277 echo ""
3278 echo "        CFLAGS:          $cflags"
3279 echo "        CXXFLAGS:        $cxxflags"
3280 echo "        CXX11_CXXFLAGS:  $CXX11_CXXFLAGS"
3281 echo "        LDFLAGS:         $ldflags"
3282 echo "        Macros:          $defines"
3283 echo ""
3284 if test "x$enable_llvm" = xyes; then
3285     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
3286     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
3287     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
3288     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
3289     echo ""
3290 fi
3291 echo "        PYTHON2:         $PYTHON2"
3292
3293 echo ""
3294 echo "        Run '${MAKE-make}' to build Mesa"
3295 echo ""