configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $PostgreSQL: pgsql/configure.in,v 1.581 2009/01/06 15:38:44 tgl Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [8.4devel], [pgsql-bugs@postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.61], [], [m4_fatal([Autoconf version 2.61 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2009, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version as a string])
  33 [PG_MAJORVERSION=`expr "$PACKAGE_VERSION" : '\([0-9][0-9]*\.[0-9][0-9]*\)'`]
  34 AC_SUBST(PG_MAJORVERSION)
  35 AC_DEFINE_UNQUOTED(PG_MAJORVERSION, "$PG_MAJORVERSION", [PostgreSQL major version as a string])
  36
  37 AC_CANONICAL_HOST
  38
  39 template=
  40 AC_MSG_CHECKING([which template to use])
  41
  42 PGAC_ARG_REQ(with, template, [NAME], [override operating system template],
  43 [
  44   case $withval in
  45     list)   echo; ls "$srcdir/src/template"; exit;;
  46     *)      if test -f "$srcdir/src/template/$with_template" ; then
  47               template=$withval
  48             else
  49               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  50             fi;;
  51   esac
  52 ],
  53 [
  54 # --with-template not given
  55
  56 case $host_os in
  57      aix*) template=aix ;;
  58     bsdi*) template=bsdi ;;
  59   cygwin*) template=cygwin ;;
  60   darwin*) template=darwin ;;
  61     dgux*) template=dgux ;;
  62  freebsd*) template=freebsd ;;
  63     hpux*) template=hpux ;;
  64     irix*) template=irix ;;
  65  linux*|gnu*|k*bsd*-gnu)
  66            template=linux ;;
  67    mingw*) template=win32 ;;
  68   netbsd*) template=netbsd ;;
  69 nextstep*) template=nextstep ;;
  70  openbsd*) template=openbsd ;;
  71      osf*) template=osf ;;
  72      sco*) template=sco ;;
  73  solaris*) template=solaris ;;
  74    sunos*) template=sunos4 ;;
  75  sysv4.2*)
  76         case $host_vendor in
  77           univel) template=univel ;;
  78         esac ;;
  79    sysv4*) template=svr4 ;;
  80    sysv5*) template=unixware ;;
  81   ultrix*) template=ultrix4 ;;
  82 esac
  83
  84   if test x"$template" = x"" ; then
  85     AC_MSG_ERROR([[
  86 *******************************************************************
  87 PostgreSQL has apparently not been ported to your platform yet.
  88 To try a manual configuration, look into the src/template directory
  89 for a similar platform and use the '--with-template=' option.
  90
  91 Please also contact <pgsql-ports@postgresql.org> to see about
  92 rectifying this.  Include the above 'checking host system type...'
  93 line.
  94 *******************************************************************
  95 ]])
  96   fi
  97
  98 ])
  99
 100 AC_MSG_RESULT([$template])
 101
 102 PORTNAME=$template
 103 AC_SUBST(PORTNAME)
 104
 105 # Initialize default assumption that we do not need separate assembly code
 106 # for TAS (test-and-set).  This can be overridden by the template file
 107 # when it's executed.
 108 need_tas=no
 109 tas_file=dummy.s
 110
 111
 112
 113 ##
 114 ## Command line options
 115 ##
 116
 117 #
 118 # Add non-standard directories to the include path
 119 #
 120 PGAC_ARG_REQ(with, includes, [DIRS], [look for additional header files in DIRS])
 121
 122
 123 #
 124 # Add non-standard directories to the library search path
 125 #
 126 PGAC_ARG_REQ(with, libraries, [DIRS], [look for additional libraries in DIRS],
 127              [LIBRARY_DIRS=$withval])
 128
 129 PGAC_ARG_REQ(with, libs,      [DIRS], [alternative spelling of --with-libraries],
 130              [LIBRARY_DIRS=$withval])
 131
 132
 133 #
 134 # 64-bit integer date/time storage: enabled by default.
 135 #
 136 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 137 PGAC_ARG_BOOL(enable, integer-datetimes, yes, [disable 64-bit integer date/time support],
 138               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 139                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 140 AC_MSG_RESULT([$enable_integer_datetimes])
 141
 142
 143 #
 144 # NLS
 145 #
 146 AC_MSG_CHECKING([whether NLS is wanted])
 147 PGAC_ARG_OPTARG(enable, nls,
 148                 [LANGUAGES], [enable Native Language Support],
 149                 [],
 150                 [WANTED_LANGUAGES=$enableval],
 151                 [AC_DEFINE(ENABLE_NLS, 1,
 152                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 153 AC_MSG_RESULT([$enable_nls])
 154 AC_SUBST(enable_nls)
 155 AC_SUBST(WANTED_LANGUAGES)
 156
 157 #
 158 # Default port number (--with-pgport), default 5432
 159 #
 160 AC_MSG_CHECKING([for default port number])
 161 PGAC_ARG_REQ(with, pgport, [PORTNUM], [set default port number [5432]],
 162              [default_port=$withval],
 163              [default_port=5432])
 164 AC_MSG_RESULT([$default_port])
 165 # Need both of these because some places want an integer and some a string
 166 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 167 [Define to the default TCP port number on which the server listens and
 168 to which clients will try to connect.  This can be overridden at run-time,
 169 but it's convenient if your clients have the right default compiled in.
 170 (--with-pgport=PORTNUM)])
 171 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 172                    [Define to the default TCP port number as a string constant.])
 173 AC_SUBST(default_port)
 174
 175 #
 176 # Option to disable shared libraries
 177 #
 178 PGAC_ARG_BOOL(enable, shared, yes,
 179               [do not build shared libraries])
 180 AC_SUBST(enable_shared)
 181
 182 #
 183 # '-rpath'-like feature can be disabled
 184 #
 185 PGAC_ARG_BOOL(enable, rpath, yes,
 186               [do not embed shared library search path in executables])
 187 AC_SUBST(enable_rpath)
 188
 189 #
 190 # Spinlocks
 191 #
 192 PGAC_ARG_BOOL(enable, spinlocks, yes,
 193               [do not use spinlocks])
 194
 195 #
 196 # --enable-debug adds -g to compiler flags
 197 #
 198 PGAC_ARG_BOOL(enable, debug, no,
 199               [build with debugging symbols (-g)])
 200 AC_SUBST(enable_debug)
 201
 202 #
 203 # --enable-profiling enables gcc profiling
 204 #
 205 PGAC_ARG_BOOL(enable, profiling, no,
 206               [build with profiling enabled ])
 207 AC_SUBST(enable_profiling)
 208
 209 #
 210 # --enable-coverage enables generation of code coverage metrics with gcov
 211 #
 212 PGAC_ARG_BOOL(enable, coverage, no,
 213               [build with coverage testing instrumentation],
 214 [AC_CHECK_PROGS(GCOV, gcov)
 215 if test -z "$GCOV"; then
 216   AC_MSG_ERROR([gcov not found])
 217 fi
 218 AC_CHECK_PROGS(LCOV, lcov)
 219 if test -z "$LCOV"; then
 220   AC_MSG_ERROR([lcov not found])
 221 fi
 222 AC_CHECK_PROGS(GENHTML, genhtml)
 223 if test -z "$GENHTML"; then
 224   AC_MSG_ERROR([genhtml not found])
 225 fi])
 226 AC_SUBST(enable_coverage)
 227
 228 #
 229 # DTrace
 230 #
 231 PGAC_ARG_BOOL(enable, dtrace, no,
 232               [build with DTrace support],
 233 [AC_DEFINE([ENABLE_DTRACE], 1,
 234            [Define to 1 to enable DTrace support. (--enable-dtrace)])
 235 AC_CHECK_PROGS(DTRACE, dtrace)
 236 if test -z "$DTRACE"; then
 237   AC_MSG_ERROR([dtrace not found])
 238 fi
 239 AC_SUBST(DTRACEFLAGS)])
 240 AC_SUBST(enable_dtrace)
 241
 242 #
 243 # Block size
 244 #
 245 AC_MSG_CHECKING([for block size])
 246 PGAC_ARG_REQ(with, blocksize, [BLOCKSIZE], [set table block size in kB [8]],
 247              [blocksize=$withval],
 248              [blocksize=8])
 249 case ${blocksize} in
 250   1) BLCKSZ=1024;;
 251   2) BLCKSZ=2048;;
 252   4) BLCKSZ=4096;;
 253   8) BLCKSZ=8192;;
 254  16) BLCKSZ=16384;;
 255  32) BLCKSZ=32768;;
 256   *) AC_MSG_ERROR([Invalid block size. Allowed values are 1,2,4,8,16,32.])
 257 esac
 258 AC_MSG_RESULT([${blocksize}kB])
 259
 260 AC_DEFINE_UNQUOTED([BLCKSZ], ${BLCKSZ}, [
 261  Size of a disk block --- this also limits the size of a tuple.  You
 262  can set it bigger if you need bigger tuples (although TOAST should
 263  reduce the need to have large tuples, since fields can be spread
 264  across multiple tuples).
 265
 266  BLCKSZ must be a power of 2.  The maximum possible value of BLCKSZ
 267  is currently 2^15 (32768).  This is determined by the 15-bit widths
 268  of the lp_off and lp_len fields in ItemIdData (see
 269  include/storage/itemid.h).
 270
 271  Changing BLCKSZ requires an initdb.
 272 ])
 273
 274 #
 275 # Relation segment size
 276 #
 277 AC_MSG_CHECKING([for segment size])
 278 PGAC_ARG_REQ(with, segsize, [SEGSIZE], [set table segment size in GB [1]],
 279              [segsize=$withval],
 280              [segsize=1])
 281 # this expression is set up to avoid unnecessary integer overflow
 282 # blocksize is already guaranteed to be a factor of 1024
 283 RELSEG_SIZE=`expr '(' 1024 / ${blocksize} ')' '*' ${segsize} '*' 1024`
 284 test $? -eq 0 || exit 1
 285 AC_MSG_RESULT([${segsize}GB])
 286
 287 AC_DEFINE_UNQUOTED([RELSEG_SIZE], ${RELSEG_SIZE}, [
 288  RELSEG_SIZE is the maximum number of blocks allowed in one disk file.
 289  Thus, the maximum size of a single file is RELSEG_SIZE * BLCKSZ;
 290  relations bigger than that are divided into multiple files.
 291
 292  RELSEG_SIZE * BLCKSZ must be less than your OS' limit on file size.
 293  This is often 2 GB or 4GB in a 32-bit operating system, unless you
 294  have large file support enabled.  By default, we make the limit 1 GB
 295  to avoid any possible integer-overflow problems within the OS.
 296  A limit smaller than necessary only means we divide a large
 297  relation into more chunks than necessary, so it seems best to err
 298  in the direction of a small limit.
 299
 300  A power-of-2 value is recommended to save a few cycles in md.c,
 301  but is not absolutely required.
 302
 303  Changing RELSEG_SIZE requires an initdb.
 304 ])
 305
 306 #
 307 # WAL block size
 308 #
 309 AC_MSG_CHECKING([for WAL block size])
 310 PGAC_ARG_REQ(with, wal-blocksize, [BLOCKSIZE], [set WAL block size in kB [8]],
 311              [wal_blocksize=$withval],
 312              [wal_blocksize=8])
 313 case ${wal_blocksize} in
 314   1) XLOG_BLCKSZ=1024;;
 315   2) XLOG_BLCKSZ=2048;;
 316   4) XLOG_BLCKSZ=4096;;
 317   8) XLOG_BLCKSZ=8192;;
 318  16) XLOG_BLCKSZ=16384;;
 319  32) XLOG_BLCKSZ=32768;;
 320  64) XLOG_BLCKSZ=65536;;
 321   *) AC_MSG_ERROR([Invalid WAL block size. Allowed values are 1,2,4,8,16,32,64.])
 322 esac
 323 AC_MSG_RESULT([${wal_blocksize}kB])
 324
 325 AC_DEFINE_UNQUOTED([XLOG_BLCKSZ], ${XLOG_BLCKSZ}, [
 326  Size of a WAL file block.  This need have no particular relation to BLCKSZ.
 327  XLOG_BLCKSZ must be a power of 2, and if your system supports O_DIRECT I/O,
 328  XLOG_BLCKSZ must be a multiple of the alignment requirement for direct-I/O
 329  buffers, else direct I/O may fail.
 330
 331  Changing XLOG_BLCKSZ requires an initdb.
 332 ])
 333
 334 #
 335 # WAL segment size
 336 #
 337 AC_MSG_CHECKING([for WAL segment size])
 338 PGAC_ARG_REQ(with, wal-segsize, [SEGSIZE], [set WAL segment size in MB [16]],
 339              [wal_segsize=$withval],
 340              [wal_segsize=16])
 341 case ${wal_segsize} in
 342   1) ;;
 343   2) ;;
 344   4) ;;
 345   8) ;;
 346  16) ;;
 347  32) ;;
 348  64) ;;
 349   *) AC_MSG_ERROR([Invalid WAL segment size. Allowed values are 1,2,4,8,16,32,64.])
 350 esac
 351 AC_MSG_RESULT([${wal_segsize}MB])
 352
 353 AC_DEFINE_UNQUOTED([XLOG_SEG_SIZE], [(${wal_segsize} * 1024 * 1024)], [
 354  XLOG_SEG_SIZE is the size of a single WAL file.  This must be a power of 2
 355  and larger than XLOG_BLCKSZ (preferably, a great deal larger than
 356  XLOG_BLCKSZ).
 357
 358  Changing XLOG_SEG_SIZE requires an initdb.
 359 ])
 360
 361 #
 362 # C compiler
 363 #
 364
 365 # For historical reasons you can also use --with-CC to specify the C compiler
 366 # to use, although the standard way to do this is to set the CC environment
 367 # variable.
 368 PGAC_ARG_REQ(with, CC, [CMD], [set compiler (deprecated)], [CC=$with_CC])
 369
 370 case $template in
 371   aix) pgac_cc_list="gcc xlc";;
 372  irix) pgac_cc_list="cc";; # no gcc
 373     *) pgac_cc_list="gcc cc";;
 374 esac
 375
 376 AC_PROG_CC([$pgac_cc_list])
 377
 378 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 379 # but has idiosyncrasies of its own.  We assume icc will define
 380 # __INTEL_COMPILER regardless of CFLAGS.
 381 AC_TRY_COMPILE([], [@%:@ifndef __INTEL_COMPILER
 382 choke me
 383 @%:@endif], [ICC=[yes]], [ICC=[no]])
 384
 385 # Check if it's Sun Studio compiler. We assume that
 386 # __SUNPRO_C will be defined for Sun Studio compilers
 387 AC_TRY_COMPILE([], [@%:@ifndef __SUNPRO_C
 388 choke me
 389 @%:@endif], [SUN_STUDIO_CC=yes], [SUN_STUDIO_CC=no])
 390
 391 AC_SUBST(SUN_STUDIO_CC)
 392
 393 unset CFLAGS
 394
 395 #
 396 # Read the template
 397 #
 398 . "$srcdir/src/template/$template" || exit
 399
 400 # CFLAGS are selected so:
 401 # If the user specifies something in the environment, that is used.
 402 # else:  If the template file set something, that is used.
 403 # else:  If coverage was enabled, don't set anything.
 404 # else:  If the compiler is GCC, then we use -O2.
 405 # else:  If the compiler is something else, then we use -O.
 406
 407 if test "$ac_env_CFLAGS_set" = set; then
 408   CFLAGS=$ac_env_CFLAGS_value
 409 elif test "${CFLAGS+set}" = set; then
 410   : # (keep what template set)
 411 elif test "$enable_coverage" = yes; then
 412   : # no optimization by default
 413 elif test "$GCC" = yes; then
 414   CFLAGS="-O2"
 415 else
 416   # if the user selected debug mode, don't use -O
 417   if test "$enable_debug" != yes; then
 418     CFLAGS="-O"
 419   fi
 420 fi
 421
 422 # Some versions of GCC support some additional useful warning flags.
 423 # Check whether they are supported, and add them to CFLAGS if so.
 424 # ICC pretends to be GCC but it's lying; it doesn't support these options.
 425
 426 if test "$GCC" = yes -a "$ICC" = no; then
 427   CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wpointer-arith"
 428   # These work in some but not all gcc versions
 429   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 430   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 431   # Disable strict-aliasing rules; needed for gcc 3.3+
 432   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 433   # Disable optimizations that assume no overflow; needed for gcc 4.3+
 434   PGAC_PROG_CC_CFLAGS_OPT([-fwrapv])
 435 elif test "$ICC" = yes; then
 436   # Intel's compiler has a bug/misoptimization in checking for
 437   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 438   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 439   # Make sure strict aliasing is off (though this is said to be the default)
 440   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 441 elif test x"${CC}" = x"xlc"; then
 442   # AIX xlc has to have strict aliasing turned off too
 443   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 444 fi
 445
 446 # supply -g if --enable-debug
 447 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 448   CFLAGS="$CFLAGS -g"
 449 fi
 450
 451 # enable code coverage if --enable-coverage
 452 if test "$enable_coverage" = yes; then
 453   if test "$GCC" = yes; then
 454     CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 455   else
 456     AC_MSG_ERROR([--enable-coverage is supported only when using GCC])
 457   fi
 458 fi
 459
 460 # enable profiling if --enable-profiling
 461 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 462   if test "$GCC" = yes; then
 463     AC_DEFINE([PROFILE_PID_DIR], 1,
 464            [Define to 1 to allow profiling output to be saved separately for each process.])
 465     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 466   else
 467     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 468   fi
 469 fi
 470
 471 # We already have this in Makefile.win32, but configure needs it too
 472 if test "$PORTNAME" = "win32"; then
 473   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 474 fi
 475
 476 # Check if the compiler still works with the template settings
 477 AC_MSG_CHECKING([whether the C compiler still works])
 478 AC_TRY_LINK([], [return 0;],
 479   [AC_MSG_RESULT(yes)],
 480   [AC_MSG_RESULT(no)
 481    AC_MSG_ERROR([cannot proceed])])
 482
 483 # Defend against gcc -ffast-math
 484 if test "$GCC" = yes; then
 485 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 486 choke me
 487 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 488 fi
 489
 490 AC_PROG_CPP
 491 AC_SUBST(GCC)
 492
 493
 494 #
 495 # Set up TAS assembly code if needed; the template file has now had its
 496 # chance to request this.
 497 #
 498 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 499
 500 if test "$need_tas" = yes ; then
 501   TAS=tas.o
 502 else
 503   TAS=""
 504 fi
 505 AC_SUBST(TAS)
 506
 507
 508 #
 509 # Automatic dependency tracking
 510 #
 511 PGAC_ARG_BOOL(enable, depend, no, [turn on automatic dependency tracking],
 512               [autodepend=yes])
 513 AC_SUBST(autodepend)
 514
 515
 516 #
 517 # Enable assert checks
 518 #
 519 PGAC_ARG_BOOL(enable, cassert, no, [enable assertion checks (for debugging)],
 520               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 521                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 522
 523
 524 #
 525 # Include directories
 526 #
 527 ac_save_IFS=$IFS
 528 IFS="${IFS}${PATH_SEPARATOR}"
 529 # SRCH_INC comes from the template file
 530 for dir in $with_includes $SRCH_INC; do
 531   if test -d "$dir"; then
 532     INCLUDES="$INCLUDES -I$dir"
 533   else
 534     AC_MSG_WARN([*** Include directory $dir does not exist.])
 535   fi
 536 done
 537 IFS=$ac_save_IFS
 538 AC_SUBST(INCLUDES)
 539
 540
 541 #
 542 # Library directories
 543 #
 544 ac_save_IFS=$IFS
 545 IFS="${IFS}${PATH_SEPARATOR}"
 546 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 547 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 548   if test -d "$dir"; then
 549     LIBDIRS="$LIBDIRS -L$dir"
 550   else
 551     AC_MSG_WARN([*** Library directory $dir does not exist.])
 552   fi
 553 done
 554 IFS=$ac_save_IFS
 555
 556 #
 557 # Enable thread-safe client libraries
 558 #
 559 AC_MSG_CHECKING([allow thread-safe client libraries])
 560 if test "$PORTNAME" != "win32"; then
 561 PGAC_ARG_BOOL(enable, thread-safety, no, [make client libraries thread-safe])
 562 else
 563 # Win32 should always use threads
 564 PGAC_ARG_BOOL(enable, thread-safety, yes, [make client libraries thread-safe])
 565 fi
 566
 567 PGAC_ARG_BOOL(enable, thread-safety-force, no, [force thread-safety despite thread test failure])
 568 if test "$enable_thread_safety" = yes -o \
 569         "$enable_thread_safety_force" = yes; then
 570   enable_thread_safety="yes"    # for 'force'
 571   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 572           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 573 fi
 574 AC_MSG_RESULT([$enable_thread_safety])
 575 AC_SUBST(enable_thread_safety)
 576
 577 #
 578 # Optionally build Tcl modules (PL/Tcl)
 579 #
 580 AC_MSG_CHECKING([whether to build with Tcl])
 581 PGAC_ARG_BOOL(with, tcl, no, [build Tcl modules (PL/Tcl)])
 582 AC_MSG_RESULT([$with_tcl])
 583 AC_SUBST([with_tcl])
 584
 585 # We see if the path to the Tcl/Tk configuration scripts is specified.
 586 # This will override the use of tclsh to find the paths to search.
 587
 588 PGAC_ARG_REQ(with, tclconfig, [DIR], [tclConfig.sh is in DIR])
 589
 590 #
 591 # Optionally build Perl modules (PL/Perl)
 592 #
 593 AC_MSG_CHECKING([whether to build Perl modules])
 594 PGAC_ARG_BOOL(with, perl, no, [build Perl modules (PL/Perl)])
 595 AC_MSG_RESULT([$with_perl])
 596 AC_SUBST(with_perl)
 597
 598 #
 599 # Optionally build Python modules (PL/Python)
 600 #
 601 AC_MSG_CHECKING([whether to build Python modules])
 602 PGAC_ARG_BOOL(with, python, no, [build Python modules (PL/Python)])
 603 AC_MSG_RESULT([$with_python])
 604 AC_SUBST(with_python)
 605
 606 #
 607 # GSSAPI
 608 #
 609 AC_MSG_CHECKING([whether to build with GSSAPI support])
 610 PGAC_ARG_BOOL(with, gssapi, no, [build with GSSAPI support],
 611 [
 612   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 613   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 614 ])
 615 AC_MSG_RESULT([$with_gssapi])
 616 AC_SUBST(with_gssapi)
 617
 618 #
 619 # Kerberos 5
 620 #
 621 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 622 PGAC_ARG_BOOL(with, krb5, no, [build with Kerberos 5 support],
 623 [
 624   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 625   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 626 ])
 627 AC_MSG_RESULT([$with_krb5])
 628 AC_SUBST(with_krb5)
 629
 630
 631 AC_SUBST(krb_srvtab)
 632
 633
 634 #
 635 # Kerberos configuration parameters
 636 #
 637 PGAC_ARG_REQ(with, krb-srvnam,
 638              [NAME], [default service principal name in Kerberos [postgres]],
 639              [],
 640              [with_krb_srvnam="postgres"])
 641 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 642                    [Define to the name of the default PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 643
 644
 645 #
 646 # PAM
 647 #
 648 AC_MSG_CHECKING([whether to build with PAM support])
 649 PGAC_ARG_BOOL(with, pam, no,
 650               [build with PAM support],
 651               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 652 AC_MSG_RESULT([$with_pam])
 653 AC_SUBST(with_pam)
 654
 655
 656 #
 657 # LDAP
 658 #
 659 AC_MSG_CHECKING([whether to build with LDAP support])
 660 PGAC_ARG_BOOL(with, ldap, no,
 661               [build with LDAP support],
 662               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 663 AC_MSG_RESULT([$with_ldap])
 664 AC_SUBST(with_ldap)
 665
 666
 667 #
 668 # Bonjour
 669 #
 670 AC_MSG_CHECKING([whether to build with Bonjour support])
 671 PGAC_ARG_BOOL(with, bonjour, no,
 672               [build with Bonjour support],
 673               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 674 AC_MSG_RESULT([$with_bonjour])
 675 AC_SUBST(with_bonjour)
 676
 677
 678 #
 679 # OpenSSL
 680 #
 681 AC_MSG_CHECKING([whether to build with OpenSSL support])
 682 PGAC_ARG_BOOL(with, openssl, no, [build with OpenSSL support],
 683               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 684 AC_MSG_RESULT([$with_openssl])
 685 AC_SUBST(with_openssl)
 686
 687
 688 #
 689 # Readline
 690 #
 691 PGAC_ARG_BOOL(with, readline, yes,
 692               [do not use GNU Readline nor BSD Libedit for editing])
 693 # readline on MinGW has problems with backslashes in psql and other bugs.
 694 # This is particularly a problem with non-US code pages.
 695 # Therefore disable its use until we understand the cause. 2004-07-20
 696 if test "$PORTNAME" = "win32"; then
 697   if test "$with_readline" = yes; then
 698     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 699     with_readline=no
 700   fi
 701 fi
 702
 703
 704 #
 705 # Prefer libedit
 706 #
 707 PGAC_ARG_BOOL(with, libedit-preferred, no,
 708               [prefer BSD Libedit over GNU Readline])
 709
 710
 711 #
 712 # OSSP UUID library
 713 #
 714 PGAC_ARG_BOOL(with, ossp-uuid, no, [use OSSP UUID library when building contrib/uuid-ossp])
 715 AC_SUBST(with_ossp_uuid)
 716
 717
 718 #
 719 # XML
 720 #
 721 PGAC_ARG_BOOL(with, libxml, no, [build with XML support],
 722               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 723
 724 if test "$with_libxml" = yes ; then
 725   AC_CHECK_PROGS(XML2_CONFIG, xml2-config)
 726   if test -n "$XML2_CONFIG"; then
 727     for pgac_option in `$XML2_CONFIG --cflags`; do
 728       case $pgac_option in
 729         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 730       esac
 731     done
 732     for pgac_option in `$XML2_CONFIG --libs`; do
 733       case $pgac_option in
 734         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 735       esac
 736     done
 737   fi
 738 fi
 739
 740 AC_SUBST(with_libxml)
 741
 742 #
 743 # XSLT
 744 #
 745 PGAC_ARG_BOOL(with, libxslt, no, [use XSLT support when building contrib/xml2],
 746               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 747
 748
 749 AC_SUBST(with_libxslt)
 750
 751 #
 752 # tzdata
 753 #
 754 PGAC_ARG_REQ(with, system-tzdata,
 755              [DIR], [use system time zone data in DIR])
 756 AC_SUBST(with_system_tzdata)
 757
 758 #
 759 # Zlib
 760 #
 761 PGAC_ARG_BOOL(with, zlib, yes,
 762               [do not use Zlib])
 763 AC_SUBST(with_zlib)
 764
 765 #
 766 # Elf
 767 #
 768
 769 # Assume system is ELF if it predefines __ELF__ as 1,
 770 # otherwise believe host_os based default.
 771 case $host_os in
 772     freebsd1*|freebsd2*) elf=no;;
 773     freebsd3*|freebsd4*) elf=yes;;
 774 esac
 775
 776 AC_EGREP_CPP(yes,
 777 [#if __ELF__
 778   yes
 779 #endif
 780 ],
 781 [ELF_SYS=true],
 782 [if test "X$elf" = "Xyes" ; then
 783   ELF_SYS=true
 784 else
 785   ELF_SYS=
 786 fi])
 787 AC_SUBST(ELF_SYS)
 788
 789 #
 790 # Assignments
 791 #
 792
 793 CPPFLAGS="$CPPFLAGS $INCLUDES"
 794 LDFLAGS="$LDFLAGS $LIBDIRS"
 795
 796 AC_ARG_VAR(LDFLAGS_SL)
 797
 798 PGAC_PROG_LD
 799 AC_SUBST(LD)
 800 AC_SUBST(with_gnu_ld)
 801 case $host_os in sysv5*)
 802   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 803   [
 804     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 805     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 806     LDFLAGS=$pgac_save_LDFLAGS
 807   ])
 808   ld_R_works=$pgac_cv_prog_ld_R
 809   AC_SUBST(ld_R_works)
 810 esac
 811 AC_PROG_RANLIB
 812 PGAC_CHECK_STRIP
 813 AC_CHECK_TOOL(AR, ar, ar)
 814 if test "$PORTNAME" = "win32"; then
 815   AC_CHECK_TOOL(DLLTOOL, dlltool, dlltool)
 816   AC_CHECK_TOOL(DLLWRAP, dllwrap, dllwrap)
 817   AC_CHECK_TOOL(WINDRES, windres, windres)
 818 fi
 819
 820 AC_PATH_PROG(TAR, tar)
 821 AC_PROG_LN_S
 822 AC_PROG_AWK
 823
 824 PGAC_PATH_BISON
 825 PGAC_PATH_FLEX
 826
 827 PGAC_PATH_PERL
 828 if test "$with_perl" = yes; then
 829   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 830   PGAC_CHECK_PERL_EMBED_LDFLAGS
 831 fi
 832
 833 if test "$with_python" = yes; then
 834   PGAC_PATH_PYTHON
 835   PGAC_CHECK_PYTHON_EMBED_SETUP
 836 fi
 837
 838 if test "$cross_compiling" = yes && test -z "$with_system_tzdata"; then
 839   AC_PATH_PROG(ZIC, zic)
 840   if test -z "$ZIC"; then
 841     AC_MSG_ERROR([
 842 When cross-compiling, either use the option --with-system-tzdata to use
 843 existing time-zone data, or set the environment variable ZIC to a zic
 844 program to use during the build.])
 845   fi
 846 fi
 847
 848
 849 ##
 850 ## Libraries
 851 ##
 852 ## Most libraries are included only if they demonstrably provide a function
 853 ## we need, but libm is an exception: always include it, because there are
 854 ## too many compilers that play cute optimization games that will break
 855 ## probes for standard functions such as pow().
 856 ##
 857
 858 AC_CHECK_LIB(m, main)
 859 AC_SEARCH_LIBS(setproctitle, util)
 860 AC_SEARCH_LIBS(dlopen, dl)
 861 AC_SEARCH_LIBS(socket, [socket wsock32])
 862 AC_SEARCH_LIBS(shl_load, dld)
 863 # We only use libld in port/dynloader/aix.c
 864 case $host_os in
 865      aix*)
 866         AC_SEARCH_LIBS(ldopen, ld)
 867         ;;
 868 esac
 869 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 870 AC_SEARCH_LIBS(crypt, crypt)
 871 # Solaris:
 872 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 873 # Cygwin:
 874 AC_SEARCH_LIBS(shmget, cygipc)
 875
 876 if test "$with_readline" = yes; then
 877   PGAC_CHECK_READLINE
 878   if test x"$pgac_cv_check_readline" = x"no"; then
 879     AC_MSG_ERROR([readline library not found
 880 If you have readline already installed, see config.log for details on the
 881 failure.  It is possible the compiler isn't looking in the proper directory.
 882 Use --without-readline to disable readline support.])
 883   fi
 884 fi
 885
 886 if test "$with_zlib" = yes; then
 887   AC_CHECK_LIB(z, inflate, [],
 888                [AC_MSG_ERROR([zlib library not found
 889 If you have zlib already installed, see config.log for details on the
 890 failure.  It is possible the compiler isn't looking in the proper directory.
 891 Use --without-zlib to disable zlib support.])])
 892 fi
 893
 894 if test "$enable_spinlocks" = yes; then
 895   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 896 else
 897   AC_MSG_WARN([
 898 *** Not using spinlocks will cause poor performance.])
 899 fi
 900
 901 if test "$with_gssapi" = yes ; then
 902   if test "$PORTNAME" != "win32"; then
 903     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
 904                                   [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
 905   else
 906     LIBS="$LIBS -lgssapi32"
 907   fi
 908 fi
 909
 910 if test "$with_krb5" = yes ; then
 911   if test "$PORTNAME" != "win32"; then
 912      AC_SEARCH_LIBS(com_err, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken' com_err], [],
 913                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 914      AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken'], [],
 915                     [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 916   else
 917      AC_SEARCH_LIBS(com_err, 'comerr32 -lkrb5_32', [],
 918                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 919   fi
 920 fi
 921
 922 if test "$with_openssl" = yes ; then
 923   dnl Order matters!
 924   if test "$PORTNAME" != "win32"; then
 925      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 926      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 927   else
 928      AC_CHECK_LIB(eay32, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'eay32' is required for OpenSSL])])
 929      AC_CHECK_LIB(ssleay32,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssleay32' is required for OpenSSL])])
 930   fi
 931 fi
 932
 933 if test "$with_pam" = yes ; then
 934   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 935 fi
 936
 937 if test "$with_libxml" = yes ; then
 938   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
 939 fi
 940
 941 if test "$with_libxslt" = yes ; then
 942   AC_CHECK_LIB(xslt, xsltCleanupGlobals, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
 943 fi
 944
 945 # for contrib/uuid-ossp
 946 if test "$with_ossp_uuid" = yes ; then
 947   AC_CHECK_LIB(ossp-uuid, uuid_export,
 948     [OSSP_UUID_LIBS="-lossp-uuid"],
 949     [AC_CHECK_LIB(uuid, uuid_export,
 950       [OSSP_UUID_LIBS="-luuid"],
 951       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP-UUID])])])
 952 fi
 953 AC_SUBST(OSSP_UUID_LIBS)
 954
 955
 956 ##
 957 ## Header files
 958 ##
 959
 960 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 961 AC_CHECK_HEADERS([crypt.h dld.h fp_class.h getopt.h ieeefp.h langinfo.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/tas.h sys/time.h sys/un.h termios.h ucred.h utime.h wchar.h wctype.h kernel/OS.h kernel/image.h SupportDefs.h])
 962
 963 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 964 # netinet/in.h is included first.
 965 AC_CHECK_HEADERS(netinet/in.h)
 966 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 967 [AC_INCLUDES_DEFAULT
 968 #ifdef HAVE_NETINET_IN_H
 969 #include <netinet/in.h>
 970 #endif
 971 ])
 972
 973 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
 974   AC_CHECK_HEADERS(readline/readline.h, [],
 975         [AC_CHECK_HEADERS(readline.h, [],
 976                 [AC_MSG_ERROR([readline header not found
 977 If you have readline already installed, see config.log for details on the
 978 failure.  It is possible the compiler isn't looking in the proper directory.
 979 Use --without-readline to disable readline support.])])])
 980   AC_CHECK_HEADERS(readline/history.h, [],
 981         [AC_CHECK_HEADERS(history.h, [],
 982                 [AC_MSG_ERROR([history header not found
 983 If you have readline already installed, see config.log for details on the
 984 failure.  It is possible the compiler isn't looking in the proper directory.
 985 Use --without-readline to disable readline support.])])])
 986 fi
 987
 988 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
 989 # Some installations of libedit usurp /usr/include/readline/, which seems
 990 # bad practice, since in combined installations readline will have its headers
 991 # there.  We might have to resort to AC_EGREP checks to make sure we found
 992 # the proper header...
 993   AC_CHECK_HEADERS(editline/readline.h, [],
 994         [AC_CHECK_HEADERS(readline.h, [],
 995                 [AC_CHECK_HEADERS(readline/readline.h, [],
 996                         [AC_MSG_ERROR([readline header not found
 997 If you have libedit already installed, see config.log for details on the
 998 failure.  It is possible the compiler isn't looking in the proper directory.
 999 Use --without-readline to disable libedit support.])])])])
1000 # Note: in a libedit installation, history.h is sometimes a dummy, and may
1001 # not be there at all.  Hence, don't complain if not found.  We must check
1002 # though, since in yet other versions it is an independent header.
1003   AC_CHECK_HEADERS(editline/history.h, [],
1004         [AC_CHECK_HEADERS(history.h, [],
1005                 [AC_CHECK_HEADERS(readline/history.h)])])
1006 fi
1007
1008 if test "$with_zlib" = yes; then
1009   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
1010 If you have zlib already installed, see config.log for details on the
1011 failure.  It is possible the compiler isn't looking in the proper directory.
1012 Use --without-zlib to disable zlib support.])])
1013 fi
1014
1015 if test "$with_gssapi" = yes ; then
1016   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
1017         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
1018 fi
1019
1020 if test "$with_krb5" = yes ; then
1021   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
1022 fi
1023
1024 if test "$with_openssl" = yes ; then
1025   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
1026   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
1027   AC_CHECK_FUNCS([ERR_set_mark])
1028 fi
1029
1030 if test "$with_pam" = yes ; then
1031   AC_CHECK_HEADERS(security/pam_appl.h, [],
1032                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
1033                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
1034 fi
1035
1036 if test "$with_libxml" = yes ; then
1037   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
1038 fi
1039
1040 if test "$with_libxslt" = yes ; then
1041   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
1042 fi
1043
1044 if test "$with_ldap" = yes ; then
1045   if test "$PORTNAME" != "win32"; then
1046      AC_CHECK_HEADERS(ldap.h, [],
1047                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
1048   else
1049      AC_CHECK_HEADERS(winldap.h, [],
1050                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
1051                       [AC_INCLUDES_DEFAULT
1052 #include <windows.h>
1053                       ])
1054   fi
1055 fi
1056
1057 if test "$with_bonjour" = yes ; then
1058   AC_CHECK_HEADER(DNSServiceDiscovery/DNSServiceDiscovery.h, [], [AC_MSG_ERROR([header file <DNSServiceDiscovery/DNSServiceDiscovery.h> is required for Bonjour])])
1059 fi
1060
1061 # for contrib/uuid-ossp
1062 if test "$with_ossp_uuid" = yes ; then
1063   AC_CHECK_HEADERS(ossp/uuid.h, [], [
1064     AC_CHECK_HEADERS(uuid.h, [],
1065       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP-UUID])])])
1066 fi
1067
1068
1069 ##
1070 ## Types, structures, compiler characteristics
1071 ##
1072
1073 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
1074 AC_C_BIGENDIAN
1075 AC_C_CONST
1076 AC_C_INLINE
1077 AC_C_STRINGIZE
1078 PGAC_C_SIGNED
1079 AC_C_VOLATILE
1080 PGAC_C_FUNCNAME_SUPPORT
1081 PGAC_STRUCT_TIMEZONE
1082 PGAC_UNION_SEMUN
1083 PGAC_STRUCT_SOCKADDR_UN
1084 PGAC_STRUCT_SOCKADDR_STORAGE
1085 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
1086 PGAC_STRUCT_ADDRINFO
1087
1088 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
1089 [#include <sys/param.h>
1090 #include <sys/types.h>
1091 #include <sys/socket.h>
1092 #include <sys/ucred.h>])
1093
1094 AC_CHECK_TYPES([struct option], [], [],
1095 [#ifdef HAVE_GETOPT_H
1096 #include <getopt.h>
1097 #endif])
1098
1099 if test "$with_zlib" = yes; then
1100   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
1101   # did not).  While we could work around the lack of z_streamp, it
1102   # seems unwise to encourage people to use such old zlib versions...
1103   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
1104 Use --without-zlib to disable zlib support.])],
1105                 [#include <zlib.h>])
1106 fi
1107
1108 if test "$with_krb5" = yes; then
1109 # Check for differences between MIT and Heimdal (KTH) releases
1110   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
1111                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
1112                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
1113                                      [#include <krb5.h>])],
1114                    [#include <krb5.h>])
1115   AC_CHECK_MEMBERS(krb5_error.text.data, [],
1116                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
1117                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
1118                                      [#include <krb5.h>])],
1119                    [#include <krb5.h>])
1120
1121 # Win32 requires headers to be loaded for __stdcall, so can't use
1122 # AC_CHECK_FUNCS here.
1123   AC_MSG_CHECKING(for krb5_free_unparsed_name)
1124   AC_TRY_LINK([#include <krb5.h>],
1125               [krb5_free_unparsed_name(NULL,NULL);],
1126               [AC_DEFINE(HAVE_KRB5_FREE_UNPARSED_NAME, 1, [Define to 1 if you have krb5_free_unparsed_name])
1127 AC_MSG_RESULT(yes)],
1128               [AC_MSG_RESULT(no)])
1129 fi
1130
1131
1132 ##
1133 ## Functions, global variables
1134 ##
1135
1136 PGAC_VAR_INT_TIMEZONE
1137 AC_FUNC_ACCEPT_ARGTYPES
1138 PGAC_FUNC_GETTIMEOFDAY_1ARG
1139
1140 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid getpeerucred getrlimit memmove poll pstat readlink setproctitle setsid sigprocmask symlink sysconf towlower utime utimes waitpid wcstombs])
1141
1142 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
1143 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
1144 AC_CHECK_DECLS([strlcat, strlcpy])
1145 # This is probably only present on Darwin, but may as well check always
1146 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
1147
1148 HAVE_IPV6=no
1149 AC_CHECK_TYPE([struct sockaddr_in6],
1150         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
1151          HAVE_IPV6=yes],
1152         [],
1153 [$ac_includes_default
1154 #include <netinet/in.h>])
1155 AC_SUBST(HAVE_IPV6)
1156
1157 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1158 [AC_TRY_LINK(
1159 [#include <machine/vmparam.h>
1160 #include <sys/exec.h>
1161 ],
1162 [PS_STRINGS->ps_nargvstr = 1;
1163 PS_STRINGS->ps_argvstr = "foo";],
1164 [pgac_cv_var_PS_STRINGS=yes],
1165 [pgac_cv_var_PS_STRINGS=no])])
1166 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1167   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
1168 fi
1169
1170
1171 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
1172 # is missing.  Yes, there are machines that have only one.  We may
1173 # also decide to use snprintf.c if snprintf() is present but does not
1174 # have all the features we need --- see below.
1175
1176 if test "$PORTNAME" = "win32"; then
1177   # Win32 gets snprintf.c built unconditionally.
1178   #
1179   # To properly translate all NLS languages strings, we must support the
1180   # *printf() %$ format, which allows *printf() arguments to be selected
1181   # by position in the translated string.
1182   #
1183   # libintl versions < 0.13 use the native *printf() functions, and Win32
1184   # *printf() doesn't understand %$, so we must use our /port versions,
1185   # which do understand %$. libintl versions >= 0.13 include their own
1186   # *printf versions on Win32.  The libintl 0.13 release note text is:
1187   #
1188   #   C format strings with positions, as they arise when a translator
1189   #   needs to reorder a sentence, are now supported on all platforms.
1190   #   On those few platforms (NetBSD and Woe32) for which the native
1191   #   printf()/fprintf()/... functions don't support such format
1192   #   strings, replacements are provided through <libintl.h>.
1193   #
1194   # We could use libintl >= 0.13's *printf() if we were sure that we had
1195   # a litint >= 0.13 at runtime, but seeing that there is no clean way
1196   # to guarantee that, it is best to just use our own, so we are sure to
1197   # get %$ support. In include/port.h we disable the *printf() macros
1198   # that might have been defined by libintl.
1199   #
1200   # We do this unconditionally whether NLS is used or not so we are sure
1201   # that all Win32 libraries and binaries behave the same.
1202   pgac_need_repl_snprintf=yes
1203 else
1204   pgac_need_repl_snprintf=no
1205   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
1206   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1207 fi
1208
1209
1210 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
1211 # include/c.h will provide declarations.  Note this is a separate test
1212 # from whether the functions exist in the C library --- there are
1213 # systems that have the functions but don't bother to declare them :-(
1214
1215 AC_CHECK_DECLS([snprintf, vsnprintf])
1216
1217
1218 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1219 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1220 [AC_TRY_LINK([
1221 #include <math.h>
1222 double glob_double;
1223 ],
1224 [return isinf(glob_double) ? 0 : 1;],
1225 [ac_cv_func_isinf=yes],
1226 [ac_cv_func_isinf=no])])
1227
1228 if test $ac_cv_func_isinf = yes ; then
1229   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1230 else
1231   AC_LIBOBJ(isinf)
1232   # Look for a way to implement a substitute for isinf()
1233   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1234 fi
1235
1236 # Some versions of libedit contain strlcpy(); so disregard that library while
1237 # checking for these standard libc functions.
1238 pgac_save_LIBS="$LIBS"
1239 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1240
1241 AC_REPLACE_FUNCS([crypt getopt getrusage inet_aton random rint srandom strdup strerror strlcat strlcpy strtol strtoul unsetenv])
1242
1243 LIBS="$pgac_save_LIBS"
1244
1245 # System's version of getaddrinfo(), if any, may be used only if we found
1246 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1247 # (Note: the AC_REPLACE_FUNCS probe fails on Windows, where the available
1248 # versions of getaddrinfo don't follow normal C call protocol.  This is OK
1249 # because we want to use our own getaddrinfo.c on Windows anyway.)
1250 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
1251   AC_REPLACE_FUNCS([getaddrinfo])
1252 else
1253   AC_LIBOBJ(getaddrinfo)
1254 fi
1255
1256 # Similarly, use system's getopt_long() only if system provides struct option.
1257 # Solaris' getopt() doesn't do what we want for long options, so always use
1258 # our versions on that platform.
1259 if test "$PORTNAME" = "solaris"; then
1260   AC_LIBOBJ(getopt)
1261   AC_LIBOBJ(getopt_long)
1262 elif test x"$ac_cv_type_struct_option" = xyes ; then
1263   AC_REPLACE_FUNCS([getopt_long])
1264 else
1265   AC_LIBOBJ(getopt_long)
1266 fi
1267
1268 # Win32 support
1269 if test "$PORTNAME" = "win32"; then
1270 AC_REPLACE_FUNCS(gettimeofday)
1271 AC_LIBOBJ(kill)
1272 AC_LIBOBJ(open)
1273 AC_LIBOBJ(rand)
1274 AC_LIBOBJ(win32error)
1275 AC_DEFINE([HAVE_SYMLINK], 1,
1276           [Define to 1 if you have the `symlink' function.])
1277 fi
1278
1279 if test "$with_readline" = yes; then
1280   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1281   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
1282   AC_CHECK_FUNCS([replace_history_entry])
1283 fi
1284
1285
1286 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
1287 dnl (especially on GNU libc)
1288 dnl See also comments in c.h.
1289 AC_MSG_CHECKING(for sigsetjmp)
1290 AC_TRY_LINK([#include <setjmp.h>],
1291             [sigjmp_buf x; sigsetjmp(x, 1);],
1292             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
1293 AC_MSG_RESULT(yes)],
1294             [AC_MSG_RESULT(no)])
1295
1296 AC_DECL_SYS_SIGLIST
1297
1298 AC_CHECK_FUNC(syslog,
1299               [AC_CHECK_HEADER(syslog.h,
1300                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1301
1302 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1303 [AC_TRY_LINK([#include <unistd.h>],
1304   [extern int optreset; optreset = 1;],
1305   [pgac_cv_var_int_optreset=yes],
1306   [pgac_cv_var_int_optreset=no])])
1307 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1308   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1309 fi
1310
1311 AC_CHECK_FUNCS([strtoll strtoq], [break])
1312 AC_CHECK_FUNCS([strtoull strtouq], [break])
1313
1314 # Check for one of atexit() or on_exit()
1315 AC_CHECK_FUNCS(atexit, [],
1316                [AC_CHECK_FUNCS(on_exit, [],
1317                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
1318
1319 AC_REPLACE_FUNCS(fseeko)
1320 case $host_os in
1321         # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
1322         bsdi*|netbsd*)
1323                 AC_DEFINE(HAVE_FSEEKO, 1, [Define to 1 because replacement version used.])
1324                 ac_cv_func_fseeko=yes;;
1325         *)
1326                 AC_FUNC_FSEEKO;;
1327 esac
1328
1329
1330 #
1331 # Pthreads
1332 #
1333 # For each platform, we need to know about any special compile and link
1334 # libraries, and whether the normal C function names are thread-safe.
1335 # See the comment at the top of src/port/thread.c for more information.
1336 # WIN32 doesn't need the pthread tests;  it always uses threads
1337 if test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"; then
1338 ACX_PTHREAD     # set thread flags
1339
1340 # Some platforms use these, so just define them.  They can't hurt if they
1341 # are not supported.  For example, on Solaris -D_POSIX_PTHREAD_SEMANTICS
1342 # enables 5-arg getpwuid_r, among other things.
1343 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1344
1345
1346 # At this point, we don't want to muck with the compiler name for threading.
1347 # Let's see who fails, perhaps AIX.  2004-04-23
1348 if test "$PTHREAD_CC" != "$CC"; then
1349 AC_MSG_ERROR([
1350 PostgreSQL does not support platforms that require a special compiler
1351 for thread safety.])
1352 fi
1353
1354 if test "$THREAD_SUPPORT" = no; then
1355 AC_MSG_ERROR([cannot enable threads on this platform
1356 This platform is known to not support thread-safe programs.  For details,
1357 compile and run src/bin/pg_thread_test.])
1358 fi
1359
1360 # Check for *_r functions
1361 _CFLAGS="$CFLAGS"
1362 _LIBS="$LIBS"
1363 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1364 LIBS="$LIBS $PTHREAD_LIBS"
1365
1366 if test "$PORTNAME" != "win32"; then
1367 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([pthread.h not found, required for --enable-thread-safety])])
1368 fi
1369
1370 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1371
1372 # Do test here with the proper thread flags
1373 PGAC_FUNC_GETPWUID_R_5ARG
1374 PGAC_FUNC_STRERROR_R_INT
1375
1376 CFLAGS="$_CFLAGS"
1377 LIBS="$_LIBS"
1378
1379 else
1380 # do not use values from template file
1381 PTHREAD_CFLAGS=
1382 PTHREAD_LIBS=
1383 fi
1384
1385 AC_SUBST(PTHREAD_CFLAGS)
1386 AC_SUBST(PTHREAD_LIBS)
1387
1388
1389 # We can test for libldap_r only after we know PTHREAD_LIBS
1390 if test "$with_ldap" = yes ; then
1391   _LIBS="$LIBS"
1392   if test "$PORTNAME" != "win32"; then
1393     AC_CHECK_LIB(ldap, ldap_bind, [],
1394                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1395                  [$EXTRA_LDAP_LIBS])
1396     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1397     if test "$enable_thread_safety" = yes; then
1398       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1399       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1400                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1401                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1402       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1403     else
1404       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1405     fi
1406   else
1407     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1408     LDAP_LIBS_FE="-lwldap32"
1409     LDAP_LIBS_BE="-lwldap32"
1410   fi
1411   LIBS="$_LIBS"
1412 fi
1413 AC_SUBST(LDAP_LIBS_FE)
1414 AC_SUBST(LDAP_LIBS_BE)
1415
1416
1417 # This test makes sure that run tests work at all.  Sometimes a shared
1418 # library is found by the linker, but the runtime linker can't find it.
1419 # This check should come after all modifications of compiler or linker
1420 # variables, and before any other run tests.
1421 AC_MSG_CHECKING([test program])
1422 AC_TRY_RUN([int main() { return 0; }],
1423 [AC_MSG_RESULT(ok)],
1424 [AC_MSG_RESULT(failed)
1425 AC_MSG_ERROR([[
1426 Could not execute a simple test program.  This may be a problem
1427 related to locating shared libraries.  Check the file 'config.log'
1428 for the exact reason.]])],
1429 [AC_MSG_RESULT([cross-compiling])])
1430
1431 # --------------------
1432 # Run tests below here
1433 # --------------------
1434
1435 # Force use of our snprintf if system's doesn't do arg control
1436 # See comment above at snprintf test for details.
1437 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1438   PGAC_FUNC_PRINTF_ARG_CONTROL
1439   if test $pgac_cv_printf_arg_control != yes ; then
1440     pgac_need_repl_snprintf=yes
1441   fi
1442 fi
1443
1444
1445 dnl Check to see if we have a working 64-bit integer type.
1446 dnl This breaks down into two steps:
1447 dnl (1) figure out if the compiler has a 64-bit int type with working
1448 dnl arithmetic, and if so
1449 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1450 dnl snprintf is the only library routine we really need for int8 support.)
1451 dnl It's entirely possible to have a compiler that handles a 64-bit type
1452 dnl when the C library doesn't; this is fairly likely when using gcc on
1453 dnl an older platform, for example.
1454 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1455 dnl we force our own version of snprintf() to be used instead.
1456 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1457
1458 PGAC_TYPE_64BIT_INT([long int])
1459
1460 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1461   PGAC_TYPE_64BIT_INT([long long int])
1462 fi
1463
1464
1465 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1466
1467 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1468   AC_TRY_COMPILE([
1469 #define INT64CONST(x)  x##LL
1470 long long int foo = INT64CONST(0x1234567890123456);
1471 ],
1472         [],
1473         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1474         [])
1475 fi
1476
1477
1478 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1479 # we found we need to use "long long int", better check.  We cope with
1480 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1481 # work, fall back to our own snprintf emulation (which we know uses %lld).
1482
1483 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1484   if test $pgac_need_repl_snprintf = no; then
1485     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1486     if test "$LONG_LONG_INT_FORMAT" = ""; then
1487       # Force usage of our own snprintf, since system snprintf is broken
1488       pgac_need_repl_snprintf=yes
1489       LONG_LONG_INT_FORMAT='%lld'
1490     fi
1491   else
1492     # Here if we previously decided we needed to use our own snprintf
1493     LONG_LONG_INT_FORMAT='%lld'
1494   fi
1495   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1496   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1497   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1498 else
1499   # Here if we are not using 'long long int' at all
1500   INT64_FORMAT='"%ld"'
1501   UINT64_FORMAT='"%lu"'
1502 fi
1503
1504 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1505                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1506
1507 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1508                    [Define to the appropriate snprintf format for unsigned 64-bit ints, if any.])
1509
1510 # Now we have checked all the reasons to replace snprintf
1511 if test $pgac_need_repl_snprintf = yes; then
1512   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1513   AC_LIBOBJ(snprintf)
1514 fi
1515
1516 # Need a #define for the size of Datum (unsigned long)
1517 AC_CHECK_SIZEOF([unsigned long])
1518
1519 # And check size of void *, size_t (enables tweaks for > 32bit address space)
1520 AC_CHECK_SIZEOF([void *])
1521 AC_CHECK_SIZEOF([size_t])
1522
1523 # Decide whether float4 is passed by value: user-selectable, enabled by default
1524 AC_MSG_CHECKING([whether to build with float4 passed by value])
1525 PGAC_ARG_BOOL(enable, float4-byval, yes, [disable float4 passed by value],
1526               [AC_DEFINE([USE_FLOAT4_BYVAL], 1,
1527                          [Define to 1 if you want float4 values to be passed by value. (--enable-float4-byval)])
1528                float4passbyval=true],
1529               [float4passbyval=false])
1530 AC_MSG_RESULT([$enable_float4_byval])
1531 AC_DEFINE_UNQUOTED([FLOAT4PASSBYVAL], [$float4passbyval], [float4 values are passed by value if 'true', by reference if 'false'])
1532
1533 # Decide whether float8 is passed by value.
1534 # Note: this setting also controls int8 and related types such as timestamp.
1535 # If sizeof(Datum) >= 8, this is user-selectable, enabled by default.
1536 # If not, trying to select it is an error.
1537 AC_MSG_CHECKING([whether to build with float8 passed by value])
1538 if test $ac_cv_sizeof_unsigned_long -ge 8 ; then
1539   PGAC_ARG_BOOL(enable, float8-byval, yes, [disable float8 passed by value])
1540 else
1541   PGAC_ARG_BOOL(enable, float8-byval, no, [disable float8 passed by value])
1542   if test "$enable_float8_byval" = yes ; then
1543     AC_MSG_ERROR([--enable-float8-byval is not supported on 32-bit platforms.])
1544   fi
1545 fi
1546 if test "$enable_float8_byval" = yes ; then
1547   AC_DEFINE([USE_FLOAT8_BYVAL], 1,
1548             [Define to 1 if you want float8, int8, etc values to be passed by value. (--enable-float8-byval)])
1549   float8passbyval=true
1550 else
1551   float8passbyval=false
1552 fi
1553 AC_MSG_RESULT([$enable_float8_byval])
1554 AC_DEFINE_UNQUOTED([FLOAT8PASSBYVAL], [$float8passbyval], [float8, int8, and related values are passed by value if 'true', by reference if 'false'])
1555
1556 # Determine memory alignment requirements for the basic C data types.
1557
1558 AC_CHECK_ALIGNOF(short)
1559 AC_CHECK_ALIGNOF(int)
1560 AC_CHECK_ALIGNOF(long)
1561 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1562   AC_CHECK_ALIGNOF(long long int)
1563 fi
1564 AC_CHECK_ALIGNOF(double)
1565
1566 # Compute maximum alignment of any basic type.
1567 # We assume long's alignment is at least as strong as char, short, or int;
1568 # but we must check long long (if it exists) and double.
1569
1570 MAX_ALIGNOF=$ac_cv_alignof_long
1571 if test $MAX_ALIGNOF -lt $ac_cv_alignof_double ; then
1572   MAX_ALIGNOF=$ac_cv_alignof_double
1573 fi
1574 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $ac_cv_alignof_long_long_int ; then
1575   MAX_ALIGNOF="$ac_cv_alignof_long_long_int"
1576 fi
1577 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1578
1579
1580 # Some platforms predefine the types int8, int16, etc.  Only check
1581 # a (hopefully) representative subset.
1582 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1583 [#include <stdio.h>
1584 #ifdef HAVE_SUPPORTDEFS_H
1585 #include <SupportDefs.h>
1586 #endif])
1587
1588 # We also check for sig_atomic_t, which *should* be defined per ANSI
1589 # C, but is missing on some old platforms.
1590 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1591
1592
1593 # If the user did not disable integer datetimes, check that
1594 # there is a working 64-bit integral type to use.
1595 if test x"$USE_INTEGER_DATETIMES" = x"yes" &&
1596    test x"$HAVE_LONG_INT_64" = x"no" &&
1597    test x"$HAVE_LONG_LONG_INT_64" = x"no" &&
1598    test x"$HAVE_INT64" = x"no" ; then
1599   AC_MSG_ERROR([
1600 Integer-based datetime support requires a 64-bit integer type,
1601 but no such type could be found. The --disable-integer-datetimes
1602 configure option can be used to disable integer-based storage
1603 of datetime values.])
1604 fi
1605
1606
1607 if test "$PORTNAME" != "win32"
1608 then
1609 PGAC_FUNC_POSIX_SIGNALS
1610 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1611   AC_MSG_ERROR([
1612 Thread-safety requires POSIX signals, which are not supported by this
1613 operating system.])
1614 fi
1615 fi
1616
1617 if test $ac_cv_func_fseeko = yes; then
1618 AC_SYS_LARGEFILE
1619 fi
1620
1621 # Check for largefile support (must be after AC_SYS_LARGEFILE)
1622 AC_CHECK_SIZEOF([off_t])
1623
1624 # If we don't have largefile support, can't handle segsize >= 2GB.
1625 if test "$ac_cv_sizeof_off_t" -lt 8 -a "$segsize" != "1"; then
1626    AC_MSG_ERROR([Large file support is not enabled. Segment size cannot be larger than 1GB.])
1627 fi
1628
1629 # SunOS doesn't handle negative byte comparisons properly with +/- return
1630 AC_FUNC_MEMCMP
1631
1632
1633 # Select semaphore implementation type.
1634 if test "$PORTNAME" != "win32"; then
1635   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1636     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1637     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1638   else
1639     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1640       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1641       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1642     else
1643       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1644       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1645     fi
1646   fi
1647 else
1648   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1649   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1650 fi
1651
1652
1653 # Select shared-memory implementation type.
1654 if test "$PORTNAME" != "win32"; then
1655   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1656   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1657 else
1658   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
1659   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
1660 fi
1661
1662 # If not set in template file, set bytes to use libc memset()
1663 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
1664   MEMSET_LOOP_LIMIT=1024
1665 fi
1666 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
1667
1668
1669 if test "$enable_nls" = yes ; then
1670   PGAC_CHECK_GETTEXT
1671 fi
1672
1673 # Check for Tcl configuration script tclConfig.sh
1674 if test "$with_tcl" = yes; then
1675     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1676     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1677                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1678     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1679     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1680     ac_save_CPPFLAGS=$CPPFLAGS
1681     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1682     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1683     CPPFLAGS=$ac_save_CPPFLAGS
1684 fi
1685
1686 #
1687 # Check for DocBook and tools
1688 #
1689 PGAC_PROG_NSGMLS
1690 PGAC_PROG_JADE
1691 PGAC_CHECK_DOCBOOK(4.2)
1692 PGAC_PATH_DOCBOOK_STYLESHEETS
1693 PGAC_PATH_COLLATEINDEX
1694 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1695 PGAC_PATH_DOCBOOK2MAN
1696
1697 # Thread testing
1698
1699 # We have to run the thread test near the end so we have all our symbols
1700 # defined.  Cross compiling throws a warning.
1701 #
1702 if test "$enable_thread_safety_force" = yes; then
1703 if test "$PORTNAME" != "win32"
1704 then
1705   AC_MSG_WARN([
1706 *** Skipping thread test program.  --enable-thread-safety-force was used.
1707 *** Run the program in src/test/thread on the your machine and add proper
1708 *** locking function calls to your applications to guarantee thread safety.
1709 ])
1710 else
1711 AC_MSG_WARN([*** skipping thread test on Win32])
1712 fi
1713 elif test "$enable_thread_safety" = yes; then
1714 if test "$PORTNAME" != "win32"
1715 then
1716 AC_MSG_CHECKING([thread safety of required library functions])
1717
1718 _CFLAGS="$CFLAGS"
1719 _LIBS="$LIBS"
1720 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1721 LIBS="$LIBS $PTHREAD_LIBS"
1722 AC_TRY_RUN([#include "$srcdir/src/test/thread/thread_test.c"],
1723   [AC_MSG_RESULT(yes)],
1724   [AC_MSG_RESULT(no)
1725   AC_MSG_ERROR([thread test program failed
1726 This platform is not thread-safe.  Check the file 'config.log' for the
1727 exact reason.
1728
1729 You can use the configure option --enable-thread-safety-force to force
1730 threads to be enabled.  But you must then run the program in
1731 src/test/thread and add locking function calls to your applications to
1732 guarantee thread safety.])],
1733   [AC_MSG_RESULT(maybe)
1734   AC_MSG_WARN([
1735 *** Skipping thread test program because of cross-compile build.
1736 *** Run the program in src/test/thread on the target machine.
1737 ])])
1738 CFLAGS="$_CFLAGS"
1739 LIBS="$_LIBS"
1740 else
1741 AC_MSG_WARN([*** skipping thread test on Win32])
1742 fi
1743 fi
1744
1745 # If compiler will take -Wl,--as-needed then add that to LDFLAGS.
1746 # This is much easier than trying to filter LIBS to the minimum for each
1747 # executable.  (Note that shared library links won't use this switch, though.)
1748 # On (at least) some Red-Hat-derived systems, this switch breaks linking to
1749 # libreadline; therefore we postpone testing it until we know what library
1750 # dependencies readline has.  The test code will try to link with $LIBS.
1751 if test "$with_readline" = yes; then
1752   link_test_func=readline
1753 else
1754   link_test_func=exit
1755 fi
1756 if test "$PORTNAME" != "darwin"; then
1757   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,--as-needed], $link_test_func)
1758 else
1759   # On Darwin it's spelled -Wl,-dead_strip_dylibs, but don't try that elsewhere
1760   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-dead_strip_dylibs], $link_test_func)
1761 fi
1762
1763
1764 # Begin output steps
1765
1766 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
1767 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
1768 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
1769
1770 # Create compiler version string
1771 if test x"$GCC" = x"yes" ; then
1772   cc_string="GCC `${CC} --version | sed q`"
1773 else
1774   cc_string=$CC
1775 fi
1776
1777 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
1778                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string, `expr $ac_cv_sizeof_void_p \* 8`-bit"],
1779                    [A string containing the version number, platform, and C compiler])
1780
1781 # Supply a numeric version string for use by 3rd party add-ons
1782 # awk -F is a regex on some platforms, and not on others, so make "." a tab
1783 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
1784 tr '.' '        ' |
1785 $AWK '{printf "%d%02d%02d", $1, $2, (NF >= 3) ? $3 : 0}'`"]
1786 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
1787
1788
1789 # prepare build tree if outside source tree
1790 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1791 # Note 2: /bin/pwd might be better than shell's built-in at getting
1792 #         a symlink-free name.
1793 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1794   vpath_build=no
1795 else
1796   vpath_build=yes
1797   if test "$no_create" != yes; then
1798     _AS_ECHO_N([preparing build tree... ])
1799     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1800     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1801       || AC_MSG_ERROR(failed)
1802     AC_MSG_RESULT(done)
1803   fi
1804 fi
1805 AC_SUBST(vpath_build)
1806
1807
1808 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1809
1810 AC_CONFIG_LINKS([
1811   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1812   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1813   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1814   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1815   src/include/pg_config_os.h:src/include/port/${template}.h
1816   src/Makefile.port:src/makefiles/Makefile.${template}
1817 ])
1818
1819 if test "$PORTNAME" = "win32"; then
1820 AC_CONFIG_COMMANDS([check_win32_symlinks],[
1821 # Links sometimes fail undetected on Mingw -
1822 # so here we detect it and warn the user
1823 for FILE in $CONFIG_LINKS
1824  do
1825         # test -e works for symlinks in the MinGW console
1826         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
1827  done
1828 ])
1829 fi
1830
1831 AC_CONFIG_HEADERS([src/include/pg_config.h],
1832 [
1833 # Update timestamp for pg_config.h (see Makefile.global)
1834 echo >src/include/stamp-h
1835 ])
1836
1837 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h])
1838
1839 AC_OUTPUT
1840
1841 # Warn about unknown options
1842 PGAC_ARG_CHECK