configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $PostgreSQL: pgsql/configure.in,v 1.590 2009/02/11 20:02:39 tgl Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [8.4devel], [pgsql-bugs@postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.61], [], [m4_fatal([Autoconf version 2.61 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2009, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version as a string])
  33 [PG_MAJORVERSION=`expr "$PACKAGE_VERSION" : '\([0-9][0-9]*\.[0-9][0-9]*\)'`]
  34 AC_SUBST(PG_MAJORVERSION)
  35 AC_DEFINE_UNQUOTED(PG_MAJORVERSION, "$PG_MAJORVERSION", [PostgreSQL major version as a string])
  36
  37 AC_CANONICAL_HOST
  38
  39 template=
  40 AC_MSG_CHECKING([which template to use])
  41
  42 PGAC_ARG_REQ(with, template, [NAME], [override operating system template],
  43 [
  44   case $withval in
  45     list)   echo; ls "$srcdir/src/template"; exit;;
  46     *)      if test -f "$srcdir/src/template/$with_template" ; then
  47               template=$withval
  48             else
  49               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  50             fi;;
  51   esac
  52 ],
  53 [
  54 # --with-template not given
  55
  56 case $host_os in
  57      aix*) template=aix ;;
  58     bsdi*) template=bsdi ;;
  59   cygwin*) template=cygwin ;;
  60   darwin*) template=darwin ;;
  61     dgux*) template=dgux ;;
  62  freebsd*) template=freebsd ;;
  63     hpux*) template=hpux ;;
  64     irix*) template=irix ;;
  65  linux*|gnu*|k*bsd*-gnu)
  66            template=linux ;;
  67    mingw*) template=win32 ;;
  68   netbsd*) template=netbsd ;;
  69 nextstep*) template=nextstep ;;
  70  openbsd*) template=openbsd ;;
  71      osf*) template=osf ;;
  72      sco*) template=sco ;;
  73  solaris*) template=solaris ;;
  74    sunos*) template=sunos4 ;;
  75  sysv4.2*)
  76         case $host_vendor in
  77           univel) template=univel ;;
  78         esac ;;
  79    sysv4*) template=svr4 ;;
  80    sysv5*) template=unixware ;;
  81   ultrix*) template=ultrix4 ;;
  82 esac
  83
  84   if test x"$template" = x"" ; then
  85     AC_MSG_ERROR([[
  86 *******************************************************************
  87 PostgreSQL has apparently not been ported to your platform yet.
  88 To try a manual configuration, look into the src/template directory
  89 for a similar platform and use the '--with-template=' option.
  90
  91 Please also contact <pgsql-bugs@postgresql.org> to see about
  92 rectifying this.  Include the above 'checking host system type...'
  93 line.
  94 *******************************************************************
  95 ]])
  96   fi
  97
  98 ])
  99
 100 AC_MSG_RESULT([$template])
 101
 102 PORTNAME=$template
 103 AC_SUBST(PORTNAME)
 104
 105 # Initialize default assumption that we do not need separate assembly code
 106 # for TAS (test-and-set).  This can be overridden by the template file
 107 # when it's executed.
 108 need_tas=no
 109 tas_file=dummy.s
 110
 111
 112
 113 ##
 114 ## Command line options
 115 ##
 116
 117 #
 118 # Add non-standard directories to the include path
 119 #
 120 PGAC_ARG_REQ(with, includes, [DIRS], [look for additional header files in DIRS])
 121
 122
 123 #
 124 # Add non-standard directories to the library search path
 125 #
 126 PGAC_ARG_REQ(with, libraries, [DIRS], [look for additional libraries in DIRS],
 127              [LIBRARY_DIRS=$withval])
 128
 129 PGAC_ARG_REQ(with, libs,      [DIRS], [alternative spelling of --with-libraries],
 130              [LIBRARY_DIRS=$withval])
 131
 132
 133 #
 134 # 64-bit integer date/time storage: enabled by default.
 135 #
 136 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 137 PGAC_ARG_BOOL(enable, integer-datetimes, yes, [disable 64-bit integer date/time support],
 138               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 139                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 140 AC_MSG_RESULT([$enable_integer_datetimes])
 141
 142
 143 #
 144 # NLS
 145 #
 146 AC_MSG_CHECKING([whether NLS is wanted])
 147 PGAC_ARG_OPTARG(enable, nls,
 148                 [LANGUAGES], [enable Native Language Support],
 149                 [],
 150                 [WANTED_LANGUAGES=$enableval],
 151                 [AC_DEFINE(ENABLE_NLS, 1,
 152                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 153 AC_MSG_RESULT([$enable_nls])
 154 AC_SUBST(enable_nls)
 155 AC_SUBST(WANTED_LANGUAGES)
 156
 157 #
 158 # Default port number (--with-pgport), default 5432
 159 #
 160 AC_MSG_CHECKING([for default port number])
 161 PGAC_ARG_REQ(with, pgport, [PORTNUM], [set default port number [5432]],
 162              [default_port=$withval],
 163              [default_port=5432])
 164 AC_MSG_RESULT([$default_port])
 165 # Need both of these because some places want an integer and some a string
 166 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 167 [Define to the default TCP port number on which the server listens and
 168 to which clients will try to connect.  This can be overridden at run-time,
 169 but it's convenient if your clients have the right default compiled in.
 170 (--with-pgport=PORTNUM)])
 171 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 172                    [Define to the default TCP port number as a string constant.])
 173 AC_SUBST(default_port)
 174
 175 #
 176 # Option to disable shared libraries
 177 #
 178 PGAC_ARG_BOOL(enable, shared, yes,
 179               [do not build shared libraries])
 180 AC_SUBST(enable_shared)
 181
 182 #
 183 # '-rpath'-like feature can be disabled
 184 #
 185 PGAC_ARG_BOOL(enable, rpath, yes,
 186               [do not embed shared library search path in executables])
 187 AC_SUBST(enable_rpath)
 188
 189 #
 190 # Spinlocks
 191 #
 192 PGAC_ARG_BOOL(enable, spinlocks, yes,
 193               [do not use spinlocks])
 194
 195 #
 196 # --enable-debug adds -g to compiler flags
 197 #
 198 PGAC_ARG_BOOL(enable, debug, no,
 199               [build with debugging symbols (-g)])
 200 AC_SUBST(enable_debug)
 201
 202 #
 203 # --enable-profiling enables gcc profiling
 204 #
 205 PGAC_ARG_BOOL(enable, profiling, no,
 206               [build with profiling enabled ])
 207 AC_SUBST(enable_profiling)
 208
 209 #
 210 # --enable-coverage enables generation of code coverage metrics with gcov
 211 #
 212 PGAC_ARG_BOOL(enable, coverage, no,
 213               [build with coverage testing instrumentation],
 214 [AC_CHECK_PROGS(GCOV, gcov)
 215 if test -z "$GCOV"; then
 216   AC_MSG_ERROR([gcov not found])
 217 fi
 218 AC_CHECK_PROGS(LCOV, lcov)
 219 if test -z "$LCOV"; then
 220   AC_MSG_ERROR([lcov not found])
 221 fi
 222 AC_CHECK_PROGS(GENHTML, genhtml)
 223 if test -z "$GENHTML"; then
 224   AC_MSG_ERROR([genhtml not found])
 225 fi])
 226 AC_SUBST(enable_coverage)
 227
 228 #
 229 # DTrace
 230 #
 231 PGAC_ARG_BOOL(enable, dtrace, no,
 232               [build with DTrace support],
 233 [AC_DEFINE([ENABLE_DTRACE], 1,
 234            [Define to 1 to enable DTrace support. (--enable-dtrace)])
 235 AC_CHECK_PROGS(DTRACE, dtrace)
 236 if test -z "$DTRACE"; then
 237   AC_MSG_ERROR([dtrace not found])
 238 fi
 239 AC_SUBST(DTRACEFLAGS)])
 240 AC_SUBST(enable_dtrace)
 241
 242 #
 243 # Block size
 244 #
 245 AC_MSG_CHECKING([for block size])
 246 PGAC_ARG_REQ(with, blocksize, [BLOCKSIZE], [set table block size in kB [8]],
 247              [blocksize=$withval],
 248              [blocksize=8])
 249 case ${blocksize} in
 250   1) BLCKSZ=1024;;
 251   2) BLCKSZ=2048;;
 252   4) BLCKSZ=4096;;
 253   8) BLCKSZ=8192;;
 254  16) BLCKSZ=16384;;
 255  32) BLCKSZ=32768;;
 256   *) AC_MSG_ERROR([Invalid block size. Allowed values are 1,2,4,8,16,32.])
 257 esac
 258 AC_MSG_RESULT([${blocksize}kB])
 259
 260 AC_DEFINE_UNQUOTED([BLCKSZ], ${BLCKSZ}, [
 261  Size of a disk block --- this also limits the size of a tuple.  You
 262  can set it bigger if you need bigger tuples (although TOAST should
 263  reduce the need to have large tuples, since fields can be spread
 264  across multiple tuples).
 265
 266  BLCKSZ must be a power of 2.  The maximum possible value of BLCKSZ
 267  is currently 2^15 (32768).  This is determined by the 15-bit widths
 268  of the lp_off and lp_len fields in ItemIdData (see
 269  include/storage/itemid.h).
 270
 271  Changing BLCKSZ requires an initdb.
 272 ])
 273
 274 #
 275 # Relation segment size
 276 #
 277 AC_MSG_CHECKING([for segment size])
 278 PGAC_ARG_REQ(with, segsize, [SEGSIZE], [set table segment size in GB [1]],
 279              [segsize=$withval],
 280              [segsize=1])
 281 # this expression is set up to avoid unnecessary integer overflow
 282 # blocksize is already guaranteed to be a factor of 1024
 283 RELSEG_SIZE=`expr '(' 1024 / ${blocksize} ')' '*' ${segsize} '*' 1024`
 284 test $? -eq 0 || exit 1
 285 AC_MSG_RESULT([${segsize}GB])
 286
 287 AC_DEFINE_UNQUOTED([RELSEG_SIZE], ${RELSEG_SIZE}, [
 288  RELSEG_SIZE is the maximum number of blocks allowed in one disk file.
 289  Thus, the maximum size of a single file is RELSEG_SIZE * BLCKSZ;
 290  relations bigger than that are divided into multiple files.
 291
 292  RELSEG_SIZE * BLCKSZ must be less than your OS' limit on file size.
 293  This is often 2 GB or 4GB in a 32-bit operating system, unless you
 294  have large file support enabled.  By default, we make the limit 1 GB
 295  to avoid any possible integer-overflow problems within the OS.
 296  A limit smaller than necessary only means we divide a large
 297  relation into more chunks than necessary, so it seems best to err
 298  in the direction of a small limit.
 299
 300  A power-of-2 value is recommended to save a few cycles in md.c,
 301  but is not absolutely required.
 302
 303  Changing RELSEG_SIZE requires an initdb.
 304 ])
 305
 306 #
 307 # WAL block size
 308 #
 309 AC_MSG_CHECKING([for WAL block size])
 310 PGAC_ARG_REQ(with, wal-blocksize, [BLOCKSIZE], [set WAL block size in kB [8]],
 311              [wal_blocksize=$withval],
 312              [wal_blocksize=8])
 313 case ${wal_blocksize} in
 314   1) XLOG_BLCKSZ=1024;;
 315   2) XLOG_BLCKSZ=2048;;
 316   4) XLOG_BLCKSZ=4096;;
 317   8) XLOG_BLCKSZ=8192;;
 318  16) XLOG_BLCKSZ=16384;;
 319  32) XLOG_BLCKSZ=32768;;
 320  64) XLOG_BLCKSZ=65536;;
 321   *) AC_MSG_ERROR([Invalid WAL block size. Allowed values are 1,2,4,8,16,32,64.])
 322 esac
 323 AC_MSG_RESULT([${wal_blocksize}kB])
 324
 325 AC_DEFINE_UNQUOTED([XLOG_BLCKSZ], ${XLOG_BLCKSZ}, [
 326  Size of a WAL file block.  This need have no particular relation to BLCKSZ.
 327  XLOG_BLCKSZ must be a power of 2, and if your system supports O_DIRECT I/O,
 328  XLOG_BLCKSZ must be a multiple of the alignment requirement for direct-I/O
 329  buffers, else direct I/O may fail.
 330
 331  Changing XLOG_BLCKSZ requires an initdb.
 332 ])
 333
 334 #
 335 # WAL segment size
 336 #
 337 AC_MSG_CHECKING([for WAL segment size])
 338 PGAC_ARG_REQ(with, wal-segsize, [SEGSIZE], [set WAL segment size in MB [16]],
 339              [wal_segsize=$withval],
 340              [wal_segsize=16])
 341 case ${wal_segsize} in
 342   1) ;;
 343   2) ;;
 344   4) ;;
 345   8) ;;
 346  16) ;;
 347  32) ;;
 348  64) ;;
 349   *) AC_MSG_ERROR([Invalid WAL segment size. Allowed values are 1,2,4,8,16,32,64.])
 350 esac
 351 AC_MSG_RESULT([${wal_segsize}MB])
 352
 353 AC_DEFINE_UNQUOTED([XLOG_SEG_SIZE], [(${wal_segsize} * 1024 * 1024)], [
 354  XLOG_SEG_SIZE is the size of a single WAL file.  This must be a power of 2
 355  and larger than XLOG_BLCKSZ (preferably, a great deal larger than
 356  XLOG_BLCKSZ).
 357
 358  Changing XLOG_SEG_SIZE requires an initdb.
 359 ])
 360
 361 #
 362 # C compiler
 363 #
 364
 365 # For historical reasons you can also use --with-CC to specify the C compiler
 366 # to use, although the standard way to do this is to set the CC environment
 367 # variable.
 368 PGAC_ARG_REQ(with, CC, [CMD], [set compiler (deprecated)], [CC=$with_CC])
 369
 370 case $template in
 371   aix) pgac_cc_list="gcc xlc";;
 372  irix) pgac_cc_list="cc";; # no gcc
 373     *) pgac_cc_list="gcc cc";;
 374 esac
 375
 376 AC_PROG_CC([$pgac_cc_list])
 377
 378 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 379 # but has idiosyncrasies of its own.  We assume icc will define
 380 # __INTEL_COMPILER regardless of CFLAGS.
 381 AC_TRY_COMPILE([], [@%:@ifndef __INTEL_COMPILER
 382 choke me
 383 @%:@endif], [ICC=[yes]], [ICC=[no]])
 384
 385 # Check if it's Sun Studio compiler. We assume that
 386 # __SUNPRO_C will be defined for Sun Studio compilers
 387 AC_TRY_COMPILE([], [@%:@ifndef __SUNPRO_C
 388 choke me
 389 @%:@endif], [SUN_STUDIO_CC=yes], [SUN_STUDIO_CC=no])
 390
 391 AC_SUBST(SUN_STUDIO_CC)
 392
 393 unset CFLAGS
 394
 395 #
 396 # Read the template
 397 #
 398 . "$srcdir/src/template/$template" || exit
 399
 400 # CFLAGS are selected so:
 401 # If the user specifies something in the environment, that is used.
 402 # else:  If the template file set something, that is used.
 403 # else:  If coverage was enabled, don't set anything.
 404 # else:  If the compiler is GCC, then we use -O2.
 405 # else:  If the compiler is something else, then we use -O, unless debugging.
 406
 407 if test "$ac_env_CFLAGS_set" = set; then
 408   CFLAGS=$ac_env_CFLAGS_value
 409 elif test "${CFLAGS+set}" = set; then
 410   : # (keep what template set)
 411 elif test "$enable_coverage" = yes; then
 412   : # no optimization by default
 413 elif test "$GCC" = yes; then
 414   CFLAGS="-O2"
 415 else
 416   # if the user selected debug mode, don't use -O
 417   if test "$enable_debug" != yes; then
 418     CFLAGS="-O"
 419   fi
 420 fi
 421
 422 # Some versions of GCC support some additional useful warning flags.
 423 # Check whether they are supported, and add them to CFLAGS if so.
 424 # ICC pretends to be GCC but it's lying; it doesn't support these flags,
 425 # but has its own.  Also check other compiler-specific flags here.
 426
 427 if test "$GCC" = yes -a "$ICC" = no; then
 428   CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wpointer-arith"
 429   # These work in some but not all gcc versions
 430   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 431   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 432   # Disable strict-aliasing rules; needed for gcc 3.3+
 433   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 434   # Disable optimizations that assume no overflow; needed for gcc 4.3+
 435   PGAC_PROG_CC_CFLAGS_OPT([-fwrapv])
 436 elif test "$ICC" = yes; then
 437   # Intel's compiler has a bug/misoptimization in checking for
 438   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 439   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 440   # Make sure strict aliasing is off (though this is said to be the default)
 441   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 442 elif test "$PORTNAME" = "aix"; then
 443   # AIX's xlc has to have strict aliasing turned off too
 444   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 445 fi
 446
 447 # supply -g if --enable-debug
 448 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 449   CFLAGS="$CFLAGS -g"
 450 fi
 451
 452 # enable code coverage if --enable-coverage
 453 if test "$enable_coverage" = yes; then
 454   if test "$GCC" = yes; then
 455     CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 456   else
 457     AC_MSG_ERROR([--enable-coverage is supported only when using GCC])
 458   fi
 459 fi
 460
 461 # enable profiling if --enable-profiling
 462 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 463   if test "$GCC" = yes; then
 464     AC_DEFINE([PROFILE_PID_DIR], 1,
 465            [Define to 1 to allow profiling output to be saved separately for each process.])
 466     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 467   else
 468     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 469   fi
 470 fi
 471
 472 # We already have this in Makefile.win32, but configure needs it too
 473 if test "$PORTNAME" = "win32"; then
 474   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 475 fi
 476
 477 # Check if the compiler still works with the template settings
 478 AC_MSG_CHECKING([whether the C compiler still works])
 479 AC_TRY_LINK([], [return 0;],
 480   [AC_MSG_RESULT(yes)],
 481   [AC_MSG_RESULT(no)
 482    AC_MSG_ERROR([cannot proceed])])
 483
 484 # Defend against gcc -ffast-math
 485 if test "$GCC" = yes; then
 486 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 487 choke me
 488 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 489 fi
 490
 491 AC_PROG_CPP
 492 AC_SUBST(GCC)
 493
 494
 495 #
 496 # Set up TAS assembly code if needed; the template file has now had its
 497 # chance to request this.
 498 #
 499 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 500
 501 if test "$need_tas" = yes ; then
 502   TAS=tas.o
 503 else
 504   TAS=""
 505 fi
 506 AC_SUBST(TAS)
 507
 508
 509 #
 510 # Automatic dependency tracking
 511 #
 512 PGAC_ARG_BOOL(enable, depend, no, [turn on automatic dependency tracking],
 513               [autodepend=yes])
 514 AC_SUBST(autodepend)
 515
 516
 517 #
 518 # Enable assert checks
 519 #
 520 PGAC_ARG_BOOL(enable, cassert, no, [enable assertion checks (for debugging)],
 521               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 522                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 523
 524
 525 #
 526 # Include directories
 527 #
 528 ac_save_IFS=$IFS
 529 IFS="${IFS}${PATH_SEPARATOR}"
 530 # SRCH_INC comes from the template file
 531 for dir in $with_includes $SRCH_INC; do
 532   if test -d "$dir"; then
 533     INCLUDES="$INCLUDES -I$dir"
 534   else
 535     AC_MSG_WARN([*** Include directory $dir does not exist.])
 536   fi
 537 done
 538 IFS=$ac_save_IFS
 539 AC_SUBST(INCLUDES)
 540
 541
 542 #
 543 # Library directories
 544 #
 545 ac_save_IFS=$IFS
 546 IFS="${IFS}${PATH_SEPARATOR}"
 547 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 548 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 549   if test -d "$dir"; then
 550     LIBDIRS="$LIBDIRS -L$dir"
 551   else
 552     AC_MSG_WARN([*** Library directory $dir does not exist.])
 553   fi
 554 done
 555 IFS=$ac_save_IFS
 556
 557 #
 558 # Enable thread-safe client libraries
 559 #
 560 AC_MSG_CHECKING([allow thread-safe client libraries])
 561 if test "$PORTNAME" != "win32"; then
 562 PGAC_ARG_BOOL(enable, thread-safety, no, [make client libraries thread-safe])
 563 else
 564 # Win32 should always use threads
 565 PGAC_ARG_BOOL(enable, thread-safety, yes, [make client libraries thread-safe])
 566 fi
 567
 568 PGAC_ARG_BOOL(enable, thread-safety-force, no, [force thread-safety despite thread test failure])
 569 if test "$enable_thread_safety" = yes -o \
 570         "$enable_thread_safety_force" = yes; then
 571   enable_thread_safety="yes"    # for 'force'
 572   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 573           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 574 fi
 575 AC_MSG_RESULT([$enable_thread_safety])
 576 AC_SUBST(enable_thread_safety)
 577
 578 #
 579 # Optionally build Tcl modules (PL/Tcl)
 580 #
 581 AC_MSG_CHECKING([whether to build with Tcl])
 582 PGAC_ARG_BOOL(with, tcl, no, [build Tcl modules (PL/Tcl)])
 583 AC_MSG_RESULT([$with_tcl])
 584 AC_SUBST([with_tcl])
 585
 586 # We see if the path to the Tcl/Tk configuration scripts is specified.
 587 # This will override the use of tclsh to find the paths to search.
 588
 589 PGAC_ARG_REQ(with, tclconfig, [DIR], [tclConfig.sh is in DIR])
 590
 591 #
 592 # Optionally build Perl modules (PL/Perl)
 593 #
 594 AC_MSG_CHECKING([whether to build Perl modules])
 595 PGAC_ARG_BOOL(with, perl, no, [build Perl modules (PL/Perl)])
 596 AC_MSG_RESULT([$with_perl])
 597 AC_SUBST(with_perl)
 598
 599 #
 600 # Optionally build Python modules (PL/Python)
 601 #
 602 AC_MSG_CHECKING([whether to build Python modules])
 603 PGAC_ARG_BOOL(with, python, no, [build Python modules (PL/Python)])
 604 AC_MSG_RESULT([$with_python])
 605 AC_SUBST(with_python)
 606
 607 #
 608 # GSSAPI
 609 #
 610 AC_MSG_CHECKING([whether to build with GSSAPI support])
 611 PGAC_ARG_BOOL(with, gssapi, no, [build with GSSAPI support],
 612 [
 613   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 614   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 615 ])
 616 AC_MSG_RESULT([$with_gssapi])
 617 AC_SUBST(with_gssapi)
 618
 619 #
 620 # Kerberos 5
 621 #
 622 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 623 PGAC_ARG_BOOL(with, krb5, no, [build with Kerberos 5 support],
 624 [
 625   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 626   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 627 ])
 628 AC_MSG_RESULT([$with_krb5])
 629 AC_SUBST(with_krb5)
 630
 631
 632 AC_SUBST(krb_srvtab)
 633
 634
 635 #
 636 # Kerberos configuration parameters
 637 #
 638 PGAC_ARG_REQ(with, krb-srvnam,
 639              [NAME], [default service principal name in Kerberos [postgres]],
 640              [],
 641              [with_krb_srvnam="postgres"])
 642 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 643                    [Define to the name of the default PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 644
 645
 646 #
 647 # PAM
 648 #
 649 AC_MSG_CHECKING([whether to build with PAM support])
 650 PGAC_ARG_BOOL(with, pam, no,
 651               [build with PAM support],
 652               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 653 AC_MSG_RESULT([$with_pam])
 654 AC_SUBST(with_pam)
 655
 656
 657 #
 658 # LDAP
 659 #
 660 AC_MSG_CHECKING([whether to build with LDAP support])
 661 PGAC_ARG_BOOL(with, ldap, no,
 662               [build with LDAP support],
 663               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 664 AC_MSG_RESULT([$with_ldap])
 665 AC_SUBST(with_ldap)
 666
 667
 668 #
 669 # Bonjour
 670 #
 671 AC_MSG_CHECKING([whether to build with Bonjour support])
 672 PGAC_ARG_BOOL(with, bonjour, no,
 673               [build with Bonjour support],
 674               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 675 AC_MSG_RESULT([$with_bonjour])
 676 AC_SUBST(with_bonjour)
 677
 678
 679 #
 680 # OpenSSL
 681 #
 682 AC_MSG_CHECKING([whether to build with OpenSSL support])
 683 PGAC_ARG_BOOL(with, openssl, no, [build with OpenSSL support],
 684               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 685 AC_MSG_RESULT([$with_openssl])
 686 AC_SUBST(with_openssl)
 687
 688
 689 #
 690 # Readline
 691 #
 692 PGAC_ARG_BOOL(with, readline, yes,
 693               [do not use GNU Readline nor BSD Libedit for editing])
 694 # readline on MinGW has problems with backslashes in psql and other bugs.
 695 # This is particularly a problem with non-US code pages.
 696 # Therefore disable its use until we understand the cause. 2004-07-20
 697 if test "$PORTNAME" = "win32"; then
 698   if test "$with_readline" = yes; then
 699     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 700     with_readline=no
 701   fi
 702 fi
 703
 704
 705 #
 706 # Prefer libedit
 707 #
 708 PGAC_ARG_BOOL(with, libedit-preferred, no,
 709               [prefer BSD Libedit over GNU Readline])
 710
 711
 712 #
 713 # OSSP UUID library
 714 #
 715 PGAC_ARG_BOOL(with, ossp-uuid, no, [use OSSP UUID library when building contrib/uuid-ossp])
 716 AC_SUBST(with_ossp_uuid)
 717
 718
 719 #
 720 # XML
 721 #
 722 PGAC_ARG_BOOL(with, libxml, no, [build with XML support],
 723               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 724
 725 if test "$with_libxml" = yes ; then
 726   AC_CHECK_PROGS(XML2_CONFIG, xml2-config)
 727   if test -n "$XML2_CONFIG"; then
 728     for pgac_option in `$XML2_CONFIG --cflags`; do
 729       case $pgac_option in
 730         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 731       esac
 732     done
 733     for pgac_option in `$XML2_CONFIG --libs`; do
 734       case $pgac_option in
 735         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 736       esac
 737     done
 738   fi
 739 fi
 740
 741 AC_SUBST(with_libxml)
 742
 743 #
 744 # XSLT
 745 #
 746 PGAC_ARG_BOOL(with, libxslt, no, [use XSLT support when building contrib/xml2],
 747               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 748
 749
 750 AC_SUBST(with_libxslt)
 751
 752 #
 753 # tzdata
 754 #
 755 PGAC_ARG_REQ(with, system-tzdata,
 756              [DIR], [use system time zone data in DIR])
 757 AC_SUBST(with_system_tzdata)
 758
 759 #
 760 # Zlib
 761 #
 762 PGAC_ARG_BOOL(with, zlib, yes,
 763               [do not use Zlib])
 764 AC_SUBST(with_zlib)
 765
 766 #
 767 # Elf
 768 #
 769
 770 # Assume system is ELF if it predefines __ELF__ as 1,
 771 # otherwise believe host_os based default.
 772 case $host_os in
 773     freebsd1*|freebsd2*) elf=no;;
 774     freebsd3*|freebsd4*) elf=yes;;
 775 esac
 776
 777 AC_EGREP_CPP(yes,
 778 [#if __ELF__
 779   yes
 780 #endif
 781 ],
 782 [ELF_SYS=true],
 783 [if test "X$elf" = "Xyes" ; then
 784   ELF_SYS=true
 785 else
 786   ELF_SYS=
 787 fi])
 788 AC_SUBST(ELF_SYS)
 789
 790 #
 791 # Assignments
 792 #
 793
 794 CPPFLAGS="$CPPFLAGS $INCLUDES"
 795 LDFLAGS="$LDFLAGS $LIBDIRS"
 796
 797 AC_ARG_VAR(LDFLAGS_SL)
 798
 799 PGAC_PROG_LD
 800 AC_SUBST(LD)
 801 AC_SUBST(with_gnu_ld)
 802 case $host_os in sysv5*)
 803   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 804   [
 805     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 806     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 807     LDFLAGS=$pgac_save_LDFLAGS
 808   ])
 809   ld_R_works=$pgac_cv_prog_ld_R
 810   AC_SUBST(ld_R_works)
 811 esac
 812 AC_PROG_RANLIB
 813 PGAC_CHECK_STRIP
 814 AC_CHECK_TOOL(AR, ar, ar)
 815 if test "$PORTNAME" = "win32"; then
 816   AC_CHECK_TOOL(DLLTOOL, dlltool, dlltool)
 817   AC_CHECK_TOOL(DLLWRAP, dllwrap, dllwrap)
 818   AC_CHECK_TOOL(WINDRES, windres, windres)
 819 fi
 820
 821 AC_PATH_PROG(TAR, tar)
 822 AC_PROG_LN_S
 823 AC_PROG_AWK
 824
 825 PGAC_PATH_BISON
 826 PGAC_PATH_FLEX
 827
 828 PGAC_PATH_PERL
 829 if test "$with_perl" = yes; then
 830   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 831   PGAC_CHECK_PERL_EMBED_LDFLAGS
 832 fi
 833
 834 if test "$with_python" = yes; then
 835   PGAC_PATH_PYTHON
 836   PGAC_CHECK_PYTHON_EMBED_SETUP
 837 fi
 838
 839 if test "$cross_compiling" = yes && test -z "$with_system_tzdata"; then
 840   AC_PATH_PROG(ZIC, zic)
 841   if test -z "$ZIC"; then
 842     AC_MSG_ERROR([
 843 When cross-compiling, either use the option --with-system-tzdata to use
 844 existing time-zone data, or set the environment variable ZIC to a zic
 845 program to use during the build.])
 846   fi
 847 fi
 848
 849
 850 ##
 851 ## Libraries
 852 ##
 853 ## Most libraries are included only if they demonstrably provide a function
 854 ## we need, but libm is an exception: always include it, because there are
 855 ## too many compilers that play cute optimization games that will break
 856 ## probes for standard functions such as pow().
 857 ##
 858
 859 AC_CHECK_LIB(m, main)
 860 AC_SEARCH_LIBS(setproctitle, util)
 861 AC_SEARCH_LIBS(dlopen, dl)
 862 AC_SEARCH_LIBS(socket, [socket wsock32])
 863 AC_SEARCH_LIBS(shl_load, dld)
 864 # We only use libld in port/dynloader/aix.c
 865 case $host_os in
 866      aix*)
 867         AC_SEARCH_LIBS(ldopen, ld)
 868         ;;
 869 esac
 870 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 871 AC_SEARCH_LIBS(crypt, crypt)
 872 # Solaris:
 873 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 874 # Required for thread_test.c on Solaris 2.5:
 875 # Other ports use it too (HP-UX) so test unconditionally
 876 AC_SEARCH_LIBS(gethostbyname_r, nsl)
 877 # Cygwin:
 878 AC_SEARCH_LIBS(shmget, cygipc)
 879
 880 if test "$with_readline" = yes; then
 881   PGAC_CHECK_READLINE
 882   if test x"$pgac_cv_check_readline" = x"no"; then
 883     AC_MSG_ERROR([readline library not found
 884 If you have readline already installed, see config.log for details on the
 885 failure.  It is possible the compiler isn't looking in the proper directory.
 886 Use --without-readline to disable readline support.])
 887   fi
 888 fi
 889
 890 if test "$with_zlib" = yes; then
 891   AC_CHECK_LIB(z, inflate, [],
 892                [AC_MSG_ERROR([zlib library not found
 893 If you have zlib already installed, see config.log for details on the
 894 failure.  It is possible the compiler isn't looking in the proper directory.
 895 Use --without-zlib to disable zlib support.])])
 896 fi
 897
 898 if test "$enable_spinlocks" = yes; then
 899   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 900 else
 901   AC_MSG_WARN([
 902 *** Not using spinlocks will cause poor performance.])
 903 fi
 904
 905 if test "$with_gssapi" = yes ; then
 906   if test "$PORTNAME" != "win32"; then
 907     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
 908                                   [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
 909   else
 910     LIBS="$LIBS -lgssapi32"
 911   fi
 912 fi
 913
 914 if test "$with_krb5" = yes ; then
 915   if test "$PORTNAME" != "win32"; then
 916      AC_SEARCH_LIBS(com_err, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken' com_err], [],
 917                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 918      AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken'], [],
 919                     [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 920   else
 921      AC_SEARCH_LIBS(com_err, 'comerr32 -lkrb5_32', [],
 922                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 923   fi
 924 fi
 925
 926 if test "$with_openssl" = yes ; then
 927   dnl Order matters!
 928   if test "$PORTNAME" != "win32"; then
 929      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 930      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 931   else
 932      AC_CHECK_LIB(eay32, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'eay32' is required for OpenSSL])])
 933      AC_CHECK_LIB(ssleay32,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssleay32' is required for OpenSSL])])
 934   fi
 935 fi
 936
 937 if test "$with_pam" = yes ; then
 938   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 939 fi
 940
 941 if test "$with_libxml" = yes ; then
 942   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
 943 fi
 944
 945 if test "$with_libxslt" = yes ; then
 946   AC_CHECK_LIB(xslt, xsltCleanupGlobals, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
 947 fi
 948
 949 # for contrib/uuid-ossp
 950 if test "$with_ossp_uuid" = yes ; then
 951   AC_CHECK_LIB(ossp-uuid, uuid_export,
 952     [OSSP_UUID_LIBS="-lossp-uuid"],
 953     [AC_CHECK_LIB(uuid, uuid_export,
 954       [OSSP_UUID_LIBS="-luuid"],
 955       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP-UUID])])])
 956 fi
 957 AC_SUBST(OSSP_UUID_LIBS)
 958
 959
 960 ##
 961 ## Header files
 962 ##
 963
 964 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 965 AC_CHECK_HEADERS([crypt.h dld.h fp_class.h getopt.h ieeefp.h langinfo.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/tas.h sys/time.h sys/un.h termios.h ucred.h utime.h wchar.h wctype.h kernel/OS.h kernel/image.h SupportDefs.h])
 966
 967 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 968 # netinet/in.h is included first.
 969 AC_CHECK_HEADERS(netinet/in.h)
 970 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 971 [AC_INCLUDES_DEFAULT
 972 #ifdef HAVE_NETINET_IN_H
 973 #include <netinet/in.h>
 974 #endif
 975 ])
 976
 977 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
 978   AC_CHECK_HEADERS(readline/readline.h, [],
 979         [AC_CHECK_HEADERS(readline.h, [],
 980                 [AC_MSG_ERROR([readline header not found
 981 If you have readline already installed, see config.log for details on the
 982 failure.  It is possible the compiler isn't looking in the proper directory.
 983 Use --without-readline to disable readline support.])])])
 984   AC_CHECK_HEADERS(readline/history.h, [],
 985         [AC_CHECK_HEADERS(history.h, [],
 986                 [AC_MSG_ERROR([history header not found
 987 If you have readline already installed, see config.log for details on the
 988 failure.  It is possible the compiler isn't looking in the proper directory.
 989 Use --without-readline to disable readline support.])])])
 990 fi
 991
 992 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
 993 # Some installations of libedit usurp /usr/include/readline/, which seems
 994 # bad practice, since in combined installations readline will have its headers
 995 # there.  We might have to resort to AC_EGREP checks to make sure we found
 996 # the proper header...
 997   AC_CHECK_HEADERS(editline/readline.h, [],
 998         [AC_CHECK_HEADERS(readline.h, [],
 999                 [AC_CHECK_HEADERS(readline/readline.h, [],
1000                         [AC_MSG_ERROR([readline header not found
1001 If you have libedit already installed, see config.log for details on the
1002 failure.  It is possible the compiler isn't looking in the proper directory.
1003 Use --without-readline to disable libedit support.])])])])
1004 # Note: in a libedit installation, history.h is sometimes a dummy, and may
1005 # not be there at all.  Hence, don't complain if not found.  We must check
1006 # though, since in yet other versions it is an independent header.
1007   AC_CHECK_HEADERS(editline/history.h, [],
1008         [AC_CHECK_HEADERS(history.h, [],
1009                 [AC_CHECK_HEADERS(readline/history.h)])])
1010 fi
1011
1012 if test "$with_zlib" = yes; then
1013   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
1014 If you have zlib already installed, see config.log for details on the
1015 failure.  It is possible the compiler isn't looking in the proper directory.
1016 Use --without-zlib to disable zlib support.])])
1017 fi
1018
1019 if test "$with_gssapi" = yes ; then
1020   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
1021         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
1022 fi
1023
1024 if test "$with_krb5" = yes ; then
1025   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
1026 fi
1027
1028 if test "$with_openssl" = yes ; then
1029   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
1030   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
1031   AC_CHECK_FUNCS([ERR_set_mark])
1032 fi
1033
1034 if test "$with_pam" = yes ; then
1035   AC_CHECK_HEADERS(security/pam_appl.h, [],
1036                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
1037                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
1038 fi
1039
1040 if test "$with_libxml" = yes ; then
1041   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
1042 fi
1043
1044 if test "$with_libxslt" = yes ; then
1045   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
1046 fi
1047
1048 if test "$with_ldap" = yes ; then
1049   if test "$PORTNAME" != "win32"; then
1050      AC_CHECK_HEADERS(ldap.h, [],
1051                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
1052   else
1053      AC_CHECK_HEADERS(winldap.h, [],
1054                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
1055                       [AC_INCLUDES_DEFAULT
1056 #include <windows.h>
1057                       ])
1058   fi
1059 fi
1060
1061 if test "$with_bonjour" = yes ; then
1062   AC_CHECK_HEADER(DNSServiceDiscovery/DNSServiceDiscovery.h, [], [AC_MSG_ERROR([header file <DNSServiceDiscovery/DNSServiceDiscovery.h> is required for Bonjour])])
1063 fi
1064
1065 # for contrib/uuid-ossp
1066 if test "$with_ossp_uuid" = yes ; then
1067   AC_CHECK_HEADERS(ossp/uuid.h, [], [
1068     AC_CHECK_HEADERS(uuid.h, [],
1069       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP-UUID])])])
1070 fi
1071
1072
1073 ##
1074 ## Types, structures, compiler characteristics
1075 ##
1076
1077 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
1078 AC_C_BIGENDIAN
1079 AC_C_CONST
1080 AC_C_INLINE
1081 AC_C_STRINGIZE
1082 PGAC_C_SIGNED
1083 AC_C_VOLATILE
1084 PGAC_C_FUNCNAME_SUPPORT
1085 PGAC_STRUCT_TIMEZONE
1086 PGAC_UNION_SEMUN
1087 PGAC_STRUCT_SOCKADDR_UN
1088 PGAC_STRUCT_SOCKADDR_STORAGE
1089 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
1090 PGAC_STRUCT_ADDRINFO
1091
1092 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
1093 [#include <sys/param.h>
1094 #include <sys/types.h>
1095 #include <sys/socket.h>
1096 #include <sys/ucred.h>])
1097
1098 AC_CHECK_TYPES([struct option], [], [],
1099 [#ifdef HAVE_GETOPT_H
1100 #include <getopt.h>
1101 #endif])
1102
1103 if test "$with_zlib" = yes; then
1104   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
1105   # did not).  While we could work around the lack of z_streamp, it
1106   # seems unwise to encourage people to use such old zlib versions...
1107   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
1108 Use --without-zlib to disable zlib support.])],
1109                 [#include <zlib.h>])
1110 fi
1111
1112 if test "$with_krb5" = yes; then
1113 # Check for differences between MIT and Heimdal (KTH) releases
1114   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
1115                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
1116                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
1117                                      [#include <krb5.h>])],
1118                    [#include <krb5.h>])
1119   AC_CHECK_MEMBERS(krb5_error.text.data, [],
1120                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
1121                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
1122                                      [#include <krb5.h>])],
1123                    [#include <krb5.h>])
1124
1125 # Win32 requires headers to be loaded for __stdcall, so can't use
1126 # AC_CHECK_FUNCS here.
1127   AC_MSG_CHECKING(for krb5_free_unparsed_name)
1128   AC_TRY_LINK([#include <krb5.h>],
1129               [krb5_free_unparsed_name(NULL,NULL);],
1130               [AC_DEFINE(HAVE_KRB5_FREE_UNPARSED_NAME, 1, [Define to 1 if you have krb5_free_unparsed_name])
1131 AC_MSG_RESULT(yes)],
1132               [AC_MSG_RESULT(no)])
1133 fi
1134
1135
1136 ##
1137 ## Functions, global variables
1138 ##
1139
1140 PGAC_VAR_INT_TIMEZONE
1141 AC_FUNC_ACCEPT_ARGTYPES
1142 PGAC_FUNC_GETTIMEOFDAY_1ARG
1143
1144 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid getpeerucred getrlimit memmove poll posix_fadvise pstat readlink setproctitle setsid sigprocmask symlink sysconf towlower utime utimes waitpid wcstombs])
1145
1146 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
1147 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
1148 AC_CHECK_DECLS([strlcat, strlcpy])
1149 # This is probably only present on Darwin, but may as well check always
1150 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
1151
1152 HAVE_IPV6=no
1153 AC_CHECK_TYPE([struct sockaddr_in6],
1154         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
1155          HAVE_IPV6=yes],
1156         [],
1157 [$ac_includes_default
1158 #include <netinet/in.h>])
1159 AC_SUBST(HAVE_IPV6)
1160
1161 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1162 [AC_TRY_LINK(
1163 [#include <machine/vmparam.h>
1164 #include <sys/exec.h>
1165 ],
1166 [PS_STRINGS->ps_nargvstr = 1;
1167 PS_STRINGS->ps_argvstr = "foo";],
1168 [pgac_cv_var_PS_STRINGS=yes],
1169 [pgac_cv_var_PS_STRINGS=no])])
1170 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1171   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
1172 fi
1173
1174
1175 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
1176 # is missing.  Yes, there are machines that have only one.  We may
1177 # also decide to use snprintf.c if snprintf() is present but does not
1178 # have all the features we need --- see below.
1179
1180 if test "$PORTNAME" = "win32"; then
1181   # Win32 gets snprintf.c built unconditionally.
1182   #
1183   # To properly translate all NLS languages strings, we must support the
1184   # *printf() %$ format, which allows *printf() arguments to be selected
1185   # by position in the translated string.
1186   #
1187   # libintl versions < 0.13 use the native *printf() functions, and Win32
1188   # *printf() doesn't understand %$, so we must use our /port versions,
1189   # which do understand %$. libintl versions >= 0.13 include their own
1190   # *printf versions on Win32.  The libintl 0.13 release note text is:
1191   #
1192   #   C format strings with positions, as they arise when a translator
1193   #   needs to reorder a sentence, are now supported on all platforms.
1194   #   On those few platforms (NetBSD and Woe32) for which the native
1195   #   printf()/fprintf()/... functions don't support such format
1196   #   strings, replacements are provided through <libintl.h>.
1197   #
1198   # We could use libintl >= 0.13's *printf() if we were sure that we had
1199   # a litint >= 0.13 at runtime, but seeing that there is no clean way
1200   # to guarantee that, it is best to just use our own, so we are sure to
1201   # get %$ support. In include/port.h we disable the *printf() macros
1202   # that might have been defined by libintl.
1203   #
1204   # We do this unconditionally whether NLS is used or not so we are sure
1205   # that all Win32 libraries and binaries behave the same.
1206   pgac_need_repl_snprintf=yes
1207 else
1208   pgac_need_repl_snprintf=no
1209   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
1210   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1211 fi
1212
1213
1214 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
1215 # include/c.h will provide declarations.  Note this is a separate test
1216 # from whether the functions exist in the C library --- there are
1217 # systems that have the functions but don't bother to declare them :-(
1218
1219 AC_CHECK_DECLS([snprintf, vsnprintf])
1220
1221
1222 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1223 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1224 [AC_TRY_LINK([
1225 #include <math.h>
1226 double glob_double;
1227 ],
1228 [return isinf(glob_double) ? 0 : 1;],
1229 [ac_cv_func_isinf=yes],
1230 [ac_cv_func_isinf=no])])
1231
1232 if test $ac_cv_func_isinf = yes ; then
1233   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1234 else
1235   AC_LIBOBJ(isinf)
1236   # Look for a way to implement a substitute for isinf()
1237   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1238 fi
1239
1240 # Some versions of libedit contain strlcpy(); so disregard that library while
1241 # checking for these standard libc functions.
1242 pgac_save_LIBS="$LIBS"
1243 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1244
1245 AC_REPLACE_FUNCS([crypt getopt getrusage inet_aton random rint srandom strdup strerror strlcat strlcpy strtol strtoul unsetenv])
1246
1247 LIBS="$pgac_save_LIBS"
1248
1249 # System's version of getaddrinfo(), if any, may be used only if we found
1250 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1251 # (Note: the AC_REPLACE_FUNCS probe fails on Windows, where the available
1252 # versions of getaddrinfo don't follow normal C call protocol.  This is OK
1253 # because we want to use our own getaddrinfo.c on Windows anyway.)
1254 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
1255   AC_REPLACE_FUNCS([getaddrinfo])
1256 else
1257   AC_LIBOBJ(getaddrinfo)
1258 fi
1259
1260 # Similarly, use system's getopt_long() only if system provides struct option.
1261 # Solaris' getopt() doesn't do what we want for long options, so always use
1262 # our versions on that platform.
1263 if test "$PORTNAME" = "solaris"; then
1264   AC_LIBOBJ(getopt)
1265   AC_LIBOBJ(getopt_long)
1266 elif test x"$ac_cv_type_struct_option" = xyes ; then
1267   AC_REPLACE_FUNCS([getopt_long])
1268 else
1269   AC_LIBOBJ(getopt_long)
1270 fi
1271
1272 # Win32 support
1273 if test "$PORTNAME" = "win32"; then
1274 AC_REPLACE_FUNCS(gettimeofday)
1275 AC_LIBOBJ(kill)
1276 AC_LIBOBJ(open)
1277 AC_LIBOBJ(rand)
1278 AC_LIBOBJ(win32env)
1279 AC_LIBOBJ(win32error)
1280 AC_DEFINE([HAVE_SYMLINK], 1,
1281           [Define to 1 if you have the `symlink' function.])
1282 fi
1283
1284 if test "$with_readline" = yes; then
1285   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1286   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
1287   AC_CHECK_FUNCS([replace_history_entry])
1288 fi
1289
1290
1291 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
1292 dnl (especially on GNU libc)
1293 dnl See also comments in c.h.
1294 AC_MSG_CHECKING(for sigsetjmp)
1295 AC_TRY_LINK([#include <setjmp.h>],
1296             [sigjmp_buf x; sigsetjmp(x, 1);],
1297             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
1298 AC_MSG_RESULT(yes)],
1299             [AC_MSG_RESULT(no)])
1300
1301 AC_DECL_SYS_SIGLIST
1302
1303 AC_CHECK_FUNC(syslog,
1304               [AC_CHECK_HEADER(syslog.h,
1305                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1306
1307 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1308 [AC_TRY_LINK([#include <unistd.h>],
1309   [extern int optreset; optreset = 1;],
1310   [pgac_cv_var_int_optreset=yes],
1311   [pgac_cv_var_int_optreset=no])])
1312 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1313   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1314 fi
1315
1316 AC_CHECK_FUNCS([strtoll strtoq], [break])
1317 AC_CHECK_FUNCS([strtoull strtouq], [break])
1318
1319 # Check for one of atexit() or on_exit()
1320 AC_CHECK_FUNCS(atexit, [],
1321                [AC_CHECK_FUNCS(on_exit, [],
1322                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
1323
1324 AC_REPLACE_FUNCS(fseeko)
1325 case $host_os in
1326         # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
1327         # Mingw uses macros to access Win32 API calls
1328         bsdi*|netbsd*|mingw*)
1329                 AC_DEFINE(HAVE_FSEEKO, 1, [Define to 1 because replacement version used.])
1330                 ac_cv_func_fseeko=yes;;
1331         *)
1332                 AC_FUNC_FSEEKO;;
1333 esac
1334
1335
1336 #
1337 # Pthreads
1338 #
1339 # For each platform, we need to know about any special compile and link
1340 # libraries, and whether the normal C function names are thread-safe.
1341 # See the comment at the top of src/port/thread.c for more information.
1342 # WIN32 doesn't need the pthread tests;  it always uses threads
1343 if test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"; then
1344 ACX_PTHREAD     # set thread flags
1345
1346 # Some platforms use these, so just define them.  They can't hurt if they
1347 # are not supported.  For example, on Solaris -D_POSIX_PTHREAD_SEMANTICS
1348 # enables 5-arg getpwuid_r, among other things.
1349 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1350
1351
1352 # At this point, we don't want to muck with the compiler name for threading.
1353 # Let's see who fails, perhaps AIX.  2004-04-23
1354 if test "$PTHREAD_CC" != "$CC"; then
1355 AC_MSG_ERROR([
1356 PostgreSQL does not support platforms that require a special compiler
1357 for thread safety.])
1358 fi
1359
1360 if test "$THREAD_SUPPORT" = no; then
1361 AC_MSG_ERROR([cannot enable threads on this platform
1362 This platform is known to not support thread-safe programs.  For details,
1363 compile and run src/bin/pg_thread_test.])
1364 fi
1365
1366 # Check for *_r functions
1367 _CFLAGS="$CFLAGS"
1368 _LIBS="$LIBS"
1369 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1370 LIBS="$LIBS $PTHREAD_LIBS"
1371
1372 if test "$PORTNAME" != "win32"; then
1373 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([pthread.h not found, required for --enable-thread-safety])])
1374 fi
1375
1376 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1377
1378 # Do test here with the proper thread flags
1379 PGAC_FUNC_GETPWUID_R_5ARG
1380 PGAC_FUNC_STRERROR_R_INT
1381
1382 CFLAGS="$_CFLAGS"
1383 LIBS="$_LIBS"
1384
1385 else
1386 # do not use values from template file
1387 PTHREAD_CFLAGS=
1388 PTHREAD_LIBS=
1389 fi
1390
1391 AC_SUBST(PTHREAD_CFLAGS)
1392 AC_SUBST(PTHREAD_LIBS)
1393
1394
1395 # We can test for libldap_r only after we know PTHREAD_LIBS
1396 if test "$with_ldap" = yes ; then
1397   _LIBS="$LIBS"
1398   if test "$PORTNAME" != "win32"; then
1399     AC_CHECK_LIB(ldap, ldap_bind, [],
1400                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1401                  [$EXTRA_LDAP_LIBS])
1402     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1403     if test "$enable_thread_safety" = yes; then
1404       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1405       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1406                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1407                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1408       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1409     else
1410       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1411     fi
1412   else
1413     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1414     LDAP_LIBS_FE="-lwldap32"
1415     LDAP_LIBS_BE="-lwldap32"
1416   fi
1417   LIBS="$_LIBS"
1418 fi
1419 AC_SUBST(LDAP_LIBS_FE)
1420 AC_SUBST(LDAP_LIBS_BE)
1421
1422
1423 # This test makes sure that run tests work at all.  Sometimes a shared
1424 # library is found by the linker, but the runtime linker can't find it.
1425 # This check should come after all modifications of compiler or linker
1426 # variables, and before any other run tests.
1427 AC_MSG_CHECKING([test program])
1428 AC_TRY_RUN([int main() { return 0; }],
1429 [AC_MSG_RESULT(ok)],
1430 [AC_MSG_RESULT(failed)
1431 AC_MSG_ERROR([[
1432 Could not execute a simple test program.  This may be a problem
1433 related to locating shared libraries.  Check the file 'config.log'
1434 for the exact reason.]])],
1435 [AC_MSG_RESULT([cross-compiling])])
1436
1437 # --------------------
1438 # Run tests below here
1439 # --------------------
1440
1441 # Force use of our snprintf if system's doesn't do arg control
1442 # See comment above at snprintf test for details.
1443 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1444   PGAC_FUNC_PRINTF_ARG_CONTROL
1445   if test $pgac_cv_printf_arg_control != yes ; then
1446     pgac_need_repl_snprintf=yes
1447   fi
1448 fi
1449
1450
1451 dnl Check to see if we have a working 64-bit integer type.
1452 dnl This breaks down into two steps:
1453 dnl (1) figure out if the compiler has a 64-bit int type with working
1454 dnl arithmetic, and if so
1455 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1456 dnl snprintf is the only library routine we really need for int8 support.)
1457 dnl It's entirely possible to have a compiler that handles a 64-bit type
1458 dnl when the C library doesn't; this is fairly likely when using gcc on
1459 dnl an older platform, for example.
1460 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1461 dnl we force our own version of snprintf() to be used instead.
1462 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1463
1464 PGAC_TYPE_64BIT_INT([long int])
1465
1466 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1467   PGAC_TYPE_64BIT_INT([long long int])
1468 fi
1469
1470
1471 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1472
1473 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1474   AC_TRY_COMPILE([
1475 #define INT64CONST(x)  x##LL
1476 long long int foo = INT64CONST(0x1234567890123456);
1477 ],
1478         [],
1479         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1480         [])
1481 fi
1482
1483
1484 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1485 # we found we need to use "long long int", better check.  We cope with
1486 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1487 # work, fall back to our own snprintf emulation (which we know uses %lld).
1488
1489 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1490   if test $pgac_need_repl_snprintf = no; then
1491     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1492     if test "$LONG_LONG_INT_FORMAT" = ""; then
1493       # Force usage of our own snprintf, since system snprintf is broken
1494       pgac_need_repl_snprintf=yes
1495       LONG_LONG_INT_FORMAT='%lld'
1496     fi
1497   else
1498     # Here if we previously decided we needed to use our own snprintf
1499     LONG_LONG_INT_FORMAT='%lld'
1500   fi
1501   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1502   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1503   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1504 else
1505   # Here if we are not using 'long long int' at all
1506   INT64_FORMAT='"%ld"'
1507   UINT64_FORMAT='"%lu"'
1508 fi
1509
1510 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1511                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1512
1513 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1514                    [Define to the appropriate snprintf format for unsigned 64-bit ints, if any.])
1515
1516 # Now we have checked all the reasons to replace snprintf
1517 if test $pgac_need_repl_snprintf = yes; then
1518   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1519   AC_LIBOBJ(snprintf)
1520 fi
1521
1522 # Need a #define for the size of Datum (unsigned long)
1523 AC_CHECK_SIZEOF([unsigned long])
1524
1525 # And check size of void *, size_t (enables tweaks for > 32bit address space)
1526 AC_CHECK_SIZEOF([void *])
1527 AC_CHECK_SIZEOF([size_t])
1528
1529 # Decide whether float4 is passed by value: user-selectable, enabled by default
1530 AC_MSG_CHECKING([whether to build with float4 passed by value])
1531 PGAC_ARG_BOOL(enable, float4-byval, yes, [disable float4 passed by value],
1532               [AC_DEFINE([USE_FLOAT4_BYVAL], 1,
1533                          [Define to 1 if you want float4 values to be passed by value. (--enable-float4-byval)])
1534                float4passbyval=true],
1535               [float4passbyval=false])
1536 AC_MSG_RESULT([$enable_float4_byval])
1537 AC_DEFINE_UNQUOTED([FLOAT4PASSBYVAL], [$float4passbyval], [float4 values are passed by value if 'true', by reference if 'false'])
1538
1539 # Decide whether float8 is passed by value.
1540 # Note: this setting also controls int8 and related types such as timestamp.
1541 # If sizeof(Datum) >= 8, this is user-selectable, enabled by default.
1542 # If not, trying to select it is an error.
1543 AC_MSG_CHECKING([whether to build with float8 passed by value])
1544 if test $ac_cv_sizeof_unsigned_long -ge 8 ; then
1545   PGAC_ARG_BOOL(enable, float8-byval, yes, [disable float8 passed by value])
1546 else
1547   PGAC_ARG_BOOL(enable, float8-byval, no, [disable float8 passed by value])
1548   if test "$enable_float8_byval" = yes ; then
1549     AC_MSG_ERROR([--enable-float8-byval is not supported on 32-bit platforms.])
1550   fi
1551 fi
1552 if test "$enable_float8_byval" = yes ; then
1553   AC_DEFINE([USE_FLOAT8_BYVAL], 1,
1554             [Define to 1 if you want float8, int8, etc values to be passed by value. (--enable-float8-byval)])
1555   float8passbyval=true
1556 else
1557   float8passbyval=false
1558 fi
1559 AC_MSG_RESULT([$enable_float8_byval])
1560 AC_DEFINE_UNQUOTED([FLOAT8PASSBYVAL], [$float8passbyval], [float8, int8, and related values are passed by value if 'true', by reference if 'false'])
1561
1562 # Determine memory alignment requirements for the basic C data types.
1563
1564 AC_CHECK_ALIGNOF(short)
1565 AC_CHECK_ALIGNOF(int)
1566 AC_CHECK_ALIGNOF(long)
1567 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1568   AC_CHECK_ALIGNOF(long long int)
1569 fi
1570 AC_CHECK_ALIGNOF(double)
1571
1572 # Compute maximum alignment of any basic type.
1573 # We assume long's alignment is at least as strong as char, short, or int;
1574 # but we must check long long (if it exists) and double.
1575
1576 MAX_ALIGNOF=$ac_cv_alignof_long
1577 if test $MAX_ALIGNOF -lt $ac_cv_alignof_double ; then
1578   MAX_ALIGNOF=$ac_cv_alignof_double
1579 fi
1580 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $ac_cv_alignof_long_long_int ; then
1581   MAX_ALIGNOF="$ac_cv_alignof_long_long_int"
1582 fi
1583 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1584
1585
1586 # Some platforms predefine the types int8, int16, etc.  Only check
1587 # a (hopefully) representative subset.
1588 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1589 [#include <stdio.h>
1590 #ifdef HAVE_SUPPORTDEFS_H
1591 #include <SupportDefs.h>
1592 #endif])
1593
1594 # We also check for sig_atomic_t, which *should* be defined per ANSI
1595 # C, but is missing on some old platforms.
1596 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1597
1598
1599 # If the user did not disable integer datetimes, check that
1600 # there is a working 64-bit integral type to use.
1601 if test x"$USE_INTEGER_DATETIMES" = x"yes" &&
1602    test x"$HAVE_LONG_INT_64" = x"no" &&
1603    test x"$HAVE_LONG_LONG_INT_64" = x"no" &&
1604    test x"$HAVE_INT64" = x"no" ; then
1605   AC_MSG_ERROR([
1606 Integer-based datetime support requires a 64-bit integer type,
1607 but no such type could be found. The --disable-integer-datetimes
1608 configure option can be used to disable integer-based storage
1609 of datetime values.])
1610 fi
1611
1612
1613 if test "$PORTNAME" != "win32"
1614 then
1615 PGAC_FUNC_POSIX_SIGNALS
1616 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1617   AC_MSG_ERROR([
1618 Thread-safety requires POSIX signals, which are not supported by this
1619 operating system.])
1620 fi
1621 fi
1622
1623 if test $ac_cv_func_fseeko = yes; then
1624 AC_SYS_LARGEFILE
1625 fi
1626
1627 # Check for largefile support (must be after AC_SYS_LARGEFILE)
1628 AC_CHECK_SIZEOF([off_t])
1629
1630 # If we don't have largefile support, can't handle segsize >= 2GB.
1631 if test "$ac_cv_sizeof_off_t" -lt 8 -a "$segsize" != "1"; then
1632    AC_MSG_ERROR([Large file support is not enabled. Segment size cannot be larger than 1GB.])
1633 fi
1634
1635 # SunOS doesn't handle negative byte comparisons properly with +/- return
1636 AC_FUNC_MEMCMP
1637
1638
1639 # Select semaphore implementation type.
1640 if test "$PORTNAME" != "win32"; then
1641   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1642     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1643     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1644   else
1645     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1646       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1647       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1648     else
1649       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1650       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1651     fi
1652   fi
1653 else
1654   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1655   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1656 fi
1657
1658
1659 # Select shared-memory implementation type.
1660 if test "$PORTNAME" != "win32"; then
1661   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1662   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1663 else
1664   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
1665   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
1666 fi
1667
1668 # If not set in template file, set bytes to use libc memset()
1669 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
1670   MEMSET_LOOP_LIMIT=1024
1671 fi
1672 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
1673
1674
1675 if test "$enable_nls" = yes ; then
1676   PGAC_CHECK_GETTEXT
1677 fi
1678
1679 # Check for Tcl configuration script tclConfig.sh
1680 if test "$with_tcl" = yes; then
1681     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1682     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1683                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1684     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1685     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1686     ac_save_CPPFLAGS=$CPPFLAGS
1687     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1688     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1689     CPPFLAGS=$ac_save_CPPFLAGS
1690 fi
1691
1692 #
1693 # Check for DocBook and tools
1694 #
1695 PGAC_PROG_NSGMLS
1696 PGAC_PROG_JADE
1697 PGAC_CHECK_DOCBOOK(4.2)
1698 PGAC_PATH_DOCBOOK_STYLESHEETS
1699 PGAC_PATH_COLLATEINDEX
1700 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1701 PGAC_PATH_DOCBOOK2MAN
1702
1703 # Thread testing
1704
1705 # We have to run the thread test near the end so we have all our symbols
1706 # defined.  Cross compiling throws a warning.
1707 #
1708 if test "$enable_thread_safety_force" = yes; then
1709 if test "$PORTNAME" != "win32"
1710 then
1711   AC_MSG_WARN([
1712 *** Skipping thread test program.  --enable-thread-safety-force was used.
1713 *** Run the program in src/test/thread on the your machine and add proper
1714 *** locking function calls to your applications to guarantee thread safety.
1715 ])
1716 else
1717 AC_MSG_WARN([*** skipping thread test on Win32])
1718 fi
1719 elif test "$enable_thread_safety" = yes; then
1720 if test "$PORTNAME" != "win32"
1721 then
1722 AC_MSG_CHECKING([thread safety of required library functions])
1723
1724 _CFLAGS="$CFLAGS"
1725 _LIBS="$LIBS"
1726 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1727 LIBS="$LIBS $PTHREAD_LIBS"
1728 AC_TRY_RUN([#include "$srcdir/src/test/thread/thread_test.c"],
1729   [AC_MSG_RESULT(yes)],
1730   [AC_MSG_RESULT(no)
1731   AC_MSG_ERROR([thread test program failed
1732 This platform is not thread-safe.  Check the file 'config.log' for the
1733 exact reason.
1734
1735 You can use the configure option --enable-thread-safety-force to force
1736 threads to be enabled.  But you must then run the program in
1737 src/test/thread and add locking function calls to your applications to
1738 guarantee thread safety.])],
1739   [AC_MSG_RESULT(maybe)
1740   AC_MSG_WARN([
1741 *** Skipping thread test program because of cross-compile build.
1742 *** Run the program in src/test/thread on the target machine.
1743 ])])
1744 CFLAGS="$_CFLAGS"
1745 LIBS="$_LIBS"
1746 else
1747 AC_MSG_WARN([*** skipping thread test on Win32])
1748 fi
1749 fi
1750
1751 # If compiler will take -Wl,--as-needed then add that to LDFLAGS.
1752 # This is much easier than trying to filter LIBS to the minimum for each
1753 # executable.  (Note that shared library links won't use this switch, though.)
1754 # On (at least) some Red-Hat-derived systems, this switch breaks linking to
1755 # libreadline; therefore we postpone testing it until we know what library
1756 # dependencies readline has.  The test code will try to link with $LIBS.
1757 if test "$with_readline" = yes; then
1758   link_test_func=readline
1759 else
1760   link_test_func=exit
1761 fi
1762 if test "$PORTNAME" != "darwin"; then
1763   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,--as-needed], $link_test_func)
1764 else
1765   # On Darwin it's spelled -Wl,-dead_strip_dylibs, but don't try that elsewhere
1766   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-dead_strip_dylibs], $link_test_func)
1767 fi
1768
1769
1770 # Begin output steps
1771
1772 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
1773 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
1774 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
1775
1776 # Create compiler version string
1777 if test x"$GCC" = x"yes" ; then
1778   cc_string="GCC `${CC} --version | sed q`"
1779 elif test x"$SUN_STUDIO_CC" = x"yes" ; then
1780   cc_string=`${CC} -V 2>&1 | sed q`
1781 else
1782   cc_string=$CC
1783 fi
1784
1785 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
1786                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string, `expr $ac_cv_sizeof_void_p \* 8`-bit"],
1787                    [A string containing the version number, platform, and C compiler])
1788
1789 # Supply a numeric version string for use by 3rd party add-ons
1790 # awk -F is a regex on some platforms, and not on others, so make "." a tab
1791 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
1792 tr '.' '        ' |
1793 $AWK '{printf "%d%02d%02d", $1, $2, (NF >= 3) ? $3 : 0}'`"]
1794 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
1795
1796
1797 # prepare build tree if outside source tree
1798 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1799 # Note 2: /bin/pwd might be better than shell's built-in at getting
1800 #         a symlink-free name.
1801 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1802   vpath_build=no
1803 else
1804   vpath_build=yes
1805   if test "$no_create" != yes; then
1806     _AS_ECHO_N([preparing build tree... ])
1807     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1808     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1809       || AC_MSG_ERROR(failed)
1810     AC_MSG_RESULT(done)
1811   fi
1812 fi
1813 AC_SUBST(vpath_build)
1814
1815
1816 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1817
1818 AC_CONFIG_LINKS([
1819   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1820   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1821   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1822   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1823   src/include/pg_config_os.h:src/include/port/${template}.h
1824   src/Makefile.port:src/makefiles/Makefile.${template}
1825 ])
1826
1827 if test "$PORTNAME" = "win32"; then
1828 AC_CONFIG_COMMANDS([check_win32_symlinks],[
1829 # Links sometimes fail undetected on Mingw -
1830 # so here we detect it and warn the user
1831 for FILE in $CONFIG_LINKS
1832  do
1833         # test -e works for symlinks in the MinGW console
1834         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
1835  done
1836 ])
1837 fi
1838
1839 AC_CONFIG_HEADERS([src/include/pg_config.h],
1840 [
1841 # Update timestamp for pg_config.h (see Makefile.global)
1842 echo >src/include/stamp-h
1843 ])
1844
1845 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h],
1846                   [echo >src/interfaces/ecpg/include/stamp-h])
1847
1848 AC_OUTPUT
1849
1850 # Warn about unknown options
1851 PGAC_ARG_CHECK