configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.59])
   4
   5 dnl Versioning - scrape the version from configs/default
   6 m4_define([mesa_version],
   7     [m4_esyscmd([${MAKE-make} -s -f bin/version.mk version | tr -d '\n'])])
   8 m4_ifval(mesa_version,[],[
   9     m4_errprint([Error: Failed to get the Mesa version from the output of
  10        running `make -f bin/version.mk version'
  11 ])
  12     m4_exit([1])
  13 ])
  14
  15 dnl Tell the user about autoconf.html in the --help output
  16 m4_divert_once([HELP_END], [
  17 See docs/autoconf.html for more details on the options for Mesa.])
  18
  19 AC_INIT([Mesa],[mesa_version],
  20     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  21 AC_CONFIG_AUX_DIR([bin])
  22 AC_CANONICAL_HOST
  23
  24 dnl Versions for external dependencies
  25 LIBDRM_REQUIRED=2.4.3
  26 DRI2PROTO_REQUIRED=1.99.3
  27
  28 dnl Check for progs
  29 AC_PROG_CPP
  30 AC_PROG_CC
  31 AC_PROG_CXX
  32 AC_CHECK_PROGS([MAKE], [gmake make])
  33 AC_PATH_PROG([MKDEP], [makedepend])
  34 AC_PATH_PROG([SED], [sed])
  35
  36 dnl We need a POSIX shell for parts of the build. Assume we have one
  37 dnl in most cases.
  38 case "$host_os" in
  39 solaris*)
  40     # Solaris /bin/sh is too old/non-POSIX compliant
  41     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  42     SHELL="$POSIX_SHELL"
  43     ;;
  44 esac
  45
  46 MKDEP_OPTIONS=-fdepend
  47 dnl Ask gcc where it's keeping its secret headers
  48 if test "x$GCC" = xyes; then
  49     for dir in include include-fixed; do
  50         GCC_INCLUDES=`$CC -print-file-name=$dir`
  51         if test "x$GCC_INCLUDES" != x && \
  52            test "$GCC_INCLUDES" != "$dir" && \
  53            test -d "$GCC_INCLUDES"; then
  54             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
  55         fi
  56     done
  57 fi
  58 AC_SUBST([MKDEP_OPTIONS])
  59
  60 dnl Make sure the pkg-config macros are defined
  61 m4_ifdef([PKG_PROG_PKG_CONFIG],[],[
  62     m4_errprint([Error: Could not locate the pkg-config autoconf macros.
  63        These are usually located in /usr/share/aclocal/pkg.m4. If your
  64        macros are in a different location, try setting the environment
  65        variable ACLOCAL="aclocal -I/other/macro/dir" before running
  66        autoreconf.
  67 ])
  68     m4_exit([1])
  69 ])
  70 PKG_PROG_PKG_CONFIG()
  71
  72 dnl LIB_DIR - library basename
  73 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
  74 AC_SUBST([LIB_DIR])
  75
  76 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
  77 _SAVE_LDFLAGS="$LDFLAGS"
  78 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
  79 AC_SUBST([EXTRA_LIB_PATH])
  80
  81 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
  82 _SAVE_CPPFLAGS="$CPPFLAGS"
  83 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
  84 AC_SUBST([X11_INCLUDES])
  85
  86 dnl Compiler macros
  87 DEFINES=""
  88 AC_SUBST([DEFINES])
  89 case "$host_os" in
  90 *-gnu*)
  91     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
  92     ;;
  93 solaris*)
  94     DEFINES="$DEFINES -DPTHREADS -DSVR4"
  95     ;;
  96 esac
  97
  98 dnl Add flags for gcc and g++
  99 if test "x$GCC" = xyes; then
 100     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -std=c99 -ffast-math"
 101
 102     # Work around aliasing bugs - developers should comment this out
 103     CFLAGS="$CFLAGS -fno-strict-aliasing"
 104 fi
 105 if test "x$GXX" = xyes; then
 106     CXXFLAGS="$CXXFLAGS -Wall"
 107
 108     # Work around aliasing bugs - developers should comment this out
 109     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 110 fi
 111
 112 dnl These should be unnecessary, but let the user set them if they want
 113 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
 114     Default is to use CFLAGS.])
 115 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
 116     compiler. Default is to use CFLAGS.])
 117 AC_SUBST([OPT_FLAGS])
 118 AC_SUBST([ARCH_FLAGS])
 119
 120 dnl
 121 dnl Hacks to enable 32 or 64 bit build
 122 dnl
 123 AC_ARG_ENABLE([32-bit],
 124     [AS_HELP_STRING([--enable-32-bit],
 125         [build 32-bit libraries @<:@default=auto@:>@])],
 126     [enable_32bit="$enableval"],
 127     [enable_32bit=auto]
 128 )
 129 if test "x$enable_32bit" = xyes; then
 130     if test "x$GCC" = xyes; then
 131         CFLAGS="$CFLAGS -m32"
 132     fi
 133     if test "x$GXX" = xyes; then
 134         CXXFLAGS="$CXXFLAGS -m32"
 135     fi
 136 fi
 137 AC_ARG_ENABLE([64-bit],
 138     [AS_HELP_STRING([--enable-64-bit],
 139         [build 64-bit libraries @<:@default=auto@:>@])],
 140     [enable_64bit="$enableval"],
 141     [enable_64bit=auto]
 142 )
 143 if test "x$enable_64bit" = xyes; then
 144     if test "x$GCC" = xyes; then
 145         CFLAGS="$CFLAGS -m64"
 146     fi
 147     if test "x$GXX" = xyes; then
 148         CXXFLAGS="$CXXFLAGS -m64"
 149     fi
 150 fi
 151
 152 dnl
 153 dnl shared/static libraries, mimic libtool options
 154 dnl
 155 AC_ARG_ENABLE([static],
 156     [AS_HELP_STRING([--enable-static],
 157         [build static libraries @<:@default=disabled@:>@])],
 158     [enable_static="$enableval"],
 159     [enable_static=no]
 160 )
 161 case "x$enable_static" in
 162 xyes|xno ) ;;
 163 x ) enable_static=no ;;
 164 * )
 165     AC_MSG_ERROR([Static library option '$enable_static' is not a valid])
 166     ;;
 167 esac
 168 AC_ARG_ENABLE([shared],
 169     [AS_HELP_STRING([--disable-shared],
 170         [build shared libraries @<:@default=enabled@:>@])],
 171     [enable_shared="$enableval"],
 172     [enable_shared=yes]
 173 )
 174 case "x$enable_shared" in
 175 xyes|xno ) ;;
 176 x ) enable_shared=yes ;;
 177 * )
 178     AC_MSG_ERROR([Shared library option '$enable_shared' is not a valid])
 179     ;;
 180 esac
 181
 182 dnl Can't have static and shared libraries, default to static if user
 183 dnl explicitly requested. If both disabled, set to static since shared
 184 dnl was explicitly requirested.
 185 case "x$enable_static$enable_shared" in
 186 xyesyes )
 187     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 188     enable_shared=no
 189     ;;
 190 xnono )
 191     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 192     enable_static=yes
 193     ;;
 194 esac
 195
 196 dnl
 197 dnl mklib options
 198 dnl
 199 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 200 if test "$enable_static" = yes; then
 201     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 202 fi
 203 AC_SUBST([MKLIB_OPTIONS])
 204
 205 dnl
 206 dnl other compiler options
 207 dnl
 208 AC_ARG_ENABLE([debug],
 209     [AS_HELP_STRING([--enable-debug],
 210         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 211     [enable_debug="$enableval"],
 212     [enable_debug=no]
 213 )
 214 if test "x$enable_debug" = xyes; then
 215     DEFINES="$DEFINES -DDEBUG"
 216     if test "x$GCC" = xyes; then
 217         CFLAGS="$CFLAGS -g"
 218     fi
 219     if test "x$GXX" = xyes; then
 220         CXXFLAGS="$CXXFLAGS -g"
 221     fi
 222 fi
 223
 224 dnl
 225 dnl library names
 226 dnl
 227 if test "$enable_static" = yes; then
 228     LIB_EXTENSION='a'
 229 else
 230     case "$host_os" in
 231     darwin* )
 232         LIB_EXTENSION='dylib' ;;
 233     * )
 234         LIB_EXTENSION='so' ;;
 235     esac
 236 fi
 237
 238 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 239 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 240 GLUT_LIB_NAME='lib$(GLUT_LIB).'${LIB_EXTENSION}
 241 GLW_LIB_NAME='lib$(GLW_LIB).'${LIB_EXTENSION}
 242 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 243
 244 GL_LIB_GLOB='lib$(GL_LIB).*'${LIB_EXTENSION}'*'
 245 GLU_LIB_GLOB='lib$(GLU_LIB).*'${LIB_EXTENSION}'*'
 246 GLUT_LIB_GLOB='lib$(GLUT_LIB).*'${LIB_EXTENSION}'*'
 247 GLW_LIB_GLOB='lib$(GLW_LIB).*'${LIB_EXTENSION}'*'
 248 OSMESA_LIB_GLOB='lib$(OSMESA_LIB).*'${LIB_EXTENSION}'*'
 249
 250 AC_SUBST([GL_LIB_NAME])
 251 AC_SUBST([GLU_LIB_NAME])
 252 AC_SUBST([GLUT_LIB_NAME])
 253 AC_SUBST([GLW_LIB_NAME])
 254 AC_SUBST([OSMESA_LIB_NAME])
 255
 256 AC_SUBST([GL_LIB_GLOB])
 257 AC_SUBST([GLU_LIB_GLOB])
 258 AC_SUBST([GLUT_LIB_GLOB])
 259 AC_SUBST([GLW_LIB_GLOB])
 260 AC_SUBST([OSMESA_LIB_GLOB])
 261
 262 dnl
 263 dnl Arch/platform-specific settings
 264 dnl
 265 AC_ARG_ENABLE([asm],
 266     [AS_HELP_STRING([--disable-asm],
 267         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 268     [enable_asm="$enableval"],
 269     [enable_asm=yes]
 270 )
 271 asm_arch=""
 272 ASM_FLAGS=""
 273 MESA_ASM_SOURCES=""
 274 GLAPI_ASM_SOURCES=""
 275 AC_MSG_CHECKING([whether to enable assembly])
 276 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 277 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 278 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 279     case "$host_cpu" in
 280     i?86 | x86_64)
 281         enable_asm=no
 282         AC_MSG_RESULT([no, cross compiling])
 283         ;;
 284     esac
 285 fi
 286 # check for supported arches
 287 if test "x$enable_asm" = xyes; then
 288     case "$host_cpu" in
 289     i?86)
 290         case "$host_os" in
 291         linux* | *freebsd* | dragonfly*)
 292             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 293             ;;
 294         esac
 295         ;;
 296     x86_64)
 297         case "$host_os" in
 298         linux* | *freebsd* | dragonfly*)
 299             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 300             ;;
 301         esac
 302         ;;
 303     powerpc)
 304         case "$host_os" in
 305         linux*)
 306             asm_arch=ppc
 307             ;;
 308         esac
 309         ;;
 310     esac
 311
 312     case "$asm_arch" in
 313     x86)
 314         ASM_FLAGS="-DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 315         MESA_ASM_SOURCES='$(X86_SOURCES)'
 316         GLAPI_ASM_SOURCES='$(X86_API)'
 317         AC_MSG_RESULT([yes, x86])
 318         ;;
 319     x86_64)
 320         ASM_FLAGS="-DUSE_X86_64_ASM"
 321         MESA_ASM_SOURCES='$(X86-64_SOURCES)'
 322         GLAPI_ASM_SOURCES='$(X86-64_API)'
 323         AC_MSG_RESULT([yes, x86_64])
 324         ;;
 325     ppc)
 326         ASM_FLAGS="-DUSE_PPC_ASM -DUSE_VMX_ASM"
 327         MESA_ASM_SOURCES='$(PPC_SOURCES)'
 328         AC_MSG_RESULT([yes, ppc])
 329         ;;
 330     *)
 331         AC_MSG_RESULT([no, platform not supported])
 332         ;;
 333     esac
 334 fi
 335 AC_SUBST([ASM_FLAGS])
 336 AC_SUBST([MESA_ASM_SOURCES])
 337 AC_SUBST([GLAPI_ASM_SOURCES])
 338
 339 dnl PIC code macro
 340 MESA_PIC_FLAGS
 341
 342 dnl Check to see if dlopen is in default libraries (like Solaris, which
 343 dnl has it in libc), or if libdl is needed to get it.
 344 AC_CHECK_FUNC([dlopen], [],
 345     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 346
 347 dnl See if posix_memalign is available
 348 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 349
 350 dnl SELinux awareness.
 351 AC_ARG_ENABLE([selinux],
 352     [AS_HELP_STRING([--enable-selinux],
 353         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 354     [MESA_SELINUX="$enableval"],
 355     [MESA_SELINUX=no])
 356 if test "x$enable_selinux" = "xyes"; then
 357     AC_CHECK_HEADER([selinux/selinux.h],[],
 358                     [AC_MSG_ERROR([SELinux headers not found])])
 359     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 360                  [AC_MSG_ERROR([SELinux library not found])])
 361     SELINUX_LIBS="-lselinux"
 362     DEFINES="$DEFINES -DMESA_SELINUX"
 363 fi
 364
 365 dnl OS-specific libraries
 366 OS_LIBS=""
 367 case "$host_os" in
 368 solaris*)
 369     OS_LIBS="-lc"
 370     if test "x$GXX" != xyes; then
 371         OS_CPLUSPLUS_LIBS="-lCrun $OS_LIBS"
 372     fi
 373     ;;
 374 esac
 375
 376 dnl
 377 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 378 dnl More later: directfb, fbdev, ...
 379 dnl
 380 default_driver="xlib"
 381
 382 case "$host_os" in
 383 linux*)
 384     case "$host_cpu" in
 385     i*86|x86_64|powerpc*) default_driver="dri";;
 386     esac
 387     ;;
 388 *freebsd* | dragonfly*)
 389     case "$host_cpu" in
 390     i*86|x86_64) default_driver="dri";;
 391     esac
 392     ;;
 393 esac
 394
 395 AC_ARG_WITH([driver],
 396     [AS_HELP_STRING([--with-driver=DRIVER],
 397         [driver for Mesa: xlib,dri,osmesa @<:@default=dri when available, or xlib@:>@])],
 398     [mesa_driver="$withval"],
 399     [mesa_driver="$default_driver"])
 400 dnl Check for valid option
 401 case "x$mesa_driver" in
 402 xxlib|xdri|xosmesa)
 403     ;;
 404 *)
 405     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 406     ;;
 407 esac
 408
 409 dnl
 410 dnl Driver specific build directories
 411 dnl
 412 SRC_DIRS="mesa egl"
 413 GLU_DIRS="sgi"
 414 WINDOW_SYSTEM=""
 415 GALLIUM_DIRS="auxiliary drivers state_trackers"
 416 GALLIUM_WINSYS_DIRS=""
 417 GALLIUM_WINSYS_DRM_DIRS=""
 418 GALLIUM_AUXILIARY_DIRS="draw translate cso_cache pipebuffer tgsi sct rtasm util"
 419 GALLIUM_DRIVER_DIRS="softpipe failover trace"
 420 GALLIUM_STATE_TRACKERS_DIRS=""
 421
 422 case "$mesa_driver" in
 423 xlib)
 424     DRIVER_DIRS="x11"
 425     ;;
 426 dri)
 427     SRC_DIRS="glx/x11 $SRC_DIRS"
 428     DRIVER_DIRS="dri"
 429     WINDOW_SYSTEM="dri"
 430     GALLIUM_WINSYS_DIRS="drm $GALLIUM_WINSYS_DIRS"
 431     GALLIUM_WINSYS_DRM_DIRS="intel"
 432     GALLIUM_DRIVER_DIRS="$GALLIUM_DRIVER_DIRS i915simple i965simple"
 433     GALLIUM_STATE_TRACKERS_DIRS="egl"
 434     ;;
 435 osmesa)
 436     DRIVER_DIRS="osmesa"
 437     ;;
 438 esac
 439 AC_SUBST([SRC_DIRS])
 440 AC_SUBST([GLU_DIRS])
 441 AC_SUBST([DRIVER_DIRS])
 442 AC_SUBST([WINDOW_SYSTEM])
 443 AC_SUBST([GALLIUM_DIRS])
 444 AC_SUBST([GALLIUM_WINSYS_DIRS])
 445 AC_SUBST([GALLIUM_WINSYS_DRM_DIRS])
 446 AC_SUBST([GALLIUM_DRIVER_DIRS])
 447 AC_SUBST([GALLIUM_AUXILIARY_DIRS])
 448 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 449
 450 dnl
 451 dnl User supplied program configuration
 452 dnl
 453 if test -d "$srcdir/progs/demos"; then
 454     default_demos=yes
 455 else
 456     default_demos=no
 457 fi
 458 AC_ARG_WITH([demos],
 459     [AS_HELP_STRING([--with-demos@<:@=DIRS...@:>@],
 460         [optional comma delimited demo directories to build
 461         @<:@default=auto if source available@:>@])],
 462     [with_demos="$withval"],
 463     [with_demos="$default_demos"])
 464 if test "x$with_demos" = x; then
 465     with_demos=no
 466 fi
 467
 468 dnl If $with_demos is yes, directories will be added as libs available
 469 PROGRAM_DIRS=""
 470 case "$with_demos" in
 471 no) ;;
 472 yes)
 473     # If the driver isn't osmesa, we have libGL and can build xdemos
 474     if test "$mesa_driver" != osmesa; then
 475         PROGRAM_DIRS="xdemos"
 476     fi
 477     ;;
 478 *)
 479     # verify the requested demos directories exist
 480     demos=`IFS=,; echo $with_demos`
 481     for demo in $demos; do
 482         test -d "$srcdir/progs/$demo" || \
 483             AC_MSG_ERROR([Program directory '$demo' doesn't exist])
 484     done
 485     PROGRAM_DIRS="$demos"
 486     ;;
 487 esac
 488
 489 dnl
 490 dnl Find out if X is available. The variable have_x is set if libX11 is
 491 dnl found to mimic AC_PATH_XTRA.
 492 dnl
 493 if test -n "$PKG_CONFIG"; then
 494     AC_MSG_CHECKING([pkg-config files for X11 are available])
 495     PKG_CHECK_EXISTS([x11],[
 496         x11_pkgconfig=yes
 497         have_x=yes
 498         ],[
 499         x11_pkgconfig=no
 500     ])
 501     AC_MSG_RESULT([$x11_pkgconfig])
 502 else
 503     x11_pkgconfig=no
 504 fi
 505 dnl Use the autoconf macro if no pkg-config files
 506 if test "$x11_pkgconfig" = no; then
 507     AC_PATH_XTRA
 508 fi
 509
 510 dnl Try to tell the user that the --x-* options are only used when
 511 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 512 m4_divert_once([HELP_BEGIN],
 513 [These options are only used when the X libraries cannot be found by the
 514 pkg-config utility.])
 515
 516 dnl We need X for xlib and dri, so bomb now if it's not found
 517 case "$mesa_driver" in
 518 xlib|dri)
 519     if test "$no_x" = yes; then
 520         AC_MSG_ERROR([X11 development libraries needed for $mesa_driver driver])
 521     fi
 522     ;;
 523 esac
 524
 525 dnl XCB - this is only used for GLX right now
 526 AC_ARG_ENABLE([xcb],
 527     [AS_HELP_STRING([--enable-xcb],
 528         [use XCB for GLX @<:@default=disabled@:>@])],
 529     [enable_xcb="$enableval"],
 530     [enable_xcb=no])
 531 if test "x$enable_xcb" = xyes; then
 532     DEFINES="$DEFINES -DUSE_XCB"
 533 else
 534     enable_xcb=no
 535 fi
 536
 537 dnl
 538 dnl libGL configuration per driver
 539 dnl
 540 case "$mesa_driver" in
 541 xlib)
 542     if test "$x11_pkgconfig" = yes; then
 543         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 544         GL_PC_REQ_PRIV="x11 xext"
 545         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 546         GL_LIB_DEPS="$XLIBGL_LIBS"
 547     else
 548         # should check these...
 549         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 550         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 551         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 552         GL_PC_CFLAGS="$X11_INCLUDES"
 553     fi
 554     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread $OS_LIBS"
 555     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread $OS_LIBS"
 556
 557     # if static, move the external libraries to the programs
 558     # and empty the libraries for libGL
 559     if test "$enable_static" = yes; then
 560         APP_LIB_DEPS="$APP_LIB_DEPS $GL_LIB_DEPS"
 561         GL_LIB_DEPS=""
 562     fi
 563     ;;
 564 dri)
 565     # DRI must be shared, I think
 566     if test "$enable_static" = yes; then
 567         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 568     fi
 569
 570     # Check for libdrm
 571     PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED])
 572     PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 573     GL_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED"
 574     DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 575
 576     # find the DRI deps for libGL
 577     if test "$x11_pkgconfig" = yes; then
 578         # add xcb modules if necessary
 579         dri_modules="x11 xext xxf86vm xdamage xfixes"
 580         if test "$enable_xcb" = yes; then
 581             dri_modules="$dri_modules x11-xcb xcb-glx"
 582         fi
 583
 584         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 585         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 586         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 587         GL_LIB_DEPS="$DRIGL_LIBS"
 588     else
 589         # should check these...
 590         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 591         GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
 592         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 593         GL_PC_CFLAGS="$X11_INCLUDES"
 594
 595         # XCB can only be used from pkg-config
 596         if test "$enable_xcb" = yes; then
 597             PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx])
 598             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
 599             X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
 600             GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
 601         fi
 602     fi
 603
 604     # need DRM libs, -lpthread, etc.
 605     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS $OS_LIBS"
 606     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS $OS_LIBS"
 607     ;;
 608 osmesa)
 609     # No libGL for osmesa
 610     GL_LIB_DEPS="$OS_LIBS"
 611     ;;
 612 esac
 613 AC_SUBST([GL_LIB_DEPS])
 614 AC_SUBST([GL_PC_REQ_PRIV])
 615 AC_SUBST([GL_PC_LIB_PRIV])
 616 AC_SUBST([GL_PC_CFLAGS])
 617 AC_SUBST([DRI_PC_REQ_PRIV])
 618
 619 dnl
 620 dnl More X11 setup
 621 dnl
 622 if test "$mesa_driver" = xlib; then
 623     DEFINES="$DEFINES -DUSE_XSHM"
 624 fi
 625
 626 dnl
 627 dnl More DRI setup
 628 dnl
 629 AC_ARG_ENABLE([glx-tls],
 630     [AS_HELP_STRING([--enable-glx-tls],
 631         [enable TLS support in GLX @<:@default=disabled@:>@])],
 632     [GLX_USE_TLS="$enableval"],
 633     [GLX_USE_TLS=no])
 634 dnl Directory for DRI drivers
 635 AC_ARG_WITH([dri-driverdir],
 636     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 637         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 638     [DRI_DRIVER_INSTALL_DIR="$withval"],
 639     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 640 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 641 dnl Direct rendering or just indirect rendering
 642 AC_ARG_ENABLE([driglx-direct],
 643     [AS_HELP_STRING([--disable-driglx-direct],
 644         [enable direct rendering in GLX for DRI @<:@default=enabled@:>@])],
 645     [driglx_direct="$enableval"],
 646     [driglx_direct="yes"])
 647 dnl Which drivers to build - default is chosen by platform
 648 AC_ARG_WITH([dri-drivers],
 649     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 650         [comma delimited DRI drivers list, e.g.
 651         "swrast,i965,radeon,nouveau" @<:@default=auto@:>@])],
 652     [with_dri_drivers="$withval"],
 653     [with_dri_drivers=yes])
 654 if test "x$with_dri_drivers" = x; then
 655     with_dri_drivers=no
 656 fi
 657
 658 dnl If $with_dri_drivers is yes, directories will be added through
 659 dnl platform checks
 660 DRI_DIRS=""
 661 case "$with_dri_drivers" in
 662 no) ;;
 663 yes)
 664     DRI_DIRS="yes"
 665     ;;
 666 *)
 667     # verify the requested driver directories exist
 668     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 669     for driver in $dri_drivers; do
 670         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 671             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
 672     done
 673     DRI_DIRS="$dri_drivers"
 674     ;;
 675 esac
 676
 677 dnl Just default to no EGL for now
 678 USING_EGL=0
 679 AC_SUBST([USING_EGL])
 680
 681 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 682 if test "$mesa_driver" = dri; then
 683     # Use TLS in GLX?
 684     if test "x$GLX_USE_TLS" = xyes; then
 685         DEFINES="$DEFINES -DGLX_USE_TLS -DPTHREADS"
 686     fi
 687
 688     if test "x$USING_EGL" = x1; then
 689         PROGRAM_DIRS="egl"
 690     fi
 691
 692     # Platform specific settings and drivers to build
 693     case "$host_os" in
 694     linux*)
 695         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 696         if test "x$driglx_direct" = xyes; then
 697             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 698         fi
 699         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 700
 701         case "$host_cpu" in
 702         x86_64)
 703             # ffb, gamma, and sis are missing because they have not be
 704             # converted to use the new interface.  i810 are missing
 705             # because there is no x86-64 system where they could *ever*
 706             # be used.
 707             if test "x$DRI_DIRS" = "xyes"; then
 708                 DRI_DIRS="i915 i965 mach64 mga r128 r200 r300 radeon \
 709                     savage tdfx unichrome swrast"
 710             fi
 711             ;;
 712         powerpc*)
 713             # Build only the drivers for cards that exist on PowerPC.
 714             # At some point MGA will be added, but not yet.
 715             if test "x$DRI_DIRS" = "xyes"; then
 716                 DRI_DIRS="mach64 r128 r200 r300 radeon tdfx swrast"
 717             fi
 718             ;;
 719         sparc*)
 720             # Build only the drivers for cards that exist on sparc`
 721             if test "x$DRI_DIRS" = "xyes"; then
 722                 DRI_DIRS="mach64 r128 r200 r300 radeon ffb swrast"
 723             fi
 724             ;;
 725         esac
 726         ;;
 727     freebsd* | dragonfly*)
 728         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
 729         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
 730         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 731         if test "x$driglx_direct" = xyes; then
 732             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 733         fi
 734         if test "x$GXX" = xyes; then
 735             CXXFLAGS="$CXXFLAGS -ansi -pedantic"
 736         fi
 737
 738         # ffb and gamma are missing because they have not been converted
 739         # to use the new interface.
 740         if test "x$DRI_DIRS" = "xyes"; then
 741             DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 radeon tdfx \
 742                 unichrome savage sis swrast"
 743         fi
 744         ;;
 745     solaris*)
 746         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 747         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 748         if test "x$driglx_direct" = xyes; then
 749             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 750         fi
 751         ;;
 752     esac
 753
 754     # default drivers
 755     if test "x$DRI_DIRS" = "xyes"; then
 756         DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 radeon s3v \
 757             savage sis tdfx trident unichrome ffb swrast"
 758     fi
 759
 760     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
 761
 762     # Check for expat
 763     EXPAT_INCLUDES=""
 764     EXPAT_LIB=-lexpat
 765     AC_ARG_WITH([expat],
 766         [AS_HELP_STRING([--with-expat=DIR],
 767             [expat install directory])],[
 768         EXPAT_INCLUDES="-I$withval/include"
 769         CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
 770         LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
 771         EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
 772         ])
 773     AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
 774     AC_CHECK_LIB([expat],[XML_ParserCreate],[],
 775         [AC_MSG_ERROR([Expat required for DRI.])])
 776
 777     # put all the necessary libs together
 778     DRI_LIB_DEPS="$SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
 779 fi
 780 AC_SUBST([DRI_DIRS])
 781 AC_SUBST([EXPAT_INCLUDES])
 782 AC_SUBST([DRI_LIB_DEPS])
 783
 784 dnl
 785 dnl OSMesa configuration
 786 dnl
 787 if test "$mesa_driver" = xlib; then
 788     default_gl_osmesa=yes
 789 else
 790     default_gl_osmesa=no
 791 fi
 792 AC_ARG_ENABLE([gl-osmesa],
 793     [AS_HELP_STRING([--enable-gl-osmesa],
 794         [enable OSMesa on libGL @<:@default=enabled for xlib driver@:>@])],
 795     [gl_osmesa="$enableval"],
 796     [gl_osmesa="$default_gl_osmesa"])
 797 if test "x$gl_osmesa" = xyes; then
 798     if test "$mesa_driver" = osmesa; then
 799         AC_MSG_ERROR([libGL is not available for OSMesa driver])
 800     else
 801         DRIVER_DIRS="$DRIVER_DIRS osmesa"
 802     fi
 803 fi
 804
 805 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
 806 AC_ARG_WITH([osmesa-bits],
 807     [AS_HELP_STRING([--with-osmesa-bits=BITS],
 808         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
 809     [osmesa_bits="$withval"],
 810     [osmesa_bits=8])
 811 if test "$mesa_driver" != osmesa && test "x$osmesa_bits" != x8; then
 812     AC_MSG_WARN([Ignoring OSMesa channel bits for non-OSMesa driver])
 813     osmesa_bits=8
 814 fi
 815 case "x$osmesa_bits" in
 816 x8)
 817     OSMESA_LIB=OSMesa
 818     ;;
 819 x16|x32)
 820     OSMESA_LIB="OSMesa$osmesa_bits"
 821     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
 822     ;;
 823 *)
 824     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
 825     ;;
 826 esac
 827 AC_SUBST([OSMESA_LIB])
 828
 829 case "$mesa_driver" in
 830 osmesa)
 831     # only link libraries with osmesa if shared
 832     if test "$enable_static" = no; then
 833         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS"
 834     else
 835         OSMESA_LIB_DEPS=""
 836     fi
 837     OSMESA_MESA_DEPS=""
 838     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS"
 839     ;;
 840 *)
 841     # Link OSMesa to libGL otherwise
 842     OSMESA_LIB_DEPS=""
 843     # only link libraries with osmesa if shared
 844     if test "$enable_static" = no; then
 845         OSMESA_MESA_DEPS='-l$(GL_LIB)'
 846     else
 847         OSMESA_MESA_DEPS=""
 848     fi
 849     OSMESA_PC_REQ="gl"
 850     ;;
 851 esac
 852 if test "$enable_static" = no; then
 853     OSMESA_LIB_DEPS="$OSMESA_LIB_DEPS $OS_LIBS"
 854 fi
 855 OSMESA_PC_LIB_PRIV="$OSMESA_PC_LIB_PRIV $OS_LIBS"
 856 AC_SUBST([OSMESA_LIB_DEPS])
 857 AC_SUBST([OSMESA_MESA_DEPS])
 858 AC_SUBST([OSMESA_PC_REQ])
 859 AC_SUBST([OSMESA_PC_LIB_PRIV])
 860
 861 dnl
 862 dnl GLU configuration
 863 dnl
 864 AC_ARG_ENABLE([glu],
 865     [AS_HELP_STRING([--disable-glu],
 866         [enable OpenGL Utility library @<:@default=enabled@:>@])],
 867     [enable_glu="$enableval"],
 868     [enable_glu=yes])
 869 if test "x$enable_glu" = xyes; then
 870     SRC_DIRS="$SRC_DIRS glu"
 871
 872     case "$mesa_driver" in
 873     osmesa)
 874         # If GLU is available and we have libOSMesa (not 16 or 32),
 875         # we can build the osdemos
 876         if test "$with_demos" = yes && test "$osmesa_bits" = 8; then
 877             PROGRAM_DIRS="$PROGRAM_DIRS osdemos"
 878         fi
 879
 880         # Link libGLU to libOSMesa instead of libGL
 881         GLU_LIB_DEPS=""
 882         GLU_PC_REQ="osmesa"
 883         if test "$enable_static" = no; then
 884             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
 885         else
 886             GLU_MESA_DEPS=""
 887         fi
 888         ;;
 889     *)
 890         # If static, empty GLU_LIB_DEPS and add libs for programs to link
 891         GLU_PC_REQ="gl"
 892         GLU_PC_LIB_PRIV="-lm"
 893         if test "$enable_static" = no; then
 894             GLU_LIB_DEPS="-lm"
 895             GLU_MESA_DEPS='-l$(GL_LIB)'
 896         else
 897             GLU_LIB_DEPS=""
 898             GLU_MESA_DEPS=""
 899             APP_LIB_DEPS="$APP_LIB_DEPS -lstdc++"
 900         fi
 901         ;;
 902     esac
 903 fi
 904 if test "$enable_static" = no; then
 905     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
 906 fi
 907 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
 908 AC_SUBST([GLU_LIB_DEPS])
 909 AC_SUBST([GLU_MESA_DEPS])
 910 AC_SUBST([GLU_PC_REQ])
 911 AC_SUBST([GLU_PC_REQ_PRIV])
 912 AC_SUBST([GLU_PC_LIB_PRIV])
 913 AC_SUBST([GLU_PC_CFLAGS])
 914
 915 dnl
 916 dnl GLw configuration
 917 dnl
 918 AC_ARG_ENABLE([glw],
 919     [AS_HELP_STRING([--disable-glw],
 920         [enable Xt/Motif widget library @<:@default=enabled@:>@])],
 921     [enable_glw="$enableval"],
 922     [enable_glw=yes])
 923 dnl Don't build GLw on osmesa
 924 if test "x$enable_glw" = xyes && test "$mesa_driver" = osmesa; then
 925     AC_MSG_WARN([Disabling GLw since the driver is OSMesa])
 926     enable_glw=no
 927 fi
 928 AC_ARG_ENABLE([motif],
 929     [AS_HELP_STRING([--enable-motif],
 930         [use Motif widgets in GLw @<:@default=disabled@:>@])],
 931     [enable_motif="$enableval"],
 932     [enable_motif=no])
 933
 934 if test "x$enable_glw" = xyes; then
 935     SRC_DIRS="$SRC_DIRS glw"
 936     if test "$x11_pkgconfig" = yes; then
 937         PKG_CHECK_MODULES([GLW],[x11 xt])
 938         GLW_PC_REQ_PRIV="x11 xt"
 939         GLW_LIB_DEPS="$GLW_LIBS"
 940     else
 941         # should check these...
 942         GLW_LIB_DEPS="$X_LIBS -lXt -lX11"
 943         GLW_PC_LIB_PRIV="$GLW_LIB_DEPS"
 944         GLW_PC_CFLAGS="$X11_INCLUDES"
 945     fi
 946
 947     GLW_SOURCES="GLwDrawA.c"
 948     MOTIF_CFLAGS=
 949     if test "x$enable_motif" = xyes; then
 950         GLW_SOURCES="$GLW_SOURCES GLwMDrawA.c"
 951         AC_PATH_PROG([MOTIF_CONFIG], [motif-config], [no])
 952         if test "x$MOTIF_CONFIG" != xno; then
 953             MOTIF_CFLAGS=`$MOTIF_CONFIG --cflags`
 954             MOTIF_LIBS=`$MOTIF_CONFIG --libs`
 955         else
 956             AC_CHECK_HEADER([Xm/PrimitiveP.h], [],
 957                 [AC_MSG_ERROR([Can't locate Motif headers])])
 958             AC_CHECK_LIB([Xm], [XmGetPixmap], [MOTIF_LIBS="-lXm"],
 959                 [AC_MSG_ERROR([Can't locate Motif Xm library])])
 960         fi
 961         # MOTIF_LIBS is prepended to GLW_LIB_DEPS since Xm needs Xt/X11
 962         GLW_LIB_DEPS="$MOTIF_LIBS $GLW_LIB_DEPS"
 963         GLW_PC_LIB_PRIV="$MOTIF_LIBS $GLW_PC_LIB_PRIV"
 964         GLW_PC_CFLAGS="$MOTIF_CFLAGS $GLW_PC_CFLAGS"
 965     fi
 966
 967     # If static, empty GLW_LIB_DEPS and add libs for programs to link
 968     GLW_PC_LIB_PRIV="$GLW_PC_LIB_PRIV $OS_LIBS"
 969     if test "$enable_static" = no; then
 970         GLW_MESA_DEPS='-l$(GL_LIB)'
 971         GLW_LIB_DEPS="$GLW_LIB_DEPS $OS_LIBS"
 972     else
 973         APP_LIB_DEPS="$APP_LIB_DEPS $GLW_LIB_DEPS"
 974         GLW_LIB_DEPS=""
 975         GLW_MESA_DEPS=""
 976     fi
 977 fi
 978 AC_SUBST([GLW_LIB_DEPS])
 979 AC_SUBST([GLW_MESA_DEPS])
 980 AC_SUBST([GLW_SOURCES])
 981 AC_SUBST([MOTIF_CFLAGS])
 982 AC_SUBST([GLW_PC_REQ_PRIV])
 983 AC_SUBST([GLW_PC_LIB_PRIV])
 984 AC_SUBST([GLW_PC_CFLAGS])
 985
 986 dnl
 987 dnl GLUT configuration
 988 dnl
 989 if test -f "$srcdir/include/GL/glut.h"; then
 990     default_glut=yes
 991 else
 992     default_glut=no
 993 fi
 994 AC_ARG_ENABLE([glut],
 995     [AS_HELP_STRING([--disable-glut],
 996         [enable GLUT library @<:@default=enabled if source available@:>@])],
 997     [enable_glut="$enableval"],
 998     [enable_glut="$default_glut"])
 999
1000 dnl Can't build glut if GLU not available
1001 if test "x$enable_glu$enable_glut" = xnoyes; then
1002     AC_MSG_WARN([Disabling glut since GLU is disabled])
1003     enable_glut=no
1004 fi
1005 dnl Don't build glut on osmesa
1006 if test "x$enable_glut" = xyes && test "$mesa_driver" = osmesa; then
1007     AC_MSG_WARN([Disabling glut since the driver is OSMesa])
1008     enable_glut=no
1009 fi
1010
1011 if test "x$enable_glut" = xyes; then
1012     SRC_DIRS="$SRC_DIRS glut/glx"
1013     GLUT_CFLAGS=""
1014     if test "x$GCC" = xyes; then
1015         GLUT_CFLAGS="-fexceptions"
1016     fi
1017     if test "$x11_pkgconfig" = yes; then
1018         PKG_CHECK_MODULES([GLUT],[x11 xmu xi])
1019         GLUT_PC_REQ_PRIV="x11 xmu xi"
1020         GLUT_LIB_DEPS="$GLUT_LIBS"
1021     else
1022         # should check these...
1023         GLUT_LIB_DEPS="$X_LIBS -lX11 -lXmu -lXi"
1024         GLUT_PC_LIB_PRIV="$GLUT_LIB_DEPS"
1025         GLUT_PC_CFLAGS="$X11_INCLUDES"
1026     fi
1027     GLUT_LIB_DEPS="$GLUT_LIB_DEPS -lm $OS_LIBS"
1028     GLUT_PC_LIB_PRIV="$GLUT_PC_LIB_PRIV -lm $OS_LIBS"
1029
1030     # If glut is available, we can build most programs
1031     if test "$with_demos" = yes; then
1032         PROGRAM_DIRS="$PROGRAM_DIRS demos redbook samples glsl"
1033     fi
1034
1035     # If static, empty GLUT_LIB_DEPS and add libs for programs to link
1036     if test "$enable_static" = no; then
1037         GLUT_MESA_DEPS='-l$(GLU_LIB) -l$(GL_LIB)'
1038     else
1039         APP_LIB_DEPS="$APP_LIB_DEPS $GLUT_LIB_DEPS"
1040         GLUT_LIB_DEPS=""
1041         GLUT_MESA_DEPS=""
1042     fi
1043 fi
1044 AC_SUBST([GLUT_LIB_DEPS])
1045 AC_SUBST([GLUT_MESA_DEPS])
1046 AC_SUBST([GLUT_CFLAGS])
1047 AC_SUBST([GLUT_PC_REQ_PRIV])
1048 AC_SUBST([GLUT_PC_LIB_PRIV])
1049 AC_SUBST([GLUT_PC_CFLAGS])
1050
1051 dnl
1052 dnl Program library dependencies
1053 dnl    Only libm is added here if necessary as the libraries should
1054 dnl    be pulled in by the linker
1055 dnl
1056 if test "x$APP_LIB_DEPS" = x; then
1057     case "$host_os" in
1058     solaris*)
1059         APP_LIB_DEPS="-lX11 -lsocket -lnsl -lm"
1060         ;;
1061     *)
1062         APP_LIB_DEPS="-lm"
1063         ;;
1064     esac
1065 fi
1066 AC_SUBST([APP_LIB_DEPS])
1067 AC_SUBST([PROGRAM_DIRS])
1068
1069 dnl
1070 dnl Gallium configuration
1071 dnl
1072 AC_ARG_ENABLE([gallium],
1073     [AS_HELP_STRING([--disable-gallium],
1074         [build gallium @<:@default=enabled@:>@])],
1075     [enable_gallium="$enableval"],
1076     [enable_gallium=yes])
1077 if test "x$enable_gallium" = xyes; then
1078     SRC_DIRS="$SRC_DIRS gallium gallium/winsys"
1079 fi
1080
1081 dnl Restore LDFLAGS and CPPFLAGS
1082 LDFLAGS="$_SAVE_LDFLAGS"
1083 CPPFLAGS="$_SAVE_CPPFLAGS"
1084
1085 dnl Substitute the config
1086 AC_CONFIG_FILES([configs/autoconf])
1087
1088 dnl Replace the configs/current symlink
1089 AC_CONFIG_COMMANDS([configs],[
1090 if test -f configs/current || test -L configs/current; then
1091     rm -f configs/current
1092 fi
1093 ln -s autoconf configs/current
1094 ])
1095
1096 AC_OUTPUT
1097
1098 dnl
1099 dnl Output some configuration info for the user
1100 dnl
1101 echo ""
1102 echo "        prefix:          $prefix"
1103 echo "        exec_prefix:     $exec_prefix"
1104 echo "        libdir:          $libdir"
1105 echo "        includedir:      $includedir"
1106
1107 dnl Driver info
1108 echo ""
1109 echo "        Driver:          $mesa_driver"
1110 if echo "$DRIVER_DIRS" | grep 'osmesa' >/dev/null 2>&1; then
1111     echo "        OSMesa:          lib$OSMESA_LIB"
1112 else
1113     echo "        OSMesa:          no"
1114 fi
1115 if test "$mesa_driver" = dri; then
1116     # cleanup the drivers var
1117     dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1118 if test "x$DRI_DIRS" = x; then
1119     echo "        DRI drivers:     no"
1120 else
1121     echo "        DRI drivers:     $dri_dirs"
1122 fi
1123     echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
1124 fi
1125 echo "        Use XCB:         $enable_xcb"
1126
1127 echo ""
1128 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
1129     echo "        Gallium:         yes"
1130     echo "        Gallium dirs:    $GALLIUM_DIRS"
1131     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
1132     echo "        Winsys drm dirs: $GALLIUM_WINSYS_DRM_DIRS"
1133     echo "        Auxiliary dirs:  $GALLIUM_AUXILIARY_DIRS"
1134     echo "        Driver dirs:     $GALLIUM_DRIVER_DIRS"
1135     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
1136 else
1137     echo "        Gallium:         no"
1138 fi
1139
1140 dnl Libraries
1141 echo ""
1142 echo "        Shared libs:     $enable_shared"
1143 echo "        Static libs:     $enable_static"
1144 echo "        GLU:             $enable_glu"
1145 echo "        GLw:             $enable_glw (Motif: $enable_motif)"
1146 echo "        glut:            $enable_glut"
1147
1148 dnl Programs
1149 # cleanup the programs var for display
1150 program_dirs=`echo $PROGRAM_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1151 if test "x$program_dirs" = x; then
1152     echo "        Demos:           no"
1153 else
1154     echo "        Demos:           $program_dirs"
1155 fi
1156
1157 dnl Compiler options
1158 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
1159 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1160     $SED 's/^ *//;s/  */ /;s/ *$//'`
1161 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1162     $SED 's/^ *//;s/  */ /;s/ *$//'`
1163 defines=`echo $DEFINES $ASM_FLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1164 echo ""
1165 echo "        CFLAGS:          $cflags"
1166 echo "        CXXFLAGS:        $cxxflags"
1167 echo "        Macros:          $defines"
1168
1169 echo ""
1170 echo "        Run '${MAKE-make}' to build Mesa"
1171 echo ""