configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $PostgreSQL: pgsql/configure.in,v 1.513 2007/04/21 18:26:44 petere Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [8.3devel], [pgsql-bugs@postgresql.org])
  21
  22 AC_PREREQ(2.59)
  23 AC_COPYRIGHT([Copyright (c) 1996-2007, PostgreSQL Global Development Group])
  24 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  25 AC_CONFIG_AUX_DIR(config)
  26 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  27 AC_SUBST(configure_args, [$ac_configure_args])
  28
  29 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version as a string])
  30
  31 AC_CANONICAL_HOST
  32
  33 template=
  34 AC_MSG_CHECKING([which template to use])
  35
  36 PGAC_ARG_REQ(with, template, [],
  37 [
  38   case $withval in
  39     list)   echo; ls "$srcdir/src/template"; exit;;
  40     *)      if test -f "$srcdir/src/template/$with_template" ; then
  41               template=$withval
  42             else
  43               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  44             fi;;
  45   esac
  46 ],
  47 [
  48 # --with-template not given
  49
  50 case $host_os in
  51      aix*) template=aix ;;
  52     bsdi*) template=bsdi ;;
  53   cygwin*) template=cygwin ;;
  54   darwin*) template=darwin ;;
  55     dgux*) template=dgux ;;
  56  freebsd*) template=freebsd ;;
  57     hpux*) template=hpux ;;
  58     irix*) template=irix ;;
  59  linux*|gnu*|k*bsd*-gnu)
  60            template=linux ;;
  61    mingw*) template=win32 ;;
  62   netbsd*) template=netbsd ;;
  63 nextstep*) template=nextstep ;;
  64  openbsd*) template=openbsd ;;
  65      osf*) template=osf ;;
  66      sco*) template=sco ;;
  67  solaris*) template=solaris ;;
  68    sunos*) template=sunos4 ;;
  69  sysv4.2*)
  70         case $host_vendor in
  71           univel) template=univel ;;
  72         esac ;;
  73    sysv4*) template=svr4 ;;
  74    sysv5*) template=unixware ;;
  75   ultrix*) template=ultrix4 ;;
  76 esac
  77
  78   if test x"$template" = x"" ; then
  79     AC_MSG_ERROR([[
  80 *******************************************************************
  81 PostgreSQL has apparently not been ported to your platform yet.
  82 To try a manual configuration, look into the src/template directory
  83 for a similar platform and use the '--with-template=' option.
  84
  85 Please also contact <pgsql-ports@postgresql.org> to see about
  86 rectifying this.  Include the above 'checking host system type...'
  87 line.
  88 *******************************************************************
  89 ]])
  90   fi
  91
  92 ])
  93
  94 AC_MSG_RESULT([$template])
  95
  96 PORTNAME=$template
  97 AC_SUBST(PORTNAME)
  98
  99 # Initialize default assumption that we do not need separate assembly code
 100 # for TAS (test-and-set).  This can be overridden by the template file
 101 # when it's executed.
 102 need_tas=no
 103 tas_file=dummy.s
 104
 105
 106
 107 ##
 108 ## Command line options
 109 ##
 110
 111 #
 112 # Installation directory for documentation
 113 #
 114 PGAC_ARG(with, docdir, [  --with-docdir=DIR       install the documentation in DIR [[PREFIX/doc]]
 115   --without-docdir        do not install the documentation],
 116          [AC_MSG_ERROR([option --with-docdir requires an argument])],
 117          [docdir=],
 118          [docdir=$withval],
 119          [docdir='${prefix}/doc'])
 120 AC_SUBST(docdir)
 121
 122
 123 #
 124 # Add non-standard directories to the include path
 125 #
 126 PGAC_ARG_REQ(with, includes, [  --with-includes=DIRS    look for additional header files in DIRS])
 127
 128
 129 #
 130 # Add non-standard directories to the library search path
 131 #
 132 PGAC_ARG_REQ(with, libraries, [  --with-libraries=DIRS   look for additional libraries in DIRS],
 133              [LIBRARY_DIRS=$withval])
 134
 135 PGAC_ARG_REQ(with, libs,      [  --with-libs=DIRS        alternative spelling of --with-libraries],
 136              [LIBRARY_DIRS=$withval])
 137
 138
 139 #
 140 # 64-bit integer date/time storage (--enable-integer-datetimes)
 141 #
 142 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 143 PGAC_ARG_BOOL(enable, integer-datetimes, no, [  --enable-integer-datetimes  enable 64-bit integer date/time support],
 144               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 145                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 146 AC_MSG_RESULT([$enable_integer_datetimes])
 147
 148
 149 #
 150 # NLS
 151 #
 152 AC_MSG_CHECKING([whether NLS is wanted])
 153 PGAC_ARG_OPTARG(enable, nls,
 154                 [[  --enable-nls[=LANGUAGES]  enable Native Language Support]],
 155                 [],
 156                 [WANTED_LANGUAGES=$enableval],
 157                 [AC_DEFINE(ENABLE_NLS, 1,
 158                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 159 AC_MSG_RESULT([$enable_nls])
 160 AC_SUBST(enable_nls)
 161 AC_SUBST(WANTED_LANGUAGES)
 162
 163 #
 164 # Default port number (--with-pgport), default 5432
 165 #
 166 AC_MSG_CHECKING([for default port number])
 167 PGAC_ARG_REQ(with, pgport, [  --with-pgport=PORTNUM   change default port number [[5432]]],
 168              [default_port=$withval],
 169              [default_port=5432])
 170 AC_MSG_RESULT([$default_port])
 171 # Need both of these because some places want an integer and some a string
 172 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 173 [Define to the default TCP port number on which the server listens and
 174 to which clients will try to connect.  This can be overridden at run-time,
 175 but it's convenient if your clients have the right default compiled in.
 176 (--with-pgport=PORTNUM)])
 177 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 178                    [Define to the default TCP port number as a string constant.])
 179 AC_SUBST(default_port)
 180
 181 #
 182 # Option to disable shared libraries
 183 #
 184 PGAC_ARG_BOOL(enable, shared, yes,
 185               [  --disable-shared        do not build shared libraries])
 186 AC_SUBST(enable_shared)
 187
 188 #
 189 # '-rpath'-like feature can be disabled
 190 #
 191 PGAC_ARG_BOOL(enable, rpath, yes,
 192               [  --disable-rpath         do not embed shared library search path in executables])
 193 AC_SUBST(enable_rpath)
 194
 195 #
 196 # Spinlocks
 197 #
 198 PGAC_ARG_BOOL(enable, spinlocks, yes,
 199               [  --disable-spinlocks     do not use spinlocks])
 200
 201 #
 202 # --enable-debug adds -g to compiler flags
 203 #
 204 PGAC_ARG_BOOL(enable, debug, no,
 205               [  --enable-debug          build with debugging symbols (-g)])
 206 AC_SUBST(enable_debug)
 207
 208 #
 209 # --enable-profiling enables gcc profiling
 210 #
 211 PGAC_ARG_BOOL(enable, profiling, no,
 212               [  --enable-profiling      build with profiling enabled ])
 213 AC_SUBST(enable_profiling)
 214
 215 #
 216 # DTrace
 217 #
 218 PGAC_ARG_BOOL(enable, dtrace, no,
 219               [  --enable-dtrace         build with DTrace support],
 220 [AC_DEFINE([ENABLE_DTRACE], 1,
 221            [Define to 1 to enable DTrace support. (--enable-dtrace)])
 222 AC_CHECK_PROGS(DTRACE, dtrace)
 223 if test -z "$DTRACE"; then
 224   AC_MSG_ERROR([dtrace not found])
 225 fi
 226 AC_SUBST(DTRACEFLAGS)])
 227 AC_SUBST(enable_dtrace)
 228
 229 #
 230 # C compiler
 231 #
 232
 233 # For historical reasons you can also use --with-CC to specify the C compiler
 234 # to use, although the standard way to do this is to set the CC environment
 235 # variable.
 236 PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
 237
 238 case $template in
 239   aix) pgac_cc_list="gcc xlc";;
 240  irix) pgac_cc_list="cc";; # no gcc
 241     *) pgac_cc_list="gcc cc";;
 242 esac
 243
 244 AC_PROG_CC([$pgac_cc_list])
 245
 246 unset CFLAGS
 247
 248 #
 249 # Read the template
 250 #
 251 . "$srcdir/src/template/$template" || exit
 252
 253 # CFLAGS are selected so:
 254 # If the user specifies something in the environment, that is used.
 255 # else:  If the template file set something, that is used.
 256 # else:  If the compiler is GCC, then we use -O2.
 257 # else:  If the compiler is something else, then we use -0.
 258
 259 if test "$ac_env_CFLAGS_set" = set; then
 260   CFLAGS=$ac_env_CFLAGS_value
 261 elif test "${CFLAGS+set}" = set; then
 262   : # (keep what template set)
 263 elif test "$GCC" = yes; then
 264   CFLAGS="-O2"
 265 else
 266   # if the user selected debug mode, don't use -O
 267   if test "$enable_debug" != yes; then
 268     CFLAGS="-O"
 269   fi
 270 fi
 271
 272 # Some versions of GCC support some additional useful warning flags.
 273 # Check whether they are supported, and add them to CFLAGS if so.
 274
 275 if test "$GCC" = yes; then
 276
 277 # ICC pretends to be GCC but it's lying; it doesn't support these options.
 278 # So we have to check if "GCC" is really ICC.
 279 AC_TRY_COMPILE([], [@%:@ifndef __INTEL_COMPILER
 280 choke me
 281 @%:@endif], [ICC=[yes]], [ICC=[no]])
 282
 283   if test "$ICC" = no; then
 284     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wpointer-arith -Winline"
 285
 286     PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 287     PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 288   else
 289     # Intel compiler has a bug/misoptimization in checking for
 290     # division by NAN (NaN == 0), -mp1 fixes it, so add it to the
 291     # CFLAGS.
 292     PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 293   fi
 294
 295   # Disable strict-aliasing rules; needed for gcc 3.3+
 296   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 297 elif test x"${CC}" = x"xlc"; then
 298   # AIX xlc has to have strict aliasing turned off too
 299   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 300 fi
 301
 302 # supply -g if --enable-debug
 303 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 304   CFLAGS="$CFLAGS -g"
 305 fi
 306
 307 # enable profiling if --enable-profiling
 308 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 309   if test "$GCC" = yes; then
 310     AC_DEFINE([PROFILE_PID_DIR], 1,
 311            [Define to 1 to enable profiling. (--enable-profiling)])
 312     CFLAGS="$CFLAGS -pg"
 313   else
 314     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 315   fi
 316 fi
 317
 318 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
 319
 320 # We already have this in Makefile.win32, but configure needs it too
 321 if test "$PORTNAME" = "win32"; then
 322   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 323 fi
 324
 325 # Check if the compiler still works with the template settings
 326 AC_MSG_CHECKING([whether the C compiler still works])
 327 AC_TRY_LINK([], [return 0;],
 328   [AC_MSG_RESULT(yes)],
 329   [AC_MSG_RESULT(no)
 330    AC_MSG_ERROR([cannot proceed])])
 331
 332 # Defend against gcc -ffast-math
 333 if test "$GCC" = yes; then
 334 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 335 choke me
 336 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 337 fi
 338
 339 AC_PROG_CPP
 340 AC_SUBST(GCC)
 341
 342 # Create compiler version string
 343 if test x"$GCC" = x"yes" ; then
 344   cc_string="GCC `${CC} --version | sed q`"
 345 else
 346   cc_string=$CC
 347 fi
 348 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
 349                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"],
 350                    [A string containing the version number, platform, and C compiler])
 351
 352
 353 #
 354 # Set up TAS assembly code if needed; the template file has now had its
 355 # chance to request this.
 356 #
 357 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 358
 359 if test "$need_tas" = yes ; then
 360   TAS=tas.o
 361 else
 362   TAS=""
 363 fi
 364 AC_SUBST(TAS)
 365
 366
 367 #
 368 # Automatic dependency tracking
 369 #
 370 PGAC_ARG_BOOL(enable, depend, no, [  --enable-depend         turn on automatic dependency tracking],
 371               [autodepend=yes])
 372 AC_SUBST(autodepend)
 373
 374
 375 #
 376 # Enable assert checks
 377 #
 378 PGAC_ARG_BOOL(enable, cassert, no, [  --enable-cassert        enable assertion checks (for debugging)],
 379               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 380                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 381
 382
 383 #
 384 # Include directories
 385 #
 386 ac_save_IFS=$IFS
 387 IFS="${IFS}${PATH_SEPARATOR}"
 388 # SRCH_INC comes from the template file
 389 for dir in $with_includes $SRCH_INC; do
 390   if test -d "$dir"; then
 391     INCLUDES="$INCLUDES -I$dir"
 392   else
 393     AC_MSG_WARN([*** Include directory $dir does not exist.])
 394   fi
 395 done
 396 IFS=$ac_save_IFS
 397 AC_SUBST(INCLUDES)
 398
 399
 400 #
 401 # Library directories
 402 #
 403 ac_save_IFS=$IFS
 404 IFS="${IFS}${PATH_SEPARATOR}"
 405 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 406 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 407   if test -d "$dir"; then
 408     LIBDIRS="$LIBDIRS -L$dir"
 409   else
 410     AC_MSG_WARN([*** Library directory $dir does not exist.])
 411   fi
 412 done
 413 IFS=$ac_save_IFS
 414
 415 #
 416 # Enable thread-safe client libraries
 417 #
 418 AC_MSG_CHECKING([allow thread-safe client libraries])
 419 if test "$PORTNAME" != "win32"; then
 420 PGAC_ARG_BOOL(enable, thread-safety, no, [  --enable-thread-safety  make client libraries thread-safe])
 421 else
 422 # Win32 should always use threads
 423 PGAC_ARG_BOOL(enable, thread-safety, yes, [  --enable-thread-safety  make client libraries thread-safe])
 424 fi
 425
 426 PGAC_ARG_BOOL(enable, thread-safety-force, no, [  --enable-thread-safety-force  force thread-safety in spite of thread test failure])
 427 if test "$enable_thread_safety" = yes -o \
 428         "$enable_thread_safety_force" = yes; then
 429   enable_thread_safety="yes"    # for 'force'
 430   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 431           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 432 fi
 433 AC_MSG_RESULT([$enable_thread_safety])
 434 AC_SUBST(enable_thread_safety)
 435
 436 #
 437 # Optionally build Tcl modules (PL/Tcl)
 438 #
 439 AC_MSG_CHECKING([whether to build with Tcl])
 440 PGAC_ARG_BOOL(with, tcl, no, [  --with-tcl              build Tcl modules (PL/Tcl)])
 441 AC_MSG_RESULT([$with_tcl])
 442 AC_SUBST([with_tcl])
 443
 444 # We see if the path to the Tcl/Tk configuration scripts is specified.
 445 # This will override the use of tclsh to find the paths to search.
 446
 447 PGAC_ARG_REQ(with, tclconfig, [  --with-tclconfig=DIR    tclConfig.sh is in DIR])
 448
 449 #
 450 # Optionally build Perl modules (PL/Perl)
 451 #
 452 AC_MSG_CHECKING([whether to build Perl modules])
 453 PGAC_ARG_BOOL(with, perl, no, [  --with-perl             build Perl modules (PL/Perl)])
 454 AC_MSG_RESULT([$with_perl])
 455 AC_SUBST(with_perl)
 456
 457 #
 458 # Optionally build Python modules (PL/Python)
 459 #
 460 AC_MSG_CHECKING([whether to build Python modules])
 461 PGAC_ARG_BOOL(with, python, no, [  --with-python           build Python modules (PL/Python)])
 462 AC_MSG_RESULT([$with_python])
 463 AC_SUBST(with_python)
 464
 465 #
 466 # Kerberos 5
 467 #
 468 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 469 PGAC_ARG_BOOL(with, krb5, no, [  --with-krb5             build with Kerberos 5 support],
 470 [
 471   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 472   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 473 ])
 474 AC_MSG_RESULT([$with_krb5])
 475 AC_SUBST(with_krb5)
 476
 477
 478 AC_SUBST(krb_srvtab)
 479
 480
 481 #
 482 # Kerberos configuration parameters
 483 #
 484 PGAC_ARG_REQ(with, krb-srvnam,
 485              [  --with-krb-srvnam=NAME  name of the default service principal in Kerberos [[postgres]]],
 486              [],
 487              [with_krb_srvnam="postgres"])
 488 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 489                    [Define to the name of the default PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 490
 491
 492 #
 493 # PAM
 494 #
 495 AC_MSG_CHECKING([whether to build with PAM support])
 496 PGAC_ARG_BOOL(with, pam, no,
 497               [  --with-pam              build with PAM support],
 498               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 499 AC_MSG_RESULT([$with_pam])
 500 AC_SUBST(with_pam)
 501
 502
 503 #
 504 # LDAP
 505 #
 506 AC_MSG_CHECKING([whether to build with LDAP support])
 507 PGAC_ARG_BOOL(with, ldap, no,
 508               [  --with-ldap             build with LDAP support],
 509               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 510 AC_MSG_RESULT([$with_ldap])
 511 AC_SUBST(with_ldap)
 512
 513
 514 #
 515 # Bonjour
 516 #
 517 AC_MSG_CHECKING([whether to build with Bonjour support])
 518 PGAC_ARG_BOOL(with, bonjour, no,
 519               [  --with-bonjour          build with Bonjour support],
 520               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 521 AC_MSG_RESULT([$with_bonjour])
 522 AC_SUBST(with_bonjour)
 523
 524
 525 #
 526 # OpenSSL
 527 #
 528 AC_MSG_CHECKING([whether to build with OpenSSL support])
 529 PGAC_ARG_BOOL(with, openssl, no, [  --with-openssl          build with OpenSSL support],
 530               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 531 AC_MSG_RESULT([$with_openssl])
 532 AC_SUBST(with_openssl)
 533
 534
 535 #
 536 # Readline
 537 #
 538 PGAC_ARG_BOOL(with, readline, yes,
 539               [  --without-readline      do not use GNU Readline nor BSD Libedit for editing])
 540 # readline on MinGW has problems with backslashes in psql and other bugs.
 541 # This is particularly a problem with non-US code pages.
 542 # Therefore disable its use until we understand the cause. 2004-07-20
 543 if test "$PORTNAME" = "win32"; then
 544   if test "$with_readline" = yes; then
 545     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 546     with_readline=no
 547   fi
 548 fi
 549
 550
 551 #
 552 # Prefer libedit
 553 #
 554 PGAC_ARG_BOOL(with, libedit-preferred, no,
 555               [  --with-libedit-preferred  prefer BSD Libedit over GNU Readline])
 556
 557
 558 #
 559 # OSSP UUID library
 560 #
 561 PGAC_ARG_BOOL(with, ossp-uuid, no, [  --with-ossp-uuid        build with OSSP UUID library for UUID generation])
 562 AC_SUBST(with_ossp_uuid)
 563
 564
 565 #
 566 # XML
 567 #
 568 PGAC_ARG_BOOL(with, libxml, no, [  --with-libxml           build with XML support],
 569               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 570
 571 if test "$with_libxml" = yes ; then
 572   AC_CHECK_PROGS(XML2_CONFIG, xml2-config)
 573   if test -n "$XML2_CONFIG"; then
 574     for pgac_option in `$XML2_CONFIG --cflags`; do
 575       case $pgac_option in
 576         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 577       esac
 578     done
 579     for pgac_option in `$XML2_CONFIG --libs`; do
 580       case $pgac_option in
 581         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 582       esac
 583     done
 584   fi
 585 fi
 586
 587 AC_SUBST(with_libxml)
 588
 589 #
 590 # XSLT
 591 #
 592 PGAC_ARG_BOOL(with, libxslt, no, [  --with-libxslt          build with XSLT support],
 593               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to build with XSLT support. (--with-libxslt)])])
 594
 595
 596 AC_SUBST(with_libxslt)
 597
 598 #
 599 # Zlib
 600 #
 601 PGAC_ARG_BOOL(with, zlib, yes,
 602               [  --without-zlib          do not use Zlib])
 603 AC_SUBST(with_zlib)
 604
 605 #
 606 # Elf
 607 #
 608
 609 # Assume system is ELF if it predefines __ELF__ as 1,
 610 # otherwise believe host_os based default.
 611 case $host_os in
 612     freebsd1*|freebsd2*) elf=no;;
 613     freebsd3*|freebsd4*) elf=yes;;
 614 esac
 615
 616 AC_EGREP_CPP(yes,
 617 [#if __ELF__
 618   yes
 619 #endif
 620 ],
 621 [ELF_SYS=true],
 622 [if test "X$elf" = "Xyes" ; then
 623   ELF_SYS=true
 624 else
 625   ELF_SYS=
 626 fi])
 627 AC_SUBST(ELF_SYS)
 628
 629 #
 630 # Assignments
 631 #
 632
 633 CPPFLAGS="$CPPFLAGS $INCLUDES"
 634 LDFLAGS="$LDFLAGS $LIBDIRS"
 635
 636 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
 637 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
 638
 639 AC_ARG_VAR(LDFLAGS_SL)
 640
 641 AC_PROG_AWK
 642 PGAC_PATH_FLEX
 643 AC_PROG_LN_S
 644 PGAC_PROG_LD
 645 AC_SUBST(LD)
 646 AC_SUBST(with_gnu_ld)
 647 case $host_os in sysv5*)
 648   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 649   [
 650     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 651     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 652     LDFLAGS=$pgac_save_LDFLAGS
 653   ])
 654   ld_R_works=$pgac_cv_prog_ld_R
 655   AC_SUBST(ld_R_works)
 656 esac
 657 AC_PROG_RANLIB
 658 AC_PATH_PROG(TAR, tar)
 659 PGAC_CHECK_STRIP
 660
 661 if test -z "$YACC"; then
 662   AC_CHECK_PROGS(YACC, ['bison -y'])
 663
 664   if test "$YACC"; then
 665     if $YACC --version | sed q | $AWK '{ if ($4 < 1.875) exit 0; else exit 1;}'; then
 666       AC_MSG_WARN([
 667 *** The installed version of Bison is too old to use with PostgreSQL.
 668 *** Bison version 1.875 or later is required.])
 669       YACC=""
 670     fi
 671   fi
 672
 673   if test -z "$YACC"; then
 674     AC_MSG_WARN([
 675 *** Without Bison you will not be able to build PostgreSQL from CVS nor
 676 *** change any of the parser definition files.  You can obtain Bison from
 677 *** a GNU mirror site.  (If you are using the official distribution of
 678 *** PostgreSQL then you do not need to worry about this, because the Bison
 679 *** output is pre-generated.)  To use a different yacc program (possible,
 680 *** but not recommended), set the environment variable YACC before running
 681 *** 'configure'.])
 682   fi
 683 fi
 684 AC_SUBST(YFLAGS)
 685
 686 PGAC_PATH_PERL
 687 if test "$with_perl" = yes; then
 688   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 689   PGAC_CHECK_PERL_EMBED_LDFLAGS
 690 fi
 691
 692 if test "$with_python" = yes; then
 693   PGAC_PATH_PYTHON
 694   PGAC_CHECK_PYTHON_EMBED_SETUP
 695 fi
 696
 697 # Supply a numeric version string for use by 3rd party add-ons
 698 # awk -F is a regex on some platforms, and not on others, so make "." a tab
 699 PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
 700 tr '.' '        ' |
 701 $AWK '{printf \"%d%02d%02d\", $1, $2, (NF >= 3) ? $3 : 0}'`"
 702 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
 703
 704 ##
 705 ## Libraries
 706 ##
 707 ## Most libraries are included only if they demonstrably provide a function
 708 ## we need, but libm is an exception: always include it, because there are
 709 ## too many compilers that play cute optimization games that will break
 710 ## probes for standard functions such as pow().
 711 ##
 712
 713 AC_CHECK_LIB(m, main)
 714 AC_SEARCH_LIBS(setproctitle, util)
 715 AC_SEARCH_LIBS(dlopen, dl)
 716 AC_SEARCH_LIBS(socket, [socket wsock32])
 717 AC_SEARCH_LIBS(shl_load, dld)
 718 # We only use libld in port/dynloader/aix.c
 719 case $host_os in
 720      aix*)
 721         AC_SEARCH_LIBS(ldopen, ld)
 722         ;;
 723 esac
 724 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 725 AC_SEARCH_LIBS(crypt, crypt)
 726 # Solaris:
 727 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 728 # Cygwin:
 729 AC_SEARCH_LIBS(shmget, cygipc)
 730
 731 if test "$with_readline" = yes; then
 732   PGAC_CHECK_READLINE
 733   if test x"$pgac_cv_check_readline" = x"no"; then
 734     AC_MSG_ERROR([readline library not found
 735 If you have readline already installed, see config.log for details on the
 736 failure.  It is possible the compiler isn't looking in the proper directory.
 737 Use --without-readline to disable readline support.])
 738   fi
 739 fi
 740
 741 if test "$with_zlib" = yes; then
 742   AC_CHECK_LIB(z, inflate, [],
 743                [AC_MSG_ERROR([zlib library not found
 744 If you have zlib already installed, see config.log for details on the
 745 failure.  It is possible the compiler isn't looking in the proper directory.
 746 Use --without-zlib to disable zlib support.])])
 747 fi
 748
 749 if test "$enable_spinlocks" = yes; then
 750   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 751 else
 752   AC_MSG_WARN([
 753 *** Not using spinlocks will cause poor performance.])
 754 fi
 755
 756 if test "$with_krb5" = yes ; then
 757   if test "$PORTNAME" != "win32"; then
 758      AC_SEARCH_LIBS(com_err, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken' com_err], [],
 759                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 760      AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken'], [],
 761                     [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 762   else
 763      AC_SEARCH_LIBS(com_err, 'comerr32 -lkrb5_32', [],
 764                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 765   fi
 766 fi
 767
 768 if test "$with_openssl" = yes ; then
 769   dnl Order matters!
 770   if test "$PORTNAME" != "win32"; then
 771      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 772      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 773   else
 774      AC_CHECK_LIB(eay32, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'eay32' is required for OpenSSL])])
 775      AC_CHECK_LIB(ssleay32,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssleay32' is required for OpenSSL])])
 776   fi
 777 fi
 778
 779 if test "$with_pam" = yes ; then
 780   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 781 fi
 782
 783 if test "$with_libxml" = yes ; then
 784   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
 785 fi
 786
 787 if test "$with_libxslt" = yes ; then
 788   AC_CHECK_LIB(xslt, xsltLibxmlVersion, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
 789 fi
 790
 791
 792 ##
 793 ## Header files
 794 ##
 795
 796 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 797 AC_CHECK_HEADERS([crypt.h dld.h fp_class.h getopt.h ieeefp.h langinfo.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/time.h sys/un.h termios.h utime.h wchar.h wctype.h kernel/OS.h kernel/image.h SupportDefs.h])
 798
 799 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 800 # netinet/in.h is included first.
 801 AC_CHECK_HEADERS(netinet/in.h)
 802 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 803 [AC_INCLUDES_DEFAULT
 804 #ifdef HAVE_NETINET_IN_H
 805 #include <netinet/in.h>
 806 #endif
 807 ])
 808
 809 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
 810   AC_CHECK_HEADERS(readline/readline.h, [],
 811         [AC_CHECK_HEADERS(readline.h, [],
 812                 [AC_MSG_ERROR([readline header not found
 813 If you have readline already installed, see config.log for details on the
 814 failure.  It is possible the compiler isn't looking in the proper directory.
 815 Use --without-readline to disable readline support.])])])
 816   AC_CHECK_HEADERS(readline/history.h, [],
 817         [AC_CHECK_HEADERS(history.h, [],
 818                 [AC_MSG_ERROR([history header not found
 819 If you have readline already installed, see config.log for details on the
 820 failure.  It is possible the compiler isn't looking in the proper directory.
 821 Use --without-readline to disable readline support.])])])
 822 fi
 823
 824 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
 825 # Some installations of libedit usurp /usr/include/readline/, which seems
 826 # bad practice, since in combined installations readline will have its headers
 827 # there.  We might have to resort to AC_EGREP checks to make sure we found
 828 # the proper header...
 829   AC_CHECK_HEADERS(editline/readline.h, [],
 830         [AC_CHECK_HEADERS(readline.h, [],
 831                 [AC_CHECK_HEADERS(readline/readline.h, [],
 832                         [AC_MSG_ERROR([readline header not found
 833 If you have libedit already installed, see config.log for details on the
 834 failure.  It is possible the compiler isn't looking in the proper directory.
 835 Use --without-readline to disable libedit support.])])])])
 836 # Note: in a libedit installation, history.h is sometimes a dummy, and may
 837 # not be there at all.  Hence, don't complain if not found.  We must check
 838 # though, since in yet other versions it is an independent header.
 839   AC_CHECK_HEADERS(editline/history.h, [],
 840         [AC_CHECK_HEADERS(history.h, [],
 841                 [AC_CHECK_HEADERS(readline/history.h)])])
 842 fi
 843
 844 if test "$with_zlib" = yes; then
 845   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
 846 If you have zlib already installed, see config.log for details on the
 847 failure.  It is possible the compiler isn't looking in the proper directory.
 848 Use --without-zlib to disable zlib support.])])
 849 fi
 850
 851 if test "$with_krb5" = yes ; then
 852   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
 853 fi
 854
 855 if test "$with_openssl" = yes ; then
 856   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
 857   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
 858 fi
 859
 860 if test "$with_pam" = yes ; then
 861   AC_CHECK_HEADERS(security/pam_appl.h, [],
 862                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
 863                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
 864 fi
 865
 866 if test "$with_libxml" = yes ; then
 867   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
 868 fi
 869
 870 if test "$with_libxslt" = yes ; then
 871   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
 872 fi
 873
 874 if test "$with_ldap" = yes ; then
 875   if test "$PORTNAME" != "win32"; then
 876      AC_CHECK_HEADERS(ldap.h, [],
 877                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
 878   else
 879      AC_CHECK_HEADERS(winldap.h, [],
 880                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
 881                       [AC_INCLUDES_DEFAULT
 882 #include <windows.h>
 883                       ])
 884   fi
 885 fi
 886
 887 if test "$with_bonjour" = yes ; then
 888   AC_CHECK_HEADER(DNSServiceDiscovery/DNSServiceDiscovery.h, [], [AC_MSG_ERROR([header file <DNSServiceDiscovery/DNSServiceDiscovery.h> is required for Bonjour])])
 889 fi
 890
 891
 892 ##
 893 ## Types, structures, compiler characteristics
 894 ##
 895
 896 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
 897 AC_C_BIGENDIAN
 898 AC_C_CONST
 899 AC_C_INLINE
 900 AC_C_STRINGIZE
 901 PGAC_C_SIGNED
 902 AC_C_VOLATILE
 903 PGAC_C_FUNCNAME_SUPPORT
 904 PGAC_STRUCT_TIMEZONE
 905 PGAC_UNION_SEMUN
 906 PGAC_STRUCT_SOCKADDR_UN
 907 PGAC_STRUCT_SOCKADDR_STORAGE
 908 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
 909 PGAC_STRUCT_ADDRINFO
 910
 911 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
 912 [#include <sys/param.h>
 913 #include <sys/types.h>
 914 #include <sys/socket.h>
 915 #include <sys/ucred.h>])
 916
 917 AC_CHECK_TYPES([struct option], [], [],
 918 [#ifdef HAVE_GETOPT_H
 919 #include <getopt.h>
 920 #endif])
 921
 922 if test "$with_zlib" = yes; then
 923   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
 924   # did not).  While we could work around the lack of z_streamp, it
 925   # seems unwise to encourage people to use such old zlib versions...
 926   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
 927 Use --without-zlib to disable zlib support.])],
 928                 [#include <zlib.h>])
 929 fi
 930
 931 if test "$with_krb5" = yes; then
 932 # Check for differences between MIT and Heimdal (KTH) releases
 933   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
 934                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
 935                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
 936                                      [#include <krb5.h>])],
 937                    [#include <krb5.h>])
 938   AC_CHECK_MEMBERS(krb5_error.text.data, [],
 939                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
 940                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
 941                                      [#include <krb5.h>])],
 942                    [#include <krb5.h>])
 943 fi
 944
 945
 946 ##
 947 ## Functions, global variables
 948 ##
 949
 950 PGAC_VAR_INT_TIMEZONE
 951 AC_FUNC_ACCEPT_ARGTYPES
 952 PGAC_FUNC_GETTIMEOFDAY_1ARG
 953
 954 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid getrlimit memmove poll pstat readlink setproctitle setsid sigprocmask symlink sysconf towlower utime utimes waitpid wcstombs])
 955
 956 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 957 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
 958 AC_CHECK_DECLS([strlcat, strlcpy])
 959 # This is probably only present on Darwin, but may as well check always
 960 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
 961
 962 HAVE_IPV6=no
 963 AC_CHECK_TYPE([struct sockaddr_in6],
 964         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
 965          HAVE_IPV6=yes],
 966         [],
 967 [$ac_includes_default
 968 #include <netinet/in.h>])
 969 AC_SUBST(HAVE_IPV6)
 970
 971 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
 972 [AC_TRY_LINK(
 973 [#include <machine/vmparam.h>
 974 #include <sys/exec.h>
 975 ],
 976 [PS_STRINGS->ps_nargvstr = 1;
 977 PS_STRINGS->ps_argvstr = "foo";],
 978 [pgac_cv_var_PS_STRINGS=yes],
 979 [pgac_cv_var_PS_STRINGS=no])])
 980 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
 981   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
 982 fi
 983
 984
 985 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
 986 # is missing.  Yes, there are machines that have only one.  We may
 987 # also decide to use snprintf.c if snprintf() is present but does not
 988 # have all the features we need --- see below.
 989
 990 if test "$PORTNAME" = "win32"; then
 991   # Win32 gets snprintf.c built unconditionally.
 992   #
 993   # To properly translate all NLS languages strings, we must support the
 994   # *printf() %$ format, which allows *printf() arguments to be selected
 995   # by position in the translated string.
 996   #
 997   # libintl versions < 0.13 use the native *printf() functions, and Win32
 998   # *printf() doesn't understand %$, so we must use our /port versions,
 999   # which do understand %$. libintl versions >= 0.13 include their own
1000   # *printf versions on Win32.  The libintl 0.13 release note text is:
1001   #
1002   #   C format strings with positions, as they arise when a translator
1003   #   needs to reorder a sentence, are now supported on all platforms.
1004   #   On those few platforms (NetBSD and Woe32) for which the native
1005   #   printf()/fprintf()/... functions don't support such format
1006   #   strings, replacements are provided through <libintl.h>.
1007   #
1008   # We could use libintl >= 0.13's *printf() if we were sure that we had
1009   # a litint >= 0.13 at runtime, but seeing that there is no clean way
1010   # to guarantee that, it is best to just use our own, so we are sure to
1011   # get %$ support. In include/port.h we disable the *printf() macros
1012   # that might have been defined by libintl.
1013   #
1014   # We do this unconditionally whether NLS is used or not so we are sure
1015   # that all Win32 libraries and binaries behave the same.
1016   pgac_need_repl_snprintf=yes
1017 else
1018   pgac_need_repl_snprintf=no
1019   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
1020   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1021 fi
1022
1023
1024 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
1025 # include/c.h will provide declarations.  Note this is a separate test
1026 # from whether the functions exist in the C library --- there are
1027 # systems that have the functions but don't bother to declare them :-(
1028
1029 AC_CHECK_DECLS([snprintf, vsnprintf])
1030
1031
1032 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1033 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1034 [AC_TRY_LINK([
1035 #include <math.h>
1036 double glob_double;
1037 ],
1038 [return isinf(glob_double) ? 0 : 1;],
1039 [ac_cv_func_isinf=yes],
1040 [ac_cv_func_isinf=no])])
1041
1042 if test $ac_cv_func_isinf = yes ; then
1043   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1044 else
1045   AC_LIBOBJ(isinf)
1046   # Look for a way to implement a substitute for isinf()
1047   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1048 fi
1049
1050 # Some versions of libedit contain strlcpy(); so disregard that library while
1051 # checking for these standard libc functions.
1052 pgac_save_LIBS="$LIBS"
1053 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1054
1055 AC_REPLACE_FUNCS([crypt fseeko getopt getrusage inet_aton random rint srandom strdup strerror strlcat strlcpy strtol strtoul unsetenv])
1056
1057 LIBS="$pgac_save_LIBS"
1058
1059 # System's version of getaddrinfo(), if any, may be used only if we found
1060 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1061 # (Note: the AC_REPLACE_FUNCS probe fails on Windows, where the available
1062 # versions of getaddrinfo don't follow normal C call protocol.  This is OK
1063 # because we want to use our own getaddrinfo.c on Windows anyway.)
1064 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
1065   AC_REPLACE_FUNCS([getaddrinfo])
1066 else
1067   AC_LIBOBJ(getaddrinfo)
1068 fi
1069
1070 # similarly, use system's getopt_long() only if system provides struct option.
1071 if test x"$ac_cv_type_struct_option" = xyes ; then
1072   AC_REPLACE_FUNCS([getopt_long])
1073 else
1074   AC_LIBOBJ(getopt_long)
1075 fi
1076
1077 # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
1078 # We override the previous test that said fseeko/ftello didn't exist
1079 # OS tests are also done in include/c.h and port/fseeko.c
1080 case $host_os in bsdi*|netbsd*)
1081 ac_cv_func_fseeko=yes
1082 esac
1083
1084 # Win32 support
1085 if test "$PORTNAME" = "win32"; then
1086 AC_LIBOBJ(gettimeofday)
1087 AC_LIBOBJ(kill)
1088 AC_LIBOBJ(open)
1089 AC_LIBOBJ(rand)
1090 AC_LIBOBJ(win32error)
1091 AC_DEFINE([HAVE_SYMLINK], 1,
1092           [Define to 1 if you have the `symlink' function.])
1093 fi
1094
1095 if test "$with_readline" = yes; then
1096   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1097   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
1098   AC_CHECK_FUNCS([replace_history_entry])
1099 fi
1100
1101
1102 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
1103 dnl (especially on GNU libc)
1104 dnl See also comments in c.h.
1105 AC_MSG_CHECKING(for sigsetjmp)
1106 AC_TRY_LINK([#include <setjmp.h>],
1107             [sigjmp_buf x; sigsetjmp(x, 1);],
1108             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
1109 AC_MSG_RESULT(yes)],
1110             [AC_MSG_RESULT(no)])
1111
1112 AC_DECL_SYS_SIGLIST
1113
1114 AC_CHECK_FUNC(syslog,
1115               [AC_CHECK_HEADER(syslog.h,
1116                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1117
1118 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1119 [AC_TRY_LINK([#include <unistd.h>],
1120   [extern int optreset; optreset = 1;],
1121   [pgac_cv_var_int_optreset=yes],
1122   [pgac_cv_var_int_optreset=no])])
1123 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1124   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1125 fi
1126
1127 AC_CHECK_FUNCS([strtoll strtoq], [break])
1128 AC_CHECK_FUNCS([strtoull strtouq], [break])
1129
1130 # Check for one of atexit() or on_exit()
1131 AC_CHECK_FUNCS(atexit, [],
1132                [AC_CHECK_FUNCS(on_exit, [],
1133                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
1134
1135 AC_FUNC_FSEEKO
1136
1137 #
1138 # Pthreads
1139 #
1140 # For each platform, we need to know about any special compile and link
1141 # libraries, and whether the normal C function names are thread-safe.
1142 # See the comment at the top of src/port/thread.c for more information.
1143 # WIN32 doesn't need the pthread tests;  it always uses threads
1144 if test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"; then
1145 ACX_PTHREAD     # set thread flags
1146
1147 # Some platforms use these, so just defineed them.  They can't hurt if they
1148 # are not supported.
1149 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1150
1151
1152 # At this point, we don't want to muck with the compiler name for threading.
1153 # Let's see who fails, perhaps AIX.  2004-04-23
1154 if test "$PTHREAD_CC" != "$CC"; then
1155 AC_MSG_ERROR([
1156 PostgreSQL does not support platforms that require a special compiler
1157 for thread safety.])
1158 fi
1159
1160 if test "$THREAD_SUPPORT" = no; then
1161 AC_MSG_ERROR([cannot enable threads on this platform
1162 This platform is known to not support thread-safe programs.  For details,
1163 compile and run src/bin/pg_thread_test.])
1164 fi
1165
1166 # Check for *_r functions
1167 _CFLAGS="$CFLAGS"
1168 _LIBS="$LIBS"
1169 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1170 LIBS="$LIBS $PTHREAD_LIBS"
1171
1172 if test "$PORTNAME" != "win32"; then
1173 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([pthread.h not found, required for --enable-thread-safety])])
1174 fi
1175
1176 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1177
1178 # Do test here with the proper thread flags
1179 PGAC_FUNC_GETPWUID_R_5ARG
1180 PGAC_FUNC_STRERROR_R_INT
1181
1182 CFLAGS="$_CFLAGS"
1183 LIBS="$_LIBS"
1184
1185 else
1186 # do not use values from template file
1187 PTHREAD_CFLAGS=
1188 PTHREAD_LIBS=
1189 fi
1190
1191 AC_SUBST(PTHREAD_CFLAGS)
1192 AC_SUBST(PTHREAD_LIBS)
1193
1194
1195 # We can test for libldap_r only after we know PTHREAD_LIBS
1196 if test "$with_ldap" = yes ; then
1197   _LIBS="$LIBS"
1198   if test "$PORTNAME" != "win32"; then
1199     AC_CHECK_LIB(ldap, ldap_bind, [],
1200                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1201                  [$EXTRA_LDAP_LIBS])
1202     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1203     if test "$enable_thread_safety" = yes; then
1204       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1205       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1206                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1207                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1208       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1209     else
1210       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1211     fi
1212   else
1213     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1214     LDAP_LIBS_FE="-lwldap32"
1215     LDAP_LIBS_BE="-lwldap32"
1216   fi
1217   LIBS="$_LIBS"
1218 fi
1219 AC_SUBST(LDAP_LIBS_FE)
1220 AC_SUBST(LDAP_LIBS_BE)
1221
1222
1223 # This test makes sure that run tests work at all.  Sometimes a shared
1224 # library is found by the linker, but the runtime linker can't find it.
1225 # This check should come after all modifications of compiler or linker
1226 # variables, and before any other run tests.
1227 AC_MSG_CHECKING([test program])
1228 AC_TRY_RUN([int main() { return 0; }],
1229 [AC_MSG_RESULT(ok)],
1230 [AC_MSG_RESULT(failed)
1231 AC_MSG_ERROR([[
1232 Could not execute a simple test program.  This may be a problem
1233 related to locating shared libraries.  Check the file 'config.log'
1234 for the exact reason.]])],
1235 [AC_MSG_RESULT([cross-compiling])])
1236
1237 # --------------------
1238 # Run tests below here
1239 # --------------------
1240
1241 # Force use of our snprintf if system's doesn't do arg control
1242 # See comment above at snprintf test for details.
1243 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1244   PGAC_FUNC_PRINTF_ARG_CONTROL
1245   if test $pgac_cv_printf_arg_control != yes ; then
1246     pgac_need_repl_snprintf=yes
1247   fi
1248 fi
1249
1250
1251 dnl Check to see if we have a working 64-bit integer type.
1252 dnl This breaks down into two steps:
1253 dnl (1) figure out if the compiler has a 64-bit int type with working
1254 dnl arithmetic, and if so
1255 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1256 dnl snprintf is the only library routine we really need for int8 support.)
1257 dnl It's entirely possible to have a compiler that handles a 64-bit type
1258 dnl when the C library doesn't; this is fairly likely when using gcc on
1259 dnl an older platform, for example.
1260 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1261 dnl we force our own version of snprintf() to be used instead.
1262 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1263
1264 PGAC_TYPE_64BIT_INT([long int])
1265
1266 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1267   PGAC_TYPE_64BIT_INT([long long int])
1268 fi
1269
1270
1271 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1272
1273 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1274   AC_TRY_COMPILE([
1275 #define INT64CONST(x)  x##LL
1276 long long int foo = INT64CONST(0x1234567890123456);
1277 ],
1278         [],
1279         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1280         [])
1281 fi
1282
1283
1284 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1285 # we found we need to use "long long int", better check.  We cope with
1286 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1287 # work, fall back to our own snprintf emulation (which we know uses %lld).
1288
1289 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1290   if test $pgac_need_repl_snprintf = no; then
1291     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1292     if test "$LONG_LONG_INT_FORMAT" = ""; then
1293       # Force usage of our own snprintf, since system snprintf is broken
1294       pgac_need_repl_snprintf=yes
1295       LONG_LONG_INT_FORMAT='%lld'
1296     fi
1297   else
1298     # Here if we previously decided we needed to use our own snprintf
1299     LONG_LONG_INT_FORMAT='%lld'
1300   fi
1301   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1302   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1303   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1304 else
1305   # Here if we are not using 'long long int' at all
1306   INT64_FORMAT='"%ld"'
1307   UINT64_FORMAT='"%lu"'
1308 fi
1309
1310 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1311                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1312
1313 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1314                    [Define to the appropriate snprintf format for unsigned 64-bit ints, if any.])
1315
1316 # Now we have checked all the reasons to replace snprintf
1317 if test $pgac_need_repl_snprintf = yes; then
1318   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1319   AC_LIBOBJ(snprintf)
1320 fi
1321
1322 # Need a #define for the size of Datum (unsigned long)
1323 AC_CHECK_SIZEOF([unsigned long])
1324
1325 # And one for the size of size_t (enables tweaks for > 32bit address space)
1326 AC_CHECK_SIZEOF([size_t])
1327
1328 # Determine memory alignment requirements for the basic C data types.
1329
1330 PGAC_CHECK_ALIGNOF(short)
1331 PGAC_CHECK_ALIGNOF(int)
1332 PGAC_CHECK_ALIGNOF(long)
1333 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1334   PGAC_CHECK_ALIGNOF(long long int)
1335 fi
1336 PGAC_CHECK_ALIGNOF(double)
1337
1338 # Compute maximum alignment of any basic type.
1339 # We assume long's alignment is at least as strong as char, short, or int;
1340 # but we must check long long (if it exists) and double.
1341
1342 MAX_ALIGNOF=$pgac_cv_alignof_long
1343 if test $MAX_ALIGNOF -lt $pgac_cv_alignof_double ; then
1344   MAX_ALIGNOF=$pgac_cv_alignof_double
1345 fi
1346 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $pgac_cv_alignof_long_long_int ; then
1347   MAX_ALIGNOF="$pgac_cv_alignof_long_long_int"
1348 fi
1349 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1350
1351
1352 # Some platforms predefine the types int8, int16, etc.  Only check
1353 # a (hopefully) representative subset.
1354 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1355 [#include <stdio.h>
1356 #ifdef HAVE_SUPPORTDEFS_H
1357 #include <SupportDefs.h>
1358 #endif])
1359
1360 # We also check for sig_atomic_t, which *should* be defined per ANSI
1361 # C, but is missing on some old platforms.
1362 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1363
1364
1365 if test "$PORTNAME" != "win32"
1366 then
1367 PGAC_FUNC_POSIX_SIGNALS
1368 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1369   AC_MSG_ERROR([
1370 Thread-safety requires POSIX signals, which are not supported by this
1371 operating system.])
1372 fi
1373 fi
1374
1375 if test $ac_cv_func_fseeko = yes; then
1376 AC_SYS_LARGEFILE
1377 fi
1378
1379 # SunOS doesn't handle negative byte comparisons properly with +/- return
1380 AC_FUNC_MEMCMP
1381
1382
1383 # Select semaphore implementation type.
1384 if test "$PORTNAME" != "win32"; then
1385   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1386     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1387     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1388   else
1389     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1390       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1391       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1392     else
1393       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1394       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1395     fi
1396   fi
1397 else
1398   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1399   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1400 fi
1401
1402
1403 # Select shared-memory implementation type.
1404 if test "$PORTNAME" != "win32"; then
1405   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1406   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1407 else
1408   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
1409   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
1410 fi
1411
1412 # If not set in template file, set bytes to use libc memset()
1413 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
1414   MEMSET_LOOP_LIMIT=1024
1415 fi
1416 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
1417
1418
1419 if test "$enable_nls" = yes ; then
1420   PGAC_CHECK_GETTEXT
1421 fi
1422
1423 # Check for Tcl configuration script tclConfig.sh
1424 if test "$with_tcl" = yes; then
1425     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1426     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1427                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1428     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1429     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1430     ac_save_CPPFLAGS=$CPPFLAGS
1431     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1432     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1433     CPPFLAGS=$ac_save_CPPFLAGS
1434 fi
1435
1436 #
1437 # Check for DocBook and tools
1438 #
1439 PGAC_PROG_NSGMLS
1440 PGAC_PROG_JADE
1441 PGAC_CHECK_DOCBOOK(4.2)
1442 PGAC_PATH_DOCBOOK_STYLESHEETS
1443 PGAC_PATH_COLLATEINDEX
1444 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1445
1446 # Thread testing
1447
1448 # We have to run the thread test near the end so we have all our symbols
1449 # defined.  Cross compiling throws a warning.
1450 #
1451 if test "$enable_thread_safety_force" = yes; then
1452 if test "$PORTNAME" != "win32"
1453 then
1454   AC_MSG_WARN([
1455 *** Skipping thread test program.  --enable-thread-safety-force was used.
1456 *** Run the program in src/test/thread on the your machine and add proper
1457 *** locking function calls to your applications to guarantee thread safety.
1458 ])
1459 else
1460 AC_MSG_WARN([*** skipping thread test on Win32])
1461 fi
1462 elif test "$enable_thread_safety" = yes; then
1463 if test "$PORTNAME" != "win32"
1464 then
1465 AC_MSG_CHECKING([thread safety of required library functions])
1466
1467 _CFLAGS="$CFLAGS"
1468 _LIBS="$LIBS"
1469 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1470 LIBS="$LIBS $PTHREAD_LIBS"
1471 AC_TRY_RUN([#include "$srcdir/src/test/thread/thread_test.c"],
1472   [AC_MSG_RESULT(yes)],
1473   [AC_MSG_RESULT(no)
1474   AC_MSG_ERROR([thread test program failed
1475 This platform is not thread-safe.  Check the file 'config.log'for the
1476 exact reason.
1477
1478 You can use the configure option --enable-thread-safety-force to force
1479 threads to be enabled.  But you must then run the program in
1480 src/test/thread and add locking function calls to your applications to
1481 guarantee thread safety.])],
1482   [AC_MSG_RESULT(maybe)
1483   AC_MSG_WARN([
1484 *** Skipping thread test program because of cross-compile build.
1485 *** Run the program in src/test/thread on the target machine.
1486 ])])
1487 CFLAGS="$_CFLAGS"
1488 LIBS="$_LIBS"
1489 else
1490 AC_MSG_WARN([*** skipping thread test on Win32])
1491 fi
1492 fi
1493
1494 # prepare build tree if outside source tree
1495 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1496 # Note 2: /bin/pwd might be better than shell's built-in at getting
1497 #         a symlink-free name.
1498 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1499   vpath_build=no
1500 else
1501   vpath_build=yes
1502   if test "$no_create" != yes; then
1503     _AS_ECHO_N([preparing build tree... ])
1504     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1505     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1506       || AC_MSG_ERROR(failed)
1507     AC_MSG_RESULT(done)
1508   fi
1509 fi
1510 AC_SUBST(vpath_build)
1511
1512
1513 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1514
1515 AC_CONFIG_LINKS([
1516   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1517   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1518   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1519   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1520   src/include/pg_config_os.h:src/include/port/${template}.h
1521   src/Makefile.port:src/makefiles/Makefile.${template}
1522 ])
1523
1524 if test "$PORTNAME" = "win32"; then
1525 AC_CONFIG_COMMANDS([check_win32_symlinks],[
1526 # Links sometimes fail undetected on Mingw -
1527 # so here we detect it and warn the user
1528 for FILE in $CONFIG_LINKS
1529  do
1530         # test -e works for symlinks in the MinGW console
1531         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
1532  done
1533 ])
1534 fi
1535
1536 AC_CONFIG_HEADERS([src/include/pg_config.h],
1537 [
1538 # Update timestamp for pg_config.h (see Makefile.global)
1539 echo >src/include/stamp-h
1540 ])
1541
1542 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h])
1543
1544 AC_OUTPUT
1545
1546 # Warn about unknown options
1547 PGAC_ARG_CHECK