etc/Deployment/_paths.bat

   1 @echo off
   2
   3 :: ------------------------------------------
   4 :: Paths already initialized?
   5 :: ------------------------------------------
   6
   7 if "%_LAMEXP_PATH_INIT%"=="%DATE%" (
   8         goto:eof
   9 )
  10
  11 :: ------------------------------------------
  12 :: Clear Paths
  13 :: ------------------------------------------
  14
  15 set "PATH_MSCDIR="
  16 set "PATH_QTMSVC="
  17 set "PATH_GITWIN="
  18 set "PATH_VCTOOL="
  19 set "PATH_VCPROJ="
  20
  21 :: ------------------------------------------
  22 :: Setup BUILDENV_TXT
  23 :: ------------------------------------------
  24
  25 set "BUILDENV_TXT=%~dp0\buildenv.txt"
  26 if not "%~1"=="" (
  27         set "BUILDENV_TXT=%~1"
  28 )
  29
  30 if not exist "%BUILDENV_TXT%" (
  31         "%~dp0\..\..\..\Prerequisites\CEcho\cecho.exe" red "\nCould not find \"buildenv.txt\" in current directory!\n\nPlease create your \"buildenv.txt\" file from 'buildenv.template.txt' first...\n"
  32         pause && exit
  33 )
  34
  35 :: ------------------------------------------
  36 :: Parse paths from BUILDENV_TXT
  37 :: ------------------------------------------
  38
  39 for /f "tokens=2,*" %%s in (%BUILDENV_TXT%) do (
  40         if "%%s"=="PATH_MSCDIR" set "PATH_MSCDIR=%%~t"
  41         if "%%s"=="PATH_QTMSVC" set "PATH_QTMSVC=%%~t"
  42         if "%%s"=="PATH_GITWIN" set "PATH_GITWIN=%%~t"
  43         if "%%s"=="PATH_VCTOOL" set "PATH_VCTOOL=%%~t"
  44         if "%%s"=="PATH_VCPROJ" set "PATH_VCPROJ=%%~t"
  45 )
  46
  47 set "BUILDENV_TXT="
  48
  49 :: ------------------------------------------
  50 :: Print all paths
  51 :: ------------------------------------------
  52
  53 "%~dp0\..\..\..\Prerequisites\CEcho\cecho.exe" yellow "\n========== BEGIN PATHS =========="
  54 "%~dp0\..\..\..\Prerequisites\CEcho\cecho.exe" yellow "PATH_MSCDIR = \"%PATH_MSCDIR:\=\\%\""
  55 "%~dp0\..\..\..\Prerequisites\CEcho\cecho.exe" yellow "PATH_QTMSVC = \"%PATH_QTMSVC:\=\\%\""
  56 "%~dp0\..\..\..\Prerequisites\CEcho\cecho.exe" yellow "PATH_GITWIN = \"%PATH_GITWIN:\=\\%\""
  57 "%~dp0\..\..\..\Prerequisites\CEcho\cecho.exe" yellow "PATH_VCTOOL = \"%PATH_VCTOOL:\=\\%\""
  58 "%~dp0\..\..\..\Prerequisites\CEcho\cecho.exe" yellow "PATH_VCPROJ = \"%PATH_VCPROJ:\=\\%\""
  59 "%~dp0\..\..\..\Prerequisites\CEcho\cecho.exe" yellow "=========== END PATHS ===========\n"
  60
  61 :: ------------------------------------------
  62 :: Validate Paths
  63 :: ------------------------------------------
  64
  65 call:validate_path PATH_MSCDIR "%PATH_MSCDIR%\vcvarsall.bat"
  66 call:validate_path PATH_QTMSVC "%PATH_QTMSVC%\bin\uic.exe"
  67 call:validate_path PATH_QTMSVC "%PATH_QTMSVC%\bin\moc.exe"
  68 call:validate_path PATH_QTMSVC "%PATH_QTMSVC%\bin\rcc.exe"
  69 call:validate_path PATH_GITWIN "%PATH_GITWIN%\bin\git.exe"
  70 call:validate_path PATH_VCPROJ "%~dp0\..\..\%PATH_VCPROJ%"
  71
  72 :: ------------------------------------------
  73 :: Locate Qt Path
  74 :: ------------------------------------------
  75
  76 if exist "%PATH_QTMSVC%\bin\qtvars.bat" goto:path_success
  77 if exist "%PATH_QTMSVC%\bin\qtenv2.bat" goto:path_success
  78
  79 "%~dp0\..\..\..\Prerequisites\CEcho\cecho.exe" red "\nCould not find \"qtvars.bat\" or \"qtenv2.bat\" in your Qt path!\n\nPlease check your PATH_QTMSVC path variable and try again...\n"
  80 pause && exit
  81
  82 :: ------------------------------------------
  83 :: Validate Path
  84 :: ------------------------------------------
  85
  86 :validate_path
  87 if not exist "%~2" (
  88         "%~dp0\..\..\..\Prerequisites\CEcho\cecho.exe" red "\nPath %1 could not be found!\n\nPlease check your %1 path variable and try again...\n"
  89         pause && exit
  90 )
  91 goto:eof
  92
  93 :: ------------------------------------------
  94 :: Completed
  95 :: ------------------------------------------
  96
  97 :path_success
  98 set "_LAMEXP_PATH_INIT=%DATE%"