configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.59])
   4
   5 dnl Versioning - scrape the version from configs/default
   6 m4_define([mesa_version],
   7     [m4_esyscmd([${MAKE-make} -s -f bin/version.mk version | tr -d '\n'])])
   8 m4_ifval(mesa_version,[],[
   9     m4_errprint([Error: Failed to get the Mesa version from the output of
  10        running `make -f bin/version.mk version'
  11 ])
  12     m4_exit([1])
  13 ])
  14
  15 dnl Tell the user about autoconf.html in the --help output
  16 m4_divert_once([HELP_END], [
  17 See docs/autoconf.html for more details on the options for Mesa.])
  18
  19 AC_INIT([Mesa],[mesa_version],
  20     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  21 AC_CONFIG_AUX_DIR([bin])
  22 AC_CANONICAL_HOST
  23
  24 dnl Versions for external dependencies
  25 LIBDRM_REQUIRED=2.4.3
  26 DRI2PROTO_REQUIRED=1.99.3
  27
  28 dnl Check for progs
  29 AC_PROG_CPP
  30 AC_PROG_CC
  31 AC_PROG_CXX
  32 AC_CHECK_PROGS([MAKE], [gmake make])
  33 AC_PATH_PROG([MKDEP], [makedepend])
  34 AC_PATH_PROG([SED], [sed])
  35
  36 dnl We need a POSIX shell for parts of the build. Assume we have one
  37 dnl in most cases.
  38 case "$host_os" in
  39 solaris*)
  40     # Solaris /bin/sh is too old/non-POSIX compliant
  41     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  42     SHELL="$POSIX_SHELL"
  43     ;;
  44 esac
  45
  46 MKDEP_OPTIONS=-fdepend
  47 dnl Ask gcc where it's keeping its secret headers
  48 if test "x$GCC" = xyes; then
  49     for dir in include include-fixed; do
  50         GCC_INCLUDES=`$CC -print-file-name=$dir`
  51         if test "x$GCC_INCLUDES" != x && \
  52            test "$GCC_INCLUDES" != "$dir" && \
  53            test -d "$GCC_INCLUDES"; then
  54             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
  55         fi
  56     done
  57 fi
  58 AC_SUBST([MKDEP_OPTIONS])
  59
  60 dnl Make sure the pkg-config macros are defined
  61 m4_ifdef([PKG_PROG_PKG_CONFIG],[],[
  62     m4_errprint([Error: Could not locate the pkg-config autoconf macros.
  63        These are usually located in /usr/share/aclocal/pkg.m4. If your
  64        macros are in a different location, try setting the environment
  65        variable ACLOCAL="aclocal -I/other/macro/dir" before running
  66        autoreconf.
  67 ])
  68     m4_exit([1])
  69 ])
  70 PKG_PROG_PKG_CONFIG()
  71
  72 dnl LIB_DIR - library basename
  73 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
  74 AC_SUBST([LIB_DIR])
  75
  76 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
  77 _SAVE_LDFLAGS="$LDFLAGS"
  78 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
  79 AC_SUBST([EXTRA_LIB_PATH])
  80
  81 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
  82 _SAVE_CPPFLAGS="$CPPFLAGS"
  83 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
  84 AC_SUBST([X11_INCLUDES])
  85
  86 dnl Compiler macros
  87 DEFINES=""
  88 AC_SUBST([DEFINES])
  89 case "$host_os" in
  90 *-gnu*)
  91     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
  92     ;;
  93 solaris*)
  94     DEFINES="$DEFINES -DPTHREADS -DSVR4"
  95     ;;
  96 esac
  97
  98 dnl Add flags for gcc and g++
  99 if test "x$GCC" = xyes; then
 100     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -std=c99 -ffast-math"
 101
 102     # Work around aliasing bugs - developers should comment this out
 103     CFLAGS="$CFLAGS -fno-strict-aliasing"
 104 fi
 105 if test "x$GXX" = xyes; then
 106     CXXFLAGS="$CXXFLAGS -Wall"
 107
 108     # Work around aliasing bugs - developers should comment this out
 109     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 110 fi
 111
 112 dnl These should be unnecessary, but let the user set them if they want
 113 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
 114     Default is to use CFLAGS.])
 115 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
 116     compiler. Default is to use CFLAGS.])
 117 AC_SUBST([OPT_FLAGS])
 118 AC_SUBST([ARCH_FLAGS])
 119
 120 dnl
 121 dnl Hacks to enable 32 or 64 bit build
 122 dnl
 123 AC_ARG_ENABLE([32-bit],
 124     [AS_HELP_STRING([--enable-32-bit],
 125         [build 32-bit libraries @<:@default=auto@:>@])],
 126     [enable_32bit="$enableval"],
 127     [enable_32bit=auto]
 128 )
 129 if test "x$enable_32bit" = xyes; then
 130     if test "x$GCC" = xyes; then
 131         CFLAGS="$CFLAGS -m32"
 132     fi
 133     if test "x$GXX" = xyes; then
 134         CXXFLAGS="$CXXFLAGS -m32"
 135     fi
 136 fi
 137 AC_ARG_ENABLE([64-bit],
 138     [AS_HELP_STRING([--enable-64-bit],
 139         [build 64-bit libraries @<:@default=auto@:>@])],
 140     [enable_64bit="$enableval"],
 141     [enable_64bit=auto]
 142 )
 143 if test "x$enable_64bit" = xyes; then
 144     if test "x$GCC" = xyes; then
 145         CFLAGS="$CFLAGS -m64"
 146     fi
 147     if test "x$GXX" = xyes; then
 148         CXXFLAGS="$CXXFLAGS -m64"
 149     fi
 150 fi
 151
 152 dnl
 153 dnl shared/static libraries, mimic libtool options
 154 dnl
 155 AC_ARG_ENABLE([static],
 156     [AS_HELP_STRING([--enable-static],
 157         [build static libraries @<:@default=disabled@:>@])],
 158     [enable_static="$enableval"],
 159     [enable_static=no]
 160 )
 161 case "x$enable_static" in
 162 xyes|xno ) ;;
 163 x ) enable_static=no ;;
 164 * )
 165     AC_MSG_ERROR([Static library option '$enable_static' is not a valid])
 166     ;;
 167 esac
 168 AC_ARG_ENABLE([shared],
 169     [AS_HELP_STRING([--disable-shared],
 170         [build shared libraries @<:@default=enabled@:>@])],
 171     [enable_shared="$enableval"],
 172     [enable_shared=yes]
 173 )
 174 case "x$enable_shared" in
 175 xyes|xno ) ;;
 176 x ) enable_shared=yes ;;
 177 * )
 178     AC_MSG_ERROR([Shared library option '$enable_shared' is not a valid])
 179     ;;
 180 esac
 181
 182 dnl Can't have static and shared libraries, default to static if user
 183 dnl explicitly requested. If both disabled, set to static since shared
 184 dnl was explicitly requirested.
 185 case "x$enable_static$enable_shared" in
 186 xyesyes )
 187     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 188     enable_shared=no
 189     ;;
 190 xnono )
 191     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 192     enable_static=yes
 193     ;;
 194 esac
 195
 196 dnl
 197 dnl mklib options
 198 dnl
 199 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 200 if test "$enable_static" = yes; then
 201     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 202 fi
 203 AC_SUBST([MKLIB_OPTIONS])
 204
 205 dnl
 206 dnl other compiler options
 207 dnl
 208 AC_ARG_ENABLE([debug],
 209     [AS_HELP_STRING([--enable-debug],
 210         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 211     [enable_debug="$enableval"],
 212     [enable_debug=no]
 213 )
 214 if test "x$enable_debug" = xyes; then
 215     DEFINES="$DEFINES -DDEBUG"
 216     if test "x$GCC" = xyes; then
 217         CFLAGS="$CFLAGS -g"
 218     fi
 219     if test "x$GXX" = xyes; then
 220         CXXFLAGS="$CXXFLAGS -g"
 221     fi
 222 fi
 223
 224 dnl
 225 dnl library names
 226 dnl
 227 if test "$enable_static" = yes; then
 228     GL_LIB_NAME='lib$(GL_LIB).a'
 229     GLU_LIB_NAME='lib$(GLU_LIB).a'
 230     GLUT_LIB_NAME='lib$(GLUT_LIB).a'
 231     GLW_LIB_NAME='lib$(GLW_LIB).a'
 232     OSMESA_LIB_NAME='lib$(OSMESA_LIB).a'
 233 else
 234     case "$host_os" in
 235     darwin* )
 236         LIB_EXTENSION='dylib' ;;
 237     * )
 238         LIB_EXTENSION='so' ;;
 239     esac
 240
 241     GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 242     GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 243     GLUT_LIB_NAME='lib$(GLUT_LIB).'${LIB_EXTENSION}
 244     GLW_LIB_NAME='lib$(GLW_LIB).'${LIB_EXTENSION}
 245     OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 246
 247     GL_LIB_GLOB='lib$(GL_LIB).*'${LIB_EXTENSION}'*'
 248     GLU_LIB_GLOB='lib$(GLU_LIB).*'${LIB_EXTENSION}'*'
 249     GLUT_LIB_GLOB='lib$(GLUT_LIB).*'${LIB_EXTENSION}'*'
 250     GLW_LIB_GLOB='lib$(GLW_LIB).*'${LIB_EXTENSION}'*'
 251     OSMESA_LIB_GLOB='lib$(OSMESA_LIB).*'${LIB_EXTENSION}'*'
 252 fi
 253 AC_SUBST([GL_LIB_NAME])
 254 AC_SUBST([GLU_LIB_NAME])
 255 AC_SUBST([GLUT_LIB_NAME])
 256 AC_SUBST([GLW_LIB_NAME])
 257 AC_SUBST([OSMESA_LIB_NAME])
 258
 259 AC_SUBST([GL_LIB_GLOB])
 260 AC_SUBST([GLU_LIB_GLOB])
 261 AC_SUBST([GLUT_LIB_GLOB])
 262 AC_SUBST([GLW_LIB_GLOB])
 263 AC_SUBST([OSMESA_LIB_GLOB])
 264
 265 dnl
 266 dnl Arch/platform-specific settings
 267 dnl
 268 AC_ARG_ENABLE([asm],
 269     [AS_HELP_STRING([--disable-asm],
 270         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 271     [enable_asm="$enableval"],
 272     [enable_asm=yes]
 273 )
 274 asm_arch=""
 275 ASM_FLAGS=""
 276 MESA_ASM_SOURCES=""
 277 GLAPI_ASM_SOURCES=""
 278 AC_MSG_CHECKING([whether to enable assembly])
 279 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 280 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 281 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 282     case "$host_cpu" in
 283     i?86 | x86_64)
 284         enable_asm=no
 285         AC_MSG_RESULT([no, cross compiling])
 286         ;;
 287     esac
 288 fi
 289 # check for supported arches
 290 if test "x$enable_asm" = xyes; then
 291     case "$host_cpu" in
 292     i?86)
 293         case "$host_os" in
 294         linux* | *freebsd* | dragonfly*)
 295             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 296             ;;
 297         esac
 298         ;;
 299     x86_64)
 300         case "$host_os" in
 301         linux* | *freebsd* | dragonfly*)
 302             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 303             ;;
 304         esac
 305         ;;
 306     powerpc)
 307         case "$host_os" in
 308         linux*)
 309             asm_arch=ppc
 310             ;;
 311         esac
 312         ;;
 313     esac
 314
 315     case "$asm_arch" in
 316     x86)
 317         ASM_FLAGS="-DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 318         MESA_ASM_SOURCES='$(X86_SOURCES)'
 319         GLAPI_ASM_SOURCES='$(X86_API)'
 320         AC_MSG_RESULT([yes, x86])
 321         ;;
 322     x86_64)
 323         ASM_FLAGS="-DUSE_X86_64_ASM"
 324         MESA_ASM_SOURCES='$(X86-64_SOURCES)'
 325         GLAPI_ASM_SOURCES='$(X86-64_API)'
 326         AC_MSG_RESULT([yes, x86_64])
 327         ;;
 328     ppc)
 329         ASM_FLAGS="-DUSE_PPC_ASM -DUSE_VMX_ASM"
 330         MESA_ASM_SOURCES='$(PPC_SOURCES)'
 331         AC_MSG_RESULT([yes, ppc])
 332         ;;
 333     *)
 334         AC_MSG_RESULT([no, platform not supported])
 335         ;;
 336     esac
 337 fi
 338 AC_SUBST([ASM_FLAGS])
 339 AC_SUBST([MESA_ASM_SOURCES])
 340 AC_SUBST([GLAPI_ASM_SOURCES])
 341
 342 dnl PIC code macro
 343 MESA_PIC_FLAGS
 344
 345 dnl Check to see if dlopen is in default libraries (like Solaris, which
 346 dnl has it in libc), or if libdl is needed to get it.
 347 AC_CHECK_FUNC([dlopen], [],
 348     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 349
 350 dnl See if posix_memalign is available
 351 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 352
 353 dnl SELinux awareness.
 354 AC_ARG_ENABLE([selinux],
 355     [AS_HELP_STRING([--enable-selinux],
 356         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 357     [MESA_SELINUX="$enableval"],
 358     [MESA_SELINUX=no])
 359 if test "x$enable_selinux" = "xyes"; then
 360     AC_CHECK_HEADER([selinux/selinux.h],[],
 361                     [AC_MSG_ERROR([SELinux headers not found])])
 362     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 363                  [AC_MSG_ERROR([SELinux library not found])])
 364     SELINUX_LIBS="-lselinux"
 365     DEFINES="$DEFINES -DMESA_SELINUX"
 366 fi
 367
 368 dnl OS-specific libraries
 369 OS_LIBS=""
 370 case "$host_os" in
 371 solaris*)
 372     OS_LIBS="-lc"
 373     if test "x$GXX" != xyes; then
 374         OS_CPLUSPLUS_LIBS="-lCrun $OS_LIBS"
 375     fi
 376     ;;
 377 esac
 378
 379 dnl
 380 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 381 dnl More later: directfb, fbdev, ...
 382 dnl
 383 default_driver="xlib"
 384
 385 case "$host_os" in
 386 linux*)
 387     case "$host_cpu" in
 388     i*86|x86_64|powerpc*) default_driver="dri";;
 389     esac
 390     ;;
 391 *freebsd* | dragonfly*)
 392     case "$host_cpu" in
 393     i*86|x86_64) default_driver="dri";;
 394     esac
 395     ;;
 396 esac
 397
 398 AC_ARG_WITH([driver],
 399     [AS_HELP_STRING([--with-driver=DRIVER],
 400         [driver for Mesa: xlib,dri,osmesa @<:@default=dri when available, or xlib@:>@])],
 401     [mesa_driver="$withval"],
 402     [mesa_driver="$default_driver"])
 403 dnl Check for valid option
 404 case "x$mesa_driver" in
 405 xxlib|xdri|xosmesa)
 406     ;;
 407 *)
 408     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 409     ;;
 410 esac
 411
 412 dnl
 413 dnl Driver specific build directories
 414 dnl
 415 SRC_DIRS="mesa egl"
 416 GLU_DIRS="sgi"
 417 WINDOW_SYSTEM=""
 418 GALLIUM_DIRS="auxiliary drivers state_trackers"
 419 GALLIUM_WINSYS_DIRS=""
 420 GALLIUM_WINSYS_DRM_DIRS=""
 421 GALLIUM_AUXILIARY_DIRS="draw translate cso_cache pipebuffer tgsi sct rtasm util"
 422 GALLIUM_DRIVER_DIRS="softpipe failover trace"
 423 GALLIUM_STATE_TRACKERS_DIRS=""
 424
 425 case "$mesa_driver" in
 426 xlib)
 427     DRIVER_DIRS="x11"
 428     ;;
 429 dri)
 430     SRC_DIRS="glx/x11 $SRC_DIRS"
 431     DRIVER_DIRS="dri"
 432     WINDOW_SYSTEM="dri"
 433     GALLIUM_WINSYS_DIRS="drm $GALLIUM_WINSYS_DIRS"
 434     GALLIUM_WINSYS_DRM_DIRS="intel"
 435     GALLIUM_DRIVER_DIRS="$GALLIUM_DRIVER_DIRS i915simple i965simple"
 436     GALLIUM_STATE_TRACKERS_DIRS="egl"
 437     ;;
 438 osmesa)
 439     DRIVER_DIRS="osmesa"
 440     ;;
 441 esac
 442 AC_SUBST([SRC_DIRS])
 443 AC_SUBST([GLU_DIRS])
 444 AC_SUBST([DRIVER_DIRS])
 445 AC_SUBST([WINDOW_SYSTEM])
 446 AC_SUBST([GALLIUM_DIRS])
 447 AC_SUBST([GALLIUM_WINSYS_DIRS])
 448 AC_SUBST([GALLIUM_WINSYS_DRM_DIRS])
 449 AC_SUBST([GALLIUM_DRIVER_DIRS])
 450 AC_SUBST([GALLIUM_AUXILIARY_DIRS])
 451 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 452
 453 dnl
 454 dnl User supplied program configuration
 455 dnl
 456 if test -d "$srcdir/progs/demos"; then
 457     default_demos=yes
 458 else
 459     default_demos=no
 460 fi
 461 AC_ARG_WITH([demos],
 462     [AS_HELP_STRING([--with-demos@<:@=DIRS...@:>@],
 463         [optional comma delimited demo directories to build
 464         @<:@default=auto if source available@:>@])],
 465     [with_demos="$withval"],
 466     [with_demos="$default_demos"])
 467 if test "x$with_demos" = x; then
 468     with_demos=no
 469 fi
 470
 471 dnl If $with_demos is yes, directories will be added as libs available
 472 PROGRAM_DIRS=""
 473 case "$with_demos" in
 474 no) ;;
 475 yes)
 476     # If the driver isn't osmesa, we have libGL and can build xdemos
 477     if test "$mesa_driver" != osmesa; then
 478         PROGRAM_DIRS="xdemos"
 479     fi
 480     ;;
 481 *)
 482     # verify the requested demos directories exist
 483     demos=`IFS=,; echo $with_demos`
 484     for demo in $demos; do
 485         test -d "$srcdir/progs/$demo" || \
 486             AC_MSG_ERROR([Program directory '$demo' doesn't exist])
 487     done
 488     PROGRAM_DIRS="$demos"
 489     ;;
 490 esac
 491
 492 dnl
 493 dnl Find out if X is available. The variable have_x is set if libX11 is
 494 dnl found to mimic AC_PATH_XTRA.
 495 dnl
 496 if test -n "$PKG_CONFIG"; then
 497     AC_MSG_CHECKING([pkg-config files for X11 are available])
 498     PKG_CHECK_EXISTS([x11],[
 499         x11_pkgconfig=yes
 500         have_x=yes
 501         ],[
 502         x11_pkgconfig=no
 503     ])
 504     AC_MSG_RESULT([$x11_pkgconfig])
 505 else
 506     x11_pkgconfig=no
 507 fi
 508 dnl Use the autoconf macro if no pkg-config files
 509 if test "$x11_pkgconfig" = no; then
 510     AC_PATH_XTRA
 511 fi
 512
 513 dnl Try to tell the user that the --x-* options are only used when
 514 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 515 m4_divert_once([HELP_BEGIN],
 516 [These options are only used when the X libraries cannot be found by the
 517 pkg-config utility.])
 518
 519 dnl We need X for xlib and dri, so bomb now if it's not found
 520 case "$mesa_driver" in
 521 xlib|dri)
 522     if test "$no_x" = yes; then
 523         AC_MSG_ERROR([X11 development libraries needed for $mesa_driver driver])
 524     fi
 525     ;;
 526 esac
 527
 528 dnl XCB - this is only used for GLX right now
 529 AC_ARG_ENABLE([xcb],
 530     [AS_HELP_STRING([--enable-xcb],
 531         [use XCB for GLX @<:@default=disabled@:>@])],
 532     [enable_xcb="$enableval"],
 533     [enable_xcb=no])
 534 if test "x$enable_xcb" = xyes; then
 535     DEFINES="$DEFINES -DUSE_XCB"
 536 else
 537     enable_xcb=no
 538 fi
 539
 540 dnl
 541 dnl libGL configuration per driver
 542 dnl
 543 case "$mesa_driver" in
 544 xlib)
 545     if test "$x11_pkgconfig" = yes; then
 546         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 547         GL_PC_REQ_PRIV="x11 xext"
 548         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 549         GL_LIB_DEPS="$XLIBGL_LIBS"
 550     else
 551         # should check these...
 552         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 553         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 554         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 555         GL_PC_CFLAGS="$X11_INCLUDES"
 556     fi
 557     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread $OS_LIBS"
 558     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread $OS_LIBS"
 559
 560     # if static, move the external libraries to the programs
 561     # and empty the libraries for libGL
 562     if test "$enable_static" = yes; then
 563         APP_LIB_DEPS="$APP_LIB_DEPS $GL_LIB_DEPS"
 564         GL_LIB_DEPS=""
 565     fi
 566     ;;
 567 dri)
 568     # DRI must be shared, I think
 569     if test "$enable_static" = yes; then
 570         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 571     fi
 572
 573     # Check for libdrm
 574     PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED])
 575     PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 576     GL_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED"
 577     DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 578
 579     # find the DRI deps for libGL
 580     if test "$x11_pkgconfig" = yes; then
 581         # add xcb modules if necessary
 582         dri_modules="x11 xext xxf86vm xdamage xfixes"
 583         if test "$enable_xcb" = yes; then
 584             dri_modules="$dri_modules x11-xcb xcb-glx"
 585         fi
 586
 587         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 588         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 589         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 590         GL_LIB_DEPS="$DRIGL_LIBS"
 591     else
 592         # should check these...
 593         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 594         GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
 595         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 596         GL_PC_CFLAGS="$X11_INCLUDES"
 597
 598         # XCB can only be used from pkg-config
 599         if test "$enable_xcb" = yes; then
 600             PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx])
 601             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
 602             X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
 603             GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
 604         fi
 605     fi
 606
 607     # need DRM libs, -lpthread, etc.
 608     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS $OS_LIBS"
 609     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS $OS_LIBS"
 610     ;;
 611 osmesa)
 612     # No libGL for osmesa
 613     GL_LIB_DEPS="$OS_LIBS"
 614     ;;
 615 esac
 616 AC_SUBST([GL_LIB_DEPS])
 617 AC_SUBST([GL_PC_REQ_PRIV])
 618 AC_SUBST([GL_PC_LIB_PRIV])
 619 AC_SUBST([GL_PC_CFLAGS])
 620 AC_SUBST([DRI_PC_REQ_PRIV])
 621
 622 dnl
 623 dnl More X11 setup
 624 dnl
 625 if test "$mesa_driver" = xlib; then
 626     DEFINES="$DEFINES -DUSE_XSHM"
 627 fi
 628
 629 dnl
 630 dnl More DRI setup
 631 dnl
 632 AC_ARG_ENABLE([glx-tls],
 633     [AS_HELP_STRING([--enable-glx-tls],
 634         [enable TLS support in GLX @<:@default=disabled@:>@])],
 635     [GLX_USE_TLS="$enableval"],
 636     [GLX_USE_TLS=no])
 637 dnl Directory for DRI drivers
 638 AC_ARG_WITH([dri-driverdir],
 639     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 640         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 641     [DRI_DRIVER_INSTALL_DIR="$withval"],
 642     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 643 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 644 dnl Direct rendering or just indirect rendering
 645 AC_ARG_ENABLE([driglx-direct],
 646     [AS_HELP_STRING([--disable-driglx-direct],
 647         [enable direct rendering in GLX for DRI @<:@default=enabled@:>@])],
 648     [driglx_direct="$enableval"],
 649     [driglx_direct="yes"])
 650 dnl Which drivers to build - default is chosen by platform
 651 AC_ARG_WITH([dri-drivers],
 652     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 653         [comma delimited DRI drivers list, e.g.
 654         "swrast,i965,radeon,nouveau" @<:@default=auto@:>@])],
 655     [with_dri_drivers="$withval"],
 656     [with_dri_drivers=yes])
 657 if test "x$with_dri_drivers" = x; then
 658     with_dri_drivers=no
 659 fi
 660
 661 dnl If $with_dri_drivers is yes, directories will be added through
 662 dnl platform checks
 663 DRI_DIRS=""
 664 case "$with_dri_drivers" in
 665 no) ;;
 666 yes)
 667     DRI_DIRS="yes"
 668     ;;
 669 *)
 670     # verify the requested driver directories exist
 671     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 672     for driver in $dri_drivers; do
 673         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 674             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
 675     done
 676     DRI_DIRS="$dri_drivers"
 677     ;;
 678 esac
 679
 680 dnl Just default to no EGL for now
 681 USING_EGL=0
 682 AC_SUBST([USING_EGL])
 683
 684 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 685 if test "$mesa_driver" = dri; then
 686     # Use TLS in GLX?
 687     if test "x$GLX_USE_TLS" = xyes; then
 688         DEFINES="$DEFINES -DGLX_USE_TLS -DPTHREADS"
 689     fi
 690
 691     if test "x$USING_EGL" = x1; then
 692         PROGRAM_DIRS="egl"
 693     fi
 694
 695     # Platform specific settings and drivers to build
 696     case "$host_os" in
 697     linux*)
 698         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 699         if test "x$driglx_direct" = xyes; then
 700             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 701         fi
 702         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 703
 704         case "$host_cpu" in
 705         x86_64)
 706             # ffb, gamma, and sis are missing because they have not be
 707             # converted to use the new interface.  i810 are missing
 708             # because there is no x86-64 system where they could *ever*
 709             # be used.
 710             if test "x$DRI_DIRS" = "xyes"; then
 711                 DRI_DIRS="i915 i965 mach64 mga r128 r200 r300 radeon \
 712                     savage tdfx unichrome swrast"
 713             fi
 714             ;;
 715         powerpc*)
 716             # Build only the drivers for cards that exist on PowerPC.
 717             # At some point MGA will be added, but not yet.
 718             if test "x$DRI_DIRS" = "xyes"; then
 719                 DRI_DIRS="mach64 r128 r200 r300 radeon tdfx swrast"
 720             fi
 721             ;;
 722         sparc*)
 723             # Build only the drivers for cards that exist on sparc`
 724             if test "x$DRI_DIRS" = "xyes"; then
 725                 DRI_DIRS="mach64 r128 r200 r300 radeon ffb swrast"
 726             fi
 727             ;;
 728         esac
 729         ;;
 730     freebsd* | dragonfly*)
 731         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
 732         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
 733         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 734         if test "x$driglx_direct" = xyes; then
 735             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 736         fi
 737         if test "x$GXX" = xyes; then
 738             CXXFLAGS="$CXXFLAGS -ansi -pedantic"
 739         fi
 740
 741         # ffb and gamma are missing because they have not been converted
 742         # to use the new interface.
 743         if test "x$DRI_DIRS" = "xyes"; then
 744             DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 radeon tdfx \
 745                 unichrome savage sis swrast"
 746         fi
 747         ;;
 748     solaris*)
 749         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 750         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 751         if test "x$driglx_direct" = xyes; then
 752             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 753         fi
 754         ;;
 755     esac
 756
 757     # default drivers
 758     if test "x$DRI_DIRS" = "xyes"; then
 759         DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 radeon s3v \
 760             savage sis tdfx trident unichrome ffb swrast"
 761     fi
 762
 763     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
 764
 765     # Check for expat
 766     EXPAT_INCLUDES=""
 767     EXPAT_LIB=-lexpat
 768     AC_ARG_WITH([expat],
 769         [AS_HELP_STRING([--with-expat=DIR],
 770             [expat install directory])],[
 771         EXPAT_INCLUDES="-I$withval/include"
 772         CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
 773         LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
 774         EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
 775         ])
 776     AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
 777     AC_CHECK_LIB([expat],[XML_ParserCreate],[],
 778         [AC_MSG_ERROR([Expat required for DRI.])])
 779
 780     # put all the necessary libs together
 781     DRI_LIB_DEPS="$SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
 782 fi
 783 AC_SUBST([DRI_DIRS])
 784 AC_SUBST([EXPAT_INCLUDES])
 785 AC_SUBST([DRI_LIB_DEPS])
 786
 787 dnl
 788 dnl OSMesa configuration
 789 dnl
 790 if test "$mesa_driver" = xlib; then
 791     default_gl_osmesa=yes
 792 else
 793     default_gl_osmesa=no
 794 fi
 795 AC_ARG_ENABLE([gl-osmesa],
 796     [AS_HELP_STRING([--enable-gl-osmesa],
 797         [enable OSMesa on libGL @<:@default=enabled for xlib driver@:>@])],
 798     [gl_osmesa="$enableval"],
 799     [gl_osmesa="$default_gl_osmesa"])
 800 if test "x$gl_osmesa" = xyes; then
 801     if test "$mesa_driver" = osmesa; then
 802         AC_MSG_ERROR([libGL is not available for OSMesa driver])
 803     else
 804         DRIVER_DIRS="$DRIVER_DIRS osmesa"
 805     fi
 806 fi
 807
 808 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
 809 AC_ARG_WITH([osmesa-bits],
 810     [AS_HELP_STRING([--with-osmesa-bits=BITS],
 811         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
 812     [osmesa_bits="$withval"],
 813     [osmesa_bits=8])
 814 if test "$mesa_driver" != osmesa && test "x$osmesa_bits" != x8; then
 815     AC_MSG_WARN([Ignoring OSMesa channel bits for non-OSMesa driver])
 816     osmesa_bits=8
 817 fi
 818 case "x$osmesa_bits" in
 819 x8)
 820     OSMESA_LIB=OSMesa
 821     ;;
 822 x16|x32)
 823     OSMESA_LIB="OSMesa$osmesa_bits"
 824     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
 825     ;;
 826 *)
 827     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
 828     ;;
 829 esac
 830 AC_SUBST([OSMESA_LIB])
 831
 832 case "$mesa_driver" in
 833 osmesa)
 834     # only link libraries with osmesa if shared
 835     if test "$enable_static" = no; then
 836         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS"
 837     else
 838         OSMESA_LIB_DEPS=""
 839     fi
 840     OSMESA_MESA_DEPS=""
 841     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS"
 842     ;;
 843 *)
 844     # Link OSMesa to libGL otherwise
 845     OSMESA_LIB_DEPS=""
 846     # only link libraries with osmesa if shared
 847     if test "$enable_static" = no; then
 848         OSMESA_MESA_DEPS='-l$(GL_LIB)'
 849     else
 850         OSMESA_MESA_DEPS=""
 851     fi
 852     OSMESA_PC_REQ="gl"
 853     ;;
 854 esac
 855 if test "$enable_static" = no; then
 856     OSMESA_LIB_DEPS="$OSMESA_LIB_DEPS $OS_LIBS"
 857 fi
 858 OSMESA_PC_LIB_PRIV="$OSMESA_PC_LIB_PRIV $OS_LIBS"
 859 AC_SUBST([OSMESA_LIB_DEPS])
 860 AC_SUBST([OSMESA_MESA_DEPS])
 861 AC_SUBST([OSMESA_PC_REQ])
 862 AC_SUBST([OSMESA_PC_LIB_PRIV])
 863
 864 dnl
 865 dnl GLU configuration
 866 dnl
 867 AC_ARG_ENABLE([glu],
 868     [AS_HELP_STRING([--disable-glu],
 869         [enable OpenGL Utility library @<:@default=enabled@:>@])],
 870     [enable_glu="$enableval"],
 871     [enable_glu=yes])
 872 if test "x$enable_glu" = xyes; then
 873     SRC_DIRS="$SRC_DIRS glu"
 874
 875     case "$mesa_driver" in
 876     osmesa)
 877         # If GLU is available and we have libOSMesa (not 16 or 32),
 878         # we can build the osdemos
 879         if test "$with_demos" = yes && test "$osmesa_bits" = 8; then
 880             PROGRAM_DIRS="$PROGRAM_DIRS osdemos"
 881         fi
 882
 883         # Link libGLU to libOSMesa instead of libGL
 884         GLU_LIB_DEPS=""
 885         GLU_PC_REQ="osmesa"
 886         if test "$enable_static" = no; then
 887             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
 888         else
 889             GLU_MESA_DEPS=""
 890         fi
 891         ;;
 892     *)
 893         # If static, empty GLU_LIB_DEPS and add libs for programs to link
 894         GLU_PC_REQ="gl"
 895         GLU_PC_LIB_PRIV="-lm"
 896         if test "$enable_static" = no; then
 897             GLU_LIB_DEPS="-lm"
 898             GLU_MESA_DEPS='-l$(GL_LIB)'
 899         else
 900             GLU_LIB_DEPS=""
 901             GLU_MESA_DEPS=""
 902             APP_LIB_DEPS="$APP_LIB_DEPS -lstdc++"
 903         fi
 904         ;;
 905     esac
 906 fi
 907 if test "$enable_static" = no; then
 908     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
 909 fi
 910 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
 911 AC_SUBST([GLU_LIB_DEPS])
 912 AC_SUBST([GLU_MESA_DEPS])
 913 AC_SUBST([GLU_PC_REQ])
 914 AC_SUBST([GLU_PC_REQ_PRIV])
 915 AC_SUBST([GLU_PC_LIB_PRIV])
 916 AC_SUBST([GLU_PC_CFLAGS])
 917
 918 dnl
 919 dnl GLw configuration
 920 dnl
 921 AC_ARG_ENABLE([glw],
 922     [AS_HELP_STRING([--disable-glw],
 923         [enable Xt/Motif widget library @<:@default=enabled@:>@])],
 924     [enable_glw="$enableval"],
 925     [enable_glw=yes])
 926 dnl Don't build GLw on osmesa
 927 if test "x$enable_glw" = xyes && test "$mesa_driver" = osmesa; then
 928     AC_MSG_WARN([Disabling GLw since the driver is OSMesa])
 929     enable_glw=no
 930 fi
 931 AC_ARG_ENABLE([motif],
 932     [AS_HELP_STRING([--enable-motif],
 933         [use Motif widgets in GLw @<:@default=disabled@:>@])],
 934     [enable_motif="$enableval"],
 935     [enable_motif=no])
 936
 937 if test "x$enable_glw" = xyes; then
 938     SRC_DIRS="$SRC_DIRS glw"
 939     if test "$x11_pkgconfig" = yes; then
 940         PKG_CHECK_MODULES([GLW],[x11 xt])
 941         GLW_PC_REQ_PRIV="x11 xt"
 942         GLW_LIB_DEPS="$GLW_LIBS"
 943     else
 944         # should check these...
 945         GLW_LIB_DEPS="$X_LIBS -lXt -lX11"
 946         GLW_PC_LIB_PRIV="$GLW_LIB_DEPS"
 947         GLW_PC_CFLAGS="$X11_INCLUDES"
 948     fi
 949
 950     GLW_SOURCES="GLwDrawA.c"
 951     MOTIF_CFLAGS=
 952     if test "x$enable_motif" = xyes; then
 953         GLW_SOURCES="$GLW_SOURCES GLwMDrawA.c"
 954         AC_PATH_PROG([MOTIF_CONFIG], [motif-config], [no])
 955         if test "x$MOTIF_CONFIG" != xno; then
 956             MOTIF_CFLAGS=`$MOTIF_CONFIG --cflags`
 957             MOTIF_LIBS=`$MOTIF_CONFIG --libs`
 958         else
 959             AC_CHECK_HEADER([Xm/PrimitiveP.h], [],
 960                 [AC_MSG_ERROR([Can't locate Motif headers])])
 961             AC_CHECK_LIB([Xm], [XmGetPixmap], [MOTIF_LIBS="-lXm"],
 962                 [AC_MSG_ERROR([Can't locate Motif Xm library])])
 963         fi
 964         # MOTIF_LIBS is prepended to GLW_LIB_DEPS since Xm needs Xt/X11
 965         GLW_LIB_DEPS="$MOTIF_LIBS $GLW_LIB_DEPS"
 966         GLW_PC_LIB_PRIV="$MOTIF_LIBS $GLW_PC_LIB_PRIV"
 967         GLW_PC_CFLAGS="$MOTIF_CFLAGS $GLW_PC_CFLAGS"
 968     fi
 969
 970     # If static, empty GLW_LIB_DEPS and add libs for programs to link
 971     GLW_PC_LIB_PRIV="$GLW_PC_LIB_PRIV $OS_LIBS"
 972     if test "$enable_static" = no; then
 973         GLW_MESA_DEPS='-l$(GL_LIB)'
 974         GLW_LIB_DEPS="$GLW_LIB_DEPS $OS_LIBS"
 975     else
 976         APP_LIB_DEPS="$APP_LIB_DEPS $GLW_LIB_DEPS"
 977         GLW_LIB_DEPS=""
 978         GLW_MESA_DEPS=""
 979     fi
 980 fi
 981 AC_SUBST([GLW_LIB_DEPS])
 982 AC_SUBST([GLW_MESA_DEPS])
 983 AC_SUBST([GLW_SOURCES])
 984 AC_SUBST([MOTIF_CFLAGS])
 985 AC_SUBST([GLW_PC_REQ_PRIV])
 986 AC_SUBST([GLW_PC_LIB_PRIV])
 987 AC_SUBST([GLW_PC_CFLAGS])
 988
 989 dnl
 990 dnl GLUT configuration
 991 dnl
 992 if test -f "$srcdir/include/GL/glut.h"; then
 993     default_glut=yes
 994 else
 995     default_glut=no
 996 fi
 997 AC_ARG_ENABLE([glut],
 998     [AS_HELP_STRING([--disable-glut],
 999         [enable GLUT library @<:@default=enabled if source available@:>@])],
1000     [enable_glut="$enableval"],
1001     [enable_glut="$default_glut"])
1002
1003 dnl Can't build glut if GLU not available
1004 if test "x$enable_glu$enable_glut" = xnoyes; then
1005     AC_MSG_WARN([Disabling glut since GLU is disabled])
1006     enable_glut=no
1007 fi
1008 dnl Don't build glut on osmesa
1009 if test "x$enable_glut" = xyes && test "$mesa_driver" = osmesa; then
1010     AC_MSG_WARN([Disabling glut since the driver is OSMesa])
1011     enable_glut=no
1012 fi
1013
1014 if test "x$enable_glut" = xyes; then
1015     SRC_DIRS="$SRC_DIRS glut/glx"
1016     GLUT_CFLAGS=""
1017     if test "x$GCC" = xyes; then
1018         GLUT_CFLAGS="-fexceptions"
1019     fi
1020     if test "$x11_pkgconfig" = yes; then
1021         PKG_CHECK_MODULES([GLUT],[x11 xmu xi])
1022         GLUT_PC_REQ_PRIV="x11 xmu xi"
1023         GLUT_LIB_DEPS="$GLUT_LIBS"
1024     else
1025         # should check these...
1026         GLUT_LIB_DEPS="$X_LIBS -lX11 -lXmu -lXi"
1027         GLUT_PC_LIB_PRIV="$GLUT_LIB_DEPS"
1028         GLUT_PC_CFLAGS="$X11_INCLUDES"
1029     fi
1030     GLUT_LIB_DEPS="$GLUT_LIB_DEPS -lm $OS_LIBS"
1031     GLUT_PC_LIB_PRIV="$GLUT_PC_LIB_PRIV -lm $OS_LIBS"
1032
1033     # If glut is available, we can build most programs
1034     if test "$with_demos" = yes; then
1035         PROGRAM_DIRS="$PROGRAM_DIRS demos redbook samples glsl"
1036     fi
1037
1038     # If static, empty GLUT_LIB_DEPS and add libs for programs to link
1039     if test "$enable_static" = no; then
1040         GLUT_MESA_DEPS='-l$(GLU_LIB) -l$(GL_LIB)'
1041     else
1042         APP_LIB_DEPS="$APP_LIB_DEPS $GLUT_LIB_DEPS"
1043         GLUT_LIB_DEPS=""
1044         GLUT_MESA_DEPS=""
1045     fi
1046 fi
1047 AC_SUBST([GLUT_LIB_DEPS])
1048 AC_SUBST([GLUT_MESA_DEPS])
1049 AC_SUBST([GLUT_CFLAGS])
1050 AC_SUBST([GLUT_PC_REQ_PRIV])
1051 AC_SUBST([GLUT_PC_LIB_PRIV])
1052 AC_SUBST([GLUT_PC_CFLAGS])
1053
1054 dnl
1055 dnl Program library dependencies
1056 dnl    Only libm is added here if necessary as the libraries should
1057 dnl    be pulled in by the linker
1058 dnl
1059 if test "x$APP_LIB_DEPS" = x; then
1060     case "$host_os" in
1061     solaris*)
1062         APP_LIB_DEPS="-lX11 -lsocket -lnsl -lm"
1063         ;;
1064     *)
1065         APP_LIB_DEPS="-lm"
1066         ;;
1067     esac
1068 fi
1069 AC_SUBST([APP_LIB_DEPS])
1070 AC_SUBST([PROGRAM_DIRS])
1071
1072 dnl
1073 dnl Gallium configuration
1074 dnl
1075 AC_ARG_ENABLE([gallium],
1076     [AS_HELP_STRING([--disable-gallium],
1077         [build gallium @<:@default=enabled@:>@])],
1078     [enable_gallium="$enableval"],
1079     [enable_gallium=yes])
1080 if test "x$enable_gallium" = xyes; then
1081     SRC_DIRS="$SRC_DIRS gallium gallium/winsys"
1082 fi
1083
1084 dnl Restore LDFLAGS and CPPFLAGS
1085 LDFLAGS="$_SAVE_LDFLAGS"
1086 CPPFLAGS="$_SAVE_CPPFLAGS"
1087
1088 dnl Substitute the config
1089 AC_CONFIG_FILES([configs/autoconf])
1090
1091 dnl Replace the configs/current symlink
1092 AC_CONFIG_COMMANDS([configs],[
1093 if test -f configs/current || test -L configs/current; then
1094     rm -f configs/current
1095 fi
1096 ln -s autoconf configs/current
1097 ])
1098
1099 AC_OUTPUT
1100
1101 dnl
1102 dnl Output some configuration info for the user
1103 dnl
1104 echo ""
1105 echo "        prefix:          $prefix"
1106 echo "        exec_prefix:     $exec_prefix"
1107 echo "        libdir:          $libdir"
1108 echo "        includedir:      $includedir"
1109
1110 dnl Driver info
1111 echo ""
1112 echo "        Driver:          $mesa_driver"
1113 if echo "$DRIVER_DIRS" | grep 'osmesa' >/dev/null 2>&1; then
1114     echo "        OSMesa:          lib$OSMESA_LIB"
1115 else
1116     echo "        OSMesa:          no"
1117 fi
1118 if test "$mesa_driver" = dri; then
1119     # cleanup the drivers var
1120     dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1121 if test "x$DRI_DIRS" = x; then
1122     echo "        DRI drivers:     no"
1123 else
1124     echo "        DRI drivers:     $dri_dirs"
1125 fi
1126     echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
1127 fi
1128 echo "        Use XCB:         $enable_xcb"
1129
1130 echo ""
1131 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
1132     echo "        Gallium:         yes"
1133     echo "        Gallium dirs:    $GALLIUM_DIRS"
1134     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
1135     echo "        Winsys drm dirs: $GALLIUM_WINSYS_DRM_DIRS"
1136     echo "        Auxiliary dirs:  $GALLIUM_AUXILIARY_DIRS"
1137     echo "        Driver dirs:     $GALLIUM_DRIVER_DIRS"
1138     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
1139 else
1140     echo "        Gallium:         no"
1141 fi
1142
1143 dnl Libraries
1144 echo ""
1145 echo "        Shared libs:     $enable_shared"
1146 echo "        Static libs:     $enable_static"
1147 echo "        GLU:             $enable_glu"
1148 echo "        GLw:             $enable_glw (Motif: $enable_motif)"
1149 echo "        glut:            $enable_glut"
1150
1151 dnl Programs
1152 # cleanup the programs var for display
1153 program_dirs=`echo $PROGRAM_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1154 if test "x$program_dirs" = x; then
1155     echo "        Demos:           no"
1156 else
1157     echo "        Demos:           $program_dirs"
1158 fi
1159
1160 dnl Compiler options
1161 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
1162 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1163     $SED 's/^ *//;s/  */ /;s/ *$//'`
1164 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1165     $SED 's/^ *//;s/  */ /;s/ *$//'`
1166 defines=`echo $DEFINES $ASM_FLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1167 echo ""
1168 echo "        CFLAGS:          $cflags"
1169 echo "        CXXFLAGS:        $cxxflags"
1170 echo "        Macros:          $defines"
1171
1172 echo ""
1173 echo "        Run '${MAKE-make}' to build Mesa"
1174 echo ""