configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl Copyright © 2003-2007 Keith Packard, Daniel Stone
  13 dnl
  14 dnl Permission is hereby granted, free of charge, to any person obtaining a
  15 dnl copy of this software and associated documentation files (the "Software"),
  16 dnl to deal in the Software without restriction, including without limitation
  17 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  18 dnl and/or sell copies of the Software, and to permit persons to whom the
  19 dnl Software is furnished to do so, subject to the following conditions:
  20 dnl
  21 dnl The above copyright notice and this permission notice (including the next
  22 dnl paragraph) shall be included in all copies or substantial portions of the
  23 dnl Software.
  24 dnl
  25 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  26 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  27 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  28 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  29 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  30 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  31 dnl DEALINGS IN THE SOFTWARE.
  32 dnl
  33 dnl Process this file with autoconf to create configure.
  34
  35 AC_PREREQ([2.60])
  36
  37 dnl Tell the user about autoconf.html in the --help output
  38 m4_divert_once([HELP_END], [
  39 See docs/autoconf.html for more details on the options for Mesa.])
  40
  41 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  42 AC_INIT([Mesa], [MESA_VERSION],
  43     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  44 AC_CONFIG_AUX_DIR([bin])
  45 AC_CONFIG_MACRO_DIR([m4])
  46 AC_CANONICAL_SYSTEM
  47 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz])
  48
  49 # Support silent build rules, requires at least automake-1.11. Disable
  50 # by either passing --disable-silent-rules to configure or passing V=1
  51 # to make
  52 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  53     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  54
  55 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  56
  57 dnl Set internal versions
  58 OSMESA_VERSION=8
  59 AC_SUBST([OSMESA_VERSION])
  60
  61 dnl Versions for external dependencies
  62 LIBDRM_REQUIRED=2.4.38
  63 LIBDRM_RADEON_REQUIRED=2.4.56
  64 LIBDRM_INTEL_REQUIRED=2.4.52
  65 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  66 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  67 LIBDRM_FREEDRENO_REQUIRED=2.4.57
  68 DRI2PROTO_REQUIRED=2.6
  69 DRI3PROTO_REQUIRED=1.0
  70 PRESENTPROTO_REQUIRED=1.0
  71 LIBUDEV_REQUIRED=151
  72 GLPROTO_REQUIRED=1.4.14
  73 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  74 LIBVA_REQUIRED=0.35.0
  75 VDPAU_REQUIRED=0.4.1
  76 WAYLAND_REQUIRED=1.2.0
  77 XCB_REQUIRED=1.9.3
  78 XCBDRI2_REQUIRED=1.8
  79 XCBGLX_REQUIRED=1.8.1
  80 XSHMFENCE_REQUIRED=1.1
  81 XVMC_REQUIRED=1.0.6
  82
  83 dnl Check for progs
  84 AC_PROG_CPP
  85 AC_PROG_CC
  86 AC_PROG_CXX
  87 AM_PROG_CC_C_O
  88 AM_PROG_AS
  89 AX_CHECK_GNU_MAKE
  90 AC_CHECK_PROGS([PYTHON2], [python2 python])
  91 AC_PROG_SED
  92 AC_PROG_MKDIR_P
  93
  94 AC_SYS_LARGEFILE
  95
  96 LT_PREREQ([2.2])
  97 LT_INIT([disable-static])
  98
  99 AX_PROG_BISON([],
 100               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
 101                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 102 AX_PROG_FLEX([],
 103              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
 104                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 105
 106 AC_CHECK_PROG(INDENT, indent, indent, cat)
 107 if test "x$INDENT" != "xcat"; then
 108     # Only GNU indent is supported
 109     INDENT_VERSION=`indent --version | grep GNU`
 110     if test $? -eq 0; then
 111        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 112     else
 113        INDENT="cat"
 114     fi
 115 fi
 116
 117 AX_CHECK_PYTHON_MAKO_MODULE(0.3.4)
 118
 119 AC_PROG_INSTALL
 120
 121 dnl We need a POSIX shell for parts of the build. Assume we have one
 122 dnl in most cases.
 123 case "$host_os" in
 124 solaris*)
 125     # Solaris /bin/sh is too old/non-POSIX compliant
 126     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 127     SHELL="$POSIX_SHELL"
 128     ;;
 129 esac
 130
 131 dnl clang is mostly GCC-compatible, but its version is much lower,
 132 dnl so we have to check for it.
 133 AC_MSG_CHECKING([if compiling with clang])
 134
 135 AC_COMPILE_IFELSE(
 136 [AC_LANG_PROGRAM([], [[
 137 #ifndef __clang__
 138        not clang
 139 #endif
 140 ]])],
 141 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 142
 143 AC_MSG_RESULT([$acv_mesa_CLANG])
 144
 145 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 146 dnl versions are explictly not supported.
 147 GEN_ASM_OFFSETS=no
 148 USE_GNU99=no
 149 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 150     AC_MSG_CHECKING([whether gcc version is sufficient])
 151     major=0
 152     minor=0
 153
 154     GCC_VERSION=`$CC -dumpversion`
 155     if test $? -eq 0; then
 156         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 157         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 158     fi
 159
 160     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 161         AC_MSG_RESULT([no])
 162         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 163     else
 164         AC_MSG_RESULT([yes])
 165     fi
 166
 167     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 168         USE_GNU99=yes
 169     fi
 170     if test "x$cross_compiling" = xyes; then
 171         GEN_ASM_OFFSETS=yes
 172     fi
 173 fi
 174
 175 dnl Check for compiler builtins
 176 AX_GCC_BUILTIN([__builtin_bswap32])
 177 AX_GCC_BUILTIN([__builtin_bswap64])
 178 AX_GCC_BUILTIN([__builtin_clz])
 179 AX_GCC_BUILTIN([__builtin_clzll])
 180 AX_GCC_BUILTIN([__builtin_ctz])
 181 AX_GCC_BUILTIN([__builtin_expect])
 182 AX_GCC_BUILTIN([__builtin_ffs])
 183 AX_GCC_BUILTIN([__builtin_ffsll])
 184 AX_GCC_BUILTIN([__builtin_popcount])
 185 AX_GCC_BUILTIN([__builtin_popcountll])
 186 AX_GCC_BUILTIN([__builtin_unreachable])
 187
 188 AX_GCC_FUNC_ATTRIBUTE([flatten])
 189 AX_GCC_FUNC_ATTRIBUTE([format])
 190 AX_GCC_FUNC_ATTRIBUTE([malloc])
 191 AX_GCC_FUNC_ATTRIBUTE([packed])
 192
 193 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 194
 195 dnl Make sure the pkg-config macros are defined
 196 m4_ifndef([PKG_PROG_PKG_CONFIG],
 197     [m4_fatal([Could not locate the pkg-config autoconf macros.
 198   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 199   are in a different location, try setting the environment variable
 200   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 201 PKG_PROG_PKG_CONFIG()
 202
 203 dnl LIB_DIR - library basename
 204 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 205 AC_SUBST([LIB_DIR])
 206
 207 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 208 _SAVE_LDFLAGS="$LDFLAGS"
 209 _SAVE_CPPFLAGS="$CPPFLAGS"
 210
 211 dnl Compiler macros
 212 DEFINES="-DUSE_EXTERNAL_DXTN_LIB=1"
 213 AC_SUBST([DEFINES])
 214 case "$host_os" in
 215 linux*|*-gnu*|gnu*)
 216     DEFINES="$DEFINES -D_GNU_SOURCE"
 217     ;;
 218 solaris*)
 219     DEFINES="$DEFINES -DSVR4"
 220     ;;
 221 cygwin*)
 222     DEFINES="$DEFINES -D_XOPEN_SOURCE=700"
 223     ;;
 224 esac
 225
 226 dnl Add flags for gcc and g++
 227 if test "x$GCC" = xyes; then
 228     CFLAGS="$CFLAGS -Wall"
 229
 230     if test "x$USE_GNU99" = xyes; then
 231         CFLAGS="$CFLAGS -std=gnu99"
 232     else
 233         CFLAGS="$CFLAGS -std=c99"
 234     fi
 235
 236     # Enable -Werror=implicit-function-declaration and
 237     # -Werror=missing-prototypes, if available, or otherwise, just
 238     # -Wmissing-prototypes.  This is particularly useful to avoid
 239     # generating a loadable driver module that has undefined symbols.
 240     save_CFLAGS="$CFLAGS"
 241     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 242     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 243     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 244     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 245                    AC_MSG_RESULT([yes]),
 246                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 247                     AC_MSG_RESULT([no])]);
 248
 249     # Enable -fvisibility=hidden if using a gcc that supports it
 250     save_CFLAGS="$CFLAGS"
 251     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 252     VISIBILITY_CFLAGS="-fvisibility=hidden"
 253     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 254     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 255                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 256
 257     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 258     CFLAGS=$save_CFLAGS
 259
 260     # Work around aliasing bugs - developers should comment this out
 261     CFLAGS="$CFLAGS -fno-strict-aliasing"
 262
 263     # gcc's builtin memcmp is slower than glibc's
 264     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 265     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 266 fi
 267 if test "x$GXX" = xyes; then
 268     CXXFLAGS="$CXXFLAGS -Wall"
 269
 270     # Enable -fvisibility=hidden if using a gcc that supports it
 271     save_CXXFLAGS="$CXXFLAGS"
 272     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 273     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 274     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 275     AC_LANG_PUSH([C++])
 276     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 277                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 278     AC_LANG_POP([C++])
 279
 280     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 281     CXXFLAGS=$save_CXXFLAGS
 282
 283     # Work around aliasing bugs - developers should comment this out
 284     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 285
 286     # gcc's builtin memcmp is slower than glibc's
 287     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 288     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 289 fi
 290
 291 dnl even if the compiler appears to support it, using visibility attributes isn't
 292 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 293 case "$host_os" in
 294 cygwin*)
 295     VISIBILITY_CFLAGS=""
 296     VISIBILITY_CXXFLAGS=""
 297     ;;
 298 esac
 299
 300 AC_SUBST([VISIBILITY_CFLAGS])
 301 AC_SUBST([VISIBILITY_CXXFLAGS])
 302
 303 dnl
 304 dnl Optional flags, check for compiler support
 305 dnl
 306 SSE41_CFLAGS="-msse4.1"
 307 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 308 dnl stack, but on x86-32 such alignment is not guaranteed.
 309 case "$target_cpu" in
 310 i?86)
 311     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 312     ;;
 313 esac
 314 save_CFLAGS="$CFLAGS"
 315 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 316 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 317 #include <smmintrin.h>
 318 int main () {
 319     __m128i a = _mm_set1_epi32 (0), b = _mm_set1_epi32 (0), c;
 320     c = _mm_max_epu32(a, b);
 321     return 0;
 322 }]])], SSE41_SUPPORTED=1)
 323 CFLAGS="$save_CFLAGS"
 324 if test "x$SSE41_SUPPORTED" = x1; then
 325     DEFINES="$DEFINES -DUSE_SSE41"
 326 fi
 327 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 328 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 329
 330 dnl Can't have static and shared libraries, default to static if user
 331 dnl explicitly requested. If both disabled, set to static since shared
 332 dnl was explicitly requested.
 333 case "x$enable_static$enable_shared" in
 334 xyesyes)
 335     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 336     enable_shared=no
 337     ;;
 338 xnono)
 339     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 340     enable_shared=yes
 341     ;;
 342 esac
 343
 344 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 345
 346 dnl
 347 dnl other compiler options
 348 dnl
 349 AC_ARG_ENABLE([debug],
 350     [AS_HELP_STRING([--enable-debug],
 351         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 352     [enable_debug="$enableval"],
 353     [enable_debug=no]
 354 )
 355 if test "x$enable_debug" = xyes; then
 356     DEFINES="$DEFINES -DDEBUG"
 357     if test "x$GCC" = xyes; then
 358         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 359             CFLAGS="$CFLAGS -g"
 360         fi
 361         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 362             CFLAGS="$CFLAGS -O0"
 363         fi
 364     fi
 365     if test "x$GXX" = xyes; then
 366         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 367             CXXFLAGS="$CXXFLAGS -g"
 368         fi
 369         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 370             CXXFLAGS="$CXXFLAGS -O0"
 371         fi
 372     fi
 373 else
 374    DEFINES="$DEFINES -DNDEBUG"
 375 fi
 376
 377 dnl
 378 dnl Check if linker supports -Bsymbolic
 379 dnl
 380 save_LDFLAGS=$LDFLAGS
 381 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 382 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 383 AC_LINK_IFELSE(
 384     [AC_LANG_SOURCE([int main() { return 0;}])],
 385     [AC_MSG_RESULT([yes])
 386         BSYMBOLIC="-Wl,-Bsymbolic";],
 387     [AC_MSG_RESULT([no])
 388         BSYMBOLIC="";])
 389 LDFLAGS=$save_LDFLAGS
 390
 391 AC_SUBST([BSYMBOLIC])
 392
 393 dnl
 394 dnl Check if linker supports garbage collection
 395 dnl
 396 save_LDFLAGS=$LDFLAGS
 397 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 398 AC_MSG_CHECKING([whether ld supports --gc-sections])
 399 AC_LINK_IFELSE(
 400     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 401     [AC_MSG_RESULT([yes])
 402         GC_SECTIONS="-Wl,--gc-sections";],
 403     [AC_MSG_RESULT([no])
 404         GC_SECTIONS="";])
 405 LDFLAGS=$save_LDFLAGS
 406
 407 AC_SUBST([GC_SECTIONS])
 408
 409 dnl
 410 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 411 dnl so when these flags are passed to ld via libtool the checks will fail
 412 dnl
 413 case "$host_os" in
 414 openbsd* | darwin* )
 415     LD_NO_UNDEFINED="" ;;
 416 *)
 417     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 418 esac
 419
 420 AC_SUBST([LD_NO_UNDEFINED])
 421
 422 dnl
 423 dnl Check if linker supports version scripts
 424 dnl
 425 AC_MSG_CHECKING([if the linker supports version-scripts])
 426 save_LDFLAGS=$LDFLAGS
 427 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 428 cat > conftest.map <<EOF
 429 VERSION_1 {
 430      global:
 431          main;
 432
 433      local:
 434          *;
 435 };
 436 EOF
 437 AC_LINK_IFELSE(
 438     [AC_LANG_SOURCE([int main() { return 0;}])],
 439     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 440     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 441 LDFLAGS=$save_LDFLAGS
 442 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 443
 444 dnl
 445 dnl Check if linker supports dynamic list files
 446 dnl
 447 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 448 save_LDFLAGS=$LDFLAGS
 449 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 450 cat > conftest.dyn <<EOF
 451 {
 452         radeon_drm_winsys_create;
 453 };
 454 EOF
 455 AC_LINK_IFELSE(
 456     [AC_LANG_SOURCE([int main() { return 0;}])],
 457     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 458     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 459 LDFLAGS=$save_LDFLAGS
 460 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 461
 462 dnl
 463 dnl compatibility symlinks
 464 dnl
 465 case "$host_os" in
 466 linux* )
 467     HAVE_COMPAT_SYMLINKS=yes ;;
 468 * )
 469     HAVE_COMPAT_SYMLINKS=no ;;
 470 esac
 471
 472 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 473
 474 dnl
 475 dnl library names
 476 dnl
 477 case "$host_os" in
 478 darwin* )
 479     LIB_EXT='dylib' ;;
 480 cygwin* )
 481     LIB_EXT='dll' ;;
 482 aix* )
 483     LIB_EXT='a' ;;
 484 * )
 485     LIB_EXT='so' ;;
 486 esac
 487
 488 AC_SUBST([LIB_EXT])
 489
 490 AC_ARG_WITH([gl-lib-name],
 491   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 492     [specify GL library name @<:@default=GL@:>@])],
 493   [GL_LIB=$withval],
 494   [GL_LIB=GL])
 495 AC_ARG_WITH([osmesa-lib-name],
 496   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 497     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 498   [OSMESA_LIB=$withval],
 499   [OSMESA_LIB=OSMesa])
 500 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 501 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 502
 503 dnl
 504 dnl Mangled Mesa support
 505 dnl
 506 AC_ARG_ENABLE([mangling],
 507   [AS_HELP_STRING([--enable-mangling],
 508     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 509   [enable_mangling="${enableval}"],
 510   [enable_mangling=no]
 511 )
 512 if test "x${enable_mangling}" = "xyes" ; then
 513   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 514   GL_LIB="Mangled${GL_LIB}"
 515   OSMESA_LIB="Mangled${OSMESA_LIB}"
 516 fi
 517 AC_SUBST([GL_LIB])
 518 AC_SUBST([OSMESA_LIB])
 519
 520 dnl
 521 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 522 dnl
 523 AC_ARG_ENABLE([texture-float],
 524     [AS_HELP_STRING([--enable-texture-float],
 525         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 526     [enable_texture_float="$enableval"],
 527     [enable_texture_float=no]
 528 )
 529 if test "x$enable_texture_float" = xyes; then
 530     AC_MSG_WARN([Floating-point textures enabled.])
 531     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 532     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 533 fi
 534
 535 dnl
 536 dnl Arch/platform-specific settings
 537 dnl
 538 AC_ARG_ENABLE([asm],
 539     [AS_HELP_STRING([--disable-asm],
 540         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 541     [enable_asm="$enableval"],
 542     [enable_asm=yes]
 543 )
 544 asm_arch=""
 545 AC_MSG_CHECKING([whether to enable assembly])
 546 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 547 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 548 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 549     case "$host_cpu" in
 550     i?86 | x86_64 | amd64)
 551         enable_asm=no
 552         AC_MSG_RESULT([no, cross compiling])
 553         ;;
 554     esac
 555 fi
 556 # check for supported arches
 557 if test "x$enable_asm" = xyes; then
 558     case "$host_cpu" in
 559     i?86)
 560         case "$host_os" in
 561         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 562             asm_arch=x86
 563             ;;
 564         esac
 565         ;;
 566     x86_64|amd64)
 567         case "$host_os" in
 568         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 569             asm_arch=x86_64
 570             ;;
 571         esac
 572         ;;
 573     sparc*)
 574         case "$host_os" in
 575         linux*)
 576             asm_arch=sparc
 577             ;;
 578         esac
 579         ;;
 580     esac
 581
 582     case "$asm_arch" in
 583     x86)
 584         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 585         AC_MSG_RESULT([yes, x86])
 586         ;;
 587     x86_64|amd64)
 588         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 589         AC_MSG_RESULT([yes, x86_64])
 590         ;;
 591     sparc)
 592         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 593         AC_MSG_RESULT([yes, sparc])
 594         ;;
 595     *)
 596         AC_MSG_RESULT([no, platform not supported])
 597         ;;
 598     esac
 599 fi
 600
 601 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 602 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 603
 604 dnl Check to see if dlopen is in default libraries (like Solaris, which
 605 dnl has it in libc), or if libdl is needed to get it.
 606 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 607     [AC_CHECK_LIB([dl], [dlopen],
 608        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 609 AC_SUBST([DLOPEN_LIBS])
 610
 611 dnl Check if that library also has dladdr
 612 save_LIBS="$LIBS"
 613 LIBS="$LIBS $DLOPEN_LIBS"
 614 AC_CHECK_FUNCS([dladdr])
 615 LIBS="$save_LIBS"
 616
 617 case "$host_os" in
 618 darwin*|mingw*)
 619     ;;
 620 *)
 621     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 622                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 623                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 624     AC_SUBST([CLOCK_LIB])
 625     ;;
 626 esac
 627
 628 dnl See if posix_memalign is available
 629 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 630
 631 dnl Check for pthreads
 632 case "$host_os" in
 633 mingw*)
 634     ;;
 635 *)
 636     AX_PTHREAD
 637     ;;
 638 esac
 639 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 640 dnl to -pthread, which causes problems if we need -lpthread to appear in
 641 dnl pkgconfig files.
 642 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 643
 644 dnl SELinux awareness.
 645 AC_ARG_ENABLE([selinux],
 646     [AS_HELP_STRING([--enable-selinux],
 647         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 648     [MESA_SELINUX="$enableval"],
 649     [MESA_SELINUX=no])
 650 if test "x$enable_selinux" = "xyes"; then
 651     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 652         [AC_CHECK_HEADER([selinux/selinux.h],[],
 653                          [AC_MSG_ERROR([SELinux headers not found])])
 654          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 655                       [AC_MSG_ERROR([SELinux library not found])])
 656          SELINUX_LIBS="-lselinux"])
 657     DEFINES="$DEFINES -DMESA_SELINUX"
 658 fi
 659 AC_SUBST([SELINUX_CFLAGS])
 660 AC_SUBST([SELINUX_LIBS])
 661
 662 dnl Options for APIs
 663 AC_ARG_ENABLE([opengl],
 664     [AS_HELP_STRING([--disable-opengl],
 665         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
 666     [enable_opengl="$enableval"],
 667     [enable_opengl=yes])
 668 AC_ARG_ENABLE([gles1],
 669     [AS_HELP_STRING([--enable-gles1],
 670         [enable support for OpenGL ES 1.x API @<:@default=disabled@:>@])],
 671     [enable_gles1="$enableval"],
 672     [enable_gles1=no])
 673 AC_ARG_ENABLE([gles2],
 674     [AS_HELP_STRING([--enable-gles2],
 675         [enable support for OpenGL ES 2.x API @<:@default=disabled@:>@])],
 676     [enable_gles2="$enableval"],
 677     [enable_gles2=no])
 678 AC_ARG_ENABLE([openvg],
 679     [AS_HELP_STRING([--enable-openvg],
 680         [enable support for OpenVG API @<:@default=disabled@:>@])],
 681     [enable_openvg="$enableval"],
 682     [enable_openvg=no])
 683
 684 AC_ARG_ENABLE([dri],
 685     [AS_HELP_STRING([--enable-dri],
 686         [enable DRI modules @<:@default=enabled@:>@])],
 687     [enable_dri="$enableval"],
 688     [enable_dri=yes])
 689
 690 case "$host_os" in
 691 linux*)
 692     dri3_default=yes
 693     ;;
 694 *)
 695     dri3_default=no
 696     ;;
 697 esac
 698 AC_ARG_ENABLE([dri3],
 699     [AS_HELP_STRING([--enable-dri3],
 700         [enable DRI3 @<:@default=auto@:>@])],
 701     [enable_dri3="$enableval"],
 702     [enable_dri3="$dri3_default"])
 703 AC_ARG_ENABLE([glx],
 704     [AS_HELP_STRING([--enable-glx],
 705         [enable GLX library @<:@default=enabled@:>@])],
 706     [enable_glx="$enableval"],
 707     [enable_glx=yes])
 708 AC_ARG_ENABLE([osmesa],
 709     [AS_HELP_STRING([--enable-osmesa],
 710         [enable OSMesa library @<:@default=disabled@:>@])],
 711     [enable_osmesa="$enableval"],
 712     [enable_osmesa=no])
 713 AC_ARG_ENABLE([gallium-osmesa],
 714     [AS_HELP_STRING([--enable-gallium-osmesa],
 715         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 716     [enable_gallium_osmesa="$enableval"],
 717     [enable_gallium_osmesa=no])
 718 AC_ARG_ENABLE([egl],
 719     [AS_HELP_STRING([--disable-egl],
 720         [disable EGL library @<:@default=enabled@:>@])],
 721     [enable_egl="$enableval"],
 722     [enable_egl=yes])
 723
 724 AC_ARG_ENABLE([xa],
 725     [AS_HELP_STRING([--enable-xa],
 726         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
 727     [enable_xa="$enableval"],
 728     [enable_xa=no])
 729 AC_ARG_ENABLE([gbm],
 730    [AS_HELP_STRING([--enable-gbm],
 731          [enable gbm library @<:@default=auto@:>@])],
 732    [enable_gbm="$enableval"],
 733    [enable_gbm=auto])
 734 AC_ARG_ENABLE([nine],
 735     [AS_HELP_STRING([--enable-nine],
 736         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
 737     [enable_nine="$enableval"],
 738     [enable_nine=no])
 739
 740 AC_ARG_ENABLE([xvmc],
 741    [AS_HELP_STRING([--enable-xvmc],
 742          [enable xvmc library @<:@default=auto@:>@])],
 743    [enable_xvmc="$enableval"],
 744    [enable_xvmc=auto])
 745 AC_ARG_ENABLE([vdpau],
 746    [AS_HELP_STRING([--enable-vdpau],
 747          [enable vdpau library @<:@default=auto@:>@])],
 748    [enable_vdpau="$enableval"],
 749    [enable_vdpau=auto])
 750 AC_ARG_ENABLE([omx],
 751    [AS_HELP_STRING([--enable-omx],
 752          [enable OpenMAX library @<:@default=disabled@:>@])],
 753    [enable_omx="$enableval"],
 754    [enable_omx=no])
 755 AC_ARG_ENABLE([va],
 756    [AS_HELP_STRING([--enable-va],
 757          [enable va library @<:@default=auto@:>@])],
 758    [enable_va="$enableval"],
 759    [enable_va=auto])
 760 AC_ARG_ENABLE([opencl],
 761    [AS_HELP_STRING([--enable-opencl],
 762          [enable OpenCL library @<:@default=disabled@:>@])],
 763    [enable_opencl="$enableval"],
 764    [enable_opencl=no])
 765 AC_ARG_ENABLE([opencl_icd],
 766    [AS_HELP_STRING([--enable-opencl-icd],
 767           [Build an OpenCL ICD library to be loaded by an ICD implementation
 768            @<:@default=disabled@:>@])],
 769     [enable_opencl_icd="$enableval"],
 770     [enable_opencl_icd=no])
 771 AC_ARG_ENABLE([xlib-glx],
 772     [AS_HELP_STRING([--enable-xlib-glx],
 773         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 774     [enable_xlib_glx="$enableval"],
 775     [enable_xlib_glx=no])
 776
 777 AC_ARG_ENABLE([r600-llvm-compiler],
 778     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 779         [Enable experimental LLVM backend for graphics shaders @<:@default=disabled@:>@])],
 780     [enable_r600_llvm="$enableval"],
 781     [enable_r600_llvm=no])
 782
 783 AC_ARG_ENABLE([gallium-tests],
 784     [AS_HELP_STRING([--enable-gallium-tests],
 785         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
 786     [enable_gallium_tests="$enableval"],
 787     [enable_gallium_tests=no])
 788
 789 # Option for Gallium drivers
 790
 791 # Keep this in sync with the --with-gallium-drivers help string default value
 792 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 793
 794 AC_ARG_WITH([gallium-drivers],
 795     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 796         [comma delimited Gallium drivers list, e.g.
 797         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4"
 798         @<:@default=r300,r600,svga,swrast@:>@])],
 799     [with_gallium_drivers="$withval"],
 800     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 801
 802 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 803 # here so that the script doesn't choke on an unknown driver name later.
 804 case "$with_gallium_drivers" in
 805     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 806     no) with_gallium_drivers='' ;;
 807 esac
 808
 809 if test "x$enable_opengl" = xno -a \
 810         "x$enable_gles1" = xno -a \
 811         "x$enable_gles2" = xno -a \
 812         "x$enable_nine" = xno -a \
 813         "x$enable_openvg" = xno -a \
 814         "x$enable_xa" = xno -a \
 815         "x$enable_xvmc" = xno -a \
 816         "x$enable_vdpau" = xno -a \
 817         "x$enable_omx" = xno -a \
 818         "x$enable_va" = xno -a \
 819         "x$enable_opencl" = xno; then
 820     AC_MSG_ERROR([at least one API should be enabled])
 821 fi
 822
 823 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 824 if test "x$enable_opengl" = xno -a \
 825         "x$enable_gles1" = xyes; then
 826     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 827 fi
 828
 829 if test "x$enable_opengl" = xno -a \
 830         "x$enable_gles2" = xyes; then
 831     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 832 fi
 833
 834 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 835 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 836 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 837 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 838                                         "x$enable_gles1" = xyes -o \
 839                                         "x$enable_gles2" = xyes)
 840
 841 if test "x$enable_glx" = xno; then
 842     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 843     enable_xlib_glx=no
 844 fi
 845
 846 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 847     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 848 fi
 849
 850 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 851     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 852 fi
 853
 854 # Disable GLX if OpenGL is not enabled
 855 if test "x$enable_glx$enable_opengl" = xyesno; then
 856     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 857     enable_glx=no
 858 fi
 859
 860 # Disable GLX if DRI and Xlib-GLX are not enabled
 861 if test "x$enable_glx" = xyes -a \
 862         "x$enable_dri" = xno -a \
 863         "x$enable_xlib_glx" = xno; then
 864     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 865     enable_glx=no
 866 fi
 867
 868 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 869                                   "x$enable_dri" = xyes)
 870
 871 # Select which platform-dependent DRI code gets built
 872 case "$host_os" in
 873 darwin*)
 874     dri_platform='apple' ;;
 875 gnu*|mingw*|cygwin*)
 876     dri_platform='none' ;;
 877 *)
 878     dri_platform='drm' ;;
 879 esac
 880
 881 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
 882 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
 883 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm )
 884 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm )
 885 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
 886
 887 AC_ARG_ENABLE([shared-glapi],
 888     [AS_HELP_STRING([--enable-shared-glapi],
 889         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
 890     [enable_shared_glapi="$enableval"],
 891     [enable_shared_glapi=yes])
 892
 893 case "x$enable_opengl$enable_gles1$enable_gles2" in
 894 x*yes*yes*)
 895     if test "x$enable_shared_glapi" = xno; then
 896         AC_MSG_ERROR([shared GLAPI required when building two or more of
 897                       the following APIs - opengl, gles1 gles2])
 898     fi
 899     ;;
 900 esac
 901
 902 # Building Xlib-GLX requires shared glapi to be disabled.
 903 if test "x$enable_xlib_glx" = xyes; then
 904     AC_MSG_NOTICE([Shared GLAPI should not used with Xlib-GLX, disabling])
 905     enable_shared_glapi=no
 906 fi
 907
 908 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 909
 910 # Build the pipe-drivers as separate libraries/modules.
 911 # Do not touch this unless you know what you are doing.
 912 # XXX: Expose via configure option ?
 913 enable_shared_pipe_drivers=no
 914
 915 dnl
 916 dnl Driver specific build directories
 917 dnl
 918
 919 case "x$enable_glx$enable_xlib_glx" in
 920 xyesyes)
 921     NEED_WINSYS_XLIB="yes"
 922     ;;
 923 esac
 924
 925 if test "x$enable_dri" = xyes; then
 926     enable_gallium_loader="$enable_shared_pipe_drivers"
 927 fi
 928
 929 if test "x$enable_gallium_osmesa" = xyes; then
 930     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
 931         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
 932     fi
 933     if test "x$enable_osmesa" = xyes; then
 934         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 935     fi
 936 fi
 937
 938 AC_SUBST([MESA_LLVM])
 939
 940 # SHA1 hashing
 941 AC_ARG_WITH([sha1],
 942         [AS_HELP_STRING([--with-sha1=libc|libmd|libnettle|libgcrypt|libcrypto|libsha1|CommonCrypto|CryptoAPI],
 943         [choose SHA1 implementation])])
 944 case "x$with_sha1" in
 945 x | xlibc | xlibmd | xlibnettle | xlibgcrypt | xlibcrypto | xlibsha1 | xCommonCrypto | xCryptoAPI)
 946   ;;
 947 *)
 948         AC_MSG_ERROR([Illegal value for --with-sha1: $with_sha1])
 949 esac
 950
 951 AC_CHECK_FUNC([SHA1Init], [HAVE_SHA1_IN_LIBC=yes])
 952 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_LIBC" = xyes; then
 953         with_sha1=libc
 954 fi
 955 if test "x$with_sha1" = xlibc && test "x$HAVE_SHA1_IN_LIBC" != xyes; then
 956         AC_MSG_ERROR([sha1 in libc requested but not found])
 957 fi
 958 if test "x$with_sha1" = xlibc; then
 959         AC_DEFINE([HAVE_SHA1_IN_LIBC], [1],
 960                 [Use libc SHA1 functions])
 961         SHA1_LIBS=""
 962 fi
 963 AC_CHECK_FUNC([CC_SHA1_Init], [HAVE_SHA1_IN_COMMONCRYPTO=yes])
 964 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_COMMONCRYPTO" = xyes; then
 965         with_sha1=CommonCrypto
 966 fi
 967 if test "x$with_sha1" = xCommonCrypto && test "x$HAVE_SHA1_IN_COMMONCRYPTO" != xyes; then
 968         AC_MSG_ERROR([CommonCrypto requested but not found])
 969 fi
 970 if test "x$with_sha1" = xCommonCrypto; then
 971         AC_DEFINE([HAVE_SHA1_IN_COMMONCRYPTO], [1],
 972                 [Use CommonCrypto SHA1 functions])
 973         SHA1_LIBS=""
 974 fi
 975 dnl stdcall functions cannot be tested with AC_CHECK_LIB
 976 AC_CHECK_HEADER([wincrypt.h], [HAVE_SHA1_IN_CRYPTOAPI=yes], [], [#include <windows.h>])
 977 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_CRYPTOAPI" = xyes; then
 978         with_sha1=CryptoAPI
 979 fi
 980 if test "x$with_sha1" = xCryptoAPI && test "x$HAVE_SHA1_IN_CRYPTOAPI" != xyes; then
 981         AC_MSG_ERROR([CryptoAPI requested but not found])
 982 fi
 983 if test "x$with_sha1" = xCryptoAPI; then
 984         AC_DEFINE([HAVE_SHA1_IN_CRYPTOAPI], [1],
 985                 [Use CryptoAPI SHA1 functions])
 986         SHA1_LIBS=""
 987 fi
 988 AC_CHECK_LIB([md], [SHA1Init], [HAVE_LIBMD=yes])
 989 if test "x$with_sha1" = x && test "x$HAVE_LIBMD" = xyes; then
 990         with_sha1=libmd
 991 fi
 992 if test "x$with_sha1" = xlibmd && test "x$HAVE_LIBMD" != xyes; then
 993         AC_MSG_ERROR([libmd requested but not found])
 994 fi
 995 if test "x$with_sha1" = xlibmd; then
 996         AC_DEFINE([HAVE_SHA1_IN_LIBMD], [1],
 997                   [Use libmd SHA1 functions])
 998         SHA1_LIBS=-lmd
 999 fi
1000 PKG_CHECK_MODULES([LIBSHA1], [libsha1], [HAVE_LIBSHA1=yes], [HAVE_LIBSHA1=no])
1001 if test "x$with_sha1" = x && test "x$HAVE_LIBSHA1" = xyes; then
1002    with_sha1=libsha1
1003 fi
1004 if test "x$with_sha1" = xlibsha1 && test "x$HAVE_LIBSHA1" != xyes; then
1005         AC_MSG_ERROR([libsha1 requested but not found])
1006 fi
1007 if test "x$with_sha1" = xlibsha1; then
1008         AC_DEFINE([HAVE_SHA1_IN_LIBSHA1], [1],
1009                   [Use libsha1 for SHA1])
1010         SHA1_LIBS=-lsha1
1011 fi
1012 AC_CHECK_LIB([nettle], [nettle_sha1_init], [HAVE_LIBNETTLE=yes])
1013 if test "x$with_sha1" = x && test "x$HAVE_LIBNETTLE" = xyes; then
1014         with_sha1=libnettle
1015 fi
1016 if test "x$with_sha1" = xlibnettle && test "x$HAVE_LIBNETTLE" != xyes; then
1017         AC_MSG_ERROR([libnettle requested but not found])
1018 fi
1019 if test "x$with_sha1" = xlibnettle; then
1020         AC_DEFINE([HAVE_SHA1_IN_LIBNETTLE], [1],
1021                   [Use libnettle SHA1 functions])
1022         SHA1_LIBS=-lnettle
1023 fi
1024 AC_CHECK_LIB([gcrypt], [gcry_md_open], [HAVE_LIBGCRYPT=yes])
1025 if test "x$with_sha1" = x && test "x$HAVE_LIBGCRYPT" = xyes; then
1026         with_sha1=libgcrypt
1027 fi
1028 if test "x$with_sha1" = xlibgcrypt && test "x$HAVE_LIBGCRYPT" != xyes; then
1029         AC_MSG_ERROR([libgcrypt requested but not found])
1030 fi
1031 if test "x$with_sha1" = xlibgcrypt; then
1032         AC_DEFINE([HAVE_SHA1_IN_LIBGCRYPT], [1],
1033                   [Use libgcrypt SHA1 functions])
1034         SHA1_LIBS=-lgcrypt
1035 fi
1036 # We don't need all of the OpenSSL libraries, just libcrypto
1037 AC_CHECK_LIB([crypto], [SHA1_Init], [HAVE_LIBCRYPTO=yes])
1038 PKG_CHECK_MODULES([OPENSSL], [openssl], [HAVE_OPENSSL_PKC=yes],
1039                   [HAVE_OPENSSL_PKC=no])
1040 if test "x$HAVE_LIBCRYPTO" = xyes || test "x$HAVE_OPENSSL_PKC" = xyes; then
1041         if test "x$with_sha1" = x; then
1042                 with_sha1=libcrypto
1043         fi
1044 else
1045         if test "x$with_sha1" = xlibcrypto; then
1046                 AC_MSG_ERROR([OpenSSL libcrypto requested but not found])
1047         fi
1048 fi
1049 if test "x$with_sha1" = xlibcrypto; then
1050         if test "x$HAVE_LIBCRYPTO" = xyes; then
1051                 SHA1_LIBS=-lcrypto
1052         else
1053                 SHA1_LIBS="$OPENSSL_LIBS"
1054                 SHA1_CFLAGS="$OPENSSL_CFLAGS"
1055         fi
1056 fi
1057 AC_MSG_CHECKING([for SHA1 implementation])
1058 AC_MSG_RESULT([$with_sha1])
1059 AC_SUBST(SHA1_LIBS)
1060 AC_SUBST(SHA1_CFLAGS)
1061
1062 # Allow user to configure out the shader-cache feature
1063 AC_ARG_ENABLE([shader-cache],
1064     AS_HELP_STRING([--disable-shader-cache], [Disable binary shader cache]),
1065     [enable_shader_cache="$enableval"],
1066     [if test "x$with_sha1" != "x"; then
1067         enable_shader_cache=yes
1068      else
1069         enable_shader_cache=no
1070      fi])
1071 if test "x$with_sha1" = "x"; then
1072     if test "x$enable_shader_cache" = "xyes"; then
1073         AC_MSG_ERROR([Cannot enable shader cache (no SHA-1 implementation found)])
1074     fi
1075 fi
1076 AM_CONDITIONAL([ENABLE_SHADER_CACHE], [test x$enable_shader_cache = xyes])
1077
1078 # Check for libdrm
1079 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1080                   [have_libdrm=yes], [have_libdrm=no])
1081 if test "x$have_libdrm" = xyes; then
1082         DEFINES="$DEFINES -DHAVE_LIBDRM"
1083 fi
1084
1085 case "$host_os" in
1086 linux*)
1087     need_pci_id=yes ;;
1088 *)
1089     need_pci_id=no ;;
1090 esac
1091
1092 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
1093                   have_libudev=yes, have_libudev=no)
1094
1095 AC_ARG_ENABLE([sysfs],
1096     [AS_HELP_STRING([--enable-sysfs],
1097         [enable /sys PCI identification @<:@default=disabled@:>@])],
1098     [have_sysfs="$enableval"],
1099     [have_sysfs=no]
1100 )
1101
1102 if test "x$enable_dri" = xyes; then
1103     if test "$enable_static" = yes; then
1104         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
1105     fi
1106
1107     # not a hard requirement as swrast does not depend on it
1108     if test "x$have_libdrm" = xyes; then
1109         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1110     fi
1111 fi
1112
1113 AC_ARG_ENABLE([driglx-direct],
1114     [AS_HELP_STRING([--disable-driglx-direct],
1115         [disable direct rendering in GLX and EGL for DRI \
1116             @<:@default=auto@:>@])],
1117     [driglx_direct="$enableval"],
1118     [driglx_direct="yes"])
1119
1120 dnl
1121 dnl libGL configuration per driver
1122 dnl
1123 case "x$enable_glx$enable_xlib_glx" in
1124 xyesyes)
1125     # Xlib-based GLX
1126     dri_modules="x11 xext xcb"
1127     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1128     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1129     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1130     GL_LIB_DEPS="$XLIBGL_LIBS"
1131     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1132     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1133     ;;
1134 xyesno)
1135     # DRI-based GLX
1136     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1137
1138     # find the DRI deps for libGL
1139     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1140
1141     if test x"$driglx_direct" = xyes; then
1142         if test x"$dri_platform" = xdrm ; then
1143             DEFINES="$DEFINES -DGLX_USE_DRM"
1144             if test "x$have_libdrm" != xyes; then
1145                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
1146             fi
1147
1148             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1149             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1150             if test x"$enable_dri3" = xyes; then
1151                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1152                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1153             fi
1154
1155             if test x"$enable_dri" = xyes; then
1156                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1157             fi
1158
1159             if test x"$enable_dri3" = xyes; then
1160                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1161                dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1162             fi
1163         fi
1164         if test x"$dri_platform" = xapple ; then
1165             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1166         fi
1167     fi
1168
1169     # add xf86vidmode if available
1170     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1171     if test "$HAVE_XF86VIDMODE" = yes ; then
1172         dri_modules="$dri_modules xxf86vm"
1173     fi
1174
1175     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1176     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1177     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1178     GL_LIB_DEPS="$DRIGL_LIBS"
1179
1180     # need DRM libs, $PTHREAD_LIBS, etc.
1181     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1182     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1183     ;;
1184 esac
1185
1186 have_pci_id=no
1187 if test "$have_libudev" = yes; then
1188     DEFINES="$DEFINES -DHAVE_LIBUDEV"
1189     have_pci_id=yes
1190 fi
1191
1192 if test "$have_sysfs" = yes; then
1193     DEFINES="$DEFINES -DHAVE_SYSFS"
1194     have_pci_id=yes
1195 fi
1196
1197 # This is outside the case (above) so that it is invoked even for non-GLX
1198 # builds.
1199 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1200
1201 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1202 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1203 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1204 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1205
1206 AC_SUBST([X11_INCLUDES])
1207 AC_SUBST([GL_LIB_DEPS])
1208 AC_SUBST([GL_PC_REQ_PRIV])
1209 AC_SUBST([GL_PC_LIB_PRIV])
1210 AC_SUBST([GL_PC_CFLAGS])
1211 AC_SUBST([DRI_PC_REQ_PRIV])
1212 AC_SUBST([GLESv1_CM_LIB_DEPS])
1213 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1214 AC_SUBST([GLESv2_LIB_DEPS])
1215 AC_SUBST([GLESv2_PC_LIB_PRIV])
1216
1217 AC_SUBST([HAVE_XF86VIDMODE])
1218
1219 dnl
1220 dnl More GLX setup
1221 dnl
1222 case "x$enable_glx$enable_xlib_glx" in
1223 xyesyes)
1224     DEFINES="$DEFINES -DUSE_XSHM"
1225     ;;
1226 xyesno)
1227     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1228     if test "x$driglx_direct" = xyes; then
1229         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1230     fi
1231     ;;
1232 esac
1233
1234 dnl
1235 dnl TLS detection
1236 dnl
1237
1238 AC_ARG_ENABLE([glx-tls],
1239     [AS_HELP_STRING([--enable-glx-tls],
1240         [enable TLS support in GLX @<:@default=disabled@:>@])],
1241     [GLX_USE_TLS="$enableval"],
1242     [GLX_USE_TLS=no])
1243 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1244
1245 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1246       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1247
1248 dnl
1249 dnl More DRI setup
1250 dnl
1251 dnl Directory for DRI drivers
1252 AC_ARG_WITH([dri-driverdir],
1253     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1254         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1255     [DRI_DRIVER_INSTALL_DIR="$withval"],
1256     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1257 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1258 dnl Extra search path for DRI drivers
1259 AC_ARG_WITH([dri-searchpath],
1260     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1261         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1262     [DRI_DRIVER_SEARCH_DIR="$withval"],
1263     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1264 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1265 dnl Which drivers to build - default is chosen by platform
1266 AC_ARG_WITH([dri-drivers],
1267     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1268         [comma delimited classic DRI drivers list, e.g.
1269         "swrast,i965,radeon" @<:@default=auto@:>@])],
1270     [with_dri_drivers="$withval"],
1271     [with_dri_drivers=auto])
1272
1273 if test "x$with_dri_drivers" = xauto; then
1274     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1275         with_dri_drivers="yes"
1276     else
1277         with_dri_drivers="no"
1278     fi
1279 fi
1280 if test "x$with_dri_drivers" = xno; then
1281     with_dri_drivers=''
1282 fi
1283
1284 dnl If $with_dri_drivers is yes, drivers will be added through
1285 dnl platform checks. Set DEFINES and LIB_DEPS
1286 if test "x$enable_dri" = xyes; then
1287     # Platform specific settings and drivers to build
1288     case "$host_os" in
1289     linux*)
1290         DEFINES="$DEFINES -DHAVE_ALIAS"
1291         if test "x$enable_dri3" = xyes; then
1292             DEFINES="$DEFINES -DHAVE_DRI3"
1293         fi
1294
1295         if test "x$have_pci_id" != xyes; then
1296             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1297         fi
1298
1299         case "$host_cpu" in
1300         powerpc* | sparc*)
1301             # Build only the drivers for cards that exist on PowerPC/sparc
1302             if test "x$with_dri_drivers" = "xyes"; then
1303                 with_dri_drivers="r200 radeon swrast"
1304             fi
1305             ;;
1306         esac
1307         ;;
1308     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1309         DEFINES="$DEFINES -DHAVE_ALIAS"
1310         ;;
1311     gnu*)
1312         DEFINES="$DEFINES -DHAVE_ALIAS"
1313         ;;
1314     cygwin*)
1315         if test "x$with_dri_drivers" = "xyes"; then
1316             with_dri_drivers="swrast"
1317         fi
1318         ;;
1319     darwin*)
1320         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED"
1321         if test "x$with_dri_drivers" = "xyes"; then
1322             with_dri_drivers="swrast"
1323         fi
1324         ;;
1325     esac
1326
1327     # default drivers
1328     if test "x$with_dri_drivers" = "xyes"; then
1329         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1330     fi
1331
1332     # Check for expat
1333     PKG_CHECK_MODULES([EXPAT], [expat], [],
1334         # expat version 2.0 and earlier do not provide expat.pc
1335         [AC_CHECK_HEADER([expat.h],[],
1336                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1337          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1338                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1339          EXPAT_LIBS="-lexpat"])
1340
1341     DRICOMMON_NEED_LIBDRM=no
1342     # If we are building any DRI driver other than swrast.
1343     if test -n "$with_dri_drivers"; then
1344         if test "x$with_dri_drivers" != xswrast; then
1345             # ... libdrm is required
1346             if test "x$have_libdrm" != xyes; then
1347                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1348             fi
1349             DRICOMMON_NEED_LIBDRM=yes
1350         fi
1351     fi
1352
1353     # If we're building any gallium DRI driver other than swrast
1354     if test -n "$with_gallium_drivers" -a "x$DRICOMMON_NEED_LIBDRM" = xno; then
1355         if test "x$with_gallium_drivers" != xswrast; then
1356             # ... build a libdrm aware dricommon
1357             DRICOMMON_NEED_LIBDRM=yes
1358         fi
1359     fi
1360
1361     # put all the necessary libs together
1362     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1363 fi
1364
1365 AC_SUBST([DRI_LIB_DEPS])
1366
1367 DRI_DIRS=''
1368 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1369 if test -n "$with_dri_drivers"; then
1370     if test "x$enable_opengl" != xyes; then
1371         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1372     fi
1373
1374     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1375     for driver in $dri_drivers; do
1376         DRI_DIRS="$DRI_DIRS $driver"
1377         case "x$driver" in
1378         xi915)
1379             HAVE_I915_DRI=yes;
1380             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1381             ;;
1382         xi965)
1383             HAVE_I965_DRI=yes;
1384             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1385             ;;
1386         xnouveau)
1387             HAVE_NOUVEAU_DRI=yes;
1388             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1389             ;;
1390         xradeon)
1391             HAVE_RADEON_DRI=yes;
1392             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1393             ;;
1394         xr200)
1395             HAVE_R200_DRI=yes;
1396             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1397             ;;
1398         xswrast)
1399             HAVE_SWRAST_DRI=yes;
1400             ;;
1401         *)
1402             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1403             ;;
1404         esac
1405     done
1406     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1407 fi
1408
1409 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1410 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1411                                   "x$enable_osmesa" = xyes -o \
1412                                   -n "$DRI_DIRS")
1413
1414 dnl
1415 dnl OSMesa configuration
1416 dnl
1417
1418 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1419 AC_ARG_WITH([osmesa-bits],
1420     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1421         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1422     [osmesa_bits="$withval"],
1423     [osmesa_bits=8])
1424 if test "x$osmesa_bits" != x8; then
1425     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1426         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1427         osmesa_bits=8
1428     fi
1429 fi
1430 case "x$osmesa_bits" in
1431 x8)
1432     OSMESA_LIB="${OSMESA_LIB}"
1433     ;;
1434 x16|x32)
1435     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1436     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1437     ;;
1438 *)
1439     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1440     ;;
1441 esac
1442
1443 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1444     # only link libraries with osmesa if shared
1445     if test "$enable_static" = no; then
1446         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1447     else
1448         OSMESA_LIB_DEPS=""
1449     fi
1450     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1451 fi
1452
1453 AC_SUBST([OSMESA_LIB_DEPS])
1454 AC_SUBST([OSMESA_PC_REQ])
1455 AC_SUBST([OSMESA_PC_LIB_PRIV])
1456
1457 dnl
1458 dnl gbm configuration
1459 dnl
1460 if test "x$enable_gbm" = xauto; then
1461     case "$with_egl_platforms" in
1462         *drm*)
1463             enable_gbm=yes ;;
1464          *)
1465             enable_gbm=no ;;
1466     esac
1467 fi
1468 if test "x$enable_gbm" = xyes; then
1469     if test "x$need_pci_id$have_pci_id" = xyesno; then
1470         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1471     fi
1472
1473     if test "x$enable_dri" = xyes; then
1474         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1475         if test "x$enable_shared_glapi" = xno; then
1476             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1477         fi
1478     else
1479         # Strictly speaking libgbm does not require --enable-dri, although
1480         # both of its backends do. Thus one can build libgbm without any
1481         # backends if --disable-dri is set.
1482         # To avoid unnecessary complexity of checking if at least one backend
1483         # is available when building, just mandate --enable-dri.
1484         AC_MSG_ERROR([gbm requires --enable-dri])
1485     fi
1486 fi
1487 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1488 if test "x$need_pci_id$have_libudev" = xyesyes; then
1489     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1490 else
1491     GBM_PC_REQ_PRIV=""
1492 fi
1493 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1494 AC_SUBST([GBM_PC_REQ_PRIV])
1495 AC_SUBST([GBM_PC_LIB_PRIV])
1496
1497 dnl
1498 dnl EGL configuration
1499 dnl
1500 EGL_CLIENT_APIS=""
1501
1502 if test "x$enable_egl" = xyes; then
1503     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1504
1505     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1506
1507     if test "$enable_static" != yes; then
1508         if test "x$enable_dri" = xyes; then
1509             HAVE_EGL_DRIVER_DRI2=1
1510         fi
1511
1512     fi
1513 fi
1514 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1515 AC_SUBST([EGL_LIB_DEPS])
1516
1517 dnl
1518 dnl XA configuration
1519 dnl
1520 if test "x$enable_xa" = xyes; then
1521     if test "x$with_gallium_drivers" = xswrast; then
1522        AC_MSG_ERROR([
1523           Building xa requires at least one non swrast gallium driver.
1524           If you are looking to use libxatracker.so with the VMware driver,
1525           make sure to include svga in the gallium drivers list, apart from
1526           enabling XA.
1527           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1528     fi
1529     enable_gallium_loader=$enable_shared_pipe_drivers
1530 fi
1531 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1532
1533 dnl
1534 dnl OpenVG configuration
1535 dnl
1536 VG_LIB_DEPS=""
1537
1538 if test "x$enable_openvg" = xyes; then
1539     if test "x$enable_egl" = xno; then
1540         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1541     fi
1542     if test -z "$with_gallium_drivers"; then
1543         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1544     fi
1545
1546     AC_MSG_ERROR([Cannot enable OpenVG, because egl_gallium has been removed and
1547                   OpenVG has not been integrated into standard libEGL yet])
1548
1549     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1550     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1551     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1552     AC_SUBST([VG_PC_LIB_PRIV])
1553 fi
1554 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1555
1556 dnl
1557 dnl Gallium G3DVL configuration
1558 dnl
1559 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1560     if test "x$enable_xvmc" = xauto; then
1561         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1562     fi
1563
1564     if test "x$enable_vdpau" = xauto; then
1565         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1566     fi
1567
1568     if test "x$enable_omx" = xauto; then
1569         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1570     fi
1571
1572     if test "x$enable_va" = xauto; then
1573         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1574     fi
1575 fi
1576
1577 if test "x$enable_dri" = xyes -o \
1578         "x$enable_xvmc" = xyes -o \
1579         "x$enable_vdpau" = xyes -o \
1580         "x$enable_omx" = xyes -o \
1581         "x$enable_va" = xyes; then
1582     need_gallium_vl=yes
1583 fi
1584 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1585
1586 if test "x$enable_xvmc" = xyes -o \
1587         "x$enable_vdpau" = xyes -o \
1588         "x$enable_omx" = xyes -o \
1589         "x$enable_va" = xyes; then
1590     PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1591     need_gallium_vl_winsys=yes
1592 fi
1593 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
1594
1595 if test "x$enable_xvmc" = xyes; then
1596     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1597     enable_gallium_loader=$enable_shared_pipe_drivers
1598 fi
1599 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1600
1601 if test "x$enable_vdpau" = xyes; then
1602     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1603     enable_gallium_loader=$enable_shared_pipe_drivers
1604 fi
1605 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1606
1607 if test "x$enable_omx" = xyes; then
1608     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
1609     enable_gallium_loader=$enable_shared_pipe_drivers
1610 fi
1611 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1612
1613 if test "x$enable_va" = xyes; then
1614     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
1615     enable_gallium_loader=$enable_shared_pipe_drivers
1616 fi
1617 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1618
1619 dnl
1620 dnl Nine Direct3D9 configuration
1621 dnl
1622 if test "x$enable_nine" = xyes; then
1623     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1624         AC_MSG_ERROR([nine requires the gallium swrast driver])
1625     fi
1626     if test "x$with_gallium_drivers" == xswrast; then
1627         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
1628     fi
1629     if test "x$enable_dri3" = xno; then
1630         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
1631     fi
1632
1633     enable_gallium_loader=$enable_shared_pipe_drivers
1634 fi
1635 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
1636
1637 dnl
1638 dnl OpenCL configuration
1639 dnl
1640
1641 AC_ARG_WITH([libclc-path],
1642    [AS_HELP_STRING([--with-libclc-path],
1643          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1644    [LIBCLC_PATH="$withval"],
1645    [LIBCLC_PATH=''])
1646
1647 if test -n "$LIBCLC_PATH"; then
1648    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1649                   Please review the updated build instructions for clover:
1650                   http://dri.freedesktop.org/wiki/GalliumCompute])
1651 fi
1652
1653
1654 AC_ARG_WITH([clang-libdir],
1655    [AS_HELP_STRING([--with-clang-libdir],
1656          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1657    [CLANG_LIBDIR="$withval"],
1658    [CLANG_LIBDIR=''])
1659
1660 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1661 AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;ELF_LIB=-lelf])
1662
1663 if test "x$enable_opencl" = xyes; then
1664     if test -z "$with_gallium_drivers"; then
1665         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1666     fi
1667
1668     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1669         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1670     fi
1671
1672     if test "x$have_libclc" = xno; then
1673         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1674                     Make sure the directory containing libclc.pc is specified in your
1675                     PKG_CONFIG_PATH environment variable.
1676                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1677     else
1678         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1679         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1680         AC_SUBST([LIBCLC_INCLUDEDIR])
1681         AC_SUBST([LIBCLC_LIBEXECDIR])
1682     fi
1683
1684     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1685     enable_gallium_loader=yes
1686
1687     if test "x$enable_opencl_icd" = xyes; then
1688         OPENCL_LIBNAME="MesaOpenCL"
1689     else
1690         OPENCL_LIBNAME="OpenCL"
1691     fi
1692
1693     if test "x$have_libelf" != xyes; then
1694        AC_MSG_ERROR([Clover requires libelf])
1695     fi
1696 fi
1697 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1698 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1699 AC_SUBST([OPENCL_LIBNAME])
1700
1701 dnl
1702 dnl Gallium configuration
1703 dnl
1704 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1705
1706 AC_SUBST([LLVM_BINDIR])
1707 AC_SUBST([LLVM_CFLAGS])
1708 AC_SUBST([LLVM_CPPFLAGS])
1709 AC_SUBST([LLVM_CXXFLAGS])
1710 AC_SUBST([LLVM_LIBDIR])
1711 AC_SUBST([LLVM_LIBS])
1712 AC_SUBST([LLVM_LDFLAGS])
1713 AC_SUBST([LLVM_INCLUDEDIR])
1714 AC_SUBST([LLVM_VERSION])
1715 AC_SUBST([CLANG_RESOURCE_DIR])
1716
1717 case "x$enable_opengl$enable_gles1$enable_gles2" in
1718 x*yes*)
1719     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1720     ;;
1721 esac
1722
1723 AC_SUBST([VG_LIB_DEPS])
1724 AC_SUBST([EGL_CLIENT_APIS])
1725
1726 dnl
1727 dnl EGL Platforms configuration
1728 dnl
1729 AC_ARG_WITH([egl-platforms],
1730     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1731         [comma delimited native platforms libEGL supports, e.g.
1732         "x11,drm" @<:@default=auto@:>@])],
1733     [with_egl_platforms="$withval"],
1734     [if test "x$enable_egl" = xyes; then
1735         with_egl_platforms="x11"
1736     else
1737         with_egl_platforms=""
1738     fi])
1739
1740 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1741     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1742 fi
1743
1744 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland_scanner],
1745         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland_scanner`,
1746         WAYLAND_SCANNER='')
1747 if test "x$WAYLAND_SCANNER" = x; then
1748     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
1749 fi
1750
1751 # Do per-EGL platform setups and checks
1752 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1753 for plat in $egl_platforms; do
1754         case "$plat" in
1755         wayland)
1756                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1757
1758                 if test "x$WAYLAND_SCANNER" = x; then
1759                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
1760                 fi
1761                 ;;
1762
1763         x11)
1764                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1765                 ;;
1766
1767         drm)
1768                 test "x$enable_gbm" = "xno" &&
1769                         AC_MSG_ERROR([EGL platform drm needs gbm])
1770                 test "x$have_libdrm" != xyes &&
1771                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1772                 ;;
1773
1774         android|fbdev|gdi|null)
1775                 ;;
1776
1777         *)
1778                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1779                 ;;
1780         esac
1781
1782         case "$plat$need_pci_id$have_pci_id" in
1783                 waylandyesno|drmyesno)
1784                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
1785         esac
1786 done
1787
1788 # libEGL wants to default to the first platform specified in
1789 # ./configure.  parse that here.
1790 if test "x$egl_platforms" != "x"; then
1791     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
1792     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1793 else
1794     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1795 fi
1796
1797 if echo "$egl_platforms" | grep -q 'x11'; then
1798     NEED_WINSYS_XLIB=yes
1799 fi
1800 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1801 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1802 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1803 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep -q 'fbdev')
1804 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1805
1806 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1807
1808 AC_SUBST([EGL_NATIVE_PLATFORM])
1809 AC_SUBST([EGL_CFLAGS])
1810
1811 # If we don't have the X11 platform, set this define so we don't try to include
1812 # the X11 headers.
1813 if ! echo "$egl_platforms" | grep -q 'x11'; then
1814     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1815     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1816 fi
1817
1818 AC_ARG_WITH([max-width],
1819     [AS_HELP_STRING([--with-max-width=N],
1820                     [Maximum framebuffer width (4096)])],
1821     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1822      AS_IF([test "${withval}" -gt "4096"],
1823            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1824 )
1825 AC_ARG_WITH([max-height],
1826     [AS_HELP_STRING([--with-max-height=N],
1827                     [Maximum framebuffer height (4096)])],
1828     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1829      AS_IF([test "${withval}" -gt "4096"],
1830            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1831 )
1832
1833 dnl
1834 dnl Gallium LLVM
1835 dnl
1836 AC_ARG_ENABLE([gallium-llvm],
1837     [AS_HELP_STRING([--enable-gallium-llvm],
1838         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1839     [enable_gallium_llvm="$enableval"],
1840     [enable_gallium_llvm=auto])
1841
1842 AC_ARG_ENABLE([llvm-shared-libs],
1843     [AS_HELP_STRING([--enable-llvm-shared-libs],
1844         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1845     [enable_llvm_shared_libs="$enableval"],
1846     [enable_llvm_shared_libs=yes])
1847
1848 AC_ARG_WITH([llvm-prefix],
1849     [AS_HELP_STRING([--with-llvm-prefix],
1850         [Prefix for LLVM installations in non-standard locations])],
1851     [llvm_prefix="$withval"],
1852     [llvm_prefix=''])
1853
1854
1855 # Call this inside ` ` to get the return value.
1856 # $1 is the llvm-config command with arguments.
1857 strip_unwanted_llvm_flags() {
1858     # Use \> (marks the end of the word)
1859     echo `$1` | sed \
1860         -e 's/-DNDEBUG\>//g' \
1861         -e 's/-D_GNU_SOURCE\>//g' \
1862         -e 's/-pedantic\>//g' \
1863         -e 's/-Wcovered-switch-default\>//g' \
1864         -e 's/-O.\>//g' \
1865         -e 's/-g\>//g' \
1866         -e 's/-Wall\>//g' \
1867         -e 's/-Wcast-qual\>//g' \
1868         -e 's/-Woverloaded-virtual\>//g' \
1869         -e 's/-fcolor-diagnostics\>//g' \
1870         -e 's/-fdata-sections\>//g' \
1871         -e 's/-ffunction-sections\>//g' \
1872         -e 's/-fno-exceptions\>//g' \
1873         -e 's/-fomit-frame-pointer\>//g' \
1874         -e 's/-fvisibility-inlines-hidden\>//g' \
1875         -e 's/-fPIC\>//g' \
1876         -e 's/-fstack-protector-strong\>//g'
1877 }
1878
1879
1880 if test -z "$with_gallium_drivers"; then
1881     enable_gallium_llvm=no
1882 fi
1883 if test "x$enable_gallium_llvm" = xauto; then
1884     case "$host_cpu" in
1885     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1886     esac
1887 fi
1888 if test "x$enable_gallium_llvm" = xyes; then
1889     if test -n "$llvm_prefix"; then
1890         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1891     else
1892         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1893     fi
1894
1895     if test "x$LLVM_CONFIG" != xno; then
1896         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1897         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1898         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1899         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1900         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1901         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1902         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1903         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1904
1905         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1906             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1907         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1908             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1909
1910         LLVM_VERSION_PATCH=`echo $LLVM_VERSION | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1911         if test -z "$LLVM_VERSION_PATCH"; then
1912             LLVM_VERSION_PATCH=0
1913         fi
1914
1915         if test -n "${LLVM_VERSION_MAJOR}"; then
1916             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1917         else
1918             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1919         fi
1920
1921         LLVM_REQUIRED_VERSION_MAJOR="3"
1922         LLVM_REQUIRED_VERSION_MINOR="3"
1923         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1924             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
1925         fi
1926
1927         LLVM_COMPONENTS="engine bitwriter"
1928         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1929             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1930         fi
1931
1932         if test "x$enable_opencl" = xyes; then
1933             LLVM_COMPONENTS="${LLVM_COMPONENTS} all-targets ipo linker instrumentation"
1934             # LLVM 3.3 >= 177971 requires IRReader
1935             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1936                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1937             fi
1938             # LLVM 3.4 requires Option
1939             if $LLVM_CONFIG --components | grep -qw 'option'; then
1940                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1941             fi
1942             # Current OpenCL/Clover and LLVM 3.5 require ObjCARCOpts and ProfileData
1943             if $LLVM_CONFIG --components | grep -qw 'objcarcopts'; then
1944                 LLVM_COMPONENTS="${LLVM_COMPONENTS} objcarcopts"
1945             fi
1946             if $LLVM_CONFIG --components | grep -qw 'profiledata'; then
1947                 LLVM_COMPONENTS="${LLVM_COMPONENTS} profiledata"
1948             fi
1949         fi
1950         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DLLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1951         MESA_LLVM=1
1952
1953         dnl Check for Clang internal headers
1954         if test "x$enable_opencl" = xyes; then
1955             if test -z "$CLANG_LIBDIR"; then
1956                 CLANG_LIBDIR=${LLVM_LIBDIR}
1957             fi
1958             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1959             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1960                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1961         fi
1962     else
1963         MESA_LLVM=0
1964         LLVM_VERSION_INT=0
1965     fi
1966 else
1967     MESA_LLVM=0
1968     LLVM_VERSION_INT=0
1969
1970     if test "x$enable_opencl" = xyes; then
1971         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
1972     fi
1973 fi
1974
1975 dnl Directory for XVMC libs
1976 AC_ARG_WITH([xvmc-libdir],
1977     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1978         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1979     [XVMC_LIB_INSTALL_DIR="$withval"],
1980     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1981 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1982
1983 dnl
1984 dnl Gallium Tests
1985 dnl
1986 if test "x$enable_gallium_tests" = xyes; then
1987     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1988     enable_gallium_loader=yes
1989 fi
1990 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1991
1992 dnl Directory for VDPAU libs
1993 AC_ARG_WITH([vdpau-libdir],
1994     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1995         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1996     [VDPAU_LIB_INSTALL_DIR="$withval"],
1997     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1998 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1999
2000 dnl Directory for OMX libs
2001
2002 AC_ARG_WITH([omx-libdir],
2003     [AS_HELP_STRING([--with-omx-libdir=DIR],
2004         [directory for the OMX libraries])],
2005     [OMX_LIB_INSTALL_DIR="$withval"],
2006     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2007 AC_SUBST([OMX_LIB_INSTALL_DIR])
2008
2009 dnl Directory for VA libs
2010
2011 AC_ARG_WITH([va-libdir],
2012     [AS_HELP_STRING([--with-va-libdir=DIR],
2013         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2014     [VA_LIB_INSTALL_DIR="$withval"],
2015     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2016 AC_SUBST([VA_LIB_INSTALL_DIR])
2017
2018 AC_ARG_WITH([d3d-libdir],
2019     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2020         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2021     [D3D_DRIVER_INSTALL_DIR="$withval"],
2022     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2023 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2024
2025 dnl
2026 dnl Gallium helper functions
2027 dnl
2028 gallium_require_drm() {
2029     if test "x$have_libdrm" != xyes; then
2030        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
2031     fi
2032 }
2033
2034 gallium_require_llvm() {
2035     if test "x$MESA_LLVM" = x0; then
2036         case "$host" in *gnux32) return;; esac
2037         case "$host_cpu" in
2038         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
2039         esac
2040     fi
2041 }
2042
2043 gallium_require_drm_loader() {
2044     if test "x$enable_gallium_loader" = xyes; then
2045         if test "x$need_pci_id$have_pci_id" = xyesno; then
2046             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
2047         fi
2048         enable_gallium_drm_loader=yes
2049     fi
2050     if test "x$enable_va" = xyes && test "x$7" != x; then
2051          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
2052     fi
2053 }
2054
2055 require_egl_drm() {
2056     case "$with_egl_platforms" in
2057         *drm*)
2058             ;;
2059          *)
2060             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
2061             ;;
2062     esac
2063     if test "x$enable_gbm" != xyes; then
2064             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
2065     fi
2066 }
2067
2068 radeon_llvm_check() {
2069     if test "x$enable_gallium_llvm" != "xyes"; then
2070         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2071     fi
2072     LLVM_REQUIRED_VERSION_MAJOR="3"
2073     LLVM_REQUIRED_VERSION_MINOR="4"
2074     LLVM_REQUIRED_VERSION_PATCH="2"
2075     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}${LLVM_REQUIRED_VERSION_PATCH}"; then
2076         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR.$LLVM_REQUIRED_VERSION_PATCH or newer is required for $1])
2077     fi
2078     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
2079         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
2080                       sources with the --enable-experimental-targets=R600
2081                       configure flag])
2082     fi
2083     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
2084     NEED_RADEON_LLVM=yes
2085     if test "x$have_libelf" != xyes; then
2086        AC_MSG_ERROR([$1 requires libelf when using llvm])
2087     fi
2088 }
2089
2090 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2091 if test -n "$with_gallium_drivers"; then
2092     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2093     for driver in $gallium_drivers; do
2094         case "x$driver" in
2095         xsvga)
2096             HAVE_GALLIUM_SVGA=yes
2097             gallium_require_drm "svga"
2098             gallium_require_drm_loader
2099             ;;
2100         xi915)
2101             HAVE_GALLIUM_I915=yes
2102             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2103             gallium_require_drm "Gallium i915"
2104             gallium_require_drm_loader
2105             ;;
2106         xilo)
2107             HAVE_GALLIUM_ILO=yes
2108             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2109             gallium_require_drm "Gallium i965/ilo"
2110             gallium_require_drm_loader
2111             ;;
2112         xr300)
2113             HAVE_GALLIUM_R300=yes
2114             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2115             gallium_require_drm "Gallium R300"
2116             gallium_require_drm_loader
2117             gallium_require_llvm "Gallium R300"
2118             ;;
2119         xr600)
2120             HAVE_GALLIUM_R600=yes
2121             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2122             gallium_require_drm "Gallium R600"
2123             gallium_require_drm_loader
2124             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
2125                 radeon_llvm_check "r600g"
2126                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2127             fi
2128             if test "x$enable_r600_llvm" = xyes; then
2129                 USE_R600_LLVM_COMPILER=yes;
2130             fi
2131             if test "x$enable_opencl" = xyes; then
2132                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2133             fi
2134             ;;
2135         xradeonsi)
2136             HAVE_GALLIUM_RADEONSI=yes
2137             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2138             gallium_require_drm "radeonsi"
2139             gallium_require_drm_loader
2140             radeon_llvm_check "radeonsi"
2141             require_egl_drm "radeonsi"
2142             ;;
2143         xnouveau)
2144             HAVE_GALLIUM_NOUVEAU=yes
2145             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2146             gallium_require_drm "nouveau"
2147             gallium_require_drm_loader
2148             ;;
2149         xfreedreno)
2150             HAVE_GALLIUM_FREEDRENO=yes
2151             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2152             gallium_require_drm "freedreno"
2153             gallium_require_drm_loader
2154             ;;
2155         xswrast)
2156             HAVE_GALLIUM_SOFTPIPE=yes
2157             if test "x$MESA_LLVM" = x1; then
2158                 HAVE_GALLIUM_LLVMPIPE=yes
2159             fi
2160             ;;
2161         xvc4)
2162             HAVE_GALLIUM_VC4=yes
2163             gallium_require_drm "vc4"
2164             gallium_require_drm_loader
2165
2166             case "$host_cpu" in
2167                 i?86 | x86_64 | amd64)
2168                 USE_VC4_SIMULATOR=yes
2169                 ;;
2170             esac
2171             ;;
2172         *)
2173             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2174             ;;
2175         esac
2176     done
2177 fi
2178
2179 dnl Set LLVM_LIBS - This is done after the driver configuration so
2180 dnl that drivers can add additional components to LLVM_COMPONENTS.
2181 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2182 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2183 dnl this was causing the same libraries to be appear multiple times
2184 dnl in LLVM_LIBS.
2185
2186 if test "x$MESA_LLVM" != x0; then
2187
2188     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2189
2190     if test "x$enable_llvm_shared_libs" = xyes; then
2191         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2192         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2193         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
2194
2195         if test "x$llvm_have_one_so" = xyes; then
2196             dnl LLVM was built using auto*, so there is only one shared object.
2197             LLVM_LIBS="-l$LLVM_SO_NAME"
2198         else
2199             dnl If LLVM was built with CMake, there will be one shared object per
2200             dnl component.
2201             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
2202                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2203         Please make sure you have built llvm with the --enable-shared option
2204         and that your llvm libraries are installed in $LLVM_LIBDIR
2205         If you have installed your llvm libraries to a different directory you
2206         can use the --with-llvm-prefix= configure flag to specify this directory.
2207         NOTE: Mesa is attempting to use llvm shared libraries by default.
2208         If you do not want to build with llvm shared libraries and instead want to
2209         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2210         invocation and rebuild.])])
2211
2212            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2213            dnl install uses a shared object for each component and we have
2214            dnl already added all of these objects to LLVM_LIBS.
2215         fi
2216     else
2217         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2218         dnl We need to link to llvm system libs when using static libs
2219         dnl However, only llvm 3.5+ provides --system-libs
2220         if test $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2221             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2222         fi
2223     fi
2224 fi
2225
2226 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2227 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2228 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2229 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2230 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2231 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2232 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2233                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2234 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2235 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2236 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2237 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2238 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2239
2240 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2241
2242 # NOTE: anything using xcb or other client side libs ends up in separate
2243 #       _CLIENT variables.  The pipe loader is built in two variants,
2244 #       one that is standalone and does not link any x client libs (for
2245 #       use by XA tracker in particular, but could be used in any case
2246 #       where communication with xserver is not desired).
2247 if test "x$enable_gallium_loader" = xyes; then
2248     if test "x$NEED_WINSYS_XLIB" = xyes; then
2249         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
2250     fi
2251
2252     if test "x$enable_dri" = xyes; then
2253         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2254     fi
2255
2256     if test "x$enable_gallium_drm_loader" = xyes; then
2257         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2258         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
2259                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
2260         if test "x$pipe_loader_have_xcb" = xyes; then
2261             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
2262             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
2263         fi
2264     fi
2265
2266     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
2267     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
2268
2269     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2270     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
2271     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
2272     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
2273 fi
2274
2275 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2276 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2277 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2278 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2279 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2280 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2281
2282 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2283                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2284                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2285 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2286 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2287 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2288 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2289 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2290 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2291 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2292 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2293 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2294     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2295 fi
2296
2297 AC_SUBST([ELF_LIB])
2298
2299 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
2300 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2301 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2302 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2303 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2304
2305 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2306 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2307 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2308
2309 AC_SUBST([NINE_MAJOR], 1)
2310 AC_SUBST([NINE_MINOR], 0)
2311 AC_SUBST([NINE_TINY], 0)
2312 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2313
2314 AC_SUBST([VDPAU_MAJOR], 1)
2315 AC_SUBST([VDPAU_MINOR], 0)
2316
2317 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2318 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2319 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2320 AC_SUBST([VA_MINOR], $VA_MINOR)
2321
2322 AC_SUBST([XVMC_MAJOR], 1)
2323 AC_SUBST([XVMC_MINOR], 0)
2324
2325 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2326 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2327 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2328 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2329
2330 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2331 AC_SUBST([XA_MINOR], $XA_MINOR)
2332 AC_SUBST([XA_TINY], $XA_TINY)
2333 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2334
2335 dnl Restore LDFLAGS and CPPFLAGS
2336 LDFLAGS="$_SAVE_LDFLAGS"
2337 CPPFLAGS="$_SAVE_CPPFLAGS"
2338
2339 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2340 if test "x$acv_mesa_CLANG" = xyes; then
2341     CFLAGS="$CFLAGS -Qunused-arguments"
2342     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2343 fi
2344
2345 dnl Add user CFLAGS and CXXFLAGS
2346 CFLAGS="$CFLAGS $USER_CFLAGS"
2347 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2348
2349 dnl Substitute the config
2350 AC_CONFIG_FILES([Makefile
2351                 src/Makefile
2352                 src/egl/drivers/dri2/Makefile
2353                 src/egl/main/Makefile
2354                 src/egl/main/egl.pc
2355                 src/egl/wayland/wayland-drm/Makefile
2356                 src/egl/wayland/wayland-egl/Makefile
2357                 src/egl/wayland/wayland-egl/wayland-egl.pc
2358                 src/gallium/Makefile
2359                 src/gallium/auxiliary/Makefile
2360                 src/gallium/auxiliary/pipe-loader/Makefile
2361                 src/gallium/drivers/freedreno/Makefile
2362                 src/gallium/drivers/galahad/Makefile
2363                 src/gallium/drivers/i915/Makefile
2364                 src/gallium/drivers/ilo/Makefile
2365                 src/gallium/drivers/llvmpipe/Makefile
2366                 src/gallium/drivers/noop/Makefile
2367                 src/gallium/drivers/nouveau/Makefile
2368                 src/gallium/drivers/r300/Makefile
2369                 src/gallium/drivers/r600/Makefile
2370                 src/gallium/drivers/radeon/Makefile
2371                 src/gallium/drivers/radeonsi/Makefile
2372                 src/gallium/drivers/rbug/Makefile
2373                 src/gallium/drivers/softpipe/Makefile
2374                 src/gallium/drivers/svga/Makefile
2375                 src/gallium/drivers/trace/Makefile
2376                 src/gallium/drivers/vc4/Makefile
2377                 src/gallium/drivers/vc4/kernel/Makefile
2378                 src/gallium/state_trackers/clover/Makefile
2379                 src/gallium/state_trackers/dri/Makefile
2380                 src/gallium/state_trackers/glx/xlib/Makefile
2381                 src/gallium/state_trackers/nine/Makefile
2382                 src/gallium/state_trackers/omx/Makefile
2383                 src/gallium/state_trackers/osmesa/Makefile
2384                 src/gallium/state_trackers/va/Makefile
2385                 src/gallium/state_trackers/vdpau/Makefile
2386                 src/gallium/state_trackers/vega/Makefile
2387                 src/gallium/state_trackers/xa/Makefile
2388                 src/gallium/state_trackers/xvmc/Makefile
2389                 src/gallium/targets/d3dadapter9/Makefile
2390                 src/gallium/targets/d3dadapter9/d3d.pc
2391                 src/gallium/targets/dri/Makefile
2392                 src/gallium/targets/libgl-xlib/Makefile
2393                 src/gallium/targets/omx/Makefile
2394                 src/gallium/targets/opencl/Makefile
2395                 src/gallium/targets/osmesa/Makefile
2396                 src/gallium/targets/osmesa/osmesa.pc
2397                 src/gallium/targets/pipe-loader/Makefile
2398                 src/gallium/targets/va/Makefile
2399                 src/gallium/targets/vdpau/Makefile
2400                 src/gallium/targets/xa/Makefile
2401                 src/gallium/targets/xa/xatracker.pc
2402                 src/gallium/targets/xvmc/Makefile
2403                 src/gallium/tests/trivial/Makefile
2404                 src/gallium/tests/unit/Makefile
2405                 src/gallium/winsys/freedreno/drm/Makefile
2406                 src/gallium/winsys/i915/drm/Makefile
2407                 src/gallium/winsys/intel/drm/Makefile
2408                 src/gallium/winsys/nouveau/drm/Makefile
2409                 src/gallium/winsys/radeon/drm/Makefile
2410                 src/gallium/winsys/svga/drm/Makefile
2411                 src/gallium/winsys/sw/dri/Makefile
2412                 src/gallium/winsys/sw/fbdev/Makefile
2413                 src/gallium/winsys/sw/kms-dri/Makefile
2414                 src/gallium/winsys/sw/null/Makefile
2415                 src/gallium/winsys/sw/wayland/Makefile
2416                 src/gallium/winsys/sw/wrapper/Makefile
2417                 src/gallium/winsys/sw/xlib/Makefile
2418                 src/gallium/winsys/vc4/drm/Makefile
2419                 src/gbm/Makefile
2420                 src/gbm/main/gbm.pc
2421                 src/glsl/Makefile
2422                 src/glx/Makefile
2423                 src/glx/apple/Makefile
2424                 src/glx/tests/Makefile
2425                 src/gtest/Makefile
2426                 src/loader/Makefile
2427                 src/mapi/Makefile
2428                 src/mapi/es1api/glesv1_cm.pc
2429                 src/mapi/es2api/glesv2.pc
2430                 src/mapi/glapi/gen/Makefile
2431                 src/mesa/Makefile
2432                 src/mesa/gl.pc
2433                 src/mesa/drivers/dri/dri.pc
2434                 src/mesa/drivers/dri/common/Makefile
2435                 src/mesa/drivers/dri/common/xmlpool/Makefile
2436                 src/mesa/drivers/dri/i915/Makefile
2437                 src/mesa/drivers/dri/i965/Makefile
2438                 src/mesa/drivers/dri/Makefile
2439                 src/mesa/drivers/dri/nouveau/Makefile
2440                 src/mesa/drivers/dri/r200/Makefile
2441                 src/mesa/drivers/dri/radeon/Makefile
2442                 src/mesa/drivers/dri/swrast/Makefile
2443                 src/mesa/drivers/osmesa/Makefile
2444                 src/mesa/drivers/osmesa/osmesa.pc
2445                 src/mesa/drivers/x11/Makefile
2446                 src/mesa/main/tests/Makefile
2447                 src/util/Makefile
2448                 src/util/tests/hash_table/Makefile])
2449
2450 AC_OUTPUT
2451
2452 dnl
2453 dnl Output some configuration info for the user
2454 dnl
2455 echo ""
2456 echo "        prefix:          $prefix"
2457 echo "        exec_prefix:     $exec_prefix"
2458 echo "        libdir:          $libdir"
2459 echo "        includedir:      $includedir"
2460
2461 dnl API info
2462 echo ""
2463 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2464 echo "        OpenVG:          $enable_openvg"
2465
2466 dnl Driver info
2467 echo ""
2468 case "x$enable_osmesa$enable_gallium_osmesa" in
2469 xnoyes)
2470         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2471         ;;
2472 xyesno)
2473         echo "        OSMesa:          lib$OSMESA_LIB"
2474         ;;
2475 xnono)
2476         echo "        OSMesa:          no"
2477         ;;
2478 esac
2479
2480 echo ""
2481 if test "x$enable_dri" != xno; then
2482         echo "        DRI platform:    $dri_platform"
2483         if test -z "$DRI_DIRS"; then
2484             echo "        DRI drivers:     no"
2485         else
2486             echo "        DRI drivers:     $DRI_DIRS"
2487         fi
2488         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2489 fi
2490
2491 case "x$enable_glx$enable_xlib_glx" in
2492 xyesyes)
2493     echo "        GLX:             Xlib-based"
2494     ;;
2495 xyesno)
2496     echo "        GLX:             DRI-based"
2497     ;;
2498 *)
2499     echo "        GLX:             $enable_glx"
2500     ;;
2501 esac
2502
2503 dnl EGL
2504 echo ""
2505 echo "        EGL:             $enable_egl"
2506 if test "$enable_egl" = yes; then
2507     echo "        EGL platforms:   $egl_platforms"
2508
2509     egl_drivers=""
2510     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2511         egl_drivers="$egl_drivers builtin:egl_dri2"
2512     fi
2513
2514     echo "        EGL drivers:    $egl_drivers"
2515 fi
2516
2517 echo ""
2518 if test "x$MESA_LLVM" = x1; then
2519     echo "        llvm:            yes"
2520     echo "        llvm-config:     $LLVM_CONFIG"
2521     echo "        llvm-version:    $LLVM_VERSION"
2522 else
2523     echo "        llvm:            no"
2524 fi
2525
2526 echo ""
2527 if test -n "$with_gallium_drivers"; then
2528     echo "        Gallium:         yes"
2529 else
2530     echo "        Gallium:         no"
2531 fi
2532
2533 dnl Shader cache
2534 echo ""
2535 echo "        Shader cache:    $enable_shader_cache"
2536 if test "x$enable_shader_cache" = "xyes"; then
2537     echo "        With SHA1 from:  $with_sha1"
2538 fi
2539
2540 dnl Libraries
2541 echo ""
2542 echo "        Shared libs:     $enable_shared"
2543 echo "        Static libs:     $enable_static"
2544 echo "        Shared-glapi:    $enable_shared_glapi"
2545
2546 dnl Compiler options
2547 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2548 cflags=`echo $CFLAGS | \
2549     $SED 's/^ *//;s/  */ /;s/ *$//'`
2550 cxxflags=`echo $CXXFLAGS | \
2551     $SED 's/^ *//;s/  */ /;s/ *$//'`
2552 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2553 echo ""
2554 echo "        CFLAGS:          $cflags"
2555 echo "        CXXFLAGS:        $cxxflags"
2556 echo "        Macros:          $defines"
2557 echo ""
2558 if test "x$MESA_LLVM" = x1; then
2559     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2560     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2561     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2562     echo ""
2563 fi
2564 echo "        PYTHON2:         $PYTHON2"
2565
2566 echo ""
2567 echo "        Run '${MAKE-make}' to build Mesa"
2568 echo ""