configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_INIT([LHa for UNIX], 1.14i-ac20020629, jca02266@nifty.ne.jp, lha)
   3 AC_CANONICAL_TARGET
   4 AM_INIT_AUTOMAKE
   5 AM_CONFIG_HEADER(config.h)
   6
   7 AC_DEFINE_UNQUOTED(PLATFORM, "$ac_cv_host",
   8                    [the type of system on which the package will run.])
   9
  10 # Checks for programs.
  11 AC_PROG_CC
  12 AC_PROG_GCC_TRADITIONAL
  13 AC_PROG_INSTALL
  14 AC_PROG_MAKE_SET
  15 AC_MINIX
  16 AM_C_PROTOTYPES
  17
  18 # Checks for libraries.
  19 AC_SEARCH_LIBS(opendir, [mingwex])
  20
  21 # Checks for header files.
  22 AC_HEADER_DIRENT
  23 AC_HEADER_STDC
  24 AC_CHECK_HEADERS(fcntl.h limits.h sys/file.h sys/param.h sys/time.h)
  25 AC_CHECK_HEADERS(pwd.h grp.h)
  26
  27 # Checks for typedefs, structures, and compiler characteristics.
  28 AC_C_CONST
  29 AC_HEADER_TIME
  30 AC_STRUCT_TM
  31 AC_STRUCT_TIMEZONE
  32
  33 AC_CHECK_TYPES([uid_t, gid_t])
  34 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct stat.st_ino],,,
  35 [
  36 #if HAVE_SYS_TYPES_H
  37 # include <sys/types.h>
  38 #endif
  39 #if HAVE_SYS_STAT_H
  40 # include <sys/stat.h>
  41 #endif
  42 #if TIME_WITH_SYS_TIME
  43 # include <sys/time.h>
  44 # include <time.h>
  45 #else
  46 # if HAVE_SYS_TIME_H
  47 #  include <sys/time.h>
  48 # else
  49 #  include <time.h>
  50 # endif
  51 #endif
  52 ])
  53
  54 # Checks for library functions.
  55 AC_TYPE_SIGNAL
  56 AC_FUNC_FORK
  57 AC_FUNC_UTIME_NULL
  58 AC_CHECK_FUNCS(strchr strdup memcpy memset memmove)
  59 AC_CHECK_FUNCS(mktime timelocal tzset ftime gettimeofday utime)
  60 AC_CHECK_FUNCS(mkdir rmdir ftruncate lchown mkstemp)
  61 AC_CHECK_FUNCS(strcasecmp link)
  62 AC_CHECK_FUNCS(getpwuid getgrgid getpwnam getgrnam)
  63
  64 if test $ac_header_dirent = no; then
  65   AC_LIBOBJ(lhdir)
  66 fi
  67
  68 # support kanji code conversion
  69 AC_SUBST(DEF_KCODE)
  70 AC_ARG_ENABLE(text_conv,
  71   AC_HELP_STRING([--enable-text-conv],
  72                  [support text code convert from/to EUC [[default=yes]]]),
  73   , enable_text_conv=yes)
  74
  75 if test $enable_text_conv = yes; then
  76   DEF_KCODE=-DEUC
  77 fi
  78
  79 # force support -lh7-
  80 AC_SUBST(SUPPORT_LZHUFF_METHOD)
  81 SUPPORT_LZHUFF_METHOD=-DSUPPORT_LH7
  82
  83 # whether use the -lh567- method
  84 AC_MSG_CHECKING(default archive method is )
  85 AC_ARG_WITH(default_method,
  86   AC_HELP_STRING([--with-default-method=[[567]]],
  87                  [create the -lh[[567]]- archive default [[default=5]]]),
  88   [case $withval in
  89    [567]) ;;
  90    *) AC_MSG_ERROR(you should have specified 5, 6 or 7);;
  91    esac],
  92   with_default_method=5)
  93 AC_MSG_RESULT(-lh$with_default_method-)
  94 AC_DEFINE_UNQUOTED(DEFAULT_LZHUFF_METHOD, LZHUFF${with_default_method}_METHOD_NUM, [Define it to 5, 6 or 7 which you want to use -lhX- method, default])
  95
  96 # decide temporary path names
  97 AC_MSG_CHECKING(template of the temporary file is )
  98 AC_ARG_WITH(tmp_file,
  99   AC_HELP_STRING([--with-tmp-file=TEMPLATE],
 100                  [temporary file template [[default=/tmp/lhXXXXXX]]]),
 101   [case $withval in
 102    yes)  with_tmp_file=/tmp/lhXXXXXX ;;
 103    no)   ;;
 104    esac],
 105   with_tmp_file=/tmp/lhXXXXXX)
 106 AC_MSG_RESULT($with_tmp_file)
 107 if test x"$with_tmp_file" != xno; then
 108   AC_DEFINE_UNQUOTED(TMP_FILENAME_TEMPLATE, "$with_tmp_file",
 109     [temporary file template for mktemp/mkstemp])
 110 fi
 111
 112 # incremental indicator
 113 AC_ARG_ENABLE(indicator,
 114   AC_HELP_STRING([--enable-indicator],
 115                  [need incremental indicator [[default=yes]]]),
 116   ,
 117   # default
 118   enable_indicator=yes)
 119 if test "x$enable_indicator" = xyes; then
 120   AC_DEFINE(NEED_INCREMENTAL_INDICATOR, 1,
 121             [Define to 1 if you want to use the incremental indicator])
 122 fi
 123
 124 # support multibyte filename
 125 AC_MSG_CHECKING(kanji code for filename is )
 126 AC_ARG_ENABLE(multibyte-filename,
 127   AC_HELP_STRING([--enable-multibyte-filename],
 128                  [support multibyte filename. specify kanji code (euc, sjis, utf8 or auto) [[default=auto]]]),,
 129   # default
 130   enable_multibyte_filename=auto)
 131
 132 case $enable_multibyte_filename in
 133 auto|yes)
 134   AC_EGREP_CPP(SJIS,[
 135 #if defined(__CYGWIN__) || defined(__MINGW32__) || defined(__hpux)
 136 SJIS
 137 #endif], enable_multibyte_filename=CODE_SJIS,
 138   AC_EGREP_CPP(UTF8,[
 139 #if defined(__APPLE__)  /* for Mac OS X */
 140 UTF8
 141 #endif], enable_multibyte_filename=CODE_UTF8,
 142          enable_multibyte_filename=CODE_EUC));;
 143 sjis)    enable_multibyte_filename=CODE_SJIS;;
 144 euc)     enable_multibyte_filename=CODE_EUC;;
 145 utf8)    enable_multibyte_filename=CODE_UTF8;;
 146 no)      ;;
 147 *)       AC_MSG_ERROR([you should specify auto, sjis or euc as your system filename code.]);;
 148 esac
 149
 150 AC_MSG_RESULT($enable_multibyte_filename)
 151 if test x$enable_multibyte_filename != xno; then
 152   AC_DEFINE_UNQUOTED(MULTIBYTE_FILENAME, $enable_multibyte_filename,
 153       [Define to CODE_EUC or CODE_SJIS if you want to use multibyte filename])
 154 fi
 155
 156 # make user/group name extented header
 157 AC_ARG_ENABLE(user-name-header,
 158   AC_HELP_STRING([--enable-user-name-header],
 159                  [make user/group name extended header [[default=no]]]),
 160   ,
 161   # default
 162   enable_user_name_header=no)
 163 if test "x$user_name_header" = xyes; then
 164   AC_DEFINE(INCLUDE_OWNER_NAME_IN_HEADER, 1,
 165             [Define to 1 if you want to use the user/group name extened header])
 166 fi
 167
 168 AC_CONFIG_FILES([Makefile src/Makefile man/Makefile])
 169 AC_CONFIG_FILES([tests/Makefile tests/lha-test])
 170 AC_OUTPUT