configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl
  13 dnl Permission is hereby granted, free of charge, to any person obtaining a
  14 dnl copy of this software and associated documentation files (the "Software"),
  15 dnl to deal in the Software without restriction, including without limitation
  16 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  17 dnl and/or sell copies of the Software, and to permit persons to whom the
  18 dnl Software is furnished to do so, subject to the following conditions:
  19 dnl
  20 dnl The above copyright notice and this permission notice (including the next
  21 dnl paragraph) shall be included in all copies or substantial portions of the
  22 dnl Software.
  23 dnl
  24 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  25 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  26 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  27 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  28 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  29 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  30 dnl DEALINGS IN THE SOFTWARE.
  31 dnl
  32 dnl Process this file with autoconf to create configure.
  33
  34 AC_PREREQ([2.60])
  35
  36 dnl Tell the user about autoconf.html in the --help output
  37 m4_divert_once([HELP_END], [
  38 See docs/autoconf.html for more details on the options for Mesa.])
  39
  40 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  41 AC_INIT([Mesa], [MESA_VERSION],
  42     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  43 AC_CONFIG_AUX_DIR([bin])
  44 AC_CONFIG_MACRO_DIR([m4])
  45 AC_CANONICAL_SYSTEM
  46 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  47
  48 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  49 case "$host_os" in
  50 mingw*)
  51     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  52     ;;
  53 esac
  54
  55 # Support silent build rules, requires at least automake-1.11. Disable
  56 # by either passing --disable-silent-rules to configure or passing V=1
  57 # to make
  58 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  59     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  60
  61 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  62
  63 dnl Set internal versions
  64 OSMESA_VERSION=8
  65 AC_SUBST([OSMESA_VERSION])
  66 OPENCL_VERSION=1
  67 AC_SUBST([OPENCL_VERSION])
  68
  69 # The idea is that libdrm is distributed as one cohesive package, even
  70 # though it is composed of multiple libraries. However some drivers
  71 # may have different version requirements than others. This list
  72 # codifies which drivers need which version of libdrm. Any libdrm
  73 # version dependencies in non-driver-specific code should be reflected
  74 # in the first entry.
  75 LIBDRM_REQUIRED=2.4.75
  76 LIBDRM_RADEON_REQUIRED=2.4.71
  77 LIBDRM_AMDGPU_REQUIRED=2.4.95
  78 LIBDRM_INTEL_REQUIRED=2.4.75
  79 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  80 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  81 LIBDRM_ETNAVIV_REQUIRED=2.4.89
  82 LIBDRM_VC4_REQUIRED=2.4.89
  83
  84 dnl Versions for external dependencies
  85 DRI2PROTO_REQUIRED=2.8
  86 GLPROTO_REQUIRED=1.4.14
  87 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  88 LIBOMXIL_TIZONIA_REQUIRED=0.10.0
  89 LIBVA_REQUIRED=0.39.0
  90 VDPAU_REQUIRED=1.1
  91 WAYLAND_REQUIRED=1.11
  92 WAYLAND_EGL_BACKEND_REQUIRED=3
  93 WAYLAND_PROTOCOLS_REQUIRED=1.8
  94 XCB_REQUIRED=1.9.3
  95 XCBDRI2_REQUIRED=1.8
  96 XCBDRI3_MODIFIERS_REQUIRED=1.13
  97 XCBGLX_REQUIRED=1.8.1
  98 XCBPRESENT_MODIFIERS_REQUIRED=1.13
  99 XDAMAGE_REQUIRED=1.1
 100 XSHMFENCE_REQUIRED=1.1
 101 XVMC_REQUIRED=1.0.6
 102 PYTHON_MAKO_REQUIRED=0.8.0
 103 LIBSENSORS_REQUIRED=4.0.0
 104 ZLIB_REQUIRED=1.2.3
 105
 106 dnl LLVM versions
 107 LLVM_REQUIRED_GALLIUM=3.3.0
 108 LLVM_REQUIRED_OPENCL=3.9.0
 109 LLVM_REQUIRED_R600=3.9.0
 110 LLVM_REQUIRED_RADEONSI=6.0.0
 111 LLVM_REQUIRED_RADV=6.0.0
 112 LLVM_REQUIRED_SWR=6.0.0
 113
 114 dnl Check for progs
 115 AC_PROG_CPP
 116 AC_PROG_CC
 117 AC_PROG_CXX
 118 dnl add this here, so the help for this environmnet variable is close to
 119 dnl other CC/CXX flags related help
 120 AC_ARG_VAR([CXX11_CXXFLAGS], [Compiler flag to enable C++11 support (only needed if not
 121                               enabled by default and different  from -std=c++11)])
 122 AM_PROG_CC_C_O
 123 AC_PROG_GREP
 124 AC_PROG_NM
 125 AM_PROG_AS
 126 AX_CHECK_GNU_MAKE
 127 AM_PATH_PYTHON([2.7],, [:])
 128 PYTHON2=$PYTHON
 129 AC_SUBST([PYTHON2])
 130
 131 AC_PROG_SED
 132 AC_PROG_MKDIR_P
 133
 134 AC_SYS_LARGEFILE
 135
 136
 137 LT_PREREQ([2.2])
 138 LT_INIT([disable-static])
 139
 140 AC_CHECK_PROG(RM, rm, [rm -f])
 141
 142 AX_PROG_BISON([],
 143               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 144                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 145 AX_PROG_FLEX([],
 146              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 147                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 148
 149 AC_CHECK_PROG(INDENT, indent, indent, cat)
 150 if test "x$INDENT" != "xcat"; then
 151     # Only GNU indent is supported
 152     INDENT_VERSION=`indent --version | grep GNU`
 153     if test $? -eq 0; then
 154        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 155     else
 156        INDENT="cat"
 157     fi
 158 fi
 159
 160 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 161
 162 if test "$PYTHON2" = ":"; then
 163     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 164         AC_MSG_ERROR([Python not found - unable to generate sources])
 165     fi
 166 else
 167     if test "x$acv_mako_found" = xno; then
 168         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 169             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 170         fi
 171     fi
 172 fi
 173
 174 AC_PROG_INSTALL
 175
 176 dnl We need a POSIX shell for parts of the build. Assume we have one
 177 dnl in most cases.
 178 case "$host_os" in
 179 solaris*)
 180     # Solaris /bin/sh is too old/non-POSIX compliant
 181     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 182     SHELL="$POSIX_SHELL"
 183     ;;
 184 esac
 185
 186 dnl clang is mostly GCC-compatible, but its version is much lower,
 187 dnl so we have to check for it.
 188 AC_MSG_CHECKING([if compiling with clang])
 189
 190 AC_COMPILE_IFELSE(
 191 [AC_LANG_PROGRAM([], [[
 192 #ifndef __clang__
 193        not clang
 194 #endif
 195 ]])],
 196 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 197
 198 AC_MSG_RESULT([$acv_mesa_CLANG])
 199
 200 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 201 dnl versions are explictly not supported.
 202 GEN_ASM_OFFSETS=no
 203 USE_GNU99=no
 204 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 205     AC_MSG_CHECKING([whether gcc version is sufficient])
 206     major=0
 207     minor=0
 208
 209     GCC_VERSION=`$CC -dumpversion`
 210     if test $? -eq 0; then
 211         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 212         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 213     fi
 214
 215     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 216         AC_MSG_RESULT([no])
 217         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 218     else
 219         AC_MSG_RESULT([yes])
 220     fi
 221
 222     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 223         USE_GNU99=yes
 224     fi
 225     if test "x$cross_compiling" = xyes; then
 226         GEN_ASM_OFFSETS=yes
 227     fi
 228 fi
 229
 230 dnl We don't support building Mesa with Sun C compiler
 231 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 232 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 233 if test "x$SUNCC" = xyes; then
 234     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 235 fi
 236
 237 dnl Check for compiler builtins
 238 AX_GCC_BUILTIN([__builtin_bswap32])
 239 AX_GCC_BUILTIN([__builtin_bswap64])
 240 AX_GCC_BUILTIN([__builtin_clz])
 241 AX_GCC_BUILTIN([__builtin_clzll])
 242 AX_GCC_BUILTIN([__builtin_ctz])
 243 AX_GCC_BUILTIN([__builtin_expect])
 244 AX_GCC_BUILTIN([__builtin_ffs])
 245 AX_GCC_BUILTIN([__builtin_ffsll])
 246 AX_GCC_BUILTIN([__builtin_popcount])
 247 AX_GCC_BUILTIN([__builtin_popcountll])
 248 AX_GCC_BUILTIN([__builtin_unreachable])
 249
 250 AX_GCC_FUNC_ATTRIBUTE([const])
 251 AX_GCC_FUNC_ATTRIBUTE([flatten])
 252 AX_GCC_FUNC_ATTRIBUTE([format])
 253 AX_GCC_FUNC_ATTRIBUTE([malloc])
 254 AX_GCC_FUNC_ATTRIBUTE([packed])
 255 AX_GCC_FUNC_ATTRIBUTE([pure])
 256 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 257 AX_GCC_FUNC_ATTRIBUTE([unused])
 258 AX_GCC_FUNC_ATTRIBUTE([visibility])
 259 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 260 AX_GCC_FUNC_ATTRIBUTE([weak])
 261 AX_GCC_FUNC_ATTRIBUTE([alias])
 262 AX_GCC_FUNC_ATTRIBUTE([noreturn])
 263
 264 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 265
 266 dnl Make sure the pkg-config macros are defined
 267 m4_ifndef([PKG_PROG_PKG_CONFIG],
 268     [m4_fatal([Could not locate the pkg-config autoconf macros.
 269   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 270   are in a different location, try setting the environment variable
 271   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 272 PKG_PROG_PKG_CONFIG()
 273
 274 dnl LIB_DIR - library basename
 275 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 276 AC_SUBST([LIB_DIR])
 277
 278 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 279 _SAVE_LDFLAGS="$LDFLAGS"
 280 _SAVE_CPPFLAGS="$CPPFLAGS"
 281
 282 dnl Compiler macros
 283 DEFINES="-D__STDC_CONSTANT_MACROS -D__STDC_FORMAT_MACROS -D__STDC_LIMIT_MACROS"
 284 AC_SUBST([DEFINES])
 285 android=no
 286 case "$host_os" in
 287 *-android*)
 288     android=yes
 289     ;;
 290 linux*|*-gnu*|gnu*|cygwin*)
 291     DEFINES="$DEFINES -D_GNU_SOURCE"
 292     ;;
 293 solaris*)
 294     DEFINES="$DEFINES -DSVR4"
 295     ;;
 296 esac
 297
 298 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 299
 300 # Toggle Werror since at some point clang started treating unknown -W
 301 # flags as warnings, succeeding with the build, yet issuing an annoying
 302 # warning.
 303 save_CFLAGS="$CFLAGS"
 304 export CFLAGS="$CFLAGS -Werror"
 305
 306 dnl
 307 dnl Check compiler flags
 308 dnl
 309 AX_CHECK_COMPILE_FLAG([-Wall],                                 [CFLAGS="$CFLAGS -Wall"])
 310 AX_CHECK_COMPILE_FLAG([-Werror=implicit-function-declaration], [CFLAGS="$CFLAGS -Werror=implicit-function-declaration"])
 311 AX_CHECK_COMPILE_FLAG([-Werror=missing-prototypes],            [CFLAGS="$CFLAGS -Werror=missing-prototypes"])
 312 AX_CHECK_COMPILE_FLAG([-Wmissing-prototypes],                  [CFLAGS="$CFLAGS -Wmissing-prototypes"])
 313 dnl Dylan Baker: gcc and clang always accepr -Wno-*, hence check for the original warning, then set the no-* flag
 314 AX_CHECK_COMPILE_FLAG([-Wmissing-field-initializers],          [CFLAGS="$CFLAGS -Wno-missing-field-initializers"])
 315 AX_CHECK_COMPILE_FLAG([-Wformat-truncation],                   [CFLAGS="$CFLAGS -Wno-format-truncation"])
 316 AX_CHECK_COMPILE_FLAG([-fno-math-errno],                       [CFLAGS="$CFLAGS -fno-math-errno"])
 317
 318 AX_CHECK_COMPILE_FLAG([-fno-trapping-math],                    [CFLAGS="$CFLAGS -fno-trapping-math"])
 319 AX_CHECK_COMPILE_FLAG([-fvisibility=hidden],                   [VISIBILITY_CFLAGS="-fvisibility=hidden"])
 320
 321 CFLAGS="$save_CFLAGS"
 322
 323 # Toggle Werror since at some point clang started treating unknown -W
 324 # flags as warnings, succeeding with the build, yet issuing an annoying
 325 # warning.
 326 dnl
 327 dnl Check C++ compiler flags
 328 dnl
 329 AC_LANG_PUSH([C++])
 330 AX_CHECK_COMPILE_FLAG([-Wall],                                 [CXXFLAGS="$CXXFLAGS -Wall"])
 331 AX_CHECK_COMPILE_FLAG([-fno-math-errno],                       [CXXFLAGS="$CXXFLAGS -fno-math-errno"])
 332 AX_CHECK_COMPILE_FLAG([-fno-trapping-math],                    [CXXFLAGS="$CXXFLAGS -fno-trapping-math"])
 333 AX_CHECK_COMPILE_FLAG([-fvisibility=hidden],                   [VISIBILITY_CXXFLAGS="-fvisibility=hidden"])
 334 AX_CHECK_COMPILE_FLAG([-Wmissing-field-initializers],          [CXXFLAGS="$CXXFLAGS -Wno-missing-field-initializers"])
 335 AX_CHECK_COMPILE_FLAG([-Wformat-truncation],                   [CXXFLAGS="$CXXFLAGS -Wno-format-truncation"])
 336 AC_LANG_POP([C++])
 337
 338 # Flags to help ensure that certain portions of the code -- and only those
 339 # portions -- can be built with MSVC:
 340 # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 341 # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 342 #   supports most of C99)
 343 # - the rest has no compiler compiler restrictions
 344 AX_CHECK_COMPILE_FLAG([-Werror=pointer-arith],                 [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=pointer-arith"])
 345 AX_CHECK_COMPILE_FLAG([-Werror=vla],                           [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla"])
 346 AC_LANG_PUSH([C++])
 347 AX_CHECK_COMPILE_FLAG([-Werror=pointer-arith],                 [MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=pointer-arith"])
 348 AX_CHECK_COMPILE_FLAG([-Werror=vla],                           [MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla"])
 349 AC_LANG_POP([C++])
 350
 351 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 352 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 353
 354 if test "x$GCC" = xyes; then
 355     if test "x$USE_GNU99" = xyes; then
 356         CFLAGS="$CFLAGS -std=gnu99"
 357     else
 358         CFLAGS="$CFLAGS -std=c99"
 359     fi
 360 fi
 361
 362 dnl
 363 dnl Check whether C++11 is supported, if the environment variable
 364 dnl CXX11_CXXFLAGS is set it takes precedence.
 365 dnl
 366
 367 AC_LANG_PUSH([C++])
 368
 369 check_cxx11_available() {
 370     output_support=$1
 371     AC_COMPILE_IFELSE(
 372         [AC_LANG_PROGRAM([
 373              #if !(__cplusplus >= 201103L)
 374              #error
 375              #endif
 376              #include <tuple>
 377         ])
 378     ], [
 379          AC_MSG_RESULT(yes)
 380          cxx11_support=yes
 381     ], AC_MSG_RESULT(no))
 382     eval "$output_support=\$cxx11_support"
 383 }
 384
 385 HAVE_CXX11=no
 386 save_CXXFLAGS="$CXXFLAGS"
 387
 388 dnl If the user provides a flag to enable c++11, then we test only this
 389 if test "x$CXX11_CXXFLAGS" != "x"; then
 390    CXXFLAGS="$CXXFLAGS $CXX11_CXXFLAGS"
 391    AC_MSG_CHECKING(whether c++11 is enabled by via $CXX11_CXXFLAGS)
 392    check_cxx11_available HAVE_CXX11
 393 else
 394    dnl test whether c++11 is enabled by default
 395    AC_MSG_CHECKING(whether c++11 is enabled by default)
 396    check_cxx11_available HAVE_CXX11
 397
 398    dnl C++11 not enabled by default, test whether -std=c++11 does the job
 399    if test "x$HAVE_CXX11" != "xyes"; then
 400        CXX11_CXXFLAGS=-std=c++11
 401        CXXFLAGS="$CXXFLAGS $CXX11_CXXFLAGS"
 402        AC_MSG_CHECKING(whether c++11 is enabled by via $CXX11_CXXFLAGS)
 403        check_cxx11_available HAVE_CXX11
 404    fi
 405 fi
 406
 407 CXXFLAGS="$save_CXXFLAGS"
 408 AM_CONDITIONAL(HAVE_STD_CXX11, test "x$HAVE_CXX11" = "xyes")
 409 AC_SUBST(CXX11_CXXFLAGS)
 410 AC_LANG_POP([C++])
 411
 412 dnl even if the compiler appears to support it, using visibility attributes isn't
 413 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 414 case "$host_os" in
 415 cygwin*)
 416     VISIBILITY_CFLAGS=""
 417     VISIBILITY_CXXFLAGS=""
 418     ;;
 419 esac
 420
 421 AC_SUBST([VISIBILITY_CFLAGS])
 422 AC_SUBST([VISIBILITY_CXXFLAGS])
 423
 424 dnl For some reason, the test for -Wno-foo always succeeds with gcc, even if the
 425 dnl option is not supported. Hence, check for -Wfoo instead.
 426 AX_CHECK_COMPILE_FLAG([-Woverride-init],                    [WNO_OVERRIDE_INIT="$WNO_OVERRIDE_INIT -Wno-override-init"])         # gcc
 427 AX_CHECK_COMPILE_FLAG([-Winitializer-overrides],            [WNO_OVERRIDE_INIT="$WNO_OVERRIDE_INIT -Wno-initializer-overrides"]) # clang
 428 AC_SUBST([WNO_OVERRIDE_INIT])
 429
 430 dnl
 431 dnl Optional flags, check for compiler support
 432 dnl
 433 SSE41_CFLAGS="-msse4.1"
 434 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 435 dnl stack, but on x86-32 such alignment is not guaranteed.
 436 case "$target_cpu" in
 437 i?86)
 438     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 439     ;;
 440 esac
 441 save_CFLAGS="$CFLAGS"
 442 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 443 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 444 #include <smmintrin.h>
 445 int param;
 446 int main () {
 447     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 448     c = _mm_max_epu32(a, b);
 449     return _mm_cvtsi128_si32(c);
 450 }]])], SSE41_SUPPORTED=1)
 451 CFLAGS="$save_CFLAGS"
 452 if test "x$SSE41_SUPPORTED" = x1; then
 453     DEFINES="$DEFINES -DUSE_SSE41"
 454 fi
 455 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 456 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 457
 458 dnl Check for new-style atomic builtins. We first check without linking to
 459 dnl -latomic.
 460 AC_MSG_CHECKING(whether __atomic_load_n is supported)
 461 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 462 #include <stdint.h>
 463 int main() {
 464     struct {
 465         uint64_t *v;
 466     } x;
 467     return (int)__atomic_load_n(x.v, __ATOMIC_ACQUIRE) &
 468            (int)__atomic_add_fetch(x.v, (uint64_t)1, __ATOMIC_ACQ_REL);
 469 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=yes, GCC_ATOMIC_BUILTINS_SUPPORTED=no)
 470
 471 dnl If that didn't work, we try linking with -latomic, which is needed on some
 472 dnl platforms.
 473 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" != xyes; then
 474    save_LDFLAGS=$LDFLAGS
 475    LDFLAGS="$LDFLAGS -latomic"
 476    AC_LINK_IFELSE([AC_LANG_SOURCE([[
 477    #include <stdint.h>
 478    int main() {
 479         struct {
 480             uint64_t *v;
 481         } x;
 482         return (int)__atomic_load_n(x.v, __ATOMIC_ACQUIRE) &
 483                (int)__atomic_add_fetch(x.v, (uint64_t)1, __ATOMIC_ACQ_REL);
 484    }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=yes LIBATOMIC_LIBS="-latomic",
 485           GCC_ATOMIC_BUILTINS_SUPPORTED=no)
 486    LDFLAGS=$save_LDFLAGS
 487 fi
 488 AC_MSG_RESULT($GCC_ATOMIC_BUILTINS_SUPPORTED)
 489
 490 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = xyes; then
 491     DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
 492 fi
 493 AC_SUBST([LIBATOMIC_LIBS])
 494
 495 dnl Check if host supports 64-bit atomics
 496 dnl note that lack of support usually results in link (not compile) error
 497 AC_MSG_CHECKING(whether __sync_add_and_fetch_8 is supported)
 498 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 499 #include <stdint.h>
 500 uint64_t v;
 501 int main() {
 502     return __sync_add_and_fetch(&v, (uint64_t)1);
 503 }]])], GCC_64BIT_ATOMICS_SUPPORTED=yes, GCC_64BIT_ATOMICS_SUPPORTED=no)
 504 if test "x$GCC_64BIT_ATOMICS_SUPPORTED" != xyes; then
 505     DEFINES="$DEFINES -DMISSING_64BIT_ATOMICS"
 506 fi
 507 AC_MSG_RESULT($GCC_64BIT_ATOMICS_SUPPORTED)
 508
 509 dnl Check for Endianness
 510 AC_C_BIGENDIAN(
 511    little_endian=no,
 512    little_endian=yes,
 513    little_endian=no,
 514    little_endian=no
 515 )
 516
 517 dnl Check for POWER8 Architecture
 518 PWR8_CFLAGS="-mpower8-vector"
 519 have_pwr8_intrinsics=no
 520 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 521 save_CFLAGS=$CFLAGS
 522 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 523 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 524 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 525 #error "Need GCC >= 4.8 for sane POWER8 support"
 526 #endif
 527 #include <altivec.h>
 528 int main () {
 529     vector unsigned char r;
 530     vector unsigned int v = vec_splat_u32 (1);
 531     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 532     return 0;
 533 }]])], have_pwr8_intrinsics=yes)
 534 CFLAGS=$save_CFLAGS
 535
 536 AC_ARG_ENABLE(pwr8,
 537    [AS_HELP_STRING([--disable-pwr8],
 538                    [disable POWER8-specific instructions])],
 539    [enable_pwr8=$enableval], [enable_pwr8=auto])
 540
 541 if test "x$enable_pwr8" = xno ; then
 542    have_pwr8_intrinsics=disabled
 543 fi
 544
 545 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 546    DEFINES="$DEFINES -D_ARCH_PWR8"
 547    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 548    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 549 else
 550    PWR8_CFLAGS=
 551 fi
 552
 553 AC_MSG_RESULT($have_pwr8_intrinsics)
 554 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 555    AC_MSG_ERROR([POWER8 compiler support not detected])
 556 fi
 557
 558 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 559    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 560 fi
 561
 562 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 563
 564 dnl Can't have static and shared libraries, default to static if user
 565 dnl explicitly requested. If both disabled, set to static since shared
 566 dnl was explicitly requested.
 567 case "x$enable_static$enable_shared" in
 568 xyesyes)
 569     AC_MSG_ERROR([Cannot enable both static and shared. Building using --enable-shared is strongly recommended])
 570     ;;
 571 xnono)
 572     AC_MSG_ERROR([Cannot disable both static and shared. Building using --enable-shared is strongly recommended])
 573     ;;
 574 esac
 575
 576 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 577
 578 dnl
 579 dnl other compiler options
 580 dnl
 581 AC_ARG_ENABLE([debug],
 582     [AS_HELP_STRING([--enable-debug],
 583         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 584     [enable_debug="$enableval"],
 585     [enable_debug=no]
 586 )
 587
 588 AC_ARG_ENABLE([profile],
 589     [AS_HELP_STRING([--enable-profile],
 590         [enable profiling of code @<:@default=disabled@:>@])],
 591     [enable_profile="$enableval"],
 592     [enable_profile=no]
 593 )
 594
 595 AC_ARG_ENABLE([sanitize],
 596     [AS_HELP_STRING([--enable-sanitize@<:@=address|undefined@:>@],
 597         [enable code sanitizer @<:@default=disabled@:>@])],
 598     [enable_sanitize="$enableval"],
 599     [enable_sanitize=no])
 600
 601 if test "x$enable_profile" = xyes; then
 602     DEFINES="$DEFINES -DPROFILE"
 603     if test "x$GCC" = xyes; then
 604         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 605     fi
 606     if test "x$GXX" = xyes; then
 607         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 608     fi
 609 fi
 610
 611 if test "x$enable_debug" = xyes; then
 612     DEFINES="$DEFINES -DDEBUG"
 613     if test "x$enable_profile" = xyes; then
 614         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 615     fi
 616     if test "x$GCC" = xyes; then
 617         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 618             CFLAGS="$CFLAGS -g"
 619         fi
 620         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 621             CFLAGS="$CFLAGS -O0"
 622         fi
 623     fi
 624     if test "x$GXX" = xyes; then
 625         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 626             CXXFLAGS="$CXXFLAGS -g"
 627         fi
 628         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 629             CXXFLAGS="$CXXFLAGS -O0"
 630         fi
 631     fi
 632 else
 633    DEFINES="$DEFINES -DNDEBUG"
 634 fi
 635
 636 if test "x$enable_sanitize" != xno; then
 637     if test "x$enable_profile" = xyes; then
 638         AC_MSG_WARN([Sanitize and Profile are enabled at the same time])
 639     fi
 640
 641     CFLAGS="$CFLAGS -fsanitize=$enable_sanitize"
 642     CXXFLAGS="$CXXFLAGS -fsanitize=$enable_sanitize"
 643     LDFLAGS="$LDFLAGS -fsanitize=$enable_sanitize"
 644
 645     AC_LINK_IFELSE(
 646         [AC_LANG_SOURCE([int main(){return 0;}])],
 647         [],
 648         [AC_MSG_FAILURE([sanitize flags '$enable_sanitize' not supported])])
 649 fi
 650
 651 dnl
 652 dnl Check if linker supports -Bsymbolic
 653 dnl
 654 save_LDFLAGS=$LDFLAGS
 655 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 656 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 657 AC_LINK_IFELSE(
 658     [AC_LANG_SOURCE([int main() { return 0;}])],
 659     [AC_MSG_RESULT([yes])
 660         BSYMBOLIC="-Wl,-Bsymbolic";],
 661     [AC_MSG_RESULT([no])
 662         BSYMBOLIC="";])
 663 LDFLAGS=$save_LDFLAGS
 664
 665 AC_SUBST([BSYMBOLIC])
 666
 667 dnl
 668 dnl Check if linker supports garbage collection
 669 dnl
 670 save_LDFLAGS=$LDFLAGS
 671 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 672 AC_MSG_CHECKING([whether ld supports --gc-sections])
 673 AC_LINK_IFELSE(
 674     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 675     [AC_MSG_RESULT([yes])
 676         GC_SECTIONS="-Wl,--gc-sections";],
 677     [AC_MSG_RESULT([no])
 678         GC_SECTIONS="";])
 679 LDFLAGS=$save_LDFLAGS
 680
 681 AC_SUBST([GC_SECTIONS])
 682
 683 dnl
 684 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 685 dnl so when these flags are passed to ld via libtool the checks will fail
 686 dnl
 687 case "$host_os" in
 688 openbsd* | darwin* )
 689     LD_NO_UNDEFINED="" ;;
 690 *)
 691     if test "x$enable_sanitize" = xno; then
 692         LD_NO_UNDEFINED="-Wl,--no-undefined"
 693     else
 694         LD_NO_UNDEFINED=""
 695     fi
 696     ;;
 697 esac
 698
 699 AC_SUBST([LD_NO_UNDEFINED])
 700
 701 dnl
 702 dnl Check if linker supports version scripts
 703 dnl
 704 AC_MSG_CHECKING([if the linker supports version-scripts])
 705 save_LDFLAGS=$LDFLAGS
 706 LDFLAGS="$LDFLAGS -Wl,--version-script=$srcdir/build-support/conftest.map"
 707 AC_LINK_IFELSE(
 708     [AC_LANG_SOURCE([int main() { return 0;}])],
 709     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 710     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 711 LDFLAGS=$save_LDFLAGS
 712 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 713
 714 dnl
 715 dnl Check if linker supports dynamic list files
 716 dnl
 717 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 718 save_LDFLAGS=$LDFLAGS
 719 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=$srcdir/build-support/conftest.dyn"
 720 AC_LINK_IFELSE(
 721     [AC_LANG_SOURCE([int main() { return 0;}])],
 722     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 723     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 724 LDFLAGS=$save_LDFLAGS
 725 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 726
 727 dnl
 728 dnl OSX linker does not support build-id
 729 dnl
 730 case "$host_os" in
 731 darwin*)
 732     LD_BUILD_ID=""
 733     ;;
 734 *)
 735     LD_BUILD_ID="-Wl,--build-id=sha1"
 736     ;;
 737 esac
 738 AC_SUBST([LD_BUILD_ID])
 739
 740 dnl
 741 dnl compatibility symlinks
 742 dnl
 743 case "$host_os" in
 744 linux* )
 745     HAVE_COMPAT_SYMLINKS=yes ;;
 746 * )
 747     HAVE_COMPAT_SYMLINKS=no ;;
 748 esac
 749
 750 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 751
 752 dnl
 753 dnl library names
 754 dnl
 755 dnl Unfortunately we need to do a few things that libtool can't help us with,
 756 dnl so we need some knowledge of shared library filenames:
 757 dnl
 758 dnl LIB_EXT is the extension used when creating symlinks for alternate
 759 dnl filenames for a shared library which will be dynamically loaded
 760 dnl
 761 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 762 dnl the file for a shared library we wish to link with
 763 dnl
 764 case "$host_os" in
 765 darwin* )
 766     LIB_EXT='dylib'
 767     IMP_LIB_EXT=$LIB_EXT
 768     ;;
 769 cygwin* )
 770     LIB_EXT='dll'
 771     IMP_LIB_EXT='dll.a'
 772     ;;
 773 aix* )
 774     LIB_EXT='a'
 775     IMP_LIB_EXT=$LIB_EXT
 776     ;;
 777 * )
 778     LIB_EXT='so'
 779     IMP_LIB_EXT=$LIB_EXT
 780     ;;
 781 esac
 782
 783 AC_SUBST([LIB_EXT])
 784
 785 dnl
 786 dnl Arch/platform-specific settings
 787 dnl
 788 AC_ARG_ENABLE([asm],
 789     [AS_HELP_STRING([--disable-asm],
 790         [disable assembly usage @<:@default=enabled on supported platforms@:>@])],
 791     [enable_asm="$enableval"],
 792     [enable_asm=yes]
 793 )
 794 asm_arch=""
 795 AC_MSG_CHECKING([whether to enable assembly])
 796 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 797 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 798 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 799     case "$host_cpu" in
 800     i?86 | x86_64 | amd64)
 801         if test "x$host_cpu" != "x$target_cpu"; then
 802             enable_asm=no
 803             AC_MSG_RESULT([no, cross compiling])
 804         fi
 805         ;;
 806     esac
 807 fi
 808 # check for supported arches
 809 if test "x$enable_asm" = xyes; then
 810     case "$host_cpu" in
 811     i?86)
 812         case "$host_os" in
 813         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 814             asm_arch=x86
 815             ;;
 816         esac
 817         ;;
 818     x86_64|amd64)
 819         case "$host_os" in
 820         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 821             asm_arch=x86_64
 822             ;;
 823         esac
 824         ;;
 825     sparc*)
 826         case "$host_os" in
 827         linux*)
 828             asm_arch=sparc
 829             ;;
 830         esac
 831         ;;
 832     powerpc64le)
 833         case "$host_os" in
 834         linux*)
 835             asm_arch=ppc64le
 836             ;;
 837         esac
 838         ;;
 839     aarch64)
 840         case "$host_os" in
 841         linux*)
 842             asm_arch=aarch64
 843             ;;
 844         esac
 845         ;;
 846     arm)
 847         case "$host_os" in
 848         linux*)
 849             asm_arch=arm
 850             ;;
 851         esac
 852         ;;
 853     esac
 854
 855     case "$asm_arch" in
 856     x86)
 857         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 858         AC_MSG_RESULT([yes, x86])
 859         ;;
 860     x86_64|amd64)
 861         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 862         AC_MSG_RESULT([yes, x86_64])
 863         ;;
 864     sparc)
 865         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 866         AC_MSG_RESULT([yes, sparc])
 867         ;;
 868     ppc64le)
 869         DEFINES="$DEFINES -DUSE_PPC64LE_ASM"
 870         AC_MSG_RESULT([yes, ppc64le])
 871         ;;
 872     aarch64)
 873         DEFINES="$DEFINES -DUSE_AARCH64_ASM"
 874         AC_MSG_RESULT([yes, aarch64])
 875         ;;
 876     arm)
 877         DEFINES="$DEFINES -DUSE_ARM_ASM"
 878         AC_MSG_RESULT([yes, arm])
 879         ;;
 880     *)
 881         AC_MSG_RESULT([no, platform not supported])
 882         ;;
 883     esac
 884 fi
 885
 886 AC_HEADER_MAJOR
 887 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 888 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 889 AC_CHECK_HEADERS([endian.h])
 890 AC_CHECK_HEADER([dlfcn.h], [DEFINES="$DEFINES -DHAVE_DLFCN_H"])
 891 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 892 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 893 AC_CHECK_FUNC([timespec_get], [DEFINES="$DEFINES -DHAVE_TIMESPEC_GET"])
 894 AC_CHECK_FUNC([memfd_create], [DEFINES="$DEFINES -DHAVE_MEMFD_CREATE"])
 895
 896 AC_MSG_CHECKING([whether strtod has locale support])
 897 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 898     #define _GNU_SOURCE
 899     #include <stdlib.h>
 900     #include <locale.h>
 901     #ifdef HAVE_XLOCALE_H
 902     #include <xlocale.h>
 903     #endif
 904     int main() {
 905        locale_t loc = newlocale(LC_CTYPE_MASK, "C", NULL);
 906        const char *s = "1.0";
 907        char *end;
 908        double d = strtod_l(s, end, loc);
 909        float f = strtof_l(s, end, loc);
 910        freelocale(loc);
 911        return 0;
 912     }]])],
 913   [DEFINES="$DEFINES -DHAVE_STRTOD_L"];
 914    AC_MSG_RESULT([yes]),
 915    AC_MSG_RESULT([no]))
 916
 917 dnl Check to see if dlopen is in default libraries (like Solaris, which
 918 dnl has it in libc), or if libdl is needed to get it.
 919 AC_CHECK_FUNC([dlopen], [],
 920     [AC_CHECK_LIB([dl], [dlopen],
 921        [DLOPEN_LIBS="-ldl"])])
 922 AC_SUBST([DLOPEN_LIBS])
 923
 924 dnl Check if that library also has dladdr
 925 save_LIBS="$LIBS"
 926 LIBS="$LIBS $DLOPEN_LIBS"
 927 AC_CHECK_FUNCS([dladdr])
 928 LIBS="$save_LIBS"
 929
 930 AC_CHECK_FUNC([dl_iterate_phdr], [DEFINES="$DEFINES -DHAVE_DL_ITERATE_PHDR"])
 931
 932 case "$host_os" in
 933 darwin*)
 934     ;;
 935 *)
 936     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 937                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 938                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 939     AC_SUBST([CLOCK_LIB])
 940     ;;
 941 esac
 942
 943 dnl See if posix_memalign is available
 944 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 945
 946 dnl Check for zlib
 947 PKG_CHECK_MODULES([ZLIB], [zlib >= $ZLIB_REQUIRED])
 948 DEFINES="$DEFINES -DHAVE_ZLIB"
 949
 950 dnl Check for pthreads
 951 AX_PTHREAD
 952 if test "x$ax_pthread_ok" = xno; then
 953     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 954 fi
 955 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 956 dnl to -pthread, which causes problems if we need -lpthread to appear in
 957 dnl pkgconfig files.  Since Android doesn't have a pthread lib, this check
 958 dnl is not valid for that platform.
 959 if test "x$android" = xno; then
 960     test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 961 fi
 962 dnl According to the manual when using pthreads, one should add -pthread to
 963 dnl both compile and link-time arguments.
 964 dnl In practise that should be sufficient for all platforms, since any
 965 dnl platforms build with GCC and Clang support the flag.
 966 PTHREAD_LIBS="$PTHREAD_LIBS -pthread"
 967
 968 dnl pthread-stubs is mandatory on some BSD platforms, due to the nature of the
 969 dnl project. Even then there's a notable issue as described in the project README
 970 case "$host_os" in
 971 linux* | cygwin* | darwin* | solaris* | *-gnu* | gnu* | openbsd*)
 972     pthread_stubs_possible="no"
 973     ;;
 974 * )
 975     pthread_stubs_possible="yes"
 976     ;;
 977 esac
 978
 979 if test "x$pthread_stubs_possible" = xyes; then
 980     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs >= 0.4)
 981 fi
 982
 983 save_LIBS="$LIBS"
 984 LIBS="$PTHREAD_LIBS"
 985 AC_MSG_CHECKING(whether pthread_setaffinity_np is supported)
 986 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 987     #define _GNU_SOURCE
 988     #include <pthread.h>
 989     int main() {
 990        void *a = (void*) &pthread_setaffinity_np;
 991        long b = (long) a;
 992        return (int) b;
 993     }]])],
 994   [DEFINES="$DEFINES -DHAVE_PTHREAD_SETAFFINITY"];
 995    AC_MSG_RESULT([yes]),
 996    AC_MSG_RESULT([no]))
 997 LIBS="$save_LIBS"
 998
 999 dnl Check for futex for fast inline simple_mtx_t.
1000 AC_CHECK_HEADER([linux/futex.h], [DEFINES="$DEFINES -DHAVE_LINUX_FUTEX_H"])
1001
1002 dnl SELinux awareness.
1003 AC_ARG_ENABLE([selinux],
1004     [AS_HELP_STRING([--enable-selinux],
1005         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
1006     [MESA_SELINUX="$enableval"],
1007     [MESA_SELINUX=no])
1008 if test "x$enable_selinux" = "xyes"; then
1009     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
1010         [AC_CHECK_HEADER([selinux/selinux.h],[],
1011                          [AC_MSG_ERROR([SELinux headers not found])])
1012          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
1013                       [AC_MSG_ERROR([SELinux library not found])])
1014          SELINUX_LIBS="-lselinux"])
1015     DEFINES="$DEFINES -DMESA_SELINUX"
1016 fi
1017 AC_SUBST([SELINUX_CFLAGS])
1018 AC_SUBST([SELINUX_LIBS])
1019
1020 dnl
1021 dnl LLVM
1022 dnl
1023 AC_ARG_ENABLE([llvm-shared-libs],
1024     [AS_HELP_STRING([--enable-llvm-shared-libs],
1025         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1026     [enable_llvm_shared_libs="$enableval"],
1027     [enable_llvm_shared_libs=yes])
1028
1029 AC_ARG_WITH([llvm-prefix],
1030     [AS_HELP_STRING([--with-llvm-prefix],
1031         [Prefix for LLVM installations in non-standard locations])],
1032     [llvm_prefix="$withval"],
1033     [llvm_prefix=''])
1034
1035 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
1036 if test "x$have_libelf" = xno; then
1037    LIBELF_LIBS=''
1038    LIBELF_CFLAGS=''
1039    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
1040    AC_SUBST([LIBELF_LIBS])
1041    AC_SUBST([LIBELF_CFLAGS])
1042 fi
1043
1044 if test -z "$LLVM_CONFIG"; then
1045     if test -n "$llvm_prefix"; then
1046         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1047     else
1048         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1049     fi
1050 fi
1051
1052 llvm_add_component() {
1053     new_llvm_component=$1
1054     driver_name=$2
1055
1056     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
1057         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
1058     else
1059         AC_MSG_ERROR([LLVM component '$new_llvm_component' not enabled in your LLVM build. Required by $driver_name.])
1060     fi
1061 }
1062
1063 llvm_add_optional_component() {
1064     new_llvm_component=$1
1065     driver_name=$2
1066
1067     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
1068         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
1069     fi
1070 }
1071
1072 llvm_add_default_components() {
1073     driver_name=$1
1074
1075     # Required default components
1076     llvm_add_component "bitwriter" $driver_name
1077     llvm_add_component "engine" $driver_name
1078     llvm_add_component "mcdisassembler" $driver_name
1079     llvm_add_component "mcjit" $driver_name
1080
1081     # Optional default components
1082     llvm_add_optional_component "inteljitevents" $driver_name
1083 }
1084
1085 llvm_add_target() {
1086     new_llvm_target=$1
1087     driver_name=$2
1088
1089     if $LLVM_CONFIG --targets-built | grep -iqw $new_llvm_target ; then
1090         llvm_add_component $new_llvm_target $driver_name
1091     else
1092         AC_MSG_ERROR([LLVM target '$new_llvm_target' not enabled in your LLVM build. Required by $driver_name.])
1093     fi
1094 }
1095
1096 # Call this inside ` ` to get the return value.
1097 # $1 is the llvm-config command with arguments.
1098 strip_unwanted_llvm_flags() {
1099     echo " `$1` " | sed -E \
1100         -e 's/[[[:space:]]]+-m[[^[:space:]]]*//g' \
1101         -e 's/[[[:space:]]]+-DNDEBUG[[[:space:]]]/ /g' \
1102         -e 's/[[[:space:]]]+-D_GNU_SOURCE[[[:space:]]]/ /g' \
1103         -e 's/[[[:space:]]]+-pedantic[[[:space:]]]/ /g' \
1104         -e 's/[[[:space:]]]+-W[[^[:space:]]]*//g' \
1105         -e 's/[[[:space:]]]+-O[[^[:space:]]]*//g' \
1106         -e 's/[[[:space:]]]+-g[[^[:space:]]]*//g' \
1107         -e 's/-fno-rtti[[[:space:]]]/-Fno-rtti /g' \
1108         -e 's/[[[:space:]]]+-f[[^[:space:]]]*//g' \
1109         -e 's/-Fno-rtti[[[:space:]]]/-fno-rtti /g' \
1110         -e 's/^[[[:space:]]]//' \
1111         -e 's/[[[:space:]]]$//'
1112 }
1113
1114 llvm_set_environment_variables() {
1115     if test "x$LLVM_CONFIG" != xno; then
1116         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1117         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1118         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1119         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1120
1121         # We need to respect LLVM_CPPFLAGS when compiling LLVM headers.
1122         save_CFLAGS="$CFLAGS"
1123         CFLAGS="$CFLAGS $LLVM_CPPFLAGS"
1124
1125         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1126             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1127         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1128             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1129         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
1130             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1131
1132         CFLAGS="$save_CFLAGS"
1133
1134         # Only needed for LLVM < 3.6.0
1135         if test -z "$LLVM_VERSION_PATCH"; then
1136             LLVM_VERSION_PATCH=0
1137         fi
1138
1139         LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1140
1141         FOUND_LLVM=yes
1142     else
1143         FOUND_LLVM=no
1144         LLVM_VERSION_INT=0
1145     fi
1146 }
1147
1148 require_llvm() {
1149     if test "x$enable_llvm" != "xyes"; then
1150         AC_MSG_ERROR([--enable-llvm is required when building $1])
1151     fi
1152 }
1153
1154 llvm_require_version() {
1155     require_llvm $2
1156
1157     llvm_target_version_major=`echo $1 | cut -d. -f1 | egrep -o '^[[0-9]]+'`
1158     llvm_target_version_minor=`echo $1 | cut -d. -f2 | egrep -o '^[[0-9]]+'`
1159     llvm_target_version_patch=`echo $1 | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1160
1161     if test "$LLVM_VERSION_MAJOR" -gt "$llvm_target_version_major"; then
1162         # major > required major
1163         #  --> OK
1164         return
1165     fi
1166
1167     if test "$LLVM_VERSION_MAJOR" -eq "$llvm_target_version_major"; then
1168         if test "$LLVM_VERSION_MINOR" -gt "$llvm_target_version_minor"; then
1169             # major = required major and
1170             # minor > required minor
1171             #  --> OK
1172             return
1173         else
1174             if test "$LLVM_VERSION_MINOR" -eq "$llvm_target_version_minor"; then
1175                 if test "$LLVM_VERSION_PATCH" -ge "$llvm_target_version_patch"; then
1176                     # major = required major and
1177                     # minor = required minor and
1178                     # patch >= required patch
1179                     #  --> OK
1180                     return
1181                 fi
1182             fi
1183         fi
1184     fi
1185
1186     AC_MSG_ERROR([LLVM $1 or newer is required for $2])
1187 }
1188
1189 radeon_llvm_check() {
1190     if test ${LLVM_VERSION_INT} -lt 307; then
1191         amdgpu_llvm_target_name='r600'
1192     else
1193         amdgpu_llvm_target_name='amdgpu'
1194     fi
1195
1196     llvm_require_version $*
1197
1198     llvm_add_target $amdgpu_llvm_target_name $2
1199
1200     llvm_add_default_components $2
1201     llvm_add_component "bitreader" $2
1202     llvm_add_component "ipo" $2
1203
1204     if test "x$have_libelf" != xyes; then
1205        AC_MSG_ERROR([$2 requires libelf when using llvm])
1206     fi
1207 }
1208
1209 llvm_set_environment_variables
1210
1211 AC_SUBST([LLVM_CFLAGS])
1212 AC_SUBST([LLVM_CXXFLAGS])
1213 AC_SUBST([LLVM_LIBS])
1214 AC_SUBST([LLVM_LDFLAGS])
1215 AC_SUBST([LLVM_INCLUDEDIR])
1216
1217 dnl
1218 dnl libunwind
1219 dnl
1220 PKG_CHECK_EXISTS(libunwind, [HAVE_LIBUNWIND=yes], [HAVE_LIBUNWIND=no])
1221 AC_ARG_ENABLE([libunwind],
1222     [AS_HELP_STRING([--enable-libunwind],
1223             [Use libunwind for backtracing (default: auto)])],
1224         [LIBUNWIND="$enableval"],
1225         [LIBUNWIND="$HAVE_LIBUNWIND"])
1226
1227 if test "x$LIBUNWIND" = "xyes"; then
1228     PKG_CHECK_MODULES(LIBUNWIND, libunwind)
1229     AC_DEFINE(HAVE_LIBUNWIND, 1, [Have libunwind support])
1230 fi
1231
1232
1233 dnl Options for APIs
1234 AC_ARG_ENABLE([opengl],
1235     [AS_HELP_STRING([--disable-opengl],
1236         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
1237     [enable_opengl="$enableval"],
1238     [enable_opengl=yes])
1239 AC_ARG_ENABLE([gles1],
1240     [AS_HELP_STRING([--disable-gles1],
1241         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
1242     [enable_gles1="$enableval"],
1243     [enable_gles1=yes])
1244 AC_ARG_ENABLE([gles2],
1245     [AS_HELP_STRING([--disable-gles2],
1246         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
1247     [enable_gles2="$enableval"],
1248     [enable_gles2=yes])
1249
1250 AC_ARG_ENABLE([dri],
1251     [AS_HELP_STRING([--enable-dri],
1252         [enable DRI modules @<:@default=enabled@:>@])],
1253     [enable_dri="$enableval"],
1254     [enable_dri=yes])
1255
1256 AC_ARG_ENABLE([gallium-extra-hud],
1257     [AS_HELP_STRING([--enable-gallium-extra-hud],
1258         [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
1259     [enable_gallium_extra_hud="$enableval"],
1260     [enable_gallium_extra_hud=no])
1261 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
1262 if test "x$enable_gallium_extra_hud" = xyes ; then
1263     DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
1264 fi
1265
1266 #TODO: no pkgconfig .pc available for libsensors.
1267 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
1268 AC_ARG_ENABLE([lmsensors],
1269     [AS_HELP_STRING([--enable-lmsensors],
1270         [enable HUD lmsensor support @<:@default=disabled@:>@])],
1271     [enable_lmsensors="$enableval"],
1272     [enable_lmsensors=no])
1273 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
1274 if test "x$enable_lmsensors" = xyes ; then
1275     DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
1276     LIBSENSORS_LIBS="-lsensors"
1277 else
1278     LIBSENSORS_LIBS=""
1279 fi
1280 AC_SUBST(LIBSENSORS_LIBS)
1281
1282 case "$host_os" in
1283 linux*)
1284     dri3_default=yes
1285     ;;
1286 *)
1287     dri3_default=no
1288     ;;
1289 esac
1290
1291 if test "x$enable_dri" = xno; then
1292     dri3_default=no
1293 fi
1294
1295 AC_ARG_ENABLE([dri3],
1296     [AS_HELP_STRING([--enable-dri3],
1297         [enable DRI3 @<:@default=auto@:>@])],
1298     [enable_dri3="$enableval"],
1299     [enable_dri3="$dri3_default"])
1300 AC_ARG_ENABLE([glx],
1301     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
1302         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
1303     [enable_glx="$enableval"],
1304     [enable_glx=yes])
1305 AC_ARG_ENABLE([osmesa],
1306     [AS_HELP_STRING([--enable-osmesa],
1307         [enable OSMesa library @<:@default=disabled@:>@])],
1308     [enable_osmesa="$enableval"],
1309     [enable_osmesa=no])
1310 AC_ARG_ENABLE([gallium-osmesa],
1311     [AS_HELP_STRING([--enable-gallium-osmesa],
1312         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
1313     [enable_gallium_osmesa="$enableval"],
1314     [enable_gallium_osmesa=no])
1315 AC_ARG_ENABLE([egl],
1316     [AS_HELP_STRING([--disable-egl],
1317         [disable EGL library @<:@default=enabled@:>@])],
1318     [enable_egl="$enableval"],
1319     [enable_egl=yes])
1320
1321 AC_ARG_ENABLE([xa],
1322     [AS_HELP_STRING([--enable-xa],
1323         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
1324     [enable_xa="$enableval"],
1325     [enable_xa=no])
1326 AC_ARG_ENABLE([gbm],
1327    [AS_HELP_STRING([--enable-gbm],
1328          [enable gbm library @<:@default=yes except cygwin and macOS@:>@])],
1329    [enable_gbm="$enableval"],
1330    [case "$host_os" in
1331        cygwin* | darwin*)
1332           enable_gbm=no
1333           ;;
1334        *)
1335           enable_gbm=yes
1336           ;;
1337     esac])
1338 AC_ARG_ENABLE([nine],
1339     [AS_HELP_STRING([--enable-nine],
1340         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
1341     [enable_nine="$enableval"],
1342     [enable_nine=no])
1343
1344 AC_ARG_ENABLE([xvmc],
1345    [AS_HELP_STRING([--enable-xvmc],
1346          [enable xvmc library @<:@default=auto@:>@])],
1347    [enable_xvmc="$enableval"],
1348    [enable_xvmc=auto])
1349 AC_ARG_ENABLE([vdpau],
1350    [AS_HELP_STRING([--enable-vdpau],
1351          [enable vdpau library @<:@default=auto@:>@])],
1352    [enable_vdpau="$enableval"],
1353    [enable_vdpau=auto])
1354 AC_ARG_ENABLE([omx],
1355    [AS_HELP_STRING([--enable-omx],
1356          [DEPRECATED: Use --enable-omx-bellagio or --enable-omx-tizonia instead @<:@default=auto@:>@])],
1357    [AC_MSG_ERROR([--enable-omx is deprecated. Use --enable-omx-bellagio or --enable-omx-tizonia instead.])],
1358    [])
1359 AC_ARG_ENABLE([omx-bellagio],
1360    [AS_HELP_STRING([--enable-omx-bellagio],
1361          [enable OpenMAX Bellagio library @<:@default=disabled@:>@])],
1362    [enable_omx_bellagio="$enableval"],
1363    [enable_omx_bellagio=no])
1364 AC_ARG_ENABLE([omx-tizonia],
1365    [AS_HELP_STRING([--enable-omx-tizonia],
1366          [enable OpenMAX Tizonia library @<:@default=disabled@:>@])],
1367    [enable_omx_tizonia="$enableval"],
1368    [enable_omx_tizonia=no])
1369 AC_ARG_ENABLE([va],
1370    [AS_HELP_STRING([--enable-va],
1371          [enable va library @<:@default=auto@:>@])],
1372    [enable_va="$enableval"],
1373    [enable_va=auto])
1374 AC_ARG_ENABLE([opencl],
1375    [AS_HELP_STRING([--enable-opencl],
1376          [enable OpenCL library @<:@default=disabled@:>@])],
1377    [enable_opencl="$enableval"],
1378    [enable_opencl=no])
1379 AC_ARG_ENABLE([opencl_icd],
1380    [AS_HELP_STRING([--enable-opencl-icd],
1381           [Build an OpenCL ICD library to be loaded by an ICD implementation
1382            @<:@default=enabled@:>@])],
1383     [enable_opencl_icd="$enableval"],
1384     [enable_opencl_icd=yes])
1385
1386 AC_ARG_ENABLE([gallium-tests],
1387     [AS_HELP_STRING([--enable-gallium-tests],
1388         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1389     [enable_gallium_tests="$enableval"],
1390     [enable_gallium_tests=no])
1391
1392 # Option for Gallium drivers
1393
1394 # Keep this in sync with the --with-gallium-drivers help string default value
1395 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1396
1397 AC_ARG_WITH([gallium-drivers],
1398     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1399         [comma delimited Gallium drivers list, e.g.
1400         "i915,nouveau,r300,r600,radeonsi,freedreno,pl111,svga,swrast,swr,tegra,v3d,vc4,virgl,etnaviv,imx"
1401         @<:@default=r300,r600,svga,swrast@:>@])],
1402     [with_gallium_drivers="$withval"],
1403     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1404
1405 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
1406 # here so that the script doesn't choke on an unknown driver name later.
1407 case "$with_gallium_drivers" in
1408     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1409     no) with_gallium_drivers='' ;;
1410 esac
1411
1412 if test "x$enable_opengl" = xno -a \
1413         "x$enable_gles1" = xno -a \
1414         "x$enable_gles2" = xno -a \
1415         "x$enable_nine" = xno -a \
1416         "x$enable_xa" = xno -a \
1417         "x$enable_xvmc" = xno -a \
1418         "x$enable_vdpau" = xno -a \
1419         "x$enable_omx_bellagio" = xno -a \
1420         "x$enable_omx_tizonia" = xno -a \
1421         "x$enable_va" = xno -a \
1422         "x$enable_opencl" = xno; then
1423     AC_MSG_ERROR([at least one API should be enabled])
1424 fi
1425
1426 if test "x$enable_omx_bellagio" = xyes -a \
1427         "x$enable_omx_tizonia" = xyes; then
1428    AC_MSG_ERROR([Can't enable both bellagio and tizonia at same time])
1429 fi
1430
1431 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1432 if test "x$enable_opengl" = xno -a \
1433         "x$enable_gles1" = xyes; then
1434     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1435 fi
1436
1437 if test "x$enable_opengl" = xno -a \
1438         "x$enable_gles2" = xyes; then
1439     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1440 fi
1441
1442 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1443 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1444 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1445 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1446                                         "x$enable_gles1" = xyes -o \
1447                                         "x$enable_gles2" = xyes)
1448 AM_CONDITIONAL(NEED_KHRPLATFORM, test "x$enable_egl" = xyes -o \
1449                                       "x$enable_opengl" = xyes -o \
1450                                       "x$enable_gles1" = xyes -o \
1451                                       "x$enable_gles2" = xyes)
1452
1453 # Validate GLX options
1454 if test "x$enable_glx" = xyes; then
1455     if test "x$enable_dri" = xyes; then
1456         enable_glx=dri
1457     elif test -n "$with_gallium_drivers"; then
1458         enable_glx=gallium-xlib
1459     else
1460         enable_glx=xlib
1461     fi
1462 fi
1463 case "x$enable_glx" in
1464 xdri | xxlib | xgallium-xlib)
1465     # GLX requires OpenGL
1466     if test "x$enable_opengl" = xno; then
1467         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1468     fi
1469
1470     # Check individual dependencies
1471     case "x$enable_glx" in
1472     xdri)
1473         if test "x$enable_dri" = xno; then
1474             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1475         fi
1476         ;;
1477     xxlib)
1478         if test "x$enable_dri" = xyes; then
1479             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1480         fi
1481         ;;
1482     xgallium-xlib )
1483         if test "x$enable_dri" = xyes; then
1484             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1485         fi
1486         if test -z "$with_gallium_drivers"; then
1487             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1488         fi
1489         ;;
1490     esac
1491     ;;
1492 xno)
1493     ;;
1494 *)
1495     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1496     ;;
1497 esac
1498
1499 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1500 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1501 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1502 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1503
1504 DEFAULT_GL_LIB_NAME=GL
1505
1506 dnl
1507 dnl Libglvnd configuration
1508 dnl
1509 AC_ARG_ENABLE([libglvnd],
1510     [AS_HELP_STRING([--enable-libglvnd],
1511         [Build GLX and EGL for libglvnd @<:@default=disabled@:>@])],
1512     [enable_libglvnd="$enableval"],
1513     [enable_libglvnd=no])
1514 AM_CONDITIONAL(USE_LIBGLVND, test "x$enable_libglvnd" = xyes)
1515
1516 if test "x$enable_libglvnd" = xyes ; then
1517     case "x$enable_glx" in
1518     xxlib | xgallium-xlib )
1519         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1520         ;;
1521     esac
1522
1523     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.2.0)
1524     LIBGLVND_DATADIR=`$PKG_CONFIG --variable=datadir libglvnd`
1525     AC_SUBST([LIBGLVND_DATADIR])
1526
1527     DEFINES="${DEFINES} -DUSE_LIBGLVND=1"
1528     DEFAULT_GL_LIB_NAME=GLX_mesa
1529
1530     if test "x$enable_glx" = xno -a "x$enable_egl" = xno; then
1531         AC_MSG_ERROR([cannot build libglvnd without GLX or EGL])
1532     fi
1533 fi
1534
1535 AC_ARG_WITH([gl-lib-name],
1536   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
1537     [specify GL library name @<:@default=GL@:>@])],
1538   [AC_MSG_ERROR([--with-gl-lib-name is no longer supported. Rename the library manually if needed.])],
1539   [])
1540 AC_ARG_WITH([osmesa-lib-name],
1541   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
1542     [specify OSMesa library name @<:@default=OSMesa@:>@])],
1543   [AC_MSG_ERROR([--with-osmesa-lib-name is no longer supported. Rename the library manually if needed.])],
1544   [])
1545 GL_LIB="$DEFAULT_GL_LIB_NAME"
1546 OSMESA_LIB=OSMesa
1547
1548 dnl
1549 dnl Mangled Mesa support
1550 dnl
1551 AC_ARG_ENABLE([mangling],
1552   [AS_HELP_STRING([--enable-mangling],
1553     [enable mangled symbols and library name @<:@default=disabled@:>@])],
1554   [enable_mangling="${enableval}"],
1555   [enable_mangling=no]
1556 )
1557 if test "x${enable_mangling}" = "xyes" ; then
1558   if test "x$enable_libglvnd" = xyes; then
1559     AC_MSG_ERROR([Conflicting options --enable-mangling and --enable-libglvnd.])
1560   fi
1561   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
1562   GL_LIB="Mangled${GL_LIB}"
1563   OSMESA_LIB="Mangled${OSMESA_LIB}"
1564 fi
1565 AC_SUBST([GL_LIB])
1566 AC_SUBST([OSMESA_LIB])
1567
1568 dnl HACK when building glx + glvnd we ship gl.pc, despite that glvnd should do it
1569 dnl Thus we need to use GL as a DSO name.
1570 if test "x$enable_libglvnd" = xyes -a "x$enable_glx" != xno; then
1571   GL_PKGCONF_LIB="GL"
1572 else
1573   GL_PKGCONF_LIB="$GL_LIB"
1574 fi
1575 AC_SUBST([GL_PKGCONF_LIB])
1576
1577 # Check for libdrm
1578 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1579                   [have_libdrm=yes], [have_libdrm=no])
1580 if test "x$have_libdrm" = xyes; then
1581     DEFINES="$DEFINES -DHAVE_LIBDRM"
1582 fi
1583
1584 require_libdrm() {
1585     if test "x$have_libdrm" != xyes; then
1586        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1587     fi
1588 }
1589
1590
1591 # Select which platform-dependent DRI code gets built
1592 case "$host_os" in
1593 darwin*)
1594     dri_platform='apple' ;;
1595 cygwin*)
1596     dri_platform='windows' ;;
1597 gnu*)
1598     dri_platform='none' ;;
1599 *)
1600     dri_platform='drm' ;;
1601 esac
1602
1603 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1604     have_drisw_kms='yes'
1605 fi
1606
1607 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1608 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1609 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1610 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1611 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1612 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1613 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1614 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1615 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1616 AM_CONDITIONAL(HAVE_XLEASE, test "x$have_xlease" = xyes )
1617
1618 AC_ARG_ENABLE([shared-glapi],
1619     [AS_HELP_STRING([--enable-shared-glapi],
1620         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1621     [enable_shared_glapi="$enableval"],
1622     [enable_shared_glapi=yes])
1623
1624 case "x$enable_opengl$enable_gles1$enable_gles2" in
1625 x*yes*yes*)
1626     if test "x$enable_shared_glapi" = xno; then
1627         AC_MSG_ERROR([shared GLAPI required when building two or more of
1628                       the following APIs - opengl, gles1 gles2])
1629     fi
1630     ;;
1631 esac
1632
1633 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1634
1635 # Build the pipe-drivers as separate libraries/modules.
1636 # Do not touch this unless you know what you are doing.
1637 # XXX: Expose via configure option ?
1638 enable_shared_pipe_drivers=no
1639
1640 dnl
1641 dnl Driver specific build directories
1642 dnl
1643
1644 if test "x$enable_gallium_osmesa" = xyes; then
1645     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1646         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1647     fi
1648     if test "x$enable_osmesa" = xyes; then
1649         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1650     fi
1651 fi
1652
1653 require_dri_shared_libs_and_glapi() {
1654     if test "x$enable_static" = xyes; then
1655         AC_MSG_ERROR([$1 cannot be build as static library])
1656     fi
1657
1658     if test "x$enable_dri" != xyes; then
1659         # There is only a single backend which won't be build/used otherwise.
1660         # XXX: Revisit this as the egl/haiku is a thing.
1661         AC_MSG_ERROR([$1 requires --enable-dri])
1662     fi
1663
1664     if test "x$enable_shared_glapi" != xyes; then
1665         AC_MSG_ERROR([$1 requires --enable-shared-glapi])
1666     fi
1667 }
1668
1669 if test "x$enable_dri" = xyes; then
1670     require_dri_shared_libs_and_glapi "DRI"
1671
1672     # not a hard requirement as swrast does not depend on it
1673     if test "x$have_libdrm" = xyes; then
1674         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1675     fi
1676 fi
1677
1678 AC_ARG_ENABLE([driglx-direct],
1679     [AS_HELP_STRING([--disable-driglx-direct],
1680         [disable direct rendering in GLX and EGL for DRI \
1681             @<:@default=enabled@:>@])],
1682     [driglx_direct="$enableval"],
1683     [driglx_direct="yes"])
1684
1685 dnl
1686 dnl libGL configuration per driver
1687 dnl
1688 if test "x$enable_glx" != xno; then
1689     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1690 fi
1691 case "x$enable_glx" in
1692 xxlib | xgallium-xlib)
1693     # Xlib-based GLX
1694     dri_modules="x11 xext xcb"
1695     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1696     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1697     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1698     GL_LIB_DEPS="$XLIBGL_LIBS"
1699     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1700     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1701     ;;
1702 xdri)
1703     # DRI-based GLX
1704
1705     require_dri_shared_libs_and_glapi "GLX"
1706
1707     # find the DRI deps for libGL
1708     dri_modules="x11 xext xdamage >= $XDAMAGE_REQUIRED xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1709
1710     if test x"$driglx_direct" = xyes; then
1711         if test x"$dri_platform" = xdrm ; then
1712             DEFINES="$DEFINES -DGLX_USE_DRM"
1713             require_libdrm "Direct rendering"
1714
1715             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1716             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1717
1718             if test x"$enable_dri" = xyes; then
1719                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1720             fi
1721         fi
1722         if test x"$dri_platform" = xapple ; then
1723             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1724         fi
1725         if test x"$dri_platform" = xwindows ; then
1726             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1727         fi
1728     fi
1729
1730     # add xf86vidmode if available
1731     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1732     if test "$HAVE_XF86VIDMODE" = yes ; then
1733         dri_modules="$dri_modules xxf86vm"
1734     fi
1735
1736     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1737     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1738     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1739     GL_LIB_DEPS="$DRIGL_LIBS"
1740
1741     # need DRM libs, $PTHREAD_LIBS, etc.
1742     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1743     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1744     ;;
1745 esac
1746
1747 # This is outside the case (above) so that it is invoked even for non-GLX
1748 # builds.
1749 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1750
1751 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1752 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1753 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1754 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1755
1756 AC_SUBST([X11_INCLUDES])
1757 AC_SUBST([GL_LIB_DEPS])
1758 AC_SUBST([GL_PC_REQ_PRIV])
1759 AC_SUBST([GL_PC_LIB_PRIV])
1760 AC_SUBST([GL_PC_CFLAGS])
1761 AC_SUBST([DRI_PC_REQ_PRIV])
1762 AC_SUBST([GLESv1_CM_LIB_DEPS])
1763 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1764 AC_SUBST([GLESv2_LIB_DEPS])
1765 AC_SUBST([GLESv2_PC_LIB_PRIV])
1766
1767 AC_SUBST([HAVE_XF86VIDMODE])
1768
1769 dnl
1770 dnl More GLX setup
1771 dnl
1772 case "x$enable_glx" in
1773 xxlib | xgallium-xlib)
1774     DEFINES="$DEFINES -DUSE_XSHM"
1775     ;;
1776 xdri)
1777     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1778     if test "x$driglx_direct" = xyes; then
1779         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1780     fi
1781     ;;
1782 esac
1783
1784 dnl
1785 dnl TLS detection
1786 dnl
1787
1788 AC_ARG_ENABLE([glx-tls],
1789     [AS_HELP_STRING([--enable-glx-tls],
1790         [enable TLS support in GLX @<:@default=enabled@:>@])],
1791     [GLX_USE_TLS="$enableval"],
1792     [GLX_USE_TLS=yes])
1793 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1794
1795 if test "x$GLX_USE_TLS" = xyes; then
1796     DEFINES="$DEFINES -DGLX_USE_TLS"
1797 fi
1798
1799 dnl Read-only text section on x86 hardened platforms
1800 AC_ARG_ENABLE([glx-read-only-text],
1801     [AS_HELP_STRING([--enable-glx-read-only-text],
1802         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1803     [enable_glx_read_only_text="$enableval"],
1804     [enable_glx_read_only_text=no])
1805 if test "x$enable_glx_read_only_text" = xyes; then
1806     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1807 fi
1808
1809 dnl
1810 dnl DEPRECATED: EGL Platforms configuration
1811 dnl
1812 AC_ARG_WITH([egl-platforms],
1813     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1814         [DEPRECATED: use --with-platforms instead@<:@default=auto@:>@])],
1815     [with_egl_platforms="$withval"],
1816     [with_egl_platforms=auto])
1817
1818 if test "x$with_egl_platforms" = xauto; then
1819     with_egl_platforms="x11,surfaceless"
1820     if test "x$enable_gbm" = xyes; then
1821         with_egl_platforms="$with_egl_platforms,drm"
1822     fi
1823 else
1824     AC_MSG_WARN([--with-egl-platforms is deprecated. Use --with-platforms instead.])
1825 fi
1826
1827 dnl
1828 dnl Platforms configuration
1829 dnl
1830 AC_ARG_WITH([platforms],
1831     [AS_HELP_STRING([--with-platforms@<:@=DIRS...@:>@],
1832         [comma delimited native platforms libEGL/Vulkan/other supports, e.g.
1833         "x11,drm,wayland,surfaceless..." @<:@default=auto@:>@])],
1834     [with_platforms="$withval"],
1835     [with_platforms=auto])
1836
1837 # Reuse the autodetection rather than duplicating it.
1838 if test "x$with_platforms" = xauto; then
1839     with_platforms=$with_egl_platforms
1840 fi
1841
1842 # Do per platform setups and checks
1843 platforms=`IFS=', '; echo $with_platforms`
1844 for plat in $platforms; do
1845     case "$plat" in
1846     wayland)
1847
1848         PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= $WAYLAND_REQUIRED])
1849         PKG_CHECK_MODULES([WAYLAND_SERVER], [wayland-server >= $WAYLAND_REQUIRED])
1850         PKG_CHECK_MODULES([WAYLAND_PROTOCOLS], [wayland-protocols >= $WAYLAND_PROTOCOLS_REQUIRED])
1851         if test "x$enable_egl" = xyes; then
1852           PKG_CHECK_MODULES([WAYLAND_EGL], [wayland-egl-backend >= $WAYLAND_EGL_BACKEND_REQUIRED])
1853         fi
1854         WAYLAND_PROTOCOLS_DATADIR=`$PKG_CONFIG --variable=pkgdatadir wayland-protocols`
1855
1856         PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
1857                           WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
1858                           WAYLAND_SCANNER='')
1859         PKG_CHECK_EXISTS([wayland-scanner >= 1.15],
1860                           AC_SUBST(SCANNER_ARG, 'private-code'),
1861                           AC_SUBST(SCANNER_ARG, 'code'))
1862
1863         if test "x$WAYLAND_SCANNER" = x; then
1864             AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner], [:])
1865         fi
1866
1867         if test "x$WAYLAND_SCANNER" = "x:"; then
1868                 AC_MSG_ERROR([wayland-scanner is needed to compile the wayland platform])
1869         fi
1870         DEFINES="$DEFINES -DHAVE_WAYLAND_PLATFORM -DWL_HIDE_DEPRECATED"
1871         ;;
1872
1873     x11)
1874         PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1875         DEFINES="$DEFINES -DHAVE_X11_PLATFORM"
1876         ;;
1877
1878     drm)
1879         test "x$enable_gbm" = "xno" &&
1880                 AC_MSG_ERROR([EGL platform drm needs gbm])
1881         DEFINES="$DEFINES -DHAVE_DRM_PLATFORM"
1882         ;;
1883
1884     surfaceless)
1885         DEFINES="$DEFINES -DHAVE_SURFACELESS_PLATFORM"
1886         ;;
1887
1888     android)
1889         PKG_CHECK_MODULES([ANDROID], [cutils hardware sync])
1890         if test -n "$with_gallium_drivers"; then
1891             PKG_CHECK_MODULES([BACKTRACE], [backtrace])
1892         fi
1893         DEFINES="$DEFINES -DHAVE_ANDROID_PLATFORM"
1894         ;;
1895
1896     *)
1897         AC_MSG_ERROR([platform '$plat' does not exist])
1898         ;;
1899     esac
1900
1901     case "$plat" in
1902     wayland|drm|surfaceless)
1903         require_libdrm "Platform $plat"
1904         ;;
1905     esac
1906 done
1907 AC_SUBST([WAYLAND_PROTOCOLS_DATADIR])
1908
1909 if test "x$enable_glx" != xno; then
1910     if ! echo "$platforms" | grep -q 'x11'; then
1911         AC_MSG_ERROR([Building GLX without the x11 platform is not supported])
1912     fi
1913 fi
1914
1915 if test x"$enable_dri3" = xyes; then
1916     DEFINES="$DEFINES -DHAVE_DRI3"
1917
1918     dri3_modules="x11-xcb xcb >= $XCB_REQUIRED xcb-dri3 xcb-xfixes xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1919     PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1920     dri3_modifier_modules="xcb-dri3 >= $XCBDRI3_MODIFIERS_REQUIRED xcb-present >= $XCBPRESENT_MODIFIERS_REQUIRED"
1921     PKG_CHECK_MODULES([XCB_DRI3_MODIFIERS], [$dri3_modifier_modules], [have_dri3_modifiers=yes], [have_dri3_modifiers=no])
1922
1923     if test "x$have_dri3_modifiers" == xyes; then
1924         DEFINES="$DEFINES -DHAVE_DRI3_MODIFIERS"
1925     fi
1926 fi
1927
1928
1929 if echo "$platforms" | grep -q 'x11' && echo "$platforms" | grep -q 'drm'; then
1930     have_xlease=yes
1931 else
1932     have_xlease=no
1933 fi
1934
1935 if test x"$have_xlease" = xyes; then
1936     randr_modules="x11-xcb xcb-randr"
1937     PKG_CHECK_MODULES([XCB_RANDR], [$randr_modules])
1938     xlib_randr_modules="xrandr"
1939     PKG_CHECK_MODULES([XLIB_RANDR], [$xlib_randr_modules])
1940 fi
1941
1942 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$platforms" | grep -q 'x11')
1943 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$platforms" | grep -q 'wayland')
1944 AM_CONDITIONAL(HAVE_PLATFORM_DRM, echo "$platforms" | grep -q 'drm')
1945 AM_CONDITIONAL(HAVE_PLATFORM_SURFACELESS, echo "$platforms" | grep -q 'surfaceless')
1946 AM_CONDITIONAL(HAVE_PLATFORM_ANDROID, echo "$platforms" | grep -q 'android')
1947
1948 AC_ARG_ENABLE(xlib-lease,
1949     [AS_HELP_STRING([--enable-xlib-lease]
1950                     [enable VK_acquire_xlib_display using X leases])],
1951     [enable_xlib_lease=$enableval], [enable_xlib_lease=auto])
1952 case "x$enable_xlib_lease" in
1953 xyes)
1954     ;;
1955 xno)
1956     ;;
1957 *)
1958     if echo "$platforms" | grep -q 'x11' && echo "$platforms" | grep -q 'drm'; then
1959         enable_xlib_lease=yes
1960     else
1961         enable_xlib_lease=no
1962     fi
1963 esac
1964
1965 AM_CONDITIONAL(HAVE_XLIB_LEASE, test "x$enable_xlib_lease" = xyes)
1966
1967 dnl
1968 dnl More DRI setup
1969 dnl
1970 dnl Directory for DRI drivers
1971 AC_ARG_WITH([dri-driverdir],
1972     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1973         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1974     [DRI_DRIVER_INSTALL_DIR="$withval"],
1975     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1976 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1977 dnl Extra search path for DRI drivers
1978 AC_ARG_WITH([dri-searchpath],
1979     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1980         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1981     [DRI_DRIVER_SEARCH_DIR="$withval"],
1982     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1983 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1984 dnl Which drivers to build - default is chosen by platform
1985 AC_ARG_WITH([dri-drivers],
1986     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1987         [comma delimited classic DRI drivers list, e.g.
1988         "i915,i965,nouveau,radeon,r200,swrast" @<:@default=auto@:>@])],
1989     [with_dri_drivers="$withval"],
1990     [with_dri_drivers=auto])
1991
1992 if test "x$with_dri_drivers" = xauto; then
1993     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1994         with_dri_drivers="yes"
1995     else
1996         with_dri_drivers="no"
1997     fi
1998 fi
1999 if test "x$with_dri_drivers" = xno; then
2000     with_dri_drivers=''
2001 fi
2002
2003 # Check for expat
2004 PKG_CHECK_MODULES([EXPAT], [expat],,
2005     [PKG_CHECK_MODULES([EXPAT], [expat21])]
2006 )
2007
2008 dnl If $with_dri_drivers is yes, drivers will be added through
2009 dnl platform checks. Set DEFINES and LIB_DEPS
2010 if test "x$enable_dri" = xyes; then
2011     # Platform specific settings and drivers to build
2012     case "$host_os" in
2013     linux*)
2014         case "$host_cpu" in
2015         powerpc* | sparc*)
2016             # Build only the drivers for cards that exist on PowerPC/sparc
2017             if test "x$with_dri_drivers" = "xyes"; then
2018                 with_dri_drivers="r200 radeon swrast"
2019             fi
2020             ;;
2021         esac
2022         ;;
2023     cygwin*)
2024         if test "x$with_dri_drivers" = "xyes"; then
2025             with_dri_drivers="swrast"
2026         fi
2027         ;;
2028     darwin*)
2029         DEFINES="$DEFINES -DBUILDING_MESA"
2030         if test "x$with_dri_drivers" = "xyes"; then
2031             with_dri_drivers="swrast"
2032         fi
2033         ;;
2034     esac
2035
2036     # default drivers
2037     if test "x$with_dri_drivers" = "xyes"; then
2038         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
2039     fi
2040
2041     # put all the necessary libs together
2042     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
2043 fi
2044
2045 AC_SUBST([DRI_LIB_DEPS])
2046
2047 DRI_DIRS=''
2048 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
2049 if test -n "$with_dri_drivers"; then
2050     if test "x$enable_opengl" != xyes; then
2051         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
2052     fi
2053
2054     dri_drivers=`IFS=', '; echo $with_dri_drivers`
2055     for driver in $dri_drivers; do
2056         DRI_DIRS="$DRI_DIRS $driver"
2057         case "x$driver" in
2058         xi915)
2059             require_libdrm "i915"
2060             HAVE_I915_DRI=yes
2061             PKG_CHECK_MODULES([I915], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2062             ;;
2063         xi965)
2064             require_libdrm "i965"
2065             HAVE_I965_DRI=yes
2066             ;;
2067         xnouveau)
2068             require_libdrm "nouveau"
2069             HAVE_NOUVEAU_DRI=yes
2070             PKG_CHECK_MODULES([NVVIEUX], [libdrm >= $LIBDRM_NVVIEUX_REQUIRED libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
2071             ;;
2072         xradeon)
2073             require_libdrm "radeon"
2074             HAVE_RADEON_DRI=yes;
2075             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2076             ;;
2077         xr200)
2078             require_libdrm "r200"
2079             HAVE_R200_DRI=yes
2080             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2081             ;;
2082         xswrast)
2083             HAVE_SWRAST_DRI=yes
2084             ;;
2085         *)
2086             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
2087             ;;
2088         esac
2089     done
2090     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2091 fi
2092
2093
2094 dnl
2095 dnl Gallium LLVM
2096 dnl Deprecated: kept for backwards compatibility
2097 dnl
2098 AC_ARG_ENABLE([gallium-llvm],
2099     [AS_HELP_STRING([--enable-gallium-llvm],
2100         [DEPRECATED: use --enable-llvm instead])],
2101     [enable_gallium_llvm="$enableval"],
2102     [enable_gallium_llvm=auto])
2103
2104 if test "x$enable_gallium_llvm" != xauto; then
2105    AC_MSG_WARN([The --enable-gallium-llvm option has been deprecated. Use --enable-llvm instead.])
2106    enable_llvm=$enable_gallium_llvm
2107 fi
2108
2109 dnl
2110 dnl LLVM
2111 dnl
2112 AC_ARG_ENABLE([llvm],
2113     [AS_HELP_STRING([--enable-llvm],
2114         [build with LLVM support @<:@default=enabled on x86/x86_64@:>@])],
2115     [enable_llvm="$enableval"],
2116     [enable_llvm=auto])
2117
2118 if test "x$enable_llvm" = xauto -a "x$FOUND_LLVM" = xyes; then
2119     if test "x$FOUND_LLVM" = xyes; then
2120         case "$host_cpu" in
2121         i*86|x86_64|amd64) enable_llvm=yes;;
2122         *) enable_llvm=no;;
2123         esac
2124     else
2125         enable_llvm=no
2126     fi
2127 fi
2128
2129 if test "x$enable_llvm" = xyes -a "x$FOUND_LLVM" = xno; then
2130     AC_MSG_ERROR([--enable-llvm selected but llvm-config is not found])
2131 fi
2132
2133 #
2134 # Vulkan driver configuration
2135 #
2136
2137 AC_ARG_WITH([vulkan-drivers],
2138     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
2139         [comma delimited Vulkan drivers list, e.g.
2140         "intel,radeon"
2141         @<:@default=no@:>@])],
2142     [with_vulkan_drivers="$withval"],
2143     [with_vulkan_drivers="no"])
2144
2145 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
2146 # here so that the script doesn't choke on an unknown driver name later.
2147 case "x$with_vulkan_drivers" in
2148     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
2149     xno) with_vulkan_drivers='' ;;
2150 esac
2151
2152 AC_ARG_WITH([vulkan-icddir],
2153     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
2154         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
2155     [VULKAN_ICD_INSTALL_DIR="$withval"],
2156     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
2157 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
2158
2159 require_x11_dri3() {
2160     if echo "$platforms" | grep -q 'x11'; then
2161         if test "x$enable_dri3" != xyes; then
2162             AC_MSG_ERROR([$1 Vulkan driver requires DRI3 when built with X11])
2163         fi
2164     fi
2165 }
2166
2167 if test -n "$with_vulkan_drivers"; then
2168     if test "x$ac_cv_func_dl_iterate_phdr" = xno; then
2169         AC_MSG_ERROR([Vulkan drivers require the dl_iterate_phdr function])
2170     fi
2171
2172     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
2173     for driver in $VULKAN_DRIVERS; do
2174         case "x$driver" in
2175         xintel)
2176             require_libdrm "ANV"
2177             require_x11_dri3 "ANV"
2178             HAVE_INTEL_VULKAN=yes
2179             ;;
2180         xradeon)
2181             require_libdrm "radv"
2182             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2183             radeon_llvm_check $LLVM_REQUIRED_RADV "radv"
2184             require_x11_dri3 "radv"
2185             if test "x$acv_mako_found" = xno; then
2186                 AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
2187             fi
2188             HAVE_RADEON_VULKAN=yes
2189             ;;
2190         *)
2191             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
2192             ;;
2193         esac
2194     done
2195     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
2196 fi
2197
2198
2199 DEFINES="$DEFINES -DENABLE_SHADER_CACHE"
2200 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
2201 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
2202                                   "x$enable_osmesa" = xyes -o \
2203                                   -n "$DRI_DIRS")
2204
2205 dnl
2206 dnl OSMesa configuration
2207 dnl
2208
2209 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
2210 AC_ARG_WITH([osmesa-bits],
2211     [AS_HELP_STRING([--with-osmesa-bits=BITS],
2212         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
2213     [osmesa_bits="$withval"],
2214     [osmesa_bits=8])
2215 if test "x$osmesa_bits" != x8; then
2216     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
2217         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
2218         osmesa_bits=8
2219     fi
2220 fi
2221 case "x$osmesa_bits" in
2222 x8)
2223     OSMESA_LIB="${OSMESA_LIB}"
2224     ;;
2225 x16|x32)
2226     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
2227     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
2228     ;;
2229 *)
2230     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
2231     ;;
2232 esac
2233
2234 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
2235     # only link libraries with osmesa if shared
2236     if test "$enable_static" = no; then
2237         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2238     else
2239         OSMESA_LIB_DEPS=""
2240     fi
2241     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2242 fi
2243
2244 AC_SUBST([OSMESA_LIB_DEPS])
2245 AC_SUBST([OSMESA_PC_REQ])
2246 AC_SUBST([OSMESA_PC_LIB_PRIV])
2247
2248 dnl
2249 dnl gbm configuration
2250 dnl
2251 if test "x$enable_gbm" = xyes; then
2252     require_dri_shared_libs_and_glapi "gbm"
2253 fi
2254 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
2255 # FINISHME: GBM has a number of dependencies which we should add below
2256 GBM_PC_REQ_PRIV=""
2257 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
2258 AC_SUBST([GBM_PC_REQ_PRIV])
2259 AC_SUBST([GBM_PC_LIB_PRIV])
2260
2261 dnl
2262 dnl EGL configuration
2263 dnl
2264
2265 if test "x$enable_egl" = xyes; then
2266     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
2267
2268     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
2269
2270     require_dri_shared_libs_and_glapi "egl"
2271 fi
2272 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
2273 AC_SUBST([EGL_LIB_DEPS])
2274
2275 gallium_st="mesa"
2276
2277 dnl
2278 dnl XA configuration
2279 dnl
2280 if test "x$enable_xa" = xyes; then
2281     if test "x$with_gallium_drivers" = xswrast; then
2282        AC_MSG_ERROR([
2283           Building xa requires at least one non swrast gallium driver.
2284           If you are looking to use libxatracker.so with the VMware driver,
2285           make sure to include svga in the gallium drivers list, apart from
2286           enabling XA.
2287           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
2288     fi
2289     gallium_st="$gallium_st xa"
2290 fi
2291 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
2292
2293 if echo $platforms | grep -q "x11"; then
2294     have_xvmc_platform=yes
2295 else
2296     have_xvmc_platform=no
2297 fi
2298
2299 if echo $platforms | grep -q "x11"; then
2300     have_vdpau_platform=yes
2301 else
2302     have_vdpau_platform=no
2303 fi
2304
2305 if echo $platforms | egrep -q "x11|drm"; then
2306     have_omx_platform=yes
2307 else
2308     have_omx_platform=no
2309 fi
2310
2311 if echo $platforms | egrep -q "x11|drm|wayland"; then
2312     have_va_platform=yes
2313 else
2314     have_va_platform=no
2315 fi
2316
2317 dnl
2318 dnl Gallium G3DVL configuration
2319 dnl
2320 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
2321     if test "x$enable_xvmc" = xauto -a "x$have_xvmc_platform" = xyes; then
2322         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
2323     fi
2324
2325     if test "x$enable_vdpau" = xauto -a "x$have_vdpau_platform" = xyes; then
2326         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
2327     fi
2328
2329     if test "x$enable_omx_bellagio" = xauto -a "x$have_omx_platform" = xyes; then
2330         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx_bellagio=yes], [enable_omx_bellagio=no])
2331     fi
2332
2333     if test "x$enable_omx_tizonia" = xauto -a "x$have_omx_platform" = xyes; then
2334        PKG_CHECK_EXISTS([libtizonia >= $LIBOMXIL_TIZONIA_REQUIRED], [enable_omx_tizonia=yes], [enable_omx_tizonia=no])
2335     fi
2336
2337     if test "x$enable_va" = xauto -a "x$have_va_platform" = xyes; then
2338         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
2339     fi
2340 fi
2341
2342 if test "x$enable_dri" = xyes -o \
2343         "x$enable_xvmc" = xyes -o \
2344         "x$enable_vdpau" = xyes -o \
2345         "x$enable_omx_bellagio" = xyes -o \
2346         "x$enable_omx_tizonia" = xyes -o \
2347         "x$enable_va" = xyes; then
2348     need_gallium_vl=yes
2349 fi
2350 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
2351
2352 if test "x$enable_xvmc" = xyes -o \
2353         "x$enable_vdpau" = xyes -o \
2354         "x$enable_omx_bellagio" = xyes -o \
2355         "x$enable_omx_tizonia" = xyes -o \
2356         "x$enable_va" = xyes; then
2357     if echo $platforms | grep -q "x11"; then
2358         PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2359     fi
2360     need_gallium_vl_winsys=yes
2361 fi
2362 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
2363
2364 if test "x$enable_xvmc" = xyes; then
2365     if test "x$have_xvmc_platform" != xyes; then
2366         AC_MSG_ERROR([XVMC requires the x11 platforms])
2367     fi
2368     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
2369     gallium_st="$gallium_st xvmc"
2370 fi
2371 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
2372
2373 if test "x$enable_vdpau" = xyes; then
2374     if test "x$have_vdpau_platform" != xyes; then
2375         AC_MSG_ERROR([VDPAU requires the x11 platforms])
2376     fi
2377     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
2378     gallium_st="$gallium_st vdpau"
2379     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
2380 fi
2381 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
2382
2383 if test "x$enable_omx_bellagio" = xyes; then
2384     if test "x$have_omx_platform" != xyes; then
2385         AC_MSG_ERROR([OMX requires at least one of the x11 or drm platforms])
2386     fi
2387     PKG_CHECK_MODULES([OMX_BELLAGIO], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
2388     gallium_st="$gallium_st omx_bellagio"
2389     AC_DEFINE([ENABLE_ST_OMX_BELLAGIO], 1, [Use Bellagio for OMX IL])
2390 else
2391     AC_DEFINE([ENABLE_ST_OMX_BELLAGIO], 0)
2392 fi
2393 AM_CONDITIONAL(HAVE_ST_OMX_BELLAGIO, test "x$enable_omx_bellagio" = xyes)
2394
2395 if test "x$enable_omx_tizonia" = xyes; then
2396     if test "x$have_omx_platform" != xyes; then
2397         AC_MSG_ERROR([OMX requires at least one of the x11 or drm platforms])
2398     fi
2399     PKG_CHECK_MODULES([OMX_TIZONIA],
2400                       [libtizonia >= $LIBOMXIL_TIZONIA_REQUIRED
2401                        tizilheaders >= $LIBOMXIL_TIZONIA_REQUIRED
2402                        libtizplatform >= $LIBOMXIL_TIZONIA_REQUIRED])
2403     gallium_st="$gallium_st omx_tizonia"
2404     AC_DEFINE([ENABLE_ST_OMX_TIZONIA], 1, [Use Tizoina for OMX IL])
2405 else
2406     AC_DEFINE([ENABLE_ST_OMX_TIZONIA], 0)
2407 fi
2408 AM_CONDITIONAL(HAVE_ST_OMX_TIZONIA, test "x$enable_omx_tizonia" = xyes)
2409
2410 if test "x$enable_va" = xyes; then
2411     if test "x$have_va_platform" != xyes; then
2412         AC_MSG_ERROR([VA requires at least one of the x11 drm or wayland platforms])
2413     fi
2414     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
2415     gallium_st="$gallium_st va"
2416 fi
2417 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
2418
2419 dnl
2420 dnl Nine Direct3D9 configuration
2421 dnl
2422 if test "x$enable_nine" = xyes; then
2423     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
2424         AC_MSG_ERROR([nine requires the gallium swrast driver])
2425     fi
2426     if test "x$with_gallium_drivers" = xswrast; then
2427         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
2428     fi
2429     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
2430         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
2431     fi
2432
2433     if test "x$enable_dri3" = xno; then
2434         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
2435     fi
2436
2437     gallium_st="$gallium_st nine"
2438 fi
2439 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
2440
2441 dnl
2442 dnl OpenCL configuration
2443 dnl
2444
2445 AC_ARG_WITH([clang-libdir],
2446    [AS_HELP_STRING([--with-clang-libdir],
2447          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
2448    [CLANG_LIBDIR="$withval"],
2449    [CLANG_LIBDIR=''])
2450
2451 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
2452
2453 if test "x$enable_opencl" = xyes; then
2454     if test -z "$with_gallium_drivers"; then
2455         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
2456     fi
2457
2458     if test "x$HAVE_CXX11" != "xyes"; then
2459        AC_MSG_ERROR([clover requires c++11 support])
2460     fi
2461
2462     if test "x$have_libclc" = xno; then
2463         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
2464                     Make sure the directory containing libclc.pc is specified in your
2465                     PKG_CONFIG_PATH environment variable.
2466                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
2467     else
2468         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
2469         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
2470         AC_SUBST([LIBCLC_INCLUDEDIR])
2471         AC_SUBST([LIBCLC_LIBEXECDIR])
2472     fi
2473
2474     gallium_st="$gallium_st clover"
2475
2476     if test "x$enable_opencl_icd" = xyes; then
2477         OPENCL_LIBNAME="MesaOpenCL"
2478     else
2479         OPENCL_LIBNAME="OpenCL"
2480     fi
2481
2482     if test "x$have_libelf" != xyes; then
2483        AC_MSG_ERROR([Clover requires libelf])
2484     fi
2485
2486     if test "x${ac_cv_cxx_compiler_gnu}" = xyes; then
2487         altivec_enabled=no
2488         AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2489         #if !defined(__VEC__) || !defined(__ALTIVEC__)
2490         #error "AltiVec not enabled"
2491         #endif
2492         ])], altivec_enabled=yes)
2493
2494         if test "$altivec_enabled" = yes; then
2495             CLOVER_STD_OVERRIDE="-std=gnu++11"
2496         fi
2497         AC_SUBST([CLOVER_STD_OVERRIDE])
2498     fi
2499
2500     llvm_require_version $LLVM_REQUIRED_OPENCL "opencl"
2501
2502     llvm_add_default_components "opencl"
2503     llvm_add_component "all-targets" "opencl"
2504     llvm_add_component "coverage" "opencl"
2505     llvm_add_component "linker" "opencl"
2506     llvm_add_component "instrumentation" "opencl"
2507     llvm_add_component "ipo" "opencl"
2508     llvm_add_component "irreader" "opencl"
2509     llvm_add_component "lto" "opencl"
2510     llvm_add_component "option" "opencl"
2511     llvm_add_component "objcarcopts" "opencl"
2512     llvm_add_component "profiledata" "opencl"
2513     llvm_add_optional_component "coroutines" "opencl"
2514
2515     dnl Check for Clang internal headers
2516     if test -z "$CLANG_LIBDIR"; then
2517         CLANG_LIBDIR=${LLVM_LIBDIR}
2518     fi
2519     CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2520     AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2521         [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2522 fi
2523 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2524 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2525 AC_SUBST([OPENCL_LIBNAME])
2526 AC_SUBST([CLANG_RESOURCE_DIR])
2527
2528 dnl
2529 dnl Gallium configuration
2530 dnl
2531 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2532
2533 # libEGL wants to default to the first platform specified in
2534 # ./configure.  parse that here.
2535 if test "x$platforms" != "x"; then
2536     FIRST_PLATFORM_CAPS=`echo $platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2537     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2538 else
2539     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2540 fi
2541
2542 AC_SUBST([EGL_NATIVE_PLATFORM])
2543 AC_SUBST([EGL_CFLAGS])
2544
2545 # If we don't have the X11 platform, set this define so we don't try to include
2546 # the X11 headers.
2547 if ! echo "$platforms" | grep -q 'x11'; then
2548     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2549     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2550 fi
2551
2552 dnl Directory for XVMC libs
2553 AC_ARG_WITH([xvmc-libdir],
2554     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2555         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2556     [XVMC_LIB_INSTALL_DIR="$withval"],
2557     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2558 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2559
2560 dnl
2561 dnl Gallium Tests
2562 dnl
2563 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2564
2565 dnl Directory for VDPAU libs
2566 AC_ARG_WITH([vdpau-libdir],
2567     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2568         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2569     [VDPAU_LIB_INSTALL_DIR="$withval"],
2570     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2571 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2572
2573 dnl Directory for OMX_BELLAGIO libs
2574
2575 AC_ARG_WITH([omx-bellagio-libdir],
2576     [AS_HELP_STRING([--with-omx-bellagio-libdir=DIR],
2577         [directory for the OMX_BELLAGIO libraries])],
2578     [OMX_BELLAGIO_LIB_INSTALL_DIR="$withval"],
2579     [OMX_BELLAGIO_LIB_INSTALL_DIR=`$PKG_CONFIG --exists libomxil-bellagio && \
2580                                    $PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2581 AC_SUBST([OMX_BELLAGIO_LIB_INSTALL_DIR])
2582
2583 dnl Directory for OMX_TIZONIA libs
2584
2585 AC_ARG_WITH([omx-tizonia-libdir],
2586     [AS_HELP_STRING([--with-omx-tizonia-libdir=DIR],
2587         [directory for the OMX_TIZONIA libraries])],
2588     [OMX_TIZONIA_LIB_INSTALL_DIR="$withval"],
2589     [OMX_TIZONIA_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libtizcore`])
2590 AC_SUBST([OMX_TIZONIA_LIB_INSTALL_DIR])
2591
2592 dnl Directory for VA libs
2593
2594 AC_ARG_WITH([va-libdir],
2595     [AS_HELP_STRING([--with-va-libdir=DIR],
2596         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2597     [VA_LIB_INSTALL_DIR="$withval"],
2598     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2599 AC_SUBST([VA_LIB_INSTALL_DIR])
2600
2601 AC_ARG_WITH([d3d-libdir],
2602     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2603         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2604     [D3D_DRIVER_INSTALL_DIR="$withval"],
2605     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2606 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2607
2608 dnl Architectures to build SWR library for
2609
2610 AC_ARG_WITH([swr-archs],
2611     [AS_HELP_STRING([--with-swr-archs@<:@=DIRS...@:>@],
2612         [comma delimited swr architectures list, e.g.
2613         "avx,avx2,knl,skx" @<:@default="avx,avx2"@:>@])],
2614     [with_swr_archs="$withval"],
2615     [with_swr_archs="avx,avx2"])
2616
2617 dnl
2618 dnl r300 doesn't strictly require LLVM, but for performance reasons we
2619 dnl highly recommend LLVM usage. So require it at least on x86 and x86_64
2620 dnl architectures.
2621 dnl
2622 r300_require_llvm() {
2623     case "$host" in *gnux32) return;; esac
2624     case "$host_cpu" in
2625     i*86|x86_64|amd64) require_llvm $1
2626         ;;
2627     esac
2628 }
2629
2630 dnl
2631 dnl DRM is needed by X, Wayland, and offscreen rendering.
2632 dnl Surfaceless is an alternative for the last one.
2633 dnl
2634 require_basic_egl() {
2635     case "$with_platforms" in
2636         *drm*|*surfaceless*|*android*)
2637             ;;
2638         *)
2639             AC_MSG_ERROR([$1 requires one of these:
2640                   1) --with-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2641                   2) --with-platforms=surfaceless (offscreen only)
2642                   3) --with-platforms=android (Android only)
2643                   Recommended options: drm,x11])
2644             ;;
2645     esac
2646 }
2647
2648 swr_require_cxx_feature_flags() {
2649     feature_name="$1"
2650     preprocessor_test="$2"
2651     option_list="$3"
2652     output_var="$4"
2653
2654     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2655     AC_LANG_PUSH([C++])
2656     save_CXXFLAGS="$CXXFLAGS"
2657     save_IFS="$IFS"
2658     IFS=","
2659     found=0
2660     for opts in $option_list
2661     do
2662         unset IFS
2663         CXXFLAGS="$opts $save_CXXFLAGS"
2664         AC_COMPILE_IFELSE(
2665             [AC_LANG_PROGRAM(
2666                 [   #if !($preprocessor_test)
2667                     #error
2668                     #endif
2669                 ])],
2670             [found=1; break],
2671             [])
2672         IFS=","
2673     done
2674     IFS="$save_IFS"
2675     CXXFLAGS="$save_CXXFLAGS"
2676     AC_LANG_POP([C++])
2677     if test $found -eq 1; then
2678         AC_MSG_RESULT([$opts])
2679         eval "$output_var=\$opts"
2680         return 0
2681     fi
2682     AC_MSG_RESULT([no])
2683     AC_MSG_ERROR([swr requires $feature_name support])
2684     return 1
2685 }
2686
2687 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2688 if test -n "$with_gallium_drivers"; then
2689     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2690     for driver in $gallium_drivers; do
2691         case "x$driver" in
2692         xsvga)
2693             HAVE_GALLIUM_SVGA=yes
2694             require_libdrm "svga"
2695             ;;
2696         xi915)
2697             HAVE_GALLIUM_I915=yes
2698             PKG_CHECK_MODULES([I915], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2699             require_libdrm "Gallium i915"
2700             ;;
2701         xr300)
2702             HAVE_GALLIUM_R300=yes
2703             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2704             require_libdrm "r300"
2705             r300_require_llvm "r300"
2706             ;;
2707         xr600)
2708             HAVE_GALLIUM_R600=yes
2709             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2710             require_libdrm "r600"
2711             if test "x$enable_llvm" = xyes; then
2712                 radeon_llvm_check $LLVM_REQUIRED_R600 "r600"
2713
2714                 llvm_add_component "asmparser" "r600"
2715                 llvm_add_component "bitreader" "r600"
2716             fi
2717             ;;
2718         xradeonsi)
2719             HAVE_GALLIUM_RADEONSI=yes
2720             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2721             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2722             require_libdrm "radeonsi"
2723             radeon_llvm_check $LLVM_REQUIRED_RADEONSI "radeonsi"
2724             if test "x$enable_egl" = xyes; then
2725                 require_basic_egl "radeonsi"
2726             fi
2727             ;;
2728         xnouveau)
2729             HAVE_GALLIUM_NOUVEAU=yes
2730             PKG_CHECK_MODULES([NOUVEAU], [libdrm >= $LIBDRM_NOUVEAU_REQUIRED libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2731             require_libdrm "nouveau"
2732             ;;
2733         xfreedreno)
2734             HAVE_GALLIUM_FREEDRENO=yes
2735             require_libdrm "freedreno"
2736             ;;
2737         xetnaviv)
2738             HAVE_GALLIUM_ETNAVIV=yes
2739             PKG_CHECK_MODULES([ETNAVIV], [libdrm >= $LIBDRM_ETNAVIV_REQUIRED libdrm_etnaviv >= $LIBDRM_ETNAVIV_REQUIRED])
2740             require_libdrm "etnaviv"
2741             ;;
2742        ximx)
2743             HAVE_GALLIUM_IMX=yes
2744             ;;
2745         xtegra)
2746             HAVE_GALLIUM_TEGRA=yes
2747             require_libdrm "tegra"
2748             ;;
2749         xswrast)
2750             HAVE_GALLIUM_SOFTPIPE=yes
2751             if test "x$enable_llvm" = xyes; then
2752                 HAVE_GALLIUM_LLVMPIPE=yes
2753             fi
2754             ;;
2755         xswr)
2756             llvm_require_version $LLVM_REQUIRED_SWR "swr"
2757
2758             if test "x$HAVE_CXX11" != "xyes"; then
2759                 AC_MSG_ERROR([swr requires c++11 support])
2760             fi
2761
2762             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2763                 ",-target-cpu=sandybridge,-mavx,-march=core-avx,-tp=sandybridge" \
2764                 SWR_AVX_CXXFLAGS
2765             AC_SUBST([SWR_AVX_CXXFLAGS])
2766
2767             swr_archs=`IFS=', '; echo $with_swr_archs`
2768             for arch in $swr_archs; do
2769                 case "x$arch" in
2770                 xavx)
2771                     HAVE_SWR_AVX=yes
2772                     ;;
2773                 xavx2)
2774                     swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2775                         ",-target-cpu=haswell,-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2,-tp=haswell" \
2776                         SWR_AVX2_CXXFLAGS
2777                     AC_SUBST([SWR_AVX2_CXXFLAGS])
2778                     HAVE_SWR_AVX2=yes
2779                     ;;
2780                 xknl)
2781                     swr_require_cxx_feature_flags "KNL" "defined(__AVX512F__) && defined(__AVX512ER__)" \
2782                         ",-target-cpu=mic-knl,-march=knl,-xMIC-AVX512" \
2783                         SWR_KNL_CXXFLAGS
2784                     AC_SUBST([SWR_KNL_CXXFLAGS])
2785                     HAVE_SWR_KNL=yes
2786                     ;;
2787                 xskx)
2788                     swr_require_cxx_feature_flags "SKX" "defined(__AVX512F__) && defined(__AVX512BW__)" \
2789                         ",-target-cpu=x86-skylake,-march=skylake-avx512,-xCORE-AVX512" \
2790                         SWR_SKX_CXXFLAGS
2791                     AC_SUBST([SWR_SKX_CXXFLAGS])
2792                     HAVE_SWR_SKX=yes
2793                     ;;
2794                 *)
2795                     AC_MSG_ERROR([unknown SWR build architecture '$arch'])
2796                     ;;
2797                 esac
2798             done
2799
2800             if test "x$HAVE_SWR_AVX" != xyes -a \
2801                     "x$HAVE_SWR_AVX2" != xyes -a \
2802                     "x$HAVE_SWR_KNL" != xyes -a \
2803                     "x$HAVE_SWR_SKX" != xyes; then
2804                AC_MSG_ERROR([swr enabled but no swr architectures selected])
2805             fi
2806
2807             # test if more than one swr arch configured
2808             if test `echo $swr_archs | wc -w` -eq 1; then
2809                 HAVE_SWR_BUILTIN=yes
2810             fi
2811
2812             HAVE_GALLIUM_SWR=yes
2813             ;;
2814         xvc4)
2815             HAVE_GALLIUM_VC4=yes
2816             PKG_CHECK_MODULES([VC4], [libdrm >= $LIBDRM_VC4_REQUIRED])
2817
2818             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2819                               [USE_VC4_SIMULATOR=yes;
2820                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2821                               [USE_VC4_SIMULATOR=no])
2822             ;;
2823         xv3d)
2824             HAVE_GALLIUM_V3D=yes
2825
2826             PKG_CHECK_MODULES([V3D_SIMULATOR], [v3dv3],
2827                               [USE_V3D_SIMULATOR=yes;
2828                                DEFINES="$DEFINES -DUSE_V3D_SIMULATOR"],
2829                               [USE_V3D_SIMULATOR=no])
2830             ;;
2831         xpl111)
2832             HAVE_GALLIUM_PL111=yes
2833             ;;
2834         xvirgl)
2835             HAVE_GALLIUM_VIRGL=yes
2836             require_libdrm "virgl"
2837             if test "x$enable_egl" = xyes; then
2838                 require_basic_egl "virgl"
2839             fi
2840             ;;
2841         *)
2842             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2843             ;;
2844         esac
2845     done
2846 fi
2847
2848 # XXX: Keep in sync with LLVM_REQUIRED_SWR
2849 AM_CONDITIONAL(SWR_INVALID_LLVM_VERSION, test "x$LLVM_VERSION" != x6.0.0 -a \
2850                                               "x$LLVM_VERSION" != x6.0.1)
2851
2852 if test "x$enable_llvm" = "xyes" -a "$with_gallium_drivers"; then
2853     llvm_require_version $LLVM_REQUIRED_GALLIUM "gallium"
2854     llvm_add_default_components "gallium"
2855 fi
2856
2857 AM_CONDITIONAL(HAVE_SWR_AVX, test "x$HAVE_SWR_AVX" = xyes)
2858 AM_CONDITIONAL(HAVE_SWR_AVX2, test "x$HAVE_SWR_AVX2" = xyes)
2859 AM_CONDITIONAL(HAVE_SWR_KNL, test "x$HAVE_SWR_KNL" = xyes)
2860 AM_CONDITIONAL(HAVE_SWR_SKX, test "x$HAVE_SWR_SKX" = xyes)
2861 AM_CONDITIONAL(HAVE_SWR_BUILTIN, test "x$HAVE_SWR_BUILTIN" = xyes)
2862
2863 dnl We need to validate some needed dependencies for renderonly drivers.
2864
2865 if test "x$HAVE_GALLIUM_ETNAVIV" != xyes -a "x$HAVE_GALLIUM_IMX" = xyes  ; then
2866     AC_MSG_ERROR([Building with imx requires etnaviv])
2867 fi
2868
2869 if test "x$HAVE_GALLIUM_VC4" != xyes -a "x$HAVE_GALLIUM_PL111" = xyes  ; then
2870     AC_MSG_ERROR([Building with pl111 requires vc4])
2871 fi
2872
2873 if test "x$HAVE_GALLIUM_NOUVEAU" != xyes -a "x$HAVE_GALLIUM_TEGRA" = xyes; then
2874     AC_MSG_ERROR([Building with tegra requires nouveau])
2875 fi
2876
2877 detect_old_buggy_llvm() {
2878     dnl llvm-config may not give the right answer when llvm is a built as a
2879     dnl single shared library, so we must work the library name out for
2880     dnl ourselves.
2881     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2882     dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2883     LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2884     AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2885
2886     if test "x$llvm_have_one_so" = xyes; then
2887         dnl LLVM was built using auto*, so there is only one shared object.
2888         LLVM_LIBS="-l$LLVM_SO_NAME"
2889     else
2890         dnl If LLVM was built with CMake, there will be one shared object per
2891         dnl component.
2892         AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2893                [AC_MSG_ERROR([Could not find llvm shared libraries:
2894                 Please make sure you have built llvm with the --enable-shared option
2895                 and that your llvm libraries are installed in $LLVM_LIBDIR
2896                 If you have installed your llvm libraries to a different directory you
2897                 can use the --with-llvm-prefix= configure flag to specify this directory.
2898                 NOTE: Mesa is attempting to use llvm shared libraries by default.
2899                 If you do not want to build with llvm shared libraries and instead want to
2900                 use llvm static libraries then add --disable-llvm-shared-libs to your configure
2901                 invocation and rebuild.])])
2902
2903         dnl We don't need to update LLVM_LIBS in this case because the LLVM
2904         dnl install uses a shared object for each component and we have
2905         dnl already added all of these objects to LLVM_LIBS.
2906     fi
2907 }
2908
2909 dnl
2910 dnl Set defines and buildtime variables only when using LLVM.
2911 dnl
2912 if test "x$enable_llvm" = xyes; then
2913     DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2914
2915     LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2916     LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
2917     LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2918
2919     dnl Set LLVM_LIBS - This is done after the driver configuration so
2920     dnl that drivers can add additional components to LLVM_COMPONENTS.
2921     dnl Previously, gallium drivers were updating LLVM_LIBS directly
2922     dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2923     dnl this was causing the same libraries to be appear multiple times
2924     dnl in LLVM_LIBS.
2925
2926     if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 9; then
2927         if test "x$enable_llvm_shared_libs" = xyes; then
2928             LLVM_LIBS="`$LLVM_CONFIG --link-shared --libs ${LLVM_COMPONENTS}`"
2929         else
2930             dnl Invoking llvm-config with both -libs and --system-libs produces the
2931             dnl two separate lines - each for the set of libraries.
2932                 dnl Call the program twice, effectively folding them into a single line.
2933             LLVM_LIBS="`$LLVM_CONFIG --link-static --libs ${LLVM_COMPONENTS}`"
2934             dnl We need to link to llvm system libs when using static libs
2935             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --link-static --system-libs`"
2936         fi
2937     else
2938         LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2939         if test "x$enable_llvm_shared_libs" = xyes; then
2940             detect_old_buggy_llvm
2941         else
2942             AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2943             dnl We need to link to llvm system libs when using static libs
2944             dnl However, only llvm 3.5+ provides --system-libs
2945             if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2946                 LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2947             fi
2948         fi
2949     fi
2950
2951     dnl The gallium-xlib GLX and gallium OSMesa targets directly embed the
2952     dnl swr/llvmpipe driver into the final binary.  Adding LLVM_LIBS results in
2953     dnl the LLVM library propagated in the Libs.private of the respective .pc
2954     dnl file which ensures complete dependency information when statically
2955     dnl linking.
2956     if test "x$enable_glx" == xgallium-xlib; then
2957         GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $LLVM_LIBS"
2958     fi
2959     if test "x$enable_gallium_osmesa" = xyes; then
2960         OSMESA_PC_LIB_PRIV="$OSMESA_PC_LIB_PRIV $LLVM_LIBS"
2961     fi
2962 fi
2963
2964 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2965 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2966 AM_CONDITIONAL(HAVE_GALLIUM_PL111, test "x$HAVE_GALLIUM_PL111" = xyes)
2967 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2968 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2969 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2970 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2971 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2972 AM_CONDITIONAL(HAVE_GALLIUM_ETNAVIV, test "x$HAVE_GALLIUM_ETNAVIV" = xyes)
2973 AM_CONDITIONAL(HAVE_GALLIUM_IMX, test "x$HAVE_GALLIUM_IMX" = xyes)
2974 AM_CONDITIONAL(HAVE_GALLIUM_TEGRA, test "x$HAVE_GALLIUM_TEGRA" = xyes)
2975 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2976 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2977 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2978 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2979                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2980                                          "x$HAVE_GALLIUM_SWR" = xyes)
2981 AM_CONDITIONAL(HAVE_GALLIUM_V3D, test "x$HAVE_GALLIUM_V3D" = xyes)
2982 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2983 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2984
2985 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2986
2987 if test "x$enable_dri" = xyes; then
2988     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2989 fi
2990
2991 if test "x$have_drisw_kms" = xyes; then
2992     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2993 fi
2994 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2995
2996 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2997 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2998 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2999 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
3000 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
3001 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
3002
3003 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
3004 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
3005
3006 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
3007                                       "x$HAVE_RADEON_VULKAN" = xyes)
3008
3009 AM_CONDITIONAL(HAVE_BROADCOM_DRIVERS, test "x$HAVE_GALLIUM_VC4" = xyes -o \
3010                                       "x$HAVE_GALLIUM_V3D" = xyes)
3011
3012 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
3013                                         "x$HAVE_I965_DRI" = xyes)
3014
3015 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
3016                                             "x$HAVE_GALLIUM_R600" = xyes -o \
3017                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
3018 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
3019 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
3020 AM_CONDITIONAL(HAVE_GALLIUM_LLVM, test "x$enable_llvm" = xyes)
3021 AM_CONDITIONAL(USE_V3D_SIMULATOR, test x$USE_V3D_SIMULATOR = xyes)
3022 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
3023
3024 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
3025 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
3026 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
3027 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
3028                                         "x$enable_gallium_osmesa" = xyes)
3029
3030 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
3031 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
3032 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
3033 AM_CONDITIONAL(HAVE_PPC64LE_ASM, test "x$asm_arch" = xppc64le)
3034 AM_CONDITIONAL(HAVE_AARCH64_ASM, test "x$asm_arch" = xaarch64)
3035 AM_CONDITIONAL(HAVE_ARM_ASM, test "x$asm_arch" = xarm)
3036
3037 AC_SUBST([NINE_MAJOR], 1)
3038 AC_SUBST([NINE_MINOR], 0)
3039 AC_SUBST([NINE_PATCH], 0)
3040 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_PATCH")
3041
3042 AC_SUBST([VDPAU_MAJOR], 1)
3043 AC_SUBST([VDPAU_MINOR], 0)
3044
3045 if test "x$enable_va" = xyes; then
3046     VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
3047     VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
3048 fi
3049 AC_SUBST([VA_MAJOR], $VA_MAJOR)
3050 AC_SUBST([VA_MINOR], $VA_MINOR)
3051
3052 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
3053
3054 AC_SUBST([XVMC_MAJOR], 1)
3055 AC_SUBST([XVMC_MINOR], 0)
3056
3057 AC_SUBST([XA_MAJOR], 2)
3058 AC_SUBST([XA_MINOR], 4)
3059 AC_SUBST([XA_PATCH], 0)
3060 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_PATCH")
3061
3062 AC_ARG_ENABLE(valgrind,
3063               [AS_HELP_STRING([--enable-valgrind],
3064                              [Build mesa with valgrind support (default: auto)])],
3065                              [VALGRIND=$enableval], [VALGRIND=auto])
3066 if test "x$VALGRIND" != xno; then
3067     PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
3068 fi
3069 AC_MSG_CHECKING([whether to enable Valgrind support])
3070 if test "x$VALGRIND" = xauto; then
3071     VALGRIND="$have_valgrind"
3072 fi
3073
3074 if test "x$VALGRIND" = "xyes"; then
3075     if ! test "x$have_valgrind" = xyes; then
3076         AC_MSG_ERROR([Valgrind support required but not present])
3077     fi
3078     AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
3079 fi
3080
3081 AC_MSG_RESULT([$VALGRIND])
3082
3083 dnl Restore LDFLAGS and CPPFLAGS
3084 LDFLAGS="$_SAVE_LDFLAGS"
3085 CPPFLAGS="$_SAVE_CPPFLAGS"
3086
3087 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
3088 if test "x$acv_mesa_CLANG" = xyes; then
3089     CFLAGS="$CFLAGS -Qunused-arguments"
3090     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
3091 fi
3092
3093 dnl Add user CFLAGS and CXXFLAGS
3094 CFLAGS="$CFLAGS $USER_CFLAGS"
3095 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
3096
3097 dnl Substitute the config
3098 AC_CONFIG_FILES([Makefile
3099                  src/Makefile
3100                  src/amd/Makefile
3101                  src/amd/vulkan/Makefile
3102                  src/broadcom/Makefile
3103                  src/compiler/Makefile
3104                  src/egl/Makefile
3105                  src/egl/main/egl.pc
3106                  src/egl/wayland/wayland-drm/Makefile
3107                  src/gallium/Makefile
3108                  src/gallium/auxiliary/Makefile
3109                  src/gallium/auxiliary/pipe-loader/Makefile
3110                  src/gallium/drivers/freedreno/Makefile
3111                  src/gallium/drivers/i915/Makefile
3112                  src/gallium/drivers/llvmpipe/Makefile
3113                  src/gallium/drivers/nouveau/Makefile
3114                  src/gallium/drivers/pl111/Makefile
3115                  src/gallium/drivers/r300/Makefile
3116                  src/gallium/drivers/r600/Makefile
3117                  src/gallium/drivers/radeonsi/Makefile
3118                  src/gallium/drivers/softpipe/Makefile
3119                  src/gallium/drivers/svga/Makefile
3120                  src/gallium/drivers/swr/Makefile
3121                  src/gallium/drivers/tegra/Makefile
3122                  src/gallium/drivers/etnaviv/Makefile
3123                  src/gallium/drivers/imx/Makefile
3124                  src/gallium/drivers/v3d/Makefile
3125                  src/gallium/drivers/vc4/Makefile
3126                  src/gallium/drivers/virgl/Makefile
3127                  src/gallium/state_trackers/clover/Makefile
3128                  src/gallium/state_trackers/dri/Makefile
3129                  src/gallium/state_trackers/glx/xlib/Makefile
3130                  src/gallium/state_trackers/nine/Makefile
3131                  src/gallium/state_trackers/omx/Makefile
3132                  src/gallium/state_trackers/omx/bellagio/Makefile
3133                  src/gallium/state_trackers/omx/tizonia/Makefile
3134                  src/gallium/state_trackers/osmesa/Makefile
3135                  src/gallium/state_trackers/va/Makefile
3136                  src/gallium/state_trackers/vdpau/Makefile
3137                  src/gallium/state_trackers/xa/Makefile
3138                  src/gallium/state_trackers/xa/xa_tracker.h
3139                  src/gallium/state_trackers/xvmc/Makefile
3140                  src/gallium/targets/d3dadapter9/Makefile
3141                  src/gallium/targets/d3dadapter9/d3d.pc
3142                  src/gallium/targets/dri/Makefile
3143                  src/gallium/targets/libgl-xlib/Makefile
3144                  src/gallium/targets/omx/Makefile
3145                  src/gallium/targets/opencl/Makefile
3146                  src/gallium/targets/opencl/mesa.icd
3147                  src/gallium/targets/osmesa/Makefile
3148                  src/gallium/targets/osmesa/osmesa.pc
3149                  src/gallium/targets/pipe-loader/Makefile
3150                  src/gallium/targets/va/Makefile
3151                  src/gallium/targets/vdpau/Makefile
3152                  src/gallium/targets/xa/Makefile
3153                  src/gallium/targets/xa/xatracker.pc
3154                  src/gallium/targets/xvmc/Makefile
3155                  src/gallium/tests/trivial/Makefile
3156                  src/gallium/tests/unit/Makefile
3157                  src/gallium/winsys/etnaviv/drm/Makefile
3158                  src/gallium/winsys/imx/drm/Makefile
3159                  src/gallium/winsys/freedreno/drm/Makefile
3160                  src/gallium/winsys/i915/drm/Makefile
3161                  src/gallium/winsys/nouveau/drm/Makefile
3162                  src/gallium/winsys/pl111/drm/Makefile
3163                  src/gallium/winsys/radeon/drm/Makefile
3164                  src/gallium/winsys/amdgpu/drm/Makefile
3165                  src/gallium/winsys/svga/drm/Makefile
3166                  src/gallium/winsys/sw/dri/Makefile
3167                  src/gallium/winsys/sw/kms-dri/Makefile
3168                  src/gallium/winsys/sw/null/Makefile
3169                  src/gallium/winsys/sw/wrapper/Makefile
3170                  src/gallium/winsys/sw/xlib/Makefile
3171                  src/gallium/winsys/tegra/drm/Makefile
3172                  src/gallium/winsys/v3d/drm/Makefile
3173                  src/gallium/winsys/vc4/drm/Makefile
3174                  src/gallium/winsys/virgl/drm/Makefile
3175                  src/gallium/winsys/virgl/vtest/Makefile
3176                  src/gbm/Makefile
3177                  src/gbm/main/gbm.pc
3178                  src/glx/Makefile
3179                  src/glx/apple/Makefile
3180                  src/glx/tests/Makefile
3181                  src/glx/windows/Makefile
3182                  src/glx/windows/windowsdriproto.pc
3183                  src/gtest/Makefile
3184                  src/intel/Makefile
3185                  src/loader/Makefile
3186                  src/mapi/Makefile
3187                  src/mapi/es1api/glesv1_cm.pc
3188                  src/mapi/es2api/glesv2.pc
3189                  src/mapi/glapi/gen/Makefile
3190                  src/mesa/Makefile
3191                  src/mesa/gl.pc
3192                  src/mesa/drivers/dri/dri.pc
3193                  src/mesa/drivers/dri/common/Makefile
3194                  src/mesa/drivers/dri/i915/Makefile
3195                  src/mesa/drivers/dri/i965/Makefile
3196                  src/mesa/drivers/dri/Makefile
3197                  src/mesa/drivers/dri/nouveau/Makefile
3198                  src/mesa/drivers/dri/r200/Makefile
3199                  src/mesa/drivers/dri/radeon/Makefile
3200                  src/mesa/drivers/dri/swrast/Makefile
3201                  src/mesa/drivers/osmesa/Makefile
3202                  src/mesa/drivers/osmesa/osmesa.pc
3203                  src/mesa/drivers/x11/Makefile
3204                  src/mesa/main/tests/Makefile
3205                  src/mesa/state_tracker/tests/Makefile
3206                  src/util/Makefile
3207                  src/util/tests/fast_idiv_by_const/Makefile
3208                  src/util/tests/hash_table/Makefile
3209                  src/util/tests/set/Makefile
3210                  src/util/tests/string_buffer/Makefile
3211                  src/util/tests/vma/Makefile
3212                  src/util/xmlpool/Makefile
3213                  src/vulkan/Makefile])
3214
3215 AC_OUTPUT
3216
3217 # Fix up dependencies in *.Plo files, where we changed the extension of a
3218 # source file
3219 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
3220
3221 rm -f src/compiler/spirv/spirv_info.lo
3222 echo "# dummy" > src/compiler/spirv/.deps/spirv_info.Plo
3223
3224 rm -f src/compiler/nir/.deps/nir_intrinsics.Plo
3225 echo "# dummy" > src/compiler/nir/.deps/nir_intrinsics.Plo
3226
3227 dnl
3228 dnl Output some configuration info for the user
3229 dnl
3230 echo ""
3231 echo "        prefix:          $prefix"
3232 echo "        exec_prefix:     $exec_prefix"
3233 echo "        libdir:          $libdir"
3234 echo "        includedir:      $includedir"
3235
3236 dnl API info
3237 echo ""
3238 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
3239
3240 dnl Driver info
3241 echo ""
3242 case "x$enable_osmesa$enable_gallium_osmesa" in
3243 xnoyes)
3244         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
3245         ;;
3246 xyesno)
3247         echo "        OSMesa:          lib$OSMESA_LIB"
3248         ;;
3249 xnono)
3250         echo "        OSMesa:          no"
3251         ;;
3252 esac
3253
3254 echo ""
3255 if test "x$enable_dri" != xno; then
3256         echo "        DRI platform:    $dri_platform"
3257         if test -z "$DRI_DIRS"; then
3258             echo "        DRI drivers:     no"
3259         else
3260             echo "        DRI drivers:     $DRI_DIRS"
3261         fi
3262         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
3263 fi
3264
3265 case "x$enable_glx" in
3266 xdri)
3267     echo "        GLX:             DRI-based"
3268     ;;
3269 xxlib)
3270     echo "        GLX:             Xlib-based"
3271     ;;
3272 xgallium-xlib)
3273     echo "        GLX:             Xlib-based (Gallium)"
3274     ;;
3275 *)
3276     echo "        GLX:             $enable_glx"
3277     ;;
3278 esac
3279
3280 dnl EGL
3281 echo ""
3282 echo "        EGL:             $enable_egl"
3283 if test "$enable_egl" = yes; then
3284
3285     egl_drivers=""
3286     if test "x$enable_dri" != "xno"; then
3287         egl_drivers="$egl_drivers builtin:egl_dri2"
3288     fi
3289     if test "x$enable_dri3" != "xno"; then
3290         egl_drivers="$egl_drivers builtin:egl_dri3"
3291     fi
3292
3293     echo "        EGL drivers:    $egl_drivers"
3294 fi
3295 if test "x$enable_gbm" = xyes; then
3296     echo "        GBM:             yes"
3297 else
3298     echo "        GBM:             no"
3299 fi
3300
3301     echo "        EGL/Vulkan/VL platforms:   $platforms"
3302
3303 # Vulkan
3304 echo ""
3305 if test "x$VULKAN_DRIVERS" != x; then
3306     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
3307     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
3308 else
3309     echo "        Vulkan drivers:  no"
3310 fi
3311
3312 echo ""
3313 if test "x$enable_llvm" = xyes; then
3314     echo "        llvm:            yes"
3315     echo "        llvm-config:     $LLVM_CONFIG"
3316     echo "        llvm-version:    $LLVM_VERSION"
3317 else
3318     echo "        llvm:            no"
3319 fi
3320
3321 echo ""
3322 if test -n "$with_gallium_drivers"; then
3323     echo "        Gallium drivers: $gallium_drivers"
3324     echo "        Gallium st:      $gallium_st"
3325 else
3326     echo "        Gallium:         no"
3327 fi
3328
3329 echo ""
3330 if test "x$enable_gallium_extra_hud" != xyes; then
3331     echo "        HUD extra stats: no"
3332 else
3333     echo "        HUD extra stats: yes"
3334 fi
3335
3336 if test "x$enable_lmsensors" != xyes; then
3337     echo "        HUD lmsensors:   no"
3338 else
3339     echo "        HUD lmsensors:   yes"
3340 fi
3341
3342 echo ""
3343 if test "x$HAVE_GALLIUM_SWR" != x; then
3344     if test "x$HAVE_SWR_BUILTIN" = xyes; then
3345         echo "        SWR archs:       $swr_archs (builtin)"
3346     else
3347         echo "        SWR archs:       $swr_archs"
3348     fi
3349 fi
3350
3351 dnl Libraries
3352 echo ""
3353 echo "        Shared libs:     $enable_shared"
3354 echo "        Static libs:     $enable_static"
3355 echo "        Shared-glapi:    $enable_shared_glapi"
3356
3357 dnl Compiler options
3358 # cleanup the CFLAGS/CXXFLAGS/LDFLAGS/DEFINES vars
3359 cflags=`echo $CFLAGS | \
3360     $SED 's/^ *//;s/  */ /;s/ *$//'`
3361 cxxflags=`echo $CXXFLAGS | \
3362     $SED 's/^ *//;s/  */ /;s/ *$//'`
3363 ldflags=`echo $LDFLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
3364 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
3365 echo ""
3366 echo "        CFLAGS:          $cflags"
3367 echo "        CXXFLAGS:        $cxxflags"
3368 echo "        CXX11_CXXFLAGS:  $CXX11_CXXFLAGS"
3369 echo "        LDFLAGS:         $ldflags"
3370 echo "        Macros:          $defines"
3371 echo ""
3372 if test "x$enable_llvm" = xyes; then
3373     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
3374     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
3375     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
3376     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
3377     echo ""
3378 fi
3379 echo "        PYTHON2:         $PYTHON2"
3380
3381 echo ""
3382 echo "        Run '${MAKE-make}' to build Mesa"
3383 echo ""