configure.ac

   1 dnl (C) Copyright IBM Corporation 2006
   2 dnl All Rights Reserved.
   3 dnl
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a
   5 dnl copy of this software and associated documentation files (the "Software"),
   6 dnl to deal in the Software without restriction, including without limitation
   7 dnl on the rights to use, copy, modify, merge, publish, distribute, sub
   8 dnl license, and/or sell copies of the Software, and to permit persons to whom
   9 dnl the Software is furnished to do so, subject to the following conditions:
  10 dnl
  11 dnl The above copyright notice and this permission notice (including the next
  12 dnl paragraph) shall be included in all copies or substantial portions of the
  13 dnl Software.
  14 dnl
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  16 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  17 dnl FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
  18 dnl IBM AND/OR THEIR SUPPLIERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  19 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  20 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  21 dnl DEALINGS IN THE SOFTWARE.
  22 dnl
  23 dnl Process this file with autoconf to create configure.
  24
  25 # AC_DEFINE_DIR macro from autoconf-archive.cryp.to
  26 AC_DEFUN([AC_DEFINE_DIR], [
  27   prefix_NONE=
  28   exec_prefix_NONE=
  29   test "x$prefix" = xNONE && prefix_NONE=yes && prefix=$ac_default_prefix
  30   test "x$exec_prefix" = xNONE && exec_prefix_NONE=yes && exec_prefix=$prefix
  31 dnl In Autoconf 2.60, ${datadir} refers to ${datarootdir}, which in turn
  32 dnl refers to ${prefix}.  Thus we have to use `eval' twice.
  33   eval ac_define_dir="\"[$]$2\""
  34   eval ac_define_dir="\"$ac_define_dir\""
  35   AC_SUBST($1, "$ac_define_dir")
  36   AC_DEFINE_UNQUOTED($1, "$ac_define_dir", [$3])
  37   test "$prefix_NONE" && prefix=NONE
  38   test "$exec_prefix_NONE" && exec_prefix=NONE
  39 ])
  40
  41 AC_PREREQ([2.57])
  42
  43 AC_INIT(libpciaccess, 0.10.5, [https://bugs.freedesktop.org/enter_bug.cgi?product=xorg&component=libpciaccess], libpciaccess)
  44 AM_INIT_AUTOMAKE([dist-bzip2])
  45 AM_MAINTAINER_MODE
  46
  47 # Require xorg-macros: XORG_CWARNFLAGS, XORG_CHANGELOG
  48 m4_ifndef([XORG_MACROS_VERSION], [AC_FATAL([must install xorg-macros 1.2 or later before running autoconf/autogen])])
  49 XORG_MACROS_VERSION(1.2)
  50 AM_CONFIG_HEADER(config.h)
  51
  52 # Check for progs
  53 AC_PROG_CC
  54 AC_PROG_LIBTOOL
  55 XORG_CWARNFLAGS
  56
  57 pciids_path=/usr/share/hwdata
  58 AC_ARG_WITH(pciids-path, AC_HELP_STRING([--with-pciids-path=PCIIDS_PATH],
  59         [Path to pci.ids file]), [pciids_path="$withval"])
  60 AC_DEFINE_DIR(PCIIDS_PATH, pciids_path, [Path to pci.ids])
  61
  62 use_zlib=no
  63 AC_ARG_WITH(zlib, AC_HELP_STRING([--with-zlib],
  64         [Enable zlib support to read gzip compressed pci.ids]),
  65         [use_zlib="$withval"])
  66 if test "x$use_zlib" = xyes; then
  67         AC_CHECK_LIB(z, gzopen,
  68         [PCIACCESS_LIBS="$PCIACCESS_LIBS -lz"],
  69         [AC_MSG_ERROR(Check for zlib library failed)])
  70         AC_CHECK_HEADER([zlib.h],
  71         [AC_DEFINE(HAVE_ZLIB, 1, [Use zlib to read gzip compressed pci.ids])],
  72         [AC_MSG_ERROR(Check for zlib.h header file failed)])
  73 fi
  74
  75 case $host_os in
  76         *freebsd* | *dragonfly*)
  77                 freebsd=yes
  78                 ;;
  79         *linux*)
  80                 linux=yes
  81                 ;;
  82         *netbsd*)
  83                 case $host in
  84                 *i386*)
  85                         PCIACCESS_LIBS="-li386"
  86                         ;;
  87                 *x86_64*|*amd64*)
  88                         PCIACCESS_LIBS="-lx86_64"
  89                         ;;
  90                 esac
  91                 netbsd=yes
  92                 ;;
  93         *openbsd*)
  94                 openbsd=yes
  95                 ;;
  96         *solaris*)
  97                 solaris=yes
  98                 PCIACCESS_LIBS="$PCIACCESS_LIBS -ldevinfo"
  99                 ;;
 100 esac
 101
 102 AM_CONDITIONAL(LINUX, [test "x$linux" = xyes])
 103 AM_CONDITIONAL(FREEBSD, [test "x$freebsd" = xyes])
 104 AM_CONDITIONAL(NETBSD, [test "x$netbsd" = xyes])
 105 AM_CONDITIONAL(OPENBSD, [test "x$openbsd" = xyes])
 106 AM_CONDITIONAL(SOLARIS, [test "x$solaris" = xyes])
 107
 108 AC_SYS_LARGEFILE
 109
 110 AC_CHECK_HEADER([asm/mtrr.h], [have_mtrr_h="yes"], [have_mtrr_h="no"])
 111
 112 if test "x$have_mtrr_h" = xyes; then
 113     AC_DEFINE(HAVE_MTRR, 1, [Use MTRRs on mappings])
 114 fi
 115
 116 dnl check for the pci_io.pi_sel.pc_domain
 117 AC_CHECK_MEMBER([struct pci_io.pi_sel.pc_domain],
 118                [AC_DEFINE(HAVE_PCI_IO_PC_DOMAIN,1,[Have the pci_io.pi_sel.pc_domain member.])],
 119                [],
 120                [ #include <sys/types.h>
 121                  #include <sys/pciio.h>
 122                ])
 123
 124 PCIACCESS_CFLAGS="$CWARFLAGS $PCIACCESS_CFLAGS"
 125 AC_SUBST(PCIACCESS_CFLAGS)
 126 AC_SUBST(PCIACCESS_LIBS)
 127
 128 XORG_RELEASE_VERSION
 129 XORG_CHANGELOG
 130
 131 AC_OUTPUT([Makefile
 132            src/Makefile
 133            pciaccess.pc])