configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $PostgreSQL: pgsql/configure.in,v 1.625 2010/02/19 18:42:30 petere Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [9.0devel], [pgsql-bugs@postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.63], [], [m4_fatal([Autoconf version 2.63 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2010, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version as a string])
  33 [PG_MAJORVERSION=`expr "$PACKAGE_VERSION" : '\([0-9][0-9]*\.[0-9][0-9]*\)'`]
  34 AC_SUBST(PG_MAJORVERSION)
  35 AC_DEFINE_UNQUOTED(PG_MAJORVERSION, "$PG_MAJORVERSION", [PostgreSQL major version as a string])
  36
  37 AC_CANONICAL_HOST
  38
  39 template=
  40 AC_MSG_CHECKING([which template to use])
  41
  42 PGAC_ARG_REQ(with, template, [NAME], [override operating system template],
  43 [
  44   case $withval in
  45     list)   echo; ls "$srcdir/src/template"; exit;;
  46     *)      if test -f "$srcdir/src/template/$with_template" ; then
  47               template=$withval
  48             else
  49               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  50             fi;;
  51   esac
  52 ],
  53 [
  54 # --with-template not given
  55
  56 case $host_os in
  57      aix*) template=aix ;;
  58     bsdi*) template=bsdi ;;
  59   cygwin*) template=cygwin ;;
  60   darwin*) template=darwin ;;
  61     dgux*) template=dgux ;;
  62  freebsd*) template=freebsd ;;
  63     hpux*) template=hpux ;;
  64     irix*) template=irix ;;
  65  linux*|gnu*|k*bsd*-gnu)
  66            template=linux ;;
  67    mingw*) template=win32 ;;
  68   netbsd*) template=netbsd ;;
  69 nextstep*) template=nextstep ;;
  70  openbsd*) template=openbsd ;;
  71      osf*) template=osf ;;
  72      sco*) template=sco ;;
  73  solaris*) template=solaris ;;
  74    sunos*) template=sunos4 ;;
  75  sysv4.2*)
  76         case $host_vendor in
  77           univel) template=univel ;;
  78         esac ;;
  79    sysv4*) template=svr4 ;;
  80    sysv5*) template=unixware ;;
  81   ultrix*) template=ultrix4 ;;
  82 esac
  83
  84   if test x"$template" = x"" ; then
  85     AC_MSG_ERROR([[
  86 *******************************************************************
  87 PostgreSQL has apparently not been ported to your platform yet.
  88 To try a manual configuration, look into the src/template directory
  89 for a similar platform and use the '--with-template=' option.
  90
  91 Please also contact <pgsql-bugs@postgresql.org> to see about
  92 rectifying this.  Include the above 'checking host system type...'
  93 line.
  94 *******************************************************************
  95 ]])
  96   fi
  97
  98 ])
  99
 100 AC_MSG_RESULT([$template])
 101
 102 PORTNAME=$template
 103 AC_SUBST(PORTNAME)
 104
 105 # Initialize default assumption that we do not need separate assembly code
 106 # for TAS (test-and-set).  This can be overridden by the template file
 107 # when it's executed.
 108 need_tas=no
 109 tas_file=dummy.s
 110
 111
 112
 113 ##
 114 ## Command line options
 115 ##
 116
 117 #
 118 # Add non-standard directories to the include path
 119 #
 120 PGAC_ARG_REQ(with, includes, [DIRS], [look for additional header files in DIRS])
 121
 122
 123 #
 124 # Add non-standard directories to the library search path
 125 #
 126 PGAC_ARG_REQ(with, libraries, [DIRS], [look for additional libraries in DIRS],
 127              [LIBRARY_DIRS=$withval])
 128
 129 PGAC_ARG_REQ(with, libs,      [DIRS], [alternative spelling of --with-libraries],
 130              [LIBRARY_DIRS=$withval])
 131
 132
 133 #
 134 # 64-bit integer date/time storage: enabled by default.
 135 #
 136 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 137 PGAC_ARG_BOOL(enable, integer-datetimes, yes, [disable 64-bit integer date/time support],
 138               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 139                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 140 AC_MSG_RESULT([$enable_integer_datetimes])
 141
 142
 143 #
 144 # NLS
 145 #
 146 AC_MSG_CHECKING([whether NLS is wanted])
 147 PGAC_ARG_OPTARG(enable, nls,
 148                 [LANGUAGES], [enable Native Language Support],
 149                 [],
 150                 [WANTED_LANGUAGES=$enableval],
 151                 [AC_DEFINE(ENABLE_NLS, 1,
 152                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 153 AC_MSG_RESULT([$enable_nls])
 154 AC_SUBST(enable_nls)
 155 AC_SUBST(WANTED_LANGUAGES)
 156
 157 #
 158 # Default port number (--with-pgport), default 5432
 159 #
 160 AC_MSG_CHECKING([for default port number])
 161 PGAC_ARG_REQ(with, pgport, [PORTNUM], [set default port number [5432]],
 162              [default_port=$withval],
 163              [default_port=5432])
 164 AC_MSG_RESULT([$default_port])
 165 # Need both of these because some places want an integer and some a string
 166 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 167 [Define to the default TCP port number on which the server listens and
 168 to which clients will try to connect.  This can be overridden at run-time,
 169 but it's convenient if your clients have the right default compiled in.
 170 (--with-pgport=PORTNUM)])
 171 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 172                    [Define to the default TCP port number as a string constant.])
 173 AC_SUBST(default_port)
 174
 175 #
 176 # Option to disable shared libraries
 177 #
 178 PGAC_ARG_BOOL(enable, shared, yes,
 179               [do not build shared libraries])
 180 AC_SUBST(enable_shared)
 181
 182 #
 183 # '-rpath'-like feature can be disabled
 184 #
 185 PGAC_ARG_BOOL(enable, rpath, yes,
 186               [do not embed shared library search path in executables])
 187 AC_SUBST(enable_rpath)
 188
 189 #
 190 # Spinlocks
 191 #
 192 PGAC_ARG_BOOL(enable, spinlocks, yes,
 193               [do not use spinlocks])
 194
 195 #
 196 # --enable-debug adds -g to compiler flags
 197 #
 198 PGAC_ARG_BOOL(enable, debug, no,
 199               [build with debugging symbols (-g)])
 200 AC_SUBST(enable_debug)
 201
 202 #
 203 # --enable-profiling enables gcc profiling
 204 #
 205 PGAC_ARG_BOOL(enable, profiling, no,
 206               [build with profiling enabled ])
 207 AC_SUBST(enable_profiling)
 208
 209 #
 210 # --enable-coverage enables generation of code coverage metrics with gcov
 211 #
 212 PGAC_ARG_BOOL(enable, coverage, no,
 213               [build with coverage testing instrumentation],
 214 [AC_CHECK_PROGS(GCOV, gcov)
 215 if test -z "$GCOV"; then
 216   AC_MSG_ERROR([gcov not found])
 217 fi
 218 AC_CHECK_PROGS(LCOV, lcov)
 219 if test -z "$LCOV"; then
 220   AC_MSG_ERROR([lcov not found])
 221 fi
 222 AC_CHECK_PROGS(GENHTML, genhtml)
 223 if test -z "$GENHTML"; then
 224   AC_MSG_ERROR([genhtml not found])
 225 fi])
 226 AC_SUBST(enable_coverage)
 227
 228 #
 229 # DTrace
 230 #
 231 PGAC_ARG_BOOL(enable, dtrace, no,
 232               [build with DTrace support],
 233 [AC_DEFINE([ENABLE_DTRACE], 1,
 234            [Define to 1 to enable DTrace support. (--enable-dtrace)])
 235 AC_CHECK_PROGS(DTRACE, dtrace)
 236 if test -z "$DTRACE"; then
 237   AC_MSG_ERROR([dtrace not found])
 238 fi
 239 AC_SUBST(DTRACEFLAGS)])
 240 AC_SUBST(enable_dtrace)
 241
 242 #
 243 # Block size
 244 #
 245 AC_MSG_CHECKING([for block size])
 246 PGAC_ARG_REQ(with, blocksize, [BLOCKSIZE], [set table block size in kB [8]],
 247              [blocksize=$withval],
 248              [blocksize=8])
 249 case ${blocksize} in
 250   1) BLCKSZ=1024;;
 251   2) BLCKSZ=2048;;
 252   4) BLCKSZ=4096;;
 253   8) BLCKSZ=8192;;
 254  16) BLCKSZ=16384;;
 255  32) BLCKSZ=32768;;
 256   *) AC_MSG_ERROR([Invalid block size. Allowed values are 1,2,4,8,16,32.])
 257 esac
 258 AC_MSG_RESULT([${blocksize}kB])
 259
 260 AC_DEFINE_UNQUOTED([BLCKSZ], ${BLCKSZ}, [
 261  Size of a disk block --- this also limits the size of a tuple.  You
 262  can set it bigger if you need bigger tuples (although TOAST should
 263  reduce the need to have large tuples, since fields can be spread
 264  across multiple tuples).
 265
 266  BLCKSZ must be a power of 2.  The maximum possible value of BLCKSZ
 267  is currently 2^15 (32768).  This is determined by the 15-bit widths
 268  of the lp_off and lp_len fields in ItemIdData (see
 269  include/storage/itemid.h).
 270
 271  Changing BLCKSZ requires an initdb.
 272 ])
 273
 274 #
 275 # Relation segment size
 276 #
 277 AC_MSG_CHECKING([for segment size])
 278 PGAC_ARG_REQ(with, segsize, [SEGSIZE], [set table segment size in GB [1]],
 279              [segsize=$withval],
 280              [segsize=1])
 281 # this expression is set up to avoid unnecessary integer overflow
 282 # blocksize is already guaranteed to be a factor of 1024
 283 RELSEG_SIZE=`expr '(' 1024 / ${blocksize} ')' '*' ${segsize} '*' 1024`
 284 test $? -eq 0 || exit 1
 285 AC_MSG_RESULT([${segsize}GB])
 286
 287 AC_DEFINE_UNQUOTED([RELSEG_SIZE], ${RELSEG_SIZE}, [
 288  RELSEG_SIZE is the maximum number of blocks allowed in one disk file.
 289  Thus, the maximum size of a single file is RELSEG_SIZE * BLCKSZ;
 290  relations bigger than that are divided into multiple files.
 291
 292  RELSEG_SIZE * BLCKSZ must be less than your OS' limit on file size.
 293  This is often 2 GB or 4GB in a 32-bit operating system, unless you
 294  have large file support enabled.  By default, we make the limit 1 GB
 295  to avoid any possible integer-overflow problems within the OS.
 296  A limit smaller than necessary only means we divide a large
 297  relation into more chunks than necessary, so it seems best to err
 298  in the direction of a small limit.
 299
 300  A power-of-2 value is recommended to save a few cycles in md.c,
 301  but is not absolutely required.
 302
 303  Changing RELSEG_SIZE requires an initdb.
 304 ])
 305
 306 #
 307 # WAL block size
 308 #
 309 AC_MSG_CHECKING([for WAL block size])
 310 PGAC_ARG_REQ(with, wal-blocksize, [BLOCKSIZE], [set WAL block size in kB [8]],
 311              [wal_blocksize=$withval],
 312              [wal_blocksize=8])
 313 case ${wal_blocksize} in
 314   1) XLOG_BLCKSZ=1024;;
 315   2) XLOG_BLCKSZ=2048;;
 316   4) XLOG_BLCKSZ=4096;;
 317   8) XLOG_BLCKSZ=8192;;
 318  16) XLOG_BLCKSZ=16384;;
 319  32) XLOG_BLCKSZ=32768;;
 320  64) XLOG_BLCKSZ=65536;;
 321   *) AC_MSG_ERROR([Invalid WAL block size. Allowed values are 1,2,4,8,16,32,64.])
 322 esac
 323 AC_MSG_RESULT([${wal_blocksize}kB])
 324
 325 AC_DEFINE_UNQUOTED([XLOG_BLCKSZ], ${XLOG_BLCKSZ}, [
 326  Size of a WAL file block.  This need have no particular relation to BLCKSZ.
 327  XLOG_BLCKSZ must be a power of 2, and if your system supports O_DIRECT I/O,
 328  XLOG_BLCKSZ must be a multiple of the alignment requirement for direct-I/O
 329  buffers, else direct I/O may fail.
 330
 331  Changing XLOG_BLCKSZ requires an initdb.
 332 ])
 333
 334 #
 335 # WAL segment size
 336 #
 337 AC_MSG_CHECKING([for WAL segment size])
 338 PGAC_ARG_REQ(with, wal-segsize, [SEGSIZE], [set WAL segment size in MB [16]],
 339              [wal_segsize=$withval],
 340              [wal_segsize=16])
 341 case ${wal_segsize} in
 342   1) ;;
 343   2) ;;
 344   4) ;;
 345   8) ;;
 346  16) ;;
 347  32) ;;
 348  64) ;;
 349   *) AC_MSG_ERROR([Invalid WAL segment size. Allowed values are 1,2,4,8,16,32,64.])
 350 esac
 351 AC_MSG_RESULT([${wal_segsize}MB])
 352
 353 AC_DEFINE_UNQUOTED([XLOG_SEG_SIZE], [(${wal_segsize} * 1024 * 1024)], [
 354  XLOG_SEG_SIZE is the size of a single WAL file.  This must be a power of 2
 355  and larger than XLOG_BLCKSZ (preferably, a great deal larger than
 356  XLOG_BLCKSZ).
 357
 358  Changing XLOG_SEG_SIZE requires an initdb.
 359 ])
 360
 361 #
 362 # C compiler
 363 #
 364
 365 # For historical reasons you can also use --with-CC to specify the C compiler
 366 # to use, although the standard way to do this is to set the CC environment
 367 # variable.
 368 PGAC_ARG_REQ(with, CC, [CMD], [set compiler (deprecated)], [CC=$with_CC])
 369
 370 case $template in
 371   aix) pgac_cc_list="gcc xlc";;
 372  irix) pgac_cc_list="cc";; # no gcc
 373     *) pgac_cc_list="gcc cc";;
 374 esac
 375
 376 AC_PROG_CC([$pgac_cc_list])
 377
 378 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 379 # but has idiosyncrasies of its own.  We assume icc will define
 380 # __INTEL_COMPILER regardless of CFLAGS.
 381 AC_TRY_COMPILE([], [@%:@ifndef __INTEL_COMPILER
 382 choke me
 383 @%:@endif], [ICC=[yes]], [ICC=[no]])
 384
 385 # Check if it's Sun Studio compiler. We assume that
 386 # __SUNPRO_C will be defined for Sun Studio compilers
 387 AC_TRY_COMPILE([], [@%:@ifndef __SUNPRO_C
 388 choke me
 389 @%:@endif], [SUN_STUDIO_CC=yes], [SUN_STUDIO_CC=no])
 390
 391 AC_SUBST(SUN_STUDIO_CC)
 392
 393 unset CFLAGS
 394
 395 #
 396 # Read the template
 397 #
 398 . "$srcdir/src/template/$template" || exit
 399
 400 # CFLAGS are selected so:
 401 # If the user specifies something in the environment, that is used.
 402 # else:  If the template file set something, that is used.
 403 # else:  If coverage was enabled, don't set anything.
 404 # else:  If the compiler is GCC, then we use -O2.
 405 # else:  If the compiler is something else, then we use -O, unless debugging.
 406
 407 if test "$ac_env_CFLAGS_set" = set; then
 408   CFLAGS=$ac_env_CFLAGS_value
 409 elif test "${CFLAGS+set}" = set; then
 410   : # (keep what template set)
 411 elif test "$enable_coverage" = yes; then
 412   : # no optimization by default
 413 elif test "$GCC" = yes; then
 414   CFLAGS="-O2"
 415 else
 416   # if the user selected debug mode, don't use -O
 417   if test "$enable_debug" != yes; then
 418     CFLAGS="-O"
 419   fi
 420 fi
 421
 422 # Some versions of GCC support some additional useful warning flags.
 423 # Check whether they are supported, and add them to CFLAGS if so.
 424 # ICC pretends to be GCC but it's lying; it doesn't support these flags,
 425 # but has its own.  Also check other compiler-specific flags here.
 426
 427 if test "$GCC" = yes -a "$ICC" = no; then
 428   CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wpointer-arith"
 429   # These work in some but not all gcc versions
 430   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 431   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 432   # Disable strict-aliasing rules; needed for gcc 3.3+
 433   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 434   # Disable optimizations that assume no overflow; needed for gcc 4.3+
 435   PGAC_PROG_CC_CFLAGS_OPT([-fwrapv])
 436 elif test "$ICC" = yes; then
 437   # Intel's compiler has a bug/misoptimization in checking for
 438   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 439   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 440   # Make sure strict aliasing is off (though this is said to be the default)
 441   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 442 elif test "$PORTNAME" = "aix"; then
 443   # AIX's xlc has to have strict aliasing turned off too
 444   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 445 fi
 446
 447 # supply -g if --enable-debug
 448 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 449   CFLAGS="$CFLAGS -g"
 450 fi
 451
 452 # enable code coverage if --enable-coverage
 453 if test "$enable_coverage" = yes; then
 454   if test "$GCC" = yes; then
 455     CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 456   else
 457     AC_MSG_ERROR([--enable-coverage is supported only when using GCC])
 458   fi
 459 fi
 460
 461 # enable profiling if --enable-profiling
 462 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 463   if test "$GCC" = yes; then
 464     AC_DEFINE([PROFILE_PID_DIR], 1,
 465            [Define to 1 to allow profiling output to be saved separately for each process.])
 466     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 467   else
 468     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 469   fi
 470 fi
 471
 472 # We already have this in Makefile.win32, but configure needs it too
 473 if test "$PORTNAME" = "win32"; then
 474   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 475 fi
 476
 477 # Check if the compiler still works with the template settings
 478 AC_MSG_CHECKING([whether the C compiler still works])
 479 AC_TRY_LINK([], [return 0;],
 480   [AC_MSG_RESULT(yes)],
 481   [AC_MSG_RESULT(no)
 482    AC_MSG_ERROR([cannot proceed])])
 483
 484 # Defend against gcc -ffast-math
 485 if test "$GCC" = yes; then
 486 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 487 choke me
 488 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 489 fi
 490
 491 AC_PROG_CPP
 492 AC_SUBST(GCC)
 493
 494
 495 #
 496 # Set up TAS assembly code if needed; the template file has now had its
 497 # chance to request this.
 498 #
 499 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 500
 501 if test "$need_tas" = yes ; then
 502   TAS=tas.o
 503 else
 504   TAS=""
 505 fi
 506 AC_SUBST(TAS)
 507
 508
 509 #
 510 # Automatic dependency tracking
 511 #
 512 PGAC_ARG_BOOL(enable, depend, no, [turn on automatic dependency tracking],
 513               [autodepend=yes])
 514 AC_SUBST(autodepend)
 515
 516
 517 #
 518 # Enable assert checks
 519 #
 520 PGAC_ARG_BOOL(enable, cassert, no, [enable assertion checks (for debugging)],
 521               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 522                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 523
 524
 525 #
 526 # Include directories
 527 #
 528 ac_save_IFS=$IFS
 529 IFS="${IFS}${PATH_SEPARATOR}"
 530 # SRCH_INC comes from the template file
 531 for dir in $with_includes $SRCH_INC; do
 532   if test -d "$dir"; then
 533     INCLUDES="$INCLUDES -I$dir"
 534   else
 535     AC_MSG_WARN([*** Include directory $dir does not exist.])
 536   fi
 537 done
 538 IFS=$ac_save_IFS
 539 AC_SUBST(INCLUDES)
 540
 541
 542 #
 543 # Library directories
 544 #
 545 ac_save_IFS=$IFS
 546 IFS="${IFS}${PATH_SEPARATOR}"
 547 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 548 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 549   if test -d "$dir"; then
 550     LIBDIRS="$LIBDIRS -L$dir"
 551   else
 552     AC_MSG_WARN([*** Library directory $dir does not exist.])
 553   fi
 554 done
 555 IFS=$ac_save_IFS
 556
 557 #
 558 # Enable thread-safe client libraries
 559 #
 560 AC_MSG_CHECKING([allow thread-safe client libraries])
 561 PGAC_ARG_BOOL(enable, thread-safety, yes, [disable thread-safety in client libraries])
 562 if test "$enable_thread_safety" = yes; then
 563   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 564           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 565 fi
 566 AC_MSG_RESULT([$enable_thread_safety])
 567 AC_SUBST(enable_thread_safety)
 568
 569 #
 570 # Optionally build Tcl modules (PL/Tcl)
 571 #
 572 AC_MSG_CHECKING([whether to build with Tcl])
 573 PGAC_ARG_BOOL(with, tcl, no, [build Tcl modules (PL/Tcl)])
 574 AC_MSG_RESULT([$with_tcl])
 575 AC_SUBST([with_tcl])
 576
 577 # We see if the path to the Tcl/Tk configuration scripts is specified.
 578 # This will override the use of tclsh to find the paths to search.
 579
 580 PGAC_ARG_REQ(with, tclconfig, [DIR], [tclConfig.sh is in DIR])
 581
 582 #
 583 # Optionally build Perl modules (PL/Perl)
 584 #
 585 AC_MSG_CHECKING([whether to build Perl modules])
 586 PGAC_ARG_BOOL(with, perl, no, [build Perl modules (PL/Perl)])
 587 AC_MSG_RESULT([$with_perl])
 588 AC_SUBST(with_perl)
 589
 590 #
 591 # Optionally build Python modules (PL/Python)
 592 #
 593 AC_MSG_CHECKING([whether to build Python modules])
 594 PGAC_ARG_BOOL(with, python, no, [build Python modules (PL/Python)])
 595 AC_MSG_RESULT([$with_python])
 596 AC_SUBST(with_python)
 597
 598 #
 599 # GSSAPI
 600 #
 601 AC_MSG_CHECKING([whether to build with GSSAPI support])
 602 PGAC_ARG_BOOL(with, gssapi, no, [build with GSSAPI support],
 603 [
 604   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 605   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 606 ])
 607 AC_MSG_RESULT([$with_gssapi])
 608 AC_SUBST(with_gssapi)
 609
 610 #
 611 # Kerberos 5
 612 #
 613 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 614 PGAC_ARG_BOOL(with, krb5, no, [build with Kerberos 5 support],
 615 [
 616   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 617   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 618 ])
 619 AC_MSG_RESULT([$with_krb5])
 620 AC_SUBST(with_krb5)
 621
 622
 623 AC_SUBST(krb_srvtab)
 624
 625
 626 #
 627 # Kerberos configuration parameters
 628 #
 629 PGAC_ARG_REQ(with, krb-srvnam,
 630              [NAME], [default service principal name in Kerberos [postgres]],
 631              [],
 632              [with_krb_srvnam="postgres"])
 633 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 634                    [Define to the name of the default PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 635
 636
 637 #
 638 # PAM
 639 #
 640 AC_MSG_CHECKING([whether to build with PAM support])
 641 PGAC_ARG_BOOL(with, pam, no,
 642               [build with PAM support],
 643               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 644 AC_MSG_RESULT([$with_pam])
 645 AC_SUBST(with_pam)
 646
 647
 648 #
 649 # LDAP
 650 #
 651 AC_MSG_CHECKING([whether to build with LDAP support])
 652 PGAC_ARG_BOOL(with, ldap, no,
 653               [build with LDAP support],
 654               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 655 AC_MSG_RESULT([$with_ldap])
 656 AC_SUBST(with_ldap)
 657
 658
 659 #
 660 # Bonjour
 661 #
 662 AC_MSG_CHECKING([whether to build with Bonjour support])
 663 PGAC_ARG_BOOL(with, bonjour, no,
 664               [build with Bonjour support],
 665               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 666 AC_MSG_RESULT([$with_bonjour])
 667 AC_SUBST(with_bonjour)
 668
 669
 670 #
 671 # OpenSSL
 672 #
 673 AC_MSG_CHECKING([whether to build with OpenSSL support])
 674 PGAC_ARG_BOOL(with, openssl, no, [build with OpenSSL support],
 675               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 676 AC_MSG_RESULT([$with_openssl])
 677 AC_SUBST(with_openssl)
 678
 679
 680 #
 681 # Readline
 682 #
 683 PGAC_ARG_BOOL(with, readline, yes,
 684               [do not use GNU Readline nor BSD Libedit for editing])
 685 # readline on MinGW has problems with backslashes in psql and other bugs.
 686 # This is particularly a problem with non-US code pages.
 687 # Therefore disable its use until we understand the cause. 2004-07-20
 688 if test "$PORTNAME" = "win32"; then
 689   if test "$with_readline" = yes; then
 690     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 691     with_readline=no
 692   fi
 693 fi
 694
 695
 696 #
 697 # Prefer libedit
 698 #
 699 PGAC_ARG_BOOL(with, libedit-preferred, no,
 700               [prefer BSD Libedit over GNU Readline])
 701
 702
 703 #
 704 # OSSP UUID library
 705 #
 706 PGAC_ARG_BOOL(with, ossp-uuid, no, [use OSSP UUID library when building contrib/uuid-ossp])
 707 AC_SUBST(with_ossp_uuid)
 708
 709
 710 #
 711 # XML
 712 #
 713 PGAC_ARG_BOOL(with, libxml, no, [build with XML support],
 714               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 715
 716 if test "$with_libxml" = yes ; then
 717   AC_CHECK_PROGS(XML2_CONFIG, xml2-config)
 718   if test -n "$XML2_CONFIG"; then
 719     for pgac_option in `$XML2_CONFIG --cflags`; do
 720       case $pgac_option in
 721         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 722       esac
 723     done
 724     for pgac_option in `$XML2_CONFIG --libs`; do
 725       case $pgac_option in
 726         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 727       esac
 728     done
 729   fi
 730 fi
 731
 732 AC_SUBST(with_libxml)
 733
 734 #
 735 # XSLT
 736 #
 737 PGAC_ARG_BOOL(with, libxslt, no, [use XSLT support when building contrib/xml2],
 738               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 739
 740
 741 AC_SUBST(with_libxslt)
 742
 743 #
 744 # tzdata
 745 #
 746 PGAC_ARG_REQ(with, system-tzdata,
 747              [DIR], [use system time zone data in DIR])
 748 AC_SUBST(with_system_tzdata)
 749
 750 #
 751 # Zlib
 752 #
 753 PGAC_ARG_BOOL(with, zlib, yes,
 754               [do not use Zlib])
 755 AC_SUBST(with_zlib)
 756
 757 #
 758 # Elf
 759 #
 760
 761 # Assume system is ELF if it predefines __ELF__ as 1,
 762 # otherwise believe host_os based default.
 763 case $host_os in
 764     freebsd1*|freebsd2*) elf=no;;
 765     freebsd3*|freebsd4*) elf=yes;;
 766 esac
 767
 768 AC_EGREP_CPP(yes,
 769 [#if __ELF__
 770   yes
 771 #endif
 772 ],
 773 [ELF_SYS=true],
 774 [if test "X$elf" = "Xyes" ; then
 775   ELF_SYS=true
 776 else
 777   ELF_SYS=
 778 fi])
 779 AC_SUBST(ELF_SYS)
 780
 781 #
 782 # Assignments
 783 #
 784
 785 CPPFLAGS="$CPPFLAGS $INCLUDES"
 786 LDFLAGS="$LDFLAGS $LIBDIRS"
 787
 788 AC_ARG_VAR(LDFLAGS_SL, [linker flags for shared library linking])
 789
 790 PGAC_PROG_LD
 791 AC_SUBST(LD)
 792 AC_SUBST(with_gnu_ld)
 793 case $host_os in sysv5*)
 794   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 795   [
 796     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 797     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 798     LDFLAGS=$pgac_save_LDFLAGS
 799   ])
 800   ld_R_works=$pgac_cv_prog_ld_R
 801   AC_SUBST(ld_R_works)
 802 esac
 803 AC_PROG_RANLIB
 804 PGAC_CHECK_STRIP
 805 AC_CHECK_TOOL(AR, ar, ar)
 806 if test "$PORTNAME" = "win32"; then
 807   AC_CHECK_TOOL(DLLTOOL, dlltool, dlltool)
 808   AC_CHECK_TOOL(DLLWRAP, dllwrap, dllwrap)
 809   AC_CHECK_TOOL(WINDRES, windres, windres)
 810 fi
 811
 812 AC_PATH_PROG(TAR, tar)
 813 AC_PROG_LN_S
 814 AC_PROG_AWK
 815 AC_PROG_MKDIR_P
 816 # When Autoconf chooses install-sh as mkdir -p program it tries to generate
 817 # a relative path to it in each makefile where it subsitutes it. This clashes
 818 # with our Makefile.global concept. This workaround helps.
 819 case $MKDIR_P in
 820   *install-sh*) MKDIR_P='\${SHELL} \${top_srcdir}/config/install-sh -c -d';;
 821 esac
 822
 823 PGAC_PATH_BISON
 824 PGAC_PATH_FLEX
 825
 826 PGAC_PATH_PERL
 827 if test "$with_perl" = yes; then
 828   if test -z "$PERL"; then
 829     AC_MSG_ERROR([Perl not found])
 830   fi
 831   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 832   PGAC_CHECK_PERL_EMBED_LDFLAGS
 833 fi
 834
 835 if test "$with_python" = yes; then
 836   PGAC_PATH_PYTHON
 837   PGAC_CHECK_PYTHON_EMBED_SETUP
 838 fi
 839
 840 if test "$cross_compiling" = yes && test -z "$with_system_tzdata"; then
 841   AC_PATH_PROG(ZIC, zic)
 842   if test -z "$ZIC"; then
 843     AC_MSG_ERROR([
 844 When cross-compiling, either use the option --with-system-tzdata to use
 845 existing time-zone data, or set the environment variable ZIC to a zic
 846 program to use during the build.])
 847   fi
 848 fi
 849
 850
 851 ##
 852 ## Libraries
 853 ##
 854 ## Most libraries are included only if they demonstrably provide a function
 855 ## we need, but libm is an exception: always include it, because there are
 856 ## too many compilers that play cute optimization games that will break
 857 ## probes for standard functions such as pow().
 858 ##
 859
 860 AC_CHECK_LIB(m, main)
 861 AC_SEARCH_LIBS(setproctitle, util)
 862 AC_SEARCH_LIBS(dlopen, dl)
 863 AC_SEARCH_LIBS(socket, [socket wsock32])
 864 AC_SEARCH_LIBS(shl_load, dld)
 865 # We only use libld in port/dynloader/aix.c
 866 case $host_os in
 867      aix*)
 868         AC_SEARCH_LIBS(ldopen, ld)
 869         ;;
 870 esac
 871 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 872 AC_SEARCH_LIBS(crypt, crypt)
 873 # Solaris:
 874 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 875 # Required for thread_test.c on Solaris 2.5:
 876 # Other ports use it too (HP-UX) so test unconditionally
 877 AC_SEARCH_LIBS(gethostbyname_r, nsl)
 878 # Cygwin:
 879 AC_SEARCH_LIBS(shmget, cygipc)
 880
 881 if test "$with_readline" = yes; then
 882   PGAC_CHECK_READLINE
 883   if test x"$pgac_cv_check_readline" = x"no"; then
 884     AC_MSG_ERROR([readline library not found
 885 If you have readline already installed, see config.log for details on the
 886 failure.  It is possible the compiler isn't looking in the proper directory.
 887 Use --without-readline to disable readline support.])
 888   fi
 889 fi
 890
 891 if test "$with_zlib" = yes; then
 892   AC_CHECK_LIB(z, inflate, [],
 893                [AC_MSG_ERROR([zlib library not found
 894 If you have zlib already installed, see config.log for details on the
 895 failure.  It is possible the compiler isn't looking in the proper directory.
 896 Use --without-zlib to disable zlib support.])])
 897 fi
 898
 899 if test "$enable_spinlocks" = yes; then
 900   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 901 else
 902   AC_MSG_WARN([
 903 *** Not using spinlocks will cause poor performance.])
 904 fi
 905
 906 if test "$with_gssapi" = yes ; then
 907   if test "$PORTNAME" != "win32"; then
 908     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
 909                                   [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
 910   else
 911     LIBS="$LIBS -lgssapi32"
 912   fi
 913 fi
 914
 915 if test "$with_krb5" = yes ; then
 916   if test "$PORTNAME" != "win32"; then
 917      AC_SEARCH_LIBS(com_err, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken' com_err 'com_err -lssl -lcrypto'], [],
 918                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 919      AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken'], [],
 920                     [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 921   else
 922      AC_SEARCH_LIBS(com_err, 'comerr32 -lkrb5_32', [],
 923                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 924   fi
 925 fi
 926
 927 if test "$with_openssl" = yes ; then
 928   dnl Order matters!
 929   if test "$PORTNAME" != "win32"; then
 930      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 931      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 932   else
 933      AC_CHECK_LIB(eay32, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'eay32' is required for OpenSSL])])
 934      AC_CHECK_LIB(ssleay32,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssleay32' is required for OpenSSL])])
 935   fi
 936 fi
 937
 938 if test "$with_pam" = yes ; then
 939   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 940 fi
 941
 942 if test "$with_libxml" = yes ; then
 943   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
 944 fi
 945
 946 if test "$with_libxslt" = yes ; then
 947   AC_CHECK_LIB(xslt, xsltCleanupGlobals, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
 948 fi
 949
 950 # for contrib/uuid-ossp
 951 if test "$with_ossp_uuid" = yes ; then
 952   AC_CHECK_LIB(ossp-uuid, uuid_export,
 953     [OSSP_UUID_LIBS="-lossp-uuid"],
 954     [AC_CHECK_LIB(uuid, uuid_export,
 955       [OSSP_UUID_LIBS="-luuid"],
 956       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP-UUID])])])
 957 fi
 958 AC_SUBST(OSSP_UUID_LIBS)
 959
 960
 961 ##
 962 ## Header files
 963 ##
 964
 965 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 966 AC_CHECK_HEADERS([crypt.h dld.h fp_class.h getopt.h ieeefp.h ifaddrs.h langinfo.h poll.h pwd.h sys/ioctl.h sys/ipc.h sys/poll.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/shm.h sys/socket.h sys/sockio.h sys/tas.h sys/time.h sys/un.h termios.h ucred.h utime.h wchar.h wctype.h kernel/OS.h kernel/image.h SupportDefs.h])
 967
 968 # On BSD, cpp test for net/if.h will fail unless sys/socket.h
 969 # is included first.
 970 AC_CHECK_HEADERS(net/if.h, [], [],
 971 [AC_INCLUDES_DEFAULT
 972 #ifdef HAVE_SYS_SOCKET_H
 973 #include <sys/socket.h>
 974 #endif
 975 ])
 976
 977 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 978 # netinet/in.h is included first.
 979 AC_CHECK_HEADERS(netinet/in.h)
 980 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 981 [AC_INCLUDES_DEFAULT
 982 #ifdef HAVE_NETINET_IN_H
 983 #include <netinet/in.h>
 984 #endif
 985 ])
 986
 987 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
 988   AC_CHECK_HEADERS(readline/readline.h, [],
 989         [AC_CHECK_HEADERS(readline.h, [],
 990                 [AC_MSG_ERROR([readline header not found
 991 If you have readline already installed, see config.log for details on the
 992 failure.  It is possible the compiler isn't looking in the proper directory.
 993 Use --without-readline to disable readline support.])])])
 994   AC_CHECK_HEADERS(readline/history.h, [],
 995         [AC_CHECK_HEADERS(history.h, [],
 996                 [AC_MSG_ERROR([history header not found
 997 If you have readline already installed, see config.log for details on the
 998 failure.  It is possible the compiler isn't looking in the proper directory.
 999 Use --without-readline to disable readline support.])])])
1000 fi
1001
1002 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
1003 # Some installations of libedit usurp /usr/include/readline/, which seems
1004 # bad practice, since in combined installations readline will have its headers
1005 # there.  We might have to resort to AC_EGREP checks to make sure we found
1006 # the proper header...
1007   AC_CHECK_HEADERS(editline/readline.h, [],
1008         [AC_CHECK_HEADERS(readline.h, [],
1009                 [AC_CHECK_HEADERS(readline/readline.h, [],
1010                         [AC_MSG_ERROR([readline header not found
1011 If you have libedit already installed, see config.log for details on the
1012 failure.  It is possible the compiler isn't looking in the proper directory.
1013 Use --without-readline to disable libedit support.])])])])
1014 # Note: in a libedit installation, history.h is sometimes a dummy, and may
1015 # not be there at all.  Hence, don't complain if not found.  We must check
1016 # though, since in yet other versions it is an independent header.
1017   AC_CHECK_HEADERS(editline/history.h, [],
1018         [AC_CHECK_HEADERS(history.h, [],
1019                 [AC_CHECK_HEADERS(readline/history.h)])])
1020 fi
1021
1022 if test "$with_zlib" = yes; then
1023   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
1024 If you have zlib already installed, see config.log for details on the
1025 failure.  It is possible the compiler isn't looking in the proper directory.
1026 Use --without-zlib to disable zlib support.])])
1027 fi
1028
1029 if test "$with_gssapi" = yes ; then
1030   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
1031         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
1032 fi
1033
1034 if test "$with_krb5" = yes ; then
1035   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
1036 fi
1037
1038 if test "$with_openssl" = yes ; then
1039   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
1040   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
1041   AC_CHECK_FUNCS([ERR_set_mark])
1042 fi
1043
1044 if test "$with_pam" = yes ; then
1045   AC_CHECK_HEADERS(security/pam_appl.h, [],
1046                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
1047                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
1048 fi
1049
1050 if test "$with_libxml" = yes ; then
1051   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
1052 fi
1053
1054 if test "$with_libxslt" = yes ; then
1055   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
1056 fi
1057
1058 if test "$with_ldap" = yes ; then
1059   if test "$PORTNAME" != "win32"; then
1060      AC_CHECK_HEADERS(ldap.h, [],
1061                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
1062   else
1063      AC_CHECK_HEADERS(winldap.h, [],
1064                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
1065                       [AC_INCLUDES_DEFAULT
1066 #include <windows.h>
1067                       ])
1068   fi
1069 fi
1070
1071 if test "$with_bonjour" = yes ; then
1072   AC_CHECK_HEADER(dns_sd.h, [], [AC_MSG_ERROR([header file <dns_sd.h> is required for Bonjour])])
1073 fi
1074
1075 # for contrib/uuid-ossp
1076 if test "$with_ossp_uuid" = yes ; then
1077   AC_CHECK_HEADERS(ossp/uuid.h, [], [
1078     AC_CHECK_HEADERS(uuid.h, [],
1079       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP-UUID])])])
1080 fi
1081
1082
1083 ##
1084 ## Types, structures, compiler characteristics
1085 ##
1086
1087 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
1088 AC_C_BIGENDIAN
1089 AC_C_CONST
1090 PGAC_C_INLINE
1091 AC_C_STRINGIZE
1092 PGAC_C_SIGNED
1093 AC_C_VOLATILE
1094 PGAC_C_FUNCNAME_SUPPORT
1095 PGAC_STRUCT_TIMEZONE
1096 PGAC_UNION_SEMUN
1097 PGAC_STRUCT_SOCKADDR_UN
1098 PGAC_STRUCT_SOCKADDR_STORAGE
1099 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
1100 PGAC_STRUCT_ADDRINFO
1101 AC_TYPE_INTPTR_T
1102 AC_TYPE_UINTPTR_T
1103
1104 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
1105 [#include <sys/param.h>
1106 #include <sys/types.h>
1107 #include <sys/socket.h>
1108 #include <sys/ucred.h>])
1109
1110 AC_CHECK_TYPES([struct option], [], [],
1111 [#ifdef HAVE_GETOPT_H
1112 #include <getopt.h>
1113 #endif])
1114
1115 if test "$with_zlib" = yes; then
1116   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
1117   # did not).  While we could work around the lack of z_streamp, it
1118   # seems unwise to encourage people to use such old zlib versions...
1119   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
1120 Use --without-zlib to disable zlib support.])],
1121                 [#include <zlib.h>])
1122 fi
1123
1124 if test "$with_krb5" = yes; then
1125 # Check for differences between MIT and Heimdal (KTH) releases
1126   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
1127                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
1128                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
1129                                      [#include <krb5.h>])],
1130                    [#include <krb5.h>])
1131   AC_CHECK_MEMBERS(krb5_error.text.data, [],
1132                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
1133                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
1134                                      [#include <krb5.h>])],
1135                    [#include <krb5.h>])
1136
1137 # Win32 requires headers to be loaded for __stdcall, so can't use
1138 # AC_CHECK_FUNCS here.
1139   AC_MSG_CHECKING(for krb5_free_unparsed_name)
1140   AC_TRY_LINK([#include <krb5.h>],
1141               [krb5_free_unparsed_name(NULL,NULL);],
1142               [AC_DEFINE(HAVE_KRB5_FREE_UNPARSED_NAME, 1, [Define to 1 if you have krb5_free_unparsed_name])
1143 AC_MSG_RESULT(yes)],
1144               [AC_MSG_RESULT(no)])
1145 fi
1146
1147 # Check largefile support.  You might think this is a system service not a
1148 # compiler characteristic, but you'd be wrong.  We must check this before
1149 # probing existence of related functions such as fseeko, since the largefile
1150 # defines can affect what is generated for that.
1151 AC_SYS_LARGEFILE
1152
1153 # Check for largefile support (must be after AC_SYS_LARGEFILE)
1154 AC_CHECK_SIZEOF([off_t])
1155
1156 # If we don't have largefile support, can't handle segsize >= 2GB.
1157 if test "$ac_cv_sizeof_off_t" -lt 8 -a "$segsize" != "1"; then
1158    AC_MSG_ERROR([Large file support is not enabled. Segment size cannot be larger than 1GB.])
1159 fi
1160
1161
1162 ##
1163 ## Functions, global variables
1164 ##
1165
1166 PGAC_VAR_INT_TIMEZONE
1167 AC_FUNC_ACCEPT_ARGTYPES
1168 PGAC_FUNC_GETTIMEOFDAY_1ARG
1169
1170 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getifaddrs getpeereid getpeerucred getrlimit memmove poll pstat readlink setproctitle setsid sigprocmask symlink sysconf towlower utime utimes waitpid wcstombs])
1171
1172 AC_REPLACE_FUNCS(fseeko)
1173 case $host_os in
1174         # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
1175         # Mingw uses macros to access Win32 API calls
1176         bsdi*|netbsd*|mingw*)
1177                 AC_DEFINE(HAVE_FSEEKO, 1, [Define to 1 because replacement version used.])
1178                 ac_cv_func_fseeko=yes;;
1179         *)
1180                 AC_FUNC_FSEEKO;;
1181 esac
1182
1183 # posix_fadvise() is a no-op on Solaris, so don't incur function overhead
1184 # by calling it, 2009-04-02
1185 # http://src.opensolaris.org/source/xref/onnv/onnv-gate/usr/src/lib/libc/port/gen/posix_fadvise.c
1186 if test "$PORTNAME" != "solaris"; then
1187 AC_CHECK_FUNCS(posix_fadvise)
1188 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
1189 fi
1190
1191 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
1192 AC_CHECK_DECLS([strlcat, strlcpy])
1193 # This is probably only present on Darwin, but may as well check always
1194 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
1195
1196 HAVE_IPV6=no
1197 AC_CHECK_TYPE([struct sockaddr_in6],
1198         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
1199          HAVE_IPV6=yes],
1200         [],
1201 [$ac_includes_default
1202 #include <netinet/in.h>])
1203 AC_SUBST(HAVE_IPV6)
1204
1205 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1206 [AC_TRY_LINK(
1207 [#include <machine/vmparam.h>
1208 #include <sys/exec.h>
1209 ],
1210 [PS_STRINGS->ps_nargvstr = 1;
1211 PS_STRINGS->ps_argvstr = "foo";],
1212 [pgac_cv_var_PS_STRINGS=yes],
1213 [pgac_cv_var_PS_STRINGS=no])])
1214 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1215   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
1216 fi
1217
1218
1219 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
1220 # is missing.  Yes, there are machines that have only one.  We may
1221 # also decide to use snprintf.c if snprintf() is present but does not
1222 # have all the features we need --- see below.
1223
1224 if test "$PORTNAME" = "win32"; then
1225   # Win32 gets snprintf.c built unconditionally.
1226   #
1227   # To properly translate all NLS languages strings, we must support the
1228   # *printf() %$ format, which allows *printf() arguments to be selected
1229   # by position in the translated string.
1230   #
1231   # libintl versions < 0.13 use the native *printf() functions, and Win32
1232   # *printf() doesn't understand %$, so we must use our /port versions,
1233   # which do understand %$. libintl versions >= 0.13 include their own
1234   # *printf versions on Win32.  The libintl 0.13 release note text is:
1235   #
1236   #   C format strings with positions, as they arise when a translator
1237   #   needs to reorder a sentence, are now supported on all platforms.
1238   #   On those few platforms (NetBSD and Woe32) for which the native
1239   #   printf()/fprintf()/... functions don't support such format
1240   #   strings, replacements are provided through <libintl.h>.
1241   #
1242   # We could use libintl >= 0.13's *printf() if we were sure that we had
1243   # a litint >= 0.13 at runtime, but seeing that there is no clean way
1244   # to guarantee that, it is best to just use our own, so we are sure to
1245   # get %$ support. In include/port.h we disable the *printf() macros
1246   # that might have been defined by libintl.
1247   #
1248   # We do this unconditionally whether NLS is used or not so we are sure
1249   # that all Win32 libraries and binaries behave the same.
1250   pgac_need_repl_snprintf=yes
1251 else
1252   pgac_need_repl_snprintf=no
1253   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
1254   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1255 fi
1256
1257
1258 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
1259 # include/c.h will provide declarations.  Note this is a separate test
1260 # from whether the functions exist in the C library --- there are
1261 # systems that have the functions but don't bother to declare them :-(
1262
1263 AC_CHECK_DECLS([snprintf, vsnprintf])
1264
1265
1266 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1267 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1268 [AC_TRY_LINK([
1269 #include <math.h>
1270 double glob_double;
1271 ],
1272 [return isinf(glob_double) ? 0 : 1;],
1273 [ac_cv_func_isinf=yes],
1274 [ac_cv_func_isinf=no])])
1275
1276 if test $ac_cv_func_isinf = yes ; then
1277   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1278 else
1279   AC_LIBOBJ(isinf)
1280   # Look for a way to implement a substitute for isinf()
1281   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1282 fi
1283
1284 # Some versions of libedit contain strlcpy(); so disregard that library while
1285 # checking for these standard libc functions.
1286 pgac_save_LIBS="$LIBS"
1287 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1288
1289 AC_REPLACE_FUNCS([crypt erand48 getopt getrusage inet_aton random rint srandom strdup strerror strlcat strlcpy strtol strtoul])
1290
1291 case $host_os in
1292
1293         # Windows uses a specialised env handler
1294         mingw*)
1295                 AC_DEFINE(HAVE_UNSETENV, 1, [Define to 1 because replacement version used.])
1296                 ac_cv_func_unsetenv=yes;;
1297         *)
1298                 AC_REPLACE_FUNCS([unsetenv])
1299                 ;;
1300 esac
1301
1302
1303 LIBS="$pgac_save_LIBS"
1304
1305 # System's version of getaddrinfo(), if any, may be used only if we found
1306 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1307 # (Note: the AC_REPLACE_FUNCS probe fails on Windows, where the available
1308 # versions of getaddrinfo don't follow normal C call protocol.  This is OK
1309 # because we want to use our own getaddrinfo.c on Windows anyway.)
1310 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
1311   AC_REPLACE_FUNCS([getaddrinfo])
1312 else
1313   AC_LIBOBJ(getaddrinfo)
1314 fi
1315
1316 # Similarly, use system's getopt_long() only if system provides struct option.
1317 if test x"$ac_cv_type_struct_option" = xyes ; then
1318   AC_REPLACE_FUNCS([getopt_long])
1319 else
1320   AC_LIBOBJ(getopt_long)
1321 fi
1322
1323 # Solaris' getopt() doesn't do what we want for long options, so always use
1324 # our version on that platform.
1325 if test "$PORTNAME" = "solaris"; then
1326   AC_LIBOBJ(getopt)
1327 fi
1328
1329 # Cygwin's erand48() is broken (always returns zero) in some releases,
1330 # so force use of ours.
1331 if test "$PORTNAME" = "cygwin"; then
1332   AC_LIBOBJ(erand48)
1333 fi
1334
1335 # Win32 support
1336 if test "$PORTNAME" = "win32"; then
1337 AC_REPLACE_FUNCS(gettimeofday)
1338 AC_LIBOBJ(kill)
1339 AC_LIBOBJ(open)
1340 AC_LIBOBJ(win32env)
1341 AC_LIBOBJ(win32error)
1342 AC_DEFINE([HAVE_SYMLINK], 1,
1343           [Define to 1 if you have the `symlink' function.])
1344 fi
1345
1346 if test "$with_readline" = yes; then
1347   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1348   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
1349   AC_CHECK_FUNCS([append_history history_truncate_file])
1350 fi
1351
1352
1353 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
1354 dnl (especially on GNU libc)
1355 dnl See also comments in c.h.
1356 AC_MSG_CHECKING(for sigsetjmp)
1357 AC_TRY_LINK([#include <setjmp.h>],
1358             [sigjmp_buf x; sigsetjmp(x, 1);],
1359             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
1360 AC_MSG_RESULT(yes)],
1361             [AC_MSG_RESULT(no)])
1362
1363 AC_DECL_SYS_SIGLIST
1364
1365 AC_CHECK_FUNC(syslog,
1366               [AC_CHECK_HEADER(syslog.h,
1367                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1368
1369 AC_CACHE_CHECK([for opterr], pgac_cv_var_int_opterr,
1370 [AC_TRY_LINK([#include <unistd.h>],
1371   [extern int opterr; opterr = 1;],
1372   [pgac_cv_var_int_opterr=yes],
1373   [pgac_cv_var_int_opterr=no])])
1374 if test x"$pgac_cv_var_int_opterr" = x"yes"; then
1375   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
1376 fi
1377
1378 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1379 [AC_TRY_LINK([#include <unistd.h>],
1380   [extern int optreset; optreset = 1;],
1381   [pgac_cv_var_int_optreset=yes],
1382   [pgac_cv_var_int_optreset=no])])
1383 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1384   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1385 fi
1386
1387 AC_CHECK_FUNCS([strtoll strtoq], [break])
1388 AC_CHECK_FUNCS([strtoull strtouq], [break])
1389
1390 # Check for one of atexit() or on_exit()
1391 AC_CHECK_FUNCS(atexit, [],
1392                [AC_CHECK_FUNCS(on_exit, [],
1393                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
1394
1395
1396 #
1397 # Pthreads
1398 #
1399 # For each platform, we need to know about any special compile and link
1400 # libraries, and whether the normal C function names are thread-safe.
1401 # See the comment at the top of src/port/thread.c for more information.
1402 # WIN32 doesn't need the pthread tests;  it always uses threads
1403 if test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"; then
1404 ACX_PTHREAD     # set thread flags
1405
1406 # Some platforms use these, so just define them.  They can't hurt if they
1407 # are not supported.  For example, on Solaris -D_POSIX_PTHREAD_SEMANTICS
1408 # enables 5-arg getpwuid_r, among other things.
1409 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1410
1411
1412 # At this point, we don't want to muck with the compiler name for threading.
1413 # Let's see who fails, perhaps AIX.  2004-04-23
1414 if test "$PTHREAD_CC" != "$CC"; then
1415 AC_MSG_ERROR([
1416 PostgreSQL does not support platforms that require a special compiler
1417 for thread safety;  use --disable-thread-safety to disable thread safety.])
1418 fi
1419
1420 # Check for *_r functions
1421 _CFLAGS="$CFLAGS"
1422 _LIBS="$LIBS"
1423 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1424 LIBS="$LIBS $PTHREAD_LIBS"
1425
1426 if test "$PORTNAME" != "win32"; then
1427 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([
1428 pthread.h not found;  use --disable-thread-safety to disable thread safety])])
1429 fi
1430
1431 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1432
1433 # Do test here with the proper thread flags
1434 PGAC_FUNC_GETPWUID_R_5ARG
1435 PGAC_FUNC_STRERROR_R_INT
1436
1437 CFLAGS="$_CFLAGS"
1438 LIBS="$_LIBS"
1439
1440 else
1441 # do not use values from template file
1442 PTHREAD_CFLAGS=
1443 PTHREAD_LIBS=
1444 fi
1445
1446 AC_SUBST(PTHREAD_CFLAGS)
1447 AC_SUBST(PTHREAD_LIBS)
1448
1449
1450 # We can test for libldap_r only after we know PTHREAD_LIBS
1451 if test "$with_ldap" = yes ; then
1452   _LIBS="$LIBS"
1453   if test "$PORTNAME" != "win32"; then
1454     AC_CHECK_LIB(ldap, ldap_bind, [],
1455                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1456                  [$EXTRA_LDAP_LIBS])
1457     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1458     if test "$enable_thread_safety" = yes; then
1459       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1460       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1461                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1462                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1463       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1464     else
1465       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1466     fi
1467   else
1468     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1469     LDAP_LIBS_FE="-lwldap32"
1470     LDAP_LIBS_BE="-lwldap32"
1471   fi
1472   LIBS="$_LIBS"
1473 fi
1474 AC_SUBST(LDAP_LIBS_FE)
1475 AC_SUBST(LDAP_LIBS_BE)
1476
1477
1478 # This test makes sure that run tests work at all.  Sometimes a shared
1479 # library is found by the linker, but the runtime linker can't find it.
1480 # This check should come after all modifications of compiler or linker
1481 # variables, and before any other run tests.
1482 AC_MSG_CHECKING([test program])
1483 AC_TRY_RUN([int main() { return 0; }],
1484 [AC_MSG_RESULT(ok)],
1485 [AC_MSG_RESULT(failed)
1486 AC_MSG_ERROR([[
1487 Could not execute a simple test program.  This may be a problem
1488 related to locating shared libraries.  Check the file 'config.log'
1489 for the exact reason.]])],
1490 [AC_MSG_RESULT([cross-compiling])])
1491
1492 # --------------------
1493 # Run tests below here
1494 # --------------------
1495
1496 # Force use of our snprintf if system's doesn't do arg control
1497 # See comment above at snprintf test for details.
1498 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1499   PGAC_FUNC_PRINTF_ARG_CONTROL
1500   if test $pgac_cv_printf_arg_control != yes ; then
1501     pgac_need_repl_snprintf=yes
1502   fi
1503 fi
1504
1505
1506 dnl Check to see if we have a working 64-bit integer type.
1507 dnl This breaks down into two steps:
1508 dnl (1) figure out if the compiler has a 64-bit int type with working
1509 dnl arithmetic, and if so
1510 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1511 dnl snprintf is the only library routine we really need for int8 support.)
1512 dnl It's entirely possible to have a compiler that handles a 64-bit type
1513 dnl when the C library doesn't; this is fairly likely when using gcc on
1514 dnl an older platform, for example.
1515 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1516 dnl we force our own version of snprintf() to be used instead.
1517 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1518
1519 dnl As of Postgres 8.4, we no longer support compilers without a working
1520 dnl 64-bit type.  But we still handle the case of snprintf being broken.
1521
1522 PGAC_TYPE_64BIT_INT([long int])
1523
1524 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1525   PGAC_TYPE_64BIT_INT([long long int])
1526   if test x"$HAVE_LONG_LONG_INT_64" = x"no" ; then
1527     AC_MSG_ERROR([Cannot find a working 64-bit integer type.])
1528   fi
1529 fi
1530
1531
1532 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1533
1534 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1535   AC_TRY_COMPILE([
1536 #define INT64CONST(x)  x##LL
1537 long long int foo = INT64CONST(0x1234567890123456);
1538 ],
1539         [],
1540         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1541         [])
1542 fi
1543
1544
1545 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1546 # we found we need to use "long long int", better check.  We cope with
1547 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1548 # work, fall back to our own snprintf emulation (which we know uses %lld).
1549
1550 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1551   if test $pgac_need_repl_snprintf = no; then
1552     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1553     if test "$LONG_LONG_INT_FORMAT" = ""; then
1554       # Force usage of our own snprintf, since system snprintf is broken
1555       pgac_need_repl_snprintf=yes
1556       LONG_LONG_INT_FORMAT='%lld'
1557     fi
1558   else
1559     # Here if we previously decided we needed to use our own snprintf
1560     LONG_LONG_INT_FORMAT='%lld'
1561   fi
1562   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1563   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1564   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1565 else
1566   # Here if we are not using 'long long int' at all
1567   INT64_FORMAT='"%ld"'
1568   UINT64_FORMAT='"%lu"'
1569 fi
1570
1571 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1572                    [Define to the appropriate snprintf format for 64-bit ints.])
1573
1574 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1575                    [Define to the appropriate snprintf format for unsigned 64-bit ints.])
1576
1577 # Now we have checked all the reasons to replace snprintf
1578 if test $pgac_need_repl_snprintf = yes; then
1579   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1580   AC_LIBOBJ(snprintf)
1581 fi
1582
1583 # Check size of void *, size_t (enables tweaks for > 32bit address space)
1584 AC_CHECK_SIZEOF([void *])
1585 AC_CHECK_SIZEOF([size_t])
1586 AC_CHECK_SIZEOF([long])
1587
1588 # Decide whether float4 is passed by value: user-selectable, enabled by default
1589 AC_MSG_CHECKING([whether to build with float4 passed by value])
1590 PGAC_ARG_BOOL(enable, float4-byval, yes, [disable float4 passed by value],
1591               [AC_DEFINE([USE_FLOAT4_BYVAL], 1,
1592                          [Define to 1 if you want float4 values to be passed by value. (--enable-float4-byval)])
1593                float4passbyval=true],
1594               [float4passbyval=false])
1595 AC_MSG_RESULT([$enable_float4_byval])
1596 AC_DEFINE_UNQUOTED([FLOAT4PASSBYVAL], [$float4passbyval], [float4 values are passed by value if 'true', by reference if 'false'])
1597
1598 # Decide whether float8 is passed by value.
1599 # Note: this setting also controls int8 and related types such as timestamp.
1600 # If sizeof(Datum) >= 8, this is user-selectable, enabled by default.
1601 # If not, trying to select it is an error.
1602 AC_MSG_CHECKING([whether to build with float8 passed by value])
1603 if test $ac_cv_sizeof_void_p -ge 8 ; then
1604   PGAC_ARG_BOOL(enable, float8-byval, yes, [disable float8 passed by value])
1605 else
1606   PGAC_ARG_BOOL(enable, float8-byval, no, [disable float8 passed by value])
1607   if test "$enable_float8_byval" = yes ; then
1608     AC_MSG_ERROR([--enable-float8-byval is not supported on 32-bit platforms.])
1609   fi
1610 fi
1611 if test "$enable_float8_byval" = yes ; then
1612   AC_DEFINE([USE_FLOAT8_BYVAL], 1,
1613             [Define to 1 if you want float8, int8, etc values to be passed by value. (--enable-float8-byval)])
1614   float8passbyval=true
1615 else
1616   float8passbyval=false
1617 fi
1618 AC_MSG_RESULT([$enable_float8_byval])
1619 AC_DEFINE_UNQUOTED([FLOAT8PASSBYVAL], [$float8passbyval], [float8, int8, and related values are passed by value if 'true', by reference if 'false'])
1620
1621 # Determine memory alignment requirements for the basic C data types.
1622
1623 AC_CHECK_ALIGNOF(short)
1624 AC_CHECK_ALIGNOF(int)
1625 AC_CHECK_ALIGNOF(long)
1626 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1627   AC_CHECK_ALIGNOF(long long int)
1628 fi
1629 AC_CHECK_ALIGNOF(double)
1630
1631 # Compute maximum alignment of any basic type.
1632 # We assume long's alignment is at least as strong as char, short, or int;
1633 # but we must check long long (if it exists) and double.
1634
1635 MAX_ALIGNOF=$ac_cv_alignof_long
1636 if test $MAX_ALIGNOF -lt $ac_cv_alignof_double ; then
1637   MAX_ALIGNOF=$ac_cv_alignof_double
1638 fi
1639 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $ac_cv_alignof_long_long_int ; then
1640   MAX_ALIGNOF="$ac_cv_alignof_long_long_int"
1641 fi
1642 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1643
1644
1645 # Some platforms predefine the types int8, int16, etc.  Only check
1646 # a (hopefully) representative subset.
1647 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1648 [#include <stdio.h>
1649 #ifdef HAVE_SUPPORTDEFS_H
1650 #include <SupportDefs.h>
1651 #endif])
1652
1653 # We also check for sig_atomic_t, which *should* be defined per ANSI
1654 # C, but is missing on some old platforms.
1655 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1656
1657
1658 if test "$PORTNAME" != "win32"
1659 then
1660 PGAC_FUNC_POSIX_SIGNALS
1661 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1662   AC_MSG_ERROR([
1663 Thread-safety requires POSIX signals, which are not supported by this
1664 operating system;  use --disable-thread-safety to disable thread safety.])
1665 fi
1666 fi
1667
1668 # SunOS doesn't handle negative byte comparisons properly with +/- return
1669 AC_FUNC_MEMCMP
1670
1671
1672 # Select semaphore implementation type.
1673 if test "$PORTNAME" != "win32"; then
1674   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1675     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1676     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1677   else
1678     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1679       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1680       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1681     else
1682       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1683       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1684     fi
1685   fi
1686 else
1687   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1688   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1689 fi
1690
1691
1692 # Select shared-memory implementation type.
1693 if test "$PORTNAME" != "win32"; then
1694   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1695   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1696 else
1697   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
1698   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
1699 fi
1700
1701 # If not set in template file, set bytes to use libc memset()
1702 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
1703   MEMSET_LOOP_LIMIT=1024
1704 fi
1705 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
1706
1707
1708 if test "$enable_nls" = yes ; then
1709   PGAC_CHECK_GETTEXT
1710 fi
1711
1712 # Check for Tcl configuration script tclConfig.sh
1713 if test "$with_tcl" = yes; then
1714     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1715     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1716                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1717     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1718     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1719     ac_save_CPPFLAGS=$CPPFLAGS
1720     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1721     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1722     CPPFLAGS=$ac_save_CPPFLAGS
1723 fi
1724
1725 #
1726 # Check for DocBook and tools
1727 #
1728 PGAC_PROG_NSGMLS
1729 PGAC_PROG_JADE
1730 PGAC_CHECK_DOCBOOK(4.2)
1731 PGAC_PATH_DOCBOOK_STYLESHEETS
1732 PGAC_PATH_COLLATEINDEX
1733 AC_CHECK_PROGS(XSLTPROC, xsltproc)
1734 AC_CHECK_PROGS(OSX, [osx sgml2xml sx])
1735
1736 # Thread testing
1737
1738 # We have to run the thread test near the end so we have all our symbols
1739 # defined.  Cross compiling throws a warning.
1740 #
1741 if test "$enable_thread_safety" = yes; then
1742 if test "$PORTNAME" != "win32"
1743 then
1744 AC_MSG_CHECKING([thread safety of required library functions])
1745
1746 _CFLAGS="$CFLAGS"
1747 _LIBS="$LIBS"
1748 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1749 LIBS="$LIBS $PTHREAD_LIBS"
1750 AC_TRY_RUN([#include "$srcdir/src/test/thread/thread_test.c"],
1751   [AC_MSG_RESULT(yes)],
1752   [AC_MSG_RESULT(no)
1753   AC_MSG_ERROR([thread test program failed
1754 This platform is not thread-safe.  Check the file 'config.log' or compile
1755 and run src/test/thread/thread_test for the exact reason.
1756 Use --disable-thread-safety to disable thread safety.])],
1757   [AC_MSG_RESULT(maybe)
1758   AC_MSG_WARN([
1759 *** Skipping thread test program because of cross-compile build.
1760 *** Run the program in src/test/thread on the target machine.
1761 ])])
1762 CFLAGS="$_CFLAGS"
1763 LIBS="$_LIBS"
1764 else
1765 AC_MSG_WARN([*** skipping thread test on Win32])
1766 fi
1767 fi
1768
1769 # If compiler will take -Wl,--as-needed (or various platform-specific
1770 # spellings thereof) then add that to LDFLAGS.  This is much easier than
1771 # trying to filter LIBS to the minimum for each executable.
1772 # (Note that shared library links won't use this switch, though.)
1773 # On (at least) some Red-Hat-derived systems, this switch breaks linking to
1774 # libreadline; therefore we postpone testing it until we know what library
1775 # dependencies readline has.  The test code will try to link with $LIBS.
1776 if test "$with_readline" = yes; then
1777   link_test_func=readline
1778 else
1779   link_test_func=exit
1780 fi
1781
1782 if test "$PORTNAME" = "darwin"; then
1783   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-dead_strip_dylibs], $link_test_func)
1784 elif test "$PORTNAME" = "openbsd"; then
1785   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-Bdynamic], $link_test_func)
1786 else
1787   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,--as-needed], $link_test_func)
1788 fi
1789
1790
1791 # Begin output steps
1792
1793 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
1794 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
1795 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
1796
1797 # Create compiler version string
1798 if test x"$GCC" = x"yes" ; then
1799   cc_string="GCC `${CC} --version | sed q`"
1800 elif test x"$SUN_STUDIO_CC" = x"yes" ; then
1801   cc_string=`${CC} -V 2>&1 | sed q`
1802 else
1803   cc_string=$CC
1804 fi
1805
1806 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
1807                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string, `expr $ac_cv_sizeof_void_p \* 8`-bit"],
1808                    [A string containing the version number, platform, and C compiler])
1809
1810 # Supply a numeric version string for use by 3rd party add-ons
1811 # awk -F is a regex on some platforms, and not on others, so make "." a tab
1812 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
1813 tr '.' '        ' |
1814 $AWK '{printf "%d%02d%02d", $1, $2, (NF >= 3) ? $3 : 0}'`"]
1815 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
1816
1817
1818 # prepare build tree if outside source tree
1819 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1820 # Note 2: /bin/pwd might be better than shell's built-in at getting
1821 #         a symlink-free name.
1822 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1823   vpath_build=no
1824 else
1825   vpath_build=yes
1826   if test "$no_create" != yes; then
1827     _AS_ECHO_N([preparing build tree... ])
1828     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1829     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1830       || AC_MSG_ERROR(failed)
1831     AC_MSG_RESULT(done)
1832   fi
1833 fi
1834 AC_SUBST(vpath_build)
1835
1836
1837 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1838
1839 AC_CONFIG_LINKS([
1840   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1841   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1842   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1843   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1844   src/include/pg_config_os.h:src/include/port/${template}.h
1845   src/Makefile.port:src/makefiles/Makefile.${template}
1846 ])
1847
1848 if test "$PORTNAME" = "win32"; then
1849 AC_CONFIG_COMMANDS([check_win32_symlinks],[
1850 # Links sometimes fail undetected on Mingw -
1851 # so here we detect it and warn the user
1852 for FILE in $CONFIG_LINKS
1853  do
1854         # test -e works for symlinks in the MinGW console
1855         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
1856  done
1857 ])
1858 fi
1859
1860 AC_CONFIG_HEADERS([src/include/pg_config.h],
1861 [
1862 # Update timestamp for pg_config.h (see Makefile.global)
1863 echo >src/include/stamp-h
1864 ])
1865
1866 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h],
1867                   [echo >src/interfaces/ecpg/include/stamp-h])
1868
1869 AC_OUTPUT