configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $PostgreSQL: pgsql/configure.in,v 1.501 2007/02/07 00:28:54 petere Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [8.3devel], [pgsql-bugs@postgresql.org])
  21
  22 AC_PREREQ(2.59)
  23 AC_COPYRIGHT([Copyright (c) 1996-2007, PostgreSQL Global Development Group])
  24 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  25 AC_CONFIG_AUX_DIR(config)
  26 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  27 AC_SUBST(configure_args, [$ac_configure_args])
  28
  29 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version as a string])
  30
  31 AC_CANONICAL_HOST
  32
  33 template=
  34 AC_MSG_CHECKING([which template to use])
  35
  36 PGAC_ARG_REQ(with, template, [],
  37 [
  38   case $withval in
  39     list)   echo; ls "$srcdir/src/template"; exit;;
  40     *)      if test -f "$srcdir/src/template/$with_template" ; then
  41               template=$withval
  42             else
  43               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  44             fi;;
  45   esac
  46 ],
  47 [
  48 # --with-template not given
  49
  50 case $host_os in
  51      aix*) template=aix ;;
  52     bsdi*) template=bsdi ;;
  53   cygwin*) template=cygwin ;;
  54   darwin*) template=darwin ;;
  55     dgux*) template=dgux ;;
  56  freebsd*) template=freebsd ;;
  57     hpux*) template=hpux ;;
  58     irix*) template=irix ;;
  59  linux*|gnu*|k*bsd*-gnu)
  60            template=linux ;;
  61    mingw*) template=win32 ;;
  62   netbsd*) template=netbsd ;;
  63 nextstep*) template=nextstep ;;
  64  openbsd*) template=openbsd ;;
  65      osf*) template=osf ;;
  66      sco*) template=sco ;;
  67  solaris*) template=solaris ;;
  68    sunos*) template=sunos4 ;;
  69  sysv4.2*)
  70         case $host_vendor in
  71           univel) template=univel ;;
  72         esac ;;
  73    sysv4*) template=svr4 ;;
  74    sysv5*) template=unixware ;;
  75   ultrix*) template=ultrix4 ;;
  76 esac
  77
  78   if test x"$template" = x"" ; then
  79     AC_MSG_ERROR([[
  80 *******************************************************************
  81 PostgreSQL has apparently not been ported to your platform yet.
  82 To try a manual configuration, look into the src/template directory
  83 for a similar platform and use the '--with-template=' option.
  84
  85 Please also contact <pgsql-ports@postgresql.org> to see about
  86 rectifying this.  Include the above 'checking host system type...'
  87 line.
  88 *******************************************************************
  89 ]])
  90   fi
  91
  92 ])
  93
  94 AC_MSG_RESULT([$template])
  95
  96 PORTNAME=$template
  97 AC_SUBST(PORTNAME)
  98
  99 # Initialize default assumption that we do not need separate assembly code
 100 # for TAS (test-and-set).  This can be overridden by the template file
 101 # when it's executed.
 102 need_tas=no
 103 tas_file=dummy.s
 104
 105
 106
 107 ##
 108 ## Command line options
 109 ##
 110
 111 #
 112 # Installation directory for documentation
 113 #
 114 PGAC_ARG(with, docdir, [  --with-docdir=DIR       install the documentation in DIR [[PREFIX/doc]]
 115   --without-docdir        do not install the documentation],
 116          [AC_MSG_ERROR([option --with-docdir requires an argument])],
 117          [docdir=],
 118          [docdir=$withval],
 119          [docdir='${prefix}/doc'])
 120 AC_SUBST(docdir)
 121
 122
 123 #
 124 # Add non-standard directories to the include path
 125 #
 126 PGAC_ARG_REQ(with, includes, [  --with-includes=DIRS    look for additional header files in DIRS])
 127
 128
 129 #
 130 # Add non-standard directories to the library search path
 131 #
 132 PGAC_ARG_REQ(with, libraries, [  --with-libraries=DIRS   look for additional libraries in DIRS],
 133              [LIBRARY_DIRS=$withval])
 134
 135 PGAC_ARG_REQ(with, libs,      [  --with-libs=DIRS        alternative spelling of --with-libraries],
 136              [LIBRARY_DIRS=$withval])
 137
 138
 139 #
 140 # 64-bit integer date/time storage (--enable-integer-datetimes)
 141 #
 142 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 143 PGAC_ARG_BOOL(enable, integer-datetimes, no, [  --enable-integer-datetimes  enable 64-bit integer date/time support],
 144               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 145                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 146 AC_MSG_RESULT([$enable_integer_datetimes])
 147
 148
 149 #
 150 # NLS
 151 #
 152 AC_MSG_CHECKING([whether NLS is wanted])
 153 PGAC_ARG_OPTARG(enable, nls,
 154                 [[  --enable-nls[=LANGUAGES]  enable Native Language Support]],
 155                 [],
 156                 [WANTED_LANGUAGES=$enableval],
 157                 [AC_DEFINE(ENABLE_NLS, 1,
 158                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 159 AC_MSG_RESULT([$enable_nls])
 160 AC_SUBST(enable_nls)
 161 AC_SUBST(WANTED_LANGUAGES)
 162
 163 #
 164 # Default port number (--with-pgport), default 5432
 165 #
 166 AC_MSG_CHECKING([for default port number])
 167 PGAC_ARG_REQ(with, pgport, [  --with-pgport=PORTNUM   change default port number [[5432]]],
 168              [default_port=$withval],
 169              [default_port=5432])
 170 AC_MSG_RESULT([$default_port])
 171 # Need both of these because some places want an integer and some a string
 172 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 173 [Define to the default TCP port number on which the server listens and
 174 to which clients will try to connect.  This can be overridden at run-time,
 175 but it's convenient if your clients have the right default compiled in.
 176 (--with-pgport=PORTNUM)])
 177 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 178                    [Define to the default TCP port number as a string constant.])
 179 AC_SUBST(default_port)
 180
 181 #
 182 # Option to disable shared libraries
 183 #
 184 PGAC_ARG_BOOL(enable, shared, yes,
 185               [  --disable-shared        do not build shared libraries])
 186 AC_SUBST(enable_shared)
 187
 188 #
 189 # '-rpath'-like feature can be disabled
 190 #
 191 PGAC_ARG_BOOL(enable, rpath, yes,
 192               [  --disable-rpath         do not embed shared library search path in executables])
 193 AC_SUBST(enable_rpath)
 194
 195 #
 196 # Spinlocks
 197 #
 198 PGAC_ARG_BOOL(enable, spinlocks, yes,
 199               [  --disable-spinlocks     do not use spinlocks])
 200
 201 #
 202 # --enable-debug adds -g to compiler flags
 203 #
 204 PGAC_ARG_BOOL(enable, debug, no,
 205               [  --enable-debug          build with debugging symbols (-g)])
 206 AC_SUBST(enable_debug)
 207
 208 #
 209 # DTrace
 210 #
 211 PGAC_ARG_BOOL(enable, dtrace, no,
 212               [  --enable-dtrace         build with DTrace support],
 213 [AC_DEFINE([ENABLE_DTRACE], 1,
 214            [Define to 1 to enable DTrace support. (--enable-dtrace)])
 215 AC_CHECK_PROGS(DTRACE, dtrace)
 216 if test -z "$DTRACE"; then
 217   AC_MSG_ERROR([dtrace not found])
 218 fi
 219 AC_SUBST(DTRACEFLAGS)])
 220 AC_SUBST(enable_dtrace)
 221
 222 #
 223 # C compiler
 224 #
 225
 226 # For historical reasons you can also use --with-CC to specify the C compiler
 227 # to use, although the standard way to do this is to set the CC environment
 228 # variable.
 229 PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
 230
 231 case $template in
 232   aix) pgac_cc_list="gcc xlc";;
 233  irix) pgac_cc_list="cc";; # no gcc
 234     *) pgac_cc_list="gcc cc";;
 235 esac
 236
 237 AC_PROG_CC([$pgac_cc_list])
 238
 239 unset CFLAGS
 240
 241 #
 242 # Read the template
 243 #
 244 . "$srcdir/src/template/$template" || exit
 245
 246 # CFLAGS are selected so:
 247 # If the user specifies something in the environment, that is used.
 248 # else:  If the template file set something, that is used.
 249 # else:  If the compiler is GCC, then we use -O2.
 250 # else:  If the compiler is something else, then we use -0.
 251
 252 if test "$ac_env_CFLAGS_set" = set; then
 253   CFLAGS=$ac_env_CFLAGS_value
 254 elif test "${CFLAGS+set}" = set; then
 255   : # (keep what template set)
 256 elif test "$GCC" = yes; then
 257   CFLAGS="-O2"
 258 else
 259   # if the user selected debug mode, don't use -O
 260   if test "$enable_debug" != yes; then
 261     CFLAGS="-O"
 262   fi
 263 fi
 264
 265 # Some versions of GCC support some additional useful warning flags.
 266 # Check whether they are supported, and add them to CFLAGS if so.
 267
 268 if test "$GCC" = yes; then
 269
 270 # ICC pretends to be GCC but it's lying; it doesn't support these options.
 271 # So we have to check if "GCC" is really ICC.
 272 AC_TRY_COMPILE([], [@%:@ifndef __INTEL_COMPILER
 273 choke me
 274 @%:@endif], [ICC=[yes]], [ICC=[no]])
 275
 276   if test "$ICC" = no; then
 277     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wpointer-arith -Winline"
 278
 279     PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 280     PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 281   else
 282     # Intel compiler has a bug/misoptimization in checking for
 283     # division by NAN (NaN == 0), -mp1 fixes it, so add it to the
 284     # CFLAGS.
 285     PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 286   fi
 287
 288   # Disable strict-aliasing rules; needed for gcc 3.3+
 289   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 290 elif test x"${CC}" = x"xlc"; then
 291   # AIX xlc has to have strict aliasing turned off too
 292   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 293 fi
 294
 295 # supply -g if --enable-debug
 296 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 297   CFLAGS="$CFLAGS -g"
 298 fi
 299
 300 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
 301
 302 # We already have this in Makefile.win32, but configure needs it too
 303 if test "$PORTNAME" = "win32"; then
 304   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 305 fi
 306
 307 # Check if the compiler still works with the template settings
 308 AC_MSG_CHECKING([whether the C compiler still works])
 309 AC_TRY_LINK([], [return 0;],
 310   [AC_MSG_RESULT(yes)],
 311   [AC_MSG_RESULT(no)
 312    AC_MSG_ERROR([cannot proceed])])
 313
 314 # Defend against gcc -ffast-math
 315 if test "$GCC" = yes; then
 316 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 317 choke me
 318 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 319 fi
 320
 321 AC_PROG_CPP
 322 AC_SUBST(GCC)
 323
 324 # Create compiler version string
 325 if test x"$GCC" = x"yes" ; then
 326   cc_string="GCC `${CC} --version | sed q`"
 327 else
 328   cc_string=$CC
 329 fi
 330 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
 331                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"],
 332                    [A string containing the version number, platform, and C compiler])
 333
 334
 335 #
 336 # Set up TAS assembly code if needed; the template file has now had its
 337 # chance to request this.
 338 #
 339 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 340
 341 if test "$need_tas" = yes ; then
 342   TAS=tas.o
 343 else
 344   TAS=""
 345 fi
 346 AC_SUBST(TAS)
 347
 348
 349 #
 350 # Automatic dependency tracking
 351 #
 352 PGAC_ARG_BOOL(enable, depend, no, [  --enable-depend         turn on automatic dependency tracking],
 353               [autodepend=yes])
 354 AC_SUBST(autodepend)
 355
 356
 357 #
 358 # Enable assert checks
 359 #
 360 PGAC_ARG_BOOL(enable, cassert, no, [  --enable-cassert        enable assertion checks (for debugging)],
 361               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 362                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 363
 364
 365 #
 366 # Include directories
 367 #
 368 ac_save_IFS=$IFS
 369 IFS="${IFS}${PATH_SEPARATOR}"
 370 # SRCH_INC comes from the template file
 371 for dir in $with_includes $SRCH_INC; do
 372   if test -d "$dir"; then
 373     INCLUDES="$INCLUDES -I$dir"
 374   else
 375     AC_MSG_WARN([*** Include directory $dir does not exist.])
 376   fi
 377 done
 378 IFS=$ac_save_IFS
 379 AC_SUBST(INCLUDES)
 380
 381
 382 #
 383 # Library directories
 384 #
 385 ac_save_IFS=$IFS
 386 IFS="${IFS}${PATH_SEPARATOR}"
 387 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 388 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 389   if test -d "$dir"; then
 390     LIBDIRS="$LIBDIRS -L$dir"
 391   else
 392     AC_MSG_WARN([*** Library directory $dir does not exist.])
 393   fi
 394 done
 395 IFS=$ac_save_IFS
 396
 397 #
 398 # Enable thread-safe client libraries
 399 #
 400 AC_MSG_CHECKING([allow thread-safe client libraries])
 401 PGAC_ARG_BOOL(enable, thread-safety, no, [  --enable-thread-safety  make client libraries thread-safe])
 402 PGAC_ARG_BOOL(enable, thread-safety-force, no, [  --enable-thread-safety-force  force thread-safety in spite of thread test failure])
 403 if test "$enable_thread_safety" = yes -o \
 404         "$enable_thread_safety_force" = yes; then
 405   enable_thread_safety="yes"    # for 'force'
 406   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 407           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 408 fi
 409 AC_MSG_RESULT([$enable_thread_safety])
 410 AC_SUBST(enable_thread_safety)
 411
 412 #
 413 # Optionally build Tcl modules (PL/Tcl)
 414 #
 415 AC_MSG_CHECKING([whether to build with Tcl])
 416 PGAC_ARG_BOOL(with, tcl, no, [  --with-tcl              build Tcl modules (PL/Tcl)])
 417 AC_MSG_RESULT([$with_tcl])
 418 AC_SUBST([with_tcl])
 419
 420 # We see if the path to the Tcl/Tk configuration scripts is specified.
 421 # This will override the use of tclsh to find the paths to search.
 422
 423 PGAC_ARG_REQ(with, tclconfig, [  --with-tclconfig=DIR    tclConfig.sh is in DIR])
 424
 425 #
 426 # Optionally build Perl modules (PL/Perl)
 427 #
 428 AC_MSG_CHECKING([whether to build Perl modules])
 429 PGAC_ARG_BOOL(with, perl, no, [  --with-perl             build Perl modules (PL/Perl)])
 430 AC_MSG_RESULT([$with_perl])
 431 AC_SUBST(with_perl)
 432
 433 #
 434 # Optionally build Python modules (PL/Python)
 435 #
 436 AC_MSG_CHECKING([whether to build Python modules])
 437 PGAC_ARG_BOOL(with, python, no, [  --with-python           build Python modules (PL/Python)])
 438 AC_MSG_RESULT([$with_python])
 439 AC_SUBST(with_python)
 440
 441 #
 442 # Kerberos 5
 443 #
 444 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 445 PGAC_ARG_BOOL(with, krb5, no, [  --with-krb5             build with Kerberos 5 support],
 446 [
 447   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 448   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 449 ])
 450 AC_MSG_RESULT([$with_krb5])
 451 AC_SUBST(with_krb5)
 452
 453
 454 AC_SUBST(krb_srvtab)
 455
 456
 457 #
 458 # Kerberos configuration parameters
 459 #
 460 PGAC_ARG_REQ(with, krb-srvnam,
 461              [  --with-krb-srvnam=NAME  name of the default service principal in Kerberos [[postgres]]],
 462              [],
 463              [with_krb_srvnam="postgres"])
 464 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 465                    [Define to the name of the default PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 466
 467
 468 #
 469 # PAM
 470 #
 471 AC_MSG_CHECKING([whether to build with PAM support])
 472 PGAC_ARG_BOOL(with, pam, no,
 473               [  --with-pam              build with PAM support],
 474               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 475 AC_MSG_RESULT([$with_pam])
 476 AC_SUBST(with_pam)
 477
 478
 479 #
 480 # LDAP
 481 #
 482 AC_MSG_CHECKING([whether to build with LDAP support])
 483 PGAC_ARG_BOOL(with, ldap, no,
 484               [  --with-ldap             build with LDAP support],
 485               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 486 AC_MSG_RESULT([$with_ldap])
 487 AC_SUBST(with_ldap)
 488
 489
 490 #
 491 # Bonjour
 492 #
 493 AC_MSG_CHECKING([whether to build with Bonjour support])
 494 PGAC_ARG_BOOL(with, bonjour, no,
 495               [  --with-bonjour          build with Bonjour support],
 496               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 497 AC_MSG_RESULT([$with_bonjour])
 498 AC_SUBST(with_bonjour)
 499
 500
 501 #
 502 # OpenSSL
 503 #
 504 AC_MSG_CHECKING([whether to build with OpenSSL support])
 505 PGAC_ARG_BOOL(with, openssl, no, [  --with-openssl          build with OpenSSL support],
 506               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 507 AC_MSG_RESULT([$with_openssl])
 508 AC_SUBST(with_openssl)
 509
 510
 511 #
 512 # Readline
 513 #
 514 PGAC_ARG_BOOL(with, readline, yes,
 515               [  --without-readline      do not use GNU Readline nor BSD Libedit for editing])
 516 # readline on MinGW has problems with backslashes in psql and other bugs.
 517 # This is particularly a problem with non-US code pages.
 518 # Therefore disable its use until we understand the cause. 2004-07-20
 519 if test "$PORTNAME" = "win32"; then
 520   if test "$with_readline" = yes; then
 521     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 522     with_readline=no
 523   fi
 524 fi
 525
 526
 527 #
 528 # Prefer libedit
 529 #
 530 PGAC_ARG_BOOL(with, libedit-preferred, no,
 531               [  --with-libedit-preferred  prefer BSD Libedit over GNU Readline])
 532
 533
 534 #
 535 # XML
 536 #
 537 PGAC_ARG_BOOL(with, libxml, no, [  --with-libxml           build with XML support],
 538               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 539
 540 if test "$with_libxml" = yes ; then
 541   AC_CHECK_PROGS(XML2_CONFIG, xml2-config)
 542   if test -n "$XML2_CONFIG"; then
 543     for pgac_option in `$XML2_CONFIG --cflags`; do
 544       case $pgac_option in
 545         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 546       esac
 547     done
 548     for pgac_option in `$XML2_CONFIG --libs`; do
 549       case $pgac_option in
 550         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 551       esac
 552     done
 553   fi
 554 fi
 555
 556
 557 #
 558 # Zlib
 559 #
 560 PGAC_ARG_BOOL(with, zlib, yes,
 561               [  --without-zlib          do not use Zlib])
 562 AC_SUBST(with_zlib)
 563
 564 #
 565 # Elf
 566 #
 567
 568 # Assume system is ELF if it predefines __ELF__ as 1,
 569 # otherwise believe host_os based default.
 570 case $host_os in
 571     freebsd1*|freebsd2*) elf=no;;
 572     freebsd3*|freebsd4*) elf=yes;;
 573 esac
 574
 575 AC_EGREP_CPP(yes,
 576 [#if __ELF__
 577   yes
 578 #endif
 579 ],
 580 [ELF_SYS=true],
 581 [if test "X$elf" = "Xyes" ; then
 582   ELF_SYS=true
 583 else
 584   ELF_SYS=
 585 fi])
 586 AC_SUBST(ELF_SYS)
 587
 588 #
 589 # Assignments
 590 #
 591
 592 CPPFLAGS="$CPPFLAGS $INCLUDES"
 593 LDFLAGS="$LDFLAGS $LIBDIRS"
 594
 595 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
 596 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
 597
 598 AC_ARG_VAR(LDFLAGS_SL)
 599
 600 AC_PROG_AWK
 601 PGAC_PATH_FLEX
 602 AC_PROG_LN_S
 603 PGAC_PROG_LD
 604 AC_SUBST(LD)
 605 AC_SUBST(with_gnu_ld)
 606 case $host_os in sysv5*)
 607   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 608   [
 609     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 610     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 611     LDFLAGS=$pgac_save_LDFLAGS
 612   ])
 613   ld_R_works=$pgac_cv_prog_ld_R
 614   AC_SUBST(ld_R_works)
 615 esac
 616 AC_PROG_RANLIB
 617 AC_PATH_PROG(TAR, tar)
 618 PGAC_CHECK_STRIP
 619
 620 if test -z "$YACC"; then
 621   AC_CHECK_PROGS(YACC, ['bison -y'])
 622
 623   if test "$YACC"; then
 624     if $YACC --version | sed q | $AWK '{ if ($4 < 1.875) exit 0; else exit 1;}'; then
 625       AC_MSG_WARN([
 626 *** The installed version of Bison is too old to use with PostgreSQL.
 627 *** Bison version 1.875 or later is required.])
 628       YACC=""
 629     fi
 630   fi
 631
 632   if test -z "$YACC"; then
 633     AC_MSG_WARN([
 634 *** Without Bison you will not be able to build PostgreSQL from CVS nor
 635 *** change any of the parser definition files.  You can obtain Bison from
 636 *** a GNU mirror site.  (If you are using the official distribution of
 637 *** PostgreSQL then you do not need to worry about this, because the Bison
 638 *** output is pre-generated.)  To use a different yacc program (possible,
 639 *** but not recommended), set the environment variable YACC before running
 640 *** 'configure'.])
 641   fi
 642 fi
 643 AC_SUBST(YFLAGS)
 644
 645 PGAC_PATH_PERL
 646 if test "$with_perl" = yes; then
 647   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 648   PGAC_CHECK_PERL_EMBED_LDFLAGS
 649 fi
 650
 651 if test "$with_python" = yes; then
 652   PGAC_PATH_PYTHON
 653   PGAC_CHECK_PYTHON_EMBED_SETUP
 654 fi
 655
 656 # Supply a numeric version string for use by 3rd party add-ons
 657 # awk -F is a regex on some platforms, and not on others, so make "." a tab
 658 PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
 659 tr '.' '        ' |
 660 $AWK '{printf \"%d%02d%02d\", $1, $2, (NF >= 3) ? $3 : 0}'`"
 661 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
 662
 663 ##
 664 ## Libraries
 665 ##
 666 ## Most libraries are included only if they demonstrably provide a function
 667 ## we need, but libm is an exception: always include it, because there are
 668 ## too many compilers that play cute optimization games that will break
 669 ## probes for standard functions such as pow().
 670 ##
 671
 672 AC_CHECK_LIB(m, main)
 673 AC_SEARCH_LIBS(setproctitle, util)
 674 AC_SEARCH_LIBS(dlopen, dl)
 675 AC_SEARCH_LIBS(socket, [socket wsock32])
 676 AC_SEARCH_LIBS(shl_load, dld)
 677 # We only use libld in port/dynloader/aix.c
 678 case $host_os in
 679      aix*)
 680         AC_SEARCH_LIBS(ldopen, ld)
 681         ;;
 682 esac
 683 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 684 AC_SEARCH_LIBS(crypt, crypt)
 685 # Solaris:
 686 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 687 # Cygwin:
 688 AC_SEARCH_LIBS(shmget, cygipc)
 689
 690 if test "$with_readline" = yes; then
 691   PGAC_CHECK_READLINE
 692   if test x"$pgac_cv_check_readline" = x"no"; then
 693     AC_MSG_ERROR([readline library not found
 694 If you have readline already installed, see config.log for details on the
 695 failure.  It is possible the compiler isn't looking in the proper directory.
 696 Use --without-readline to disable readline support.])
 697   fi
 698 fi
 699
 700 if test "$with_zlib" = yes; then
 701   AC_CHECK_LIB(z, inflate, [],
 702                [AC_MSG_ERROR([zlib library not found
 703 If you have zlib already installed, see config.log for details on the
 704 failure.  It is possible the compiler isn't looking in the proper directory.
 705 Use --without-zlib to disable zlib support.])])
 706 fi
 707
 708 if test "$enable_spinlocks" = yes; then
 709   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 710 else
 711   AC_MSG_WARN([
 712 *** Not using spinlocks will cause poor performance.])
 713 fi
 714
 715 if test "$with_krb5" = yes ; then
 716   if test "$PORTNAME" != "win32"; then
 717      AC_SEARCH_LIBS(com_err, [krb5 'krb5 -ldes -lasn1 -lroken' com_err], [],
 718                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 719      AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -ldes -lasn1 -lroken'], [],
 720                     [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 721   else
 722      AC_SEARCH_LIBS(com_err, 'comerr32 -lkrb5_32', [],
 723                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 724   fi
 725 fi
 726
 727 if test "$with_openssl" = yes ; then
 728   dnl Order matters!
 729   if test "$PORTNAME" != "win32"; then
 730      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 731      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 732   else
 733      AC_CHECK_LIB(eay32, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'eay32' is required for OpenSSL])])
 734      AC_CHECK_LIB(ssleay32,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssleay32' is required for OpenSSL])])
 735   fi
 736 fi
 737
 738 if test "$with_pam" = yes ; then
 739   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 740 fi
 741
 742 if test "$with_libxml" = yes ; then
 743   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
 744 fi
 745
 746
 747 ##
 748 ## Header files
 749 ##
 750
 751 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 752 AC_CHECK_HEADERS([crypt.h dld.h endian.h fp_class.h getopt.h ieeefp.h langinfo.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/time.h sys/un.h termios.h utime.h wchar.h wctype.h kernel/OS.h kernel/image.h SupportDefs.h])
 753
 754 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 755 # netinet/in.h is included first.
 756 AC_CHECK_HEADERS(netinet/in.h)
 757 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 758 [AC_INCLUDES_DEFAULT
 759 #ifdef HAVE_NETINET_IN_H
 760 #include <netinet/in.h>
 761 #endif
 762 ])
 763
 764 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
 765   AC_CHECK_HEADERS(readline/readline.h, [],
 766         [AC_CHECK_HEADERS(readline.h, [],
 767                 [AC_MSG_ERROR([readline header not found
 768 If you have readline already installed, see config.log for details on the
 769 failure.  It is possible the compiler isn't looking in the proper directory.
 770 Use --without-readline to disable readline support.])])])
 771   AC_CHECK_HEADERS(readline/history.h, [],
 772         [AC_CHECK_HEADERS(history.h, [],
 773                 [AC_MSG_ERROR([history header not found
 774 If you have readline already installed, see config.log for details on the
 775 failure.  It is possible the compiler isn't looking in the proper directory.
 776 Use --without-readline to disable readline support.])])])
 777 fi
 778
 779 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
 780 # Some installations of libedit usurp /usr/include/readline/, which seems
 781 # bad practice, since in combined installations readline will have its headers
 782 # there.  We might have to resort to AC_EGREP checks to make sure we found
 783 # the proper header...
 784   AC_CHECK_HEADERS(editline/readline.h, [],
 785         [AC_CHECK_HEADERS(readline.h, [],
 786                 [AC_CHECK_HEADERS(readline/readline.h, [],
 787                         [AC_MSG_ERROR([readline header not found
 788 If you have libedit already installed, see config.log for details on the
 789 failure.  It is possible the compiler isn't looking in the proper directory.
 790 Use --without-readline to disable libedit support.])])])])
 791 # Note: in a libedit installation, history.h is sometimes a dummy, and may
 792 # not be there at all.  Hence, don't complain if not found.  We must check
 793 # though, since in yet other versions it is an independent header.
 794   AC_CHECK_HEADERS(editline/history.h, [],
 795         [AC_CHECK_HEADERS(history.h, [],
 796                 [AC_CHECK_HEADERS(readline/history.h)])])
 797 fi
 798
 799 if test "$with_zlib" = yes; then
 800   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
 801 If you have zlib already installed, see config.log for details on the
 802 failure.  It is possible the compiler isn't looking in the proper directory.
 803 Use --without-zlib to disable zlib support.])])
 804 fi
 805
 806 if test "$with_krb5" = yes ; then
 807   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
 808 fi
 809
 810 if test "$with_openssl" = yes ; then
 811   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
 812   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
 813 fi
 814
 815 if test "$with_pam" = yes ; then
 816   AC_CHECK_HEADERS(security/pam_appl.h, [],
 817                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
 818                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
 819 fi
 820
 821 if test "$with_libxml" = yes ; then
 822   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
 823 fi
 824
 825 if test "$with_ldap" = yes ; then
 826   if test "$PORTNAME" != "win32"; then
 827      AC_CHECK_HEADERS(ldap.h, [],
 828                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
 829   else
 830      AC_CHECK_HEADERS(winldap.h, [],
 831                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
 832                       [AC_INCLUDES_DEFAULT
 833 #include <windows.h>
 834                       ])
 835   fi
 836 fi
 837
 838 if test "$with_bonjour" = yes ; then
 839   AC_CHECK_HEADER(DNSServiceDiscovery/DNSServiceDiscovery.h, [], [AC_MSG_ERROR([header file <DNSServiceDiscovery/DNSServiceDiscovery.h> is required for Bonjour])])
 840 fi
 841
 842
 843 ##
 844 ## Types, structures, compiler characteristics
 845 ##
 846
 847 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
 848 AC_C_CONST
 849 AC_C_INLINE
 850 AC_C_STRINGIZE
 851 PGAC_C_SIGNED
 852 AC_C_VOLATILE
 853 PGAC_C_FUNCNAME_SUPPORT
 854 PGAC_STRUCT_TIMEZONE
 855 PGAC_UNION_SEMUN
 856 PGAC_STRUCT_SOCKADDR_UN
 857 PGAC_STRUCT_SOCKADDR_STORAGE
 858 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
 859 PGAC_STRUCT_ADDRINFO
 860
 861 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
 862 [#include <sys/param.h>
 863 #include <sys/types.h>
 864 #include <sys/socket.h>
 865 #include <sys/ucred.h>])
 866
 867 AC_CHECK_TYPES([struct option], [], [],
 868 [#ifdef HAVE_GETOPT_H
 869 #include <getopt.h>
 870 #endif])
 871
 872 if test "$with_zlib" = yes; then
 873   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
 874   # did not).  While we could work around the lack of z_streamp, it
 875   # seems unwise to encourage people to use such old zlib versions...
 876   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
 877 Use --without-zlib to disable zlib support.])],
 878                 [#include <zlib.h>])
 879 fi
 880
 881 if test "$with_krb5" = yes; then
 882 # Check for differences between MIT and Heimdal (KTH) releases
 883   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
 884                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
 885                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
 886                                      [#include <krb5.h>])],
 887                    [#include <krb5.h>])
 888   AC_CHECK_MEMBERS(krb5_error.text.data, [],
 889                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
 890                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
 891                                      [#include <krb5.h>])],
 892                    [#include <krb5.h>])
 893 fi
 894
 895
 896 ##
 897 ## Functions, global variables
 898 ##
 899
 900 PGAC_VAR_INT_TIMEZONE
 901 AC_FUNC_ACCEPT_ARGTYPES
 902 PGAC_FUNC_GETTIMEOFDAY_1ARG
 903
 904 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid getrlimit memmove poll pstat readlink setproctitle setsid sigprocmask symlink sysconf towlower utime utimes waitpid wcstombs])
 905
 906 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 907 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
 908 AC_CHECK_DECLS([strlcat, strlcpy])
 909 # This is probably only present on Darwin, but may as well check always
 910 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
 911
 912 HAVE_IPV6=no
 913 AC_CHECK_TYPE([struct sockaddr_in6],
 914         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
 915          HAVE_IPV6=yes],
 916         [],
 917 [$ac_includes_default
 918 #include <netinet/in.h>])
 919 AC_SUBST(HAVE_IPV6)
 920
 921 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
 922 [AC_TRY_LINK(
 923 [#include <machine/vmparam.h>
 924 #include <sys/exec.h>
 925 ],
 926 [PS_STRINGS->ps_nargvstr = 1;
 927 PS_STRINGS->ps_argvstr = "foo";],
 928 [pgac_cv_var_PS_STRINGS=yes],
 929 [pgac_cv_var_PS_STRINGS=no])])
 930 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
 931   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
 932 fi
 933
 934
 935 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
 936 # is missing.  Yes, there are machines that have only one.  We may
 937 # also decide to use snprintf.c if snprintf() is present but does not
 938 # have all the features we need --- see below.
 939
 940 if test "$PORTNAME" = "win32"; then
 941   # Win32 gets snprintf.c built unconditionally.
 942   #
 943   # To properly translate all NLS languages strings, we must support the
 944   # *printf() %$ format, which allows *printf() arguments to be selected
 945   # by position in the translated string.
 946   #
 947   # libintl versions < 0.13 use the native *printf() functions, and Win32
 948   # *printf() doesn't understand %$, so we must use our /port versions,
 949   # which do understand %$. libintl versions >= 0.13 include their own
 950   # *printf versions on Win32.  The libintl 0.13 release note text is:
 951   #
 952   #   C format strings with positions, as they arise when a translator
 953   #   needs to reorder a sentence, are now supported on all platforms.
 954   #   On those few platforms (NetBSD and Woe32) for which the native
 955   #   printf()/fprintf()/... functions don't support such format
 956   #   strings, replacements are provided through <libintl.h>.
 957   #
 958   # We could use libintl >= 0.13's *printf() if we were sure that we had
 959   # a litint >= 0.13 at runtime, but seeing that there is no clean way
 960   # to guarantee that, it is best to just use our own, so we are sure to
 961   # get %$ support. In include/port.h we disable the *printf() macros
 962   # that might have been defined by libintl.
 963   #
 964   # We do this unconditionally whether NLS is used or not so we are sure
 965   # that all Win32 libraries and binaries behave the same.
 966   pgac_need_repl_snprintf=yes
 967 else
 968   pgac_need_repl_snprintf=no
 969   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
 970   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
 971 fi
 972
 973
 974 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
 975 # include/c.h will provide declarations.  Note this is a separate test
 976 # from whether the functions exist in the C library --- there are
 977 # systems that have the functions but don't bother to declare them :-(
 978
 979 AC_CHECK_DECLS([snprintf, vsnprintf])
 980
 981
 982 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
 983 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
 984 [AC_TRY_LINK([
 985 #include <math.h>
 986 double glob_double;
 987 ],
 988 [return isinf(glob_double) ? 0 : 1;],
 989 [ac_cv_func_isinf=yes],
 990 [ac_cv_func_isinf=no])])
 991
 992 if test $ac_cv_func_isinf = yes ; then
 993   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
 994 else
 995   AC_LIBOBJ(isinf)
 996   # Look for a way to implement a substitute for isinf()
 997   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
 998 fi
 999
1000 # Some versions of libedit contain strlcpy(); so disregard that library while
1001 # checking for these standard libc functions.
1002 pgac_save_LIBS="$LIBS"
1003 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1004
1005 AC_REPLACE_FUNCS([crypt fseeko getopt getrusage inet_aton random rint srandom strdup strerror strlcat strlcpy strtol strtoul unsetenv])
1006
1007 LIBS="$pgac_save_LIBS"
1008
1009 # System's version of getaddrinfo(), if any, may be used only if we found
1010 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1011 # (Note: the AC_REPLACE_FUNCS probe fails on Windows, where the available
1012 # versions of getaddrinfo don't follow normal C call protocol.  This is OK
1013 # because we want to use our own getaddrinfo.c on Windows anyway.)
1014 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
1015   AC_REPLACE_FUNCS([getaddrinfo])
1016 else
1017   AC_LIBOBJ(getaddrinfo)
1018 fi
1019
1020 # similarly, use system's getopt_long() only if system provides struct option.
1021 if test x"$ac_cv_type_struct_option" = xyes ; then
1022   AC_REPLACE_FUNCS([getopt_long])
1023 else
1024   AC_LIBOBJ(getopt_long)
1025 fi
1026
1027 # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
1028 # We override the previous test that said fseeko/ftello didn't exist
1029 # OS tests are also done in include/c.h and port/fseeko.c
1030 case $host_os in bsdi*|netbsd*)
1031 ac_cv_func_fseeko=yes
1032 esac
1033
1034 # Win32 support
1035 if test "$PORTNAME" = "win32"; then
1036 AC_LIBOBJ(gettimeofday)
1037 AC_LIBOBJ(kill)
1038 AC_LIBOBJ(open)
1039 AC_LIBOBJ(rand)
1040 AC_LIBOBJ(win32error)
1041 AC_DEFINE([HAVE_SYMLINK], 1,
1042           [Define to 1 if you have the `symlink' function.])
1043 fi
1044
1045 if test "$with_readline" = yes; then
1046   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1047   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
1048   AC_CHECK_FUNCS([replace_history_entry])
1049 fi
1050
1051
1052 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
1053 dnl (especially on GNU libc)
1054 dnl See also comments in c.h.
1055 AC_MSG_CHECKING(for sigsetjmp)
1056 AC_TRY_LINK([#include <setjmp.h>],
1057             [sigjmp_buf x; sigsetjmp(x, 1);],
1058             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
1059 AC_MSG_RESULT(yes)],
1060             [AC_MSG_RESULT(no)])
1061
1062 AC_DECL_SYS_SIGLIST
1063
1064 AC_CHECK_FUNC(syslog,
1065               [AC_CHECK_HEADER(syslog.h,
1066                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1067
1068 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1069 [AC_TRY_LINK([#include <unistd.h>],
1070   [extern int optreset; optreset = 1;],
1071   [pgac_cv_var_int_optreset=yes],
1072   [pgac_cv_var_int_optreset=no])])
1073 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1074   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1075 fi
1076
1077 AC_CHECK_FUNCS([strtoll strtoq], [break])
1078 AC_CHECK_FUNCS([strtoull strtouq], [break])
1079
1080 # Check for one of atexit() or on_exit()
1081 AC_CHECK_FUNCS(atexit, [],
1082                [AC_CHECK_FUNCS(on_exit, [],
1083                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
1084
1085 AC_FUNC_FSEEKO
1086
1087 #
1088 # Pthreads
1089 #
1090 # For each platform, we need to know about any special compile and link
1091 # libraries, and whether the normal C function names are thread-safe.
1092 # See the comment at the top of src/port/thread.c for more information.
1093 #
1094 if test "$enable_thread_safety" = yes; then
1095 ACX_PTHREAD     # set thread flags
1096
1097 # Some platforms use these, so just defineed them.  They can't hurt if they
1098 # are not supported.
1099 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1100
1101
1102 # At this point, we don't want to muck with the compiler name for threading.
1103 # Let's see who fails, perhaps AIX.  2004-04-23
1104 if test "$PTHREAD_CC" != "$CC"; then
1105 AC_MSG_ERROR([
1106 PostgreSQL does not support platforms that require a special compiler
1107 for thread safety.])
1108 fi
1109
1110 if test "$THREAD_SUPPORT" = no; then
1111 AC_MSG_ERROR([cannot enable threads on this platform
1112 This platform is known to not support thread-safe programs.  For details,
1113 compile and run src/bin/pg_thread_test.])
1114 fi
1115
1116 # Check for *_r functions
1117 _CFLAGS="$CFLAGS"
1118 _LIBS="$LIBS"
1119 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1120 LIBS="$LIBS $PTHREAD_LIBS"
1121
1122 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([pthread.h not found, required for --enable-thread-safety])])
1123
1124 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1125
1126 # Do test here with the proper thread flags
1127 PGAC_FUNC_GETPWUID_R_5ARG
1128 PGAC_FUNC_STRERROR_R_INT
1129
1130 CFLAGS="$_CFLAGS"
1131 LIBS="$_LIBS"
1132
1133 else
1134 # do not use values from template file
1135 PTHREAD_CFLAGS=
1136 PTHREAD_LIBS=
1137 fi
1138
1139 AC_SUBST(PTHREAD_CFLAGS)
1140 AC_SUBST(PTHREAD_LIBS)
1141
1142
1143 # We can test for libldap_r only after we know PTHREAD_LIBS
1144 if test "$with_ldap" = yes ; then
1145   _LIBS="$LIBS"
1146   if test "$PORTNAME" != "win32"; then
1147     AC_CHECK_LIB(ldap, ldap_bind, [],
1148                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1149                  [$EXTRA_LDAP_LIBS])
1150     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1151     if test "$enable_thread_safety" = yes; then
1152       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1153       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1154                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1155                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1156       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1157     else
1158       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1159     fi
1160   else
1161     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1162     LDAP_LIBS_FE="-lwldap32"
1163     LDAP_LIBS_BE="-lwldap32"
1164   fi
1165   LIBS="$_LIBS"
1166 fi
1167 AC_SUBST(LDAP_LIBS_FE)
1168 AC_SUBST(LDAP_LIBS_BE)
1169
1170
1171 # This test makes sure that run tests work at all.  Sometimes a shared
1172 # library is found by the linker, but the runtime linker can't find it.
1173 # This check should come after all modifications of compiler or linker
1174 # variables, and before any other run tests.
1175 AC_MSG_CHECKING([test program])
1176 AC_TRY_RUN([int main() { return 0; }],
1177 [AC_MSG_RESULT(ok)],
1178 [AC_MSG_RESULT(failed)
1179 AC_MSG_ERROR([[
1180 Could not execute a simple test program.  This may be a problem
1181 related to locating shared libraries.  Check the file 'config.log'
1182 for the exact reason.]])],
1183 [AC_MSG_RESULT([cross-compiling])])
1184
1185 # --------------------
1186 # Run tests below here
1187 # --------------------
1188
1189 # Force use of our snprintf if system's doesn't do arg control
1190 # See comment above at snprintf test for details.
1191 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1192   PGAC_FUNC_PRINTF_ARG_CONTROL
1193   if test $pgac_cv_printf_arg_control != yes ; then
1194     pgac_need_repl_snprintf=yes
1195   fi
1196 fi
1197
1198
1199 dnl Check to see if we have a working 64-bit integer type.
1200 dnl This breaks down into two steps:
1201 dnl (1) figure out if the compiler has a 64-bit int type with working
1202 dnl arithmetic, and if so
1203 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1204 dnl snprintf is the only library routine we really need for int8 support.)
1205 dnl It's entirely possible to have a compiler that handles a 64-bit type
1206 dnl when the C library doesn't; this is fairly likely when using gcc on
1207 dnl an older platform, for example.
1208 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1209 dnl we force our own version of snprintf() to be used instead.
1210 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1211
1212 PGAC_TYPE_64BIT_INT([long int])
1213
1214 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1215   PGAC_TYPE_64BIT_INT([long long int])
1216 fi
1217
1218
1219 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1220
1221 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1222   AC_TRY_COMPILE([
1223 #define INT64CONST(x)  x##LL
1224 long long int foo = INT64CONST(0x1234567890123456);
1225 ],
1226         [],
1227         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1228         [])
1229 fi
1230
1231
1232 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1233 # we found we need to use "long long int", better check.  We cope with
1234 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1235 # work, fall back to our own snprintf emulation (which we know uses %lld).
1236
1237 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1238   if test $pgac_need_repl_snprintf = no; then
1239     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1240     if test "$LONG_LONG_INT_FORMAT" = ""; then
1241       # Force usage of our own snprintf, since system snprintf is broken
1242       pgac_need_repl_snprintf=yes
1243       LONG_LONG_INT_FORMAT='%lld'
1244     fi
1245   else
1246     # Here if we previously decided we needed to use our own snprintf
1247     LONG_LONG_INT_FORMAT='%lld'
1248   fi
1249   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1250   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1251   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1252 else
1253   # Here if we are not using 'long long int' at all
1254   INT64_FORMAT='"%ld"'
1255   UINT64_FORMAT='"%lu"'
1256 fi
1257
1258 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1259                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1260
1261 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1262                    [Define to the appropriate snprintf format for unsigned 64-bit ints, if any.])
1263
1264 # Now we have checked all the reasons to replace snprintf
1265 if test $pgac_need_repl_snprintf = yes; then
1266   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1267   AC_LIBOBJ(snprintf)
1268 fi
1269
1270 # Need a #define for the size of Datum (unsigned long)
1271 AC_CHECK_SIZEOF([unsigned long])
1272
1273 # And one for the size of size_t (enables tweaks for > 32bit address space)
1274 AC_CHECK_SIZEOF([size_t])
1275
1276 # Determine memory alignment requirements for the basic C data types.
1277
1278 PGAC_CHECK_ALIGNOF(short)
1279 PGAC_CHECK_ALIGNOF(int)
1280 PGAC_CHECK_ALIGNOF(long)
1281 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1282   PGAC_CHECK_ALIGNOF(long long int)
1283 fi
1284 PGAC_CHECK_ALIGNOF(double)
1285
1286 # Compute maximum alignment of any basic type.
1287 # We assume long's alignment is at least as strong as char, short, or int;
1288 # but we must check long long (if it exists) and double.
1289
1290 MAX_ALIGNOF=$pgac_cv_alignof_long
1291 if test $MAX_ALIGNOF -lt $pgac_cv_alignof_double ; then
1292   MAX_ALIGNOF=$pgac_cv_alignof_double
1293 fi
1294 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $pgac_cv_alignof_long_long_int ; then
1295   MAX_ALIGNOF="$pgac_cv_alignof_long_long_int"
1296 fi
1297 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1298
1299
1300 # Some platforms predefine the types int8, int16, etc.  Only check
1301 # a (hopefully) representative subset.
1302 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1303 [#include <stdio.h>
1304 #ifdef HAVE_SUPPORTDEFS_H
1305 #include <SupportDefs.h>
1306 #endif])
1307
1308 # We also check for sig_atomic_t, which *should* be defined per ANSI
1309 # C, but is missing on some old platforms.
1310 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1311
1312
1313 if test x"$template" != x"win32"
1314 then
1315 PGAC_FUNC_POSIX_SIGNALS
1316 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1317   AC_MSG_ERROR([
1318 Thread-safety requires POSIX signals, which are not supported by this
1319 operating system.])
1320 fi
1321 fi
1322
1323 if test $ac_cv_func_fseeko = yes; then
1324 AC_SYS_LARGEFILE
1325 fi
1326
1327 # SunOS doesn't handle negative byte comparisons properly with +/- return
1328 AC_FUNC_MEMCMP
1329
1330
1331 # Select semaphore implementation type.
1332 if test "$PORTNAME" != "win32"; then
1333   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1334     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1335     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1336   else
1337     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1338       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1339       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1340     else
1341       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1342       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1343     fi
1344   fi
1345 else
1346   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1347   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1348 fi
1349
1350
1351 # Select shared-memory implementation type.
1352 AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1353 SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1354
1355
1356 # If not set in template file, set bytes to use libc memset()
1357 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
1358   MEMSET_LOOP_LIMIT=1024
1359 fi
1360 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
1361
1362
1363 if test "$enable_nls" = yes ; then
1364   PGAC_CHECK_GETTEXT
1365 fi
1366
1367 # Check for Tcl configuration script tclConfig.sh
1368 if test "$with_tcl" = yes; then
1369     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1370     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1371                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1372     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1373     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1374     ac_save_CPPFLAGS=$CPPFLAGS
1375     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1376     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1377     CPPFLAGS=$ac_save_CPPFLAGS
1378 fi
1379
1380 #
1381 # Check for DocBook and tools
1382 #
1383 PGAC_PROG_NSGMLS
1384 PGAC_PROG_JADE
1385 PGAC_CHECK_DOCBOOK(4.2)
1386 PGAC_PATH_DOCBOOK_STYLESHEETS
1387 PGAC_PATH_COLLATEINDEX
1388 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1389
1390 # Thread testing
1391
1392 # We have to run the thread test near the end so we have all our symbols
1393 # defined.  Cross compiling throws a warning.
1394 #
1395 if test "$enable_thread_safety_force" = yes; then
1396 if test x"$template" != x"win32"
1397 then
1398   AC_MSG_WARN([
1399 *** Skipping thread test program.  --enable-thread-safety-force was used.
1400 *** Run the program in src/test/thread on the your machine and add proper
1401 *** locking function calls to your applications to guarantee thread safety.
1402 ])
1403 else
1404 AC_MSG_WARN([*** skipping thread test on Win32])
1405 fi
1406 elif test "$enable_thread_safety" = yes; then
1407 if test x"$template" != x"win32"
1408 then
1409 AC_MSG_CHECKING([thread safety of required library functions])
1410
1411 _CFLAGS="$CFLAGS"
1412 _LIBS="$LIBS"
1413 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1414 LIBS="$LIBS $PTHREAD_LIBS"
1415 AC_TRY_RUN([#include "$srcdir/src/test/thread/thread_test.c"],
1416   [AC_MSG_RESULT(yes)],
1417   [AC_MSG_RESULT(no)
1418   AC_MSG_ERROR([thread test program failed
1419 This platform is not thread-safe.  Check the file 'config.log'for the
1420 exact reason.
1421
1422 You can use the configure option --enable-thread-safety-force to force
1423 threads to be enabled.  But you must then run the program in
1424 src/test/thread and add locking function calls to your applications to
1425 guarantee thread safety.])],
1426   [AC_MSG_RESULT(maybe)
1427   AC_MSG_WARN([
1428 *** Skipping thread test program because of cross-compile build.
1429 *** Run the program in src/test/thread on the target machine.
1430 ])])
1431 CFLAGS="$_CFLAGS"
1432 LIBS="$_LIBS"
1433 else
1434 AC_MSG_WARN([*** skipping thread test on Win32])
1435 fi
1436 fi
1437
1438 # prepare build tree if outside source tree
1439 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1440 # Note 2: /bin/pwd might be better than shell's built-in at getting
1441 #         a symlink-free name.
1442 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1443   vpath_build=no
1444 else
1445   vpath_build=yes
1446   if test "$no_create" != yes; then
1447     _AS_ECHO_N([preparing build tree... ])
1448     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1449     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1450       || AC_MSG_ERROR(failed)
1451     AC_MSG_RESULT(done)
1452   fi
1453 fi
1454 AC_SUBST(vpath_build)
1455
1456
1457 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1458
1459 AC_CONFIG_LINKS([
1460   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1461   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1462   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1463   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1464   src/include/pg_config_os.h:src/include/port/${template}.h
1465   src/Makefile.port:src/makefiles/Makefile.${template}
1466 ])
1467
1468 if test "$PORTNAME" = "win32"; then
1469 AC_CONFIG_COMMANDS([check_win32_symlinks],[
1470 # Links sometimes fail undetected on Mingw -
1471 # so here we detect it and warn the user
1472 for FILE in $CONFIG_LINKS
1473  do
1474         # test -e works for symlinks in the MinGW console
1475         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
1476  done
1477 ])
1478 fi
1479
1480 AC_CONFIG_HEADERS([src/include/pg_config.h],
1481 [
1482 # Update timestamp for pg_config.h (see Makefile.global)
1483 echo >src/include/stamp-h
1484 ])
1485
1486 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h])
1487
1488 AC_OUTPUT
1489
1490 # Warn about unknown options
1491 PGAC_ARG_CHECK