gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   3 dnl 2005, 2006, 2007, 2008, 2009
   4 dnl Free Software Foundation, Inc.
   5 dnl
   6 dnl This file is part of GDB.
   7 dnl
   8 dnl This program is free software; you can redistribute it and/or modify
   9 dnl it under the terms of the GNU General Public License as published by
  10 dnl the Free Software Foundation; either version 3 of the License, or
  11 dnl (at your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful,
  14 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl GNU General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 dnl Process this file with autoconf to produce a configure script.
  22
  23 AC_PREREQ(2.59)dnl
  24 AC_INIT(main.c)
  25 AC_CONFIG_HEADER(config.h:config.in)
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_GNU_SOURCE
  30 AC_AIX
  31 AC_ISC_POSIX
  32 gl_EARLY
  33 AM_PROG_CC_STDC
  34
  35 AC_CONFIG_AUX_DIR(..)
  36 AC_CANONICAL_SYSTEM
  37
  38 # Dependency checking.
  39 ZW_CREATE_DEPDIR
  40 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  41
  42 # Check for the 'make' the user wants to use.
  43 AC_CHECK_PROGS(MAKE, make)
  44 MAKE_IS_GNU=
  45 case "`$MAKE --version 2>&1 | sed 1q`" in
  46   *GNU*)
  47     MAKE_IS_GNU=yes
  48     ;;
  49 esac
  50 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  51 AC_PROG_MAKE_SET
  52
  53 dnl List of object files and targets accumulated by configure.
  54
  55 CONFIG_OBS=
  56 CONFIG_DEPS=
  57 CONFIG_SRCS=
  58 ENABLE_CFLAGS=
  59
  60 CONFIG_ALL=
  61 CONFIG_CLEAN=
  62 CONFIG_INSTALL=
  63 CONFIG_UNINSTALL=
  64
  65 dnl Set up for gettext.
  66 ZW_GNU_GETTEXT_SISTER_DIR
  67
  68 localedir='${datadir}/locale'
  69 AC_SUBST(localedir)
  70
  71 if test x"$USE_NLS" = xyes; then
  72    CONFIG_ALL="$CONFIG_ALL all-po"
  73    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  74    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  75    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  76 fi
  77
  78 gl_INIT
  79
  80 # For Makefile dependencies.
  81 GNULIB_STDINT_H=
  82 if test x"$STDINT_H" != x; then
  83   GNULIB_STDINT_H=gnulib/$STDINT_H
  84 fi
  85 AC_SUBST(GNULIB_STDINT_H)
  86
  87 PACKAGE=gdb
  88 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  89 AC_SUBST(PACKAGE)
  90
  91 # GDB does not use automake, but gnulib does.  This line lets us
  92 # generate its Makefile.in.
  93 AM_INIT_AUTOMAKE(gdb, UNUSED-VERSION, [no-define])
  94
  95 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
  96     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
  97     [${libdir}/debug])
  98
  99 # GDB's datadir relocation
 100
 101 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 102     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 103     [${datadir}/gdb])
 104
 105 AC_ARG_WITH(relocated-sources,
 106 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 107 [reloc_srcdir="${withval}"
 108  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 109               [Relocated directory for source files. ])
 110 ])
 111
 112 AC_CONFIG_SUBDIRS(doc testsuite)
 113
 114 # Check whether to support alternative target configurations
 115 AC_ARG_ENABLE(targets,
 116 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 117 [case "${enableval}" in
 118   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 119             ;;
 120   no)       enable_targets= ;;
 121   *)        enable_targets=$enableval ;;
 122 esac])
 123
 124 # Check whether to enable 64-bit support on 32-bit hosts
 125 AC_ARG_ENABLE(64-bit-bfd,
 126 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 127 [case "${enableval}" in
 128   yes)  want64=true  ;;
 129   no)   want64=false ;;
 130   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 131 esac],[want64=false])dnl
 132
 133 # Provide defaults for some variables set by the per-host and per-target
 134 # configuration.
 135 gdb_host_obs=posix-hdep.o
 136
 137 if test "${target}" = "${host}"; then
 138   gdb_native=yes
 139 else
 140   gdb_native=no
 141 fi
 142
 143 . $srcdir/configure.host
 144
 145 # Accumulate some settings from configure.tgt over all enabled targets
 146
 147 TARGET_OBS=
 148 all_targets=
 149
 150 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 151 do
 152   if test "$targ_alias" = "all"; then
 153     all_targets=true
 154   else
 155     # Canonicalize the secondary target names.
 156     result=`$ac_config_sub $targ_alias 2>/dev/null`
 157     if test -n "$result"; then
 158         targ=$result
 159     else
 160         targ=$targ_alias
 161     fi
 162
 163     . ${srcdir}/configure.tgt
 164
 165     # Target-specific object files
 166     for i in ${gdb_target_obs}; do
 167         case " $TARGET_OBS " in
 168         *" ${i} "*) ;;
 169         *)
 170           TARGET_OBS="$TARGET_OBS ${i}"
 171           ;;
 172         esac
 173     done
 174
 175     # Check whether this target needs 64-bit CORE_ADDR
 176     if test x${want64} = xfalse; then
 177       . ${srcdir}/../bfd/config.bfd
 178     fi
 179   fi
 180 done
 181
 182 if test x${all_targets} = xtrue; then
 183
 184   # We want all 64-bit targets if we either:
 185   #  - run on a 64-bit host  or
 186   #  - already require 64-bit support for some other target  or
 187   #  - the --enable-64-bit-bfd option was supplied
 188   # Otherwise we only support all 32-bit targets.
 189   #
 190   # NOTE: This test must be in sync with the corresponding
 191   #       tests in BFD!
 192
 193   if test x${want64} = xfalse; then
 194     AC_CHECK_SIZEOF(long)
 195     if test "x${ac_cv_sizeof_long}" = "x8"; then
 196       want64=true
 197     fi
 198   fi
 199   if test x${want64} = xtrue; then
 200     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 201   else
 202     TARGET_OBS='$(ALL_TARGET_OBS)'
 203   fi
 204 fi
 205
 206 AC_SUBST(TARGET_OBS)
 207
 208 # For other settings, only the main target counts.
 209 gdb_sim=
 210 gdb_osabi=
 211 build_gdbserver=
 212 targ=$target; . ${srcdir}/configure.tgt
 213
 214 # Fetch the default architecture and default target vector from BFD.
 215 targ=$target; . $srcdir/../bfd/config.bfd
 216
 217 # We only want the first architecture, so strip off the others if
 218 # there is more than one.
 219 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 220
 221 if test "x$targ_archs" != x; then
 222   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 223     [Define to BFD's default architecture. ])
 224 fi
 225 if test "x$targ_defvec" != x; then
 226   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 227     [Define to BFD's default target vector. ])
 228 fi
 229
 230 # The CLI cannot be disabled yet, but may be in the future.
 231
 232 # Enable CLI.
 233 AC_ARG_ENABLE(gdbcli,
 234 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 235   [case $enableval in
 236     yes)
 237       ;;
 238     no)
 239       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 240     *)
 241       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 242   esac],
 243   [enable_gdbcli=yes])
 244 if test x"$enable_gdbcli" = xyes; then
 245   if test -d $srcdir/cli; then
 246     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 247     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 248     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 249     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 250   fi
 251 fi
 252
 253 # Enable MI.
 254 AC_ARG_ENABLE(gdbmi,
 255 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 256   [case $enableval in
 257     yes | no)
 258       ;;
 259     *)
 260       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 261   esac],
 262   [enable_gdbmi=yes])
 263 if test x"$enable_gdbmi" = xyes; then
 264   if test -d $srcdir/mi; then
 265     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 266     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 267     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 268     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 269   fi
 270 fi
 271
 272 # Enable TUI.
 273 AC_ARG_ENABLE(tui,
 274 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 275   [case $enableval in
 276     yes | no | auto)
 277       ;;
 278     *)
 279       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 280   esac],enable_tui=auto)
 281
 282 # Enable gdbtk.
 283 AC_ARG_ENABLE(gdbtk,
 284 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 285   [case $enableval in
 286     yes | no)
 287       ;;
 288     *)
 289       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 290   esac],
 291   [if test -d $srcdir/gdbtk; then
 292     enable_gdbtk=yes
 293   else
 294     enable_gdbtk=no
 295   fi])
 296 # We unconditionally disable gdbtk tests on selected platforms.
 297 case $host_os in
 298   go32* | windows*)
 299     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 300     enable_gdbtk=no ;;
 301 esac
 302
 303 # Libunwind support.
 304 AC_ARG_WITH(libunwind,
 305 AS_HELP_STRING([--with-libunwind], [use libunwind frame unwinding support]),
 306 [case "${withval}" in
 307   yes)  enable_libunwind=yes ;;
 308   no)   enable_libunwind=no ;;
 309   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;;
 310 esac],[
 311   AC_CHECK_HEADERS(libunwind.h libunwind-ia64.h)
 312   if test x"$ac_cv_header_libunwind_h" = xyes -a x"$ac_cv_header_libunwind_ia64_h" = xyes; then
 313     enable_libunwind=yes;
 314   fi
 315 ])
 316
 317 if test x"$enable_libunwind" = xyes; then
 318   AC_CHECK_HEADERS(libunwind.h libunwind-ia64.h)
 319   AC_DEFINE(HAVE_LIBUNWIND, 1, [Define if libunwind library is being used.])
 320   CONFIG_OBS="$CONFIG_OBS libunwind-frame.o"
 321   CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o"
 322   CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c"
 323 fi
 324
 325 opt_curses=no
 326 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 327
 328 prefer_curses=no
 329 if test "$opt_curses" = "yes"; then
 330   prefer_curses=yes
 331 fi
 332
 333 # Profiling support.
 334 AC_ARG_ENABLE(profiling,
 335 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 336   [case $enableval in
 337     yes | no)
 338       ;;
 339     *)
 340       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 341   esac],
 342  [enable_profiling=no])
 343
 344 AC_CHECK_FUNCS(monstartup _mcleanup)
 345 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 346 [AC_TRY_LINK(
 347 [#include <stdlib.h>
 348 extern char _etext;
 349 ],
 350 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 351 if test $ac_cv_var__etext = yes; then
 352   AC_DEFINE(HAVE__ETEXT, 1,
 353             [Define to 1 if your system has the _etext variable. ])
 354 fi
 355 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 356 [AC_TRY_LINK(
 357 [#include <stdlib.h>
 358 extern char etext;
 359 ],
 360 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 361 if test $ac_cv_var_etext = yes; then
 362   AC_DEFINE(HAVE_ETEXT, 1,
 363             [Define to 1 if your system has the etext variable. ])
 364 fi
 365 if test "$enable_profiling" = yes ; then
 366   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 367     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 368   fi
 369   PROFILE_CFLAGS=-pg
 370   OLD_CFLAGS="$CFLAGS"
 371   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 372
 373   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 374     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 375      ac_cv_cc_supports_pg=no)])
 376
 377   if test $ac_cv_cc_supports_pg = no; then
 378     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 379   fi
 380
 381   CFLAGS="$OLD_CFLAGS"
 382 fi
 383
 384 ACX_PKGVERSION([GDB])
 385 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 386 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 387 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 388
 389 # --------------------- #
 390 # Checks for programs.  #
 391 # --------------------- #
 392
 393 AC_PROG_AWK
 394 AC_PROG_INSTALL
 395 AC_PROG_LN_S
 396 AC_PROG_RANLIB
 397 AC_PROG_YACC
 398
 399 AC_CHECK_TOOL(AR, ar)
 400 AC_CHECK_TOOL(DLLTOOL, dlltool)
 401 AC_CHECK_TOOL(WINDRES, windres)
 402
 403 # Needed for GNU/Hurd.
 404 AC_CHECK_TOOL(MIG, mig)
 405
 406 # ---------------------- #
 407 # Checks for libraries.  #
 408 # ---------------------- #
 409
 410 # We might need to link with -lm; most simulators need it.
 411 AC_CHECK_LIB(m, main)
 412
 413 # We need to link with -lw to get `wctype' on Solaris before Solaris
 414 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 415 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 416 # is known to have this problem).  Therefore we avoid libw if we can.
 417 AC_CHECK_FUNC(wctype, [],
 418   [AC_CHECK_LIB(w, wctype)])
 419
 420 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 421 AC_SEARCH_LIBS(gethostbyname, nsl)
 422
 423 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 424 AC_SEARCH_LIBS(socketpair, socket)
 425
 426 # Link in zlib if we can.  This allows us to read compressed debug sections.
 427 AC_SEARCH_LIBS(zlibVersion, z, [AC_CHECK_HEADERS(zlib.h)])
 428
 429 # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c).
 430 AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl])
 431
 432 AM_ICONV
 433
 434 # On alpha-osf, it appears that libtermcap and libcurses are not compatible.
 435 # There is a very specific comment in /usr/include/curses.h explaining that
 436 # termcap routines built into libcurses must not be used.
 437 #
 438 # The symptoms we observed so far is GDB unexpectedly changing
 439 # the terminal settings when tgetent is called - this is particularly
 440 # visible as the output is missing carriage returns, and so rapidly
 441 # becomes very hard to read.
 442 #
 443 # The readline configure script has already decided that libtermcap
 444 # was enough for its purposes, and so decided to build readline using
 445 # libtermcap.  Since the TUI mode requires curses, building GDB with
 446 # TUI enabled results in both libraries to be used at the same time,
 447 # which is not allowed.  This basically means that GDB with TUI is
 448 # broken on alpha-osf.
 449
 450 case $host_os in
 451   alpha*-*-osf* )
 452     if "$enable_tui" = "yes"; then
 453       AC_MSG_ERROR([Building GDB with TUI mode is not supported on this host])
 454     fi
 455     if "$enable_tui" = "auto"; then
 456       enable_tui=no
 457     fi
 458     ;;
 459 esac
 460
 461 # For the TUI, we need enhanced curses functionality.
 462 if test x"$enable_tui" != xno; then
 463   prefer_curses=yes
 464 fi
 465
 466 curses_found=no
 467 if test x"$prefer_curses" = xyes; then
 468   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 469   # curses library because the latter might not provide all the
 470   # functionality we need.  However, this leads to problems on systems
 471   # where the linker searches /usr/local/lib, but the compiler doesn't
 472   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 473   # default installation of ncurses on alpha*-dec-osf* will lead to such
 474   # a situation.
 475   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 476
 477   if test "$ac_cv_search_waddstr" != no; then
 478     curses_found=yes
 479   fi
 480 fi
 481
 482 # Check whether we should enable the TUI, but only do so if we really
 483 # can.
 484 if test x"$enable_tui" != xno; then
 485   if test -d $srcdir/tui; then
 486     if test "$curses_found" != no; then
 487       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 488       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 489       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 490       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 491       CONFIG_ALL="${CONFIG_ALL} all-tui"
 492       CONFIG_CLEAN="${CONFIG_CLEAN} clean-tui"
 493       CONFIG_INSTALL="${CONFIG_INSTALL} install-tui"
 494       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-tui"
 495     else
 496       if test x"$enable_tui" = xyes; then
 497         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 498       else
 499         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 500       fi
 501     fi
 502   fi
 503 fi
 504
 505 # Since GDB uses Readline, we need termcap functionality.  In many
 506 # cases this will be provided by the curses library, but some systems
 507 # have a seperate termcap library, or no curses library at all.
 508
 509 case $host_os in
 510   cygwin*)
 511     if test -d $srcdir/libtermcap; then
 512       LIBS="../libtermcap/libtermcap.a $LIBS"
 513       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 514     fi ;;
 515   go32* | *djgpp*)
 516     ac_cv_search_tgetent="none required"
 517     ;;
 518   *mingw32*)
 519     ac_cv_search_tgetent="none required"
 520     CONFIG_OBS="$CONFIG_OBS windows-termcap.o"
 521     ;;
 522 esac
 523
 524 # These are the libraries checked by Readline.
 525 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 526
 527 if test "$ac_cv_search_tgetent" = no; then
 528   AC_MSG_ERROR([no termcap library found])
 529 fi
 530
 531 AC_ARG_WITH([system-readline],
 532   [AS_HELP_STRING([--with-system-readline],
 533                   [use installed readline library])])
 534
 535 if test "$with_system_readline" = yes; then
 536   READLINE=-lreadline
 537   READLINE_DEPS=
 538   READLINE_CFLAGS=
 539 else
 540   READLINE='$(READLINE_DIR)/libreadline.a'
 541   READLINE_DEPS='$(READLINE)'
 542   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 543 fi
 544 AC_SUBST(READLINE)
 545 AC_SUBST(READLINE_DEPS)
 546 AC_SUBST(READLINE_CFLAGS)
 547
 548 AC_ARG_WITH(expat,
 549   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 550   [], [with_expat=auto])
 551 AC_MSG_CHECKING([whether to use expat])
 552 AC_MSG_RESULT([$with_expat])
 553
 554 if test "${with_expat}" = no; then
 555   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 556   HAVE_LIBEXPAT=no
 557 else
 558   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 559                         [XML_Parser p = XML_ParserCreate (0);])
 560   if test "$HAVE_LIBEXPAT" != yes; then
 561     if test "$with_expat" = yes; then
 562       AC_MSG_ERROR([expat is missing or unusable])
 563     else
 564       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 565     fi
 566   else
 567     save_LIBS=$LIBS
 568     LIBS="$LIBS $LIBEXPAT"
 569     AC_CHECK_FUNCS(XML_StopParser)
 570     LIBS=$save_LIBS
 571   fi
 572 fi
 573
 574 dnl Utility to simplify finding libpython.
 575 AC_DEFUN([AC_TRY_LIBPYTHON],
 576 [
 577   version=$1
 578   define([have_libpython_var],$2)
 579   define([VERSION],[translit([$1],[abcdefghijklmnopqrstuvwxyz./-],
 580                                   [ABCDEFGHIJKLMNOPQRSTUVWXYZ___])])
 581   [HAVE_LIB]VERSION=no
 582   AC_MSG_CHECKING([for ${version}])
 583   save_LIBS=$LIBS
 584   LIBS="$LIBS -l${version}"
 585   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "${version}/Python.h"]],
 586                                  [[Py_Initialize ();]]),
 587                  [[HAVE_LIB]VERSION=yes
 588                   have_libpython_var=yes],
 589                  [LIBS=$save_LIBS])
 590   AC_MSG_RESULT([$[HAVE_LIB]VERSION])
 591 ])
 592
 593 AC_ARG_WITH(python,
 594   AS_HELP_STRING([--with-python], [include python support (auto/yes/no/<path>)]),
 595   [], [with_python=auto])
 596 AC_MSG_CHECKING([whether to use python])
 597 AC_MSG_RESULT([$with_python])
 598
 599 if test "${with_python}" = no; then
 600   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 601   have_libpython=no
 602 else
 603   case "${with_python}" in
 604   yes | auto)
 605     # Leave as empty, use defaults.
 606     python_includes=
 607     python_libs=
 608     ;;
 609   /*)
 610     python_includes="-I${with_python}/include"
 611     python_libs="-L${with_python}/lib"
 612     ;;
 613   *)
 614     AC_ERROR(invalid value for --with-python)
 615     ;;
 616   esac
 617
 618   save_CPPFLAGS=$CPPFLAGS
 619   CPPFLAGS="$CPPFLAGS ${python_includes}"
 620   save_LIBS=$LIBS
 621   LIBS="$LIBS ${python_libs}"
 622   have_libpython=no
 623   if test "${have_libpython}" = no; then
 624     AC_TRY_LIBPYTHON(python2.6, have_libpython)
 625     if test "${HAVE_LIBPYTHON2_6}" = yes; then
 626       AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 627     fi
 628   fi
 629   if test ${have_libpython} = no; then
 630     AC_TRY_LIBPYTHON(python2.5, have_libpython)
 631     if test "${HAVE_LIBPYTHON2_5}" = yes; then
 632       AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 633     fi
 634   fi
 635   if test ${have_libpython} = no; then
 636     AC_TRY_LIBPYTHON(python2.4, have_libpython)
 637     if test "${HAVE_LIBPYTHON2_4}" = yes; then
 638       AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 639     fi
 640   fi
 641   if test ${have_libpython} = no; then
 642     case "${with_python}" in
 643     yes)
 644       AC_MSG_ERROR([python is missing or unusable])
 645       ;;
 646     auto)
 647       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 648       ;;
 649     *)
 650       AC_MSG_ERROR([no usable python found at ${with_python}])
 651       ;;
 652     esac
 653     CPPFLAGS=$save_CPPFLAGS
 654     LIBS=$save_LIBS
 655   fi
 656 fi
 657
 658 if test "${have_libpython}" = yes; then
 659   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 660   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 661   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 662   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 663   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 664
 665   # Flags needed to compile Python code (taken from python-config --cflags).
 666   # We cannot call python-config directly because it will output whatever was
 667   # used when compiling the Python interpreter itself, including flags which
 668   # would make the python-related objects be compiled differently from the
 669   # rest of GDB (e.g., -O2 and -fPIC).
 670   if test "${GCC}" = yes; then
 671     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 672   fi
 673
 674   if test "x${tentative_python_cflags}" != x; then
 675     AC_MSG_CHECKING(compiler flags for python code)
 676     for flag in ${tentative_python_cflags}; do
 677       # Check that the compiler accepts it
 678       saved_CFLAGS="$CFLAGS"
 679       CFLAGS="$CFLAGS $flag"
 680       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 681       CFLAGS="$saved_CFLAGS"
 682     done
 683     AC_MSG_RESULT(${PYTHON_CFLAGS})
 684   fi
 685 else
 686   # Even if Python support is not compiled in, we need to have these files
 687   # included in order to recognize the GDB command "python".
 688   CONFIG_OBS="$CONFIG_OBS python.o python-value.o python-prettyprint.o"
 689   CONFIG_SRCS="$CONFIG_SRCS python/python.c python/python-value.c python/python-prettyprint.c"
 690 fi
 691 AC_SUBST(PYTHON_CFLAGS)
 692
 693 # ------------------------- #
 694 # Checks for header files.  #
 695 # ------------------------- #
 696
 697 AC_HEADER_DIRENT
 698 AC_HEADER_STAT
 699 AC_HEADER_STDC
 700 # elf_hp.h is for HP/UX 64-bit shared library support.
 701 # FIXME: kettenis/20030102: In most cases we include these (ctype.h, time.h)
 702 # unconditionally, so what's the point in checking these?
 703 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
 704                   thread_db.h gnu/libc-version.h signal.h stddef.h \
 705                   stdlib.h string.h memory.h strings.h sys/fault.h \
 706                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
 707                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
 708                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
 709                   sys/types.h sys/wait.h wait.h termios.h termio.h \
 710                   sgtty.h unistd.h elf_hp.h ctype.h time.h locale.h])
 711 AC_CHECK_HEADERS(link.h, [], [],
 712 [#if HAVE_SYS_TYPES_H
 713 # include <sys/types.h>
 714 #endif
 715 #if HAVE_NLIST_H
 716 # include <nlist.h>
 717 #endif
 718 ])
 719 AC_CHECK_HEADERS(sys/proc.h, [], [],
 720 [#if HAVE_SYS_PARAM_H
 721 # include <sys/param.h>
 722 #endif
 723 ])
 724 AC_CHECK_HEADERS(sys/user.h, [], [],
 725 [#if HAVE_SYS_PARAM_H
 726 # include <sys/param.h>
 727 #endif
 728 ])
 729
 730 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
 731 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
 732 # think that we don't have <curses.h> if we're using GCC.
 733 case $host_os in
 734   solaris2.[[789]])
 735     if test "$GCC" = yes; then
 736       AC_DEFINE(_MSE_INT_H, 1,
 737         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
 738    Solaris 2.[789] when using GCC. ])
 739     fi ;;
 740 esac
 741 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
 742 AC_CHECK_HEADERS(term.h, [], [],
 743 [#if HAVE_CURSES_H
 744 # include <curses.h>
 745 #endif
 746 ])
 747
 748 # ------------------------- #
 749 # Checks for declarations.  #
 750 # ------------------------- #
 751
 752 AC_CHECK_DECLS([free, malloc, realloc, strerror, strstr, getopt,
 753                 snprintf, vsnprintf])
 754 AM_LC_MESSAGES
 755
 756 # ----------------------- #
 757 # Checks for structures.  #
 758 # ----------------------- #
 759
 760 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
 761
 762 # ------------------ #
 763 # Checks for types.  #
 764 # ------------------ #
 765
 766 AC_TYPE_SIGNAL
 767 AC_CHECK_TYPES(socklen_t, [], [],
 768 [#include <sys/types.h>
 769 #include <sys/socket.h>
 770 ])
 771
 772 # ------------------------------------- #
 773 # Checks for compiler characteristics.  #
 774 # ------------------------------------- #
 775
 776 AC_C_CONST
 777 AC_C_INLINE
 778 AC_C_BIGENDIAN
 779
 780 # ------------------------------ #
 781 # Checks for library functions.  #
 782 # ------------------------------ #
 783
 784 AC_FUNC_ALLOCA
 785 AC_FUNC_MMAP
 786 AC_FUNC_VFORK
 787 AC_CHECK_FUNCS([canonicalize_file_name realpath getrusage getuid \
 788                 getgid pipe poll pread64 sbrk setpgid setpgrp setsid \
 789                 sigaction sigprocmask sigsetmask socketpair syscall \
 790                 ttrace wborder setlocale iconvlist libiconvlist btowc])
 791 AM_LANGINFO_CODESET
 792
 793 # Check the return and argument types of ptrace.  No canned test for
 794 # this, so roll our own.
 795 gdb_ptrace_headers='
 796 #if HAVE_SYS_TYPES_H
 797 # include <sys/types.h>
 798 #endif
 799 #if HAVE_SYS_PTRACE_H
 800 # include <sys/ptrace.h>
 801 #endif
 802 #if HAVE_UNISTD_H
 803 # include <unistd.h>
 804 #endif
 805 '
 806 # There is no point in checking if we don't have a prototype.
 807 AC_CHECK_DECLS(ptrace, [], [
 808   : ${gdb_cv_func_ptrace_ret='int'}
 809   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 810 ], $gdb_ptrace_headers)
 811 # Check return type.  Varargs (used on GNU/Linux) conflict with the
 812 # empty argument list, so check for that explicitly.
 813 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
 814   AC_TRY_COMPILE($gdb_ptrace_headers,
 815     [extern long ptrace (enum __ptrace_request, ...);],
 816     gdb_cv_func_ptrace_ret='long',
 817     AC_TRY_COMPILE($gdb_ptrace_headers,
 818       [extern int ptrace ();],
 819       gdb_cv_func_ptrace_ret='int',
 820       gdb_cv_func_ptrace_ret='long')))
 821 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
 822   [Define as the return type of ptrace.])
 823 # Check argument types.
 824 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
 825   AC_TRY_COMPILE($gdb_ptrace_headers,
 826     [extern long ptrace (enum __ptrace_request, ...);],
 827     [gdb_cv_func_ptrace_args='int,int,long,long'],[
 828 for gdb_arg1 in 'int' 'long'; do
 829  for gdb_arg2 in 'pid_t' 'int' 'long'; do
 830   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
 831    for gdb_arg4 in 'int' 'long'; do
 832      AC_TRY_COMPILE($gdb_ptrace_headers, [
 833 extern $gdb_cv_func_ptrace_ret
 834   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
 835 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
 836     break 4;])
 837     for gdb_arg5 in 'int *' 'int' 'long'; do
 838      AC_TRY_COMPILE($gdb_ptrace_headers, [
 839 extern $gdb_cv_func_ptrace_ret
 840   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
 841 ], [
 842 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
 843     break 5;])
 844     done
 845    done
 846   done
 847  done
 848 done
 849 # Provide a safe default value.
 850 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 851 ])])
 852 ac_save_IFS=$IFS; IFS=','
 853 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
 854 IFS=$ac_save_IFS
 855 shift
 856 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
 857   [Define to the type of arg 3 for ptrace.])
 858 if test -n "$[5]"; then
 859   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
 860     [Define to the type of arg 5 for ptrace.])
 861 fi
 862
 863 dnl AC_FUNC_SETPGRP does not work when cross compiling
 864 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
 865 if test "$cross_compiling" = no; then
 866   AC_FUNC_SETPGRP
 867 else
 868   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
 869     [AC_TRY_COMPILE([
 870 #include <unistd.h>
 871 ], [
 872   if (setpgrp(1,1) == -1)
 873     exit (0);
 874   else
 875     exit (1);
 876 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
 877 if test $ac_cv_func_setpgrp_void = yes; then
 878   AC_DEFINE(SETPGRP_VOID, 1)
 879 fi
 880 fi
 881
 882 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
 883 # since sigsetjmp might only be defined as a macro.
 884 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
 885 [AC_TRY_COMPILE([
 886 #include <setjmp.h>
 887 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
 888 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
 889 if test $gdb_cv_func_sigsetjmp = yes; then
 890   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
 891 fi
 892
 893 # Assume we'll default to using the included libiberty regex.
 894 gdb_use_included_regex=yes
 895
 896 # However, if the system regex is GNU regex, then default to *not*
 897 # using the included regex.
 898 AC_CACHE_CHECK(
 899   [for GNU regex],
 900   [gdb_cv_have_gnu_regex],
 901   [AC_TRY_COMPILE(
 902     [#include <gnu-versions.h>],
 903     [#define REGEX_INTERFACE_VERSION 1
 904 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
 905 # error "Version mismatch"
 906 #endif],
 907     gdb_cv_have_gnu_regex=yes,
 908     gdb_cv_have_gnu_regex=no)])
 909 if test $gdb_cv_have_gnu_regex = yes; then
 910   gdb_use_included_regex=no
 911 fi
 912
 913 AC_ARG_WITH(included-regex,
 914   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
 915   gdb_with_regex=$withval,
 916   gdb_with_regex=$gdb_use_included_regex)
 917 if test "$gdb_with_regex" = yes; then
 918   AC_DEFINE(USE_INCLUDED_REGEX, 1,
 919     [Define to 1 if the regex included in libiberty should be used.])
 920 fi
 921
 922 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
 923 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
 924 [#include <sys/param.h>
 925 #include <sys/proc.h>
 926 ])
 927
 928 # See if <sys/lwp.h> defines `struct lwp`.
 929 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
 930 [AC_TRY_COMPILE([#include <sys/param.h>
 931 #include <sys/lwp.h>], [struct lwp l;],
 932 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
 933 if test $gdb_cv_struct_lwp = yes; then
 934   AC_DEFINE(HAVE_STRUCT_LWP, 1,
 935             [Define to 1 if your system has struct lwp.])
 936 fi
 937
 938 # See if <machine/reg.h> degines `struct reg'.
 939 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
 940 [AC_TRY_COMPILE([#include <sys/types.h>
 941 #include <machine/reg.h>], [struct reg r;],
 942 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
 943 if test $gdb_cv_struct_reg = yes; then
 944   AC_DEFINE(HAVE_STRUCT_REG, 1,
 945             [Define to 1 if your system has struct reg in <machine/reg.h>.])
 946 fi
 947
 948 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
 949 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
 950 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
 951                  [#include <machine/reg.h>])
 952
 953 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
 954 AC_MSG_CHECKING(for PTRACE_GETREGS)
 955 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
 956 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 957                 [PTRACE_GETREGS;],
 958                 [gdb_cv_have_ptrace_getregs=yes],
 959                 [gdb_cv_have_ptrace_getregs=no])])
 960 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
 961 if test $gdb_cv_have_ptrace_getregs = yes; then
 962   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
 963   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
 964 fi
 965
 966 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
 967 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 968 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
 969 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 970                 [PTRACE_GETFPXREGS;],
 971                 [gdb_cv_have_ptrace_getfpxregs=yes],
 972                 [gdb_cv_have_ptrace_getfpxregs=no])])
 973 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
 974 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
 975   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
 976   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
 977 fi
 978
 979 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
 980 AC_MSG_CHECKING(for PT_GETDBREGS)
 981 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
 982 [AC_TRY_COMPILE([#include <sys/types.h>
 983 #include <sys/ptrace.h>],
 984                 [PT_GETDBREGS;],
 985                 [gdb_cv_have_pt_getdbregs=yes],
 986                 [gdb_cv_have_pt_getdbregs=no])])
 987 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
 988 if test $gdb_cv_have_pt_getdbregs = yes; then
 989   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
 990   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
 991 fi
 992
 993 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
 994 AC_MSG_CHECKING(for PT_GETXMMREGS)
 995 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
 996 [AC_TRY_COMPILE([#include <sys/types.h>
 997 #include <sys/ptrace.h>],
 998                 [PT_GETXMMREGS;],
 999                 [gdb_cv_have_pt_getxmmregs=yes],
1000                 [gdb_cv_have_pt_getxmmregs=no])])
1001 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1002 if test $gdb_cv_have_pt_getxmmregs = yes; then
1003   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1004   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1005 fi
1006
1007 # Detect which type of /proc is in use, such as for Unixware or Solaris.
1008
1009 if test "${target}" = "${host}"; then
1010   case "${host}" in
1011   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
1012       AC_DEFINE(NEW_PROC_API, 1,
1013       [Define if you want to use new multi-fd /proc interface
1014        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1015       ;;
1016   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1017       AC_DEFINE(NEW_PROC_API, 1,
1018       [Define if you want to use new multi-fd /proc interface
1019        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1020       ;;
1021   mips-sgi-irix5*)
1022       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1023       AC_DEFINE([_KMEMUSER], 1,
1024       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1025        around a <sys/proc.h> problem on IRIX 5.])
1026       ;;
1027   esac
1028 fi
1029
1030 if test "$ac_cv_header_sys_procfs_h" = yes; then
1031   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
1032   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
1033   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1034   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1035   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1036   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1037   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1038   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
1039   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1040   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1041   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1042   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1043   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1044   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1045
1046
1047   dnl Check for broken prfpregset_t type
1048
1049   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1050   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1051   dnl instead of the struct itself).  We detect this here, and work
1052   dnl around it in gdb_proc_service.h.
1053
1054   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1055     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1056     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1057       [AC_TRY_RUN([#include <sys/procfs.h>
1058        int main ()
1059        {
1060          if (sizeof (prfpregset_t) == sizeof (void *))
1061            return 1;
1062          return 0;
1063        }],
1064        gdb_cv_prfpregset_t_broken=no,
1065        gdb_cv_prfpregset_t_broken=yes,
1066        gdb_cv_prfpregset_t_broken=yes)])
1067     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1068     if test $gdb_cv_prfpregset_t_broken = yes; then
1069       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1070       [Define if the prfpregset_t type is broken.])
1071     fi
1072   fi
1073
1074   dnl Check for PIOCSET ioctl entry
1075
1076   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
1077   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
1078   [AC_TRY_COMPILE([#include <unistd.h>
1079 #include <sys/types.h>
1080 #include <sys/procfs.h>
1081 ], [
1082     int dummy;;
1083     dummy = ioctl(0, PIOCSET, &dummy);
1084   ],
1085   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
1086   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
1087   if test $gdb_cv_have_procfs_piocset = yes; then
1088     AC_DEFINE(HAVE_PROCFS_PIOCSET, 1,
1089     [Define if ioctl argument PIOCSET is available.])
1090   fi
1091 fi
1092
1093 dnl For native ports (host == target), check to see what kind of
1094 dnl legacy link.h support is needed.  (See solib-legacy.c.)
1095 if test ${host} = ${target} ; then
1096   dnl Check for struct link_map with l_ members which are indicative
1097   dnl of SVR4-like shared libraries
1098
1099   AC_MSG_CHECKING(for member l_addr in struct link_map)
1100   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
1101     [AC_TRY_COMPILE([#include <link.h>],
1102                     [struct link_map lm; (void) lm.l_addr;],
1103                     gdb_cv_have_struct_link_map_with_l_members=yes,
1104                     gdb_cv_have_struct_link_map_with_l_members=no)])
1105   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
1106   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
1107     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS,1,
1108     [Define if <link.h> exists and defines struct link_map which has
1109      members with an ``l_'' prefix.  (For Solaris, SVR4, and
1110      SVR4-like systems.)])
1111   fi
1112
1113   dnl Check for struct link_map with lm_ members which are indicative
1114   dnl of SunOS-like shared libraries
1115
1116   AC_MSG_CHECKING(for member lm_addr in struct link_map)
1117   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
1118     [AC_TRY_COMPILE([#include <sys/types.h>
1119 #include <link.h>],
1120                     [struct link_map lm; (void) lm.lm_addr;],
1121                     gdb_cv_have_struct_link_map_with_lm_members=yes,
1122                     gdb_cv_have_struct_link_map_with_lm_members=no)])
1123   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
1124   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
1125     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS, 1,
1126     [Define if <link.h> exists and defines struct link_map which has
1127      members with an ``lm_'' prefix.  (For SunOS.)])
1128   fi
1129
1130   dnl Check for struct so_map with som_ members which are found on
1131   dnl some *BSD systems.
1132
1133   AC_MSG_CHECKING(for member som_addr in struct so_map)
1134   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
1135     [AC_TRY_COMPILE([#include <sys/types.h>
1136 #ifdef HAVE_NLIST_H
1137 #include <nlist.h>
1138 #endif
1139 #include <link.h>],
1140                     [struct so_map lm; (void) lm.som_addr;],
1141                     gdb_cv_have_struct_so_map_with_som_members=yes,
1142                     gdb_cv_have_struct_so_map_with_som_members=no)])
1143   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
1144   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
1145     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS, 1,
1146     [Define if <link.h> exists and defines a struct so_map which has
1147      members with an ``som_'' prefix.  (Found on older *BSD systems.)])
1148   fi
1149
1150   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
1151   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
1152
1153   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
1154   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
1155     [AC_TRY_COMPILE([#define _SYSCALL32
1156 #include <sys/link.h>], [struct link_map32 l;],
1157      gdb_cv_have_struct_link_map32=yes,
1158      gdb_cv_have_struct_link_map32=no)])
1159   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
1160   if test $gdb_cv_have_struct_link_map32 = yes; then
1161     AC_DEFINE(HAVE_STRUCT_LINK_MAP32, 1,
1162     [Define if <sys/link.h> has struct link_map32])
1163     AC_DEFINE(_SYSCALL32, 1,
1164     [Define if <sys/link.h> has link_map32 (solaris sparc-64 target)])
1165   fi
1166 fi
1167
1168 # Check if the compiler supports the `long long' type.
1169
1170 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1171                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1172 [[extern long long foo;]],
1173 [[switch (foo & 2) { case 0: return 1; }]])],
1174                                   gdb_cv_c_long_long=yes,
1175                                   gdb_cv_c_long_long=no)])
1176 if test $gdb_cv_c_long_long = yes; then
1177   AC_DEFINE(CC_HAS_LONG_LONG, 1,
1178             [Define to 1 if the compiler supports long long.])
1179 fi
1180
1181 # Check if the compiler and runtime support printing long longs.
1182
1183 AC_CACHE_CHECK([for long long support in printf],
1184                gdb_cv_printf_has_long_long,
1185                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1186 [[char buf[32];
1187   long long l = 0;
1188   l = (l << 16) + 0x0123;
1189   l = (l << 16) + 0x4567;
1190   l = (l << 16) + 0x89ab;
1191   l = (l << 16) + 0xcdef;
1192   sprintf (buf, "0x%016llx", l);
1193   return (strcmp ("0x0123456789abcdef", buf));]])],
1194                               gdb_cv_printf_has_long_long=yes,
1195                               gdb_cv_printf_has_long_long=no,
1196                               gdb_cv_printf_has_long_long=no)])
1197 if test $gdb_cv_printf_has_long_long = yes; then
1198   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1199             [Define to 1 if the "%ll" format works to print long longs.])
1200 fi
1201
1202 # Check if the compiler and runtime support printing decfloats.
1203
1204 AC_CACHE_CHECK([for decfloat support in printf],
1205                gdb_cv_printf_has_decfloat,
1206                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1207 [[char buf[64];
1208   _Decimal32 d32 = 1.2345df;
1209   _Decimal64 d64 = 1.2345dd;
1210   _Decimal128 d128 = 1.2345dl;
1211   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1212   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1213                               gdb_cv_printf_has_decfloat=yes,
1214                               gdb_cv_printf_has_decfloat=no,
1215                               gdb_cv_printf_has_decfloat=no)])
1216 if test $gdb_cv_printf_has_decfloat = yes; then
1217   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1218             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1219 fi
1220
1221 # Check if the compiler supports the `long double' type.  We can't use
1222 # AC_C_LONG_DOUBLE because that one does additional checks on the
1223 # constants defined in <float.h> that fail on some systems,
1224 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1225
1226 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1227                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1228                                   gdb_cv_c_long_double=yes,
1229                                   gdb_cv_c_long_double=no)])
1230 if test $gdb_cv_c_long_double = yes; then
1231   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1232            [Define to 1 if the compiler supports long double.])
1233 fi
1234
1235 # Check if the compiler and runtime support printing long doubles.
1236
1237 AC_CACHE_CHECK([for long double support in printf],
1238                gdb_cv_printf_has_long_double,
1239                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1240 [[char buf[16];
1241   long double f = 3.141592653;
1242   sprintf (buf, "%Lg", f);
1243   return (strncmp ("3.14159", buf, 7));]])],
1244                               gdb_cv_printf_has_long_double=yes,
1245                               gdb_cv_printf_has_long_double=no,
1246                               gdb_cv_printf_has_long_double=no)])
1247 if test $gdb_cv_printf_has_long_double = yes; then
1248   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1249             [Define to 1 if the "%Lg" format works to print long doubles.])
1250 fi
1251
1252 # Check if the compiler and runtime support scanning long doubles.
1253
1254 AC_CACHE_CHECK([for long double support in scanf],
1255                gdb_cv_scanf_has_long_double,
1256                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1257 [[#include <stdio.h>]],
1258 [[char *buf = "3.141592653";
1259   long double f = 0;
1260   sscanf (buf, "%Lg", &f);
1261   return !(f > 3.14159 && f < 3.14160);]])],
1262                               gdb_cv_scanf_has_long_double=yes,
1263                               gdb_cv_scanf_has_long_double=no,
1264                               gdb_cv_scanf_has_long_double=no)])
1265 if test $gdb_cv_scanf_has_long_double = yes; then
1266   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1267             [Define to 1 if the "%Lg" format works to scan long doubles.])
1268 fi
1269
1270 case ${host_os} in
1271 aix*)
1272   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1273     SAVE_LDFLAGS=$LDFLAGS
1274
1275     case $GCC in
1276     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1277     *) gdb_cv_bigtoc=-bbigtoc ;;
1278     esac
1279
1280     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1281     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1282     LDFLAGS="${SAVE_LDFLAGS}"
1283   ])
1284   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1285   ;;
1286 esac
1287
1288
1289 dnl For certain native configurations, we need to check whether thread
1290 dnl support can be built in or not.
1291 dnl
1292 dnl Note that we only want this if we are both native (host == target),
1293 dnl and not doing a canadian cross build (build == host).
1294
1295 if test ${build} = ${host} -a ${host} = ${target} ; then
1296    case ${host_os} in
1297    hpux*)
1298       AC_MSG_CHECKING(for HPUX/OSF thread support)
1299       if test -f /usr/include/dce/cma_config.h ; then
1300          if test "$GCC" = "yes" ; then
1301             AC_MSG_RESULT(yes)
1302             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT, 1,
1303             [Define if you have HPUX threads])
1304             CONFIG_OBS="${CONFIG_OBS} hpux-thread.o"
1305             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
1306          else
1307             AC_MSG_RESULT(no (suppressed because you are not using GCC))
1308          fi
1309       else
1310          AC_MSG_RESULT(no)
1311       fi
1312       ;;
1313    solaris*)
1314       # See if thread_db library is around for Solaris thread debugging.
1315       # Note that we must explicitly test for version 1 of the library
1316       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1317       # the same API.
1318       AC_MSG_CHECKING(for Solaris thread debugging library)
1319       if test -f /usr/lib/libthread_db.so.1 ; then
1320          AC_MSG_RESULT(yes)
1321          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1322          [Define if using Solaris thread debugging.])
1323          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1324          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1325          AC_CHECK_LIB(dl, dlopen)
1326          if test "$GCC" = "yes" ; then
1327             # The GNU linker requires the -export-dynamic option to make
1328             # all symbols visible in the dynamic symbol table.
1329             hold_ldflags=$LDFLAGS
1330             AC_MSG_CHECKING(for the ld -export-dynamic flag)
1331             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
1332             AC_TRY_LINK(, [int i;], found=yes, found=no)
1333             LDFLAGS=$hold_ldflags
1334             AC_MSG_RESULT($found)
1335             if test $found = yes; then
1336                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
1337             fi
1338          fi
1339          # Sun randomly tweaked the prototypes in <proc_service.h>
1340          # at one point.
1341          AC_MSG_CHECKING(if <proc_service.h> is old)
1342          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1343             AC_TRY_COMPILE([
1344                 #include <proc_service.h>
1345                 ps_err_e ps_pdwrite
1346                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1347             ],, gdb_cv_proc_service_is_old=no,
1348                 gdb_cv_proc_service_is_old=yes)
1349          ])
1350          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1351          if test $gdb_cv_proc_service_is_old = yes; then
1352             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1353             [Define if <proc_service.h> on solaris uses int instead of
1354              size_t, and assorted other type changes.])
1355          fi
1356       else
1357          AC_MSG_RESULT(no)
1358       fi
1359       ;;
1360    aix*)
1361       AC_MSG_CHECKING(for AiX thread debugging library)
1362       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1363                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1364                                    [#ifndef PTHDB_VERSION_3
1365                                     #error
1366                                     #endif],
1367                                    gdb_cv_have_aix_thread_debug=yes,
1368                                    gdb_cv_have_aix_thread_debug=no)])
1369       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1370       if test $gdb_cv_have_aix_thread_debug = yes; then
1371          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1372          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1373          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
1374       fi
1375       ;;
1376    esac
1377    AC_SUBST(CONFIG_LDFLAGS)
1378 fi
1379
1380 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1381 dnl other error codes.
1382 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1383    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1384                   gdb_cv_thread_db_h_has_td_notalloc,
1385      AC_TRY_COMPILE(
1386        [#include <thread_db.h>],
1387        [int i = TD_NOTALLOC;],
1388        gdb_cv_thread_db_h_has_td_notalloc=yes,
1389        gdb_cv_thread_db_h_has_td_notalloc=no
1390      )
1391    )
1392    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1393                   gdb_cv_thread_db_h_has_td_version,
1394      AC_TRY_COMPILE(
1395        [#include <thread_db.h>],
1396        [int i = TD_VERSION;],
1397        gdb_cv_thread_db_h_has_td_version=yes,
1398        gdb_cv_thread_db_h_has_td_version=no
1399      )
1400    )
1401    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1402                   gdb_cv_thread_db_h_has_td_notls,
1403      AC_TRY_COMPILE(
1404        [#include <thread_db.h>],
1405        [int i = TD_NOTLS;],
1406        gdb_cv_thread_db_h_has_td_notls=yes,
1407        gdb_cv_thread_db_h_has_td_notls=no
1408      )
1409    )
1410 fi
1411 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1412   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1413             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1414 fi
1415 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1416   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1417             [Define if <thread_db.h> has the TD_VERSION error code.])
1418 fi
1419 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1420   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1421             [Define if <thread_db.h> has the TD_NOTLS error code.])
1422 fi
1423
1424 dnl See if we have a sys/syscall header file that has __NR_tkill.
1425 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1426    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1427                   gdb_cv_sys_syscall_h_has_tkill,
1428      AC_TRY_COMPILE(
1429        [#include <sys/syscall.h>],
1430        [int i = __NR_tkill;],
1431        gdb_cv_sys_syscall_h_has_tkill=yes,
1432        gdb_cv_sys_syscall_h_has_tkill=no
1433      )
1434    )
1435 fi
1436 dnl See if we can issue tkill syscall.
1437 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1438   AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1439 fi
1440
1441 dnl Check if we can disable the virtual address space randomization.
1442 dnl The functionality of setarch -R.
1443 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1444 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1445 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1446 #       define ADDR_NO_RANDOMIZE 0x0040000
1447 #      endif
1448        /* Test the flag could be set and stays set.  */
1449        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1450        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1451            return 1])])
1452 AC_RUN_IFELSE([PERSONALITY_TEST],
1453               [have_personality=true],
1454               [have_personality=false],
1455               [AC_LINK_IFELSE([PERSONALITY_TEST],
1456                               [have_personality=true],
1457                               [have_personality=false])])
1458 if $have_personality
1459 then
1460     AC_DEFINE([HAVE_PERSONALITY], 1,
1461               [Define if you support the personality syscall.])
1462 fi
1463
1464 dnl Handle optional features that can be enabled.
1465
1466 target_sysroot_reloc=0
1467 AC_ARG_WITH(sysroot,
1468 AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@], [search for usr/lib et al within DIR]),
1469 [
1470  case ${with_sysroot} in
1471  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
1472  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
1473  esac
1474
1475  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
1476
1477  if test "x$prefix" = xNONE; then
1478   test_prefix=/usr/local
1479  else
1480   test_prefix=$prefix
1481  fi
1482  if test "x$exec_prefix" = xNONE || test "x$exec_prefix" = 'x${prefix}'; then
1483   test_exec_prefix=$test_prefix
1484  else
1485   test_exec_prefix=$exec_prefix
1486  fi
1487  case ${TARGET_SYSTEM_ROOT} in
1488  "${test_prefix}"|"${test_prefix}/"*|\
1489  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
1490  '${prefix}'|'${prefix}/'*|\
1491  '${exec_prefix}'|'${exec_prefix}/'*)
1492    target_sysroot_reloc=1
1493    ;;
1494  esac
1495 ], [
1496  TARGET_SYSTEM_ROOT=
1497  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
1498 ])
1499 TARGET_SYSTEM_ROOT_DEFINE="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE=$target_sysroot_reloc"
1500 AC_SUBST(TARGET_SYSTEM_ROOT)
1501 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
1502
1503 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1504     [automatically load a system-wide gdbinit file],
1505     [])
1506
1507 AC_ARG_ENABLE(werror,
1508   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
1509   [case "${enableval}" in
1510      yes | y) ERROR_ON_WARNING="yes" ;;
1511      no | n)  ERROR_ON_WARNING="no" ;;
1512      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1513    esac])
1514
1515 # Enable -Werror by default when using gcc
1516 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" ; then
1517     ERROR_ON_WARNING=yes
1518 fi
1519
1520 WERROR_CFLAGS=""
1521 if test "${ERROR_ON_WARNING}" = yes ; then
1522     WERROR_CFLAGS="-Werror"
1523 fi
1524
1525 # The entries after -Wno-pointer-sign are disabled warnings which may
1526 # be enabled in the future, which can not currently be used to build
1527 # GDB.
1528 # NOTE: If you change this list, remember to update
1529 # gdb/doc/gdbint.texinfo.
1530 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1531 -Wformat-nonliteral -Wno-pointer-sign \
1532 -Wno-unused -Wno-switch -Wno-char-subscripts"
1533
1534 # Enable -Wno-format by default when using gcc on mingw since many
1535 # GCC versions complain about %I64.
1536 case "${host}" in
1537   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
1538 esac
1539
1540 AC_ARG_ENABLE(build-warnings,
1541 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
1542 [case "${enableval}" in
1543   yes)  ;;
1544   no)   build_warnings="-w";;
1545   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1546         build_warnings="${build_warnings} ${t}";;
1547   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1548         build_warnings="${t} ${build_warnings}";;
1549   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1550 esac
1551 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1552   echo "Setting compiler warning flags = $build_warnings" 6>&1
1553 fi])dnl
1554 AC_ARG_ENABLE(gdb-build-warnings,
1555 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
1556 [case "${enableval}" in
1557   yes)  ;;
1558   no)   build_warnings="-w";;
1559   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1560         build_warnings="${build_warnings} ${t}";;
1561   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1562         build_warnings="${t} ${build_warnings}";;
1563   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1564 esac
1565 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1566   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1567 fi])dnl
1568 WARN_CFLAGS=""
1569 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1570 then
1571     AC_MSG_CHECKING(compiler warning flags)
1572     # Separate out the -Werror flag as some files just cannot be
1573     # compiled with it enabled.
1574     for w in ${build_warnings}; do
1575         case $w in
1576         -Werr*) WERROR_CFLAGS=-Werror ;;
1577         *) # Check that GCC accepts it
1578             saved_CFLAGS="$CFLAGS"
1579             CFLAGS="$CFLAGS $w"
1580             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1581             CFLAGS="$saved_CFLAGS"
1582         esac
1583     done
1584     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
1585 fi
1586 AC_SUBST(WARN_CFLAGS)
1587 AC_SUBST(WERROR_CFLAGS)
1588
1589 # In the Cygwin environment, we need some additional flags.
1590 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1591 [AC_EGREP_CPP(lose, [
1592 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1593 lose
1594 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1595
1596
1597 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1598 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1599 case ${host} in
1600   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1601   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1602   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1603 esac
1604 AC_SUBST(SER_HARDWIRE)
1605
1606 # libreadline needs libuser32.a in a cygwin environment
1607 WIN32LIBS=
1608 if test x$gdb_cv_os_cygwin = xyes; then
1609     WIN32LIBS="-luser32"
1610     case "${target}" in
1611         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1612         ;;
1613     esac
1614 fi
1615
1616 # The ser-tcp.c module requires sockets.
1617 case ${host} in
1618   *mingw32*)
1619     AC_DEFINE(USE_WIN32API, 1,
1620               [Define if we should use the Windows API, instead of the
1621                POSIX API.  On Windows, we use the Windows API when
1622                building for MinGW, but the POSIX API when building
1623                for Cygwin.])
1624     WIN32LIBS="$WIN32LIBS -lws2_32"
1625     ;;
1626 esac
1627 AC_SUBST(WIN32LIBS)
1628
1629 # Add ELF support to GDB, but only if BFD includes ELF support.
1630 OLD_CFLAGS=$CFLAGS
1631 OLD_LDFLAGS=$LDFLAGS
1632 OLD_LIBS=$LIBS
1633 CFLAGS="$CFLAGS -I${srcdir}/../include -I../bfd -I${srcdir}/../bfd"
1634 LDFLAGS="$LDFLAGS -L../bfd -L../libiberty"
1635 intl=`echo $LIBINTL | sed 's,${top_builddir}/,,g'`
1636 LIBS="-lbfd -liberty $intl $LIBS"
1637 AC_CACHE_CHECK([for ELF support in BFD], gdb_cv_var_elf,
1638 [AC_TRY_LINK(
1639 [#include <stdlib.h>
1640 #include "bfd.h"
1641 #include "elf-bfd.h"
1642 ],
1643 [bfd *abfd = NULL; bfd_get_elf_phdr_upper_bound (abfd); ],
1644 gdb_cv_var_elf=yes, gdb_cv_var_elf=no)])
1645 if test $gdb_cv_var_elf = yes; then
1646   CONFIG_OBS="$CONFIG_OBS elfread.o"
1647   AC_DEFINE(HAVE_ELF, 1,
1648             [Define if ELF support should be included.])
1649 fi
1650 CFLAGS=$OLD_CFLAGS
1651 LDFLAGS=$OLD_LDFLAGS
1652 LIBS=$OLD_LIBS
1653
1654 # Add any host-specific objects to GDB.
1655 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1656
1657 LIBGUI="../libgui/src/libgui.a"
1658 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1659 AC_SUBST(LIBGUI)
1660 AC_SUBST(GUI_CFLAGS_X)
1661
1662 WIN32LDAPP=
1663 AC_SUBST(WIN32LIBS)
1664 AC_SUBST(WIN32LDAPP)
1665
1666 case "${host}" in
1667 *-*-cygwin* | *-*-mingw* )
1668     configdir="win"
1669     ;;
1670 *)
1671     configdir="unix"
1672     ;;
1673 esac
1674
1675 GDBTKLIBS=
1676 if test "${enable_gdbtk}" = "yes"; then
1677
1678     # Gdbtk must have an absolute path to srcdir in order to run
1679     # properly when not installed.
1680     here=`pwd`
1681     cd ${srcdir}
1682     GDBTK_SRC_DIR=`pwd`
1683     cd $here
1684
1685     SC_PATH_TCLCONFIG
1686
1687     # If $no_tk is nonempty, then we can't do Tk, and there is no
1688     # point to doing Tcl.
1689     SC_PATH_TKCONFIG
1690
1691     if test -z "${no_tcl}" -a -z "${no_tk}"; then
1692         SC_LOAD_TCLCONFIG
1693
1694         # Check for in-tree tcl
1695         here=`pwd`
1696         cd ${srcdir}/..
1697         topdir=`pwd`
1698         cd ${here}
1699
1700         intree="no"
1701         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
1702           intree="yes"
1703         fi
1704
1705         # Find Tcl private headers
1706         if test x"${intree}" = xno; then
1707           CY_AC_TCL_PRIVATE_HEADERS
1708           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
1709           TCL_LIBRARY="${TCL_LIB_SPEC}"
1710           TCL_DEPS=""
1711         else
1712           # If building tcl in the same src tree, private headers
1713           # are not needed, but we need to be sure to use the right
1714           # headers library
1715           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
1716           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
1717           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
1718         fi
1719         AC_SUBST(TCL_INCLUDE)
1720         AC_SUBST(TCL_LIBRARY)
1721         AC_SUBST(TCL_DEPS)
1722
1723         SC_LOAD_TKCONFIG
1724
1725         # Check for in-tree Tk
1726         intree="no"
1727         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
1728           intree="yes"
1729         fi
1730
1731         # Find Tk private headers
1732         if test x"${intree}" = xno; then
1733           CY_AC_TK_PRIVATE_HEADERS
1734           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
1735           TK_LIBRARY=${TK_LIB_SPEC}
1736           TK_DEPS=""
1737         else
1738           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
1739           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
1740           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
1741         fi
1742         AC_SUBST(TK_INCLUDE)
1743         AC_SUBST(TK_LIBRARY)
1744         AC_SUBST(TK_DEPS)
1745         AC_SUBST(TK_XINCLUDES)
1746
1747         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1748
1749         # Include some libraries that Tcl and Tk want.
1750         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1751         # Yes, the ordering seems wrong here.  But it isn't.
1752         # TK_LIBS is the list of libraries that need to be linked
1753         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
1754         # were in LIBS then any link tests after this point would
1755         # try to include things like `$(LIBGUI)', which wouldn't work.
1756         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1757
1758         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1759         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1760         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1761         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
1762         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
1763         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
1764         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
1765
1766         if test x$gdb_cv_os_cygwin = xyes; then
1767           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
1768           WIN32LDAPP="-Wl,--subsystem,console"
1769           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
1770         fi
1771
1772         AC_CONFIG_SUBDIRS(gdbtk)
1773     fi
1774 fi
1775
1776 AC_SUBST(X_CFLAGS)
1777 AC_SUBST(X_LDFLAGS)
1778 AC_SUBST(X_LIBS)
1779 AC_SUBST(GDBTKLIBS)
1780 AC_SUBST(GDBTK_CFLAGS)
1781 AC_SUBST(GDBTK_SRC_DIR)
1782
1783 AC_PATH_X
1784
1785 # Unlike the sim directory, whether a simulator is linked is controlled by
1786 # presence of a gdb_sim definition in the target configure.tgt entry.
1787 # This code just checks for a few cases where we'd like to ignore those
1788 # definitions, even when they're present in the '.mt' file.  These cases
1789 # are when --disable-sim is specified, or if the simulator directory is
1790 # not part of the source tree.
1791 #
1792 AC_ARG_ENABLE(sim,
1793 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
1794 [echo "enable_sim = $enable_sim";
1795  echo "enableval = ${enableval}";
1796  case "${enableval}" in
1797   yes) ignore_sim=false ;;
1798   no)  ignore_sim=true ;;
1799   *)   ignore_sim=false ;;
1800  esac],
1801 [ignore_sim=false])
1802
1803 if test ! -d "${srcdir}/../sim"; then
1804   ignore_sim=true
1805 fi
1806
1807 SIM=
1808 SIM_OBS=
1809 if test "${ignore_sim}" = "false"; then
1810   if test x"${gdb_sim}" != x ; then
1811     SIM="${gdb_sim}"
1812     SIM_OBS="remote-sim.o"
1813     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
1814   fi
1815 fi
1816 AC_SUBST(SIM)
1817 AC_SUBST(SIM_OBS)
1818
1819 AC_SUBST(ENABLE_CFLAGS)
1820 AC_SUBST(PROFILE_CFLAGS)
1821
1822 AC_SUBST(CONFIG_OBS)
1823 AC_SUBST(CONFIG_DEPS)
1824 AC_SUBST(CONFIG_SRCS)
1825 AC_SUBST(CONFIG_ALL)
1826 AC_SUBST(CONFIG_CLEAN)
1827 AC_SUBST(CONFIG_INSTALL)
1828 AC_SUBST(CONFIG_UNINSTALL)
1829
1830 # List of host floatformats.
1831 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
1832 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
1833 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
1834
1835 # target_subdir is used by the testsuite to find the target libraries.
1836 target_subdir=
1837 if test "${host}" != "${target}"; then
1838     target_subdir="${target_alias}/"
1839 fi
1840 AC_SUBST(target_subdir)
1841
1842 frags=
1843 if test "${gdb_native}" = "yes"; then
1844   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
1845   if test ! -f ${host_makefile_frag}; then
1846     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
1847   fi
1848   frags="$frags $host_makefile_frag"
1849 else
1850   host_makefile_frag=/dev/null
1851 fi
1852
1853 AC_SUBST_FILE(host_makefile_frag)
1854 AC_SUBST(frags)
1855
1856 changequote(,)dnl
1857 if test "${gdb_native}" = "yes"; then
1858 # We pick this up from the host configuration file (.mh) because we
1859 # do not have a native configuration Makefile fragment.
1860 nativefile=`sed -n '
1861 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
1862 ' ${host_makefile_frag}`
1863 fi
1864 changequote([,])
1865
1866 if test x"${gdb_osabi}" != x ; then
1867     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
1868                        [Define to the default OS ABI for this configuration.])
1869 fi
1870
1871 # Enable multi-ice-gdb-server.
1872 AC_ARG_ENABLE(multi-ice,
1873 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
1874   [case $enableval in
1875     yes | no)
1876       ;;
1877     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
1878   esac])
1879 if test "x$enable_multi_ice" = xyes; then
1880    AC_CONFIG_SUBDIRS(multi-ice)
1881 fi
1882
1883 # We only build gdbserver automatically in a native configuration.
1884 if test "$gdb_native" = "yes"; then
1885   AC_MSG_CHECKING(whether gdbserver is supported on this host)
1886   if test "x$build_gdbserver" = xyes; then
1887     AC_MSG_RESULT(yes)
1888     AC_CONFIG_SUBDIRS(gdbserver)
1889   else
1890     AC_MSG_RESULT(no)
1891   fi
1892 fi
1893
1894 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
1895 # to an empty version.
1896
1897 files=
1898 links=
1899
1900 rm -f nm.h
1901 if test "${nativefile}" != ""; then
1902     case "${nativefile}" in
1903       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
1904       * ) GDB_NM_FILE="${nativefile}"
1905     esac
1906     files="${files} ${GDB_NM_FILE}"
1907     links="${links} nm.h"
1908     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
1909 fi
1910 AC_SUBST(GDB_NM_FILE)
1911
1912 AC_LINK_FILES($files, $links)
1913
1914 dnl Check for exe extension set on certain hosts (e.g. Win32)
1915 AC_EXEEXT
1916
1917 dnl  Detect the character set used by this host.
1918 dnl  At the moment, we just assume it's UTF-8.
1919 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
1920           [Define to be a string naming the default host character set.])
1921
1922 # Flags needed to enable html installing and building
1923 AC_ARG_WITH(datarootdir,
1924 AC_HELP_STRING([--with-datarootdir], [use datarootdir as the data root directory.]),
1925 [datarootdir="\${prefix}/${withval}"],
1926 [datarootdir="\${prefix}/share"])
1927
1928 AC_ARG_WITH(docdir,
1929 AC_HELP_STRING([--with-docdir], [install documentation in this directory.]),
1930 [docdir="\${prefix}/${withval}"],
1931 [docdir="\${datarootdir}/doc"])
1932
1933 AC_ARG_WITH(pdfdir,
1934 AC_HELP_STRING([--with-pdfdir], [install pdf in this directory.]),
1935 [pdfdir="\${prefix}/${withval}"],
1936 [pdfdir="\${docdir}"])
1937
1938 AC_ARG_WITH(htmldir,
1939 AC_HELP_STRING([--with-htmldir], [install html in this directory.]),
1940 [htmldir="\${prefix}/${withval}"],
1941 [htmldir="\${docdir}"])
1942
1943 AC_SUBST(datarootdir)
1944 AC_SUBST(docdir)
1945 AC_SUBST(htmldir)
1946 AC_SUBST(pdfdir)
1947
1948 AC_OUTPUT(Makefile .gdbinit:gdbinit.in gnulib/Makefile,
1949 [
1950 case x$CONFIG_HEADERS in
1951 xconfig.h:config.in)
1952 echo > stamp-h ;;
1953 esac
1954 ])
1955
1956 exit 0