configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.59])
   4
   5 dnl Versioning - scrape the version from configs/default
   6 m4_define([mesa_version],
   7     [m4_esyscmd([${MAKE-make} -s -f bin/version.mk version | tr -d '\n'])])
   8 m4_ifval(mesa_version,,
   9     [m4_fatal([Failed to get the Mesa version from `make -f bin/version.mk version`])])
  10
  11 dnl Tell the user about autoconf.html in the --help output
  12 m4_divert_once([HELP_END], [
  13 See docs/autoconf.html for more details on the options for Mesa.])
  14
  15 AC_INIT([Mesa],[mesa_version],
  16     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  17 AC_CONFIG_AUX_DIR([bin])
  18 AC_CANONICAL_HOST
  19
  20 dnl Versions for external dependencies
  21 LIBDRM_REQUIRED=2.4.3
  22 DRI2PROTO_REQUIRED=1.99.3
  23
  24 dnl Check for progs
  25 AC_PROG_CPP
  26 AC_PROG_CC
  27 AC_PROG_CXX
  28 AC_CHECK_PROGS([MAKE], [gmake make])
  29 AC_PATH_PROG([MKDEP], [makedepend])
  30 AC_PATH_PROG([SED], [sed])
  31
  32 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  33 dnl configuration in that case.
  34 AC_PROG_INSTALL
  35 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  36
  37 dnl We need a POSIX shell for parts of the build. Assume we have one
  38 dnl in most cases.
  39 case "$host_os" in
  40 solaris*)
  41     # Solaris /bin/sh is too old/non-POSIX compliant
  42     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  43     SHELL="$POSIX_SHELL"
  44     ;;
  45 esac
  46
  47 MKDEP_OPTIONS=-fdepend
  48 dnl Ask gcc where it's keeping its secret headers
  49 if test "x$GCC" = xyes; then
  50     for dir in include include-fixed; do
  51         GCC_INCLUDES=`$CC -print-file-name=$dir`
  52         if test "x$GCC_INCLUDES" != x && \
  53            test "$GCC_INCLUDES" != "$dir" && \
  54            test -d "$GCC_INCLUDES"; then
  55             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
  56         fi
  57     done
  58 fi
  59 AC_SUBST([MKDEP_OPTIONS])
  60
  61 dnl Make sure the pkg-config macros are defined
  62 m4_ifndef([PKG_PROG_PKG_CONFIG],
  63     [m4_fatal([Could not locate the pkg-config autoconf macros.
  64   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
  65   are in a different location, try setting the environment variable
  66   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
  67 PKG_PROG_PKG_CONFIG()
  68
  69 dnl LIB_DIR - library basename
  70 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
  71 AC_SUBST([LIB_DIR])
  72
  73 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
  74 _SAVE_LDFLAGS="$LDFLAGS"
  75 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
  76 AC_SUBST([EXTRA_LIB_PATH])
  77
  78 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
  79 _SAVE_CPPFLAGS="$CPPFLAGS"
  80 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
  81 AC_SUBST([X11_INCLUDES])
  82
  83 dnl Compiler macros
  84 DEFINES=""
  85 AC_SUBST([DEFINES])
  86 case "$host_os" in
  87 linux*|*-gnu*|gnu*)
  88     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
  89     ;;
  90 solaris*)
  91     DEFINES="$DEFINES -DPTHREADS -DSVR4"
  92     ;;
  93 esac
  94
  95 dnl Add flags for gcc and g++
  96 if test "x$GCC" = xyes; then
  97     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -std=c99 -ffast-math"
  98
  99     # Work around aliasing bugs - developers should comment this out
 100     CFLAGS="$CFLAGS -fno-strict-aliasing"
 101 fi
 102 if test "x$GXX" = xyes; then
 103     CXXFLAGS="$CXXFLAGS -Wall"
 104
 105     # Work around aliasing bugs - developers should comment this out
 106     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 107 fi
 108
 109 dnl These should be unnecessary, but let the user set them if they want
 110 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
 111     Default is to use CFLAGS.])
 112 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
 113     compiler. Default is to use CFLAGS.])
 114 AC_SUBST([OPT_FLAGS])
 115 AC_SUBST([ARCH_FLAGS])
 116
 117 dnl
 118 dnl Hacks to enable 32 or 64 bit build
 119 dnl
 120 AC_ARG_ENABLE([32-bit],
 121     [AS_HELP_STRING([--enable-32-bit],
 122         [build 32-bit libraries @<:@default=auto@:>@])],
 123     [enable_32bit="$enableval"],
 124     [enable_32bit=auto]
 125 )
 126 if test "x$enable_32bit" = xyes; then
 127     if test "x$GCC" = xyes; then
 128         CFLAGS="$CFLAGS -m32"
 129     fi
 130     if test "x$GXX" = xyes; then
 131         CXXFLAGS="$CXXFLAGS -m32"
 132     fi
 133 fi
 134 AC_ARG_ENABLE([64-bit],
 135     [AS_HELP_STRING([--enable-64-bit],
 136         [build 64-bit libraries @<:@default=auto@:>@])],
 137     [enable_64bit="$enableval"],
 138     [enable_64bit=auto]
 139 )
 140 if test "x$enable_64bit" = xyes; then
 141     if test "x$GCC" = xyes; then
 142         CFLAGS="$CFLAGS -m64"
 143     fi
 144     if test "x$GXX" = xyes; then
 145         CXXFLAGS="$CXXFLAGS -m64"
 146     fi
 147 fi
 148
 149 dnl
 150 dnl shared/static libraries, mimic libtool options
 151 dnl
 152 AC_ARG_ENABLE([static],
 153     [AS_HELP_STRING([--enable-static],
 154         [build static libraries @<:@default=disabled@:>@])],
 155     [enable_static="$enableval"],
 156     [enable_static=no]
 157 )
 158 case "x$enable_static" in
 159 xyes|xno ) ;;
 160 x ) enable_static=no ;;
 161 * )
 162     AC_MSG_ERROR([Static library option '$enable_static' is not a valid])
 163     ;;
 164 esac
 165 AC_ARG_ENABLE([shared],
 166     [AS_HELP_STRING([--disable-shared],
 167         [build shared libraries @<:@default=enabled@:>@])],
 168     [enable_shared="$enableval"],
 169     [enable_shared=yes]
 170 )
 171 case "x$enable_shared" in
 172 xyes|xno ) ;;
 173 x ) enable_shared=yes ;;
 174 * )
 175     AC_MSG_ERROR([Shared library option '$enable_shared' is not a valid])
 176     ;;
 177 esac
 178
 179 dnl Can't have static and shared libraries, default to static if user
 180 dnl explicitly requested. If both disabled, set to static since shared
 181 dnl was explicitly requirested.
 182 case "x$enable_static$enable_shared" in
 183 xyesyes )
 184     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 185     enable_shared=no
 186     ;;
 187 xnono )
 188     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 189     enable_static=yes
 190     ;;
 191 esac
 192
 193 dnl
 194 dnl mklib options
 195 dnl
 196 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 197 if test "$enable_static" = yes; then
 198     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 199 fi
 200 AC_SUBST([MKLIB_OPTIONS])
 201
 202 dnl
 203 dnl other compiler options
 204 dnl
 205 AC_ARG_ENABLE([debug],
 206     [AS_HELP_STRING([--enable-debug],
 207         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 208     [enable_debug="$enableval"],
 209     [enable_debug=no]
 210 )
 211 if test "x$enable_debug" = xyes; then
 212     DEFINES="$DEFINES -DDEBUG"
 213     if test "x$GCC" = xyes; then
 214         CFLAGS="$CFLAGS -g"
 215     fi
 216     if test "x$GXX" = xyes; then
 217         CXXFLAGS="$CXXFLAGS -g"
 218     fi
 219 fi
 220
 221 dnl
 222 dnl library names
 223 dnl
 224 if test "$enable_static" = yes; then
 225     LIB_EXTENSION='a'
 226 else
 227     case "$host_os" in
 228     darwin* )
 229         LIB_EXTENSION='dylib' ;;
 230     * )
 231         LIB_EXTENSION='so' ;;
 232     esac
 233 fi
 234
 235 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 236 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 237 GLUT_LIB_NAME='lib$(GLUT_LIB).'${LIB_EXTENSION}
 238 GLW_LIB_NAME='lib$(GLW_LIB).'${LIB_EXTENSION}
 239 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 240
 241 GL_LIB_GLOB='lib$(GL_LIB).*'${LIB_EXTENSION}'*'
 242 GLU_LIB_GLOB='lib$(GLU_LIB).*'${LIB_EXTENSION}'*'
 243 GLUT_LIB_GLOB='lib$(GLUT_LIB).*'${LIB_EXTENSION}'*'
 244 GLW_LIB_GLOB='lib$(GLW_LIB).*'${LIB_EXTENSION}'*'
 245 OSMESA_LIB_GLOB='lib$(OSMESA_LIB).*'${LIB_EXTENSION}'*'
 246
 247 AC_SUBST([GL_LIB_NAME])
 248 AC_SUBST([GLU_LIB_NAME])
 249 AC_SUBST([GLUT_LIB_NAME])
 250 AC_SUBST([GLW_LIB_NAME])
 251 AC_SUBST([OSMESA_LIB_NAME])
 252
 253 AC_SUBST([GL_LIB_GLOB])
 254 AC_SUBST([GLU_LIB_GLOB])
 255 AC_SUBST([GLUT_LIB_GLOB])
 256 AC_SUBST([GLW_LIB_GLOB])
 257 AC_SUBST([OSMESA_LIB_GLOB])
 258
 259 dnl
 260 dnl Arch/platform-specific settings
 261 dnl
 262 AC_ARG_ENABLE([asm],
 263     [AS_HELP_STRING([--disable-asm],
 264         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 265     [enable_asm="$enableval"],
 266     [enable_asm=yes]
 267 )
 268 asm_arch=""
 269 ASM_FLAGS=""
 270 MESA_ASM_SOURCES=""
 271 GLAPI_ASM_SOURCES=""
 272 AC_MSG_CHECKING([whether to enable assembly])
 273 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 274 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 275 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 276     case "$host_cpu" in
 277     i?86 | x86_64)
 278         enable_asm=no
 279         AC_MSG_RESULT([no, cross compiling])
 280         ;;
 281     esac
 282 fi
 283 # check for supported arches
 284 if test "x$enable_asm" = xyes; then
 285     case "$host_cpu" in
 286     i?86)
 287         case "$host_os" in
 288         linux* | *freebsd* | dragonfly*)
 289             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 290             ;;
 291         esac
 292         ;;
 293     x86_64)
 294         case "$host_os" in
 295         linux* | *freebsd* | dragonfly*)
 296             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 297             ;;
 298         esac
 299         ;;
 300     powerpc)
 301         case "$host_os" in
 302         linux*)
 303             asm_arch=ppc
 304             ;;
 305         esac
 306         ;;
 307     sparc*)
 308         case "$host_os" in
 309         linux*)
 310             asm_arch=sparc
 311             ;;
 312         esac
 313         ;;
 314     esac
 315
 316     case "$asm_arch" in
 317     x86)
 318         ASM_FLAGS="-DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 319         MESA_ASM_SOURCES='$(X86_SOURCES)'
 320         GLAPI_ASM_SOURCES='$(X86_API)'
 321         AC_MSG_RESULT([yes, x86])
 322         ;;
 323     x86_64)
 324         ASM_FLAGS="-DUSE_X86_64_ASM"
 325         MESA_ASM_SOURCES='$(X86-64_SOURCES)'
 326         GLAPI_ASM_SOURCES='$(X86-64_API)'
 327         AC_MSG_RESULT([yes, x86_64])
 328         ;;
 329     ppc)
 330         ASM_FLAGS="-DUSE_PPC_ASM -DUSE_VMX_ASM"
 331         MESA_ASM_SOURCES='$(PPC_SOURCES)'
 332         AC_MSG_RESULT([yes, ppc])
 333         ;;
 334     sparc)
 335         ASM_FLAGS="-DUSE_SPARC_ASM"
 336         MESA_ASM_SOURCES='$(SPARC_SOURCES)'
 337         GLAPI_ASM_SOURCES='$(SPARC_API)'
 338         AC_MSG_RESULT([yes, sparc])
 339         ;;
 340     *)
 341         AC_MSG_RESULT([no, platform not supported])
 342         ;;
 343     esac
 344 fi
 345 AC_SUBST([ASM_FLAGS])
 346 AC_SUBST([MESA_ASM_SOURCES])
 347 AC_SUBST([GLAPI_ASM_SOURCES])
 348
 349 dnl PIC code macro
 350 MESA_PIC_FLAGS
 351
 352 dnl Check to see if dlopen is in default libraries (like Solaris, which
 353 dnl has it in libc), or if libdl is needed to get it.
 354 AC_CHECK_FUNC([dlopen], [],
 355     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 356
 357 dnl See if posix_memalign is available
 358 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 359
 360 dnl SELinux awareness.
 361 AC_ARG_ENABLE([selinux],
 362     [AS_HELP_STRING([--enable-selinux],
 363         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 364     [MESA_SELINUX="$enableval"],
 365     [MESA_SELINUX=no])
 366 if test "x$enable_selinux" = "xyes"; then
 367     AC_CHECK_HEADER([selinux/selinux.h],[],
 368                     [AC_MSG_ERROR([SELinux headers not found])])
 369     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 370                  [AC_MSG_ERROR([SELinux library not found])])
 371     SELINUX_LIBS="-lselinux"
 372     DEFINES="$DEFINES -DMESA_SELINUX"
 373 fi
 374
 375 dnl
 376 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 377 dnl More later: directfb, fbdev, ...
 378 dnl
 379 default_driver="xlib"
 380
 381 case "$host_os" in
 382 linux*)
 383     case "$host_cpu" in
 384     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 385     esac
 386     ;;
 387 *freebsd* | dragonfly*)
 388     case "$host_cpu" in
 389     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 390     esac
 391     ;;
 392 esac
 393
 394 AC_ARG_WITH([driver],
 395     [AS_HELP_STRING([--with-driver=DRIVER],
 396         [driver for Mesa: xlib,dri,osmesa @<:@default=dri when available, or xlib@:>@])],
 397     [mesa_driver="$withval"],
 398     [mesa_driver="$default_driver"])
 399 dnl Check for valid option
 400 case "x$mesa_driver" in
 401 xxlib|xdri|xosmesa)
 402     ;;
 403 *)
 404     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 405     ;;
 406 esac
 407
 408 dnl
 409 dnl Driver specific build directories
 410 dnl
 411 SRC_DIRS="mesa glew"
 412 GLU_DIRS="sgi"
 413 WINDOW_SYSTEM=""
 414 GALLIUM_DIRS="auxiliary drivers state_trackers"
 415 GALLIUM_WINSYS_DIRS=""
 416 GALLIUM_WINSYS_DRM_DIRS=""
 417 GALLIUM_AUXILIARY_DIRS="rbug draw translate cso_cache pipebuffer tgsi sct rtasm util indices"
 418 GALLIUM_DRIVERS_DIRS="softpipe failover trace"
 419 GALLIUM_STATE_TRACKERS_DIRS=""
 420
 421 case "$mesa_driver" in
 422 xlib)
 423     DRIVER_DIRS="x11"
 424     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS xlib"
 425     ;;
 426 dri)
 427     SRC_DIRS="glx/x11 $SRC_DIRS"
 428     DRIVER_DIRS="dri"
 429     WINDOW_SYSTEM="dri"
 430     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS drm"
 431     ;;
 432 osmesa)
 433     DRIVER_DIRS="osmesa"
 434     ;;
 435 esac
 436 AC_SUBST([SRC_DIRS])
 437 AC_SUBST([GLU_DIRS])
 438 AC_SUBST([DRIVER_DIRS])
 439 AC_SUBST([WINDOW_SYSTEM])
 440 AC_SUBST([GALLIUM_DIRS])
 441 AC_SUBST([GALLIUM_WINSYS_DIRS])
 442 AC_SUBST([GALLIUM_WINSYS_DRM_DIRS])
 443 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 444 AC_SUBST([GALLIUM_AUXILIARY_DIRS])
 445 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 446
 447 dnl
 448 dnl User supplied program configuration
 449 dnl
 450 if test -d "$srcdir/progs/demos"; then
 451     default_demos=yes
 452 else
 453     default_demos=no
 454 fi
 455 AC_ARG_WITH([demos],
 456     [AS_HELP_STRING([--with-demos@<:@=DIRS...@:>@],
 457         [optional comma delimited demo directories to build
 458         @<:@default=auto if source available@:>@])],
 459     [with_demos="$withval"],
 460     [with_demos="$default_demos"])
 461 if test "x$with_demos" = x; then
 462     with_demos=no
 463 fi
 464
 465 dnl If $with_demos is yes, directories will be added as libs available
 466 PROGRAM_DIRS=""
 467 case "$with_demos" in
 468 no) ;;
 469 yes)
 470     # If the driver isn't osmesa, we have libGL and can build xdemos
 471     if test "$mesa_driver" != osmesa; then
 472         PROGRAM_DIRS="xdemos"
 473     fi
 474     ;;
 475 *)
 476     # verify the requested demos directories exist
 477     demos=`IFS=,; echo $with_demos`
 478     for demo in $demos; do
 479         test -d "$srcdir/progs/$demo" || \
 480             AC_MSG_ERROR([Program directory '$demo' doesn't exist])
 481     done
 482     PROGRAM_DIRS="$demos"
 483     ;;
 484 esac
 485
 486 dnl
 487 dnl Find out if X is available. The variable have_x is set if libX11 is
 488 dnl found to mimic AC_PATH_XTRA.
 489 dnl
 490 if test -n "$PKG_CONFIG"; then
 491     AC_MSG_CHECKING([pkg-config files for X11 are available])
 492     PKG_CHECK_EXISTS([x11],[
 493         x11_pkgconfig=yes
 494         have_x=yes
 495         ],[
 496         x11_pkgconfig=no
 497     ])
 498     AC_MSG_RESULT([$x11_pkgconfig])
 499 else
 500     x11_pkgconfig=no
 501 fi
 502 dnl Use the autoconf macro if no pkg-config files
 503 if test "$x11_pkgconfig" = no; then
 504     AC_PATH_XTRA
 505 fi
 506
 507 dnl Try to tell the user that the --x-* options are only used when
 508 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 509 m4_divert_once([HELP_BEGIN],
 510 [These options are only used when the X libraries cannot be found by the
 511 pkg-config utility.])
 512
 513 dnl We need X for xlib and dri, so bomb now if it's not found
 514 case "$mesa_driver" in
 515 xlib|dri)
 516     if test "$no_x" = yes; then
 517         AC_MSG_ERROR([X11 development libraries needed for $mesa_driver driver])
 518     fi
 519     ;;
 520 esac
 521
 522 dnl XCB - this is only used for GLX right now
 523 AC_ARG_ENABLE([xcb],
 524     [AS_HELP_STRING([--enable-xcb],
 525         [use XCB for GLX @<:@default=disabled@:>@])],
 526     [enable_xcb="$enableval"],
 527     [enable_xcb=no])
 528 if test "x$enable_xcb" = xyes; then
 529     DEFINES="$DEFINES -DUSE_XCB"
 530 else
 531     enable_xcb=no
 532 fi
 533
 534 dnl
 535 dnl libGL configuration per driver
 536 dnl
 537 case "$mesa_driver" in
 538 xlib)
 539     if test "$x11_pkgconfig" = yes; then
 540         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 541         GL_PC_REQ_PRIV="x11 xext"
 542         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 543         GL_LIB_DEPS="$XLIBGL_LIBS"
 544     else
 545         # should check these...
 546         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 547         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 548         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 549         GL_PC_CFLAGS="$X11_INCLUDES"
 550     fi
 551     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread"
 552     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread"
 553
 554     # if static, move the external libraries to the programs
 555     # and empty the libraries for libGL
 556     if test "$enable_static" = yes; then
 557         APP_LIB_DEPS="$APP_LIB_DEPS $GL_LIB_DEPS"
 558         GL_LIB_DEPS=""
 559     fi
 560     ;;
 561 dri)
 562     # DRI must be shared, I think
 563     if test "$enable_static" = yes; then
 564         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 565     fi
 566
 567     # Check for libdrm
 568     PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED])
 569     PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 570     GL_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED"
 571     DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 572
 573     # find the DRI deps for libGL
 574     if test "$x11_pkgconfig" = yes; then
 575         # add xcb modules if necessary
 576         dri_modules="x11 xext xxf86vm xdamage xfixes"
 577         if test "$enable_xcb" = yes; then
 578             dri_modules="$dri_modules x11-xcb xcb-glx"
 579         fi
 580
 581         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 582         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 583         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 584         GL_LIB_DEPS="$DRIGL_LIBS"
 585     else
 586         # should check these...
 587         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 588         GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
 589         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 590         GL_PC_CFLAGS="$X11_INCLUDES"
 591
 592         # XCB can only be used from pkg-config
 593         if test "$enable_xcb" = yes; then
 594             PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx])
 595             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
 596             X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
 597             GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
 598         fi
 599     fi
 600
 601     # need DRM libs, -lpthread, etc.
 602     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 603     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 604     ;;
 605 osmesa)
 606     # No libGL for osmesa
 607     GL_LIB_DEPS=""
 608     ;;
 609 esac
 610 AC_SUBST([GL_LIB_DEPS])
 611 AC_SUBST([GL_PC_REQ_PRIV])
 612 AC_SUBST([GL_PC_LIB_PRIV])
 613 AC_SUBST([GL_PC_CFLAGS])
 614 AC_SUBST([DRI_PC_REQ_PRIV])
 615
 616 dnl
 617 dnl More X11 setup
 618 dnl
 619 if test "$mesa_driver" = xlib; then
 620     DEFINES="$DEFINES -DUSE_XSHM"
 621 fi
 622
 623 dnl
 624 dnl More DRI setup
 625 dnl
 626 AC_ARG_ENABLE([glx-tls],
 627     [AS_HELP_STRING([--enable-glx-tls],
 628         [enable TLS support in GLX @<:@default=disabled@:>@])],
 629     [GLX_USE_TLS="$enableval"],
 630     [GLX_USE_TLS=no])
 631 dnl Directory for DRI drivers
 632 AC_ARG_WITH([dri-driverdir],
 633     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 634         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 635     [DRI_DRIVER_INSTALL_DIR="$withval"],
 636     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 637 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 638 dnl Direct rendering or just indirect rendering
 639 AC_ARG_ENABLE([driglx-direct],
 640     [AS_HELP_STRING([--disable-driglx-direct],
 641         [enable direct rendering in GLX for DRI @<:@default=enabled@:>@])],
 642     [driglx_direct="$enableval"],
 643     [driglx_direct="yes"])
 644 dnl Which drivers to build - default is chosen by platform
 645 AC_ARG_WITH([dri-drivers],
 646     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 647         [comma delimited DRI drivers list, e.g.
 648         "swrast,i965,radeon,nouveau" @<:@default=auto@:>@])],
 649     [with_dri_drivers="$withval"],
 650     [with_dri_drivers=yes])
 651 if test "x$with_dri_drivers" = x; then
 652     with_dri_drivers=no
 653 fi
 654
 655 dnl If $with_dri_drivers is yes, directories will be added through
 656 dnl platform checks
 657 DRI_DIRS=""
 658 case "$with_dri_drivers" in
 659 no) ;;
 660 yes)
 661     DRI_DIRS="yes"
 662     ;;
 663 *)
 664     # verify the requested driver directories exist
 665     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 666     for driver in $dri_drivers; do
 667         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 668             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
 669     done
 670     DRI_DIRS="$dri_drivers"
 671     ;;
 672 esac
 673
 674 dnl Just default to no EGL for now
 675 USING_EGL=0
 676 AC_SUBST([USING_EGL])
 677
 678 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 679 if test "$mesa_driver" = dri; then
 680     # Use TLS in GLX?
 681     if test "x$GLX_USE_TLS" = xyes; then
 682         DEFINES="$DEFINES -DGLX_USE_TLS -DPTHREADS"
 683     fi
 684
 685     if test "x$USING_EGL" = x1; then
 686         PROGRAM_DIRS="egl"
 687     fi
 688
 689     # Platform specific settings and drivers to build
 690     case "$host_os" in
 691     linux*)
 692         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 693         if test "x$driglx_direct" = xyes; then
 694             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 695         fi
 696         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 697
 698         case "$host_cpu" in
 699         x86_64)
 700             # ffb, gamma, and sis are missing because they have not be
 701             # converted to use the new interface.  i810 are missing
 702             # because there is no x86-64 system where they could *ever*
 703             # be used.
 704             if test "x$DRI_DIRS" = "xyes"; then
 705                 DRI_DIRS="i915 i965 mach64 mga r128 r200 r300 radeon \
 706                     savage tdfx unichrome swrast"
 707             fi
 708             ;;
 709         powerpc*)
 710             # Build only the drivers for cards that exist on PowerPC.
 711             # At some point MGA will be added, but not yet.
 712             if test "x$DRI_DIRS" = "xyes"; then
 713                 DRI_DIRS="mach64 r128 r200 r300 radeon tdfx swrast"
 714             fi
 715             ;;
 716         sparc*)
 717             # Build only the drivers for cards that exist on sparc`
 718             if test "x$DRI_DIRS" = "xyes"; then
 719                 DRI_DIRS="mach64 r128 r200 r300 radeon ffb swrast"
 720             fi
 721             ;;
 722         esac
 723         ;;
 724     freebsd* | dragonfly*)
 725         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
 726         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
 727         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 728         if test "x$driglx_direct" = xyes; then
 729             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 730         fi
 731         if test "x$GXX" = xyes; then
 732             CXXFLAGS="$CXXFLAGS -ansi -pedantic"
 733         fi
 734
 735         # ffb and gamma are missing because they have not been converted
 736         # to use the new interface.
 737         if test "x$DRI_DIRS" = "xyes"; then
 738             DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 radeon tdfx \
 739                 unichrome savage sis swrast"
 740         fi
 741         ;;
 742     gnu*)
 743         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 744         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 745         ;;
 746     solaris*)
 747         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 748         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 749         if test "x$driglx_direct" = xyes; then
 750             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 751         fi
 752         ;;
 753     esac
 754
 755     # default drivers
 756     if test "x$DRI_DIRS" = "xyes"; then
 757         DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 radeon s3v \
 758             savage sis tdfx trident unichrome ffb swrast"
 759     fi
 760
 761     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
 762
 763     # Check for expat
 764     EXPAT_INCLUDES=""
 765     EXPAT_LIB=-lexpat
 766     AC_ARG_WITH([expat],
 767         [AS_HELP_STRING([--with-expat=DIR],
 768             [expat install directory])],[
 769         EXPAT_INCLUDES="-I$withval/include"
 770         CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
 771         LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
 772         EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
 773         ])
 774     AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
 775     AC_CHECK_LIB([expat],[XML_ParserCreate],[],
 776         [AC_MSG_ERROR([Expat required for DRI.])])
 777
 778     # put all the necessary libs together
 779     DRI_LIB_DEPS="$SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
 780 fi
 781 AC_SUBST([DRI_DIRS])
 782 AC_SUBST([EXPAT_INCLUDES])
 783 AC_SUBST([DRI_LIB_DEPS])
 784
 785 dnl
 786 dnl OSMesa configuration
 787 dnl
 788 if test "$mesa_driver" = xlib; then
 789     default_gl_osmesa=yes
 790 else
 791     default_gl_osmesa=no
 792 fi
 793 AC_ARG_ENABLE([gl-osmesa],
 794     [AS_HELP_STRING([--enable-gl-osmesa],
 795         [enable OSMesa on libGL @<:@default=enabled for xlib driver@:>@])],
 796     [gl_osmesa="$enableval"],
 797     [gl_osmesa="$default_gl_osmesa"])
 798 if test "x$gl_osmesa" = xyes; then
 799     if test "$mesa_driver" = osmesa; then
 800         AC_MSG_ERROR([libGL is not available for OSMesa driver])
 801     else
 802         DRIVER_DIRS="$DRIVER_DIRS osmesa"
 803     fi
 804 fi
 805
 806 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
 807 AC_ARG_WITH([osmesa-bits],
 808     [AS_HELP_STRING([--with-osmesa-bits=BITS],
 809         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
 810     [osmesa_bits="$withval"],
 811     [osmesa_bits=8])
 812 if test "$mesa_driver" != osmesa && test "x$osmesa_bits" != x8; then
 813     AC_MSG_WARN([Ignoring OSMesa channel bits for non-OSMesa driver])
 814     osmesa_bits=8
 815 fi
 816 case "x$osmesa_bits" in
 817 x8)
 818     OSMESA_LIB=OSMesa
 819     ;;
 820 x16|x32)
 821     OSMESA_LIB="OSMesa$osmesa_bits"
 822     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
 823     ;;
 824 *)
 825     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
 826     ;;
 827 esac
 828 AC_SUBST([OSMESA_LIB])
 829
 830 case "$mesa_driver" in
 831 osmesa)
 832     # only link libraries with osmesa if shared
 833     if test "$enable_static" = no; then
 834         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS"
 835     else
 836         OSMESA_LIB_DEPS=""
 837     fi
 838     OSMESA_MESA_DEPS=""
 839     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS"
 840     ;;
 841 *)
 842     # Link OSMesa to libGL otherwise
 843     OSMESA_LIB_DEPS=""
 844     # only link libraries with osmesa if shared
 845     if test "$enable_static" = no; then
 846         OSMESA_MESA_DEPS='-l$(GL_LIB)'
 847     else
 848         OSMESA_MESA_DEPS=""
 849     fi
 850     OSMESA_PC_REQ="gl"
 851     ;;
 852 esac
 853 if test "$enable_static" = no; then
 854     OSMESA_LIB_DEPS="$OSMESA_LIB_DEPS"
 855 fi
 856 OSMESA_PC_LIB_PRIV="$OSMESA_PC_LIB_PRIV"
 857 AC_SUBST([OSMESA_LIB_DEPS])
 858 AC_SUBST([OSMESA_MESA_DEPS])
 859 AC_SUBST([OSMESA_PC_REQ])
 860 AC_SUBST([OSMESA_PC_LIB_PRIV])
 861
 862 dnl
 863 dnl EGL configuration
 864 dnl
 865 AC_ARG_ENABLE([egl],
 866     [AS_HELP_STRING([--disable-egl],
 867         [disable EGL library @<:@default=enabled@:>@])],
 868     [enable_egl="$enableval"],
 869     [enable_egl=yes])
 870 if test "x$enable_egl" = xyes; then
 871     SRC_DIRS="$SRC_DIRS egl"
 872
 873     if test "$x11_pkgconfig" = yes; then
 874         PKG_CHECK_MODULES([EGL], [x11])
 875         EGL_LIB_DEPS="$EGL_LIBS"
 876     else
 877         # should check these...
 878         EGL_LIB_DEPS="$X_LIBS -lX11"
 879     fi
 880     EGL_LIB_DEPS="$EGL_LIB_DEPS $DLOPEN_LIBS"
 881 fi
 882 AC_SUBST([EGL_LIB_DEPS])
 883
 884 dnl
 885 dnl GLU configuration
 886 dnl
 887 AC_ARG_ENABLE([glu],
 888     [AS_HELP_STRING([--disable-glu],
 889         [enable OpenGL Utility library @<:@default=enabled@:>@])],
 890     [enable_glu="$enableval"],
 891     [enable_glu=yes])
 892 if test "x$enable_glu" = xyes; then
 893     SRC_DIRS="$SRC_DIRS glu"
 894
 895     case "$mesa_driver" in
 896     osmesa)
 897         # If GLU is available and we have libOSMesa (not 16 or 32),
 898         # we can build the osdemos
 899         if test "$with_demos" = yes && test "$osmesa_bits" = 8; then
 900             PROGRAM_DIRS="$PROGRAM_DIRS osdemos"
 901         fi
 902
 903         # Link libGLU to libOSMesa instead of libGL
 904         GLU_LIB_DEPS=""
 905         GLU_PC_REQ="osmesa"
 906         if test "$enable_static" = no; then
 907             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
 908         else
 909             GLU_MESA_DEPS=""
 910         fi
 911         ;;
 912     *)
 913         # If static, empty GLU_LIB_DEPS and add libs for programs to link
 914         GLU_PC_REQ="gl"
 915         GLU_PC_LIB_PRIV="-lm"
 916         if test "$enable_static" = no; then
 917             GLU_LIB_DEPS="-lm"
 918             GLU_MESA_DEPS='-l$(GL_LIB)'
 919         else
 920             GLU_LIB_DEPS=""
 921             GLU_MESA_DEPS=""
 922             APP_LIB_DEPS="$APP_LIB_DEPS -lstdc++"
 923         fi
 924         ;;
 925     esac
 926 fi
 927 if test "$enable_static" = no; then
 928     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
 929 fi
 930 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
 931 AC_SUBST([GLU_LIB_DEPS])
 932 AC_SUBST([GLU_MESA_DEPS])
 933 AC_SUBST([GLU_PC_REQ])
 934 AC_SUBST([GLU_PC_REQ_PRIV])
 935 AC_SUBST([GLU_PC_LIB_PRIV])
 936 AC_SUBST([GLU_PC_CFLAGS])
 937
 938 dnl
 939 dnl GLw configuration
 940 dnl
 941 AC_ARG_ENABLE([glw],
 942     [AS_HELP_STRING([--disable-glw],
 943         [enable Xt/Motif widget library @<:@default=enabled@:>@])],
 944     [enable_glw="$enableval"],
 945     [enable_glw=yes])
 946 dnl Don't build GLw on osmesa
 947 if test "x$enable_glw" = xyes && test "$mesa_driver" = osmesa; then
 948     AC_MSG_WARN([Disabling GLw since the driver is OSMesa])
 949     enable_glw=no
 950 fi
 951 AC_ARG_ENABLE([motif],
 952     [AS_HELP_STRING([--enable-motif],
 953         [use Motif widgets in GLw @<:@default=disabled@:>@])],
 954     [enable_motif="$enableval"],
 955     [enable_motif=no])
 956
 957 if test "x$enable_glw" = xyes; then
 958     SRC_DIRS="$SRC_DIRS glw"
 959     if test "$x11_pkgconfig" = yes; then
 960         PKG_CHECK_MODULES([GLW],[x11 xt])
 961         GLW_PC_REQ_PRIV="x11 xt"
 962         GLW_LIB_DEPS="$GLW_LIBS"
 963     else
 964         # should check these...
 965         GLW_LIB_DEPS="$X_LIBS -lXt -lX11"
 966         GLW_PC_LIB_PRIV="$GLW_LIB_DEPS"
 967         GLW_PC_CFLAGS="$X11_INCLUDES"
 968     fi
 969
 970     GLW_SOURCES="GLwDrawA.c"
 971     MOTIF_CFLAGS=
 972     if test "x$enable_motif" = xyes; then
 973         GLW_SOURCES="$GLW_SOURCES GLwMDrawA.c"
 974         AC_PATH_PROG([MOTIF_CONFIG], [motif-config], [no])
 975         if test "x$MOTIF_CONFIG" != xno; then
 976             MOTIF_CFLAGS=`$MOTIF_CONFIG --cflags`
 977             MOTIF_LIBS=`$MOTIF_CONFIG --libs`
 978         else
 979             AC_CHECK_HEADER([Xm/PrimitiveP.h], [],
 980                 [AC_MSG_ERROR([Can't locate Motif headers])])
 981             AC_CHECK_LIB([Xm], [XmGetPixmap], [MOTIF_LIBS="-lXm"],
 982                 [AC_MSG_ERROR([Can't locate Motif Xm library])])
 983         fi
 984         # MOTIF_LIBS is prepended to GLW_LIB_DEPS since Xm needs Xt/X11
 985         GLW_LIB_DEPS="$MOTIF_LIBS $GLW_LIB_DEPS"
 986         GLW_PC_LIB_PRIV="$MOTIF_LIBS $GLW_PC_LIB_PRIV"
 987         GLW_PC_CFLAGS="$MOTIF_CFLAGS $GLW_PC_CFLAGS"
 988     fi
 989
 990     # If static, empty GLW_LIB_DEPS and add libs for programs to link
 991     GLW_PC_LIB_PRIV="$GLW_PC_LIB_PRIV"
 992     if test "$enable_static" = no; then
 993         GLW_MESA_DEPS='-l$(GL_LIB)'
 994         GLW_LIB_DEPS="$GLW_LIB_DEPS"
 995     else
 996         APP_LIB_DEPS="$APP_LIB_DEPS $GLW_LIB_DEPS"
 997         GLW_LIB_DEPS=""
 998         GLW_MESA_DEPS=""
 999     fi
1000 fi
1001 AC_SUBST([GLW_LIB_DEPS])
1002 AC_SUBST([GLW_MESA_DEPS])
1003 AC_SUBST([GLW_SOURCES])
1004 AC_SUBST([MOTIF_CFLAGS])
1005 AC_SUBST([GLW_PC_REQ_PRIV])
1006 AC_SUBST([GLW_PC_LIB_PRIV])
1007 AC_SUBST([GLW_PC_CFLAGS])
1008
1009 dnl
1010 dnl GLUT configuration
1011 dnl
1012 if test -f "$srcdir/include/GL/glut.h"; then
1013     default_glut=yes
1014 else
1015     default_glut=no
1016 fi
1017 AC_ARG_ENABLE([glut],
1018     [AS_HELP_STRING([--disable-glut],
1019         [enable GLUT library @<:@default=enabled if source available@:>@])],
1020     [enable_glut="$enableval"],
1021     [enable_glut="$default_glut"])
1022
1023 dnl Can't build glut if GLU not available
1024 if test "x$enable_glu$enable_glut" = xnoyes; then
1025     AC_MSG_WARN([Disabling glut since GLU is disabled])
1026     enable_glut=no
1027 fi
1028 dnl Don't build glut on osmesa
1029 if test "x$enable_glut" = xyes && test "$mesa_driver" = osmesa; then
1030     AC_MSG_WARN([Disabling glut since the driver is OSMesa])
1031     enable_glut=no
1032 fi
1033
1034 if test "x$enable_glut" = xyes; then
1035     SRC_DIRS="$SRC_DIRS glut/glx"
1036     GLUT_CFLAGS=""
1037     if test "x$GCC" = xyes; then
1038         GLUT_CFLAGS="-fexceptions"
1039     fi
1040     if test "$x11_pkgconfig" = yes; then
1041         PKG_CHECK_MODULES([GLUT],[x11 xmu xi])
1042         GLUT_PC_REQ_PRIV="x11 xmu xi"
1043         GLUT_LIB_DEPS="$GLUT_LIBS"
1044     else
1045         # should check these...
1046         GLUT_LIB_DEPS="$X_LIBS -lX11 -lXmu -lXi"
1047         GLUT_PC_LIB_PRIV="$GLUT_LIB_DEPS"
1048         GLUT_PC_CFLAGS="$X11_INCLUDES"
1049     fi
1050     GLUT_LIB_DEPS="$GLUT_LIB_DEPS -lm"
1051     GLUT_PC_LIB_PRIV="$GLUT_PC_LIB_PRIV -lm"
1052
1053     # If glut is available, we can build most programs
1054     if test "$with_demos" = yes; then
1055         PROGRAM_DIRS="$PROGRAM_DIRS demos redbook samples glsl"
1056     fi
1057
1058     # If static, empty GLUT_LIB_DEPS and add libs for programs to link
1059     if test "$enable_static" = no; then
1060         GLUT_MESA_DEPS='-l$(GLU_LIB) -l$(GL_LIB)'
1061     else
1062         APP_LIB_DEPS="$APP_LIB_DEPS $GLUT_LIB_DEPS"
1063         GLUT_LIB_DEPS=""
1064         GLUT_MESA_DEPS=""
1065     fi
1066 fi
1067 AC_SUBST([GLUT_LIB_DEPS])
1068 AC_SUBST([GLUT_MESA_DEPS])
1069 AC_SUBST([GLUT_CFLAGS])
1070 AC_SUBST([GLUT_PC_REQ_PRIV])
1071 AC_SUBST([GLUT_PC_LIB_PRIV])
1072 AC_SUBST([GLUT_PC_CFLAGS])
1073
1074 dnl
1075 dnl Program library dependencies
1076 dnl    Only libm is added here if necessary as the libraries should
1077 dnl    be pulled in by the linker
1078 dnl
1079 if test "x$APP_LIB_DEPS" = x; then
1080     case "$host_os" in
1081     solaris*)
1082         APP_LIB_DEPS="-lX11 -lsocket -lnsl -lm"
1083         ;;
1084     *)
1085         APP_LIB_DEPS="-lm"
1086         ;;
1087     esac
1088 fi
1089 AC_SUBST([APP_LIB_DEPS])
1090 AC_SUBST([PROGRAM_DIRS])
1091
1092 dnl
1093 dnl Gallium configuration
1094 dnl
1095 AC_ARG_ENABLE([gallium],
1096     [AS_HELP_STRING([--disable-gallium],
1097         [build gallium @<:@default=enabled@:>@])],
1098     [enable_gallium="$enableval"],
1099     [enable_gallium=yes])
1100 if test "x$enable_gallium" = xyes; then
1101     SRC_DIRS="$SRC_DIRS gallium gallium/winsys"
1102 fi
1103
1104 dnl
1105 dnl Gallium state trackers configuration
1106 dnl
1107 AC_ARG_WITH([state-trackers],
1108     [AS_HELP_STRING([--with-state-trackers@<:@=DIRS...@:>@],
1109         [comma delimited state_trackers list, e.g.
1110         "egl,glx" @<:@default=auto@:>@])],
1111     [with_state_trackers="$withval"],
1112     [with_state_trackers=yes])
1113
1114 case "$with_state_trackers" in
1115 no)
1116     GALLIUM_STATE_TRACKERS_DIRS=""
1117     ;;
1118 yes)
1119     # look at what else is built
1120     case "$mesa_driver" in
1121     xlib)
1122         GALLIUM_STATE_TRACKERS_DIRS=glx
1123         ;;
1124     dri)
1125         test "x$enable_egl" = xyes && GALLIUM_STATE_TRACKERS_DIRS=egl
1126         ;;
1127     esac
1128     ;;
1129 *)
1130     # verify the requested state tracker exist
1131     state_trackers=`IFS=', '; echo $with_state_trackers`
1132     for tracker in $state_trackers; do
1133         test -d "$srcdir/src/gallium/state_trackers/$tracker" || \
1134             AC_MSG_ERROR([state tracker '$tracker' doesn't exist])
1135
1136         if test "$tracker" = egl && test "x$enable_egl" != xyes; then
1137             AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1138         fi
1139     done
1140     GALLIUM_STATE_TRACKERS_DIRS="$state_trackers"
1141     ;;
1142 esac
1143
1144 AC_ARG_WITH([xorg-driver-dir],
1145     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1146                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1147     [XORG_DRIVER_INSTALL_DIR="$withval"],
1148     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1149 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1150
1151 dnl
1152 dnl Gallium Intel configuration
1153 dnl
1154 AC_ARG_ENABLE([gallium-intel],
1155     [AS_HELP_STRING([--disable-gallium-intel],
1156         [build gallium intel @<:@default=enabled@:>@])],
1157     [enable_gallium_intel="$enableval"],
1158     [enable_gallium_intel=yes])
1159 if test "x$enable_gallium_intel" = xyes; then
1160     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS intel"
1161     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915simple"
1162 fi
1163
1164 dnl
1165 dnl Gallium Radeon configuration
1166 dnl
1167 AC_ARG_ENABLE([gallium-radeon],
1168     [AS_HELP_STRING([--enable-gallium-radeon],
1169         [build gallium radeon @<:@default=disabled@:>@])],
1170     [enable_gallium_radeon="$enableval"],
1171     [enable_gallium_radeon=no])
1172 if test "x$enable_gallium_radeon" = xyes; then
1173     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS radeon"
1174     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1175 fi
1176
1177 dnl
1178 dnl Gallium Radeon configuration
1179 dnl
1180 AC_ARG_ENABLE([gallium-nouveau],
1181     [AS_HELP_STRING([--enable-gallium-nouveau],
1182         [build gallium nouveau @<:@default=disabled@:>@])],
1183     [enable_gallium_nouveau="$enableval"],
1184     [enable_gallium_nouveau=no])
1185 if test "x$enable_gallium_nouveau" = xyes; then
1186     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS nouveau"
1187     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nv04 nv10 nv20 nv30 nv40 nv50"
1188 fi
1189
1190
1191 dnl Restore LDFLAGS and CPPFLAGS
1192 LDFLAGS="$_SAVE_LDFLAGS"
1193 CPPFLAGS="$_SAVE_CPPFLAGS"
1194
1195 dnl Substitute the config
1196 AC_CONFIG_FILES([configs/autoconf])
1197
1198 dnl Replace the configs/current symlink
1199 AC_CONFIG_COMMANDS([configs],[
1200 if test -f configs/current || test -L configs/current; then
1201     rm -f configs/current
1202 fi
1203 ln -s autoconf configs/current
1204 ])
1205
1206 AC_OUTPUT
1207
1208 dnl
1209 dnl Output some configuration info for the user
1210 dnl
1211 echo ""
1212 echo "        prefix:          $prefix"
1213 echo "        exec_prefix:     $exec_prefix"
1214 echo "        libdir:          $libdir"
1215 echo "        includedir:      $includedir"
1216
1217 dnl Driver info
1218 echo ""
1219 echo "        Driver:          $mesa_driver"
1220 if echo "$DRIVER_DIRS" | grep 'osmesa' >/dev/null 2>&1; then
1221     echo "        OSMesa:          lib$OSMESA_LIB"
1222 else
1223     echo "        OSMesa:          no"
1224 fi
1225 if test "$mesa_driver" = dri; then
1226     # cleanup the drivers var
1227     dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1228 if test "x$DRI_DIRS" = x; then
1229     echo "        DRI drivers:     no"
1230 else
1231     echo "        DRI drivers:     $dri_dirs"
1232 fi
1233     echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
1234 fi
1235 echo "        Use XCB:         $enable_xcb"
1236
1237 echo ""
1238 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
1239     echo "        Gallium:         yes"
1240     echo "        Gallium dirs:    $GALLIUM_DIRS"
1241     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
1242     echo "        Winsys drm dirs:$GALLIUM_WINSYS_DRM_DIRS"
1243     echo "        Auxiliary dirs:  $GALLIUM_AUXILIARY_DIRS"
1244     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
1245     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
1246 else
1247     echo "        Gallium:         no"
1248 fi
1249
1250 dnl Libraries
1251 echo ""
1252 echo "        Shared libs:     $enable_shared"
1253 echo "        Static libs:     $enable_static"
1254 echo "        EGL:             $enable_egl"
1255 echo "        GLU:             $enable_glu"
1256 echo "        GLw:             $enable_glw (Motif: $enable_motif)"
1257 echo "        glut:            $enable_glut"
1258
1259 dnl Programs
1260 # cleanup the programs var for display
1261 program_dirs=`echo $PROGRAM_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1262 if test "x$program_dirs" = x; then
1263     echo "        Demos:           no"
1264 else
1265     echo "        Demos:           $program_dirs"
1266 fi
1267
1268 dnl Compiler options
1269 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
1270 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1271     $SED 's/^ *//;s/  */ /;s/ *$//'`
1272 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1273     $SED 's/^ *//;s/  */ /;s/ *$//'`
1274 defines=`echo $DEFINES $ASM_FLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1275 echo ""
1276 echo "        CFLAGS:          $cflags"
1277 echo "        CXXFLAGS:        $cxxflags"
1278 echo "        Macros:          $defines"
1279
1280 echo ""
1281 echo "        Run '${MAKE-make}' to build Mesa"
1282 echo ""