configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl configure.in
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [9.1beta1], [pgsql-bugs@postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.63], [], [m4_fatal([Autoconf version 2.63 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2011, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version as a string])
  33 [PG_MAJORVERSION=`expr "$PACKAGE_VERSION" : '\([0-9][0-9]*\.[0-9][0-9]*\)'`]
  34 AC_SUBST(PG_MAJORVERSION)
  35 AC_DEFINE_UNQUOTED(PG_MAJORVERSION, "$PG_MAJORVERSION", [PostgreSQL major version as a string])
  36
  37 AC_CANONICAL_HOST
  38
  39 template=
  40 AC_MSG_CHECKING([which template to use])
  41
  42 PGAC_ARG_REQ(with, template, [NAME], [override operating system template],
  43 [
  44   case $withval in
  45     list)   echo; ls "$srcdir/src/template"; exit;;
  46     *)      if test -f "$srcdir/src/template/$with_template" ; then
  47               template=$withval
  48             else
  49               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  50             fi;;
  51   esac
  52 ],
  53 [
  54 # --with-template not given
  55
  56 case $host_os in
  57      aix*) template=aix ;;
  58     bsdi*) template=bsdi ;;
  59   cygwin*) template=cygwin ;;
  60   darwin*) template=darwin ;;
  61 dragonfly*) template=netbsd ;;
  62     dgux*) template=dgux ;;
  63  freebsd*) template=freebsd ;;
  64     hpux*) template=hpux ;;
  65     irix*) template=irix ;;
  66  linux*|gnu*|k*bsd*-gnu)
  67            template=linux ;;
  68    mingw*) template=win32 ;;
  69   netbsd*) template=netbsd ;;
  70 nextstep*) template=nextstep ;;
  71  openbsd*) template=openbsd ;;
  72      osf*) template=osf ;;
  73      sco*) template=sco ;;
  74  solaris*) template=solaris ;;
  75    sunos*) template=sunos4 ;;
  76  sysv4.2*)
  77         case $host_vendor in
  78           univel) template=univel ;;
  79         esac ;;
  80    sysv4*) template=svr4 ;;
  81    sysv5*) template=unixware ;;
  82   ultrix*) template=ultrix4 ;;
  83 esac
  84
  85   if test x"$template" = x"" ; then
  86     AC_MSG_ERROR([[
  87 *******************************************************************
  88 PostgreSQL has apparently not been ported to your platform yet.
  89 To try a manual configuration, look into the src/template directory
  90 for a similar platform and use the '--with-template=' option.
  91
  92 Please also contact <pgsql-bugs@postgresql.org> to see about
  93 rectifying this.  Include the above 'checking host system type...'
  94 line.
  95 *******************************************************************
  96 ]])
  97   fi
  98
  99 ])
 100
 101 AC_MSG_RESULT([$template])
 102
 103 PORTNAME=$template
 104 AC_SUBST(PORTNAME)
 105
 106 # Initialize default assumption that we do not need separate assembly code
 107 # for TAS (test-and-set).  This can be overridden by the template file
 108 # when it's executed.
 109 need_tas=no
 110 tas_file=dummy.s
 111
 112
 113
 114 ##
 115 ## Command line options
 116 ##
 117
 118 #
 119 # Add non-standard directories to the include path
 120 #
 121 PGAC_ARG_REQ(with, includes, [DIRS], [look for additional header files in DIRS])
 122
 123
 124 #
 125 # Add non-standard directories to the library search path
 126 #
 127 PGAC_ARG_REQ(with, libraries, [DIRS], [look for additional libraries in DIRS],
 128              [LIBRARY_DIRS=$withval])
 129
 130 PGAC_ARG_REQ(with, libs,      [DIRS], [alternative spelling of --with-libraries],
 131              [LIBRARY_DIRS=$withval])
 132
 133
 134 #
 135 # 64-bit integer date/time storage: enabled by default.
 136 #
 137 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 138 PGAC_ARG_BOOL(enable, integer-datetimes, yes, [disable 64-bit integer date/time support],
 139               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 140                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 141 AC_MSG_RESULT([$enable_integer_datetimes])
 142
 143
 144 #
 145 # NLS
 146 #
 147 AC_MSG_CHECKING([whether NLS is wanted])
 148 PGAC_ARG_OPTARG(enable, nls,
 149                 [LANGUAGES], [enable Native Language Support],
 150                 [],
 151                 [WANTED_LANGUAGES=$enableval],
 152                 [AC_DEFINE(ENABLE_NLS, 1,
 153                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 154 AC_MSG_RESULT([$enable_nls])
 155 AC_SUBST(enable_nls)
 156 AC_SUBST(WANTED_LANGUAGES)
 157
 158 #
 159 # Default port number (--with-pgport), default 5432
 160 #
 161 AC_MSG_CHECKING([for default port number])
 162 PGAC_ARG_REQ(with, pgport, [PORTNUM], [set default port number [5432]],
 163              [default_port=$withval],
 164              [default_port=5432])
 165 AC_MSG_RESULT([$default_port])
 166 # Need both of these because some places want an integer and some a string
 167 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 168 [Define to the default TCP port number on which the server listens and
 169 to which clients will try to connect.  This can be overridden at run-time,
 170 but it's convenient if your clients have the right default compiled in.
 171 (--with-pgport=PORTNUM)])
 172 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 173                    [Define to the default TCP port number as a string constant.])
 174 AC_SUBST(default_port)
 175
 176 #
 177 # Option to disable shared libraries
 178 #
 179 PGAC_ARG_BOOL(enable, shared, yes,
 180               [do not build shared libraries])
 181 AC_SUBST(enable_shared)
 182
 183 #
 184 # '-rpath'-like feature can be disabled
 185 #
 186 PGAC_ARG_BOOL(enable, rpath, yes,
 187               [do not embed shared library search path in executables])
 188 AC_SUBST(enable_rpath)
 189
 190 #
 191 # Spinlocks
 192 #
 193 PGAC_ARG_BOOL(enable, spinlocks, yes,
 194               [do not use spinlocks])
 195
 196 #
 197 # --enable-debug adds -g to compiler flags
 198 #
 199 PGAC_ARG_BOOL(enable, debug, no,
 200               [build with debugging symbols (-g)])
 201 AC_SUBST(enable_debug)
 202
 203 #
 204 # --enable-profiling enables gcc profiling
 205 #
 206 PGAC_ARG_BOOL(enable, profiling, no,
 207               [build with profiling enabled ])
 208 AC_SUBST(enable_profiling)
 209
 210 #
 211 # --enable-coverage enables generation of code coverage metrics with gcov
 212 #
 213 PGAC_ARG_BOOL(enable, coverage, no,
 214               [build with coverage testing instrumentation],
 215 [AC_CHECK_PROGS(GCOV, gcov)
 216 if test -z "$GCOV"; then
 217   AC_MSG_ERROR([gcov not found])
 218 fi
 219 AC_CHECK_PROGS(LCOV, lcov)
 220 if test -z "$LCOV"; then
 221   AC_MSG_ERROR([lcov not found])
 222 fi
 223 AC_CHECK_PROGS(GENHTML, genhtml)
 224 if test -z "$GENHTML"; then
 225   AC_MSG_ERROR([genhtml not found])
 226 fi])
 227 AC_SUBST(enable_coverage)
 228
 229 #
 230 # DTrace
 231 #
 232 PGAC_ARG_BOOL(enable, dtrace, no,
 233               [build with DTrace support],
 234 [AC_DEFINE([ENABLE_DTRACE], 1,
 235            [Define to 1 to enable DTrace support. (--enable-dtrace)])
 236 AC_CHECK_PROGS(DTRACE, dtrace)
 237 if test -z "$DTRACE"; then
 238   AC_MSG_ERROR([dtrace not found])
 239 fi
 240 AC_SUBST(DTRACEFLAGS)])
 241 AC_SUBST(enable_dtrace)
 242
 243 #
 244 # Block size
 245 #
 246 AC_MSG_CHECKING([for block size])
 247 PGAC_ARG_REQ(with, blocksize, [BLOCKSIZE], [set table block size in kB [8]],
 248              [blocksize=$withval],
 249              [blocksize=8])
 250 case ${blocksize} in
 251   1) BLCKSZ=1024;;
 252   2) BLCKSZ=2048;;
 253   4) BLCKSZ=4096;;
 254   8) BLCKSZ=8192;;
 255  16) BLCKSZ=16384;;
 256  32) BLCKSZ=32768;;
 257   *) AC_MSG_ERROR([Invalid block size. Allowed values are 1,2,4,8,16,32.])
 258 esac
 259 AC_MSG_RESULT([${blocksize}kB])
 260
 261 AC_DEFINE_UNQUOTED([BLCKSZ], ${BLCKSZ}, [
 262  Size of a disk block --- this also limits the size of a tuple.  You
 263  can set it bigger if you need bigger tuples (although TOAST should
 264  reduce the need to have large tuples, since fields can be spread
 265  across multiple tuples).
 266
 267  BLCKSZ must be a power of 2.  The maximum possible value of BLCKSZ
 268  is currently 2^15 (32768).  This is determined by the 15-bit widths
 269  of the lp_off and lp_len fields in ItemIdData (see
 270  include/storage/itemid.h).
 271
 272  Changing BLCKSZ requires an initdb.
 273 ])
 274
 275 #
 276 # Relation segment size
 277 #
 278 AC_MSG_CHECKING([for segment size])
 279 PGAC_ARG_REQ(with, segsize, [SEGSIZE], [set table segment size in GB [1]],
 280              [segsize=$withval],
 281              [segsize=1])
 282 # this expression is set up to avoid unnecessary integer overflow
 283 # blocksize is already guaranteed to be a factor of 1024
 284 RELSEG_SIZE=`expr '(' 1024 / ${blocksize} ')' '*' ${segsize} '*' 1024`
 285 test $? -eq 0 || exit 1
 286 AC_MSG_RESULT([${segsize}GB])
 287
 288 AC_DEFINE_UNQUOTED([RELSEG_SIZE], ${RELSEG_SIZE}, [
 289  RELSEG_SIZE is the maximum number of blocks allowed in one disk file.
 290  Thus, the maximum size of a single file is RELSEG_SIZE * BLCKSZ;
 291  relations bigger than that are divided into multiple files.
 292
 293  RELSEG_SIZE * BLCKSZ must be less than your OS' limit on file size.
 294  This is often 2 GB or 4GB in a 32-bit operating system, unless you
 295  have large file support enabled.  By default, we make the limit 1 GB
 296  to avoid any possible integer-overflow problems within the OS.
 297  A limit smaller than necessary only means we divide a large
 298  relation into more chunks than necessary, so it seems best to err
 299  in the direction of a small limit.
 300
 301  A power-of-2 value is recommended to save a few cycles in md.c,
 302  but is not absolutely required.
 303
 304  Changing RELSEG_SIZE requires an initdb.
 305 ])
 306
 307 #
 308 # WAL block size
 309 #
 310 AC_MSG_CHECKING([for WAL block size])
 311 PGAC_ARG_REQ(with, wal-blocksize, [BLOCKSIZE], [set WAL block size in kB [8]],
 312              [wal_blocksize=$withval],
 313              [wal_blocksize=8])
 314 case ${wal_blocksize} in
 315   1) XLOG_BLCKSZ=1024;;
 316   2) XLOG_BLCKSZ=2048;;
 317   4) XLOG_BLCKSZ=4096;;
 318   8) XLOG_BLCKSZ=8192;;
 319  16) XLOG_BLCKSZ=16384;;
 320  32) XLOG_BLCKSZ=32768;;
 321  64) XLOG_BLCKSZ=65536;;
 322   *) AC_MSG_ERROR([Invalid WAL block size. Allowed values are 1,2,4,8,16,32,64.])
 323 esac
 324 AC_MSG_RESULT([${wal_blocksize}kB])
 325
 326 AC_DEFINE_UNQUOTED([XLOG_BLCKSZ], ${XLOG_BLCKSZ}, [
 327  Size of a WAL file block.  This need have no particular relation to BLCKSZ.
 328  XLOG_BLCKSZ must be a power of 2, and if your system supports O_DIRECT I/O,
 329  XLOG_BLCKSZ must be a multiple of the alignment requirement for direct-I/O
 330  buffers, else direct I/O may fail.
 331
 332  Changing XLOG_BLCKSZ requires an initdb.
 333 ])
 334
 335 #
 336 # WAL segment size
 337 #
 338 AC_MSG_CHECKING([for WAL segment size])
 339 PGAC_ARG_REQ(with, wal-segsize, [SEGSIZE], [set WAL segment size in MB [16]],
 340              [wal_segsize=$withval],
 341              [wal_segsize=16])
 342 case ${wal_segsize} in
 343   1) ;;
 344   2) ;;
 345   4) ;;
 346   8) ;;
 347  16) ;;
 348  32) ;;
 349  64) ;;
 350   *) AC_MSG_ERROR([Invalid WAL segment size. Allowed values are 1,2,4,8,16,32,64.])
 351 esac
 352 AC_MSG_RESULT([${wal_segsize}MB])
 353
 354 AC_DEFINE_UNQUOTED([XLOG_SEG_SIZE], [(${wal_segsize} * 1024 * 1024)], [
 355  XLOG_SEG_SIZE is the size of a single WAL file.  This must be a power of 2
 356  and larger than XLOG_BLCKSZ (preferably, a great deal larger than
 357  XLOG_BLCKSZ).
 358
 359  Changing XLOG_SEG_SIZE requires an initdb.
 360 ])
 361
 362 #
 363 # C compiler
 364 #
 365
 366 # For historical reasons you can also use --with-CC to specify the C compiler
 367 # to use, although the standard way to do this is to set the CC environment
 368 # variable.
 369 PGAC_ARG_REQ(with, CC, [CMD], [set compiler (deprecated)], [CC=$with_CC])
 370
 371 case $template in
 372   aix) pgac_cc_list="gcc xlc";;
 373  irix) pgac_cc_list="cc";; # no gcc
 374     *) pgac_cc_list="gcc cc";;
 375 esac
 376
 377 AC_PROG_CC([$pgac_cc_list])
 378
 379 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 380 # but has idiosyncrasies of its own.  We assume icc will define
 381 # __INTEL_COMPILER regardless of CFLAGS.
 382 AC_TRY_COMPILE([], [@%:@ifndef __INTEL_COMPILER
 383 choke me
 384 @%:@endif], [ICC=[yes]], [ICC=[no]])
 385
 386 # Check if it's Sun Studio compiler. We assume that
 387 # __SUNPRO_C will be defined for Sun Studio compilers
 388 AC_TRY_COMPILE([], [@%:@ifndef __SUNPRO_C
 389 choke me
 390 @%:@endif], [SUN_STUDIO_CC=yes], [SUN_STUDIO_CC=no])
 391
 392 AC_SUBST(SUN_STUDIO_CC)
 393
 394 unset CFLAGS
 395
 396 #
 397 # Read the template
 398 #
 399 . "$srcdir/src/template/$template" || exit
 400
 401 # CFLAGS are selected so:
 402 # If the user specifies something in the environment, that is used.
 403 # else:  If the template file set something, that is used.
 404 # else:  If coverage was enabled, don't set anything.
 405 # else:  If the compiler is GCC, then we use -O2.
 406 # else:  If the compiler is something else, then we use -O, unless debugging.
 407
 408 if test "$ac_env_CFLAGS_set" = set; then
 409   CFLAGS=$ac_env_CFLAGS_value
 410 elif test "${CFLAGS+set}" = set; then
 411   : # (keep what template set)
 412 elif test "$enable_coverage" = yes; then
 413   : # no optimization by default
 414 elif test "$GCC" = yes; then
 415   CFLAGS="-O2"
 416 else
 417   # if the user selected debug mode, don't use -O
 418   if test "$enable_debug" != yes; then
 419     CFLAGS="-O"
 420   fi
 421 fi
 422
 423 # Some versions of GCC support some additional useful warning flags.
 424 # Check whether they are supported, and add them to CFLAGS if so.
 425 # ICC pretends to be GCC but it's lying; it doesn't support these flags,
 426 # but has its own.  Also check other compiler-specific flags here.
 427
 428 if test "$GCC" = yes -a "$ICC" = no; then
 429   CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wpointer-arith"
 430   # These work in some but not all gcc versions
 431   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 432   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 433   # This was included in -Wall/-Wformat in older GCC versions
 434   PGAC_PROG_CC_CFLAGS_OPT([-Wformat-security])
 435   # Disable strict-aliasing rules; needed for gcc 3.3+
 436   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 437   # Disable optimizations that assume no overflow; needed for gcc 4.3+
 438   PGAC_PROG_CC_CFLAGS_OPT([-fwrapv])
 439 elif test "$ICC" = yes; then
 440   # Intel's compiler has a bug/misoptimization in checking for
 441   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 442   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 443   # Make sure strict aliasing is off (though this is said to be the default)
 444   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 445 elif test "$PORTNAME" = "aix"; then
 446   # AIX's xlc has to have strict aliasing turned off too
 447   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 448 fi
 449
 450 # supply -g if --enable-debug
 451 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 452   CFLAGS="$CFLAGS -g"
 453 fi
 454
 455 # enable code coverage if --enable-coverage
 456 if test "$enable_coverage" = yes; then
 457   if test "$GCC" = yes; then
 458     CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 459   else
 460     AC_MSG_ERROR([--enable-coverage is supported only when using GCC])
 461   fi
 462 fi
 463
 464 # enable profiling if --enable-profiling
 465 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 466   if test "$GCC" = yes; then
 467     AC_DEFINE([PROFILE_PID_DIR], 1,
 468            [Define to 1 to allow profiling output to be saved separately for each process.])
 469     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 470   else
 471     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 472   fi
 473 fi
 474
 475 # We already have this in Makefile.win32, but configure needs it too
 476 if test "$PORTNAME" = "win32"; then
 477   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 478 fi
 479
 480 # Check if the compiler still works with the template settings
 481 AC_MSG_CHECKING([whether the C compiler still works])
 482 AC_TRY_LINK([], [return 0;],
 483   [AC_MSG_RESULT(yes)],
 484   [AC_MSG_RESULT(no)
 485    AC_MSG_ERROR([cannot proceed])])
 486
 487 # Defend against gcc -ffast-math
 488 if test "$GCC" = yes; then
 489 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 490 choke me
 491 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 492 fi
 493
 494 AC_PROG_CPP
 495 AC_SUBST(GCC)
 496
 497
 498 #
 499 # Set up TAS assembly code if needed; the template file has now had its
 500 # chance to request this.
 501 #
 502 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 503
 504 if test "$need_tas" = yes ; then
 505   TAS=tas.o
 506 else
 507   TAS=""
 508 fi
 509 AC_SUBST(TAS)
 510
 511
 512 #
 513 # Automatic dependency tracking
 514 #
 515 PGAC_ARG_BOOL(enable, depend, no, [turn on automatic dependency tracking],
 516               [autodepend=yes])
 517 AC_SUBST(autodepend)
 518
 519
 520 #
 521 # Enable assert checks
 522 #
 523 PGAC_ARG_BOOL(enable, cassert, no, [enable assertion checks (for debugging)],
 524               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 525                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 526
 527
 528 #
 529 # Include directories
 530 #
 531 ac_save_IFS=$IFS
 532 IFS="${IFS}${PATH_SEPARATOR}"
 533 # SRCH_INC comes from the template file
 534 for dir in $with_includes $SRCH_INC; do
 535   if test -d "$dir"; then
 536     INCLUDES="$INCLUDES -I$dir"
 537   else
 538     AC_MSG_WARN([*** Include directory $dir does not exist.])
 539   fi
 540 done
 541 IFS=$ac_save_IFS
 542 AC_SUBST(INCLUDES)
 543
 544
 545 #
 546 # Library directories
 547 #
 548 ac_save_IFS=$IFS
 549 IFS="${IFS}${PATH_SEPARATOR}"
 550 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 551 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 552   if test -d "$dir"; then
 553     LIBDIRS="$LIBDIRS -L$dir"
 554   else
 555     AC_MSG_WARN([*** Library directory $dir does not exist.])
 556   fi
 557 done
 558 IFS=$ac_save_IFS
 559
 560 #
 561 # Enable thread-safe client libraries
 562 #
 563 AC_MSG_CHECKING([allow thread-safe client libraries])
 564 PGAC_ARG_BOOL(enable, thread-safety, yes, [disable thread-safety in client libraries])
 565 if test "$enable_thread_safety" = yes; then
 566   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 567           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 568 fi
 569 AC_MSG_RESULT([$enable_thread_safety])
 570 AC_SUBST(enable_thread_safety)
 571
 572 #
 573 # Optionally build Tcl modules (PL/Tcl)
 574 #
 575 AC_MSG_CHECKING([whether to build with Tcl])
 576 PGAC_ARG_BOOL(with, tcl, no, [build Tcl modules (PL/Tcl)])
 577 AC_MSG_RESULT([$with_tcl])
 578 AC_SUBST([with_tcl])
 579
 580 # We see if the path to the Tcl/Tk configuration scripts is specified.
 581 # This will override the use of tclsh to find the paths to search.
 582
 583 PGAC_ARG_REQ(with, tclconfig, [DIR], [tclConfig.sh is in DIR])
 584
 585 #
 586 # Optionally build Perl modules (PL/Perl)
 587 #
 588 AC_MSG_CHECKING([whether to build Perl modules])
 589 PGAC_ARG_BOOL(with, perl, no, [build Perl modules (PL/Perl)])
 590 AC_MSG_RESULT([$with_perl])
 591 AC_SUBST(with_perl)
 592
 593 #
 594 # Optionally build Python modules (PL/Python)
 595 #
 596 AC_MSG_CHECKING([whether to build Python modules])
 597 PGAC_ARG_BOOL(with, python, no, [build Python modules (PL/Python)])
 598 AC_MSG_RESULT([$with_python])
 599 AC_SUBST(with_python)
 600
 601 #
 602 # GSSAPI
 603 #
 604 AC_MSG_CHECKING([whether to build with GSSAPI support])
 605 PGAC_ARG_BOOL(with, gssapi, no, [build with GSSAPI support],
 606 [
 607   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 608   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 609 ])
 610 AC_MSG_RESULT([$with_gssapi])
 611 AC_SUBST(with_gssapi)
 612
 613 #
 614 # Kerberos 5
 615 #
 616 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 617 PGAC_ARG_BOOL(with, krb5, no, [build with Kerberos 5 support],
 618 [
 619   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 620   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 621 ])
 622 AC_MSG_RESULT([$with_krb5])
 623 AC_SUBST(with_krb5)
 624
 625
 626 AC_SUBST(krb_srvtab)
 627
 628
 629 #
 630 # Kerberos configuration parameters
 631 #
 632 PGAC_ARG_REQ(with, krb-srvnam,
 633              [NAME], [default service principal name in Kerberos [postgres]],
 634              [],
 635              [with_krb_srvnam="postgres"])
 636 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 637                    [Define to the name of the default PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 638
 639
 640 #
 641 # PAM
 642 #
 643 AC_MSG_CHECKING([whether to build with PAM support])
 644 PGAC_ARG_BOOL(with, pam, no,
 645               [build with PAM support],
 646               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 647 AC_MSG_RESULT([$with_pam])
 648 AC_SUBST(with_pam)
 649
 650
 651 #
 652 # LDAP
 653 #
 654 AC_MSG_CHECKING([whether to build with LDAP support])
 655 PGAC_ARG_BOOL(with, ldap, no,
 656               [build with LDAP support],
 657               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 658 AC_MSG_RESULT([$with_ldap])
 659 AC_SUBST(with_ldap)
 660
 661
 662 #
 663 # Bonjour
 664 #
 665 AC_MSG_CHECKING([whether to build with Bonjour support])
 666 PGAC_ARG_BOOL(with, bonjour, no,
 667               [build with Bonjour support],
 668               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 669 AC_MSG_RESULT([$with_bonjour])
 670 AC_SUBST(with_bonjour)
 671
 672
 673 #
 674 # OpenSSL
 675 #
 676 AC_MSG_CHECKING([whether to build with OpenSSL support])
 677 PGAC_ARG_BOOL(with, openssl, no, [build with OpenSSL support],
 678               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 679 AC_MSG_RESULT([$with_openssl])
 680 AC_SUBST(with_openssl)
 681
 682 #
 683 # SELinux
 684 #
 685 AC_MSG_CHECKING([whether to build with SELinux support])
 686 PGAC_ARG_BOOL(with, selinux, no, [build with SELinux support])
 687 AC_SUBST(with_selinux)
 688 AC_MSG_RESULT([$with_selinux])
 689
 690 #
 691 # Readline
 692 #
 693 PGAC_ARG_BOOL(with, readline, yes,
 694               [do not use GNU Readline nor BSD Libedit for editing])
 695 # readline on MinGW has problems with backslashes in psql and other bugs.
 696 # This is particularly a problem with non-US code pages.
 697 # Therefore disable its use until we understand the cause. 2004-07-20
 698 if test "$PORTNAME" = "win32"; then
 699   if test "$with_readline" = yes; then
 700     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 701     with_readline=no
 702   fi
 703 fi
 704
 705
 706 #
 707 # Prefer libedit
 708 #
 709 PGAC_ARG_BOOL(with, libedit-preferred, no,
 710               [prefer BSD Libedit over GNU Readline])
 711
 712
 713 #
 714 # OSSP UUID library
 715 #
 716 PGAC_ARG_BOOL(with, ossp-uuid, no, [use OSSP UUID library when building contrib/uuid-ossp])
 717 AC_SUBST(with_ossp_uuid)
 718
 719
 720 #
 721 # XML
 722 #
 723 PGAC_ARG_BOOL(with, libxml, no, [build with XML support],
 724               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 725
 726 if test "$with_libxml" = yes ; then
 727   AC_CHECK_PROGS(XML2_CONFIG, xml2-config)
 728   if test -n "$XML2_CONFIG"; then
 729     for pgac_option in `$XML2_CONFIG --cflags`; do
 730       case $pgac_option in
 731         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 732       esac
 733     done
 734     for pgac_option in `$XML2_CONFIG --libs`; do
 735       case $pgac_option in
 736         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 737       esac
 738     done
 739   fi
 740 fi
 741
 742 AC_SUBST(with_libxml)
 743
 744 #
 745 # XSLT
 746 #
 747 PGAC_ARG_BOOL(with, libxslt, no, [use XSLT support when building contrib/xml2],
 748               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 749
 750
 751 AC_SUBST(with_libxslt)
 752
 753 #
 754 # tzdata
 755 #
 756 PGAC_ARG_REQ(with, system-tzdata,
 757              [DIR], [use system time zone data in DIR])
 758 AC_SUBST(with_system_tzdata)
 759
 760 #
 761 # Zlib
 762 #
 763 PGAC_ARG_BOOL(with, zlib, yes,
 764               [do not use Zlib])
 765 AC_SUBST(with_zlib)
 766
 767 #
 768 # Elf
 769 #
 770
 771 # Assume system is ELF if it predefines __ELF__ as 1,
 772 # otherwise believe host_os based default.
 773 case $host_os in
 774     freebsd1*|freebsd2*) elf=no;;
 775     freebsd3*|freebsd4*) elf=yes;;
 776 esac
 777
 778 AC_EGREP_CPP(yes,
 779 [#if __ELF__
 780   yes
 781 #endif
 782 ],
 783 [ELF_SYS=true],
 784 [if test "X$elf" = "Xyes" ; then
 785   ELF_SYS=true
 786 else
 787   ELF_SYS=
 788 fi])
 789 AC_SUBST(ELF_SYS)
 790
 791 #
 792 # Assignments
 793 #
 794
 795 CPPFLAGS="$CPPFLAGS $INCLUDES"
 796 LDFLAGS="$LDFLAGS $LIBDIRS"
 797
 798 AC_ARG_VAR(LDFLAGS_EX, [extra linker flags for linking executables only])
 799 AC_ARG_VAR(LDFLAGS_SL, [extra linker flags for linking shared libraries only])
 800
 801 PGAC_PROG_LD
 802 AC_SUBST(LD)
 803 AC_SUBST(with_gnu_ld)
 804 case $host_os in sysv5*)
 805   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 806   [
 807     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 808     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 809     LDFLAGS=$pgac_save_LDFLAGS
 810   ])
 811   ld_R_works=$pgac_cv_prog_ld_R
 812   AC_SUBST(ld_R_works)
 813 esac
 814 AC_PROG_RANLIB
 815 PGAC_CHECK_STRIP
 816 AC_CHECK_TOOL(AR, ar, ar)
 817 if test "$PORTNAME" = "win32"; then
 818   AC_CHECK_TOOL(DLLTOOL, dlltool, dlltool)
 819   AC_CHECK_TOOL(DLLWRAP, dllwrap, dllwrap)
 820   AC_CHECK_TOOL(WINDRES, windres, windres)
 821 fi
 822
 823 AC_PATH_PROG(TAR, tar)
 824 AC_PROG_LN_S
 825 AC_PROG_AWK
 826 AC_PROG_MKDIR_P
 827 # When Autoconf chooses install-sh as mkdir -p program it tries to generate
 828 # a relative path to it in each makefile where it subsitutes it. This clashes
 829 # with our Makefile.global concept. This workaround helps.
 830 case $MKDIR_P in
 831   *install-sh*) MKDIR_P='\${SHELL} \${top_srcdir}/config/install-sh -c -d';;
 832 esac
 833
 834 PGAC_PATH_BISON
 835 PGAC_PATH_FLEX
 836
 837 PGAC_PATH_PERL
 838 if test "$with_perl" = yes; then
 839   if test -z "$PERL"; then
 840     AC_MSG_ERROR([Perl not found])
 841   fi
 842   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 843   PGAC_CHECK_PERL_EMBED_LDFLAGS
 844 fi
 845
 846 if test "$with_python" = yes; then
 847   PGAC_PATH_PYTHON
 848   PGAC_CHECK_PYTHON_EMBED_SETUP
 849 fi
 850
 851 if test "$cross_compiling" = yes && test -z "$with_system_tzdata"; then
 852   AC_PATH_PROG(ZIC, zic)
 853   if test -z "$ZIC"; then
 854     AC_MSG_ERROR([
 855 When cross-compiling, either use the option --with-system-tzdata to use
 856 existing time-zone data, or set the environment variable ZIC to a zic
 857 program to use during the build.])
 858   fi
 859 fi
 860
 861
 862 ##
 863 ## Libraries
 864 ##
 865 ## Most libraries are included only if they demonstrably provide a function
 866 ## we need, but libm is an exception: always include it, because there are
 867 ## too many compilers that play cute optimization games that will break
 868 ## probes for standard functions such as pow().
 869 ##
 870
 871 AC_CHECK_LIB(m, main)
 872 AC_SEARCH_LIBS(setproctitle, util)
 873 AC_SEARCH_LIBS(dlopen, dl)
 874 AC_SEARCH_LIBS(socket, [socket wsock32])
 875 AC_SEARCH_LIBS(shl_load, dld)
 876 # We only use libld in port/dynloader/aix.c
 877 case $host_os in
 878      aix*)
 879         AC_SEARCH_LIBS(ldopen, ld)
 880         ;;
 881 esac
 882 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 883 AC_SEARCH_LIBS(crypt, crypt)
 884 # Solaris:
 885 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 886 # Required for thread_test.c on Solaris 2.5:
 887 # Other ports use it too (HP-UX) so test unconditionally
 888 AC_SEARCH_LIBS(gethostbyname_r, nsl)
 889 # Cygwin:
 890 AC_SEARCH_LIBS(shmget, cygipc)
 891
 892 if test "$with_readline" = yes; then
 893   PGAC_CHECK_READLINE
 894   if test x"$pgac_cv_check_readline" = x"no"; then
 895     AC_MSG_ERROR([readline library not found
 896 If you have readline already installed, see config.log for details on the
 897 failure.  It is possible the compiler isn't looking in the proper directory.
 898 Use --without-readline to disable readline support.])
 899   fi
 900 fi
 901
 902 if test "$with_zlib" = yes; then
 903   AC_CHECK_LIB(z, inflate, [],
 904                [AC_MSG_ERROR([zlib library not found
 905 If you have zlib already installed, see config.log for details on the
 906 failure.  It is possible the compiler isn't looking in the proper directory.
 907 Use --without-zlib to disable zlib support.])])
 908 fi
 909
 910 if test "$enable_spinlocks" = yes; then
 911   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 912 else
 913   AC_MSG_WARN([
 914 *** Not using spinlocks will cause poor performance.])
 915 fi
 916
 917 if test "$with_gssapi" = yes ; then
 918   if test "$PORTNAME" != "win32"; then
 919     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
 920                                   [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
 921   else
 922     LIBS="$LIBS -lgssapi32"
 923   fi
 924 fi
 925
 926 if test "$with_krb5" = yes ; then
 927   if test "$PORTNAME" != "win32"; then
 928      AC_SEARCH_LIBS(com_err, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken' com_err 'com_err -lssl -lcrypto'], [],
 929                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 930      AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken'], [],
 931                     [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 932   else
 933      AC_SEARCH_LIBS(com_err, 'comerr32 -lkrb5_32', [],
 934                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 935   fi
 936 fi
 937
 938 if test "$with_openssl" = yes ; then
 939   dnl Order matters!
 940   if test "$PORTNAME" != "win32"; then
 941      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 942      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 943   else
 944      AC_CHECK_LIB(eay32, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'eay32' is required for OpenSSL])])
 945      AC_CHECK_LIB(ssleay32,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssleay32' is required for OpenSSL])])
 946   fi
 947 fi
 948
 949 if test "$with_pam" = yes ; then
 950   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 951 fi
 952
 953 if test "$with_libxml" = yes ; then
 954   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
 955 fi
 956
 957 if test "$with_libxslt" = yes ; then
 958   AC_CHECK_LIB(xslt, xsltCleanupGlobals, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
 959 fi
 960
 961 # for contrib/sepgsql
 962 if test "$with_selinux" = yes; then
 963   AC_CHECK_LIB(selinux, getpeercon_raw, [],
 964                [AC_MSG_ERROR([library 'libselinux' is required for SELinux support])])
 965 fi
 966
 967 # for contrib/uuid-ossp
 968 if test "$with_ossp_uuid" = yes ; then
 969   AC_CHECK_LIB(ossp-uuid, uuid_export,
 970     [OSSP_UUID_LIBS="-lossp-uuid"],
 971     [AC_CHECK_LIB(uuid, uuid_export,
 972       [OSSP_UUID_LIBS="-luuid"],
 973       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP-UUID])])])
 974 fi
 975 AC_SUBST(OSSP_UUID_LIBS)
 976
 977
 978 ##
 979 ## Header files
 980 ##
 981
 982 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 983 AC_CHECK_HEADERS([crypt.h dld.h fp_class.h getopt.h ieeefp.h ifaddrs.h langinfo.h poll.h pwd.h sys/ioctl.h sys/ipc.h sys/poll.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/shm.h sys/socket.h sys/sockio.h sys/tas.h sys/time.h sys/un.h termios.h ucred.h utime.h wchar.h wctype.h kernel/OS.h kernel/image.h SupportDefs.h])
 984
 985 # On BSD, cpp test for net/if.h will fail unless sys/socket.h
 986 # is included first.
 987 AC_CHECK_HEADERS(net/if.h, [], [],
 988 [AC_INCLUDES_DEFAULT
 989 #ifdef HAVE_SYS_SOCKET_H
 990 #include <sys/socket.h>
 991 #endif
 992 ])
 993
 994 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 995 # netinet/in.h is included first.
 996 AC_CHECK_HEADERS(netinet/in.h)
 997 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 998 [AC_INCLUDES_DEFAULT
 999 #ifdef HAVE_NETINET_IN_H
1000 #include <netinet/in.h>
1001 #endif
1002 ])
1003
1004 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
1005   AC_CHECK_HEADERS(readline/readline.h, [],
1006         [AC_CHECK_HEADERS(readline.h, [],
1007                 [AC_MSG_ERROR([readline header not found
1008 If you have readline already installed, see config.log for details on the
1009 failure.  It is possible the compiler isn't looking in the proper directory.
1010 Use --without-readline to disable readline support.])])])
1011   AC_CHECK_HEADERS(readline/history.h, [],
1012         [AC_CHECK_HEADERS(history.h, [],
1013                 [AC_MSG_ERROR([history header not found
1014 If you have readline already installed, see config.log for details on the
1015 failure.  It is possible the compiler isn't looking in the proper directory.
1016 Use --without-readline to disable readline support.])])])
1017 fi
1018
1019 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
1020 # Some installations of libedit usurp /usr/include/readline/, which seems
1021 # bad practice, since in combined installations readline will have its headers
1022 # there.  We might have to resort to AC_EGREP checks to make sure we found
1023 # the proper header...
1024   AC_CHECK_HEADERS(editline/readline.h, [],
1025         [AC_CHECK_HEADERS(readline.h, [],
1026                 [AC_CHECK_HEADERS(readline/readline.h, [],
1027                         [AC_MSG_ERROR([readline header not found
1028 If you have libedit already installed, see config.log for details on the
1029 failure.  It is possible the compiler isn't looking in the proper directory.
1030 Use --without-readline to disable libedit support.])])])])
1031 # Note: in a libedit installation, history.h is sometimes a dummy, and may
1032 # not be there at all.  Hence, don't complain if not found.  We must check
1033 # though, since in yet other versions it is an independent header.
1034   AC_CHECK_HEADERS(editline/history.h, [],
1035         [AC_CHECK_HEADERS(history.h, [],
1036                 [AC_CHECK_HEADERS(readline/history.h)])])
1037 fi
1038
1039 if test "$with_zlib" = yes; then
1040   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
1041 If you have zlib already installed, see config.log for details on the
1042 failure.  It is possible the compiler isn't looking in the proper directory.
1043 Use --without-zlib to disable zlib support.])])
1044 fi
1045
1046 if test "$with_gssapi" = yes ; then
1047   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
1048         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
1049 fi
1050
1051 if test "$with_krb5" = yes ; then
1052   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
1053 fi
1054
1055 if test "$with_openssl" = yes ; then
1056   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
1057   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
1058   AC_CHECK_FUNCS([ERR_set_mark])
1059 fi
1060
1061 if test "$with_pam" = yes ; then
1062   AC_CHECK_HEADERS(security/pam_appl.h, [],
1063                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
1064                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
1065 fi
1066
1067 if test "$with_libxml" = yes ; then
1068   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
1069 fi
1070
1071 if test "$with_libxslt" = yes ; then
1072   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
1073 fi
1074
1075 if test "$with_ldap" = yes ; then
1076   if test "$PORTNAME" != "win32"; then
1077      AC_CHECK_HEADERS(ldap.h, [],
1078                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
1079   else
1080      AC_CHECK_HEADERS(winldap.h, [],
1081                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
1082                       [AC_INCLUDES_DEFAULT
1083 #include <windows.h>
1084                       ])
1085   fi
1086 fi
1087
1088 if test "$with_bonjour" = yes ; then
1089   AC_CHECK_HEADER(dns_sd.h, [], [AC_MSG_ERROR([header file <dns_sd.h> is required for Bonjour])])
1090 fi
1091
1092 # for contrib/uuid-ossp
1093 if test "$with_ossp_uuid" = yes ; then
1094   AC_CHECK_HEADERS(ossp/uuid.h, [], [
1095     AC_CHECK_HEADERS(uuid.h, [],
1096       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP-UUID])])])
1097 fi
1098
1099
1100 ##
1101 ## Types, structures, compiler characteristics
1102 ##
1103
1104 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
1105 AC_C_BIGENDIAN
1106 AC_C_CONST
1107 PGAC_C_INLINE
1108 AC_C_STRINGIZE
1109 PGAC_C_SIGNED
1110 AC_C_VOLATILE
1111 PGAC_C_FUNCNAME_SUPPORT
1112 PGAC_STRUCT_TIMEZONE
1113 PGAC_UNION_SEMUN
1114 PGAC_STRUCT_SOCKADDR_UN
1115 PGAC_STRUCT_SOCKADDR_STORAGE
1116 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
1117 PGAC_STRUCT_ADDRINFO
1118 AC_TYPE_INTPTR_T
1119 AC_TYPE_UINTPTR_T
1120 AC_TYPE_LONG_LONG_INT
1121
1122 PGAC_TYPE_LOCALE_T
1123
1124 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
1125 [#include <sys/param.h>
1126 #include <sys/types.h>
1127 #include <sys/socket.h>
1128 #include <sys/ucred.h>])
1129
1130 AC_CHECK_TYPES([struct option], [], [],
1131 [#ifdef HAVE_GETOPT_H
1132 #include <getopt.h>
1133 #endif])
1134
1135 if test "$with_zlib" = yes; then
1136   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
1137   # did not).  While we could work around the lack of z_streamp, it
1138   # seems unwise to encourage people to use such old zlib versions...
1139   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
1140 Use --without-zlib to disable zlib support.])],
1141                 [#include <zlib.h>])
1142 fi
1143
1144 if test "$with_krb5" = yes; then
1145 # Check for differences between MIT and Heimdal (KTH) releases
1146   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
1147                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
1148                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
1149                                      [#include <krb5.h>])],
1150                    [#include <krb5.h>])
1151   AC_CHECK_MEMBERS(krb5_error.text.data, [],
1152                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
1153                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
1154                                      [#include <krb5.h>])],
1155                    [#include <krb5.h>])
1156
1157 # Win32 requires headers to be loaded for __stdcall, so can't use
1158 # AC_CHECK_FUNCS here.
1159   AC_MSG_CHECKING(for krb5_free_unparsed_name)
1160   AC_TRY_LINK([#include <krb5.h>],
1161               [krb5_free_unparsed_name(NULL,NULL);],
1162               [AC_DEFINE(HAVE_KRB5_FREE_UNPARSED_NAME, 1, [Define to 1 if you have krb5_free_unparsed_name])
1163 AC_MSG_RESULT(yes)],
1164               [AC_MSG_RESULT(no)])
1165 fi
1166
1167 # Check largefile support.  You might think this is a system service not a
1168 # compiler characteristic, but you'd be wrong.  We must check this before
1169 # probing existence of related functions such as fseeko, since the largefile
1170 # defines can affect what is generated for that.
1171 AC_SYS_LARGEFILE
1172
1173 # Check for largefile support (must be after AC_SYS_LARGEFILE)
1174 AC_CHECK_SIZEOF([off_t])
1175
1176 # If we don't have largefile support, can't handle segsize >= 2GB.
1177 if test "$ac_cv_sizeof_off_t" -lt 8 -a "$segsize" != "1"; then
1178    AC_MSG_ERROR([Large file support is not enabled. Segment size cannot be larger than 1GB.])
1179 fi
1180
1181
1182 ##
1183 ## Functions, global variables
1184 ##
1185
1186 PGAC_VAR_INT_TIMEZONE
1187 AC_FUNC_ACCEPT_ARGTYPES
1188 PGAC_FUNC_GETTIMEOFDAY_1ARG
1189
1190 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getifaddrs getpeereid getpeerucred getrlimit memmove poll pstat readlink scandir setproctitle setsid sigprocmask symlink sysconf towlower utime utimes waitpid wcstombs wcstombs_l])
1191
1192 AC_REPLACE_FUNCS(fseeko)
1193 case $host_os in
1194         # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
1195         # Mingw uses macros to access Win32 API calls
1196         bsdi*|netbsd*|mingw*)
1197                 AC_DEFINE(HAVE_FSEEKO, 1, [Define to 1 because replacement version used.])
1198                 ac_cv_func_fseeko=yes;;
1199         *)
1200                 AC_FUNC_FSEEKO;;
1201 esac
1202
1203 # posix_fadvise() is a no-op on Solaris, so don't incur function overhead
1204 # by calling it, 2009-04-02
1205 # http://src.opensolaris.org/source/xref/onnv/onnv-gate/usr/src/lib/libc/port/gen/posix_fadvise.c
1206 if test "$PORTNAME" != "solaris"; then
1207 AC_CHECK_FUNCS(posix_fadvise)
1208 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
1209 fi
1210
1211 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
1212 AC_CHECK_DECLS([strlcat, strlcpy])
1213 # This is probably only present on Darwin, but may as well check always
1214 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
1215
1216 HAVE_IPV6=no
1217 AC_CHECK_TYPE([struct sockaddr_in6],
1218         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
1219          HAVE_IPV6=yes],
1220         [],
1221 [$ac_includes_default
1222 #include <netinet/in.h>])
1223 AC_SUBST(HAVE_IPV6)
1224
1225 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1226 [AC_TRY_LINK(
1227 [#include <machine/vmparam.h>
1228 #include <sys/exec.h>
1229 ],
1230 [PS_STRINGS->ps_nargvstr = 1;
1231 PS_STRINGS->ps_argvstr = "foo";],
1232 [pgac_cv_var_PS_STRINGS=yes],
1233 [pgac_cv_var_PS_STRINGS=no])])
1234 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1235   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
1236 fi
1237
1238
1239 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
1240 # is missing.  Yes, there are machines that have only one.  We may
1241 # also decide to use snprintf.c if snprintf() is present but does not
1242 # have all the features we need --- see below.
1243
1244 if test "$PORTNAME" = "win32"; then
1245   # Win32 gets snprintf.c built unconditionally.
1246   #
1247   # To properly translate all NLS languages strings, we must support the
1248   # *printf() %$ format, which allows *printf() arguments to be selected
1249   # by position in the translated string.
1250   #
1251   # libintl versions < 0.13 use the native *printf() functions, and Win32
1252   # *printf() doesn't understand %$, so we must use our /port versions,
1253   # which do understand %$. libintl versions >= 0.13 include their own
1254   # *printf versions on Win32.  The libintl 0.13 release note text is:
1255   #
1256   #   C format strings with positions, as they arise when a translator
1257   #   needs to reorder a sentence, are now supported on all platforms.
1258   #   On those few platforms (NetBSD and Woe32) for which the native
1259   #   printf()/fprintf()/... functions don't support such format
1260   #   strings, replacements are provided through <libintl.h>.
1261   #
1262   # We could use libintl >= 0.13's *printf() if we were sure that we had
1263   # a litint >= 0.13 at runtime, but seeing that there is no clean way
1264   # to guarantee that, it is best to just use our own, so we are sure to
1265   # get %$ support. In include/port.h we disable the *printf() macros
1266   # that might have been defined by libintl.
1267   #
1268   # We do this unconditionally whether NLS is used or not so we are sure
1269   # that all Win32 libraries and binaries behave the same.
1270   pgac_need_repl_snprintf=yes
1271 else
1272   pgac_need_repl_snprintf=no
1273   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
1274   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1275 fi
1276
1277
1278 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
1279 # include/c.h will provide declarations.  Note this is a separate test
1280 # from whether the functions exist in the C library --- there are
1281 # systems that have the functions but don't bother to declare them :-(
1282
1283 AC_CHECK_DECLS([snprintf, vsnprintf])
1284
1285
1286 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1287 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1288 [AC_TRY_LINK([
1289 #include <math.h>
1290 double glob_double;
1291 ],
1292 [return isinf(glob_double) ? 0 : 1;],
1293 [ac_cv_func_isinf=yes],
1294 [ac_cv_func_isinf=no])])
1295
1296 if test $ac_cv_func_isinf = yes ; then
1297   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1298 else
1299   AC_LIBOBJ(isinf)
1300   # Look for a way to implement a substitute for isinf()
1301   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1302 fi
1303
1304 # Some versions of libedit contain strlcpy(); so disregard that library while
1305 # checking for these standard libc functions.
1306 pgac_save_LIBS="$LIBS"
1307 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1308
1309 AC_REPLACE_FUNCS([crypt erand48 getopt getrusage inet_aton random rint srandom strdup strerror strlcat strlcpy strtol strtoul])
1310
1311 case $host_os in
1312
1313         # Windows uses a specialised env handler
1314         mingw*)
1315                 AC_DEFINE(HAVE_UNSETENV, 1, [Define to 1 because replacement version used.])
1316                 ac_cv_func_unsetenv=yes;;
1317         *)
1318                 AC_REPLACE_FUNCS([unsetenv])
1319                 ;;
1320 esac
1321
1322
1323 LIBS="$pgac_save_LIBS"
1324
1325 # System's version of getaddrinfo(), if any, may be used only if we found
1326 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1327 # (Note: the AC_REPLACE_FUNCS probe fails on Windows, where the available
1328 # versions of getaddrinfo don't follow normal C call protocol.  This is OK
1329 # because we want to use our own getaddrinfo.c on Windows anyway.)
1330 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
1331   AC_REPLACE_FUNCS([getaddrinfo])
1332 else
1333   AC_LIBOBJ(getaddrinfo)
1334 fi
1335
1336 # Similarly, use system's getopt_long() only if system provides struct option.
1337 if test x"$ac_cv_type_struct_option" = xyes ; then
1338   AC_REPLACE_FUNCS([getopt_long])
1339 else
1340   AC_LIBOBJ(getopt_long)
1341 fi
1342
1343 # Solaris' getopt() doesn't do what we want for long options, so always use
1344 # our version on that platform.
1345 if test "$PORTNAME" = "solaris"; then
1346   AC_LIBOBJ(getopt)
1347 fi
1348
1349 # mingw has adopted a GNU-centric interpretation of optind/optreset,
1350 # so always use our version on Windows.
1351 if test "$PORTNAME" = "win32"; then
1352   AC_LIBOBJ(getopt)
1353   AC_LIBOBJ(getopt_long)
1354 fi
1355
1356 # Cygwin's erand48() is broken (always returns zero) in some releases,
1357 # so force use of ours.
1358 if test "$PORTNAME" = "cygwin"; then
1359   AC_LIBOBJ(erand48)
1360 fi
1361
1362 # Win32 support
1363 if test "$PORTNAME" = "win32"; then
1364   AC_REPLACE_FUNCS(gettimeofday)
1365   AC_LIBOBJ(kill)
1366   AC_LIBOBJ(open)
1367   AC_LIBOBJ(win32env)
1368   AC_LIBOBJ(win32error)
1369   AC_DEFINE([HAVE_SYMLINK], 1,
1370             [Define to 1 if you have the `symlink' function.])
1371   AC_CHECK_TYPES(MINIDUMP_TYPE, [pgac_minidump_type=yes], [pgac_minidump_type=no], [
1372 #define WIN32_LEAN_AND_MEAN
1373 #include <windows.h>
1374 #include <string.h>
1375 #include <dbghelp.h>])
1376 fi
1377 if test x"$pgac_minidump_type" = x"yes" ; then
1378   AC_SUBST(have_win32_dbghelp,yes)
1379 else
1380   AC_SUBST(have_win32_dbghelp,no)
1381 fi
1382
1383 if test "$with_readline" = yes; then
1384   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1385   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
1386   AC_CHECK_FUNCS([append_history history_truncate_file])
1387 fi
1388
1389
1390 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
1391 dnl (especially on GNU libc)
1392 dnl See also comments in c.h.
1393 AC_CACHE_CHECK([for sigsetjmp], pgac_cv_func_sigsetjmp,
1394 [AC_TRY_LINK([#include <setjmp.h>],
1395             [sigjmp_buf x; sigsetjmp(x, 1);],
1396             [pgac_cv_func_sigsetjmp=yes],
1397             [pgac_cv_func_sigsetjmp=no])])
1398 if test x"$pgac_cv_func_sigsetjmp" = x"yes"; then
1399   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
1400 fi
1401
1402 AC_DECL_SYS_SIGLIST
1403
1404 AC_CHECK_FUNC(syslog,
1405               [AC_CHECK_HEADER(syslog.h,
1406                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1407
1408 AC_CACHE_CHECK([for opterr], pgac_cv_var_int_opterr,
1409 [AC_TRY_LINK([#include <unistd.h>],
1410   [extern int opterr; opterr = 1;],
1411   [pgac_cv_var_int_opterr=yes],
1412   [pgac_cv_var_int_opterr=no])])
1413 if test x"$pgac_cv_var_int_opterr" = x"yes"; then
1414   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
1415 fi
1416
1417 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1418 [AC_TRY_LINK([#include <unistd.h>],
1419   [extern int optreset; optreset = 1;],
1420   [pgac_cv_var_int_optreset=yes],
1421   [pgac_cv_var_int_optreset=no])])
1422 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1423   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1424 fi
1425
1426 AC_CHECK_FUNCS([strtoll strtoq], [break])
1427 AC_CHECK_FUNCS([strtoull strtouq], [break])
1428
1429 # Check for one of atexit() or on_exit()
1430 AC_CHECK_FUNCS(atexit, [],
1431                [AC_CHECK_FUNCS(on_exit, [],
1432                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
1433
1434
1435 #
1436 # Pthreads
1437 #
1438 # For each platform, we need to know about any special compile and link
1439 # libraries, and whether the normal C function names are thread-safe.
1440 # See the comment at the top of src/port/thread.c for more information.
1441 # WIN32 doesn't need the pthread tests;  it always uses threads
1442 if test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"; then
1443 ACX_PTHREAD     # set thread flags
1444
1445 # Some platforms use these, so just define them.  They can't hurt if they
1446 # are not supported.  For example, on Solaris -D_POSIX_PTHREAD_SEMANTICS
1447 # enables 5-arg getpwuid_r, among other things.
1448 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1449
1450
1451 # At this point, we don't want to muck with the compiler name for threading.
1452 # Let's see who fails, perhaps AIX.  2004-04-23
1453 if test "$PTHREAD_CC" != "$CC"; then
1454 AC_MSG_ERROR([
1455 PostgreSQL does not support platforms that require a special compiler
1456 for thread safety;  use --disable-thread-safety to disable thread safety.])
1457 fi
1458
1459 # Check for *_r functions
1460 _CFLAGS="$CFLAGS"
1461 _LIBS="$LIBS"
1462 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1463 LIBS="$LIBS $PTHREAD_LIBS"
1464
1465 if test "$PORTNAME" != "win32"; then
1466 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([
1467 pthread.h not found;  use --disable-thread-safety to disable thread safety])])
1468 fi
1469
1470 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1471
1472 # Do test here with the proper thread flags
1473 PGAC_FUNC_GETPWUID_R_5ARG
1474 PGAC_FUNC_STRERROR_R_INT
1475
1476 CFLAGS="$_CFLAGS"
1477 LIBS="$_LIBS"
1478
1479 else
1480 # do not use values from template file
1481 PTHREAD_CFLAGS=
1482 PTHREAD_LIBS=
1483 fi
1484
1485 AC_SUBST(PTHREAD_CFLAGS)
1486 AC_SUBST(PTHREAD_LIBS)
1487
1488
1489 # We can test for libldap_r only after we know PTHREAD_LIBS
1490 if test "$with_ldap" = yes ; then
1491   _LIBS="$LIBS"
1492   if test "$PORTNAME" != "win32"; then
1493     AC_CHECK_LIB(ldap, ldap_bind, [],
1494                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1495                  [$EXTRA_LDAP_LIBS])
1496     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1497     if test "$enable_thread_safety" = yes; then
1498       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1499       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1500                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1501                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1502       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1503     else
1504       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1505     fi
1506   else
1507     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1508     LDAP_LIBS_FE="-lwldap32"
1509     LDAP_LIBS_BE="-lwldap32"
1510   fi
1511   LIBS="$_LIBS"
1512 fi
1513 AC_SUBST(LDAP_LIBS_FE)
1514 AC_SUBST(LDAP_LIBS_BE)
1515
1516
1517 # This test makes sure that run tests work at all.  Sometimes a shared
1518 # library is found by the linker, but the runtime linker can't find it.
1519 # This check should come after all modifications of compiler or linker
1520 # variables, and before any other run tests.
1521 AC_MSG_CHECKING([test program])
1522 AC_TRY_RUN([int main() { return 0; }],
1523 [AC_MSG_RESULT(ok)],
1524 [AC_MSG_RESULT(failed)
1525 AC_MSG_ERROR([[
1526 Could not execute a simple test program.  This may be a problem
1527 related to locating shared libraries.  Check the file 'config.log'
1528 for the exact reason.]])],
1529 [AC_MSG_RESULT([cross-compiling])])
1530
1531 # --------------------
1532 # Run tests below here
1533 # --------------------
1534
1535 # Force use of our snprintf if system's doesn't do arg control
1536 # See comment above at snprintf test for details.
1537 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1538   PGAC_FUNC_PRINTF_ARG_CONTROL
1539   if test $pgac_cv_printf_arg_control != yes ; then
1540     pgac_need_repl_snprintf=yes
1541   fi
1542 fi
1543
1544
1545 dnl Check to see if we have a working 64-bit integer type.
1546 dnl This breaks down into two steps:
1547 dnl (1) figure out if the compiler has a 64-bit int type with working
1548 dnl arithmetic, and if so
1549 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1550 dnl snprintf is the only library routine we really need for int8 support.)
1551 dnl It's entirely possible to have a compiler that handles a 64-bit type
1552 dnl when the C library doesn't; this is fairly likely when using gcc on
1553 dnl an older platform, for example.
1554 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1555 dnl we force our own version of snprintf() to be used instead.
1556 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1557
1558 dnl As of Postgres 8.4, we no longer support compilers without a working
1559 dnl 64-bit type.  But we still handle the case of snprintf being broken.
1560
1561 PGAC_TYPE_64BIT_INT([long int])
1562
1563 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1564   PGAC_TYPE_64BIT_INT([long long int])
1565   if test x"$HAVE_LONG_LONG_INT_64" = x"no" ; then
1566     AC_MSG_ERROR([Cannot find a working 64-bit integer type.])
1567   fi
1568 fi
1569
1570
1571 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1572
1573 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1574   AC_TRY_COMPILE([
1575 #define INT64CONST(x)  x##LL
1576 long long int foo = INT64CONST(0x1234567890123456);
1577 ],
1578         [],
1579         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1580         [])
1581 fi
1582
1583
1584 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1585 # we found we need to use "long long int", better check.  We cope with
1586 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1587 # work, fall back to our own snprintf emulation (which we know uses %lld).
1588
1589 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1590   if test $pgac_need_repl_snprintf = no; then
1591     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1592     if test "$LONG_LONG_INT_FORMAT" = ""; then
1593       # Force usage of our own snprintf, since system snprintf is broken
1594       pgac_need_repl_snprintf=yes
1595       LONG_LONG_INT_FORMAT='%lld'
1596     fi
1597   else
1598     # Here if we previously decided we needed to use our own snprintf
1599     LONG_LONG_INT_FORMAT='%lld'
1600   fi
1601   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1602   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1603   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1604 else
1605   # Here if we are not using 'long long int' at all
1606   INT64_FORMAT='"%ld"'
1607   UINT64_FORMAT='"%lu"'
1608 fi
1609
1610 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1611                    [Define to the appropriate snprintf format for 64-bit ints.])
1612
1613 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1614                    [Define to the appropriate snprintf format for unsigned 64-bit ints.])
1615
1616 # Now we have checked all the reasons to replace snprintf
1617 if test $pgac_need_repl_snprintf = yes; then
1618   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1619   AC_LIBOBJ(snprintf)
1620 fi
1621
1622 # Check size of void *, size_t (enables tweaks for > 32bit address space)
1623 AC_CHECK_SIZEOF([void *])
1624 AC_CHECK_SIZEOF([size_t])
1625 AC_CHECK_SIZEOF([long])
1626
1627 # Decide whether float4 is passed by value: user-selectable, enabled by default
1628 AC_MSG_CHECKING([whether to build with float4 passed by value])
1629 PGAC_ARG_BOOL(enable, float4-byval, yes, [disable float4 passed by value],
1630               [AC_DEFINE([USE_FLOAT4_BYVAL], 1,
1631                          [Define to 1 if you want float4 values to be passed by value. (--enable-float4-byval)])
1632                float4passbyval=true],
1633               [float4passbyval=false])
1634 AC_MSG_RESULT([$enable_float4_byval])
1635 AC_DEFINE_UNQUOTED([FLOAT4PASSBYVAL], [$float4passbyval], [float4 values are passed by value if 'true', by reference if 'false'])
1636
1637 # Decide whether float8 is passed by value.
1638 # Note: this setting also controls int8 and related types such as timestamp.
1639 # If sizeof(Datum) >= 8, this is user-selectable, enabled by default.
1640 # If not, trying to select it is an error.
1641 AC_MSG_CHECKING([whether to build with float8 passed by value])
1642 if test $ac_cv_sizeof_void_p -ge 8 ; then
1643   PGAC_ARG_BOOL(enable, float8-byval, yes, [disable float8 passed by value])
1644 else
1645   PGAC_ARG_BOOL(enable, float8-byval, no, [disable float8 passed by value])
1646   if test "$enable_float8_byval" = yes ; then
1647     AC_MSG_ERROR([--enable-float8-byval is not supported on 32-bit platforms.])
1648   fi
1649 fi
1650 if test "$enable_float8_byval" = yes ; then
1651   AC_DEFINE([USE_FLOAT8_BYVAL], 1,
1652             [Define to 1 if you want float8, int8, etc values to be passed by value. (--enable-float8-byval)])
1653   float8passbyval=true
1654 else
1655   float8passbyval=false
1656 fi
1657 AC_MSG_RESULT([$enable_float8_byval])
1658 AC_DEFINE_UNQUOTED([FLOAT8PASSBYVAL], [$float8passbyval], [float8, int8, and related values are passed by value if 'true', by reference if 'false'])
1659
1660 # Determine memory alignment requirements for the basic C data types.
1661
1662 AC_CHECK_ALIGNOF(short)
1663 AC_CHECK_ALIGNOF(int)
1664 AC_CHECK_ALIGNOF(long)
1665 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1666   AC_CHECK_ALIGNOF(long long int)
1667 fi
1668 AC_CHECK_ALIGNOF(double)
1669
1670 # Compute maximum alignment of any basic type.
1671 # We assume long's alignment is at least as strong as char, short, or int;
1672 # but we must check long long (if it exists) and double.
1673
1674 MAX_ALIGNOF=$ac_cv_alignof_long
1675 if test $MAX_ALIGNOF -lt $ac_cv_alignof_double ; then
1676   MAX_ALIGNOF=$ac_cv_alignof_double
1677 fi
1678 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $ac_cv_alignof_long_long_int ; then
1679   MAX_ALIGNOF="$ac_cv_alignof_long_long_int"
1680 fi
1681 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1682
1683
1684 # Some platforms predefine the types int8, int16, etc.  Only check
1685 # a (hopefully) representative subset.
1686 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1687 [#include <stdio.h>
1688 #ifdef HAVE_SUPPORTDEFS_H
1689 #include <SupportDefs.h>
1690 #endif])
1691
1692 # We also check for sig_atomic_t, which *should* be defined per ANSI
1693 # C, but is missing on some old platforms.
1694 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1695
1696
1697 if test "$PORTNAME" != "win32"
1698 then
1699 PGAC_FUNC_POSIX_SIGNALS
1700 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1701   AC_MSG_ERROR([
1702 Thread-safety requires POSIX signals, which are not supported by this
1703 operating system;  use --disable-thread-safety to disable thread safety.])
1704 fi
1705 fi
1706
1707 # SunOS doesn't handle negative byte comparisons properly with +/- return
1708 AC_FUNC_MEMCMP
1709
1710
1711 # Select semaphore implementation type.
1712 if test "$PORTNAME" != "win32"; then
1713   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1714     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1715     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1716   else
1717     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1718       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1719       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1720     else
1721       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1722       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1723     fi
1724   fi
1725 else
1726   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1727   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1728 fi
1729
1730
1731 # Select shared-memory implementation type.
1732 if test "$PORTNAME" != "win32"; then
1733   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1734   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1735 else
1736   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
1737   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
1738 fi
1739
1740 # Select latch implementation type.
1741 if test "$PORTNAME" != "win32"; then
1742   LATCH_IMPLEMENTATION="src/backend/port/unix_latch.c"
1743 else
1744   LATCH_IMPLEMENTATION="src/backend/port/win32_latch.c"
1745 fi
1746
1747 # If not set in template file, set bytes to use libc memset()
1748 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
1749   MEMSET_LOOP_LIMIT=1024
1750 fi
1751 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
1752
1753
1754 if test "$enable_nls" = yes ; then
1755   PGAC_CHECK_GETTEXT
1756 fi
1757
1758 # Check for Tcl configuration script tclConfig.sh
1759 if test "$with_tcl" = yes; then
1760     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1761     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1762                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1763     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1764     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1765     ac_save_CPPFLAGS=$CPPFLAGS
1766     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1767     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1768     CPPFLAGS=$ac_save_CPPFLAGS
1769 fi
1770
1771 # check for <Python.h>
1772 if test "$with_python" = yes; then
1773   ac_save_CPPFLAGS=$CPPFLAGS
1774   CPPFLAGS="$python_includespec $CPPFLAGS"
1775   AC_CHECK_HEADER(Python.h, [], [AC_MSG_ERROR([header file <Python.h> is required for Python])])
1776   CPPFLAGS=$ac_save_CPPFLAGS
1777 fi
1778
1779 #
1780 # Check for DocBook and tools
1781 #
1782 PGAC_PROG_NSGMLS
1783 PGAC_PROG_JADE
1784 PGAC_CHECK_DOCBOOK(4.2)
1785 PGAC_PATH_DOCBOOK_STYLESHEETS
1786 PGAC_PATH_COLLATEINDEX
1787 AC_CHECK_PROGS(XSLTPROC, xsltproc)
1788 AC_CHECK_PROGS(OSX, [osx sgml2xml sx])
1789
1790 # Thread testing
1791
1792 # We have to run the thread test near the end so we have all our symbols
1793 # defined.  Cross compiling throws a warning.
1794 #
1795 if test "$enable_thread_safety" = yes; then
1796 if test "$PORTNAME" != "win32"
1797 then
1798 AC_MSG_CHECKING([thread safety of required library functions])
1799
1800 _CFLAGS="$CFLAGS"
1801 _LIBS="$LIBS"
1802 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1803 LIBS="$LIBS $PTHREAD_LIBS"
1804 AC_TRY_RUN([#include "$srcdir/src/test/thread/thread_test.c"],
1805   [AC_MSG_RESULT(yes)],
1806   [AC_MSG_RESULT(no)
1807   AC_MSG_ERROR([thread test program failed
1808 This platform is not thread-safe.  Check the file 'config.log' or compile
1809 and run src/test/thread/thread_test for the exact reason.
1810 Use --disable-thread-safety to disable thread safety.])],
1811   [AC_MSG_RESULT(maybe)
1812   AC_MSG_WARN([
1813 *** Skipping thread test program because of cross-compile build.
1814 *** Run the program in src/test/thread on the target machine.
1815 ])])
1816 CFLAGS="$_CFLAGS"
1817 LIBS="$_LIBS"
1818 else
1819 AC_MSG_WARN([*** skipping thread test on Win32])
1820 fi
1821 fi
1822
1823 # If compiler will take -Wl,--as-needed (or various platform-specific
1824 # spellings thereof) then add that to LDFLAGS.  This is much easier than
1825 # trying to filter LIBS to the minimum for each executable.
1826 # On (at least) some Red-Hat-derived systems, this switch breaks linking to
1827 # libreadline; therefore we postpone testing it until we know what library
1828 # dependencies readline has.  The test code will try to link with $LIBS.
1829 if test "$with_readline" = yes; then
1830   link_test_func=readline
1831 else
1832   link_test_func=exit
1833 fi
1834
1835 if test "$PORTNAME" = "darwin"; then
1836   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-dead_strip_dylibs], $link_test_func)
1837 elif test "$PORTNAME" = "openbsd"; then
1838   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-Bdynamic], $link_test_func)
1839 else
1840   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,--as-needed], $link_test_func)
1841 fi
1842
1843
1844 # Begin output steps
1845
1846 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
1847 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
1848 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
1849
1850 # Create compiler version string
1851 if test x"$GCC" = x"yes" ; then
1852   cc_string="GCC `${CC} --version | sed q`"
1853 elif test x"$SUN_STUDIO_CC" = x"yes" ; then
1854   cc_string=`${CC} -V 2>&1 | sed q`
1855 else
1856   cc_string=$CC
1857 fi
1858
1859 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
1860                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string, `expr $ac_cv_sizeof_void_p \* 8`-bit"],
1861                    [A string containing the version number, platform, and C compiler])
1862
1863 # Supply a numeric version string for use by 3rd party add-ons
1864 # awk -F is a regex on some platforms, and not on others, so make "." a tab
1865 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
1866 tr '.' '        ' |
1867 $AWK '{printf "%d%02d%02d", $1, $2, (NF >= 3) ? $3 : 0}'`"]
1868 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
1869
1870
1871 # prepare build tree if outside source tree
1872 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1873 # Note 2: /bin/pwd might be better than shell's built-in at getting
1874 #         a symlink-free name.
1875 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1876   vpath_build=no
1877 else
1878   vpath_build=yes
1879   if test "$no_create" != yes; then
1880     _AS_ECHO_N([preparing build tree... ])
1881     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1882     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1883       || AC_MSG_ERROR(failed)
1884     AC_MSG_RESULT(done)
1885   fi
1886 fi
1887 AC_SUBST(vpath_build)
1888
1889
1890 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1891
1892 AC_CONFIG_LINKS([
1893   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1894   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1895   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1896   src/backend/port/pg_latch.c:${LATCH_IMPLEMENTATION}
1897   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1898   src/include/pg_config_os.h:src/include/port/${template}.h
1899   src/Makefile.port:src/makefiles/Makefile.${template}
1900 ])
1901
1902 if test "$PORTNAME" = "win32"; then
1903 AC_CONFIG_COMMANDS([check_win32_symlinks],[
1904 # Links sometimes fail undetected on Mingw -
1905 # so here we detect it and warn the user
1906 for FILE in $CONFIG_LINKS
1907  do
1908         # test -e works for symlinks in the MinGW console
1909         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
1910  done
1911 ])
1912 fi
1913
1914 AC_CONFIG_HEADERS([src/include/pg_config.h],
1915 [
1916 # Update timestamp for pg_config.h (see Makefile.global)
1917 echo >src/include/stamp-h
1918 ])
1919
1920 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h],
1921                   [echo >src/interfaces/ecpg/include/stamp-h])
1922
1923 AC_OUTPUT