configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl
  13 dnl Permission is hereby granted, free of charge, to any person obtaining a
  14 dnl copy of this software and associated documentation files (the "Software"),
  15 dnl to deal in the Software without restriction, including without limitation
  16 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  17 dnl and/or sell copies of the Software, and to permit persons to whom the
  18 dnl Software is furnished to do so, subject to the following conditions:
  19 dnl
  20 dnl The above copyright notice and this permission notice (including the next
  21 dnl paragraph) shall be included in all copies or substantial portions of the
  22 dnl Software.
  23 dnl
  24 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  25 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  26 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  27 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  28 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  29 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  30 dnl DEALINGS IN THE SOFTWARE.
  31 dnl
  32 dnl Process this file with autoconf to create configure.
  33
  34 AC_PREREQ([2.60])
  35
  36 dnl Tell the user about autoconf.html in the --help output
  37 m4_divert_once([HELP_END], [
  38 See docs/autoconf.html for more details on the options for Mesa.])
  39
  40 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  41 AC_INIT([Mesa], [MESA_VERSION],
  42     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  43 AC_CONFIG_AUX_DIR([bin])
  44 AC_CONFIG_MACRO_DIR([m4])
  45 AC_CANONICAL_SYSTEM
  46 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  47
  48 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  49 case "$host_os" in
  50 mingw*)
  51     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  52     ;;
  53 esac
  54
  55 # Support silent build rules, requires at least automake-1.11. Disable
  56 # by either passing --disable-silent-rules to configure or passing V=1
  57 # to make
  58 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  59     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  60
  61 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  62
  63 dnl Set internal versions
  64 OSMESA_VERSION=8
  65 AC_SUBST([OSMESA_VERSION])
  66 OPENCL_VERSION=1
  67 AC_SUBST([OPENCL_VERSION])
  68
  69 # The idea is that libdrm is distributed as one cohesive package, even
  70 # though it is composed of multiple libraries. However some drivers
  71 # may have different version requirements than others. This list
  72 # codifies which drivers need which version of libdrm. Any libdrm
  73 # version dependencies in non-driver-specific code should be reflected
  74 # in the first entry.
  75 LIBDRM_REQUIRED=2.4.66
  76 LIBDRM_RADEON_REQUIRED=2.4.56
  77 LIBDRM_AMDGPU_REQUIRED=2.4.63
  78 LIBDRM_INTEL_REQUIRED=2.4.75
  79 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  80 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  81 LIBDRM_FREEDRENO_REQUIRED=2.4.74
  82 LIBDRM_VC4_REQUIRED=2.4.69
  83 LIBDRM_ETNAVIV_REQUIRED=2.4.74
  84
  85 dnl Versions for external dependencies
  86 DRI2PROTO_REQUIRED=2.8
  87 DRI3PROTO_REQUIRED=1.0
  88 PRESENTPROTO_REQUIRED=1.0
  89 GLPROTO_REQUIRED=1.4.14
  90 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  91 LIBVA_REQUIRED=0.38.0
  92 VDPAU_REQUIRED=1.1
  93 WAYLAND_REQUIRED=1.11
  94 XCB_REQUIRED=1.9.3
  95 XCBDRI2_REQUIRED=1.8
  96 XCBGLX_REQUIRED=1.8.1
  97 XDAMAGE_REQUIRED=1.1
  98 XSHMFENCE_REQUIRED=1.1
  99 XVMC_REQUIRED=1.0.6
 100 PYTHON_MAKO_REQUIRED=0.8.0
 101 LIBSENSORS_REQUIRED=4.0.0
 102
 103 dnl LLVM versions
 104 LLVM_REQUIRED_GALLIUM=3.3.0
 105 LLVM_REQUIRED_OPENCL=3.6.0
 106 LLVM_REQUIRED_R600=3.6.0
 107 LLVM_REQUIRED_RADEONSI=3.6.0
 108 LLVM_REQUIRED_RADV=3.9.0
 109 LLVM_REQUIRED_SWR=3.6.0
 110
 111 dnl Check for progs
 112 AC_PROG_CPP
 113 AC_PROG_CC
 114 AC_PROG_CXX
 115 AM_PROG_CC_C_O
 116 AM_PROG_AS
 117 AX_CHECK_GNU_MAKE
 118 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 119 AC_PROG_SED
 120 AC_PROG_MKDIR_P
 121
 122 AC_SYS_LARGEFILE
 123
 124 LT_PREREQ([2.2])
 125 LT_INIT([disable-static])
 126
 127 AC_CHECK_PROG(RM, rm, [rm -f])
 128 AC_CHECK_PROG(XXD, xxd, [xxd])
 129
 130 AX_PROG_BISON([],
 131               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 132                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 133 AX_PROG_FLEX([],
 134              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 135                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 136
 137 AC_CHECK_PROG(INDENT, indent, indent, cat)
 138 if test "x$INDENT" != "xcat"; then
 139     # Only GNU indent is supported
 140     INDENT_VERSION=`indent --version | grep GNU`
 141     if test $? -eq 0; then
 142        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 143     else
 144        INDENT="cat"
 145     fi
 146 fi
 147
 148 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 149
 150 if test -z "$PYTHON2"; then
 151     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 152         AC_MSG_ERROR([Python not found - unable to generate sources])
 153     fi
 154 else
 155     if test "x$acv_mako_found" = xno; then
 156         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 157             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 158         fi
 159     fi
 160 fi
 161
 162 AC_PROG_INSTALL
 163
 164 dnl We need a POSIX shell for parts of the build. Assume we have one
 165 dnl in most cases.
 166 case "$host_os" in
 167 solaris*)
 168     # Solaris /bin/sh is too old/non-POSIX compliant
 169     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 170     SHELL="$POSIX_SHELL"
 171     ;;
 172 esac
 173
 174 dnl clang is mostly GCC-compatible, but its version is much lower,
 175 dnl so we have to check for it.
 176 AC_MSG_CHECKING([if compiling with clang])
 177
 178 AC_COMPILE_IFELSE(
 179 [AC_LANG_PROGRAM([], [[
 180 #ifndef __clang__
 181        not clang
 182 #endif
 183 ]])],
 184 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 185
 186 AC_MSG_RESULT([$acv_mesa_CLANG])
 187
 188 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 189 dnl versions are explictly not supported.
 190 GEN_ASM_OFFSETS=no
 191 USE_GNU99=no
 192 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 193     AC_MSG_CHECKING([whether gcc version is sufficient])
 194     major=0
 195     minor=0
 196
 197     GCC_VERSION=`$CC -dumpversion`
 198     if test $? -eq 0; then
 199         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 200         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 201     fi
 202
 203     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 204         AC_MSG_RESULT([no])
 205         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 206     else
 207         AC_MSG_RESULT([yes])
 208     fi
 209
 210     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 211         USE_GNU99=yes
 212     fi
 213     if test "x$cross_compiling" = xyes; then
 214         GEN_ASM_OFFSETS=yes
 215     fi
 216 fi
 217
 218 dnl We don't support building Mesa with Sun C compiler
 219 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 220 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 221 if test "x$SUNCC" = xyes; then
 222     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 223 fi
 224
 225 dnl Check for compiler builtins
 226 AX_GCC_BUILTIN([__builtin_bswap32])
 227 AX_GCC_BUILTIN([__builtin_bswap64])
 228 AX_GCC_BUILTIN([__builtin_clz])
 229 AX_GCC_BUILTIN([__builtin_clzll])
 230 AX_GCC_BUILTIN([__builtin_ctz])
 231 AX_GCC_BUILTIN([__builtin_expect])
 232 AX_GCC_BUILTIN([__builtin_ffs])
 233 AX_GCC_BUILTIN([__builtin_ffsll])
 234 AX_GCC_BUILTIN([__builtin_popcount])
 235 AX_GCC_BUILTIN([__builtin_popcountll])
 236 AX_GCC_BUILTIN([__builtin_unreachable])
 237
 238 AX_GCC_FUNC_ATTRIBUTE([const])
 239 AX_GCC_FUNC_ATTRIBUTE([flatten])
 240 AX_GCC_FUNC_ATTRIBUTE([format])
 241 AX_GCC_FUNC_ATTRIBUTE([malloc])
 242 AX_GCC_FUNC_ATTRIBUTE([packed])
 243 AX_GCC_FUNC_ATTRIBUTE([pure])
 244 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 245 AX_GCC_FUNC_ATTRIBUTE([unused])
 246 AX_GCC_FUNC_ATTRIBUTE([visibility])
 247 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 248 AX_GCC_FUNC_ATTRIBUTE([weak])
 249 AX_GCC_FUNC_ATTRIBUTE([alias])
 250
 251 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 252
 253 dnl Make sure the pkg-config macros are defined
 254 m4_ifndef([PKG_PROG_PKG_CONFIG],
 255     [m4_fatal([Could not locate the pkg-config autoconf macros.
 256   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 257   are in a different location, try setting the environment variable
 258   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 259 PKG_PROG_PKG_CONFIG()
 260
 261 dnl LIB_DIR - library basename
 262 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 263 AC_SUBST([LIB_DIR])
 264
 265 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 266 _SAVE_LDFLAGS="$LDFLAGS"
 267 _SAVE_CPPFLAGS="$CPPFLAGS"
 268
 269 dnl Compiler macros
 270 DEFINES="-D__STDC_CONSTANT_MACROS -D__STDC_FORMAT_MACROS -D__STDC_LIMIT_MACROS"
 271 AC_SUBST([DEFINES])
 272 android=no
 273 case "$host_os" in
 274 *-android)
 275     android=yes
 276     ;;
 277 linux*|*-gnu*|gnu*|cygwin*)
 278     DEFINES="$DEFINES -D_GNU_SOURCE"
 279     ;;
 280 solaris*)
 281     DEFINES="$DEFINES -DSVR4"
 282     ;;
 283 esac
 284
 285 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 286
 287 dnl Add flags for gcc and g++
 288 if test "x$GCC" = xyes; then
 289     CFLAGS="$CFLAGS -Wall"
 290
 291     if test "x$USE_GNU99" = xyes; then
 292         CFLAGS="$CFLAGS -std=gnu99"
 293     else
 294         CFLAGS="$CFLAGS -std=c99"
 295     fi
 296
 297     # Enable -Werror=implicit-function-declaration and
 298     # -Werror=missing-prototypes, if available, or otherwise, just
 299     # -Wmissing-prototypes.  This is particularly useful to avoid
 300     # generating a loadable driver module that has undefined symbols.
 301     save_CFLAGS="$CFLAGS"
 302     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 303     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 304     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 305     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 306                    AC_MSG_RESULT([yes]),
 307                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 308                     AC_MSG_RESULT([no])]);
 309
 310     # Enable -fvisibility=hidden if using a gcc that supports it
 311     save_CFLAGS="$CFLAGS"
 312     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 313     VISIBILITY_CFLAGS="-fvisibility=hidden"
 314     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 315     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 316                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 317
 318     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 319     CFLAGS=$save_CFLAGS
 320
 321     # We don't want floating-point math functions to set errno or trap
 322     CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
 323
 324     # Flags to help ensure that certain portions of the code -- and only those
 325     # portions -- can be built with MSVC:
 326     # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 327     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 328     #   supports most of C99)
 329     # - the rest has no compiler compiler restrictions
 330     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 331     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 332
 333     # Enable -Werror=vla if compiler supports it
 334     save_CFLAGS="$CFLAGS"
 335     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 336     CFLAGS="$CFLAGS -Werror=vla"
 337     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 338                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 339                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 340                     AC_MSG_RESULT([yes])],
 341                     AC_MSG_RESULT([no]));
 342     CFLAGS="$save_CFLAGS"
 343 fi
 344 if test "x$GXX" = xyes; then
 345     CXXFLAGS="$CXXFLAGS -Wall"
 346
 347     # Enable -fvisibility=hidden if using a gcc that supports it
 348     save_CXXFLAGS="$CXXFLAGS"
 349     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 350     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 351     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 352     AC_LANG_PUSH([C++])
 353     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 354                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 355     AC_LANG_POP([C++])
 356
 357     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 358     CXXFLAGS=$save_CXXFLAGS
 359
 360     # We don't want floating-point math functions to set errno or trap
 361     CXXFLAGS="$CXXFLAGS -fno-math-errno -fno-trapping-math"
 362 fi
 363
 364 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 365 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 366
 367 dnl even if the compiler appears to support it, using visibility attributes isn't
 368 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 369 case "$host_os" in
 370 cygwin*)
 371     VISIBILITY_CFLAGS=""
 372     VISIBILITY_CXXFLAGS=""
 373     ;;
 374 esac
 375
 376 AC_SUBST([VISIBILITY_CFLAGS])
 377 AC_SUBST([VISIBILITY_CXXFLAGS])
 378
 379 dnl
 380 dnl Optional flags, check for compiler support
 381 dnl
 382 SSE41_CFLAGS="-msse4.1"
 383 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 384 dnl stack, but on x86-32 such alignment is not guaranteed.
 385 case "$target_cpu" in
 386 i?86)
 387     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 388     ;;
 389 esac
 390 save_CFLAGS="$CFLAGS"
 391 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 392 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 393 #include <smmintrin.h>
 394 int param;
 395 int main () {
 396     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 397     c = _mm_max_epu32(a, b);
 398     return _mm_cvtsi128_si32(c);
 399 }]])], SSE41_SUPPORTED=1)
 400 CFLAGS="$save_CFLAGS"
 401 if test "x$SSE41_SUPPORTED" = x1; then
 402     DEFINES="$DEFINES -DUSE_SSE41"
 403 fi
 404 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 405 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 406
 407 dnl Check for new-style atomic builtins
 408 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 409 int main() {
 410     int n;
 411     return __atomic_load_n(&n, __ATOMIC_ACQUIRE);
 412 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=1)
 413 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = x1; then
 414     DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
 415 fi
 416 AM_CONDITIONAL([GCC_ATOMIC_BUILTINS_SUPPORTED], [test x$GCC_ATOMIC_BUILTINS_SUPPORTED = x1])
 417
 418 dnl Check for Endianness
 419 AC_C_BIGENDIAN(
 420    little_endian=no,
 421    little_endian=yes,
 422    little_endian=no,
 423    little_endian=no
 424 )
 425
 426 dnl Check for POWER8 Architecture
 427 PWR8_CFLAGS="-mpower8-vector"
 428 have_pwr8_intrinsics=no
 429 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 430 save_CFLAGS=$CFLAGS
 431 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 432 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 433 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 434 #error "Need GCC >= 4.8 for sane POWER8 support"
 435 #endif
 436 #include <altivec.h>
 437 int main () {
 438     vector unsigned char r;
 439     vector unsigned int v = vec_splat_u32 (1);
 440     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 441     return 0;
 442 }]])], have_pwr8_intrinsics=yes)
 443 CFLAGS=$save_CFLAGS
 444
 445 AC_ARG_ENABLE(pwr8,
 446    [AS_HELP_STRING([--disable-pwr8-inst],
 447                    [disable POWER8-specific instructions])],
 448    [enable_pwr8=$enableval], [enable_pwr8=auto])
 449
 450 if test "x$enable_pwr8" = xno ; then
 451    have_pwr8_intrinsics=disabled
 452 fi
 453
 454 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 455    DEFINES="$DEFINES -D_ARCH_PWR8"
 456    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 457    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 458 else
 459    PWR8_CFLAGS=
 460 fi
 461
 462 AC_MSG_RESULT($have_pwr8_intrinsics)
 463 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 464    AC_MSG_ERROR([POWER8 compiler support not detected])
 465 fi
 466
 467 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 468    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 469 fi
 470
 471 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 472
 473 dnl Can't have static and shared libraries, default to static if user
 474 dnl explicitly requested. If both disabled, set to static since shared
 475 dnl was explicitly requested.
 476 case "x$enable_static$enable_shared" in
 477 xyesyes)
 478     AC_MSG_ERROR([Cannot enable both static and shared. Building using --enable-shared is strongly recommended])
 479     ;;
 480 xnono)
 481     AC_MSG_ERROR([Cannot disable both static and shared. Building using --enable-shared is strongly recommended])
 482     ;;
 483 esac
 484
 485 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 486
 487 dnl
 488 dnl other compiler options
 489 dnl
 490 AC_ARG_ENABLE([debug],
 491     [AS_HELP_STRING([--enable-debug],
 492         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 493     [enable_debug="$enableval"],
 494     [enable_debug=no]
 495 )
 496
 497 AC_ARG_ENABLE([profile],
 498     [AS_HELP_STRING([--enable-profile],
 499         [enable profiling of code @<:@default=disabled@:>@])],
 500     [enable_profile="$enableval"],
 501     [enable_profile=no]
 502 )
 503
 504 if test "x$enable_profile" = xyes; then
 505     DEFINES="$DEFINES -DPROFILE"
 506     if test "x$GCC" = xyes; then
 507         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 508     fi
 509     if test "x$GXX" = xyes; then
 510         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 511     fi
 512 fi
 513
 514 if test "x$enable_debug" = xyes; then
 515     DEFINES="$DEFINES -DDEBUG"
 516     if test "x$enable_profile" = xyes; then
 517         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 518     fi
 519     if test "x$GCC" = xyes; then
 520         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 521             CFLAGS="$CFLAGS -g"
 522         fi
 523         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 524             CFLAGS="$CFLAGS -O0"
 525         fi
 526     fi
 527     if test "x$GXX" = xyes; then
 528         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 529             CXXFLAGS="$CXXFLAGS -g"
 530         fi
 531         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 532             CXXFLAGS="$CXXFLAGS -O0"
 533         fi
 534     fi
 535 else
 536    DEFINES="$DEFINES -DNDEBUG"
 537 fi
 538
 539 dnl
 540 dnl Check if linker supports -Bsymbolic
 541 dnl
 542 save_LDFLAGS=$LDFLAGS
 543 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 544 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 545 AC_LINK_IFELSE(
 546     [AC_LANG_SOURCE([int main() { return 0;}])],
 547     [AC_MSG_RESULT([yes])
 548         BSYMBOLIC="-Wl,-Bsymbolic";],
 549     [AC_MSG_RESULT([no])
 550         BSYMBOLIC="";])
 551 LDFLAGS=$save_LDFLAGS
 552
 553 AC_SUBST([BSYMBOLIC])
 554
 555 dnl
 556 dnl Check if linker supports garbage collection
 557 dnl
 558 save_LDFLAGS=$LDFLAGS
 559 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 560 AC_MSG_CHECKING([whether ld supports --gc-sections])
 561 AC_LINK_IFELSE(
 562     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 563     [AC_MSG_RESULT([yes])
 564         GC_SECTIONS="-Wl,--gc-sections";],
 565     [AC_MSG_RESULT([no])
 566         GC_SECTIONS="";])
 567 LDFLAGS=$save_LDFLAGS
 568
 569 AC_SUBST([GC_SECTIONS])
 570
 571 dnl
 572 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 573 dnl so when these flags are passed to ld via libtool the checks will fail
 574 dnl
 575 case "$host_os" in
 576 openbsd* | darwin* )
 577     LD_NO_UNDEFINED="" ;;
 578 *)
 579     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 580 esac
 581
 582 AC_SUBST([LD_NO_UNDEFINED])
 583
 584 dnl
 585 dnl Check if linker supports version scripts
 586 dnl
 587 AC_MSG_CHECKING([if the linker supports version-scripts])
 588 save_LDFLAGS=$LDFLAGS
 589 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 590 cat > conftest.map <<EOF
 591 VERSION_1 {
 592      global:
 593          main;
 594
 595      local:
 596          *;
 597 };
 598 EOF
 599 AC_LINK_IFELSE(
 600     [AC_LANG_SOURCE([int main() { return 0;}])],
 601     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 602     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 603 LDFLAGS=$save_LDFLAGS
 604 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 605
 606 dnl
 607 dnl Check if linker supports dynamic list files
 608 dnl
 609 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 610 save_LDFLAGS=$LDFLAGS
 611 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 612 cat > conftest.dyn <<EOF
 613 {
 614         radeon_drm_winsys_create;
 615 };
 616 EOF
 617 AC_LINK_IFELSE(
 618     [AC_LANG_SOURCE([int main() { return 0;}])],
 619     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 620     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 621 LDFLAGS=$save_LDFLAGS
 622 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 623
 624 dnl
 625 dnl compatibility symlinks
 626 dnl
 627 case "$host_os" in
 628 linux* )
 629     HAVE_COMPAT_SYMLINKS=yes ;;
 630 * )
 631     HAVE_COMPAT_SYMLINKS=no ;;
 632 esac
 633
 634 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 635
 636 dnl
 637 dnl library names
 638 dnl
 639 dnl Unfortunately we need to do a few things that libtool can't help us with,
 640 dnl so we need some knowledge of shared library filenames:
 641 dnl
 642 dnl LIB_EXT is the extension used when creating symlinks for alternate
 643 dnl filenames for a shared library which will be dynamically loaded
 644 dnl
 645 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 646 dnl the file for a shared library we wish to link with
 647 dnl
 648 case "$host_os" in
 649 darwin* )
 650     LIB_EXT='dylib'
 651     IMP_LIB_EXT=$LIB_EXT
 652     ;;
 653 cygwin* )
 654     LIB_EXT='dll'
 655     IMP_LIB_EXT='dll.a'
 656     ;;
 657 aix* )
 658     LIB_EXT='a'
 659     IMP_LIB_EXT=$LIB_EXT
 660     ;;
 661 * )
 662     LIB_EXT='so'
 663     IMP_LIB_EXT=$LIB_EXT
 664     ;;
 665 esac
 666
 667 AC_SUBST([LIB_EXT])
 668
 669 dnl
 670 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 671 dnl
 672 AC_ARG_ENABLE([texture-float],
 673     [AS_HELP_STRING([--enable-texture-float],
 674         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 675     [enable_texture_float="$enableval"],
 676     [enable_texture_float=no]
 677 )
 678 if test "x$enable_texture_float" = xyes; then
 679     AC_MSG_WARN([Floating-point textures enabled.])
 680     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 681     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 682 fi
 683
 684 dnl
 685 dnl Arch/platform-specific settings
 686 dnl
 687 AC_ARG_ENABLE([asm],
 688     [AS_HELP_STRING([--disable-asm],
 689         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 690     [enable_asm="$enableval"],
 691     [enable_asm=yes]
 692 )
 693 asm_arch=""
 694 AC_MSG_CHECKING([whether to enable assembly])
 695 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 696 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 697 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 698     case "$host_cpu" in
 699     i?86 | x86_64 | amd64)
 700         if test "x$host_cpu" != "x$target_cpu"; then
 701             enable_asm=no
 702             AC_MSG_RESULT([no, cross compiling])
 703         fi
 704         ;;
 705     esac
 706 fi
 707 # check for supported arches
 708 if test "x$enable_asm" = xyes; then
 709     case "$host_cpu" in
 710     i?86)
 711         case "$host_os" in
 712         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 713             asm_arch=x86
 714             ;;
 715         esac
 716         ;;
 717     x86_64|amd64)
 718         case "$host_os" in
 719         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 720             asm_arch=x86_64
 721             ;;
 722         esac
 723         ;;
 724     sparc*)
 725         case "$host_os" in
 726         linux*)
 727             asm_arch=sparc
 728             ;;
 729         esac
 730         ;;
 731     esac
 732
 733     case "$asm_arch" in
 734     x86)
 735         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 736         AC_MSG_RESULT([yes, x86])
 737         ;;
 738     x86_64|amd64)
 739         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 740         AC_MSG_RESULT([yes, x86_64])
 741         ;;
 742     sparc)
 743         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 744         AC_MSG_RESULT([yes, sparc])
 745         ;;
 746     *)
 747         AC_MSG_RESULT([no, platform not supported])
 748         ;;
 749     esac
 750 fi
 751
 752 AC_HEADER_MAJOR
 753 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 754 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 755 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 756 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 757
 758 dnl Check to see if dlopen is in default libraries (like Solaris, which
 759 dnl has it in libc), or if libdl is needed to get it.
 760 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 761     [AC_CHECK_LIB([dl], [dlopen],
 762        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 763 AC_SUBST([DLOPEN_LIBS])
 764
 765 dnl Check if that library also has dladdr
 766 save_LIBS="$LIBS"
 767 LIBS="$LIBS $DLOPEN_LIBS"
 768 AC_CHECK_FUNCS([dladdr])
 769 LIBS="$save_LIBS"
 770
 771 case "$host_os" in
 772 darwin*)
 773     ;;
 774 *)
 775     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 776                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 777                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 778     AC_SUBST([CLOCK_LIB])
 779     ;;
 780 esac
 781
 782 dnl See if posix_memalign is available
 783 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 784
 785 dnl Check for pthreads
 786 AX_PTHREAD
 787 if test "x$ax_pthread_ok" = xno; then
 788     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 789 fi
 790 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 791 dnl to -pthread, which causes problems if we need -lpthread to appear in
 792 dnl pkgconfig files.  Since Android doesn't have a pthread lib, this check
 793 dnl is not valid for that platform.
 794 if test "x$android" = xno; then
 795     test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 796 fi
 797
 798 dnl pthread-stubs is mandatory on targets where it exists
 799 case "$host_os" in
 800 cygwin* )
 801     pthread_stubs_possible="no"
 802     ;;
 803 * )
 804     pthread_stubs_possible="yes"
 805     ;;
 806 esac
 807
 808 if test "x$pthread_stubs_possible" = xyes; then
 809     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
 810     AC_SUBST(PTHREADSTUBS_CFLAGS)
 811     AC_SUBST(PTHREADSTUBS_LIBS)
 812 fi
 813
 814 dnl SELinux awareness.
 815 AC_ARG_ENABLE([selinux],
 816     [AS_HELP_STRING([--enable-selinux],
 817         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 818     [MESA_SELINUX="$enableval"],
 819     [MESA_SELINUX=no])
 820 if test "x$enable_selinux" = "xyes"; then
 821     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 822         [AC_CHECK_HEADER([selinux/selinux.h],[],
 823                          [AC_MSG_ERROR([SELinux headers not found])])
 824          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 825                       [AC_MSG_ERROR([SELinux library not found])])
 826          SELINUX_LIBS="-lselinux"])
 827     DEFINES="$DEFINES -DMESA_SELINUX"
 828 fi
 829 AC_SUBST([SELINUX_CFLAGS])
 830 AC_SUBST([SELINUX_LIBS])
 831
 832 dnl
 833 dnl LLVM
 834 dnl
 835 AC_ARG_ENABLE([llvm-shared-libs],
 836     [AS_HELP_STRING([--enable-llvm-shared-libs],
 837         [link with LLVM shared libraries @<:@default=enabled@:>@])],
 838     [enable_llvm_shared_libs="$enableval"],
 839     [enable_llvm_shared_libs=yes])
 840
 841 AC_ARG_WITH([llvm-prefix],
 842     [AS_HELP_STRING([--with-llvm-prefix],
 843         [Prefix for LLVM installations in non-standard locations])],
 844     [llvm_prefix="$withval"],
 845     [llvm_prefix=''])
 846
 847 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
 848 if test "x$have_libelf" = xno; then
 849    LIBELF_LIBS=''
 850    LIBELF_CFLAGS=''
 851    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
 852    AC_SUBST([LIBELF_LIBS])
 853    AC_SUBST([LIBELF_CFLAGS])
 854 fi
 855
 856 if test -z "$LLVM_CONFIG"; then
 857     if test -n "$llvm_prefix"; then
 858         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
 859     else
 860         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
 861     fi
 862 fi
 863
 864 llvm_add_component() {
 865     new_llvm_component=$1
 866     driver_name=$2
 867
 868     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
 869         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
 870     else
 871         AC_MSG_ERROR([LLVM component '$new_llvm_component' not enabled in your LLVM build. Required by $driver_name.])
 872     fi
 873 }
 874
 875 llvm_add_default_components() {
 876     driver_name=$1
 877
 878     # Required default components
 879     llvm_add_component "bitwriter" $driver_name
 880     llvm_add_component "engine" $driver_name
 881     llvm_add_component "mcdisassembler" $driver_name
 882     llvm_add_component "mcjit" $driver_name
 883
 884     # Optional default components
 885     if $LLVM_CONFIG --components | grep -iqw inteljitevents ; then
 886         LLVM_COMPONENTS="$LLVM_COMPONENTS inteljitevents"
 887     fi
 888 }
 889
 890 llvm_add_target() {
 891     new_llvm_target=$1
 892     driver_name=$2
 893
 894     if $LLVM_CONFIG --targets-built | grep -iqw $new_llvm_target ; then
 895         llvm_add_component $new_llvm_target $driver_name
 896     else
 897         AC_MSG_ERROR([LLVM target '$new_llvm_target' not enabled in your LLVM build. Required by $driver_name.])
 898     fi
 899 }
 900
 901 # Call this inside ` ` to get the return value.
 902 # $1 is the llvm-config command with arguments.
 903 strip_unwanted_llvm_flags() {
 904     # Use \> (marks the end of the word)
 905     echo " `$1`" | sed \
 906         -e 's/\s\+-m\S*//g' \
 907         -e 's/\s\+-DNDEBUG\>//g' \
 908         -e 's/\s\+-D_GNU_SOURCE\>//g' \
 909         -e 's/\s\+-pedantic\>//g' \
 910         -e 's/\s\+-W\S*//g' \
 911         -e 's/\s\+-O\S*//g' \
 912         -e 's/\s\+-g\S*//g' \
 913         -e 's/-fno-rtti\>/-Fno-rtti/g' \
 914         -e 's/\s\+-f\S*//g' \
 915         -e 's/-Fno-rtti\>/-fno-rtti/g' \
 916         -e 's/^ //'
 917 }
 918
 919 llvm_set_environment_variables() {
 920     if test "x$LLVM_CONFIG" != xno; then
 921         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
 922         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
 923         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
 924         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
 925
 926         # We need to respect LLVM_CPPFLAGS when compiling LLVM headers.
 927         save_CFLAGS="$CFLAGS"
 928         CFLAGS="$CFLAGS $LLVM_CPPFLAGS"
 929
 930         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
 931             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 932         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
 933             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 934         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
 935             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 936
 937         CFLAGS="$save_CFLAGS"
 938
 939         # Only needed for LLVM < 3.6.0
 940         if test -z "$LLVM_VERSION_PATCH"; then
 941             LLVM_VERSION_PATCH=0
 942         fi
 943
 944         LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
 945
 946         FOUND_LLVM=yes
 947     else
 948         FOUND_LLVM=no
 949         LLVM_VERSION_INT=0
 950     fi
 951 }
 952
 953 require_llvm() {
 954     if test "x$enable_llvm" != "xyes"; then
 955         AC_MSG_ERROR([--enable-llvm is required when building $1])
 956     fi
 957 }
 958
 959 llvm_require_version() {
 960     require_llvm $2
 961
 962     llvm_target_version_major=`echo $1 | cut -d. -f1 | egrep -o '^[[0-9]]+'`
 963     llvm_target_version_minor=`echo $1 | cut -d. -f2 | egrep -o '^[[0-9]]+'`
 964     llvm_target_version_patch=`echo $1 | cut -d. -f3 | egrep -o '^[[0-9]]+'`
 965
 966     if test "$LLVM_VERSION_MAJOR" -gt "$llvm_target_version_major"; then
 967         # major > required major
 968         #  --> OK
 969         return
 970     fi
 971
 972     if test "$LLVM_VERSION_MAJOR" -eq "$llvm_target_version_major"; then
 973         if test "$LLVM_VERSION_MINOR" -gt "$llvm_target_version_minor"; then
 974             # major = required major and
 975             # minor > required minor
 976             #  --> OK
 977             return
 978         else
 979             if test "$LLVM_VERSION_MINOR" -eq "$llvm_target_version_minor"; then
 980                 if test "$LLVM_VERSION_PATCH" -ge "$llvm_target_version_patch"; then
 981                     # major = required major and
 982                     # minor = required minor and
 983                     # patch >= required patch
 984                     #  --> OK
 985                     return
 986                 fi
 987             fi
 988         fi
 989     fi
 990
 991     AC_MSG_ERROR([LLVM $1 or newer is required for $2])
 992 }
 993
 994 radeon_llvm_check() {
 995     if test ${LLVM_VERSION_INT} -lt 307; then
 996         amdgpu_llvm_target_name='r600'
 997     else
 998         amdgpu_llvm_target_name='amdgpu'
 999     fi
1000
1001     llvm_require_version $*
1002
1003     llvm_add_target $amdgpu_llvm_target_name $2
1004
1005     llvm_add_default_components $2
1006     llvm_add_component "bitreader" $2
1007     llvm_add_component "ipo" $2
1008
1009     NEED_RADEON_LLVM=yes
1010     if test "x$have_libelf" != xyes; then
1011        AC_MSG_ERROR([$1 requires libelf when using llvm])
1012     fi
1013 }
1014
1015 llvm_set_environment_variables
1016
1017 AC_SUBST([LLVM_CFLAGS])
1018 AC_SUBST([LLVM_CXXFLAGS])
1019 AC_SUBST([LLVM_LIBS])
1020 AC_SUBST([LLVM_LDFLAGS])
1021 AC_SUBST([LLVM_INCLUDEDIR])
1022
1023 dnl Options for APIs
1024 AC_ARG_ENABLE([opengl],
1025     [AS_HELP_STRING([--disable-opengl],
1026         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
1027     [enable_opengl="$enableval"],
1028     [enable_opengl=yes])
1029 AC_ARG_ENABLE([gles1],
1030     [AS_HELP_STRING([--disable-gles1],
1031         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
1032     [enable_gles1="$enableval"],
1033     [enable_gles1=yes])
1034 AC_ARG_ENABLE([gles2],
1035     [AS_HELP_STRING([--disable-gles2],
1036         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
1037     [enable_gles2="$enableval"],
1038     [enable_gles2=yes])
1039
1040 AC_ARG_ENABLE([dri],
1041     [AS_HELP_STRING([--enable-dri],
1042         [enable DRI modules @<:@default=enabled@:>@])],
1043     [enable_dri="$enableval"],
1044     [enable_dri=yes])
1045
1046 AC_ARG_ENABLE([gallium-extra-hud],
1047     [AS_HELP_STRING([--enable-gallium-extra-hud],
1048         [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
1049     [enable_gallium_extra_hud="$enableval"],
1050     [enable_gallium_extra_hud=no])
1051 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
1052 if test "x$enable_gallium_extra_hud" = xyes ; then
1053     DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
1054 fi
1055
1056 #TODO: no pkgconfig .pc available for libsensors.
1057 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
1058 AC_ARG_ENABLE([lmsensors],
1059     [AS_HELP_STRING([--enable-lmsensors],
1060         [enable HUD lmsensor support @<:@default=disabled@:>@])],
1061     [enable_lmsensors="$enableval"],
1062     [enable_lmsensors=no])
1063 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
1064 if test "x$enable_lmsensors" = xyes ; then
1065     DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
1066     LIBSENSORS_LIBS="-lsensors"
1067 else
1068     LIBSENSORS_LIBS=""
1069 fi
1070 AC_SUBST(LIBSENSORS_LIBS)
1071
1072 case "$host_os" in
1073 linux*)
1074     dri3_default=yes
1075     ;;
1076 *)
1077     dri3_default=no
1078     ;;
1079 esac
1080
1081 if test "x$enable_dri" = xno; then
1082     dri3_default=no
1083 fi
1084
1085 AC_ARG_ENABLE([dri3],
1086     [AS_HELP_STRING([--enable-dri3],
1087         [enable DRI3 @<:@default=auto@:>@])],
1088     [enable_dri3="$enableval"],
1089     [enable_dri3="$dri3_default"])
1090 AC_ARG_ENABLE([glx],
1091     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
1092         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
1093     [enable_glx="$enableval"],
1094     [enable_glx=yes])
1095 AC_ARG_ENABLE([osmesa],
1096     [AS_HELP_STRING([--enable-osmesa],
1097         [enable OSMesa library @<:@default=disabled@:>@])],
1098     [enable_osmesa="$enableval"],
1099     [enable_osmesa=no])
1100 AC_ARG_ENABLE([gallium-osmesa],
1101     [AS_HELP_STRING([--enable-gallium-osmesa],
1102         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
1103     [enable_gallium_osmesa="$enableval"],
1104     [enable_gallium_osmesa=no])
1105 AC_ARG_ENABLE([egl],
1106     [AS_HELP_STRING([--disable-egl],
1107         [disable EGL library @<:@default=enabled@:>@])],
1108     [enable_egl="$enableval"],
1109     [enable_egl=yes])
1110
1111 AC_ARG_ENABLE([xa],
1112     [AS_HELP_STRING([--enable-xa],
1113         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
1114     [enable_xa="$enableval"],
1115     [enable_xa=no])
1116 AC_ARG_ENABLE([gbm],
1117    [AS_HELP_STRING([--enable-gbm],
1118          [enable gbm library @<:@default=yes except cygwin@:>@])],
1119    [enable_gbm="$enableval"],
1120    [case "$host_os" in
1121        cygwin*)
1122           enable_gbm=no
1123           ;;
1124        *)
1125           enable_gbm=yes
1126           ;;
1127     esac])
1128 AC_ARG_ENABLE([nine],
1129     [AS_HELP_STRING([--enable-nine],
1130         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
1131     [enable_nine="$enableval"],
1132     [enable_nine=no])
1133
1134 AC_ARG_ENABLE([xvmc],
1135    [AS_HELP_STRING([--enable-xvmc],
1136          [enable xvmc library @<:@default=auto@:>@])],
1137    [enable_xvmc="$enableval"],
1138    [enable_xvmc=auto])
1139 AC_ARG_ENABLE([vdpau],
1140    [AS_HELP_STRING([--enable-vdpau],
1141          [enable vdpau library @<:@default=auto@:>@])],
1142    [enable_vdpau="$enableval"],
1143    [enable_vdpau=auto])
1144 AC_ARG_ENABLE([omx],
1145    [AS_HELP_STRING([--enable-omx],
1146          [enable OpenMAX library @<:@default=disabled@:>@])],
1147    [enable_omx="$enableval"],
1148    [enable_omx=no])
1149 AC_ARG_ENABLE([va],
1150    [AS_HELP_STRING([--enable-va],
1151          [enable va library @<:@default=auto@:>@])],
1152    [enable_va="$enableval"],
1153    [enable_va=auto])
1154 AC_ARG_ENABLE([opencl],
1155    [AS_HELP_STRING([--enable-opencl],
1156          [enable OpenCL library @<:@default=disabled@:>@])],
1157    [enable_opencl="$enableval"],
1158    [enable_opencl=no])
1159 AC_ARG_ENABLE([opencl_icd],
1160    [AS_HELP_STRING([--enable-opencl-icd],
1161           [Build an OpenCL ICD library to be loaded by an ICD implementation
1162            @<:@default=disabled@:>@])],
1163     [enable_opencl_icd="$enableval"],
1164     [enable_opencl_icd=no])
1165
1166 AC_ARG_ENABLE([gallium-tests],
1167     [AS_HELP_STRING([--enable-gallium-tests],
1168         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1169     [enable_gallium_tests="$enableval"],
1170     [enable_gallium_tests=no])
1171
1172 # Option for Gallium drivers
1173
1174 # Keep this in sync with the --with-gallium-drivers help string default value
1175 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1176
1177 AC_ARG_WITH([gallium-drivers],
1178     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1179         [comma delimited Gallium drivers list, e.g.
1180         "i915,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,swr,vc4,virgl,etnaviv,imx"
1181         @<:@default=r300,r600,svga,swrast@:>@])],
1182     [with_gallium_drivers="$withval"],
1183     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1184
1185 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
1186 # here so that the script doesn't choke on an unknown driver name later.
1187 case "$with_gallium_drivers" in
1188     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1189     no) with_gallium_drivers='' ;;
1190 esac
1191
1192 if test "x$enable_opengl" = xno -a \
1193         "x$enable_gles1" = xno -a \
1194         "x$enable_gles2" = xno -a \
1195         "x$enable_nine" = xno -a \
1196         "x$enable_xa" = xno -a \
1197         "x$enable_xvmc" = xno -a \
1198         "x$enable_vdpau" = xno -a \
1199         "x$enable_omx" = xno -a \
1200         "x$enable_va" = xno -a \
1201         "x$enable_opencl" = xno; then
1202     AC_MSG_ERROR([at least one API should be enabled])
1203 fi
1204
1205 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1206 if test "x$enable_opengl" = xno -a \
1207         "x$enable_gles1" = xyes; then
1208     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1209 fi
1210
1211 if test "x$enable_opengl" = xno -a \
1212         "x$enable_gles2" = xyes; then
1213     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1214 fi
1215
1216 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1217 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1218 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1219 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1220                                         "x$enable_gles1" = xyes -o \
1221                                         "x$enable_gles2" = xyes)
1222
1223 # Validate GLX options
1224 if test "x$enable_glx" = xyes; then
1225     if test "x$enable_dri" = xyes; then
1226         enable_glx=dri
1227     elif test -n "$with_gallium_drivers"; then
1228         enable_glx=gallium-xlib
1229     else
1230         enable_glx=xlib
1231     fi
1232 fi
1233 case "x$enable_glx" in
1234 xdri | xxlib | xgallium-xlib)
1235     # GLX requires OpenGL
1236     if test "x$enable_opengl" = xno; then
1237         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1238     fi
1239
1240     # Check individual dependencies
1241     case "x$enable_glx" in
1242     xdri)
1243         if test "x$enable_dri" = xno; then
1244             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1245         fi
1246         ;;
1247     xxlib)
1248         if test "x$enable_dri" = xyes; then
1249             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1250         fi
1251         ;;
1252     xgallium-xlib )
1253         if test "x$enable_dri" = xyes; then
1254             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1255         fi
1256         if test -z "$with_gallium_drivers"; then
1257             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1258         fi
1259         ;;
1260     esac
1261     ;;
1262 xno)
1263     ;;
1264 *)
1265     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1266     ;;
1267 esac
1268
1269 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1270 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1271 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1272 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1273
1274 DEFAULT_GL_LIB_NAME=GL
1275
1276 dnl
1277 dnl Libglvnd configuration
1278 dnl
1279 AC_ARG_ENABLE([libglvnd],
1280     [AS_HELP_STRING([--enable-libglvnd],
1281         [Build for libglvnd @<:@default=disabled@:>@])],
1282     [enable_libglvnd="$enableval"],
1283     [enable_libglvnd=no])
1284 AM_CONDITIONAL(USE_LIBGLVND_GLX, test "x$enable_libglvnd" = xyes)
1285 if test "x$enable_libglvnd" = xyes ; then
1286     dnl XXX: update once we can handle more than libGL/glx.
1287     dnl Namely: we should error out if neither of the glvnd enabled libraries
1288     dnl are built
1289     case "x$enable_glx" in
1290     xno)
1291         AC_MSG_ERROR([cannot build libglvnd without GLX])
1292         ;;
1293     xxlib | xgallium-xlib )
1294         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1295         ;;
1296     xdri)
1297         ;;
1298     esac
1299
1300     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.1.0)
1301     DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"
1302     DEFAULT_GL_LIB_NAME=GLX_mesa
1303 fi
1304
1305 AC_ARG_WITH([gl-lib-name],
1306   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
1307     [specify GL library name @<:@default=GL@:>@])],
1308   [GL_LIB=$withval],
1309   [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1310 AC_ARG_WITH([osmesa-lib-name],
1311   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
1312     [specify OSMesa library name @<:@default=OSMesa@:>@])],
1313   [OSMESA_LIB=$withval],
1314   [OSMESA_LIB=OSMesa])
1315 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1316 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
1317
1318 dnl
1319 dnl Mangled Mesa support
1320 dnl
1321 AC_ARG_ENABLE([mangling],
1322   [AS_HELP_STRING([--enable-mangling],
1323     [enable mangled symbols and library name @<:@default=disabled@:>@])],
1324   [enable_mangling="${enableval}"],
1325   [enable_mangling=no]
1326 )
1327 if test "x${enable_mangling}" = "xyes" ; then
1328   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
1329   GL_LIB="Mangled${GL_LIB}"
1330   OSMESA_LIB="Mangled${OSMESA_LIB}"
1331 fi
1332 AC_SUBST([GL_LIB])
1333 AC_SUBST([OSMESA_LIB])
1334
1335 # Check for libdrm
1336 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1337                   [have_libdrm=yes], [have_libdrm=no])
1338 if test "x$have_libdrm" = xyes; then
1339         DEFINES="$DEFINES -DHAVE_LIBDRM"
1340 fi
1341
1342 require_libdrm() {
1343     if test "x$have_libdrm" != xyes; then
1344        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1345     fi
1346 }
1347
1348
1349 # Select which platform-dependent DRI code gets built
1350 case "$host_os" in
1351 darwin*)
1352     dri_platform='apple' ;;
1353 cygwin*)
1354     dri_platform='windows' ;;
1355 gnu*)
1356     dri_platform='none' ;;
1357 *)
1358     dri_platform='drm' ;;
1359 esac
1360
1361 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1362     have_drisw_kms='yes'
1363 fi
1364
1365 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1366 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1367 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1368 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1369 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1370 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1371 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1372 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1373 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1374
1375 AC_ARG_ENABLE([shared-glapi],
1376     [AS_HELP_STRING([--enable-shared-glapi],
1377         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1378     [enable_shared_glapi="$enableval"],
1379     [enable_shared_glapi=yes])
1380
1381 case "x$enable_opengl$enable_gles1$enable_gles2" in
1382 x*yes*yes*)
1383     if test "x$enable_shared_glapi" = xno; then
1384         AC_MSG_ERROR([shared GLAPI required when building two or more of
1385                       the following APIs - opengl, gles1 gles2])
1386     fi
1387     ;;
1388 esac
1389
1390 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1391
1392 # Build the pipe-drivers as separate libraries/modules.
1393 # Do not touch this unless you know what you are doing.
1394 # XXX: Expose via configure option ?
1395 enable_shared_pipe_drivers=no
1396
1397 dnl
1398 dnl Driver specific build directories
1399 dnl
1400
1401 if test "x$enable_gallium_osmesa" = xyes; then
1402     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1403         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1404     fi
1405     if test "x$enable_osmesa" = xyes; then
1406         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1407     fi
1408 fi
1409
1410 require_dri_shared_libs_and_glapi() {
1411     if test "x$enable_static" = xyes; then
1412         AC_MSG_ERROR([$1 cannot be build as static library])
1413     fi
1414
1415     if test "x$enable_dri" != xyes; then
1416         # There is only a single backend which won't be build/used otherwise.
1417         # XXX: Revisit this as the egl/haiku is a thing.
1418         AC_MSG_ERROR([$1 requires --enable-dri])
1419     fi
1420
1421     if test "x$enable_shared_glapi" != xyes; then
1422         AC_MSG_ERROR([$1 requires --enable-shared-glapi])
1423     fi
1424 }
1425
1426 if test "x$enable_dri" = xyes; then
1427     require_dri_shared_libs_and_glapi "DRI"
1428
1429     # not a hard requirement as swrast does not depend on it
1430     if test "x$have_libdrm" = xyes; then
1431         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1432     fi
1433 fi
1434
1435 AC_ARG_ENABLE([driglx-direct],
1436     [AS_HELP_STRING([--disable-driglx-direct],
1437         [disable direct rendering in GLX and EGL for DRI \
1438             @<:@default=auto@:>@])],
1439     [driglx_direct="$enableval"],
1440     [driglx_direct="yes"])
1441
1442 dnl
1443 dnl libGL configuration per driver
1444 dnl
1445 if test "x$enable_glx" != xno; then
1446     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1447 fi
1448 case "x$enable_glx" in
1449 xxlib | xgallium-xlib)
1450     # Xlib-based GLX
1451     dri_modules="x11 xext xcb"
1452     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1453     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1454     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1455     GL_LIB_DEPS="$XLIBGL_LIBS"
1456     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1457     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1458     ;;
1459 xdri)
1460     # DRI-based GLX
1461
1462     # find the DRI deps for libGL
1463     dri_modules="x11 xext xdamage >= $XDAMAGE_REQUIRED xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1464
1465     if test x"$driglx_direct" = xyes; then
1466         if test x"$dri_platform" = xdrm ; then
1467             DEFINES="$DEFINES -DGLX_USE_DRM"
1468             require_libdrm "Direct rendering"
1469
1470             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1471             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1472             if test x"$enable_dri3" = xyes; then
1473                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1474                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1475             fi
1476
1477             if test x"$enable_dri" = xyes; then
1478                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1479             fi
1480
1481             if test x"$enable_dri3" = xyes; then
1482                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1483                dri3_modules="xcb xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1484                PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1485             fi
1486         fi
1487         if test x"$dri_platform" = xapple ; then
1488             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1489         fi
1490         if test x"$dri_platform" = xwindows ; then
1491             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1492         fi
1493     fi
1494
1495     # add xf86vidmode if available
1496     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1497     if test "$HAVE_XF86VIDMODE" = yes ; then
1498         dri_modules="$dri_modules xxf86vm"
1499     fi
1500
1501     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1502     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1503     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1504     GL_LIB_DEPS="$DRIGL_LIBS"
1505
1506     # need DRM libs, $PTHREAD_LIBS, etc.
1507     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1508     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1509     ;;
1510 esac
1511
1512 # This is outside the case (above) so that it is invoked even for non-GLX
1513 # builds.
1514 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1515
1516 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1517 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1518 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1519 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1520
1521 AC_SUBST([X11_INCLUDES])
1522 AC_SUBST([GL_LIB_DEPS])
1523 AC_SUBST([GL_PC_REQ_PRIV])
1524 AC_SUBST([GL_PC_LIB_PRIV])
1525 AC_SUBST([GL_PC_CFLAGS])
1526 AC_SUBST([DRI_PC_REQ_PRIV])
1527 AC_SUBST([GLESv1_CM_LIB_DEPS])
1528 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1529 AC_SUBST([GLESv2_LIB_DEPS])
1530 AC_SUBST([GLESv2_PC_LIB_PRIV])
1531
1532 AC_SUBST([HAVE_XF86VIDMODE])
1533
1534 dnl
1535 dnl More GLX setup
1536 dnl
1537 case "x$enable_glx" in
1538 xxlib | xgallium-xlib)
1539     DEFINES="$DEFINES -DUSE_XSHM"
1540     ;;
1541 xdri)
1542     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1543     if test "x$driglx_direct" = xyes; then
1544         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1545     fi
1546     ;;
1547 esac
1548
1549 dnl
1550 dnl TLS detection
1551 dnl
1552
1553 AC_ARG_ENABLE([glx-tls],
1554     [AS_HELP_STRING([--enable-glx-tls],
1555         [enable TLS support in GLX @<:@default=enabled@:>@])],
1556     [GLX_USE_TLS="$enableval"],
1557     [GLX_USE_TLS=yes])
1558 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1559
1560 if test "x$GLX_USE_TLS" = xyes; then
1561     DEFINES="$DEFINES -DGLX_USE_TLS"
1562 fi
1563
1564 dnl Read-only text section on x86 hardened platforms
1565 AC_ARG_ENABLE([glx-read-only-text],
1566     [AS_HELP_STRING([--enable-glx-read-only-text],
1567         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1568     [enable_glx_read_only_text="$enableval"],
1569     [enable_glx_read_only_text=no])
1570 if test "x$enable_glx_read_only_text" = xyes; then
1571     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1572 fi
1573
1574 dnl
1575 dnl More DRI setup
1576 dnl
1577 dnl Directory for DRI drivers
1578 AC_ARG_WITH([dri-driverdir],
1579     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1580         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1581     [DRI_DRIVER_INSTALL_DIR="$withval"],
1582     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1583 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1584 dnl Extra search path for DRI drivers
1585 AC_ARG_WITH([dri-searchpath],
1586     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1587         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1588     [DRI_DRIVER_SEARCH_DIR="$withval"],
1589     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1590 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1591 dnl Which drivers to build - default is chosen by platform
1592 AC_ARG_WITH([dri-drivers],
1593     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1594         [comma delimited classic DRI drivers list, e.g.
1595         "i915,i965,nouveau,radeon,r200,swrast" @<:@default=auto@:>@])],
1596     [with_dri_drivers="$withval"],
1597     [with_dri_drivers=auto])
1598
1599 if test "x$with_dri_drivers" = xauto; then
1600     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1601         with_dri_drivers="yes"
1602     else
1603         with_dri_drivers="no"
1604     fi
1605 fi
1606 if test "x$with_dri_drivers" = xno; then
1607     with_dri_drivers=''
1608 fi
1609
1610 dnl If $with_dri_drivers is yes, drivers will be added through
1611 dnl platform checks. Set DEFINES and LIB_DEPS
1612 if test "x$enable_dri" = xyes; then
1613     # Platform specific settings and drivers to build
1614     case "$host_os" in
1615     linux*)
1616         if test "x$enable_dri3" = xyes; then
1617             DEFINES="$DEFINES -DHAVE_DRI3"
1618         fi
1619
1620         case "$host_cpu" in
1621         powerpc* | sparc*)
1622             # Build only the drivers for cards that exist on PowerPC/sparc
1623             if test "x$with_dri_drivers" = "xyes"; then
1624                 with_dri_drivers="r200 radeon swrast"
1625             fi
1626             ;;
1627         esac
1628         ;;
1629     cygwin*)
1630         if test "x$with_dri_drivers" = "xyes"; then
1631             with_dri_drivers="swrast"
1632         fi
1633         ;;
1634     darwin*)
1635         DEFINES="$DEFINES -DBUILDING_MESA"
1636         if test "x$with_dri_drivers" = "xyes"; then
1637             with_dri_drivers="swrast"
1638         fi
1639         ;;
1640     esac
1641
1642     # default drivers
1643     if test "x$with_dri_drivers" = "xyes"; then
1644         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1645     fi
1646
1647     # Check for expat
1648     PKG_CHECK_MODULES([EXPAT], [expat], [],
1649         # expat version 2.0 and earlier do not provide expat.pc
1650         [AC_CHECK_HEADER([expat.h],[],
1651                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1652          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1653                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1654          EXPAT_LIBS="-lexpat"])
1655
1656     # put all the necessary libs together
1657     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1658 fi
1659
1660 AC_SUBST([DRI_LIB_DEPS])
1661
1662 DRI_DIRS=''
1663 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1664 if test -n "$with_dri_drivers"; then
1665     if test "x$enable_opengl" != xyes; then
1666         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1667     fi
1668
1669     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1670     for driver in $dri_drivers; do
1671         DRI_DIRS="$DRI_DIRS $driver"
1672         case "x$driver" in
1673         xi915)
1674             require_libdrm "i915"
1675             HAVE_I915_DRI=yes;
1676             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1677             ;;
1678         xi965)
1679             require_libdrm "i965"
1680             HAVE_I965_DRI=yes;
1681             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1682             ;;
1683         xnouveau)
1684             require_libdrm "nouveau"
1685             HAVE_NOUVEAU_DRI=yes;
1686             PKG_CHECK_MODULES([NVVIEUX], [libdrm >= $LIBDRM_NVVIEUX_REQUIRED libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1687             ;;
1688         xradeon)
1689             require_libdrm "radeon"
1690             HAVE_RADEON_DRI=yes;
1691             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1692             ;;
1693         xr200)
1694             require_libdrm "r200"
1695             HAVE_R200_DRI=yes;
1696             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1697             ;;
1698         xswrast)
1699             HAVE_SWRAST_DRI=yes;
1700             ;;
1701         *)
1702             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1703             ;;
1704         esac
1705     done
1706     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1707 fi
1708
1709
1710 dnl
1711 dnl Gallium LLVM
1712 dnl Deprecated: kept for backwards compatibility
1713 dnl
1714 AC_ARG_ENABLE([gallium-llvm],
1715     [AS_HELP_STRING([--enable-gallium-llvm],
1716         [DEPRECATED: use --enable-llvm instead])],
1717     [enable_gallium_llvm="$enableval"],
1718     [enable_gallium_llvm=auto])
1719
1720 if test "x$enable_gallium_llvm" != xauto; then
1721    AC_MSG_WARN([The --enable-gallium-llvm option has been deprecated. Use --enable-llvm instead.])
1722    enable_llvm=$enable_gallium_llvm
1723 fi
1724
1725 dnl
1726 dnl LLVM
1727 dnl
1728 AC_ARG_ENABLE([llvm],
1729     [AS_HELP_STRING([--enable-llvm],
1730         [build with LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1731     [enable_llvm="$enableval"],
1732     [enable_llvm=auto])
1733
1734 if test "x$enable_llvm" = xauto -a "x$FOUND_LLVM" = xyes; then
1735     if test "x$FOUND_LLVM" = xyes; then
1736         case "$host_cpu" in
1737         i*86|x86_64|amd64) enable_llvm=yes;;
1738         *) enable_llvm=no;;
1739         esac
1740     else
1741         enable_llvm=no
1742     fi
1743 fi
1744
1745 if test "x$enable_llvm" = xyes -a "x$FOUND_LLVM" = xno; then
1746     AC_MSG_ERROR([--enable-llvm selected but llvm-config is not found])
1747 fi
1748
1749 #
1750 # Vulkan driver configuration
1751 #
1752
1753 AC_ARG_WITH([vulkan-drivers],
1754     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
1755         [comma delimited Vulkan drivers list, e.g.
1756         "intel,radeon"
1757         @<:@default=no@:>@])],
1758     [with_vulkan_drivers="$withval"],
1759     [with_vulkan_drivers="no"])
1760
1761 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
1762 # here so that the script doesn't choke on an unknown driver name later.
1763 case "x$with_vulkan_drivers" in
1764     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
1765     xno) with_vulkan_drivers='' ;;
1766 esac
1767
1768 AC_ARG_WITH([vulkan-icddir],
1769     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
1770         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
1771     [VULKAN_ICD_INSTALL_DIR="$withval"],
1772     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
1773 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
1774
1775 if test -n "$with_vulkan_drivers"; then
1776     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
1777     for driver in $VULKAN_DRIVERS; do
1778         case "x$driver" in
1779         xintel)
1780             if test "x$HAVE_I965_DRI" != xyes; then
1781                 AC_MSG_ERROR([Intel Vulkan driver requires the i965 dri driver])
1782             fi
1783             HAVE_INTEL_VULKAN=yes;
1784
1785             ;;
1786         xradeon)
1787             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
1788             radeon_llvm_check $LLVM_REQUIRED_RADV "radv"
1789             HAVE_RADEON_VULKAN=yes;
1790             ;;
1791         *)
1792             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
1793             ;;
1794         esac
1795     done
1796     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
1797 fi
1798
1799
1800 DEFINES="$DEFINES -DENABLE_SHADER_CACHE"
1801 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1802 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
1803                                   "x$enable_osmesa" = xyes -o \
1804                                   -n "$DRI_DIRS")
1805
1806 dnl
1807 dnl OSMesa configuration
1808 dnl
1809
1810 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1811 AC_ARG_WITH([osmesa-bits],
1812     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1813         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1814     [osmesa_bits="$withval"],
1815     [osmesa_bits=8])
1816 if test "x$osmesa_bits" != x8; then
1817     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
1818         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1819         osmesa_bits=8
1820     fi
1821 fi
1822 case "x$osmesa_bits" in
1823 x8)
1824     OSMESA_LIB="${OSMESA_LIB}"
1825     ;;
1826 x16|x32)
1827     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1828     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1829     ;;
1830 *)
1831     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1832     ;;
1833 esac
1834
1835 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1836     # only link libraries with osmesa if shared
1837     if test "$enable_static" = no; then
1838         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1839     else
1840         OSMESA_LIB_DEPS=""
1841     fi
1842     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1843 fi
1844
1845 AC_SUBST([OSMESA_LIB_DEPS])
1846 AC_SUBST([OSMESA_PC_REQ])
1847 AC_SUBST([OSMESA_PC_LIB_PRIV])
1848
1849 dnl
1850 dnl gbm configuration
1851 dnl
1852 if test "x$enable_gbm" = xyes; then
1853     require_dri_shared_libs_and_glapi "gbm"
1854 fi
1855 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1856 # FINISHME: GBM has a number of dependencies which we should add below
1857 GBM_PC_REQ_PRIV=""
1858 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1859 AC_SUBST([GBM_PC_REQ_PRIV])
1860 AC_SUBST([GBM_PC_LIB_PRIV])
1861
1862 dnl
1863 dnl EGL configuration
1864 dnl
1865
1866 if test "x$enable_egl" = xyes; then
1867     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1868
1869     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1870
1871     require_dri_shared_libs_and_glapi "egl"
1872 fi
1873 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1874 AC_SUBST([EGL_LIB_DEPS])
1875
1876 gallium_st="mesa"
1877
1878 dnl
1879 dnl XA configuration
1880 dnl
1881 if test "x$enable_xa" = xyes; then
1882     if test "x$with_gallium_drivers" = xswrast; then
1883        AC_MSG_ERROR([
1884           Building xa requires at least one non swrast gallium driver.
1885           If you are looking to use libxatracker.so with the VMware driver,
1886           make sure to include svga in the gallium drivers list, apart from
1887           enabling XA.
1888           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1889     fi
1890     gallium_st="$gallium_st xa"
1891 fi
1892 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1893
1894 dnl
1895 dnl Gallium G3DVL configuration
1896 dnl
1897 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1898     if test "x$enable_xvmc" = xauto; then
1899         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1900     fi
1901
1902     if test "x$enable_vdpau" = xauto; then
1903         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1904     fi
1905
1906     if test "x$enable_omx" = xauto; then
1907         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1908     fi
1909
1910     if test "x$enable_va" = xauto; then
1911         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1912     fi
1913 fi
1914
1915 if test "x$enable_dri" = xyes -o \
1916         "x$enable_xvmc" = xyes -o \
1917         "x$enable_vdpau" = xyes -o \
1918         "x$enable_omx" = xyes -o \
1919         "x$enable_va" = xyes; then
1920     need_gallium_vl=yes
1921 fi
1922 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1923
1924 if test "x$enable_xvmc" = xyes -o \
1925         "x$enable_vdpau" = xyes -o \
1926         "x$enable_omx" = xyes -o \
1927         "x$enable_va" = xyes; then
1928     if test x"$enable_dri3" = xyes; then
1929         PKG_CHECK_MODULES([VL], [xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED
1930                                  xcb-xfixes x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1931     else
1932         PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1933     fi
1934     need_gallium_vl_winsys=yes
1935 fi
1936 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
1937
1938 if test "x$enable_xvmc" = xyes; then
1939     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1940     gallium_st="$gallium_st xvmc"
1941 fi
1942 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1943
1944 if test "x$enable_vdpau" = xyes; then
1945     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1946     gallium_st="$gallium_st vdpau"
1947     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
1948 fi
1949 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1950
1951 if test "x$enable_omx" = xyes; then
1952     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
1953     gallium_st="$gallium_st omx"
1954 fi
1955 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1956
1957 if test "x$enable_va" = xyes; then
1958     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
1959     gallium_st="$gallium_st va"
1960 fi
1961 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1962
1963 dnl
1964 dnl Nine Direct3D9 configuration
1965 dnl
1966 if test "x$enable_nine" = xyes; then
1967     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1968         AC_MSG_ERROR([nine requires the gallium swrast driver])
1969     fi
1970     if test "x$with_gallium_drivers" = xswrast; then
1971         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
1972     fi
1973     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1974         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
1975     fi
1976
1977     if test "x$enable_dri3" = xno; then
1978         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
1979     fi
1980
1981     gallium_st="$gallium_st nine"
1982 fi
1983 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
1984
1985 dnl
1986 dnl OpenCL configuration
1987 dnl
1988
1989 AC_ARG_WITH([clang-libdir],
1990    [AS_HELP_STRING([--with-clang-libdir],
1991          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1992    [CLANG_LIBDIR="$withval"],
1993    [CLANG_LIBDIR=''])
1994
1995 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1996
1997 if test "x$enable_opencl" = xyes; then
1998     if test -z "$with_gallium_drivers"; then
1999         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
2000     fi
2001
2002     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
2003         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
2004     fi
2005
2006     if test "x$have_libclc" = xno; then
2007         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
2008                     Make sure the directory containing libclc.pc is specified in your
2009                     PKG_CONFIG_PATH environment variable.
2010                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
2011     else
2012         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
2013         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
2014         AC_SUBST([LIBCLC_INCLUDEDIR])
2015         AC_SUBST([LIBCLC_LIBEXECDIR])
2016     fi
2017
2018     gallium_st="$gallium_st clover"
2019
2020     if test "x$enable_opencl_icd" = xyes; then
2021         OPENCL_LIBNAME="MesaOpenCL"
2022     else
2023         OPENCL_LIBNAME="OpenCL"
2024     fi
2025
2026     if test "x$have_libelf" != xyes; then
2027        AC_MSG_ERROR([Clover requires libelf])
2028     fi
2029
2030     llvm_require_version $LLVM_REQUIRED_OPENCL "opencl"
2031
2032     llvm_add_default_components "opencl"
2033     llvm_add_component "all-targets" "opencl"
2034     llvm_add_component "linker" "opencl"
2035     llvm_add_component "instrumentation" "opencl"
2036     llvm_add_component "ipo" "opencl"
2037     llvm_add_component "irreader" "opencl"
2038     llvm_add_component "option" "opencl"
2039     llvm_add_component "objcarcopts" "opencl"
2040     llvm_add_component "profiledata" "opencl"
2041
2042     dnl Check for Clang internal headers
2043     if test -z "$CLANG_LIBDIR"; then
2044         CLANG_LIBDIR=${LLVM_LIBDIR}
2045     fi
2046     CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2047     AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2048         [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2049 fi
2050 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2051 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2052 AC_SUBST([OPENCL_LIBNAME])
2053 AC_SUBST([CLANG_RESOURCE_DIR])
2054
2055 dnl
2056 dnl Gallium configuration
2057 dnl
2058 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2059
2060 dnl
2061 dnl EGL Platforms configuration
2062 dnl
2063 AC_ARG_WITH([egl-platforms],
2064     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
2065         [comma delimited native platforms libEGL supports, e.g.
2066         "x11,drm" @<:@default=auto@:>@])],
2067     [with_egl_platforms="$withval"],
2068     [if test "x$enable_egl" = xyes; then
2069         if test "x$enable_gbm" = xyes; then
2070            with_egl_platforms="x11,drm"
2071         else
2072            with_egl_platforms="x11"
2073         fi
2074     else
2075         with_egl_platforms=""
2076     fi])
2077
2078 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
2079     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
2080 fi
2081
2082 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
2083         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
2084         WAYLAND_SCANNER='')
2085 if test "x$WAYLAND_SCANNER" = x; then
2086     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
2087 fi
2088
2089 # Do per-EGL platform setups and checks
2090 egl_platforms=`IFS=', '; echo $with_egl_platforms`
2091 for plat in $egl_platforms; do
2092         case "$plat" in
2093         wayland)
2094
2095                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
2096
2097                 if test "x$WAYLAND_SCANNER" = x; then
2098                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
2099                 fi
2100                 ;;
2101
2102         x11)
2103                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
2104                 ;;
2105
2106         drm)
2107                 test "x$enable_gbm" = "xno" &&
2108                         AC_MSG_ERROR([EGL platform drm needs gbm])
2109                 ;;
2110
2111         surfaceless)
2112                 ;;
2113
2114         android)
2115                 PKG_CHECK_MODULES([ANDROID], [cutils hardware sync])
2116                 ;;
2117
2118         *)
2119                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
2120                 ;;
2121         esac
2122
2123         case "$plat" in
2124         wayland|drm|surfaceless)
2125                 require_libdrm "Platform $plat"
2126                 ;;
2127         esac
2128 done
2129
2130 # libEGL wants to default to the first platform specified in
2131 # ./configure.  parse that here.
2132 if test "x$egl_platforms" != "x"; then
2133     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2134     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2135 else
2136     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2137 fi
2138
2139 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
2140 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
2141 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
2142 AM_CONDITIONAL(HAVE_EGL_PLATFORM_SURFACELESS, echo "$egl_platforms" | grep -q 'surfaceless')
2143 AM_CONDITIONAL(HAVE_EGL_PLATFORM_ANDROID, echo "$egl_platforms" | grep -q 'android')
2144
2145 AC_SUBST([EGL_NATIVE_PLATFORM])
2146 AC_SUBST([EGL_CFLAGS])
2147
2148 # If we don't have the X11 platform, set this define so we don't try to include
2149 # the X11 headers.
2150 if ! echo "$egl_platforms" | grep -q 'x11'; then
2151     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2152     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2153 fi
2154
2155 dnl Directory for XVMC libs
2156 AC_ARG_WITH([xvmc-libdir],
2157     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2158         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2159     [XVMC_LIB_INSTALL_DIR="$withval"],
2160     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2161 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2162
2163 dnl
2164 dnl Gallium Tests
2165 dnl
2166 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2167
2168 dnl Directory for VDPAU libs
2169 AC_ARG_WITH([vdpau-libdir],
2170     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2171         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2172     [VDPAU_LIB_INSTALL_DIR="$withval"],
2173     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2174 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2175
2176 dnl Directory for OMX libs
2177
2178 AC_ARG_WITH([omx-libdir],
2179     [AS_HELP_STRING([--with-omx-libdir=DIR],
2180         [directory for the OMX libraries])],
2181     [OMX_LIB_INSTALL_DIR="$withval"],
2182     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2183 AC_SUBST([OMX_LIB_INSTALL_DIR])
2184
2185 dnl Directory for VA libs
2186
2187 AC_ARG_WITH([va-libdir],
2188     [AS_HELP_STRING([--with-va-libdir=DIR],
2189         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2190     [VA_LIB_INSTALL_DIR="$withval"],
2191     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2192 AC_SUBST([VA_LIB_INSTALL_DIR])
2193
2194 AC_ARG_WITH([d3d-libdir],
2195     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2196         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2197     [D3D_DRIVER_INSTALL_DIR="$withval"],
2198     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2199 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2200
2201 dnl
2202 dnl r300 doesn't strictly require LLVM, but for performance reasons we
2203 dnl highly recommend LLVM usage. So require it at least on x86 and x86_64
2204 dnl architectures.
2205 dnl
2206 r300_require_llvm() {
2207     case "$host" in *gnux32) return;; esac
2208     case "$host_cpu" in
2209     i*86|x86_64|amd64) require_llvm $1
2210         ;;
2211     esac
2212 }
2213
2214 dnl
2215 dnl DRM is needed by X, Wayland, and offscreen rendering.
2216 dnl Surfaceless is an alternative for the last one.
2217 dnl
2218 require_basic_egl() {
2219     case "$with_egl_platforms" in
2220         *drm*|*surfaceless*)
2221             ;;
2222         *)
2223             AC_MSG_ERROR([$1 requires one of these:
2224                   1) --with-egl-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2225                   2) --with-egl-platforms=surfaceless (offscreen only)
2226                   Recommended options: drm,x11])
2227             ;;
2228     esac
2229 }
2230
2231 swr_require_cxx_feature_flags() {
2232     feature_name="$1"
2233     preprocessor_test="$2"
2234     option_list="$3"
2235     output_var="$4"
2236
2237     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2238     AC_LANG_PUSH([C++])
2239     save_CXXFLAGS="$CXXFLAGS"
2240     save_IFS="$IFS"
2241     IFS=","
2242     found=0
2243     for opts in $option_list
2244     do
2245         unset IFS
2246         CXXFLAGS="$opts $save_CXXFLAGS"
2247         AC_COMPILE_IFELSE(
2248             [AC_LANG_PROGRAM(
2249                 [   #if !($preprocessor_test)
2250                     #error
2251                     #endif
2252                 ])],
2253             [found=1; break],
2254             [])
2255         IFS=","
2256     done
2257     IFS="$save_IFS"
2258     CXXFLAGS="$save_CXXFLAGS"
2259     AC_LANG_POP([C++])
2260     if test $found -eq 1; then
2261         AC_MSG_RESULT([$opts])
2262         eval "$output_var=\$opts"
2263         return 0
2264     fi
2265     AC_MSG_RESULT([no])
2266     AC_MSG_ERROR([swr requires $feature_name support])
2267     return 1
2268 }
2269
2270 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2271 if test -n "$with_gallium_drivers"; then
2272     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2273     for driver in $gallium_drivers; do
2274         case "x$driver" in
2275         xsvga)
2276             HAVE_GALLIUM_SVGA=yes
2277             require_libdrm "svga"
2278             ;;
2279         xi915)
2280             HAVE_GALLIUM_I915=yes
2281             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2282             require_libdrm "Gallium i915"
2283             ;;
2284         xr300)
2285             HAVE_GALLIUM_R300=yes
2286             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2287             require_libdrm "r300"
2288             r300_require_llvm "r300"
2289             ;;
2290         xr600)
2291             HAVE_GALLIUM_R600=yes
2292             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2293             require_libdrm "r600"
2294             if test "x$enable_opencl" = xyes; then
2295                 radeon_llvm_check $LLVM_REQUIRED_R600 "r600"
2296
2297                 llvm_add_component "asmparser" "r600"
2298                 llvm_add_component "bitreader" "r600"
2299             fi
2300             ;;
2301         xradeonsi)
2302             HAVE_GALLIUM_RADEONSI=yes
2303             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2304             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2305             require_libdrm "radeonsi"
2306             radeon_llvm_check $LLVM_REQUIRED_RADEONSI "radeonsi"
2307             require_basic_egl "radeonsi"
2308             ;;
2309         xnouveau)
2310             HAVE_GALLIUM_NOUVEAU=yes
2311             PKG_CHECK_MODULES([NOUVEAU], [libdrm >= $LIBDRM_NOUVEAU_REQUIRED libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2312             require_libdrm "nouveau"
2313             ;;
2314         xfreedreno)
2315             HAVE_GALLIUM_FREEDRENO=yes
2316             PKG_CHECK_MODULES([FREEDRENO], [libdrm >= $LIBDRM_FREEDRENO_REQUIRED libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2317             require_libdrm "freedreno"
2318             ;;
2319         xetnaviv)
2320             HAVE_GALLIUM_ETNAVIV=yes
2321             PKG_CHECK_MODULES([ETNAVIV], [libdrm >= $LIBDRM_ETNAVIV_REQUIRED libdrm_etnaviv >= $LIBDRM_ETNAVIV_REQUIRED])
2322             require_libdrm "etnaviv"
2323             ;;
2324        ximx)
2325             HAVE_GALLIUM_IMX=yes
2326             ;;
2327         xswrast)
2328             HAVE_GALLIUM_SOFTPIPE=yes
2329             if test "x$enable_llvm" = xyes; then
2330                 HAVE_GALLIUM_LLVMPIPE=yes
2331             fi
2332             ;;
2333         xswr)
2334             llvm_require_version $LLVM_REQUIRED_SWR "swr"
2335
2336             swr_require_cxx_feature_flags "C++11" "__cplusplus >= 201103L" \
2337                 ",-std=c++11" \
2338                 SWR_CXX11_CXXFLAGS
2339             AC_SUBST([SWR_CXX11_CXXFLAGS])
2340
2341             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2342                 ",-mavx,-march=core-avx" \
2343                 SWR_AVX_CXXFLAGS
2344             AC_SUBST([SWR_AVX_CXXFLAGS])
2345
2346             swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2347                 ",-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2" \
2348                 SWR_AVX2_CXXFLAGS
2349             AC_SUBST([SWR_AVX2_CXXFLAGS])
2350
2351             HAVE_GALLIUM_SWR=yes
2352             ;;
2353         xvc4)
2354             HAVE_GALLIUM_VC4=yes
2355             PKG_CHECK_MODULES([VC4], [libdrm >= $LIBDRM_VC4_REQUIRED libdrm_vc4 >= $LIBDRM_VC4_REQUIRED])
2356             require_libdrm "vc4"
2357
2358             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2359                               [USE_VC4_SIMULATOR=yes;
2360                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2361                               [USE_VC4_SIMULATOR=no])
2362             ;;
2363         xvirgl)
2364             HAVE_GALLIUM_VIRGL=yes
2365             require_libdrm "virgl"
2366             require_basic_egl "virgl"
2367             ;;
2368         *)
2369             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2370             ;;
2371         esac
2372     done
2373 fi
2374
2375 if test "x$enable_llvm" = "xyes" -a "$with_gallium_drivers"; then
2376     llvm_require_version $LLVM_REQUIRED_GALLIUM "gallium"
2377     llvm_add_default_components "gallium"
2378 fi
2379
2380 dnl We need to validate some needed dependencies for renderonly drivers.
2381
2382 if test "x$HAVE_GALLIUM_ETNAVIV" != xyes -a "x$HAVE_GALLIUM_IMX" = xyes  ; then
2383     AC_MSG_ERROR([Building with imx requires etnaviv])
2384 fi
2385
2386 dnl
2387 dnl Set defines and buildtime variables only when using LLVM.
2388 dnl
2389 if test "x$enable_llvm" = xyes; then
2390     DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2391
2392     LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2393     LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
2394     LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2395
2396     dnl Set LLVM_LIBS - This is done after the driver configuration so
2397     dnl that drivers can add additional components to LLVM_COMPONENTS.
2398     dnl Previously, gallium drivers were updating LLVM_LIBS directly
2399     dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2400     dnl this was causing the same libraries to be appear multiple times
2401     dnl in LLVM_LIBS.
2402
2403     if ! $LLVM_CONFIG --libs ${LLVM_COMPONENTS} >/dev/null; then
2404        AC_MSG_ERROR([Calling ${LLVM_CONFIG} failed])
2405     fi
2406     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2407
2408     dnl llvm-config may not give the right answer when llvm is a built as a
2409     dnl single shared library, so we must work the library name out for
2410     dnl ourselves.
2411     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2412     if test "x$enable_llvm_shared_libs" = xyes; then
2413         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2414         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2415         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2416
2417         if test "x$llvm_have_one_so" = xyes; then
2418             dnl LLVM was built using auto*, so there is only one shared object.
2419             LLVM_LIBS="-l$LLVM_SO_NAME"
2420         else
2421             dnl If LLVM was built with CMake, there will be one shared object per
2422             dnl component.
2423             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2424                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2425         Please make sure you have built llvm with the --enable-shared option
2426         and that your llvm libraries are installed in $LLVM_LIBDIR
2427         If you have installed your llvm libraries to a different directory you
2428         can use the --with-llvm-prefix= configure flag to specify this directory.
2429         NOTE: Mesa is attempting to use llvm shared libraries by default.
2430         If you do not want to build with llvm shared libraries and instead want to
2431         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2432         invocation and rebuild.])])
2433
2434            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2435            dnl install uses a shared object for each component and we have
2436            dnl already added all of these objects to LLVM_LIBS.
2437         fi
2438     else
2439         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2440         dnl We need to link to llvm system libs when using static libs
2441         dnl However, only llvm 3.5+ provides --system-libs
2442         if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2443             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2444         fi
2445     fi
2446 fi
2447
2448 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2449 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2450 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2451 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2452 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2453 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2454                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2455 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2456 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2457 AM_CONDITIONAL(HAVE_GALLIUM_ETNAVIV, test "x$HAVE_GALLIUM_ETNAVIV" = xyes)
2458 AM_CONDITIONAL(HAVE_GALLIUM_IMX, test "x$HAVE_GALLIUM_IMX" = xyes)
2459 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2460 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2461 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2462 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2463                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2464                                          "x$HAVE_GALLIUM_SWR" = xyes)
2465 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2466 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2467
2468 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2469
2470 if test "x$enable_dri" = xyes; then
2471     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2472 fi
2473
2474 if test "x$have_drisw_kms" = xyes; then
2475     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2476 fi
2477 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2478
2479 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2480 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2481 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2482 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2483 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2484 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2485
2486 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2487 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2488
2489 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_R600" = xyes -o \
2490                                       "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2491                                       "x$HAVE_RADEON_VULKAN" = xyes)
2492
2493 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2494                                         "x$HAVE_I965_DRI" = xyes)
2495
2496 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2497                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2498                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2499 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2500 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2501 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2502 AM_CONDITIONAL(HAVE_GALLIUM_LLVM, test "x$enable_llvm" = xyes)
2503 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2504
2505 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2506 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2507 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2508 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
2509                                         "x$enable_gallium_osmesa" = xyes)
2510
2511 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2512 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2513 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2514
2515 AC_SUBST([NINE_MAJOR], 1)
2516 AC_SUBST([NINE_MINOR], 0)
2517 AC_SUBST([NINE_TINY], 0)
2518 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2519
2520 AC_SUBST([VDPAU_MAJOR], 1)
2521 AC_SUBST([VDPAU_MINOR], 0)
2522
2523 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2524 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2525 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2526 AC_SUBST([VA_MINOR], $VA_MINOR)
2527
2528 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
2529
2530 AC_SUBST([XVMC_MAJOR], 1)
2531 AC_SUBST([XVMC_MINOR], 0)
2532
2533 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2534 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2535 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2536 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2537
2538 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2539 AC_SUBST([XA_MINOR], $XA_MINOR)
2540 AC_SUBST([XA_TINY], $XA_TINY)
2541 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2542
2543 AC_ARG_ENABLE(valgrind,
2544               [AS_HELP_STRING([--enable-valgrind],
2545                              [Build mesa with valgrind support (default: auto)])],
2546                              [VALGRIND=$enableval], [VALGRIND=auto])
2547 if test "x$VALGRIND" != xno; then
2548         PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2549 fi
2550 AC_MSG_CHECKING([whether to enable Valgrind support])
2551 if test "x$VALGRIND" = xauto; then
2552         VALGRIND="$have_valgrind"
2553 fi
2554
2555 if test "x$VALGRIND" = "xyes"; then
2556         if ! test "x$have_valgrind" = xyes; then
2557                 AC_MSG_ERROR([Valgrind support required but not present])
2558         fi
2559         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2560 fi
2561
2562 AC_MSG_RESULT([$VALGRIND])
2563
2564 dnl Restore LDFLAGS and CPPFLAGS
2565 LDFLAGS="$_SAVE_LDFLAGS"
2566 CPPFLAGS="$_SAVE_CPPFLAGS"
2567
2568 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2569 if test "x$acv_mesa_CLANG" = xyes; then
2570     CFLAGS="$CFLAGS -Qunused-arguments"
2571     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2572 fi
2573
2574 dnl Add user CFLAGS and CXXFLAGS
2575 CFLAGS="$CFLAGS $USER_CFLAGS"
2576 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2577
2578 dnl Substitute the config
2579 AC_CONFIG_FILES([Makefile
2580                 src/Makefile
2581                 src/amd/Makefile
2582                 src/amd/vulkan/Makefile
2583                 src/compiler/Makefile
2584                 src/egl/Makefile
2585                 src/egl/main/egl.pc
2586                 src/egl/wayland/wayland-drm/Makefile
2587                 src/egl/wayland/wayland-egl/Makefile
2588                 src/egl/wayland/wayland-egl/wayland-egl.pc
2589                 src/gallium/Makefile
2590                 src/gallium/auxiliary/Makefile
2591                 src/gallium/auxiliary/pipe-loader/Makefile
2592                 src/gallium/drivers/freedreno/Makefile
2593                 src/gallium/drivers/ddebug/Makefile
2594                 src/gallium/drivers/i915/Makefile
2595                 src/gallium/drivers/llvmpipe/Makefile
2596                 src/gallium/drivers/noop/Makefile
2597                 src/gallium/drivers/nouveau/Makefile
2598                 src/gallium/drivers/r300/Makefile
2599                 src/gallium/drivers/r600/Makefile
2600                 src/gallium/drivers/radeon/Makefile
2601                 src/gallium/drivers/radeonsi/Makefile
2602                 src/gallium/drivers/rbug/Makefile
2603                 src/gallium/drivers/softpipe/Makefile
2604                 src/gallium/drivers/svga/Makefile
2605                 src/gallium/drivers/swr/Makefile
2606                 src/gallium/drivers/trace/Makefile
2607                 src/gallium/drivers/etnaviv/Makefile
2608                 src/gallium/drivers/imx/Makefile
2609                 src/gallium/drivers/vc4/Makefile
2610                 src/gallium/drivers/virgl/Makefile
2611                 src/gallium/state_trackers/clover/Makefile
2612                 src/gallium/state_trackers/dri/Makefile
2613                 src/gallium/state_trackers/glx/xlib/Makefile
2614                 src/gallium/state_trackers/nine/Makefile
2615                 src/gallium/state_trackers/omx/Makefile
2616                 src/gallium/state_trackers/osmesa/Makefile
2617                 src/gallium/state_trackers/va/Makefile
2618                 src/gallium/state_trackers/vdpau/Makefile
2619                 src/gallium/state_trackers/xa/Makefile
2620                 src/gallium/state_trackers/xvmc/Makefile
2621                 src/gallium/targets/d3dadapter9/Makefile
2622                 src/gallium/targets/d3dadapter9/d3d.pc
2623                 src/gallium/targets/dri/Makefile
2624                 src/gallium/targets/libgl-xlib/Makefile
2625                 src/gallium/targets/omx/Makefile
2626                 src/gallium/targets/opencl/Makefile
2627                 src/gallium/targets/opencl/mesa.icd
2628                 src/gallium/targets/osmesa/Makefile
2629                 src/gallium/targets/osmesa/osmesa.pc
2630                 src/gallium/targets/pipe-loader/Makefile
2631                 src/gallium/targets/va/Makefile
2632                 src/gallium/targets/vdpau/Makefile
2633                 src/gallium/targets/xa/Makefile
2634                 src/gallium/targets/xa/xatracker.pc
2635                 src/gallium/targets/xvmc/Makefile
2636                 src/gallium/tests/trivial/Makefile
2637                 src/gallium/tests/unit/Makefile
2638                 src/gallium/winsys/etnaviv/drm/Makefile
2639                 src/gallium/winsys/imx/drm/Makefile
2640                 src/gallium/winsys/freedreno/drm/Makefile
2641                 src/gallium/winsys/i915/drm/Makefile
2642                 src/gallium/winsys/nouveau/drm/Makefile
2643                 src/gallium/winsys/radeon/drm/Makefile
2644                 src/gallium/winsys/amdgpu/drm/Makefile
2645                 src/gallium/winsys/svga/drm/Makefile
2646                 src/gallium/winsys/sw/dri/Makefile
2647                 src/gallium/winsys/sw/kms-dri/Makefile
2648                 src/gallium/winsys/sw/null/Makefile
2649                 src/gallium/winsys/sw/wrapper/Makefile
2650                 src/gallium/winsys/sw/xlib/Makefile
2651                 src/gallium/winsys/vc4/drm/Makefile
2652                 src/gallium/winsys/virgl/drm/Makefile
2653                 src/gallium/winsys/virgl/vtest/Makefile
2654                 src/gbm/Makefile
2655                 src/gbm/main/gbm.pc
2656                 src/glx/Makefile
2657                 src/glx/apple/Makefile
2658                 src/glx/tests/Makefile
2659                 src/glx/windows/Makefile
2660                 src/glx/windows/windowsdriproto.pc
2661                 src/gtest/Makefile
2662                 src/intel/Makefile
2663                 src/intel/tools/Makefile
2664                 src/intel/vulkan/Makefile
2665                 src/loader/Makefile
2666                 src/mapi/Makefile
2667                 src/mapi/es1api/glesv1_cm.pc
2668                 src/mapi/es2api/glesv2.pc
2669                 src/mapi/glapi/gen/Makefile
2670                 src/mesa/Makefile
2671                 src/mesa/gl.pc
2672                 src/mesa/drivers/dri/dri.pc
2673                 src/mesa/drivers/dri/common/Makefile
2674                 src/mesa/drivers/dri/common/xmlpool/Makefile
2675                 src/mesa/drivers/dri/i915/Makefile
2676                 src/mesa/drivers/dri/i965/Makefile
2677                 src/mesa/drivers/dri/Makefile
2678                 src/mesa/drivers/dri/nouveau/Makefile
2679                 src/mesa/drivers/dri/r200/Makefile
2680                 src/mesa/drivers/dri/radeon/Makefile
2681                 src/mesa/drivers/dri/swrast/Makefile
2682                 src/mesa/drivers/osmesa/Makefile
2683                 src/mesa/drivers/osmesa/osmesa.pc
2684                 src/mesa/drivers/x11/Makefile
2685                 src/mesa/main/tests/Makefile
2686                 src/util/Makefile
2687                 src/util/tests/hash_table/Makefile
2688                 src/vulkan/wsi/Makefile])
2689
2690 AC_OUTPUT
2691
2692 # Fix up dependencies in *.Plo files, where we changed the extension of a
2693 # source file
2694 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
2695
2696
2697 dnl
2698 dnl Output some configuration info for the user
2699 dnl
2700 echo ""
2701 echo "        prefix:          $prefix"
2702 echo "        exec_prefix:     $exec_prefix"
2703 echo "        libdir:          $libdir"
2704 echo "        includedir:      $includedir"
2705
2706 dnl API info
2707 echo ""
2708 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2709
2710 dnl Driver info
2711 echo ""
2712 case "x$enable_osmesa$enable_gallium_osmesa" in
2713 xnoyes)
2714         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2715         ;;
2716 xyesno)
2717         echo "        OSMesa:          lib$OSMESA_LIB"
2718         ;;
2719 xnono)
2720         echo "        OSMesa:          no"
2721         ;;
2722 esac
2723
2724 echo ""
2725 if test "x$enable_dri" != xno; then
2726         echo "        DRI platform:    $dri_platform"
2727         if test -z "$DRI_DIRS"; then
2728             echo "        DRI drivers:     no"
2729         else
2730             echo "        DRI drivers:     $DRI_DIRS"
2731         fi
2732         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2733 fi
2734
2735 case "x$enable_glx" in
2736 xdri)
2737     echo "        GLX:             DRI-based"
2738     ;;
2739 xxlib)
2740     echo "        GLX:             Xlib-based"
2741     ;;
2742 xgallium-xlib)
2743     echo "        GLX:             Xlib-based (Gallium)"
2744     ;;
2745 *)
2746     echo "        GLX:             $enable_glx"
2747     ;;
2748 esac
2749
2750 dnl EGL
2751 echo ""
2752 echo "        EGL:             $enable_egl"
2753 if test "$enable_egl" = yes; then
2754     echo "        EGL platforms:   $egl_platforms"
2755
2756     egl_drivers=""
2757     if test "x$enable_dri" != "xno"; then
2758         egl_drivers="$egl_drivers builtin:egl_dri2"
2759     fi
2760     if test "x$enable_dri3" != "xno"; then
2761         egl_drivers="$egl_drivers builtin:egl_dri3"
2762     fi
2763
2764     echo "        EGL drivers:    $egl_drivers"
2765 fi
2766 if test "x$enable_gbm" = xyes; then
2767     echo "        GBM:             yes"
2768 else
2769     echo "        GBM:             no"
2770 fi
2771
2772 # Vulkan
2773 echo ""
2774 if test "x$VULKAN_DRIVERS" != x; then
2775     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
2776     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
2777 else
2778     echo "        Vulkan drivers:  no"
2779 fi
2780
2781 echo ""
2782 if test "x$enable_llvm" = xyes; then
2783     echo "        llvm:            yes"
2784     echo "        llvm-config:     $LLVM_CONFIG"
2785     echo "        llvm-version:    $LLVM_VERSION"
2786 else
2787     echo "        llvm:            no"
2788 fi
2789
2790 echo ""
2791 if test -n "$with_gallium_drivers"; then
2792     echo "        Gallium drivers: $gallium_drivers"
2793     echo "        Gallium st:      $gallium_st"
2794 else
2795     echo "        Gallium:         no"
2796 fi
2797
2798 echo ""
2799 if test "x$enable_gallium_extra_hud" != xyes; then
2800     echo "        HUD extra stats: no"
2801 else
2802     echo "        HUD extra stats: yes"
2803 fi
2804
2805 if test "x$enable_lmsensors" != xyes; then
2806     echo "        HUD lmsensors:   no"
2807 else
2808     echo "        HUD lmsensors:   yes"
2809 fi
2810
2811 dnl Libraries
2812 echo ""
2813 echo "        Shared libs:     $enable_shared"
2814 echo "        Static libs:     $enable_static"
2815 echo "        Shared-glapi:    $enable_shared_glapi"
2816
2817 dnl Compiler options
2818 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2819 cflags=`echo $CFLAGS | \
2820     $SED 's/^ *//;s/  */ /;s/ *$//'`
2821 cxxflags=`echo $CXXFLAGS | \
2822     $SED 's/^ *//;s/  */ /;s/ *$//'`
2823 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2824 echo ""
2825 echo "        CFLAGS:          $cflags"
2826 echo "        CXXFLAGS:        $cxxflags"
2827 echo "        Macros:          $defines"
2828 echo ""
2829 if test "x$enable_llvm" = xyes; then
2830     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2831     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2832     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2833     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
2834     echo ""
2835 fi
2836 echo "        PYTHON2:         $PYTHON2"
2837
2838 echo ""
2839 echo "        Run '${MAKE-make}' to build Mesa"
2840 echo ""