ffmpeg/libavcodec/arm/ac3dsp_armv6.S

   1 /*
   2  * Copyright (c) 2011 Mans Rullgard <mans@mansr.com>
   3  *
   4  * This file is part of Libav.
   5  *
   6  * Libav is free software; you can redistribute it and/or
   7  * modify it under the terms of the GNU Lesser General Public
   8  * License as published by the Free Software Foundation; either
   9  * version 2.1 of the License, or (at your option) any later version.
  10  *
  11  * Libav is distributed in the hope that it will be useful,
  12  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  13  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14  * Lesser General Public License for more details.
  15  *
  16  * You should have received a copy of the GNU Lesser General Public
  17  * License along with Libav; if not, write to the Free Software
  18  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
  19  */
  20
  21 #include "asm.S"
  22
  23 function ff_ac3_bit_alloc_calc_bap_armv6, export=1
  24         ldr             r12, [sp]
  25         cmp             r12, #-960
  26         beq             4f
  27         push            {r4-r11,lr}
  28         add             r5,  sp,  #40
  29         movrel          r4,  X(ff_ac3_bin_to_band_tab)
  30         movrel          lr,  X(ff_ac3_band_start_tab)
  31         ldm             r5,  {r5-r7}
  32         ldrb            r4,  [r4, r2]
  33         add             r1,  r1,  r2,  lsl #1           @ psd + start
  34         add             r0,  r0,  r4,  lsl #1           @ mask + band
  35         add             r4,  lr,  r4
  36         add             r7,  r7,  r2                    @ bap + start
  37         ldrb            r10, [r4], #1
  38 1:
  39         ldrsh           r9,  [r0], #2                   @ mask[band]
  40         mov             r8,  #0xff0
  41         sub             r9,  r9,  r12                   @   - snr_offset
  42         mov             r11, r10
  43         ldrb            r10, [r4], #1                   @ band_start_tab[band++]
  44         subs            r9,  r9,  r5                    @   - floor
  45         it              lt
  46         movlt           r9,  #0
  47         cmp             r10, r3                         @   - end
  48         and             r9,  r9,  r8, lsl #1            @   & 0x1fe0
  49         ite             gt
  50         subgt           r8,  r3,  r11
  51         suble           r8,  r10, r11
  52         add             r9,  r9,  r5                    @   + floor => m
  53         tst             r8,  #1
  54         add             r2,  r7,  r8
  55         bne             3f
  56         b               5f
  57 2:
  58         ldrsh           r8,  [r1], #2
  59         ldrsh           lr,  [r1], #2
  60         sub             r8,  r8,  r9
  61         sub             lr,  lr,  r9
  62         usat            r8,  #6,  r8,  asr #5           @ address
  63         usat            lr,  #6,  lr,  asr #5
  64         ldrb            r8,  [r6, r8]                   @ bap_tab[address]
  65         ldrb            lr,  [r6, lr]
  66         strb            r8,  [r7], #1                   @ bap[bin]
  67         strb            lr,  [r7], #1
  68 5:      cmp             r7,  r2
  69         blo             2b
  70         cmp             r3,  r11
  71         bgt             1b
  72         pop             {r4-r11,pc}
  73 3:
  74         ldrsh           r8,  [r1], #2                   @ psd[bin]
  75         sub             r8,  r8,  r9                    @   - m
  76         usat            r8,  #6,  r8,  asr #5           @ address
  77         ldrb            r8,  [r6, r8]                   @ bap_tab[address]
  78         strb            r8,  [r7], #1                   @ bap[bin]
  79         b               5b
  80 4:
  81         ldr             r0,  [sp, #12]
  82         mov             r1,  #0
  83         mov             r2,  #256
  84         b               X(memset)
  85 endfunc