configure.ac

   1 AC_PREREQ(2.60)
   2 AC_INIT(bluez, 5.29)
   3
   4 AM_INIT_AUTOMAKE([foreign subdir-objects color-tests silent-rules
   5                                         tar-pax no-dist-gzip dist-xz])
   6 AC_CONFIG_HEADERS(config.h)
   7 AC_USE_SYSTEM_EXTENSIONS
   8
   9 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  10
  11 AM_MAINTAINER_MODE
  12
  13 AC_PREFIX_DEFAULT(/usr/local)
  14
  15 PKG_PROG_PKG_CONFIG
  16
  17 COMPILER_FLAGS
  18
  19 AC_LANG_C
  20
  21 AC_C_RESTRICT
  22
  23 AC_PROG_CC
  24 AM_PROG_CC_C_O
  25 AC_PROG_CC_PIE
  26 AC_PROG_INSTALL
  27 AC_PROG_MKDIR_P
  28
  29 m4_define([_LT_AC_TAGCONFIG], [])
  30 m4_ifdef([AC_LIBTOOL_TAGS], [AC_LIBTOOL_TAGS([])])
  31
  32 AC_DISABLE_STATIC
  33 AC_PROG_LIBTOOL
  34
  35 if (test "$USE_MAINTAINER_MODE" = "yes"); then
  36         AC_CHECK_PROG(enable_coverage, [lcov], [yes], [no])
  37 fi
  38 AM_CONDITIONAL(COVERAGE, test "${enable_coverage}" = "yes")
  39
  40 MISC_FLAGS
  41
  42 AC_ARG_ENABLE(threads, AC_HELP_STRING([--enable-threads],
  43                 [enable threading support]), [enable_threads=${enableval}])
  44
  45 AC_CHECK_FUNC(signalfd, dummy=yes,
  46                         AC_MSG_ERROR(signalfd support is required))
  47
  48 AC_CHECK_LIB(rt, clock_gettime, dummy=yes,
  49                         AC_MSG_ERROR(realtime clock support is required))
  50
  51 AC_CHECK_LIB(pthread, pthread_create, dummy=yes,
  52                         AC_MSG_ERROR(posix thread support is required))
  53
  54 AC_CHECK_LIB(dl, dlopen, dummy=yes,
  55                         AC_MSG_ERROR(dynamic linking loader is required))
  56
  57 AC_CHECK_HEADERS(linux/types.h linux/if_alg.h)
  58
  59 PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.28, dummy=yes,
  60                                 AC_MSG_ERROR(GLib >= 2.28 is required))
  61 AC_SUBST(GLIB_CFLAGS)
  62 AC_SUBST(GLIB_LIBS)
  63
  64 if (test "${enable_threads}" = "yes"); then
  65         AC_DEFINE(NEED_THREADS, 1, [Define if threading support is required])
  66         PKG_CHECK_MODULES(GTHREAD, gthread-2.0 >= 2.16, dummy=yes,
  67                                 AC_MSG_ERROR(GThread >= 2.16 is required))
  68         GLIB_CFLAGS="$GLIB_CFLAGS $GTHREAD_CFLAGS"
  69         GLIB_LIBS="$GLIB_LIBS $GTHREAD_LIBS"
  70 fi
  71
  72 PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.6, dummy=yes,
  73                                 AC_MSG_ERROR(D-Bus >= 1.6 is required))
  74 AC_SUBST(DBUS_CFLAGS)
  75 AC_SUBST(DBUS_LIBS)
  76
  77 AC_ARG_WITH([dbusconfdir], AC_HELP_STRING([--with-dbusconfdir=DIR],
  78                                 [path to D-Bus configuration directory]),
  79                                         [path_dbusconfdir=${withval}])
  80 if (test -z "${path_dbusconfdir}"); then
  81         AC_MSG_CHECKING([D-Bus configuration directory])
  82         path_dbusconfdir="`$PKG_CONFIG --variable=sysconfdir dbus-1`"
  83         if (test -z "${path_dbusconfdir}"); then
  84                 AC_MSG_ERROR([D-Bus configuration directory is required])
  85         fi
  86         AC_MSG_RESULT([${path_dbusconfdir}])
  87 fi
  88 AC_SUBST(DBUS_CONFDIR, [${path_dbusconfdir}])
  89
  90 AC_ARG_WITH([dbussystembusdir], AC_HELP_STRING([--with-dbussystembusdir=DIR],
  91                                 [path to D-Bus system bus services directory]),
  92                                         [path_dbussystembusdir=${withval}])
  93 if (test -z "${path_dbussystembusdir}"); then
  94         AC_MSG_CHECKING([D-Bus system bus services dir])
  95         path_dbussystembusdir="`$PKG_CONFIG --variable=system_bus_services_dir dbus-1`"
  96         if (test -z "${path_dbussystembusdir}"); then
  97                 AC_MSG_ERROR([D-Bus system bus services directory is required])
  98         fi
  99         AC_MSG_RESULT([${path_dbussystembusdir}])
 100 fi
 101 AC_SUBST(DBUS_SYSTEMBUSDIR, [${path_dbussystembusdir}])
 102
 103 AC_ARG_WITH([dbussessionbusdir], AC_HELP_STRING([--with-dbussessionbusdir=DIR],
 104                                 [path to D-Bus session bus services directory]),
 105                                         [path_dbussessionbusdir=${withval}])
 106 if (test -z "${path_dbussessionbusdir}"); then
 107         AC_MSG_CHECKING([D-Bus session bus services dir])
 108         path_dbussessionbusdir="`$PKG_CONFIG --variable=session_bus_services_dir dbus-1`"
 109         if (test -z "${path_dbussessionbusdir}"); then
 110                 AC_MSG_ERROR([D-Bus session bus services directory is required])
 111         fi
 112         AC_MSG_RESULT([${path_dbussessionbusdir}])
 113 fi
 114 AC_SUBST(DBUS_SESSIONBUSDIR, [${path_dbussessionbusdir}])
 115
 116 AC_ARG_ENABLE(library, AC_HELP_STRING([--enable-library],
 117                 [install Bluetooth library]), [enable_library=${enableval}])
 118 AM_CONDITIONAL(LIBRARY, test "${enable_library}" = "yes")
 119
 120 AC_ARG_ENABLE(test, AC_HELP_STRING([--enable-test],
 121                 [enable test/example scripts]), [enable_test=${enableval}])
 122 AM_CONDITIONAL(TEST, test "${enable_test}" = "yes")
 123
 124 AC_ARG_ENABLE(tools, AC_HELP_STRING([--disable-tools],
 125                 [disable Bluetooth tools]), [enable_tools=${enableval}])
 126 AM_CONDITIONAL(TOOLS, test "${enable_tools}" != "no")
 127
 128 AC_ARG_ENABLE(monitor, AC_HELP_STRING([--disable-monitor],
 129                 [disable Bluetooth monitor]), [enable_monitor=${enableval}])
 130 AM_CONDITIONAL(MONITOR, test "${enable_monitor}" != "no")
 131
 132 AC_ARG_ENABLE(udev, AC_HELP_STRING([--disable-udev],
 133                 [disable udev device support]), [enable_udev=${enableval}])
 134 if (test "${enable_tools}" != "no" && test "${enable_udev}" != "no"); then
 135         PKG_CHECK_MODULES(UDEV, libudev >= 172, dummy=yes,
 136                                 AC_MSG_ERROR(libudev >= 172 is required))
 137         AC_SUBST(UDEV_CFLAGS)
 138         AC_SUBST(UDEV_LIBS)
 139         AC_CHECK_LIB(udev, udev_hwdb_new,
 140                 AC_DEFINE(HAVE_UDEV_HWDB_NEW, 1,
 141                         [Define to 1 if you have the udev_hwdb_new() function.]))
 142 fi
 143 AM_CONDITIONAL(UDEV, test "${enable_udev}" != "no")
 144
 145 AC_ARG_WITH([udevdir], AC_HELP_STRING([--with-udevdir=DIR],
 146                         [path to udev directory]), [path_udevdir=${withval}])
 147 if (test "${enable_udev}" != "no" && test -z "${path_udevdir}"); then
 148         AC_MSG_CHECKING([udev directory])
 149         path_udevdir="`$PKG_CONFIG --variable=udevdir udev`"
 150         if (test -z "${path_udevdir}"); then
 151                 AC_MSG_ERROR([udev directory is required])
 152         fi
 153         AC_MSG_RESULT([${path_udevdir}])
 154 fi
 155 AC_SUBST(UDEV_DIR, [${path_udevdir}])
 156
 157 AM_CONDITIONAL(HID2HCI, test "${enable_tools}" != "no" &&
 158                                                 test "${enable_udev}" != "no")
 159
 160 AC_ARG_ENABLE(cups, AC_HELP_STRING([--disable-cups],
 161                 [disable CUPS printer support]), [enable_cups=${enableval}])
 162 AM_CONDITIONAL(CUPS, test "${enable_cups}" != "no")
 163
 164 AC_ARG_ENABLE(obex, AC_HELP_STRING([--disable-obex],
 165                 [disable OBEX profile support]), [enable_obex=${enableval}])
 166 if (test "${enable_obex}" != "no"); then
 167         PKG_CHECK_MODULES(ICAL, libical, dummy=yes,
 168                                         AC_MSG_ERROR(libical is required))
 169         AC_SUBST(ICAL_CFLAGS)
 170         AC_SUBST(ICAL_LIBS)
 171 fi
 172 AM_CONDITIONAL(OBEX, test "${enable_obex}" != "no")
 173
 174 AC_ARG_ENABLE(client, AC_HELP_STRING([--disable-client],
 175                 [disable command line client]), [enable_client=${enableval}])
 176 AM_CONDITIONAL(CLIENT, test "${enable_client}" != "no")
 177
 178 if (test "${enable_client}" != "no"); then
 179         AC_CHECK_HEADERS(readline/readline.h, enable_readline=yes,
 180                 AC_MSG_ERROR(readline header files are required))
 181 fi
 182 AM_CONDITIONAL(READLINE, test "${enable_readline}" = "yes")
 183
 184 AC_ARG_ENABLE(systemd, AC_HELP_STRING([--disable-systemd],
 185                 [disable systemd integration]), [enable_systemd=${enableval}])
 186 AM_CONDITIONAL(SYSTEMD, test "${enable_systemd}" != "no")
 187
 188 AC_ARG_WITH([systemdsystemunitdir],
 189                         AC_HELP_STRING([--with-systemdsystemunitdir=DIR],
 190                         [path to systemd system unit directory]),
 191                                         [path_systemunitdir=${withval}])
 192 if (test "${enable_systemd}" != "no" && test -z "${path_systemunitdir}"); then
 193         AC_MSG_CHECKING([systemd system unit dir])
 194         path_systemunitdir="`$PKG_CONFIG --variable=systemdsystemunitdir systemd`"
 195         if (test -z "${path_systemunitdir}"); then
 196                 AC_MSG_ERROR([systemd system unit directory is required])
 197         fi
 198         AC_MSG_RESULT([${path_systemunitdir}])
 199 fi
 200 AC_SUBST(SYSTEMD_SYSTEMUNITDIR, [${path_systemunitdir}])
 201
 202 AC_ARG_WITH([systemduserunitdir],
 203                         AC_HELP_STRING([--with-systemduserunitdir=DIR],
 204                         [path to systemd user unit directory]),
 205                                         [path_userunitdir=${withval}])
 206 if (test "${enable_systemd}" != "no" && test -z "${path_userunitdir}"); then
 207         AC_MSG_CHECKING([systemd user unit dir])
 208         path_userunitdir="`$PKG_CONFIG --variable=systemduserunitdir systemd`"
 209         if (test -z "${path_userunitdir}"); then
 210                 AC_MSG_ERROR([systemd user unit directory is required])
 211         fi
 212         AC_MSG_RESULT([${path_userunitdir}])
 213 fi
 214 AC_SUBST(SYSTEMD_USERUNITDIR, [${path_userunitdir}])
 215
 216 AC_ARG_ENABLE(datafiles, AC_HELP_STRING([--disable-datafiles],
 217                         [do not install configuration and data files]),
 218                                         [enable_datafiles=${enableval}])
 219 AM_CONDITIONAL(DATAFILES, test "${enable_datafiles}" != "no")
 220
 221 AC_ARG_ENABLE(manpages, AC_HELP_STRING([--enable-manpages],
 222                         [enable building of manual pages]),
 223                                         [enable_manpages=${enableval}])
 224 AM_CONDITIONAL(MANPAGES, test "${enable_manpages}" = "yes")
 225
 226 AC_ARG_ENABLE(experimental, AC_HELP_STRING([--enable-experimental],
 227                         [enable experimental plugins (SAP, NFC, ...)]),
 228                                         [enable_experimental=${enableval}])
 229 AM_CONDITIONAL(EXPERIMENTAL, test "${enable_experimental}" = "yes")
 230
 231 AC_ARG_ENABLE(sixaxis, AC_HELP_STRING([--enable-sixaxis],
 232                 [enable sixaxis plugin]), [enable_sixaxis=${enableval}])
 233 AM_CONDITIONAL(SIXAXIS, test "${enable_sixaxis}" = "yes" &&
 234                                          test "${enable_udev}" != "no")
 235
 236 if (test "${prefix}" = "NONE"); then
 237         dnl no prefix and no localstatedir, so default to /var
 238         if (test "$localstatedir" = '${prefix}/var'); then
 239                 AC_SUBST([localstatedir], ['/var'])
 240         fi
 241
 242         prefix="${ac_default_prefix}"
 243 fi
 244
 245 if (test "$localstatedir" = '${prefix}/var'); then
 246         storagedir="${prefix}/var/lib/bluetooth"
 247 else
 248         storagedir="${localstatedir}/lib/bluetooth"
 249 fi
 250 AC_DEFINE_UNQUOTED(STORAGEDIR, "${storagedir}",
 251                         [Directory for the storage files])
 252
 253 if (test "$sysconfdir" = '${prefix}/etc'); then
 254         configdir="${prefix}/etc/bluetooth"
 255 else
 256         configdir="${sysconfdir}/bluetooth"
 257 fi
 258 AC_DEFINE_UNQUOTED(CONFIGDIR, "${configdir}",
 259                         [Directory for the configuration files])
 260 AC_SUBST(CONFIGDIR, "${configdir}")
 261
 262 AC_ARG_ENABLE(android, AC_HELP_STRING([--enable-android],
 263                         [enable BlueZ for Android]),
 264                                         [enable_android=${enableval}])
 265 AM_CONDITIONAL(ANDROID, test "${enable_android}" = "yes")
 266
 267 if (test "${enable_android}" = "yes"); then
 268         PKG_CHECK_MODULES(SBC, sbc >= 1.2, dummy=yes,
 269                                         AC_MSG_ERROR(SBC library >= 1.2 is required))
 270         AC_SUBST(SBC_CFLAGS)
 271         AC_SUBST(SBC_LIBS)
 272 fi
 273
 274 if (test "${enable_android}" = "yes"); then
 275         PKG_CHECK_MODULES(SPEEXDSP, speexdsp >= 1.2, dummy=yes,
 276                                         AC_MSG_ERROR(SPEEXDSP library >= 1.2 is required))
 277         AC_SUBST(SPEEXDSP_CFLAGS)
 278         AC_SUBST(SPEEXDSP_LIBS)
 279 fi
 280
 281 AC_DEFINE_UNQUOTED(ANDROID_STORAGEDIR, "${storagedir}/android",
 282                         [Directory for the Android daemon storage files])
 283
 284 AC_OUTPUT(Makefile src/bluetoothd.8 lib/bluez.pc)