gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   3 dnl 2005, 2006, 2007, 2008
   4 dnl Free Software Foundation, Inc.
   5 dnl
   6 dnl This file is part of GDB.
   7 dnl
   8 dnl This program is free software; you can redistribute it and/or modify
   9 dnl it under the terms of the GNU General Public License as published by
  10 dnl the Free Software Foundation; either version 3 of the License, or
  11 dnl (at your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful,
  14 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl GNU General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 dnl Process this file with autoconf to produce a configure script.
  22
  23 AC_PREREQ(2.59)dnl
  24 AC_INIT(main.c)
  25 AC_CONFIG_HEADER(config.h:config.in)
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_GNU_SOURCE
  30 AC_AIX
  31 AC_ISC_POSIX
  32 gl_EARLY
  33 AM_PROG_CC_STDC
  34
  35 AC_CONFIG_AUX_DIR(..)
  36 AC_CANONICAL_SYSTEM
  37
  38 dnl List of object files and targets accumulated by configure.
  39
  40 CONFIG_OBS=
  41 CONFIG_DEPS=
  42 CONFIG_SRCS=
  43 ENABLE_CFLAGS=
  44
  45 CONFIG_ALL=
  46 CONFIG_CLEAN=
  47 CONFIG_INSTALL=
  48 CONFIG_UNINSTALL=
  49
  50 dnl Set up for gettext.
  51 ZW_GNU_GETTEXT_SISTER_DIR
  52
  53 localedir='${datadir}/locale'
  54 AC_SUBST(localedir)
  55
  56 if test x"$USE_NLS" = xyes; then
  57    CONFIG_ALL="$CONFIG_ALL all-po"
  58    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  59    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  60    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  61 fi
  62
  63 gl_INIT
  64
  65 # For Makefile dependencies.
  66 GNULIB_STDINT_H=
  67 if test x"$STDINT_H" != x; then
  68   GNULIB_STDINT_H=gnulib/$STDINT_H
  69 fi
  70 AC_SUBST(GNULIB_STDINT_H)
  71
  72 PACKAGE=gdb
  73 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  74 AC_SUBST(PACKAGE)
  75
  76 # GDB does not use automake, but gnulib does.  This line lets us
  77 # generate its Makefile.in.
  78 AM_INIT_AUTOMAKE(gdb, UNUSED-VERSION, [no-define])
  79
  80 debugdir=${libdir}/debug
  81
  82 AC_ARG_WITH(separate-debug-dir,
  83 [  --with-separate-debug-dir=path   Look for global separate debug info in this path [LIBDIR/debug]],
  84 [debugdir="${withval}"])
  85
  86 AC_DEFINE_DIR(DEBUGDIR, debugdir,
  87               [Global directory for separate debug files. ])
  88 #AC_DEFINE_UNQUOTED(DEBUGDIR, "$debugdir"),
  89
  90 if test "x$exec_prefix" = xNONE || test "x$exec_prefix" = 'x${prefix}'; then
  91   if test "x$prefix" = xNONE; then
  92     test_prefix=/usr/local
  93   else
  94     test_prefix=$prefix
  95   fi
  96 else
  97   test_prefix=$exec_prefix
  98 fi
  99 case ${debugdir} in
 100 "${test_prefix}"|"${test_prefix}/"*|\
 101 '${exec_prefix}'|'${exec_prefix}/'*)
 102   AC_DEFINE(DEBUGDIR_RELOCATABLE, 1, [Define if the debug directory should be relocated when GDB is moved.])
 103   ;;
 104 esac
 105
 106 AC_CONFIG_SUBDIRS(doc testsuite)
 107
 108 # Check whether to support alternative target configurations
 109 AC_ARG_ENABLE(targets,
 110 [  --enable-targets        alternative target configurations],
 111 [case "${enableval}" in
 112   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 113             ;;
 114   no)       enable_targets= ;;
 115   *)        enable_targets=$enableval ;;
 116 esac])
 117
 118 # Check whether to enable 64-bit support on 32-bit hosts
 119 AC_ARG_ENABLE(64-bit-bfd,
 120 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
 121 [case "${enableval}" in
 122   yes)  want64=true  ;;
 123   no)   want64=false ;;
 124   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 125 esac],[want64=false])dnl
 126
 127 # Provide defaults for some variables set by the per-host and per-target
 128 # configuration.
 129 gdb_host_obs=posix-hdep.o
 130
 131 if test "${target}" = "${host}"; then
 132   gdb_native=yes
 133 else
 134   gdb_native=no
 135 fi
 136
 137 . $srcdir/configure.host
 138
 139 # Accumulate some settings from configure.tgt over all enabled targets
 140
 141 TARGET_OBS=
 142 all_targets=
 143
 144 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 145 do
 146   if test "$targ_alias" = "all"; then
 147     all_targets=true
 148   else
 149     # Canonicalize the secondary target names.
 150     result=`$ac_config_sub $targ_alias 2>/dev/null`
 151     if test -n "$result"; then
 152         targ=$result
 153     else
 154         targ=$targ_alias
 155     fi
 156
 157     . ${srcdir}/configure.tgt
 158
 159     # Target-specific object files
 160     for i in ${gdb_target_obs}; do
 161         case " $TARGET_OBS " in
 162         *" ${i} "*) ;;
 163         *)
 164           TARGET_OBS="$TARGET_OBS ${i}"
 165           ;;
 166         esac
 167     done
 168
 169     # Check whether this target needs 64-bit CORE_ADDR
 170     if test x${want64} = xfalse; then
 171       . ${srcdir}/../bfd/config.bfd
 172     fi
 173   fi
 174 done
 175
 176 if test x${all_targets} = xtrue; then
 177
 178   # We want all 64-bit targets if we either:
 179   #  - run on a 64-bit host  or
 180   #  - already require 64-bit support for some other target  or
 181   #  - the --enable-64-bit-bfd option was supplied
 182   # Otherwise we only support all 32-bit targets.
 183   #
 184   # NOTE: This test must be in sync with the corresponding
 185   #       tests in BFD!
 186
 187   if test x${want64} = xfalse; then
 188     AC_CHECK_SIZEOF(long)
 189     if test "x${ac_cv_sizeof_long}" = "x8"; then
 190       want64=true
 191     fi
 192   fi
 193   if test x${want64} = xtrue; then
 194     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 195   else
 196     TARGET_OBS='$(ALL_TARGET_OBS)'
 197   fi
 198 fi
 199
 200 AC_SUBST(TARGET_OBS)
 201
 202 # For other settings, only the main target counts.
 203 gdb_sim=
 204 gdb_osabi=
 205 build_gdbserver=
 206 targ=$target; . ${srcdir}/configure.tgt
 207
 208 # Fetch the default architecture and default target vector from BFD.
 209 targ=$target; . $srcdir/../bfd/config.bfd
 210
 211 # We only want the first architecture, so strip off the others if
 212 # there is more than one.
 213 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 214
 215 if test "x$targ_archs" != x; then
 216   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 217     [Define to BFD's default architecture. ])
 218 fi
 219 if test "x$targ_defvec" != x; then
 220   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 221     [Define to BFD's default target vector. ])
 222 fi
 223
 224 # The CLI cannot be disabled yet, but may be in the future.
 225
 226 # Enable CLI.
 227 AC_ARG_ENABLE(gdbcli,
 228 [  --disable-gdbcli        disable command-line interface (CLI)],
 229   [case $enableval in
 230     yes)
 231       ;;
 232     no)
 233       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 234     *)
 235       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 236   esac],
 237   [enable_gdbcli=yes])
 238 if test x"$enable_gdbcli" = xyes; then
 239   if test -d $srcdir/cli; then
 240     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 241     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 242     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 243     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 244   fi
 245 fi
 246
 247 # Enable MI.
 248 AC_ARG_ENABLE(gdbmi,
 249 [  --disable-gdbmi         disable machine-interface (MI)],
 250   [case $enableval in
 251     yes | no)
 252       ;;
 253     *)
 254       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 255   esac],
 256   [enable_gdbmi=yes])
 257 if test x"$enable_gdbmi" = xyes; then
 258   if test -d $srcdir/mi; then
 259     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 260     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 261     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 262     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 263   fi
 264 fi
 265
 266 # Enable TUI.
 267 AC_ARG_ENABLE(tui,
 268 [  --enable-tui            enable full-screen terminal user interface (TUI)],
 269   [case $enableval in
 270     yes | no | auto)
 271       ;;
 272     *)
 273       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 274   esac],enable_tui=auto)
 275
 276 # Enable gdbtk.
 277 AC_ARG_ENABLE(gdbtk,
 278 [  --enable-gdbtk          enable gdbtk graphical user interface (GUI)],
 279   [case $enableval in
 280     yes | no)
 281       ;;
 282     *)
 283       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 284   esac],
 285   [if test -d $srcdir/gdbtk -a -d $srcdir/../itcl; then
 286     enable_gdbtk=yes
 287   else
 288     enable_gdbtk=no
 289   fi])
 290 # We unconditionally disable gdbtk tests on selected platforms.
 291 case $host_os in
 292   go32* | windows*)
 293     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 294     enable_gdbtk=no ;;
 295 esac
 296
 297 # Libunwind support.
 298 AC_ARG_WITH(libunwind,
 299 [  --with-libunwind            Use libunwind frame unwinding support],
 300 [case "${withval}" in
 301   yes)  enable_libunwind=yes ;;
 302   no)   enable_libunwind=no ;;
 303   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;;
 304 esac],[
 305   AC_CHECK_HEADERS(libunwind.h)
 306   AC_CHECK_HEADERS(libunwind-ia64.h)
 307   if test x"$ac_cv_header_libunwind_h" = xyes -a x"$ac_cv_header_libunwind_ia64_h" = xyes; then
 308     enable_libunwind=yes;
 309   fi
 310 ])
 311
 312 if test x"$enable_libunwind" = xyes; then
 313   AC_CHECK_HEADERS(libunwind.h)
 314   AC_CHECK_HEADERS(libunwind-ia64.h)
 315   AC_DEFINE(HAVE_LIBUNWIND, 1, [Define if libunwind library is being used.])
 316   CONFIG_OBS="$CONFIG_OBS libunwind-frame.o"
 317   CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o"
 318   CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c"
 319 fi
 320
 321 # Profiling support.
 322 AC_ARG_ENABLE(profiling,
 323 [  --enable-profiling      enable profiling of GDB],
 324   [case $enableval in
 325     yes | no)
 326       ;;
 327     *)
 328       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 329   esac],
 330  [enable_profiling=no])
 331
 332 AC_CHECK_FUNCS(monstartup _mcleanup)
 333 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 334 [AC_TRY_LINK(
 335 [#include <stdlib.h>
 336 extern char _etext;
 337 ],
 338 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 339 if test $ac_cv_var__etext = yes; then
 340   AC_DEFINE(HAVE__ETEXT, 1,
 341             [Define to 1 if your system has the _etext variable. ])
 342 fi
 343 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 344 [AC_TRY_LINK(
 345 [#include <stdlib.h>
 346 extern char etext;
 347 ],
 348 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 349 if test $ac_cv_var_etext = yes; then
 350   AC_DEFINE(HAVE_ETEXT, 1,
 351             [Define to 1 if your system has the etext variable. ])
 352 fi
 353 if test "$enable_profiling" = yes ; then
 354   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 355     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 356   fi
 357   PROFILE_CFLAGS=-pg
 358   OLD_CFLAGS="$CFLAGS"
 359   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 360
 361   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 362     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 363      ac_cv_cc_supports_pg=no)])
 364
 365   if test $ac_cv_cc_supports_pg = no; then
 366     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 367   fi
 368
 369   CFLAGS="$OLD_CFLAGS"
 370 fi
 371
 372 ACX_PKGVERSION([GDB])
 373 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 374 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 375 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 376
 377 # --------------------- #
 378 # Checks for programs.  #
 379 # --------------------- #
 380
 381 AC_PROG_AWK
 382 AC_PROG_INSTALL
 383 AC_PROG_LN_S
 384 AC_PROG_RANLIB
 385 AC_PROG_YACC
 386
 387 AC_CHECK_TOOL(AR, ar)
 388 AC_CHECK_TOOL(DLLTOOL, dlltool)
 389 AC_CHECK_TOOL(WINDRES, windres)
 390
 391 # Needed for GNU/Hurd.
 392 AC_CHECK_TOOL(MIG, mig)
 393
 394 # ---------------------- #
 395 # Checks for libraries.  #
 396 # ---------------------- #
 397
 398 # We might need to link with -lm; most simulators need it.
 399 AC_CHECK_LIB(m, main)
 400
 401 # We need to link with -lw to get `wctype' on Solaris before Solaris
 402 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 403 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 404 # is known to have this problem).  Therefore we avoid libw if we can.
 405 AC_CHECK_FUNC(wctype, [],
 406   [AC_CHECK_LIB(w, wctype)])
 407
 408 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 409 AC_SEARCH_LIBS(gethostbyname, nsl)
 410
 411 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 412 AC_SEARCH_LIBS(socketpair, socket)
 413
 414 # Link in zlib if we can.  This allows us to read compressed debug sections.
 415 AC_SEARCH_LIBS(zlibVersion, z, [AC_CHECK_HEADERS(zlib.h)])
 416
 417 # For the TUI, we need enhanced curses functionality.
 418 #
 419 # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 420 # curses library because the latter might not provide all the
 421 # functionality we need.  However, this leads to problems on systems
 422 # where the linker searches /usr/local/lib, but the compiler doesn't
 423 # search /usr/local/include, if ncurses is installed in /usr/local.  A
 424 # default installation of ncurses on alpha*-dec-osf* will lead to such
 425 # a situation.
 426 AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 427
 428 # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c).
 429 AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl])
 430
 431 # Since GDB uses Readline, we need termcap functionality.  In many
 432 # cases this will be provided by the curses library, but some systems
 433 # have a seperate termcap library, or no curses library at all.
 434
 435 case $host_os in
 436   cygwin*)
 437     if test -d $srcdir/libtermcap; then
 438       LIBS="../libtermcap/libtermcap.a $LIBS"
 439       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 440     fi ;;
 441   go32* | *djgpp*)
 442     ac_cv_search_tgetent="none required"
 443     ;;
 444   *mingw32*)
 445     ac_cv_search_tgetent="none required"
 446     CONFIG_OBS="$CONFIG_OBS win32-termcap.o"
 447     ;;
 448 esac
 449
 450 # These are the libraries checked by Readline.
 451 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 452
 453 if test "$ac_cv_search_tgetent" = no; then
 454   AC_MSG_ERROR([no termcap library found])
 455 fi
 456
 457 AC_ARG_WITH([system-readline],
 458   [AS_HELP_STRING([--with-system-readline],
 459                   [use installed readline library])])
 460
 461 if test "$with_system_readline" = yes; then
 462   READLINE=-lreadline
 463   READLINE_DEPS=
 464   READLINE_CFLAGS=
 465 else
 466   READLINE='$(READLINE_DIR)/libreadline.a'
 467   READLINE_DEPS='$(READLINE)'
 468   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 469 fi
 470 AC_SUBST(READLINE)
 471 AC_SUBST(READLINE_DEPS)
 472 AC_SUBST(READLINE_CFLAGS)
 473
 474 AC_ARG_WITH(expat,
 475   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 476   [], [with_expat=auto])
 477 AC_MSG_CHECKING([whether to use expat])
 478 AC_MSG_RESULT([$with_expat])
 479
 480 if test "${with_expat}" = no; then
 481   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 482   HAVE_LIBEXPAT=no
 483 else
 484   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 485                         [XML_Parser p = XML_ParserCreate (0);])
 486   if test "$HAVE_LIBEXPAT" != yes; then
 487     if test "$with_expat" = yes; then
 488       AC_MSG_ERROR([expat is missing or unusable])
 489     else
 490       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 491     fi
 492   else
 493     save_LIBS=$LIBS
 494     LIBS="$LIBS $LIBEXPAT"
 495     AC_CHECK_FUNCS(XML_StopParser)
 496     LIBS=$save_LIBS
 497   fi
 498 fi
 499
 500 # ------------------------- #
 501 # Checks for header files.  #
 502 # ------------------------- #
 503
 504 AC_HEADER_DIRENT
 505 AC_HEADER_STAT
 506 AC_HEADER_STDC
 507 AC_CHECK_HEADERS(nlist.h)
 508 AC_CHECK_HEADERS(link.h, [], [],
 509 [#if HAVE_SYS_TYPES_H
 510 # include <sys/types.h>
 511 #endif
 512 #if HAVE_NLIST_H
 513 # include <nlist.h>
 514 #endif
 515 ])
 516 AC_CHECK_HEADERS(machine/reg.h)
 517 AC_CHECK_HEADERS(poll.h sys/poll.h)
 518 AC_CHECK_HEADERS(proc_service.h thread_db.h gnu/libc-version.h)
 519 AC_CHECK_HEADERS(signal.h)
 520 AC_CHECK_HEADERS(stddef.h)
 521 AC_CHECK_HEADERS(stdlib.h)
 522 AC_CHECK_HEADERS(string.h memory.h strings.h)
 523 AC_CHECK_HEADERS(sys/fault.h)
 524 AC_CHECK_HEADERS(sys/file.h)
 525 AC_CHECK_HEADERS(sys/filio.h)
 526 AC_CHECK_HEADERS(sys/ioctl.h)
 527 AC_CHECK_HEADERS(sys/param.h)
 528 AC_CHECK_HEADERS(sys/resource.h)
 529 AC_CHECK_HEADERS(sys/proc.h, [], [],
 530 [#if HAVE_SYS_PARAM_H
 531 # include <sys/param.h>
 532 #endif
 533 ])
 534 AC_CHECK_HEADERS(sys/procfs.h)
 535 AC_CHECK_HEADERS(sys/ptrace.h ptrace.h)
 536 AC_CHECK_HEADERS(sys/reg.h sys/debugreg.h)
 537 AC_CHECK_HEADERS(sys/select.h)
 538 AC_CHECK_HEADERS(sys/syscall.h)
 539 AC_CHECK_HEADERS(sys/types.h)
 540 AC_CHECK_HEADERS(sys/user.h, [], [],
 541 [#if HAVE_SYS_PARAM_H
 542 # include <sys/param.h>
 543 #endif
 544 ])
 545 AC_CHECK_HEADERS(sys/wait.h wait.h)
 546 AC_CHECK_HEADERS(termios.h termio.h sgtty.h)
 547 AC_CHECK_HEADERS(unistd.h)
 548
 549 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
 550 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
 551 # think that we don't have <curses.h> if we're using GCC.
 552 case $host_os in
 553   solaris2.[[789]])
 554     if test "$GCC" = yes; then
 555       AC_DEFINE(_MSE_INT_H, 1,
 556         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
 557    Solaris 2.[789] when using GCC. ])
 558     fi ;;
 559 esac
 560 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h)
 561 AC_CHECK_HEADERS(ncurses/term.h)
 562 AC_CHECK_HEADERS(term.h, [], [],
 563 [#if HAVE_CURSES_H
 564 # include <curses.h>
 565 #endif
 566 ])
 567
 568 # Check for HP/UX 64-bit shared library support
 569 AC_CHECK_HEADERS(elf_hp.h)
 570
 571 # FIXME: kettenis/20030102: In most cases we include these
 572 # unconditionally, so what's the point in checking these?
 573 AC_CHECK_HEADERS(ctype.h time.h)
 574
 575 # ------------------------- #
 576 # Checks for declarations.  #
 577 # ------------------------- #
 578
 579 AC_CHECK_DECLS([free, malloc, realloc])
 580 AC_CHECK_DECLS([strerror, strstr])
 581 AC_CHECK_DECLS([getopt, snprintf, vsnprintf])
 582
 583 # ----------------------- #
 584 # Checks for structures.  #
 585 # ----------------------- #
 586
 587 AC_CHECK_MEMBERS([struct stat.st_blocks])
 588 AC_CHECK_MEMBERS([struct stat.st_blksize])
 589
 590 # ------------------ #
 591 # Checks for types.  #
 592 # ------------------ #
 593
 594 AC_TYPE_SIGNAL
 595 AC_CHECK_TYPES(socklen_t, [], [],
 596 [#include <sys/types.h>
 597 #include <sys/socket.h>
 598 ])
 599
 600 # ------------------------------------- #
 601 # Checks for compiler characteristics.  #
 602 # ------------------------------------- #
 603
 604 AC_C_CONST
 605 AC_C_INLINE
 606 AC_C_BIGENDIAN
 607
 608 # ------------------------------ #
 609 # Checks for library functions.  #
 610 # ------------------------------ #
 611
 612 AC_FUNC_ALLOCA
 613 AC_FUNC_MMAP
 614 AC_FUNC_VFORK
 615 AC_CHECK_FUNCS(canonicalize_file_name realpath)
 616 AC_CHECK_FUNCS(getrusage)
 617 AC_CHECK_FUNCS(getuid getgid)
 618 AC_CHECK_FUNCS(poll)
 619 AC_CHECK_FUNCS(pread64)
 620 AC_CHECK_FUNCS(sbrk)
 621 AC_CHECK_FUNCS(setpgid setpgrp setsid)
 622 AC_CHECK_FUNCS(sigaction sigprocmask sigsetmask)
 623 AC_CHECK_FUNCS(socketpair)
 624 AC_CHECK_FUNCS(syscall)
 625 AC_CHECK_FUNCS(ttrace)
 626 AC_CHECK_FUNCS(wborder)
 627
 628 # Check the return and argument types of ptrace.  No canned test for
 629 # this, so roll our own.
 630 gdb_ptrace_headers='
 631 #if HAVE_SYS_TYPES_H
 632 # include <sys/types.h>
 633 #endif
 634 #if HAVE_SYS_PTRACE_H
 635 # include <sys/ptrace.h>
 636 #endif
 637 #if HAVE_UNISTD_H
 638 # include <unistd.h>
 639 #endif
 640 '
 641 # There is no point in checking if we don't have a prototype.
 642 AC_CHECK_DECLS(ptrace, [], [
 643   : ${gdb_cv_func_ptrace_ret='int'}
 644   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 645 ], $gdb_ptrace_headers)
 646 # Check return type.
 647 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
 648   AC_TRY_COMPILE($gdb_ptrace_headers,
 649     [extern int ptrace ();],
 650     gdb_cv_func_ptrace_ret='int',
 651     gdb_cv_func_ptrace_ret='long'))
 652 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
 653   [Define as the return type of ptrace.])
 654 # Check argument types.
 655 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
 656 for gdb_arg1 in 'int' 'long'; do
 657  for gdb_arg2 in 'pid_t' 'int' 'long'; do
 658   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
 659    for gdb_arg4 in 'int' 'long'; do
 660      AC_TRY_COMPILE($gdb_ptrace_headers, [
 661 extern $gdb_cv_func_ptrace_ret
 662   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
 663 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
 664     break 4;])
 665     for gdb_arg5 in 'int *' 'int' 'long'; do
 666      AC_TRY_COMPILE($gdb_ptrace_headers, [
 667 extern $gdb_cv_func_ptrace_ret
 668   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
 669 ], [
 670 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
 671     break 5;])
 672     done
 673    done
 674   done
 675  done
 676 done
 677 # Provide a safe default value.
 678 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 679 ])
 680 ac_save_IFS=$IFS; IFS=','
 681 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
 682 IFS=$ac_save_IFS
 683 shift
 684 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
 685   [Define to the type of arg 3 for ptrace.])
 686 if test -n "$[5]"; then
 687   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
 688     [Define to the type of arg 5 for ptrace.])
 689 fi
 690
 691 dnl AC_FUNC_SETPGRP does not work when cross compiling
 692 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
 693 if test "$cross_compiling" = no; then
 694   AC_FUNC_SETPGRP
 695 else
 696   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
 697     [AC_TRY_COMPILE([
 698 #include <unistd.h>
 699 ], [
 700   if (setpgrp(1,1) == -1)
 701     exit (0);
 702   else
 703     exit (1);
 704 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
 705 if test $ac_cv_func_setpgrp_void = yes; then
 706   AC_DEFINE(SETPGRP_VOID, 1)
 707 fi
 708 fi
 709
 710 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
 711 # since sigsetjmp might only be defined as a macro.
 712 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
 713 [AC_TRY_COMPILE([
 714 #include <setjmp.h>
 715 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
 716 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
 717 if test $gdb_cv_func_sigsetjmp = yes; then
 718   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
 719 fi
 720
 721 # Assume we'll default to using the included libiberty regex.
 722 gdb_use_included_regex=yes
 723
 724 # However, if the system regex is GNU regex, then default to *not*
 725 # using the included regex.
 726 AC_CACHE_CHECK(
 727   [for GNU regex],
 728   [gdb_cv_have_gnu_regex],
 729   [AC_TRY_COMPILE(
 730     [#include <gnu-versions.h>],
 731     [#define REGEX_INTERFACE_VERSION 1
 732 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
 733 # error "Version mismatch"
 734 #endif],
 735     gdb_cv_have_gnu_regex=yes,
 736     gdb_cv_have_gnu_regex=no)])
 737 if test $gdb_cv_have_gnu_regex = yes; then
 738   gdb_use_included_regex=no
 739 fi
 740
 741 AC_ARG_WITH(included-regex,
 742   [  --without-included-regex don't use included regex; this is the default
 743                           on systems with version 2 of the GNU C library
 744                           (use with caution on other system)],
 745   gdb_with_regex=$withval,
 746   gdb_with_regex=$gdb_use_included_regex)
 747 if test "$gdb_with_regex" = yes; then
 748   AC_DEFINE(USE_INCLUDED_REGEX, 1,
 749     [Define to 1 if the regex included in libiberty should be used.])
 750 fi
 751
 752 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
 753 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
 754 [#include <sys/param.h>
 755 #include <sys/proc.h>
 756 ])
 757
 758 # See if <sys/lwp.h> defines `struct lwp`.
 759 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
 760 [AC_TRY_COMPILE([#include <sys/param.h>
 761 #include <sys/lwp.h>], [struct lwp l;],
 762 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
 763 if test $gdb_cv_struct_lwp = yes; then
 764   AC_DEFINE(HAVE_STRUCT_LWP, 1,
 765             [Define to 1 if your system has struct lwp.])
 766 fi
 767
 768 # See if <machine/reg.h> degines `struct reg'.
 769 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
 770 [AC_TRY_COMPILE([#include <sys/types.h>
 771 #include <machine/reg.h>], [struct reg r;],
 772 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
 773 if test $gdb_cv_struct_reg = yes; then
 774   AC_DEFINE(HAVE_STRUCT_REG, 1,
 775             [Define to 1 if your system has struct reg in <machine/reg.h>.])
 776 fi
 777
 778 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
 779 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
 780 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
 781                  [#include <machine/reg.h>])
 782
 783 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
 784 AC_MSG_CHECKING(for PTRACE_GETREGS)
 785 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
 786 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 787                 [PTRACE_GETREGS;],
 788                 [gdb_cv_have_ptrace_getregs=yes],
 789                 [gdb_cv_have_ptrace_getregs=no])])
 790 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
 791 if test $gdb_cv_have_ptrace_getregs = yes; then
 792   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
 793   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
 794 fi
 795
 796 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
 797 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 798 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
 799 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 800                 [PTRACE_GETFPXREGS;],
 801                 [gdb_cv_have_ptrace_getfpxregs=yes],
 802                 [gdb_cv_have_ptrace_getfpxregs=no])])
 803 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
 804 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
 805   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
 806   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
 807 fi
 808
 809 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
 810 AC_MSG_CHECKING(for PT_GETDBREGS)
 811 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
 812 [AC_TRY_COMPILE([#include <sys/types.h>
 813 #include <sys/ptrace.h>],
 814                 [PT_GETDBREGS;],
 815                 [gdb_cv_have_pt_getdbregs=yes],
 816                 [gdb_cv_have_pt_getdbregs=no])])
 817 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
 818 if test $gdb_cv_have_pt_getdbregs = yes; then
 819   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
 820   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
 821 fi
 822
 823 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
 824 AC_MSG_CHECKING(for PT_GETXMMREGS)
 825 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
 826 [AC_TRY_COMPILE([#include <sys/types.h>
 827 #include <sys/ptrace.h>],
 828                 [PT_GETXMMREGS;],
 829                 [gdb_cv_have_pt_getxmmregs=yes],
 830                 [gdb_cv_have_pt_getxmmregs=no])])
 831 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
 832 if test $gdb_cv_have_pt_getxmmregs = yes; then
 833   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
 834   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
 835 fi
 836
 837 # Detect which type of /proc is in use, such as for Unixware or Solaris.
 838
 839 if test "${target}" = "${host}"; then
 840   case "${host}" in
 841   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
 842       AC_DEFINE(NEW_PROC_API, 1,
 843       [Define if you want to use new multi-fd /proc interface
 844        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
 845       ;;
 846   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
 847       AC_DEFINE(NEW_PROC_API, 1,
 848       [Define if you want to use new multi-fd /proc interface
 849        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
 850       ;;
 851   mips-sgi-irix5*)
 852       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
 853       AC_DEFINE([_KMEMUSER], 1,
 854       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
 855        around a <sys/proc.h> problem on IRIX 5.])
 856       ;;
 857   esac
 858 fi
 859
 860 if test "$ac_cv_header_sys_procfs_h" = yes; then
 861   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 862   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
 863   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
 864   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
 865   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
 866   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
 867   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
 868   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
 869   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
 870   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
 871   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
 872   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
 873   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
 874   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
 875
 876
 877   dnl Check for broken prfpregset_t type
 878
 879   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
 880   dnl prfpregset_t type (it's a typedef for the pointer to a struct
 881   dnl instead of the struct itself).  We detect this here, and work
 882   dnl around it in gdb_proc_service.h.
 883
 884   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
 885     AC_MSG_CHECKING(whether prfpregset_t type is broken)
 886     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
 887       [AC_TRY_RUN([#include <sys/procfs.h>
 888        int main ()
 889        {
 890          if (sizeof (prfpregset_t) == sizeof (void *))
 891            return 1;
 892          return 0;
 893        }],
 894        gdb_cv_prfpregset_t_broken=no,
 895        gdb_cv_prfpregset_t_broken=yes,
 896        gdb_cv_prfpregset_t_broken=yes)])
 897     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
 898     if test $gdb_cv_prfpregset_t_broken = yes; then
 899       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
 900       [Define if the prfpregset_t type is broken.])
 901     fi
 902   fi
 903
 904   dnl Check for PIOCSET ioctl entry
 905
 906   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
 907   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
 908   [AC_TRY_COMPILE([#include <unistd.h>
 909 #include <sys/types.h>
 910 #include <sys/procfs.h>
 911 ], [
 912     int dummy;;
 913     dummy = ioctl(0, PIOCSET, &dummy);
 914   ],
 915   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
 916   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
 917   if test $gdb_cv_have_procfs_piocset = yes; then
 918     AC_DEFINE(HAVE_PROCFS_PIOCSET, 1,
 919     [Define if ioctl argument PIOCSET is available.])
 920   fi
 921 fi
 922
 923 dnl For native ports (host == target), check to see what kind of
 924 dnl legacy link.h support is needed.  (See solib-legacy.c.)
 925 if test ${host} = ${target} ; then
 926   dnl Check for struct link_map with l_ members which are indicative
 927   dnl of SVR4-like shared libraries
 928
 929   AC_MSG_CHECKING(for member l_addr in struct link_map)
 930   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
 931     [AC_TRY_COMPILE([#include <link.h>],
 932                     [struct link_map lm; (void) lm.l_addr;],
 933                     gdb_cv_have_struct_link_map_with_l_members=yes,
 934                     gdb_cv_have_struct_link_map_with_l_members=no)])
 935   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
 936   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
 937     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS,1,
 938     [Define if <link.h> exists and defines struct link_map which has
 939      members with an ``l_'' prefix.  (For Solaris, SVR4, and
 940      SVR4-like systems.)])
 941   fi
 942
 943   dnl Check for struct link_map with lm_ members which are indicative
 944   dnl of SunOS-like shared libraries
 945
 946   AC_MSG_CHECKING(for member lm_addr in struct link_map)
 947   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
 948     [AC_TRY_COMPILE([#include <sys/types.h>
 949 #include <link.h>],
 950                     [struct link_map lm; (void) lm.lm_addr;],
 951                     gdb_cv_have_struct_link_map_with_lm_members=yes,
 952                     gdb_cv_have_struct_link_map_with_lm_members=no)])
 953   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
 954   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
 955     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS, 1,
 956     [Define if <link.h> exists and defines struct link_map which has
 957      members with an ``lm_'' prefix.  (For SunOS.)])
 958   fi
 959
 960   dnl Check for struct so_map with som_ members which are found on
 961   dnl some *BSD systems.
 962
 963   AC_MSG_CHECKING(for member som_addr in struct so_map)
 964   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
 965     [AC_TRY_COMPILE([#include <sys/types.h>
 966 #ifdef HAVE_NLIST_H
 967 #include <nlist.h>
 968 #endif
 969 #include <link.h>],
 970                     [struct so_map lm; (void) lm.som_addr;],
 971                     gdb_cv_have_struct_so_map_with_som_members=yes,
 972                     gdb_cv_have_struct_so_map_with_som_members=no)])
 973   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
 974   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
 975     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS, 1,
 976     [Define if <link.h> exists and defines a struct so_map which has
 977      members with an ``som_'' prefix.  (Found on older *BSD systems.)])
 978   fi
 979
 980   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
 981   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
 982
 983   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
 984   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
 985     [AC_TRY_COMPILE([#define _SYSCALL32
 986 #include <sys/link.h>], [struct link_map32 l;],
 987      gdb_cv_have_struct_link_map32=yes,
 988      gdb_cv_have_struct_link_map32=no)])
 989   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
 990   if test $gdb_cv_have_struct_link_map32 = yes; then
 991     AC_DEFINE(HAVE_STRUCT_LINK_MAP32, 1,
 992     [Define if <sys/link.h> has struct link_map32])
 993     AC_DEFINE(_SYSCALL32, 1,
 994     [Define if <sys/link.h> has link_map32 (solaris sparc-64 target)])
 995   fi
 996 fi
 997
 998 # Check if the compiler supports the `long long' type.
 999
1000 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1001                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1002 [[extern long long foo;]],
1003 [[switch (foo & 2) { case 0: return 1; }]])],
1004                                   gdb_cv_c_long_long=yes,
1005                                   gdb_cv_c_long_long=no)])
1006 if test $gdb_cv_c_long_long = yes; then
1007   AC_DEFINE(CC_HAS_LONG_LONG, 1,
1008             [Define to 1 if the compiler supports long long.])
1009 fi
1010
1011 # Check if the compiler and runtime support printing long longs.
1012
1013 AC_CACHE_CHECK([for long long support in printf],
1014                gdb_cv_printf_has_long_long,
1015                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1016 [[char buf[32];
1017   long long l = 0;
1018   l = (l << 16) + 0x0123;
1019   l = (l << 16) + 0x4567;
1020   l = (l << 16) + 0x89ab;
1021   l = (l << 16) + 0xcdef;
1022   sprintf (buf, "0x%016llx", l);
1023   return (strcmp ("0x0123456789abcdef", buf));]])],
1024                               gdb_cv_printf_has_long_long=yes,
1025                               gdb_cv_printf_has_long_long=no,
1026                               gdb_cv_printf_has_long_long=no)])
1027 if test $gdb_cv_printf_has_long_long = yes; then
1028   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1029             [Define to 1 if the "%ll" format works to print long longs.])
1030 fi
1031
1032 # Check if the compiler and runtime support printing decfloats.
1033
1034 AC_CACHE_CHECK([for decfloat support in printf],
1035                gdb_cv_printf_has_decfloat,
1036                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1037 [[char buf[64];
1038   _Decimal32 d32 = 1.2345df;
1039   _Decimal64 d64 = 1.2345dd;
1040   _Decimal128 d128 = 1.2345dl;
1041   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1042   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1043                               gdb_cv_printf_has_decfloat=yes,
1044                               gdb_cv_printf_has_decfloat=no,
1045                               gdb_cv_printf_has_decfloat=no)])
1046 if test $gdb_cv_printf_has_decfloat = yes; then
1047   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1048             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1049 fi
1050
1051 # Check if the compiler supports the `long double' type.  We can't use
1052 # AC_C_LONG_DOUBLE because that one does additional checks on the
1053 # constants defined in <float.h> that fail on some systems,
1054 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1055
1056 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1057                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1058                                   gdb_cv_c_long_double=yes,
1059                                   gdb_cv_c_long_double=no)])
1060 if test $gdb_cv_c_long_double = yes; then
1061   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1062            [Define to 1 if the compiler supports long double.])
1063 fi
1064
1065 # Check if the compiler and runtime support printing long doubles.
1066
1067 AC_CACHE_CHECK([for long double support in printf],
1068                gdb_cv_printf_has_long_double,
1069                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1070 [[char buf[16];
1071   long double f = 3.141592653;
1072   sprintf (buf, "%Lg", f);
1073   return (strncmp ("3.14159", buf, 7));]])],
1074                               gdb_cv_printf_has_long_double=yes,
1075                               gdb_cv_printf_has_long_double=no,
1076                               gdb_cv_printf_has_long_double=no)])
1077 if test $gdb_cv_printf_has_long_double = yes; then
1078   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1079             [Define to 1 if the "%Lg" format works to print long doubles.])
1080 fi
1081
1082 # Check if the compiler and runtime support scanning long doubles.
1083
1084 AC_CACHE_CHECK([for long double support in scanf],
1085                gdb_cv_scanf_has_long_double,
1086                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1087 [[#include <stdio.h>]],
1088 [[char *buf = "3.141592653";
1089   long double f = 0;
1090   sscanf (buf, "%Lg", &f);
1091   return !(f > 3.14159 && f < 3.14160);]])],
1092                               gdb_cv_scanf_has_long_double=yes,
1093                               gdb_cv_scanf_has_long_double=no,
1094                               gdb_cv_scanf_has_long_double=no)])
1095 if test $gdb_cv_scanf_has_long_double = yes; then
1096   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1097             [Define to 1 if the "%Lg" format works to scan long doubles.])
1098 fi
1099
1100 case ${host_os} in
1101 aix*)
1102   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1103     SAVE_LDFLAGS=$LDFLAGS
1104
1105     case $GCC in
1106     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1107     *) gdb_cv_bigtoc=-bbigtoc ;;
1108     esac
1109
1110     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1111     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1112     LDFLAGS="${SAVE_LDFLAGS}"
1113   ])
1114   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1115   ;;
1116 esac
1117
1118
1119 dnl For certain native configurations, we need to check whether thread
1120 dnl support can be built in or not.
1121 dnl
1122 dnl Note that we only want this if we are both native (host == target),
1123 dnl and not doing a canadian cross build (build == host).
1124
1125 if test ${build} = ${host} -a ${host} = ${target} ; then
1126    case ${host_os} in
1127    hpux*)
1128       AC_MSG_CHECKING(for HPUX/OSF thread support)
1129       if test -f /usr/include/dce/cma_config.h ; then
1130          if test "$GCC" = "yes" ; then
1131             AC_MSG_RESULT(yes)
1132             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT, 1,
1133             [Define if you have HPUX threads])
1134             CONFIG_OBS="${CONFIG_OBS} hpux-thread.o"
1135             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
1136          else
1137             AC_MSG_RESULT(no (suppressed because you are not using GCC))
1138          fi
1139       else
1140          AC_MSG_RESULT(no)
1141       fi
1142       ;;
1143    solaris*)
1144       # See if thread_db library is around for Solaris thread debugging.
1145       # Note that we must explicitly test for version 1 of the library
1146       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1147       # the same API.
1148       AC_MSG_CHECKING(for Solaris thread debugging library)
1149       if test -f /usr/lib/libthread_db.so.1 ; then
1150          AC_MSG_RESULT(yes)
1151          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1152          [Define if using Solaris thread debugging.])
1153          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1154          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1155          AC_CHECK_LIB(dl, dlopen)
1156          if test "$GCC" = "yes" ; then
1157             # The GNU linker requires the -export-dynamic option to make
1158             # all symbols visible in the dynamic symbol table.
1159             hold_ldflags=$LDFLAGS
1160             AC_MSG_CHECKING(for the ld -export-dynamic flag)
1161             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
1162             AC_TRY_LINK(, [int i;], found=yes, found=no)
1163             LDFLAGS=$hold_ldflags
1164             AC_MSG_RESULT($found)
1165             if test $found = yes; then
1166                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
1167             fi
1168          fi
1169          # Sun randomly tweaked the prototypes in <proc_service.h>
1170          # at one point.
1171          AC_MSG_CHECKING(if <proc_service.h> is old)
1172          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1173             AC_TRY_COMPILE([
1174                 #include <proc_service.h>
1175                 ps_err_e ps_pdwrite
1176                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1177             ],, gdb_cv_proc_service_is_old=no,
1178                 gdb_cv_proc_service_is_old=yes)
1179          ])
1180          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1181          if test $gdb_cv_proc_service_is_old = yes; then
1182             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1183             [Define if <proc_service.h> on solaris uses int instead of
1184              size_t, and assorted other type changes.])
1185          fi
1186       else
1187          AC_MSG_RESULT(no)
1188       fi
1189       ;;
1190    aix*)
1191       AC_MSG_CHECKING(for AiX thread debugging library)
1192       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1193                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1194                                    [#ifndef PTHDB_VERSION_3
1195                                     #error
1196                                     #endif],
1197                                    gdb_cv_have_aix_thread_debug=yes,
1198                                    gdb_cv_have_aix_thread_debug=no)])
1199       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1200       if test $gdb_cv_have_aix_thread_debug = yes; then
1201          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1202          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1203          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
1204       fi
1205       ;;
1206    esac
1207    AC_SUBST(CONFIG_LDFLAGS)
1208 fi
1209
1210 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1211 dnl other error codes.
1212 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1213    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1214                   gdb_cv_thread_db_h_has_td_notalloc,
1215      AC_TRY_COMPILE(
1216        [#include <thread_db.h>],
1217        [int i = TD_NOTALLOC;],
1218        gdb_cv_thread_db_h_has_td_notalloc=yes,
1219        gdb_cv_thread_db_h_has_td_notalloc=no
1220      )
1221    )
1222    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1223                   gdb_cv_thread_db_h_has_td_version,
1224      AC_TRY_COMPILE(
1225        [#include <thread_db.h>],
1226        [int i = TD_VERSION;],
1227        gdb_cv_thread_db_h_has_td_version=yes,
1228        gdb_cv_thread_db_h_has_td_version=no
1229      )
1230    )
1231    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1232                   gdb_cv_thread_db_h_has_td_notls,
1233      AC_TRY_COMPILE(
1234        [#include <thread_db.h>],
1235        [int i = TD_NOTLS;],
1236        gdb_cv_thread_db_h_has_td_notls=yes,
1237        gdb_cv_thread_db_h_has_td_notls=no
1238      )
1239    )
1240 fi
1241 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1242   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1243             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1244 fi
1245 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1246   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1247             [Define if <thread_db.h> has the TD_VERSION error code.])
1248 fi
1249 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1250   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1251             [Define if <thread_db.h> has the TD_NOTLS error code.])
1252 fi
1253
1254 dnl See if we have a sys/syscall header file that has __NR_tkill.
1255 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1256    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1257                   gdb_cv_sys_syscall_h_has_tkill,
1258      AC_TRY_COMPILE(
1259        [#include <sys/syscall.h>],
1260        [int i = __NR_tkill;],
1261        gdb_cv_sys_syscall_h_has_tkill=yes,
1262        gdb_cv_sys_syscall_h_has_tkill=no
1263      )
1264    )
1265 fi
1266 dnl See if we can issue tkill syscall.
1267 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1268   AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1269 fi
1270
1271 dnl Check if we can disable the virtual address space randomization.
1272 dnl The functionality of setarch -R.
1273 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1274 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1275 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1276 #       define ADDR_NO_RANDOMIZE 0x0040000
1277 #      endif
1278        /* Test the flag could be set and stays set.  */
1279        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1280        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1281            return 1])])
1282 AC_RUN_IFELSE([PERSONALITY_TEST],
1283               [have_personality=true],
1284               [have_personality=false],
1285               [AC_LINK_IFELSE([PERSONALITY_TEST],
1286                               [have_personality=true],
1287                               [have_personality=false])])
1288 if $have_personality
1289 then
1290     AC_DEFINE([HAVE_PERSONALITY], 1,
1291               [Define if you support the personality syscall.])
1292 fi
1293
1294 dnl Handle optional features that can be enabled.
1295
1296 AC_ARG_WITH(sysroot,
1297 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
1298 [
1299  case ${with_sysroot} in
1300  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
1301  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
1302  esac
1303
1304  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
1305
1306  if test "x$prefix" = xNONE; then
1307   test_prefix=/usr/local
1308  else
1309   test_prefix=$prefix
1310  fi
1311  if test "x$exec_prefix" = xNONE || test "x$exec_prefix" = 'x${prefix}'; then
1312   test_exec_prefix=$test_prefix
1313  else
1314   test_exec_prefix=$exec_prefix
1315  fi
1316  case ${TARGET_SYSTEM_ROOT} in
1317  "${test_prefix}"|"${test_prefix}/"*|\
1318  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
1319  '${prefix}'|'${prefix}/'*|\
1320  '${exec_prefix}'|'${exec_prefix}/'*)
1321    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
1322    TARGET_SYSTEM_ROOT_DEFINE="$t"
1323    ;;
1324  esac
1325 ], [
1326  TARGET_SYSTEM_ROOT=
1327  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
1328 ])
1329 AC_SUBST(TARGET_SYSTEM_ROOT)
1330 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
1331
1332 AC_ARG_ENABLE(werror,
1333   [  --enable-werror    treat compile warnings as errors],
1334   [case "${enableval}" in
1335      yes | y) ERROR_ON_WARNING="yes" ;;
1336      no | n)  ERROR_ON_WARNING="no" ;;
1337      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1338    esac])
1339
1340 # Enable -Werror by default when using gcc
1341 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" ; then
1342     ERROR_ON_WARNING=yes
1343 fi
1344
1345 WERROR_CFLAGS=""
1346 if test "${ERROR_ON_WARNING}" = yes ; then
1347     WERROR_CFLAGS="-Werror"
1348 fi
1349
1350 # The entries after -Wno-pointer-sign are disabled warnings which may
1351 # be enabled in the future, which can not currently be used to build
1352 # GDB.
1353 # NOTE: If you change this list, remember to update
1354 # gdb/doc/gdbint.texinfo.
1355 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1356 -Wformat-nonliteral -Wno-pointer-sign \
1357 -Wno-unused -Wno-switch -Wno-char-subscripts"
1358
1359 # Enable -Wno-format by default when using gcc on mingw since many
1360 # GCC versions complain about %I64.
1361 case "${host}" in
1362   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
1363 esac
1364
1365 AC_ARG_ENABLE(build-warnings,
1366 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
1367 [case "${enableval}" in
1368   yes)  ;;
1369   no)   build_warnings="-w";;
1370   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1371         build_warnings="${build_warnings} ${t}";;
1372   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1373         build_warnings="${t} ${build_warnings}";;
1374   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1375 esac
1376 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1377   echo "Setting compiler warning flags = $build_warnings" 6>&1
1378 fi])dnl
1379 AC_ARG_ENABLE(gdb-build-warnings,
1380 [  --enable-gdb-build-warnings Enable GDB specific build-time compiler warnings if gcc is used],
1381 [case "${enableval}" in
1382   yes)  ;;
1383   no)   build_warnings="-w";;
1384   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1385         build_warnings="${build_warnings} ${t}";;
1386   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1387         build_warnings="${t} ${build_warnings}";;
1388   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1389 esac
1390 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1391   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1392 fi])dnl
1393 WARN_CFLAGS=""
1394 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1395 then
1396     AC_MSG_CHECKING(compiler warning flags)
1397     # Separate out the -Werror flag as some files just cannot be
1398     # compiled with it enabled.
1399     for w in ${build_warnings}; do
1400         case $w in
1401         -Werr*) WERROR_CFLAGS=-Werror ;;
1402         *) # Check that GCC accepts it
1403             saved_CFLAGS="$CFLAGS"
1404             CFLAGS="$CFLAGS $w"
1405             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1406             CFLAGS="$saved_CFLAGS"
1407         esac
1408     done
1409     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
1410 fi
1411 AC_SUBST(WARN_CFLAGS)
1412 AC_SUBST(WERROR_CFLAGS)
1413
1414 # In the Cygwin environment, we need some additional flags.
1415 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1416 [AC_EGREP_CPP(lose, [
1417 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1418 lose
1419 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1420
1421
1422 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1423 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1424 case ${host} in
1425   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1426   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1427   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1428 esac
1429 AC_SUBST(SER_HARDWIRE)
1430
1431 # libreadline needs libuser32.a in a cygwin environment
1432 WIN32LIBS=
1433 if test x$gdb_cv_os_cygwin = xyes; then
1434     WIN32LIBS="-luser32"
1435     case "${target}" in
1436         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1437         ;;
1438     esac
1439 fi
1440
1441 # The ser-tcp.c module requires sockets.
1442 case ${host} in
1443   *mingw32*)
1444     AC_DEFINE(USE_WIN32API, 1,
1445               [Define if we should use the Windows API, instead of the
1446                POSIX API.  On Windows, we use the Windows API when
1447                building for MinGW, but the POSIX API when building
1448                for Cygwin.])
1449     WIN32LIBS="$WIN32LIBS -lws2_32"
1450     ;;
1451 esac
1452 AC_SUBST(WIN32LIBS)
1453
1454 # Add ELF support to GDB, but only if BFD includes ELF support.
1455 OLD_CFLAGS=$CFLAGS
1456 OLD_LDFLAGS=$LDFLAGS
1457 OLD_LIBS=$LIBS
1458 CFLAGS="$CFLAGS -I${srcdir}/../include -I../bfd -I${srcdir}/../bfd"
1459 LDFLAGS="$LDFLAGS -L../bfd -L../libiberty"
1460 intl=`echo $LIBINTL | sed 's,${top_builddir}/,,g'`
1461 LIBS="-lbfd -liberty $intl $LIBS"
1462 AC_CACHE_CHECK([for ELF support in BFD], gdb_cv_var_elf,
1463 [AC_TRY_LINK(
1464 [#include <stdlib.h>
1465 #include "bfd.h"
1466 #include "elf-bfd.h"
1467 ],
1468 [bfd *abfd = NULL; bfd_get_elf_phdr_upper_bound (abfd); ],
1469 gdb_cv_var_elf=yes, gdb_cv_var_elf=no)])
1470 if test $gdb_cv_var_elf = yes; then
1471   CONFIG_OBS="$CONFIG_OBS elfread.o"
1472   AC_DEFINE(HAVE_ELF, 1,
1473             [Define if ELF support should be included.])
1474 fi
1475 CFLAGS=$OLD_CFLAGS
1476 LDFLAGS=$OLD_LDFLAGS
1477 LIBS=$OLD_LIBS
1478
1479 # Add any host-specific objects to GDB.
1480 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1481
1482 LIBGUI="../libgui/src/libgui.a"
1483 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1484 AC_SUBST(LIBGUI)
1485 AC_SUBST(GUI_CFLAGS_X)
1486
1487 WIN32LDAPP=
1488 AC_SUBST(WIN32LIBS)
1489 AC_SUBST(WIN32LDAPP)
1490
1491 case "${host}" in
1492 *-*-cygwin* | *-*-mingw* )
1493     configdir="win"
1494     ;;
1495 *)
1496     configdir="unix"
1497     ;;
1498 esac
1499
1500 GDBTKLIBS=
1501 if test "${enable_gdbtk}" = "yes"; then
1502
1503     # Gdbtk must have an absolute path to srcdir in order to run
1504     # properly when not installed.
1505     here=`pwd`
1506     cd ${srcdir}
1507     GDBTK_SRC_DIR=`pwd`
1508     cd $here
1509
1510     CY_AC_PATH_TCLCONFIG
1511     if test -z "${no_tcl}"; then
1512         CY_AC_LOAD_TCLCONFIG
1513         CY_AC_PATH_TKCONFIG
1514
1515         # now look for Tcl library stuff
1516
1517         tcldir="../tcl/${configdir}/"
1518
1519         TCL_DEPS="${tcldir}${TCL_LIB_FILE}"
1520
1521         # If $no_tk is nonempty, then we can't do Tk, and there is no
1522         # point to doing Tcl.
1523         if test -z "${no_tk}"; then
1524            CY_AC_LOAD_TKCONFIG
1525            CY_AC_PATH_TCLH
1526            CY_AC_PATH_TKH
1527            CY_AC_PATH_ITCLH
1528            CY_AC_PATH_ITKH
1529
1530
1531            # now look for Tk library stuff
1532
1533            tkdir="../tk/${configdir}/"
1534
1535            TK_DEPS="${tkdir}${TK_LIB_FILE}"
1536
1537            # now look for Itcl library stuff
1538
1539            CY_AC_PATH_ITCLCONFIG
1540            if test -z "${no_itcl}"; then
1541              CY_AC_LOAD_ITCLCONFIG
1542
1543              ITCLLIB="${ITCL_BUILD_LIB_SPEC}"
1544              ITCL_DEPS="${ITCL_LIB_FULL_PATH}"
1545            fi
1546
1547
1548            # now look for Itk library stuff
1549            CY_AC_PATH_ITKCONFIG
1550            if test -z "${no_itcl}"; then
1551              CY_AC_LOAD_ITKCONFIG
1552
1553              ITKLIB="${ITK_BUILD_LIB_SPEC}"
1554              ITK_DEPS="${ITK_LIB_FULL_PATH}"
1555            fi
1556
1557            ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1558
1559            # Include some libraries that Tcl and Tk want.
1560            TCL_LIBS='$(LIBGUI) $(ITCL) $(ITK) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1561            # Yes, the ordering seems wrong here.  But it isn't.
1562            # TK_LIBS is the list of libraries that need to be linked
1563            # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
1564            # were in LIBS then any link tests after this point would
1565            # try to include things like `$(LIBGUI)', which wouldn't work.
1566            GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1567
1568            CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1569            CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1570            CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1571            CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
1572            CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
1573            CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
1574            CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
1575
1576            if test x$gdb_cv_os_cygwin = xyes; then
1577               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
1578               WIN32LDAPP="-Wl,--subsystem,console"
1579               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
1580            fi
1581         fi
1582     fi
1583
1584     AC_CONFIG_SUBDIRS(gdbtk)
1585 fi
1586
1587 AC_SUBST(X_CFLAGS)
1588 AC_SUBST(X_LDFLAGS)
1589 AC_SUBST(X_LIBS)
1590 AC_SUBST(TCL_DEPS)
1591 AC_SUBST(TK_DEPS)
1592 AC_SUBST(ITCLLIB)
1593 AC_SUBST(ITCL_DEPS)
1594 AC_SUBST(ITKLIB)
1595 AC_SUBST(ITK_DEPS)
1596 AC_SUBST(GDBTKLIBS)
1597 AC_SUBST(GDBTK_CFLAGS)
1598 AC_SUBST(GDBTK_SRC_DIR)
1599
1600 AC_PATH_X
1601
1602 # Check whether we should enable the TUI, but only do so if we really
1603 # can.
1604 if test x"$enable_tui" != xno; then
1605   if test -d $srcdir/tui; then
1606     if test "$ac_cv_search_waddstr" != no; then
1607       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
1608       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
1609       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
1610       CONFIG_INITS="$CONFIG_INITS \$(SUBDIR_TUI_INITS)"
1611       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
1612       CONFIG_ALL="${CONFIG_ALL} all-tui"
1613       CONFIG_CLEAN="${CONFIG_CLEAN} clean-tui"
1614       CONFIG_INSTALL="${CONFIG_INSTALL} install-tui"
1615       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-tui"
1616     else
1617       if test x"$enable_tui" = xyes; then
1618         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
1619       else
1620         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
1621       fi
1622     fi
1623   fi
1624 fi
1625
1626 # Unlike the sim directory, whether a simulator is linked is controlled by
1627 # presence of a gdb_sim definition in the target configure.tgt entry.
1628 # This code just checks for a few cases where we'd like to ignore those
1629 # definitions, even when they're present in the '.mt' file.  These cases
1630 # are when --disable-sim is specified, or if the simulator directory is
1631 # not part of the source tree.
1632 #
1633 AC_ARG_ENABLE(sim,
1634 [  --enable-sim            Link gdb with simulator],
1635 [echo "enable_sim = $enable_sim";
1636  echo "enableval = ${enableval}";
1637  case "${enableval}" in
1638   yes) ignore_sim=false ;;
1639   no)  ignore_sim=true ;;
1640   *)   ignore_sim=false ;;
1641  esac],
1642 [ignore_sim=false])
1643
1644 if test ! -d "${srcdir}/../sim"; then
1645   ignore_sim=true
1646 fi
1647
1648 SIM=
1649 SIM_OBS=
1650 if test "${ignore_sim}" = "false"; then
1651   if test x"${gdb_sim}" != x ; then
1652     SIM="${gdb_sim}"
1653     SIM_OBS="remote-sim.o"
1654     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
1655   fi
1656 fi
1657 AC_SUBST(SIM)
1658 AC_SUBST(SIM_OBS)
1659
1660 AC_SUBST(ENABLE_CFLAGS)
1661 AC_SUBST(PROFILE_CFLAGS)
1662
1663 AC_SUBST(CONFIG_OBS)
1664 AC_SUBST(CONFIG_DEPS)
1665 AC_SUBST(CONFIG_SRCS)
1666 AC_SUBST(CONFIG_ALL)
1667 AC_SUBST(CONFIG_CLEAN)
1668 AC_SUBST(CONFIG_INSTALL)
1669 AC_SUBST(CONFIG_UNINSTALL)
1670
1671 # List of host floatformats.
1672 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
1673 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
1674 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
1675
1676 # target_subdir is used by the testsuite to find the target libraries.
1677 target_subdir=
1678 if test "${host}" != "${target}"; then
1679     target_subdir="${target_alias}/"
1680 fi
1681 AC_SUBST(target_subdir)
1682
1683 frags=
1684 if test "${gdb_native}" = "yes"; then
1685   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
1686   if test ! -f ${host_makefile_frag}; then
1687     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
1688   fi
1689   frags="$frags $host_makefile_frag"
1690 else
1691   host_makefile_frag=/dev/null
1692 fi
1693
1694 AC_SUBST_FILE(host_makefile_frag)
1695 AC_SUBST(frags)
1696
1697 changequote(,)dnl
1698 if test "${gdb_native}" = "yes"; then
1699 # We pick this up from the host configuration file (.mh) because we
1700 # do not have a native configuration Makefile fragment.
1701 nativefile=`sed -n '
1702 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
1703 ' ${host_makefile_frag}`
1704 fi
1705 changequote([,])
1706
1707 if test x"${gdb_osabi}" != x ; then
1708     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
1709                        [Define to the default OS ABI for this configuration.])
1710 fi
1711
1712 # Enable multi-ice-gdb-server.
1713 AC_ARG_ENABLE(multi-ice,
1714 [  --enable-multi-ice      build the multi-ice-gdb-server],
1715   [case $enableval in
1716     yes | no)
1717       ;;
1718     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
1719   esac])
1720 if test "x$enable_multi_ice" = xyes; then
1721    AC_CONFIG_SUBDIRS(multi-ice)
1722 fi
1723
1724 # We only build gdbserver automatically in a native configuration.
1725 if test "$gdb_native" = "yes"; then
1726   AC_MSG_CHECKING(whether gdbserver is supported on this host)
1727   if test "x$build_gdbserver" = xyes; then
1728     AC_MSG_RESULT(yes)
1729     AC_CONFIG_SUBDIRS(gdbserver)
1730   else
1731     AC_MSG_RESULT(no)
1732   fi
1733 fi
1734
1735 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
1736 # to an empty version.
1737
1738 files=
1739 links=
1740
1741 rm -f nm.h
1742 nm_h=""
1743 if test "${nativefile}" != ""; then
1744     nm_h=nm.h
1745     case "${nativefile}" in
1746       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
1747       * ) GDB_NM_FILE="${nativefile}"
1748     esac
1749     files="${files} ${GDB_NM_FILE}"
1750     links="${links} nm.h"
1751     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
1752 fi
1753 AC_SUBST(nm_h)
1754
1755 AC_LINK_FILES($files, $links)
1756
1757 dnl Check for exe extension set on certain hosts (e.g. Win32)
1758 AC_EXEEXT
1759
1760 dnl  Detect the character set used by this host.
1761
1762 dnl  At the moment, we just assume it's ISO-8859-1 (which is a
1763 dnl  superset of ASCII containing the characters needed for French,
1764 dnl  German, Spanish, Italian, and possibly others), but if were
1765 dnl  *were* to support any host character sets other than ISO-8859-1,
1766 dnl  here's where we'd detect it.
1767 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "ISO-8859-1",
1768           [Define to be a string naming the default host character set.])
1769
1770 AM_ICONV
1771
1772 AC_OUTPUT(Makefile .gdbinit:gdbinit.in gnulib/Makefile,
1773 [
1774 dnl Autoconf doesn't provide a mechanism for modifying definitions
1775 dnl provided by makefile fragments.
1776 dnl
1777
1778 changequote(,)dnl
1779 sed -e '/^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
1780 mv -f Makefile.tmp Makefile
1781 changequote([,])dnl
1782
1783
1784 case x$CONFIG_HEADERS in
1785 xconfig.h:config.in)
1786 echo > stamp-h ;;
1787 esac
1788 ],
1789 [
1790 gdb_host_cpu=$gdb_host_cpu
1791 nativefile=$nativefile
1792 ])
1793
1794 exit 0