etc/Deployment/_deploy.bat

   1 @echo off
   2 setlocal ENABLEDELAYEDEXPANSION
   3 REM ------------------------------------------
   4 REM :: SETUP ENVIRONMENT ::
   5 REM ------------------------------------------
   6 call "%~dp0\_paths.bat"
   7 if not "%LAMEXP_ERROR%"=="0" (
   8         call "%~dp0\_error.bat" "FAILD TO SETUP PATHS. CHECK YOUR 'BUILDENV.TXT' FILE"
   9         GOTO:EOF
  10 )
  11 REM ------------------------------------------
  12 if "%LAMEXP_CONFIG%"=="" (
  13         set "LAMEXP_CONFIG=Release"
  14 )
  15 if not "%LAMEXP_REDIST%"=="0" (
  16         set "LAMEXP_REDIST=1"
  17 )
  18 REM ------------------------------------------
  19 REM :: SETUP BUILD DATE ::
  20 REM ------------------------------------------
  21 call "%~dp0\_date.bat"
  22 if not "%LAMEXP_ERROR%"=="0" (
  23         call "%~dp0\_error.bat" "FAILD TO SETUP BUILD-DATE"
  24         GOTO:EOF
  25 )
  26 REM ------------------------------------------
  27 REM :: SETUP PATHS ::
  28 REM ------------------------------------------
  29 set "OUT_PATH=%~dp0\..\..\bin\%LAMEXP_CONFIG%"
  30 set "TMP_PATH=%TEMP%\~LameXP.%LAMEXP_CONFIG%.%ISO_DATE%.%RANDOM%.tmp"
  31 set "OBJ_PATH=%~dp0\..\..\obj\%LAMEXP_CONFIG%"
  32 set "MOC_PATH=%~dp0\..\..\tmp"
  33 set "IPC_PATH=%~dp0\..\..\ipch"
  34 REM ------------------------------------------
  35 if "%LAMEXP_SKIP_BUILD%"=="YES" (
  36         goto SkipBuildThisTime
  37 )
  38 REM ------------------------------------------
  39 REM :: CLEAN UP ::
  40 REM ------------------------------------------
  41 del /Q "%OUT_PATH%\*.exe"
  42 del /Q "%OUT_PATH%\*.dll"
  43 del /Q "%OBJ_PATH%\*.obj"
  44 del /Q "%OBJ_PATH%\*.res"
  45 del /Q "%OBJ_PATH%\*.bat"
  46 del /Q "%OBJ_PATH%\*.idb"
  47 del /Q "%OBJ_PATH%\*.log"
  48 del /Q "%OBJ_PATH%\*.manifest"
  49 del /Q "%OBJ_PATH%\*.lastbuildstate"
  50 del /Q "%OBJ_PATH%\*.htm"
  51 del /Q "%OBJ_PATH%\*.dep"
  52 del /Q "%MOC_PATH%\*.cpp"
  53 del /Q "%MOC_PATH%\*.h"
  54 del /Q /S "%IPC_PATH%\*.*"
  55 REM ------------------------------------------
  56 REM :: BUILD BINARIES ::
  57 REM ------------------------------------------
  58 call "%~dp0\_lupdate.bat"
  59 call "%~dp0\_build.bat" "%~dp0\..\..\%PATH_VCPROJ%" "%LAMEXP_CONFIG%"
  60 if not "%LAMEXP_ERROR%"=="0" (
  61         call "%~dp0\_error.bat" "BUILD HAS FAILED"
  62         GOTO:EOF
  63 )
  64 REM ------------------------------------------
  65 :SkipBuildThisTime
  66 REM ------------------------------------------
  67 REM :: READ VERSION INFO ::
  68 REM ------------------------------------------
  69 call "%~dp0\_version.bat"
  70 if not "%LAMEXP_ERROR%"=="0" (
  71         call "%~dp0\_error.bat" "FAILD TO READ VERSION INFO!"
  72         GOTO:EOF
  73 )
  74 REM ------------------------------------------
  75 set "OUT_FILE=%OUT_PATH%\..\LameXP.%ISO_DATE%.%LAMEXP_CONFIG:_=-%.Build-%VER_LAMEXP_BUILD%"
  76 for /L %%n in (1, 1, 99) do (
  77         if exist "!OUT_FILE!.exe" set "OUT_FILE=%OUT_PATH%\..\LameXP.%ISO_DATE%.%LAMEXP_CONFIG:_=-%.Build-%VER_LAMEXP_BUILD%.Update-%%n"
  78         if exist "!OUT_FILE!.zip" set "OUT_FILE=%OUT_PATH%\..\LameXP.%ISO_DATE%.%LAMEXP_CONFIG:_=-%.Build-%VER_LAMEXP_BUILD%.Update-%%n"
  79 )
  80 REM ------------------------------------------
  81 REM :: DELETE OLD OUTPUT FILE ::
  82 REM ------------------------------------------
  83 del "%OUT_FILE%.exe"
  84 del "%OUT_FILE%.sfx"
  85 del "%OUT_FILE%.zip"
  86 REM ------------------------------------------
  87 if exist "%OUT_FILE%.exe" (
  88         call "%~dp0\_error.bat" "FAILD TO DELET EXISTING FILE"
  89         GOTO:EOF
  90 )
  91 if exist "%OUT_FILE%.zip" (
  92         call "%~dp0\_error.bat" "FAILD TO DELET EXISTING FILE"
  93         GOTO:EOF
  94 )
  95 REM ------------------------------------------
  96 REM :: POST BUILD ::
  97 REM ------------------------------------------
  98 rd /S /Q "%TMP_PATH%"
  99 mkdir "%TMP_PATH%"
 100 copy "%OUT_PATH%\*.exe" "%TMP_PATH%"
 101 REM ------------------------------------------
 102 if "%LAMEXP_REDIST%"=="1" (
 103         copy "%QTDIR%\bin\QtCore4.dll" "%TMP_PATH%"
 104         copy "%QTDIR%\bin\QtGui4.dll" "%TMP_PATH%"
 105         copy "%QTDIR%\bin\QtXml4.dll" "%TMP_PATH%"
 106         copy "%QTDIR%\bin\QtSvg4.dll" "%TMP_PATH%"
 107         mkdir "%TMP_PATH%\imageformats"
 108         copy "%QTDIR%\plugins\imageformats\q???4.dll" "%TMP_PATH%\imageformats"
 109 )
 110 REM ------------------------------------------
 111 for %%f in ("%TMP_PATH%\*.exe") do (
 112         "%PATH_UPXBIN%\upx.exe" --best "%%f"
 113 )
 114 for %%f in ("%TMP_PATH%\*.dll") do (
 115         "%PATH_UPXBIN%\upx.exe" --best "%%f"
 116 )
 117 REM ------------------------------------------
 118 if exist "%~dp0\_postproc.bat" (
 119         call "%~dp0\_postproc.bat" "%TMP_PATH%"
 120 )
 121 REM ------------------------------------------
 122 if "%LAMEXP_REDIST%"=="1" (
 123         copy "..\Redist\*.*" "%TMP_PATH%"
 124 )
 125 copy "%~dp0\..\..\ReadMe.txt" "%TMP_PATH%"
 126 copy "%~dp0\..\..\License.txt" "%TMP_PATH%"
 127 copy "%~dp0\..\..\doc\Changelog.html" "%TMP_PATH%"
 128 copy "%~dp0\..\..\doc\Translate.html" "%TMP_PATH%"
 129 copy "%~dp0\..\..\doc\FAQ.html" "%TMP_PATH%"
 130 REM ------------------------------------------
 131 REM :: CREATE PACKAGES ::
 132 REM ------------------------------------------
 133 "%PATH_SEVENZ%\7z.exe" a -tzip -r "%OUT_FILE%.zip" "%TMP_PATH%\*"
 134 "%PATH_MKNSIS%\makensis.exe" "/DLAMEXP_UPX_PATH=%PATH_UPXBIN%" "/DLAMEXP_DATE=%ISO_DATE%" "/DLAMEXP_VERSION=%VER_LAMEXP_MAJOR%.%VER_LAMEXP_MINOR_HI%%VER_LAMEXP_MINOR_LO%" "/DLAMEXP_BUILD=%VER_LAMEXP_BUILD%" "/DLAMEXP_INSTTYPE=%VER_LAMEXP_TYPE%" "/DLAMEXP_PATCH=%VER_LAMEXP_PATCH%" "/DLAMEXP_OUTPUT_FILE=%OUT_FILE%.sfx" "/DLAMEXP_SOURCE_PATH=%TMP_PATH%" "%~dp0\..\NSIS\setup.nsi"
 135 "%PATH_MKNSIS%\makensis.exe" "/DLAMEXP_UPX_PATH=%PATH_UPXBIN%" "/DLAMEXP_DATE=%ISO_DATE%" "/DLAMEXP_VERSION=%VER_LAMEXP_MAJOR%.%VER_LAMEXP_MINOR_HI%%VER_LAMEXP_MINOR_LO%" "/DLAMEXP_BUILD=%VER_LAMEXP_BUILD%" "/DLAMEXP_INSTTYPE=%VER_LAMEXP_TYPE%" "/DLAMEXP_PATCH=%VER_LAMEXP_PATCH%" "/DLAMEXP_OUTPUT_FILE=%OUT_FILE%.exe" "/DLAMEXP_SOURCE_FILE=%OUT_FILE%.sfx" "%~dp0\..\NSIS\wrapper.nsi"
 136 rd /S /Q "%TMP_PATH%"
 137 REM ------------------------------------------
 138 if not exist "%OUT_FILE%.zip" (
 139         call "%~dp0\_error.bat" "PACKAGING HAS FAILED"
 140         GOTO:EOF
 141 )
 142 if not exist "%OUT_FILE%.exe" (
 143         call "%~dp0\_error.bat" "PACKAGING HAS FAILED"
 144         GOTO:EOF
 145 )
 146 REM ------------------------------------------
 147 attrib +R "%OUT_FILE%.zip"
 148 attrib +R "%OUT_FILE%.sfx"
 149 attrib +R "%OUT_FILE%.exe"
 150 REM ------------------------------------------
 151 REM :: CREATE SIGNATURE ::
 152 REM ------------------------------------------
 153 "%PATH_GNUPG1%\gpg.exe" --detach-sign "%OUT_FILE%.exe"
 154 attrib +R "%OUT_FILE%.exe.sig"
 155 REM ------------------------------------------
 156 echo.
 157 echo BUIDL COMPLETED SUCCESSFULLY :-)
 158 echo.
 159 REM ------------------------------------------
 160 pause