configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl
  13 dnl Permission is hereby granted, free of charge, to any person obtaining a
  14 dnl copy of this software and associated documentation files (the "Software"),
  15 dnl to deal in the Software without restriction, including without limitation
  16 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  17 dnl and/or sell copies of the Software, and to permit persons to whom the
  18 dnl Software is furnished to do so, subject to the following conditions:
  19 dnl
  20 dnl The above copyright notice and this permission notice (including the next
  21 dnl paragraph) shall be included in all copies or substantial portions of the
  22 dnl Software.
  23 dnl
  24 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  25 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  26 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  27 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  28 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  29 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  30 dnl DEALINGS IN THE SOFTWARE.
  31 dnl
  32 dnl Process this file with autoconf to create configure.
  33
  34 AC_PREREQ([2.60])
  35
  36 dnl Tell the user about autoconf.html in the --help output
  37 m4_divert_once([HELP_END], [
  38 See docs/autoconf.html for more details on the options for Mesa.])
  39
  40 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  41 AC_INIT([Mesa], [MESA_VERSION],
  42     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  43 AC_CONFIG_AUX_DIR([bin])
  44 AC_CONFIG_MACRO_DIR([m4])
  45 AC_CANONICAL_SYSTEM
  46 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  47
  48 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  49 case "$host_os" in
  50 mingw*)
  51     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  52     ;;
  53 esac
  54
  55 # Support silent build rules, requires at least automake-1.11. Disable
  56 # by either passing --disable-silent-rules to configure or passing V=1
  57 # to make
  58 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  59     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  60
  61 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  62
  63 dnl Set internal versions
  64 OSMESA_VERSION=8
  65 AC_SUBST([OSMESA_VERSION])
  66 OPENCL_VERSION=1
  67 AC_SUBST([OPENCL_VERSION])
  68
  69 # The idea is that libdrm is distributed as one cohesive package, even
  70 # though it is composed of multiple libraries. However some drivers
  71 # may have different version requirements than others. This list
  72 # codifies which drivers need which version of libdrm. Any libdrm
  73 # version dependencies in non-driver-specific code should be reflected
  74 # in the first entry.
  75 LIBDRM_REQUIRED=2.4.66
  76 LIBDRM_RADEON_REQUIRED=2.4.71
  77 LIBDRM_AMDGPU_REQUIRED=2.4.63
  78 LIBDRM_INTEL_REQUIRED=2.4.75
  79 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  80 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  81 LIBDRM_FREEDRENO_REQUIRED=2.4.74
  82 LIBDRM_VC4_REQUIRED=2.4.69
  83 LIBDRM_ETNAVIV_REQUIRED=2.4.74
  84
  85 dnl Versions for external dependencies
  86 DRI2PROTO_REQUIRED=2.8
  87 DRI3PROTO_REQUIRED=1.0
  88 PRESENTPROTO_REQUIRED=1.0
  89 GLPROTO_REQUIRED=1.4.14
  90 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  91 LIBVA_REQUIRED=0.38.0
  92 VDPAU_REQUIRED=1.1
  93 WAYLAND_REQUIRED=1.11
  94 XCB_REQUIRED=1.9.3
  95 XCBDRI2_REQUIRED=1.8
  96 XCBGLX_REQUIRED=1.8.1
  97 XDAMAGE_REQUIRED=1.1
  98 XSHMFENCE_REQUIRED=1.1
  99 XVMC_REQUIRED=1.0.6
 100 PYTHON_MAKO_REQUIRED=0.8.0
 101 LIBSENSORS_REQUIRED=4.0.0
 102
 103 dnl LLVM versions
 104 LLVM_REQUIRED_GALLIUM=3.3.0
 105 LLVM_REQUIRED_OPENCL=3.6.0
 106 LLVM_REQUIRED_R600=3.6.0
 107 LLVM_REQUIRED_RADEONSI=3.6.0
 108 LLVM_REQUIRED_RADV=3.9.0
 109 LLVM_REQUIRED_SWR=3.6.0
 110
 111 dnl Check for progs
 112 AC_PROG_CPP
 113 AC_PROG_CC
 114 AC_PROG_CXX
 115 AM_PROG_CC_C_O
 116 AM_PROG_AS
 117 AX_CHECK_GNU_MAKE
 118 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 119 AC_PROG_SED
 120 AC_PROG_MKDIR_P
 121
 122 AC_SYS_LARGEFILE
 123
 124 LT_PREREQ([2.2])
 125 LT_INIT([disable-static])
 126
 127 AC_CHECK_PROG(RM, rm, [rm -f])
 128 AC_CHECK_PROG(XXD, xxd, [xxd])
 129
 130 AX_PROG_BISON([],
 131               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 132                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 133 AX_PROG_FLEX([],
 134              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 135                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 136
 137 AC_CHECK_PROG(INDENT, indent, indent, cat)
 138 if test "x$INDENT" != "xcat"; then
 139     # Only GNU indent is supported
 140     INDENT_VERSION=`indent --version | grep GNU`
 141     if test $? -eq 0; then
 142        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 143     else
 144        INDENT="cat"
 145     fi
 146 fi
 147
 148 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 149
 150 if test -z "$PYTHON2"; then
 151     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 152         AC_MSG_ERROR([Python not found - unable to generate sources])
 153     fi
 154 else
 155     if test "x$acv_mako_found" = xno; then
 156         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 157             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 158         fi
 159     fi
 160 fi
 161
 162 AC_PROG_INSTALL
 163
 164 dnl We need a POSIX shell for parts of the build. Assume we have one
 165 dnl in most cases.
 166 case "$host_os" in
 167 solaris*)
 168     # Solaris /bin/sh is too old/non-POSIX compliant
 169     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 170     SHELL="$POSIX_SHELL"
 171     ;;
 172 esac
 173
 174 dnl clang is mostly GCC-compatible, but its version is much lower,
 175 dnl so we have to check for it.
 176 AC_MSG_CHECKING([if compiling with clang])
 177
 178 AC_COMPILE_IFELSE(
 179 [AC_LANG_PROGRAM([], [[
 180 #ifndef __clang__
 181        not clang
 182 #endif
 183 ]])],
 184 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 185
 186 AC_MSG_RESULT([$acv_mesa_CLANG])
 187
 188 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 189 dnl versions are explictly not supported.
 190 GEN_ASM_OFFSETS=no
 191 USE_GNU99=no
 192 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 193     AC_MSG_CHECKING([whether gcc version is sufficient])
 194     major=0
 195     minor=0
 196
 197     GCC_VERSION=`$CC -dumpversion`
 198     if test $? -eq 0; then
 199         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 200         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 201     fi
 202
 203     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 204         AC_MSG_RESULT([no])
 205         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 206     else
 207         AC_MSG_RESULT([yes])
 208     fi
 209
 210     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 211         USE_GNU99=yes
 212     fi
 213     if test "x$cross_compiling" = xyes; then
 214         GEN_ASM_OFFSETS=yes
 215     fi
 216 fi
 217
 218 dnl We don't support building Mesa with Sun C compiler
 219 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 220 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 221 if test "x$SUNCC" = xyes; then
 222     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 223 fi
 224
 225 dnl Check for compiler builtins
 226 AX_GCC_BUILTIN([__builtin_bswap32])
 227 AX_GCC_BUILTIN([__builtin_bswap64])
 228 AX_GCC_BUILTIN([__builtin_clz])
 229 AX_GCC_BUILTIN([__builtin_clzll])
 230 AX_GCC_BUILTIN([__builtin_ctz])
 231 AX_GCC_BUILTIN([__builtin_expect])
 232 AX_GCC_BUILTIN([__builtin_ffs])
 233 AX_GCC_BUILTIN([__builtin_ffsll])
 234 AX_GCC_BUILTIN([__builtin_popcount])
 235 AX_GCC_BUILTIN([__builtin_popcountll])
 236 AX_GCC_BUILTIN([__builtin_unreachable])
 237
 238 AX_GCC_FUNC_ATTRIBUTE([const])
 239 AX_GCC_FUNC_ATTRIBUTE([flatten])
 240 AX_GCC_FUNC_ATTRIBUTE([format])
 241 AX_GCC_FUNC_ATTRIBUTE([malloc])
 242 AX_GCC_FUNC_ATTRIBUTE([packed])
 243 AX_GCC_FUNC_ATTRIBUTE([pure])
 244 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 245 AX_GCC_FUNC_ATTRIBUTE([unused])
 246 AX_GCC_FUNC_ATTRIBUTE([visibility])
 247 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 248 AX_GCC_FUNC_ATTRIBUTE([weak])
 249 AX_GCC_FUNC_ATTRIBUTE([alias])
 250
 251 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 252
 253 dnl Make sure the pkg-config macros are defined
 254 m4_ifndef([PKG_PROG_PKG_CONFIG],
 255     [m4_fatal([Could not locate the pkg-config autoconf macros.
 256   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 257   are in a different location, try setting the environment variable
 258   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 259 PKG_PROG_PKG_CONFIG()
 260
 261 dnl LIB_DIR - library basename
 262 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 263 AC_SUBST([LIB_DIR])
 264
 265 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 266 _SAVE_LDFLAGS="$LDFLAGS"
 267 _SAVE_CPPFLAGS="$CPPFLAGS"
 268
 269 dnl Compiler macros
 270 DEFINES="-D__STDC_CONSTANT_MACROS -D__STDC_FORMAT_MACROS -D__STDC_LIMIT_MACROS"
 271 AC_SUBST([DEFINES])
 272 android=no
 273 case "$host_os" in
 274 *-android)
 275     android=yes
 276     ;;
 277 linux*|*-gnu*|gnu*|cygwin*)
 278     DEFINES="$DEFINES -D_GNU_SOURCE"
 279     ;;
 280 solaris*)
 281     DEFINES="$DEFINES -DSVR4"
 282     ;;
 283 esac
 284
 285 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 286
 287 dnl Add flags for gcc and g++
 288 if test "x$GCC" = xyes; then
 289     CFLAGS="$CFLAGS -Wall"
 290
 291     if test "x$USE_GNU99" = xyes; then
 292         CFLAGS="$CFLAGS -std=gnu99"
 293     else
 294         CFLAGS="$CFLAGS -std=c99"
 295     fi
 296
 297     # Enable -Werror=implicit-function-declaration and
 298     # -Werror=missing-prototypes, if available, or otherwise, just
 299     # -Wmissing-prototypes.  This is particularly useful to avoid
 300     # generating a loadable driver module that has undefined symbols.
 301     save_CFLAGS="$CFLAGS"
 302     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 303     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 304     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 305     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 306                    AC_MSG_RESULT([yes]),
 307                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 308                     AC_MSG_RESULT([no])])
 309
 310     # Enable -fvisibility=hidden if using a gcc that supports it
 311     save_CFLAGS="$CFLAGS"
 312     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 313     VISIBILITY_CFLAGS="-fvisibility=hidden"
 314     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 315     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 316                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])])
 317
 318     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 319     CFLAGS=$save_CFLAGS
 320
 321     # We don't want floating-point math functions to set errno or trap
 322     CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
 323
 324     # Flags to help ensure that certain portions of the code -- and only those
 325     # portions -- can be built with MSVC:
 326     # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 327     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 328     #   supports most of C99)
 329     # - the rest has no compiler compiler restrictions
 330     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 331     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 332
 333     # Enable -Werror=vla if compiler supports it
 334     save_CFLAGS="$CFLAGS"
 335     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 336     CFLAGS="$CFLAGS -Werror=vla"
 337     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 338                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 339                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 340                     AC_MSG_RESULT([yes])],
 341                     AC_MSG_RESULT([no]))
 342     CFLAGS="$save_CFLAGS"
 343 fi
 344 if test "x$GXX" = xyes; then
 345     CXXFLAGS="$CXXFLAGS -Wall"
 346
 347     # Enable -fvisibility=hidden if using a gcc that supports it
 348     save_CXXFLAGS="$CXXFLAGS"
 349     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 350     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 351     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 352     AC_LANG_PUSH([C++])
 353     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 354                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])])
 355     AC_LANG_POP([C++])
 356
 357     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 358     CXXFLAGS=$save_CXXFLAGS
 359
 360     # We don't want floating-point math functions to set errno or trap
 361     CXXFLAGS="$CXXFLAGS -fno-math-errno -fno-trapping-math"
 362 fi
 363
 364 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 365 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 366
 367 dnl even if the compiler appears to support it, using visibility attributes isn't
 368 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 369 case "$host_os" in
 370 cygwin*)
 371     VISIBILITY_CFLAGS=""
 372     VISIBILITY_CXXFLAGS=""
 373     ;;
 374 esac
 375
 376 AC_SUBST([VISIBILITY_CFLAGS])
 377 AC_SUBST([VISIBILITY_CXXFLAGS])
 378
 379 dnl
 380 dnl Optional flags, check for compiler support
 381 dnl
 382 SSE41_CFLAGS="-msse4.1"
 383 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 384 dnl stack, but on x86-32 such alignment is not guaranteed.
 385 case "$target_cpu" in
 386 i?86)
 387     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 388     ;;
 389 esac
 390 save_CFLAGS="$CFLAGS"
 391 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 392 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 393 #include <smmintrin.h>
 394 int param;
 395 int main () {
 396     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 397     c = _mm_max_epu32(a, b);
 398     return _mm_cvtsi128_si32(c);
 399 }]])], SSE41_SUPPORTED=1)
 400 CFLAGS="$save_CFLAGS"
 401 if test "x$SSE41_SUPPORTED" = x1; then
 402     DEFINES="$DEFINES -DUSE_SSE41"
 403 fi
 404 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 405 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 406
 407 dnl Check for new-style atomic builtins
 408 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 409 int main() {
 410     int n;
 411     return __atomic_load_n(&n, __ATOMIC_ACQUIRE);
 412 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=1)
 413 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = x1; then
 414     DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
 415 fi
 416 AM_CONDITIONAL([GCC_ATOMIC_BUILTINS_SUPPORTED], [test x$GCC_ATOMIC_BUILTINS_SUPPORTED = x1])
 417
 418 dnl Check for Endianness
 419 AC_C_BIGENDIAN(
 420    little_endian=no,
 421    little_endian=yes,
 422    little_endian=no,
 423    little_endian=no
 424 )
 425
 426 dnl Check for POWER8 Architecture
 427 PWR8_CFLAGS="-mpower8-vector"
 428 have_pwr8_intrinsics=no
 429 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 430 save_CFLAGS=$CFLAGS
 431 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 432 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 433 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 434 #error "Need GCC >= 4.8 for sane POWER8 support"
 435 #endif
 436 #include <altivec.h>
 437 int main () {
 438     vector unsigned char r;
 439     vector unsigned int v = vec_splat_u32 (1);
 440     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 441     return 0;
 442 }]])], have_pwr8_intrinsics=yes)
 443 CFLAGS=$save_CFLAGS
 444
 445 AC_ARG_ENABLE(pwr8,
 446    [AS_HELP_STRING([--disable-pwr8-inst],
 447                    [disable POWER8-specific instructions])],
 448    [enable_pwr8=$enableval], [enable_pwr8=auto])
 449
 450 if test "x$enable_pwr8" = xno ; then
 451    have_pwr8_intrinsics=disabled
 452 fi
 453
 454 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 455    DEFINES="$DEFINES -D_ARCH_PWR8"
 456    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 457    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 458 else
 459    PWR8_CFLAGS=
 460 fi
 461
 462 AC_MSG_RESULT($have_pwr8_intrinsics)
 463 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 464    AC_MSG_ERROR([POWER8 compiler support not detected])
 465 fi
 466
 467 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 468    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 469 fi
 470
 471 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 472
 473 dnl Can't have static and shared libraries, default to static if user
 474 dnl explicitly requested. If both disabled, set to static since shared
 475 dnl was explicitly requested.
 476 case "x$enable_static$enable_shared" in
 477 xyesyes)
 478     AC_MSG_ERROR([Cannot enable both static and shared. Building using --enable-shared is strongly recommended])
 479     ;;
 480 xnono)
 481     AC_MSG_ERROR([Cannot disable both static and shared. Building using --enable-shared is strongly recommended])
 482     ;;
 483 esac
 484
 485 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 486
 487 dnl
 488 dnl other compiler options
 489 dnl
 490 AC_ARG_ENABLE([debug],
 491     [AS_HELP_STRING([--enable-debug],
 492         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 493     [enable_debug="$enableval"],
 494     [enable_debug=no]
 495 )
 496
 497 AC_ARG_ENABLE([profile],
 498     [AS_HELP_STRING([--enable-profile],
 499         [enable profiling of code @<:@default=disabled@:>@])],
 500     [enable_profile="$enableval"],
 501     [enable_profile=no]
 502 )
 503
 504 if test "x$enable_profile" = xyes; then
 505     DEFINES="$DEFINES -DPROFILE"
 506     if test "x$GCC" = xyes; then
 507         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 508     fi
 509     if test "x$GXX" = xyes; then
 510         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 511     fi
 512 fi
 513
 514 if test "x$enable_debug" = xyes; then
 515     DEFINES="$DEFINES -DDEBUG"
 516     if test "x$enable_profile" = xyes; then
 517         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 518     fi
 519     if test "x$GCC" = xyes; then
 520         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 521             CFLAGS="$CFLAGS -g"
 522         fi
 523         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 524             CFLAGS="$CFLAGS -O0"
 525         fi
 526     fi
 527     if test "x$GXX" = xyes; then
 528         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 529             CXXFLAGS="$CXXFLAGS -g"
 530         fi
 531         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 532             CXXFLAGS="$CXXFLAGS -O0"
 533         fi
 534     fi
 535 else
 536    DEFINES="$DEFINES -DNDEBUG"
 537 fi
 538
 539 dnl
 540 dnl Check if linker supports -Bsymbolic
 541 dnl
 542 save_LDFLAGS=$LDFLAGS
 543 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 544 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 545 AC_LINK_IFELSE(
 546     [AC_LANG_SOURCE([int main() { return 0;}])],
 547     [AC_MSG_RESULT([yes])
 548         BSYMBOLIC="-Wl,-Bsymbolic";],
 549     [AC_MSG_RESULT([no])
 550         BSYMBOLIC="";])
 551 LDFLAGS=$save_LDFLAGS
 552
 553 AC_SUBST([BSYMBOLIC])
 554
 555 dnl
 556 dnl Check if linker supports garbage collection
 557 dnl
 558 save_LDFLAGS=$LDFLAGS
 559 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 560 AC_MSG_CHECKING([whether ld supports --gc-sections])
 561 AC_LINK_IFELSE(
 562     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 563     [AC_MSG_RESULT([yes])
 564         GC_SECTIONS="-Wl,--gc-sections";],
 565     [AC_MSG_RESULT([no])
 566         GC_SECTIONS="";])
 567 LDFLAGS=$save_LDFLAGS
 568
 569 AC_SUBST([GC_SECTIONS])
 570
 571 dnl
 572 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 573 dnl so when these flags are passed to ld via libtool the checks will fail
 574 dnl
 575 case "$host_os" in
 576 openbsd* | darwin* )
 577     LD_NO_UNDEFINED="" ;;
 578 *)
 579     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 580 esac
 581
 582 AC_SUBST([LD_NO_UNDEFINED])
 583
 584 dnl
 585 dnl Check if linker supports version scripts
 586 dnl
 587 AC_MSG_CHECKING([if the linker supports version-scripts])
 588 save_LDFLAGS=$LDFLAGS
 589 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 590 cat > conftest.map <<EOF
 591 VERSION_1 {
 592      global:
 593          main;
 594
 595      local:
 596          *;
 597 };
 598 EOF
 599 AC_LINK_IFELSE(
 600     [AC_LANG_SOURCE([int main() { return 0;}])],
 601     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 602     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 603 LDFLAGS=$save_LDFLAGS
 604 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 605
 606 dnl
 607 dnl Check if linker supports dynamic list files
 608 dnl
 609 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 610 save_LDFLAGS=$LDFLAGS
 611 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 612 cat > conftest.dyn <<EOF
 613 {
 614         radeon_drm_winsys_create;
 615 };
 616 EOF
 617 AC_LINK_IFELSE(
 618     [AC_LANG_SOURCE([int main() { return 0;}])],
 619     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 620     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 621 LDFLAGS=$save_LDFLAGS
 622 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 623
 624 dnl
 625 dnl compatibility symlinks
 626 dnl
 627 case "$host_os" in
 628 linux* )
 629     HAVE_COMPAT_SYMLINKS=yes ;;
 630 * )
 631     HAVE_COMPAT_SYMLINKS=no ;;
 632 esac
 633
 634 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 635
 636 dnl
 637 dnl library names
 638 dnl
 639 dnl Unfortunately we need to do a few things that libtool can't help us with,
 640 dnl so we need some knowledge of shared library filenames:
 641 dnl
 642 dnl LIB_EXT is the extension used when creating symlinks for alternate
 643 dnl filenames for a shared library which will be dynamically loaded
 644 dnl
 645 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 646 dnl the file for a shared library we wish to link with
 647 dnl
 648 case "$host_os" in
 649 darwin* )
 650     LIB_EXT='dylib'
 651     IMP_LIB_EXT=$LIB_EXT
 652     ;;
 653 cygwin* )
 654     LIB_EXT='dll'
 655     IMP_LIB_EXT='dll.a'
 656     ;;
 657 aix* )
 658     LIB_EXT='a'
 659     IMP_LIB_EXT=$LIB_EXT
 660     ;;
 661 * )
 662     LIB_EXT='so'
 663     IMP_LIB_EXT=$LIB_EXT
 664     ;;
 665 esac
 666
 667 AC_SUBST([LIB_EXT])
 668
 669 dnl
 670 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 671 dnl
 672 AC_ARG_ENABLE([texture-float],
 673     [AS_HELP_STRING([--enable-texture-float],
 674         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 675     [enable_texture_float="$enableval"],
 676     [enable_texture_float=no]
 677 )
 678 if test "x$enable_texture_float" = xyes; then
 679     AC_MSG_WARN([Floating-point textures enabled.])
 680     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 681     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 682 fi
 683
 684 dnl
 685 dnl Arch/platform-specific settings
 686 dnl
 687 AC_ARG_ENABLE([asm],
 688     [AS_HELP_STRING([--disable-asm],
 689         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 690     [enable_asm="$enableval"],
 691     [enable_asm=yes]
 692 )
 693 asm_arch=""
 694 AC_MSG_CHECKING([whether to enable assembly])
 695 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 696 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 697 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 698     case "$host_cpu" in
 699     i?86 | x86_64 | amd64)
 700         if test "x$host_cpu" != "x$target_cpu"; then
 701             enable_asm=no
 702             AC_MSG_RESULT([no, cross compiling])
 703         fi
 704         ;;
 705     esac
 706 fi
 707 # check for supported arches
 708 if test "x$enable_asm" = xyes; then
 709     case "$host_cpu" in
 710     i?86)
 711         case "$host_os" in
 712         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 713             asm_arch=x86
 714             ;;
 715         esac
 716         ;;
 717     x86_64|amd64)
 718         case "$host_os" in
 719         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 720             asm_arch=x86_64
 721             ;;
 722         esac
 723         ;;
 724     sparc*)
 725         case "$host_os" in
 726         linux*)
 727             asm_arch=sparc
 728             ;;
 729         esac
 730         ;;
 731     esac
 732
 733     case "$asm_arch" in
 734     x86)
 735         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 736         AC_MSG_RESULT([yes, x86])
 737         ;;
 738     x86_64|amd64)
 739         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 740         AC_MSG_RESULT([yes, x86_64])
 741         ;;
 742     sparc)
 743         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 744         AC_MSG_RESULT([yes, sparc])
 745         ;;
 746     *)
 747         AC_MSG_RESULT([no, platform not supported])
 748         ;;
 749     esac
 750 fi
 751
 752 AC_HEADER_MAJOR
 753 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 754 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 755 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 756 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 757
 758 dnl Check to see if dlopen is in default libraries (like Solaris, which
 759 dnl has it in libc), or if libdl is needed to get it.
 760 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 761     [AC_CHECK_LIB([dl], [dlopen],
 762        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 763 AC_SUBST([DLOPEN_LIBS])
 764
 765 dnl Check if that library also has dladdr
 766 save_LIBS="$LIBS"
 767 LIBS="$LIBS $DLOPEN_LIBS"
 768 AC_CHECK_FUNCS([dladdr])
 769 LIBS="$save_LIBS"
 770
 771 AC_CHECK_FUNC([dl_iterate_phdr], [DEFINES="$DEFINES -DHAVE_DL_ITERATE_PHDR"])
 772
 773 case "$host_os" in
 774 darwin*)
 775     ;;
 776 *)
 777     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 778                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 779                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 780     AC_SUBST([CLOCK_LIB])
 781     ;;
 782 esac
 783
 784 dnl See if posix_memalign is available
 785 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 786
 787 dnl Check for pthreads
 788 AX_PTHREAD
 789 if test "x$ax_pthread_ok" = xno; then
 790     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 791 fi
 792 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 793 dnl to -pthread, which causes problems if we need -lpthread to appear in
 794 dnl pkgconfig files.  Since Android doesn't have a pthread lib, this check
 795 dnl is not valid for that platform.
 796 if test "x$android" = xno; then
 797     test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 798 fi
 799
 800 dnl pthread-stubs is mandatory on targets where it exists
 801 case "$host_os" in
 802 cygwin* )
 803     pthread_stubs_possible="no"
 804     ;;
 805 * )
 806     pthread_stubs_possible="yes"
 807     ;;
 808 esac
 809
 810 if test "x$pthread_stubs_possible" = xyes; then
 811     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
 812     AC_SUBST(PTHREADSTUBS_CFLAGS)
 813     AC_SUBST(PTHREADSTUBS_LIBS)
 814 fi
 815
 816 dnl SELinux awareness.
 817 AC_ARG_ENABLE([selinux],
 818     [AS_HELP_STRING([--enable-selinux],
 819         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 820     [MESA_SELINUX="$enableval"],
 821     [MESA_SELINUX=no])
 822 if test "x$enable_selinux" = "xyes"; then
 823     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 824         [AC_CHECK_HEADER([selinux/selinux.h],[],
 825                          [AC_MSG_ERROR([SELinux headers not found])])
 826          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 827                       [AC_MSG_ERROR([SELinux library not found])])
 828          SELINUX_LIBS="-lselinux"])
 829     DEFINES="$DEFINES -DMESA_SELINUX"
 830 fi
 831 AC_SUBST([SELINUX_CFLAGS])
 832 AC_SUBST([SELINUX_LIBS])
 833
 834 dnl
 835 dnl LLVM
 836 dnl
 837 AC_ARG_ENABLE([llvm-shared-libs],
 838     [AS_HELP_STRING([--enable-llvm-shared-libs],
 839         [link with LLVM shared libraries @<:@default=enabled@:>@])],
 840     [enable_llvm_shared_libs="$enableval"],
 841     [enable_llvm_shared_libs=yes])
 842
 843 AC_ARG_WITH([llvm-prefix],
 844     [AS_HELP_STRING([--with-llvm-prefix],
 845         [Prefix for LLVM installations in non-standard locations])],
 846     [llvm_prefix="$withval"],
 847     [llvm_prefix=''])
 848
 849 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
 850 if test "x$have_libelf" = xno; then
 851    LIBELF_LIBS=''
 852    LIBELF_CFLAGS=''
 853    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
 854    AC_SUBST([LIBELF_LIBS])
 855    AC_SUBST([LIBELF_CFLAGS])
 856 fi
 857
 858 if test -z "$LLVM_CONFIG"; then
 859     if test -n "$llvm_prefix"; then
 860         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
 861     else
 862         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
 863     fi
 864 fi
 865
 866 llvm_add_component() {
 867     new_llvm_component=$1
 868     driver_name=$2
 869
 870     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
 871         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
 872     else
 873         AC_MSG_ERROR([LLVM component '$new_llvm_component' not enabled in your LLVM build. Required by $driver_name.])
 874     fi
 875 }
 876
 877 llvm_add_default_components() {
 878     driver_name=$1
 879
 880     # Required default components
 881     llvm_add_component "bitwriter" $driver_name
 882     llvm_add_component "engine" $driver_name
 883     llvm_add_component "mcdisassembler" $driver_name
 884     llvm_add_component "mcjit" $driver_name
 885
 886     # Optional default components
 887     if $LLVM_CONFIG --components | grep -iqw inteljitevents ; then
 888         LLVM_COMPONENTS="$LLVM_COMPONENTS inteljitevents"
 889     fi
 890 }
 891
 892 llvm_add_target() {
 893     new_llvm_target=$1
 894     driver_name=$2
 895
 896     if $LLVM_CONFIG --targets-built | grep -iqw $new_llvm_target ; then
 897         llvm_add_component $new_llvm_target $driver_name
 898     else
 899         AC_MSG_ERROR([LLVM target '$new_llvm_target' not enabled in your LLVM build. Required by $driver_name.])
 900     fi
 901 }
 902
 903 # Call this inside ` ` to get the return value.
 904 # $1 is the llvm-config command with arguments.
 905 strip_unwanted_llvm_flags() {
 906     # Use \> (marks the end of the word)
 907     echo " `$1`" | sed \
 908         -e 's/\s\+-m\S*//g' \
 909         -e 's/\s\+-DNDEBUG\>//g' \
 910         -e 's/\s\+-D_GNU_SOURCE\>//g' \
 911         -e 's/\s\+-pedantic\>//g' \
 912         -e 's/\s\+-W\S*//g' \
 913         -e 's/\s\+-O\S*//g' \
 914         -e 's/\s\+-g\S*//g' \
 915         -e 's/-fno-rtti\>/-Fno-rtti/g' \
 916         -e 's/\s\+-f\S*//g' \
 917         -e 's/-Fno-rtti\>/-fno-rtti/g' \
 918         -e 's/^ //'
 919 }
 920
 921 llvm_set_environment_variables() {
 922     if test "x$LLVM_CONFIG" != xno; then
 923         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
 924         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
 925         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
 926         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
 927
 928         # We need to respect LLVM_CPPFLAGS when compiling LLVM headers.
 929         save_CFLAGS="$CFLAGS"
 930         CFLAGS="$CFLAGS $LLVM_CPPFLAGS"
 931
 932         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
 933             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 934         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
 935             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 936         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
 937             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 938
 939         CFLAGS="$save_CFLAGS"
 940
 941         # Only needed for LLVM < 3.6.0
 942         if test -z "$LLVM_VERSION_PATCH"; then
 943             LLVM_VERSION_PATCH=0
 944         fi
 945
 946         LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
 947
 948         FOUND_LLVM=yes
 949     else
 950         FOUND_LLVM=no
 951         LLVM_VERSION_INT=0
 952     fi
 953 }
 954
 955 require_llvm() {
 956     if test "x$enable_llvm" != "xyes"; then
 957         AC_MSG_ERROR([--enable-llvm is required when building $1])
 958     fi
 959 }
 960
 961 llvm_require_version() {
 962     require_llvm $2
 963
 964     llvm_target_version_major=`echo $1 | cut -d. -f1 | egrep -o '^[[0-9]]+'`
 965     llvm_target_version_minor=`echo $1 | cut -d. -f2 | egrep -o '^[[0-9]]+'`
 966     llvm_target_version_patch=`echo $1 | cut -d. -f3 | egrep -o '^[[0-9]]+'`
 967
 968     if test "$LLVM_VERSION_MAJOR" -gt "$llvm_target_version_major"; then
 969         # major > required major
 970         #  --> OK
 971         return
 972     fi
 973
 974     if test "$LLVM_VERSION_MAJOR" -eq "$llvm_target_version_major"; then
 975         if test "$LLVM_VERSION_MINOR" -gt "$llvm_target_version_minor"; then
 976             # major = required major and
 977             # minor > required minor
 978             #  --> OK
 979             return
 980         else
 981             if test "$LLVM_VERSION_MINOR" -eq "$llvm_target_version_minor"; then
 982                 if test "$LLVM_VERSION_PATCH" -ge "$llvm_target_version_patch"; then
 983                     # major = required major and
 984                     # minor = required minor and
 985                     # patch >= required patch
 986                     #  --> OK
 987                     return
 988                 fi
 989             fi
 990         fi
 991     fi
 992
 993     AC_MSG_ERROR([LLVM $1 or newer is required for $2])
 994 }
 995
 996 radeon_llvm_check() {
 997     if test ${LLVM_VERSION_INT} -lt 307; then
 998         amdgpu_llvm_target_name='r600'
 999     else
1000         amdgpu_llvm_target_name='amdgpu'
1001     fi
1002
1003     llvm_require_version $*
1004
1005     llvm_add_target $amdgpu_llvm_target_name $2
1006
1007     llvm_add_default_components $2
1008     llvm_add_component "bitreader" $2
1009     llvm_add_component "ipo" $2
1010
1011     NEED_RADEON_LLVM=yes
1012     if test "x$have_libelf" != xyes; then
1013        AC_MSG_ERROR([$1 requires libelf when using llvm])
1014     fi
1015 }
1016
1017 llvm_set_environment_variables
1018
1019 AC_SUBST([LLVM_CFLAGS])
1020 AC_SUBST([LLVM_CXXFLAGS])
1021 AC_SUBST([LLVM_LIBS])
1022 AC_SUBST([LLVM_LDFLAGS])
1023 AC_SUBST([LLVM_INCLUDEDIR])
1024
1025 dnl Options for APIs
1026 AC_ARG_ENABLE([opengl],
1027     [AS_HELP_STRING([--disable-opengl],
1028         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
1029     [enable_opengl="$enableval"],
1030     [enable_opengl=yes])
1031 AC_ARG_ENABLE([gles1],
1032     [AS_HELP_STRING([--disable-gles1],
1033         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
1034     [enable_gles1="$enableval"],
1035     [enable_gles1=yes])
1036 AC_ARG_ENABLE([gles2],
1037     [AS_HELP_STRING([--disable-gles2],
1038         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
1039     [enable_gles2="$enableval"],
1040     [enable_gles2=yes])
1041
1042 AC_ARG_ENABLE([dri],
1043     [AS_HELP_STRING([--enable-dri],
1044         [enable DRI modules @<:@default=enabled@:>@])],
1045     [enable_dri="$enableval"],
1046     [enable_dri=yes])
1047
1048 AC_ARG_ENABLE([gallium-extra-hud],
1049     [AS_HELP_STRING([--enable-gallium-extra-hud],
1050         [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
1051     [enable_gallium_extra_hud="$enableval"],
1052     [enable_gallium_extra_hud=no])
1053 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
1054 if test "x$enable_gallium_extra_hud" = xyes ; then
1055     DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
1056 fi
1057
1058 #TODO: no pkgconfig .pc available for libsensors.
1059 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
1060 AC_ARG_ENABLE([lmsensors],
1061     [AS_HELP_STRING([--enable-lmsensors],
1062         [enable HUD lmsensor support @<:@default=disabled@:>@])],
1063     [enable_lmsensors="$enableval"],
1064     [enable_lmsensors=no])
1065 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
1066 if test "x$enable_lmsensors" = xyes ; then
1067     DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
1068     LIBSENSORS_LIBS="-lsensors"
1069 else
1070     LIBSENSORS_LIBS=""
1071 fi
1072 AC_SUBST(LIBSENSORS_LIBS)
1073
1074 case "$host_os" in
1075 linux*)
1076     dri3_default=yes
1077     ;;
1078 *)
1079     dri3_default=no
1080     ;;
1081 esac
1082
1083 if test "x$enable_dri" = xno; then
1084     dri3_default=no
1085 fi
1086
1087 AC_ARG_ENABLE([dri3],
1088     [AS_HELP_STRING([--enable-dri3],
1089         [enable DRI3 @<:@default=auto@:>@])],
1090     [enable_dri3="$enableval"],
1091     [enable_dri3="$dri3_default"])
1092 AC_ARG_ENABLE([glx],
1093     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
1094         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
1095     [enable_glx="$enableval"],
1096     [enable_glx=yes])
1097 AC_ARG_ENABLE([osmesa],
1098     [AS_HELP_STRING([--enable-osmesa],
1099         [enable OSMesa library @<:@default=disabled@:>@])],
1100     [enable_osmesa="$enableval"],
1101     [enable_osmesa=no])
1102 AC_ARG_ENABLE([gallium-osmesa],
1103     [AS_HELP_STRING([--enable-gallium-osmesa],
1104         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
1105     [enable_gallium_osmesa="$enableval"],
1106     [enable_gallium_osmesa=no])
1107 AC_ARG_ENABLE([egl],
1108     [AS_HELP_STRING([--disable-egl],
1109         [disable EGL library @<:@default=enabled@:>@])],
1110     [enable_egl="$enableval"],
1111     [enable_egl=yes])
1112
1113 AC_ARG_ENABLE([xa],
1114     [AS_HELP_STRING([--enable-xa],
1115         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
1116     [enable_xa="$enableval"],
1117     [enable_xa=no])
1118 AC_ARG_ENABLE([gbm],
1119    [AS_HELP_STRING([--enable-gbm],
1120          [enable gbm library @<:@default=yes except cygwin@:>@])],
1121    [enable_gbm="$enableval"],
1122    [case "$host_os" in
1123        cygwin*)
1124           enable_gbm=no
1125           ;;
1126        *)
1127           enable_gbm=yes
1128           ;;
1129     esac])
1130 AC_ARG_ENABLE([nine],
1131     [AS_HELP_STRING([--enable-nine],
1132         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
1133     [enable_nine="$enableval"],
1134     [enable_nine=no])
1135
1136 AC_ARG_ENABLE([xvmc],
1137    [AS_HELP_STRING([--enable-xvmc],
1138          [enable xvmc library @<:@default=auto@:>@])],
1139    [enable_xvmc="$enableval"],
1140    [enable_xvmc=auto])
1141 AC_ARG_ENABLE([vdpau],
1142    [AS_HELP_STRING([--enable-vdpau],
1143          [enable vdpau library @<:@default=auto@:>@])],
1144    [enable_vdpau="$enableval"],
1145    [enable_vdpau=auto])
1146 AC_ARG_ENABLE([omx],
1147    [AS_HELP_STRING([--enable-omx],
1148          [enable OpenMAX library @<:@default=disabled@:>@])],
1149    [enable_omx="$enableval"],
1150    [enable_omx=no])
1151 AC_ARG_ENABLE([va],
1152    [AS_HELP_STRING([--enable-va],
1153          [enable va library @<:@default=auto@:>@])],
1154    [enable_va="$enableval"],
1155    [enable_va=auto])
1156 AC_ARG_ENABLE([opencl],
1157    [AS_HELP_STRING([--enable-opencl],
1158          [enable OpenCL library @<:@default=disabled@:>@])],
1159    [enable_opencl="$enableval"],
1160    [enable_opencl=no])
1161 AC_ARG_ENABLE([opencl_icd],
1162    [AS_HELP_STRING([--enable-opencl-icd],
1163           [Build an OpenCL ICD library to be loaded by an ICD implementation
1164            @<:@default=disabled@:>@])],
1165     [enable_opencl_icd="$enableval"],
1166     [enable_opencl_icd=no])
1167
1168 AC_ARG_ENABLE([gallium-tests],
1169     [AS_HELP_STRING([--enable-gallium-tests],
1170         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1171     [enable_gallium_tests="$enableval"],
1172     [enable_gallium_tests=no])
1173
1174 # Option for Gallium drivers
1175
1176 # Keep this in sync with the --with-gallium-drivers help string default value
1177 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1178
1179 AC_ARG_WITH([gallium-drivers],
1180     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1181         [comma delimited Gallium drivers list, e.g.
1182         "i915,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,swr,vc4,virgl,etnaviv,imx"
1183         @<:@default=r300,r600,svga,swrast@:>@])],
1184     [with_gallium_drivers="$withval"],
1185     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1186
1187 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
1188 # here so that the script doesn't choke on an unknown driver name later.
1189 case "$with_gallium_drivers" in
1190     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1191     no) with_gallium_drivers='' ;;
1192 esac
1193
1194 if test "x$enable_opengl" = xno -a \
1195         "x$enable_gles1" = xno -a \
1196         "x$enable_gles2" = xno -a \
1197         "x$enable_nine" = xno -a \
1198         "x$enable_xa" = xno -a \
1199         "x$enable_xvmc" = xno -a \
1200         "x$enable_vdpau" = xno -a \
1201         "x$enable_omx" = xno -a \
1202         "x$enable_va" = xno -a \
1203         "x$enable_opencl" = xno; then
1204     AC_MSG_ERROR([at least one API should be enabled])
1205 fi
1206
1207 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1208 if test "x$enable_opengl" = xno -a \
1209         "x$enable_gles1" = xyes; then
1210     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1211 fi
1212
1213 if test "x$enable_opengl" = xno -a \
1214         "x$enable_gles2" = xyes; then
1215     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1216 fi
1217
1218 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1219 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1220 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1221 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1222                                         "x$enable_gles1" = xyes -o \
1223                                         "x$enable_gles2" = xyes)
1224
1225 # Validate GLX options
1226 if test "x$enable_glx" = xyes; then
1227     if test "x$enable_dri" = xyes; then
1228         enable_glx=dri
1229     elif test -n "$with_gallium_drivers"; then
1230         enable_glx=gallium-xlib
1231     else
1232         enable_glx=xlib
1233     fi
1234 fi
1235 case "x$enable_glx" in
1236 xdri | xxlib | xgallium-xlib)
1237     # GLX requires OpenGL
1238     if test "x$enable_opengl" = xno; then
1239         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1240     fi
1241
1242     # Check individual dependencies
1243     case "x$enable_glx" in
1244     xdri)
1245         if test "x$enable_dri" = xno; then
1246             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1247         fi
1248         ;;
1249     xxlib)
1250         if test "x$enable_dri" = xyes; then
1251             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1252         fi
1253         ;;
1254     xgallium-xlib )
1255         if test "x$enable_dri" = xyes; then
1256             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1257         fi
1258         if test -z "$with_gallium_drivers"; then
1259             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1260         fi
1261         ;;
1262     esac
1263     ;;
1264 xno)
1265     ;;
1266 *)
1267     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1268     ;;
1269 esac
1270
1271 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1272 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1273 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1274 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1275
1276 DEFAULT_GL_LIB_NAME=GL
1277
1278 dnl
1279 dnl Libglvnd configuration
1280 dnl
1281 AC_ARG_ENABLE([libglvnd],
1282     [AS_HELP_STRING([--enable-libglvnd],
1283         [Build for libglvnd @<:@default=disabled@:>@])],
1284     [enable_libglvnd="$enableval"],
1285     [enable_libglvnd=no])
1286 AM_CONDITIONAL(USE_LIBGLVND_GLX, test "x$enable_libglvnd" = xyes)
1287 if test "x$enable_libglvnd" = xyes ; then
1288     dnl XXX: update once we can handle more than libGL/glx.
1289     dnl Namely: we should error out if neither of the glvnd enabled libraries
1290     dnl are built
1291     case "x$enable_glx" in
1292     xno)
1293         AC_MSG_ERROR([cannot build libglvnd without GLX])
1294         ;;
1295     xxlib | xgallium-xlib )
1296         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1297         ;;
1298     xdri)
1299         ;;
1300     esac
1301
1302     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.1.0)
1303     DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"
1304     DEFAULT_GL_LIB_NAME=GLX_mesa
1305 fi
1306
1307 AC_ARG_WITH([gl-lib-name],
1308   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
1309     [specify GL library name @<:@default=GL@:>@])],
1310   [GL_LIB=$withval],
1311   [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1312 AC_ARG_WITH([osmesa-lib-name],
1313   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
1314     [specify OSMesa library name @<:@default=OSMesa@:>@])],
1315   [OSMESA_LIB=$withval],
1316   [OSMESA_LIB=OSMesa])
1317 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1318 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
1319
1320 dnl
1321 dnl Mangled Mesa support
1322 dnl
1323 AC_ARG_ENABLE([mangling],
1324   [AS_HELP_STRING([--enable-mangling],
1325     [enable mangled symbols and library name @<:@default=disabled@:>@])],
1326   [enable_mangling="${enableval}"],
1327   [enable_mangling=no]
1328 )
1329 if test "x${enable_mangling}" = "xyes" ; then
1330   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
1331   GL_LIB="Mangled${GL_LIB}"
1332   OSMESA_LIB="Mangled${OSMESA_LIB}"
1333 fi
1334 AC_SUBST([GL_LIB])
1335 AC_SUBST([OSMESA_LIB])
1336
1337 # Check for libdrm
1338 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1339                   [have_libdrm=yes], [have_libdrm=no])
1340 if test "x$have_libdrm" = xyes; then
1341         DEFINES="$DEFINES -DHAVE_LIBDRM"
1342 fi
1343
1344 require_libdrm() {
1345     if test "x$have_libdrm" != xyes; then
1346        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1347     fi
1348 }
1349
1350
1351 # Select which platform-dependent DRI code gets built
1352 case "$host_os" in
1353 darwin*)
1354     dri_platform='apple' ;;
1355 cygwin*)
1356     dri_platform='windows' ;;
1357 gnu*)
1358     dri_platform='none' ;;
1359 *)
1360     dri_platform='drm' ;;
1361 esac
1362
1363 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1364     have_drisw_kms='yes'
1365 fi
1366
1367 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1368 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1369 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1370 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1371 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1372 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1373 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1374 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1375 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1376
1377 AC_ARG_ENABLE([shared-glapi],
1378     [AS_HELP_STRING([--enable-shared-glapi],
1379         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1380     [enable_shared_glapi="$enableval"],
1381     [enable_shared_glapi=yes])
1382
1383 case "x$enable_opengl$enable_gles1$enable_gles2" in
1384 x*yes*yes*)
1385     if test "x$enable_shared_glapi" = xno; then
1386         AC_MSG_ERROR([shared GLAPI required when building two or more of
1387                       the following APIs - opengl, gles1 gles2])
1388     fi
1389     ;;
1390 esac
1391
1392 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1393
1394 # Build the pipe-drivers as separate libraries/modules.
1395 # Do not touch this unless you know what you are doing.
1396 # XXX: Expose via configure option ?
1397 enable_shared_pipe_drivers=no
1398
1399 dnl
1400 dnl Driver specific build directories
1401 dnl
1402
1403 if test "x$enable_gallium_osmesa" = xyes; then
1404     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1405         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1406     fi
1407     if test "x$enable_osmesa" = xyes; then
1408         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1409     fi
1410 fi
1411
1412 require_dri_shared_libs_and_glapi() {
1413     if test "x$enable_static" = xyes; then
1414         AC_MSG_ERROR([$1 cannot be build as static library])
1415     fi
1416
1417     if test "x$enable_dri" != xyes; then
1418         # There is only a single backend which won't be build/used otherwise.
1419         # XXX: Revisit this as the egl/haiku is a thing.
1420         AC_MSG_ERROR([$1 requires --enable-dri])
1421     fi
1422
1423     if test "x$enable_shared_glapi" != xyes; then
1424         AC_MSG_ERROR([$1 requires --enable-shared-glapi])
1425     fi
1426 }
1427
1428 if test "x$enable_dri" = xyes; then
1429     require_dri_shared_libs_and_glapi "DRI"
1430
1431     # not a hard requirement as swrast does not depend on it
1432     if test "x$have_libdrm" = xyes; then
1433         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1434     fi
1435 fi
1436
1437 AC_ARG_ENABLE([driglx-direct],
1438     [AS_HELP_STRING([--disable-driglx-direct],
1439         [disable direct rendering in GLX and EGL for DRI \
1440             @<:@default=auto@:>@])],
1441     [driglx_direct="$enableval"],
1442     [driglx_direct="yes"])
1443
1444 dnl
1445 dnl libGL configuration per driver
1446 dnl
1447 if test "x$enable_glx" != xno; then
1448     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1449 fi
1450 case "x$enable_glx" in
1451 xxlib | xgallium-xlib)
1452     # Xlib-based GLX
1453     dri_modules="x11 xext xcb"
1454     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1455     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1456     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1457     GL_LIB_DEPS="$XLIBGL_LIBS"
1458     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1459     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1460     ;;
1461 xdri)
1462     # DRI-based GLX
1463
1464     # find the DRI deps for libGL
1465     dri_modules="x11 xext xdamage >= $XDAMAGE_REQUIRED xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1466
1467     if test x"$driglx_direct" = xyes; then
1468         if test x"$dri_platform" = xdrm ; then
1469             DEFINES="$DEFINES -DGLX_USE_DRM"
1470             require_libdrm "Direct rendering"
1471
1472             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1473             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1474             if test x"$enable_dri3" = xyes; then
1475                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1476                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1477             fi
1478
1479             if test x"$enable_dri" = xyes; then
1480                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1481             fi
1482
1483             if test x"$enable_dri3" = xyes; then
1484                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1485                dri3_modules="xcb xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1486                PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1487             fi
1488         fi
1489         if test x"$dri_platform" = xapple ; then
1490             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1491         fi
1492         if test x"$dri_platform" = xwindows ; then
1493             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1494         fi
1495     fi
1496
1497     # add xf86vidmode if available
1498     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1499     if test "$HAVE_XF86VIDMODE" = yes ; then
1500         dri_modules="$dri_modules xxf86vm"
1501     fi
1502
1503     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1504     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1505     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1506     GL_LIB_DEPS="$DRIGL_LIBS"
1507
1508     # need DRM libs, $PTHREAD_LIBS, etc.
1509     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1510     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1511     ;;
1512 esac
1513
1514 # This is outside the case (above) so that it is invoked even for non-GLX
1515 # builds.
1516 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1517
1518 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1519 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1520 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1521 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1522
1523 AC_SUBST([X11_INCLUDES])
1524 AC_SUBST([GL_LIB_DEPS])
1525 AC_SUBST([GL_PC_REQ_PRIV])
1526 AC_SUBST([GL_PC_LIB_PRIV])
1527 AC_SUBST([GL_PC_CFLAGS])
1528 AC_SUBST([DRI_PC_REQ_PRIV])
1529 AC_SUBST([GLESv1_CM_LIB_DEPS])
1530 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1531 AC_SUBST([GLESv2_LIB_DEPS])
1532 AC_SUBST([GLESv2_PC_LIB_PRIV])
1533
1534 AC_SUBST([HAVE_XF86VIDMODE])
1535
1536 dnl
1537 dnl More GLX setup
1538 dnl
1539 case "x$enable_glx" in
1540 xxlib | xgallium-xlib)
1541     DEFINES="$DEFINES -DUSE_XSHM"
1542     ;;
1543 xdri)
1544     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1545     if test "x$driglx_direct" = xyes; then
1546         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1547     fi
1548     ;;
1549 esac
1550
1551 dnl
1552 dnl TLS detection
1553 dnl
1554
1555 AC_ARG_ENABLE([glx-tls],
1556     [AS_HELP_STRING([--enable-glx-tls],
1557         [enable TLS support in GLX @<:@default=enabled@:>@])],
1558     [GLX_USE_TLS="$enableval"],
1559     [GLX_USE_TLS=yes])
1560 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1561
1562 if test "x$GLX_USE_TLS" = xyes; then
1563     DEFINES="$DEFINES -DGLX_USE_TLS"
1564 fi
1565
1566 dnl Read-only text section on x86 hardened platforms
1567 AC_ARG_ENABLE([glx-read-only-text],
1568     [AS_HELP_STRING([--enable-glx-read-only-text],
1569         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1570     [enable_glx_read_only_text="$enableval"],
1571     [enable_glx_read_only_text=no])
1572 if test "x$enable_glx_read_only_text" = xyes; then
1573     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1574 fi
1575
1576 dnl
1577 dnl More DRI setup
1578 dnl
1579 dnl Directory for DRI drivers
1580 AC_ARG_WITH([dri-driverdir],
1581     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1582         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1583     [DRI_DRIVER_INSTALL_DIR="$withval"],
1584     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1585 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1586 dnl Extra search path for DRI drivers
1587 AC_ARG_WITH([dri-searchpath],
1588     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1589         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1590     [DRI_DRIVER_SEARCH_DIR="$withval"],
1591     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1592 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1593 dnl Which drivers to build - default is chosen by platform
1594 AC_ARG_WITH([dri-drivers],
1595     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1596         [comma delimited classic DRI drivers list, e.g.
1597         "i915,i965,nouveau,radeon,r200,swrast" @<:@default=auto@:>@])],
1598     [with_dri_drivers="$withval"],
1599     [with_dri_drivers=auto])
1600
1601 if test "x$with_dri_drivers" = xauto; then
1602     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1603         with_dri_drivers="yes"
1604     else
1605         with_dri_drivers="no"
1606     fi
1607 fi
1608 if test "x$with_dri_drivers" = xno; then
1609     with_dri_drivers=''
1610 fi
1611
1612 dnl If $with_dri_drivers is yes, drivers will be added through
1613 dnl platform checks. Set DEFINES and LIB_DEPS
1614 if test "x$enable_dri" = xyes; then
1615     # Platform specific settings and drivers to build
1616     case "$host_os" in
1617     linux*)
1618         if test "x$enable_dri3" = xyes; then
1619             DEFINES="$DEFINES -DHAVE_DRI3"
1620         fi
1621
1622         case "$host_cpu" in
1623         powerpc* | sparc*)
1624             # Build only the drivers for cards that exist on PowerPC/sparc
1625             if test "x$with_dri_drivers" = "xyes"; then
1626                 with_dri_drivers="r200 radeon swrast"
1627             fi
1628             ;;
1629         esac
1630         ;;
1631     cygwin*)
1632         if test "x$with_dri_drivers" = "xyes"; then
1633             with_dri_drivers="swrast"
1634         fi
1635         ;;
1636     darwin*)
1637         DEFINES="$DEFINES -DBUILDING_MESA"
1638         if test "x$with_dri_drivers" = "xyes"; then
1639             with_dri_drivers="swrast"
1640         fi
1641         ;;
1642     esac
1643
1644     # default drivers
1645     if test "x$with_dri_drivers" = "xyes"; then
1646         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1647     fi
1648
1649     # Check for expat
1650     PKG_CHECK_MODULES([EXPAT], [expat], [],
1651         # expat version 2.0 and earlier do not provide expat.pc
1652         [AC_CHECK_HEADER([expat.h],[],
1653                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1654          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1655                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1656          EXPAT_LIBS="-lexpat"])
1657
1658     # put all the necessary libs together
1659     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1660 fi
1661
1662 AC_SUBST([DRI_LIB_DEPS])
1663
1664 DRI_DIRS=''
1665 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1666 if test -n "$with_dri_drivers"; then
1667     if test "x$enable_opengl" != xyes; then
1668         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1669     fi
1670
1671     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1672     for driver in $dri_drivers; do
1673         DRI_DIRS="$DRI_DIRS $driver"
1674         case "x$driver" in
1675         xi915)
1676             require_libdrm "i915"
1677             HAVE_I915_DRI=yes
1678             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1679             ;;
1680         xi965)
1681             require_libdrm "i965"
1682             HAVE_I965_DRI=yes
1683             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1684             ;;
1685         xnouveau)
1686             require_libdrm "nouveau"
1687             HAVE_NOUVEAU_DRI=yes
1688             PKG_CHECK_MODULES([NVVIEUX], [libdrm >= $LIBDRM_NVVIEUX_REQUIRED libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1689             ;;
1690         xradeon)
1691             require_libdrm "radeon"
1692             HAVE_RADEON_DRI=yes;
1693             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1694             ;;
1695         xr200)
1696             require_libdrm "r200"
1697             HAVE_R200_DRI=yes
1698             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1699             ;;
1700         xswrast)
1701             HAVE_SWRAST_DRI=yes
1702             ;;
1703         *)
1704             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1705             ;;
1706         esac
1707     done
1708     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1709 fi
1710
1711
1712 dnl
1713 dnl Gallium LLVM
1714 dnl Deprecated: kept for backwards compatibility
1715 dnl
1716 AC_ARG_ENABLE([gallium-llvm],
1717     [AS_HELP_STRING([--enable-gallium-llvm],
1718         [DEPRECATED: use --enable-llvm instead])],
1719     [enable_gallium_llvm="$enableval"],
1720     [enable_gallium_llvm=auto])
1721
1722 if test "x$enable_gallium_llvm" != xauto; then
1723    AC_MSG_WARN([The --enable-gallium-llvm option has been deprecated. Use --enable-llvm instead.])
1724    enable_llvm=$enable_gallium_llvm
1725 fi
1726
1727 dnl
1728 dnl LLVM
1729 dnl
1730 AC_ARG_ENABLE([llvm],
1731     [AS_HELP_STRING([--enable-llvm],
1732         [build with LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1733     [enable_llvm="$enableval"],
1734     [enable_llvm=auto])
1735
1736 if test "x$enable_llvm" = xauto -a "x$FOUND_LLVM" = xyes; then
1737     if test "x$FOUND_LLVM" = xyes; then
1738         case "$host_cpu" in
1739         i*86|x86_64|amd64) enable_llvm=yes;;
1740         *) enable_llvm=no;;
1741         esac
1742     else
1743         enable_llvm=no
1744     fi
1745 fi
1746
1747 if test "x$enable_llvm" = xyes -a "x$FOUND_LLVM" = xno; then
1748     AC_MSG_ERROR([--enable-llvm selected but llvm-config is not found])
1749 fi
1750
1751 #
1752 # Vulkan driver configuration
1753 #
1754
1755 AC_ARG_WITH([vulkan-drivers],
1756     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
1757         [comma delimited Vulkan drivers list, e.g.
1758         "intel,radeon"
1759         @<:@default=no@:>@])],
1760     [with_vulkan_drivers="$withval"],
1761     [with_vulkan_drivers="no"])
1762
1763 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
1764 # here so that the script doesn't choke on an unknown driver name later.
1765 case "x$with_vulkan_drivers" in
1766     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
1767     xno) with_vulkan_drivers='' ;;
1768 esac
1769
1770 AC_ARG_WITH([vulkan-icddir],
1771     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
1772         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
1773     [VULKAN_ICD_INSTALL_DIR="$withval"],
1774     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
1775 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
1776
1777 if test -n "$with_vulkan_drivers"; then
1778     if test "x$ac_cv_func_dl_iterate_phdr" = xno; then
1779         AC_MSG_ERROR([Vulkan drivers require the dl_iterate_phdr function])
1780     fi
1781
1782     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
1783     for driver in $VULKAN_DRIVERS; do
1784         case "x$driver" in
1785         xintel)
1786             if test "x$HAVE_I965_DRI" != xyes; then
1787                 AC_MSG_ERROR([Intel Vulkan driver requires the i965 dri driver])
1788             fi
1789             HAVE_INTEL_VULKAN=yes
1790
1791             ;;
1792         xradeon)
1793             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
1794             radeon_llvm_check $LLVM_REQUIRED_RADV "radv"
1795             HAVE_RADEON_VULKAN=yes
1796             ;;
1797         *)
1798             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
1799             ;;
1800         esac
1801     done
1802     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
1803 fi
1804
1805
1806 DEFINES="$DEFINES -DENABLE_SHADER_CACHE"
1807 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1808 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
1809                                   "x$enable_osmesa" = xyes -o \
1810                                   -n "$DRI_DIRS")
1811
1812 dnl
1813 dnl OSMesa configuration
1814 dnl
1815
1816 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1817 AC_ARG_WITH([osmesa-bits],
1818     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1819         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1820     [osmesa_bits="$withval"],
1821     [osmesa_bits=8])
1822 if test "x$osmesa_bits" != x8; then
1823     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
1824         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1825         osmesa_bits=8
1826     fi
1827 fi
1828 case "x$osmesa_bits" in
1829 x8)
1830     OSMESA_LIB="${OSMESA_LIB}"
1831     ;;
1832 x16|x32)
1833     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1834     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1835     ;;
1836 *)
1837     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1838     ;;
1839 esac
1840
1841 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1842     # only link libraries with osmesa if shared
1843     if test "$enable_static" = no; then
1844         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1845     else
1846         OSMESA_LIB_DEPS=""
1847     fi
1848     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1849 fi
1850
1851 AC_SUBST([OSMESA_LIB_DEPS])
1852 AC_SUBST([OSMESA_PC_REQ])
1853 AC_SUBST([OSMESA_PC_LIB_PRIV])
1854
1855 dnl
1856 dnl gbm configuration
1857 dnl
1858 if test "x$enable_gbm" = xyes; then
1859     require_dri_shared_libs_and_glapi "gbm"
1860 fi
1861 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1862 # FINISHME: GBM has a number of dependencies which we should add below
1863 GBM_PC_REQ_PRIV=""
1864 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1865 AC_SUBST([GBM_PC_REQ_PRIV])
1866 AC_SUBST([GBM_PC_LIB_PRIV])
1867
1868 dnl
1869 dnl EGL configuration
1870 dnl
1871
1872 if test "x$enable_egl" = xyes; then
1873     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1874
1875     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1876
1877     require_dri_shared_libs_and_glapi "egl"
1878 fi
1879 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1880 AC_SUBST([EGL_LIB_DEPS])
1881
1882 gallium_st="mesa"
1883
1884 dnl
1885 dnl XA configuration
1886 dnl
1887 if test "x$enable_xa" = xyes; then
1888     if test "x$with_gallium_drivers" = xswrast; then
1889        AC_MSG_ERROR([
1890           Building xa requires at least one non swrast gallium driver.
1891           If you are looking to use libxatracker.so with the VMware driver,
1892           make sure to include svga in the gallium drivers list, apart from
1893           enabling XA.
1894           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1895     fi
1896     gallium_st="$gallium_st xa"
1897 fi
1898 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1899
1900 dnl
1901 dnl Gallium G3DVL configuration
1902 dnl
1903 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1904     if test "x$enable_xvmc" = xauto; then
1905         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1906     fi
1907
1908     if test "x$enable_vdpau" = xauto; then
1909         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1910     fi
1911
1912     if test "x$enable_omx" = xauto; then
1913         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1914     fi
1915
1916     if test "x$enable_va" = xauto; then
1917         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1918     fi
1919 fi
1920
1921 if test "x$enable_dri" = xyes -o \
1922         "x$enable_xvmc" = xyes -o \
1923         "x$enable_vdpau" = xyes -o \
1924         "x$enable_omx" = xyes -o \
1925         "x$enable_va" = xyes; then
1926     need_gallium_vl=yes
1927 fi
1928 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1929
1930 if test "x$enable_xvmc" = xyes -o \
1931         "x$enable_vdpau" = xyes -o \
1932         "x$enable_omx" = xyes -o \
1933         "x$enable_va" = xyes; then
1934     if test x"$enable_dri3" = xyes; then
1935         PKG_CHECK_MODULES([VL], [xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED
1936                                  xcb-xfixes x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1937     else
1938         PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1939     fi
1940     need_gallium_vl_winsys=yes
1941 fi
1942 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
1943
1944 if test "x$enable_xvmc" = xyes; then
1945     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1946     gallium_st="$gallium_st xvmc"
1947 fi
1948 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1949
1950 if test "x$enable_vdpau" = xyes; then
1951     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1952     gallium_st="$gallium_st vdpau"
1953     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
1954 fi
1955 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1956
1957 if test "x$enable_omx" = xyes; then
1958     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
1959     gallium_st="$gallium_st omx"
1960 fi
1961 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1962
1963 if test "x$enable_va" = xyes; then
1964     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
1965     gallium_st="$gallium_st va"
1966 fi
1967 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1968
1969 dnl
1970 dnl Nine Direct3D9 configuration
1971 dnl
1972 if test "x$enable_nine" = xyes; then
1973     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1974         AC_MSG_ERROR([nine requires the gallium swrast driver])
1975     fi
1976     if test "x$with_gallium_drivers" = xswrast; then
1977         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
1978     fi
1979     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1980         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
1981     fi
1982
1983     if test "x$enable_dri3" = xno; then
1984         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
1985     fi
1986
1987     gallium_st="$gallium_st nine"
1988 fi
1989 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
1990
1991 dnl
1992 dnl OpenCL configuration
1993 dnl
1994
1995 AC_ARG_WITH([clang-libdir],
1996    [AS_HELP_STRING([--with-clang-libdir],
1997          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1998    [CLANG_LIBDIR="$withval"],
1999    [CLANG_LIBDIR=''])
2000
2001 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
2002
2003 if test "x$enable_opencl" = xyes; then
2004     if test -z "$with_gallium_drivers"; then
2005         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
2006     fi
2007
2008     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
2009         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
2010     fi
2011
2012     if test "x$have_libclc" = xno; then
2013         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
2014                     Make sure the directory containing libclc.pc is specified in your
2015                     PKG_CONFIG_PATH environment variable.
2016                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
2017     else
2018         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
2019         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
2020         AC_SUBST([LIBCLC_INCLUDEDIR])
2021         AC_SUBST([LIBCLC_LIBEXECDIR])
2022     fi
2023
2024     gallium_st="$gallium_st clover"
2025
2026     if test "x$enable_opencl_icd" = xyes; then
2027         OPENCL_LIBNAME="MesaOpenCL"
2028     else
2029         OPENCL_LIBNAME="OpenCL"
2030     fi
2031
2032     if test "x$have_libelf" != xyes; then
2033        AC_MSG_ERROR([Clover requires libelf])
2034     fi
2035
2036     llvm_require_version $LLVM_REQUIRED_OPENCL "opencl"
2037
2038     llvm_add_default_components "opencl"
2039     llvm_add_component "all-targets" "opencl"
2040     llvm_add_component "linker" "opencl"
2041     llvm_add_component "instrumentation" "opencl"
2042     llvm_add_component "ipo" "opencl"
2043     llvm_add_component "irreader" "opencl"
2044     llvm_add_component "option" "opencl"
2045     llvm_add_component "objcarcopts" "opencl"
2046     llvm_add_component "profiledata" "opencl"
2047
2048     dnl Check for Clang internal headers
2049     if test -z "$CLANG_LIBDIR"; then
2050         CLANG_LIBDIR=${LLVM_LIBDIR}
2051     fi
2052     CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2053     AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2054         [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2055 fi
2056 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2057 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2058 AC_SUBST([OPENCL_LIBNAME])
2059 AC_SUBST([CLANG_RESOURCE_DIR])
2060
2061 dnl
2062 dnl Gallium configuration
2063 dnl
2064 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2065
2066 dnl
2067 dnl EGL Platforms configuration
2068 dnl
2069 AC_ARG_WITH([egl-platforms],
2070     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
2071         [comma delimited native platforms libEGL supports, e.g.
2072         "x11,drm" @<:@default=auto@:>@])],
2073     [with_egl_platforms="$withval"],
2074     [if test "x$enable_egl" = xyes; then
2075         if test "x$enable_gbm" = xyes; then
2076            with_egl_platforms="x11,drm"
2077         else
2078            with_egl_platforms="x11"
2079         fi
2080     else
2081         with_egl_platforms=""
2082     fi])
2083
2084 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
2085     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
2086 fi
2087
2088 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
2089         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
2090         WAYLAND_SCANNER='')
2091 if test "x$WAYLAND_SCANNER" = x; then
2092     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
2093 fi
2094
2095 # Do per-EGL platform setups and checks
2096 egl_platforms=`IFS=', '; echo $with_egl_platforms`
2097 for plat in $egl_platforms; do
2098         case "$plat" in
2099         wayland)
2100
2101                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
2102
2103                 if test "x$WAYLAND_SCANNER" = x; then
2104                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
2105                 fi
2106                 ;;
2107
2108         x11)
2109                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
2110                 ;;
2111
2112         drm)
2113                 test "x$enable_gbm" = "xno" &&
2114                         AC_MSG_ERROR([EGL platform drm needs gbm])
2115                 ;;
2116
2117         surfaceless)
2118                 ;;
2119
2120         android)
2121                 PKG_CHECK_MODULES([ANDROID], [cutils hardware sync])
2122                 ;;
2123
2124         *)
2125                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
2126                 ;;
2127         esac
2128
2129         case "$plat" in
2130         wayland|drm|surfaceless)
2131                 require_libdrm "Platform $plat"
2132                 ;;
2133         esac
2134 done
2135
2136 # libEGL wants to default to the first platform specified in
2137 # ./configure.  parse that here.
2138 if test "x$egl_platforms" != "x"; then
2139     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2140     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2141 else
2142     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2143 fi
2144
2145 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
2146 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
2147 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
2148 AM_CONDITIONAL(HAVE_EGL_PLATFORM_SURFACELESS, echo "$egl_platforms" | grep -q 'surfaceless')
2149 AM_CONDITIONAL(HAVE_EGL_PLATFORM_ANDROID, echo "$egl_platforms" | grep -q 'android')
2150
2151 AC_SUBST([EGL_NATIVE_PLATFORM])
2152 AC_SUBST([EGL_CFLAGS])
2153
2154 # If we don't have the X11 platform, set this define so we don't try to include
2155 # the X11 headers.
2156 if ! echo "$egl_platforms" | grep -q 'x11'; then
2157     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2158     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2159 fi
2160
2161 dnl Directory for XVMC libs
2162 AC_ARG_WITH([xvmc-libdir],
2163     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2164         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2165     [XVMC_LIB_INSTALL_DIR="$withval"],
2166     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2167 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2168
2169 dnl
2170 dnl Gallium Tests
2171 dnl
2172 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2173
2174 dnl Directory for VDPAU libs
2175 AC_ARG_WITH([vdpau-libdir],
2176     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2177         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2178     [VDPAU_LIB_INSTALL_DIR="$withval"],
2179     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2180 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2181
2182 dnl Directory for OMX libs
2183
2184 AC_ARG_WITH([omx-libdir],
2185     [AS_HELP_STRING([--with-omx-libdir=DIR],
2186         [directory for the OMX libraries])],
2187     [OMX_LIB_INSTALL_DIR="$withval"],
2188     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2189 AC_SUBST([OMX_LIB_INSTALL_DIR])
2190
2191 dnl Directory for VA libs
2192
2193 AC_ARG_WITH([va-libdir],
2194     [AS_HELP_STRING([--with-va-libdir=DIR],
2195         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2196     [VA_LIB_INSTALL_DIR="$withval"],
2197     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2198 AC_SUBST([VA_LIB_INSTALL_DIR])
2199
2200 AC_ARG_WITH([d3d-libdir],
2201     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2202         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2203     [D3D_DRIVER_INSTALL_DIR="$withval"],
2204     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2205 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2206
2207 dnl
2208 dnl r300 doesn't strictly require LLVM, but for performance reasons we
2209 dnl highly recommend LLVM usage. So require it at least on x86 and x86_64
2210 dnl architectures.
2211 dnl
2212 r300_require_llvm() {
2213     case "$host" in *gnux32) return;; esac
2214     case "$host_cpu" in
2215     i*86|x86_64|amd64) require_llvm $1
2216         ;;
2217     esac
2218 }
2219
2220 dnl
2221 dnl DRM is needed by X, Wayland, and offscreen rendering.
2222 dnl Surfaceless is an alternative for the last one.
2223 dnl
2224 require_basic_egl() {
2225     case "$with_egl_platforms" in
2226         *drm*|*surfaceless*)
2227             ;;
2228         *)
2229             AC_MSG_ERROR([$1 requires one of these:
2230                   1) --with-egl-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2231                   2) --with-egl-platforms=surfaceless (offscreen only)
2232                   Recommended options: drm,x11])
2233             ;;
2234     esac
2235 }
2236
2237 swr_require_cxx_feature_flags() {
2238     feature_name="$1"
2239     preprocessor_test="$2"
2240     option_list="$3"
2241     output_var="$4"
2242
2243     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2244     AC_LANG_PUSH([C++])
2245     save_CXXFLAGS="$CXXFLAGS"
2246     save_IFS="$IFS"
2247     IFS=","
2248     found=0
2249     for opts in $option_list
2250     do
2251         unset IFS
2252         CXXFLAGS="$opts $save_CXXFLAGS"
2253         AC_COMPILE_IFELSE(
2254             [AC_LANG_PROGRAM(
2255                 [   #if !($preprocessor_test)
2256                     #error
2257                     #endif
2258                 ])],
2259             [found=1; break],
2260             [])
2261         IFS=","
2262     done
2263     IFS="$save_IFS"
2264     CXXFLAGS="$save_CXXFLAGS"
2265     AC_LANG_POP([C++])
2266     if test $found -eq 1; then
2267         AC_MSG_RESULT([$opts])
2268         eval "$output_var=\$opts"
2269         return 0
2270     fi
2271     AC_MSG_RESULT([no])
2272     AC_MSG_ERROR([swr requires $feature_name support])
2273     return 1
2274 }
2275
2276 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2277 if test -n "$with_gallium_drivers"; then
2278     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2279     for driver in $gallium_drivers; do
2280         case "x$driver" in
2281         xsvga)
2282             HAVE_GALLIUM_SVGA=yes
2283             require_libdrm "svga"
2284             ;;
2285         xi915)
2286             HAVE_GALLIUM_I915=yes
2287             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2288             require_libdrm "Gallium i915"
2289             ;;
2290         xr300)
2291             HAVE_GALLIUM_R300=yes
2292             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2293             require_libdrm "r300"
2294             r300_require_llvm "r300"
2295             ;;
2296         xr600)
2297             HAVE_GALLIUM_R600=yes
2298             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2299             require_libdrm "r600"
2300             if test "x$enable_opencl" = xyes; then
2301                 radeon_llvm_check $LLVM_REQUIRED_R600 "r600"
2302
2303                 llvm_add_component "asmparser" "r600"
2304                 llvm_add_component "bitreader" "r600"
2305             fi
2306             ;;
2307         xradeonsi)
2308             HAVE_GALLIUM_RADEONSI=yes
2309             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2310             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2311             require_libdrm "radeonsi"
2312             radeon_llvm_check $LLVM_REQUIRED_RADEONSI "radeonsi"
2313             require_basic_egl "radeonsi"
2314             ;;
2315         xnouveau)
2316             HAVE_GALLIUM_NOUVEAU=yes
2317             PKG_CHECK_MODULES([NOUVEAU], [libdrm >= $LIBDRM_NOUVEAU_REQUIRED libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2318             require_libdrm "nouveau"
2319             ;;
2320         xfreedreno)
2321             HAVE_GALLIUM_FREEDRENO=yes
2322             PKG_CHECK_MODULES([FREEDRENO], [libdrm >= $LIBDRM_FREEDRENO_REQUIRED libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2323             require_libdrm "freedreno"
2324             ;;
2325         xetnaviv)
2326             HAVE_GALLIUM_ETNAVIV=yes
2327             PKG_CHECK_MODULES([ETNAVIV], [libdrm >= $LIBDRM_ETNAVIV_REQUIRED libdrm_etnaviv >= $LIBDRM_ETNAVIV_REQUIRED])
2328             require_libdrm "etnaviv"
2329             ;;
2330        ximx)
2331             HAVE_GALLIUM_IMX=yes
2332             ;;
2333         xswrast)
2334             HAVE_GALLIUM_SOFTPIPE=yes
2335             if test "x$enable_llvm" = xyes; then
2336                 HAVE_GALLIUM_LLVMPIPE=yes
2337             fi
2338             ;;
2339         xswr)
2340             llvm_require_version $LLVM_REQUIRED_SWR "swr"
2341
2342             swr_require_cxx_feature_flags "C++11" "__cplusplus >= 201103L" \
2343                 ",-std=c++11" \
2344                 SWR_CXX11_CXXFLAGS
2345             AC_SUBST([SWR_CXX11_CXXFLAGS])
2346
2347             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2348                 ",-mavx,-march=core-avx" \
2349                 SWR_AVX_CXXFLAGS
2350             AC_SUBST([SWR_AVX_CXXFLAGS])
2351
2352             swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2353                 ",-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2" \
2354                 SWR_AVX2_CXXFLAGS
2355             AC_SUBST([SWR_AVX2_CXXFLAGS])
2356
2357             HAVE_GALLIUM_SWR=yes
2358             ;;
2359         xvc4)
2360             HAVE_GALLIUM_VC4=yes
2361             PKG_CHECK_MODULES([VC4], [libdrm >= $LIBDRM_VC4_REQUIRED libdrm_vc4 >= $LIBDRM_VC4_REQUIRED])
2362             require_libdrm "vc4"
2363
2364             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2365                               [USE_VC4_SIMULATOR=yes;
2366                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2367                               [USE_VC4_SIMULATOR=no])
2368             ;;
2369         xvirgl)
2370             HAVE_GALLIUM_VIRGL=yes
2371             require_libdrm "virgl"
2372             require_basic_egl "virgl"
2373             ;;
2374         *)
2375             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2376             ;;
2377         esac
2378     done
2379 fi
2380
2381 if test "x$enable_llvm" = "xyes" -a "$with_gallium_drivers"; then
2382     llvm_require_version $LLVM_REQUIRED_GALLIUM "gallium"
2383     llvm_add_default_components "gallium"
2384 fi
2385
2386 dnl We need to validate some needed dependencies for renderonly drivers.
2387
2388 if test "x$HAVE_GALLIUM_ETNAVIV" != xyes -a "x$HAVE_GALLIUM_IMX" = xyes  ; then
2389     AC_MSG_ERROR([Building with imx requires etnaviv])
2390 fi
2391
2392 dnl
2393 dnl Set defines and buildtime variables only when using LLVM.
2394 dnl
2395 if test "x$enable_llvm" = xyes; then
2396     DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2397
2398     LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2399     LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
2400     LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2401
2402     dnl Set LLVM_LIBS - This is done after the driver configuration so
2403     dnl that drivers can add additional components to LLVM_COMPONENTS.
2404     dnl Previously, gallium drivers were updating LLVM_LIBS directly
2405     dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2406     dnl this was causing the same libraries to be appear multiple times
2407     dnl in LLVM_LIBS.
2408
2409     if ! $LLVM_CONFIG --libs ${LLVM_COMPONENTS} >/dev/null; then
2410        AC_MSG_ERROR([Calling ${LLVM_CONFIG} failed])
2411     fi
2412     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2413
2414     dnl llvm-config may not give the right answer when llvm is a built as a
2415     dnl single shared library, so we must work the library name out for
2416     dnl ourselves.
2417     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2418     if test "x$enable_llvm_shared_libs" = xyes; then
2419         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2420         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2421         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2422
2423         if test "x$llvm_have_one_so" = xyes; then
2424             dnl LLVM was built using auto*, so there is only one shared object.
2425             LLVM_LIBS="-l$LLVM_SO_NAME"
2426         else
2427             dnl If LLVM was built with CMake, there will be one shared object per
2428             dnl component.
2429             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2430                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2431         Please make sure you have built llvm with the --enable-shared option
2432         and that your llvm libraries are installed in $LLVM_LIBDIR
2433         If you have installed your llvm libraries to a different directory you
2434         can use the --with-llvm-prefix= configure flag to specify this directory.
2435         NOTE: Mesa is attempting to use llvm shared libraries by default.
2436         If you do not want to build with llvm shared libraries and instead want to
2437         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2438         invocation and rebuild.])])
2439
2440            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2441            dnl install uses a shared object for each component and we have
2442            dnl already added all of these objects to LLVM_LIBS.
2443         fi
2444     else
2445         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2446         dnl We need to link to llvm system libs when using static libs
2447         dnl However, only llvm 3.5+ provides --system-libs
2448         if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2449             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2450         fi
2451     fi
2452 fi
2453
2454 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2455 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2456 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2457 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2458 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2459 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2460                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2461 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2462 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2463 AM_CONDITIONAL(HAVE_GALLIUM_ETNAVIV, test "x$HAVE_GALLIUM_ETNAVIV" = xyes)
2464 AM_CONDITIONAL(HAVE_GALLIUM_IMX, test "x$HAVE_GALLIUM_IMX" = xyes)
2465 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2466 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2467 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2468 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2469                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2470                                          "x$HAVE_GALLIUM_SWR" = xyes)
2471 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2472 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2473
2474 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2475
2476 if test "x$enable_dri" = xyes; then
2477     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2478 fi
2479
2480 if test "x$have_drisw_kms" = xyes; then
2481     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2482 fi
2483 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2484
2485 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2486 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2487 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2488 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2489 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2490 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2491
2492 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2493 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2494
2495 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_R600" = xyes -o \
2496                                       "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2497                                       "x$HAVE_RADEON_VULKAN" = xyes)
2498
2499 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2500                                         "x$HAVE_I965_DRI" = xyes)
2501
2502 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2503                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2504                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2505 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2506 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2507 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2508 AM_CONDITIONAL(HAVE_GALLIUM_LLVM, test "x$enable_llvm" = xyes)
2509 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2510
2511 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2512 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2513 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2514 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
2515                                         "x$enable_gallium_osmesa" = xyes)
2516
2517 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2518 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2519 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2520
2521 AC_SUBST([NINE_MAJOR], 1)
2522 AC_SUBST([NINE_MINOR], 0)
2523 AC_SUBST([NINE_TINY], 0)
2524 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2525
2526 AC_SUBST([VDPAU_MAJOR], 1)
2527 AC_SUBST([VDPAU_MINOR], 0)
2528
2529 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2530 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2531 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2532 AC_SUBST([VA_MINOR], $VA_MINOR)
2533
2534 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
2535
2536 AC_SUBST([XVMC_MAJOR], 1)
2537 AC_SUBST([XVMC_MINOR], 0)
2538
2539 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2540 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2541 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2542 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2543
2544 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2545 AC_SUBST([XA_MINOR], $XA_MINOR)
2546 AC_SUBST([XA_TINY], $XA_TINY)
2547 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2548
2549 AC_ARG_ENABLE(valgrind,
2550               [AS_HELP_STRING([--enable-valgrind],
2551                              [Build mesa with valgrind support (default: auto)])],
2552                              [VALGRIND=$enableval], [VALGRIND=auto])
2553 if test "x$VALGRIND" != xno; then
2554         PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2555 fi
2556 AC_MSG_CHECKING([whether to enable Valgrind support])
2557 if test "x$VALGRIND" = xauto; then
2558         VALGRIND="$have_valgrind"
2559 fi
2560
2561 if test "x$VALGRIND" = "xyes"; then
2562         if ! test "x$have_valgrind" = xyes; then
2563                 AC_MSG_ERROR([Valgrind support required but not present])
2564         fi
2565         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2566 fi
2567
2568 AC_MSG_RESULT([$VALGRIND])
2569
2570 dnl Restore LDFLAGS and CPPFLAGS
2571 LDFLAGS="$_SAVE_LDFLAGS"
2572 CPPFLAGS="$_SAVE_CPPFLAGS"
2573
2574 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2575 if test "x$acv_mesa_CLANG" = xyes; then
2576     CFLAGS="$CFLAGS -Qunused-arguments"
2577     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2578 fi
2579
2580 dnl Add user CFLAGS and CXXFLAGS
2581 CFLAGS="$CFLAGS $USER_CFLAGS"
2582 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2583
2584 dnl Substitute the config
2585 AC_CONFIG_FILES([Makefile
2586                 src/Makefile
2587                 src/amd/Makefile
2588                 src/amd/vulkan/Makefile
2589                 src/compiler/Makefile
2590                 src/egl/Makefile
2591                 src/egl/main/egl.pc
2592                 src/egl/wayland/wayland-drm/Makefile
2593                 src/egl/wayland/wayland-egl/Makefile
2594                 src/egl/wayland/wayland-egl/wayland-egl.pc
2595                 src/gallium/Makefile
2596                 src/gallium/auxiliary/Makefile
2597                 src/gallium/auxiliary/pipe-loader/Makefile
2598                 src/gallium/drivers/freedreno/Makefile
2599                 src/gallium/drivers/ddebug/Makefile
2600                 src/gallium/drivers/i915/Makefile
2601                 src/gallium/drivers/llvmpipe/Makefile
2602                 src/gallium/drivers/noop/Makefile
2603                 src/gallium/drivers/nouveau/Makefile
2604                 src/gallium/drivers/r300/Makefile
2605                 src/gallium/drivers/r600/Makefile
2606                 src/gallium/drivers/radeon/Makefile
2607                 src/gallium/drivers/radeonsi/Makefile
2608                 src/gallium/drivers/rbug/Makefile
2609                 src/gallium/drivers/softpipe/Makefile
2610                 src/gallium/drivers/svga/Makefile
2611                 src/gallium/drivers/swr/Makefile
2612                 src/gallium/drivers/trace/Makefile
2613                 src/gallium/drivers/etnaviv/Makefile
2614                 src/gallium/drivers/imx/Makefile
2615                 src/gallium/drivers/vc4/Makefile
2616                 src/gallium/drivers/virgl/Makefile
2617                 src/gallium/state_trackers/clover/Makefile
2618                 src/gallium/state_trackers/dri/Makefile
2619                 src/gallium/state_trackers/glx/xlib/Makefile
2620                 src/gallium/state_trackers/nine/Makefile
2621                 src/gallium/state_trackers/omx/Makefile
2622                 src/gallium/state_trackers/osmesa/Makefile
2623                 src/gallium/state_trackers/va/Makefile
2624                 src/gallium/state_trackers/vdpau/Makefile
2625                 src/gallium/state_trackers/xa/Makefile
2626                 src/gallium/state_trackers/xvmc/Makefile
2627                 src/gallium/targets/d3dadapter9/Makefile
2628                 src/gallium/targets/d3dadapter9/d3d.pc
2629                 src/gallium/targets/dri/Makefile
2630                 src/gallium/targets/libgl-xlib/Makefile
2631                 src/gallium/targets/omx/Makefile
2632                 src/gallium/targets/opencl/Makefile
2633                 src/gallium/targets/opencl/mesa.icd
2634                 src/gallium/targets/osmesa/Makefile
2635                 src/gallium/targets/osmesa/osmesa.pc
2636                 src/gallium/targets/pipe-loader/Makefile
2637                 src/gallium/targets/va/Makefile
2638                 src/gallium/targets/vdpau/Makefile
2639                 src/gallium/targets/xa/Makefile
2640                 src/gallium/targets/xa/xatracker.pc
2641                 src/gallium/targets/xvmc/Makefile
2642                 src/gallium/tests/trivial/Makefile
2643                 src/gallium/tests/unit/Makefile
2644                 src/gallium/winsys/etnaviv/drm/Makefile
2645                 src/gallium/winsys/imx/drm/Makefile
2646                 src/gallium/winsys/freedreno/drm/Makefile
2647                 src/gallium/winsys/i915/drm/Makefile
2648                 src/gallium/winsys/nouveau/drm/Makefile
2649                 src/gallium/winsys/radeon/drm/Makefile
2650                 src/gallium/winsys/amdgpu/drm/Makefile
2651                 src/gallium/winsys/svga/drm/Makefile
2652                 src/gallium/winsys/sw/dri/Makefile
2653                 src/gallium/winsys/sw/kms-dri/Makefile
2654                 src/gallium/winsys/sw/null/Makefile
2655                 src/gallium/winsys/sw/wrapper/Makefile
2656                 src/gallium/winsys/sw/xlib/Makefile
2657                 src/gallium/winsys/vc4/drm/Makefile
2658                 src/gallium/winsys/virgl/drm/Makefile
2659                 src/gallium/winsys/virgl/vtest/Makefile
2660                 src/gbm/Makefile
2661                 src/gbm/main/gbm.pc
2662                 src/glx/Makefile
2663                 src/glx/apple/Makefile
2664                 src/glx/tests/Makefile
2665                 src/glx/windows/Makefile
2666                 src/glx/windows/windowsdriproto.pc
2667                 src/gtest/Makefile
2668                 src/intel/Makefile
2669                 src/intel/tools/Makefile
2670                 src/intel/vulkan/Makefile
2671                 src/loader/Makefile
2672                 src/mapi/Makefile
2673                 src/mapi/es1api/glesv1_cm.pc
2674                 src/mapi/es2api/glesv2.pc
2675                 src/mapi/glapi/gen/Makefile
2676                 src/mesa/Makefile
2677                 src/mesa/gl.pc
2678                 src/mesa/drivers/dri/dri.pc
2679                 src/mesa/drivers/dri/common/Makefile
2680                 src/mesa/drivers/dri/common/xmlpool/Makefile
2681                 src/mesa/drivers/dri/i915/Makefile
2682                 src/mesa/drivers/dri/i965/Makefile
2683                 src/mesa/drivers/dri/Makefile
2684                 src/mesa/drivers/dri/nouveau/Makefile
2685                 src/mesa/drivers/dri/r200/Makefile
2686                 src/mesa/drivers/dri/radeon/Makefile
2687                 src/mesa/drivers/dri/swrast/Makefile
2688                 src/mesa/drivers/osmesa/Makefile
2689                 src/mesa/drivers/osmesa/osmesa.pc
2690                 src/mesa/drivers/x11/Makefile
2691                 src/mesa/main/tests/Makefile
2692                 src/util/Makefile
2693                 src/util/tests/hash_table/Makefile
2694                 src/vulkan/Makefile])
2695
2696 AC_OUTPUT
2697
2698 # Fix up dependencies in *.Plo files, where we changed the extension of a
2699 # source file
2700 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
2701
2702
2703 dnl
2704 dnl Output some configuration info for the user
2705 dnl
2706 echo ""
2707 echo "        prefix:          $prefix"
2708 echo "        exec_prefix:     $exec_prefix"
2709 echo "        libdir:          $libdir"
2710 echo "        includedir:      $includedir"
2711
2712 dnl API info
2713 echo ""
2714 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2715
2716 dnl Driver info
2717 echo ""
2718 case "x$enable_osmesa$enable_gallium_osmesa" in
2719 xnoyes)
2720         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2721         ;;
2722 xyesno)
2723         echo "        OSMesa:          lib$OSMESA_LIB"
2724         ;;
2725 xnono)
2726         echo "        OSMesa:          no"
2727         ;;
2728 esac
2729
2730 echo ""
2731 if test "x$enable_dri" != xno; then
2732         echo "        DRI platform:    $dri_platform"
2733         if test -z "$DRI_DIRS"; then
2734             echo "        DRI drivers:     no"
2735         else
2736             echo "        DRI drivers:     $DRI_DIRS"
2737         fi
2738         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2739 fi
2740
2741 case "x$enable_glx" in
2742 xdri)
2743     echo "        GLX:             DRI-based"
2744     ;;
2745 xxlib)
2746     echo "        GLX:             Xlib-based"
2747     ;;
2748 xgallium-xlib)
2749     echo "        GLX:             Xlib-based (Gallium)"
2750     ;;
2751 *)
2752     echo "        GLX:             $enable_glx"
2753     ;;
2754 esac
2755
2756 dnl EGL
2757 echo ""
2758 echo "        EGL:             $enable_egl"
2759 if test "$enable_egl" = yes; then
2760     echo "        EGL platforms:   $egl_platforms"
2761
2762     egl_drivers=""
2763     if test "x$enable_dri" != "xno"; then
2764         egl_drivers="$egl_drivers builtin:egl_dri2"
2765     fi
2766     if test "x$enable_dri3" != "xno"; then
2767         egl_drivers="$egl_drivers builtin:egl_dri3"
2768     fi
2769
2770     echo "        EGL drivers:    $egl_drivers"
2771 fi
2772 if test "x$enable_gbm" = xyes; then
2773     echo "        GBM:             yes"
2774 else
2775     echo "        GBM:             no"
2776 fi
2777
2778 # Vulkan
2779 echo ""
2780 if test "x$VULKAN_DRIVERS" != x; then
2781     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
2782     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
2783 else
2784     echo "        Vulkan drivers:  no"
2785 fi
2786
2787 echo ""
2788 if test "x$enable_llvm" = xyes; then
2789     echo "        llvm:            yes"
2790     echo "        llvm-config:     $LLVM_CONFIG"
2791     echo "        llvm-version:    $LLVM_VERSION"
2792 else
2793     echo "        llvm:            no"
2794 fi
2795
2796 echo ""
2797 if test -n "$with_gallium_drivers"; then
2798     echo "        Gallium drivers: $gallium_drivers"
2799     echo "        Gallium st:      $gallium_st"
2800 else
2801     echo "        Gallium:         no"
2802 fi
2803
2804 echo ""
2805 if test "x$enable_gallium_extra_hud" != xyes; then
2806     echo "        HUD extra stats: no"
2807 else
2808     echo "        HUD extra stats: yes"
2809 fi
2810
2811 if test "x$enable_lmsensors" != xyes; then
2812     echo "        HUD lmsensors:   no"
2813 else
2814     echo "        HUD lmsensors:   yes"
2815 fi
2816
2817 dnl Libraries
2818 echo ""
2819 echo "        Shared libs:     $enable_shared"
2820 echo "        Static libs:     $enable_static"
2821 echo "        Shared-glapi:    $enable_shared_glapi"
2822
2823 dnl Compiler options
2824 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2825 cflags=`echo $CFLAGS | \
2826     $SED 's/^ *//;s/  */ /;s/ *$//'`
2827 cxxflags=`echo $CXXFLAGS | \
2828     $SED 's/^ *//;s/  */ /;s/ *$//'`
2829 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2830 echo ""
2831 echo "        CFLAGS:          $cflags"
2832 echo "        CXXFLAGS:        $cxxflags"
2833 echo "        Macros:          $defines"
2834 echo ""
2835 if test "x$enable_llvm" = xyes; then
2836     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2837     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2838     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2839     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
2840     echo ""
2841 fi
2842 echo "        PYTHON2:         $PYTHON2"
2843
2844 echo ""
2845 echo "        Run '${MAKE-make}' to build Mesa"
2846 echo ""