configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $PostgreSQL: pgsql/configure.in,v 1.612 2009/10/01 01:58:57 tgl Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [8.5devel], [pgsql-bugs@postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.63], [], [m4_fatal([Autoconf version 2.63 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2009, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version as a string])
  33 [PG_MAJORVERSION=`expr "$PACKAGE_VERSION" : '\([0-9][0-9]*\.[0-9][0-9]*\)'`]
  34 AC_SUBST(PG_MAJORVERSION)
  35 AC_DEFINE_UNQUOTED(PG_MAJORVERSION, "$PG_MAJORVERSION", [PostgreSQL major version as a string])
  36
  37 AC_CANONICAL_HOST
  38
  39 template=
  40 AC_MSG_CHECKING([which template to use])
  41
  42 PGAC_ARG_REQ(with, template, [NAME], [override operating system template],
  43 [
  44   case $withval in
  45     list)   echo; ls "$srcdir/src/template"; exit;;
  46     *)      if test -f "$srcdir/src/template/$with_template" ; then
  47               template=$withval
  48             else
  49               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  50             fi;;
  51   esac
  52 ],
  53 [
  54 # --with-template not given
  55
  56 case $host_os in
  57      aix*) template=aix ;;
  58     bsdi*) template=bsdi ;;
  59   cygwin*) template=cygwin ;;
  60   darwin*) template=darwin ;;
  61     dgux*) template=dgux ;;
  62  freebsd*) template=freebsd ;;
  63     hpux*) template=hpux ;;
  64     irix*) template=irix ;;
  65  linux*|gnu*|k*bsd*-gnu)
  66            template=linux ;;
  67    mingw*) template=win32 ;;
  68   netbsd*) template=netbsd ;;
  69 nextstep*) template=nextstep ;;
  70  openbsd*) template=openbsd ;;
  71      osf*) template=osf ;;
  72      sco*) template=sco ;;
  73  solaris*) template=solaris ;;
  74    sunos*) template=sunos4 ;;
  75  sysv4.2*)
  76         case $host_vendor in
  77           univel) template=univel ;;
  78         esac ;;
  79    sysv4*) template=svr4 ;;
  80    sysv5*) template=unixware ;;
  81   ultrix*) template=ultrix4 ;;
  82 esac
  83
  84   if test x"$template" = x"" ; then
  85     AC_MSG_ERROR([[
  86 *******************************************************************
  87 PostgreSQL has apparently not been ported to your platform yet.
  88 To try a manual configuration, look into the src/template directory
  89 for a similar platform and use the '--with-template=' option.
  90
  91 Please also contact <pgsql-bugs@postgresql.org> to see about
  92 rectifying this.  Include the above 'checking host system type...'
  93 line.
  94 *******************************************************************
  95 ]])
  96   fi
  97
  98 ])
  99
 100 AC_MSG_RESULT([$template])
 101
 102 PORTNAME=$template
 103 AC_SUBST(PORTNAME)
 104
 105 # Initialize default assumption that we do not need separate assembly code
 106 # for TAS (test-and-set).  This can be overridden by the template file
 107 # when it's executed.
 108 need_tas=no
 109 tas_file=dummy.s
 110
 111
 112
 113 ##
 114 ## Command line options
 115 ##
 116
 117 #
 118 # Add non-standard directories to the include path
 119 #
 120 PGAC_ARG_REQ(with, includes, [DIRS], [look for additional header files in DIRS])
 121
 122
 123 #
 124 # Add non-standard directories to the library search path
 125 #
 126 PGAC_ARG_REQ(with, libraries, [DIRS], [look for additional libraries in DIRS],
 127              [LIBRARY_DIRS=$withval])
 128
 129 PGAC_ARG_REQ(with, libs,      [DIRS], [alternative spelling of --with-libraries],
 130              [LIBRARY_DIRS=$withval])
 131
 132
 133 #
 134 # 64-bit integer date/time storage: enabled by default.
 135 #
 136 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 137 PGAC_ARG_BOOL(enable, integer-datetimes, yes, [disable 64-bit integer date/time support],
 138               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 139                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 140 AC_MSG_RESULT([$enable_integer_datetimes])
 141
 142
 143 #
 144 # NLS
 145 #
 146 AC_MSG_CHECKING([whether NLS is wanted])
 147 PGAC_ARG_OPTARG(enable, nls,
 148                 [LANGUAGES], [enable Native Language Support],
 149                 [],
 150                 [WANTED_LANGUAGES=$enableval],
 151                 [AC_DEFINE(ENABLE_NLS, 1,
 152                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 153 AC_MSG_RESULT([$enable_nls])
 154 AC_SUBST(enable_nls)
 155 AC_SUBST(WANTED_LANGUAGES)
 156
 157 #
 158 # Default port number (--with-pgport), default 5432
 159 #
 160 AC_MSG_CHECKING([for default port number])
 161 PGAC_ARG_REQ(with, pgport, [PORTNUM], [set default port number [5432]],
 162              [default_port=$withval],
 163              [default_port=5432])
 164 AC_MSG_RESULT([$default_port])
 165 # Need both of these because some places want an integer and some a string
 166 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 167 [Define to the default TCP port number on which the server listens and
 168 to which clients will try to connect.  This can be overridden at run-time,
 169 but it's convenient if your clients have the right default compiled in.
 170 (--with-pgport=PORTNUM)])
 171 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 172                    [Define to the default TCP port number as a string constant.])
 173 AC_SUBST(default_port)
 174
 175 #
 176 # Option to disable shared libraries
 177 #
 178 PGAC_ARG_BOOL(enable, shared, yes,
 179               [do not build shared libraries])
 180 AC_SUBST(enable_shared)
 181
 182 #
 183 # '-rpath'-like feature can be disabled
 184 #
 185 PGAC_ARG_BOOL(enable, rpath, yes,
 186               [do not embed shared library search path in executables])
 187 AC_SUBST(enable_rpath)
 188
 189 #
 190 # Spinlocks
 191 #
 192 PGAC_ARG_BOOL(enable, spinlocks, yes,
 193               [do not use spinlocks])
 194
 195 #
 196 # --enable-debug adds -g to compiler flags
 197 #
 198 PGAC_ARG_BOOL(enable, debug, no,
 199               [build with debugging symbols (-g)])
 200 AC_SUBST(enable_debug)
 201
 202 #
 203 # --enable-profiling enables gcc profiling
 204 #
 205 PGAC_ARG_BOOL(enable, profiling, no,
 206               [build with profiling enabled ])
 207 AC_SUBST(enable_profiling)
 208
 209 #
 210 # --enable-coverage enables generation of code coverage metrics with gcov
 211 #
 212 PGAC_ARG_BOOL(enable, coverage, no,
 213               [build with coverage testing instrumentation],
 214 [AC_CHECK_PROGS(GCOV, gcov)
 215 if test -z "$GCOV"; then
 216   AC_MSG_ERROR([gcov not found])
 217 fi
 218 AC_CHECK_PROGS(LCOV, lcov)
 219 if test -z "$LCOV"; then
 220   AC_MSG_ERROR([lcov not found])
 221 fi
 222 AC_CHECK_PROGS(GENHTML, genhtml)
 223 if test -z "$GENHTML"; then
 224   AC_MSG_ERROR([genhtml not found])
 225 fi])
 226 AC_SUBST(enable_coverage)
 227
 228 #
 229 # DTrace
 230 #
 231 PGAC_ARG_BOOL(enable, dtrace, no,
 232               [build with DTrace support],
 233 [AC_DEFINE([ENABLE_DTRACE], 1,
 234            [Define to 1 to enable DTrace support. (--enable-dtrace)])
 235 AC_CHECK_PROGS(DTRACE, dtrace)
 236 if test -z "$DTRACE"; then
 237   AC_MSG_ERROR([dtrace not found])
 238 fi
 239 AC_SUBST(DTRACEFLAGS)])
 240 AC_SUBST(enable_dtrace)
 241
 242 #
 243 # Block size
 244 #
 245 AC_MSG_CHECKING([for block size])
 246 PGAC_ARG_REQ(with, blocksize, [BLOCKSIZE], [set table block size in kB [8]],
 247              [blocksize=$withval],
 248              [blocksize=8])
 249 case ${blocksize} in
 250   1) BLCKSZ=1024;;
 251   2) BLCKSZ=2048;;
 252   4) BLCKSZ=4096;;
 253   8) BLCKSZ=8192;;
 254  16) BLCKSZ=16384;;
 255  32) BLCKSZ=32768;;
 256   *) AC_MSG_ERROR([Invalid block size. Allowed values are 1,2,4,8,16,32.])
 257 esac
 258 AC_MSG_RESULT([${blocksize}kB])
 259
 260 AC_DEFINE_UNQUOTED([BLCKSZ], ${BLCKSZ}, [
 261  Size of a disk block --- this also limits the size of a tuple.  You
 262  can set it bigger if you need bigger tuples (although TOAST should
 263  reduce the need to have large tuples, since fields can be spread
 264  across multiple tuples).
 265
 266  BLCKSZ must be a power of 2.  The maximum possible value of BLCKSZ
 267  is currently 2^15 (32768).  This is determined by the 15-bit widths
 268  of the lp_off and lp_len fields in ItemIdData (see
 269  include/storage/itemid.h).
 270
 271  Changing BLCKSZ requires an initdb.
 272 ])
 273
 274 #
 275 # Relation segment size
 276 #
 277 AC_MSG_CHECKING([for segment size])
 278 PGAC_ARG_REQ(with, segsize, [SEGSIZE], [set table segment size in GB [1]],
 279              [segsize=$withval],
 280              [segsize=1])
 281 # this expression is set up to avoid unnecessary integer overflow
 282 # blocksize is already guaranteed to be a factor of 1024
 283 RELSEG_SIZE=`expr '(' 1024 / ${blocksize} ')' '*' ${segsize} '*' 1024`
 284 test $? -eq 0 || exit 1
 285 AC_MSG_RESULT([${segsize}GB])
 286
 287 AC_DEFINE_UNQUOTED([RELSEG_SIZE], ${RELSEG_SIZE}, [
 288  RELSEG_SIZE is the maximum number of blocks allowed in one disk file.
 289  Thus, the maximum size of a single file is RELSEG_SIZE * BLCKSZ;
 290  relations bigger than that are divided into multiple files.
 291
 292  RELSEG_SIZE * BLCKSZ must be less than your OS' limit on file size.
 293  This is often 2 GB or 4GB in a 32-bit operating system, unless you
 294  have large file support enabled.  By default, we make the limit 1 GB
 295  to avoid any possible integer-overflow problems within the OS.
 296  A limit smaller than necessary only means we divide a large
 297  relation into more chunks than necessary, so it seems best to err
 298  in the direction of a small limit.
 299
 300  A power-of-2 value is recommended to save a few cycles in md.c,
 301  but is not absolutely required.
 302
 303  Changing RELSEG_SIZE requires an initdb.
 304 ])
 305
 306 #
 307 # WAL block size
 308 #
 309 AC_MSG_CHECKING([for WAL block size])
 310 PGAC_ARG_REQ(with, wal-blocksize, [BLOCKSIZE], [set WAL block size in kB [8]],
 311              [wal_blocksize=$withval],
 312              [wal_blocksize=8])
 313 case ${wal_blocksize} in
 314   1) XLOG_BLCKSZ=1024;;
 315   2) XLOG_BLCKSZ=2048;;
 316   4) XLOG_BLCKSZ=4096;;
 317   8) XLOG_BLCKSZ=8192;;
 318  16) XLOG_BLCKSZ=16384;;
 319  32) XLOG_BLCKSZ=32768;;
 320  64) XLOG_BLCKSZ=65536;;
 321   *) AC_MSG_ERROR([Invalid WAL block size. Allowed values are 1,2,4,8,16,32,64.])
 322 esac
 323 AC_MSG_RESULT([${wal_blocksize}kB])
 324
 325 AC_DEFINE_UNQUOTED([XLOG_BLCKSZ], ${XLOG_BLCKSZ}, [
 326  Size of a WAL file block.  This need have no particular relation to BLCKSZ.
 327  XLOG_BLCKSZ must be a power of 2, and if your system supports O_DIRECT I/O,
 328  XLOG_BLCKSZ must be a multiple of the alignment requirement for direct-I/O
 329  buffers, else direct I/O may fail.
 330
 331  Changing XLOG_BLCKSZ requires an initdb.
 332 ])
 333
 334 #
 335 # WAL segment size
 336 #
 337 AC_MSG_CHECKING([for WAL segment size])
 338 PGAC_ARG_REQ(with, wal-segsize, [SEGSIZE], [set WAL segment size in MB [16]],
 339              [wal_segsize=$withval],
 340              [wal_segsize=16])
 341 case ${wal_segsize} in
 342   1) ;;
 343   2) ;;
 344   4) ;;
 345   8) ;;
 346  16) ;;
 347  32) ;;
 348  64) ;;
 349   *) AC_MSG_ERROR([Invalid WAL segment size. Allowed values are 1,2,4,8,16,32,64.])
 350 esac
 351 AC_MSG_RESULT([${wal_segsize}MB])
 352
 353 AC_DEFINE_UNQUOTED([XLOG_SEG_SIZE], [(${wal_segsize} * 1024 * 1024)], [
 354  XLOG_SEG_SIZE is the size of a single WAL file.  This must be a power of 2
 355  and larger than XLOG_BLCKSZ (preferably, a great deal larger than
 356  XLOG_BLCKSZ).
 357
 358  Changing XLOG_SEG_SIZE requires an initdb.
 359 ])
 360
 361 #
 362 # C compiler
 363 #
 364
 365 # For historical reasons you can also use --with-CC to specify the C compiler
 366 # to use, although the standard way to do this is to set the CC environment
 367 # variable.
 368 PGAC_ARG_REQ(with, CC, [CMD], [set compiler (deprecated)], [CC=$with_CC])
 369
 370 case $template in
 371   aix) pgac_cc_list="gcc xlc";;
 372  irix) pgac_cc_list="cc";; # no gcc
 373     *) pgac_cc_list="gcc cc";;
 374 esac
 375
 376 AC_PROG_CC([$pgac_cc_list])
 377
 378 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 379 # but has idiosyncrasies of its own.  We assume icc will define
 380 # __INTEL_COMPILER regardless of CFLAGS.
 381 AC_TRY_COMPILE([], [@%:@ifndef __INTEL_COMPILER
 382 choke me
 383 @%:@endif], [ICC=[yes]], [ICC=[no]])
 384
 385 # Check if it's Sun Studio compiler. We assume that
 386 # __SUNPRO_C will be defined for Sun Studio compilers
 387 AC_TRY_COMPILE([], [@%:@ifndef __SUNPRO_C
 388 choke me
 389 @%:@endif], [SUN_STUDIO_CC=yes], [SUN_STUDIO_CC=no])
 390
 391 AC_SUBST(SUN_STUDIO_CC)
 392
 393 unset CFLAGS
 394
 395 #
 396 # Read the template
 397 #
 398 . "$srcdir/src/template/$template" || exit
 399
 400 # CFLAGS are selected so:
 401 # If the user specifies something in the environment, that is used.
 402 # else:  If the template file set something, that is used.
 403 # else:  If coverage was enabled, don't set anything.
 404 # else:  If the compiler is GCC, then we use -O2.
 405 # else:  If the compiler is something else, then we use -O, unless debugging.
 406
 407 if test "$ac_env_CFLAGS_set" = set; then
 408   CFLAGS=$ac_env_CFLAGS_value
 409 elif test "${CFLAGS+set}" = set; then
 410   : # (keep what template set)
 411 elif test "$enable_coverage" = yes; then
 412   : # no optimization by default
 413 elif test "$GCC" = yes; then
 414   CFLAGS="-O2"
 415 else
 416   # if the user selected debug mode, don't use -O
 417   if test "$enable_debug" != yes; then
 418     CFLAGS="-O"
 419   fi
 420 fi
 421
 422 # Some versions of GCC support some additional useful warning flags.
 423 # Check whether they are supported, and add them to CFLAGS if so.
 424 # ICC pretends to be GCC but it's lying; it doesn't support these flags,
 425 # but has its own.  Also check other compiler-specific flags here.
 426
 427 if test "$GCC" = yes -a "$ICC" = no; then
 428   CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wpointer-arith"
 429   # These work in some but not all gcc versions
 430   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 431   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 432   # Disable strict-aliasing rules; needed for gcc 3.3+
 433   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 434   # Disable optimizations that assume no overflow; needed for gcc 4.3+
 435   PGAC_PROG_CC_CFLAGS_OPT([-fwrapv])
 436 elif test "$ICC" = yes; then
 437   # Intel's compiler has a bug/misoptimization in checking for
 438   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 439   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 440   # Make sure strict aliasing is off (though this is said to be the default)
 441   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 442 elif test "$PORTNAME" = "aix"; then
 443   # AIX's xlc has to have strict aliasing turned off too
 444   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 445 fi
 446
 447 # supply -g if --enable-debug
 448 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 449   CFLAGS="$CFLAGS -g"
 450 fi
 451
 452 # enable code coverage if --enable-coverage
 453 if test "$enable_coverage" = yes; then
 454   if test "$GCC" = yes; then
 455     CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 456   else
 457     AC_MSG_ERROR([--enable-coverage is supported only when using GCC])
 458   fi
 459 fi
 460
 461 # enable profiling if --enable-profiling
 462 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 463   if test "$GCC" = yes; then
 464     AC_DEFINE([PROFILE_PID_DIR], 1,
 465            [Define to 1 to allow profiling output to be saved separately for each process.])
 466     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 467   else
 468     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 469   fi
 470 fi
 471
 472 # We already have this in Makefile.win32, but configure needs it too
 473 if test "$PORTNAME" = "win32"; then
 474   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 475 fi
 476
 477 # Check if the compiler still works with the template settings
 478 AC_MSG_CHECKING([whether the C compiler still works])
 479 AC_TRY_LINK([], [return 0;],
 480   [AC_MSG_RESULT(yes)],
 481   [AC_MSG_RESULT(no)
 482    AC_MSG_ERROR([cannot proceed])])
 483
 484 # Defend against gcc -ffast-math
 485 if test "$GCC" = yes; then
 486 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 487 choke me
 488 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 489 fi
 490
 491 AC_PROG_CPP
 492 AC_SUBST(GCC)
 493
 494
 495 #
 496 # Set up TAS assembly code if needed; the template file has now had its
 497 # chance to request this.
 498 #
 499 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 500
 501 if test "$need_tas" = yes ; then
 502   TAS=tas.o
 503 else
 504   TAS=""
 505 fi
 506 AC_SUBST(TAS)
 507
 508
 509 #
 510 # Automatic dependency tracking
 511 #
 512 PGAC_ARG_BOOL(enable, depend, no, [turn on automatic dependency tracking],
 513               [autodepend=yes])
 514 AC_SUBST(autodepend)
 515
 516
 517 #
 518 # Enable assert checks
 519 #
 520 PGAC_ARG_BOOL(enable, cassert, no, [enable assertion checks (for debugging)],
 521               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 522                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 523
 524
 525 #
 526 # Include directories
 527 #
 528 ac_save_IFS=$IFS
 529 IFS="${IFS}${PATH_SEPARATOR}"
 530 # SRCH_INC comes from the template file
 531 for dir in $with_includes $SRCH_INC; do
 532   if test -d "$dir"; then
 533     INCLUDES="$INCLUDES -I$dir"
 534   else
 535     AC_MSG_WARN([*** Include directory $dir does not exist.])
 536   fi
 537 done
 538 IFS=$ac_save_IFS
 539 AC_SUBST(INCLUDES)
 540
 541
 542 #
 543 # Library directories
 544 #
 545 ac_save_IFS=$IFS
 546 IFS="${IFS}${PATH_SEPARATOR}"
 547 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 548 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 549   if test -d "$dir"; then
 550     LIBDIRS="$LIBDIRS -L$dir"
 551   else
 552     AC_MSG_WARN([*** Library directory $dir does not exist.])
 553   fi
 554 done
 555 IFS=$ac_save_IFS
 556
 557 #
 558 # Enable thread-safe client libraries
 559 #
 560 AC_MSG_CHECKING([allow thread-safe client libraries])
 561 if test "$PORTNAME" != "win32"; then
 562 PGAC_ARG_BOOL(enable, thread-safety, no, [make client libraries thread-safe])
 563 else
 564 # Win32 should always use threads
 565 PGAC_ARG_BOOL(enable, thread-safety, yes, [make client libraries thread-safe])
 566 fi
 567
 568 PGAC_ARG_BOOL(enable, thread-safety-force, no, [force thread-safety despite thread test failure])
 569 if test "$enable_thread_safety" = yes -o \
 570         "$enable_thread_safety_force" = yes; then
 571   enable_thread_safety="yes"    # for 'force'
 572   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 573           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 574 fi
 575 AC_MSG_RESULT([$enable_thread_safety])
 576 AC_SUBST(enable_thread_safety)
 577
 578 #
 579 # Optionally build Tcl modules (PL/Tcl)
 580 #
 581 AC_MSG_CHECKING([whether to build with Tcl])
 582 PGAC_ARG_BOOL(with, tcl, no, [build Tcl modules (PL/Tcl)])
 583 AC_MSG_RESULT([$with_tcl])
 584 AC_SUBST([with_tcl])
 585
 586 # We see if the path to the Tcl/Tk configuration scripts is specified.
 587 # This will override the use of tclsh to find the paths to search.
 588
 589 PGAC_ARG_REQ(with, tclconfig, [DIR], [tclConfig.sh is in DIR])
 590
 591 #
 592 # Optionally build Perl modules (PL/Perl)
 593 #
 594 AC_MSG_CHECKING([whether to build Perl modules])
 595 PGAC_ARG_BOOL(with, perl, no, [build Perl modules (PL/Perl)])
 596 AC_MSG_RESULT([$with_perl])
 597 AC_SUBST(with_perl)
 598
 599 #
 600 # Optionally build Python modules (PL/Python)
 601 #
 602 AC_MSG_CHECKING([whether to build Python modules])
 603 PGAC_ARG_BOOL(with, python, no, [build Python modules (PL/Python)])
 604 AC_MSG_RESULT([$with_python])
 605 AC_SUBST(with_python)
 606
 607 #
 608 # GSSAPI
 609 #
 610 AC_MSG_CHECKING([whether to build with GSSAPI support])
 611 PGAC_ARG_BOOL(with, gssapi, no, [build with GSSAPI support],
 612 [
 613   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 614   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 615 ])
 616 AC_MSG_RESULT([$with_gssapi])
 617 AC_SUBST(with_gssapi)
 618
 619 #
 620 # Kerberos 5
 621 #
 622 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 623 PGAC_ARG_BOOL(with, krb5, no, [build with Kerberos 5 support],
 624 [
 625   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 626   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 627 ])
 628 AC_MSG_RESULT([$with_krb5])
 629 AC_SUBST(with_krb5)
 630
 631
 632 AC_SUBST(krb_srvtab)
 633
 634
 635 #
 636 # Kerberos configuration parameters
 637 #
 638 PGAC_ARG_REQ(with, krb-srvnam,
 639              [NAME], [default service principal name in Kerberos [postgres]],
 640              [],
 641              [with_krb_srvnam="postgres"])
 642 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 643                    [Define to the name of the default PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 644
 645
 646 #
 647 # PAM
 648 #
 649 AC_MSG_CHECKING([whether to build with PAM support])
 650 PGAC_ARG_BOOL(with, pam, no,
 651               [build with PAM support],
 652               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 653 AC_MSG_RESULT([$with_pam])
 654 AC_SUBST(with_pam)
 655
 656
 657 #
 658 # LDAP
 659 #
 660 AC_MSG_CHECKING([whether to build with LDAP support])
 661 PGAC_ARG_BOOL(with, ldap, no,
 662               [build with LDAP support],
 663               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 664 AC_MSG_RESULT([$with_ldap])
 665 AC_SUBST(with_ldap)
 666
 667
 668 #
 669 # Bonjour
 670 #
 671 AC_MSG_CHECKING([whether to build with Bonjour support])
 672 PGAC_ARG_BOOL(with, bonjour, no,
 673               [build with Bonjour support],
 674               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 675 AC_MSG_RESULT([$with_bonjour])
 676 AC_SUBST(with_bonjour)
 677
 678
 679 #
 680 # OpenSSL
 681 #
 682 AC_MSG_CHECKING([whether to build with OpenSSL support])
 683 PGAC_ARG_BOOL(with, openssl, no, [build with OpenSSL support],
 684               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 685 AC_MSG_RESULT([$with_openssl])
 686 AC_SUBST(with_openssl)
 687
 688
 689 #
 690 # Readline
 691 #
 692 PGAC_ARG_BOOL(with, readline, yes,
 693               [do not use GNU Readline nor BSD Libedit for editing])
 694 # readline on MinGW has problems with backslashes in psql and other bugs.
 695 # This is particularly a problem with non-US code pages.
 696 # Therefore disable its use until we understand the cause. 2004-07-20
 697 if test "$PORTNAME" = "win32"; then
 698   if test "$with_readline" = yes; then
 699     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 700     with_readline=no
 701   fi
 702 fi
 703
 704
 705 #
 706 # Prefer libedit
 707 #
 708 PGAC_ARG_BOOL(with, libedit-preferred, no,
 709               [prefer BSD Libedit over GNU Readline])
 710
 711
 712 #
 713 # OSSP UUID library
 714 #
 715 PGAC_ARG_BOOL(with, ossp-uuid, no, [use OSSP UUID library when building contrib/uuid-ossp])
 716 AC_SUBST(with_ossp_uuid)
 717
 718
 719 #
 720 # XML
 721 #
 722 PGAC_ARG_BOOL(with, libxml, no, [build with XML support],
 723               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 724
 725 if test "$with_libxml" = yes ; then
 726   AC_CHECK_PROGS(XML2_CONFIG, xml2-config)
 727   if test -n "$XML2_CONFIG"; then
 728     for pgac_option in `$XML2_CONFIG --cflags`; do
 729       case $pgac_option in
 730         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 731       esac
 732     done
 733     for pgac_option in `$XML2_CONFIG --libs`; do
 734       case $pgac_option in
 735         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 736       esac
 737     done
 738   fi
 739 fi
 740
 741 AC_SUBST(with_libxml)
 742
 743 #
 744 # XSLT
 745 #
 746 PGAC_ARG_BOOL(with, libxslt, no, [use XSLT support when building contrib/xml2],
 747               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 748
 749
 750 AC_SUBST(with_libxslt)
 751
 752 #
 753 # tzdata
 754 #
 755 PGAC_ARG_REQ(with, system-tzdata,
 756              [DIR], [use system time zone data in DIR])
 757 AC_SUBST(with_system_tzdata)
 758
 759 #
 760 # Zlib
 761 #
 762 PGAC_ARG_BOOL(with, zlib, yes,
 763               [do not use Zlib])
 764 AC_SUBST(with_zlib)
 765
 766 #
 767 # Elf
 768 #
 769
 770 # Assume system is ELF if it predefines __ELF__ as 1,
 771 # otherwise believe host_os based default.
 772 case $host_os in
 773     freebsd1*|freebsd2*) elf=no;;
 774     freebsd3*|freebsd4*) elf=yes;;
 775 esac
 776
 777 AC_EGREP_CPP(yes,
 778 [#if __ELF__
 779   yes
 780 #endif
 781 ],
 782 [ELF_SYS=true],
 783 [if test "X$elf" = "Xyes" ; then
 784   ELF_SYS=true
 785 else
 786   ELF_SYS=
 787 fi])
 788 AC_SUBST(ELF_SYS)
 789
 790 #
 791 # Assignments
 792 #
 793
 794 CPPFLAGS="$CPPFLAGS $INCLUDES"
 795 LDFLAGS="$LDFLAGS $LIBDIRS"
 796
 797 AC_ARG_VAR(LDFLAGS_SL, [linker flags for shared library linking])
 798
 799 PGAC_PROG_LD
 800 AC_SUBST(LD)
 801 AC_SUBST(with_gnu_ld)
 802 case $host_os in sysv5*)
 803   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 804   [
 805     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 806     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 807     LDFLAGS=$pgac_save_LDFLAGS
 808   ])
 809   ld_R_works=$pgac_cv_prog_ld_R
 810   AC_SUBST(ld_R_works)
 811 esac
 812 AC_PROG_RANLIB
 813 PGAC_CHECK_STRIP
 814 AC_CHECK_TOOL(AR, ar, ar)
 815 if test "$PORTNAME" = "win32"; then
 816   AC_CHECK_TOOL(DLLTOOL, dlltool, dlltool)
 817   AC_CHECK_TOOL(DLLWRAP, dllwrap, dllwrap)
 818   AC_CHECK_TOOL(WINDRES, windres, windres)
 819 fi
 820
 821 AC_PATH_PROG(TAR, tar)
 822 AC_PROG_LN_S
 823 AC_PROG_AWK
 824 AC_PROG_MKDIR_P
 825 # When Autoconf chooses install-sh as mkdir -p program it tries to generate
 826 # a relative path to it in each makefile where it subsitutes it. This clashes
 827 # with our Makefile.global concept. This workaround helps.
 828 case $MKDIR_P in
 829   *install-sh*) MKDIR_P='\${SHELL} \${top_srcdir}/config/install-sh -c -d';;
 830 esac
 831
 832 PGAC_PATH_BISON
 833 PGAC_PATH_FLEX
 834
 835 PGAC_PATH_PERL
 836 if test "$with_perl" = yes; then
 837   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 838   PGAC_CHECK_PERL_EMBED_LDFLAGS
 839 fi
 840
 841 if test "$with_python" = yes; then
 842   PGAC_PATH_PYTHON
 843   PGAC_CHECK_PYTHON_EMBED_SETUP
 844 fi
 845
 846 if test "$cross_compiling" = yes && test -z "$with_system_tzdata"; then
 847   AC_PATH_PROG(ZIC, zic)
 848   if test -z "$ZIC"; then
 849     AC_MSG_ERROR([
 850 When cross-compiling, either use the option --with-system-tzdata to use
 851 existing time-zone data, or set the environment variable ZIC to a zic
 852 program to use during the build.])
 853   fi
 854 fi
 855
 856
 857 ##
 858 ## Libraries
 859 ##
 860 ## Most libraries are included only if they demonstrably provide a function
 861 ## we need, but libm is an exception: always include it, because there are
 862 ## too many compilers that play cute optimization games that will break
 863 ## probes for standard functions such as pow().
 864 ##
 865
 866 AC_CHECK_LIB(m, main)
 867 AC_SEARCH_LIBS(setproctitle, util)
 868 AC_SEARCH_LIBS(dlopen, dl)
 869 AC_SEARCH_LIBS(socket, [socket wsock32])
 870 AC_SEARCH_LIBS(shl_load, dld)
 871 # We only use libld in port/dynloader/aix.c
 872 case $host_os in
 873      aix*)
 874         AC_SEARCH_LIBS(ldopen, ld)
 875         ;;
 876 esac
 877 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 878 AC_SEARCH_LIBS(crypt, crypt)
 879 # Solaris:
 880 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 881 # Required for thread_test.c on Solaris 2.5:
 882 # Other ports use it too (HP-UX) so test unconditionally
 883 AC_SEARCH_LIBS(gethostbyname_r, nsl)
 884 # Cygwin:
 885 AC_SEARCH_LIBS(shmget, cygipc)
 886
 887 if test "$with_readline" = yes; then
 888   PGAC_CHECK_READLINE
 889   if test x"$pgac_cv_check_readline" = x"no"; then
 890     AC_MSG_ERROR([readline library not found
 891 If you have readline already installed, see config.log for details on the
 892 failure.  It is possible the compiler isn't looking in the proper directory.
 893 Use --without-readline to disable readline support.])
 894   fi
 895 fi
 896
 897 if test "$with_zlib" = yes; then
 898   AC_CHECK_LIB(z, inflate, [],
 899                [AC_MSG_ERROR([zlib library not found
 900 If you have zlib already installed, see config.log for details on the
 901 failure.  It is possible the compiler isn't looking in the proper directory.
 902 Use --without-zlib to disable zlib support.])])
 903 fi
 904
 905 if test "$enable_spinlocks" = yes; then
 906   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 907 else
 908   AC_MSG_WARN([
 909 *** Not using spinlocks will cause poor performance.])
 910 fi
 911
 912 if test "$with_gssapi" = yes ; then
 913   if test "$PORTNAME" != "win32"; then
 914     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
 915                                   [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
 916   else
 917     LIBS="$LIBS -lgssapi32"
 918   fi
 919 fi
 920
 921 if test "$with_krb5" = yes ; then
 922   if test "$PORTNAME" != "win32"; then
 923      AC_SEARCH_LIBS(com_err, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken' com_err 'com_err -lssl -lcrypto'], [],
 924                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 925      AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken'], [],
 926                     [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 927   else
 928      AC_SEARCH_LIBS(com_err, 'comerr32 -lkrb5_32', [],
 929                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 930   fi
 931 fi
 932
 933 if test "$with_openssl" = yes ; then
 934   dnl Order matters!
 935   if test "$PORTNAME" != "win32"; then
 936      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 937      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 938   else
 939      AC_CHECK_LIB(eay32, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'eay32' is required for OpenSSL])])
 940      AC_CHECK_LIB(ssleay32,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssleay32' is required for OpenSSL])])
 941   fi
 942 fi
 943
 944 if test "$with_pam" = yes ; then
 945   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 946 fi
 947
 948 if test "$with_libxml" = yes ; then
 949   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
 950 fi
 951
 952 if test "$with_libxslt" = yes ; then
 953   AC_CHECK_LIB(xslt, xsltCleanupGlobals, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
 954 fi
 955
 956 # for contrib/uuid-ossp
 957 if test "$with_ossp_uuid" = yes ; then
 958   AC_CHECK_LIB(ossp-uuid, uuid_export,
 959     [OSSP_UUID_LIBS="-lossp-uuid"],
 960     [AC_CHECK_LIB(uuid, uuid_export,
 961       [OSSP_UUID_LIBS="-luuid"],
 962       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP-UUID])])])
 963 fi
 964 AC_SUBST(OSSP_UUID_LIBS)
 965
 966
 967 ##
 968 ## Header files
 969 ##
 970
 971 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 972 AC_CHECK_HEADERS([crypt.h dld.h fp_class.h getopt.h ieeefp.h ifaddrs.h langinfo.h poll.h pwd.h sys/ioctl.h sys/ipc.h sys/poll.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/shm.h sys/socket.h sys/sockio.h sys/tas.h sys/time.h sys/un.h termios.h ucred.h utime.h wchar.h wctype.h kernel/OS.h kernel/image.h SupportDefs.h])
 973
 974 # On BSD, cpp test for net/if.h will fail unless sys/socket.h
 975 # is included first.
 976 AC_CHECK_HEADERS(net/if.h, [], [],
 977 [AC_INCLUDES_DEFAULT
 978 #ifdef HAVE_SYS_SOCKET_H
 979 #include <sys/socket.h>
 980 #endif
 981 ])
 982
 983 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 984 # netinet/in.h is included first.
 985 AC_CHECK_HEADERS(netinet/in.h)
 986 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 987 [AC_INCLUDES_DEFAULT
 988 #ifdef HAVE_NETINET_IN_H
 989 #include <netinet/in.h>
 990 #endif
 991 ])
 992
 993 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
 994   AC_CHECK_HEADERS(readline/readline.h, [],
 995         [AC_CHECK_HEADERS(readline.h, [],
 996                 [AC_MSG_ERROR([readline header not found
 997 If you have readline already installed, see config.log for details on the
 998 failure.  It is possible the compiler isn't looking in the proper directory.
 999 Use --without-readline to disable readline support.])])])
1000   AC_CHECK_HEADERS(readline/history.h, [],
1001         [AC_CHECK_HEADERS(history.h, [],
1002                 [AC_MSG_ERROR([history header not found
1003 If you have readline already installed, see config.log for details on the
1004 failure.  It is possible the compiler isn't looking in the proper directory.
1005 Use --without-readline to disable readline support.])])])
1006 fi
1007
1008 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
1009 # Some installations of libedit usurp /usr/include/readline/, which seems
1010 # bad practice, since in combined installations readline will have its headers
1011 # there.  We might have to resort to AC_EGREP checks to make sure we found
1012 # the proper header...
1013   AC_CHECK_HEADERS(editline/readline.h, [],
1014         [AC_CHECK_HEADERS(readline.h, [],
1015                 [AC_CHECK_HEADERS(readline/readline.h, [],
1016                         [AC_MSG_ERROR([readline header not found
1017 If you have libedit already installed, see config.log for details on the
1018 failure.  It is possible the compiler isn't looking in the proper directory.
1019 Use --without-readline to disable libedit support.])])])])
1020 # Note: in a libedit installation, history.h is sometimes a dummy, and may
1021 # not be there at all.  Hence, don't complain if not found.  We must check
1022 # though, since in yet other versions it is an independent header.
1023   AC_CHECK_HEADERS(editline/history.h, [],
1024         [AC_CHECK_HEADERS(history.h, [],
1025                 [AC_CHECK_HEADERS(readline/history.h)])])
1026 fi
1027
1028 if test "$with_zlib" = yes; then
1029   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
1030 If you have zlib already installed, see config.log for details on the
1031 failure.  It is possible the compiler isn't looking in the proper directory.
1032 Use --without-zlib to disable zlib support.])])
1033 fi
1034
1035 if test "$with_gssapi" = yes ; then
1036   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
1037         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
1038 fi
1039
1040 if test "$with_krb5" = yes ; then
1041   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
1042 fi
1043
1044 if test "$with_openssl" = yes ; then
1045   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
1046   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
1047   AC_CHECK_FUNCS([ERR_set_mark])
1048 fi
1049
1050 if test "$with_pam" = yes ; then
1051   AC_CHECK_HEADERS(security/pam_appl.h, [],
1052                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
1053                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
1054 fi
1055
1056 if test "$with_libxml" = yes ; then
1057   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
1058 fi
1059
1060 if test "$with_libxslt" = yes ; then
1061   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
1062 fi
1063
1064 if test "$with_ldap" = yes ; then
1065   if test "$PORTNAME" != "win32"; then
1066      AC_CHECK_HEADERS(ldap.h, [],
1067                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
1068   else
1069      AC_CHECK_HEADERS(winldap.h, [],
1070                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
1071                       [AC_INCLUDES_DEFAULT
1072 #include <windows.h>
1073                       ])
1074   fi
1075 fi
1076
1077 if test "$with_bonjour" = yes ; then
1078   AC_CHECK_HEADER(dns_sd.h, [], [AC_MSG_ERROR([header file <dns_sd.h> is required for Bonjour])])
1079 fi
1080
1081 # for contrib/uuid-ossp
1082 if test "$with_ossp_uuid" = yes ; then
1083   AC_CHECK_HEADERS(ossp/uuid.h, [], [
1084     AC_CHECK_HEADERS(uuid.h, [],
1085       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP-UUID])])])
1086 fi
1087
1088
1089 ##
1090 ## Types, structures, compiler characteristics
1091 ##
1092
1093 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
1094 AC_C_BIGENDIAN
1095 AC_C_CONST
1096 AC_C_INLINE
1097 AC_C_STRINGIZE
1098 PGAC_C_SIGNED
1099 AC_C_VOLATILE
1100 PGAC_C_FUNCNAME_SUPPORT
1101 PGAC_STRUCT_TIMEZONE
1102 PGAC_UNION_SEMUN
1103 PGAC_STRUCT_SOCKADDR_UN
1104 PGAC_STRUCT_SOCKADDR_STORAGE
1105 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
1106 PGAC_STRUCT_ADDRINFO
1107
1108 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
1109 [#include <sys/param.h>
1110 #include <sys/types.h>
1111 #include <sys/socket.h>
1112 #include <sys/ucred.h>])
1113
1114 AC_CHECK_TYPES([struct option], [], [],
1115 [#ifdef HAVE_GETOPT_H
1116 #include <getopt.h>
1117 #endif])
1118
1119 if test "$with_zlib" = yes; then
1120   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
1121   # did not).  While we could work around the lack of z_streamp, it
1122   # seems unwise to encourage people to use such old zlib versions...
1123   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
1124 Use --without-zlib to disable zlib support.])],
1125                 [#include <zlib.h>])
1126 fi
1127
1128 if test "$with_krb5" = yes; then
1129 # Check for differences between MIT and Heimdal (KTH) releases
1130   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
1131                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
1132                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
1133                                      [#include <krb5.h>])],
1134                    [#include <krb5.h>])
1135   AC_CHECK_MEMBERS(krb5_error.text.data, [],
1136                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
1137                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
1138                                      [#include <krb5.h>])],
1139                    [#include <krb5.h>])
1140
1141 # Win32 requires headers to be loaded for __stdcall, so can't use
1142 # AC_CHECK_FUNCS here.
1143   AC_MSG_CHECKING(for krb5_free_unparsed_name)
1144   AC_TRY_LINK([#include <krb5.h>],
1145               [krb5_free_unparsed_name(NULL,NULL);],
1146               [AC_DEFINE(HAVE_KRB5_FREE_UNPARSED_NAME, 1, [Define to 1 if you have krb5_free_unparsed_name])
1147 AC_MSG_RESULT(yes)],
1148               [AC_MSG_RESULT(no)])
1149 fi
1150
1151
1152 ##
1153 ## Functions, global variables
1154 ##
1155
1156 PGAC_VAR_INT_TIMEZONE
1157 AC_FUNC_ACCEPT_ARGTYPES
1158 PGAC_FUNC_GETTIMEOFDAY_1ARG
1159
1160 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getifaddrs getpeereid getpeerucred getrlimit memmove poll pstat readlink setproctitle setsid sigprocmask symlink sysconf towlower utime utimes waitpid wcstombs])
1161
1162 # posix_fadvise() is a no-op on Solaris, so don't incur function overhead
1163 # by calling it, 2009-04-02
1164 # http://src.opensolaris.org/source/xref/onnv/onnv-gate/usr/src/lib/libc/port/gen/posix_fadvise.c
1165 if test "$PORTNAME" != "solaris"; then
1166 AC_CHECK_FUNCS(posix_fadvise)
1167 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
1168 fi
1169
1170 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
1171 AC_CHECK_DECLS([strlcat, strlcpy])
1172 # This is probably only present on Darwin, but may as well check always
1173 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
1174
1175 HAVE_IPV6=no
1176 AC_CHECK_TYPE([struct sockaddr_in6],
1177         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
1178          HAVE_IPV6=yes],
1179         [],
1180 [$ac_includes_default
1181 #include <netinet/in.h>])
1182 AC_SUBST(HAVE_IPV6)
1183
1184 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1185 [AC_TRY_LINK(
1186 [#include <machine/vmparam.h>
1187 #include <sys/exec.h>
1188 ],
1189 [PS_STRINGS->ps_nargvstr = 1;
1190 PS_STRINGS->ps_argvstr = "foo";],
1191 [pgac_cv_var_PS_STRINGS=yes],
1192 [pgac_cv_var_PS_STRINGS=no])])
1193 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1194   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
1195 fi
1196
1197
1198 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
1199 # is missing.  Yes, there are machines that have only one.  We may
1200 # also decide to use snprintf.c if snprintf() is present but does not
1201 # have all the features we need --- see below.
1202
1203 if test "$PORTNAME" = "win32"; then
1204   # Win32 gets snprintf.c built unconditionally.
1205   #
1206   # To properly translate all NLS languages strings, we must support the
1207   # *printf() %$ format, which allows *printf() arguments to be selected
1208   # by position in the translated string.
1209   #
1210   # libintl versions < 0.13 use the native *printf() functions, and Win32
1211   # *printf() doesn't understand %$, so we must use our /port versions,
1212   # which do understand %$. libintl versions >= 0.13 include their own
1213   # *printf versions on Win32.  The libintl 0.13 release note text is:
1214   #
1215   #   C format strings with positions, as they arise when a translator
1216   #   needs to reorder a sentence, are now supported on all platforms.
1217   #   On those few platforms (NetBSD and Woe32) for which the native
1218   #   printf()/fprintf()/... functions don't support such format
1219   #   strings, replacements are provided through <libintl.h>.
1220   #
1221   # We could use libintl >= 0.13's *printf() if we were sure that we had
1222   # a litint >= 0.13 at runtime, but seeing that there is no clean way
1223   # to guarantee that, it is best to just use our own, so we are sure to
1224   # get %$ support. In include/port.h we disable the *printf() macros
1225   # that might have been defined by libintl.
1226   #
1227   # We do this unconditionally whether NLS is used or not so we are sure
1228   # that all Win32 libraries and binaries behave the same.
1229   pgac_need_repl_snprintf=yes
1230 else
1231   pgac_need_repl_snprintf=no
1232   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
1233   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1234 fi
1235
1236
1237 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
1238 # include/c.h will provide declarations.  Note this is a separate test
1239 # from whether the functions exist in the C library --- there are
1240 # systems that have the functions but don't bother to declare them :-(
1241
1242 AC_CHECK_DECLS([snprintf, vsnprintf])
1243
1244
1245 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1246 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1247 [AC_TRY_LINK([
1248 #include <math.h>
1249 double glob_double;
1250 ],
1251 [return isinf(glob_double) ? 0 : 1;],
1252 [ac_cv_func_isinf=yes],
1253 [ac_cv_func_isinf=no])])
1254
1255 if test $ac_cv_func_isinf = yes ; then
1256   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1257 else
1258   AC_LIBOBJ(isinf)
1259   # Look for a way to implement a substitute for isinf()
1260   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1261 fi
1262
1263 # Some versions of libedit contain strlcpy(); so disregard that library while
1264 # checking for these standard libc functions.
1265 pgac_save_LIBS="$LIBS"
1266 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1267
1268 AC_REPLACE_FUNCS([crypt erand48 getopt getrusage inet_aton random rint srandom strdup strerror strlcat strlcpy strtol strtoul])
1269
1270 case $host_os in
1271
1272         # Windows uses a specialised env handler
1273         mingw*)
1274                 AC_DEFINE(HAVE_UNSETENV, 1, [Define to 1 because replacement version used.])
1275                 ac_cv_func_unsetenv=yes;;
1276         *)
1277                 AC_REPLACE_FUNCS([unsetenv])
1278                 ;;
1279 esac
1280
1281
1282 LIBS="$pgac_save_LIBS"
1283
1284 # System's version of getaddrinfo(), if any, may be used only if we found
1285 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1286 # (Note: the AC_REPLACE_FUNCS probe fails on Windows, where the available
1287 # versions of getaddrinfo don't follow normal C call protocol.  This is OK
1288 # because we want to use our own getaddrinfo.c on Windows anyway.)
1289 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
1290   AC_REPLACE_FUNCS([getaddrinfo])
1291 else
1292   AC_LIBOBJ(getaddrinfo)
1293 fi
1294
1295 # Similarly, use system's getopt_long() only if system provides struct option.
1296 if test x"$ac_cv_type_struct_option" = xyes ; then
1297   AC_REPLACE_FUNCS([getopt_long])
1298 else
1299   AC_LIBOBJ(getopt_long)
1300 fi
1301
1302 # Solaris' getopt() doesn't do what we want for long options, so always use
1303 # our version on that platform.
1304 if test "$PORTNAME" = "solaris"; then
1305   AC_LIBOBJ(getopt)
1306 fi
1307
1308 # Cygwin's erand48() is broken (always returns zero) in some releases,
1309 # so force use of ours.
1310 if test "$PORTNAME" = "cygwin"; then
1311   AC_LIBOBJ(erand48)
1312 fi
1313
1314 # Win32 support
1315 if test "$PORTNAME" = "win32"; then
1316 AC_REPLACE_FUNCS(gettimeofday)
1317 AC_LIBOBJ(kill)
1318 AC_LIBOBJ(open)
1319 AC_LIBOBJ(win32env)
1320 AC_LIBOBJ(win32error)
1321 AC_DEFINE([HAVE_SYMLINK], 1,
1322           [Define to 1 if you have the `symlink' function.])
1323 fi
1324
1325 if test "$with_readline" = yes; then
1326   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1327   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
1328   AC_CHECK_FUNCS([append_history history_truncate_file])
1329 fi
1330
1331
1332 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
1333 dnl (especially on GNU libc)
1334 dnl See also comments in c.h.
1335 AC_MSG_CHECKING(for sigsetjmp)
1336 AC_TRY_LINK([#include <setjmp.h>],
1337             [sigjmp_buf x; sigsetjmp(x, 1);],
1338             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
1339 AC_MSG_RESULT(yes)],
1340             [AC_MSG_RESULT(no)])
1341
1342 AC_DECL_SYS_SIGLIST
1343
1344 AC_CHECK_FUNC(syslog,
1345               [AC_CHECK_HEADER(syslog.h,
1346                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1347
1348 AC_CACHE_CHECK([for opterr], pgac_cv_var_int_opterr,
1349 [AC_TRY_LINK([#include <unistd.h>],
1350   [extern int opterr; opterr = 1;],
1351   [pgac_cv_var_int_opterr=yes],
1352   [pgac_cv_var_int_opterr=no])])
1353 if test x"$pgac_cv_var_int_opterr" = x"yes"; then
1354   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
1355 fi
1356
1357 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1358 [AC_TRY_LINK([#include <unistd.h>],
1359   [extern int optreset; optreset = 1;],
1360   [pgac_cv_var_int_optreset=yes],
1361   [pgac_cv_var_int_optreset=no])])
1362 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1363   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1364 fi
1365
1366 AC_CHECK_FUNCS([strtoll strtoq], [break])
1367 AC_CHECK_FUNCS([strtoull strtouq], [break])
1368
1369 # Check for one of atexit() or on_exit()
1370 AC_CHECK_FUNCS(atexit, [],
1371                [AC_CHECK_FUNCS(on_exit, [],
1372                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
1373
1374 AC_REPLACE_FUNCS(fseeko)
1375 case $host_os in
1376         # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
1377         # Mingw uses macros to access Win32 API calls
1378         bsdi*|netbsd*|mingw*)
1379                 AC_DEFINE(HAVE_FSEEKO, 1, [Define to 1 because replacement version used.])
1380                 ac_cv_func_fseeko=yes;;
1381         *)
1382                 AC_FUNC_FSEEKO;;
1383 esac
1384
1385
1386 #
1387 # Pthreads
1388 #
1389 # For each platform, we need to know about any special compile and link
1390 # libraries, and whether the normal C function names are thread-safe.
1391 # See the comment at the top of src/port/thread.c for more information.
1392 # WIN32 doesn't need the pthread tests;  it always uses threads
1393 if test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"; then
1394 ACX_PTHREAD     # set thread flags
1395
1396 # Some platforms use these, so just define them.  They can't hurt if they
1397 # are not supported.  For example, on Solaris -D_POSIX_PTHREAD_SEMANTICS
1398 # enables 5-arg getpwuid_r, among other things.
1399 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1400
1401
1402 # At this point, we don't want to muck with the compiler name for threading.
1403 # Let's see who fails, perhaps AIX.  2004-04-23
1404 if test "$PTHREAD_CC" != "$CC"; then
1405 AC_MSG_ERROR([
1406 PostgreSQL does not support platforms that require a special compiler
1407 for thread safety.])
1408 fi
1409
1410 if test "$THREAD_SUPPORT" = no; then
1411 AC_MSG_ERROR([cannot enable threads on this platform
1412 This platform is known to not support thread-safe programs.  For details,
1413 compile and run src/bin/pg_thread_test.])
1414 fi
1415
1416 # Check for *_r functions
1417 _CFLAGS="$CFLAGS"
1418 _LIBS="$LIBS"
1419 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1420 LIBS="$LIBS $PTHREAD_LIBS"
1421
1422 if test "$PORTNAME" != "win32"; then
1423 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([pthread.h not found, required for --enable-thread-safety])])
1424 fi
1425
1426 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1427
1428 # Do test here with the proper thread flags
1429 PGAC_FUNC_GETPWUID_R_5ARG
1430 PGAC_FUNC_STRERROR_R_INT
1431
1432 CFLAGS="$_CFLAGS"
1433 LIBS="$_LIBS"
1434
1435 else
1436 # do not use values from template file
1437 PTHREAD_CFLAGS=
1438 PTHREAD_LIBS=
1439 fi
1440
1441 AC_SUBST(PTHREAD_CFLAGS)
1442 AC_SUBST(PTHREAD_LIBS)
1443
1444
1445 # We can test for libldap_r only after we know PTHREAD_LIBS
1446 if test "$with_ldap" = yes ; then
1447   _LIBS="$LIBS"
1448   if test "$PORTNAME" != "win32"; then
1449     AC_CHECK_LIB(ldap, ldap_bind, [],
1450                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1451                  [$EXTRA_LDAP_LIBS])
1452     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1453     if test "$enable_thread_safety" = yes; then
1454       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1455       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1456                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1457                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1458       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1459     else
1460       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1461     fi
1462   else
1463     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1464     LDAP_LIBS_FE="-lwldap32"
1465     LDAP_LIBS_BE="-lwldap32"
1466   fi
1467   LIBS="$_LIBS"
1468 fi
1469 AC_SUBST(LDAP_LIBS_FE)
1470 AC_SUBST(LDAP_LIBS_BE)
1471
1472
1473 # This test makes sure that run tests work at all.  Sometimes a shared
1474 # library is found by the linker, but the runtime linker can't find it.
1475 # This check should come after all modifications of compiler or linker
1476 # variables, and before any other run tests.
1477 AC_MSG_CHECKING([test program])
1478 AC_TRY_RUN([int main() { return 0; }],
1479 [AC_MSG_RESULT(ok)],
1480 [AC_MSG_RESULT(failed)
1481 AC_MSG_ERROR([[
1482 Could not execute a simple test program.  This may be a problem
1483 related to locating shared libraries.  Check the file 'config.log'
1484 for the exact reason.]])],
1485 [AC_MSG_RESULT([cross-compiling])])
1486
1487 # --------------------
1488 # Run tests below here
1489 # --------------------
1490
1491 # Force use of our snprintf if system's doesn't do arg control
1492 # See comment above at snprintf test for details.
1493 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1494   PGAC_FUNC_PRINTF_ARG_CONTROL
1495   if test $pgac_cv_printf_arg_control != yes ; then
1496     pgac_need_repl_snprintf=yes
1497   fi
1498 fi
1499
1500
1501 dnl Check to see if we have a working 64-bit integer type.
1502 dnl This breaks down into two steps:
1503 dnl (1) figure out if the compiler has a 64-bit int type with working
1504 dnl arithmetic, and if so
1505 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1506 dnl snprintf is the only library routine we really need for int8 support.)
1507 dnl It's entirely possible to have a compiler that handles a 64-bit type
1508 dnl when the C library doesn't; this is fairly likely when using gcc on
1509 dnl an older platform, for example.
1510 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1511 dnl we force our own version of snprintf() to be used instead.
1512 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1513
1514 PGAC_TYPE_64BIT_INT([long int])
1515
1516 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1517   PGAC_TYPE_64BIT_INT([long long int])
1518 fi
1519
1520
1521 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1522
1523 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1524   AC_TRY_COMPILE([
1525 #define INT64CONST(x)  x##LL
1526 long long int foo = INT64CONST(0x1234567890123456);
1527 ],
1528         [],
1529         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1530         [])
1531 fi
1532
1533
1534 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1535 # we found we need to use "long long int", better check.  We cope with
1536 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1537 # work, fall back to our own snprintf emulation (which we know uses %lld).
1538
1539 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1540   if test $pgac_need_repl_snprintf = no; then
1541     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1542     if test "$LONG_LONG_INT_FORMAT" = ""; then
1543       # Force usage of our own snprintf, since system snprintf is broken
1544       pgac_need_repl_snprintf=yes
1545       LONG_LONG_INT_FORMAT='%lld'
1546     fi
1547   else
1548     # Here if we previously decided we needed to use our own snprintf
1549     LONG_LONG_INT_FORMAT='%lld'
1550   fi
1551   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1552   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1553   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1554 else
1555   # Here if we are not using 'long long int' at all
1556   INT64_FORMAT='"%ld"'
1557   UINT64_FORMAT='"%lu"'
1558 fi
1559
1560 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1561                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1562
1563 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1564                    [Define to the appropriate snprintf format for unsigned 64-bit ints, if any.])
1565
1566 # Now we have checked all the reasons to replace snprintf
1567 if test $pgac_need_repl_snprintf = yes; then
1568   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1569   AC_LIBOBJ(snprintf)
1570 fi
1571
1572 # Need a #define for the size of Datum (unsigned long)
1573 AC_CHECK_SIZEOF([unsigned long])
1574
1575 # And check size of void *, size_t (enables tweaks for > 32bit address space)
1576 AC_CHECK_SIZEOF([void *])
1577 AC_CHECK_SIZEOF([size_t])
1578
1579 # Decide whether float4 is passed by value: user-selectable, enabled by default
1580 AC_MSG_CHECKING([whether to build with float4 passed by value])
1581 PGAC_ARG_BOOL(enable, float4-byval, yes, [disable float4 passed by value],
1582               [AC_DEFINE([USE_FLOAT4_BYVAL], 1,
1583                          [Define to 1 if you want float4 values to be passed by value. (--enable-float4-byval)])
1584                float4passbyval=true],
1585               [float4passbyval=false])
1586 AC_MSG_RESULT([$enable_float4_byval])
1587 AC_DEFINE_UNQUOTED([FLOAT4PASSBYVAL], [$float4passbyval], [float4 values are passed by value if 'true', by reference if 'false'])
1588
1589 # Decide whether float8 is passed by value.
1590 # Note: this setting also controls int8 and related types such as timestamp.
1591 # If sizeof(Datum) >= 8, this is user-selectable, enabled by default.
1592 # If not, trying to select it is an error.
1593 AC_MSG_CHECKING([whether to build with float8 passed by value])
1594 if test $ac_cv_sizeof_unsigned_long -ge 8 ; then
1595   PGAC_ARG_BOOL(enable, float8-byval, yes, [disable float8 passed by value])
1596 else
1597   PGAC_ARG_BOOL(enable, float8-byval, no, [disable float8 passed by value])
1598   if test "$enable_float8_byval" = yes ; then
1599     AC_MSG_ERROR([--enable-float8-byval is not supported on 32-bit platforms.])
1600   fi
1601 fi
1602 if test "$enable_float8_byval" = yes ; then
1603   AC_DEFINE([USE_FLOAT8_BYVAL], 1,
1604             [Define to 1 if you want float8, int8, etc values to be passed by value. (--enable-float8-byval)])
1605   float8passbyval=true
1606 else
1607   float8passbyval=false
1608 fi
1609 AC_MSG_RESULT([$enable_float8_byval])
1610 AC_DEFINE_UNQUOTED([FLOAT8PASSBYVAL], [$float8passbyval], [float8, int8, and related values are passed by value if 'true', by reference if 'false'])
1611
1612 # Determine memory alignment requirements for the basic C data types.
1613
1614 AC_CHECK_ALIGNOF(short)
1615 AC_CHECK_ALIGNOF(int)
1616 AC_CHECK_ALIGNOF(long)
1617 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1618   AC_CHECK_ALIGNOF(long long int)
1619 fi
1620 AC_CHECK_ALIGNOF(double)
1621
1622 # Compute maximum alignment of any basic type.
1623 # We assume long's alignment is at least as strong as char, short, or int;
1624 # but we must check long long (if it exists) and double.
1625
1626 MAX_ALIGNOF=$ac_cv_alignof_long
1627 if test $MAX_ALIGNOF -lt $ac_cv_alignof_double ; then
1628   MAX_ALIGNOF=$ac_cv_alignof_double
1629 fi
1630 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $ac_cv_alignof_long_long_int ; then
1631   MAX_ALIGNOF="$ac_cv_alignof_long_long_int"
1632 fi
1633 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1634
1635
1636 # Some platforms predefine the types int8, int16, etc.  Only check
1637 # a (hopefully) representative subset.
1638 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1639 [#include <stdio.h>
1640 #ifdef HAVE_SUPPORTDEFS_H
1641 #include <SupportDefs.h>
1642 #endif])
1643
1644 # We also check for sig_atomic_t, which *should* be defined per ANSI
1645 # C, but is missing on some old platforms.
1646 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1647
1648
1649 # If the user did not disable integer datetimes, check that
1650 # there is a working 64-bit integral type to use.
1651 if test x"$USE_INTEGER_DATETIMES" = x"yes" &&
1652    test x"$HAVE_LONG_INT_64" = x"no" &&
1653    test x"$HAVE_LONG_LONG_INT_64" = x"no" &&
1654    test x"$HAVE_INT64" = x"no" ; then
1655   AC_MSG_ERROR([
1656 Integer-based datetime support requires a 64-bit integer type,
1657 but no such type could be found. The --disable-integer-datetimes
1658 configure option can be used to disable integer-based storage
1659 of datetime values.])
1660 fi
1661
1662
1663 if test "$PORTNAME" != "win32"
1664 then
1665 PGAC_FUNC_POSIX_SIGNALS
1666 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1667   AC_MSG_ERROR([
1668 Thread-safety requires POSIX signals, which are not supported by this
1669 operating system.])
1670 fi
1671 fi
1672
1673 if test $ac_cv_func_fseeko = yes; then
1674 AC_SYS_LARGEFILE
1675 fi
1676
1677 # Check for largefile support (must be after AC_SYS_LARGEFILE)
1678 AC_CHECK_SIZEOF([off_t])
1679
1680 # If we don't have largefile support, can't handle segsize >= 2GB.
1681 if test "$ac_cv_sizeof_off_t" -lt 8 -a "$segsize" != "1"; then
1682    AC_MSG_ERROR([Large file support is not enabled. Segment size cannot be larger than 1GB.])
1683 fi
1684
1685 # SunOS doesn't handle negative byte comparisons properly with +/- return
1686 AC_FUNC_MEMCMP
1687
1688
1689 # Select semaphore implementation type.
1690 if test "$PORTNAME" != "win32"; then
1691   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1692     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1693     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1694   else
1695     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1696       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1697       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1698     else
1699       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1700       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1701     fi
1702   fi
1703 else
1704   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1705   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1706 fi
1707
1708
1709 # Select shared-memory implementation type.
1710 if test "$PORTNAME" != "win32"; then
1711   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1712   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1713 else
1714   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
1715   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
1716 fi
1717
1718 # If not set in template file, set bytes to use libc memset()
1719 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
1720   MEMSET_LOOP_LIMIT=1024
1721 fi
1722 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
1723
1724
1725 if test "$enable_nls" = yes ; then
1726   PGAC_CHECK_GETTEXT
1727 fi
1728
1729 # Check for Tcl configuration script tclConfig.sh
1730 if test "$with_tcl" = yes; then
1731     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1732     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1733                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1734     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1735     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1736     ac_save_CPPFLAGS=$CPPFLAGS
1737     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1738     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1739     CPPFLAGS=$ac_save_CPPFLAGS
1740 fi
1741
1742 #
1743 # Check for DocBook and tools
1744 #
1745 PGAC_PROG_NSGMLS
1746 PGAC_PROG_JADE
1747 PGAC_CHECK_DOCBOOK(4.2)
1748 PGAC_PATH_DOCBOOK_STYLESHEETS
1749 PGAC_PATH_COLLATEINDEX
1750 AC_CHECK_PROGS(XSLTPROC, xsltproc)
1751 AC_CHECK_PROGS(OSX, [osx sgml2xml sx])
1752
1753 # Thread testing
1754
1755 # We have to run the thread test near the end so we have all our symbols
1756 # defined.  Cross compiling throws a warning.
1757 #
1758 if test "$enable_thread_safety_force" = yes; then
1759 if test "$PORTNAME" != "win32"
1760 then
1761   AC_MSG_WARN([
1762 *** Skipping thread test program.  --enable-thread-safety-force was used.
1763 *** Run the program in src/test/thread on the your machine and add proper
1764 *** locking function calls to your applications to guarantee thread safety.
1765 ])
1766 else
1767 AC_MSG_WARN([*** skipping thread test on Win32])
1768 fi
1769 elif test "$enable_thread_safety" = yes; then
1770 if test "$PORTNAME" != "win32"
1771 then
1772 AC_MSG_CHECKING([thread safety of required library functions])
1773
1774 _CFLAGS="$CFLAGS"
1775 _LIBS="$LIBS"
1776 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1777 LIBS="$LIBS $PTHREAD_LIBS"
1778 AC_TRY_RUN([#include "$srcdir/src/test/thread/thread_test.c"],
1779   [AC_MSG_RESULT(yes)],
1780   [AC_MSG_RESULT(no)
1781   AC_MSG_ERROR([thread test program failed
1782 This platform is not thread-safe.  Check the file 'config.log' for the
1783 exact reason.
1784
1785 You can use the configure option --enable-thread-safety-force to force
1786 threads to be enabled.  But you must then run the program in
1787 src/test/thread and add locking function calls to your applications to
1788 guarantee thread safety.])],
1789   [AC_MSG_RESULT(maybe)
1790   AC_MSG_WARN([
1791 *** Skipping thread test program because of cross-compile build.
1792 *** Run the program in src/test/thread on the target machine.
1793 ])])
1794 CFLAGS="$_CFLAGS"
1795 LIBS="$_LIBS"
1796 else
1797 AC_MSG_WARN([*** skipping thread test on Win32])
1798 fi
1799 fi
1800
1801 # If compiler will take -Wl,--as-needed (or various platform-specific
1802 # spellings thereof) then add that to LDFLAGS.  This is much easier than
1803 # trying to filter LIBS to the minimum for each executable.
1804 # (Note that shared library links won't use this switch, though.)
1805 # On (at least) some Red-Hat-derived systems, this switch breaks linking to
1806 # libreadline; therefore we postpone testing it until we know what library
1807 # dependencies readline has.  The test code will try to link with $LIBS.
1808 if test "$with_readline" = yes; then
1809   link_test_func=readline
1810 else
1811   link_test_func=exit
1812 fi
1813
1814 if test "$PORTNAME" = "darwin"; then
1815   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-dead_strip_dylibs], $link_test_func)
1816 elif test "$PORTNAME" = "openbsd"; then
1817   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-Bdynamic], $link_test_func)
1818 else
1819   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,--as-needed], $link_test_func)
1820 fi
1821
1822
1823 # Begin output steps
1824
1825 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
1826 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
1827 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
1828
1829 # Create compiler version string
1830 if test x"$GCC" = x"yes" ; then
1831   cc_string="GCC `${CC} --version | sed q`"
1832 elif test x"$SUN_STUDIO_CC" = x"yes" ; then
1833   cc_string=`${CC} -V 2>&1 | sed q`
1834 else
1835   cc_string=$CC
1836 fi
1837
1838 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
1839                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string, `expr $ac_cv_sizeof_void_p \* 8`-bit"],
1840                    [A string containing the version number, platform, and C compiler])
1841
1842 # Supply a numeric version string for use by 3rd party add-ons
1843 # awk -F is a regex on some platforms, and not on others, so make "." a tab
1844 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
1845 tr '.' '        ' |
1846 $AWK '{printf "%d%02d%02d", $1, $2, (NF >= 3) ? $3 : 0}'`"]
1847 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
1848
1849
1850 # prepare build tree if outside source tree
1851 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1852 # Note 2: /bin/pwd might be better than shell's built-in at getting
1853 #         a symlink-free name.
1854 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1855   vpath_build=no
1856 else
1857   vpath_build=yes
1858   if test "$no_create" != yes; then
1859     _AS_ECHO_N([preparing build tree... ])
1860     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1861     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1862       || AC_MSG_ERROR(failed)
1863     AC_MSG_RESULT(done)
1864   fi
1865 fi
1866 AC_SUBST(vpath_build)
1867
1868
1869 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1870
1871 AC_CONFIG_LINKS([
1872   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1873   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1874   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1875   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1876   src/include/pg_config_os.h:src/include/port/${template}.h
1877   src/Makefile.port:src/makefiles/Makefile.${template}
1878 ])
1879
1880 if test "$PORTNAME" = "win32"; then
1881 AC_CONFIG_COMMANDS([check_win32_symlinks],[
1882 # Links sometimes fail undetected on Mingw -
1883 # so here we detect it and warn the user
1884 for FILE in $CONFIG_LINKS
1885  do
1886         # test -e works for symlinks in the MinGW console
1887         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
1888  done
1889 ])
1890 fi
1891
1892 AC_CONFIG_HEADERS([src/include/pg_config.h],
1893 [
1894 # Update timestamp for pg_config.h (see Makefile.global)
1895 echo >src/include/stamp-h
1896 ])
1897
1898 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h],
1899                   [echo >src/interfaces/ecpg/include/stamp-h])
1900
1901 AC_OUTPUT