configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl
  13 dnl Permission is hereby granted, free of charge, to any person obtaining a
  14 dnl copy of this software and associated documentation files (the "Software"),
  15 dnl to deal in the Software without restriction, including without limitation
  16 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  17 dnl and/or sell copies of the Software, and to permit persons to whom the
  18 dnl Software is furnished to do so, subject to the following conditions:
  19 dnl
  20 dnl The above copyright notice and this permission notice (including the next
  21 dnl paragraph) shall be included in all copies or substantial portions of the
  22 dnl Software.
  23 dnl
  24 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  25 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  26 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  27 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  28 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  29 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  30 dnl DEALINGS IN THE SOFTWARE.
  31 dnl
  32 dnl Process this file with autoconf to create configure.
  33
  34 AC_PREREQ([2.60])
  35
  36 dnl Tell the user about autoconf.html in the --help output
  37 m4_divert_once([HELP_END], [
  38 See docs/autoconf.html for more details on the options for Mesa.])
  39
  40 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  41 AC_INIT([Mesa], [MESA_VERSION],
  42     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  43 AC_CONFIG_AUX_DIR([bin])
  44 AC_CONFIG_MACRO_DIR([m4])
  45 AC_CANONICAL_SYSTEM
  46 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  47
  48 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  49 case "$host_os" in
  50 mingw*)
  51     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  52     ;;
  53 esac
  54
  55 # Support silent build rules, requires at least automake-1.11. Disable
  56 # by either passing --disable-silent-rules to configure or passing V=1
  57 # to make
  58 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  59     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  60
  61 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  62
  63 dnl Set internal versions
  64 OSMESA_VERSION=8
  65 AC_SUBST([OSMESA_VERSION])
  66 OPENCL_VERSION=1
  67 AC_SUBST([OPENCL_VERSION])
  68
  69 # The idea is that libdrm is distributed as one cohesive package, even
  70 # though it is composed of multiple libraries. However some drivers
  71 # may have different version requirements than others. This list
  72 # codifies which drivers need which version of libdrm. Any libdrm
  73 # version dependencies in non-driver-specific code should be reflected
  74 # in the first entry.
  75 LIBDRM_REQUIRED=2.4.75
  76 LIBDRM_RADEON_REQUIRED=2.4.71
  77 LIBDRM_AMDGPU_REQUIRED=2.4.79
  78 LIBDRM_INTEL_REQUIRED=2.4.75
  79 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  80 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  81 LIBDRM_FREEDRENO_REQUIRED=2.4.74
  82 LIBDRM_VC4_REQUIRED=2.4.69
  83 LIBDRM_ETNAVIV_REQUIRED=2.4.74
  84
  85 dnl Versions for external dependencies
  86 DRI2PROTO_REQUIRED=2.8
  87 DRI3PROTO_REQUIRED=1.0
  88 PRESENTPROTO_REQUIRED=1.0
  89 GLPROTO_REQUIRED=1.4.14
  90 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  91 LIBVA_REQUIRED=0.38.0
  92 VDPAU_REQUIRED=1.1
  93 WAYLAND_REQUIRED=1.11
  94 XCB_REQUIRED=1.9.3
  95 XCBDRI2_REQUIRED=1.8
  96 XCBGLX_REQUIRED=1.8.1
  97 XDAMAGE_REQUIRED=1.1
  98 XSHMFENCE_REQUIRED=1.1
  99 XVMC_REQUIRED=1.0.6
 100 PYTHON_MAKO_REQUIRED=0.8.0
 101 LIBSENSORS_REQUIRED=4.0.0
 102 ZLIB_REQUIRED=1.2.8
 103
 104 dnl LLVM versions
 105 LLVM_REQUIRED_GALLIUM=3.3.0
 106 LLVM_REQUIRED_OPENCL=3.6.0
 107 LLVM_REQUIRED_R600=3.8.0
 108 LLVM_REQUIRED_RADEONSI=3.8.0
 109 LLVM_REQUIRED_RADV=3.9.0
 110 LLVM_REQUIRED_SWR=3.9.0
 111
 112 dnl Check for progs
 113 AC_PROG_CPP
 114 AC_PROG_CC
 115 AC_PROG_CXX
 116 AM_PROG_CC_C_O
 117 AM_PROG_AS
 118 AX_CHECK_GNU_MAKE
 119 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 120 AC_PROG_SED
 121 AC_PROG_MKDIR_P
 122
 123 AC_SYS_LARGEFILE
 124
 125 LT_PREREQ([2.2])
 126 LT_INIT([disable-static])
 127
 128 AC_CHECK_PROG(RM, rm, [rm -f])
 129
 130 AX_PROG_BISON([],
 131               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 132                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 133 AX_PROG_FLEX([],
 134              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 135                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 136
 137 AC_CHECK_PROG(INDENT, indent, indent, cat)
 138 if test "x$INDENT" != "xcat"; then
 139     # Only GNU indent is supported
 140     INDENT_VERSION=`indent --version | grep GNU`
 141     if test $? -eq 0; then
 142        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 143     else
 144        INDENT="cat"
 145     fi
 146 fi
 147
 148 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 149
 150 if test -z "$PYTHON2"; then
 151     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 152         AC_MSG_ERROR([Python not found - unable to generate sources])
 153     fi
 154 else
 155     if test "x$acv_mako_found" = xno; then
 156         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 157             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 158         fi
 159     fi
 160 fi
 161
 162 AC_PROG_INSTALL
 163
 164 dnl We need a POSIX shell for parts of the build. Assume we have one
 165 dnl in most cases.
 166 case "$host_os" in
 167 solaris*)
 168     # Solaris /bin/sh is too old/non-POSIX compliant
 169     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 170     SHELL="$POSIX_SHELL"
 171     ;;
 172 esac
 173
 174 dnl clang is mostly GCC-compatible, but its version is much lower,
 175 dnl so we have to check for it.
 176 AC_MSG_CHECKING([if compiling with clang])
 177
 178 AC_COMPILE_IFELSE(
 179 [AC_LANG_PROGRAM([], [[
 180 #ifndef __clang__
 181        not clang
 182 #endif
 183 ]])],
 184 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 185
 186 AC_MSG_RESULT([$acv_mesa_CLANG])
 187
 188 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 189 dnl versions are explictly not supported.
 190 GEN_ASM_OFFSETS=no
 191 USE_GNU99=no
 192 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 193     AC_MSG_CHECKING([whether gcc version is sufficient])
 194     major=0
 195     minor=0
 196
 197     GCC_VERSION=`$CC -dumpversion`
 198     if test $? -eq 0; then
 199         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 200         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 201     fi
 202
 203     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 204         AC_MSG_RESULT([no])
 205         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 206     else
 207         AC_MSG_RESULT([yes])
 208     fi
 209
 210     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 211         USE_GNU99=yes
 212     fi
 213     if test "x$cross_compiling" = xyes; then
 214         GEN_ASM_OFFSETS=yes
 215     fi
 216 fi
 217
 218 dnl We don't support building Mesa with Sun C compiler
 219 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 220 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 221 if test "x$SUNCC" = xyes; then
 222     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 223 fi
 224
 225 dnl Check for compiler builtins
 226 AX_GCC_BUILTIN([__builtin_bswap32])
 227 AX_GCC_BUILTIN([__builtin_bswap64])
 228 AX_GCC_BUILTIN([__builtin_clz])
 229 AX_GCC_BUILTIN([__builtin_clzll])
 230 AX_GCC_BUILTIN([__builtin_ctz])
 231 AX_GCC_BUILTIN([__builtin_expect])
 232 AX_GCC_BUILTIN([__builtin_ffs])
 233 AX_GCC_BUILTIN([__builtin_ffsll])
 234 AX_GCC_BUILTIN([__builtin_popcount])
 235 AX_GCC_BUILTIN([__builtin_popcountll])
 236 AX_GCC_BUILTIN([__builtin_unreachable])
 237
 238 AX_GCC_FUNC_ATTRIBUTE([const])
 239 AX_GCC_FUNC_ATTRIBUTE([flatten])
 240 AX_GCC_FUNC_ATTRIBUTE([format])
 241 AX_GCC_FUNC_ATTRIBUTE([malloc])
 242 AX_GCC_FUNC_ATTRIBUTE([packed])
 243 AX_GCC_FUNC_ATTRIBUTE([pure])
 244 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 245 AX_GCC_FUNC_ATTRIBUTE([unused])
 246 AX_GCC_FUNC_ATTRIBUTE([visibility])
 247 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 248 AX_GCC_FUNC_ATTRIBUTE([weak])
 249 AX_GCC_FUNC_ATTRIBUTE([alias])
 250
 251 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 252
 253 dnl Make sure the pkg-config macros are defined
 254 m4_ifndef([PKG_PROG_PKG_CONFIG],
 255     [m4_fatal([Could not locate the pkg-config autoconf macros.
 256   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 257   are in a different location, try setting the environment variable
 258   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 259 PKG_PROG_PKG_CONFIG()
 260
 261 dnl LIB_DIR - library basename
 262 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 263 AC_SUBST([LIB_DIR])
 264
 265 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 266 _SAVE_LDFLAGS="$LDFLAGS"
 267 _SAVE_CPPFLAGS="$CPPFLAGS"
 268
 269 dnl Compiler macros
 270 DEFINES="-D__STDC_CONSTANT_MACROS -D__STDC_FORMAT_MACROS -D__STDC_LIMIT_MACROS"
 271 AC_SUBST([DEFINES])
 272 android=no
 273 case "$host_os" in
 274 *-android)
 275     android=yes
 276     ;;
 277 linux*|*-gnu*|gnu*|cygwin*)
 278     DEFINES="$DEFINES -D_GNU_SOURCE"
 279     ;;
 280 solaris*)
 281     DEFINES="$DEFINES -DSVR4"
 282     ;;
 283 esac
 284
 285 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 286
 287 dnl Add flags for gcc and g++
 288 if test "x$GCC" = xyes; then
 289     CFLAGS="$CFLAGS -Wall"
 290
 291     if test "x$USE_GNU99" = xyes; then
 292         CFLAGS="$CFLAGS -std=gnu99"
 293     else
 294         CFLAGS="$CFLAGS -std=c99"
 295     fi
 296
 297     # Enable -Werror=implicit-function-declaration and
 298     # -Werror=missing-prototypes, if available, or otherwise, just
 299     # -Wmissing-prototypes.  This is particularly useful to avoid
 300     # generating a loadable driver module that has undefined symbols.
 301     save_CFLAGS="$CFLAGS"
 302     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 303     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 304     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 305     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 306                    AC_MSG_RESULT([yes]),
 307                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 308                     AC_MSG_RESULT([no])])
 309
 310     # Enable -fvisibility=hidden if using a gcc that supports it
 311     save_CFLAGS="$CFLAGS"
 312     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 313     VISIBILITY_CFLAGS="-fvisibility=hidden"
 314     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 315     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 316                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])])
 317
 318     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 319     CFLAGS=$save_CFLAGS
 320
 321     # We don't want floating-point math functions to set errno or trap
 322     CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
 323
 324     # Flags to help ensure that certain portions of the code -- and only those
 325     # portions -- can be built with MSVC:
 326     # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 327     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 328     #   supports most of C99)
 329     # - the rest has no compiler compiler restrictions
 330     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 331     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 332
 333     # Enable -Werror=vla if compiler supports it
 334     save_CFLAGS="$CFLAGS"
 335     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 336     CFLAGS="$CFLAGS -Werror=vla"
 337     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 338                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 339                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 340                     AC_MSG_RESULT([yes])],
 341                     AC_MSG_RESULT([no]))
 342     CFLAGS="$save_CFLAGS"
 343 fi
 344 if test "x$GXX" = xyes; then
 345     CXXFLAGS="$CXXFLAGS -Wall"
 346
 347     # Enable -fvisibility=hidden if using a gcc that supports it
 348     save_CXXFLAGS="$CXXFLAGS"
 349     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 350     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 351     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 352     AC_LANG_PUSH([C++])
 353     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 354                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])])
 355     AC_LANG_POP([C++])
 356
 357     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 358     CXXFLAGS=$save_CXXFLAGS
 359
 360     # We don't want floating-point math functions to set errno or trap
 361     CXXFLAGS="$CXXFLAGS -fno-math-errno -fno-trapping-math"
 362 fi
 363
 364 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 365 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 366
 367 dnl even if the compiler appears to support it, using visibility attributes isn't
 368 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 369 case "$host_os" in
 370 cygwin*)
 371     VISIBILITY_CFLAGS=""
 372     VISIBILITY_CXXFLAGS=""
 373     ;;
 374 esac
 375
 376 AC_SUBST([VISIBILITY_CFLAGS])
 377 AC_SUBST([VISIBILITY_CXXFLAGS])
 378
 379 dnl
 380 dnl Optional flags, check for compiler support
 381 dnl
 382 SSE41_CFLAGS="-msse4.1"
 383 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 384 dnl stack, but on x86-32 such alignment is not guaranteed.
 385 case "$target_cpu" in
 386 i?86)
 387     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 388     ;;
 389 esac
 390 save_CFLAGS="$CFLAGS"
 391 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 392 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 393 #include <smmintrin.h>
 394 int param;
 395 int main () {
 396     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 397     c = _mm_max_epu32(a, b);
 398     return _mm_cvtsi128_si32(c);
 399 }]])], SSE41_SUPPORTED=1)
 400 CFLAGS="$save_CFLAGS"
 401 if test "x$SSE41_SUPPORTED" = x1; then
 402     DEFINES="$DEFINES -DUSE_SSE41"
 403 fi
 404 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 405 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 406
 407 dnl Check for new-style atomic builtins
 408 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 409 int main() {
 410     int n;
 411     return __atomic_load_n(&n, __ATOMIC_ACQUIRE);
 412 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=1)
 413 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = x1; then
 414     DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
 415 fi
 416 AM_CONDITIONAL([GCC_ATOMIC_BUILTINS_SUPPORTED], [test x$GCC_ATOMIC_BUILTINS_SUPPORTED = x1])
 417
 418 dnl Check if host supports 64-bit atomics
 419 dnl note that lack of support usually results in link (not compile) error
 420 AC_MSG_CHECKING(whether __sync_add_and_fetch_8 is supported)
 421 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 422 #include <stdint.h>
 423 uint64_t v;
 424 int main() {
 425     return __sync_add_and_fetch(&v, (uint64_t)1);
 426 }]])], GCC_64BIT_ATOMICS_SUPPORTED=yes, GCC_64BIT_ATOMICS_SUPPORTED=no)
 427 if test "x$GCC_64BIT_ATOMICS_SUPPORTED" != xyes; then
 428     DEFINES="$DEFINES -DMISSING_64BIT_ATOMICS"
 429 fi
 430 AC_MSG_RESULT($GCC_64BIT_ATOMICS_SUPPORTED)
 431
 432 dnl Check for Endianness
 433 AC_C_BIGENDIAN(
 434    little_endian=no,
 435    little_endian=yes,
 436    little_endian=no,
 437    little_endian=no
 438 )
 439
 440 dnl Check for POWER8 Architecture
 441 PWR8_CFLAGS="-mpower8-vector"
 442 have_pwr8_intrinsics=no
 443 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 444 save_CFLAGS=$CFLAGS
 445 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 446 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 447 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 448 #error "Need GCC >= 4.8 for sane POWER8 support"
 449 #endif
 450 #include <altivec.h>
 451 int main () {
 452     vector unsigned char r;
 453     vector unsigned int v = vec_splat_u32 (1);
 454     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 455     return 0;
 456 }]])], have_pwr8_intrinsics=yes)
 457 CFLAGS=$save_CFLAGS
 458
 459 AC_ARG_ENABLE(pwr8,
 460    [AS_HELP_STRING([--disable-pwr8-inst],
 461                    [disable POWER8-specific instructions])],
 462    [enable_pwr8=$enableval], [enable_pwr8=auto])
 463
 464 if test "x$enable_pwr8" = xno ; then
 465    have_pwr8_intrinsics=disabled
 466 fi
 467
 468 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 469    DEFINES="$DEFINES -D_ARCH_PWR8"
 470    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 471    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 472 else
 473    PWR8_CFLAGS=
 474 fi
 475
 476 AC_MSG_RESULT($have_pwr8_intrinsics)
 477 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 478    AC_MSG_ERROR([POWER8 compiler support not detected])
 479 fi
 480
 481 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 482    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 483 fi
 484
 485 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 486
 487 dnl Can't have static and shared libraries, default to static if user
 488 dnl explicitly requested. If both disabled, set to static since shared
 489 dnl was explicitly requested.
 490 case "x$enable_static$enable_shared" in
 491 xyesyes)
 492     AC_MSG_ERROR([Cannot enable both static and shared. Building using --enable-shared is strongly recommended])
 493     ;;
 494 xnono)
 495     AC_MSG_ERROR([Cannot disable both static and shared. Building using --enable-shared is strongly recommended])
 496     ;;
 497 esac
 498
 499 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 500
 501 dnl
 502 dnl other compiler options
 503 dnl
 504 AC_ARG_ENABLE([debug],
 505     [AS_HELP_STRING([--enable-debug],
 506         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 507     [enable_debug="$enableval"],
 508     [enable_debug=no]
 509 )
 510
 511 AC_ARG_ENABLE([profile],
 512     [AS_HELP_STRING([--enable-profile],
 513         [enable profiling of code @<:@default=disabled@:>@])],
 514     [enable_profile="$enableval"],
 515     [enable_profile=no]
 516 )
 517
 518 AC_ARG_ENABLE([sanitize],
 519     [AS_HELP_STRING([--enable-sanitize@<:@=address|undefined@:>@],
 520         [enable code sanitizer @<:@default=disabled@:>@])],
 521     [enable_sanitize="$enableval"],
 522     [enable_sanitize=no])
 523
 524 if test "x$enable_profile" = xyes; then
 525     DEFINES="$DEFINES -DPROFILE"
 526     if test "x$GCC" = xyes; then
 527         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 528     fi
 529     if test "x$GXX" = xyes; then
 530         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 531     fi
 532 fi
 533
 534 if test "x$enable_debug" = xyes; then
 535     DEFINES="$DEFINES -DDEBUG"
 536     if test "x$enable_profile" = xyes; then
 537         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 538     fi
 539     if test "x$GCC" = xyes; then
 540         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 541             CFLAGS="$CFLAGS -g"
 542         fi
 543         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 544             CFLAGS="$CFLAGS -O0"
 545         fi
 546     fi
 547     if test "x$GXX" = xyes; then
 548         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 549             CXXFLAGS="$CXXFLAGS -g"
 550         fi
 551         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 552             CXXFLAGS="$CXXFLAGS -O0"
 553         fi
 554     fi
 555 else
 556    DEFINES="$DEFINES -DNDEBUG"
 557 fi
 558
 559 if test "x$enable_sanitize" != xno; then
 560     if test "x$enable_profile" = xyes; then
 561         AC_MSG_WARN([Sanitize and Profile are enabled at the same time])
 562     fi
 563
 564     CFLAGS="$CFLAGS -fsanitize=$enable_sanitize"
 565     CXXFLAGS="$CXXFLAGS -fsanitize=$enable_sanitize"
 566     LDFLAGS="$LDFLAGS -fsanitize=$enable_sanitize"
 567
 568     AC_LINK_IFELSE(
 569         [AC_LANG_SOURCE([int main(){return 0;}])],
 570         [],
 571         [AC_MSG_FAILURE([sanitize flags '$enable_sanitize' not supported])])
 572 fi
 573
 574 dnl
 575 dnl Check if linker supports -Bsymbolic
 576 dnl
 577 save_LDFLAGS=$LDFLAGS
 578 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 579 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 580 AC_LINK_IFELSE(
 581     [AC_LANG_SOURCE([int main() { return 0;}])],
 582     [AC_MSG_RESULT([yes])
 583         BSYMBOLIC="-Wl,-Bsymbolic";],
 584     [AC_MSG_RESULT([no])
 585         BSYMBOLIC="";])
 586 LDFLAGS=$save_LDFLAGS
 587
 588 AC_SUBST([BSYMBOLIC])
 589
 590 dnl
 591 dnl Check if linker supports garbage collection
 592 dnl
 593 save_LDFLAGS=$LDFLAGS
 594 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 595 AC_MSG_CHECKING([whether ld supports --gc-sections])
 596 AC_LINK_IFELSE(
 597     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 598     [AC_MSG_RESULT([yes])
 599         GC_SECTIONS="-Wl,--gc-sections";],
 600     [AC_MSG_RESULT([no])
 601         GC_SECTIONS="";])
 602 LDFLAGS=$save_LDFLAGS
 603
 604 AC_SUBST([GC_SECTIONS])
 605
 606 dnl
 607 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 608 dnl so when these flags are passed to ld via libtool the checks will fail
 609 dnl
 610 case "$host_os" in
 611 openbsd* | darwin* )
 612     LD_NO_UNDEFINED="" ;;
 613 *)
 614     if test "x$enable_sanitize" = xno; then
 615         LD_NO_UNDEFINED="-Wl,--no-undefined"
 616     else
 617         LD_NO_UNDEFINED=""
 618     fi
 619     ;;
 620 esac
 621
 622 AC_SUBST([LD_NO_UNDEFINED])
 623
 624 dnl
 625 dnl Check if linker supports version scripts
 626 dnl
 627 AC_MSG_CHECKING([if the linker supports version-scripts])
 628 save_LDFLAGS=$LDFLAGS
 629 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 630 cat > conftest.map <<EOF
 631 VERSION_1 {
 632      global:
 633          main;
 634
 635      local:
 636          *;
 637 };
 638 EOF
 639 AC_LINK_IFELSE(
 640     [AC_LANG_SOURCE([int main() { return 0;}])],
 641     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 642     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 643 LDFLAGS=$save_LDFLAGS
 644 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 645
 646 dnl
 647 dnl Check if linker supports dynamic list files
 648 dnl
 649 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 650 save_LDFLAGS=$LDFLAGS
 651 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 652 cat > conftest.dyn <<EOF
 653 {
 654         radeon_drm_winsys_create;
 655 };
 656 EOF
 657 AC_LINK_IFELSE(
 658     [AC_LANG_SOURCE([int main() { return 0;}])],
 659     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 660     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 661 LDFLAGS=$save_LDFLAGS
 662 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 663
 664 dnl
 665 dnl compatibility symlinks
 666 dnl
 667 case "$host_os" in
 668 linux* )
 669     HAVE_COMPAT_SYMLINKS=yes ;;
 670 * )
 671     HAVE_COMPAT_SYMLINKS=no ;;
 672 esac
 673
 674 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 675
 676 dnl
 677 dnl library names
 678 dnl
 679 dnl Unfortunately we need to do a few things that libtool can't help us with,
 680 dnl so we need some knowledge of shared library filenames:
 681 dnl
 682 dnl LIB_EXT is the extension used when creating symlinks for alternate
 683 dnl filenames for a shared library which will be dynamically loaded
 684 dnl
 685 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 686 dnl the file for a shared library we wish to link with
 687 dnl
 688 case "$host_os" in
 689 darwin* )
 690     LIB_EXT='dylib'
 691     IMP_LIB_EXT=$LIB_EXT
 692     ;;
 693 cygwin* )
 694     LIB_EXT='dll'
 695     IMP_LIB_EXT='dll.a'
 696     ;;
 697 aix* )
 698     LIB_EXT='a'
 699     IMP_LIB_EXT=$LIB_EXT
 700     ;;
 701 * )
 702     LIB_EXT='so'
 703     IMP_LIB_EXT=$LIB_EXT
 704     ;;
 705 esac
 706
 707 AC_SUBST([LIB_EXT])
 708
 709 dnl
 710 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 711 dnl
 712 AC_ARG_ENABLE([texture-float],
 713     [AS_HELP_STRING([--enable-texture-float],
 714         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 715     [enable_texture_float="$enableval"],
 716     [enable_texture_float=no]
 717 )
 718 if test "x$enable_texture_float" = xyes; then
 719     AC_MSG_WARN([Floating-point textures enabled.])
 720     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 721     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 722 fi
 723
 724 dnl
 725 dnl Arch/platform-specific settings
 726 dnl
 727 AC_ARG_ENABLE([asm],
 728     [AS_HELP_STRING([--disable-asm],
 729         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 730     [enable_asm="$enableval"],
 731     [enable_asm=yes]
 732 )
 733 asm_arch=""
 734 AC_MSG_CHECKING([whether to enable assembly])
 735 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 736 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 737 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 738     case "$host_cpu" in
 739     i?86 | x86_64 | amd64)
 740         if test "x$host_cpu" != "x$target_cpu"; then
 741             enable_asm=no
 742             AC_MSG_RESULT([no, cross compiling])
 743         fi
 744         ;;
 745     esac
 746 fi
 747 # check for supported arches
 748 if test "x$enable_asm" = xyes; then
 749     case "$host_cpu" in
 750     i?86)
 751         case "$host_os" in
 752         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 753             asm_arch=x86
 754             ;;
 755         esac
 756         ;;
 757     x86_64|amd64)
 758         case "$host_os" in
 759         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 760             asm_arch=x86_64
 761             ;;
 762         esac
 763         ;;
 764     sparc*)
 765         case "$host_os" in
 766         linux*)
 767             asm_arch=sparc
 768             ;;
 769         esac
 770         ;;
 771     esac
 772
 773     case "$asm_arch" in
 774     x86)
 775         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 776         AC_MSG_RESULT([yes, x86])
 777         ;;
 778     x86_64|amd64)
 779         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 780         AC_MSG_RESULT([yes, x86_64])
 781         ;;
 782     sparc)
 783         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 784         AC_MSG_RESULT([yes, sparc])
 785         ;;
 786     *)
 787         AC_MSG_RESULT([no, platform not supported])
 788         ;;
 789     esac
 790 fi
 791
 792 AC_HEADER_MAJOR
 793 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 794 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 795 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 796 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 797
 798 dnl Check to see if dlopen is in default libraries (like Solaris, which
 799 dnl has it in libc), or if libdl is needed to get it.
 800 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 801     [AC_CHECK_LIB([dl], [dlopen],
 802        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 803 AC_SUBST([DLOPEN_LIBS])
 804
 805 dnl Check if that library also has dladdr
 806 save_LIBS="$LIBS"
 807 LIBS="$LIBS $DLOPEN_LIBS"
 808 AC_CHECK_FUNCS([dladdr])
 809 LIBS="$save_LIBS"
 810
 811 AC_CHECK_FUNC([dl_iterate_phdr], [DEFINES="$DEFINES -DHAVE_DL_ITERATE_PHDR"])
 812
 813 case "$host_os" in
 814 darwin*)
 815     ;;
 816 *)
 817     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 818                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 819                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 820     AC_SUBST([CLOCK_LIB])
 821     ;;
 822 esac
 823
 824 dnl See if posix_memalign is available
 825 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 826
 827 dnl Check for zlib
 828 PKG_CHECK_MODULES([ZLIB], [zlib >= $ZLIB_REQUIRED])
 829
 830 dnl Check for pthreads
 831 AX_PTHREAD
 832 if test "x$ax_pthread_ok" = xno; then
 833     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 834 fi
 835 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 836 dnl to -pthread, which causes problems if we need -lpthread to appear in
 837 dnl pkgconfig files.  Since Android doesn't have a pthread lib, this check
 838 dnl is not valid for that platform.
 839 if test "x$android" = xno; then
 840     test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 841 fi
 842
 843 dnl pthread-stubs is mandatory on BSD platforms, due to the nature of the
 844 dnl project. Even then there's a notable issue as described in the project README
 845 case "$host_os" in
 846 linux* | cygwin* | darwin* | solaris* | *-gnu* | gnu*)
 847     pthread_stubs_possible="no"
 848     ;;
 849 * )
 850     pthread_stubs_possible="yes"
 851     ;;
 852 esac
 853
 854 if test "x$pthread_stubs_possible" = xyes; then
 855     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs >= 0.4)
 856     AC_SUBST(PTHREADSTUBS_CFLAGS)
 857     AC_SUBST(PTHREADSTUBS_LIBS)
 858 fi
 859
 860 dnl SELinux awareness.
 861 AC_ARG_ENABLE([selinux],
 862     [AS_HELP_STRING([--enable-selinux],
 863         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 864     [MESA_SELINUX="$enableval"],
 865     [MESA_SELINUX=no])
 866 if test "x$enable_selinux" = "xyes"; then
 867     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 868         [AC_CHECK_HEADER([selinux/selinux.h],[],
 869                          [AC_MSG_ERROR([SELinux headers not found])])
 870          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 871                       [AC_MSG_ERROR([SELinux library not found])])
 872          SELINUX_LIBS="-lselinux"])
 873     DEFINES="$DEFINES -DMESA_SELINUX"
 874 fi
 875 AC_SUBST([SELINUX_CFLAGS])
 876 AC_SUBST([SELINUX_LIBS])
 877
 878 dnl
 879 dnl LLVM
 880 dnl
 881 AC_ARG_ENABLE([llvm-shared-libs],
 882     [AS_HELP_STRING([--enable-llvm-shared-libs],
 883         [link with LLVM shared libraries @<:@default=enabled@:>@])],
 884     [enable_llvm_shared_libs="$enableval"],
 885     [enable_llvm_shared_libs=yes])
 886
 887 AC_ARG_WITH([llvm-prefix],
 888     [AS_HELP_STRING([--with-llvm-prefix],
 889         [Prefix for LLVM installations in non-standard locations])],
 890     [llvm_prefix="$withval"],
 891     [llvm_prefix=''])
 892
 893 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
 894 if test "x$have_libelf" = xno; then
 895    LIBELF_LIBS=''
 896    LIBELF_CFLAGS=''
 897    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
 898    AC_SUBST([LIBELF_LIBS])
 899    AC_SUBST([LIBELF_CFLAGS])
 900 fi
 901
 902 if test -z "$LLVM_CONFIG"; then
 903     if test -n "$llvm_prefix"; then
 904         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
 905     else
 906         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
 907     fi
 908 fi
 909
 910 llvm_add_component() {
 911     new_llvm_component=$1
 912     driver_name=$2
 913
 914     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
 915         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
 916     else
 917         AC_MSG_ERROR([LLVM component '$new_llvm_component' not enabled in your LLVM build. Required by $driver_name.])
 918     fi
 919 }
 920
 921 llvm_add_default_components() {
 922     driver_name=$1
 923
 924     # Required default components
 925     llvm_add_component "bitwriter" $driver_name
 926     llvm_add_component "engine" $driver_name
 927     llvm_add_component "mcdisassembler" $driver_name
 928     llvm_add_component "mcjit" $driver_name
 929
 930     # Optional default components
 931     if $LLVM_CONFIG --components | grep -iqw inteljitevents ; then
 932         LLVM_COMPONENTS="$LLVM_COMPONENTS inteljitevents"
 933     fi
 934 }
 935
 936 llvm_add_target() {
 937     new_llvm_target=$1
 938     driver_name=$2
 939
 940     if $LLVM_CONFIG --targets-built | grep -iqw $new_llvm_target ; then
 941         llvm_add_component $new_llvm_target $driver_name
 942     else
 943         AC_MSG_ERROR([LLVM target '$new_llvm_target' not enabled in your LLVM build. Required by $driver_name.])
 944     fi
 945 }
 946
 947 # Call this inside ` ` to get the return value.
 948 # $1 is the llvm-config command with arguments.
 949 strip_unwanted_llvm_flags() {
 950     echo " `$1` " | sed -E \
 951         -e 's/[[[:space:]]]+-m[[^[:space:]]]*//g' \
 952         -e 's/[[[:space:]]]+-DNDEBUG[[[:space:]]]/ /g' \
 953         -e 's/[[[:space:]]]+-D_GNU_SOURCE[[[:space:]]]/ /g' \
 954         -e 's/[[[:space:]]]+-pedantic[[[:space:]]]/ /g' \
 955         -e 's/[[[:space:]]]+-W[[^[:space:]]]*//g' \
 956         -e 's/[[[:space:]]]+-O[[^[:space:]]]*//g' \
 957         -e 's/[[[:space:]]]+-g[[^[:space:]]]*//g' \
 958         -e 's/-fno-rtti[[[:space:]]]/-Fno-rtti /g' \
 959         -e 's/[[[:space:]]]+-f[[^[:space:]]]*//g' \
 960         -e 's/-Fno-rtti[[[:space:]]]/-fno-rtti /g' \
 961         -e 's/^[[[:space:]]]//' \
 962         -e 's/[[[:space:]]]$//'
 963 }
 964
 965 llvm_set_environment_variables() {
 966     if test "x$LLVM_CONFIG" != xno; then
 967         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
 968         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
 969         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
 970         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
 971
 972         # We need to respect LLVM_CPPFLAGS when compiling LLVM headers.
 973         save_CFLAGS="$CFLAGS"
 974         CFLAGS="$CFLAGS $LLVM_CPPFLAGS"
 975
 976         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
 977             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 978         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
 979             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 980         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
 981             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 982
 983         CFLAGS="$save_CFLAGS"
 984
 985         # Only needed for LLVM < 3.6.0
 986         if test -z "$LLVM_VERSION_PATCH"; then
 987             LLVM_VERSION_PATCH=0
 988         fi
 989
 990         LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
 991
 992         FOUND_LLVM=yes
 993     else
 994         FOUND_LLVM=no
 995         LLVM_VERSION_INT=0
 996     fi
 997 }
 998
 999 require_llvm() {
1000     if test "x$enable_llvm" != "xyes"; then
1001         AC_MSG_ERROR([--enable-llvm is required when building $1])
1002     fi
1003 }
1004
1005 llvm_require_version() {
1006     require_llvm $2
1007
1008     llvm_target_version_major=`echo $1 | cut -d. -f1 | egrep -o '^[[0-9]]+'`
1009     llvm_target_version_minor=`echo $1 | cut -d. -f2 | egrep -o '^[[0-9]]+'`
1010     llvm_target_version_patch=`echo $1 | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1011
1012     if test "$LLVM_VERSION_MAJOR" -gt "$llvm_target_version_major"; then
1013         # major > required major
1014         #  --> OK
1015         return
1016     fi
1017
1018     if test "$LLVM_VERSION_MAJOR" -eq "$llvm_target_version_major"; then
1019         if test "$LLVM_VERSION_MINOR" -gt "$llvm_target_version_minor"; then
1020             # major = required major and
1021             # minor > required minor
1022             #  --> OK
1023             return
1024         else
1025             if test "$LLVM_VERSION_MINOR" -eq "$llvm_target_version_minor"; then
1026                 if test "$LLVM_VERSION_PATCH" -ge "$llvm_target_version_patch"; then
1027                     # major = required major and
1028                     # minor = required minor and
1029                     # patch >= required patch
1030                     #  --> OK
1031                     return
1032                 fi
1033             fi
1034         fi
1035     fi
1036
1037     AC_MSG_ERROR([LLVM $1 or newer is required for $2])
1038 }
1039
1040 radeon_llvm_check() {
1041     if test ${LLVM_VERSION_INT} -lt 307; then
1042         amdgpu_llvm_target_name='r600'
1043     else
1044         amdgpu_llvm_target_name='amdgpu'
1045     fi
1046
1047     llvm_require_version $*
1048
1049     llvm_add_target $amdgpu_llvm_target_name $2
1050
1051     llvm_add_default_components $2
1052     llvm_add_component "bitreader" $2
1053     llvm_add_component "ipo" $2
1054
1055     if test "x$have_libelf" != xyes; then
1056        AC_MSG_ERROR([$2 requires libelf when using llvm])
1057     fi
1058 }
1059
1060 llvm_set_environment_variables
1061
1062 AC_SUBST([LLVM_CFLAGS])
1063 AC_SUBST([LLVM_CXXFLAGS])
1064 AC_SUBST([LLVM_LIBS])
1065 AC_SUBST([LLVM_LDFLAGS])
1066 AC_SUBST([LLVM_INCLUDEDIR])
1067
1068 dnl
1069 dnl libunwind
1070 dnl
1071 AC_ARG_ENABLE([libunwind],
1072     [AS_HELP_STRING([--enable-libunwind],
1073             [Use libunwind for backtracing (default: auto)])],
1074         [LIBUNWIND="$enableval"],
1075         [LIBUNWIND="auto"])
1076
1077 PKG_CHECK_MODULES(LIBUNWIND, libunwind, [HAVE_LIBUNWIND=yes], [HAVE_LIBUNWIND=no])
1078 if test "x$LIBUNWIND" = "xauto"; then
1079     LIBUNWIND="$HAVE_LIBUNWIND"
1080 fi
1081
1082 if test "x$LIBUNWIND" = "xyes"; then
1083     if test "x$HAVE_LIBUNWIND" != "xyes"; then
1084         AC_MSG_ERROR([libunwind requested but not installed.])
1085     fi
1086     AC_DEFINE(HAVE_LIBUNWIND, 1, [Have libunwind support])
1087 fi
1088
1089 AM_CONDITIONAL(HAVE_LIBUNWIND, [test "x$LIBUNWIND" = xyes])
1090
1091
1092 dnl Options for APIs
1093 AC_ARG_ENABLE([opengl],
1094     [AS_HELP_STRING([--disable-opengl],
1095         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
1096     [enable_opengl="$enableval"],
1097     [enable_opengl=yes])
1098 AC_ARG_ENABLE([gles1],
1099     [AS_HELP_STRING([--disable-gles1],
1100         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
1101     [enable_gles1="$enableval"],
1102     [enable_gles1=yes])
1103 AC_ARG_ENABLE([gles2],
1104     [AS_HELP_STRING([--disable-gles2],
1105         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
1106     [enable_gles2="$enableval"],
1107     [enable_gles2=yes])
1108
1109 AC_ARG_ENABLE([dri],
1110     [AS_HELP_STRING([--enable-dri],
1111         [enable DRI modules @<:@default=enabled@:>@])],
1112     [enable_dri="$enableval"],
1113     [enable_dri=yes])
1114
1115 AC_ARG_ENABLE([gallium-extra-hud],
1116     [AS_HELP_STRING([--enable-gallium-extra-hud],
1117         [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
1118     [enable_gallium_extra_hud="$enableval"],
1119     [enable_gallium_extra_hud=no])
1120 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
1121 if test "x$enable_gallium_extra_hud" = xyes ; then
1122     DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
1123 fi
1124
1125 #TODO: no pkgconfig .pc available for libsensors.
1126 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
1127 AC_ARG_ENABLE([lmsensors],
1128     [AS_HELP_STRING([--enable-lmsensors],
1129         [enable HUD lmsensor support @<:@default=disabled@:>@])],
1130     [enable_lmsensors="$enableval"],
1131     [enable_lmsensors=no])
1132 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
1133 if test "x$enable_lmsensors" = xyes ; then
1134     DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
1135     LIBSENSORS_LIBS="-lsensors"
1136 else
1137     LIBSENSORS_LIBS=""
1138 fi
1139 AC_SUBST(LIBSENSORS_LIBS)
1140
1141 case "$host_os" in
1142 linux*)
1143     dri3_default=yes
1144     ;;
1145 *)
1146     dri3_default=no
1147     ;;
1148 esac
1149
1150 if test "x$enable_dri" = xno; then
1151     dri3_default=no
1152 fi
1153
1154 AC_ARG_ENABLE([dri3],
1155     [AS_HELP_STRING([--enable-dri3],
1156         [enable DRI3 @<:@default=auto@:>@])],
1157     [enable_dri3="$enableval"],
1158     [enable_dri3="$dri3_default"])
1159 AC_ARG_ENABLE([glx],
1160     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
1161         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
1162     [enable_glx="$enableval"],
1163     [enable_glx=yes])
1164 AC_ARG_ENABLE([osmesa],
1165     [AS_HELP_STRING([--enable-osmesa],
1166         [enable OSMesa library @<:@default=disabled@:>@])],
1167     [enable_osmesa="$enableval"],
1168     [enable_osmesa=no])
1169 AC_ARG_ENABLE([gallium-osmesa],
1170     [AS_HELP_STRING([--enable-gallium-osmesa],
1171         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
1172     [enable_gallium_osmesa="$enableval"],
1173     [enable_gallium_osmesa=no])
1174 AC_ARG_ENABLE([egl],
1175     [AS_HELP_STRING([--disable-egl],
1176         [disable EGL library @<:@default=enabled@:>@])],
1177     [enable_egl="$enableval"],
1178     [enable_egl=yes])
1179
1180 AC_ARG_ENABLE([xa],
1181     [AS_HELP_STRING([--enable-xa],
1182         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
1183     [enable_xa="$enableval"],
1184     [enable_xa=no])
1185 AC_ARG_ENABLE([gbm],
1186    [AS_HELP_STRING([--enable-gbm],
1187          [enable gbm library @<:@default=yes except cygwin@:>@])],
1188    [enable_gbm="$enableval"],
1189    [case "$host_os" in
1190        cygwin*)
1191           enable_gbm=no
1192           ;;
1193        *)
1194           enable_gbm=yes
1195           ;;
1196     esac])
1197 AC_ARG_ENABLE([nine],
1198     [AS_HELP_STRING([--enable-nine],
1199         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
1200     [enable_nine="$enableval"],
1201     [enable_nine=no])
1202
1203 AC_ARG_ENABLE([xvmc],
1204    [AS_HELP_STRING([--enable-xvmc],
1205          [enable xvmc library @<:@default=auto@:>@])],
1206    [enable_xvmc="$enableval"],
1207    [enable_xvmc=auto])
1208 AC_ARG_ENABLE([vdpau],
1209    [AS_HELP_STRING([--enable-vdpau],
1210          [enable vdpau library @<:@default=auto@:>@])],
1211    [enable_vdpau="$enableval"],
1212    [enable_vdpau=auto])
1213 AC_ARG_ENABLE([omx],
1214    [AS_HELP_STRING([--enable-omx],
1215          [enable OpenMAX library @<:@default=disabled@:>@])],
1216    [enable_omx="$enableval"],
1217    [enable_omx=no])
1218 AC_ARG_ENABLE([va],
1219    [AS_HELP_STRING([--enable-va],
1220          [enable va library @<:@default=auto@:>@])],
1221    [enable_va="$enableval"],
1222    [enable_va=auto])
1223 AC_ARG_ENABLE([opencl],
1224    [AS_HELP_STRING([--enable-opencl],
1225          [enable OpenCL library @<:@default=disabled@:>@])],
1226    [enable_opencl="$enableval"],
1227    [enable_opencl=no])
1228 AC_ARG_ENABLE([opencl_icd],
1229    [AS_HELP_STRING([--enable-opencl-icd],
1230           [Build an OpenCL ICD library to be loaded by an ICD implementation
1231            @<:@default=disabled@:>@])],
1232     [enable_opencl_icd="$enableval"],
1233     [enable_opencl_icd=no])
1234
1235 AC_ARG_ENABLE([gallium-tests],
1236     [AS_HELP_STRING([--enable-gallium-tests],
1237         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1238     [enable_gallium_tests="$enableval"],
1239     [enable_gallium_tests=no])
1240
1241 # Option for Gallium drivers
1242
1243 # Keep this in sync with the --with-gallium-drivers help string default value
1244 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1245
1246 AC_ARG_WITH([gallium-drivers],
1247     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1248         [comma delimited Gallium drivers list, e.g.
1249         "i915,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,swr,vc4,virgl,etnaviv,imx"
1250         @<:@default=r300,r600,svga,swrast@:>@])],
1251     [with_gallium_drivers="$withval"],
1252     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1253
1254 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
1255 # here so that the script doesn't choke on an unknown driver name later.
1256 case "$with_gallium_drivers" in
1257     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1258     no) with_gallium_drivers='' ;;
1259 esac
1260
1261 if test "x$enable_opengl" = xno -a \
1262         "x$enable_gles1" = xno -a \
1263         "x$enable_gles2" = xno -a \
1264         "x$enable_nine" = xno -a \
1265         "x$enable_xa" = xno -a \
1266         "x$enable_xvmc" = xno -a \
1267         "x$enable_vdpau" = xno -a \
1268         "x$enable_omx" = xno -a \
1269         "x$enable_va" = xno -a \
1270         "x$enable_opencl" = xno; then
1271     AC_MSG_ERROR([at least one API should be enabled])
1272 fi
1273
1274 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1275 if test "x$enable_opengl" = xno -a \
1276         "x$enable_gles1" = xyes; then
1277     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1278 fi
1279
1280 if test "x$enable_opengl" = xno -a \
1281         "x$enable_gles2" = xyes; then
1282     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1283 fi
1284
1285 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1286 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1287 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1288 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1289                                         "x$enable_gles1" = xyes -o \
1290                                         "x$enable_gles2" = xyes)
1291
1292 # Validate GLX options
1293 if test "x$enable_glx" = xyes; then
1294     if test "x$enable_dri" = xyes; then
1295         enable_glx=dri
1296     elif test -n "$with_gallium_drivers"; then
1297         enable_glx=gallium-xlib
1298     else
1299         enable_glx=xlib
1300     fi
1301 fi
1302 case "x$enable_glx" in
1303 xdri | xxlib | xgallium-xlib)
1304     # GLX requires OpenGL
1305     if test "x$enable_opengl" = xno; then
1306         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1307     fi
1308
1309     # Check individual dependencies
1310     case "x$enable_glx" in
1311     xdri)
1312         if test "x$enable_dri" = xno; then
1313             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1314         fi
1315         ;;
1316     xxlib)
1317         if test "x$enable_dri" = xyes; then
1318             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1319         fi
1320         ;;
1321     xgallium-xlib )
1322         if test "x$enable_dri" = xyes; then
1323             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1324         fi
1325         if test -z "$with_gallium_drivers"; then
1326             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1327         fi
1328         ;;
1329     esac
1330     ;;
1331 xno)
1332     ;;
1333 *)
1334     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1335     ;;
1336 esac
1337
1338 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1339 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1340 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1341 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1342
1343 DEFAULT_GL_LIB_NAME=GL
1344
1345 dnl
1346 dnl Libglvnd configuration
1347 dnl
1348 AC_ARG_ENABLE([libglvnd],
1349     [AS_HELP_STRING([--enable-libglvnd],
1350         [Build for libglvnd @<:@default=disabled@:>@])],
1351     [enable_libglvnd="$enableval"],
1352     [enable_libglvnd=no])
1353 AM_CONDITIONAL(USE_LIBGLVND_GLX, test "x$enable_libglvnd" = xyes)
1354 if test "x$enable_libglvnd" = xyes ; then
1355     dnl XXX: update once we can handle more than libGL/glx.
1356     dnl Namely: we should error out if neither of the glvnd enabled libraries
1357     dnl are built
1358     case "x$enable_glx" in
1359     xno)
1360         AC_MSG_ERROR([cannot build libglvnd without GLX])
1361         ;;
1362     xxlib | xgallium-xlib )
1363         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1364         ;;
1365     xdri)
1366         ;;
1367     esac
1368
1369     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.1.0)
1370     DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"
1371     DEFAULT_GL_LIB_NAME=GLX_mesa
1372 fi
1373
1374 AC_ARG_WITH([gl-lib-name],
1375   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
1376     [specify GL library name @<:@default=GL@:>@])],
1377   [GL_LIB=$withval],
1378   [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1379 AC_ARG_WITH([osmesa-lib-name],
1380   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
1381     [specify OSMesa library name @<:@default=OSMesa@:>@])],
1382   [OSMESA_LIB=$withval],
1383   [OSMESA_LIB=OSMesa])
1384 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1385 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
1386
1387 dnl
1388 dnl Mangled Mesa support
1389 dnl
1390 AC_ARG_ENABLE([mangling],
1391   [AS_HELP_STRING([--enable-mangling],
1392     [enable mangled symbols and library name @<:@default=disabled@:>@])],
1393   [enable_mangling="${enableval}"],
1394   [enable_mangling=no]
1395 )
1396 if test "x${enable_mangling}" = "xyes" ; then
1397   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
1398   GL_LIB="Mangled${GL_LIB}"
1399   OSMESA_LIB="Mangled${OSMESA_LIB}"
1400 fi
1401 AC_SUBST([GL_LIB])
1402 AC_SUBST([OSMESA_LIB])
1403
1404 # Check for libdrm
1405 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1406                   [have_libdrm=yes], [have_libdrm=no])
1407 if test "x$have_libdrm" = xyes; then
1408         DEFINES="$DEFINES -DHAVE_LIBDRM"
1409 fi
1410
1411 require_libdrm() {
1412     if test "x$have_libdrm" != xyes; then
1413        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1414     fi
1415 }
1416
1417
1418 # Select which platform-dependent DRI code gets built
1419 case "$host_os" in
1420 darwin*)
1421     dri_platform='apple' ;;
1422 cygwin*)
1423     dri_platform='windows' ;;
1424 gnu*)
1425     dri_platform='none' ;;
1426 *)
1427     dri_platform='drm' ;;
1428 esac
1429
1430 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1431     have_drisw_kms='yes'
1432 fi
1433
1434 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1435 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1436 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1437 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1438 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1439 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1440 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1441 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1442 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1443
1444 AC_ARG_ENABLE([shared-glapi],
1445     [AS_HELP_STRING([--enable-shared-glapi],
1446         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1447     [enable_shared_glapi="$enableval"],
1448     [enable_shared_glapi=yes])
1449
1450 case "x$enable_opengl$enable_gles1$enable_gles2" in
1451 x*yes*yes*)
1452     if test "x$enable_shared_glapi" = xno; then
1453         AC_MSG_ERROR([shared GLAPI required when building two or more of
1454                       the following APIs - opengl, gles1 gles2])
1455     fi
1456     ;;
1457 esac
1458
1459 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1460
1461 # Build the pipe-drivers as separate libraries/modules.
1462 # Do not touch this unless you know what you are doing.
1463 # XXX: Expose via configure option ?
1464 enable_shared_pipe_drivers=no
1465
1466 dnl
1467 dnl Driver specific build directories
1468 dnl
1469
1470 if test "x$enable_gallium_osmesa" = xyes; then
1471     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1472         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1473     fi
1474     if test "x$enable_osmesa" = xyes; then
1475         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1476     fi
1477 fi
1478
1479 require_dri_shared_libs_and_glapi() {
1480     if test "x$enable_static" = xyes; then
1481         AC_MSG_ERROR([$1 cannot be build as static library])
1482     fi
1483
1484     if test "x$enable_dri" != xyes; then
1485         # There is only a single backend which won't be build/used otherwise.
1486         # XXX: Revisit this as the egl/haiku is a thing.
1487         AC_MSG_ERROR([$1 requires --enable-dri])
1488     fi
1489
1490     if test "x$enable_shared_glapi" != xyes; then
1491         AC_MSG_ERROR([$1 requires --enable-shared-glapi])
1492     fi
1493 }
1494
1495 if test "x$enable_dri" = xyes; then
1496     require_dri_shared_libs_and_glapi "DRI"
1497
1498     # not a hard requirement as swrast does not depend on it
1499     if test "x$have_libdrm" = xyes; then
1500         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1501     fi
1502 fi
1503
1504 AC_ARG_ENABLE([driglx-direct],
1505     [AS_HELP_STRING([--disable-driglx-direct],
1506         [disable direct rendering in GLX and EGL for DRI \
1507             @<:@default=auto@:>@])],
1508     [driglx_direct="$enableval"],
1509     [driglx_direct="yes"])
1510
1511 dnl
1512 dnl libGL configuration per driver
1513 dnl
1514 if test "x$enable_glx" != xno; then
1515     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1516 fi
1517 case "x$enable_glx" in
1518 xxlib | xgallium-xlib)
1519     # Xlib-based GLX
1520     dri_modules="x11 xext xcb"
1521     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1522     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1523     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1524     GL_LIB_DEPS="$XLIBGL_LIBS"
1525     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1526     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1527     ;;
1528 xdri)
1529     # DRI-based GLX
1530
1531     # find the DRI deps for libGL
1532     dri_modules="x11 xext xdamage >= $XDAMAGE_REQUIRED xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1533
1534     if test x"$driglx_direct" = xyes; then
1535         if test x"$dri_platform" = xdrm ; then
1536             DEFINES="$DEFINES -DGLX_USE_DRM"
1537             require_libdrm "Direct rendering"
1538
1539             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1540             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1541             if test x"$enable_dri3" = xyes; then
1542                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1543                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1544             fi
1545
1546             if test x"$enable_dri" = xyes; then
1547                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1548             fi
1549
1550             if test x"$enable_dri3" = xyes; then
1551                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1552                dri3_modules="xcb xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1553                PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1554             fi
1555         fi
1556         if test x"$dri_platform" = xapple ; then
1557             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1558         fi
1559         if test x"$dri_platform" = xwindows ; then
1560             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1561         fi
1562     fi
1563
1564     # add xf86vidmode if available
1565     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1566     if test "$HAVE_XF86VIDMODE" = yes ; then
1567         dri_modules="$dri_modules xxf86vm"
1568     fi
1569
1570     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1571     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1572     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1573     GL_LIB_DEPS="$DRIGL_LIBS"
1574
1575     # need DRM libs, $PTHREAD_LIBS, etc.
1576     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1577     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1578     ;;
1579 esac
1580
1581 # This is outside the case (above) so that it is invoked even for non-GLX
1582 # builds.
1583 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1584
1585 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1586 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1587 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1588 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1589
1590 AC_SUBST([X11_INCLUDES])
1591 AC_SUBST([GL_LIB_DEPS])
1592 AC_SUBST([GL_PC_REQ_PRIV])
1593 AC_SUBST([GL_PC_LIB_PRIV])
1594 AC_SUBST([GL_PC_CFLAGS])
1595 AC_SUBST([DRI_PC_REQ_PRIV])
1596 AC_SUBST([GLESv1_CM_LIB_DEPS])
1597 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1598 AC_SUBST([GLESv2_LIB_DEPS])
1599 AC_SUBST([GLESv2_PC_LIB_PRIV])
1600
1601 AC_SUBST([HAVE_XF86VIDMODE])
1602
1603 dnl
1604 dnl More GLX setup
1605 dnl
1606 case "x$enable_glx" in
1607 xxlib | xgallium-xlib)
1608     DEFINES="$DEFINES -DUSE_XSHM"
1609     ;;
1610 xdri)
1611     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1612     if test "x$driglx_direct" = xyes; then
1613         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1614     fi
1615     ;;
1616 esac
1617
1618 dnl
1619 dnl TLS detection
1620 dnl
1621
1622 AC_ARG_ENABLE([glx-tls],
1623     [AS_HELP_STRING([--enable-glx-tls],
1624         [enable TLS support in GLX @<:@default=enabled@:>@])],
1625     [GLX_USE_TLS="$enableval"],
1626     [GLX_USE_TLS=yes])
1627 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1628
1629 if test "x$GLX_USE_TLS" = xyes; then
1630     DEFINES="$DEFINES -DGLX_USE_TLS"
1631 fi
1632
1633 dnl Read-only text section on x86 hardened platforms
1634 AC_ARG_ENABLE([glx-read-only-text],
1635     [AS_HELP_STRING([--enable-glx-read-only-text],
1636         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1637     [enable_glx_read_only_text="$enableval"],
1638     [enable_glx_read_only_text=no])
1639 if test "x$enable_glx_read_only_text" = xyes; then
1640     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1641 fi
1642
1643 dnl
1644 dnl More DRI setup
1645 dnl
1646 dnl Directory for DRI drivers
1647 AC_ARG_WITH([dri-driverdir],
1648     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1649         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1650     [DRI_DRIVER_INSTALL_DIR="$withval"],
1651     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1652 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1653 dnl Extra search path for DRI drivers
1654 AC_ARG_WITH([dri-searchpath],
1655     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1656         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1657     [DRI_DRIVER_SEARCH_DIR="$withval"],
1658     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1659 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1660 dnl Which drivers to build - default is chosen by platform
1661 AC_ARG_WITH([dri-drivers],
1662     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1663         [comma delimited classic DRI drivers list, e.g.
1664         "i915,i965,nouveau,radeon,r200,swrast" @<:@default=auto@:>@])],
1665     [with_dri_drivers="$withval"],
1666     [with_dri_drivers=auto])
1667
1668 if test "x$with_dri_drivers" = xauto; then
1669     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1670         with_dri_drivers="yes"
1671     else
1672         with_dri_drivers="no"
1673     fi
1674 fi
1675 if test "x$with_dri_drivers" = xno; then
1676     with_dri_drivers=''
1677 fi
1678
1679 dnl If $with_dri_drivers is yes, drivers will be added through
1680 dnl platform checks. Set DEFINES and LIB_DEPS
1681 if test "x$enable_dri" = xyes; then
1682     # Platform specific settings and drivers to build
1683     case "$host_os" in
1684     linux*)
1685         if test "x$enable_dri3" = xyes; then
1686             DEFINES="$DEFINES -DHAVE_DRI3"
1687         fi
1688
1689         case "$host_cpu" in
1690         powerpc* | sparc*)
1691             # Build only the drivers for cards that exist on PowerPC/sparc
1692             if test "x$with_dri_drivers" = "xyes"; then
1693                 with_dri_drivers="r200 radeon swrast"
1694             fi
1695             ;;
1696         esac
1697         ;;
1698     cygwin*)
1699         if test "x$with_dri_drivers" = "xyes"; then
1700             with_dri_drivers="swrast"
1701         fi
1702         ;;
1703     darwin*)
1704         DEFINES="$DEFINES -DBUILDING_MESA"
1705         if test "x$with_dri_drivers" = "xyes"; then
1706             with_dri_drivers="swrast"
1707         fi
1708         ;;
1709     esac
1710
1711     # default drivers
1712     if test "x$with_dri_drivers" = "xyes"; then
1713         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1714     fi
1715
1716     # Check for expat
1717     PKG_CHECK_MODULES([EXPAT], [expat], [],
1718         # expat version 2.0 and earlier do not provide expat.pc
1719         [AC_CHECK_HEADER([expat.h],[],
1720                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1721          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1722                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1723          EXPAT_LIBS="-lexpat"])
1724
1725     # put all the necessary libs together
1726     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1727 fi
1728
1729 AC_SUBST([DRI_LIB_DEPS])
1730
1731 DRI_DIRS=''
1732 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1733 if test -n "$with_dri_drivers"; then
1734     if test "x$enable_opengl" != xyes; then
1735         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1736     fi
1737
1738     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1739     for driver in $dri_drivers; do
1740         DRI_DIRS="$DRI_DIRS $driver"
1741         case "x$driver" in
1742         xi915)
1743             require_libdrm "i915"
1744             HAVE_I915_DRI=yes
1745             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1746             ;;
1747         xi965)
1748             require_libdrm "i965"
1749             HAVE_I965_DRI=yes
1750             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1751             ;;
1752         xnouveau)
1753             require_libdrm "nouveau"
1754             HAVE_NOUVEAU_DRI=yes
1755             PKG_CHECK_MODULES([NVVIEUX], [libdrm >= $LIBDRM_NVVIEUX_REQUIRED libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1756             ;;
1757         xradeon)
1758             require_libdrm "radeon"
1759             HAVE_RADEON_DRI=yes;
1760             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1761             ;;
1762         xr200)
1763             require_libdrm "r200"
1764             HAVE_R200_DRI=yes
1765             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1766             ;;
1767         xswrast)
1768             HAVE_SWRAST_DRI=yes
1769             ;;
1770         *)
1771             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1772             ;;
1773         esac
1774     done
1775     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1776 fi
1777
1778
1779 dnl
1780 dnl Gallium LLVM
1781 dnl Deprecated: kept for backwards compatibility
1782 dnl
1783 AC_ARG_ENABLE([gallium-llvm],
1784     [AS_HELP_STRING([--enable-gallium-llvm],
1785         [DEPRECATED: use --enable-llvm instead])],
1786     [enable_gallium_llvm="$enableval"],
1787     [enable_gallium_llvm=auto])
1788
1789 if test "x$enable_gallium_llvm" != xauto; then
1790    AC_MSG_WARN([The --enable-gallium-llvm option has been deprecated. Use --enable-llvm instead.])
1791    enable_llvm=$enable_gallium_llvm
1792 fi
1793
1794 dnl
1795 dnl LLVM
1796 dnl
1797 AC_ARG_ENABLE([llvm],
1798     [AS_HELP_STRING([--enable-llvm],
1799         [build with LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1800     [enable_llvm="$enableval"],
1801     [enable_llvm=auto])
1802
1803 if test "x$enable_llvm" = xauto -a "x$FOUND_LLVM" = xyes; then
1804     if test "x$FOUND_LLVM" = xyes; then
1805         case "$host_cpu" in
1806         i*86|x86_64|amd64) enable_llvm=yes;;
1807         *) enable_llvm=no;;
1808         esac
1809     else
1810         enable_llvm=no
1811     fi
1812 fi
1813
1814 if test "x$enable_llvm" = xyes -a "x$FOUND_LLVM" = xno; then
1815     AC_MSG_ERROR([--enable-llvm selected but llvm-config is not found])
1816 fi
1817
1818 #
1819 # Vulkan driver configuration
1820 #
1821
1822 AC_ARG_WITH([vulkan-drivers],
1823     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
1824         [comma delimited Vulkan drivers list, e.g.
1825         "intel,radeon"
1826         @<:@default=no@:>@])],
1827     [with_vulkan_drivers="$withval"],
1828     [with_vulkan_drivers="no"])
1829
1830 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
1831 # here so that the script doesn't choke on an unknown driver name later.
1832 case "x$with_vulkan_drivers" in
1833     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
1834     xno) with_vulkan_drivers='' ;;
1835 esac
1836
1837 AC_ARG_WITH([vulkan-icddir],
1838     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
1839         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
1840     [VULKAN_ICD_INSTALL_DIR="$withval"],
1841     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
1842 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
1843
1844 if test -n "$with_vulkan_drivers"; then
1845     if test "x$ac_cv_func_dl_iterate_phdr" = xno; then
1846         AC_MSG_ERROR([Vulkan drivers require the dl_iterate_phdr function])
1847     fi
1848
1849     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
1850     for driver in $VULKAN_DRIVERS; do
1851         case "x$driver" in
1852         xintel)
1853             require_libdrm "ANV"
1854             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1855             HAVE_INTEL_VULKAN=yes
1856             ;;
1857         xradeon)
1858             require_libdrm "radv"
1859             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
1860             radeon_llvm_check $LLVM_REQUIRED_RADV "radv"
1861             HAVE_RADEON_VULKAN=yes
1862             ;;
1863         *)
1864             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
1865             ;;
1866         esac
1867     done
1868     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
1869 fi
1870
1871
1872 DEFINES="$DEFINES -DENABLE_SHADER_CACHE"
1873 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1874 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
1875                                   "x$enable_osmesa" = xyes -o \
1876                                   -n "$DRI_DIRS")
1877
1878 dnl
1879 dnl OSMesa configuration
1880 dnl
1881
1882 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1883 AC_ARG_WITH([osmesa-bits],
1884     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1885         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1886     [osmesa_bits="$withval"],
1887     [osmesa_bits=8])
1888 if test "x$osmesa_bits" != x8; then
1889     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
1890         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1891         osmesa_bits=8
1892     fi
1893 fi
1894 case "x$osmesa_bits" in
1895 x8)
1896     OSMESA_LIB="${OSMESA_LIB}"
1897     ;;
1898 x16|x32)
1899     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1900     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1901     ;;
1902 *)
1903     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1904     ;;
1905 esac
1906
1907 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1908     # only link libraries with osmesa if shared
1909     if test "$enable_static" = no; then
1910         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1911     else
1912         OSMESA_LIB_DEPS=""
1913     fi
1914     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1915 fi
1916
1917 AC_SUBST([OSMESA_LIB_DEPS])
1918 AC_SUBST([OSMESA_PC_REQ])
1919 AC_SUBST([OSMESA_PC_LIB_PRIV])
1920
1921 dnl
1922 dnl gbm configuration
1923 dnl
1924 if test "x$enable_gbm" = xyes; then
1925     require_dri_shared_libs_and_glapi "gbm"
1926 fi
1927 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1928 # FINISHME: GBM has a number of dependencies which we should add below
1929 GBM_PC_REQ_PRIV=""
1930 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1931 AC_SUBST([GBM_PC_REQ_PRIV])
1932 AC_SUBST([GBM_PC_LIB_PRIV])
1933
1934 dnl
1935 dnl EGL configuration
1936 dnl
1937
1938 if test "x$enable_egl" = xyes; then
1939     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1940
1941     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1942
1943     require_dri_shared_libs_and_glapi "egl"
1944 fi
1945 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1946 AC_SUBST([EGL_LIB_DEPS])
1947
1948 gallium_st="mesa"
1949
1950 dnl
1951 dnl XA configuration
1952 dnl
1953 if test "x$enable_xa" = xyes; then
1954     if test "x$with_gallium_drivers" = xswrast; then
1955        AC_MSG_ERROR([
1956           Building xa requires at least one non swrast gallium driver.
1957           If you are looking to use libxatracker.so with the VMware driver,
1958           make sure to include svga in the gallium drivers list, apart from
1959           enabling XA.
1960           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1961     fi
1962     gallium_st="$gallium_st xa"
1963 fi
1964 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1965
1966 dnl
1967 dnl Gallium G3DVL configuration
1968 dnl
1969 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1970     if test "x$enable_xvmc" = xauto; then
1971         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1972     fi
1973
1974     if test "x$enable_vdpau" = xauto; then
1975         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1976     fi
1977
1978     if test "x$enable_omx" = xauto; then
1979         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1980     fi
1981
1982     if test "x$enable_va" = xauto; then
1983         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1984     fi
1985 fi
1986
1987 if test "x$enable_dri" = xyes -o \
1988         "x$enable_xvmc" = xyes -o \
1989         "x$enable_vdpau" = xyes -o \
1990         "x$enable_omx" = xyes -o \
1991         "x$enable_va" = xyes; then
1992     need_gallium_vl=yes
1993 fi
1994 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1995
1996 if test "x$enable_xvmc" = xyes -o \
1997         "x$enable_vdpau" = xyes -o \
1998         "x$enable_omx" = xyes -o \
1999         "x$enable_va" = xyes; then
2000     if test x"$enable_dri3" = xyes; then
2001         PKG_CHECK_MODULES([VL], [xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED
2002                                  xcb-xfixes x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2003     else
2004         PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2005     fi
2006     need_gallium_vl_winsys=yes
2007 fi
2008 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
2009
2010 if test "x$enable_xvmc" = xyes; then
2011     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
2012     gallium_st="$gallium_st xvmc"
2013 fi
2014 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
2015
2016 if test "x$enable_vdpau" = xyes; then
2017     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
2018     gallium_st="$gallium_st vdpau"
2019     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
2020 fi
2021 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
2022
2023 if test "x$enable_omx" = xyes; then
2024     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
2025     gallium_st="$gallium_st omx"
2026 fi
2027 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
2028
2029 if test "x$enable_va" = xyes; then
2030     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
2031     gallium_st="$gallium_st va"
2032 fi
2033 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
2034
2035 dnl
2036 dnl Nine Direct3D9 configuration
2037 dnl
2038 if test "x$enable_nine" = xyes; then
2039     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
2040         AC_MSG_ERROR([nine requires the gallium swrast driver])
2041     fi
2042     if test "x$with_gallium_drivers" = xswrast; then
2043         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
2044     fi
2045     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
2046         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
2047     fi
2048
2049     if test "x$enable_dri3" = xno; then
2050         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
2051     fi
2052
2053     gallium_st="$gallium_st nine"
2054 fi
2055 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
2056
2057 dnl
2058 dnl OpenCL configuration
2059 dnl
2060
2061 AC_ARG_WITH([clang-libdir],
2062    [AS_HELP_STRING([--with-clang-libdir],
2063          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
2064    [CLANG_LIBDIR="$withval"],
2065    [CLANG_LIBDIR=''])
2066
2067 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
2068
2069 if test "x$enable_opencl" = xyes; then
2070     if test -z "$with_gallium_drivers"; then
2071         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
2072     fi
2073
2074     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
2075         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
2076     fi
2077
2078     if test "x$have_libclc" = xno; then
2079         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
2080                     Make sure the directory containing libclc.pc is specified in your
2081                     PKG_CONFIG_PATH environment variable.
2082                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
2083     else
2084         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
2085         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
2086         AC_SUBST([LIBCLC_INCLUDEDIR])
2087         AC_SUBST([LIBCLC_LIBEXECDIR])
2088     fi
2089
2090     gallium_st="$gallium_st clover"
2091
2092     if test "x$enable_opencl_icd" = xyes; then
2093         OPENCL_LIBNAME="MesaOpenCL"
2094     else
2095         OPENCL_LIBNAME="OpenCL"
2096     fi
2097
2098     if test "x$have_libelf" != xyes; then
2099        AC_MSG_ERROR([Clover requires libelf])
2100     fi
2101
2102     if test "x${ac_cv_cxx_compiler_gnu}" = xyes; then
2103         altivec_enabled=no
2104         AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2105         #if !defined(__VEC__) || !defined(__ALTIVEC__)
2106         #error "AltiVec not enabled"
2107         #endif
2108         ])], altivec_enabled=yes)
2109
2110         if test "$altivec_enabled" = yes; then
2111             CLOVER_STD_OVERRIDE="-std=gnu++11"
2112         fi
2113         AC_SUBST([CLOVER_STD_OVERRIDE])
2114     fi
2115
2116     llvm_require_version $LLVM_REQUIRED_OPENCL "opencl"
2117
2118     llvm_add_default_components "opencl"
2119     llvm_add_component "all-targets" "opencl"
2120     llvm_add_component "linker" "opencl"
2121     llvm_add_component "instrumentation" "opencl"
2122     llvm_add_component "ipo" "opencl"
2123     llvm_add_component "irreader" "opencl"
2124     llvm_add_component "option" "opencl"
2125     llvm_add_component "objcarcopts" "opencl"
2126     llvm_add_component "profiledata" "opencl"
2127
2128     dnl Check for Clang internal headers
2129     if test -z "$CLANG_LIBDIR"; then
2130         CLANG_LIBDIR=${LLVM_LIBDIR}
2131     fi
2132     CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2133     AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2134         [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2135 fi
2136 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2137 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2138 AC_SUBST([OPENCL_LIBNAME])
2139 AC_SUBST([CLANG_RESOURCE_DIR])
2140
2141 dnl
2142 dnl Gallium configuration
2143 dnl
2144 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2145
2146 dnl
2147 dnl EGL Platforms configuration
2148 dnl
2149 AC_ARG_WITH([egl-platforms],
2150     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
2151         [comma delimited native platforms libEGL supports, e.g.
2152         "x11,drm" @<:@default=auto@:>@])],
2153     [with_egl_platforms="$withval"],
2154     [if test "x$enable_egl" = xyes; then
2155         if test "x$enable_gbm" = xyes; then
2156            with_egl_platforms="x11,drm"
2157         else
2158            with_egl_platforms="x11"
2159         fi
2160     else
2161         with_egl_platforms=""
2162     fi])
2163
2164 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
2165     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
2166 fi
2167
2168 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
2169         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
2170         WAYLAND_SCANNER='')
2171 if test "x$WAYLAND_SCANNER" = x; then
2172     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner], [:])
2173 fi
2174
2175 # Do per-EGL platform setups and checks
2176 egl_platforms=`IFS=', '; echo $with_egl_platforms`
2177 for plat in $egl_platforms; do
2178         case "$plat" in
2179         wayland)
2180
2181                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
2182
2183                 if test "x$WAYLAND_SCANNER" = "x:"; then
2184                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
2185                 fi
2186                 ;;
2187
2188         x11)
2189                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
2190                 ;;
2191
2192         drm)
2193                 test "x$enable_gbm" = "xno" &&
2194                         AC_MSG_ERROR([EGL platform drm needs gbm])
2195                 ;;
2196
2197         surfaceless)
2198                 ;;
2199
2200         android)
2201                 PKG_CHECK_MODULES([ANDROID], [cutils hardware sync])
2202                 ;;
2203
2204         *)
2205                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
2206                 ;;
2207         esac
2208
2209         case "$plat" in
2210         wayland|drm|surfaceless)
2211                 require_libdrm "Platform $plat"
2212                 ;;
2213         esac
2214 done
2215
2216 # libEGL wants to default to the first platform specified in
2217 # ./configure.  parse that here.
2218 if test "x$egl_platforms" != "x"; then
2219     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2220     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2221 else
2222     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2223 fi
2224
2225 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
2226 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
2227 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
2228 AM_CONDITIONAL(HAVE_EGL_PLATFORM_SURFACELESS, echo "$egl_platforms" | grep -q 'surfaceless')
2229 AM_CONDITIONAL(HAVE_EGL_PLATFORM_ANDROID, echo "$egl_platforms" | grep -q 'android')
2230
2231 AC_SUBST([EGL_NATIVE_PLATFORM])
2232 AC_SUBST([EGL_CFLAGS])
2233
2234 # If we don't have the X11 platform, set this define so we don't try to include
2235 # the X11 headers.
2236 if ! echo "$egl_platforms" | grep -q 'x11'; then
2237     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2238     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2239 fi
2240
2241 dnl Directory for XVMC libs
2242 AC_ARG_WITH([xvmc-libdir],
2243     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2244         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2245     [XVMC_LIB_INSTALL_DIR="$withval"],
2246     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2247 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2248
2249 dnl
2250 dnl Gallium Tests
2251 dnl
2252 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2253
2254 dnl Directory for VDPAU libs
2255 AC_ARG_WITH([vdpau-libdir],
2256     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2257         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2258     [VDPAU_LIB_INSTALL_DIR="$withval"],
2259     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2260 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2261
2262 dnl Directory for OMX libs
2263
2264 AC_ARG_WITH([omx-libdir],
2265     [AS_HELP_STRING([--with-omx-libdir=DIR],
2266         [directory for the OMX libraries])],
2267     [OMX_LIB_INSTALL_DIR="$withval"],
2268     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --exists libomxil-bellagio && \
2269                           $PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2270 AC_SUBST([OMX_LIB_INSTALL_DIR])
2271
2272 dnl Directory for VA libs
2273
2274 AC_ARG_WITH([va-libdir],
2275     [AS_HELP_STRING([--with-va-libdir=DIR],
2276         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2277     [VA_LIB_INSTALL_DIR="$withval"],
2278     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2279 AC_SUBST([VA_LIB_INSTALL_DIR])
2280
2281 AC_ARG_WITH([d3d-libdir],
2282     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2283         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2284     [D3D_DRIVER_INSTALL_DIR="$withval"],
2285     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2286 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2287
2288 dnl
2289 dnl r300 doesn't strictly require LLVM, but for performance reasons we
2290 dnl highly recommend LLVM usage. So require it at least on x86 and x86_64
2291 dnl architectures.
2292 dnl
2293 r300_require_llvm() {
2294     case "$host" in *gnux32) return;; esac
2295     case "$host_cpu" in
2296     i*86|x86_64|amd64) require_llvm $1
2297         ;;
2298     esac
2299 }
2300
2301 dnl
2302 dnl DRM is needed by X, Wayland, and offscreen rendering.
2303 dnl Surfaceless is an alternative for the last one.
2304 dnl
2305 require_basic_egl() {
2306     case "$with_egl_platforms" in
2307         *drm*|*surfaceless*)
2308             ;;
2309         *)
2310             AC_MSG_ERROR([$1 requires one of these:
2311                   1) --with-egl-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2312                   2) --with-egl-platforms=surfaceless (offscreen only)
2313                   Recommended options: drm,x11])
2314             ;;
2315     esac
2316 }
2317
2318 swr_require_cxx_feature_flags() {
2319     feature_name="$1"
2320     preprocessor_test="$2"
2321     option_list="$3"
2322     output_var="$4"
2323
2324     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2325     AC_LANG_PUSH([C++])
2326     save_CXXFLAGS="$CXXFLAGS"
2327     save_IFS="$IFS"
2328     IFS=","
2329     found=0
2330     for opts in $option_list
2331     do
2332         unset IFS
2333         CXXFLAGS="$opts $save_CXXFLAGS"
2334         AC_COMPILE_IFELSE(
2335             [AC_LANG_PROGRAM(
2336                 [   #if !($preprocessor_test)
2337                     #error
2338                     #endif
2339                 ])],
2340             [found=1; break],
2341             [])
2342         IFS=","
2343     done
2344     IFS="$save_IFS"
2345     CXXFLAGS="$save_CXXFLAGS"
2346     AC_LANG_POP([C++])
2347     if test $found -eq 1; then
2348         AC_MSG_RESULT([$opts])
2349         eval "$output_var=\$opts"
2350         return 0
2351     fi
2352     AC_MSG_RESULT([no])
2353     AC_MSG_ERROR([swr requires $feature_name support])
2354     return 1
2355 }
2356
2357 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2358 if test -n "$with_gallium_drivers"; then
2359     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2360     for driver in $gallium_drivers; do
2361         case "x$driver" in
2362         xsvga)
2363             HAVE_GALLIUM_SVGA=yes
2364             require_libdrm "svga"
2365             ;;
2366         xi915)
2367             HAVE_GALLIUM_I915=yes
2368             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2369             require_libdrm "Gallium i915"
2370             ;;
2371         xr300)
2372             HAVE_GALLIUM_R300=yes
2373             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2374             require_libdrm "r300"
2375             r300_require_llvm "r300"
2376             ;;
2377         xr600)
2378             HAVE_GALLIUM_R600=yes
2379             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2380             require_libdrm "r600"
2381             if test "x$enable_llvm" = xyes; then
2382                 radeon_llvm_check $LLVM_REQUIRED_R600 "r600"
2383
2384                 llvm_add_component "asmparser" "r600"
2385                 llvm_add_component "bitreader" "r600"
2386             fi
2387             ;;
2388         xradeonsi)
2389             HAVE_GALLIUM_RADEONSI=yes
2390             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2391             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2392             require_libdrm "radeonsi"
2393             radeon_llvm_check $LLVM_REQUIRED_RADEONSI "radeonsi"
2394             if test "x$enable_egl" = xyes; then
2395                 require_basic_egl "radeonsi"
2396             fi
2397             ;;
2398         xnouveau)
2399             HAVE_GALLIUM_NOUVEAU=yes
2400             PKG_CHECK_MODULES([NOUVEAU], [libdrm >= $LIBDRM_NOUVEAU_REQUIRED libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2401             require_libdrm "nouveau"
2402             ;;
2403         xfreedreno)
2404             HAVE_GALLIUM_FREEDRENO=yes
2405             PKG_CHECK_MODULES([FREEDRENO], [libdrm >= $LIBDRM_FREEDRENO_REQUIRED libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2406             require_libdrm "freedreno"
2407             ;;
2408         xetnaviv)
2409             HAVE_GALLIUM_ETNAVIV=yes
2410             PKG_CHECK_MODULES([ETNAVIV], [libdrm >= $LIBDRM_ETNAVIV_REQUIRED libdrm_etnaviv >= $LIBDRM_ETNAVIV_REQUIRED])
2411             require_libdrm "etnaviv"
2412             ;;
2413        ximx)
2414             HAVE_GALLIUM_IMX=yes
2415             ;;
2416         xswrast)
2417             HAVE_GALLIUM_SOFTPIPE=yes
2418             if test "x$enable_llvm" = xyes; then
2419                 HAVE_GALLIUM_LLVMPIPE=yes
2420             fi
2421             ;;
2422         xswr)
2423             llvm_require_version $LLVM_REQUIRED_SWR "swr"
2424
2425             swr_require_cxx_feature_flags "C++14" "__cplusplus >= 201402L" \
2426                 "-std=c++14" \
2427                 SWR_CXX14_CXXFLAGS
2428             AC_SUBST([SWR_CXX14_CXXFLAGS])
2429
2430             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2431                 ",-mavx,-march=core-avx" \
2432                 SWR_AVX_CXXFLAGS
2433             AC_SUBST([SWR_AVX_CXXFLAGS])
2434
2435             swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2436                 ",-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2" \
2437                 SWR_AVX2_CXXFLAGS
2438             AC_SUBST([SWR_AVX2_CXXFLAGS])
2439
2440             HAVE_GALLIUM_SWR=yes
2441             ;;
2442         xvc4)
2443             HAVE_GALLIUM_VC4=yes
2444             PKG_CHECK_MODULES([VC4], [libdrm >= $LIBDRM_VC4_REQUIRED libdrm_vc4 >= $LIBDRM_VC4_REQUIRED])
2445             require_libdrm "vc4"
2446
2447             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2448                               [USE_VC4_SIMULATOR=yes;
2449                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2450                               [USE_VC4_SIMULATOR=no])
2451             ;;
2452         xvirgl)
2453             HAVE_GALLIUM_VIRGL=yes
2454             require_libdrm "virgl"
2455             require_basic_egl "virgl"
2456             ;;
2457         *)
2458             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2459             ;;
2460         esac
2461     done
2462 fi
2463
2464 if test "x$enable_llvm" = "xyes" -a "$with_gallium_drivers"; then
2465     llvm_require_version $LLVM_REQUIRED_GALLIUM "gallium"
2466     llvm_add_default_components "gallium"
2467 fi
2468
2469 dnl We need to validate some needed dependencies for renderonly drivers.
2470
2471 if test "x$HAVE_GALLIUM_ETNAVIV" != xyes -a "x$HAVE_GALLIUM_IMX" = xyes  ; then
2472     AC_MSG_ERROR([Building with imx requires etnaviv])
2473 fi
2474
2475 dnl
2476 dnl Set defines and buildtime variables only when using LLVM.
2477 dnl
2478 if test "x$enable_llvm" = xyes; then
2479     DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2480
2481     LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2482     LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
2483     LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2484
2485     dnl Set LLVM_LIBS - This is done after the driver configuration so
2486     dnl that drivers can add additional components to LLVM_COMPONENTS.
2487     dnl Previously, gallium drivers were updating LLVM_LIBS directly
2488     dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2489     dnl this was causing the same libraries to be appear multiple times
2490     dnl in LLVM_LIBS.
2491
2492     if ! $LLVM_CONFIG --libs ${LLVM_COMPONENTS} >/dev/null; then
2493        AC_MSG_ERROR([Calling ${LLVM_CONFIG} failed])
2494     fi
2495     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2496
2497     dnl llvm-config may not give the right answer when llvm is a built as a
2498     dnl single shared library, so we must work the library name out for
2499     dnl ourselves.
2500     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2501     if test "x$enable_llvm_shared_libs" = xyes; then
2502         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2503         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2504         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2505
2506         if test "x$llvm_have_one_so" = xyes; then
2507             dnl LLVM was built using auto*, so there is only one shared object.
2508             LLVM_LIBS="-l$LLVM_SO_NAME"
2509         else
2510             dnl If LLVM was built with CMake, there will be one shared object per
2511             dnl component.
2512             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2513                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2514         Please make sure you have built llvm with the --enable-shared option
2515         and that your llvm libraries are installed in $LLVM_LIBDIR
2516         If you have installed your llvm libraries to a different directory you
2517         can use the --with-llvm-prefix= configure flag to specify this directory.
2518         NOTE: Mesa is attempting to use llvm shared libraries by default.
2519         If you do not want to build with llvm shared libraries and instead want to
2520         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2521         invocation and rebuild.])])
2522
2523            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2524            dnl install uses a shared object for each component and we have
2525            dnl already added all of these objects to LLVM_LIBS.
2526         fi
2527     else
2528         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2529         dnl We need to link to llvm system libs when using static libs
2530         dnl However, only llvm 3.5+ provides --system-libs
2531         if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2532             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2533         fi
2534     fi
2535 fi
2536
2537 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2538 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2539 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2540 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2541 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2542 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2543                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2544 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2545 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2546 AM_CONDITIONAL(HAVE_GALLIUM_ETNAVIV, test "x$HAVE_GALLIUM_ETNAVIV" = xyes)
2547 AM_CONDITIONAL(HAVE_GALLIUM_IMX, test "x$HAVE_GALLIUM_IMX" = xyes)
2548 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2549 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2550 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2551 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2552                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2553                                          "x$HAVE_GALLIUM_SWR" = xyes)
2554 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2555 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2556
2557 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2558
2559 if test "x$enable_dri" = xyes; then
2560     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2561 fi
2562
2563 if test "x$have_drisw_kms" = xyes; then
2564     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2565 fi
2566 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2567
2568 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2569 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2570 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2571 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2572 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2573 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2574
2575 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2576 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2577
2578 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_R600" = xyes -o \
2579                                       "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2580                                       "x$HAVE_RADEON_VULKAN" = xyes)
2581
2582 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2583                                         "x$HAVE_I965_DRI" = xyes)
2584
2585 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2586                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2587                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2588 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2589 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2590 AM_CONDITIONAL(HAVE_GALLIUM_LLVM, test "x$enable_llvm" = xyes)
2591 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2592
2593 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2594 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2595 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2596 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
2597                                         "x$enable_gallium_osmesa" = xyes)
2598
2599 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2600 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2601 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2602
2603 AC_SUBST([NINE_MAJOR], 1)
2604 AC_SUBST([NINE_MINOR], 0)
2605 AC_SUBST([NINE_TINY], 0)
2606 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2607
2608 AC_SUBST([VDPAU_MAJOR], 1)
2609 AC_SUBST([VDPAU_MINOR], 0)
2610
2611 if test "x$enable_va" = xyes; then
2612     VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2613     VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2614 fi
2615 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2616 AC_SUBST([VA_MINOR], $VA_MINOR)
2617
2618 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
2619
2620 AC_SUBST([XVMC_MAJOR], 1)
2621 AC_SUBST([XVMC_MINOR], 0)
2622
2623 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2624 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2625 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2626 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2627
2628 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2629 AC_SUBST([XA_MINOR], $XA_MINOR)
2630 AC_SUBST([XA_TINY], $XA_TINY)
2631 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2632
2633 AC_ARG_ENABLE(valgrind,
2634               [AS_HELP_STRING([--enable-valgrind],
2635                              [Build mesa with valgrind support (default: auto)])],
2636                              [VALGRIND=$enableval], [VALGRIND=auto])
2637 if test "x$VALGRIND" != xno; then
2638         PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2639 fi
2640 AC_MSG_CHECKING([whether to enable Valgrind support])
2641 if test "x$VALGRIND" = xauto; then
2642         VALGRIND="$have_valgrind"
2643 fi
2644
2645 if test "x$VALGRIND" = "xyes"; then
2646         if ! test "x$have_valgrind" = xyes; then
2647                 AC_MSG_ERROR([Valgrind support required but not present])
2648         fi
2649         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2650 fi
2651
2652 AC_MSG_RESULT([$VALGRIND])
2653
2654 dnl Restore LDFLAGS and CPPFLAGS
2655 LDFLAGS="$_SAVE_LDFLAGS"
2656 CPPFLAGS="$_SAVE_CPPFLAGS"
2657
2658 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2659 if test "x$acv_mesa_CLANG" = xyes; then
2660     CFLAGS="$CFLAGS -Qunused-arguments"
2661     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2662 fi
2663
2664 dnl Add user CFLAGS and CXXFLAGS
2665 CFLAGS="$CFLAGS $USER_CFLAGS"
2666 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2667
2668 dnl Substitute the config
2669 AC_CONFIG_FILES([Makefile
2670                 src/Makefile
2671                 src/amd/Makefile
2672                 src/amd/vulkan/Makefile
2673                 src/compiler/Makefile
2674                 src/egl/Makefile
2675                 src/egl/main/egl.pc
2676                 src/egl/wayland/wayland-drm/Makefile
2677                 src/egl/wayland/wayland-egl/Makefile
2678                 src/egl/wayland/wayland-egl/wayland-egl.pc
2679                 src/gallium/Makefile
2680                 src/gallium/auxiliary/Makefile
2681                 src/gallium/auxiliary/pipe-loader/Makefile
2682                 src/gallium/drivers/freedreno/Makefile
2683                 src/gallium/drivers/ddebug/Makefile
2684                 src/gallium/drivers/i915/Makefile
2685                 src/gallium/drivers/llvmpipe/Makefile
2686                 src/gallium/drivers/noop/Makefile
2687                 src/gallium/drivers/nouveau/Makefile
2688                 src/gallium/drivers/r300/Makefile
2689                 src/gallium/drivers/r600/Makefile
2690                 src/gallium/drivers/radeon/Makefile
2691                 src/gallium/drivers/radeonsi/Makefile
2692                 src/gallium/drivers/rbug/Makefile
2693                 src/gallium/drivers/softpipe/Makefile
2694                 src/gallium/drivers/svga/Makefile
2695                 src/gallium/drivers/swr/Makefile
2696                 src/gallium/drivers/trace/Makefile
2697                 src/gallium/drivers/etnaviv/Makefile
2698                 src/gallium/drivers/imx/Makefile
2699                 src/gallium/drivers/vc4/Makefile
2700                 src/gallium/drivers/virgl/Makefile
2701                 src/gallium/state_trackers/clover/Makefile
2702                 src/gallium/state_trackers/dri/Makefile
2703                 src/gallium/state_trackers/glx/xlib/Makefile
2704                 src/gallium/state_trackers/nine/Makefile
2705                 src/gallium/state_trackers/omx/Makefile
2706                 src/gallium/state_trackers/osmesa/Makefile
2707                 src/gallium/state_trackers/va/Makefile
2708                 src/gallium/state_trackers/vdpau/Makefile
2709                 src/gallium/state_trackers/xa/Makefile
2710                 src/gallium/state_trackers/xvmc/Makefile
2711                 src/gallium/targets/d3dadapter9/Makefile
2712                 src/gallium/targets/d3dadapter9/d3d.pc
2713                 src/gallium/targets/dri/Makefile
2714                 src/gallium/targets/libgl-xlib/Makefile
2715                 src/gallium/targets/omx/Makefile
2716                 src/gallium/targets/opencl/Makefile
2717                 src/gallium/targets/opencl/mesa.icd
2718                 src/gallium/targets/osmesa/Makefile
2719                 src/gallium/targets/osmesa/osmesa.pc
2720                 src/gallium/targets/pipe-loader/Makefile
2721                 src/gallium/targets/va/Makefile
2722                 src/gallium/targets/vdpau/Makefile
2723                 src/gallium/targets/xa/Makefile
2724                 src/gallium/targets/xa/xatracker.pc
2725                 src/gallium/targets/xvmc/Makefile
2726                 src/gallium/tests/trivial/Makefile
2727                 src/gallium/tests/unit/Makefile
2728                 src/gallium/winsys/etnaviv/drm/Makefile
2729                 src/gallium/winsys/imx/drm/Makefile
2730                 src/gallium/winsys/freedreno/drm/Makefile
2731                 src/gallium/winsys/i915/drm/Makefile
2732                 src/gallium/winsys/nouveau/drm/Makefile
2733                 src/gallium/winsys/radeon/drm/Makefile
2734                 src/gallium/winsys/amdgpu/drm/Makefile
2735                 src/gallium/winsys/svga/drm/Makefile
2736                 src/gallium/winsys/sw/dri/Makefile
2737                 src/gallium/winsys/sw/kms-dri/Makefile
2738                 src/gallium/winsys/sw/null/Makefile
2739                 src/gallium/winsys/sw/wrapper/Makefile
2740                 src/gallium/winsys/sw/xlib/Makefile
2741                 src/gallium/winsys/vc4/drm/Makefile
2742                 src/gallium/winsys/virgl/drm/Makefile
2743                 src/gallium/winsys/virgl/vtest/Makefile
2744                 src/gbm/Makefile
2745                 src/gbm/main/gbm.pc
2746                 src/glx/Makefile
2747                 src/glx/apple/Makefile
2748                 src/glx/tests/Makefile
2749                 src/glx/windows/Makefile
2750                 src/glx/windows/windowsdriproto.pc
2751                 src/gtest/Makefile
2752                 src/intel/Makefile
2753                 src/loader/Makefile
2754                 src/mapi/Makefile
2755                 src/mapi/es1api/glesv1_cm.pc
2756                 src/mapi/es2api/glesv2.pc
2757                 src/mapi/glapi/gen/Makefile
2758                 src/mesa/Makefile
2759                 src/mesa/gl.pc
2760                 src/mesa/drivers/dri/dri.pc
2761                 src/mesa/drivers/dri/common/Makefile
2762                 src/mesa/drivers/dri/common/xmlpool/Makefile
2763                 src/mesa/drivers/dri/i915/Makefile
2764                 src/mesa/drivers/dri/i965/Makefile
2765                 src/mesa/drivers/dri/Makefile
2766                 src/mesa/drivers/dri/nouveau/Makefile
2767                 src/mesa/drivers/dri/r200/Makefile
2768                 src/mesa/drivers/dri/radeon/Makefile
2769                 src/mesa/drivers/dri/swrast/Makefile
2770                 src/mesa/drivers/osmesa/Makefile
2771                 src/mesa/drivers/osmesa/osmesa.pc
2772                 src/mesa/drivers/x11/Makefile
2773                 src/mesa/main/tests/Makefile
2774                 src/util/Makefile
2775                 src/util/tests/hash_table/Makefile
2776                 src/vulkan/Makefile])
2777
2778 AC_OUTPUT
2779
2780 # Fix up dependencies in *.Plo files, where we changed the extension of a
2781 # source file
2782 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
2783
2784
2785 dnl
2786 dnl Output some configuration info for the user
2787 dnl
2788 echo ""
2789 echo "        prefix:          $prefix"
2790 echo "        exec_prefix:     $exec_prefix"
2791 echo "        libdir:          $libdir"
2792 echo "        includedir:      $includedir"
2793
2794 dnl API info
2795 echo ""
2796 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2797
2798 dnl Driver info
2799 echo ""
2800 case "x$enable_osmesa$enable_gallium_osmesa" in
2801 xnoyes)
2802         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2803         ;;
2804 xyesno)
2805         echo "        OSMesa:          lib$OSMESA_LIB"
2806         ;;
2807 xnono)
2808         echo "        OSMesa:          no"
2809         ;;
2810 esac
2811
2812 echo ""
2813 if test "x$enable_dri" != xno; then
2814         echo "        DRI platform:    $dri_platform"
2815         if test -z "$DRI_DIRS"; then
2816             echo "        DRI drivers:     no"
2817         else
2818             echo "        DRI drivers:     $DRI_DIRS"
2819         fi
2820         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2821 fi
2822
2823 case "x$enable_glx" in
2824 xdri)
2825     echo "        GLX:             DRI-based"
2826     ;;
2827 xxlib)
2828     echo "        GLX:             Xlib-based"
2829     ;;
2830 xgallium-xlib)
2831     echo "        GLX:             Xlib-based (Gallium)"
2832     ;;
2833 *)
2834     echo "        GLX:             $enable_glx"
2835     ;;
2836 esac
2837
2838 dnl EGL
2839 echo ""
2840 echo "        EGL:             $enable_egl"
2841 if test "$enable_egl" = yes; then
2842     echo "        EGL platforms:   $egl_platforms"
2843
2844     egl_drivers=""
2845     if test "x$enable_dri" != "xno"; then
2846         egl_drivers="$egl_drivers builtin:egl_dri2"
2847     fi
2848     if test "x$enable_dri3" != "xno"; then
2849         egl_drivers="$egl_drivers builtin:egl_dri3"
2850     fi
2851
2852     echo "        EGL drivers:    $egl_drivers"
2853 fi
2854 if test "x$enable_gbm" = xyes; then
2855     echo "        GBM:             yes"
2856 else
2857     echo "        GBM:             no"
2858 fi
2859
2860 # Vulkan
2861 echo ""
2862 if test "x$VULKAN_DRIVERS" != x; then
2863     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
2864     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
2865 else
2866     echo "        Vulkan drivers:  no"
2867 fi
2868
2869 echo ""
2870 if test "x$enable_llvm" = xyes; then
2871     echo "        llvm:            yes"
2872     echo "        llvm-config:     $LLVM_CONFIG"
2873     echo "        llvm-version:    $LLVM_VERSION"
2874 else
2875     echo "        llvm:            no"
2876 fi
2877
2878 echo ""
2879 if test -n "$with_gallium_drivers"; then
2880     echo "        Gallium drivers: $gallium_drivers"
2881     echo "        Gallium st:      $gallium_st"
2882 else
2883     echo "        Gallium:         no"
2884 fi
2885
2886 echo ""
2887 if test "x$enable_gallium_extra_hud" != xyes; then
2888     echo "        HUD extra stats: no"
2889 else
2890     echo "        HUD extra stats: yes"
2891 fi
2892
2893 if test "x$enable_lmsensors" != xyes; then
2894     echo "        HUD lmsensors:   no"
2895 else
2896     echo "        HUD lmsensors:   yes"
2897 fi
2898
2899 dnl Libraries
2900 echo ""
2901 echo "        Shared libs:     $enable_shared"
2902 echo "        Static libs:     $enable_static"
2903 echo "        Shared-glapi:    $enable_shared_glapi"
2904
2905 dnl Compiler options
2906 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2907 cflags=`echo $CFLAGS | \
2908     $SED 's/^ *//;s/  */ /;s/ *$//'`
2909 cxxflags=`echo $CXXFLAGS | \
2910     $SED 's/^ *//;s/  */ /;s/ *$//'`
2911 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2912 echo ""
2913 echo "        CFLAGS:          $cflags"
2914 echo "        CXXFLAGS:        $cxxflags"
2915 echo "        Macros:          $defines"
2916 echo ""
2917 if test "x$enable_llvm" = xyes; then
2918     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2919     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2920     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2921     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
2922     echo ""
2923 fi
2924 echo "        PYTHON2:         $PYTHON2"
2925
2926 echo ""
2927 echo "        Run '${MAKE-make}' to build Mesa"
2928 echo ""