gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 dnl v2.5 needed for --bindir et al
   8 AC_PREREQ(2.13)
   9 AC_INIT(as.h)
  10
  11 AC_CANONICAL_SYSTEM
  12 AC_ISC_POSIX
  13
  14 changequote(,)dnl
  15 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  16 changequote([,])dnl
  17 AM_INIT_AUTOMAKE(gas, ${BFD_VERSION})
  18
  19 AM_PROG_LIBTOOL
  20
  21 user_bfd_gas=
  22 AC_ARG_ENABLE(bfd-assembler,
  23 [  --enable-bfd-assembler  use BFD back end for writing object files],
  24 [case "${enableval}" in
  25   yes) need_bfd=yes user_bfd_gas=yes ;;
  26   no)  user_bfd_gas=no ;;
  27   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  28 esac])dnl
  29 AC_ARG_ENABLE(targets,
  30 [    targets            alternative target configurations besides the primary],
  31 [case "${enableval}" in
  32   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  33             ;;
  34   no)       enable_targets= ;;
  35   *)        enable_targets=$enableval ;;
  36 esac])dnl
  37 AC_ARG_ENABLE(commonbfdlib,
  38 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  39 [case "${enableval}" in
  40   yes) commonbfdlib=true ;;
  41   no)  commonbfdlib=false ;;
  42   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  43 esac])dnl
  44
  45 using_cgen=no
  46
  47 build_warnings="-W -Wall -Wstrict-prototypes -Wmissing-prototypes"
  48 AC_ARG_ENABLE(build-warnings,
  49 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  50 [case "${enableval}" in
  51   yes)  ;;
  52   no)   build_warnings="-w";;
  53   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  54         build_warnings="${build_warnings} ${t}";;
  55   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  56         build_warnings="${t} ${build_warnings}";;
  57   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  58 esac
  59 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  60   echo "Setting warning flags = $build_warnings" 6>&1
  61 fi])dnl
  62 WARN_CFLAGS=""
  63 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
  64     WARN_CFLAGS="${build_warnings}"
  65 fi
  66 AC_SUBST(WARN_CFLAGS)
  67
  68 # Generate a header file
  69 AM_CONFIG_HEADER(config.h:config.in)
  70
  71 # If we are on a DOS filesystem, we must use gdb.ini rather than
  72 # .gdbinit.
  73 GDBINIT=".gdbinit"
  74 case "${host}" in
  75   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-windows*)
  76     GDBINIT="gdb.ini"
  77     ;;
  78 esac
  79 AC_SUBST(GDBINIT)
  80
  81 te_file=generic
  82
  83 # Makefile target for installing gas in $(tooldir)/bin.
  84 install_tooldir=install-exec-tooldir
  85
  86 canon_targets=""
  87 all_targets=no
  88 if test -n "$enable_targets" ; then
  89   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  90     if test $t = "all"; then
  91       all_targets=yes
  92       continue
  93     fi
  94     result=`$ac_config_sub $t 2>/dev/null`
  95     if test -n "$result" ; then
  96       canon_targets="$canon_targets $result"
  97 #    else
  98 #      # Permit "all", etc.  We don't support it yet though.
  99 #      canon_targets="$canon_targets $t"
 100     fi
 101   done
 102   GAS_UNIQ(canon_targets)
 103 fi
 104
 105 emulations=""
 106
 107 for this_target in $target $canon_targets ; do
 108
 109 changequote(,)dnl
 110     eval `echo $this_target | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/cpu=\1 vendor=\2 os=\3/'`
 111 changequote([,])dnl
 112
 113     # check for architecture variants
 114     arch=
 115     endian=
 116     case ${cpu} in
 117       alpha*)           cpu_type=alpha ;;
 118       arm*b|xscale*b|strongarm*b) cpu_type=arm endian=big ;;
 119       arm*|xscale*|strongarm*)    cpu_type=arm endian=little ;;
 120       hppa*)            cpu_type=hppa ;;
 121 changequote(,)dnl
 122       i[3-7]86)         cpu_type=i386 arch=i386;;
 123       x86_64)           cpu_type=i386 arch=x86_64;;
 124       ia64)             cpu_type=ia64 ;;
 125       ip2k)             cpu_type=ip2k endian=big ;;
 126       iq2000)           cpu_type=iq2000 endian=big ;;
 127       m6811|m6812|m68hc12) cpu_type=m68hc11 ;;
 128       m680[012346]0)    cpu_type=m68k ;;
 129 changequote([,])dnl
 130       m68008)           cpu_type=m68k ;;
 131       m683??)           cpu_type=m68k ;;
 132       m5200)            cpu_type=m68k ;;
 133       m8*)              cpu_type=m88k ;;
 134       mips*el)          cpu_type=mips endian=little ;;
 135       mips*)            cpu_type=mips endian=big ;;
 136       or32*)            cpu_type=or32 endian=big ;;
 137       pjl*)             cpu_type=pj endian=little ;;
 138       pj*)              cpu_type=pj endian=big ;;
 139       powerpc*le*)      cpu_type=ppc endian=little ;;
 140       powerpc*)         cpu_type=ppc endian=big ;;
 141       rs6000*)          cpu_type=ppc ;;
 142       s390x*)           cpu_type=s390 arch=s390x ;;
 143       s390*)            cpu_type=s390 arch=s390 ;;
 144       sh5*)             cpu_type=sh64 endian=big ;;
 145       sh5le*)           cpu_type=sh64 endian=little ;;
 146       sh64*)            cpu_type=sh64 endian=big ;;
 147       sh64le*)          cpu_type=sh64 endian=little ;;
 148       sh*le)            cpu_type=sh endian=little ;;
 149       sh*)              cpu_type=sh endian=big ;;
 150       sparclite*)       cpu_type=sparc arch=sparclite ;;
 151       sparclet*)        cpu_type=sparc arch=sparclet ;;
 152       sparc64*)         cpu_type=sparc arch=v9-64 ;;
 153       sparc86x*)        cpu_type=sparc arch=sparc86x  ;;
 154       sparc*)           cpu_type=sparc arch=sparclite ;; # ??? See tc-sparc.c.
 155       v850*)            cpu_type=v850 ;;
 156       xtensa*)          cpu_type=xtensa arch=xtensa ;;
 157       *)                cpu_type=${cpu} ;;
 158     esac
 159
 160     if test ${this_target} = $target ; then
 161       target_cpu_type=${cpu_type}
 162     elif test ${target_cpu_type} != ${cpu_type} ; then
 163       continue
 164     fi
 165
 166     generic_target=${cpu_type}-$vendor-$os
 167     dev=no
 168     bfd_gas=no
 169     em=generic
 170
 171     # assign object format
 172     case ${generic_target} in
 173       a29k-*-coff)                      fmt=coff ;;
 174       a29k-amd-udi)                     fmt=coff ;;
 175       a29k-amd-ebmon)                   fmt=coff ;;
 176       a29k-nyu-sym1)                    fmt=coff ;;
 177       a29k-*-rtems*)                    fmt=coff ;;
 178       a29k-*-vxworks*)                  fmt=coff ;;
 179
 180       alpha*-*-*vms*)                   fmt=evax ;;
 181       alpha*-*-netware*)                fmt=ecoff ;;
 182       alpha*-*-osf*)                    fmt=ecoff ;;
 183       alpha*-*-linuxecoff*)             fmt=ecoff ;;
 184       alpha*-*-linux-gnu*)              fmt=elf em=linux ;;
 185       alpha*-*-netbsd*)                 fmt=elf em=nbsd ;;
 186       alpha*-*-openbsd*)                fmt=elf em=obsd ;;
 187
 188       arc-*-elf*)                       fmt=elf ;;
 189
 190       arm-*-aout)                       fmt=aout ;;
 191       arm-*-coff | thumb-*-coff)        fmt=coff ;;
 192       arm-*-rtems | thumb-*-rtems)      fmt=elf ;;
 193       arm-*-elf | thumb-*-elf)          fmt=elf ;;
 194       arm-*-kaos*)                      fmt=elf ;;
 195       arm*-*-conix*)                    fmt=elf ;;
 196       arm-*-linux*aout*)                fmt=aout em=linux ;;
 197       arm*-*-linux-gnu*)                fmt=elf  em=linux ;;
 198       arm*-*-uclinux*)                  fmt=elf  em=linux ;;
 199       arm-*-netbsdelf*)                 fmt=elf  em=nbsd ;;
 200       arm-*-*n*bsd*)                    fmt=aout em=nbsd ;;
 201       arm-**-nto*)                      fmt=elf ;;
 202       arm-*-oabi | thumb-*-oabi)        fmt=elf ;;
 203       arm-epoc-pe | thumb-epoc-pe)      fmt=coff em=epoc-pe ;;
 204       arm-*-wince)                      fmt=coff em=wince-pe ;;
 205       arm-*-pe | thumb-*-pe)            fmt=coff em=pe ;;
 206       arm-*-riscix*)                    fmt=aout em=riscix ;;
 207       arm-*-vxworks)                    fmt=coff ;;
 208
 209       avr-*-*)                          fmt=elf ;;
 210
 211       cris-*-*)                         fmt=multi bfd_gas=yes ;;
 212
 213       d10v-*-*)                         fmt=elf ;;
 214       d30v-*-*)                         fmt=elf ;;
 215       dlx-*-*)                          fmt=elf ;;
 216
 217       fr30-*-*)                         fmt=elf ;;
 218       frv-*-*)                          fmt=elf ;;
 219
 220       hppa-*-linux*)    case ${cpu} in
 221                             hppa*64*)   fmt=elf em=hppalinux64;;
 222                             hppa*)      fmt=elf em=linux;;
 223                         esac ;;
 224       hppa-*-*elf*)                     fmt=elf em=hppa ;;
 225       hppa-*-lites*)                    fmt=elf em=hppa ;;
 226       hppa-*-netbsd*)                   fmt=elf em=nbsd ;;
 227       hppa-*-openbsd*)                  fmt=elf em=hppa ;;
 228       hppa-*-osf*)                      fmt=som em=hppa ;;
 229       hppa-*-rtems*)                    fmt=elf em=hppa ;;
 230       hppa-*-hpux11*)   case ${cpu} in
 231                             hppa*64*)   fmt=elf em=hppa64 ;;
 232                             hppa*)      fmt=som em=hppa ;;
 233                         esac ;;
 234       hppa-*-hpux*)                     fmt=som em=hppa ;;
 235       hppa-*-mpeix*)                    fmt=som em=hppa ;;
 236       hppa-*-bsd*)                      fmt=som em=hppa ;;
 237       hppa-*-hiux*)                     fmt=som em=hppa ;;
 238
 239       h8300-*-rtems*)                   fmt=coff ;;
 240       h8300-*-coff)                     fmt=coff ;;
 241       h8300-*-elf)                      fmt=elf ;;
 242       h8500-*-rtems*)                   fmt=coff ;;
 243       h8500-*-coff)                     fmt=coff ;;
 244
 245       i370-*-elf* | i370-*-linux*)      fmt=elf ;;
 246       i386-ibm-aix*)                    fmt=coff em=i386aix ;;
 247       i386-sequent-bsd*)                fmt=aout em=dynix ;;
 248       i386-*-beospe*)                   fmt=coff em=pe ;;
 249       i386-*-beos*)                     fmt=elf ;;
 250       i386-*-coff)                      fmt=coff ;;
 251       i386-*-elf)                       fmt=elf ;;
 252       i386-*-kaos*)                     fmt=elf ;;
 253       i386-*-bsd*)                      fmt=aout em=386bsd ;;
 254       i386-*-netbsd0.8)                 fmt=aout em=386bsd ;;
 255       i386-*-netbsdpe*)                 fmt=coff em=pe ;;
 256       i386-*-netbsdelf*)                fmt=elf em=nbsd ;;
 257       i386-*-*n*bsd*)   case ${cpu} in
 258                             x86_64)     fmt=elf em=nbsd ;;
 259                             *)          fmt=aout em=nbsd ;;
 260                         esac ;;
 261       i386-*-linux*aout*)               fmt=aout em=linux ;;
 262       i386-*-linux*oldld)               fmt=aout em=linux ;;
 263       i386-*-linux*coff*)               fmt=coff em=linux ;;
 264       i386-*-linux-gnu*)                fmt=elf em=linux ;;
 265       x86_64-*-linux-gnu*)              fmt=elf em=linux ;;
 266       i386-*-lynxos*)                   fmt=coff em=lynx ;;
 267 changequote(,)dnl
 268       i386-*-sysv[45]*)                 fmt=elf ;;
 269       i386-*-solaris*)                  fmt=elf ;;
 270       i386-*-freebsdaout*)              fmt=aout em=386bsd ;;
 271       i386-*-freebsd[12].*)             fmt=aout em=386bsd ;;
 272       i386-*-freebsd[12])               fmt=aout em=386bsd ;;
 273 changequote([,])dnl
 274       i386-*-sysv*)                     fmt=coff ;;
 275       i386-*-sco3.2v5*coff)             fmt=coff ;;
 276       i386-*-isc*)                      fmt=coff ;;
 277       i386-*-sco3.2v5*)                 fmt=elf
 278           if test ${this_target} = $target; then
 279             AC_DEFINE(SCO_ELF, 1, [Define if defaulting to ELF on SCO 5.])
 280           fi ;;
 281       i386-*-sco3.2*)                   fmt=coff ;;
 282       i386-*-vsta)                      fmt=aout ;;
 283       i386-*-msdosdjgpp* \
 284       | i386-*-go32* \
 285       | i386-go32-rtems*)               fmt=coff em=go32
 286             AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?]) ;;
 287       i386-*-rtemself*)                 fmt=elf ;;
 288       i386-*-rtemscoff*)                fmt=coff ;;
 289       i386-*-rtems*)                    fmt=elf ;;
 290       i386-*-gnu*)                      fmt=elf ;;
 291       i386-*-mach*)                     fmt=aout em=mach ;;
 292       i386-*-msdos*)                    fmt=aout ;;
 293       i386-*-moss*)                     fmt=elf ;;
 294       i386-*-pe)                        fmt=coff em=pe ;;
 295       i386-*-cygwin*)                   fmt=coff em=pe ;;
 296       i386-*-interix*)                  fmt=coff em=interix ;;
 297       i386-*-mingw32*)                  fmt=coff em=pe ;;
 298       i386-*-nto-qnx*)                  fmt=elf ;;
 299       i386-*-*nt*)                      fmt=coff em=pe ;;
 300       i386-*-vxworks*)                  fmt=aout ;;
 301       i386-*-chaos)                     fmt=elf ;;
 302
 303       i860-*-*)                         fmt=elf endian=little
 304                 AC_MSG_WARN(GAS support for ${generic_target} is preliminary and a work in progress) ;;
 305       i960-*-bout)                      fmt=bout ;;
 306       i960-*-coff)                      fmt=coff em=ic960 ;;
 307       i960-*-rtems*)                    fmt=coff em=ic960 ;;
 308       i960-*-nindy*)                    fmt=bout ;;
 309       i960-*-vxworks5.0)                fmt=bout ;;
 310       i960-*-vxworks5.*)                fmt=coff em=ic960 ;;
 311       i960-*-vxworks*)                  fmt=bout ;;
 312       i960-*-elf*)                      fmt=elf ;;
 313
 314       ia64-*-elf*)                      fmt=elf ;;
 315       ia64-*-aix*)                      fmt=elf em=ia64aix ;;
 316       ia64-*-linux-gnu*)                fmt=elf em=linux ;;
 317       ia64-*-hpux*)                     fmt=elf em=hpux ;;
 318       ia64-*-netbsd*)                   fmt=elf em=nbsd ;;
 319
 320       ip2k-*-*)                         fmt=elf ;;
 321
 322       iq2000-*-elf)                     fmt=elf bfd_gas=yes ;;
 323
 324       m32r-*-*)                         fmt=elf ;;
 325
 326       m68hc11-*-* | m6811-*-*)          fmt=elf ;;
 327       m68hc12-*-* | m6812-*-*)          fmt=elf ;;
 328
 329       m68k-*-vxworks*)                  fmt=aout em=sun3 ;;
 330       m68k-ericsson-ose)                fmt=aout em=sun3 ;;
 331       m68k-*-sunos*)                    fmt=aout em=sun3 ;;
 332       m68k-motorola-sysv*)              fmt=coff em=delta ;;
 333       m68k-bull-sysv3*)                 fmt=coff em=dpx2 ;;
 334       m68k-apollo-*)                    fmt=coff em=apollo ;;
 335       m68k-*-elf*)                      fmt=elf ;;
 336       m68k-*-sysv4*)                    fmt=elf em=svr4 ;;
 337       m68k-*-sysv*)                     fmt=coff ;;
 338       m68k-*-coff | m68k-*-rtemscoff*)  fmt=coff ;;
 339       m68k-*-rtems*)                    fmt=elf ;;
 340       m68k-*-hpux*)                     fmt=hp300 em=hp300 ;;
 341       m68k-*-linux*aout*)               fmt=aout em=linux ;;
 342       m68k-*-linux-gnu*)                fmt=elf em=linux ;;
 343       m68k-*-gnu*)                      fmt=elf ;;
 344       m68k-*-lynxos*)                   fmt=coff em=lynx ;;
 345       m68k-*-netbsdelf*)                fmt=elf em=nbsd ;;
 346       m68k-*-netbsd*)                   fmt=aout em=nbsd bfd_gas=yes ;;
 347       m68k-*-openbsd*)                  fmt=aout em=nbsd bfd_gas=yes ;;
 348       m68k-apple-aux*)                  fmt=coff em=aux ;;
 349       m68k-*-psos*)                     fmt=elf em=psos;;
 350
 351       m88k-motorola-sysv3*)             fmt=coff em=delt88 ;;
 352       m88k-*-coff*)                     fmt=coff ;;
 353
 354       mcore-*-elf)                      fmt=elf ;;
 355       mcore-*-pe)                       fmt=coff em=pe bfd_gas=yes ;;
 356
 357       # don't change em like *-*-bsd does
 358       mips-dec-openbsd*)                fmt=elf endian=little ;;
 359       mips-dec-bsd*)                    fmt=aout endian=little ;;
 360       mips-sony-bsd*)                   fmt=ecoff ;;
 361       mips-*-bsd*)
 362             AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.) ;;
 363       mips-*-ultrix*)                   fmt=ecoff endian=little ;;
 364       mips-*-osf*)                      fmt=ecoff endian=little ;;
 365       mips-*-ecoff*)                    fmt=ecoff ;;
 366       mips-*-pe*)                       fmt=coff endian=little em=pe ;;
 367       mips-*-irix6*)                    fmt=elf em=irix ;;
 368       mips-*-irix5*)                    fmt=elf em=irix ;;
 369       mips-*-irix*)                     fmt=ecoff em=irix ;;
 370       mips-*-lnews*)                    fmt=ecoff em=lnews ;;
 371       mips-*-riscos*)                   fmt=ecoff ;;
 372       mips*-*-linux*)                   fmt=elf em=tmips ;;
 373       mips-*-sysv4*MP* | mips-*-gnu*)   fmt=elf em=tmips ;;
 374       mips-*-sysv*)                     fmt=ecoff ;;
 375       mips-*-elf* | mips-*-rtems*)      fmt=elf ;;
 376       mips-*-netbsd*)                   fmt=elf ;;
 377       mips-*-openbsd*)                  fmt=elf ;;
 378       mips-*-vxworks*)                  fmt=elf ;;
 379
 380       mmix-*-*)                         fmt=elf ;;
 381       mn10200-*-*)                      fmt=elf ;;
 382       mn10300-*-*)                      fmt=elf ;;
 383       msp430-*-*)                       fmt=elf ;;
 384       openrisc-*-*)                     fmt=elf ;;
 385       or32-*-rtems*)                    fmt=coff ;;
 386       or32-*-coff)                      fmt=coff ;;
 387       or32-*-elf)                       fmt=elf ;;
 388       pj*)                              fmt=elf ;;
 389
 390       ppc-*-pe | ppc-*-cygwin*)         fmt=coff em=pe ;;
 391       ppc-*-winnt*)                     fmt=coff em=pe ;;
 392       ppc-*-aix5*)                      fmt=coff em=aix5 ;;
 393       ppc-*-aix*)                       fmt=coff ;;
 394       ppc-*-beos*)                      fmt=coff ;;
 395       ppc-*-*n*bsd* | ppc-*-elf*)       fmt=elf ;;
 396       ppc-*-eabi* | ppc-*-sysv4*)       fmt=elf ;;
 397       ppc-*-linux-gnu*)                 fmt=elf
 398             case "$endian" in
 399                 big)  ;;
 400                 *)    AC_MSG_ERROR(GNU/Linux must be configured big endian) ;;
 401             esac ;;
 402       ppc-*-solaris*)                   fmt=elf
 403             if test ${this_target} = $target; then
 404                 AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 405                           [Define if default target is PowerPC Solaris.])
 406             fi
 407             if test x${endian} = xbig; then
 408                 AC_MSG_ERROR(Solaris must be configured little endian)
 409             fi ;;
 410       ppc-*-rtems*)                     fmt=elf ;;
 411       ppc-*-macos* | ppc-*-mpw*)        fmt=coff em=macos ;;
 412       ppc-*-netware*)                   fmt=elf em=ppcnw ;;
 413       ppc-**-nto*)                      fmt=elf ;;
 414       ppc-*-vxworks*)                   fmt=elf ;;
 415       ppc-*-windiss*)                   fmt=elf ;;
 416       ppc-*-kaos*)                      fmt=elf ;;
 417
 418       s390x-*-linux-gnu*)               fmt=elf em=linux ;;
 419       s390-*-linux-gnu*)                fmt=elf em=linux ;;
 420
 421       sh*-*-linux*)                     fmt=elf em=linux
 422             case ${cpu} in
 423                 sh*eb)  endian=big ;;
 424                 *)      endian=little ;;
 425             esac ;;
 426       sh5*-*-netbsd*)                   fmt=elf em=nbsd ;;
 427       sh64*-*-netbsd*)                  fmt=elf em=nbsd ;;
 428       sh*-*-netbsdelf*)                 fmt=elf em=nbsd ;;
 429       sh-*-elf*)                        fmt=elf ;;
 430       sh-*-coff*)                       fmt=coff ;;
 431       sh-*-nto*)                        fmt=elf ;;
 432       sh-*-pe*)                         fmt=coff em=pe bfd_gas=yes endian=little ;;
 433       sh-*-rtemself*)                   fmt=elf ;;
 434       sh-*-rtems*)                      fmt=coff ;;
 435       sh-*-kaos*)                       fmt=elf ;;
 436       shle*-*-kaos*)                    fmt=elf ;;
 437       sh64-*-elf*)                      fmt=elf ;;
 438
 439       ns32k-pc532-mach*)                fmt=aout em=pc532mach ;;
 440       ns32k-pc532-ux*)                  fmt=aout em=pc532mach ;;
 441       ns32k-pc532-lites*)               fmt=aout em=nbsd532 ;;
 442       ns32k-*-*n*bsd*)                  fmt=aout em=nbsd532 ;;
 443
 444       sparc-*-rtemsaout*)               fmt=aout ;;
 445       sparc-*-rtemself*)                fmt=elf ;;
 446       sparc-*-rtems*)                   fmt=elf ;;
 447       sparc-*-sunos4*)                  fmt=aout em=sun3 ;;
 448       sparc-*-aout | sparc*-*-vxworks*) fmt=aout em=sparcaout ;;
 449       sparc-*-coff)                     fmt=coff ;;
 450       sparc-*-linux*aout*)              fmt=aout em=linux ;;
 451       sparc-*-linux-gnu*)               fmt=elf em=linux ;;
 452       sparc-*-lynxos*)                  fmt=coff em=lynx ;;
 453       sparc-fujitsu-none)               fmt=aout ;;
 454       sparc-*-elf)                      fmt=elf ;;
 455       sparc-*-sysv4*)                   fmt=elf ;;
 456       sparc-*-solaris*)                 fmt=elf ;;
 457       sparc-*-netbsdelf*)               fmt=elf em=nbsd ;;
 458       sparc-*-*n*bsd*)  case ${cpu} in
 459                             sparc64)    fmt=elf em=nbsd ;;
 460                             *)          fmt=aout em=nbsd ;;
 461                         esac ;;
 462       strongarm-*-coff)                 fmt=coff ;;
 463       strongarm-*-elf)                  fmt=elf ;;
 464       strongarm-*-kaos*)                fmt=elf ;;
 465       xscale-*-coff)                    fmt=coff ;;
 466       xscale-*-elf)                     fmt=elf ;;
 467
 468       tic30-*-*aout*)                   fmt=aout bfd_gas=yes ;;
 469       tic30-*-*coff*)                   fmt=coff bfd_gas=yes ;;
 470       tic4x-*-* | c4x-*-*)              fmt=coff bfd_gas=yes ;;
 471       tic54x-*-* | c54x*-*-*)           fmt=coff bfd_gas=yes need_libm=yes;;
 472       tic80-*-*)                        fmt=coff ;;
 473
 474       v850-*-*)                         fmt=elf ;;
 475       v850e-*-*)                        fmt=elf ;;
 476       v850ea-*-*)                       fmt=elf ;;
 477
 478       vax-*-netbsdelf*)                 fmt=elf em=nbsd ;;
 479       vax-*-netbsd*)                    fmt=aout em=nbsd ;;
 480       vax-*-bsd* | vax-*-ultrix*)       fmt=aout ;;
 481       vax-*-vms)                        fmt=vms ;;
 482
 483       w65-*-*)                          fmt=coff ;;
 484
 485       xstormy16-*-*)                    fmt=elf ;;
 486
 487       xtensa-*-*)                       fmt=elf ;;
 488
 489       z8k-*-coff | z8k-*-sim)           fmt=coff ;;
 490
 491       *-*-aout | *-*-scout)             fmt=aout ;;
 492       *-*-freebsd*)                     fmt=elf em=freebsd ;;
 493       *-*-nindy*)                       fmt=bout ;;
 494       *-*-bsd*)                         fmt=aout em=sun3 ;;
 495       *-*-generic)                      fmt=generic ;;
 496       *-*-xray | *-*-hms)               fmt=coff ;;
 497       *-*-sim)                          fmt=coff ;;
 498       *-*-elf | *-*-sysv4* | *-*-solaris*) fmt=elf dev=yes ;;
 499       *-*-aros*)                                fmt=elf em=linux bfd_gas=yes ;;
 500       *-*-vxworks)                      fmt=aout ;;
 501       *-*-netware)                      fmt=elf ;;
 502     esac
 503
 504     if test ${this_target} = $target ; then
 505       endian_def=
 506       if test x${endian} = xbig; then
 507         endian_def=1
 508       elif test x${endian} = xlittle; then
 509         endian_def=0
 510       fi
 511       if test x${endian_def} != x; then
 512         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 513                            [Define as 1 if big endian.])
 514       fi
 515     fi
 516
 517     case ${cpu_type}-${fmt} in
 518         alpha*-* | arm-* | i386-* | ia64*-* | mips-* | ns32k-* \
 519                 | pdp11-* | ppc-* | sparc-* | strongarm-* | xscale-* \
 520                 | *-elf | *-ecoff | *-som)
 521             bfd_gas=yes ;;
 522     esac
 523
 524 # Other random stuff.
 525
 526     case ${cpu_type} in
 527       mips)
 528         # Set mips_cpu to the name of the default CPU.
 529         case ${target_cpu} in
 530           mips | mipsbe | mipseb | mipsle | mipsel | mips64 | mips64el)
 531             mips_cpu=from-abi
 532             ;;
 533           mipsisa32 | mipsisa32el)
 534             mips_cpu=mips32
 535             ;;
 536           mipsisa32r2 | mipsisa32r2el)
 537             mips_cpu=mips32r2
 538             ;;
 539           mipsisa64 | mipsisa64el)
 540             mips_cpu=mips64
 541             ;;
 542           mipstx39 | mipstx39el)
 543             mips_cpu=r3900
 544             ;;
 545           mips64vr | mips64vrel)
 546             mips_cpu=vr4100
 547             ;;
 548           mipsisa32r2*)
 549 changequote(,)dnl
 550             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r2//' -e 's/el$//'`
 551 changequote([,])dnl
 552             ;;
 553           mips64* | mipsisa64* | mipsisa32*)
 554 changequote(,)dnl
 555             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..//' -e 's/el$//'`
 556 changequote([,])dnl
 557             ;;
 558           *)
 559             AC_ERROR($target_cpu isn't a supported MIPS CPU name)
 560             ;;
 561         esac
 562         # See whether it's appropriate to set E_MIPS_ABI_O32 for o32
 563         # binaries.  It's a GNU extension that some OSes don't understand.
 564         # The value only matters on ELF targets.
 565         case ${target} in
 566           *-*-irix*)
 567             use_e_mips_abi_o32=0
 568             ;;
 569           *)
 570             use_e_mips_abi_o32=1
 571             ;;
 572         esac
 573         # Decide whether to generate 32-bit or 64-bit code by default.
 574         # Used to resolve -march=from-abi when an embedded ABI is selected.
 575         case ${target} in
 576           mips64*-*-* | mipsisa64*-*-*)
 577             mips_default_64bit=1
 578             ;;
 579           *)
 580             mips_default_64bit=0
 581             ;;
 582         esac
 583         # Decide which ABI to target by default.
 584         case ${target} in
 585           mips64*-linux* | mips-sgi-irix6*)
 586             mips_default_abi=N32_ABI
 587             ;;
 588           mips*-linux*)
 589             mips_default_abi=O32_ABI
 590             ;;
 591           *)
 592             mips_default_abi=NO_ABI
 593             ;;
 594         esac
 595         AC_DEFINE_UNQUOTED(MIPS_CPU_STRING_DEFAULT, "$mips_cpu",
 596                            [Default CPU for MIPS targets. ])
 597         AC_DEFINE_UNQUOTED(USE_E_MIPS_ABI_O32, $use_e_mips_abi_o32,
 598                            [Allow use of E_MIPS_ABI_O32 on MIPS targets. ])
 599         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_64BIT, $mips_default_64bit,
 600                            [Generate 64-bit code by default on MIPS targets. ])
 601         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_ABI, $mips_default_abi,
 602                            [Choose a default ABI for MIPS targets. ])
 603         ;;
 604     esac
 605
 606     # Do we need the opcodes library?
 607     case ${cpu_type} in
 608       vax | i386 | tic30)
 609         ;;
 610
 611       *)
 612         need_opcodes=yes
 613
 614         case "${enable_shared}" in
 615         yes) shared_opcodes=true ;;
 616         *opcodes*) shared_opcodes=true ;;
 617         *) shared_opcodes=false ;;
 618         esac
 619         if test "${shared_opcodes}" = "true"; then
 620           # A shared libopcodes must be linked against libbfd.
 621           need_bfd=yes
 622         fi
 623         ;;
 624     esac
 625
 626     # Any other special object files needed ?
 627     case ${cpu_type} in
 628       fr30 | ip2k | iq2000 | m32r | openrisc)
 629         using_cgen=yes
 630         ;;
 631
 632       frv)
 633         using_cgen=yes
 634         ;;
 635       m68k)
 636         case ${extra_objects} in
 637         *m68k-parse.o*) ;;
 638         *) extra_objects="$extra_objects m68k-parse.o" ;;
 639         esac
 640         ;;
 641
 642       mips)
 643         echo ${extra_objects} | grep -s "itbl-parse.o"
 644         if test $? -ne 0 ; then
 645           extra_objects="$extra_objects itbl-parse.o"
 646         fi
 647
 648         echo ${extra_objects} | grep -s "itbl-lex.o"
 649         if test $? -ne 0 ; then
 650           extra_objects="$extra_objects itbl-lex.o"
 651         fi
 652
 653         echo ${extra_objects} | grep -s "itbl-ops.o"
 654         if test $? -ne 0 ; then
 655           extra_objects="$extra_objects itbl-ops.o"
 656         fi
 657         ;;
 658
 659       i386 | s390 | sparc)
 660         if test $this_target = $target ; then
 661           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 662         fi
 663         ;;
 664
 665       xstormy16)
 666         using_cgen=yes
 667         ;;
 668
 669       xtensa)
 670         echo ${extra_objects} | grep -s "xtensa-relax.o"
 671         if test $? -ne 0 ; then
 672           extra_objects="$extra_objects xtensa-relax.o"
 673         fi
 674         ;;
 675
 676       *)
 677         ;;
 678     esac
 679
 680     if test $using_cgen = yes ; then
 681         case "x${extra_objects}" in
 682         *cgen.o*) ;;
 683         *) extra_objects="$extra_objects cgen.o" ;;
 684         esac
 685     fi
 686
 687 # See if we really can support this configuration with the emulation code.
 688
 689     if test $this_target = $target ; then
 690       primary_bfd_gas=$bfd_gas
 691       obj_format=$fmt
 692       te_file=$em
 693
 694       if test $bfd_gas = no ; then
 695         # Can't support other configurations this way.
 696         break
 697       fi
 698     elif test $bfd_gas = no ; then
 699       # Can't support this configuration.
 700       break
 701     fi
 702
 703 # From target name and format, produce a list of supported emulations.
 704
 705     case ${generic_target}-${fmt} in
 706       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 707       mips*-*-linux*-*) case "$endian" in
 708                         big)    emulation="mipsbelf mipslelf mipself" ;;
 709                         *)      emulation="mipslelf mipsbelf mipself" ;;
 710                         esac ;;
 711       mips-*-lnews*-ecoff) ;;
 712       mips-*-*-ecoff)   case "$endian" in
 713                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 714                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 715                         esac ;;
 716       mips-*-*-elf)     case "$endian" in
 717                         big)    emulation="mipsbelf mipslelf mipself" ;;
 718                         *)      emulation="mipslelf mipsbelf mipself" ;;
 719                         esac ;;
 720       mips-*-sysv4*MP*-*) emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 721       # i386-pc-pe-coff != i386-pc-coff.
 722       i386-*-pe-coff)   ;;
 723       # Uncommenting the next line will turn on support for i386 AOUT
 724       # for the default linux configuration
 725       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 726       #
 727       i386-*-aout)      emulation="i386aout" ;;
 728       i386-*-coff)      emulation="i386coff" ;;
 729       i386-*-elf)       emulation="i386elf" ;;
 730
 731       # Always all formats.  The first stated emulation becomes the default.
 732       cris-*-*aout*)    emulation="crisaout criself" ;;
 733       cris-*-*)         emulation="criself crisaout" ;;
 734     esac
 735
 736     emulations="$emulations $emulation"
 737
 738 done
 739
 740 # Turn on all targets if possible
 741 if test ${all_targets} = "yes"; then
 742   case ${target_cpu_type} in
 743   i386)
 744     case ${obj_format} in
 745     aout)
 746       emulations="$emulations i386coff i386elf"
 747       ;;
 748     coff)
 749       emulations="$emulations i386aout i386elf"
 750     ;;
 751     elf)
 752       emulations="$emulations i386aout i386coff"
 753       ;;
 754     esac
 755   ;;
 756   esac
 757 fi
 758
 759 # Assign floating point type.  Most processors with FP support
 760 # IEEE FP.  On those that don't support FP at all, usually IEEE
 761 # is emulated.
 762 case ${target_cpu} in
 763   vax | tahoe ) atof=${target_cpu} ;;
 764   pdp11)        atof=vax ;;
 765   *)            atof=ieee ;;
 766 esac
 767
 768 case "${obj_format}" in
 769   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 770 esac
 771
 772 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 773 cgen_cpu_prefix=""
 774 if test $using_cgen = yes ; then
 775   case ${target_cpu} in
 776     *) cgen_cpu_prefix=${target_cpu} ;;
 777   esac
 778   AC_SUBST(cgen_cpu_prefix)
 779   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 780 fi
 781
 782 dnl
 783 dnl Make sure the desired support files exist.
 784 dnl
 785
 786 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 787   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 788 fi
 789
 790 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 791   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 792 fi
 793
 794 case ${user_bfd_gas}-${primary_bfd_gas} in
 795   yes-yes | no-no)
 796     # We didn't override user's choice.
 797     ;;
 798   no-yes)
 799     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 800     ;;
 801   no-preferred)
 802     primary_bfd_gas=no
 803     ;;
 804   *-preferred)
 805     primary_bfd_gas=yes
 806     ;;
 807   yes-*)
 808     primary_bfd_gas=yes
 809     ;;
 810   -*)
 811     # User specified nothing.
 812     ;;
 813 esac
 814
 815 # Some COFF configurations want these random other flags set.
 816 case ${obj_format} in
 817   coff)
 818     case ${target_cpu_type} in
 819       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 820       m68k) AC_DEFINE(M68KCOFF, 1, [Using m68k COFF?]) ;;
 821       m88k) AC_DEFINE(M88KCOFF, 1, [Using m88k COFF?]) ;;
 822     esac
 823     ;;
 824 esac
 825
 826 # Getting this done right is going to be a bitch.  Each configuration specified
 827 # with --enable-targets=... should be checked for environment, format, cpu, and
 828 # bfd_gas setting.
 829 #
 830 # For each configuration, the necessary object file support code must be linked
 831 # in.  This might be only one, it might be up to four.  The necessary emulation
 832 # code needs to be provided, too.
 833 #
 834 # And then there's "--enable-targets=all"....
 835 #
 836 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 837
 838 formats="${obj_format}"
 839 emfiles=""
 840 EMULATIONS=""
 841 GAS_UNIQ(emulations)
 842 for em in . $emulations ; do
 843   case $em in
 844     .)  continue ;;
 845     mipsbelf | mipslelf | mipself)
 846         fmt=elf   file=mipself ;;
 847     mipsbecoff | mipslecoff | mipsecoff)
 848         fmt=ecoff file=mipsecoff ;;
 849     *coff)
 850         fmt=coff  file=$em ;;
 851     *aout)
 852         fmt=aout file=$em ;;
 853     *elf)
 854         fmt=elf file=$em ;;
 855   esac
 856   formats="$formats $fmt"
 857   emfiles="$emfiles e-$file.o"
 858   EMULATIONS="$EMULATIONS &$em,"
 859 done
 860 GAS_UNIQ(formats)
 861 GAS_UNIQ(emfiles)
 862 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 863   for fmt in $formats ; do
 864     case $fmt in
 865       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 866       bout)     AC_DEFINE(OBJ_MAYBE_BOUT, 1,    [b.out support?])   ;;
 867       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 868       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 869       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 870       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 871       hp300)    AC_DEFINE(OBJ_MAYBE_HP300, 1,   [HP300 support?])   ;;
 872       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE, 1,    [IEEE support?])    ;;
 873       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 874       vms)      AC_DEFINE(OBJ_MAYBE_VMS, 1,     [VMS support?])     ;;
 875     esac
 876     extra_objects="$extra_objects obj-$fmt.o"
 877   done
 878   obj_format=multi
 879 fi
 880 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 881   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 882   # e-mips* has more than one emulation per file, e-i386* has just one at the
 883   # moment.  If only one emulation is specified, then don't define
 884   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 885   case "${obj_format}${emfiles}" in
 886     multi* | *mips*)
 887       extra_objects="$extra_objects $emfiles"
 888       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 889   esac
 890 fi
 891 AC_SUBST(extra_objects)
 892 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 893 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 894                    [Default emulation.])
 895
 896 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 897   yes-*-coff)   need_bfd=yes ;;
 898   no-*-coff)    need_bfd=yes
 899                 AC_DEFINE(MANY_SEGMENTS, 1, [old COFF support?]) ;;
 900 esac
 901
 902 reject_dev_configs=yes
 903
 904 case ${reject_dev_configs}-${dev} in
 905   yes-yes) # Oops.
 906     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 907     ;;
 908 esac
 909
 910 AC_SUBST(target_cpu_type)
 911 AC_SUBST(obj_format)
 912 AC_SUBST(te_file)
 913 AC_SUBST(install_tooldir)
 914 AC_SUBST(atof)
 915 dnl AC_SUBST(emulation)
 916
 917 case "${primary_bfd_gas}" in
 918   yes)  AC_DEFINE(BFD_ASSEMBLER, 1, [Use BFD interface?])
 919         need_bfd=yes ;;
 920 esac
 921
 922 # do we need the opcodes library?
 923 case "${need_opcodes}" in
 924 yes)
 925   OPCODES_LIB=../opcodes/libopcodes.la
 926   ;;
 927 esac
 928
 929 case "${need_bfd}" in
 930 yes)
 931   BFDLIB=../bfd/libbfd.la
 932   BFDVER_H=../bfd/bfdver.h
 933   ALL_OBJ_DEPS="$ALL_OBJ_DEPS"' ../bfd/bfd.h $(INCDIR)/symcat.h'
 934   ;;
 935 esac
 936
 937 AC_SUBST(BFDLIB)
 938 AC_SUBST(OPCODES_LIB)
 939
 940 AC_SUBST(BFDVER_H)
 941 AC_SUBST(ALL_OBJ_DEPS)
 942
 943 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 944 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 945 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 946 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 947 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 948
 949 AC_PROG_CC
 950
 951 AC_PROG_YACC
 952 AM_PROG_LEX
 953
 954 ALL_LINGUAS="fr tr es"
 955 CY_GNU_GETTEXT
 956
 957 AM_MAINTAINER_MODE
 958 AC_EXEEXT
 959
 960 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 961
 962 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 963 # people who are not cross-compiling but are compiling cross-assemblers.
 964 AC_MSG_CHECKING(whether compiling a cross-assembler)
 965 if test "${host}" = "${target}"; then
 966   cross_gas=no
 967 else
 968   cross_gas=yes
 969   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 970 fi
 971 AC_MSG_RESULT($cross_gas)
 972
 973 dnl ansidecl.h will deal with const
 974 dnl AC_CONST
 975 AC_FUNC_ALLOCA
 976 AC_C_INLINE
 977
 978 # VMS doesn't have unlink.
 979 AC_CHECK_FUNCS(unlink remove, break)
 980
 981 # Some systems don't have sbrk().
 982 AC_CHECK_FUNCS(sbrk)
 983
 984 # do we need the math library?
 985 case "${need_libm}" in
 986 yes)
 987   AC_CHECK_LIBM
 988   AC_SUBST(LIBM)
 989   ;;
 990 esac
 991
 992 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 993 # enough, but on some of those systems, the assert macro relies on requoting
 994 # working properly!
 995 GAS_WORKING_ASSERT
 996
 997 # On some systems, the system header files may not declare malloc, realloc,
 998 # and free.  There are places where gas needs these functions to have been
 999 # declared -- such as when taking their addresses.
1000 gas_test_headers="
1001 #ifdef HAVE_MEMORY_H
1002 #include <memory.h>
1003 #endif
1004 #ifdef HAVE_STRING_H
1005 #include <string.h>
1006 #else
1007 #ifdef HAVE_STRINGS_H
1008 #include <strings.h>
1009 #endif
1010 #endif
1011 #ifdef HAVE_STDLIB_H
1012 #include <stdlib.h>
1013 #endif
1014 #ifdef HAVE_UNISTD_H
1015 #include <unistd.h>
1016 #endif
1017 "
1018 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
1019 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
1020 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
1021 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
1022 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
1023
1024 # Does errno.h declare errno, or do we have to add a separate declaration
1025 # for it?
1026 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
1027 #ifdef HAVE_ERRNO_H
1028 #include <errno.h>
1029 #endif
1030 ])
1031
1032 dnl This must come last.
1033
1034 dnl We used to make symlinks to files in the source directory, but now
1035 dnl we just use the right name for .c files, and create .h files in
1036 dnl the build directory which include the right .h file.  Make sure
1037 dnl the old symlinks don't exist, so that a reconfigure in an existing
1038 dnl directory behaves reasonably.
1039
1040 AC_OUTPUT(Makefile doc/Makefile ${GDBINIT}:gdbinit.in po/Makefile.in:po/Make-in,
1041 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
1042  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
1043  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
1044  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
1045  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
1046  if test "x$cgen_cpu_prefix" != x ; then
1047    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
1048  fi
1049
1050  sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile],
1051 [target_cpu_type=${target_cpu_type}
1052  cgen_cpu_prefix=${cgen_cpu_prefix}
1053  obj_format=${obj_format}
1054  te_file=${te_file}])