configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $PostgreSQL: pgsql/configure.in,v 1.587 2009/01/14 18:10:21 momjian Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [8.4devel], [pgsql-bugs@postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.61], [], [m4_fatal([Autoconf version 2.61 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2009, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version as a string])
  33 [PG_MAJORVERSION=`expr "$PACKAGE_VERSION" : '\([0-9][0-9]*\.[0-9][0-9]*\)'`]
  34 AC_SUBST(PG_MAJORVERSION)
  35 AC_DEFINE_UNQUOTED(PG_MAJORVERSION, "$PG_MAJORVERSION", [PostgreSQL major version as a string])
  36
  37 AC_CANONICAL_HOST
  38
  39 template=
  40 AC_MSG_CHECKING([which template to use])
  41
  42 PGAC_ARG_REQ(with, template, [NAME], [override operating system template],
  43 [
  44   case $withval in
  45     list)   echo; ls "$srcdir/src/template"; exit;;
  46     *)      if test -f "$srcdir/src/template/$with_template" ; then
  47               template=$withval
  48             else
  49               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  50             fi;;
  51   esac
  52 ],
  53 [
  54 # --with-template not given
  55
  56 case $host_os in
  57      aix*) template=aix ;;
  58     bsdi*) template=bsdi ;;
  59   cygwin*) template=cygwin ;;
  60   darwin*) template=darwin ;;
  61     dgux*) template=dgux ;;
  62  freebsd*) template=freebsd ;;
  63     hpux*) template=hpux ;;
  64     irix*) template=irix ;;
  65  linux*|gnu*|k*bsd*-gnu)
  66            template=linux ;;
  67    mingw*) template=win32 ;;
  68   netbsd*) template=netbsd ;;
  69 nextstep*) template=nextstep ;;
  70  openbsd*) template=openbsd ;;
  71      osf*) template=osf ;;
  72      sco*) template=sco ;;
  73  solaris*) template=solaris ;;
  74    sunos*) template=sunos4 ;;
  75  sysv4.2*)
  76         case $host_vendor in
  77           univel) template=univel ;;
  78         esac ;;
  79    sysv4*) template=svr4 ;;
  80    sysv5*) template=unixware ;;
  81   ultrix*) template=ultrix4 ;;
  82 esac
  83
  84   if test x"$template" = x"" ; then
  85     AC_MSG_ERROR([[
  86 *******************************************************************
  87 PostgreSQL has apparently not been ported to your platform yet.
  88 To try a manual configuration, look into the src/template directory
  89 for a similar platform and use the '--with-template=' option.
  90
  91 Please also contact <pgsql-bugs@postgresql.org> to see about
  92 rectifying this.  Include the above 'checking host system type...'
  93 line.
  94 *******************************************************************
  95 ]])
  96   fi
  97
  98 ])
  99
 100 AC_MSG_RESULT([$template])
 101
 102 PORTNAME=$template
 103 AC_SUBST(PORTNAME)
 104
 105 # Initialize default assumption that we do not need separate assembly code
 106 # for TAS (test-and-set).  This can be overridden by the template file
 107 # when it's executed.
 108 need_tas=no
 109 tas_file=dummy.s
 110
 111
 112
 113 ##
 114 ## Command line options
 115 ##
 116
 117 #
 118 # Add non-standard directories to the include path
 119 #
 120 PGAC_ARG_REQ(with, includes, [DIRS], [look for additional header files in DIRS])
 121
 122
 123 #
 124 # Add non-standard directories to the library search path
 125 #
 126 PGAC_ARG_REQ(with, libraries, [DIRS], [look for additional libraries in DIRS],
 127              [LIBRARY_DIRS=$withval])
 128
 129 PGAC_ARG_REQ(with, libs,      [DIRS], [alternative spelling of --with-libraries],
 130              [LIBRARY_DIRS=$withval])
 131
 132
 133 #
 134 # 64-bit integer date/time storage: enabled by default.
 135 #
 136 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 137 PGAC_ARG_BOOL(enable, integer-datetimes, yes, [disable 64-bit integer date/time support],
 138               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 139                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 140 AC_MSG_RESULT([$enable_integer_datetimes])
 141
 142
 143 #
 144 # NLS
 145 #
 146 AC_MSG_CHECKING([whether NLS is wanted])
 147 PGAC_ARG_OPTARG(enable, nls,
 148                 [LANGUAGES], [enable Native Language Support],
 149                 [],
 150                 [WANTED_LANGUAGES=$enableval],
 151                 [AC_DEFINE(ENABLE_NLS, 1,
 152                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 153 AC_MSG_RESULT([$enable_nls])
 154 AC_SUBST(enable_nls)
 155 AC_SUBST(WANTED_LANGUAGES)
 156
 157 #
 158 # Default port number (--with-pgport), default 5432
 159 #
 160 AC_MSG_CHECKING([for default port number])
 161 PGAC_ARG_REQ(with, pgport, [PORTNUM], [set default port number [5432]],
 162              [default_port=$withval],
 163              [default_port=5432])
 164 AC_MSG_RESULT([$default_port])
 165 # Need both of these because some places want an integer and some a string
 166 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 167 [Define to the default TCP port number on which the server listens and
 168 to which clients will try to connect.  This can be overridden at run-time,
 169 but it's convenient if your clients have the right default compiled in.
 170 (--with-pgport=PORTNUM)])
 171 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 172                    [Define to the default TCP port number as a string constant.])
 173 AC_SUBST(default_port)
 174
 175 #
 176 # Option to disable shared libraries
 177 #
 178 PGAC_ARG_BOOL(enable, shared, yes,
 179               [do not build shared libraries])
 180 AC_SUBST(enable_shared)
 181
 182 #
 183 # '-rpath'-like feature can be disabled
 184 #
 185 PGAC_ARG_BOOL(enable, rpath, yes,
 186               [do not embed shared library search path in executables])
 187 AC_SUBST(enable_rpath)
 188
 189 #
 190 # Spinlocks
 191 #
 192 PGAC_ARG_BOOL(enable, spinlocks, yes,
 193               [do not use spinlocks])
 194
 195 #
 196 # --enable-debug adds -g to compiler flags
 197 #
 198 PGAC_ARG_BOOL(enable, debug, no,
 199               [build with debugging symbols (-g)])
 200 AC_SUBST(enable_debug)
 201
 202 #
 203 # --enable-profiling enables gcc profiling
 204 #
 205 PGAC_ARG_BOOL(enable, profiling, no,
 206               [build with profiling enabled ])
 207 AC_SUBST(enable_profiling)
 208
 209 #
 210 # --enable-coverage enables generation of code coverage metrics with gcov
 211 #
 212 PGAC_ARG_BOOL(enable, coverage, no,
 213               [build with coverage testing instrumentation],
 214 [AC_CHECK_PROGS(GCOV, gcov)
 215 if test -z "$GCOV"; then
 216   AC_MSG_ERROR([gcov not found])
 217 fi
 218 AC_CHECK_PROGS(LCOV, lcov)
 219 if test -z "$LCOV"; then
 220   AC_MSG_ERROR([lcov not found])
 221 fi
 222 AC_CHECK_PROGS(GENHTML, genhtml)
 223 if test -z "$GENHTML"; then
 224   AC_MSG_ERROR([genhtml not found])
 225 fi])
 226 AC_SUBST(enable_coverage)
 227
 228 #
 229 # DTrace
 230 #
 231 PGAC_ARG_BOOL(enable, dtrace, no,
 232               [build with DTrace support],
 233 [AC_DEFINE([ENABLE_DTRACE], 1,
 234            [Define to 1 to enable DTrace support. (--enable-dtrace)])
 235 AC_CHECK_PROGS(DTRACE, dtrace)
 236 if test -z "$DTRACE"; then
 237   AC_MSG_ERROR([dtrace not found])
 238 fi
 239 AC_SUBST(DTRACEFLAGS)])
 240 AC_SUBST(enable_dtrace)
 241
 242 #
 243 # Block size
 244 #
 245 AC_MSG_CHECKING([for block size])
 246 PGAC_ARG_REQ(with, blocksize, [BLOCKSIZE], [set table block size in kB [8]],
 247              [blocksize=$withval],
 248              [blocksize=8])
 249 case ${blocksize} in
 250   1) BLCKSZ=1024;;
 251   2) BLCKSZ=2048;;
 252   4) BLCKSZ=4096;;
 253   8) BLCKSZ=8192;;
 254  16) BLCKSZ=16384;;
 255  32) BLCKSZ=32768;;
 256   *) AC_MSG_ERROR([Invalid block size. Allowed values are 1,2,4,8,16,32.])
 257 esac
 258 AC_MSG_RESULT([${blocksize}kB])
 259
 260 AC_DEFINE_UNQUOTED([BLCKSZ], ${BLCKSZ}, [
 261  Size of a disk block --- this also limits the size of a tuple.  You
 262  can set it bigger if you need bigger tuples (although TOAST should
 263  reduce the need to have large tuples, since fields can be spread
 264  across multiple tuples).
 265
 266  BLCKSZ must be a power of 2.  The maximum possible value of BLCKSZ
 267  is currently 2^15 (32768).  This is determined by the 15-bit widths
 268  of the lp_off and lp_len fields in ItemIdData (see
 269  include/storage/itemid.h).
 270
 271  Changing BLCKSZ requires an initdb.
 272 ])
 273
 274 #
 275 # Relation segment size
 276 #
 277 AC_MSG_CHECKING([for segment size])
 278 PGAC_ARG_REQ(with, segsize, [SEGSIZE], [set table segment size in GB [1]],
 279              [segsize=$withval],
 280              [segsize=1])
 281 # this expression is set up to avoid unnecessary integer overflow
 282 # blocksize is already guaranteed to be a factor of 1024
 283 RELSEG_SIZE=`expr '(' 1024 / ${blocksize} ')' '*' ${segsize} '*' 1024`
 284 test $? -eq 0 || exit 1
 285 AC_MSG_RESULT([${segsize}GB])
 286
 287 AC_DEFINE_UNQUOTED([RELSEG_SIZE], ${RELSEG_SIZE}, [
 288  RELSEG_SIZE is the maximum number of blocks allowed in one disk file.
 289  Thus, the maximum size of a single file is RELSEG_SIZE * BLCKSZ;
 290  relations bigger than that are divided into multiple files.
 291
 292  RELSEG_SIZE * BLCKSZ must be less than your OS' limit on file size.
 293  This is often 2 GB or 4GB in a 32-bit operating system, unless you
 294  have large file support enabled.  By default, we make the limit 1 GB
 295  to avoid any possible integer-overflow problems within the OS.
 296  A limit smaller than necessary only means we divide a large
 297  relation into more chunks than necessary, so it seems best to err
 298  in the direction of a small limit.
 299
 300  A power-of-2 value is recommended to save a few cycles in md.c,
 301  but is not absolutely required.
 302
 303  Changing RELSEG_SIZE requires an initdb.
 304 ])
 305
 306 #
 307 # WAL block size
 308 #
 309 AC_MSG_CHECKING([for WAL block size])
 310 PGAC_ARG_REQ(with, wal-blocksize, [BLOCKSIZE], [set WAL block size in kB [8]],
 311              [wal_blocksize=$withval],
 312              [wal_blocksize=8])
 313 case ${wal_blocksize} in
 314   1) XLOG_BLCKSZ=1024;;
 315   2) XLOG_BLCKSZ=2048;;
 316   4) XLOG_BLCKSZ=4096;;
 317   8) XLOG_BLCKSZ=8192;;
 318  16) XLOG_BLCKSZ=16384;;
 319  32) XLOG_BLCKSZ=32768;;
 320  64) XLOG_BLCKSZ=65536;;
 321   *) AC_MSG_ERROR([Invalid WAL block size. Allowed values are 1,2,4,8,16,32,64.])
 322 esac
 323 AC_MSG_RESULT([${wal_blocksize}kB])
 324
 325 AC_DEFINE_UNQUOTED([XLOG_BLCKSZ], ${XLOG_BLCKSZ}, [
 326  Size of a WAL file block.  This need have no particular relation to BLCKSZ.
 327  XLOG_BLCKSZ must be a power of 2, and if your system supports O_DIRECT I/O,
 328  XLOG_BLCKSZ must be a multiple of the alignment requirement for direct-I/O
 329  buffers, else direct I/O may fail.
 330
 331  Changing XLOG_BLCKSZ requires an initdb.
 332 ])
 333
 334 #
 335 # WAL segment size
 336 #
 337 AC_MSG_CHECKING([for WAL segment size])
 338 PGAC_ARG_REQ(with, wal-segsize, [SEGSIZE], [set WAL segment size in MB [16]],
 339              [wal_segsize=$withval],
 340              [wal_segsize=16])
 341 case ${wal_segsize} in
 342   1) ;;
 343   2) ;;
 344   4) ;;
 345   8) ;;
 346  16) ;;
 347  32) ;;
 348  64) ;;
 349   *) AC_MSG_ERROR([Invalid WAL segment size. Allowed values are 1,2,4,8,16,32,64.])
 350 esac
 351 AC_MSG_RESULT([${wal_segsize}MB])
 352
 353 AC_DEFINE_UNQUOTED([XLOG_SEG_SIZE], [(${wal_segsize} * 1024 * 1024)], [
 354  XLOG_SEG_SIZE is the size of a single WAL file.  This must be a power of 2
 355  and larger than XLOG_BLCKSZ (preferably, a great deal larger than
 356  XLOG_BLCKSZ).
 357
 358  Changing XLOG_SEG_SIZE requires an initdb.
 359 ])
 360
 361 #
 362 # C compiler
 363 #
 364
 365 # For historical reasons you can also use --with-CC to specify the C compiler
 366 # to use, although the standard way to do this is to set the CC environment
 367 # variable.
 368 PGAC_ARG_REQ(with, CC, [CMD], [set compiler (deprecated)], [CC=$with_CC])
 369
 370 case $template in
 371   aix) pgac_cc_list="gcc xlc";;
 372  irix) pgac_cc_list="cc";; # no gcc
 373     *) pgac_cc_list="gcc cc";;
 374 esac
 375
 376 AC_PROG_CC([$pgac_cc_list])
 377
 378 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 379 # but has idiosyncrasies of its own.  We assume icc will define
 380 # __INTEL_COMPILER regardless of CFLAGS.
 381 AC_TRY_COMPILE([], [@%:@ifndef __INTEL_COMPILER
 382 choke me
 383 @%:@endif], [ICC=[yes]], [ICC=[no]])
 384
 385 # Check if it's Sun Studio compiler. We assume that
 386 # __SUNPRO_C will be defined for Sun Studio compilers
 387 AC_TRY_COMPILE([], [@%:@ifndef __SUNPRO_C
 388 choke me
 389 @%:@endif], [SUN_STUDIO_CC=yes], [SUN_STUDIO_CC=no])
 390
 391 AC_SUBST(SUN_STUDIO_CC)
 392
 393 unset CFLAGS
 394
 395 #
 396 # Read the template
 397 #
 398 . "$srcdir/src/template/$template" || exit
 399
 400 # CFLAGS are selected so:
 401 # If the user specifies something in the environment, that is used.
 402 # else:  If the template file set something, that is used.
 403 # else:  If coverage was enabled, don't set anything.
 404 # else:  If the compiler is GCC, then we use -O2.
 405 # else:  If the compiler is something else, then we use -O.
 406
 407 if test "$ac_env_CFLAGS_set" = set; then
 408   CFLAGS=$ac_env_CFLAGS_value
 409 elif test "${CFLAGS+set}" = set; then
 410   : # (keep what template set)
 411 elif test "$enable_coverage" = yes; then
 412   : # no optimization by default
 413 elif test "$GCC" = yes; then
 414   CFLAGS="-O2"
 415 else
 416   # if the user selected debug mode, don't use -O
 417   if test "$enable_debug" != yes; then
 418     CFLAGS="-O"
 419   fi
 420 fi
 421
 422 # Some versions of GCC support some additional useful warning flags.
 423 # Check whether they are supported, and add them to CFLAGS if so.
 424 # ICC pretends to be GCC but it's lying; it doesn't support these options.
 425
 426 if test "$GCC" = yes -a "$ICC" = no; then
 427   CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wpointer-arith"
 428   # These work in some but not all gcc versions
 429   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 430   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 431   # Disable strict-aliasing rules; needed for gcc 3.3+
 432   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 433   # Disable optimizations that assume no overflow; needed for gcc 4.3+
 434   PGAC_PROG_CC_CFLAGS_OPT([-fwrapv])
 435 elif test "$ICC" = yes; then
 436   # Intel's compiler has a bug/misoptimization in checking for
 437   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 438   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 439   # Make sure strict aliasing is off (though this is said to be the default)
 440   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 441 elif test x"${CC}" = x"xlc"; then
 442   # AIX xlc has to have strict aliasing turned off too
 443   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 444 fi
 445
 446 # supply -g if --enable-debug
 447 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 448   CFLAGS="$CFLAGS -g"
 449 fi
 450
 451 # enable code coverage if --enable-coverage
 452 if test "$enable_coverage" = yes; then
 453   if test "$GCC" = yes; then
 454     CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 455   else
 456     AC_MSG_ERROR([--enable-coverage is supported only when using GCC])
 457   fi
 458 fi
 459
 460 # enable profiling if --enable-profiling
 461 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 462   if test "$GCC" = yes; then
 463     AC_DEFINE([PROFILE_PID_DIR], 1,
 464            [Define to 1 to allow profiling output to be saved separately for each process.])
 465     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 466   else
 467     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 468   fi
 469 fi
 470
 471 # We already have this in Makefile.win32, but configure needs it too
 472 if test "$PORTNAME" = "win32"; then
 473   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 474 fi
 475
 476 # Check if the compiler still works with the template settings
 477 AC_MSG_CHECKING([whether the C compiler still works])
 478 AC_TRY_LINK([], [return 0;],
 479   [AC_MSG_RESULT(yes)],
 480   [AC_MSG_RESULT(no)
 481    AC_MSG_ERROR([cannot proceed])])
 482
 483 # Defend against gcc -ffast-math
 484 if test "$GCC" = yes; then
 485 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 486 choke me
 487 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 488 fi
 489
 490 AC_PROG_CPP
 491 AC_SUBST(GCC)
 492
 493
 494 #
 495 # Set up TAS assembly code if needed; the template file has now had its
 496 # chance to request this.
 497 #
 498 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 499
 500 if test "$need_tas" = yes ; then
 501   TAS=tas.o
 502 else
 503   TAS=""
 504 fi
 505 AC_SUBST(TAS)
 506
 507
 508 #
 509 # Automatic dependency tracking
 510 #
 511 PGAC_ARG_BOOL(enable, depend, no, [turn on automatic dependency tracking],
 512               [autodepend=yes])
 513 AC_SUBST(autodepend)
 514
 515
 516 #
 517 # Enable assert checks
 518 #
 519 PGAC_ARG_BOOL(enable, cassert, no, [enable assertion checks (for debugging)],
 520               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 521                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 522
 523
 524 #
 525 # Include directories
 526 #
 527 ac_save_IFS=$IFS
 528 IFS="${IFS}${PATH_SEPARATOR}"
 529 # SRCH_INC comes from the template file
 530 for dir in $with_includes $SRCH_INC; do
 531   if test -d "$dir"; then
 532     INCLUDES="$INCLUDES -I$dir"
 533   else
 534     AC_MSG_WARN([*** Include directory $dir does not exist.])
 535   fi
 536 done
 537 IFS=$ac_save_IFS
 538 AC_SUBST(INCLUDES)
 539
 540
 541 #
 542 # Library directories
 543 #
 544 ac_save_IFS=$IFS
 545 IFS="${IFS}${PATH_SEPARATOR}"
 546 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 547 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 548   if test -d "$dir"; then
 549     LIBDIRS="$LIBDIRS -L$dir"
 550   else
 551     AC_MSG_WARN([*** Library directory $dir does not exist.])
 552   fi
 553 done
 554 IFS=$ac_save_IFS
 555
 556 #
 557 # Enable thread-safe client libraries
 558 #
 559 AC_MSG_CHECKING([allow thread-safe client libraries])
 560 if test "$PORTNAME" != "win32"; then
 561 PGAC_ARG_BOOL(enable, thread-safety, no, [make client libraries thread-safe])
 562 else
 563 # Win32 should always use threads
 564 PGAC_ARG_BOOL(enable, thread-safety, yes, [make client libraries thread-safe])
 565 fi
 566
 567 PGAC_ARG_BOOL(enable, thread-safety-force, no, [force thread-safety despite thread test failure])
 568 if test "$enable_thread_safety" = yes -o \
 569         "$enable_thread_safety_force" = yes; then
 570   enable_thread_safety="yes"    # for 'force'
 571   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 572           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 573 fi
 574 AC_MSG_RESULT([$enable_thread_safety])
 575 AC_SUBST(enable_thread_safety)
 576
 577 #
 578 # Optionally build Tcl modules (PL/Tcl)
 579 #
 580 AC_MSG_CHECKING([whether to build with Tcl])
 581 PGAC_ARG_BOOL(with, tcl, no, [build Tcl modules (PL/Tcl)])
 582 AC_MSG_RESULT([$with_tcl])
 583 AC_SUBST([with_tcl])
 584
 585 # We see if the path to the Tcl/Tk configuration scripts is specified.
 586 # This will override the use of tclsh to find the paths to search.
 587
 588 PGAC_ARG_REQ(with, tclconfig, [DIR], [tclConfig.sh is in DIR])
 589
 590 #
 591 # Optionally build Perl modules (PL/Perl)
 592 #
 593 AC_MSG_CHECKING([whether to build Perl modules])
 594 PGAC_ARG_BOOL(with, perl, no, [build Perl modules (PL/Perl)])
 595 AC_MSG_RESULT([$with_perl])
 596 AC_SUBST(with_perl)
 597
 598 #
 599 # Optionally build Python modules (PL/Python)
 600 #
 601 AC_MSG_CHECKING([whether to build Python modules])
 602 PGAC_ARG_BOOL(with, python, no, [build Python modules (PL/Python)])
 603 AC_MSG_RESULT([$with_python])
 604 AC_SUBST(with_python)
 605
 606 #
 607 # GSSAPI
 608 #
 609 AC_MSG_CHECKING([whether to build with GSSAPI support])
 610 PGAC_ARG_BOOL(with, gssapi, no, [build with GSSAPI support],
 611 [
 612   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 613   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 614 ])
 615 AC_MSG_RESULT([$with_gssapi])
 616 AC_SUBST(with_gssapi)
 617
 618 #
 619 # Kerberos 5
 620 #
 621 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 622 PGAC_ARG_BOOL(with, krb5, no, [build with Kerberos 5 support],
 623 [
 624   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 625   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 626 ])
 627 AC_MSG_RESULT([$with_krb5])
 628 AC_SUBST(with_krb5)
 629
 630
 631 AC_SUBST(krb_srvtab)
 632
 633
 634 #
 635 # Kerberos configuration parameters
 636 #
 637 PGAC_ARG_REQ(with, krb-srvnam,
 638              [NAME], [default service principal name in Kerberos [postgres]],
 639              [],
 640              [with_krb_srvnam="postgres"])
 641 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 642                    [Define to the name of the default PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 643
 644
 645 #
 646 # PAM
 647 #
 648 AC_MSG_CHECKING([whether to build with PAM support])
 649 PGAC_ARG_BOOL(with, pam, no,
 650               [build with PAM support],
 651               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 652 AC_MSG_RESULT([$with_pam])
 653 AC_SUBST(with_pam)
 654
 655
 656 #
 657 # LDAP
 658 #
 659 AC_MSG_CHECKING([whether to build with LDAP support])
 660 PGAC_ARG_BOOL(with, ldap, no,
 661               [build with LDAP support],
 662               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 663 AC_MSG_RESULT([$with_ldap])
 664 AC_SUBST(with_ldap)
 665
 666
 667 #
 668 # Bonjour
 669 #
 670 AC_MSG_CHECKING([whether to build with Bonjour support])
 671 PGAC_ARG_BOOL(with, bonjour, no,
 672               [build with Bonjour support],
 673               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 674 AC_MSG_RESULT([$with_bonjour])
 675 AC_SUBST(with_bonjour)
 676
 677
 678 #
 679 # OpenSSL
 680 #
 681 AC_MSG_CHECKING([whether to build with OpenSSL support])
 682 PGAC_ARG_BOOL(with, openssl, no, [build with OpenSSL support],
 683               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 684 AC_MSG_RESULT([$with_openssl])
 685 AC_SUBST(with_openssl)
 686
 687
 688 #
 689 # Readline
 690 #
 691 PGAC_ARG_BOOL(with, readline, yes,
 692               [do not use GNU Readline nor BSD Libedit for editing])
 693 # readline on MinGW has problems with backslashes in psql and other bugs.
 694 # This is particularly a problem with non-US code pages.
 695 # Therefore disable its use until we understand the cause. 2004-07-20
 696 if test "$PORTNAME" = "win32"; then
 697   if test "$with_readline" = yes; then
 698     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 699     with_readline=no
 700   fi
 701 fi
 702
 703
 704 #
 705 # Prefer libedit
 706 #
 707 PGAC_ARG_BOOL(with, libedit-preferred, no,
 708               [prefer BSD Libedit over GNU Readline])
 709
 710
 711 #
 712 # OSSP UUID library
 713 #
 714 PGAC_ARG_BOOL(with, ossp-uuid, no, [use OSSP UUID library when building contrib/uuid-ossp])
 715 AC_SUBST(with_ossp_uuid)
 716
 717
 718 #
 719 # XML
 720 #
 721 PGAC_ARG_BOOL(with, libxml, no, [build with XML support],
 722               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 723
 724 if test "$with_libxml" = yes ; then
 725   AC_CHECK_PROGS(XML2_CONFIG, xml2-config)
 726   if test -n "$XML2_CONFIG"; then
 727     for pgac_option in `$XML2_CONFIG --cflags`; do
 728       case $pgac_option in
 729         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 730       esac
 731     done
 732     for pgac_option in `$XML2_CONFIG --libs`; do
 733       case $pgac_option in
 734         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 735       esac
 736     done
 737   fi
 738 fi
 739
 740 AC_SUBST(with_libxml)
 741
 742 #
 743 # XSLT
 744 #
 745 PGAC_ARG_BOOL(with, libxslt, no, [use XSLT support when building contrib/xml2],
 746               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 747
 748
 749 AC_SUBST(with_libxslt)
 750
 751 #
 752 # tzdata
 753 #
 754 PGAC_ARG_REQ(with, system-tzdata,
 755              [DIR], [use system time zone data in DIR])
 756 AC_SUBST(with_system_tzdata)
 757
 758 #
 759 # Zlib
 760 #
 761 PGAC_ARG_BOOL(with, zlib, yes,
 762               [do not use Zlib])
 763 AC_SUBST(with_zlib)
 764
 765 #
 766 # Elf
 767 #
 768
 769 # Assume system is ELF if it predefines __ELF__ as 1,
 770 # otherwise believe host_os based default.
 771 case $host_os in
 772     freebsd1*|freebsd2*) elf=no;;
 773     freebsd3*|freebsd4*) elf=yes;;
 774 esac
 775
 776 AC_EGREP_CPP(yes,
 777 [#if __ELF__
 778   yes
 779 #endif
 780 ],
 781 [ELF_SYS=true],
 782 [if test "X$elf" = "Xyes" ; then
 783   ELF_SYS=true
 784 else
 785   ELF_SYS=
 786 fi])
 787 AC_SUBST(ELF_SYS)
 788
 789 #
 790 # Assignments
 791 #
 792
 793 CPPFLAGS="$CPPFLAGS $INCLUDES"
 794 LDFLAGS="$LDFLAGS $LIBDIRS"
 795
 796 AC_ARG_VAR(LDFLAGS_SL)
 797
 798 PGAC_PROG_LD
 799 AC_SUBST(LD)
 800 AC_SUBST(with_gnu_ld)
 801 case $host_os in sysv5*)
 802   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 803   [
 804     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 805     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 806     LDFLAGS=$pgac_save_LDFLAGS
 807   ])
 808   ld_R_works=$pgac_cv_prog_ld_R
 809   AC_SUBST(ld_R_works)
 810 esac
 811 AC_PROG_RANLIB
 812 PGAC_CHECK_STRIP
 813 AC_CHECK_TOOL(AR, ar, ar)
 814 if test "$PORTNAME" = "win32"; then
 815   AC_CHECK_TOOL(DLLTOOL, dlltool, dlltool)
 816   AC_CHECK_TOOL(DLLWRAP, dllwrap, dllwrap)
 817   AC_CHECK_TOOL(WINDRES, windres, windres)
 818 fi
 819
 820 AC_PATH_PROG(TAR, tar)
 821 AC_PROG_LN_S
 822 AC_PROG_AWK
 823
 824 PGAC_PATH_BISON
 825 PGAC_PATH_FLEX
 826
 827 PGAC_PATH_PERL
 828 if test "$with_perl" = yes; then
 829   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 830   PGAC_CHECK_PERL_EMBED_LDFLAGS
 831 fi
 832
 833 if test "$with_python" = yes; then
 834   PGAC_PATH_PYTHON
 835   PGAC_CHECK_PYTHON_EMBED_SETUP
 836 fi
 837
 838 if test "$cross_compiling" = yes && test -z "$with_system_tzdata"; then
 839   AC_PATH_PROG(ZIC, zic)
 840   if test -z "$ZIC"; then
 841     AC_MSG_ERROR([
 842 When cross-compiling, either use the option --with-system-tzdata to use
 843 existing time-zone data, or set the environment variable ZIC to a zic
 844 program to use during the build.])
 845   fi
 846 fi
 847
 848
 849 ##
 850 ## Libraries
 851 ##
 852 ## Most libraries are included only if they demonstrably provide a function
 853 ## we need, but libm is an exception: always include it, because there are
 854 ## too many compilers that play cute optimization games that will break
 855 ## probes for standard functions such as pow().
 856 ##
 857
 858 AC_CHECK_LIB(m, main)
 859 AC_SEARCH_LIBS(setproctitle, util)
 860 AC_SEARCH_LIBS(dlopen, dl)
 861 AC_SEARCH_LIBS(socket, [socket wsock32])
 862 AC_SEARCH_LIBS(shl_load, dld)
 863 # We only use libld in port/dynloader/aix.c
 864 case $host_os in
 865      aix*)
 866         AC_SEARCH_LIBS(ldopen, ld)
 867         ;;
 868 esac
 869 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 870 AC_SEARCH_LIBS(crypt, crypt)
 871 # Solaris:
 872 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 873 # Required for thread_test.c on Solaris 2.5:
 874 # Other ports use it too (HP-UX) so test unconditionally
 875 AC_SEARCH_LIBS(gethostbyname_r, nsl)
 876 # Cygwin:
 877 AC_SEARCH_LIBS(shmget, cygipc)
 878
 879 if test "$with_readline" = yes; then
 880   PGAC_CHECK_READLINE
 881   if test x"$pgac_cv_check_readline" = x"no"; then
 882     AC_MSG_ERROR([readline library not found
 883 If you have readline already installed, see config.log for details on the
 884 failure.  It is possible the compiler isn't looking in the proper directory.
 885 Use --without-readline to disable readline support.])
 886   fi
 887 fi
 888
 889 if test "$with_zlib" = yes; then
 890   AC_CHECK_LIB(z, inflate, [],
 891                [AC_MSG_ERROR([zlib library not found
 892 If you have zlib already installed, see config.log for details on the
 893 failure.  It is possible the compiler isn't looking in the proper directory.
 894 Use --without-zlib to disable zlib support.])])
 895 fi
 896
 897 if test "$enable_spinlocks" = yes; then
 898   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 899 else
 900   AC_MSG_WARN([
 901 *** Not using spinlocks will cause poor performance.])
 902 fi
 903
 904 if test "$with_gssapi" = yes ; then
 905   if test "$PORTNAME" != "win32"; then
 906     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
 907                                   [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
 908   else
 909     LIBS="$LIBS -lgssapi32"
 910   fi
 911 fi
 912
 913 if test "$with_krb5" = yes ; then
 914   if test "$PORTNAME" != "win32"; then
 915      AC_SEARCH_LIBS(com_err, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken' com_err], [],
 916                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 917      AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken'], [],
 918                     [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 919   else
 920      AC_SEARCH_LIBS(com_err, 'comerr32 -lkrb5_32', [],
 921                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 922   fi
 923 fi
 924
 925 if test "$with_openssl" = yes ; then
 926   dnl Order matters!
 927   if test "$PORTNAME" != "win32"; then
 928      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 929      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 930   else
 931      AC_CHECK_LIB(eay32, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'eay32' is required for OpenSSL])])
 932      AC_CHECK_LIB(ssleay32,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssleay32' is required for OpenSSL])])
 933   fi
 934 fi
 935
 936 if test "$with_pam" = yes ; then
 937   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 938 fi
 939
 940 if test "$with_libxml" = yes ; then
 941   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
 942 fi
 943
 944 if test "$with_libxslt" = yes ; then
 945   AC_CHECK_LIB(xslt, xsltCleanupGlobals, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
 946 fi
 947
 948 # for contrib/uuid-ossp
 949 if test "$with_ossp_uuid" = yes ; then
 950   AC_CHECK_LIB(ossp-uuid, uuid_export,
 951     [OSSP_UUID_LIBS="-lossp-uuid"],
 952     [AC_CHECK_LIB(uuid, uuid_export,
 953       [OSSP_UUID_LIBS="-luuid"],
 954       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP-UUID])])])
 955 fi
 956 AC_SUBST(OSSP_UUID_LIBS)
 957
 958
 959 ##
 960 ## Header files
 961 ##
 962
 963 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 964 AC_CHECK_HEADERS([crypt.h dld.h fp_class.h getopt.h ieeefp.h langinfo.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/tas.h sys/time.h sys/un.h termios.h ucred.h utime.h wchar.h wctype.h kernel/OS.h kernel/image.h SupportDefs.h])
 965
 966 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 967 # netinet/in.h is included first.
 968 AC_CHECK_HEADERS(netinet/in.h)
 969 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 970 [AC_INCLUDES_DEFAULT
 971 #ifdef HAVE_NETINET_IN_H
 972 #include <netinet/in.h>
 973 #endif
 974 ])
 975
 976 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
 977   AC_CHECK_HEADERS(readline/readline.h, [],
 978         [AC_CHECK_HEADERS(readline.h, [],
 979                 [AC_MSG_ERROR([readline header not found
 980 If you have readline already installed, see config.log for details on the
 981 failure.  It is possible the compiler isn't looking in the proper directory.
 982 Use --without-readline to disable readline support.])])])
 983   AC_CHECK_HEADERS(readline/history.h, [],
 984         [AC_CHECK_HEADERS(history.h, [],
 985                 [AC_MSG_ERROR([history header not found
 986 If you have readline already installed, see config.log for details on the
 987 failure.  It is possible the compiler isn't looking in the proper directory.
 988 Use --without-readline to disable readline support.])])])
 989 fi
 990
 991 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
 992 # Some installations of libedit usurp /usr/include/readline/, which seems
 993 # bad practice, since in combined installations readline will have its headers
 994 # there.  We might have to resort to AC_EGREP checks to make sure we found
 995 # the proper header...
 996   AC_CHECK_HEADERS(editline/readline.h, [],
 997         [AC_CHECK_HEADERS(readline.h, [],
 998                 [AC_CHECK_HEADERS(readline/readline.h, [],
 999                         [AC_MSG_ERROR([readline header not found
1000 If you have libedit already installed, see config.log for details on the
1001 failure.  It is possible the compiler isn't looking in the proper directory.
1002 Use --without-readline to disable libedit support.])])])])
1003 # Note: in a libedit installation, history.h is sometimes a dummy, and may
1004 # not be there at all.  Hence, don't complain if not found.  We must check
1005 # though, since in yet other versions it is an independent header.
1006   AC_CHECK_HEADERS(editline/history.h, [],
1007         [AC_CHECK_HEADERS(history.h, [],
1008                 [AC_CHECK_HEADERS(readline/history.h)])])
1009 fi
1010
1011 if test "$with_zlib" = yes; then
1012   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
1013 If you have zlib already installed, see config.log for details on the
1014 failure.  It is possible the compiler isn't looking in the proper directory.
1015 Use --without-zlib to disable zlib support.])])
1016 fi
1017
1018 if test "$with_gssapi" = yes ; then
1019   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
1020         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
1021 fi
1022
1023 if test "$with_krb5" = yes ; then
1024   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
1025 fi
1026
1027 if test "$with_openssl" = yes ; then
1028   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
1029   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
1030   AC_CHECK_FUNCS([ERR_set_mark])
1031 fi
1032
1033 if test "$with_pam" = yes ; then
1034   AC_CHECK_HEADERS(security/pam_appl.h, [],
1035                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
1036                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
1037 fi
1038
1039 if test "$with_libxml" = yes ; then
1040   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
1041 fi
1042
1043 if test "$with_libxslt" = yes ; then
1044   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
1045 fi
1046
1047 if test "$with_ldap" = yes ; then
1048   if test "$PORTNAME" != "win32"; then
1049      AC_CHECK_HEADERS(ldap.h, [],
1050                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
1051   else
1052      AC_CHECK_HEADERS(winldap.h, [],
1053                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
1054                       [AC_INCLUDES_DEFAULT
1055 #include <windows.h>
1056                       ])
1057   fi
1058 fi
1059
1060 if test "$with_bonjour" = yes ; then
1061   AC_CHECK_HEADER(DNSServiceDiscovery/DNSServiceDiscovery.h, [], [AC_MSG_ERROR([header file <DNSServiceDiscovery/DNSServiceDiscovery.h> is required for Bonjour])])
1062 fi
1063
1064 # for contrib/uuid-ossp
1065 if test "$with_ossp_uuid" = yes ; then
1066   AC_CHECK_HEADERS(ossp/uuid.h, [], [
1067     AC_CHECK_HEADERS(uuid.h, [],
1068       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP-UUID])])])
1069 fi
1070
1071
1072 ##
1073 ## Types, structures, compiler characteristics
1074 ##
1075
1076 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
1077 AC_C_BIGENDIAN
1078 AC_C_CONST
1079 AC_C_INLINE
1080 AC_C_STRINGIZE
1081 PGAC_C_SIGNED
1082 AC_C_VOLATILE
1083 PGAC_C_FUNCNAME_SUPPORT
1084 PGAC_STRUCT_TIMEZONE
1085 PGAC_UNION_SEMUN
1086 PGAC_STRUCT_SOCKADDR_UN
1087 PGAC_STRUCT_SOCKADDR_STORAGE
1088 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
1089 PGAC_STRUCT_ADDRINFO
1090
1091 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
1092 [#include <sys/param.h>
1093 #include <sys/types.h>
1094 #include <sys/socket.h>
1095 #include <sys/ucred.h>])
1096
1097 AC_CHECK_TYPES([struct option], [], [],
1098 [#ifdef HAVE_GETOPT_H
1099 #include <getopt.h>
1100 #endif])
1101
1102 if test "$with_zlib" = yes; then
1103   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
1104   # did not).  While we could work around the lack of z_streamp, it
1105   # seems unwise to encourage people to use such old zlib versions...
1106   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
1107 Use --without-zlib to disable zlib support.])],
1108                 [#include <zlib.h>])
1109 fi
1110
1111 if test "$with_krb5" = yes; then
1112 # Check for differences between MIT and Heimdal (KTH) releases
1113   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
1114                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
1115                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
1116                                      [#include <krb5.h>])],
1117                    [#include <krb5.h>])
1118   AC_CHECK_MEMBERS(krb5_error.text.data, [],
1119                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
1120                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
1121                                      [#include <krb5.h>])],
1122                    [#include <krb5.h>])
1123
1124 # Win32 requires headers to be loaded for __stdcall, so can't use
1125 # AC_CHECK_FUNCS here.
1126   AC_MSG_CHECKING(for krb5_free_unparsed_name)
1127   AC_TRY_LINK([#include <krb5.h>],
1128               [krb5_free_unparsed_name(NULL,NULL);],
1129               [AC_DEFINE(HAVE_KRB5_FREE_UNPARSED_NAME, 1, [Define to 1 if you have krb5_free_unparsed_name])
1130 AC_MSG_RESULT(yes)],
1131               [AC_MSG_RESULT(no)])
1132 fi
1133
1134
1135 ##
1136 ## Functions, global variables
1137 ##
1138
1139 PGAC_VAR_INT_TIMEZONE
1140 AC_FUNC_ACCEPT_ARGTYPES
1141 PGAC_FUNC_GETTIMEOFDAY_1ARG
1142
1143 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid getpeerucred getrlimit memmove poll posix_fadvise pstat readlink setproctitle setsid sigprocmask symlink sysconf towlower utime utimes waitpid wcstombs])
1144
1145 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
1146 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
1147 AC_CHECK_DECLS([strlcat, strlcpy])
1148 # This is probably only present on Darwin, but may as well check always
1149 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
1150
1151 HAVE_IPV6=no
1152 AC_CHECK_TYPE([struct sockaddr_in6],
1153         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
1154          HAVE_IPV6=yes],
1155         [],
1156 [$ac_includes_default
1157 #include <netinet/in.h>])
1158 AC_SUBST(HAVE_IPV6)
1159
1160 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1161 [AC_TRY_LINK(
1162 [#include <machine/vmparam.h>
1163 #include <sys/exec.h>
1164 ],
1165 [PS_STRINGS->ps_nargvstr = 1;
1166 PS_STRINGS->ps_argvstr = "foo";],
1167 [pgac_cv_var_PS_STRINGS=yes],
1168 [pgac_cv_var_PS_STRINGS=no])])
1169 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1170   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
1171 fi
1172
1173
1174 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
1175 # is missing.  Yes, there are machines that have only one.  We may
1176 # also decide to use snprintf.c if snprintf() is present but does not
1177 # have all the features we need --- see below.
1178
1179 if test "$PORTNAME" = "win32"; then
1180   # Win32 gets snprintf.c built unconditionally.
1181   #
1182   # To properly translate all NLS languages strings, we must support the
1183   # *printf() %$ format, which allows *printf() arguments to be selected
1184   # by position in the translated string.
1185   #
1186   # libintl versions < 0.13 use the native *printf() functions, and Win32
1187   # *printf() doesn't understand %$, so we must use our /port versions,
1188   # which do understand %$. libintl versions >= 0.13 include their own
1189   # *printf versions on Win32.  The libintl 0.13 release note text is:
1190   #
1191   #   C format strings with positions, as they arise when a translator
1192   #   needs to reorder a sentence, are now supported on all platforms.
1193   #   On those few platforms (NetBSD and Woe32) for which the native
1194   #   printf()/fprintf()/... functions don't support such format
1195   #   strings, replacements are provided through <libintl.h>.
1196   #
1197   # We could use libintl >= 0.13's *printf() if we were sure that we had
1198   # a litint >= 0.13 at runtime, but seeing that there is no clean way
1199   # to guarantee that, it is best to just use our own, so we are sure to
1200   # get %$ support. In include/port.h we disable the *printf() macros
1201   # that might have been defined by libintl.
1202   #
1203   # We do this unconditionally whether NLS is used or not so we are sure
1204   # that all Win32 libraries and binaries behave the same.
1205   pgac_need_repl_snprintf=yes
1206 else
1207   pgac_need_repl_snprintf=no
1208   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
1209   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1210 fi
1211
1212
1213 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
1214 # include/c.h will provide declarations.  Note this is a separate test
1215 # from whether the functions exist in the C library --- there are
1216 # systems that have the functions but don't bother to declare them :-(
1217
1218 AC_CHECK_DECLS([snprintf, vsnprintf])
1219
1220
1221 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1222 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1223 [AC_TRY_LINK([
1224 #include <math.h>
1225 double glob_double;
1226 ],
1227 [return isinf(glob_double) ? 0 : 1;],
1228 [ac_cv_func_isinf=yes],
1229 [ac_cv_func_isinf=no])])
1230
1231 if test $ac_cv_func_isinf = yes ; then
1232   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1233 else
1234   AC_LIBOBJ(isinf)
1235   # Look for a way to implement a substitute for isinf()
1236   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1237 fi
1238
1239 # Some versions of libedit contain strlcpy(); so disregard that library while
1240 # checking for these standard libc functions.
1241 pgac_save_LIBS="$LIBS"
1242 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1243
1244 AC_REPLACE_FUNCS([crypt getopt getrusage inet_aton random rint srandom strdup strerror strlcat strlcpy strtol strtoul unsetenv])
1245
1246 LIBS="$pgac_save_LIBS"
1247
1248 # System's version of getaddrinfo(), if any, may be used only if we found
1249 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1250 # (Note: the AC_REPLACE_FUNCS probe fails on Windows, where the available
1251 # versions of getaddrinfo don't follow normal C call protocol.  This is OK
1252 # because we want to use our own getaddrinfo.c on Windows anyway.)
1253 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
1254   AC_REPLACE_FUNCS([getaddrinfo])
1255 else
1256   AC_LIBOBJ(getaddrinfo)
1257 fi
1258
1259 # Similarly, use system's getopt_long() only if system provides struct option.
1260 # Solaris' getopt() doesn't do what we want for long options, so always use
1261 # our versions on that platform.
1262 if test "$PORTNAME" = "solaris"; then
1263   AC_LIBOBJ(getopt)
1264   AC_LIBOBJ(getopt_long)
1265 elif test x"$ac_cv_type_struct_option" = xyes ; then
1266   AC_REPLACE_FUNCS([getopt_long])
1267 else
1268   AC_LIBOBJ(getopt_long)
1269 fi
1270
1271 # Win32 support
1272 if test "$PORTNAME" = "win32"; then
1273 AC_REPLACE_FUNCS(gettimeofday)
1274 AC_LIBOBJ(kill)
1275 AC_LIBOBJ(open)
1276 AC_LIBOBJ(rand)
1277 AC_LIBOBJ(win32error)
1278 AC_DEFINE([HAVE_SYMLINK], 1,
1279           [Define to 1 if you have the `symlink' function.])
1280 fi
1281
1282 if test "$with_readline" = yes; then
1283   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1284   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
1285   AC_CHECK_FUNCS([replace_history_entry])
1286 fi
1287
1288
1289 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
1290 dnl (especially on GNU libc)
1291 dnl See also comments in c.h.
1292 AC_MSG_CHECKING(for sigsetjmp)
1293 AC_TRY_LINK([#include <setjmp.h>],
1294             [sigjmp_buf x; sigsetjmp(x, 1);],
1295             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
1296 AC_MSG_RESULT(yes)],
1297             [AC_MSG_RESULT(no)])
1298
1299 AC_DECL_SYS_SIGLIST
1300
1301 AC_CHECK_FUNC(syslog,
1302               [AC_CHECK_HEADER(syslog.h,
1303                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1304
1305 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1306 [AC_TRY_LINK([#include <unistd.h>],
1307   [extern int optreset; optreset = 1;],
1308   [pgac_cv_var_int_optreset=yes],
1309   [pgac_cv_var_int_optreset=no])])
1310 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1311   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1312 fi
1313
1314 AC_CHECK_FUNCS([strtoll strtoq], [break])
1315 AC_CHECK_FUNCS([strtoull strtouq], [break])
1316
1317 # Check for one of atexit() or on_exit()
1318 AC_CHECK_FUNCS(atexit, [],
1319                [AC_CHECK_FUNCS(on_exit, [],
1320                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
1321
1322 AC_REPLACE_FUNCS(fseeko)
1323 case $host_os in
1324         # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
1325         # Mingw uses macros to access Win32 API calls
1326         bsdi*|netbsd*|mingw*)
1327                 AC_DEFINE(HAVE_FSEEKO, 1, [Define to 1 because replacement version used.])
1328                 ac_cv_func_fseeko=yes;;
1329         *)
1330                 AC_FUNC_FSEEKO;;
1331 esac
1332
1333
1334 #
1335 # Pthreads
1336 #
1337 # For each platform, we need to know about any special compile and link
1338 # libraries, and whether the normal C function names are thread-safe.
1339 # See the comment at the top of src/port/thread.c for more information.
1340 # WIN32 doesn't need the pthread tests;  it always uses threads
1341 if test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"; then
1342 ACX_PTHREAD     # set thread flags
1343
1344 # Some platforms use these, so just define them.  They can't hurt if they
1345 # are not supported.  For example, on Solaris -D_POSIX_PTHREAD_SEMANTICS
1346 # enables 5-arg getpwuid_r, among other things.
1347 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1348
1349
1350 # At this point, we don't want to muck with the compiler name for threading.
1351 # Let's see who fails, perhaps AIX.  2004-04-23
1352 if test "$PTHREAD_CC" != "$CC"; then
1353 AC_MSG_ERROR([
1354 PostgreSQL does not support platforms that require a special compiler
1355 for thread safety.])
1356 fi
1357
1358 if test "$THREAD_SUPPORT" = no; then
1359 AC_MSG_ERROR([cannot enable threads on this platform
1360 This platform is known to not support thread-safe programs.  For details,
1361 compile and run src/bin/pg_thread_test.])
1362 fi
1363
1364 # Check for *_r functions
1365 _CFLAGS="$CFLAGS"
1366 _LIBS="$LIBS"
1367 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1368 LIBS="$LIBS $PTHREAD_LIBS"
1369
1370 if test "$PORTNAME" != "win32"; then
1371 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([pthread.h not found, required for --enable-thread-safety])])
1372 fi
1373
1374 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1375
1376 # Do test here with the proper thread flags
1377 PGAC_FUNC_GETPWUID_R_5ARG
1378 PGAC_FUNC_STRERROR_R_INT
1379
1380 CFLAGS="$_CFLAGS"
1381 LIBS="$_LIBS"
1382
1383 else
1384 # do not use values from template file
1385 PTHREAD_CFLAGS=
1386 PTHREAD_LIBS=
1387 fi
1388
1389 AC_SUBST(PTHREAD_CFLAGS)
1390 AC_SUBST(PTHREAD_LIBS)
1391
1392
1393 # We can test for libldap_r only after we know PTHREAD_LIBS
1394 if test "$with_ldap" = yes ; then
1395   _LIBS="$LIBS"
1396   if test "$PORTNAME" != "win32"; then
1397     AC_CHECK_LIB(ldap, ldap_bind, [],
1398                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1399                  [$EXTRA_LDAP_LIBS])
1400     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1401     if test "$enable_thread_safety" = yes; then
1402       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1403       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1404                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1405                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1406       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1407     else
1408       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1409     fi
1410   else
1411     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1412     LDAP_LIBS_FE="-lwldap32"
1413     LDAP_LIBS_BE="-lwldap32"
1414   fi
1415   LIBS="$_LIBS"
1416 fi
1417 AC_SUBST(LDAP_LIBS_FE)
1418 AC_SUBST(LDAP_LIBS_BE)
1419
1420
1421 # This test makes sure that run tests work at all.  Sometimes a shared
1422 # library is found by the linker, but the runtime linker can't find it.
1423 # This check should come after all modifications of compiler or linker
1424 # variables, and before any other run tests.
1425 AC_MSG_CHECKING([test program])
1426 AC_TRY_RUN([int main() { return 0; }],
1427 [AC_MSG_RESULT(ok)],
1428 [AC_MSG_RESULT(failed)
1429 AC_MSG_ERROR([[
1430 Could not execute a simple test program.  This may be a problem
1431 related to locating shared libraries.  Check the file 'config.log'
1432 for the exact reason.]])],
1433 [AC_MSG_RESULT([cross-compiling])])
1434
1435 # --------------------
1436 # Run tests below here
1437 # --------------------
1438
1439 # Force use of our snprintf if system's doesn't do arg control
1440 # See comment above at snprintf test for details.
1441 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1442   PGAC_FUNC_PRINTF_ARG_CONTROL
1443   if test $pgac_cv_printf_arg_control != yes ; then
1444     pgac_need_repl_snprintf=yes
1445   fi
1446 fi
1447
1448
1449 dnl Check to see if we have a working 64-bit integer type.
1450 dnl This breaks down into two steps:
1451 dnl (1) figure out if the compiler has a 64-bit int type with working
1452 dnl arithmetic, and if so
1453 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1454 dnl snprintf is the only library routine we really need for int8 support.)
1455 dnl It's entirely possible to have a compiler that handles a 64-bit type
1456 dnl when the C library doesn't; this is fairly likely when using gcc on
1457 dnl an older platform, for example.
1458 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1459 dnl we force our own version of snprintf() to be used instead.
1460 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1461
1462 PGAC_TYPE_64BIT_INT([long int])
1463
1464 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1465   PGAC_TYPE_64BIT_INT([long long int])
1466 fi
1467
1468
1469 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1470
1471 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1472   AC_TRY_COMPILE([
1473 #define INT64CONST(x)  x##LL
1474 long long int foo = INT64CONST(0x1234567890123456);
1475 ],
1476         [],
1477         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1478         [])
1479 fi
1480
1481
1482 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1483 # we found we need to use "long long int", better check.  We cope with
1484 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1485 # work, fall back to our own snprintf emulation (which we know uses %lld).
1486
1487 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1488   if test $pgac_need_repl_snprintf = no; then
1489     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1490     if test "$LONG_LONG_INT_FORMAT" = ""; then
1491       # Force usage of our own snprintf, since system snprintf is broken
1492       pgac_need_repl_snprintf=yes
1493       LONG_LONG_INT_FORMAT='%lld'
1494     fi
1495   else
1496     # Here if we previously decided we needed to use our own snprintf
1497     LONG_LONG_INT_FORMAT='%lld'
1498   fi
1499   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1500   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1501   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1502 else
1503   # Here if we are not using 'long long int' at all
1504   INT64_FORMAT='"%ld"'
1505   UINT64_FORMAT='"%lu"'
1506 fi
1507
1508 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1509                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1510
1511 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1512                    [Define to the appropriate snprintf format for unsigned 64-bit ints, if any.])
1513
1514 # Now we have checked all the reasons to replace snprintf
1515 if test $pgac_need_repl_snprintf = yes; then
1516   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1517   AC_LIBOBJ(snprintf)
1518 fi
1519
1520 # Need a #define for the size of Datum (unsigned long)
1521 AC_CHECK_SIZEOF([unsigned long])
1522
1523 # And check size of void *, size_t (enables tweaks for > 32bit address space)
1524 AC_CHECK_SIZEOF([void *])
1525 AC_CHECK_SIZEOF([size_t])
1526
1527 # Decide whether float4 is passed by value: user-selectable, enabled by default
1528 AC_MSG_CHECKING([whether to build with float4 passed by value])
1529 PGAC_ARG_BOOL(enable, float4-byval, yes, [disable float4 passed by value],
1530               [AC_DEFINE([USE_FLOAT4_BYVAL], 1,
1531                          [Define to 1 if you want float4 values to be passed by value. (--enable-float4-byval)])
1532                float4passbyval=true],
1533               [float4passbyval=false])
1534 AC_MSG_RESULT([$enable_float4_byval])
1535 AC_DEFINE_UNQUOTED([FLOAT4PASSBYVAL], [$float4passbyval], [float4 values are passed by value if 'true', by reference if 'false'])
1536
1537 # Decide whether float8 is passed by value.
1538 # Note: this setting also controls int8 and related types such as timestamp.
1539 # If sizeof(Datum) >= 8, this is user-selectable, enabled by default.
1540 # If not, trying to select it is an error.
1541 AC_MSG_CHECKING([whether to build with float8 passed by value])
1542 if test $ac_cv_sizeof_unsigned_long -ge 8 ; then
1543   PGAC_ARG_BOOL(enable, float8-byval, yes, [disable float8 passed by value])
1544 else
1545   PGAC_ARG_BOOL(enable, float8-byval, no, [disable float8 passed by value])
1546   if test "$enable_float8_byval" = yes ; then
1547     AC_MSG_ERROR([--enable-float8-byval is not supported on 32-bit platforms.])
1548   fi
1549 fi
1550 if test "$enable_float8_byval" = yes ; then
1551   AC_DEFINE([USE_FLOAT8_BYVAL], 1,
1552             [Define to 1 if you want float8, int8, etc values to be passed by value. (--enable-float8-byval)])
1553   float8passbyval=true
1554 else
1555   float8passbyval=false
1556 fi
1557 AC_MSG_RESULT([$enable_float8_byval])
1558 AC_DEFINE_UNQUOTED([FLOAT8PASSBYVAL], [$float8passbyval], [float8, int8, and related values are passed by value if 'true', by reference if 'false'])
1559
1560 # Determine memory alignment requirements for the basic C data types.
1561
1562 AC_CHECK_ALIGNOF(short)
1563 AC_CHECK_ALIGNOF(int)
1564 AC_CHECK_ALIGNOF(long)
1565 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1566   AC_CHECK_ALIGNOF(long long int)
1567 fi
1568 AC_CHECK_ALIGNOF(double)
1569
1570 # Compute maximum alignment of any basic type.
1571 # We assume long's alignment is at least as strong as char, short, or int;
1572 # but we must check long long (if it exists) and double.
1573
1574 MAX_ALIGNOF=$ac_cv_alignof_long
1575 if test $MAX_ALIGNOF -lt $ac_cv_alignof_double ; then
1576   MAX_ALIGNOF=$ac_cv_alignof_double
1577 fi
1578 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $ac_cv_alignof_long_long_int ; then
1579   MAX_ALIGNOF="$ac_cv_alignof_long_long_int"
1580 fi
1581 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1582
1583
1584 # Some platforms predefine the types int8, int16, etc.  Only check
1585 # a (hopefully) representative subset.
1586 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1587 [#include <stdio.h>
1588 #ifdef HAVE_SUPPORTDEFS_H
1589 #include <SupportDefs.h>
1590 #endif])
1591
1592 # We also check for sig_atomic_t, which *should* be defined per ANSI
1593 # C, but is missing on some old platforms.
1594 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1595
1596
1597 # If the user did not disable integer datetimes, check that
1598 # there is a working 64-bit integral type to use.
1599 if test x"$USE_INTEGER_DATETIMES" = x"yes" &&
1600    test x"$HAVE_LONG_INT_64" = x"no" &&
1601    test x"$HAVE_LONG_LONG_INT_64" = x"no" &&
1602    test x"$HAVE_INT64" = x"no" ; then
1603   AC_MSG_ERROR([
1604 Integer-based datetime support requires a 64-bit integer type,
1605 but no such type could be found. The --disable-integer-datetimes
1606 configure option can be used to disable integer-based storage
1607 of datetime values.])
1608 fi
1609
1610
1611 if test "$PORTNAME" != "win32"
1612 then
1613 PGAC_FUNC_POSIX_SIGNALS
1614 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1615   AC_MSG_ERROR([
1616 Thread-safety requires POSIX signals, which are not supported by this
1617 operating system.])
1618 fi
1619 fi
1620
1621 if test $ac_cv_func_fseeko = yes; then
1622 AC_SYS_LARGEFILE
1623 fi
1624
1625 # Check for largefile support (must be after AC_SYS_LARGEFILE)
1626 AC_CHECK_SIZEOF([off_t])
1627
1628 # If we don't have largefile support, can't handle segsize >= 2GB.
1629 if test "$ac_cv_sizeof_off_t" -lt 8 -a "$segsize" != "1"; then
1630    AC_MSG_ERROR([Large file support is not enabled. Segment size cannot be larger than 1GB.])
1631 fi
1632
1633 # SunOS doesn't handle negative byte comparisons properly with +/- return
1634 AC_FUNC_MEMCMP
1635
1636
1637 # Select semaphore implementation type.
1638 if test "$PORTNAME" != "win32"; then
1639   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1640     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1641     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1642   else
1643     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1644       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1645       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1646     else
1647       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1648       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1649     fi
1650   fi
1651 else
1652   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1653   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1654 fi
1655
1656
1657 # Select shared-memory implementation type.
1658 if test "$PORTNAME" != "win32"; then
1659   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1660   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1661 else
1662   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
1663   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
1664 fi
1665
1666 # If not set in template file, set bytes to use libc memset()
1667 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
1668   MEMSET_LOOP_LIMIT=1024
1669 fi
1670 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
1671
1672
1673 if test "$enable_nls" = yes ; then
1674   PGAC_CHECK_GETTEXT
1675 fi
1676
1677 # Check for Tcl configuration script tclConfig.sh
1678 if test "$with_tcl" = yes; then
1679     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1680     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1681                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1682     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1683     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1684     ac_save_CPPFLAGS=$CPPFLAGS
1685     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1686     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1687     CPPFLAGS=$ac_save_CPPFLAGS
1688 fi
1689
1690 #
1691 # Check for DocBook and tools
1692 #
1693 PGAC_PROG_NSGMLS
1694 PGAC_PROG_JADE
1695 PGAC_CHECK_DOCBOOK(4.2)
1696 PGAC_PATH_DOCBOOK_STYLESHEETS
1697 PGAC_PATH_COLLATEINDEX
1698 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1699 PGAC_PATH_DOCBOOK2MAN
1700
1701 # Thread testing
1702
1703 # We have to run the thread test near the end so we have all our symbols
1704 # defined.  Cross compiling throws a warning.
1705 #
1706 if test "$enable_thread_safety_force" = yes; then
1707 if test "$PORTNAME" != "win32"
1708 then
1709   AC_MSG_WARN([
1710 *** Skipping thread test program.  --enable-thread-safety-force was used.
1711 *** Run the program in src/test/thread on the your machine and add proper
1712 *** locking function calls to your applications to guarantee thread safety.
1713 ])
1714 else
1715 AC_MSG_WARN([*** skipping thread test on Win32])
1716 fi
1717 elif test "$enable_thread_safety" = yes; then
1718 if test "$PORTNAME" != "win32"
1719 then
1720 AC_MSG_CHECKING([thread safety of required library functions])
1721
1722 _CFLAGS="$CFLAGS"
1723 _LIBS="$LIBS"
1724 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1725 LIBS="$LIBS $PTHREAD_LIBS"
1726 AC_TRY_RUN([#include "$srcdir/src/test/thread/thread_test.c"],
1727   [AC_MSG_RESULT(yes)],
1728   [AC_MSG_RESULT(no)
1729   AC_MSG_ERROR([thread test program failed
1730 This platform is not thread-safe.  Check the file 'config.log' for the
1731 exact reason.
1732
1733 You can use the configure option --enable-thread-safety-force to force
1734 threads to be enabled.  But you must then run the program in
1735 src/test/thread and add locking function calls to your applications to
1736 guarantee thread safety.])],
1737   [AC_MSG_RESULT(maybe)
1738   AC_MSG_WARN([
1739 *** Skipping thread test program because of cross-compile build.
1740 *** Run the program in src/test/thread on the target machine.
1741 ])])
1742 CFLAGS="$_CFLAGS"
1743 LIBS="$_LIBS"
1744 else
1745 AC_MSG_WARN([*** skipping thread test on Win32])
1746 fi
1747 fi
1748
1749 # If compiler will take -Wl,--as-needed then add that to LDFLAGS.
1750 # This is much easier than trying to filter LIBS to the minimum for each
1751 # executable.  (Note that shared library links won't use this switch, though.)
1752 # On (at least) some Red-Hat-derived systems, this switch breaks linking to
1753 # libreadline; therefore we postpone testing it until we know what library
1754 # dependencies readline has.  The test code will try to link with $LIBS.
1755 if test "$with_readline" = yes; then
1756   link_test_func=readline
1757 else
1758   link_test_func=exit
1759 fi
1760 if test "$PORTNAME" != "darwin"; then
1761   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,--as-needed], $link_test_func)
1762 else
1763   # On Darwin it's spelled -Wl,-dead_strip_dylibs, but don't try that elsewhere
1764   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-dead_strip_dylibs], $link_test_func)
1765 fi
1766
1767
1768 # Begin output steps
1769
1770 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
1771 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
1772 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
1773
1774 # Create compiler version string
1775 if test x"$GCC" = x"yes" ; then
1776   cc_string="GCC `${CC} --version | sed q`"
1777 elif test x"$SUN_STUDIO_CC" = x"yes" ; then
1778   cc_string=`${CC} -V 2>&1 | sed q`
1779 else
1780   cc_string=$CC
1781 fi
1782
1783 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
1784                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string, `expr $ac_cv_sizeof_void_p \* 8`-bit"],
1785                    [A string containing the version number, platform, and C compiler])
1786
1787 # Supply a numeric version string for use by 3rd party add-ons
1788 # awk -F is a regex on some platforms, and not on others, so make "." a tab
1789 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
1790 tr '.' '        ' |
1791 $AWK '{printf "%d%02d%02d", $1, $2, (NF >= 3) ? $3 : 0}'`"]
1792 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
1793
1794
1795 # prepare build tree if outside source tree
1796 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1797 # Note 2: /bin/pwd might be better than shell's built-in at getting
1798 #         a symlink-free name.
1799 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1800   vpath_build=no
1801 else
1802   vpath_build=yes
1803   if test "$no_create" != yes; then
1804     _AS_ECHO_N([preparing build tree... ])
1805     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1806     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1807       || AC_MSG_ERROR(failed)
1808     AC_MSG_RESULT(done)
1809   fi
1810 fi
1811 AC_SUBST(vpath_build)
1812
1813
1814 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1815
1816 AC_CONFIG_LINKS([
1817   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1818   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1819   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1820   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1821   src/include/pg_config_os.h:src/include/port/${template}.h
1822   src/Makefile.port:src/makefiles/Makefile.${template}
1823 ])
1824
1825 if test "$PORTNAME" = "win32"; then
1826 AC_CONFIG_COMMANDS([check_win32_symlinks],[
1827 # Links sometimes fail undetected on Mingw -
1828 # so here we detect it and warn the user
1829 for FILE in $CONFIG_LINKS
1830  do
1831         # test -e works for symlinks in the MinGW console
1832         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
1833  done
1834 ])
1835 fi
1836
1837 AC_CONFIG_HEADERS([src/include/pg_config.h],
1838 [
1839 # Update timestamp for pg_config.h (see Makefile.global)
1840 echo >src/include/stamp-h
1841 ])
1842
1843 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h])
1844
1845 AC_OUTPUT
1846
1847 # Warn about unknown options
1848 PGAC_ARG_CHECK