gdb/testsuite/configure.ac

   1 #                                                       -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # Copyright 2002, 2003, 2004, 2005, 2009
   5 # Free Software Foundation, Inc.
   6 #
   7 # This program is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ(2.59)
  21 AC_INIT(gdb.base)
  22
  23 AC_CANONICAL_BUILD
  24 AC_CANONICAL_HOST
  25 AC_CANONICAL_TARGET
  26
  27 ACX_NONCANONICAL_TARGET
  28
  29 # Check for the 'make' the user wants to use.
  30 AC_CHECK_PROGS(MAKE, make)
  31 MAKE_IS_GNU=
  32 case "`$MAKE --version 2>&1 | sed 1q`" in
  33   *GNU*)
  34     MAKE_IS_GNU=yes
  35     ;;
  36 esac
  37 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  38 AC_PROG_MAKE_SET
  39
  40 # Add HP-specific tests when appropriate.
  41 case $target in
  42   hppa*-*-hpux*)
  43     AC_CONFIG_SUBDIRS(gdb.hp) ;;
  44 esac
  45
  46 # Add Cell/B.E. specific tests when appropriate.
  47 # We need support for both PowerPC and SPU targets configured in.
  48 case $target in
  49   powerpc*-*-linux*)
  50     have_spu_target=no
  51     for targ in `echo $enable_targets | sed 's/,/ /g'`
  52       do
  53         case "${targ}" in
  54           spu*|all) have_spu_target=yes ;;
  55         esac
  56       done
  57     if test x$have_spu_target = xyes; then
  58       AC_CONFIG_SUBDIRS(gdb.cell)
  59     fi
  60     ;;
  61 esac
  62
  63 # With stabs.
  64 AC_ARG_WITH(stabs,
  65 [  --with-stabs            arrange to use stabs instead of host debug format],,
  66 [# We enable stabs tests by default on selected targets.
  67 case $target in
  68    powerpc-*-aix* \
  69  | rs6000-*-aix*  \
  70  | *-*-*bsd*      \
  71  | *-*-go32*      \
  72  | *-*-linux*     \
  73  | *-*-lynxos*    \
  74  | *-sun-*        \
  75  | hppa*-*-*      \
  76  | *-*-elf*       \
  77  | *-*-cygwin*    \
  78  | *-*-mingw*     \
  79  )
  80     with_stabs=yes ;;
  81  *)
  82     with_stabs=no ;;
  83 esac])
  84
  85 # Add stabs tests when appropriate.
  86 if test $with_stabs = yes; then
  87    AC_CONFIG_SUBDIRS(gdb.stabs)
  88 fi
  89
  90 # Enable gdbtk.
  91 AC_ARG_ENABLE(gdbtk,
  92 [  --enable-gtk            enable gdbtk graphical user interface (GUI)],,
  93   [if test -d $srcdir/gdb.gdbtk; then
  94     enable_gdbtk=yes
  95   else
  96     enable_gdbtk=no
  97   fi])
  98 # We unconditionally disable gdbtk tests on selected platforms.
  99 case $host_os in
 100   go32* | windows*)
 101     enable_gdbtk=no ;;
 102 esac
 103
 104 # Add gdbtk tests when appropriate.
 105 if test $enable_gdbtk = yes; then
 106    AC_CONFIG_SUBDIRS(gdb.gdbtk)
 107 fi
 108
 109 # Enable shared libraries.
 110 AC_ARG_ENABLE(shared,
 111 [  --enable-shared         build shared libraries [deault=yes]],,
 112   enable_shared=yes)
 113
 114 # If we have shared libraries, try to set RPATH_ENVVAR reasonably,
 115 # such that we can find the shared libraries in the build tree.
 116 if test $enable_shared = no; then
 117   # The variable `RPATH_ENVVAR' itself is not likely to be used on any
 118   # platform.
 119   RPATH_ENVVAR=RPATH_ENVVAR
 120 else
 121   # The variable `LD_LIBRARY_PATH' is used on most platforms.
 122   RPATH_ENVVAR=LD_LIBRARY_PATH
 123   # The following exceptions are taken from Libtool 1.4.3.
 124   case $host_os in
 125     aix*)
 126       if test $host_cpu != ia64; then
 127         RPATH_ENVVAR=LIBPATH
 128       fi ;;
 129     darwin* | rhapsody*)
 130       RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
 131     hpux*)
 132       RPATH_ENVVAR=SHLIB_PATH ;;
 133   esac
 134 fi
 135 AC_SUBST(RPATH_ENVVAR)
 136
 137 AC_CHECK_HEADERS(pthread.h)
 138
 139 AC_EXEEXT
 140
 141 AC_OUTPUT([Makefile \
 142   gdb.ada/Makefile \
 143   gdb.arch/Makefile gdb.asm/Makefile gdb.base/Makefile \
 144   gdb.cp/Makefile gdb.disasm/Makefile gdb.dwarf2/Makefile \
 145   gdb.fortran/Makefile gdb.server/Makefile \
 146   gdb.java/Makefile gdb.mi/Makefile gdb.modula2/Makefile \
 147   gdb.objc/Makefile gdb.opt/Makefile gdb.pascal/Makefile \
 148   gdb.python/Makefile gdb.reverse/Makefile \
 149   gdb.threads/Makefile gdb.trace/Makefile gdb.xml/Makefile])