configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $PostgreSQL: pgsql/configure.in,v 1.577 2008/12/11 07:34:07 petere Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [8.4devel], [pgsql-bugs@postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.61], [], [m4_fatal([Autoconf version 2.61 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2008, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version as a string])
  33 [PG_MAJORVERSION=`expr "$PACKAGE_VERSION" : '\([0-9][0-9]*\.[0-9][0-9]*\)'`]
  34 AC_SUBST(PG_MAJORVERSION)
  35 AC_DEFINE_UNQUOTED(PG_MAJORVERSION, "$PG_MAJORVERSION", [PostgreSQL major version as a string])
  36
  37 AC_CANONICAL_HOST
  38
  39 template=
  40 AC_MSG_CHECKING([which template to use])
  41
  42 PGAC_ARG_REQ(with, template, [NAME], [override operating system template],
  43 [
  44   case $withval in
  45     list)   echo; ls "$srcdir/src/template"; exit;;
  46     *)      if test -f "$srcdir/src/template/$with_template" ; then
  47               template=$withval
  48             else
  49               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  50             fi;;
  51   esac
  52 ],
  53 [
  54 # --with-template not given
  55
  56 case $host_os in
  57      aix*) template=aix ;;
  58     bsdi*) template=bsdi ;;
  59   cygwin*) template=cygwin ;;
  60   darwin*) template=darwin ;;
  61     dgux*) template=dgux ;;
  62  freebsd*) template=freebsd ;;
  63     hpux*) template=hpux ;;
  64     irix*) template=irix ;;
  65  linux*|gnu*|k*bsd*-gnu)
  66            template=linux ;;
  67    mingw*) template=win32 ;;
  68   netbsd*) template=netbsd ;;
  69 nextstep*) template=nextstep ;;
  70  openbsd*) template=openbsd ;;
  71      osf*) template=osf ;;
  72      sco*) template=sco ;;
  73  solaris*) template=solaris ;;
  74    sunos*) template=sunos4 ;;
  75  sysv4.2*)
  76         case $host_vendor in
  77           univel) template=univel ;;
  78         esac ;;
  79    sysv4*) template=svr4 ;;
  80    sysv5*) template=unixware ;;
  81   ultrix*) template=ultrix4 ;;
  82 esac
  83
  84   if test x"$template" = x"" ; then
  85     AC_MSG_ERROR([[
  86 *******************************************************************
  87 PostgreSQL has apparently not been ported to your platform yet.
  88 To try a manual configuration, look into the src/template directory
  89 for a similar platform and use the '--with-template=' option.
  90
  91 Please also contact <pgsql-ports@postgresql.org> to see about
  92 rectifying this.  Include the above 'checking host system type...'
  93 line.
  94 *******************************************************************
  95 ]])
  96   fi
  97
  98 ])
  99
 100 AC_MSG_RESULT([$template])
 101
 102 PORTNAME=$template
 103 AC_SUBST(PORTNAME)
 104
 105 # Initialize default assumption that we do not need separate assembly code
 106 # for TAS (test-and-set).  This can be overridden by the template file
 107 # when it's executed.
 108 need_tas=no
 109 tas_file=dummy.s
 110
 111
 112
 113 ##
 114 ## Command line options
 115 ##
 116
 117 #
 118 # Add non-standard directories to the include path
 119 #
 120 PGAC_ARG_REQ(with, includes, [DIRS], [look for additional header files in DIRS])
 121
 122
 123 #
 124 # Add non-standard directories to the library search path
 125 #
 126 PGAC_ARG_REQ(with, libraries, [DIRS], [look for additional libraries in DIRS],
 127              [LIBRARY_DIRS=$withval])
 128
 129 PGAC_ARG_REQ(with, libs,      [DIRS], [alternative spelling of --with-libraries],
 130              [LIBRARY_DIRS=$withval])
 131
 132
 133 #
 134 # 64-bit integer date/time storage: enabled by default.
 135 #
 136 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 137 PGAC_ARG_BOOL(enable, integer-datetimes, yes, [disable 64-bit integer date/time support],
 138               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 139                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 140 AC_MSG_RESULT([$enable_integer_datetimes])
 141
 142
 143 #
 144 # NLS
 145 #
 146 AC_MSG_CHECKING([whether NLS is wanted])
 147 PGAC_ARG_OPTARG(enable, nls,
 148                 [LANGUAGES], [enable Native Language Support],
 149                 [],
 150                 [WANTED_LANGUAGES=$enableval],
 151                 [AC_DEFINE(ENABLE_NLS, 1,
 152                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 153 AC_MSG_RESULT([$enable_nls])
 154 AC_SUBST(enable_nls)
 155 AC_SUBST(WANTED_LANGUAGES)
 156
 157 #
 158 # Default port number (--with-pgport), default 5432
 159 #
 160 AC_MSG_CHECKING([for default port number])
 161 PGAC_ARG_REQ(with, pgport, [PORTNUM], [set default port number [5432]],
 162              [default_port=$withval],
 163              [default_port=5432])
 164 AC_MSG_RESULT([$default_port])
 165 # Need both of these because some places want an integer and some a string
 166 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 167 [Define to the default TCP port number on which the server listens and
 168 to which clients will try to connect.  This can be overridden at run-time,
 169 but it's convenient if your clients have the right default compiled in.
 170 (--with-pgport=PORTNUM)])
 171 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 172                    [Define to the default TCP port number as a string constant.])
 173 AC_SUBST(default_port)
 174
 175 #
 176 # Option to disable shared libraries
 177 #
 178 PGAC_ARG_BOOL(enable, shared, yes,
 179               [do not build shared libraries])
 180 AC_SUBST(enable_shared)
 181
 182 #
 183 # '-rpath'-like feature can be disabled
 184 #
 185 PGAC_ARG_BOOL(enable, rpath, yes,
 186               [do not embed shared library search path in executables])
 187 AC_SUBST(enable_rpath)
 188
 189 #
 190 # Spinlocks
 191 #
 192 PGAC_ARG_BOOL(enable, spinlocks, yes,
 193               [do not use spinlocks])
 194
 195 #
 196 # --enable-debug adds -g to compiler flags
 197 #
 198 PGAC_ARG_BOOL(enable, debug, no,
 199               [build with debugging symbols (-g)])
 200 AC_SUBST(enable_debug)
 201
 202 #
 203 # --enable-profiling enables gcc profiling
 204 #
 205 PGAC_ARG_BOOL(enable, profiling, no,
 206               [build with profiling enabled ])
 207 AC_SUBST(enable_profiling)
 208
 209 #
 210 # --enable-coverage enables generation of code coverage metrics with gcov
 211 #
 212 PGAC_ARG_BOOL(enable, coverage, no,
 213               [build with coverage testing instrumentation],
 214 [AC_CHECK_PROGS(GCOV, gcov)
 215 if test -z "$GCOV"; then
 216   AC_MSG_ERROR([gcov not found])
 217 fi
 218 AC_CHECK_PROGS(LCOV, lcov)
 219 if test -z "$LCOV"; then
 220   AC_MSG_ERROR([lcov not found])
 221 fi
 222 AC_CHECK_PROGS(GENHTML, genhtml)
 223 if test -z "$GENHTML"; then
 224   AC_MSG_ERROR([genhtml not found])
 225 fi])
 226 AC_SUBST(enable_coverage)
 227
 228 #
 229 # DTrace
 230 #
 231 PGAC_ARG_BOOL(enable, dtrace, no,
 232               [build with DTrace support],
 233 [AC_DEFINE([ENABLE_DTRACE], 1,
 234            [Define to 1 to enable DTrace support. (--enable-dtrace)])
 235 AC_CHECK_PROGS(DTRACE, dtrace)
 236 if test -z "$DTRACE"; then
 237   AC_MSG_ERROR([dtrace not found])
 238 fi
 239 AC_SUBST(DTRACEFLAGS)])
 240 AC_SUBST(enable_dtrace)
 241
 242 #
 243 # Block size
 244 #
 245 AC_MSG_CHECKING([for block size])
 246 PGAC_ARG_REQ(with, blocksize, [BLOCKSIZE], [set table block size in kB [8]],
 247              [blocksize=$withval],
 248              [blocksize=8])
 249 case ${blocksize} in
 250   1) BLCKSZ=1024;;
 251   2) BLCKSZ=2048;;
 252   4) BLCKSZ=4096;;
 253   8) BLCKSZ=8192;;
 254  16) BLCKSZ=16384;;
 255  32) BLCKSZ=32768;;
 256   *) AC_MSG_ERROR([Invalid block size. Allowed values are 1,2,4,8,16,32.])
 257 esac
 258 AC_MSG_RESULT([${blocksize}kB])
 259
 260 AC_DEFINE_UNQUOTED([BLCKSZ], ${BLCKSZ}, [
 261  Size of a disk block --- this also limits the size of a tuple.  You
 262  can set it bigger if you need bigger tuples (although TOAST should
 263  reduce the need to have large tuples, since fields can be spread
 264  across multiple tuples).
 265
 266  BLCKSZ must be a power of 2.  The maximum possible value of BLCKSZ
 267  is currently 2^15 (32768).  This is determined by the 15-bit widths
 268  of the lp_off and lp_len fields in ItemIdData (see
 269  include/storage/itemid.h).
 270
 271  Changing BLCKSZ requires an initdb.
 272 ])
 273
 274 #
 275 # Relation segment size
 276 #
 277 AC_MSG_CHECKING([for segment size])
 278 PGAC_ARG_REQ(with, segsize, [SEGSIZE], [set table segment size in GB [1]],
 279              [segsize=$withval],
 280              [segsize=1])
 281 # this expression is set up to avoid unnecessary integer overflow
 282 # blocksize is already guaranteed to be a factor of 1024
 283 RELSEG_SIZE=`expr '(' 1024 / ${blocksize} ')' '*' ${segsize} '*' 1024`
 284 test $? -eq 0 || exit 1
 285 AC_MSG_RESULT([${segsize}GB])
 286
 287 AC_DEFINE_UNQUOTED([RELSEG_SIZE], ${RELSEG_SIZE}, [
 288  RELSEG_SIZE is the maximum number of blocks allowed in one disk file.
 289  Thus, the maximum size of a single file is RELSEG_SIZE * BLCKSZ;
 290  relations bigger than that are divided into multiple files.
 291
 292  RELSEG_SIZE * BLCKSZ must be less than your OS' limit on file size.
 293  This is often 2 GB or 4GB in a 32-bit operating system, unless you
 294  have large file support enabled.  By default, we make the limit 1 GB
 295  to avoid any possible integer-overflow problems within the OS.
 296  A limit smaller than necessary only means we divide a large
 297  relation into more chunks than necessary, so it seems best to err
 298  in the direction of a small limit.
 299
 300  A power-of-2 value is recommended to save a few cycles in md.c,
 301  but is not absolutely required.
 302
 303  Changing RELSEG_SIZE requires an initdb.
 304 ])
 305
 306 #
 307 # WAL block size
 308 #
 309 AC_MSG_CHECKING([for WAL block size])
 310 PGAC_ARG_REQ(with, wal-blocksize, [BLOCKSIZE], [set WAL block size in kB [8]],
 311              [wal_blocksize=$withval],
 312              [wal_blocksize=8])
 313 case ${wal_blocksize} in
 314   1) XLOG_BLCKSZ=1024;;
 315   2) XLOG_BLCKSZ=2048;;
 316   4) XLOG_BLCKSZ=4096;;
 317   8) XLOG_BLCKSZ=8192;;
 318  16) XLOG_BLCKSZ=16384;;
 319  32) XLOG_BLCKSZ=32768;;
 320  64) XLOG_BLCKSZ=65536;;
 321   *) AC_MSG_ERROR([Invalid WAL block size. Allowed values are 1,2,4,8,16,32,64.])
 322 esac
 323 AC_MSG_RESULT([${wal_blocksize}kB])
 324
 325 AC_DEFINE_UNQUOTED([XLOG_BLCKSZ], ${XLOG_BLCKSZ}, [
 326  Size of a WAL file block.  This need have no particular relation to BLCKSZ.
 327  XLOG_BLCKSZ must be a power of 2, and if your system supports O_DIRECT I/O,
 328  XLOG_BLCKSZ must be a multiple of the alignment requirement for direct-I/O
 329  buffers, else direct I/O may fail.
 330
 331  Changing XLOG_BLCKSZ requires an initdb.
 332 ])
 333
 334 #
 335 # WAL segment size
 336 #
 337 AC_MSG_CHECKING([for WAL segment size])
 338 PGAC_ARG_REQ(with, wal-segsize, [SEGSIZE], [set WAL segment size in MB [16]],
 339              [wal_segsize=$withval],
 340              [wal_segsize=16])
 341 case ${wal_segsize} in
 342   1) ;;
 343   2) ;;
 344   4) ;;
 345   8) ;;
 346  16) ;;
 347  32) ;;
 348  64) ;;
 349   *) AC_MSG_ERROR([Invalid WAL segment size. Allowed values are 1,2,4,8,16,32,64.])
 350 esac
 351 AC_MSG_RESULT([${wal_segsize}MB])
 352
 353 AC_DEFINE_UNQUOTED([XLOG_SEG_SIZE], [(${wal_segsize} * 1024 * 1024)], [
 354  XLOG_SEG_SIZE is the size of a single WAL file.  This must be a power of 2
 355  and larger than XLOG_BLCKSZ (preferably, a great deal larger than
 356  XLOG_BLCKSZ).
 357
 358  Changing XLOG_SEG_SIZE requires an initdb.
 359 ])
 360
 361 #
 362 # C compiler
 363 #
 364
 365 # For historical reasons you can also use --with-CC to specify the C compiler
 366 # to use, although the standard way to do this is to set the CC environment
 367 # variable.
 368 PGAC_ARG_REQ(with, CC, [CMD], [set compiler (deprecated)], [CC=$with_CC])
 369
 370 case $template in
 371   aix) pgac_cc_list="gcc xlc";;
 372  irix) pgac_cc_list="cc";; # no gcc
 373     *) pgac_cc_list="gcc cc";;
 374 esac
 375
 376 AC_PROG_CC([$pgac_cc_list])
 377
 378 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 379 # but has idiosyncrasies of its own.  We assume icc will define
 380 # __INTEL_COMPILER regardless of CFLAGS.
 381 AC_TRY_COMPILE([], [@%:@ifndef __INTEL_COMPILER
 382 choke me
 383 @%:@endif], [ICC=[yes]], [ICC=[no]])
 384
 385 # Check if it's Sun Studio compiler. We assume that
 386 # __SUNPRO_C will be defined for Sun Studio compilers
 387 AC_TRY_COMPILE([], [@%:@ifndef __SUNPRO_C
 388 choke me
 389 @%:@endif], [SUN_STUDIO_CC=yes], [SUN_STUDIO_CC=no])
 390
 391 AC_SUBST(SUN_STUDIO_CC)
 392
 393 unset CFLAGS
 394
 395 #
 396 # Read the template
 397 #
 398 . "$srcdir/src/template/$template" || exit
 399
 400 # CFLAGS are selected so:
 401 # If the user specifies something in the environment, that is used.
 402 # else:  If the template file set something, that is used.
 403 # else:  If coverage was enabled, don't set anything.
 404 # else:  If the compiler is GCC, then we use -O2.
 405 # else:  If the compiler is something else, then we use -O.
 406
 407 if test "$ac_env_CFLAGS_set" = set; then
 408   CFLAGS=$ac_env_CFLAGS_value
 409 elif test "${CFLAGS+set}" = set; then
 410   : # (keep what template set)
 411 elif test "$enable_coverage" = yes; then
 412   : # no optimization by default
 413 elif test "$GCC" = yes; then
 414   CFLAGS="-O2"
 415 else
 416   # if the user selected debug mode, don't use -O
 417   if test "$enable_debug" != yes; then
 418     CFLAGS="-O"
 419   fi
 420 fi
 421
 422 # Some versions of GCC support some additional useful warning flags.
 423 # Check whether they are supported, and add them to CFLAGS if so.
 424 # ICC pretends to be GCC but it's lying; it doesn't support these options.
 425
 426 if test "$GCC" = yes -a "$ICC" = no; then
 427   CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wpointer-arith"
 428   # These work in some but not all gcc versions
 429   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 430   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 431   # Disable strict-aliasing rules; needed for gcc 3.3+
 432   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 433   # Disable optimizations that assume no overflow; needed for gcc 4.3+
 434   PGAC_PROG_CC_CFLAGS_OPT([-fwrapv])
 435 elif test "$ICC" = yes; then
 436   # Intel's compiler has a bug/misoptimization in checking for
 437   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 438   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 439   # Make sure strict aliasing is off (though this is said to be the default)
 440   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 441 elif test x"${CC}" = x"xlc"; then
 442   # AIX xlc has to have strict aliasing turned off too
 443   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 444 fi
 445
 446 # supply -g if --enable-debug
 447 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 448   CFLAGS="$CFLAGS -g"
 449 fi
 450
 451 # enable code coverage if --enable-coverage
 452 if test "$enable_coverage" = yes; then
 453   if test "$GCC" = yes; then
 454     CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 455   else
 456     AC_MSG_ERROR([--enable-coverage is supported only when using GCC])
 457   fi
 458 fi
 459
 460 # enable profiling if --enable-profiling
 461 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 462   if test "$GCC" = yes; then
 463     AC_DEFINE([PROFILE_PID_DIR], 1,
 464            [Define to 1 to allow profiling output to be saved separately for each process.])
 465     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 466   else
 467     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 468   fi
 469 fi
 470
 471 # We already have this in Makefile.win32, but configure needs it too
 472 if test "$PORTNAME" = "win32"; then
 473   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 474 fi
 475
 476 # Check if the compiler still works with the template settings
 477 AC_MSG_CHECKING([whether the C compiler still works])
 478 AC_TRY_LINK([], [return 0;],
 479   [AC_MSG_RESULT(yes)],
 480   [AC_MSG_RESULT(no)
 481    AC_MSG_ERROR([cannot proceed])])
 482
 483 # Defend against gcc -ffast-math
 484 if test "$GCC" = yes; then
 485 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 486 choke me
 487 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 488 fi
 489
 490 AC_PROG_CPP
 491 AC_SUBST(GCC)
 492
 493 # Create compiler version string
 494 if test x"$GCC" = x"yes" ; then
 495   cc_string="GCC `${CC} --version | sed q`"
 496 else
 497   cc_string=$CC
 498 fi
 499 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
 500                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"],
 501                    [A string containing the version number, platform, and C compiler])
 502
 503
 504 #
 505 # Set up TAS assembly code if needed; the template file has now had its
 506 # chance to request this.
 507 #
 508 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 509
 510 if test "$need_tas" = yes ; then
 511   TAS=tas.o
 512 else
 513   TAS=""
 514 fi
 515 AC_SUBST(TAS)
 516
 517
 518 #
 519 # Automatic dependency tracking
 520 #
 521 PGAC_ARG_BOOL(enable, depend, no, [turn on automatic dependency tracking],
 522               [autodepend=yes])
 523 AC_SUBST(autodepend)
 524
 525
 526 #
 527 # Enable assert checks
 528 #
 529 PGAC_ARG_BOOL(enable, cassert, no, [enable assertion checks (for debugging)],
 530               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 531                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 532
 533
 534 #
 535 # Include directories
 536 #
 537 ac_save_IFS=$IFS
 538 IFS="${IFS}${PATH_SEPARATOR}"
 539 # SRCH_INC comes from the template file
 540 for dir in $with_includes $SRCH_INC; do
 541   if test -d "$dir"; then
 542     INCLUDES="$INCLUDES -I$dir"
 543   else
 544     AC_MSG_WARN([*** Include directory $dir does not exist.])
 545   fi
 546 done
 547 IFS=$ac_save_IFS
 548 AC_SUBST(INCLUDES)
 549
 550
 551 #
 552 # Library directories
 553 #
 554 ac_save_IFS=$IFS
 555 IFS="${IFS}${PATH_SEPARATOR}"
 556 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 557 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 558   if test -d "$dir"; then
 559     LIBDIRS="$LIBDIRS -L$dir"
 560   else
 561     AC_MSG_WARN([*** Library directory $dir does not exist.])
 562   fi
 563 done
 564 IFS=$ac_save_IFS
 565
 566 #
 567 # Enable thread-safe client libraries
 568 #
 569 AC_MSG_CHECKING([allow thread-safe client libraries])
 570 if test "$PORTNAME" != "win32"; then
 571 PGAC_ARG_BOOL(enable, thread-safety, no, [make client libraries thread-safe])
 572 else
 573 # Win32 should always use threads
 574 PGAC_ARG_BOOL(enable, thread-safety, yes, [make client libraries thread-safe])
 575 fi
 576
 577 PGAC_ARG_BOOL(enable, thread-safety-force, no, [force thread-safety despite thread test failure])
 578 if test "$enable_thread_safety" = yes -o \
 579         "$enable_thread_safety_force" = yes; then
 580   enable_thread_safety="yes"    # for 'force'
 581   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 582           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 583 fi
 584 AC_MSG_RESULT([$enable_thread_safety])
 585 AC_SUBST(enable_thread_safety)
 586
 587 #
 588 # Optionally build Tcl modules (PL/Tcl)
 589 #
 590 AC_MSG_CHECKING([whether to build with Tcl])
 591 PGAC_ARG_BOOL(with, tcl, no, [build Tcl modules (PL/Tcl)])
 592 AC_MSG_RESULT([$with_tcl])
 593 AC_SUBST([with_tcl])
 594
 595 # We see if the path to the Tcl/Tk configuration scripts is specified.
 596 # This will override the use of tclsh to find the paths to search.
 597
 598 PGAC_ARG_REQ(with, tclconfig, [DIR], [tclConfig.sh is in DIR])
 599
 600 #
 601 # Optionally build Perl modules (PL/Perl)
 602 #
 603 AC_MSG_CHECKING([whether to build Perl modules])
 604 PGAC_ARG_BOOL(with, perl, no, [build Perl modules (PL/Perl)])
 605 AC_MSG_RESULT([$with_perl])
 606 AC_SUBST(with_perl)
 607
 608 #
 609 # Optionally build Python modules (PL/Python)
 610 #
 611 AC_MSG_CHECKING([whether to build Python modules])
 612 PGAC_ARG_BOOL(with, python, no, [build Python modules (PL/Python)])
 613 AC_MSG_RESULT([$with_python])
 614 AC_SUBST(with_python)
 615
 616 #
 617 # GSSAPI
 618 #
 619 AC_MSG_CHECKING([whether to build with GSSAPI support])
 620 PGAC_ARG_BOOL(with, gssapi, no, [build with GSSAPI support],
 621 [
 622   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 623   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 624 ])
 625 AC_MSG_RESULT([$with_gssapi])
 626 AC_SUBST(with_gssapi)
 627
 628 #
 629 # Kerberos 5
 630 #
 631 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 632 PGAC_ARG_BOOL(with, krb5, no, [build with Kerberos 5 support],
 633 [
 634   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 635   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 636 ])
 637 AC_MSG_RESULT([$with_krb5])
 638 AC_SUBST(with_krb5)
 639
 640
 641 AC_SUBST(krb_srvtab)
 642
 643
 644 #
 645 # Kerberos configuration parameters
 646 #
 647 PGAC_ARG_REQ(with, krb-srvnam,
 648              [NAME], [default service principal name in Kerberos [postgres]],
 649              [],
 650              [with_krb_srvnam="postgres"])
 651 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 652                    [Define to the name of the default PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 653
 654
 655 #
 656 # PAM
 657 #
 658 AC_MSG_CHECKING([whether to build with PAM support])
 659 PGAC_ARG_BOOL(with, pam, no,
 660               [build with PAM support],
 661               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 662 AC_MSG_RESULT([$with_pam])
 663 AC_SUBST(with_pam)
 664
 665
 666 #
 667 # LDAP
 668 #
 669 AC_MSG_CHECKING([whether to build with LDAP support])
 670 PGAC_ARG_BOOL(with, ldap, no,
 671               [build with LDAP support],
 672               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 673 AC_MSG_RESULT([$with_ldap])
 674 AC_SUBST(with_ldap)
 675
 676
 677 #
 678 # Bonjour
 679 #
 680 AC_MSG_CHECKING([whether to build with Bonjour support])
 681 PGAC_ARG_BOOL(with, bonjour, no,
 682               [build with Bonjour support],
 683               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 684 AC_MSG_RESULT([$with_bonjour])
 685 AC_SUBST(with_bonjour)
 686
 687
 688 #
 689 # OpenSSL
 690 #
 691 AC_MSG_CHECKING([whether to build with OpenSSL support])
 692 PGAC_ARG_BOOL(with, openssl, no, [build with OpenSSL support],
 693               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 694 AC_MSG_RESULT([$with_openssl])
 695 AC_SUBST(with_openssl)
 696
 697
 698 #
 699 # Readline
 700 #
 701 PGAC_ARG_BOOL(with, readline, yes,
 702               [do not use GNU Readline nor BSD Libedit for editing])
 703 # readline on MinGW has problems with backslashes in psql and other bugs.
 704 # This is particularly a problem with non-US code pages.
 705 # Therefore disable its use until we understand the cause. 2004-07-20
 706 if test "$PORTNAME" = "win32"; then
 707   if test "$with_readline" = yes; then
 708     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 709     with_readline=no
 710   fi
 711 fi
 712
 713
 714 #
 715 # Prefer libedit
 716 #
 717 PGAC_ARG_BOOL(with, libedit-preferred, no,
 718               [prefer BSD Libedit over GNU Readline])
 719
 720
 721 #
 722 # OSSP UUID library
 723 #
 724 PGAC_ARG_BOOL(with, ossp-uuid, no, [use OSSP UUID library when building contrib/uuid-ossp])
 725 AC_SUBST(with_ossp_uuid)
 726
 727
 728 #
 729 # XML
 730 #
 731 PGAC_ARG_BOOL(with, libxml, no, [build with XML support],
 732               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 733
 734 if test "$with_libxml" = yes ; then
 735   AC_CHECK_PROGS(XML2_CONFIG, xml2-config)
 736   if test -n "$XML2_CONFIG"; then
 737     for pgac_option in `$XML2_CONFIG --cflags`; do
 738       case $pgac_option in
 739         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 740       esac
 741     done
 742     for pgac_option in `$XML2_CONFIG --libs`; do
 743       case $pgac_option in
 744         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 745       esac
 746     done
 747   fi
 748 fi
 749
 750 AC_SUBST(with_libxml)
 751
 752 #
 753 # XSLT
 754 #
 755 PGAC_ARG_BOOL(with, libxslt, no, [use XSLT support when building contrib/xml2],
 756               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 757
 758
 759 AC_SUBST(with_libxslt)
 760
 761 #
 762 # tzdata
 763 #
 764 PGAC_ARG_REQ(with, system-tzdata,
 765              [DIR], [use system time zone data in DIR])
 766 AC_SUBST(with_system_tzdata)
 767
 768 #
 769 # Zlib
 770 #
 771 PGAC_ARG_BOOL(with, zlib, yes,
 772               [do not use Zlib])
 773 AC_SUBST(with_zlib)
 774
 775 #
 776 # Elf
 777 #
 778
 779 # Assume system is ELF if it predefines __ELF__ as 1,
 780 # otherwise believe host_os based default.
 781 case $host_os in
 782     freebsd1*|freebsd2*) elf=no;;
 783     freebsd3*|freebsd4*) elf=yes;;
 784 esac
 785
 786 AC_EGREP_CPP(yes,
 787 [#if __ELF__
 788   yes
 789 #endif
 790 ],
 791 [ELF_SYS=true],
 792 [if test "X$elf" = "Xyes" ; then
 793   ELF_SYS=true
 794 else
 795   ELF_SYS=
 796 fi])
 797 AC_SUBST(ELF_SYS)
 798
 799 #
 800 # Assignments
 801 #
 802
 803 CPPFLAGS="$CPPFLAGS $INCLUDES"
 804 LDFLAGS="$LDFLAGS $LIBDIRS"
 805
 806 AC_ARG_VAR(LDFLAGS_SL)
 807
 808 PGAC_PROG_LD
 809 AC_SUBST(LD)
 810 AC_SUBST(with_gnu_ld)
 811 case $host_os in sysv5*)
 812   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 813   [
 814     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 815     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 816     LDFLAGS=$pgac_save_LDFLAGS
 817   ])
 818   ld_R_works=$pgac_cv_prog_ld_R
 819   AC_SUBST(ld_R_works)
 820 esac
 821 AC_PROG_RANLIB
 822 PGAC_CHECK_STRIP
 823 AC_CHECK_TOOL(AR, ar, ar)
 824 if test "$PORTNAME" = "win32"; then
 825   AC_CHECK_TOOL(DLLTOOL, dlltool, dlltool)
 826   AC_CHECK_TOOL(DLLWRAP, dllwrap, dllwrap)
 827   AC_CHECK_TOOL(WINDRES, windres, windres)
 828 fi
 829
 830 AC_PATH_PROG(TAR, tar)
 831 AC_PROG_LN_S
 832 AC_PROG_AWK
 833
 834 PGAC_PATH_BISON
 835 PGAC_PATH_FLEX
 836
 837 PGAC_PATH_PERL
 838 if test "$with_perl" = yes; then
 839   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 840   PGAC_CHECK_PERL_EMBED_LDFLAGS
 841 fi
 842
 843 if test "$with_python" = yes; then
 844   PGAC_PATH_PYTHON
 845   PGAC_CHECK_PYTHON_EMBED_SETUP
 846 fi
 847
 848 # Supply a numeric version string for use by 3rd party add-ons
 849 # awk -F is a regex on some platforms, and not on others, so make "." a tab
 850 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
 851 tr '.' '        ' |
 852 $AWK '{printf "%d%02d%02d", $1, $2, (NF >= 3) ? $3 : 0}'`"]
 853 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
 854
 855 ##
 856 ## Libraries
 857 ##
 858 ## Most libraries are included only if they demonstrably provide a function
 859 ## we need, but libm is an exception: always include it, because there are
 860 ## too many compilers that play cute optimization games that will break
 861 ## probes for standard functions such as pow().
 862 ##
 863
 864 AC_CHECK_LIB(m, main)
 865 AC_SEARCH_LIBS(setproctitle, util)
 866 AC_SEARCH_LIBS(dlopen, dl)
 867 AC_SEARCH_LIBS(socket, [socket wsock32])
 868 AC_SEARCH_LIBS(shl_load, dld)
 869 # We only use libld in port/dynloader/aix.c
 870 case $host_os in
 871      aix*)
 872         AC_SEARCH_LIBS(ldopen, ld)
 873         ;;
 874 esac
 875 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 876 AC_SEARCH_LIBS(crypt, crypt)
 877 # Solaris:
 878 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 879 # Cygwin:
 880 AC_SEARCH_LIBS(shmget, cygipc)
 881
 882 if test "$with_readline" = yes; then
 883   PGAC_CHECK_READLINE
 884   if test x"$pgac_cv_check_readline" = x"no"; then
 885     AC_MSG_ERROR([readline library not found
 886 If you have readline already installed, see config.log for details on the
 887 failure.  It is possible the compiler isn't looking in the proper directory.
 888 Use --without-readline to disable readline support.])
 889   fi
 890 fi
 891
 892 if test "$with_zlib" = yes; then
 893   AC_CHECK_LIB(z, inflate, [],
 894                [AC_MSG_ERROR([zlib library not found
 895 If you have zlib already installed, see config.log for details on the
 896 failure.  It is possible the compiler isn't looking in the proper directory.
 897 Use --without-zlib to disable zlib support.])])
 898 fi
 899
 900 if test "$enable_spinlocks" = yes; then
 901   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 902 else
 903   AC_MSG_WARN([
 904 *** Not using spinlocks will cause poor performance.])
 905 fi
 906
 907 if test "$with_gssapi" = yes ; then
 908   if test "$PORTNAME" != "win32"; then
 909     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
 910                                   [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
 911   else
 912     LIBS="$LIBS -lgssapi32"
 913   fi
 914 fi
 915
 916 if test "$with_krb5" = yes ; then
 917   if test "$PORTNAME" != "win32"; then
 918      AC_SEARCH_LIBS(com_err, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken' com_err], [],
 919                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 920      AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken'], [],
 921                     [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 922   else
 923      AC_SEARCH_LIBS(com_err, 'comerr32 -lkrb5_32', [],
 924                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 925   fi
 926 fi
 927
 928 if test "$with_openssl" = yes ; then
 929   dnl Order matters!
 930   if test "$PORTNAME" != "win32"; then
 931      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 932      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 933   else
 934      AC_CHECK_LIB(eay32, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'eay32' is required for OpenSSL])])
 935      AC_CHECK_LIB(ssleay32,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssleay32' is required for OpenSSL])])
 936   fi
 937 fi
 938
 939 if test "$with_pam" = yes ; then
 940   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 941 fi
 942
 943 if test "$with_libxml" = yes ; then
 944   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
 945 fi
 946
 947 if test "$with_libxslt" = yes ; then
 948   AC_CHECK_LIB(xslt, xsltCleanupGlobals, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
 949 fi
 950
 951 # for contrib/uuid-ossp
 952 if test "$with_ossp_uuid" = yes ; then
 953   AC_CHECK_LIB(ossp-uuid, uuid_export,
 954     [OSSP_UUID_LIBS="-lossp-uuid"],
 955     [AC_CHECK_LIB(uuid, uuid_export,
 956       [OSSP_UUID_LIBS="-luuid"],
 957       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP-UUID])])])
 958 fi
 959 AC_SUBST(OSSP_UUID_LIBS)
 960
 961
 962 ##
 963 ## Header files
 964 ##
 965
 966 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 967 AC_CHECK_HEADERS([crypt.h dld.h fp_class.h getopt.h ieeefp.h langinfo.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/tas.h sys/time.h sys/un.h termios.h ucred.h utime.h wchar.h wctype.h kernel/OS.h kernel/image.h SupportDefs.h])
 968
 969 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 970 # netinet/in.h is included first.
 971 AC_CHECK_HEADERS(netinet/in.h)
 972 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 973 [AC_INCLUDES_DEFAULT
 974 #ifdef HAVE_NETINET_IN_H
 975 #include <netinet/in.h>
 976 #endif
 977 ])
 978
 979 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
 980   AC_CHECK_HEADERS(readline/readline.h, [],
 981         [AC_CHECK_HEADERS(readline.h, [],
 982                 [AC_MSG_ERROR([readline header not found
 983 If you have readline already installed, see config.log for details on the
 984 failure.  It is possible the compiler isn't looking in the proper directory.
 985 Use --without-readline to disable readline support.])])])
 986   AC_CHECK_HEADERS(readline/history.h, [],
 987         [AC_CHECK_HEADERS(history.h, [],
 988                 [AC_MSG_ERROR([history header not found
 989 If you have readline already installed, see config.log for details on the
 990 failure.  It is possible the compiler isn't looking in the proper directory.
 991 Use --without-readline to disable readline support.])])])
 992 fi
 993
 994 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
 995 # Some installations of libedit usurp /usr/include/readline/, which seems
 996 # bad practice, since in combined installations readline will have its headers
 997 # there.  We might have to resort to AC_EGREP checks to make sure we found
 998 # the proper header...
 999   AC_CHECK_HEADERS(editline/readline.h, [],
1000         [AC_CHECK_HEADERS(readline.h, [],
1001                 [AC_CHECK_HEADERS(readline/readline.h, [],
1002                         [AC_MSG_ERROR([readline header not found
1003 If you have libedit already installed, see config.log for details on the
1004 failure.  It is possible the compiler isn't looking in the proper directory.
1005 Use --without-readline to disable libedit support.])])])])
1006 # Note: in a libedit installation, history.h is sometimes a dummy, and may
1007 # not be there at all.  Hence, don't complain if not found.  We must check
1008 # though, since in yet other versions it is an independent header.
1009   AC_CHECK_HEADERS(editline/history.h, [],
1010         [AC_CHECK_HEADERS(history.h, [],
1011                 [AC_CHECK_HEADERS(readline/history.h)])])
1012 fi
1013
1014 if test "$with_zlib" = yes; then
1015   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
1016 If you have zlib already installed, see config.log for details on the
1017 failure.  It is possible the compiler isn't looking in the proper directory.
1018 Use --without-zlib to disable zlib support.])])
1019 fi
1020
1021 if test "$with_gssapi" = yes ; then
1022   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
1023         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
1024 fi
1025
1026 if test "$with_krb5" = yes ; then
1027   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
1028 fi
1029
1030 if test "$with_openssl" = yes ; then
1031   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
1032   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
1033   AC_CHECK_FUNCS([ERR_set_mark])
1034 fi
1035
1036 if test "$with_pam" = yes ; then
1037   AC_CHECK_HEADERS(security/pam_appl.h, [],
1038                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
1039                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
1040 fi
1041
1042 if test "$with_libxml" = yes ; then
1043   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
1044 fi
1045
1046 if test "$with_libxslt" = yes ; then
1047   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
1048 fi
1049
1050 if test "$with_ldap" = yes ; then
1051   if test "$PORTNAME" != "win32"; then
1052      AC_CHECK_HEADERS(ldap.h, [],
1053                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
1054   else
1055      AC_CHECK_HEADERS(winldap.h, [],
1056                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
1057                       [AC_INCLUDES_DEFAULT
1058 #include <windows.h>
1059                       ])
1060   fi
1061 fi
1062
1063 if test "$with_bonjour" = yes ; then
1064   AC_CHECK_HEADER(DNSServiceDiscovery/DNSServiceDiscovery.h, [], [AC_MSG_ERROR([header file <DNSServiceDiscovery/DNSServiceDiscovery.h> is required for Bonjour])])
1065 fi
1066
1067 # for contrib/uuid-ossp
1068 if test "$with_ossp_uuid" = yes ; then
1069   AC_CHECK_HEADERS(ossp/uuid.h, [], [
1070     AC_CHECK_HEADERS(uuid.h, [],
1071       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP-UUID])])])
1072 fi
1073
1074
1075 ##
1076 ## Types, structures, compiler characteristics
1077 ##
1078
1079 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
1080 AC_C_BIGENDIAN
1081 AC_C_CONST
1082 AC_C_INLINE
1083 AC_C_STRINGIZE
1084 PGAC_C_SIGNED
1085 AC_C_VOLATILE
1086 PGAC_C_FUNCNAME_SUPPORT
1087 PGAC_STRUCT_TIMEZONE
1088 PGAC_UNION_SEMUN
1089 PGAC_STRUCT_SOCKADDR_UN
1090 PGAC_STRUCT_SOCKADDR_STORAGE
1091 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
1092 PGAC_STRUCT_ADDRINFO
1093
1094 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
1095 [#include <sys/param.h>
1096 #include <sys/types.h>
1097 #include <sys/socket.h>
1098 #include <sys/ucred.h>])
1099
1100 AC_CHECK_TYPES([struct option], [], [],
1101 [#ifdef HAVE_GETOPT_H
1102 #include <getopt.h>
1103 #endif])
1104
1105 if test "$with_zlib" = yes; then
1106   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
1107   # did not).  While we could work around the lack of z_streamp, it
1108   # seems unwise to encourage people to use such old zlib versions...
1109   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
1110 Use --without-zlib to disable zlib support.])],
1111                 [#include <zlib.h>])
1112 fi
1113
1114 if test "$with_krb5" = yes; then
1115 # Check for differences between MIT and Heimdal (KTH) releases
1116   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
1117                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
1118                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
1119                                      [#include <krb5.h>])],
1120                    [#include <krb5.h>])
1121   AC_CHECK_MEMBERS(krb5_error.text.data, [],
1122                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
1123                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
1124                                      [#include <krb5.h>])],
1125                    [#include <krb5.h>])
1126
1127 # Win32 requires headers to be loaded for __stdcall, so can't use
1128 # AC_CHECK_FUNCS here.
1129   AC_MSG_CHECKING(for krb5_free_unparsed_name)
1130   AC_TRY_LINK([#include <krb5.h>],
1131               [krb5_free_unparsed_name(NULL,NULL);],
1132               [AC_DEFINE(HAVE_KRB5_FREE_UNPARSED_NAME, 1, [Define to 1 if you have krb5_free_unparsed_name])
1133 AC_MSG_RESULT(yes)],
1134               [AC_MSG_RESULT(no)])
1135 fi
1136
1137
1138 ##
1139 ## Functions, global variables
1140 ##
1141
1142 PGAC_VAR_INT_TIMEZONE
1143 AC_FUNC_ACCEPT_ARGTYPES
1144 PGAC_FUNC_GETTIMEOFDAY_1ARG
1145
1146 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid getpeerucred getrlimit memmove poll pstat readlink setproctitle setsid sigprocmask symlink sysconf towlower utime utimes waitpid wcstombs])
1147
1148 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
1149 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
1150 AC_CHECK_DECLS([strlcat, strlcpy])
1151 # This is probably only present on Darwin, but may as well check always
1152 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
1153
1154 HAVE_IPV6=no
1155 AC_CHECK_TYPE([struct sockaddr_in6],
1156         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
1157          HAVE_IPV6=yes],
1158         [],
1159 [$ac_includes_default
1160 #include <netinet/in.h>])
1161 AC_SUBST(HAVE_IPV6)
1162
1163 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1164 [AC_TRY_LINK(
1165 [#include <machine/vmparam.h>
1166 #include <sys/exec.h>
1167 ],
1168 [PS_STRINGS->ps_nargvstr = 1;
1169 PS_STRINGS->ps_argvstr = "foo";],
1170 [pgac_cv_var_PS_STRINGS=yes],
1171 [pgac_cv_var_PS_STRINGS=no])])
1172 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1173   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
1174 fi
1175
1176
1177 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
1178 # is missing.  Yes, there are machines that have only one.  We may
1179 # also decide to use snprintf.c if snprintf() is present but does not
1180 # have all the features we need --- see below.
1181
1182 if test "$PORTNAME" = "win32"; then
1183   # Win32 gets snprintf.c built unconditionally.
1184   #
1185   # To properly translate all NLS languages strings, we must support the
1186   # *printf() %$ format, which allows *printf() arguments to be selected
1187   # by position in the translated string.
1188   #
1189   # libintl versions < 0.13 use the native *printf() functions, and Win32
1190   # *printf() doesn't understand %$, so we must use our /port versions,
1191   # which do understand %$. libintl versions >= 0.13 include their own
1192   # *printf versions on Win32.  The libintl 0.13 release note text is:
1193   #
1194   #   C format strings with positions, as they arise when a translator
1195   #   needs to reorder a sentence, are now supported on all platforms.
1196   #   On those few platforms (NetBSD and Woe32) for which the native
1197   #   printf()/fprintf()/... functions don't support such format
1198   #   strings, replacements are provided through <libintl.h>.
1199   #
1200   # We could use libintl >= 0.13's *printf() if we were sure that we had
1201   # a litint >= 0.13 at runtime, but seeing that there is no clean way
1202   # to guarantee that, it is best to just use our own, so we are sure to
1203   # get %$ support. In include/port.h we disable the *printf() macros
1204   # that might have been defined by libintl.
1205   #
1206   # We do this unconditionally whether NLS is used or not so we are sure
1207   # that all Win32 libraries and binaries behave the same.
1208   pgac_need_repl_snprintf=yes
1209 else
1210   pgac_need_repl_snprintf=no
1211   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
1212   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1213 fi
1214
1215
1216 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
1217 # include/c.h will provide declarations.  Note this is a separate test
1218 # from whether the functions exist in the C library --- there are
1219 # systems that have the functions but don't bother to declare them :-(
1220
1221 AC_CHECK_DECLS([snprintf, vsnprintf])
1222
1223
1224 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1225 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1226 [AC_TRY_LINK([
1227 #include <math.h>
1228 double glob_double;
1229 ],
1230 [return isinf(glob_double) ? 0 : 1;],
1231 [ac_cv_func_isinf=yes],
1232 [ac_cv_func_isinf=no])])
1233
1234 if test $ac_cv_func_isinf = yes ; then
1235   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1236 else
1237   AC_LIBOBJ(isinf)
1238   # Look for a way to implement a substitute for isinf()
1239   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1240 fi
1241
1242 # Some versions of libedit contain strlcpy(); so disregard that library while
1243 # checking for these standard libc functions.
1244 pgac_save_LIBS="$LIBS"
1245 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1246
1247 AC_REPLACE_FUNCS([crypt getopt getrusage inet_aton random rint srandom strdup strerror strlcat strlcpy strtol strtoul unsetenv])
1248
1249 LIBS="$pgac_save_LIBS"
1250
1251 # System's version of getaddrinfo(), if any, may be used only if we found
1252 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1253 # (Note: the AC_REPLACE_FUNCS probe fails on Windows, where the available
1254 # versions of getaddrinfo don't follow normal C call protocol.  This is OK
1255 # because we want to use our own getaddrinfo.c on Windows anyway.)
1256 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
1257   AC_REPLACE_FUNCS([getaddrinfo])
1258 else
1259   AC_LIBOBJ(getaddrinfo)
1260 fi
1261
1262 # Similarly, use system's getopt_long() only if system provides struct option.
1263 # Solaris' getopt() doesn't do what we want for long options, so always use
1264 # our versions on that platform.
1265 if test "$PORTNAME" = "solaris"; then
1266   AC_LIBOBJ(getopt)
1267   AC_LIBOBJ(getopt_long)
1268 elif test x"$ac_cv_type_struct_option" = xyes ; then
1269   AC_REPLACE_FUNCS([getopt_long])
1270 else
1271   AC_LIBOBJ(getopt_long)
1272 fi
1273
1274 # Win32 support
1275 if test "$PORTNAME" = "win32"; then
1276 AC_REPLACE_FUNCS(gettimeofday)
1277 AC_LIBOBJ(kill)
1278 AC_LIBOBJ(open)
1279 AC_LIBOBJ(rand)
1280 AC_LIBOBJ(win32error)
1281 AC_DEFINE([HAVE_SYMLINK], 1,
1282           [Define to 1 if you have the `symlink' function.])
1283 fi
1284
1285 if test "$with_readline" = yes; then
1286   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1287   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
1288   AC_CHECK_FUNCS([replace_history_entry])
1289 fi
1290
1291
1292 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
1293 dnl (especially on GNU libc)
1294 dnl See also comments in c.h.
1295 AC_MSG_CHECKING(for sigsetjmp)
1296 AC_TRY_LINK([#include <setjmp.h>],
1297             [sigjmp_buf x; sigsetjmp(x, 1);],
1298             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
1299 AC_MSG_RESULT(yes)],
1300             [AC_MSG_RESULT(no)])
1301
1302 AC_DECL_SYS_SIGLIST
1303
1304 AC_CHECK_FUNC(syslog,
1305               [AC_CHECK_HEADER(syslog.h,
1306                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1307
1308 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1309 [AC_TRY_LINK([#include <unistd.h>],
1310   [extern int optreset; optreset = 1;],
1311   [pgac_cv_var_int_optreset=yes],
1312   [pgac_cv_var_int_optreset=no])])
1313 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1314   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1315 fi
1316
1317 AC_CHECK_FUNCS([strtoll strtoq], [break])
1318 AC_CHECK_FUNCS([strtoull strtouq], [break])
1319
1320 # Check for one of atexit() or on_exit()
1321 AC_CHECK_FUNCS(atexit, [],
1322                [AC_CHECK_FUNCS(on_exit, [],
1323                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
1324
1325 AC_REPLACE_FUNCS(fseeko)
1326 case $host_os in
1327         # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
1328         bsdi*|netbsd*)
1329                 AC_DEFINE(HAVE_FSEEKO, 1, [Define to 1 because replacement version used.])
1330                 ac_cv_func_fseeko=yes;;
1331         *)
1332                 AC_FUNC_FSEEKO;;
1333 esac
1334
1335
1336 #
1337 # Pthreads
1338 #
1339 # For each platform, we need to know about any special compile and link
1340 # libraries, and whether the normal C function names are thread-safe.
1341 # See the comment at the top of src/port/thread.c for more information.
1342 # WIN32 doesn't need the pthread tests;  it always uses threads
1343 if test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"; then
1344 ACX_PTHREAD     # set thread flags
1345
1346 # Some platforms use these, so just define them.  They can't hurt if they
1347 # are not supported.  For example, on Solaris -D_POSIX_PTHREAD_SEMANTICS
1348 # enables 5-arg getpwuid_r, among other things.
1349 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1350
1351
1352 # At this point, we don't want to muck with the compiler name for threading.
1353 # Let's see who fails, perhaps AIX.  2004-04-23
1354 if test "$PTHREAD_CC" != "$CC"; then
1355 AC_MSG_ERROR([
1356 PostgreSQL does not support platforms that require a special compiler
1357 for thread safety.])
1358 fi
1359
1360 if test "$THREAD_SUPPORT" = no; then
1361 AC_MSG_ERROR([cannot enable threads on this platform
1362 This platform is known to not support thread-safe programs.  For details,
1363 compile and run src/bin/pg_thread_test.])
1364 fi
1365
1366 # Check for *_r functions
1367 _CFLAGS="$CFLAGS"
1368 _LIBS="$LIBS"
1369 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1370 LIBS="$LIBS $PTHREAD_LIBS"
1371
1372 if test "$PORTNAME" != "win32"; then
1373 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([pthread.h not found, required for --enable-thread-safety])])
1374 fi
1375
1376 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1377
1378 # Do test here with the proper thread flags
1379 PGAC_FUNC_GETPWUID_R_5ARG
1380 PGAC_FUNC_STRERROR_R_INT
1381
1382 CFLAGS="$_CFLAGS"
1383 LIBS="$_LIBS"
1384
1385 else
1386 # do not use values from template file
1387 PTHREAD_CFLAGS=
1388 PTHREAD_LIBS=
1389 fi
1390
1391 AC_SUBST(PTHREAD_CFLAGS)
1392 AC_SUBST(PTHREAD_LIBS)
1393
1394
1395 # We can test for libldap_r only after we know PTHREAD_LIBS
1396 if test "$with_ldap" = yes ; then
1397   _LIBS="$LIBS"
1398   if test "$PORTNAME" != "win32"; then
1399     AC_CHECK_LIB(ldap, ldap_bind, [],
1400                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1401                  [$EXTRA_LDAP_LIBS])
1402     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1403     if test "$enable_thread_safety" = yes; then
1404       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1405       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1406                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1407                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1408       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1409     else
1410       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1411     fi
1412   else
1413     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1414     LDAP_LIBS_FE="-lwldap32"
1415     LDAP_LIBS_BE="-lwldap32"
1416   fi
1417   LIBS="$_LIBS"
1418 fi
1419 AC_SUBST(LDAP_LIBS_FE)
1420 AC_SUBST(LDAP_LIBS_BE)
1421
1422
1423 # This test makes sure that run tests work at all.  Sometimes a shared
1424 # library is found by the linker, but the runtime linker can't find it.
1425 # This check should come after all modifications of compiler or linker
1426 # variables, and before any other run tests.
1427 AC_MSG_CHECKING([test program])
1428 AC_TRY_RUN([int main() { return 0; }],
1429 [AC_MSG_RESULT(ok)],
1430 [AC_MSG_RESULT(failed)
1431 AC_MSG_ERROR([[
1432 Could not execute a simple test program.  This may be a problem
1433 related to locating shared libraries.  Check the file 'config.log'
1434 for the exact reason.]])],
1435 [AC_MSG_RESULT([cross-compiling])])
1436
1437 # --------------------
1438 # Run tests below here
1439 # --------------------
1440
1441 # Force use of our snprintf if system's doesn't do arg control
1442 # See comment above at snprintf test for details.
1443 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1444   PGAC_FUNC_PRINTF_ARG_CONTROL
1445   if test $pgac_cv_printf_arg_control != yes ; then
1446     pgac_need_repl_snprintf=yes
1447   fi
1448 fi
1449
1450
1451 dnl Check to see if we have a working 64-bit integer type.
1452 dnl This breaks down into two steps:
1453 dnl (1) figure out if the compiler has a 64-bit int type with working
1454 dnl arithmetic, and if so
1455 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1456 dnl snprintf is the only library routine we really need for int8 support.)
1457 dnl It's entirely possible to have a compiler that handles a 64-bit type
1458 dnl when the C library doesn't; this is fairly likely when using gcc on
1459 dnl an older platform, for example.
1460 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1461 dnl we force our own version of snprintf() to be used instead.
1462 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1463
1464 PGAC_TYPE_64BIT_INT([long int])
1465
1466 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1467   PGAC_TYPE_64BIT_INT([long long int])
1468 fi
1469
1470
1471 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1472
1473 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1474   AC_TRY_COMPILE([
1475 #define INT64CONST(x)  x##LL
1476 long long int foo = INT64CONST(0x1234567890123456);
1477 ],
1478         [],
1479         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1480         [])
1481 fi
1482
1483
1484 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1485 # we found we need to use "long long int", better check.  We cope with
1486 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1487 # work, fall back to our own snprintf emulation (which we know uses %lld).
1488
1489 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1490   if test $pgac_need_repl_snprintf = no; then
1491     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1492     if test "$LONG_LONG_INT_FORMAT" = ""; then
1493       # Force usage of our own snprintf, since system snprintf is broken
1494       pgac_need_repl_snprintf=yes
1495       LONG_LONG_INT_FORMAT='%lld'
1496     fi
1497   else
1498     # Here if we previously decided we needed to use our own snprintf
1499     LONG_LONG_INT_FORMAT='%lld'
1500   fi
1501   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1502   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1503   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1504 else
1505   # Here if we are not using 'long long int' at all
1506   INT64_FORMAT='"%ld"'
1507   UINT64_FORMAT='"%lu"'
1508 fi
1509
1510 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1511                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1512
1513 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1514                    [Define to the appropriate snprintf format for unsigned 64-bit ints, if any.])
1515
1516 # Now we have checked all the reasons to replace snprintf
1517 if test $pgac_need_repl_snprintf = yes; then
1518   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1519   AC_LIBOBJ(snprintf)
1520 fi
1521
1522 # Need a #define for the size of Datum (unsigned long)
1523 AC_CHECK_SIZEOF([unsigned long])
1524
1525 # And one for the size of size_t (enables tweaks for > 32bit address space)
1526 AC_CHECK_SIZEOF([size_t])
1527
1528 # Decide whether float4 is passed by value: user-selectable, enabled by default
1529 AC_MSG_CHECKING([whether to build with float4 passed by value])
1530 PGAC_ARG_BOOL(enable, float4-byval, yes, [disable float4 passed by value],
1531               [AC_DEFINE([USE_FLOAT4_BYVAL], 1,
1532                          [Define to 1 if you want float4 values to be passed by value. (--enable-float4-byval)])
1533                float4passbyval=true],
1534               [float4passbyval=false])
1535 AC_MSG_RESULT([$enable_float4_byval])
1536 AC_DEFINE_UNQUOTED([FLOAT4PASSBYVAL], [$float4passbyval], [float4 values are passed by value if 'true', by reference if 'false'])
1537
1538 # Decide whether float8 is passed by value.
1539 # Note: this setting also controls int8 and related types such as timestamp.
1540 # If sizeof(Datum) >= 8, this is user-selectable, enabled by default.
1541 # If not, trying to select it is an error.
1542 AC_MSG_CHECKING([whether to build with float8 passed by value])
1543 if test $ac_cv_sizeof_unsigned_long -ge 8 ; then
1544   PGAC_ARG_BOOL(enable, float8-byval, yes, [disable float8 passed by value])
1545 else
1546   PGAC_ARG_BOOL(enable, float8-byval, no, [disable float8 passed by value])
1547   if test "$enable_float8_byval" = yes ; then
1548     AC_MSG_ERROR([--enable-float8-byval is not supported on 32-bit platforms.])
1549   fi
1550 fi
1551 if test "$enable_float8_byval" = yes ; then
1552   AC_DEFINE([USE_FLOAT8_BYVAL], 1,
1553             [Define to 1 if you want float8, int8, etc values to be passed by value. (--enable-float8-byval)])
1554   float8passbyval=true
1555 else
1556   float8passbyval=false
1557 fi
1558 AC_MSG_RESULT([$enable_float8_byval])
1559 AC_DEFINE_UNQUOTED([FLOAT8PASSBYVAL], [$float8passbyval], [float8, int8, and related values are passed by value if 'true', by reference if 'false'])
1560
1561 # Determine memory alignment requirements for the basic C data types.
1562
1563 AC_CHECK_ALIGNOF(short)
1564 AC_CHECK_ALIGNOF(int)
1565 AC_CHECK_ALIGNOF(long)
1566 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1567   AC_CHECK_ALIGNOF(long long int)
1568 fi
1569 AC_CHECK_ALIGNOF(double)
1570
1571 # Compute maximum alignment of any basic type.
1572 # We assume long's alignment is at least as strong as char, short, or int;
1573 # but we must check long long (if it exists) and double.
1574
1575 MAX_ALIGNOF=$ac_cv_alignof_long
1576 if test $MAX_ALIGNOF -lt $ac_cv_alignof_double ; then
1577   MAX_ALIGNOF=$ac_cv_alignof_double
1578 fi
1579 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $ac_cv_alignof_long_long_int ; then
1580   MAX_ALIGNOF="$ac_cv_alignof_long_long_int"
1581 fi
1582 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1583
1584
1585 # Some platforms predefine the types int8, int16, etc.  Only check
1586 # a (hopefully) representative subset.
1587 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1588 [#include <stdio.h>
1589 #ifdef HAVE_SUPPORTDEFS_H
1590 #include <SupportDefs.h>
1591 #endif])
1592
1593 # We also check for sig_atomic_t, which *should* be defined per ANSI
1594 # C, but is missing on some old platforms.
1595 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1596
1597
1598 # If the user did not disable integer datetimes, check that
1599 # there is a working 64-bit integral type to use.
1600 if test x"$USE_INTEGER_DATETIMES" = x"yes" &&
1601    test x"$HAVE_LONG_INT_64" = x"no" &&
1602    test x"$HAVE_LONG_LONG_INT_64" = x"no" &&
1603    test x"$HAVE_INT64" = x"no" ; then
1604   AC_MSG_ERROR([
1605 Integer-based datetime support requires a 64-bit integer type,
1606 but no such type could be found. The --disable-integer-datetimes
1607 configure option can be used to disable integer-based storage
1608 of datetime values.])
1609 fi
1610
1611
1612 if test "$PORTNAME" != "win32"
1613 then
1614 PGAC_FUNC_POSIX_SIGNALS
1615 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1616   AC_MSG_ERROR([
1617 Thread-safety requires POSIX signals, which are not supported by this
1618 operating system.])
1619 fi
1620 fi
1621
1622 if test $ac_cv_func_fseeko = yes; then
1623 AC_SYS_LARGEFILE
1624 fi
1625
1626 # Check for largefile support (must be after AC_SYS_LARGEFILE)
1627 AC_CHECK_SIZEOF([off_t])
1628
1629 # If we don't have largefile support, can't handle segsize >= 2GB.
1630 if test "$ac_cv_sizeof_off_t" -lt 8 -a "$segsize" != "1"; then
1631    AC_MSG_ERROR([Large file support is not enabled. Segment size cannot be larger than 1GB.])
1632 fi
1633
1634 # SunOS doesn't handle negative byte comparisons properly with +/- return
1635 AC_FUNC_MEMCMP
1636
1637
1638 # Select semaphore implementation type.
1639 if test "$PORTNAME" != "win32"; then
1640   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1641     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1642     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1643   else
1644     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1645       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1646       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1647     else
1648       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1649       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1650     fi
1651   fi
1652 else
1653   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1654   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1655 fi
1656
1657
1658 # Select shared-memory implementation type.
1659 if test "$PORTNAME" != "win32"; then
1660   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1661   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1662 else
1663   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
1664   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
1665 fi
1666
1667 # If not set in template file, set bytes to use libc memset()
1668 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
1669   MEMSET_LOOP_LIMIT=1024
1670 fi
1671 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
1672
1673
1674 if test "$enable_nls" = yes ; then
1675   PGAC_CHECK_GETTEXT
1676 fi
1677
1678 # Check for Tcl configuration script tclConfig.sh
1679 if test "$with_tcl" = yes; then
1680     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1681     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1682                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1683     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1684     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1685     ac_save_CPPFLAGS=$CPPFLAGS
1686     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1687     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1688     CPPFLAGS=$ac_save_CPPFLAGS
1689 fi
1690
1691 #
1692 # Check for DocBook and tools
1693 #
1694 PGAC_PROG_NSGMLS
1695 PGAC_PROG_JADE
1696 PGAC_CHECK_DOCBOOK(4.2)
1697 PGAC_PATH_DOCBOOK_STYLESHEETS
1698 PGAC_PATH_COLLATEINDEX
1699 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1700 PGAC_PATH_DOCBOOK2MAN
1701
1702 # Thread testing
1703
1704 # We have to run the thread test near the end so we have all our symbols
1705 # defined.  Cross compiling throws a warning.
1706 #
1707 if test "$enable_thread_safety_force" = yes; then
1708 if test "$PORTNAME" != "win32"
1709 then
1710   AC_MSG_WARN([
1711 *** Skipping thread test program.  --enable-thread-safety-force was used.
1712 *** Run the program in src/test/thread on the your machine and add proper
1713 *** locking function calls to your applications to guarantee thread safety.
1714 ])
1715 else
1716 AC_MSG_WARN([*** skipping thread test on Win32])
1717 fi
1718 elif test "$enable_thread_safety" = yes; then
1719 if test "$PORTNAME" != "win32"
1720 then
1721 AC_MSG_CHECKING([thread safety of required library functions])
1722
1723 _CFLAGS="$CFLAGS"
1724 _LIBS="$LIBS"
1725 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1726 LIBS="$LIBS $PTHREAD_LIBS"
1727 AC_TRY_RUN([#include "$srcdir/src/test/thread/thread_test.c"],
1728   [AC_MSG_RESULT(yes)],
1729   [AC_MSG_RESULT(no)
1730   AC_MSG_ERROR([thread test program failed
1731 This platform is not thread-safe.  Check the file 'config.log' for the
1732 exact reason.
1733
1734 You can use the configure option --enable-thread-safety-force to force
1735 threads to be enabled.  But you must then run the program in
1736 src/test/thread and add locking function calls to your applications to
1737 guarantee thread safety.])],
1738   [AC_MSG_RESULT(maybe)
1739   AC_MSG_WARN([
1740 *** Skipping thread test program because of cross-compile build.
1741 *** Run the program in src/test/thread on the target machine.
1742 ])])
1743 CFLAGS="$_CFLAGS"
1744 LIBS="$_LIBS"
1745 else
1746 AC_MSG_WARN([*** skipping thread test on Win32])
1747 fi
1748 fi
1749
1750 # If compiler will take -Wl,--as-needed then add that to LDFLAGS.
1751 # This is much easier than trying to filter LIBS to the minimum for each
1752 # executable.  (Note that shared library links won't use this switch, though.)
1753 # On (at least) some Red-Hat-derived systems, this switch breaks linking to
1754 # libreadline; therefore we postpone testing it until we know what library
1755 # dependencies readline has.  The test code will try to link with $LIBS.
1756 if test "$with_readline" = yes; then
1757   link_test_func=readline
1758 else
1759   link_test_func=exit
1760 fi
1761 if test "$PORTNAME" != "darwin"; then
1762   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,--as-needed], $link_test_func)
1763 else
1764   # On Darwin it's spelled -Wl,-dead_strip_dylibs, but don't try that elsewhere
1765   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-dead_strip_dylibs], $link_test_func)
1766 fi
1767
1768
1769 # Begin output steps
1770
1771 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
1772 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
1773 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
1774
1775 # prepare build tree if outside source tree
1776 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1777 # Note 2: /bin/pwd might be better than shell's built-in at getting
1778 #         a symlink-free name.
1779 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1780   vpath_build=no
1781 else
1782   vpath_build=yes
1783   if test "$no_create" != yes; then
1784     _AS_ECHO_N([preparing build tree... ])
1785     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1786     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1787       || AC_MSG_ERROR(failed)
1788     AC_MSG_RESULT(done)
1789   fi
1790 fi
1791 AC_SUBST(vpath_build)
1792
1793
1794 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1795
1796 AC_CONFIG_LINKS([
1797   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1798   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1799   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1800   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1801   src/include/pg_config_os.h:src/include/port/${template}.h
1802   src/Makefile.port:src/makefiles/Makefile.${template}
1803 ])
1804
1805 if test "$PORTNAME" = "win32"; then
1806 AC_CONFIG_COMMANDS([check_win32_symlinks],[
1807 # Links sometimes fail undetected on Mingw -
1808 # so here we detect it and warn the user
1809 for FILE in $CONFIG_LINKS
1810  do
1811         # test -e works for symlinks in the MinGW console
1812         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
1813  done
1814 ])
1815 fi
1816
1817 AC_CONFIG_HEADERS([src/include/pg_config.h],
1818 [
1819 # Update timestamp for pg_config.h (see Makefile.global)
1820 echo >src/include/stamp-h
1821 ])
1822
1823 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h])
1824
1825 AC_OUTPUT
1826
1827 # Warn about unknown options
1828 PGAC_ARG_CHECK