configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $PostgreSQL: pgsql/configure.in,v 1.545 2008/01/24 06:23:32 petere Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [8.3RC2], [pgsql-bugs@postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.59], [], [m4_fatal([Autoconf version 2.59 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2008, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version as a string])
  33
  34 AC_CANONICAL_HOST
  35
  36 template=
  37 AC_MSG_CHECKING([which template to use])
  38
  39 PGAC_ARG_REQ(with, template, [],
  40 [
  41   case $withval in
  42     list)   echo; ls "$srcdir/src/template"; exit;;
  43     *)      if test -f "$srcdir/src/template/$with_template" ; then
  44               template=$withval
  45             else
  46               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  47             fi;;
  48   esac
  49 ],
  50 [
  51 # --with-template not given
  52
  53 case $host_os in
  54      aix*) template=aix ;;
  55     bsdi*) template=bsdi ;;
  56   cygwin*) template=cygwin ;;
  57   darwin*) template=darwin ;;
  58     dgux*) template=dgux ;;
  59  freebsd*) template=freebsd ;;
  60     hpux*) template=hpux ;;
  61     irix*) template=irix ;;
  62  linux*|gnu*|k*bsd*-gnu)
  63            template=linux ;;
  64    mingw*) template=win32 ;;
  65   netbsd*) template=netbsd ;;
  66 nextstep*) template=nextstep ;;
  67  openbsd*) template=openbsd ;;
  68      osf*) template=osf ;;
  69      sco*) template=sco ;;
  70  solaris*) template=solaris ;;
  71    sunos*) template=sunos4 ;;
  72  sysv4.2*)
  73         case $host_vendor in
  74           univel) template=univel ;;
  75         esac ;;
  76    sysv4*) template=svr4 ;;
  77    sysv5*) template=unixware ;;
  78   ultrix*) template=ultrix4 ;;
  79 esac
  80
  81   if test x"$template" = x"" ; then
  82     AC_MSG_ERROR([[
  83 *******************************************************************
  84 PostgreSQL has apparently not been ported to your platform yet.
  85 To try a manual configuration, look into the src/template directory
  86 for a similar platform and use the '--with-template=' option.
  87
  88 Please also contact <pgsql-ports@postgresql.org> to see about
  89 rectifying this.  Include the above 'checking host system type...'
  90 line.
  91 *******************************************************************
  92 ]])
  93   fi
  94
  95 ])
  96
  97 AC_MSG_RESULT([$template])
  98
  99 PORTNAME=$template
 100 AC_SUBST(PORTNAME)
 101
 102 # Initialize default assumption that we do not need separate assembly code
 103 # for TAS (test-and-set).  This can be overridden by the template file
 104 # when it's executed.
 105 need_tas=no
 106 tas_file=dummy.s
 107
 108
 109
 110 ##
 111 ## Command line options
 112 ##
 113
 114 #
 115 # Installation directory for documentation
 116 #
 117 PGAC_ARG(with, docdir, [  --with-docdir=DIR       install the documentation in DIR [[PREFIX/doc]]
 118   --without-docdir        do not install the documentation],
 119          [AC_MSG_ERROR([option --with-docdir requires an argument])],
 120          [docdir=],
 121          [docdir=$withval],
 122          [docdir='${prefix}/doc'])
 123 AC_SUBST(docdir)
 124
 125
 126 #
 127 # Add non-standard directories to the include path
 128 #
 129 PGAC_ARG_REQ(with, includes, [  --with-includes=DIRS    look for additional header files in DIRS])
 130
 131
 132 #
 133 # Add non-standard directories to the library search path
 134 #
 135 PGAC_ARG_REQ(with, libraries, [  --with-libraries=DIRS   look for additional libraries in DIRS],
 136              [LIBRARY_DIRS=$withval])
 137
 138 PGAC_ARG_REQ(with, libs,      [  --with-libs=DIRS        alternative spelling of --with-libraries],
 139              [LIBRARY_DIRS=$withval])
 140
 141
 142 #
 143 # 64-bit integer date/time storage (--enable-integer-datetimes)
 144 #
 145 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 146 PGAC_ARG_BOOL(enable, integer-datetimes, no, [  --enable-integer-datetimes  enable 64-bit integer date/time support],
 147               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 148                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 149 AC_MSG_RESULT([$enable_integer_datetimes])
 150
 151
 152 #
 153 # NLS
 154 #
 155 AC_MSG_CHECKING([whether NLS is wanted])
 156 PGAC_ARG_OPTARG(enable, nls,
 157                 [[  --enable-nls[=LANGUAGES]  enable Native Language Support]],
 158                 [],
 159                 [WANTED_LANGUAGES=$enableval],
 160                 [AC_DEFINE(ENABLE_NLS, 1,
 161                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 162 AC_MSG_RESULT([$enable_nls])
 163 AC_SUBST(enable_nls)
 164 AC_SUBST(WANTED_LANGUAGES)
 165
 166 #
 167 # Default port number (--with-pgport), default 5432
 168 #
 169 AC_MSG_CHECKING([for default port number])
 170 PGAC_ARG_REQ(with, pgport, [  --with-pgport=PORTNUM   change default port number [[5432]]],
 171              [default_port=$withval],
 172              [default_port=5432])
 173 AC_MSG_RESULT([$default_port])
 174 # Need both of these because some places want an integer and some a string
 175 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 176 [Define to the default TCP port number on which the server listens and
 177 to which clients will try to connect.  This can be overridden at run-time,
 178 but it's convenient if your clients have the right default compiled in.
 179 (--with-pgport=PORTNUM)])
 180 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 181                    [Define to the default TCP port number as a string constant.])
 182 AC_SUBST(default_port)
 183
 184 #
 185 # Option to disable shared libraries
 186 #
 187 PGAC_ARG_BOOL(enable, shared, yes,
 188               [  --disable-shared        do not build shared libraries])
 189 AC_SUBST(enable_shared)
 190
 191 #
 192 # '-rpath'-like feature can be disabled
 193 #
 194 PGAC_ARG_BOOL(enable, rpath, yes,
 195               [  --disable-rpath         do not embed shared library search path in executables])
 196 AC_SUBST(enable_rpath)
 197
 198 #
 199 # Spinlocks
 200 #
 201 PGAC_ARG_BOOL(enable, spinlocks, yes,
 202               [  --disable-spinlocks     do not use spinlocks])
 203
 204 #
 205 # --enable-debug adds -g to compiler flags
 206 #
 207 PGAC_ARG_BOOL(enable, debug, no,
 208               [  --enable-debug          build with debugging symbols (-g)])
 209 AC_SUBST(enable_debug)
 210
 211 #
 212 # --enable-profiling enables gcc profiling
 213 #
 214 PGAC_ARG_BOOL(enable, profiling, no,
 215               [  --enable-profiling      build with profiling enabled ])
 216 AC_SUBST(enable_profiling)
 217
 218 #
 219 # DTrace
 220 #
 221 PGAC_ARG_BOOL(enable, dtrace, no,
 222               [  --enable-dtrace         build with DTrace support],
 223 [AC_DEFINE([ENABLE_DTRACE], 1,
 224            [Define to 1 to enable DTrace support. (--enable-dtrace)])
 225 AC_CHECK_PROGS(DTRACE, dtrace)
 226 if test -z "$DTRACE"; then
 227   AC_MSG_ERROR([dtrace not found])
 228 fi
 229 AC_SUBST(DTRACEFLAGS)])
 230 AC_SUBST(enable_dtrace)
 231
 232 #
 233 # C compiler
 234 #
 235
 236 # For historical reasons you can also use --with-CC to specify the C compiler
 237 # to use, although the standard way to do this is to set the CC environment
 238 # variable.
 239 PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
 240
 241 case $template in
 242   aix) pgac_cc_list="gcc xlc";;
 243  irix) pgac_cc_list="cc";; # no gcc
 244     *) pgac_cc_list="gcc cc";;
 245 esac
 246
 247 AC_PROG_CC([$pgac_cc_list])
 248
 249 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 250 # but has idiosyncrasies of its own.  We assume icc will define
 251 # __INTEL_COMPILER regardless of CFLAGS.
 252 AC_TRY_COMPILE([], [@%:@ifndef __INTEL_COMPILER
 253 choke me
 254 @%:@endif], [ICC=[yes]], [ICC=[no]])
 255
 256 unset CFLAGS
 257
 258 #
 259 # Read the template
 260 #
 261 . "$srcdir/src/template/$template" || exit
 262
 263 # CFLAGS are selected so:
 264 # If the user specifies something in the environment, that is used.
 265 # else:  If the template file set something, that is used.
 266 # else:  If the compiler is GCC, then we use -O2.
 267 # else:  If the compiler is something else, then we use -0.
 268
 269 if test "$ac_env_CFLAGS_set" = set; then
 270   CFLAGS=$ac_env_CFLAGS_value
 271 elif test "${CFLAGS+set}" = set; then
 272   : # (keep what template set)
 273 elif test "$GCC" = yes; then
 274   CFLAGS="-O2"
 275 else
 276   # if the user selected debug mode, don't use -O
 277   if test "$enable_debug" != yes; then
 278     CFLAGS="-O"
 279   fi
 280 fi
 281
 282 # Some versions of GCC support some additional useful warning flags.
 283 # Check whether they are supported, and add them to CFLAGS if so.
 284 # ICC pretends to be GCC but it's lying; it doesn't support these options.
 285
 286 if test "$GCC" = yes -a "$ICC" = no; then
 287   CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wpointer-arith -Winline"
 288   # These work in some but not all gcc versions
 289   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 290   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 291   # Disable strict-aliasing rules; needed for gcc 3.3+
 292   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 293 elif test "$ICC" = yes; then
 294   # Intel's compiler has a bug/misoptimization in checking for
 295   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 296   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 297   # Make sure strict aliasing is off (though this is said to be the default)
 298   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 299 elif test x"${CC}" = x"xlc"; then
 300   # AIX xlc has to have strict aliasing turned off too
 301   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 302 fi
 303
 304 # supply -g if --enable-debug
 305 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 306   CFLAGS="$CFLAGS -g"
 307 fi
 308
 309 # enable profiling if --enable-profiling
 310 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 311   if test "$GCC" = yes; then
 312     AC_DEFINE([PROFILE_PID_DIR], 1,
 313            [Define to 1 to allow profiling output to be saved separately for each process.])
 314     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 315   else
 316     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 317   fi
 318 fi
 319
 320 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
 321
 322 # We already have this in Makefile.win32, but configure needs it too
 323 if test "$PORTNAME" = "win32"; then
 324   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 325 fi
 326
 327 # Check if the compiler still works with the template settings
 328 AC_MSG_CHECKING([whether the C compiler still works])
 329 AC_TRY_LINK([], [return 0;],
 330   [AC_MSG_RESULT(yes)],
 331   [AC_MSG_RESULT(no)
 332    AC_MSG_ERROR([cannot proceed])])
 333
 334 # Defend against gcc -ffast-math
 335 if test "$GCC" = yes; then
 336 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 337 choke me
 338 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 339 fi
 340
 341 AC_PROG_CPP
 342 AC_SUBST(GCC)
 343
 344 # Create compiler version string
 345 if test x"$GCC" = x"yes" ; then
 346   cc_string="GCC `${CC} --version | sed q`"
 347 else
 348   cc_string=$CC
 349 fi
 350 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
 351                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"],
 352                    [A string containing the version number, platform, and C compiler])
 353
 354
 355 #
 356 # Set up TAS assembly code if needed; the template file has now had its
 357 # chance to request this.
 358 #
 359 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 360
 361 if test "$need_tas" = yes ; then
 362   TAS=tas.o
 363 else
 364   TAS=""
 365 fi
 366 AC_SUBST(TAS)
 367
 368
 369 #
 370 # Automatic dependency tracking
 371 #
 372 PGAC_ARG_BOOL(enable, depend, no, [  --enable-depend         turn on automatic dependency tracking],
 373               [autodepend=yes])
 374 AC_SUBST(autodepend)
 375
 376
 377 #
 378 # Enable assert checks
 379 #
 380 PGAC_ARG_BOOL(enable, cassert, no, [  --enable-cassert        enable assertion checks (for debugging)],
 381               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 382                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 383
 384
 385 #
 386 # Include directories
 387 #
 388 ac_save_IFS=$IFS
 389 IFS="${IFS}${PATH_SEPARATOR}"
 390 # SRCH_INC comes from the template file
 391 for dir in $with_includes $SRCH_INC; do
 392   if test -d "$dir"; then
 393     INCLUDES="$INCLUDES -I$dir"
 394   else
 395     AC_MSG_WARN([*** Include directory $dir does not exist.])
 396   fi
 397 done
 398 IFS=$ac_save_IFS
 399 AC_SUBST(INCLUDES)
 400
 401
 402 #
 403 # Library directories
 404 #
 405 ac_save_IFS=$IFS
 406 IFS="${IFS}${PATH_SEPARATOR}"
 407 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 408 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 409   if test -d "$dir"; then
 410     LIBDIRS="$LIBDIRS -L$dir"
 411   else
 412     AC_MSG_WARN([*** Library directory $dir does not exist.])
 413   fi
 414 done
 415 IFS=$ac_save_IFS
 416
 417 #
 418 # Enable thread-safe client libraries
 419 #
 420 AC_MSG_CHECKING([allow thread-safe client libraries])
 421 if test "$PORTNAME" != "win32"; then
 422 PGAC_ARG_BOOL(enable, thread-safety, no, [  --enable-thread-safety  make client libraries thread-safe])
 423 else
 424 # Win32 should always use threads
 425 PGAC_ARG_BOOL(enable, thread-safety, yes, [  --enable-thread-safety  make client libraries thread-safe])
 426 fi
 427
 428 PGAC_ARG_BOOL(enable, thread-safety-force, no, [  --enable-thread-safety-force  force thread-safety despite thread test failure])
 429 if test "$enable_thread_safety" = yes -o \
 430         "$enable_thread_safety_force" = yes; then
 431   enable_thread_safety="yes"    # for 'force'
 432   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 433           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 434 fi
 435 AC_MSG_RESULT([$enable_thread_safety])
 436 AC_SUBST(enable_thread_safety)
 437
 438 #
 439 # Optionally build Tcl modules (PL/Tcl)
 440 #
 441 AC_MSG_CHECKING([whether to build with Tcl])
 442 PGAC_ARG_BOOL(with, tcl, no, [  --with-tcl              build Tcl modules (PL/Tcl)])
 443 AC_MSG_RESULT([$with_tcl])
 444 AC_SUBST([with_tcl])
 445
 446 # We see if the path to the Tcl/Tk configuration scripts is specified.
 447 # This will override the use of tclsh to find the paths to search.
 448
 449 PGAC_ARG_REQ(with, tclconfig, [  --with-tclconfig=DIR    tclConfig.sh is in DIR])
 450
 451 #
 452 # Optionally build Perl modules (PL/Perl)
 453 #
 454 AC_MSG_CHECKING([whether to build Perl modules])
 455 PGAC_ARG_BOOL(with, perl, no, [  --with-perl             build Perl modules (PL/Perl)])
 456 AC_MSG_RESULT([$with_perl])
 457 AC_SUBST(with_perl)
 458
 459 #
 460 # Optionally build Python modules (PL/Python)
 461 #
 462 AC_MSG_CHECKING([whether to build Python modules])
 463 PGAC_ARG_BOOL(with, python, no, [  --with-python           build Python modules (PL/Python)])
 464 AC_MSG_RESULT([$with_python])
 465 AC_SUBST(with_python)
 466
 467 #
 468 # GSSAPI
 469 #
 470 AC_MSG_CHECKING([whether to build with GSSAPI support])
 471 PGAC_ARG_BOOL(with, gssapi, no, [  --with-gssapi           build with GSSAPI support],
 472 [
 473   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 474   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 475 ])
 476 AC_MSG_RESULT([$with_gssapi])
 477 AC_SUBST(with_gssapi)
 478
 479 #
 480 # Kerberos 5
 481 #
 482 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 483 PGAC_ARG_BOOL(with, krb5, no, [  --with-krb5             build with Kerberos 5 support],
 484 [
 485   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 486   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 487 ])
 488 AC_MSG_RESULT([$with_krb5])
 489 AC_SUBST(with_krb5)
 490
 491
 492 AC_SUBST(krb_srvtab)
 493
 494
 495 #
 496 # Kerberos configuration parameters
 497 #
 498 PGAC_ARG_REQ(with, krb-srvnam,
 499              [  --with-krb-srvnam=NAME  default service principal name in Kerberos [[postgres]]],
 500              [],
 501              [with_krb_srvnam="postgres"])
 502 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 503                    [Define to the name of the default PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 504
 505
 506 #
 507 # PAM
 508 #
 509 AC_MSG_CHECKING([whether to build with PAM support])
 510 PGAC_ARG_BOOL(with, pam, no,
 511               [  --with-pam              build with PAM support],
 512               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 513 AC_MSG_RESULT([$with_pam])
 514 AC_SUBST(with_pam)
 515
 516
 517 #
 518 # LDAP
 519 #
 520 AC_MSG_CHECKING([whether to build with LDAP support])
 521 PGAC_ARG_BOOL(with, ldap, no,
 522               [  --with-ldap             build with LDAP support],
 523               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 524 AC_MSG_RESULT([$with_ldap])
 525 AC_SUBST(with_ldap)
 526
 527
 528 #
 529 # Bonjour
 530 #
 531 AC_MSG_CHECKING([whether to build with Bonjour support])
 532 PGAC_ARG_BOOL(with, bonjour, no,
 533               [  --with-bonjour          build with Bonjour support],
 534               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 535 AC_MSG_RESULT([$with_bonjour])
 536 AC_SUBST(with_bonjour)
 537
 538
 539 #
 540 # OpenSSL
 541 #
 542 AC_MSG_CHECKING([whether to build with OpenSSL support])
 543 PGAC_ARG_BOOL(with, openssl, no, [  --with-openssl          build with OpenSSL support],
 544               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 545 AC_MSG_RESULT([$with_openssl])
 546 AC_SUBST(with_openssl)
 547
 548
 549 #
 550 # Readline
 551 #
 552 PGAC_ARG_BOOL(with, readline, yes,
 553               [  --without-readline      do not use GNU Readline nor BSD Libedit for editing])
 554 # readline on MinGW has problems with backslashes in psql and other bugs.
 555 # This is particularly a problem with non-US code pages.
 556 # Therefore disable its use until we understand the cause. 2004-07-20
 557 if test "$PORTNAME" = "win32"; then
 558   if test "$with_readline" = yes; then
 559     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 560     with_readline=no
 561   fi
 562 fi
 563
 564
 565 #
 566 # Prefer libedit
 567 #
 568 PGAC_ARG_BOOL(with, libedit-preferred, no,
 569               [  --with-libedit-preferred  prefer BSD Libedit over GNU Readline])
 570
 571
 572 #
 573 # OSSP UUID library
 574 #
 575 PGAC_ARG_BOOL(with, ossp-uuid, no, [  --with-ossp-uuid        use OSSP UUID library when building contrib/uuid-ossp])
 576 AC_SUBST(with_ossp_uuid)
 577
 578
 579 #
 580 # XML
 581 #
 582 PGAC_ARG_BOOL(with, libxml, no, [  --with-libxml           build with XML support],
 583               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 584
 585 if test "$with_libxml" = yes ; then
 586   AC_CHECK_PROGS(XML2_CONFIG, xml2-config)
 587   if test -n "$XML2_CONFIG"; then
 588     for pgac_option in `$XML2_CONFIG --cflags`; do
 589       case $pgac_option in
 590         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 591       esac
 592     done
 593     for pgac_option in `$XML2_CONFIG --libs`; do
 594       case $pgac_option in
 595         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 596       esac
 597     done
 598   fi
 599 fi
 600
 601 AC_SUBST(with_libxml)
 602
 603 #
 604 # XSLT
 605 #
 606 PGAC_ARG_BOOL(with, libxslt, no, [  --with-libxslt          use XSLT support when building contrib/xml2],
 607               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 608
 609
 610 AC_SUBST(with_libxslt)
 611
 612 #
 613 # tzdata
 614 #
 615 PGAC_ARG_REQ(with, system-tzdata,
 616              [  --with-system-tzdata=DIR  use system time zone data in DIR])
 617 AC_SUBST(with_system_tzdata)
 618
 619 #
 620 # Zlib
 621 #
 622 PGAC_ARG_BOOL(with, zlib, yes,
 623               [  --without-zlib          do not use Zlib])
 624 AC_SUBST(with_zlib)
 625
 626 #
 627 # Elf
 628 #
 629
 630 # Assume system is ELF if it predefines __ELF__ as 1,
 631 # otherwise believe host_os based default.
 632 case $host_os in
 633     freebsd1*|freebsd2*) elf=no;;
 634     freebsd3*|freebsd4*) elf=yes;;
 635 esac
 636
 637 AC_EGREP_CPP(yes,
 638 [#if __ELF__
 639   yes
 640 #endif
 641 ],
 642 [ELF_SYS=true],
 643 [if test "X$elf" = "Xyes" ; then
 644   ELF_SYS=true
 645 else
 646   ELF_SYS=
 647 fi])
 648 AC_SUBST(ELF_SYS)
 649
 650 #
 651 # Assignments
 652 #
 653
 654 CPPFLAGS="$CPPFLAGS $INCLUDES"
 655 LDFLAGS="$LDFLAGS $LIBDIRS"
 656
 657 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
 658 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
 659
 660 AC_ARG_VAR(LDFLAGS_SL)
 661
 662 PGAC_PROG_LD
 663 AC_SUBST(LD)
 664 AC_SUBST(with_gnu_ld)
 665 case $host_os in sysv5*)
 666   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 667   [
 668     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 669     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 670     LDFLAGS=$pgac_save_LDFLAGS
 671   ])
 672   ld_R_works=$pgac_cv_prog_ld_R
 673   AC_SUBST(ld_R_works)
 674 esac
 675 AC_PROG_RANLIB
 676 PGAC_CHECK_STRIP
 677
 678 AC_PATH_PROG(TAR, tar)
 679 AC_PROG_LN_S
 680 AC_PROG_AWK
 681
 682 PGAC_PATH_YACC
 683 PGAC_PATH_FLEX
 684
 685 PGAC_PATH_PERL
 686 if test "$with_perl" = yes; then
 687   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 688   PGAC_CHECK_PERL_EMBED_LDFLAGS
 689 fi
 690
 691 if test "$with_python" = yes; then
 692   PGAC_PATH_PYTHON
 693   PGAC_CHECK_PYTHON_EMBED_SETUP
 694 fi
 695
 696 # Supply a numeric version string for use by 3rd party add-ons
 697 # awk -F is a regex on some platforms, and not on others, so make "." a tab
 698 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
 699 tr '.' '        ' |
 700 $AWK '{printf "%d%02d%02d", $1, $2, (NF >= 3) ? $3 : 0}'`"]
 701 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
 702
 703 ##
 704 ## Libraries
 705 ##
 706 ## Most libraries are included only if they demonstrably provide a function
 707 ## we need, but libm is an exception: always include it, because there are
 708 ## too many compilers that play cute optimization games that will break
 709 ## probes for standard functions such as pow().
 710 ##
 711
 712 AC_CHECK_LIB(m, main)
 713 AC_SEARCH_LIBS(setproctitle, util)
 714 AC_SEARCH_LIBS(dlopen, dl)
 715 AC_SEARCH_LIBS(socket, [socket wsock32])
 716 AC_SEARCH_LIBS(shl_load, dld)
 717 # We only use libld in port/dynloader/aix.c
 718 case $host_os in
 719      aix*)
 720         AC_SEARCH_LIBS(ldopen, ld)
 721         ;;
 722 esac
 723 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 724 AC_SEARCH_LIBS(crypt, crypt)
 725 # Solaris:
 726 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 727 # Cygwin:
 728 AC_SEARCH_LIBS(shmget, cygipc)
 729
 730 if test "$with_readline" = yes; then
 731   PGAC_CHECK_READLINE
 732   if test x"$pgac_cv_check_readline" = x"no"; then
 733     AC_MSG_ERROR([readline library not found
 734 If you have readline already installed, see config.log for details on the
 735 failure.  It is possible the compiler isn't looking in the proper directory.
 736 Use --without-readline to disable readline support.])
 737   fi
 738 fi
 739
 740 if test "$with_zlib" = yes; then
 741   AC_CHECK_LIB(z, inflate, [],
 742                [AC_MSG_ERROR([zlib library not found
 743 If you have zlib already installed, see config.log for details on the
 744 failure.  It is possible the compiler isn't looking in the proper directory.
 745 Use --without-zlib to disable zlib support.])])
 746 fi
 747
 748 if test "$enable_spinlocks" = yes; then
 749   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 750 else
 751   AC_MSG_WARN([
 752 *** Not using spinlocks will cause poor performance.])
 753 fi
 754
 755 if test "$with_gssapi" = yes ; then
 756   if test "$PORTNAME" != "win32"; then
 757     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
 758                                   [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
 759   else
 760     LIBS="$LIBS -lgssapi32"
 761   fi
 762 fi
 763
 764 if test "$with_krb5" = yes ; then
 765   if test "$PORTNAME" != "win32"; then
 766      AC_SEARCH_LIBS(com_err, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken' com_err], [],
 767                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 768      AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken'], [],
 769                     [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 770   else
 771      AC_SEARCH_LIBS(com_err, 'comerr32 -lkrb5_32', [],
 772                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 773   fi
 774 fi
 775
 776 if test "$with_openssl" = yes ; then
 777   dnl Order matters!
 778   if test "$PORTNAME" != "win32"; then
 779      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 780      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 781   else
 782      AC_CHECK_LIB(eay32, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'eay32' is required for OpenSSL])])
 783      AC_CHECK_LIB(ssleay32,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssleay32' is required for OpenSSL])])
 784   fi
 785 fi
 786
 787 if test "$with_pam" = yes ; then
 788   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 789 fi
 790
 791 if test "$with_libxml" = yes ; then
 792   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
 793 fi
 794
 795 if test "$with_libxslt" = yes ; then
 796   AC_CHECK_LIB(xslt, xsltLibxmlVersion, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
 797 fi
 798
 799 # for contrib/uuid-ossp
 800 if test "$with_ossp_uuid" = yes ; then
 801   AC_CHECK_LIB(ossp-uuid, uuid_export,
 802     [OSSP_UUID_LIBS="-lossp-uuid"],
 803     [AC_CHECK_LIB(uuid, uuid_export,
 804       [OSSP_UUID_LIBS="-luuid"],
 805       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP-UUID])])])
 806 fi
 807 AC_SUBST(OSSP_UUID_LIBS)
 808
 809
 810 ##
 811 ## Header files
 812 ##
 813
 814 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 815 AC_CHECK_HEADERS([crypt.h dld.h fp_class.h getopt.h ieeefp.h langinfo.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/tas.h sys/time.h sys/un.h termios.h utime.h wchar.h wctype.h kernel/OS.h kernel/image.h SupportDefs.h])
 816
 817 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 818 # netinet/in.h is included first.
 819 AC_CHECK_HEADERS(netinet/in.h)
 820 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 821 [AC_INCLUDES_DEFAULT
 822 #ifdef HAVE_NETINET_IN_H
 823 #include <netinet/in.h>
 824 #endif
 825 ])
 826
 827 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
 828   AC_CHECK_HEADERS(readline/readline.h, [],
 829         [AC_CHECK_HEADERS(readline.h, [],
 830                 [AC_MSG_ERROR([readline header not found
 831 If you have readline already installed, see config.log for details on the
 832 failure.  It is possible the compiler isn't looking in the proper directory.
 833 Use --without-readline to disable readline support.])])])
 834   AC_CHECK_HEADERS(readline/history.h, [],
 835         [AC_CHECK_HEADERS(history.h, [],
 836                 [AC_MSG_ERROR([history header not found
 837 If you have readline already installed, see config.log for details on the
 838 failure.  It is possible the compiler isn't looking in the proper directory.
 839 Use --without-readline to disable readline support.])])])
 840 fi
 841
 842 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
 843 # Some installations of libedit usurp /usr/include/readline/, which seems
 844 # bad practice, since in combined installations readline will have its headers
 845 # there.  We might have to resort to AC_EGREP checks to make sure we found
 846 # the proper header...
 847   AC_CHECK_HEADERS(editline/readline.h, [],
 848         [AC_CHECK_HEADERS(readline.h, [],
 849                 [AC_CHECK_HEADERS(readline/readline.h, [],
 850                         [AC_MSG_ERROR([readline header not found
 851 If you have libedit already installed, see config.log for details on the
 852 failure.  It is possible the compiler isn't looking in the proper directory.
 853 Use --without-readline to disable libedit support.])])])])
 854 # Note: in a libedit installation, history.h is sometimes a dummy, and may
 855 # not be there at all.  Hence, don't complain if not found.  We must check
 856 # though, since in yet other versions it is an independent header.
 857   AC_CHECK_HEADERS(editline/history.h, [],
 858         [AC_CHECK_HEADERS(history.h, [],
 859                 [AC_CHECK_HEADERS(readline/history.h)])])
 860 fi
 861
 862 if test "$with_zlib" = yes; then
 863   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
 864 If you have zlib already installed, see config.log for details on the
 865 failure.  It is possible the compiler isn't looking in the proper directory.
 866 Use --without-zlib to disable zlib support.])])
 867 fi
 868
 869 if test "$with_gssapi" = yes ; then
 870   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
 871         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
 872 fi
 873
 874 if test "$with_krb5" = yes ; then
 875   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
 876 fi
 877
 878 if test "$with_openssl" = yes ; then
 879   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
 880   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
 881   AC_CHECK_FUNCS([ERR_set_mark])
 882 fi
 883
 884 if test "$with_pam" = yes ; then
 885   AC_CHECK_HEADERS(security/pam_appl.h, [],
 886                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
 887                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
 888 fi
 889
 890 if test "$with_libxml" = yes ; then
 891   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
 892 fi
 893
 894 if test "$with_libxslt" = yes ; then
 895   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
 896 fi
 897
 898 if test "$with_ldap" = yes ; then
 899   if test "$PORTNAME" != "win32"; then
 900      AC_CHECK_HEADERS(ldap.h, [],
 901                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
 902   else
 903      AC_CHECK_HEADERS(winldap.h, [],
 904                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
 905                       [AC_INCLUDES_DEFAULT
 906 #include <windows.h>
 907                       ])
 908   fi
 909 fi
 910
 911 if test "$with_bonjour" = yes ; then
 912   AC_CHECK_HEADER(DNSServiceDiscovery/DNSServiceDiscovery.h, [], [AC_MSG_ERROR([header file <DNSServiceDiscovery/DNSServiceDiscovery.h> is required for Bonjour])])
 913 fi
 914
 915 # for contrib/uuid-ossp
 916 if test "$with_ossp_uuid" = yes ; then
 917   AC_CHECK_HEADERS(ossp/uuid.h, [], [
 918     AC_CHECK_HEADERS(uuid.h, [],
 919       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP-UUID])])])
 920 fi
 921
 922
 923 ##
 924 ## Types, structures, compiler characteristics
 925 ##
 926
 927 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
 928 AC_C_BIGENDIAN
 929 AC_C_CONST
 930 AC_C_INLINE
 931 AC_C_STRINGIZE
 932 PGAC_C_SIGNED
 933 AC_C_VOLATILE
 934 PGAC_C_FUNCNAME_SUPPORT
 935 PGAC_STRUCT_TIMEZONE
 936 PGAC_UNION_SEMUN
 937 PGAC_STRUCT_SOCKADDR_UN
 938 PGAC_STRUCT_SOCKADDR_STORAGE
 939 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
 940 PGAC_STRUCT_ADDRINFO
 941
 942 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
 943 [#include <sys/param.h>
 944 #include <sys/types.h>
 945 #include <sys/socket.h>
 946 #include <sys/ucred.h>])
 947
 948 AC_CHECK_TYPES([struct option], [], [],
 949 [#ifdef HAVE_GETOPT_H
 950 #include <getopt.h>
 951 #endif])
 952
 953 if test "$with_zlib" = yes; then
 954   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
 955   # did not).  While we could work around the lack of z_streamp, it
 956   # seems unwise to encourage people to use such old zlib versions...
 957   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
 958 Use --without-zlib to disable zlib support.])],
 959                 [#include <zlib.h>])
 960 fi
 961
 962 if test "$with_krb5" = yes; then
 963 # Check for differences between MIT and Heimdal (KTH) releases
 964   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
 965                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
 966                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
 967                                      [#include <krb5.h>])],
 968                    [#include <krb5.h>])
 969   AC_CHECK_MEMBERS(krb5_error.text.data, [],
 970                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
 971                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
 972                                      [#include <krb5.h>])],
 973                    [#include <krb5.h>])
 974
 975 # Win32 requires headers to be loaded for __stdcall, so can't use
 976 # AC_CHECK_FUNCS here.
 977   AC_MSG_CHECKING(for krb5_free_unparsed_name)
 978   AC_TRY_LINK([#include <krb5.h>],
 979               [krb5_free_unparsed_name(NULL,NULL);],
 980               [AC_DEFINE(HAVE_KRB5_FREE_UNPARSED_NAME, 1, [Define to 1 if you have krb5_free_unparsed_name])
 981 AC_MSG_RESULT(yes)],
 982               [AC_MSG_RESULT(no)])
 983 fi
 984
 985
 986 ##
 987 ## Functions, global variables
 988 ##
 989
 990 PGAC_VAR_INT_TIMEZONE
 991 AC_FUNC_ACCEPT_ARGTYPES
 992 PGAC_FUNC_GETTIMEOFDAY_1ARG
 993
 994 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid getrlimit memmove poll pstat readlink setproctitle setsid sigprocmask symlink sysconf towlower utime utimes waitpid wcstombs])
 995
 996 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 997 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
 998 AC_CHECK_DECLS([strlcat, strlcpy])
 999 # This is probably only present on Darwin, but may as well check always
1000 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
1001
1002 HAVE_IPV6=no
1003 AC_CHECK_TYPE([struct sockaddr_in6],
1004         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
1005          HAVE_IPV6=yes],
1006         [],
1007 [$ac_includes_default
1008 #include <netinet/in.h>])
1009 AC_SUBST(HAVE_IPV6)
1010
1011 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1012 [AC_TRY_LINK(
1013 [#include <machine/vmparam.h>
1014 #include <sys/exec.h>
1015 ],
1016 [PS_STRINGS->ps_nargvstr = 1;
1017 PS_STRINGS->ps_argvstr = "foo";],
1018 [pgac_cv_var_PS_STRINGS=yes],
1019 [pgac_cv_var_PS_STRINGS=no])])
1020 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1021   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
1022 fi
1023
1024
1025 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
1026 # is missing.  Yes, there are machines that have only one.  We may
1027 # also decide to use snprintf.c if snprintf() is present but does not
1028 # have all the features we need --- see below.
1029
1030 if test "$PORTNAME" = "win32"; then
1031   # Win32 gets snprintf.c built unconditionally.
1032   #
1033   # To properly translate all NLS languages strings, we must support the
1034   # *printf() %$ format, which allows *printf() arguments to be selected
1035   # by position in the translated string.
1036   #
1037   # libintl versions < 0.13 use the native *printf() functions, and Win32
1038   # *printf() doesn't understand %$, so we must use our /port versions,
1039   # which do understand %$. libintl versions >= 0.13 include their own
1040   # *printf versions on Win32.  The libintl 0.13 release note text is:
1041   #
1042   #   C format strings with positions, as they arise when a translator
1043   #   needs to reorder a sentence, are now supported on all platforms.
1044   #   On those few platforms (NetBSD and Woe32) for which the native
1045   #   printf()/fprintf()/... functions don't support such format
1046   #   strings, replacements are provided through <libintl.h>.
1047   #
1048   # We could use libintl >= 0.13's *printf() if we were sure that we had
1049   # a litint >= 0.13 at runtime, but seeing that there is no clean way
1050   # to guarantee that, it is best to just use our own, so we are sure to
1051   # get %$ support. In include/port.h we disable the *printf() macros
1052   # that might have been defined by libintl.
1053   #
1054   # We do this unconditionally whether NLS is used or not so we are sure
1055   # that all Win32 libraries and binaries behave the same.
1056   pgac_need_repl_snprintf=yes
1057 else
1058   pgac_need_repl_snprintf=no
1059   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
1060   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1061 fi
1062
1063
1064 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
1065 # include/c.h will provide declarations.  Note this is a separate test
1066 # from whether the functions exist in the C library --- there are
1067 # systems that have the functions but don't bother to declare them :-(
1068
1069 AC_CHECK_DECLS([snprintf, vsnprintf])
1070
1071
1072 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1073 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1074 [AC_TRY_LINK([
1075 #include <math.h>
1076 double glob_double;
1077 ],
1078 [return isinf(glob_double) ? 0 : 1;],
1079 [ac_cv_func_isinf=yes],
1080 [ac_cv_func_isinf=no])])
1081
1082 if test $ac_cv_func_isinf = yes ; then
1083   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1084 else
1085   AC_LIBOBJ(isinf)
1086   # Look for a way to implement a substitute for isinf()
1087   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1088 fi
1089
1090 # Some versions of libedit contain strlcpy(); so disregard that library while
1091 # checking for these standard libc functions.
1092 pgac_save_LIBS="$LIBS"
1093 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1094
1095 AC_REPLACE_FUNCS([crypt fseeko getopt getrusage inet_aton random rint srandom strdup strerror strlcat strlcpy strtol strtoul unsetenv])
1096
1097 LIBS="$pgac_save_LIBS"
1098
1099 # System's version of getaddrinfo(), if any, may be used only if we found
1100 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1101 # (Note: the AC_REPLACE_FUNCS probe fails on Windows, where the available
1102 # versions of getaddrinfo don't follow normal C call protocol.  This is OK
1103 # because we want to use our own getaddrinfo.c on Windows anyway.)
1104 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
1105   AC_REPLACE_FUNCS([getaddrinfo])
1106 else
1107   AC_LIBOBJ(getaddrinfo)
1108 fi
1109
1110 # similarly, use system's getopt_long() only if system provides struct option.
1111 if test x"$ac_cv_type_struct_option" = xyes ; then
1112   AC_REPLACE_FUNCS([getopt_long])
1113 else
1114   AC_LIBOBJ(getopt_long)
1115 fi
1116
1117 # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
1118 # We override the previous test that said fseeko/ftello didn't exist
1119 # OS tests are also done in include/c.h and port/fseeko.c
1120 case $host_os in bsdi*|netbsd*)
1121 ac_cv_func_fseeko=yes
1122 esac
1123
1124 # Win32 support
1125 if test "$PORTNAME" = "win32"; then
1126 AC_REPLACE_FUNCS(gettimeofday)
1127 AC_LIBOBJ(kill)
1128 AC_LIBOBJ(open)
1129 AC_LIBOBJ(rand)
1130 AC_LIBOBJ(win32error)
1131 AC_DEFINE([HAVE_SYMLINK], 1,
1132           [Define to 1 if you have the `symlink' function.])
1133 fi
1134
1135 if test "$with_readline" = yes; then
1136   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1137   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
1138   AC_CHECK_FUNCS([replace_history_entry])
1139 fi
1140
1141
1142 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
1143 dnl (especially on GNU libc)
1144 dnl See also comments in c.h.
1145 AC_MSG_CHECKING(for sigsetjmp)
1146 AC_TRY_LINK([#include <setjmp.h>],
1147             [sigjmp_buf x; sigsetjmp(x, 1);],
1148             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
1149 AC_MSG_RESULT(yes)],
1150             [AC_MSG_RESULT(no)])
1151
1152 AC_DECL_SYS_SIGLIST
1153
1154 AC_CHECK_FUNC(syslog,
1155               [AC_CHECK_HEADER(syslog.h,
1156                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1157
1158 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1159 [AC_TRY_LINK([#include <unistd.h>],
1160   [extern int optreset; optreset = 1;],
1161   [pgac_cv_var_int_optreset=yes],
1162   [pgac_cv_var_int_optreset=no])])
1163 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1164   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1165 fi
1166
1167 AC_CHECK_FUNCS([strtoll strtoq], [break])
1168 AC_CHECK_FUNCS([strtoull strtouq], [break])
1169
1170 # Check for one of atexit() or on_exit()
1171 AC_CHECK_FUNCS(atexit, [],
1172                [AC_CHECK_FUNCS(on_exit, [],
1173                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
1174
1175 AC_FUNC_FSEEKO
1176
1177 #
1178 # Pthreads
1179 #
1180 # For each platform, we need to know about any special compile and link
1181 # libraries, and whether the normal C function names are thread-safe.
1182 # See the comment at the top of src/port/thread.c for more information.
1183 # WIN32 doesn't need the pthread tests;  it always uses threads
1184 if test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"; then
1185 ACX_PTHREAD     # set thread flags
1186
1187 # Some platforms use these, so just defineed them.  They can't hurt if they
1188 # are not supported.
1189 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1190
1191
1192 # At this point, we don't want to muck with the compiler name for threading.
1193 # Let's see who fails, perhaps AIX.  2004-04-23
1194 if test "$PTHREAD_CC" != "$CC"; then
1195 AC_MSG_ERROR([
1196 PostgreSQL does not support platforms that require a special compiler
1197 for thread safety.])
1198 fi
1199
1200 if test "$THREAD_SUPPORT" = no; then
1201 AC_MSG_ERROR([cannot enable threads on this platform
1202 This platform is known to not support thread-safe programs.  For details,
1203 compile and run src/bin/pg_thread_test.])
1204 fi
1205
1206 # Check for *_r functions
1207 _CFLAGS="$CFLAGS"
1208 _LIBS="$LIBS"
1209 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1210 LIBS="$LIBS $PTHREAD_LIBS"
1211
1212 if test "$PORTNAME" != "win32"; then
1213 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([pthread.h not found, required for --enable-thread-safety])])
1214 fi
1215
1216 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1217
1218 # Do test here with the proper thread flags
1219 PGAC_FUNC_GETPWUID_R_5ARG
1220 PGAC_FUNC_STRERROR_R_INT
1221
1222 CFLAGS="$_CFLAGS"
1223 LIBS="$_LIBS"
1224
1225 else
1226 # do not use values from template file
1227 PTHREAD_CFLAGS=
1228 PTHREAD_LIBS=
1229 fi
1230
1231 AC_SUBST(PTHREAD_CFLAGS)
1232 AC_SUBST(PTHREAD_LIBS)
1233
1234
1235 # We can test for libldap_r only after we know PTHREAD_LIBS
1236 if test "$with_ldap" = yes ; then
1237   _LIBS="$LIBS"
1238   if test "$PORTNAME" != "win32"; then
1239     AC_CHECK_LIB(ldap, ldap_bind, [],
1240                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1241                  [$EXTRA_LDAP_LIBS])
1242     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1243     if test "$enable_thread_safety" = yes; then
1244       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1245       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1246                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1247                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1248       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1249     else
1250       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1251     fi
1252   else
1253     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1254     LDAP_LIBS_FE="-lwldap32"
1255     LDAP_LIBS_BE="-lwldap32"
1256   fi
1257   LIBS="$_LIBS"
1258 fi
1259 AC_SUBST(LDAP_LIBS_FE)
1260 AC_SUBST(LDAP_LIBS_BE)
1261
1262
1263 # This test makes sure that run tests work at all.  Sometimes a shared
1264 # library is found by the linker, but the runtime linker can't find it.
1265 # This check should come after all modifications of compiler or linker
1266 # variables, and before any other run tests.
1267 AC_MSG_CHECKING([test program])
1268 AC_TRY_RUN([int main() { return 0; }],
1269 [AC_MSG_RESULT(ok)],
1270 [AC_MSG_RESULT(failed)
1271 AC_MSG_ERROR([[
1272 Could not execute a simple test program.  This may be a problem
1273 related to locating shared libraries.  Check the file 'config.log'
1274 for the exact reason.]])],
1275 [AC_MSG_RESULT([cross-compiling])])
1276
1277 # --------------------
1278 # Run tests below here
1279 # --------------------
1280
1281 # Force use of our snprintf if system's doesn't do arg control
1282 # See comment above at snprintf test for details.
1283 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1284   PGAC_FUNC_PRINTF_ARG_CONTROL
1285   if test $pgac_cv_printf_arg_control != yes ; then
1286     pgac_need_repl_snprintf=yes
1287   fi
1288 fi
1289
1290
1291 dnl Check to see if we have a working 64-bit integer type.
1292 dnl This breaks down into two steps:
1293 dnl (1) figure out if the compiler has a 64-bit int type with working
1294 dnl arithmetic, and if so
1295 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1296 dnl snprintf is the only library routine we really need for int8 support.)
1297 dnl It's entirely possible to have a compiler that handles a 64-bit type
1298 dnl when the C library doesn't; this is fairly likely when using gcc on
1299 dnl an older platform, for example.
1300 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1301 dnl we force our own version of snprintf() to be used instead.
1302 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1303
1304 PGAC_TYPE_64BIT_INT([long int])
1305
1306 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1307   PGAC_TYPE_64BIT_INT([long long int])
1308 fi
1309
1310
1311 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1312
1313 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1314   AC_TRY_COMPILE([
1315 #define INT64CONST(x)  x##LL
1316 long long int foo = INT64CONST(0x1234567890123456);
1317 ],
1318         [],
1319         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1320         [])
1321 fi
1322
1323
1324 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1325 # we found we need to use "long long int", better check.  We cope with
1326 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1327 # work, fall back to our own snprintf emulation (which we know uses %lld).
1328
1329 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1330   if test $pgac_need_repl_snprintf = no; then
1331     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1332     if test "$LONG_LONG_INT_FORMAT" = ""; then
1333       # Force usage of our own snprintf, since system snprintf is broken
1334       pgac_need_repl_snprintf=yes
1335       LONG_LONG_INT_FORMAT='%lld'
1336     fi
1337   else
1338     # Here if we previously decided we needed to use our own snprintf
1339     LONG_LONG_INT_FORMAT='%lld'
1340   fi
1341   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1342   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1343   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1344 else
1345   # Here if we are not using 'long long int' at all
1346   INT64_FORMAT='"%ld"'
1347   UINT64_FORMAT='"%lu"'
1348 fi
1349
1350 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1351                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1352
1353 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1354                    [Define to the appropriate snprintf format for unsigned 64-bit ints, if any.])
1355
1356 # Now we have checked all the reasons to replace snprintf
1357 if test $pgac_need_repl_snprintf = yes; then
1358   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1359   AC_LIBOBJ(snprintf)
1360 fi
1361
1362 # Need a #define for the size of Datum (unsigned long)
1363 AC_CHECK_SIZEOF([unsigned long])
1364
1365 # And one for the size of size_t (enables tweaks for > 32bit address space)
1366 AC_CHECK_SIZEOF([size_t])
1367
1368 # Determine memory alignment requirements for the basic C data types.
1369
1370 PGAC_CHECK_ALIGNOF(short)
1371 PGAC_CHECK_ALIGNOF(int)
1372 PGAC_CHECK_ALIGNOF(long)
1373 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1374   PGAC_CHECK_ALIGNOF(long long int)
1375 fi
1376 PGAC_CHECK_ALIGNOF(double)
1377
1378 # Compute maximum alignment of any basic type.
1379 # We assume long's alignment is at least as strong as char, short, or int;
1380 # but we must check long long (if it exists) and double.
1381
1382 MAX_ALIGNOF=$pgac_cv_alignof_long
1383 if test $MAX_ALIGNOF -lt $pgac_cv_alignof_double ; then
1384   MAX_ALIGNOF=$pgac_cv_alignof_double
1385 fi
1386 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $pgac_cv_alignof_long_long_int ; then
1387   MAX_ALIGNOF="$pgac_cv_alignof_long_long_int"
1388 fi
1389 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1390
1391
1392 # Some platforms predefine the types int8, int16, etc.  Only check
1393 # a (hopefully) representative subset.
1394 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1395 [#include <stdio.h>
1396 #ifdef HAVE_SUPPORTDEFS_H
1397 #include <SupportDefs.h>
1398 #endif])
1399
1400 # We also check for sig_atomic_t, which *should* be defined per ANSI
1401 # C, but is missing on some old platforms.
1402 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1403
1404
1405 if test "$PORTNAME" != "win32"
1406 then
1407 PGAC_FUNC_POSIX_SIGNALS
1408 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1409   AC_MSG_ERROR([
1410 Thread-safety requires POSIX signals, which are not supported by this
1411 operating system.])
1412 fi
1413 fi
1414
1415 if test $ac_cv_func_fseeko = yes; then
1416 AC_SYS_LARGEFILE
1417 fi
1418
1419 # SunOS doesn't handle negative byte comparisons properly with +/- return
1420 AC_FUNC_MEMCMP
1421
1422
1423 # Select semaphore implementation type.
1424 if test "$PORTNAME" != "win32"; then
1425   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1426     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1427     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1428   else
1429     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1430       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1431       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1432     else
1433       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1434       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1435     fi
1436   fi
1437 else
1438   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1439   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1440 fi
1441
1442
1443 # Select shared-memory implementation type.
1444 if test "$PORTNAME" != "win32"; then
1445   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1446   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1447 else
1448   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
1449   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
1450 fi
1451
1452 # If not set in template file, set bytes to use libc memset()
1453 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
1454   MEMSET_LOOP_LIMIT=1024
1455 fi
1456 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
1457
1458
1459 if test "$enable_nls" = yes ; then
1460   PGAC_CHECK_GETTEXT
1461 fi
1462
1463 # Check for Tcl configuration script tclConfig.sh
1464 if test "$with_tcl" = yes; then
1465     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1466     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1467                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1468     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1469     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1470     ac_save_CPPFLAGS=$CPPFLAGS
1471     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1472     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1473     CPPFLAGS=$ac_save_CPPFLAGS
1474 fi
1475
1476 #
1477 # Check for DocBook and tools
1478 #
1479 PGAC_PROG_NSGMLS
1480 PGAC_PROG_JADE
1481 PGAC_CHECK_DOCBOOK(4.2)
1482 PGAC_PATH_DOCBOOK_STYLESHEETS
1483 PGAC_PATH_COLLATEINDEX
1484 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1485
1486 # Thread testing
1487
1488 # We have to run the thread test near the end so we have all our symbols
1489 # defined.  Cross compiling throws a warning.
1490 #
1491 if test "$enable_thread_safety_force" = yes; then
1492 if test "$PORTNAME" != "win32"
1493 then
1494   AC_MSG_WARN([
1495 *** Skipping thread test program.  --enable-thread-safety-force was used.
1496 *** Run the program in src/test/thread on the your machine and add proper
1497 *** locking function calls to your applications to guarantee thread safety.
1498 ])
1499 else
1500 AC_MSG_WARN([*** skipping thread test on Win32])
1501 fi
1502 elif test "$enable_thread_safety" = yes; then
1503 if test "$PORTNAME" != "win32"
1504 then
1505 AC_MSG_CHECKING([thread safety of required library functions])
1506
1507 _CFLAGS="$CFLAGS"
1508 _LIBS="$LIBS"
1509 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1510 LIBS="$LIBS $PTHREAD_LIBS"
1511 AC_TRY_RUN([#include "$srcdir/src/test/thread/thread_test.c"],
1512   [AC_MSG_RESULT(yes)],
1513   [AC_MSG_RESULT(no)
1514   AC_MSG_ERROR([thread test program failed
1515 This platform is not thread-safe.  Check the file 'config.log'for the
1516 exact reason.
1517
1518 You can use the configure option --enable-thread-safety-force to force
1519 threads to be enabled.  But you must then run the program in
1520 src/test/thread and add locking function calls to your applications to
1521 guarantee thread safety.])],
1522   [AC_MSG_RESULT(maybe)
1523   AC_MSG_WARN([
1524 *** Skipping thread test program because of cross-compile build.
1525 *** Run the program in src/test/thread on the target machine.
1526 ])])
1527 CFLAGS="$_CFLAGS"
1528 LIBS="$_LIBS"
1529 else
1530 AC_MSG_WARN([*** skipping thread test on Win32])
1531 fi
1532 fi
1533
1534 # prepare build tree if outside source tree
1535 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1536 # Note 2: /bin/pwd might be better than shell's built-in at getting
1537 #         a symlink-free name.
1538 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1539   vpath_build=no
1540 else
1541   vpath_build=yes
1542   if test "$no_create" != yes; then
1543     _AS_ECHO_N([preparing build tree... ])
1544     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1545     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1546       || AC_MSG_ERROR(failed)
1547     AC_MSG_RESULT(done)
1548   fi
1549 fi
1550 AC_SUBST(vpath_build)
1551
1552
1553 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1554
1555 AC_CONFIG_LINKS([
1556   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1557   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1558   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1559   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1560   src/include/pg_config_os.h:src/include/port/${template}.h
1561   src/Makefile.port:src/makefiles/Makefile.${template}
1562 ])
1563
1564 if test "$PORTNAME" = "win32"; then
1565 AC_CONFIG_COMMANDS([check_win32_symlinks],[
1566 # Links sometimes fail undetected on Mingw -
1567 # so here we detect it and warn the user
1568 for FILE in $CONFIG_LINKS
1569  do
1570         # test -e works for symlinks in the MinGW console
1571         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
1572  done
1573 ])
1574 fi
1575
1576 AC_CONFIG_HEADERS([src/include/pg_config.h],
1577 [
1578 # Update timestamp for pg_config.h (see Makefile.global)
1579 echo >src/include/stamp-h
1580 ])
1581
1582 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h])
1583
1584 AC_OUTPUT
1585
1586 # Warn about unknown options
1587 PGAC_ARG_CHECK