configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $PostgreSQL: pgsql/configure.in,v 1.576 2008/12/07 08:36:21 petere Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [8.4devel], [pgsql-bugs@postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.61], [], [m4_fatal([Autoconf version 2.61 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2008, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version as a string])
  33
  34 AC_CANONICAL_HOST
  35
  36 template=
  37 AC_MSG_CHECKING([which template to use])
  38
  39 PGAC_ARG_REQ(with, template, [NAME], [override operating system template],
  40 [
  41   case $withval in
  42     list)   echo; ls "$srcdir/src/template"; exit;;
  43     *)      if test -f "$srcdir/src/template/$with_template" ; then
  44               template=$withval
  45             else
  46               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  47             fi;;
  48   esac
  49 ],
  50 [
  51 # --with-template not given
  52
  53 case $host_os in
  54      aix*) template=aix ;;
  55     bsdi*) template=bsdi ;;
  56   cygwin*) template=cygwin ;;
  57   darwin*) template=darwin ;;
  58     dgux*) template=dgux ;;
  59  freebsd*) template=freebsd ;;
  60     hpux*) template=hpux ;;
  61     irix*) template=irix ;;
  62  linux*|gnu*|k*bsd*-gnu)
  63            template=linux ;;
  64    mingw*) template=win32 ;;
  65   netbsd*) template=netbsd ;;
  66 nextstep*) template=nextstep ;;
  67  openbsd*) template=openbsd ;;
  68      osf*) template=osf ;;
  69      sco*) template=sco ;;
  70  solaris*) template=solaris ;;
  71    sunos*) template=sunos4 ;;
  72  sysv4.2*)
  73         case $host_vendor in
  74           univel) template=univel ;;
  75         esac ;;
  76    sysv4*) template=svr4 ;;
  77    sysv5*) template=unixware ;;
  78   ultrix*) template=ultrix4 ;;
  79 esac
  80
  81   if test x"$template" = x"" ; then
  82     AC_MSG_ERROR([[
  83 *******************************************************************
  84 PostgreSQL has apparently not been ported to your platform yet.
  85 To try a manual configuration, look into the src/template directory
  86 for a similar platform and use the '--with-template=' option.
  87
  88 Please also contact <pgsql-ports@postgresql.org> to see about
  89 rectifying this.  Include the above 'checking host system type...'
  90 line.
  91 *******************************************************************
  92 ]])
  93   fi
  94
  95 ])
  96
  97 AC_MSG_RESULT([$template])
  98
  99 PORTNAME=$template
 100 AC_SUBST(PORTNAME)
 101
 102 # Initialize default assumption that we do not need separate assembly code
 103 # for TAS (test-and-set).  This can be overridden by the template file
 104 # when it's executed.
 105 need_tas=no
 106 tas_file=dummy.s
 107
 108
 109
 110 ##
 111 ## Command line options
 112 ##
 113
 114 #
 115 # Add non-standard directories to the include path
 116 #
 117 PGAC_ARG_REQ(with, includes, [DIRS], [look for additional header files in DIRS])
 118
 119
 120 #
 121 # Add non-standard directories to the library search path
 122 #
 123 PGAC_ARG_REQ(with, libraries, [DIRS], [look for additional libraries in DIRS],
 124              [LIBRARY_DIRS=$withval])
 125
 126 PGAC_ARG_REQ(with, libs,      [DIRS], [alternative spelling of --with-libraries],
 127              [LIBRARY_DIRS=$withval])
 128
 129
 130 #
 131 # 64-bit integer date/time storage: enabled by default.
 132 #
 133 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 134 PGAC_ARG_BOOL(enable, integer-datetimes, yes, [disable 64-bit integer date/time support],
 135               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 136                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 137 AC_MSG_RESULT([$enable_integer_datetimes])
 138
 139
 140 #
 141 # NLS
 142 #
 143 AC_MSG_CHECKING([whether NLS is wanted])
 144 PGAC_ARG_OPTARG(enable, nls,
 145                 [LANGUAGES], [enable Native Language Support],
 146                 [],
 147                 [WANTED_LANGUAGES=$enableval],
 148                 [AC_DEFINE(ENABLE_NLS, 1,
 149                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 150 AC_MSG_RESULT([$enable_nls])
 151 AC_SUBST(enable_nls)
 152 AC_SUBST(WANTED_LANGUAGES)
 153
 154 #
 155 # Default port number (--with-pgport), default 5432
 156 #
 157 AC_MSG_CHECKING([for default port number])
 158 PGAC_ARG_REQ(with, pgport, [PORTNUM], [set default port number [5432]],
 159              [default_port=$withval],
 160              [default_port=5432])
 161 AC_MSG_RESULT([$default_port])
 162 # Need both of these because some places want an integer and some a string
 163 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 164 [Define to the default TCP port number on which the server listens and
 165 to which clients will try to connect.  This can be overridden at run-time,
 166 but it's convenient if your clients have the right default compiled in.
 167 (--with-pgport=PORTNUM)])
 168 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 169                    [Define to the default TCP port number as a string constant.])
 170 AC_SUBST(default_port)
 171
 172 #
 173 # Option to disable shared libraries
 174 #
 175 PGAC_ARG_BOOL(enable, shared, yes,
 176               [do not build shared libraries])
 177 AC_SUBST(enable_shared)
 178
 179 #
 180 # '-rpath'-like feature can be disabled
 181 #
 182 PGAC_ARG_BOOL(enable, rpath, yes,
 183               [do not embed shared library search path in executables])
 184 AC_SUBST(enable_rpath)
 185
 186 #
 187 # Spinlocks
 188 #
 189 PGAC_ARG_BOOL(enable, spinlocks, yes,
 190               [do not use spinlocks])
 191
 192 #
 193 # --enable-debug adds -g to compiler flags
 194 #
 195 PGAC_ARG_BOOL(enable, debug, no,
 196               [build with debugging symbols (-g)])
 197 AC_SUBST(enable_debug)
 198
 199 #
 200 # --enable-profiling enables gcc profiling
 201 #
 202 PGAC_ARG_BOOL(enable, profiling, no,
 203               [build with profiling enabled ])
 204 AC_SUBST(enable_profiling)
 205
 206 #
 207 # --enable-coverage enables generation of code coverage metrics with gcov
 208 #
 209 PGAC_ARG_BOOL(enable, coverage, no,
 210               [build with coverage testing instrumentation],
 211 [AC_CHECK_PROGS(GCOV, gcov)
 212 if test -z "$GCOV"; then
 213   AC_MSG_ERROR([gcov not found])
 214 fi
 215 AC_CHECK_PROGS(LCOV, lcov)
 216 if test -z "$LCOV"; then
 217   AC_MSG_ERROR([lcov not found])
 218 fi
 219 AC_CHECK_PROGS(GENHTML, genhtml)
 220 if test -z "$GENHTML"; then
 221   AC_MSG_ERROR([genhtml not found])
 222 fi])
 223 AC_SUBST(enable_coverage)
 224
 225 #
 226 # DTrace
 227 #
 228 PGAC_ARG_BOOL(enable, dtrace, no,
 229               [build with DTrace support],
 230 [AC_DEFINE([ENABLE_DTRACE], 1,
 231            [Define to 1 to enable DTrace support. (--enable-dtrace)])
 232 AC_CHECK_PROGS(DTRACE, dtrace)
 233 if test -z "$DTRACE"; then
 234   AC_MSG_ERROR([dtrace not found])
 235 fi
 236 AC_SUBST(DTRACEFLAGS)])
 237 AC_SUBST(enable_dtrace)
 238
 239 #
 240 # Block size
 241 #
 242 AC_MSG_CHECKING([for block size])
 243 PGAC_ARG_REQ(with, blocksize, [BLOCKSIZE], [set table block size in kB [8]],
 244              [blocksize=$withval],
 245              [blocksize=8])
 246 case ${blocksize} in
 247   1) BLCKSZ=1024;;
 248   2) BLCKSZ=2048;;
 249   4) BLCKSZ=4096;;
 250   8) BLCKSZ=8192;;
 251  16) BLCKSZ=16384;;
 252  32) BLCKSZ=32768;;
 253   *) AC_MSG_ERROR([Invalid block size. Allowed values are 1,2,4,8,16,32.])
 254 esac
 255 AC_MSG_RESULT([${blocksize}kB])
 256
 257 AC_DEFINE_UNQUOTED([BLCKSZ], ${BLCKSZ}, [
 258  Size of a disk block --- this also limits the size of a tuple.  You
 259  can set it bigger if you need bigger tuples (although TOAST should
 260  reduce the need to have large tuples, since fields can be spread
 261  across multiple tuples).
 262
 263  BLCKSZ must be a power of 2.  The maximum possible value of BLCKSZ
 264  is currently 2^15 (32768).  This is determined by the 15-bit widths
 265  of the lp_off and lp_len fields in ItemIdData (see
 266  include/storage/itemid.h).
 267
 268  Changing BLCKSZ requires an initdb.
 269 ])
 270
 271 #
 272 # Relation segment size
 273 #
 274 AC_MSG_CHECKING([for segment size])
 275 PGAC_ARG_REQ(with, segsize, [SEGSIZE], [set table segment size in GB [1]],
 276              [segsize=$withval],
 277              [segsize=1])
 278 # this expression is set up to avoid unnecessary integer overflow
 279 # blocksize is already guaranteed to be a factor of 1024
 280 RELSEG_SIZE=`expr '(' 1024 / ${blocksize} ')' '*' ${segsize} '*' 1024`
 281 test $? -eq 0 || exit 1
 282 AC_MSG_RESULT([${segsize}GB])
 283
 284 AC_DEFINE_UNQUOTED([RELSEG_SIZE], ${RELSEG_SIZE}, [
 285  RELSEG_SIZE is the maximum number of blocks allowed in one disk file.
 286  Thus, the maximum size of a single file is RELSEG_SIZE * BLCKSZ;
 287  relations bigger than that are divided into multiple files.
 288
 289  RELSEG_SIZE * BLCKSZ must be less than your OS' limit on file size.
 290  This is often 2 GB or 4GB in a 32-bit operating system, unless you
 291  have large file support enabled.  By default, we make the limit 1 GB
 292  to avoid any possible integer-overflow problems within the OS.
 293  A limit smaller than necessary only means we divide a large
 294  relation into more chunks than necessary, so it seems best to err
 295  in the direction of a small limit.
 296
 297  A power-of-2 value is recommended to save a few cycles in md.c,
 298  but is not absolutely required.
 299
 300  Changing RELSEG_SIZE requires an initdb.
 301 ])
 302
 303 #
 304 # WAL block size
 305 #
 306 AC_MSG_CHECKING([for WAL block size])
 307 PGAC_ARG_REQ(with, wal-blocksize, [BLOCKSIZE], [set WAL block size in kB [8]],
 308              [wal_blocksize=$withval],
 309              [wal_blocksize=8])
 310 case ${wal_blocksize} in
 311   1) XLOG_BLCKSZ=1024;;
 312   2) XLOG_BLCKSZ=2048;;
 313   4) XLOG_BLCKSZ=4096;;
 314   8) XLOG_BLCKSZ=8192;;
 315  16) XLOG_BLCKSZ=16384;;
 316  32) XLOG_BLCKSZ=32768;;
 317  64) XLOG_BLCKSZ=65536;;
 318   *) AC_MSG_ERROR([Invalid WAL block size. Allowed values are 1,2,4,8,16,32,64.])
 319 esac
 320 AC_MSG_RESULT([${wal_blocksize}kB])
 321
 322 AC_DEFINE_UNQUOTED([XLOG_BLCKSZ], ${XLOG_BLCKSZ}, [
 323  Size of a WAL file block.  This need have no particular relation to BLCKSZ.
 324  XLOG_BLCKSZ must be a power of 2, and if your system supports O_DIRECT I/O,
 325  XLOG_BLCKSZ must be a multiple of the alignment requirement for direct-I/O
 326  buffers, else direct I/O may fail.
 327
 328  Changing XLOG_BLCKSZ requires an initdb.
 329 ])
 330
 331 #
 332 # WAL segment size
 333 #
 334 AC_MSG_CHECKING([for WAL segment size])
 335 PGAC_ARG_REQ(with, wal-segsize, [SEGSIZE], [set WAL segment size in MB [16]],
 336              [wal_segsize=$withval],
 337              [wal_segsize=16])
 338 case ${wal_segsize} in
 339   1) ;;
 340   2) ;;
 341   4) ;;
 342   8) ;;
 343  16) ;;
 344  32) ;;
 345  64) ;;
 346   *) AC_MSG_ERROR([Invalid WAL segment size. Allowed values are 1,2,4,8,16,32,64.])
 347 esac
 348 AC_MSG_RESULT([${wal_segsize}MB])
 349
 350 AC_DEFINE_UNQUOTED([XLOG_SEG_SIZE], [(${wal_segsize} * 1024 * 1024)], [
 351  XLOG_SEG_SIZE is the size of a single WAL file.  This must be a power of 2
 352  and larger than XLOG_BLCKSZ (preferably, a great deal larger than
 353  XLOG_BLCKSZ).
 354
 355  Changing XLOG_SEG_SIZE requires an initdb.
 356 ])
 357
 358 #
 359 # C compiler
 360 #
 361
 362 # For historical reasons you can also use --with-CC to specify the C compiler
 363 # to use, although the standard way to do this is to set the CC environment
 364 # variable.
 365 PGAC_ARG_REQ(with, CC, [CMD], [set compiler (deprecated)], [CC=$with_CC])
 366
 367 case $template in
 368   aix) pgac_cc_list="gcc xlc";;
 369  irix) pgac_cc_list="cc";; # no gcc
 370     *) pgac_cc_list="gcc cc";;
 371 esac
 372
 373 AC_PROG_CC([$pgac_cc_list])
 374
 375 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 376 # but has idiosyncrasies of its own.  We assume icc will define
 377 # __INTEL_COMPILER regardless of CFLAGS.
 378 AC_TRY_COMPILE([], [@%:@ifndef __INTEL_COMPILER
 379 choke me
 380 @%:@endif], [ICC=[yes]], [ICC=[no]])
 381
 382 # Check if it's Sun Studio compiler. We assume that
 383 # __SUNPRO_C will be defined for Sun Studio compilers
 384 AC_TRY_COMPILE([], [@%:@ifndef __SUNPRO_C
 385 choke me
 386 @%:@endif], [SUN_STUDIO_CC=yes], [SUN_STUDIO_CC=no])
 387
 388 AC_SUBST(SUN_STUDIO_CC)
 389
 390 unset CFLAGS
 391
 392 #
 393 # Read the template
 394 #
 395 . "$srcdir/src/template/$template" || exit
 396
 397 # CFLAGS are selected so:
 398 # If the user specifies something in the environment, that is used.
 399 # else:  If the template file set something, that is used.
 400 # else:  If coverage was enabled, don't set anything.
 401 # else:  If the compiler is GCC, then we use -O2.
 402 # else:  If the compiler is something else, then we use -O.
 403
 404 if test "$ac_env_CFLAGS_set" = set; then
 405   CFLAGS=$ac_env_CFLAGS_value
 406 elif test "${CFLAGS+set}" = set; then
 407   : # (keep what template set)
 408 elif test "$enable_coverage" = yes; then
 409   : # no optimization by default
 410 elif test "$GCC" = yes; then
 411   CFLAGS="-O2"
 412 else
 413   # if the user selected debug mode, don't use -O
 414   if test "$enable_debug" != yes; then
 415     CFLAGS="-O"
 416   fi
 417 fi
 418
 419 # Some versions of GCC support some additional useful warning flags.
 420 # Check whether they are supported, and add them to CFLAGS if so.
 421 # ICC pretends to be GCC but it's lying; it doesn't support these options.
 422
 423 if test "$GCC" = yes -a "$ICC" = no; then
 424   CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wpointer-arith"
 425   # These work in some but not all gcc versions
 426   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 427   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 428   # Disable strict-aliasing rules; needed for gcc 3.3+
 429   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 430   # Disable optimizations that assume no overflow; needed for gcc 4.3+
 431   PGAC_PROG_CC_CFLAGS_OPT([-fwrapv])
 432 elif test "$ICC" = yes; then
 433   # Intel's compiler has a bug/misoptimization in checking for
 434   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 435   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 436   # Make sure strict aliasing is off (though this is said to be the default)
 437   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 438 elif test x"${CC}" = x"xlc"; then
 439   # AIX xlc has to have strict aliasing turned off too
 440   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 441 fi
 442
 443 # supply -g if --enable-debug
 444 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 445   CFLAGS="$CFLAGS -g"
 446 fi
 447
 448 # enable code coverage if --enable-coverage
 449 if test "$enable_coverage" = yes; then
 450   if test "$GCC" = yes; then
 451     CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 452   else
 453     AC_MSG_ERROR([--enable-coverage is supported only when using GCC])
 454   fi
 455 fi
 456
 457 # enable profiling if --enable-profiling
 458 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 459   if test "$GCC" = yes; then
 460     AC_DEFINE([PROFILE_PID_DIR], 1,
 461            [Define to 1 to allow profiling output to be saved separately for each process.])
 462     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 463   else
 464     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 465   fi
 466 fi
 467
 468 # We already have this in Makefile.win32, but configure needs it too
 469 if test "$PORTNAME" = "win32"; then
 470   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 471 fi
 472
 473 # Check if the compiler still works with the template settings
 474 AC_MSG_CHECKING([whether the C compiler still works])
 475 AC_TRY_LINK([], [return 0;],
 476   [AC_MSG_RESULT(yes)],
 477   [AC_MSG_RESULT(no)
 478    AC_MSG_ERROR([cannot proceed])])
 479
 480 # Defend against gcc -ffast-math
 481 if test "$GCC" = yes; then
 482 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 483 choke me
 484 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 485 fi
 486
 487 AC_PROG_CPP
 488 AC_SUBST(GCC)
 489
 490 # Create compiler version string
 491 if test x"$GCC" = x"yes" ; then
 492   cc_string="GCC `${CC} --version | sed q`"
 493 else
 494   cc_string=$CC
 495 fi
 496 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
 497                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"],
 498                    [A string containing the version number, platform, and C compiler])
 499
 500
 501 #
 502 # Set up TAS assembly code if needed; the template file has now had its
 503 # chance to request this.
 504 #
 505 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 506
 507 if test "$need_tas" = yes ; then
 508   TAS=tas.o
 509 else
 510   TAS=""
 511 fi
 512 AC_SUBST(TAS)
 513
 514
 515 #
 516 # Automatic dependency tracking
 517 #
 518 PGAC_ARG_BOOL(enable, depend, no, [turn on automatic dependency tracking],
 519               [autodepend=yes])
 520 AC_SUBST(autodepend)
 521
 522
 523 #
 524 # Enable assert checks
 525 #
 526 PGAC_ARG_BOOL(enable, cassert, no, [enable assertion checks (for debugging)],
 527               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 528                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 529
 530
 531 #
 532 # Include directories
 533 #
 534 ac_save_IFS=$IFS
 535 IFS="${IFS}${PATH_SEPARATOR}"
 536 # SRCH_INC comes from the template file
 537 for dir in $with_includes $SRCH_INC; do
 538   if test -d "$dir"; then
 539     INCLUDES="$INCLUDES -I$dir"
 540   else
 541     AC_MSG_WARN([*** Include directory $dir does not exist.])
 542   fi
 543 done
 544 IFS=$ac_save_IFS
 545 AC_SUBST(INCLUDES)
 546
 547
 548 #
 549 # Library directories
 550 #
 551 ac_save_IFS=$IFS
 552 IFS="${IFS}${PATH_SEPARATOR}"
 553 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 554 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 555   if test -d "$dir"; then
 556     LIBDIRS="$LIBDIRS -L$dir"
 557   else
 558     AC_MSG_WARN([*** Library directory $dir does not exist.])
 559   fi
 560 done
 561 IFS=$ac_save_IFS
 562
 563 #
 564 # Enable thread-safe client libraries
 565 #
 566 AC_MSG_CHECKING([allow thread-safe client libraries])
 567 if test "$PORTNAME" != "win32"; then
 568 PGAC_ARG_BOOL(enable, thread-safety, no, [make client libraries thread-safe])
 569 else
 570 # Win32 should always use threads
 571 PGAC_ARG_BOOL(enable, thread-safety, yes, [make client libraries thread-safe])
 572 fi
 573
 574 PGAC_ARG_BOOL(enable, thread-safety-force, no, [force thread-safety despite thread test failure])
 575 if test "$enable_thread_safety" = yes -o \
 576         "$enable_thread_safety_force" = yes; then
 577   enable_thread_safety="yes"    # for 'force'
 578   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 579           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 580 fi
 581 AC_MSG_RESULT([$enable_thread_safety])
 582 AC_SUBST(enable_thread_safety)
 583
 584 #
 585 # Optionally build Tcl modules (PL/Tcl)
 586 #
 587 AC_MSG_CHECKING([whether to build with Tcl])
 588 PGAC_ARG_BOOL(with, tcl, no, [build Tcl modules (PL/Tcl)])
 589 AC_MSG_RESULT([$with_tcl])
 590 AC_SUBST([with_tcl])
 591
 592 # We see if the path to the Tcl/Tk configuration scripts is specified.
 593 # This will override the use of tclsh to find the paths to search.
 594
 595 PGAC_ARG_REQ(with, tclconfig, [DIR], [tclConfig.sh is in DIR])
 596
 597 #
 598 # Optionally build Perl modules (PL/Perl)
 599 #
 600 AC_MSG_CHECKING([whether to build Perl modules])
 601 PGAC_ARG_BOOL(with, perl, no, [build Perl modules (PL/Perl)])
 602 AC_MSG_RESULT([$with_perl])
 603 AC_SUBST(with_perl)
 604
 605 #
 606 # Optionally build Python modules (PL/Python)
 607 #
 608 AC_MSG_CHECKING([whether to build Python modules])
 609 PGAC_ARG_BOOL(with, python, no, [build Python modules (PL/Python)])
 610 AC_MSG_RESULT([$with_python])
 611 AC_SUBST(with_python)
 612
 613 #
 614 # GSSAPI
 615 #
 616 AC_MSG_CHECKING([whether to build with GSSAPI support])
 617 PGAC_ARG_BOOL(with, gssapi, no, [build with GSSAPI support],
 618 [
 619   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 620   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 621 ])
 622 AC_MSG_RESULT([$with_gssapi])
 623 AC_SUBST(with_gssapi)
 624
 625 #
 626 # Kerberos 5
 627 #
 628 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 629 PGAC_ARG_BOOL(with, krb5, no, [build with Kerberos 5 support],
 630 [
 631   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 632   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 633 ])
 634 AC_MSG_RESULT([$with_krb5])
 635 AC_SUBST(with_krb5)
 636
 637
 638 AC_SUBST(krb_srvtab)
 639
 640
 641 #
 642 # Kerberos configuration parameters
 643 #
 644 PGAC_ARG_REQ(with, krb-srvnam,
 645              [NAME], [default service principal name in Kerberos [postgres]],
 646              [],
 647              [with_krb_srvnam="postgres"])
 648 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 649                    [Define to the name of the default PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 650
 651
 652 #
 653 # PAM
 654 #
 655 AC_MSG_CHECKING([whether to build with PAM support])
 656 PGAC_ARG_BOOL(with, pam, no,
 657               [build with PAM support],
 658               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 659 AC_MSG_RESULT([$with_pam])
 660 AC_SUBST(with_pam)
 661
 662
 663 #
 664 # LDAP
 665 #
 666 AC_MSG_CHECKING([whether to build with LDAP support])
 667 PGAC_ARG_BOOL(with, ldap, no,
 668               [build with LDAP support],
 669               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 670 AC_MSG_RESULT([$with_ldap])
 671 AC_SUBST(with_ldap)
 672
 673
 674 #
 675 # Bonjour
 676 #
 677 AC_MSG_CHECKING([whether to build with Bonjour support])
 678 PGAC_ARG_BOOL(with, bonjour, no,
 679               [build with Bonjour support],
 680               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 681 AC_MSG_RESULT([$with_bonjour])
 682 AC_SUBST(with_bonjour)
 683
 684
 685 #
 686 # OpenSSL
 687 #
 688 AC_MSG_CHECKING([whether to build with OpenSSL support])
 689 PGAC_ARG_BOOL(with, openssl, no, [build with OpenSSL support],
 690               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 691 AC_MSG_RESULT([$with_openssl])
 692 AC_SUBST(with_openssl)
 693
 694
 695 #
 696 # Readline
 697 #
 698 PGAC_ARG_BOOL(with, readline, yes,
 699               [do not use GNU Readline nor BSD Libedit for editing])
 700 # readline on MinGW has problems with backslashes in psql and other bugs.
 701 # This is particularly a problem with non-US code pages.
 702 # Therefore disable its use until we understand the cause. 2004-07-20
 703 if test "$PORTNAME" = "win32"; then
 704   if test "$with_readline" = yes; then
 705     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 706     with_readline=no
 707   fi
 708 fi
 709
 710
 711 #
 712 # Prefer libedit
 713 #
 714 PGAC_ARG_BOOL(with, libedit-preferred, no,
 715               [prefer BSD Libedit over GNU Readline])
 716
 717
 718 #
 719 # OSSP UUID library
 720 #
 721 PGAC_ARG_BOOL(with, ossp-uuid, no, [use OSSP UUID library when building contrib/uuid-ossp])
 722 AC_SUBST(with_ossp_uuid)
 723
 724
 725 #
 726 # XML
 727 #
 728 PGAC_ARG_BOOL(with, libxml, no, [build with XML support],
 729               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 730
 731 if test "$with_libxml" = yes ; then
 732   AC_CHECK_PROGS(XML2_CONFIG, xml2-config)
 733   if test -n "$XML2_CONFIG"; then
 734     for pgac_option in `$XML2_CONFIG --cflags`; do
 735       case $pgac_option in
 736         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 737       esac
 738     done
 739     for pgac_option in `$XML2_CONFIG --libs`; do
 740       case $pgac_option in
 741         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 742       esac
 743     done
 744   fi
 745 fi
 746
 747 AC_SUBST(with_libxml)
 748
 749 #
 750 # XSLT
 751 #
 752 PGAC_ARG_BOOL(with, libxslt, no, [use XSLT support when building contrib/xml2],
 753               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 754
 755
 756 AC_SUBST(with_libxslt)
 757
 758 #
 759 # tzdata
 760 #
 761 PGAC_ARG_REQ(with, system-tzdata,
 762              [DIR], [use system time zone data in DIR])
 763 AC_SUBST(with_system_tzdata)
 764
 765 #
 766 # Zlib
 767 #
 768 PGAC_ARG_BOOL(with, zlib, yes,
 769               [do not use Zlib])
 770 AC_SUBST(with_zlib)
 771
 772 #
 773 # Elf
 774 #
 775
 776 # Assume system is ELF if it predefines __ELF__ as 1,
 777 # otherwise believe host_os based default.
 778 case $host_os in
 779     freebsd1*|freebsd2*) elf=no;;
 780     freebsd3*|freebsd4*) elf=yes;;
 781 esac
 782
 783 AC_EGREP_CPP(yes,
 784 [#if __ELF__
 785   yes
 786 #endif
 787 ],
 788 [ELF_SYS=true],
 789 [if test "X$elf" = "Xyes" ; then
 790   ELF_SYS=true
 791 else
 792   ELF_SYS=
 793 fi])
 794 AC_SUBST(ELF_SYS)
 795
 796 #
 797 # Assignments
 798 #
 799
 800 CPPFLAGS="$CPPFLAGS $INCLUDES"
 801 LDFLAGS="$LDFLAGS $LIBDIRS"
 802
 803 AC_ARG_VAR(LDFLAGS_SL)
 804
 805 PGAC_PROG_LD
 806 AC_SUBST(LD)
 807 AC_SUBST(with_gnu_ld)
 808 case $host_os in sysv5*)
 809   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 810   [
 811     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 812     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 813     LDFLAGS=$pgac_save_LDFLAGS
 814   ])
 815   ld_R_works=$pgac_cv_prog_ld_R
 816   AC_SUBST(ld_R_works)
 817 esac
 818 AC_PROG_RANLIB
 819 PGAC_CHECK_STRIP
 820 AC_CHECK_TOOL(AR, ar, ar)
 821 if test "$PORTNAME" = "win32"; then
 822   AC_CHECK_TOOL(DLLTOOL, dlltool, dlltool)
 823   AC_CHECK_TOOL(DLLWRAP, dllwrap, dllwrap)
 824   AC_CHECK_TOOL(WINDRES, windres, windres)
 825 fi
 826
 827 AC_PATH_PROG(TAR, tar)
 828 AC_PROG_LN_S
 829 AC_PROG_AWK
 830
 831 PGAC_PATH_BISON
 832 PGAC_PATH_FLEX
 833
 834 PGAC_PATH_PERL
 835 if test "$with_perl" = yes; then
 836   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 837   PGAC_CHECK_PERL_EMBED_LDFLAGS
 838 fi
 839
 840 if test "$with_python" = yes; then
 841   PGAC_PATH_PYTHON
 842   PGAC_CHECK_PYTHON_EMBED_SETUP
 843 fi
 844
 845 # Supply a numeric version string for use by 3rd party add-ons
 846 # awk -F is a regex on some platforms, and not on others, so make "." a tab
 847 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
 848 tr '.' '        ' |
 849 $AWK '{printf "%d%02d%02d", $1, $2, (NF >= 3) ? $3 : 0}'`"]
 850 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
 851
 852 ##
 853 ## Libraries
 854 ##
 855 ## Most libraries are included only if they demonstrably provide a function
 856 ## we need, but libm is an exception: always include it, because there are
 857 ## too many compilers that play cute optimization games that will break
 858 ## probes for standard functions such as pow().
 859 ##
 860
 861 AC_CHECK_LIB(m, main)
 862 AC_SEARCH_LIBS(setproctitle, util)
 863 AC_SEARCH_LIBS(dlopen, dl)
 864 AC_SEARCH_LIBS(socket, [socket wsock32])
 865 AC_SEARCH_LIBS(shl_load, dld)
 866 # We only use libld in port/dynloader/aix.c
 867 case $host_os in
 868      aix*)
 869         AC_SEARCH_LIBS(ldopen, ld)
 870         ;;
 871 esac
 872 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 873 AC_SEARCH_LIBS(crypt, crypt)
 874 # Solaris:
 875 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 876 # Cygwin:
 877 AC_SEARCH_LIBS(shmget, cygipc)
 878
 879 if test "$with_readline" = yes; then
 880   PGAC_CHECK_READLINE
 881   if test x"$pgac_cv_check_readline" = x"no"; then
 882     AC_MSG_ERROR([readline library not found
 883 If you have readline already installed, see config.log for details on the
 884 failure.  It is possible the compiler isn't looking in the proper directory.
 885 Use --without-readline to disable readline support.])
 886   fi
 887 fi
 888
 889 if test "$with_zlib" = yes; then
 890   AC_CHECK_LIB(z, inflate, [],
 891                [AC_MSG_ERROR([zlib library not found
 892 If you have zlib already installed, see config.log for details on the
 893 failure.  It is possible the compiler isn't looking in the proper directory.
 894 Use --without-zlib to disable zlib support.])])
 895 fi
 896
 897 if test "$enable_spinlocks" = yes; then
 898   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 899 else
 900   AC_MSG_WARN([
 901 *** Not using spinlocks will cause poor performance.])
 902 fi
 903
 904 if test "$with_gssapi" = yes ; then
 905   if test "$PORTNAME" != "win32"; then
 906     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
 907                                   [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
 908   else
 909     LIBS="$LIBS -lgssapi32"
 910   fi
 911 fi
 912
 913 if test "$with_krb5" = yes ; then
 914   if test "$PORTNAME" != "win32"; then
 915      AC_SEARCH_LIBS(com_err, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken' com_err], [],
 916                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 917      AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken'], [],
 918                     [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 919   else
 920      AC_SEARCH_LIBS(com_err, 'comerr32 -lkrb5_32', [],
 921                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 922   fi
 923 fi
 924
 925 if test "$with_openssl" = yes ; then
 926   dnl Order matters!
 927   if test "$PORTNAME" != "win32"; then
 928      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 929      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 930   else
 931      AC_CHECK_LIB(eay32, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'eay32' is required for OpenSSL])])
 932      AC_CHECK_LIB(ssleay32,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssleay32' is required for OpenSSL])])
 933   fi
 934 fi
 935
 936 if test "$with_pam" = yes ; then
 937   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 938 fi
 939
 940 if test "$with_libxml" = yes ; then
 941   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
 942 fi
 943
 944 if test "$with_libxslt" = yes ; then
 945   AC_CHECK_LIB(xslt, xsltCleanupGlobals, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
 946 fi
 947
 948 # for contrib/uuid-ossp
 949 if test "$with_ossp_uuid" = yes ; then
 950   AC_CHECK_LIB(ossp-uuid, uuid_export,
 951     [OSSP_UUID_LIBS="-lossp-uuid"],
 952     [AC_CHECK_LIB(uuid, uuid_export,
 953       [OSSP_UUID_LIBS="-luuid"],
 954       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP-UUID])])])
 955 fi
 956 AC_SUBST(OSSP_UUID_LIBS)
 957
 958
 959 ##
 960 ## Header files
 961 ##
 962
 963 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 964 AC_CHECK_HEADERS([crypt.h dld.h fp_class.h getopt.h ieeefp.h langinfo.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/tas.h sys/time.h sys/un.h termios.h ucred.h utime.h wchar.h wctype.h kernel/OS.h kernel/image.h SupportDefs.h])
 965
 966 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 967 # netinet/in.h is included first.
 968 AC_CHECK_HEADERS(netinet/in.h)
 969 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 970 [AC_INCLUDES_DEFAULT
 971 #ifdef HAVE_NETINET_IN_H
 972 #include <netinet/in.h>
 973 #endif
 974 ])
 975
 976 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
 977   AC_CHECK_HEADERS(readline/readline.h, [],
 978         [AC_CHECK_HEADERS(readline.h, [],
 979                 [AC_MSG_ERROR([readline header not found
 980 If you have readline already installed, see config.log for details on the
 981 failure.  It is possible the compiler isn't looking in the proper directory.
 982 Use --without-readline to disable readline support.])])])
 983   AC_CHECK_HEADERS(readline/history.h, [],
 984         [AC_CHECK_HEADERS(history.h, [],
 985                 [AC_MSG_ERROR([history header not found
 986 If you have readline already installed, see config.log for details on the
 987 failure.  It is possible the compiler isn't looking in the proper directory.
 988 Use --without-readline to disable readline support.])])])
 989 fi
 990
 991 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
 992 # Some installations of libedit usurp /usr/include/readline/, which seems
 993 # bad practice, since in combined installations readline will have its headers
 994 # there.  We might have to resort to AC_EGREP checks to make sure we found
 995 # the proper header...
 996   AC_CHECK_HEADERS(editline/readline.h, [],
 997         [AC_CHECK_HEADERS(readline.h, [],
 998                 [AC_CHECK_HEADERS(readline/readline.h, [],
 999                         [AC_MSG_ERROR([readline header not found
1000 If you have libedit already installed, see config.log for details on the
1001 failure.  It is possible the compiler isn't looking in the proper directory.
1002 Use --without-readline to disable libedit support.])])])])
1003 # Note: in a libedit installation, history.h is sometimes a dummy, and may
1004 # not be there at all.  Hence, don't complain if not found.  We must check
1005 # though, since in yet other versions it is an independent header.
1006   AC_CHECK_HEADERS(editline/history.h, [],
1007         [AC_CHECK_HEADERS(history.h, [],
1008                 [AC_CHECK_HEADERS(readline/history.h)])])
1009 fi
1010
1011 if test "$with_zlib" = yes; then
1012   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
1013 If you have zlib already installed, see config.log for details on the
1014 failure.  It is possible the compiler isn't looking in the proper directory.
1015 Use --without-zlib to disable zlib support.])])
1016 fi
1017
1018 if test "$with_gssapi" = yes ; then
1019   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
1020         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
1021 fi
1022
1023 if test "$with_krb5" = yes ; then
1024   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
1025 fi
1026
1027 if test "$with_openssl" = yes ; then
1028   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
1029   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
1030   AC_CHECK_FUNCS([ERR_set_mark])
1031 fi
1032
1033 if test "$with_pam" = yes ; then
1034   AC_CHECK_HEADERS(security/pam_appl.h, [],
1035                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
1036                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
1037 fi
1038
1039 if test "$with_libxml" = yes ; then
1040   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
1041 fi
1042
1043 if test "$with_libxslt" = yes ; then
1044   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
1045 fi
1046
1047 if test "$with_ldap" = yes ; then
1048   if test "$PORTNAME" != "win32"; then
1049      AC_CHECK_HEADERS(ldap.h, [],
1050                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
1051   else
1052      AC_CHECK_HEADERS(winldap.h, [],
1053                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
1054                       [AC_INCLUDES_DEFAULT
1055 #include <windows.h>
1056                       ])
1057   fi
1058 fi
1059
1060 if test "$with_bonjour" = yes ; then
1061   AC_CHECK_HEADER(DNSServiceDiscovery/DNSServiceDiscovery.h, [], [AC_MSG_ERROR([header file <DNSServiceDiscovery/DNSServiceDiscovery.h> is required for Bonjour])])
1062 fi
1063
1064 # for contrib/uuid-ossp
1065 if test "$with_ossp_uuid" = yes ; then
1066   AC_CHECK_HEADERS(ossp/uuid.h, [], [
1067     AC_CHECK_HEADERS(uuid.h, [],
1068       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP-UUID])])])
1069 fi
1070
1071
1072 ##
1073 ## Types, structures, compiler characteristics
1074 ##
1075
1076 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
1077 AC_C_BIGENDIAN
1078 AC_C_CONST
1079 AC_C_INLINE
1080 AC_C_STRINGIZE
1081 PGAC_C_SIGNED
1082 AC_C_VOLATILE
1083 PGAC_C_FUNCNAME_SUPPORT
1084 PGAC_STRUCT_TIMEZONE
1085 PGAC_UNION_SEMUN
1086 PGAC_STRUCT_SOCKADDR_UN
1087 PGAC_STRUCT_SOCKADDR_STORAGE
1088 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
1089 PGAC_STRUCT_ADDRINFO
1090
1091 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
1092 [#include <sys/param.h>
1093 #include <sys/types.h>
1094 #include <sys/socket.h>
1095 #include <sys/ucred.h>])
1096
1097 AC_CHECK_TYPES([struct option], [], [],
1098 [#ifdef HAVE_GETOPT_H
1099 #include <getopt.h>
1100 #endif])
1101
1102 if test "$with_zlib" = yes; then
1103   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
1104   # did not).  While we could work around the lack of z_streamp, it
1105   # seems unwise to encourage people to use such old zlib versions...
1106   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
1107 Use --without-zlib to disable zlib support.])],
1108                 [#include <zlib.h>])
1109 fi
1110
1111 if test "$with_krb5" = yes; then
1112 # Check for differences between MIT and Heimdal (KTH) releases
1113   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
1114                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
1115                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
1116                                      [#include <krb5.h>])],
1117                    [#include <krb5.h>])
1118   AC_CHECK_MEMBERS(krb5_error.text.data, [],
1119                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
1120                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
1121                                      [#include <krb5.h>])],
1122                    [#include <krb5.h>])
1123
1124 # Win32 requires headers to be loaded for __stdcall, so can't use
1125 # AC_CHECK_FUNCS here.
1126   AC_MSG_CHECKING(for krb5_free_unparsed_name)
1127   AC_TRY_LINK([#include <krb5.h>],
1128               [krb5_free_unparsed_name(NULL,NULL);],
1129               [AC_DEFINE(HAVE_KRB5_FREE_UNPARSED_NAME, 1, [Define to 1 if you have krb5_free_unparsed_name])
1130 AC_MSG_RESULT(yes)],
1131               [AC_MSG_RESULT(no)])
1132 fi
1133
1134
1135 ##
1136 ## Functions, global variables
1137 ##
1138
1139 PGAC_VAR_INT_TIMEZONE
1140 AC_FUNC_ACCEPT_ARGTYPES
1141 PGAC_FUNC_GETTIMEOFDAY_1ARG
1142
1143 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid getpeerucred getrlimit memmove poll pstat readlink setproctitle setsid sigprocmask symlink sysconf towlower utime utimes waitpid wcstombs])
1144
1145 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
1146 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
1147 AC_CHECK_DECLS([strlcat, strlcpy])
1148 # This is probably only present on Darwin, but may as well check always
1149 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
1150
1151 HAVE_IPV6=no
1152 AC_CHECK_TYPE([struct sockaddr_in6],
1153         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
1154          HAVE_IPV6=yes],
1155         [],
1156 [$ac_includes_default
1157 #include <netinet/in.h>])
1158 AC_SUBST(HAVE_IPV6)
1159
1160 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1161 [AC_TRY_LINK(
1162 [#include <machine/vmparam.h>
1163 #include <sys/exec.h>
1164 ],
1165 [PS_STRINGS->ps_nargvstr = 1;
1166 PS_STRINGS->ps_argvstr = "foo";],
1167 [pgac_cv_var_PS_STRINGS=yes],
1168 [pgac_cv_var_PS_STRINGS=no])])
1169 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1170   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
1171 fi
1172
1173
1174 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
1175 # is missing.  Yes, there are machines that have only one.  We may
1176 # also decide to use snprintf.c if snprintf() is present but does not
1177 # have all the features we need --- see below.
1178
1179 if test "$PORTNAME" = "win32"; then
1180   # Win32 gets snprintf.c built unconditionally.
1181   #
1182   # To properly translate all NLS languages strings, we must support the
1183   # *printf() %$ format, which allows *printf() arguments to be selected
1184   # by position in the translated string.
1185   #
1186   # libintl versions < 0.13 use the native *printf() functions, and Win32
1187   # *printf() doesn't understand %$, so we must use our /port versions,
1188   # which do understand %$. libintl versions >= 0.13 include their own
1189   # *printf versions on Win32.  The libintl 0.13 release note text is:
1190   #
1191   #   C format strings with positions, as they arise when a translator
1192   #   needs to reorder a sentence, are now supported on all platforms.
1193   #   On those few platforms (NetBSD and Woe32) for which the native
1194   #   printf()/fprintf()/... functions don't support such format
1195   #   strings, replacements are provided through <libintl.h>.
1196   #
1197   # We could use libintl >= 0.13's *printf() if we were sure that we had
1198   # a litint >= 0.13 at runtime, but seeing that there is no clean way
1199   # to guarantee that, it is best to just use our own, so we are sure to
1200   # get %$ support. In include/port.h we disable the *printf() macros
1201   # that might have been defined by libintl.
1202   #
1203   # We do this unconditionally whether NLS is used or not so we are sure
1204   # that all Win32 libraries and binaries behave the same.
1205   pgac_need_repl_snprintf=yes
1206 else
1207   pgac_need_repl_snprintf=no
1208   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
1209   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1210 fi
1211
1212
1213 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
1214 # include/c.h will provide declarations.  Note this is a separate test
1215 # from whether the functions exist in the C library --- there are
1216 # systems that have the functions but don't bother to declare them :-(
1217
1218 AC_CHECK_DECLS([snprintf, vsnprintf])
1219
1220
1221 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1222 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1223 [AC_TRY_LINK([
1224 #include <math.h>
1225 double glob_double;
1226 ],
1227 [return isinf(glob_double) ? 0 : 1;],
1228 [ac_cv_func_isinf=yes],
1229 [ac_cv_func_isinf=no])])
1230
1231 if test $ac_cv_func_isinf = yes ; then
1232   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1233 else
1234   AC_LIBOBJ(isinf)
1235   # Look for a way to implement a substitute for isinf()
1236   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1237 fi
1238
1239 # Some versions of libedit contain strlcpy(); so disregard that library while
1240 # checking for these standard libc functions.
1241 pgac_save_LIBS="$LIBS"
1242 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1243
1244 AC_REPLACE_FUNCS([crypt getopt getrusage inet_aton random rint srandom strdup strerror strlcat strlcpy strtol strtoul unsetenv])
1245
1246 LIBS="$pgac_save_LIBS"
1247
1248 # System's version of getaddrinfo(), if any, may be used only if we found
1249 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1250 # (Note: the AC_REPLACE_FUNCS probe fails on Windows, where the available
1251 # versions of getaddrinfo don't follow normal C call protocol.  This is OK
1252 # because we want to use our own getaddrinfo.c on Windows anyway.)
1253 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
1254   AC_REPLACE_FUNCS([getaddrinfo])
1255 else
1256   AC_LIBOBJ(getaddrinfo)
1257 fi
1258
1259 # Similarly, use system's getopt_long() only if system provides struct option.
1260 # Solaris' getopt() doesn't do what we want for long options, so always use
1261 # our versions on that platform.
1262 if test "$PORTNAME" = "solaris"; then
1263   AC_LIBOBJ(getopt)
1264   AC_LIBOBJ(getopt_long)
1265 elif test x"$ac_cv_type_struct_option" = xyes ; then
1266   AC_REPLACE_FUNCS([getopt_long])
1267 else
1268   AC_LIBOBJ(getopt_long)
1269 fi
1270
1271 # Win32 support
1272 if test "$PORTNAME" = "win32"; then
1273 AC_REPLACE_FUNCS(gettimeofday)
1274 AC_LIBOBJ(kill)
1275 AC_LIBOBJ(open)
1276 AC_LIBOBJ(rand)
1277 AC_LIBOBJ(win32error)
1278 AC_DEFINE([HAVE_SYMLINK], 1,
1279           [Define to 1 if you have the `symlink' function.])
1280 fi
1281
1282 if test "$with_readline" = yes; then
1283   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1284   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
1285   AC_CHECK_FUNCS([replace_history_entry])
1286 fi
1287
1288
1289 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
1290 dnl (especially on GNU libc)
1291 dnl See also comments in c.h.
1292 AC_MSG_CHECKING(for sigsetjmp)
1293 AC_TRY_LINK([#include <setjmp.h>],
1294             [sigjmp_buf x; sigsetjmp(x, 1);],
1295             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
1296 AC_MSG_RESULT(yes)],
1297             [AC_MSG_RESULT(no)])
1298
1299 AC_DECL_SYS_SIGLIST
1300
1301 AC_CHECK_FUNC(syslog,
1302               [AC_CHECK_HEADER(syslog.h,
1303                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1304
1305 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1306 [AC_TRY_LINK([#include <unistd.h>],
1307   [extern int optreset; optreset = 1;],
1308   [pgac_cv_var_int_optreset=yes],
1309   [pgac_cv_var_int_optreset=no])])
1310 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1311   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1312 fi
1313
1314 AC_CHECK_FUNCS([strtoll strtoq], [break])
1315 AC_CHECK_FUNCS([strtoull strtouq], [break])
1316
1317 # Check for one of atexit() or on_exit()
1318 AC_CHECK_FUNCS(atexit, [],
1319                [AC_CHECK_FUNCS(on_exit, [],
1320                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
1321
1322 AC_REPLACE_FUNCS(fseeko)
1323 case $host_os in
1324         # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
1325         bsdi*|netbsd*)
1326                 AC_DEFINE(HAVE_FSEEKO, 1, [Define to 1 because replacement version used.])
1327                 ac_cv_func_fseeko=yes;;
1328         *)
1329                 AC_FUNC_FSEEKO;;
1330 esac
1331
1332
1333 #
1334 # Pthreads
1335 #
1336 # For each platform, we need to know about any special compile and link
1337 # libraries, and whether the normal C function names are thread-safe.
1338 # See the comment at the top of src/port/thread.c for more information.
1339 # WIN32 doesn't need the pthread tests;  it always uses threads
1340 if test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"; then
1341 ACX_PTHREAD     # set thread flags
1342
1343 # Some platforms use these, so just define them.  They can't hurt if they
1344 # are not supported.  For example, on Solaris -D_POSIX_PTHREAD_SEMANTICS
1345 # enables 5-arg getpwuid_r, among other things.
1346 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1347
1348
1349 # At this point, we don't want to muck with the compiler name for threading.
1350 # Let's see who fails, perhaps AIX.  2004-04-23
1351 if test "$PTHREAD_CC" != "$CC"; then
1352 AC_MSG_ERROR([
1353 PostgreSQL does not support platforms that require a special compiler
1354 for thread safety.])
1355 fi
1356
1357 if test "$THREAD_SUPPORT" = no; then
1358 AC_MSG_ERROR([cannot enable threads on this platform
1359 This platform is known to not support thread-safe programs.  For details,
1360 compile and run src/bin/pg_thread_test.])
1361 fi
1362
1363 # Check for *_r functions
1364 _CFLAGS="$CFLAGS"
1365 _LIBS="$LIBS"
1366 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1367 LIBS="$LIBS $PTHREAD_LIBS"
1368
1369 if test "$PORTNAME" != "win32"; then
1370 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([pthread.h not found, required for --enable-thread-safety])])
1371 fi
1372
1373 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1374
1375 # Do test here with the proper thread flags
1376 PGAC_FUNC_GETPWUID_R_5ARG
1377 PGAC_FUNC_STRERROR_R_INT
1378
1379 CFLAGS="$_CFLAGS"
1380 LIBS="$_LIBS"
1381
1382 else
1383 # do not use values from template file
1384 PTHREAD_CFLAGS=
1385 PTHREAD_LIBS=
1386 fi
1387
1388 AC_SUBST(PTHREAD_CFLAGS)
1389 AC_SUBST(PTHREAD_LIBS)
1390
1391
1392 # We can test for libldap_r only after we know PTHREAD_LIBS
1393 if test "$with_ldap" = yes ; then
1394   _LIBS="$LIBS"
1395   if test "$PORTNAME" != "win32"; then
1396     AC_CHECK_LIB(ldap, ldap_bind, [],
1397                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1398                  [$EXTRA_LDAP_LIBS])
1399     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1400     if test "$enable_thread_safety" = yes; then
1401       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1402       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1403                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1404                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1405       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1406     else
1407       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1408     fi
1409   else
1410     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1411     LDAP_LIBS_FE="-lwldap32"
1412     LDAP_LIBS_BE="-lwldap32"
1413   fi
1414   LIBS="$_LIBS"
1415 fi
1416 AC_SUBST(LDAP_LIBS_FE)
1417 AC_SUBST(LDAP_LIBS_BE)
1418
1419
1420 # This test makes sure that run tests work at all.  Sometimes a shared
1421 # library is found by the linker, but the runtime linker can't find it.
1422 # This check should come after all modifications of compiler or linker
1423 # variables, and before any other run tests.
1424 AC_MSG_CHECKING([test program])
1425 AC_TRY_RUN([int main() { return 0; }],
1426 [AC_MSG_RESULT(ok)],
1427 [AC_MSG_RESULT(failed)
1428 AC_MSG_ERROR([[
1429 Could not execute a simple test program.  This may be a problem
1430 related to locating shared libraries.  Check the file 'config.log'
1431 for the exact reason.]])],
1432 [AC_MSG_RESULT([cross-compiling])])
1433
1434 # --------------------
1435 # Run tests below here
1436 # --------------------
1437
1438 # Force use of our snprintf if system's doesn't do arg control
1439 # See comment above at snprintf test for details.
1440 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1441   PGAC_FUNC_PRINTF_ARG_CONTROL
1442   if test $pgac_cv_printf_arg_control != yes ; then
1443     pgac_need_repl_snprintf=yes
1444   fi
1445 fi
1446
1447
1448 dnl Check to see if we have a working 64-bit integer type.
1449 dnl This breaks down into two steps:
1450 dnl (1) figure out if the compiler has a 64-bit int type with working
1451 dnl arithmetic, and if so
1452 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1453 dnl snprintf is the only library routine we really need for int8 support.)
1454 dnl It's entirely possible to have a compiler that handles a 64-bit type
1455 dnl when the C library doesn't; this is fairly likely when using gcc on
1456 dnl an older platform, for example.
1457 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1458 dnl we force our own version of snprintf() to be used instead.
1459 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1460
1461 PGAC_TYPE_64BIT_INT([long int])
1462
1463 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1464   PGAC_TYPE_64BIT_INT([long long int])
1465 fi
1466
1467
1468 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1469
1470 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1471   AC_TRY_COMPILE([
1472 #define INT64CONST(x)  x##LL
1473 long long int foo = INT64CONST(0x1234567890123456);
1474 ],
1475         [],
1476         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1477         [])
1478 fi
1479
1480
1481 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1482 # we found we need to use "long long int", better check.  We cope with
1483 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1484 # work, fall back to our own snprintf emulation (which we know uses %lld).
1485
1486 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1487   if test $pgac_need_repl_snprintf = no; then
1488     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1489     if test "$LONG_LONG_INT_FORMAT" = ""; then
1490       # Force usage of our own snprintf, since system snprintf is broken
1491       pgac_need_repl_snprintf=yes
1492       LONG_LONG_INT_FORMAT='%lld'
1493     fi
1494   else
1495     # Here if we previously decided we needed to use our own snprintf
1496     LONG_LONG_INT_FORMAT='%lld'
1497   fi
1498   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1499   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1500   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1501 else
1502   # Here if we are not using 'long long int' at all
1503   INT64_FORMAT='"%ld"'
1504   UINT64_FORMAT='"%lu"'
1505 fi
1506
1507 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1508                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1509
1510 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1511                    [Define to the appropriate snprintf format for unsigned 64-bit ints, if any.])
1512
1513 # Now we have checked all the reasons to replace snprintf
1514 if test $pgac_need_repl_snprintf = yes; then
1515   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1516   AC_LIBOBJ(snprintf)
1517 fi
1518
1519 # Need a #define for the size of Datum (unsigned long)
1520 AC_CHECK_SIZEOF([unsigned long])
1521
1522 # And one for the size of size_t (enables tweaks for > 32bit address space)
1523 AC_CHECK_SIZEOF([size_t])
1524
1525 # Decide whether float4 is passed by value: user-selectable, enabled by default
1526 AC_MSG_CHECKING([whether to build with float4 passed by value])
1527 PGAC_ARG_BOOL(enable, float4-byval, yes, [disable float4 passed by value],
1528               [AC_DEFINE([USE_FLOAT4_BYVAL], 1,
1529                          [Define to 1 if you want float4 values to be passed by value. (--enable-float4-byval)])
1530                float4passbyval=true],
1531               [float4passbyval=false])
1532 AC_MSG_RESULT([$enable_float4_byval])
1533 AC_DEFINE_UNQUOTED([FLOAT4PASSBYVAL], [$float4passbyval], [float4 values are passed by value if 'true', by reference if 'false'])
1534
1535 # Decide whether float8 is passed by value.
1536 # Note: this setting also controls int8 and related types such as timestamp.
1537 # If sizeof(Datum) >= 8, this is user-selectable, enabled by default.
1538 # If not, trying to select it is an error.
1539 AC_MSG_CHECKING([whether to build with float8 passed by value])
1540 if test $ac_cv_sizeof_unsigned_long -ge 8 ; then
1541   PGAC_ARG_BOOL(enable, float8-byval, yes, [disable float8 passed by value])
1542 else
1543   PGAC_ARG_BOOL(enable, float8-byval, no, [disable float8 passed by value])
1544   if test "$enable_float8_byval" = yes ; then
1545     AC_MSG_ERROR([--enable-float8-byval is not supported on 32-bit platforms.])
1546   fi
1547 fi
1548 if test "$enable_float8_byval" = yes ; then
1549   AC_DEFINE([USE_FLOAT8_BYVAL], 1,
1550             [Define to 1 if you want float8, int8, etc values to be passed by value. (--enable-float8-byval)])
1551   float8passbyval=true
1552 else
1553   float8passbyval=false
1554 fi
1555 AC_MSG_RESULT([$enable_float8_byval])
1556 AC_DEFINE_UNQUOTED([FLOAT8PASSBYVAL], [$float8passbyval], [float8, int8, and related values are passed by value if 'true', by reference if 'false'])
1557
1558 # Determine memory alignment requirements for the basic C data types.
1559
1560 AC_CHECK_ALIGNOF(short)
1561 AC_CHECK_ALIGNOF(int)
1562 AC_CHECK_ALIGNOF(long)
1563 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1564   AC_CHECK_ALIGNOF(long long int)
1565 fi
1566 AC_CHECK_ALIGNOF(double)
1567
1568 # Compute maximum alignment of any basic type.
1569 # We assume long's alignment is at least as strong as char, short, or int;
1570 # but we must check long long (if it exists) and double.
1571
1572 MAX_ALIGNOF=$ac_cv_alignof_long
1573 if test $MAX_ALIGNOF -lt $ac_cv_alignof_double ; then
1574   MAX_ALIGNOF=$ac_cv_alignof_double
1575 fi
1576 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $ac_cv_alignof_long_long_int ; then
1577   MAX_ALIGNOF="$ac_cv_alignof_long_long_int"
1578 fi
1579 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1580
1581
1582 # Some platforms predefine the types int8, int16, etc.  Only check
1583 # a (hopefully) representative subset.
1584 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1585 [#include <stdio.h>
1586 #ifdef HAVE_SUPPORTDEFS_H
1587 #include <SupportDefs.h>
1588 #endif])
1589
1590 # We also check for sig_atomic_t, which *should* be defined per ANSI
1591 # C, but is missing on some old platforms.
1592 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1593
1594
1595 # If the user did not disable integer datetimes, check that
1596 # there is a working 64-bit integral type to use.
1597 if test x"$USE_INTEGER_DATETIMES" = x"yes" &&
1598    test x"$HAVE_LONG_INT_64" = x"no" &&
1599    test x"$HAVE_LONG_LONG_INT_64" = x"no" &&
1600    test x"$HAVE_INT64" = x"no" ; then
1601   AC_MSG_ERROR([
1602 Integer-based datetime support requires a 64-bit integer type,
1603 but no such type could be found. The --disable-integer-datetimes
1604 configure option can be used to disable integer-based storage
1605 of datetime values.])
1606 fi
1607
1608
1609 if test "$PORTNAME" != "win32"
1610 then
1611 PGAC_FUNC_POSIX_SIGNALS
1612 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1613   AC_MSG_ERROR([
1614 Thread-safety requires POSIX signals, which are not supported by this
1615 operating system.])
1616 fi
1617 fi
1618
1619 if test $ac_cv_func_fseeko = yes; then
1620 AC_SYS_LARGEFILE
1621 fi
1622
1623 # Check for largefile support (must be after AC_SYS_LARGEFILE)
1624 AC_CHECK_SIZEOF([off_t])
1625
1626 # If we don't have largefile support, can't handle segsize >= 2GB.
1627 if test "$ac_cv_sizeof_off_t" -lt 8 -a "$segsize" != "1"; then
1628    AC_MSG_ERROR([Large file support is not enabled. Segment size cannot be larger than 1GB.])
1629 fi
1630
1631 # SunOS doesn't handle negative byte comparisons properly with +/- return
1632 AC_FUNC_MEMCMP
1633
1634
1635 # Select semaphore implementation type.
1636 if test "$PORTNAME" != "win32"; then
1637   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1638     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1639     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1640   else
1641     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1642       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1643       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1644     else
1645       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1646       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1647     fi
1648   fi
1649 else
1650   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1651   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1652 fi
1653
1654
1655 # Select shared-memory implementation type.
1656 if test "$PORTNAME" != "win32"; then
1657   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1658   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1659 else
1660   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
1661   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
1662 fi
1663
1664 # If not set in template file, set bytes to use libc memset()
1665 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
1666   MEMSET_LOOP_LIMIT=1024
1667 fi
1668 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
1669
1670
1671 if test "$enable_nls" = yes ; then
1672   PGAC_CHECK_GETTEXT
1673 fi
1674
1675 # Check for Tcl configuration script tclConfig.sh
1676 if test "$with_tcl" = yes; then
1677     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1678     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1679                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1680     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1681     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1682     ac_save_CPPFLAGS=$CPPFLAGS
1683     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1684     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1685     CPPFLAGS=$ac_save_CPPFLAGS
1686 fi
1687
1688 #
1689 # Check for DocBook and tools
1690 #
1691 PGAC_PROG_NSGMLS
1692 PGAC_PROG_JADE
1693 PGAC_CHECK_DOCBOOK(4.2)
1694 PGAC_PATH_DOCBOOK_STYLESHEETS
1695 PGAC_PATH_COLLATEINDEX
1696 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1697 PGAC_PATH_DOCBOOK2MAN
1698
1699 # Thread testing
1700
1701 # We have to run the thread test near the end so we have all our symbols
1702 # defined.  Cross compiling throws a warning.
1703 #
1704 if test "$enable_thread_safety_force" = yes; then
1705 if test "$PORTNAME" != "win32"
1706 then
1707   AC_MSG_WARN([
1708 *** Skipping thread test program.  --enable-thread-safety-force was used.
1709 *** Run the program in src/test/thread on the your machine and add proper
1710 *** locking function calls to your applications to guarantee thread safety.
1711 ])
1712 else
1713 AC_MSG_WARN([*** skipping thread test on Win32])
1714 fi
1715 elif test "$enable_thread_safety" = yes; then
1716 if test "$PORTNAME" != "win32"
1717 then
1718 AC_MSG_CHECKING([thread safety of required library functions])
1719
1720 _CFLAGS="$CFLAGS"
1721 _LIBS="$LIBS"
1722 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1723 LIBS="$LIBS $PTHREAD_LIBS"
1724 AC_TRY_RUN([#include "$srcdir/src/test/thread/thread_test.c"],
1725   [AC_MSG_RESULT(yes)],
1726   [AC_MSG_RESULT(no)
1727   AC_MSG_ERROR([thread test program failed
1728 This platform is not thread-safe.  Check the file 'config.log' for the
1729 exact reason.
1730
1731 You can use the configure option --enable-thread-safety-force to force
1732 threads to be enabled.  But you must then run the program in
1733 src/test/thread and add locking function calls to your applications to
1734 guarantee thread safety.])],
1735   [AC_MSG_RESULT(maybe)
1736   AC_MSG_WARN([
1737 *** Skipping thread test program because of cross-compile build.
1738 *** Run the program in src/test/thread on the target machine.
1739 ])])
1740 CFLAGS="$_CFLAGS"
1741 LIBS="$_LIBS"
1742 else
1743 AC_MSG_WARN([*** skipping thread test on Win32])
1744 fi
1745 fi
1746
1747 # If compiler will take -Wl,--as-needed then add that to LDFLAGS.
1748 # This is much easier than trying to filter LIBS to the minimum for each
1749 # executable.  (Note that shared library links won't use this switch, though.)
1750 # On (at least) some Red-Hat-derived systems, this switch breaks linking to
1751 # libreadline; therefore we postpone testing it until we know what library
1752 # dependencies readline has.  The test code will try to link with $LIBS.
1753 if test "$with_readline" = yes; then
1754   link_test_func=readline
1755 else
1756   link_test_func=exit
1757 fi
1758 if test "$PORTNAME" != "darwin"; then
1759   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,--as-needed], $link_test_func)
1760 else
1761   # On Darwin it's spelled -Wl,-dead_strip_dylibs, but don't try that elsewhere
1762   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-dead_strip_dylibs], $link_test_func)
1763 fi
1764
1765
1766 # Begin output steps
1767
1768 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
1769 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
1770 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
1771
1772 # prepare build tree if outside source tree
1773 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1774 # Note 2: /bin/pwd might be better than shell's built-in at getting
1775 #         a symlink-free name.
1776 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1777   vpath_build=no
1778 else
1779   vpath_build=yes
1780   if test "$no_create" != yes; then
1781     _AS_ECHO_N([preparing build tree... ])
1782     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1783     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1784       || AC_MSG_ERROR(failed)
1785     AC_MSG_RESULT(done)
1786   fi
1787 fi
1788 AC_SUBST(vpath_build)
1789
1790
1791 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1792
1793 AC_CONFIG_LINKS([
1794   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1795   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1796   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1797   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1798   src/include/pg_config_os.h:src/include/port/${template}.h
1799   src/Makefile.port:src/makefiles/Makefile.${template}
1800 ])
1801
1802 if test "$PORTNAME" = "win32"; then
1803 AC_CONFIG_COMMANDS([check_win32_symlinks],[
1804 # Links sometimes fail undetected on Mingw -
1805 # so here we detect it and warn the user
1806 for FILE in $CONFIG_LINKS
1807  do
1808         # test -e works for symlinks in the MinGW console
1809         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
1810  done
1811 ])
1812 fi
1813
1814 AC_CONFIG_HEADERS([src/include/pg_config.h],
1815 [
1816 # Update timestamp for pg_config.h (see Makefile.global)
1817 echo >src/include/stamp-h
1818 ])
1819
1820 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h])
1821
1822 AC_OUTPUT
1823
1824 # Warn about unknown options
1825 PGAC_ARG_CHECK