etc/NSIS/wrapper.nsi

   1 ; ///////////////////////////////////////////////////////////////////////////////
   2 ; // LameXP - Audio Encoder Front-End
   3 ; // Copyright (C) 2004-2014 LoRd_MuldeR <MuldeR2@GMX.de>
   4 ; //
   5 ; // This program is free software; you can redistribute it and/or modify
   6 ; // it under the terms of the GNU General Public License as published by
   7 ; // the Free Software Foundation; either version 2 of the License, or
   8 ; // (at your option) any later version.
   9 ; //
  10 ; // This program is distributed in the hope that it will be useful,
  11 ; // but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 ; // MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 ; // GNU General Public License for more details.
  14 ; //
  15 ; // You should have received a copy of the GNU General Public License along
  16 ; // with this program; if not, write to the Free Software Foundation, Inc.,
  17 ; // 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  18 ; //
  19 ; // http://www.gnu.org/licenses/gpl-2.0.txt
  20 ; ///////////////////////////////////////////////////////////////////////////////
  21
  22 ;--------------------------------
  23 ;Basic Defines
  24 ;--------------------------------
  25
  26 !ifndef LAMEXP_VERSION
  27   !error "LAMEXP_VERSION is not defined !!!"
  28 !endif
  29 !ifndef LAMEXP_BUILD
  30   !error "LAMEXP_BUILD is not defined !!!"
  31 !endif
  32 !ifndef LAMEXP_INSTTYPE
  33   !error "LAMEXP_INSTTYPE is not defined !!!"
  34 !endif
  35 !ifndef LAMEXP_PATCH
  36   !error "LAMEXP_PATCH is not defined !!!"
  37 !endif
  38 !ifndef LAMEXP_DATE
  39   !error "LAMEXP_DATE is not defined !!!"
  40 !endif
  41 !ifndef LAMEXP_OUTPUT_FILE
  42   !error "LAMEXP_OUTPUT_FILE is not defined !!!"
  43 !endif
  44 !ifndef LAMEXP_SOURCE_FILE
  45   !error "LAMEXP_SOURCE_FILE is not defined !!!"
  46 !endif
  47 !ifndef LAMEXP_UPX_PATH
  48   !error "LAMEXP_UPX_PATH is not defined !!!"
  49 !endif
  50
  51 ;Web-Site
  52 !define MyWebSite "http://mulder.at.gg/"
  53
  54 ;Installer file name
  55 !define InstallerFileName "$PLUGINSDIR\LameXP-SETUP-r${LAMEXP_BUILD}.exe"
  56
  57 ;--------------------------------
  58 ;Includes
  59 ;--------------------------------
  60
  61 !include `LogicLib.nsh`
  62 !include `StdUtils.nsh`
  63
  64
  65 ;--------------------------------
  66 ;Installer Attributes
  67 ;--------------------------------
  68
  69 XPStyle on
  70 RequestExecutionLevel user
  71 InstallColors /windows
  72 Name "LameXP v${LAMEXP_VERSION} ${LAMEXP_INSTTYPE}-${LAMEXP_PATCH} [Build #${LAMEXP_BUILD}]"
  73 OutFile "${LAMEXP_OUTPUT_FILE}"
  74 BrandingText "${LAMEXP_DATE} / Build #${LAMEXP_BUILD}"
  75 Icon "${NSISDIR}\Contrib\Graphics\Icons\orange-install.ico"
  76 ChangeUI all "${NSISDIR}\Contrib\UIs\sdbarker_tiny.exe"
  77 ShowInstDetails show
  78 AutoCloseWindow true
  79 InstallDir ""
  80
  81
  82 ;--------------------------------
  83 ;Page Captions
  84 ;--------------------------------
  85
  86 SubCaption 0 " "
  87 SubCaption 1 " "
  88 SubCaption 2 " "
  89 SubCaption 3 " "
  90 SubCaption 4 " "
  91
  92
  93 ;--------------------------------
  94 ;Compressor
  95 ;--------------------------------
  96
  97 !packhdr "$%TEMP%\exehead.tmp" '"${LAMEXP_UPX_PATH}\upx.exe" --brute "$%TEMP%\exehead.tmp"'
  98
  99
 100 ;--------------------------------
 101 ;Reserved Files
 102 ;--------------------------------
 103
 104 ReserveFile "${NSISDIR}\Plugins\System.dll"
 105 ReserveFile "${NSISDIR}\Plugins\StdUtils.dll"
 106
 107
 108 ;--------------------------------
 109 ;Version Info
 110 ;--------------------------------
 111
 112 !searchreplace PRODUCT_VERSION_DATE "${LAMEXP_DATE}" "-" "."
 113 VIProductVersion "${PRODUCT_VERSION_DATE}.${LAMEXP_BUILD}"
 114
 115 VIAddVersionKey "Author" "LoRd_MuldeR <mulder2@gmx.de>"
 116 VIAddVersionKey "Comments" "This program is free software; you can redistribute it and/or modify it under the terms of the GNU General Public License as published by the Free Software Foundation; either version 2 of the License, or (at your option) any later version."
 117 VIAddVersionKey "CompanyName" "Free Software Foundation"
 118 VIAddVersionKey "FileDescription" "LameXP v${LAMEXP_VERSION} ${LAMEXP_INSTTYPE}-${LAMEXP_PATCH} [Build #${LAMEXP_BUILD}]"
 119 VIAddVersionKey "FileVersion" "${PRODUCT_VERSION_DATE}.${LAMEXP_BUILD} (${LAMEXP_VERSION})"
 120 VIAddVersionKey "LegalCopyright" "Copyright 2004-2014 LoRd_MuldeR"
 121 VIAddVersionKey "LegalTrademarks" "GNU"
 122 VIAddVersionKey "OriginalFilename" "LameXP.${LAMEXP_DATE}.Build-${LAMEXP_BUILD}.exe"
 123 VIAddVersionKey "ProductName" "LameXP - Audio Encoder Frontend"
 124 VIAddVersionKey "ProductVersion" "${LAMEXP_VERSION}, Build #${LAMEXP_BUILD} (${LAMEXP_DATE})"
 125 VIAddVersionKey "Website" "${MyWebSite}"
 126
 127
 128 ;--------------------------------
 129 ;Installer initialization
 130 ;--------------------------------
 131
 132 Section "-LaunchTheInstaller"
 133         SetDetailsPrint textonly
 134         DetailPrint "Launching installer, please stay tuned..."
 135         SetDetailsPrint listonly
 136
 137         InitPluginsDir
 138         SetOutPath "$PLUGINSDIR"
 139
 140         SetOverwrite on
 141         File "/oname=${InstallerFileName}" "${LAMEXP_SOURCE_FILE}"
 142
 143         ; --------
 144
 145         ${If} "$EXEFILE" == "LameXP.exe"
 146         ${OrIf} "$EXEFILE" == "LameXP-Portable.exe"
 147                 MessageBox MB_ICONSTOP|MB_TOPMOST "Sorry, you must NOT rename the LameXP installation program to 'LameXP.exe' or 'LameXP-Portable.exe'. Please re-rename the installer executable file (e.g. to 'LameXP-Setup.exe') and then try again!"
 148                 Quit
 149         ${EndIf}
 150
 151         ; --------
 152
 153         ${StdUtils.GetAllParameters} $R9 0
 154         ${IfThen} "$R9" == "too_long" ${|} StrCpy $R9 "" ${|}
 155
 156         ${IfNot} "$R9" == ""
 157                 DetailPrint "Parameters: $R9"
 158         ${EndIf}
 159
 160         ; --------
 161
 162         ${Do}
 163                 SetOverwrite ifdiff
 164                 File "/oname=${InstallerFileName}" "${LAMEXP_SOURCE_FILE}"
 165
 166                 DetailPrint "ExecShellWait: ${InstallerFileName}"
 167                 ${StdUtils.ExecShellWaitEx} $R1 $R2 "${InstallerFileName}" "open" '$R9'
 168                 DetailPrint "Result: $R1 ($R2)"
 169
 170                 ${IfThen} $R1 == "no_wait" ${|} Goto RunSuccess ${|}
 171
 172                 ${If} $R1 == "ok"
 173                         Sleep 333
 174                         HideWindow
 175                         ${StdUtils.WaitForProcEx} $R1 $R2
 176                         Goto RunSuccess
 177                 ${EndIf}
 178
 179                 MessageBox MB_RETRYCANCEL|MB_ICONSTOP|MB_TOPMOST "Failed to launch the installer. Please try again!" IDCANCEL FallbackMode
 180         ${Loop}
 181
 182
 183         ; -----------
 184
 185         FallbackMode:
 186
 187         DetailPrint "Installer not launched yet, trying fallback mode!"
 188
 189         SetOverwrite ifdiff
 190         File "/oname=${InstallerFileName}" "${LAMEXP_SOURCE_FILE}"
 191
 192         ClearErrors
 193         ExecShell "open" "${InstallerFileName}" '$R9' SW_SHOWNORMAL
 194         IfErrors 0 RunSuccess
 195
 196         ClearErrors
 197         ExecShell "" "${InstallerFileName}" '$R9' SW_SHOWNORMAL
 198         IfErrors 0 RunSuccess
 199
 200         ; --------
 201
 202         SetDetailsPrint both
 203         DetailPrint "Failed to launch installer :-("
 204         SetDetailsPrint listonly
 205
 206         SetErrorLevel 1
 207         Abort "Aborted."
 208
 209         ; --------
 210
 211         RunSuccess:
 212
 213         Delete /REBOOTOK "${InstallerFileName}"
 214         SetErrorLevel 0
 215 SectionEnd