configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.59])
   4
   5 dnl Versioning - scrape the version from configs/default
   6 m4_define([mesa_version],
   7     [m4_esyscmd([${MAKE-make} -s -f bin/version.mk version | tr -d '\n'])])
   8 m4_ifval(mesa_version,[],[
   9     m4_errprint([Error: Failed to get the Mesa version from the output of
  10        running `make -f bin/version.mk version'
  11 ])
  12     m4_exit([1])
  13 ])
  14
  15 dnl Tell the user about autoconf.html in the --help output
  16 m4_divert_once([HELP_END], [
  17 See docs/autoconf.html for more details on the options for Mesa.])
  18
  19 AC_INIT([Mesa],[mesa_version],
  20     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  21 AC_CONFIG_AUX_DIR([bin])
  22 AC_CANONICAL_HOST
  23
  24 dnl Versions for external dependencies
  25 LIBDRM_REQUIRED=2.4.3
  26 DRI2PROTO_REQUIRED=1.99.3
  27
  28 dnl Check for progs
  29 AC_PROG_CPP
  30 AC_PROG_CC
  31 AC_PROG_CXX
  32 AC_CHECK_PROGS([MAKE], [gmake make])
  33 AC_PATH_PROG([MKDEP], [makedepend])
  34 AC_PATH_PROG([SED], [sed])
  35
  36 dnl We need a POSIX shell for parts of the build. Assume we have one
  37 dnl in most cases.
  38 case "$host_os" in
  39 solaris*)
  40     # Solaris /bin/sh is too old/non-POSIX compliant
  41     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  42     SHELL="$POSIX_SHELL"
  43     ;;
  44 esac
  45
  46 MKDEP_OPTIONS=-fdepend
  47 dnl Ask gcc where it's keeping its secret headers
  48 if test "x$GCC" = xyes; then
  49     for dir in include include-fixed; do
  50         GCC_INCLUDES=`$CC -print-file-name=$dir`
  51         if test "x$GCC_INCLUDES" != x && \
  52            test "$GCC_INCLUDES" != "$dir" && \
  53            test -d "$GCC_INCLUDES"; then
  54             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
  55         fi
  56     done
  57 fi
  58 AC_SUBST([MKDEP_OPTIONS])
  59
  60 dnl Make sure the pkg-config macros are defined
  61 m4_ifdef([PKG_PROG_PKG_CONFIG],[],[
  62     m4_errprint([Error: Could not locate the pkg-config autoconf macros.
  63        These are usually located in /usr/share/aclocal/pkg.m4. If your
  64        macros are in a different location, try setting the environment
  65        variable ACLOCAL="aclocal -I/other/macro/dir" before running
  66        autoreconf.
  67 ])
  68     m4_exit([1])
  69 ])
  70 PKG_PROG_PKG_CONFIG()
  71
  72 dnl LIB_DIR - library basename
  73 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
  74 AC_SUBST([LIB_DIR])
  75
  76 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
  77 _SAVE_LDFLAGS="$LDFLAGS"
  78 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
  79 AC_SUBST([EXTRA_LIB_PATH])
  80
  81 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
  82 _SAVE_CPPFLAGS="$CPPFLAGS"
  83 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
  84 AC_SUBST([X11_INCLUDES])
  85
  86 dnl Compiler macros
  87 DEFINES=""
  88 AC_SUBST([DEFINES])
  89 case "$host_os" in
  90 linux*|*-gnu*)
  91     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
  92     ;;
  93 solaris*)
  94     DEFINES="$DEFINES -DPTHREADS -DSVR4"
  95     ;;
  96 esac
  97
  98 dnl Add flags for gcc and g++
  99 if test "x$GCC" = xyes; then
 100     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -std=c99 -ffast-math"
 101
 102     # Work around aliasing bugs - developers should comment this out
 103     CFLAGS="$CFLAGS -fno-strict-aliasing"
 104 fi
 105 if test "x$GXX" = xyes; then
 106     CXXFLAGS="$CXXFLAGS -Wall"
 107
 108     # Work around aliasing bugs - developers should comment this out
 109     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 110 fi
 111
 112 dnl These should be unnecessary, but let the user set them if they want
 113 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
 114     Default is to use CFLAGS.])
 115 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
 116     compiler. Default is to use CFLAGS.])
 117 AC_SUBST([OPT_FLAGS])
 118 AC_SUBST([ARCH_FLAGS])
 119
 120 dnl
 121 dnl Hacks to enable 32 or 64 bit build
 122 dnl
 123 AC_ARG_ENABLE([32-bit],
 124     [AS_HELP_STRING([--enable-32-bit],
 125         [build 32-bit libraries @<:@default=auto@:>@])],
 126     [enable_32bit="$enableval"],
 127     [enable_32bit=auto]
 128 )
 129 if test "x$enable_32bit" = xyes; then
 130     if test "x$GCC" = xyes; then
 131         CFLAGS="$CFLAGS -m32"
 132     fi
 133     if test "x$GXX" = xyes; then
 134         CXXFLAGS="$CXXFLAGS -m32"
 135     fi
 136 fi
 137 AC_ARG_ENABLE([64-bit],
 138     [AS_HELP_STRING([--enable-64-bit],
 139         [build 64-bit libraries @<:@default=auto@:>@])],
 140     [enable_64bit="$enableval"],
 141     [enable_64bit=auto]
 142 )
 143 if test "x$enable_64bit" = xyes; then
 144     if test "x$GCC" = xyes; then
 145         CFLAGS="$CFLAGS -m64"
 146     fi
 147     if test "x$GXX" = xyes; then
 148         CXXFLAGS="$CXXFLAGS -m64"
 149     fi
 150 fi
 151
 152 dnl
 153 dnl shared/static libraries, mimic libtool options
 154 dnl
 155 AC_ARG_ENABLE([static],
 156     [AS_HELP_STRING([--enable-static],
 157         [build static libraries @<:@default=disabled@:>@])],
 158     [enable_static="$enableval"],
 159     [enable_static=no]
 160 )
 161 case "x$enable_static" in
 162 xyes|xno ) ;;
 163 x ) enable_static=no ;;
 164 * )
 165     AC_MSG_ERROR([Static library option '$enable_static' is not a valid])
 166     ;;
 167 esac
 168 AC_ARG_ENABLE([shared],
 169     [AS_HELP_STRING([--disable-shared],
 170         [build shared libraries @<:@default=enabled@:>@])],
 171     [enable_shared="$enableval"],
 172     [enable_shared=yes]
 173 )
 174 case "x$enable_shared" in
 175 xyes|xno ) ;;
 176 x ) enable_shared=yes ;;
 177 * )
 178     AC_MSG_ERROR([Shared library option '$enable_shared' is not a valid])
 179     ;;
 180 esac
 181
 182 dnl Can't have static and shared libraries, default to static if user
 183 dnl explicitly requested. If both disabled, set to static since shared
 184 dnl was explicitly requirested.
 185 case "x$enable_static$enable_shared" in
 186 xyesyes )
 187     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 188     enable_shared=no
 189     ;;
 190 xnono )
 191     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 192     enable_static=yes
 193     ;;
 194 esac
 195
 196 dnl
 197 dnl mklib options
 198 dnl
 199 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 200 if test "$enable_static" = yes; then
 201     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 202 fi
 203 AC_SUBST([MKLIB_OPTIONS])
 204
 205 dnl
 206 dnl other compiler options
 207 dnl
 208 AC_ARG_ENABLE([debug],
 209     [AS_HELP_STRING([--enable-debug],
 210         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 211     [enable_debug="$enableval"],
 212     [enable_debug=no]
 213 )
 214 if test "x$enable_debug" = xyes; then
 215     DEFINES="$DEFINES -DDEBUG"
 216     if test "x$GCC" = xyes; then
 217         CFLAGS="$CFLAGS -g"
 218     fi
 219     if test "x$GXX" = xyes; then
 220         CXXFLAGS="$CXXFLAGS -g"
 221     fi
 222 fi
 223
 224 dnl
 225 dnl library names
 226 dnl
 227 if test "$enable_static" = yes; then
 228     LIB_EXTENSION='a'
 229 else
 230     case "$host_os" in
 231     darwin* )
 232         LIB_EXTENSION='dylib' ;;
 233     * )
 234         LIB_EXTENSION='so' ;;
 235     esac
 236 fi
 237
 238 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 239 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 240 GLUT_LIB_NAME='lib$(GLUT_LIB).'${LIB_EXTENSION}
 241 GLW_LIB_NAME='lib$(GLW_LIB).'${LIB_EXTENSION}
 242 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 243
 244 GL_LIB_GLOB='lib$(GL_LIB).*'${LIB_EXTENSION}'*'
 245 GLU_LIB_GLOB='lib$(GLU_LIB).*'${LIB_EXTENSION}'*'
 246 GLUT_LIB_GLOB='lib$(GLUT_LIB).*'${LIB_EXTENSION}'*'
 247 GLW_LIB_GLOB='lib$(GLW_LIB).*'${LIB_EXTENSION}'*'
 248 OSMESA_LIB_GLOB='lib$(OSMESA_LIB).*'${LIB_EXTENSION}'*'
 249
 250 AC_SUBST([GL_LIB_NAME])
 251 AC_SUBST([GLU_LIB_NAME])
 252 AC_SUBST([GLUT_LIB_NAME])
 253 AC_SUBST([GLW_LIB_NAME])
 254 AC_SUBST([OSMESA_LIB_NAME])
 255
 256 AC_SUBST([GL_LIB_GLOB])
 257 AC_SUBST([GLU_LIB_GLOB])
 258 AC_SUBST([GLUT_LIB_GLOB])
 259 AC_SUBST([GLW_LIB_GLOB])
 260 AC_SUBST([OSMESA_LIB_GLOB])
 261
 262 dnl
 263 dnl Arch/platform-specific settings
 264 dnl
 265 AC_ARG_ENABLE([asm],
 266     [AS_HELP_STRING([--disable-asm],
 267         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 268     [enable_asm="$enableval"],
 269     [enable_asm=yes]
 270 )
 271 asm_arch=""
 272 ASM_FLAGS=""
 273 MESA_ASM_SOURCES=""
 274 GLAPI_ASM_SOURCES=""
 275 AC_MSG_CHECKING([whether to enable assembly])
 276 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 277 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 278 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 279     case "$host_cpu" in
 280     i?86 | x86_64)
 281         enable_asm=no
 282         AC_MSG_RESULT([no, cross compiling])
 283         ;;
 284     esac
 285 fi
 286 # check for supported arches
 287 if test "x$enable_asm" = xyes; then
 288     case "$host_cpu" in
 289     i?86)
 290         case "$host_os" in
 291         linux* | *freebsd* | dragonfly*)
 292             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 293             ;;
 294         esac
 295         ;;
 296     x86_64)
 297         case "$host_os" in
 298         linux* | *freebsd* | dragonfly*)
 299             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 300             ;;
 301         esac
 302         ;;
 303     powerpc)
 304         case "$host_os" in
 305         linux*)
 306             asm_arch=ppc
 307             ;;
 308         esac
 309         ;;
 310     sparc*)
 311         case "$host_os" in
 312         linux*)
 313             asm_arch=sparc
 314             ;;
 315         esac
 316         ;;
 317     esac
 318
 319     case "$asm_arch" in
 320     x86)
 321         ASM_FLAGS="-DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 322         MESA_ASM_SOURCES='$(X86_SOURCES)'
 323         GLAPI_ASM_SOURCES='$(X86_API)'
 324         AC_MSG_RESULT([yes, x86])
 325         ;;
 326     x86_64)
 327         ASM_FLAGS="-DUSE_X86_64_ASM"
 328         MESA_ASM_SOURCES='$(X86-64_SOURCES)'
 329         GLAPI_ASM_SOURCES='$(X86-64_API)'
 330         AC_MSG_RESULT([yes, x86_64])
 331         ;;
 332     ppc)
 333         ASM_FLAGS="-DUSE_PPC_ASM -DUSE_VMX_ASM"
 334         MESA_ASM_SOURCES='$(PPC_SOURCES)'
 335         AC_MSG_RESULT([yes, ppc])
 336         ;;
 337     sparc)
 338         ASM_FLAGS="-DUSE_SPARC_ASM"
 339         MESA_ASM_SOURCES='$(SPARC_SOURCES)'
 340         GLAPI_ASM_SOURCES='$(SPARC_API)'
 341         AC_MSG_RESULT([yes, sparc])
 342         ;;
 343     *)
 344         AC_MSG_RESULT([no, platform not supported])
 345         ;;
 346     esac
 347 fi
 348 AC_SUBST([ASM_FLAGS])
 349 AC_SUBST([MESA_ASM_SOURCES])
 350 AC_SUBST([GLAPI_ASM_SOURCES])
 351
 352 dnl PIC code macro
 353 MESA_PIC_FLAGS
 354
 355 dnl Check to see if dlopen is in default libraries (like Solaris, which
 356 dnl has it in libc), or if libdl is needed to get it.
 357 AC_CHECK_FUNC([dlopen], [],
 358     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 359
 360 dnl See if posix_memalign is available
 361 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 362
 363 dnl SELinux awareness.
 364 AC_ARG_ENABLE([selinux],
 365     [AS_HELP_STRING([--enable-selinux],
 366         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 367     [MESA_SELINUX="$enableval"],
 368     [MESA_SELINUX=no])
 369 if test "x$enable_selinux" = "xyes"; then
 370     AC_CHECK_HEADER([selinux/selinux.h],[],
 371                     [AC_MSG_ERROR([SELinux headers not found])])
 372     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 373                  [AC_MSG_ERROR([SELinux library not found])])
 374     SELINUX_LIBS="-lselinux"
 375     DEFINES="$DEFINES -DMESA_SELINUX"
 376 fi
 377
 378 dnl OS-specific libraries
 379 OS_LIBS=""
 380 case "$host_os" in
 381 solaris*)
 382     OS_LIBS="-lc"
 383     if test "x$GXX" != xyes; then
 384         OS_CPLUSPLUS_LIBS="-lCrun $OS_LIBS"
 385     fi
 386     ;;
 387 esac
 388
 389 dnl
 390 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 391 dnl More later: directfb, fbdev, ...
 392 dnl
 393 default_driver="xlib"
 394
 395 case "$host_os" in
 396 linux*)
 397     case "$host_cpu" in
 398     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 399     esac
 400     ;;
 401 *freebsd* | dragonfly*)
 402     case "$host_cpu" in
 403     i*86|x86_64) default_driver="dri";;
 404     esac
 405     ;;
 406 esac
 407
 408 AC_ARG_WITH([driver],
 409     [AS_HELP_STRING([--with-driver=DRIVER],
 410         [driver for Mesa: xlib,dri,osmesa @<:@default=dri when available, or xlib@:>@])],
 411     [mesa_driver="$withval"],
 412     [mesa_driver="$default_driver"])
 413 dnl Check for valid option
 414 case "x$mesa_driver" in
 415 xxlib|xdri|xosmesa)
 416     ;;
 417 *)
 418     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 419     ;;
 420 esac
 421
 422 dnl
 423 dnl Driver specific build directories
 424 dnl
 425 SRC_DIRS="mesa egl glew"
 426 GLU_DIRS="sgi"
 427 WINDOW_SYSTEM=""
 428 GALLIUM_DIRS="auxiliary drivers state_trackers"
 429 GALLIUM_WINSYS_DIRS=""
 430 GALLIUM_WINSYS_DRM_DIRS=""
 431 GALLIUM_AUXILIARY_DIRS="draw translate cso_cache pipebuffer tgsi sct rtasm util"
 432 GALLIUM_DRIVERS_DIRS="softpipe failover trace"
 433 GALLIUM_STATE_TRACKERS_DIRS=""
 434
 435 case "$mesa_driver" in
 436 xlib)
 437     DRIVER_DIRS="x11"
 438     ;;
 439 dri)
 440     SRC_DIRS="glx/x11 $SRC_DIRS"
 441     DRIVER_DIRS="dri"
 442     WINDOW_SYSTEM="dri"
 443     GALLIUM_WINSYS_DIRS="drm $GALLIUM_WINSYS_DIRS"
 444     ;;
 445 osmesa)
 446     DRIVER_DIRS="osmesa"
 447     ;;
 448 esac
 449 AC_SUBST([SRC_DIRS])
 450 AC_SUBST([GLU_DIRS])
 451 AC_SUBST([DRIVER_DIRS])
 452 AC_SUBST([WINDOW_SYSTEM])
 453 AC_SUBST([GALLIUM_DIRS])
 454 AC_SUBST([GALLIUM_WINSYS_DIRS])
 455 AC_SUBST([GALLIUM_WINSYS_DRM_DIRS])
 456 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 457 AC_SUBST([GALLIUM_AUXILIARY_DIRS])
 458 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 459
 460 dnl
 461 dnl User supplied program configuration
 462 dnl
 463 if test -d "$srcdir/progs/demos"; then
 464     default_demos=yes
 465 else
 466     default_demos=no
 467 fi
 468 AC_ARG_WITH([demos],
 469     [AS_HELP_STRING([--with-demos@<:@=DIRS...@:>@],
 470         [optional comma delimited demo directories to build
 471         @<:@default=auto if source available@:>@])],
 472     [with_demos="$withval"],
 473     [with_demos="$default_demos"])
 474 if test "x$with_demos" = x; then
 475     with_demos=no
 476 fi
 477
 478 dnl If $with_demos is yes, directories will be added as libs available
 479 PROGRAM_DIRS=""
 480 case "$with_demos" in
 481 no) ;;
 482 yes)
 483     # If the driver isn't osmesa, we have libGL and can build xdemos
 484     if test "$mesa_driver" != osmesa; then
 485         PROGRAM_DIRS="xdemos"
 486     fi
 487     ;;
 488 *)
 489     # verify the requested demos directories exist
 490     demos=`IFS=,; echo $with_demos`
 491     for demo in $demos; do
 492         test -d "$srcdir/progs/$demo" || \
 493             AC_MSG_ERROR([Program directory '$demo' doesn't exist])
 494     done
 495     PROGRAM_DIRS="$demos"
 496     ;;
 497 esac
 498
 499 dnl
 500 dnl Find out if X is available. The variable have_x is set if libX11 is
 501 dnl found to mimic AC_PATH_XTRA.
 502 dnl
 503 if test -n "$PKG_CONFIG"; then
 504     AC_MSG_CHECKING([pkg-config files for X11 are available])
 505     PKG_CHECK_EXISTS([x11],[
 506         x11_pkgconfig=yes
 507         have_x=yes
 508         ],[
 509         x11_pkgconfig=no
 510     ])
 511     AC_MSG_RESULT([$x11_pkgconfig])
 512 else
 513     x11_pkgconfig=no
 514 fi
 515 dnl Use the autoconf macro if no pkg-config files
 516 if test "$x11_pkgconfig" = no; then
 517     AC_PATH_XTRA
 518 fi
 519
 520 dnl Try to tell the user that the --x-* options are only used when
 521 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 522 m4_divert_once([HELP_BEGIN],
 523 [These options are only used when the X libraries cannot be found by the
 524 pkg-config utility.])
 525
 526 dnl We need X for xlib and dri, so bomb now if it's not found
 527 case "$mesa_driver" in
 528 xlib|dri)
 529     if test "$no_x" = yes; then
 530         AC_MSG_ERROR([X11 development libraries needed for $mesa_driver driver])
 531     fi
 532     ;;
 533 esac
 534
 535 dnl XCB - this is only used for GLX right now
 536 AC_ARG_ENABLE([xcb],
 537     [AS_HELP_STRING([--enable-xcb],
 538         [use XCB for GLX @<:@default=disabled@:>@])],
 539     [enable_xcb="$enableval"],
 540     [enable_xcb=no])
 541 if test "x$enable_xcb" = xyes; then
 542     DEFINES="$DEFINES -DUSE_XCB"
 543 else
 544     enable_xcb=no
 545 fi
 546
 547 dnl
 548 dnl libGL configuration per driver
 549 dnl
 550 case "$mesa_driver" in
 551 xlib)
 552     if test "$x11_pkgconfig" = yes; then
 553         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 554         GL_PC_REQ_PRIV="x11 xext"
 555         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 556         GL_LIB_DEPS="$XLIBGL_LIBS"
 557     else
 558         # should check these...
 559         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 560         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 561         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 562         GL_PC_CFLAGS="$X11_INCLUDES"
 563     fi
 564     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread $OS_LIBS"
 565     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread $OS_LIBS"
 566
 567     # if static, move the external libraries to the programs
 568     # and empty the libraries for libGL
 569     if test "$enable_static" = yes; then
 570         APP_LIB_DEPS="$APP_LIB_DEPS $GL_LIB_DEPS"
 571         GL_LIB_DEPS=""
 572     fi
 573     ;;
 574 dri)
 575     # DRI must be shared, I think
 576     if test "$enable_static" = yes; then
 577         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 578     fi
 579
 580     # Check for libdrm
 581     PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED])
 582     PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 583     GL_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED"
 584     DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 585
 586     # find the DRI deps for libGL
 587     if test "$x11_pkgconfig" = yes; then
 588         # add xcb modules if necessary
 589         dri_modules="x11 xext xxf86vm xdamage xfixes"
 590         if test "$enable_xcb" = yes; then
 591             dri_modules="$dri_modules x11-xcb xcb-glx"
 592         fi
 593
 594         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 595         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 596         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 597         GL_LIB_DEPS="$DRIGL_LIBS"
 598     else
 599         # should check these...
 600         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 601         GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
 602         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 603         GL_PC_CFLAGS="$X11_INCLUDES"
 604
 605         # XCB can only be used from pkg-config
 606         if test "$enable_xcb" = yes; then
 607             PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx])
 608             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
 609             X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
 610             GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
 611         fi
 612     fi
 613
 614     # need DRM libs, -lpthread, etc.
 615     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS $OS_LIBS"
 616     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS $OS_LIBS"
 617     ;;
 618 osmesa)
 619     # No libGL for osmesa
 620     GL_LIB_DEPS="$OS_LIBS"
 621     ;;
 622 esac
 623 AC_SUBST([GL_LIB_DEPS])
 624 AC_SUBST([GL_PC_REQ_PRIV])
 625 AC_SUBST([GL_PC_LIB_PRIV])
 626 AC_SUBST([GL_PC_CFLAGS])
 627 AC_SUBST([DRI_PC_REQ_PRIV])
 628
 629 dnl
 630 dnl More X11 setup
 631 dnl
 632 if test "$mesa_driver" = xlib; then
 633     DEFINES="$DEFINES -DUSE_XSHM"
 634 fi
 635
 636 dnl
 637 dnl More DRI setup
 638 dnl
 639 AC_ARG_ENABLE([glx-tls],
 640     [AS_HELP_STRING([--enable-glx-tls],
 641         [enable TLS support in GLX @<:@default=disabled@:>@])],
 642     [GLX_USE_TLS="$enableval"],
 643     [GLX_USE_TLS=no])
 644 dnl Directory for DRI drivers
 645 AC_ARG_WITH([dri-driverdir],
 646     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 647         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 648     [DRI_DRIVER_INSTALL_DIR="$withval"],
 649     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 650 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 651 dnl Direct rendering or just indirect rendering
 652 AC_ARG_ENABLE([driglx-direct],
 653     [AS_HELP_STRING([--disable-driglx-direct],
 654         [enable direct rendering in GLX for DRI @<:@default=enabled@:>@])],
 655     [driglx_direct="$enableval"],
 656     [driglx_direct="yes"])
 657 dnl Which drivers to build - default is chosen by platform
 658 AC_ARG_WITH([dri-drivers],
 659     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 660         [comma delimited DRI drivers list, e.g.
 661         "swrast,i965,radeon,nouveau" @<:@default=auto@:>@])],
 662     [with_dri_drivers="$withval"],
 663     [with_dri_drivers=yes])
 664 if test "x$with_dri_drivers" = x; then
 665     with_dri_drivers=no
 666 fi
 667
 668 dnl If $with_dri_drivers is yes, directories will be added through
 669 dnl platform checks
 670 DRI_DIRS=""
 671 case "$with_dri_drivers" in
 672 no) ;;
 673 yes)
 674     DRI_DIRS="yes"
 675     ;;
 676 *)
 677     # verify the requested driver directories exist
 678     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 679     for driver in $dri_drivers; do
 680         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 681             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
 682     done
 683     DRI_DIRS="$dri_drivers"
 684     ;;
 685 esac
 686
 687 dnl Just default to no EGL for now
 688 USING_EGL=0
 689 AC_SUBST([USING_EGL])
 690
 691 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 692 if test "$mesa_driver" = dri; then
 693     # Use TLS in GLX?
 694     if test "x$GLX_USE_TLS" = xyes; then
 695         DEFINES="$DEFINES -DGLX_USE_TLS -DPTHREADS"
 696     fi
 697
 698     if test "x$USING_EGL" = x1; then
 699         PROGRAM_DIRS="egl"
 700     fi
 701
 702     # Platform specific settings and drivers to build
 703     case "$host_os" in
 704     linux*)
 705         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 706         if test "x$driglx_direct" = xyes; then
 707             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 708         fi
 709         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 710
 711         case "$host_cpu" in
 712         x86_64)
 713             # ffb, gamma, and sis are missing because they have not be
 714             # converted to use the new interface.  i810 are missing
 715             # because there is no x86-64 system where they could *ever*
 716             # be used.
 717             if test "x$DRI_DIRS" = "xyes"; then
 718                 DRI_DIRS="i915 i965 mach64 mga r128 r200 r300 radeon \
 719                     savage tdfx unichrome swrast"
 720             fi
 721             ;;
 722         powerpc*)
 723             # Build only the drivers for cards that exist on PowerPC.
 724             # At some point MGA will be added, but not yet.
 725             if test "x$DRI_DIRS" = "xyes"; then
 726                 DRI_DIRS="mach64 r128 r200 r300 radeon tdfx swrast"
 727             fi
 728             ;;
 729         sparc*)
 730             # Build only the drivers for cards that exist on sparc`
 731             if test "x$DRI_DIRS" = "xyes"; then
 732                 DRI_DIRS="mach64 r128 r200 r300 radeon ffb swrast"
 733             fi
 734             ;;
 735         esac
 736         ;;
 737     freebsd* | dragonfly*)
 738         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
 739         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
 740         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 741         if test "x$driglx_direct" = xyes; then
 742             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 743         fi
 744         if test "x$GXX" = xyes; then
 745             CXXFLAGS="$CXXFLAGS -ansi -pedantic"
 746         fi
 747
 748         # ffb and gamma are missing because they have not been converted
 749         # to use the new interface.
 750         if test "x$DRI_DIRS" = "xyes"; then
 751             DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 radeon tdfx \
 752                 unichrome savage sis swrast"
 753         fi
 754         ;;
 755     solaris*)
 756         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 757         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 758         if test "x$driglx_direct" = xyes; then
 759             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 760         fi
 761         ;;
 762     esac
 763
 764     # default drivers
 765     if test "x$DRI_DIRS" = "xyes"; then
 766         DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 radeon s3v \
 767             savage sis tdfx trident unichrome ffb swrast"
 768     fi
 769
 770     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
 771
 772     # Check for expat
 773     EXPAT_INCLUDES=""
 774     EXPAT_LIB=-lexpat
 775     AC_ARG_WITH([expat],
 776         [AS_HELP_STRING([--with-expat=DIR],
 777             [expat install directory])],[
 778         EXPAT_INCLUDES="-I$withval/include"
 779         CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
 780         LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
 781         EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
 782         ])
 783     AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
 784     AC_CHECK_LIB([expat],[XML_ParserCreate],[],
 785         [AC_MSG_ERROR([Expat required for DRI.])])
 786
 787     # put all the necessary libs together
 788     DRI_LIB_DEPS="$SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
 789 fi
 790 AC_SUBST([DRI_DIRS])
 791 AC_SUBST([EXPAT_INCLUDES])
 792 AC_SUBST([DRI_LIB_DEPS])
 793
 794 dnl
 795 dnl OSMesa configuration
 796 dnl
 797 if test "$mesa_driver" = xlib; then
 798     default_gl_osmesa=yes
 799 else
 800     default_gl_osmesa=no
 801 fi
 802 AC_ARG_ENABLE([gl-osmesa],
 803     [AS_HELP_STRING([--enable-gl-osmesa],
 804         [enable OSMesa on libGL @<:@default=enabled for xlib driver@:>@])],
 805     [gl_osmesa="$enableval"],
 806     [gl_osmesa="$default_gl_osmesa"])
 807 if test "x$gl_osmesa" = xyes; then
 808     if test "$mesa_driver" = osmesa; then
 809         AC_MSG_ERROR([libGL is not available for OSMesa driver])
 810     else
 811         DRIVER_DIRS="$DRIVER_DIRS osmesa"
 812     fi
 813 fi
 814
 815 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
 816 AC_ARG_WITH([osmesa-bits],
 817     [AS_HELP_STRING([--with-osmesa-bits=BITS],
 818         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
 819     [osmesa_bits="$withval"],
 820     [osmesa_bits=8])
 821 if test "$mesa_driver" != osmesa && test "x$osmesa_bits" != x8; then
 822     AC_MSG_WARN([Ignoring OSMesa channel bits for non-OSMesa driver])
 823     osmesa_bits=8
 824 fi
 825 case "x$osmesa_bits" in
 826 x8)
 827     OSMESA_LIB=OSMesa
 828     ;;
 829 x16|x32)
 830     OSMESA_LIB="OSMesa$osmesa_bits"
 831     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
 832     ;;
 833 *)
 834     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
 835     ;;
 836 esac
 837 AC_SUBST([OSMESA_LIB])
 838
 839 case "$mesa_driver" in
 840 osmesa)
 841     # only link libraries with osmesa if shared
 842     if test "$enable_static" = no; then
 843         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS"
 844     else
 845         OSMESA_LIB_DEPS=""
 846     fi
 847     OSMESA_MESA_DEPS=""
 848     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS"
 849     ;;
 850 *)
 851     # Link OSMesa to libGL otherwise
 852     OSMESA_LIB_DEPS=""
 853     # only link libraries with osmesa if shared
 854     if test "$enable_static" = no; then
 855         OSMESA_MESA_DEPS='-l$(GL_LIB)'
 856     else
 857         OSMESA_MESA_DEPS=""
 858     fi
 859     OSMESA_PC_REQ="gl"
 860     ;;
 861 esac
 862 if test "$enable_static" = no; then
 863     OSMESA_LIB_DEPS="$OSMESA_LIB_DEPS $OS_LIBS"
 864 fi
 865 OSMESA_PC_LIB_PRIV="$OSMESA_PC_LIB_PRIV $OS_LIBS"
 866 AC_SUBST([OSMESA_LIB_DEPS])
 867 AC_SUBST([OSMESA_MESA_DEPS])
 868 AC_SUBST([OSMESA_PC_REQ])
 869 AC_SUBST([OSMESA_PC_LIB_PRIV])
 870
 871 dnl
 872 dnl EGL configuration
 873 dnl
 874 if test "$x11_pkgconfig" = yes; then
 875     PKG_CHECK_MODULES([EGL],[x11])
 876     EGL_LIB_DEPS="$EGL_LIBS"
 877 else
 878     # should check these...
 879     EGL_LIB_DEPS="$X_LIBS -lX11"
 880 fi
 881 EGL_LIB_DEPS="$EGL_LIB_DEPS $DLOPEN_LIBS $OS_LIBS"
 882 AC_SUBST([EGL_LIB_DEPS])
 883
 884 dnl
 885 dnl GLU configuration
 886 dnl
 887 AC_ARG_ENABLE([glu],
 888     [AS_HELP_STRING([--disable-glu],
 889         [enable OpenGL Utility library @<:@default=enabled@:>@])],
 890     [enable_glu="$enableval"],
 891     [enable_glu=yes])
 892 if test "x$enable_glu" = xyes; then
 893     SRC_DIRS="$SRC_DIRS glu"
 894
 895     case "$mesa_driver" in
 896     osmesa)
 897         # If GLU is available and we have libOSMesa (not 16 or 32),
 898         # we can build the osdemos
 899         if test "$with_demos" = yes && test "$osmesa_bits" = 8; then
 900             PROGRAM_DIRS="$PROGRAM_DIRS osdemos"
 901         fi
 902
 903         # Link libGLU to libOSMesa instead of libGL
 904         GLU_LIB_DEPS=""
 905         GLU_PC_REQ="osmesa"
 906         if test "$enable_static" = no; then
 907             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
 908         else
 909             GLU_MESA_DEPS=""
 910         fi
 911         ;;
 912     *)
 913         # If static, empty GLU_LIB_DEPS and add libs for programs to link
 914         GLU_PC_REQ="gl"
 915         GLU_PC_LIB_PRIV="-lm"
 916         if test "$enable_static" = no; then
 917             GLU_LIB_DEPS="-lm"
 918             GLU_MESA_DEPS='-l$(GL_LIB)'
 919         else
 920             GLU_LIB_DEPS=""
 921             GLU_MESA_DEPS=""
 922             APP_LIB_DEPS="$APP_LIB_DEPS -lstdc++"
 923         fi
 924         ;;
 925     esac
 926 fi
 927 if test "$enable_static" = no; then
 928     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
 929 fi
 930 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
 931 AC_SUBST([GLU_LIB_DEPS])
 932 AC_SUBST([GLU_MESA_DEPS])
 933 AC_SUBST([GLU_PC_REQ])
 934 AC_SUBST([GLU_PC_REQ_PRIV])
 935 AC_SUBST([GLU_PC_LIB_PRIV])
 936 AC_SUBST([GLU_PC_CFLAGS])
 937
 938 dnl
 939 dnl GLw configuration
 940 dnl
 941 AC_ARG_ENABLE([glw],
 942     [AS_HELP_STRING([--disable-glw],
 943         [enable Xt/Motif widget library @<:@default=enabled@:>@])],
 944     [enable_glw="$enableval"],
 945     [enable_glw=yes])
 946 dnl Don't build GLw on osmesa
 947 if test "x$enable_glw" = xyes && test "$mesa_driver" = osmesa; then
 948     AC_MSG_WARN([Disabling GLw since the driver is OSMesa])
 949     enable_glw=no
 950 fi
 951 AC_ARG_ENABLE([motif],
 952     [AS_HELP_STRING([--enable-motif],
 953         [use Motif widgets in GLw @<:@default=disabled@:>@])],
 954     [enable_motif="$enableval"],
 955     [enable_motif=no])
 956
 957 if test "x$enable_glw" = xyes; then
 958     SRC_DIRS="$SRC_DIRS glw"
 959     if test "$x11_pkgconfig" = yes; then
 960         PKG_CHECK_MODULES([GLW],[x11 xt])
 961         GLW_PC_REQ_PRIV="x11 xt"
 962         GLW_LIB_DEPS="$GLW_LIBS"
 963     else
 964         # should check these...
 965         GLW_LIB_DEPS="$X_LIBS -lXt -lX11"
 966         GLW_PC_LIB_PRIV="$GLW_LIB_DEPS"
 967         GLW_PC_CFLAGS="$X11_INCLUDES"
 968     fi
 969
 970     GLW_SOURCES="GLwDrawA.c"
 971     MOTIF_CFLAGS=
 972     if test "x$enable_motif" = xyes; then
 973         GLW_SOURCES="$GLW_SOURCES GLwMDrawA.c"
 974         AC_PATH_PROG([MOTIF_CONFIG], [motif-config], [no])
 975         if test "x$MOTIF_CONFIG" != xno; then
 976             MOTIF_CFLAGS=`$MOTIF_CONFIG --cflags`
 977             MOTIF_LIBS=`$MOTIF_CONFIG --libs`
 978         else
 979             AC_CHECK_HEADER([Xm/PrimitiveP.h], [],
 980                 [AC_MSG_ERROR([Can't locate Motif headers])])
 981             AC_CHECK_LIB([Xm], [XmGetPixmap], [MOTIF_LIBS="-lXm"],
 982                 [AC_MSG_ERROR([Can't locate Motif Xm library])])
 983         fi
 984         # MOTIF_LIBS is prepended to GLW_LIB_DEPS since Xm needs Xt/X11
 985         GLW_LIB_DEPS="$MOTIF_LIBS $GLW_LIB_DEPS"
 986         GLW_PC_LIB_PRIV="$MOTIF_LIBS $GLW_PC_LIB_PRIV"
 987         GLW_PC_CFLAGS="$MOTIF_CFLAGS $GLW_PC_CFLAGS"
 988     fi
 989
 990     # If static, empty GLW_LIB_DEPS and add libs for programs to link
 991     GLW_PC_LIB_PRIV="$GLW_PC_LIB_PRIV $OS_LIBS"
 992     if test "$enable_static" = no; then
 993         GLW_MESA_DEPS='-l$(GL_LIB)'
 994         GLW_LIB_DEPS="$GLW_LIB_DEPS $OS_LIBS"
 995     else
 996         APP_LIB_DEPS="$APP_LIB_DEPS $GLW_LIB_DEPS"
 997         GLW_LIB_DEPS=""
 998         GLW_MESA_DEPS=""
 999     fi
1000 fi
1001 AC_SUBST([GLW_LIB_DEPS])
1002 AC_SUBST([GLW_MESA_DEPS])
1003 AC_SUBST([GLW_SOURCES])
1004 AC_SUBST([MOTIF_CFLAGS])
1005 AC_SUBST([GLW_PC_REQ_PRIV])
1006 AC_SUBST([GLW_PC_LIB_PRIV])
1007 AC_SUBST([GLW_PC_CFLAGS])
1008
1009 dnl
1010 dnl GLUT configuration
1011 dnl
1012 if test -f "$srcdir/include/GL/glut.h"; then
1013     default_glut=yes
1014 else
1015     default_glut=no
1016 fi
1017 AC_ARG_ENABLE([glut],
1018     [AS_HELP_STRING([--disable-glut],
1019         [enable GLUT library @<:@default=enabled if source available@:>@])],
1020     [enable_glut="$enableval"],
1021     [enable_glut="$default_glut"])
1022
1023 dnl Can't build glut if GLU not available
1024 if test "x$enable_glu$enable_glut" = xnoyes; then
1025     AC_MSG_WARN([Disabling glut since GLU is disabled])
1026     enable_glut=no
1027 fi
1028 dnl Don't build glut on osmesa
1029 if test "x$enable_glut" = xyes && test "$mesa_driver" = osmesa; then
1030     AC_MSG_WARN([Disabling glut since the driver is OSMesa])
1031     enable_glut=no
1032 fi
1033
1034 if test "x$enable_glut" = xyes; then
1035     SRC_DIRS="$SRC_DIRS glut/glx"
1036     GLUT_CFLAGS=""
1037     if test "x$GCC" = xyes; then
1038         GLUT_CFLAGS="-fexceptions"
1039     fi
1040     if test "$x11_pkgconfig" = yes; then
1041         PKG_CHECK_MODULES([GLUT],[x11 xmu xi])
1042         GLUT_PC_REQ_PRIV="x11 xmu xi"
1043         GLUT_LIB_DEPS="$GLUT_LIBS"
1044     else
1045         # should check these...
1046         GLUT_LIB_DEPS="$X_LIBS -lX11 -lXmu -lXi"
1047         GLUT_PC_LIB_PRIV="$GLUT_LIB_DEPS"
1048         GLUT_PC_CFLAGS="$X11_INCLUDES"
1049     fi
1050     GLUT_LIB_DEPS="$GLUT_LIB_DEPS -lm $OS_LIBS"
1051     GLUT_PC_LIB_PRIV="$GLUT_PC_LIB_PRIV -lm $OS_LIBS"
1052
1053     # If glut is available, we can build most programs
1054     if test "$with_demos" = yes; then
1055         PROGRAM_DIRS="$PROGRAM_DIRS demos redbook samples glsl"
1056     fi
1057
1058     # If static, empty GLUT_LIB_DEPS and add libs for programs to link
1059     if test "$enable_static" = no; then
1060         GLUT_MESA_DEPS='-l$(GLU_LIB) -l$(GL_LIB)'
1061     else
1062         APP_LIB_DEPS="$APP_LIB_DEPS $GLUT_LIB_DEPS"
1063         GLUT_LIB_DEPS=""
1064         GLUT_MESA_DEPS=""
1065     fi
1066 fi
1067 AC_SUBST([GLUT_LIB_DEPS])
1068 AC_SUBST([GLUT_MESA_DEPS])
1069 AC_SUBST([GLUT_CFLAGS])
1070 AC_SUBST([GLUT_PC_REQ_PRIV])
1071 AC_SUBST([GLUT_PC_LIB_PRIV])
1072 AC_SUBST([GLUT_PC_CFLAGS])
1073
1074 dnl
1075 dnl Program library dependencies
1076 dnl    Only libm is added here if necessary as the libraries should
1077 dnl    be pulled in by the linker
1078 dnl
1079 if test "x$APP_LIB_DEPS" = x; then
1080     case "$host_os" in
1081     solaris*)
1082         APP_LIB_DEPS="-lX11 -lsocket -lnsl -lm"
1083         ;;
1084     *)
1085         APP_LIB_DEPS="-lm"
1086         ;;
1087     esac
1088 fi
1089 AC_SUBST([APP_LIB_DEPS])
1090 AC_SUBST([PROGRAM_DIRS])
1091
1092 dnl
1093 dnl Gallium configuration
1094 dnl
1095 AC_ARG_ENABLE([gallium],
1096     [AS_HELP_STRING([--disable-gallium],
1097         [build gallium @<:@default=enabled@:>@])],
1098     [enable_gallium="$enableval"],
1099     [enable_gallium=yes])
1100 if test "x$enable_gallium" = xyes; then
1101     SRC_DIRS="$SRC_DIRS gallium gallium/winsys"
1102 fi
1103
1104 dnl
1105 dnl Gallium state trackers configuration
1106 dnl
1107 AC_ARG_WITH([state-trackers],
1108     [AS_HELP_STRING([--with-state-trackers@<:@=DIRS...@:>@],
1109         [comma delimited state_trackers list, e.g.
1110         "egl,glx" @<:@default=auto@:>@])],
1111     [with_state_trackers="$withval"],
1112     [with_state_trackers=yes])
1113
1114 case "$with_state_trackers" in
1115 no)
1116     GALLIUM_STATE_TRACKERS_DIRS=""
1117     ;;
1118 yes)
1119     # look at what else is built
1120     case "$mesa_driver" in
1121     dri)
1122         GALLIUM_STATE_TRACKERS_DIRS=egl
1123         ;;
1124     esac
1125     ;;
1126 *)
1127     # verify the requested state tracker exist
1128     state_trackers=`IFS=', '; echo $with_state_trackers`
1129     for tracker in $state_trackers; do
1130         test -d "$srcdir/src/gallium/state_trackers/$tracker" || \
1131             AC_MSG_ERROR([state tracker '$tracker' doesn't exist])
1132     done
1133     GALLIUM_STATE_TRACKERS_DIRS="$state_trackers"
1134     ;;
1135 esac
1136
1137 AC_ARG_WITH([xorg-driver-dir],
1138     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1139                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1140     [XORG_DRIVER_INSTALL_DIR="$withval"],
1141     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1142 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1143
1144 dnl
1145 dnl Gallium Intel configuration
1146 dnl
1147 AC_ARG_ENABLE([gallium-intel],
1148     [AS_HELP_STRING([--disable-gallium-intel],
1149         [build gallium intel @<:@default=enabled@:>@])],
1150     [enable_gallium_intel="$enableval"],
1151     [enable_gallium_intel=yes])
1152 if test "x$enable_gallium_intel" = xyes; then
1153     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS intel"
1154     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915simple"
1155 fi
1156
1157 dnl
1158 dnl Gallium Radeon configuration
1159 dnl
1160 AC_ARG_ENABLE([gallium-radeon],
1161     [AS_HELP_STRING([--enable-gallium-radeon],
1162         [build gallium radeon @<:@default=disabled@:>@])],
1163     [enable_gallium_radeon="$enableval"],
1164     [enable_gallium_radeon=no])
1165 if test "x$enable_gallium_radeon" = xyes; then
1166     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS radeon"
1167     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1168 fi
1169
1170 dnl
1171 dnl Gallium Radeon configuration
1172 dnl
1173 AC_ARG_ENABLE([gallium-nouveau],
1174     [AS_HELP_STRING([--enable-gallium-nouveau],
1175         [build gallium nouveau @<:@default=disabled@:>@])],
1176     [enable_gallium_nouveau="$enableval"],
1177     [enable_gallium_nouveau=no])
1178 if test "x$enable_gallium_nouveau" = xyes; then
1179     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS nouveau"
1180     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nv04 nv10 nv20 nv30 nv40 nv50"
1181 fi
1182
1183
1184 dnl Restore LDFLAGS and CPPFLAGS
1185 LDFLAGS="$_SAVE_LDFLAGS"
1186 CPPFLAGS="$_SAVE_CPPFLAGS"
1187
1188 dnl Substitute the config
1189 AC_CONFIG_FILES([configs/autoconf])
1190
1191 dnl Replace the configs/current symlink
1192 AC_CONFIG_COMMANDS([configs],[
1193 if test -f configs/current || test -L configs/current; then
1194     rm -f configs/current
1195 fi
1196 ln -s autoconf configs/current
1197 ])
1198
1199 AC_OUTPUT
1200
1201 dnl
1202 dnl Output some configuration info for the user
1203 dnl
1204 echo ""
1205 echo "        prefix:          $prefix"
1206 echo "        exec_prefix:     $exec_prefix"
1207 echo "        libdir:          $libdir"
1208 echo "        includedir:      $includedir"
1209
1210 dnl Driver info
1211 echo ""
1212 echo "        Driver:          $mesa_driver"
1213 if echo "$DRIVER_DIRS" | grep 'osmesa' >/dev/null 2>&1; then
1214     echo "        OSMesa:          lib$OSMESA_LIB"
1215 else
1216     echo "        OSMesa:          no"
1217 fi
1218 if test "$mesa_driver" = dri; then
1219     # cleanup the drivers var
1220     dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1221 if test "x$DRI_DIRS" = x; then
1222     echo "        DRI drivers:     no"
1223 else
1224     echo "        DRI drivers:     $dri_dirs"
1225 fi
1226     echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
1227 fi
1228 echo "        Use XCB:         $enable_xcb"
1229
1230 echo ""
1231 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
1232     echo "        Gallium:         yes"
1233     echo "        Gallium dirs:    $GALLIUM_DIRS"
1234     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
1235     echo "        Winsys drm dirs:$GALLIUM_WINSYS_DRM_DIRS"
1236     echo "        Auxiliary dirs:  $GALLIUM_AUXILIARY_DIRS"
1237     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
1238     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
1239 else
1240     echo "        Gallium:         no"
1241 fi
1242
1243 dnl Libraries
1244 echo ""
1245 echo "        Shared libs:     $enable_shared"
1246 echo "        Static libs:     $enable_static"
1247 echo "        GLU:             $enable_glu"
1248 echo "        GLw:             $enable_glw (Motif: $enable_motif)"
1249 echo "        glut:            $enable_glut"
1250
1251 dnl Programs
1252 # cleanup the programs var for display
1253 program_dirs=`echo $PROGRAM_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1254 if test "x$program_dirs" = x; then
1255     echo "        Demos:           no"
1256 else
1257     echo "        Demos:           $program_dirs"
1258 fi
1259
1260 dnl Compiler options
1261 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
1262 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1263     $SED 's/^ *//;s/  */ /;s/ *$//'`
1264 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1265     $SED 's/^ *//;s/  */ /;s/ *$//'`
1266 defines=`echo $DEFINES $ASM_FLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1267 echo ""
1268 echo "        CFLAGS:          $cflags"
1269 echo "        CXXFLAGS:        $cxxflags"
1270 echo "        Macros:          $defines"
1271
1272 echo ""
1273 echo "        Run '${MAKE-make}' to build Mesa"
1274 echo ""