git-svn.perl

   1 #!/usr/bin/env perl
   2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
   3 # License: GPL v2 or later
   4 use warnings;
   5 use strict;
   6 use vars qw/    $AUTHOR $VERSION
   7                 $sha1 $sha1_short $_revision $_repository
   8                 $_q $_authors $_authors_prog %users/;
   9 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
  10 $VERSION = '@@GIT_VERSION@@';
  11
  12 # From which subdir have we been invoked?
  13 my $cmd_dir_prefix = eval {
  14         command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
  15 } || '';
  16
  17 my $git_dir_user_set = 1 if defined $ENV{GIT_DIR};
  18 $ENV{GIT_DIR} ||= '.git';
  19 $Git::SVN::default_repo_id = 'svn';
  20 $Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
  21 $Git::SVN::Ra::_log_window_size = 100;
  22 $Git::SVN::_minimize_url = 'unset';
  23
  24 if (! exists $ENV{SVN_SSH}) {
  25         if (exists $ENV{GIT_SSH}) {
  26                 $ENV{SVN_SSH} = $ENV{GIT_SSH};
  27                 if ($^O eq 'msys') {
  28                         $ENV{SVN_SSH} =~ s/\\/\\\\/g;
  29                 }
  30         }
  31 }
  32
  33 $Git::SVN::Log::TZ = $ENV{TZ};
  34 $ENV{TZ} = 'UTC';
  35 $| = 1; # unbuffer STDOUT
  36
  37 sub fatal (@) { print STDERR "@_\n"; exit 1 }
  38 require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
  39 require SVN::Ra;
  40 require SVN::Delta;
  41 if ($SVN::Core::VERSION lt '1.1.0') {
  42         fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
  43 }
  44 my $can_compress = eval { require Compress::Zlib; 1};
  45 push @Git::SVN::Ra::ISA, 'SVN::Ra';
  46 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
  47 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
  48 use Carp qw/croak/;
  49 use Digest::MD5;
  50 use IO::File qw//;
  51 use File::Basename qw/dirname basename/;
  52 use File::Path qw/mkpath/;
  53 use File::Spec;
  54 use File::Find;
  55 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
  56 use IPC::Open3;
  57 use Git;
  58
  59 BEGIN {
  60         # import functions from Git into our packages, en masse
  61         no strict 'refs';
  62         foreach (qw/command command_oneline command_noisy command_output_pipe
  63                     command_input_pipe command_close_pipe
  64                     command_bidi_pipe command_close_bidi_pipe/) {
  65                 for my $package ( qw(SVN::Git::Editor SVN::Git::Fetcher
  66                         Git::SVN::Migration Git::SVN::Log Git::SVN),
  67                         __PACKAGE__) {
  68                         *{"${package}::$_"} = \&{"Git::$_"};
  69                 }
  70         }
  71 }
  72
  73 my ($SVN);
  74
  75 $sha1 = qr/[a-f\d]{40}/;
  76 $sha1_short = qr/[a-f\d]{4,40}/;
  77 my ($_stdin, $_help, $_edit,
  78         $_message, $_file, $_branch_dest,
  79         $_template, $_shared,
  80         $_version, $_fetch_all, $_no_rebase, $_fetch_parent,
  81         $_merge, $_strategy, $_dry_run, $_local,
  82         $_prefix, $_no_checkout, $_url, $_verbose,
  83         $_git_format, $_commit_url, $_tag);
  84 $Git::SVN::_follow_parent = 1;
  85 $_q ||= 0;
  86 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
  87                     'config-dir=s' => \$Git::SVN::Ra::config_dir,
  88                     'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache,
  89                     'ignore-paths=s' => \$SVN::Git::Fetcher::_ignore_regex );
  90 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
  91                 'authors-file|A=s' => \$_authors,
  92                 'authors-prog=s' => \$_authors_prog,
  93                 'repack:i' => \$Git::SVN::_repack,
  94                 'noMetadata' => \$Git::SVN::_no_metadata,
  95                 'useSvmProps' => \$Git::SVN::_use_svm_props,
  96                 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
  97                 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
  98                 'no-checkout' => \$_no_checkout,
  99                 'quiet|q+' => \$_q,
 100                 'repack-flags|repack-args|repack-opts=s' =>
 101                    \$Git::SVN::_repack_flags,
 102                 'use-log-author' => \$Git::SVN::_use_log_author,
 103                 'add-author-from' => \$Git::SVN::_add_author_from,
 104                 'localtime' => \$Git::SVN::_localtime,
 105                 %remote_opts );
 106
 107 my ($_trunk, @_tags, @_branches, $_stdlayout);
 108 my %icv;
 109 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
 110                   'trunk|T=s' => \$_trunk, 'tags|t=s@' => \@_tags,
 111                   'branches|b=s@' => \@_branches, 'prefix=s' => \$_prefix,
 112                   'stdlayout|s' => \$_stdlayout,
 113                   'minimize-url|m!' => \$Git::SVN::_minimize_url,
 114                   'no-metadata' => sub { $icv{noMetadata} = 1 },
 115                   'use-svm-props' => sub { $icv{useSvmProps} = 1 },
 116                   'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
 117                   'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
 118                   %remote_opts );
 119 my %cmt_opts = ( 'edit|e' => \$_edit,
 120                 'rmdir' => \$SVN::Git::Editor::_rmdir,
 121                 'find-copies-harder' => \$SVN::Git::Editor::_find_copies_harder,
 122                 'l=i' => \$SVN::Git::Editor::_rename_limit,
 123                 'copy-similarity|C=i'=> \$SVN::Git::Editor::_cp_similarity
 124 );
 125
 126 my %cmd = (
 127         fetch => [ \&cmd_fetch, "Download new revisions from SVN",
 128                         { 'revision|r=s' => \$_revision,
 129                           'fetch-all|all' => \$_fetch_all,
 130                           'parent|p' => \$_fetch_parent,
 131                            %fc_opts } ],
 132         clone => [ \&cmd_clone, "Initialize and fetch revisions",
 133                         { 'revision|r=s' => \$_revision,
 134                            %fc_opts, %init_opts } ],
 135         init => [ \&cmd_init, "Initialize a repo for tracking" .
 136                           " (requires URL argument)",
 137                           \%init_opts ],
 138         'multi-init' => [ \&cmd_multi_init,
 139                           "Deprecated alias for ".
 140                           "'$0 init -T<trunk> -b<branches> -t<tags>'",
 141                           \%init_opts ],
 142         dcommit => [ \&cmd_dcommit,
 143                      'Commit several diffs to merge with upstream',
 144                         { 'merge|m|M' => \$_merge,
 145                           'strategy|s=s' => \$_strategy,
 146                           'verbose|v' => \$_verbose,
 147                           'dry-run|n' => \$_dry_run,
 148                           'fetch-all|all' => \$_fetch_all,
 149                           'commit-url=s' => \$_commit_url,
 150                           'revision|r=i' => \$_revision,
 151                           'no-rebase' => \$_no_rebase,
 152                         %cmt_opts, %fc_opts } ],
 153         branch => [ \&cmd_branch,
 154                     'Create a branch in the SVN repository',
 155                     { 'message|m=s' => \$_message,
 156                       'destination|d=s' => \$_branch_dest,
 157                       'dry-run|n' => \$_dry_run,
 158                       'tag|t' => \$_tag } ],
 159         tag => [ sub { $_tag = 1; cmd_branch(@_) },
 160                  'Create a tag in the SVN repository',
 161                  { 'message|m=s' => \$_message,
 162                    'destination|d=s' => \$_branch_dest,
 163                    'dry-run|n' => \$_dry_run } ],
 164         'set-tree' => [ \&cmd_set_tree,
 165                         "Set an SVN repository to a git tree-ish",
 166                         { 'stdin' => \$_stdin, %cmt_opts, %fc_opts, } ],
 167         'create-ignore' => [ \&cmd_create_ignore,
 168                              'Create a .gitignore per svn:ignore',
 169                              { 'revision|r=i' => \$_revision
 170                              } ],
 171         'mkdirs' => [ \&cmd_mkdirs ,
 172                       "recreate empty directories after a checkout",
 173                       { 'revision|r=i' => \$_revision } ],
 174         'propget' => [ \&cmd_propget,
 175                        'Print the value of a property on a file or directory',
 176                        { 'revision|r=i' => \$_revision } ],
 177         'proplist' => [ \&cmd_proplist,
 178                        'List all properties of a file or directory',
 179                        { 'revision|r=i' => \$_revision } ],
 180         'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
 181                         { 'revision|r=i' => \$_revision
 182                         } ],
 183         'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
 184                         { 'revision|r=i' => \$_revision
 185                         } ],
 186         'multi-fetch' => [ \&cmd_multi_fetch,
 187                            "Deprecated alias for $0 fetch --all",
 188                            { 'revision|r=s' => \$_revision, %fc_opts } ],
 189         'migrate' => [ sub { },
 190                        # no-op, we automatically run this anyways,
 191                        'Migrate configuration/metadata/layout from
 192                         previous versions of git-svn',
 193                        { 'minimize' => \$Git::SVN::Migration::_minimize,
 194                          %remote_opts } ],
 195         'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
 196                         { 'limit=i' => \$Git::SVN::Log::limit,
 197                           'revision|r=s' => \$_revision,
 198                           'verbose|v' => \$Git::SVN::Log::verbose,
 199                           'incremental' => \$Git::SVN::Log::incremental,
 200                           'oneline' => \$Git::SVN::Log::oneline,
 201                           'show-commit' => \$Git::SVN::Log::show_commit,
 202                           'non-recursive' => \$Git::SVN::Log::non_recursive,
 203                           'authors-file|A=s' => \$_authors,
 204                           'color' => \$Git::SVN::Log::color,
 205                           'pager=s' => \$Git::SVN::Log::pager
 206                         } ],
 207         'find-rev' => [ \&cmd_find_rev,
 208                         "Translate between SVN revision numbers and tree-ish",
 209                         {} ],
 210         'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
 211                         { 'merge|m|M' => \$_merge,
 212                           'verbose|v' => \$_verbose,
 213                           'strategy|s=s' => \$_strategy,
 214                           'local|l' => \$_local,
 215                           'fetch-all|all' => \$_fetch_all,
 216                           'dry-run|n' => \$_dry_run,
 217                           %fc_opts } ],
 218         'commit-diff' => [ \&cmd_commit_diff,
 219                            'Commit a diff between two trees',
 220                         { 'message|m=s' => \$_message,
 221                           'file|F=s' => \$_file,
 222                           'revision|r=s' => \$_revision,
 223                         %cmt_opts } ],
 224         'info' => [ \&cmd_info,
 225                     "Show info about the latest SVN revision
 226                      on the current branch",
 227                     { 'url' => \$_url, } ],
 228         'blame' => [ \&Git::SVN::Log::cmd_blame,
 229                     "Show what revision and author last modified each line of a file",
 230                     { 'git-format' => \$_git_format } ],
 231         'reset' => [ \&cmd_reset,
 232                      "Undo fetches back to the specified SVN revision",
 233                      { 'revision|r=s' => \$_revision,
 234                        'parent|p' => \$_fetch_parent } ],
 235         'gc' => [ \&cmd_gc,
 236                   "Compress unhandled.log files in .git/svn and remove " .
 237                   "index files in .git/svn",
 238                 {} ],
 239 );
 240
 241 my $cmd;
 242 for (my $i = 0; $i < @ARGV; $i++) {
 243         if (defined $cmd{$ARGV[$i]}) {
 244                 $cmd = $ARGV[$i];
 245                 splice @ARGV, $i, 1;
 246                 last;
 247         } elsif ($ARGV[$i] eq 'help') {
 248                 $cmd = $ARGV[$i+1];
 249                 usage(0);
 250         }
 251 };
 252
 253 # make sure we're always running at the top-level working directory
 254 unless ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) {
 255         unless (-d $ENV{GIT_DIR}) {
 256                 if ($git_dir_user_set) {
 257                         die "GIT_DIR=$ENV{GIT_DIR} explicitly set, ",
 258                             "but it is not a directory\n";
 259                 }
 260                 my $git_dir = delete $ENV{GIT_DIR};
 261                 my $cdup = undef;
 262                 git_cmd_try {
 263                         $cdup = command_oneline(qw/rev-parse --show-cdup/);
 264                         $git_dir = '.' unless ($cdup);
 265                         chomp $cdup if ($cdup);
 266                         $cdup = "." unless ($cdup && length $cdup);
 267                 } "Already at toplevel, but $git_dir not found\n";
 268                 chdir $cdup or die "Unable to chdir up to '$cdup'\n";
 269                 unless (-d $git_dir) {
 270                         die "$git_dir still not found after going to ",
 271                             "'$cdup'\n";
 272                 }
 273                 $ENV{GIT_DIR} = $git_dir;
 274         }
 275         $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 276 }
 277
 278 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
 279
 280 read_git_config(\%opts);
 281 if ($cmd && ($cmd eq 'log' || $cmd eq 'blame')) {
 282         Getopt::Long::Configure('pass_through');
 283 }
 284 my $rv = GetOptions(%opts, 'help|H|h' => \$_help, 'version|V' => \$_version,
 285                     'minimize-connections' => \$Git::SVN::Migration::_minimize,
 286                     'id|i=s' => \$Git::SVN::default_ref_id,
 287                     'svn-remote|remote|R=s' => sub {
 288                        $Git::SVN::no_reuse_existing = 1;
 289                        $Git::SVN::default_repo_id = $_[1] });
 290 exit 1 if (!$rv && $cmd && $cmd ne 'log');
 291
 292 usage(0) if $_help;
 293 version() if $_version;
 294 usage(1) unless defined $cmd;
 295 load_authors() if $_authors;
 296 if (defined $_authors_prog) {
 297         $_authors_prog = "'" . File::Spec->rel2abs($_authors_prog) . "'";
 298 }
 299
 300 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
 301         Git::SVN::Migration::migration_check();
 302 }
 303 Git::SVN::init_vars();
 304 eval {
 305         Git::SVN::verify_remotes_sanity();
 306         $cmd{$cmd}->[0]->(@ARGV);
 307 };
 308 fatal $@ if $@;
 309 post_fetch_checkout();
 310 exit 0;
 311
 312 ####################### primary functions ######################
 313 sub usage {
 314         my $exit = shift || 0;
 315         my $fd = $exit ? \*STDERR : \*STDOUT;
 316         print $fd <<"";
 317 git-svn - bidirectional operations between a single Subversion tree and git
 318 Usage: git svn <command> [options] [arguments]\n
 319
 320         print $fd "Available commands:\n" unless $cmd;
 321
 322         foreach (sort keys %cmd) {
 323                 next if $cmd && $cmd ne $_;
 324                 next if /^multi-/; # don't show deprecated commands
 325                 print $fd '  ',pack('A17',$_),$cmd{$_}->[1],"\n";
 326                 foreach (sort keys %{$cmd{$_}->[2]}) {
 327                         # mixed-case options are for .git/config only
 328                         next if /[A-Z]/ && /^[a-z]+$/i;
 329                         # prints out arguments as they should be passed:
 330                         my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
 331                         print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
 332                                                         "--$_" : "-$_" }
 333                                                 split /\|/,$_)," $x\n";
 334                 }
 335         }
 336         print $fd <<"";
 337 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
 338 arbitrary identifier if you're tracking multiple SVN branches/repositories in
 339 one git repository and want to keep them separate.  See git-svn(1) for more
 340 information.
 341
 342         exit $exit;
 343 }
 344
 345 sub version {
 346         print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
 347         exit 0;
 348 }
 349
 350 sub do_git_init_db {
 351         unless (-d $ENV{GIT_DIR}) {
 352                 my @init_db = ('init');
 353                 push @init_db, "--template=$_template" if defined $_template;
 354                 if (defined $_shared) {
 355                         if ($_shared =~ /[a-z]/) {
 356                                 push @init_db, "--shared=$_shared";
 357                         } else {
 358                                 push @init_db, "--shared";
 359                         }
 360                 }
 361                 command_noisy(@init_db);
 362                 $_repository = Git->repository(Repository => ".git");
 363         }
 364         command_noisy('config', 'core.autocrlf', 'false');
 365         my $set;
 366         my $pfx = "svn-remote.$Git::SVN::default_repo_id";
 367         foreach my $i (keys %icv) {
 368                 die "'$set' and '$i' cannot both be set\n" if $set;
 369                 next unless defined $icv{$i};
 370                 command_noisy('config', "$pfx.$i", $icv{$i});
 371                 $set = $i;
 372         }
 373         my $ignore_regex = \$SVN::Git::Fetcher::_ignore_regex;
 374         command_noisy('config', "$pfx.ignore-paths", $$ignore_regex)
 375                 if defined $$ignore_regex;
 376 }
 377
 378 sub init_subdir {
 379         my $repo_path = shift or return;
 380         mkpath([$repo_path]) unless -d $repo_path;
 381         chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
 382         $ENV{GIT_DIR} = '.git';
 383         $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 384 }
 385
 386 sub cmd_clone {
 387         my ($url, $path) = @_;
 388         if (!defined $path &&
 389             (defined $_trunk || @_branches || @_tags ||
 390              defined $_stdlayout) &&
 391             $url !~ m#^[a-z\+]+://#) {
 392                 $path = $url;
 393         }
 394         $path = basename($url) if !defined $path || !length $path;
 395         my $authors_absolute = $_authors ? File::Spec->rel2abs($_authors) : "";
 396         cmd_init($url, $path);
 397         command_oneline('config', 'svn.authorsfile', $authors_absolute)
 398             if $_authors;
 399         Git::SVN::fetch_all($Git::SVN::default_repo_id);
 400 }
 401
 402 sub cmd_init {
 403         if (defined $_stdlayout) {
 404                 $_trunk = 'trunk' if (!defined $_trunk);
 405                 @_tags = 'tags' if (! @_tags);
 406                 @_branches = 'branches' if (! @_branches);
 407         }
 408         if (defined $_trunk || @_branches || @_tags) {
 409                 return cmd_multi_init(@_);
 410         }
 411         my $url = shift or die "SVN repository location required ",
 412                                "as a command-line argument\n";
 413         $url = canonicalize_url($url);
 414         init_subdir(@_);
 415         do_git_init_db();
 416
 417         if ($Git::SVN::_minimize_url eq 'unset') {
 418                 $Git::SVN::_minimize_url = 0;
 419         }
 420
 421         Git::SVN->init($url);
 422 }
 423
 424 sub cmd_fetch {
 425         if (grep /^\d+=./, @_) {
 426                 die "'<rev>=<commit>' fetch arguments are ",
 427                     "no longer supported.\n";
 428         }
 429         my ($remote) = @_;
 430         if (@_ > 1) {
 431                 die "Usage: $0 fetch [--all] [--parent] [svn-remote]\n";
 432         }
 433         $Git::SVN::no_reuse_existing = undef;
 434         if ($_fetch_parent) {
 435                 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 436                 unless ($gs) {
 437                         die "Unable to determine upstream SVN information from ",
 438                             "working tree history\n";
 439                 }
 440                 # just fetch, don't checkout.
 441                 $_no_checkout = 'true';
 442                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
 443         } elsif ($_fetch_all) {
 444                 cmd_multi_fetch();
 445         } else {
 446                 $remote ||= $Git::SVN::default_repo_id;
 447                 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
 448         }
 449 }
 450
 451 sub cmd_set_tree {
 452         my (@commits) = @_;
 453         if ($_stdin || !@commits) {
 454                 print "Reading from stdin...\n";
 455                 @commits = ();
 456                 while (<STDIN>) {
 457                         if (/\b($sha1_short)\b/o) {
 458                                 unshift @commits, $1;
 459                         }
 460                 }
 461         }
 462         my @revs;
 463         foreach my $c (@commits) {
 464                 my @tmp = command('rev-parse',$c);
 465                 if (scalar @tmp == 1) {
 466                         push @revs, $tmp[0];
 467                 } elsif (scalar @tmp > 1) {
 468                         push @revs, reverse(command('rev-list',@tmp));
 469                 } else {
 470                         fatal "Failed to rev-parse $c";
 471                 }
 472         }
 473         my $gs = Git::SVN->new;
 474         my ($r_last, $cmt_last) = $gs->last_rev_commit;
 475         $gs->fetch;
 476         if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
 477                 fatal "There are new revisions that were fetched ",
 478                       "and need to be merged (or acknowledged) ",
 479                       "before committing.\nlast rev: $r_last\n",
 480                       " current: $gs->{last_rev}";
 481         }
 482         $gs->set_tree($_) foreach @revs;
 483         print "Done committing ",scalar @revs," revisions to SVN\n";
 484         unlink $gs->{index};
 485 }
 486
 487 sub cmd_dcommit {
 488         my $head = shift;
 489         git_cmd_try { command_oneline(qw/diff-index --quiet HEAD/) }
 490                 'Cannot dcommit with a dirty index.  Commit your changes first, '
 491                 . "or stash them with `git stash'.\n";
 492         $head ||= 'HEAD';
 493
 494         my $old_head;
 495         if ($head ne 'HEAD') {
 496                 $old_head = eval {
 497                         command_oneline([qw/symbolic-ref -q HEAD/])
 498                 };
 499                 if ($old_head) {
 500                         $old_head =~ s{^refs/heads/}{};
 501                 } else {
 502                         $old_head = eval { command_oneline(qw/rev-parse HEAD/) };
 503                 }
 504                 command(['checkout', $head], STDERR => 0);
 505         }
 506
 507         my @refs;
 508         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD', \@refs);
 509         unless ($gs) {
 510                 die "Unable to determine upstream SVN information from ",
 511                     "$head history.\nPerhaps the repository is empty.";
 512         }
 513
 514         if (defined $_commit_url) {
 515                 $url = $_commit_url;
 516         } else {
 517                 $url = eval { command_oneline('config', '--get',
 518                               "svn-remote.$gs->{repo_id}.commiturl") };
 519                 if (!$url) {
 520                         $url = $gs->full_url
 521                 }
 522         }
 523
 524         my $last_rev = $_revision if defined $_revision;
 525         if ($url) {
 526                 print "Committing to $url ...\n";
 527         }
 528         my ($linear_refs, $parents) = linearize_history($gs, \@refs);
 529         if ($_no_rebase && scalar(@$linear_refs) > 1) {
 530                 warn "Attempting to commit more than one change while ",
 531                      "--no-rebase is enabled.\n",
 532                      "If these changes depend on each other, re-running ",
 533                      "without --no-rebase may be required."
 534         }
 535         my $expect_url = $url;
 536         Git::SVN::remove_username($expect_url);
 537         while (1) {
 538                 my $d = shift @$linear_refs or last;
 539                 unless (defined $last_rev) {
 540                         (undef, $last_rev, undef) = cmt_metadata("$d~1");
 541                         unless (defined $last_rev) {
 542                                 fatal "Unable to extract revision information ",
 543                                       "from commit $d~1";
 544                         }
 545                 }
 546                 if ($_dry_run) {
 547                         print "diff-tree $d~1 $d\n";
 548                 } else {
 549                         my $cmt_rev;
 550                         my %ed_opts = ( r => $last_rev,
 551                                         log => get_commit_entry($d)->{log},
 552                                         ra => Git::SVN::Ra->new($url),
 553                                         config => SVN::Core::config_get_config(
 554                                                 $Git::SVN::Ra::config_dir
 555                                         ),
 556                                         tree_a => "$d~1",
 557                                         tree_b => $d,
 558                                         editor_cb => sub {
 559                                                print "Committed r$_[0]\n";
 560                                                $cmt_rev = $_[0];
 561                                         },
 562                                         svn_path => '');
 563                         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
 564                                 print "No changes\n$d~1 == $d\n";
 565                         } elsif ($parents->{$d} && @{$parents->{$d}}) {
 566                                 $gs->{inject_parents_dcommit}->{$cmt_rev} =
 567                                                                $parents->{$d};
 568                         }
 569                         $_fetch_all ? $gs->fetch_all : $gs->fetch;
 570                         $last_rev = $cmt_rev;
 571                         next if $_no_rebase;
 572
 573                         # we always want to rebase against the current HEAD,
 574                         # not any head that was passed to us
 575                         my @diff = command('diff-tree', $d,
 576                                            $gs->refname, '--');
 577                         my @finish;
 578                         if (@diff) {
 579                                 @finish = rebase_cmd();
 580                                 print STDERR "W: $d and ", $gs->refname,
 581                                              " differ, using @finish:\n",
 582                                              join("\n", @diff), "\n";
 583                         } else {
 584                                 print "No changes between current HEAD and ",
 585                                       $gs->refname,
 586                                       "\nResetting to the latest ",
 587                                       $gs->refname, "\n";
 588                                 @finish = qw/reset --mixed/;
 589                         }
 590                         command_noisy(@finish, $gs->refname);
 591                         if (@diff) {
 592                                 @refs = ();
 593                                 my ($url_, $rev_, $uuid_, $gs_) =
 594                                               working_head_info('HEAD', \@refs);
 595                                 my ($linear_refs_, $parents_) =
 596                                               linearize_history($gs_, \@refs);
 597                                 if (scalar(@$linear_refs) !=
 598                                     scalar(@$linear_refs_)) {
 599                                         fatal "# of revisions changed ",
 600                                           "\nbefore:\n",
 601                                           join("\n", @$linear_refs),
 602                                           "\n\nafter:\n",
 603                                           join("\n", @$linear_refs_), "\n",
 604                                           'If you are attempting to commit ',
 605                                           "merges, try running:\n\t",
 606                                           'git rebase --interactive',
 607                                           '--preserve-merges ',
 608                                           $gs->refname,
 609                                           "\nBefore dcommitting";
 610                                 }
 611                                 if ($url_ ne $expect_url) {
 612                                         if ($url_ eq $gs->metadata_url) {
 613                                                 print
 614                                                   "Accepting rewritten URL:",
 615                                                   " $url_\n";
 616                                         } else {
 617                                                 fatal
 618                                                   "URL mismatch after rebase:",
 619                                                   " $url_ != $expect_url";
 620                                         }
 621                                 }
 622                                 if ($uuid_ ne $uuid) {
 623                                         fatal "uuid mismatch after rebase: ",
 624                                               "$uuid_ != $uuid";
 625                                 }
 626                                 # remap parents
 627                                 my (%p, @l, $i);
 628                                 for ($i = 0; $i < scalar @$linear_refs; $i++) {
 629                                         my $new = $linear_refs_->[$i] or next;
 630                                         $p{$new} =
 631                                                 $parents->{$linear_refs->[$i]};
 632                                         push @l, $new;
 633                                 }
 634                                 $parents = \%p;
 635                                 $linear_refs = \@l;
 636                         }
 637                 }
 638         }
 639
 640         if ($old_head) {
 641                 my $new_head = command_oneline(qw/rev-parse HEAD/);
 642                 my $new_is_symbolic = eval {
 643                         command_oneline(qw/symbolic-ref -q HEAD/);
 644                 };
 645                 if ($new_is_symbolic) {
 646                         print "dcommitted the branch ", $head, "\n";
 647                 } else {
 648                         print "dcommitted on a detached HEAD because you gave ",
 649                               "a revision argument.\n",
 650                               "The rewritten commit is: ", $new_head, "\n";
 651                 }
 652                 command(['checkout', $old_head], STDERR => 0);
 653         }
 654
 655         unlink $gs->{index};
 656 }
 657
 658 sub cmd_branch {
 659         my ($branch_name, $head) = @_;
 660
 661         unless (defined $branch_name && length $branch_name) {
 662                 die(($_tag ? "tag" : "branch") . " name required\n");
 663         }
 664         $head ||= 'HEAD';
 665
 666         my ($src, $rev, undef, $gs) = working_head_info($head);
 667
 668         my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
 669         my $allglobs = $remote->{ $_tag ? 'tags' : 'branches' };
 670         my $glob;
 671         if ($#{$allglobs} == 0) {
 672                 $glob = $allglobs->[0];
 673         } else {
 674                 unless(defined $_branch_dest) {
 675                         die "Multiple ",
 676                             $_tag ? "tag" : "branch",
 677                             " paths defined for Subversion repository.\n",
 678                             "You must specify where you want to create the ",
 679                             $_tag ? "tag" : "branch",
 680                             " with the --destination argument.\n";
 681                 }
 682                 foreach my $g (@{$allglobs}) {
 683                         # SVN::Git::Editor could probably be moved to Git.pm..
 684                         my $re = SVN::Git::Editor::glob2pat($g->{path}->{left});
 685                         if ($_branch_dest =~ /$re/) {
 686                                 $glob = $g;
 687                                 last;
 688                         }
 689                 }
 690                 unless (defined $glob) {
 691                         my $dest_re = qr/\b\Q$_branch_dest\E\b/;
 692                         foreach my $g (@{$allglobs}) {
 693                                 $g->{path}->{left} =~ /$dest_re/ or next;
 694                                 if (defined $glob) {
 695                                         die "Ambiguous destination: ",
 696                                             $_branch_dest, "\nmatches both '",
 697                                             $glob->{path}->{left}, "' and '",
 698                                             $g->{path}->{left}, "'\n";
 699                                 }
 700                                 $glob = $g;
 701                         }
 702                         unless (defined $glob) {
 703                                 die "Unknown ",
 704                                     $_tag ? "tag" : "branch",
 705                                     " destination $_branch_dest\n";
 706                         }
 707                 }
 708         }
 709         my ($lft, $rgt) = @{ $glob->{path} }{qw/left right/};
 710         my $dst = join '/', $remote->{url}, $lft, $branch_name, ($rgt || ());
 711
 712         my $ctx = SVN::Client->new(
 713                 auth    => Git::SVN::Ra::_auth_providers(),
 714                 log_msg => sub {
 715                         ${ $_[0] } = defined $_message
 716                                 ? $_message
 717                                 : 'Create ' . ($_tag ? 'tag ' : 'branch ' )
 718                                 . $branch_name;
 719                 },
 720         );
 721
 722         eval {
 723                 $ctx->ls($dst, 'HEAD', 0);
 724         } and die "branch ${branch_name} already exists\n";
 725
 726         print "Copying ${src} at r${rev} to ${dst}...\n";
 727         $ctx->copy($src, $rev, $dst)
 728                 unless $_dry_run;
 729
 730         $gs->fetch_all;
 731 }
 732
 733 sub cmd_find_rev {
 734         my $revision_or_hash = shift or die "SVN or git revision required ",
 735                                             "as a command-line argument\n";
 736         my $result;
 737         if ($revision_or_hash =~ /^r\d+$/) {
 738                 my $head = shift;
 739                 $head ||= 'HEAD';
 740                 my @refs;
 741                 my (undef, undef, $uuid, $gs) = working_head_info($head, \@refs);
 742                 unless ($gs) {
 743                         die "Unable to determine upstream SVN information from ",
 744                             "$head history\n";
 745                 }
 746                 my $desired_revision = substr($revision_or_hash, 1);
 747                 $result = $gs->rev_map_get($desired_revision, $uuid);
 748         } else {
 749                 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
 750                 $result = $rev;
 751         }
 752         print "$result\n" if $result;
 753 }
 754
 755 sub cmd_rebase {
 756         command_noisy(qw/update-index --refresh/);
 757         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 758         unless ($gs) {
 759                 die "Unable to determine upstream SVN information from ",
 760                     "working tree history\n";
 761         }
 762         if ($_dry_run) {
 763                 print "Remote Branch: " . $gs->refname . "\n";
 764                 print "SVN URL: " . $url . "\n";
 765                 return;
 766         }
 767         if (command(qw/diff-index HEAD --/)) {
 768                 print STDERR "Cannot rebase with uncommited changes:\n";
 769                 command_noisy('status');
 770                 exit 1;
 771         }
 772         unless ($_local) {
 773                 # rebase will checkout for us, so no need to do it explicitly
 774                 $_no_checkout = 'true';
 775                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
 776         }
 777         command_noisy(rebase_cmd(), $gs->refname);
 778         $gs->mkemptydirs;
 779 }
 780
 781 sub cmd_show_ignore {
 782         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 783         $gs ||= Git::SVN->new;
 784         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 785         $gs->prop_walk($gs->{path}, $r, sub {
 786                 my ($gs, $path, $props) = @_;
 787                 print STDOUT "\n# $path\n";
 788                 my $s = $props->{'svn:ignore'} or return;
 789                 $s =~ s/[\r\n]+/\n/g;
 790                 $s =~ s/^\n+//;
 791                 chomp $s;
 792                 $s =~ s#^#$path#gm;
 793                 print STDOUT "$s\n";
 794         });
 795 }
 796
 797 sub cmd_show_externals {
 798         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 799         $gs ||= Git::SVN->new;
 800         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 801         $gs->prop_walk($gs->{path}, $r, sub {
 802                 my ($gs, $path, $props) = @_;
 803                 print STDOUT "\n# $path\n";
 804                 my $s = $props->{'svn:externals'} or return;
 805                 $s =~ s/[\r\n]+/\n/g;
 806                 chomp $s;
 807                 $s =~ s#^#$path#gm;
 808                 print STDOUT "$s\n";
 809         });
 810 }
 811
 812 sub cmd_create_ignore {
 813         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 814         $gs ||= Git::SVN->new;
 815         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 816         $gs->prop_walk($gs->{path}, $r, sub {
 817                 my ($gs, $path, $props) = @_;
 818                 # $path is of the form /path/to/dir/
 819                 $path = '.' . $path;
 820                 # SVN can have attributes on empty directories,
 821                 # which git won't track
 822                 mkpath([$path]) unless -d $path;
 823                 my $ignore = $path . '.gitignore';
 824                 my $s = $props->{'svn:ignore'} or return;
 825                 open(GITIGNORE, '>', $ignore)
 826                   or fatal("Failed to open `$ignore' for writing: $!");
 827                 $s =~ s/[\r\n]+/\n/g;
 828                 $s =~ s/^\n+//;
 829                 chomp $s;
 830                 # Prefix all patterns so that the ignore doesn't apply
 831                 # to sub-directories.
 832                 $s =~ s#^#/#gm;
 833                 print GITIGNORE "$s\n";
 834                 close(GITIGNORE)
 835                   or fatal("Failed to close `$ignore': $!");
 836                 command_noisy('add', '-f', $ignore);
 837         });
 838 }
 839
 840 sub cmd_mkdirs {
 841         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 842         $gs ||= Git::SVN->new;
 843         $gs->mkemptydirs($_revision);
 844 }
 845
 846 sub canonicalize_path {
 847         my ($path) = @_;
 848         my $dot_slash_added = 0;
 849         if (substr($path, 0, 1) ne "/") {
 850                 $path = "./" . $path;
 851                 $dot_slash_added = 1;
 852         }
 853         # File::Spec->canonpath doesn't collapse x/../y into y (for a
 854         # good reason), so let's do this manually.
 855         $path =~ s#/+#/#g;
 856         $path =~ s#/\.(?:/|$)#/#g;
 857         $path =~ s#/[^/]+/\.\.##g;
 858         $path =~ s#/$##g;
 859         $path =~ s#^\./## if $dot_slash_added;
 860         $path =~ s#^/##;
 861         $path =~ s#^\.$##;
 862         return $path;
 863 }
 864
 865 sub canonicalize_url {
 866         my ($url) = @_;
 867         $url =~ s#^([^:]+://[^/]*/)(.*)$#$1 . canonicalize_path($2)#e;
 868         return $url;
 869 }
 870
 871 # get_svnprops(PATH)
 872 # ------------------
 873 # Helper for cmd_propget and cmd_proplist below.
 874 sub get_svnprops {
 875         my $path = shift;
 876         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 877         $gs ||= Git::SVN->new;
 878
 879         # prefix THE PATH by the sub-directory from which the user
 880         # invoked us.
 881         $path = $cmd_dir_prefix . $path;
 882         fatal("No such file or directory: $path") unless -e $path;
 883         my $is_dir = -d $path ? 1 : 0;
 884         $path = $gs->{path} . '/' . $path;
 885
 886         # canonicalize the path (otherwise libsvn will abort or fail to
 887         # find the file)
 888         $path = canonicalize_path($path);
 889
 890         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 891         my $props;
 892         if ($is_dir) {
 893                 (undef, undef, $props) = $gs->ra->get_dir($path, $r);
 894         }
 895         else {
 896                 (undef, $props) = $gs->ra->get_file($path, $r, undef);
 897         }
 898         return $props;
 899 }
 900
 901 # cmd_propget (PROP, PATH)
 902 # ------------------------
 903 # Print the SVN property PROP for PATH.
 904 sub cmd_propget {
 905         my ($prop, $path) = @_;
 906         $path = '.' if not defined $path;
 907         usage(1) if not defined $prop;
 908         my $props = get_svnprops($path);
 909         if (not defined $props->{$prop}) {
 910                 fatal("`$path' does not have a `$prop' SVN property.");
 911         }
 912         print $props->{$prop} . "\n";
 913 }
 914
 915 # cmd_proplist (PATH)
 916 # -------------------
 917 # Print the list of SVN properties for PATH.
 918 sub cmd_proplist {
 919         my $path = shift;
 920         $path = '.' if not defined $path;
 921         my $props = get_svnprops($path);
 922         print "Properties on '$path':\n";
 923         foreach (sort keys %{$props}) {
 924                 print "  $_\n";
 925         }
 926 }
 927
 928 sub cmd_multi_init {
 929         my $url = shift;
 930         unless (defined $_trunk || @_branches || @_tags) {
 931                 usage(1);
 932         }
 933
 934         $_prefix = '' unless defined $_prefix;
 935         if (defined $url) {
 936                 $url = canonicalize_url($url);
 937                 init_subdir(@_);
 938         }
 939         do_git_init_db();
 940         if (defined $_trunk) {
 941                 my $trunk_ref = 'refs/remotes/' . $_prefix . 'trunk';
 942                 # try both old-style and new-style lookups:
 943                 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
 944                 unless ($gs_trunk) {
 945                         my ($trunk_url, $trunk_path) =
 946                                               complete_svn_url($url, $_trunk);
 947                         $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
 948                                                    undef, $trunk_ref);
 949                 }
 950         }
 951         return unless @_branches || @_tags;
 952         my $ra = $url ? Git::SVN::Ra->new($url) : undef;
 953         foreach my $path (@_branches) {
 954                 complete_url_ls_init($ra, $path, '--branches/-b', $_prefix);
 955         }
 956         foreach my $path (@_tags) {
 957                 complete_url_ls_init($ra, $path, '--tags/-t', $_prefix.'tags/');
 958         }
 959 }
 960
 961 sub cmd_multi_fetch {
 962         $Git::SVN::no_reuse_existing = undef;
 963         my $remotes = Git::SVN::read_all_remotes();
 964         foreach my $repo_id (sort keys %$remotes) {
 965                 if ($remotes->{$repo_id}->{url}) {
 966                         Git::SVN::fetch_all($repo_id, $remotes);
 967                 }
 968         }
 969 }
 970
 971 # this command is special because it requires no metadata
 972 sub cmd_commit_diff {
 973         my ($ta, $tb, $url) = @_;
 974         my $usage = "Usage: $0 commit-diff -r<revision> ".
 975                     "<tree-ish> <tree-ish> [<URL>]";
 976         fatal($usage) if (!defined $ta || !defined $tb);
 977         my $svn_path = '';
 978         if (!defined $url) {
 979                 my $gs = eval { Git::SVN->new };
 980                 if (!$gs) {
 981                         fatal("Needed URL or usable git-svn --id in ",
 982                               "the command-line\n", $usage);
 983                 }
 984                 $url = $gs->{url};
 985                 $svn_path = $gs->{path};
 986         }
 987         unless (defined $_revision) {
 988                 fatal("-r|--revision is a required argument\n", $usage);
 989         }
 990         if (defined $_message && defined $_file) {
 991                 fatal("Both --message/-m and --file/-F specified ",
 992                       "for the commit message.\n",
 993                       "I have no idea what you mean");
 994         }
 995         if (defined $_file) {
 996                 $_message = file_to_s($_file);
 997         } else {
 998                 $_message ||= get_commit_entry($tb)->{log};
 999         }
1000         my $ra ||= Git::SVN::Ra->new($url);
1001         my $r = $_revision;
1002         if ($r eq 'HEAD') {
1003                 $r = $ra->get_latest_revnum;
1004         } elsif ($r !~ /^\d+$/) {
1005                 die "revision argument: $r not understood by git-svn\n";
1006         }
1007         my %ed_opts = ( r => $r,
1008                         log => $_message,
1009                         ra => $ra,
1010                         tree_a => $ta,
1011                         tree_b => $tb,
1012                         editor_cb => sub { print "Committed r$_[0]\n" },
1013                         svn_path => $svn_path );
1014         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
1015                 print "No changes\n$ta == $tb\n";
1016         }
1017 }
1018
1019 sub escape_uri_only {
1020         my ($uri) = @_;
1021         my @tmp;
1022         foreach (split m{/}, $uri) {
1023                 s/([^~\w.%+-]|%(?![a-fA-F0-9]{2}))/sprintf("%%%02X",ord($1))/eg;
1024                 push @tmp, $_;
1025         }
1026         join('/', @tmp);
1027 }
1028
1029 sub escape_url {
1030         my ($url) = @_;
1031         if ($url =~ m#^([^:]+)://([^/]*)(.*)$#) {
1032                 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
1033                 $url = "$scheme://$domain$uri";
1034         }
1035         $url;
1036 }
1037
1038 sub cmd_info {
1039         my $path = canonicalize_path(defined($_[0]) ? $_[0] : ".");
1040         my $fullpath = canonicalize_path($cmd_dir_prefix . $path);
1041         if (exists $_[1]) {
1042                 die "Too many arguments specified\n";
1043         }
1044
1045         my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
1046
1047         if (!$file_type && !$diff_status) {
1048                 print STDERR "svn: '$path' is not under version control\n";
1049                 exit 1;
1050         }
1051
1052         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1053         unless ($gs) {
1054                 die "Unable to determine upstream SVN information from ",
1055                     "working tree history\n";
1056         }
1057
1058         # canonicalize_path() will return "" to make libsvn 1.5.x happy,
1059         $path = "." if $path eq "";
1060
1061         my $full_url = $url . ($fullpath eq "" ? "" : "/$fullpath");
1062
1063         if ($_url) {
1064                 print escape_url($full_url), "\n";
1065                 return;
1066         }
1067
1068         my $result = "Path: $path\n";
1069         $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
1070         $result .= "URL: " . escape_url($full_url) . "\n";
1071
1072         eval {
1073                 my $repos_root = $gs->repos_root;
1074                 Git::SVN::remove_username($repos_root);
1075                 $result .= "Repository Root: " . escape_url($repos_root) . "\n";
1076         };
1077         if ($@) {
1078                 $result .= "Repository Root: (offline)\n";
1079         }
1080         $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A" &&
1081                 ($SVN::Core::VERSION le '1.5.4' || $file_type ne "dir");
1082         $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
1083
1084         $result .= "Node Kind: " .
1085                    ($file_type eq "dir" ? "directory" : "file") . "\n";
1086
1087         my $schedule = $diff_status eq "A"
1088                        ? "add"
1089                        : ($diff_status eq "D" ? "delete" : "normal");
1090         $result .= "Schedule: $schedule\n";
1091
1092         if ($diff_status eq "A") {
1093                 print $result, "\n";
1094                 return;
1095         }
1096
1097         my ($lc_author, $lc_rev, $lc_date_utc);
1098         my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $fullpath);
1099         my $log = command_output_pipe(@args);
1100         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
1101         while (<$log>) {
1102                 if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
1103                         $lc_author = $1;
1104                         $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
1105                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
1106                         (undef, $lc_rev, undef) = ::extract_metadata($1);
1107                 }
1108         }
1109         close $log;
1110
1111         Git::SVN::Log::set_local_timezone();
1112
1113         $result .= "Last Changed Author: $lc_author\n";
1114         $result .= "Last Changed Rev: $lc_rev\n";
1115         $result .= "Last Changed Date: " .
1116                    Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
1117
1118         if ($file_type ne "dir") {
1119                 my $text_last_updated_date =
1120                     ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
1121                 $result .=
1122                     "Text Last Updated: " .
1123                     Git::SVN::Log::format_svn_date($text_last_updated_date) .
1124                     "\n";
1125                 my $checksum;
1126                 if ($diff_status eq "D") {
1127                         my ($fh, $ctx) =
1128                             command_output_pipe(qw(cat-file blob), "HEAD:$path");
1129                         if ($file_type eq "link") {
1130                                 my $file_name = <$fh>;
1131                                 $checksum = md5sum("link $file_name");
1132                         } else {
1133                                 $checksum = md5sum($fh);
1134                         }
1135                         command_close_pipe($fh, $ctx);
1136                 } elsif ($file_type eq "link") {
1137                         my $file_name =
1138                             command(qw(cat-file blob), "HEAD:$path");
1139                         $checksum =
1140                             md5sum("link " . $file_name);
1141                 } else {
1142                         open FILE, "<", $path or die $!;
1143                         $checksum = md5sum(\*FILE);
1144                         close FILE or die $!;
1145                 }
1146                 $result .= "Checksum: " . $checksum . "\n";
1147         }
1148
1149         print $result, "\n";
1150 }
1151
1152 sub cmd_reset {
1153         my $target = shift || $_revision or die "SVN revision required\n";
1154         $target = $1 if $target =~ /^r(\d+)$/;
1155         $target =~ /^\d+$/ or die "Numeric SVN revision expected\n";
1156         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1157         unless ($gs) {
1158                 die "Unable to determine upstream SVN information from ".
1159                     "history\n";
1160         }
1161         my ($r, $c) = $gs->find_rev_before($target, not $_fetch_parent);
1162         $gs->rev_map_set($r, $c, 'reset', $uuid);
1163         print "r$r = $c ($gs->{ref_id})\n";
1164 }
1165
1166 sub cmd_gc {
1167         if (!$can_compress) {
1168                 warn "Compress::Zlib could not be found; unhandled.log " .
1169                      "files will not be compressed.\n";
1170         }
1171         find({ wanted => \&gc_directory, no_chdir => 1}, "$ENV{GIT_DIR}/svn");
1172 }
1173
1174 ########################### utility functions #########################
1175
1176 sub rebase_cmd {
1177         my @cmd = qw/rebase/;
1178         push @cmd, '-v' if $_verbose;
1179         push @cmd, qw/--merge/ if $_merge;
1180         push @cmd, "--strategy=$_strategy" if $_strategy;
1181         @cmd;
1182 }
1183
1184 sub post_fetch_checkout {
1185         return if $_no_checkout;
1186         my $gs = $Git::SVN::_head or return;
1187         return if verify_ref('refs/heads/master^0');
1188
1189         # look for "trunk" ref if it exists
1190         my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
1191         my $fetch = $remote->{fetch};
1192         if ($fetch) {
1193                 foreach my $p (keys %$fetch) {
1194                         basename($fetch->{$p}) eq 'trunk' or next;
1195                         $gs = Git::SVN->new($fetch->{$p}, $gs->{repo_id}, $p);
1196                         last;
1197                 }
1198         }
1199
1200         my $valid_head = verify_ref('HEAD^0');
1201         command_noisy(qw(update-ref refs/heads/master), $gs->refname);
1202         return if ($valid_head || !verify_ref('HEAD^0'));
1203
1204         return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
1205         my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
1206         return if -f $index;
1207
1208         return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
1209         return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
1210         command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
1211         print STDERR "Checked out HEAD:\n  ",
1212                      $gs->full_url, " r", $gs->last_rev, "\n";
1213         $gs->mkemptydirs($gs->last_rev);
1214 }
1215
1216 sub complete_svn_url {
1217         my ($url, $path) = @_;
1218         $path =~ s#/+$##;
1219         if ($path !~ m#^[a-z\+]+://#) {
1220                 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
1221                         fatal("E: '$path' is not a complete URL ",
1222                               "and a separate URL is not specified");
1223                 }
1224                 return ($url, $path);
1225         }
1226         return ($path, '');
1227 }
1228
1229 sub complete_url_ls_init {
1230         my ($ra, $repo_path, $switch, $pfx) = @_;
1231         unless ($repo_path) {
1232                 print STDERR "W: $switch not specified\n";
1233                 return;
1234         }
1235         $repo_path =~ s#/+$##;
1236         if ($repo_path =~ m#^[a-z\+]+://#) {
1237                 $ra = Git::SVN::Ra->new($repo_path);
1238                 $repo_path = '';
1239         } else {
1240                 $repo_path =~ s#^/+##;
1241                 unless ($ra) {
1242                         fatal("E: '$repo_path' is not a complete URL ",
1243                               "and a separate URL is not specified");
1244                 }
1245         }
1246         my $url = $ra->{url};
1247         my $gs = Git::SVN->init($url, undef, undef, undef, 1);
1248         my $k = "svn-remote.$gs->{repo_id}.url";
1249         my $orig_url = eval { command_oneline(qw/config --get/, $k) };
1250         if ($orig_url && ($orig_url ne $gs->{url})) {
1251                 die "$k already set: $orig_url\n",
1252                     "wanted to set to: $gs->{url}\n";
1253         }
1254         command_oneline('config', $k, $gs->{url}) unless $orig_url;
1255         my $remote_path = "$gs->{path}/$repo_path";
1256         $remote_path =~ s{%([0-9A-F]{2})}{chr hex($1)}ieg;
1257         $remote_path =~ s#/+#/#g;
1258         $remote_path =~ s#^/##g;
1259         $remote_path .= "/*" if $remote_path !~ /\*/;
1260         my ($n) = ($switch =~ /^--(\w+)/);
1261         if (length $pfx && $pfx !~ m#/$#) {
1262                 die "--prefix='$pfx' must have a trailing slash '/'\n";
1263         }
1264         command_noisy('config',
1265                       '--add',
1266                       "svn-remote.$gs->{repo_id}.$n",
1267                       "$remote_path:refs/remotes/$pfx*" .
1268                         ('/*' x (($remote_path =~ tr/*/*/) - 1)) );
1269 }
1270
1271 sub verify_ref {
1272         my ($ref) = @_;
1273         eval { command_oneline([ 'rev-parse', '--verify', $ref ],
1274                                { STDERR => 0 }); };
1275 }
1276
1277 sub get_tree_from_treeish {
1278         my ($treeish) = @_;
1279         # $treeish can be a symbolic ref, too:
1280         my $type = command_oneline(qw/cat-file -t/, $treeish);
1281         my $expected;
1282         while ($type eq 'tag') {
1283                 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
1284         }
1285         if ($type eq 'commit') {
1286                 $expected = (grep /^tree /, command(qw/cat-file commit/,
1287                                                     $treeish))[0];
1288                 ($expected) = ($expected =~ /^tree ($sha1)$/o);
1289                 die "Unable to get tree from $treeish\n" unless $expected;
1290         } elsif ($type eq 'tree') {
1291                 $expected = $treeish;
1292         } else {
1293                 die "$treeish is a $type, expected tree, tag or commit\n";
1294         }
1295         return $expected;
1296 }
1297
1298 sub get_commit_entry {
1299         my ($treeish) = shift;
1300         my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
1301         my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
1302         my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
1303         open my $log_fh, '>', $commit_editmsg or croak $!;
1304
1305         my $type = command_oneline(qw/cat-file -t/, $treeish);
1306         if ($type eq 'commit' || $type eq 'tag') {
1307                 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1308                                                          $type, $treeish);
1309                 my $in_msg = 0;
1310                 my $author;
1311                 my $saw_from = 0;
1312                 my $msgbuf = "";
1313                 while (<$msg_fh>) {
1314                         if (!$in_msg) {
1315                                 $in_msg = 1 if (/^\s*$/);
1316                                 $author = $1 if (/^author (.*>)/);
1317                         } elsif (/^git-svn-id: /) {
1318                                 # skip this for now, we regenerate the
1319                                 # correct one on re-fetch anyways
1320                                 # TODO: set *:merge properties or like...
1321                         } else {
1322                                 if (/^From:/ || /^Signed-off-by:/) {
1323                                         $saw_from = 1;
1324                                 }
1325                                 $msgbuf .= $_;
1326                         }
1327                 }
1328                 $msgbuf =~ s/\s+$//s;
1329                 if ($Git::SVN::_add_author_from && defined($author)
1330                     && !$saw_from) {
1331                         $msgbuf .= "\n\nFrom: $author";
1332                 }
1333                 print $log_fh $msgbuf or croak $!;
1334                 command_close_pipe($msg_fh, $ctx);
1335         }
1336         close $log_fh or croak $!;
1337
1338         if ($_edit || ($type eq 'tree')) {
1339                 chomp(my $editor = command_oneline(qw(var GIT_EDITOR)));
1340                 system('sh', '-c', $editor.' "$@"', $editor, $commit_editmsg);
1341         }
1342         rename $commit_editmsg, $commit_msg or croak $!;
1343         {
1344                 require Encode;
1345                 # SVN requires messages to be UTF-8 when entering the repo
1346                 local $/;
1347                 open $log_fh, '<', $commit_msg or croak $!;
1348                 binmode $log_fh;
1349                 chomp($log_entry{log} = <$log_fh>);
1350
1351                 my $enc = Git::config('i18n.commitencoding') || 'UTF-8';
1352                 my $msg = $log_entry{log};
1353
1354                 eval { $msg = Encode::decode($enc, $msg, 1) };
1355                 if ($@) {
1356                         die "Could not decode as $enc:\n", $msg,
1357                             "\nPerhaps you need to set i18n.commitencoding\n";
1358                 }
1359
1360                 eval { $msg = Encode::encode('UTF-8', $msg, 1) };
1361                 die "Could not encode as UTF-8:\n$msg\n" if $@;
1362
1363                 $log_entry{log} = $msg;
1364
1365                 close $log_fh or croak $!;
1366         }
1367         unlink $commit_msg;
1368         \%log_entry;
1369 }
1370
1371 sub s_to_file {
1372         my ($str, $file, $mode) = @_;
1373         open my $fd,'>',$file or croak $!;
1374         print $fd $str,"\n" or croak $!;
1375         close $fd or croak $!;
1376         chmod ($mode &~ umask, $file) if (defined $mode);
1377 }
1378
1379 sub file_to_s {
1380         my $file = shift;
1381         open my $fd,'<',$file or croak "$!: file: $file\n";
1382         local $/;
1383         my $ret = <$fd>;
1384         close $fd or croak $!;
1385         $ret =~ s/\s*$//s;
1386         return $ret;
1387 }
1388
1389 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
1390 sub load_authors {
1391         open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1392         my $log = $cmd eq 'log';
1393         while (<$authors>) {
1394                 chomp;
1395                 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
1396                 my ($user, $name, $email) = ($1, $2, $3);
1397                 if ($log) {
1398                         $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1399                 } else {
1400                         $users{$user} = [$name, $email];
1401                 }
1402         }
1403         close $authors or croak $!;
1404 }
1405
1406 # convert GetOpt::Long specs for use by git-config
1407 sub read_git_config {
1408         my $opts = shift;
1409         my @config_only;
1410         foreach my $o (keys %$opts) {
1411                 # if we have mixedCase and a long option-only, then
1412                 # it's a config-only variable that we don't need for
1413                 # the command-line.
1414                 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1415                 my $v = $opts->{$o};
1416                 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1417                 $key =~ s/-//g;
1418                 my $arg = 'git config';
1419                 $arg .= ' --int' if ($o =~ /[:=]i$/);
1420                 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1421                 if (ref $v eq 'ARRAY') {
1422                         chomp(my @tmp = `$arg --get-all svn.$key`);
1423                         @$v = @tmp if @tmp;
1424                 } else {
1425                         chomp(my $tmp = `$arg --get svn.$key`);
1426                         if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1427                                 $$v = $tmp;
1428                         }
1429                 }
1430         }
1431         delete @$opts{@config_only} if @config_only;
1432 }
1433
1434 sub extract_metadata {
1435         my $id = shift or return (undef, undef, undef);
1436         my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1437                                                         \s([a-f\d\-]+)$/ix);
1438         if (!defined $rev || !$uuid || !$url) {
1439                 # some of the original repositories I made had
1440                 # identifiers like this:
1441                 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/i);
1442         }
1443         return ($url, $rev, $uuid);
1444 }
1445
1446 sub cmt_metadata {
1447         return extract_metadata((grep(/^git-svn-id: /,
1448                 command(qw/cat-file commit/, shift)))[-1]);
1449 }
1450
1451 sub cmt_sha2rev_batch {
1452         my %s2r;
1453         my ($pid, $in, $out, $ctx) = command_bidi_pipe(qw/cat-file --batch/);
1454         my $list = shift;
1455
1456         foreach my $sha (@{$list}) {
1457                 my $first = 1;
1458                 my $size = 0;
1459                 print $out $sha, "\n";
1460
1461                 while (my $line = <$in>) {
1462                         if ($first && $line =~ /^[[:xdigit:]]{40}\smissing$/) {
1463                                 last;
1464                         } elsif ($first &&
1465                                $line =~ /^[[:xdigit:]]{40}\scommit\s(\d+)$/) {
1466                                 $first = 0;
1467                                 $size = $1;
1468                                 next;
1469                         } elsif ($line =~ /^(git-svn-id: )/) {
1470                                 my (undef, $rev, undef) =
1471                                                       extract_metadata($line);
1472                                 $s2r{$sha} = $rev;
1473                         }
1474
1475                         $size -= length($line);
1476                         last if ($size == 0);
1477                 }
1478         }
1479
1480         command_close_bidi_pipe($pid, $in, $out, $ctx);
1481
1482         return \%s2r;
1483 }
1484
1485 sub working_head_info {
1486         my ($head, $refs) = @_;
1487         my @args = ('log', '--no-color', '--first-parent', '--pretty=medium');
1488         my ($fh, $ctx) = command_output_pipe(@args, $head);
1489         my $hash;
1490         my %max;
1491         while (<$fh>) {
1492                 if ( m{^commit ($::sha1)$} ) {
1493                         unshift @$refs, $hash if $hash and $refs;
1494                         $hash = $1;
1495                         next;
1496                 }
1497                 next unless s{^\s*(git-svn-id:)}{$1};
1498                 my ($url, $rev, $uuid) = extract_metadata($_);
1499                 if (defined $url && defined $rev) {
1500                         next if $max{$url} and $max{$url} < $rev;
1501                         if (my $gs = Git::SVN->find_by_url($url)) {
1502                                 my $c = $gs->rev_map_get($rev, $uuid);
1503                                 if ($c && $c eq $hash) {
1504                                         close $fh; # break the pipe
1505                                         return ($url, $rev, $uuid, $gs);
1506                                 } else {
1507                                         $max{$url} ||= $gs->rev_map_max;
1508                                 }
1509                         }
1510                 }
1511         }
1512         command_close_pipe($fh, $ctx);
1513         (undef, undef, undef, undef);
1514 }
1515
1516 sub read_commit_parents {
1517         my ($parents, $c) = @_;
1518         chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
1519         $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
1520         @{$parents->{$c}} = split(/ /, $p);
1521 }
1522
1523 sub linearize_history {
1524         my ($gs, $refs) = @_;
1525         my %parents;
1526         foreach my $c (@$refs) {
1527                 read_commit_parents(\%parents, $c);
1528         }
1529
1530         my @linear_refs;
1531         my %skip = ();
1532         my $last_svn_commit = $gs->last_commit;
1533         foreach my $c (reverse @$refs) {
1534                 next if $c eq $last_svn_commit;
1535                 last if $skip{$c};
1536
1537                 unshift @linear_refs, $c;
1538                 $skip{$c} = 1;
1539
1540                 # we only want the first parent to diff against for linear
1541                 # history, we save the rest to inject when we finalize the
1542                 # svn commit
1543                 my $fp_a = verify_ref("$c~1");
1544                 my $fp_b = shift @{$parents{$c}} if $parents{$c};
1545                 if (!$fp_a || !$fp_b) {
1546                         die "Commit $c\n",
1547                             "has no parent commit, and therefore ",
1548                             "nothing to diff against.\n",
1549                             "You should be working from a repository ",
1550                             "originally created by git-svn\n";
1551                 }
1552                 if ($fp_a ne $fp_b) {
1553                         die "$c~1 = $fp_a, however parsing commit $c ",
1554                             "revealed that:\n$c~1 = $fp_b\nBUG!\n";
1555                 }
1556
1557                 foreach my $p (@{$parents{$c}}) {
1558                         $skip{$p} = 1;
1559                 }
1560         }
1561         (\@linear_refs, \%parents);
1562 }
1563
1564 sub find_file_type_and_diff_status {
1565         my ($path) = @_;
1566         return ('dir', '') if $path eq '';
1567
1568         my $diff_output =
1569             command_oneline(qw(diff --cached --name-status --), $path) || "";
1570         my $diff_status = (split(' ', $diff_output))[0] || "";
1571
1572         my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
1573
1574         return (undef, undef) if !$diff_status && !$ls_tree;
1575
1576         if ($diff_status eq "A") {
1577                 return ("link", $diff_status) if -l $path;
1578                 return ("dir", $diff_status) if -d $path;
1579                 return ("file", $diff_status);
1580         }
1581
1582         my $mode = (split(' ', $ls_tree))[0] || "";
1583
1584         return ("link", $diff_status) if $mode eq "120000";
1585         return ("dir", $diff_status) if $mode eq "040000";
1586         return ("file", $diff_status);
1587 }
1588
1589 sub md5sum {
1590         my $arg = shift;
1591         my $ref = ref $arg;
1592         my $md5 = Digest::MD5->new();
1593         if ($ref eq 'GLOB' || $ref eq 'IO::File' || $ref eq 'File::Temp') {
1594                 $md5->addfile($arg) or croak $!;
1595         } elsif ($ref eq 'SCALAR') {
1596                 $md5->add($$arg) or croak $!;
1597         } elsif (!$ref) {
1598                 $md5->add($arg) or croak $!;
1599         } else {
1600                 ::fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
1601         }
1602         return $md5->hexdigest();
1603 }
1604
1605 sub gc_directory {
1606         if ($can_compress && -f $_ && basename($_) eq "unhandled.log") {
1607                 my $out_filename = $_ . ".gz";
1608                 open my $in_fh, "<", $_ or die "Unable to open $_: $!\n";
1609                 binmode $in_fh;
1610                 my $gz = Compress::Zlib::gzopen($out_filename, "ab") or
1611                                 die "Unable to open $out_filename: $!\n";
1612
1613                 my $res;
1614                 while ($res = sysread($in_fh, my $str, 1024)) {
1615                         $gz->gzwrite($str) or
1616                                 die "Unable to write: ".$gz->gzerror()."!\n";
1617                 }
1618                 unlink $_ or die "unlink $File::Find::name: $!\n";
1619         } elsif (-f $_ && basename($_) eq "index") {
1620                 unlink $_ or die "unlink $_: $!\n";
1621         }
1622 }
1623
1624 package Git::SVN;
1625 use strict;
1626 use warnings;
1627 use Fcntl qw/:DEFAULT :seek/;
1628 use constant rev_map_fmt => 'NH40';
1629 use vars qw/$default_repo_id $default_ref_id $_no_metadata $_follow_parent
1630             $_repack $_repack_flags $_use_svm_props $_head
1631             $_use_svnsync_props $no_reuse_existing $_minimize_url
1632             $_use_log_author $_add_author_from $_localtime/;
1633 use Carp qw/croak/;
1634 use File::Path qw/mkpath/;
1635 use File::Copy qw/copy/;
1636 use IPC::Open3;
1637
1638 my ($_gc_nr, $_gc_period);
1639
1640 # properties that we do not log:
1641 my %SKIP_PROP;
1642 BEGIN {
1643         %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
1644                                         svn:special svn:executable
1645                                         svn:entry:committed-rev
1646                                         svn:entry:last-author
1647                                         svn:entry:uuid
1648                                         svn:entry:committed-date/;
1649
1650         # some options are read globally, but can be overridden locally
1651         # per [svn-remote "..."] section.  Command-line options will *NOT*
1652         # override options set in an [svn-remote "..."] section
1653         no strict 'refs';
1654         for my $option (qw/follow_parent no_metadata use_svm_props
1655                            use_svnsync_props/) {
1656                 my $key = $option;
1657                 $key =~ tr/_//d;
1658                 my $prop = "-$option";
1659                 *$option = sub {
1660                         my ($self) = @_;
1661                         return $self->{$prop} if exists $self->{$prop};
1662                         my $k = "svn-remote.$self->{repo_id}.$key";
1663                         eval { command_oneline(qw/config --get/, $k) };
1664                         if ($@) {
1665                                 $self->{$prop} = ${"Git::SVN::_$option"};
1666                         } else {
1667                                 my $v = command_oneline(qw/config --bool/,$k);
1668                                 $self->{$prop} = $v eq 'false' ? 0 : 1;
1669                         }
1670                         return $self->{$prop};
1671                 }
1672         }
1673 }
1674
1675
1676 my (%LOCKFILES, %INDEX_FILES);
1677 END {
1678         unlink keys %LOCKFILES if %LOCKFILES;
1679         unlink keys %INDEX_FILES if %INDEX_FILES;
1680 }
1681
1682 sub resolve_local_globs {
1683         my ($url, $fetch, $glob_spec) = @_;
1684         return unless defined $glob_spec;
1685         my $ref = $glob_spec->{ref};
1686         my $path = $glob_spec->{path};
1687         foreach (command(qw#for-each-ref --format=%(refname) refs/#)) {
1688                 next unless m#^$ref->{regex}$#;
1689                 my $p = $1;
1690                 my $pathname = desanitize_refname($path->full_path($p));
1691                 my $refname = desanitize_refname($ref->full_path($p));
1692                 if (my $existing = $fetch->{$pathname}) {
1693                         if ($existing ne $refname) {
1694                                 die "Refspec conflict:\n",
1695                                     "existing: $existing\n",
1696                                     " globbed: $refname\n";
1697                         }
1698                         my $u = (::cmt_metadata("$refname"))[0];
1699                         $u =~ s!^\Q$url\E(/|$)!! or die
1700                           "$refname: '$url' not found in '$u'\n";
1701                         if ($pathname ne $u) {
1702                                 warn "W: Refspec glob conflict ",
1703                                      "(ref: $refname):\n",
1704                                      "expected path: $pathname\n",
1705                                      "    real path: $u\n",
1706                                      "Continuing ahead with $u\n";
1707                                 next;
1708                         }
1709                 } else {
1710                         $fetch->{$pathname} = $refname;
1711                 }
1712         }
1713 }
1714
1715 sub parse_revision_argument {
1716         my ($base, $head) = @_;
1717         if (!defined $::_revision || $::_revision eq 'BASE:HEAD') {
1718                 return ($base, $head);
1719         }
1720         return ($1, $2) if ($::_revision =~ /^(\d+):(\d+)$/);
1721         return ($::_revision, $::_revision) if ($::_revision =~ /^\d+$/);
1722         return ($head, $head) if ($::_revision eq 'HEAD');
1723         return ($base, $1) if ($::_revision =~ /^BASE:(\d+)$/);
1724         return ($1, $head) if ($::_revision =~ /^(\d+):HEAD$/);
1725         die "revision argument: $::_revision not understood by git-svn\n";
1726 }
1727
1728 sub fetch_all {
1729         my ($repo_id, $remotes) = @_;
1730         if (ref $repo_id) {
1731                 my $gs = $repo_id;
1732                 $repo_id = undef;
1733                 $repo_id = $gs->{repo_id};
1734         }
1735         $remotes ||= read_all_remotes();
1736         my $remote = $remotes->{$repo_id} or
1737                      die "[svn-remote \"$repo_id\"] unknown\n";
1738         my $fetch = $remote->{fetch};
1739         my $url = $remote->{url} or die "svn-remote.$repo_id.url not defined\n";
1740         my (@gs, @globs);
1741         my $ra = Git::SVN::Ra->new($url);
1742         my $uuid = $ra->get_uuid;
1743         my $head = $ra->get_latest_revnum;
1744         $ra->get_log("", $head, 0, 1, 0, 1, sub { $head = $_[1] });
1745         my $base = defined $fetch ? $head : 0;
1746
1747         # read the max revs for wildcard expansion (branches/*, tags/*)
1748         foreach my $t (qw/branches tags/) {
1749                 defined $remote->{$t} or next;
1750                 push @globs, @{$remote->{$t}};
1751
1752                 my $max_rev = eval { tmp_config(qw/--int --get/,
1753                                          "svn-remote.$repo_id.${t}-maxRev") };
1754                 if (defined $max_rev && ($max_rev < $base)) {
1755                         $base = $max_rev;
1756                 } elsif (!defined $max_rev) {
1757                         $base = 0;
1758                 }
1759         }
1760
1761         if ($fetch) {
1762                 foreach my $p (sort keys %$fetch) {
1763                         my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
1764                         my $lr = $gs->rev_map_max;
1765                         if (defined $lr) {
1766                                 $base = $lr if ($lr < $base);
1767                         }
1768                         push @gs, $gs;
1769                 }
1770         }
1771
1772         ($base, $head) = parse_revision_argument($base, $head);
1773         $ra->gs_fetch_loop_common($base, $head, \@gs, \@globs);
1774 }
1775
1776 sub read_all_remotes {
1777         my $r = {};
1778         my $use_svm_props = eval { command_oneline(qw/config --bool
1779             svn.useSvmProps/) };
1780         $use_svm_props = $use_svm_props eq 'true' if $use_svm_props;
1781         my $svn_refspec = qr{\s*(.*?)\s*:\s*(.+?)\s*};
1782         foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
1783                 if (m!^(.+)\.fetch=$svn_refspec$!) {
1784                         my ($remote, $local_ref, $remote_ref) = ($1, $2, $3);
1785                         die("svn-remote.$remote: remote ref '$remote_ref' "
1786                             . "must start with 'refs/'\n")
1787                                 unless $remote_ref =~ m{^refs/};
1788                         $r->{$remote}->{fetch}->{$local_ref} = $remote_ref;
1789                         $r->{$remote}->{svm} = {} if $use_svm_props;
1790                 } elsif (m!^(.+)\.usesvmprops=\s*(.*)\s*$!) {
1791                         $r->{$1}->{svm} = {};
1792                 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
1793                         $r->{$1}->{url} = $2;
1794                 } elsif (m!^(.+)\.(branches|tags)=$svn_refspec$!) {
1795                         my ($remote, $t, $local_ref, $remote_ref) =
1796                                                              ($1, $2, $3, $4);
1797                         die("svn-remote.$remote: remote ref '$remote_ref' ($t) "
1798                             . "must start with 'refs/'\n")
1799                                 unless $remote_ref =~ m{^refs/};
1800                         my $rs = {
1801                             t => $t,
1802                             remote => $remote,
1803                             path => Git::SVN::GlobSpec->new($local_ref),
1804                             ref => Git::SVN::GlobSpec->new($remote_ref) };
1805                         if (length($rs->{ref}->{right}) != 0) {
1806                                 die "The '*' glob character must be the last ",
1807                                     "character of '$remote_ref'\n";
1808                         }
1809                         push @{ $r->{$remote}->{$t} }, $rs;
1810                 }
1811         }
1812
1813         map {
1814                 if (defined $r->{$_}->{svm}) {
1815                         my $svm;
1816                         eval {
1817                                 my $section = "svn-remote.$_";
1818                                 $svm = {
1819                                         source => tmp_config('--get',
1820                                             "$section.svm-source"),
1821                                         replace => tmp_config('--get',
1822                                             "$section.svm-replace"),
1823                                 }
1824                         };
1825                         $r->{$_}->{svm} = $svm;
1826                 }
1827         } keys %$r;
1828
1829         $r;
1830 }
1831
1832 sub init_vars {
1833         $_gc_nr = $_gc_period = 1000;
1834         if (defined $_repack || defined $_repack_flags) {
1835                warn "Repack options are obsolete; they have no effect.\n";
1836         }
1837 }
1838
1839 sub verify_remotes_sanity {
1840         return unless -d $ENV{GIT_DIR};
1841         my %seen;
1842         foreach (command(qw/config -l/)) {
1843                 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
1844                         if ($seen{$1}) {
1845                                 die "Remote ref refs/remote/$1 is tracked by",
1846                                     "\n  \"$_\"\nand\n  \"$seen{$1}\"\n",
1847                                     "Please resolve this ambiguity in ",
1848                                     "your git configuration file before ",
1849                                     "continuing\n";
1850                         }
1851                         $seen{$1} = $_;
1852                 }
1853         }
1854 }
1855
1856 sub find_existing_remote {
1857         my ($url, $remotes) = @_;
1858         return undef if $no_reuse_existing;
1859         my $existing;
1860         foreach my $repo_id (keys %$remotes) {
1861                 my $u = $remotes->{$repo_id}->{url} or next;
1862                 next if $u ne $url;
1863                 $existing = $repo_id;
1864                 last;
1865         }
1866         $existing;
1867 }
1868
1869 sub init_remote_config {
1870         my ($self, $url, $no_write) = @_;
1871         $url =~ s!/+$!!; # strip trailing slash
1872         my $r = read_all_remotes();
1873         my $existing = find_existing_remote($url, $r);
1874         if ($existing) {
1875                 unless ($no_write) {
1876                         print STDERR "Using existing ",
1877                                      "[svn-remote \"$existing\"]\n";
1878                 }
1879                 $self->{repo_id} = $existing;
1880         } elsif ($_minimize_url) {
1881                 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
1882                 $existing = find_existing_remote($min_url, $r);
1883                 if ($existing) {
1884                         unless ($no_write) {
1885                                 print STDERR "Using existing ",
1886                                              "[svn-remote \"$existing\"]\n";
1887                         }
1888                         $self->{repo_id} = $existing;
1889                 }
1890                 if ($min_url ne $url) {
1891                         unless ($no_write) {
1892                                 print STDERR "Using higher level of URL: ",
1893                                              "$url => $min_url\n";
1894                         }
1895                         my $old_path = $self->{path};
1896                         $self->{path} = $url;
1897                         $self->{path} =~ s!^\Q$min_url\E(/|$)!!;
1898                         if (length $old_path) {
1899                                 $self->{path} .= "/$old_path";
1900                         }
1901                         $url = $min_url;
1902                 }
1903         }
1904         my $orig_url;
1905         if (!$existing) {
1906                 # verify that we aren't overwriting anything:
1907                 $orig_url = eval {
1908                         command_oneline('config', '--get',
1909                                         "svn-remote.$self->{repo_id}.url")
1910                 };
1911                 if ($orig_url && ($orig_url ne $url)) {
1912                         die "svn-remote.$self->{repo_id}.url already set: ",
1913                             "$orig_url\nwanted to set to: $url\n";
1914                 }
1915         }
1916         my ($xrepo_id, $xpath) = find_ref($self->refname);
1917         if (!$no_write && defined $xpath) {
1918                 die "svn-remote.$xrepo_id.fetch already set to track ",
1919                     "$xpath:", $self->refname, "\n";
1920         }
1921         unless ($no_write) {
1922                 command_noisy('config',
1923                               "svn-remote.$self->{repo_id}.url", $url);
1924                 $self->{path} =~ s{^/}{};
1925                 $self->{path} =~ s{%([0-9A-F]{2})}{chr hex($1)}ieg;
1926                 command_noisy('config', '--add',
1927                               "svn-remote.$self->{repo_id}.fetch",
1928                               "$self->{path}:".$self->refname);
1929         }
1930         $self->{url} = $url;
1931 }
1932
1933 sub find_by_url { # repos_root and, path are optional
1934         my ($class, $full_url, $repos_root, $path) = @_;
1935
1936         return undef unless defined $full_url;
1937         remove_username($full_url);
1938         remove_username($repos_root) if defined $repos_root;
1939         my $remotes = read_all_remotes();
1940         if (defined $full_url && defined $repos_root && !defined $path) {
1941                 $path = $full_url;
1942                 $path =~ s#^\Q$repos_root\E(?:/|$)##;
1943         }
1944         foreach my $repo_id (keys %$remotes) {
1945                 my $u = $remotes->{$repo_id}->{url} or next;
1946                 remove_username($u);
1947                 next if defined $repos_root && $repos_root ne $u;
1948
1949                 my $fetch = $remotes->{$repo_id}->{fetch} || {};
1950                 foreach my $t (qw/branches tags/) {
1951                         foreach my $globspec (@{$remotes->{$repo_id}->{$t}}) {
1952                                 resolve_local_globs($u, $fetch, $globspec);
1953                         }
1954                 }
1955                 my $p = $path;
1956                 my $rwr = rewrite_root({repo_id => $repo_id});
1957                 my $svm = $remotes->{$repo_id}->{svm}
1958                         if defined $remotes->{$repo_id}->{svm};
1959                 unless (defined $p) {
1960                         $p = $full_url;
1961                         my $z = $u;
1962                         my $prefix = '';
1963                         if ($rwr) {
1964                                 $z = $rwr;
1965                                 remove_username($z);
1966                         } elsif (defined $svm) {
1967                                 $z = $svm->{source};
1968                                 $prefix = $svm->{replace};
1969                                 $prefix =~ s#^\Q$u\E(?:/|$)##;
1970                                 $prefix =~ s#/$##;
1971                         }
1972                         $p =~ s#^\Q$z\E(?:/|$)#$prefix# or next;
1973                 }
1974                 foreach my $f (keys %$fetch) {
1975                         next if $f ne $p;
1976                         return Git::SVN->new($fetch->{$f}, $repo_id, $f);
1977                 }
1978         }
1979         undef;
1980 }
1981
1982 sub init {
1983         my ($class, $url, $path, $repo_id, $ref_id, $no_write) = @_;
1984         my $self = _new($class, $repo_id, $ref_id, $path);
1985         if (defined $url) {
1986                 $self->init_remote_config($url, $no_write);
1987         }
1988         $self;
1989 }
1990
1991 sub find_ref {
1992         my ($ref_id) = @_;
1993         foreach (command(qw/config -l/)) {
1994                 next unless m!^svn-remote\.(.+)\.fetch=
1995                               \s*(.*?)\s*:\s*(.+?)\s*$!x;
1996                 my ($repo_id, $path, $ref) = ($1, $2, $3);
1997                 if ($ref eq $ref_id) {
1998                         $path = '' if ($path =~ m#^\./?#);
1999                         return ($repo_id, $path);
2000                 }
2001         }
2002         (undef, undef, undef);
2003 }
2004
2005 sub new {
2006         my ($class, $ref_id, $repo_id, $path) = @_;
2007         if (defined $ref_id && !defined $repo_id && !defined $path) {
2008                 ($repo_id, $path) = find_ref($ref_id);
2009                 if (!defined $repo_id) {
2010                         die "Could not find a \"svn-remote.*.fetch\" key ",
2011                             "in the repository configuration matching: ",
2012                             "$ref_id\n";
2013                 }
2014         }
2015         my $self = _new($class, $repo_id, $ref_id, $path);
2016         if (!defined $self->{path} || !length $self->{path}) {
2017                 my $fetch = command_oneline('config', '--get',
2018                                             "svn-remote.$repo_id.fetch",
2019                                             ":$ref_id\$") or
2020                      die "Failed to read \"svn-remote.$repo_id.fetch\" ",
2021                          "\":$ref_id\$\" in config\n";
2022                 ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
2023         }
2024         $self->{url} = command_oneline('config', '--get',
2025                                        "svn-remote.$repo_id.url") or
2026                   die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
2027         $self->rebuild;
2028         $self;
2029 }
2030
2031 sub refname {
2032         my ($refname) = $_[0]->{ref_id} ;
2033
2034         # It cannot end with a slash /, we'll throw up on this because
2035         # SVN can't have directories with a slash in their name, either:
2036         if ($refname =~ m{/$}) {
2037                 die "ref: '$refname' ends with a trailing slash, this is ",
2038                     "not permitted by git nor Subversion\n";
2039         }
2040
2041         # It cannot have ASCII control character space, tilde ~, caret ^,
2042         # colon :, question-mark ?, asterisk *, space, or open bracket [
2043         # anywhere.
2044         #
2045         # Additionally, % must be escaped because it is used for escaping
2046         # and we want our escaped refname to be reversible
2047         $refname =~ s{([ \%~\^:\?\*\[\t])}{uc sprintf('%%%02x',ord($1))}eg;
2048
2049         # no slash-separated component can begin with a dot .
2050         # /.* becomes /%2E*
2051         $refname =~ s{/\.}{/%2E}g;
2052
2053         # It cannot have two consecutive dots .. anywhere
2054         # .. becomes %2E%2E
2055         $refname =~ s{\.\.}{%2E%2E}g;
2056
2057         return $refname;
2058 }
2059
2060 sub desanitize_refname {
2061         my ($refname) = @_;
2062         $refname =~ s{%(?:([0-9A-F]{2}))}{chr hex($1)}eg;
2063         return $refname;
2064 }
2065
2066 sub svm_uuid {
2067         my ($self) = @_;
2068         return $self->{svm}->{uuid} if $self->svm;
2069         $self->ra;
2070         unless ($self->{svm}) {
2071                 die "SVM UUID not cached, and reading remotely failed\n";
2072         }
2073         $self->{svm}->{uuid};
2074 }
2075
2076 sub svm {
2077         my ($self) = @_;
2078         return $self->{svm} if $self->{svm};
2079         my $svm;
2080         # see if we have it in our config, first:
2081         eval {
2082                 my $section = "svn-remote.$self->{repo_id}";
2083                 $svm = {
2084                   source => tmp_config('--get', "$section.svm-source"),
2085                   uuid => tmp_config('--get', "$section.svm-uuid"),
2086                   replace => tmp_config('--get', "$section.svm-replace"),
2087                 }
2088         };
2089         if ($svm && $svm->{source} && $svm->{uuid} && $svm->{replace}) {
2090                 $self->{svm} = $svm;
2091         }
2092         $self->{svm};
2093 }
2094
2095 sub _set_svm_vars {
2096         my ($self, $ra) = @_;
2097         return $ra if $self->svm;
2098
2099         my @err = ( "useSvmProps set, but failed to read SVM properties\n",
2100                     "(svm:source, svm:uuid) ",
2101                     "from the following URLs:\n" );
2102         sub read_svm_props {
2103                 my ($self, $ra, $path, $r) = @_;
2104                 my $props = ($ra->get_dir($path, $r))[2];
2105                 my $src = $props->{'svm:source'};
2106                 my $uuid = $props->{'svm:uuid'};
2107                 return undef if (!$src || !$uuid);
2108
2109                 chomp($src, $uuid);
2110
2111                 $uuid =~ m{^[0-9a-f\-]{30,}$}i
2112                     or die "doesn't look right - svm:uuid is '$uuid'\n";
2113
2114                 # the '!' is used to mark the repos_root!/relative/path
2115                 $src =~ s{/?!/?}{/};
2116                 $src =~ s{/+$}{}; # no trailing slashes please
2117                 # username is of no interest
2118                 $src =~ s{(^[a-z\+]*://)[^/@]*@}{$1};
2119
2120                 my $replace = $ra->{url};
2121                 $replace .= "/$path" if length $path;
2122
2123                 my $section = "svn-remote.$self->{repo_id}";
2124                 tmp_config("$section.svm-source", $src);
2125                 tmp_config("$section.svm-replace", $replace);
2126                 tmp_config("$section.svm-uuid", $uuid);
2127                 $self->{svm} = {
2128                         source => $src,
2129                         uuid => $uuid,
2130                         replace => $replace
2131                 };
2132         }
2133
2134         my $r = $ra->get_latest_revnum;
2135         my $path = $self->{path};
2136         my %tried;
2137         while (length $path) {
2138                 unless ($tried{"$self->{url}/$path"}) {
2139                         return $ra if $self->read_svm_props($ra, $path, $r);
2140                         $tried{"$self->{url}/$path"} = 1;
2141                 }
2142                 $path =~ s#/?[^/]+$##;
2143         }
2144         die "Path: '$path' should be ''\n" if $path ne '';
2145         return $ra if $self->read_svm_props($ra, $path, $r);
2146         $tried{"$self->{url}/$path"} = 1;
2147
2148         if ($ra->{repos_root} eq $self->{url}) {
2149                 die @err, (map { "  $_\n" } keys %tried), "\n";
2150         }
2151
2152         # nope, make sure we're connected to the repository root:
2153         my $ok;
2154         my @tried_b;
2155         $path = $ra->{svn_path};
2156         $ra = Git::SVN::Ra->new($ra->{repos_root});
2157         while (length $path) {
2158                 unless ($tried{"$ra->{url}/$path"}) {
2159                         $ok = $self->read_svm_props($ra, $path, $r);
2160                         last if $ok;
2161                         $tried{"$ra->{url}/$path"} = 1;
2162                 }
2163                 $path =~ s#/?[^/]+$##;
2164         }
2165         die "Path: '$path' should be ''\n" if $path ne '';
2166         $ok ||= $self->read_svm_props($ra, $path, $r);
2167         $tried{"$ra->{url}/$path"} = 1;
2168         if (!$ok) {
2169                 die @err, (map { "  $_\n" } keys %tried), "\n";
2170         }
2171         Git::SVN::Ra->new($self->{url});
2172 }
2173
2174 sub svnsync {
2175         my ($self) = @_;
2176         return $self->{svnsync} if $self->{svnsync};
2177
2178         if ($self->no_metadata) {
2179                 die "Can't have both 'noMetadata' and ",
2180                     "'useSvnsyncProps' options set!\n";
2181         }
2182         if ($self->rewrite_root) {
2183                 die "Can't have both 'useSvnsyncProps' and 'rewriteRoot' ",
2184                     "options set!\n";
2185         }
2186
2187         my $svnsync;
2188         # see if we have it in our config, first:
2189         eval {
2190                 my $section = "svn-remote.$self->{repo_id}";
2191
2192                 my $url = tmp_config('--get', "$section.svnsync-url");
2193                 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
2194                    die "doesn't look right - svn:sync-from-url is '$url'\n";
2195
2196                 my $uuid = tmp_config('--get', "$section.svnsync-uuid");
2197                 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}i) or
2198                    die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
2199
2200                 $svnsync = { url => $url, uuid => $uuid }
2201         };
2202         if ($svnsync && $svnsync->{url} && $svnsync->{uuid}) {
2203                 return $self->{svnsync} = $svnsync;
2204         }
2205
2206         my $err = "useSvnsyncProps set, but failed to read " .
2207                   "svnsync property: svn:sync-from-";
2208         my $rp = $self->ra->rev_proplist(0);
2209
2210         my $url = $rp->{'svn:sync-from-url'} or die $err . "url\n";
2211         ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
2212                    die "doesn't look right - svn:sync-from-url is '$url'\n";
2213
2214         my $uuid = $rp->{'svn:sync-from-uuid'} or die $err . "uuid\n";
2215         ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}i) or
2216                    die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
2217
2218         my $section = "svn-remote.$self->{repo_id}";
2219         tmp_config('--add', "$section.svnsync-uuid", $uuid);
2220         tmp_config('--add', "$section.svnsync-url", $url);
2221         return $self->{svnsync} = { url => $url, uuid => $uuid };
2222 }
2223
2224 # this allows us to memoize our SVN::Ra UUID locally and avoid a
2225 # remote lookup (useful for 'git svn log').
2226 sub ra_uuid {
2227         my ($self) = @_;
2228         unless ($self->{ra_uuid}) {
2229                 my $key = "svn-remote.$self->{repo_id}.uuid";
2230                 my $uuid = eval { tmp_config('--get', $key) };
2231                 if (!$@ && $uuid && $uuid =~ /^([a-f\d\-]{30,})$/i) {
2232                         $self->{ra_uuid} = $uuid;
2233                 } else {
2234                         die "ra_uuid called without URL\n" unless $self->{url};
2235                         $self->{ra_uuid} = $self->ra->get_uuid;
2236                         tmp_config('--add', $key, $self->{ra_uuid});
2237                 }
2238         }
2239         $self->{ra_uuid};
2240 }
2241
2242 sub _set_repos_root {
2243         my ($self, $repos_root) = @_;
2244         my $k = "svn-remote.$self->{repo_id}.reposRoot";
2245         $repos_root ||= $self->ra->{repos_root};
2246         tmp_config($k, $repos_root);
2247         $repos_root;
2248 }
2249
2250 sub repos_root {
2251         my ($self) = @_;
2252         my $k = "svn-remote.$self->{repo_id}.reposRoot";
2253         eval { tmp_config('--get', $k) } || $self->_set_repos_root;
2254 }
2255
2256 sub ra {
2257         my ($self) = shift;
2258         my $ra = Git::SVN::Ra->new($self->{url});
2259         $self->_set_repos_root($ra->{repos_root});
2260         if ($self->use_svm_props && !$self->{svm}) {
2261                 if ($self->no_metadata) {
2262                         die "Can't have both 'noMetadata' and ",
2263                             "'useSvmProps' options set!\n";
2264                 } elsif ($self->use_svnsync_props) {
2265                         die "Can't have both 'useSvnsyncProps' and ",
2266                             "'useSvmProps' options set!\n";
2267                 }
2268                 $ra = $self->_set_svm_vars($ra);
2269                 $self->{-want_revprops} = 1;
2270         }
2271         $ra;
2272 }
2273
2274 # prop_walk(PATH, REV, SUB)
2275 # -------------------------
2276 # Recursively traverse PATH at revision REV and invoke SUB for each
2277 # directory that contains a SVN property.  SUB will be invoked as
2278 # follows:  &SUB(gs, path, props);  where `gs' is this instance of
2279 # Git::SVN, `path' the path to the directory where the properties
2280 # `props' were found.  The `path' will be relative to point of checkout,
2281 # that is, if url://repo/trunk is the current Git branch, and that
2282 # directory contains a sub-directory `d', SUB will be invoked with `/d/'
2283 # as `path' (note the trailing `/').
2284 sub prop_walk {
2285         my ($self, $path, $rev, $sub) = @_;
2286
2287         $path =~ s#^/##;
2288         my ($dirent, undef, $props) = $self->ra->get_dir($path, $rev);
2289         $path =~ s#^/*#/#g;
2290         my $p = $path;
2291         # Strip the irrelevant part of the path.
2292         $p =~ s#^/+\Q$self->{path}\E(/|$)#/#;
2293         # Ensure the path is terminated by a `/'.
2294         $p =~ s#/*$#/#;
2295
2296         # The properties contain all the internal SVN stuff nobody
2297         # (usually) cares about.
2298         my $interesting_props = 0;
2299         foreach (keys %{$props}) {
2300                 # If it doesn't start with `svn:', it must be a
2301                 # user-defined property.
2302                 ++$interesting_props and next if $_ !~ /^svn:/;
2303                 # FIXME: Fragile, if SVN adds new public properties,
2304                 # this needs to be updated.
2305                 ++$interesting_props if /^svn:(?:ignore|keywords|executable
2306                                                  |eol-style|mime-type
2307                                                  |externals|needs-lock)$/x;
2308         }
2309         &$sub($self, $p, $props) if $interesting_props;
2310
2311         foreach (sort keys %$dirent) {
2312                 next if $dirent->{$_}->{kind} != $SVN::Node::dir;
2313                 $self->prop_walk($self->{path} . $p . $_, $rev, $sub);
2314         }
2315 }
2316
2317 sub last_rev { ($_[0]->last_rev_commit)[0] }
2318 sub last_commit { ($_[0]->last_rev_commit)[1] }
2319
2320 # returns the newest SVN revision number and newest commit SHA1
2321 sub last_rev_commit {
2322         my ($self) = @_;
2323         if (defined $self->{last_rev} && defined $self->{last_commit}) {
2324                 return ($self->{last_rev}, $self->{last_commit});
2325         }
2326         my $c = ::verify_ref($self->refname.'^0');
2327         if ($c && !$self->use_svm_props && !$self->no_metadata) {
2328                 my $rev = (::cmt_metadata($c))[1];
2329                 if (defined $rev) {
2330                         ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
2331                         return ($rev, $c);
2332                 }
2333         }
2334         my $map_path = $self->map_path;
2335         unless (-e $map_path) {
2336                 ($self->{last_rev}, $self->{last_commit}) = (undef, undef);
2337                 return (undef, undef);
2338         }
2339         my ($rev, $commit) = $self->rev_map_max(1);
2340         ($self->{last_rev}, $self->{last_commit}) = ($rev, $commit);
2341         return ($rev, $commit);
2342 }
2343
2344 sub get_fetch_range {
2345         my ($self, $min, $max) = @_;
2346         $max ||= $self->ra->get_latest_revnum;
2347         $min ||= $self->rev_map_max;
2348         (++$min, $max);
2349 }
2350
2351 sub tmp_config {
2352         my (@args) = @_;
2353         my $old_def_config = "$ENV{GIT_DIR}/svn/config";
2354         my $config = "$ENV{GIT_DIR}/svn/.metadata";
2355         if (! -f $config && -f $old_def_config) {
2356                 rename $old_def_config, $config or
2357                        die "Failed rename $old_def_config => $config: $!\n";
2358         }
2359         my $old_config = $ENV{GIT_CONFIG};
2360         $ENV{GIT_CONFIG} = $config;
2361         $@ = undef;
2362         my @ret = eval {
2363                 unless (-f $config) {
2364                         mkfile($config);
2365                         open my $fh, '>', $config or
2366                             die "Can't open $config: $!\n";
2367                         print $fh "; This file is used internally by ",
2368                                   "git-svn\n" or die
2369                                   "Couldn't write to $config: $!\n";
2370                         print $fh "; You should not have to edit it\n" or
2371                               die "Couldn't write to $config: $!\n";
2372                         close $fh or die "Couldn't close $config: $!\n";
2373                 }
2374                 command('config', @args);
2375         };
2376         my $err = $@;
2377         if (defined $old_config) {
2378                 $ENV{GIT_CONFIG} = $old_config;
2379         } else {
2380                 delete $ENV{GIT_CONFIG};
2381         }
2382         die $err if $err;
2383         wantarray ? @ret : $ret[0];
2384 }
2385
2386 sub tmp_index_do {
2387         my ($self, $sub) = @_;
2388         my $old_index = $ENV{GIT_INDEX_FILE};
2389         $ENV{GIT_INDEX_FILE} = $self->{index};
2390         $@ = undef;
2391         my @ret = eval {
2392                 my ($dir, $base) = ($self->{index} =~ m#^(.*?)/?([^/]+)$#);
2393                 mkpath([$dir]) unless -d $dir;
2394                 &$sub;
2395         };
2396         my $err = $@;
2397         if (defined $old_index) {
2398                 $ENV{GIT_INDEX_FILE} = $old_index;
2399         } else {
2400                 delete $ENV{GIT_INDEX_FILE};
2401         }
2402         die $err if $err;
2403         wantarray ? @ret : $ret[0];
2404 }
2405
2406 sub assert_index_clean {
2407         my ($self, $treeish) = @_;
2408
2409         $self->tmp_index_do(sub {
2410                 command_noisy('read-tree', $treeish) unless -e $self->{index};
2411                 my $x = command_oneline('write-tree');
2412                 my ($y) = (command(qw/cat-file commit/, $treeish) =~
2413                            /^tree ($::sha1)/mo);
2414                 return if $y eq $x;
2415
2416                 warn "Index mismatch: $y != $x\nrereading $treeish\n";
2417                 unlink $self->{index} or die "unlink $self->{index}: $!\n";
2418                 command_noisy('read-tree', $treeish);
2419                 $x = command_oneline('write-tree');
2420                 if ($y ne $x) {
2421                         ::fatal "trees ($treeish) $y != $x\n",
2422                                 "Something is seriously wrong...";
2423                 }
2424         });
2425 }
2426
2427 sub get_commit_parents {
2428         my ($self, $log_entry) = @_;
2429         my (%seen, @ret, @tmp);
2430         # legacy support for 'set-tree'; this is only used by set_tree_cb:
2431         if (my $ip = $self->{inject_parents}) {
2432                 if (my $commit = delete $ip->{$log_entry->{revision}}) {
2433                         push @tmp, $commit;
2434                 }
2435         }
2436         if (my $cur = ::verify_ref($self->refname.'^0')) {
2437                 push @tmp, $cur;
2438         }
2439         if (my $ipd = $self->{inject_parents_dcommit}) {
2440                 if (my $commit = delete $ipd->{$log_entry->{revision}}) {
2441                         push @tmp, @$commit;
2442                 }
2443         }
2444         push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
2445         while (my $p = shift @tmp) {
2446                 next if $seen{$p};
2447                 $seen{$p} = 1;
2448                 push @ret, $p;
2449                 # MAXPARENT is defined to 16 in commit-tree.c:
2450                 last if @ret >= 16;
2451         }
2452         if (@tmp) {
2453                 die "r$log_entry->{revision}: No room for parents:\n\t",
2454                     join("\n\t", @tmp), "\n";
2455         }
2456         @ret;
2457 }
2458
2459 sub rewrite_root {
2460         my ($self) = @_;
2461         return $self->{-rewrite_root} if exists $self->{-rewrite_root};
2462         my $k = "svn-remote.$self->{repo_id}.rewriteRoot";
2463         my $rwr = eval { command_oneline(qw/config --get/, $k) };
2464         if ($rwr) {
2465                 $rwr =~ s#/+$##;
2466                 if ($rwr !~ m#^[a-z\+]+://#) {
2467                         die "$rwr is not a valid URL (key: $k)\n";
2468                 }
2469         }
2470         $self->{-rewrite_root} = $rwr;
2471 }
2472
2473 sub metadata_url {
2474         my ($self) = @_;
2475         ($self->rewrite_root || $self->{url}) .
2476            (length $self->{path} ? '/' . $self->{path} : '');
2477 }
2478
2479 sub full_url {
2480         my ($self) = @_;
2481         $self->{url} . (length $self->{path} ? '/' . $self->{path} : '');
2482 }
2483
2484
2485 sub set_commit_header_env {
2486         my ($log_entry) = @_;
2487         my %env;
2488         foreach my $ned (qw/NAME EMAIL DATE/) {
2489                 foreach my $ac (qw/AUTHOR COMMITTER/) {
2490                         $env{"GIT_${ac}_${ned}"} = $ENV{"GIT_${ac}_${ned}"};
2491                 }
2492         }
2493
2494         $ENV{GIT_AUTHOR_NAME} = $log_entry->{name};
2495         $ENV{GIT_AUTHOR_EMAIL} = $log_entry->{email};
2496         $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
2497
2498         $ENV{GIT_COMMITTER_NAME} = (defined $log_entry->{commit_name})
2499                                                 ? $log_entry->{commit_name}
2500                                                 : $log_entry->{name};
2501         $ENV{GIT_COMMITTER_EMAIL} = (defined $log_entry->{commit_email})
2502                                                 ? $log_entry->{commit_email}
2503                                                 : $log_entry->{email};
2504         \%env;
2505 }
2506
2507 sub restore_commit_header_env {
2508         my ($env) = @_;
2509         foreach my $ned (qw/NAME EMAIL DATE/) {
2510                 foreach my $ac (qw/AUTHOR COMMITTER/) {
2511                         my $k = "GIT_${ac}_${ned}";
2512                         if (defined $env->{$k}) {
2513                                 $ENV{$k} = $env->{$k};
2514                         } else {
2515                                 delete $ENV{$k};
2516                         }
2517                 }
2518         }
2519 }
2520
2521 sub gc {
2522         command_noisy('gc', '--auto');
2523 };
2524
2525 sub do_git_commit {
2526         my ($self, $log_entry) = @_;
2527         my $lr = $self->last_rev;
2528         if (defined $lr && $lr >= $log_entry->{revision}) {
2529                 die "Last fetched revision of ", $self->refname,
2530                     " was r$lr, but we are about to fetch: ",
2531                     "r$log_entry->{revision}!\n";
2532         }
2533         if (my $c = $self->rev_map_get($log_entry->{revision})) {
2534                 croak "$log_entry->{revision} = $c already exists! ",
2535                       "Why are we refetching it?\n";
2536         }
2537         my $old_env = set_commit_header_env($log_entry);
2538         my $tree = $log_entry->{tree};
2539         if (!defined $tree) {
2540                 $tree = $self->tmp_index_do(sub {
2541                                             command_oneline('write-tree') });
2542         }
2543         die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
2544
2545         my @exec = ('git', 'commit-tree', $tree);
2546         foreach ($self->get_commit_parents($log_entry)) {
2547                 push @exec, '-p', $_;
2548         }
2549         defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
2550                                                                    or croak $!;
2551         binmode $msg_fh;
2552
2553         # we always get UTF-8 from SVN, but we may want our commits in
2554         # a different encoding.
2555         if (my $enc = Git::config('i18n.commitencoding')) {
2556                 require Encode;
2557                 Encode::from_to($log_entry->{log}, 'UTF-8', $enc);
2558         }
2559         print $msg_fh $log_entry->{log} or croak $!;
2560         restore_commit_header_env($old_env);
2561         unless ($self->no_metadata) {
2562                 print $msg_fh "\ngit-svn-id: $log_entry->{metadata}\n"
2563                               or croak $!;
2564         }
2565         $msg_fh->flush == 0 or croak $!;
2566         close $msg_fh or croak $!;
2567         chomp(my $commit = do { local $/; <$out_fh> });
2568         close $out_fh or croak $!;
2569         waitpid $pid, 0;
2570         croak $? if $?;
2571         if ($commit !~ /^$::sha1$/o) {
2572                 die "Failed to commit, invalid sha1: $commit\n";
2573         }
2574
2575         $self->rev_map_set($log_entry->{revision}, $commit, 1);
2576
2577         $self->{last_rev} = $log_entry->{revision};
2578         $self->{last_commit} = $commit;
2579         print "r$log_entry->{revision}" unless $::_q > 1;
2580         if (defined $log_entry->{svm_revision}) {
2581                  print " (\@$log_entry->{svm_revision})" unless $::_q > 1;
2582                  $self->rev_map_set($log_entry->{svm_revision}, $commit,
2583                                    0, $self->svm_uuid);
2584         }
2585         print " = $commit ($self->{ref_id})\n" unless $::_q > 1;
2586         if (--$_gc_nr == 0) {
2587                 $_gc_nr = $_gc_period;
2588                 gc();
2589         }
2590         return $commit;
2591 }
2592
2593 sub match_paths {
2594         my ($self, $paths, $r) = @_;
2595         return 1 if $self->{path} eq '';
2596         if (my $path = $paths->{"/$self->{path}"}) {
2597                 return ($path->{action} eq 'D') ? 0 : 1;
2598         }
2599         $self->{path_regex} ||= qr/^\/\Q$self->{path}\E\//;
2600         if (grep /$self->{path_regex}/, keys %$paths) {
2601                 return 1;
2602         }
2603         my $c = '';
2604         foreach (split m#/#, $self->{path}) {
2605                 $c .= "/$_";
2606                 next unless ($paths->{$c} &&
2607                              ($paths->{$c}->{action} =~ /^[AR]$/));
2608                 if ($self->ra->check_path($self->{path}, $r) ==
2609                     $SVN::Node::dir) {
2610                         return 1;
2611                 }
2612         }
2613         return 0;
2614 }
2615
2616 sub find_parent_branch {
2617         my ($self, $paths, $rev) = @_;
2618         return undef unless $self->follow_parent;
2619         unless (defined $paths) {
2620                 my $err_handler = $SVN::Error::handler;
2621                 $SVN::Error::handler = \&Git::SVN::Ra::skip_unknown_revs;
2622                 $self->ra->get_log([$self->{path}], $rev, $rev, 0, 1, 1,
2623                                    sub { $paths = $_[0] });
2624                 $SVN::Error::handler = $err_handler;
2625         }
2626         return undef unless defined $paths;
2627
2628         # look for a parent from another branch:
2629         my @b_path_components = split m#/#, $self->{path};
2630         my @a_path_components;
2631         my $i;
2632         while (@b_path_components) {
2633                 $i = $paths->{'/'.join('/', @b_path_components)};
2634                 last if $i && defined $i->{copyfrom_path};
2635                 unshift(@a_path_components, pop(@b_path_components));
2636         }
2637         return undef unless defined $i && defined $i->{copyfrom_path};
2638         my $branch_from = $i->{copyfrom_path};
2639         if (@a_path_components) {
2640                 print STDERR "branch_from: $branch_from => ";
2641                 $branch_from .= '/'.join('/', @a_path_components);
2642                 print STDERR $branch_from, "\n";
2643         }
2644         my $r = $i->{copyfrom_rev};
2645         my $repos_root = $self->ra->{repos_root};
2646         my $url = $self->ra->{url};
2647         my $new_url = $url . $branch_from;
2648         print STDERR  "Found possible branch point: ",
2649                       "$new_url => ", $self->full_url, ", $r\n"
2650                       unless $::_q > 1;
2651         $branch_from =~ s#^/##;
2652         my $gs = $self->other_gs($new_url, $url,
2653                                  $branch_from, $r, $self->{ref_id});
2654         my ($r0, $parent) = $gs->find_rev_before($r, 1);
2655         {
2656                 my ($base, $head);
2657                 if (!defined $r0 || !defined $parent) {
2658                         ($base, $head) = parse_revision_argument(0, $r);
2659                 } else {
2660                         if ($r0 < $r) {
2661                                 $gs->ra->get_log([$gs->{path}], $r0 + 1, $r, 1,
2662                                         0, 1, sub { $base = $_[1] - 1 });
2663                         }
2664                 }
2665                 if (defined $base && $base <= $r) {
2666                         $gs->fetch($base, $r);
2667                 }
2668                 ($r0, $parent) = $gs->find_rev_before($r, 1);
2669         }
2670         if (defined $r0 && defined $parent) {
2671                 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n"
2672                              unless $::_q > 1;
2673                 my $ed;
2674                 if ($self->ra->can_do_switch) {
2675                         $self->assert_index_clean($parent);
2676                         print STDERR "Following parent with do_switch\n"
2677                                      unless $::_q > 1;
2678                         # do_switch works with svn/trunk >= r22312, but that
2679                         # is not included with SVN 1.4.3 (the latest version
2680                         # at the moment), so we can't rely on it
2681                         $self->{last_rev} = $r0;
2682                         $self->{last_commit} = $parent;
2683                         $ed = SVN::Git::Fetcher->new($self, $gs->{path});
2684                         $gs->ra->gs_do_switch($r0, $rev, $gs,
2685                                               $self->full_url, $ed)
2686                           or die "SVN connection failed somewhere...\n";
2687                 } elsif ($self->ra->trees_match($new_url, $r0,
2688                                                 $self->full_url, $rev)) {
2689                         print STDERR "Trees match:\n",
2690                                      "  $new_url\@$r0\n",
2691                                      "  ${\$self->full_url}\@$rev\n",
2692                                      "Following parent with no changes\n"
2693                                      unless $::_q > 1;
2694                         $self->tmp_index_do(sub {
2695                             command_noisy('read-tree', $parent);
2696                         });
2697                         $self->{last_commit} = $parent;
2698                 } else {
2699                         print STDERR "Following parent with do_update\n"
2700                                      unless $::_q > 1;
2701                         $ed = SVN::Git::Fetcher->new($self);
2702                         $self->ra->gs_do_update($rev, $rev, $self, $ed)
2703                           or die "SVN connection failed somewhere...\n";
2704                 }
2705                 print STDERR "Successfully followed parent\n" unless $::_q > 1;
2706                 return $self->make_log_entry($rev, [$parent], $ed);
2707         }
2708         return undef;
2709 }
2710
2711 sub do_fetch {
2712         my ($self, $paths, $rev) = @_;
2713         my $ed;
2714         my ($last_rev, @parents);
2715         if (my $lc = $self->last_commit) {
2716                 # we can have a branch that was deleted, then re-added
2717                 # under the same name but copied from another path, in
2718                 # which case we'll have multiple parents (we don't
2719                 # want to break the original ref, nor lose copypath info):
2720                 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2721                         push @{$log_entry->{parents}}, $lc;
2722                         return $log_entry;
2723                 }
2724                 $ed = SVN::Git::Fetcher->new($self);
2725                 $last_rev = $self->{last_rev};
2726                 $ed->{c} = $lc;
2727                 @parents = ($lc);
2728         } else {
2729                 $last_rev = $rev;
2730                 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2731                         return $log_entry;
2732                 }
2733                 $ed = SVN::Git::Fetcher->new($self);
2734         }
2735         unless ($self->ra->gs_do_update($last_rev, $rev, $self, $ed)) {
2736                 die "SVN connection failed somewhere...\n";
2737         }
2738         $self->make_log_entry($rev, \@parents, $ed);
2739 }
2740
2741 sub mkemptydirs {
2742         my ($self, $r) = @_;
2743
2744         sub scan {
2745                 my ($r, $empty_dirs, $line) = @_;
2746                 if (defined $r && $line =~ /^r(\d+)$/) {
2747                         return 0 if $1 > $r;
2748                 } elsif ($line =~ /^  \+empty_dir: (.+)$/) {
2749                         $empty_dirs->{$1} = 1;
2750                 } elsif ($line =~ /^  \-empty_dir: (.+)$/) {
2751                         my @d = grep {m[^\Q$1\E(/|$)]} (keys %$empty_dirs);
2752                         delete @$empty_dirs{@d};
2753                 }
2754                 1; # continue
2755         };
2756
2757         my %empty_dirs = ();
2758         my $gz_file = "$self->{dir}/unhandled.log.gz";
2759         if (-f $gz_file) {
2760                 if (!$can_compress) {
2761                         warn "Compress::Zlib could not be found; ",
2762                              "empty directories in $gz_file will not be read\n";
2763                 } else {
2764                         my $gz = Compress::Zlib::gzopen($gz_file, "rb") or
2765                                 die "Unable to open $gz_file: $!\n";
2766                         my $line;
2767                         while ($gz->gzreadline($line) > 0) {
2768                                 scan($r, \%empty_dirs, $line) or last;
2769                         }
2770                         $gz->gzclose;
2771                 }
2772         }
2773
2774         if (open my $fh, '<', "$self->{dir}/unhandled.log") {
2775                 binmode $fh or croak "binmode: $!";
2776                 while (<$fh>) {
2777                         scan($r, \%empty_dirs, $_) or last;
2778                 }
2779                 close $fh;
2780         }
2781
2782         my $strip = qr/\A\Q$self->{path}\E(?:\/|$)/;
2783         foreach my $d (sort keys %empty_dirs) {
2784                 $d = uri_decode($d);
2785                 $d =~ s/$strip//;
2786                 next if -d $d;
2787                 if (-e _) {
2788                         warn "$d exists but is not a directory\n";
2789                 } else {
2790                         print "creating empty directory: $d\n";
2791                         mkpath([$d]);
2792                 }
2793         }
2794 }
2795
2796 sub get_untracked {
2797         my ($self, $ed) = @_;
2798         my @out;
2799         my $h = $ed->{empty};
2800         foreach (sort keys %$h) {
2801                 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
2802                 push @out, "  $act: " . uri_encode($_);
2803                 warn "W: $act: $_\n";
2804         }
2805         foreach my $t (qw/dir_prop file_prop/) {
2806                 $h = $ed->{$t} or next;
2807                 foreach my $path (sort keys %$h) {
2808                         my $ppath = $path eq '' ? '.' : $path;
2809                         foreach my $prop (sort keys %{$h->{$path}}) {
2810                                 next if $SKIP_PROP{$prop};
2811                                 my $v = $h->{$path}->{$prop};
2812                                 my $t_ppath_prop = "$t: " .
2813                                                     uri_encode($ppath) . ' ' .
2814                                                     uri_encode($prop);
2815                                 if (defined $v) {
2816                                         push @out, "  +$t_ppath_prop " .
2817                                                    uri_encode($v);
2818                                 } else {
2819                                         push @out, "  -$t_ppath_prop";
2820                                 }
2821                         }
2822                 }
2823         }
2824         foreach my $t (qw/absent_file absent_directory/) {
2825                 $h = $ed->{$t} or next;
2826                 foreach my $parent (sort keys %$h) {
2827                         foreach my $path (sort @{$h->{$parent}}) {
2828                                 push @out, "  $t: " .
2829                                            uri_encode("$parent/$path");
2830                                 warn "W: $t: $parent/$path ",
2831                                      "Insufficient permissions?\n";
2832                         }
2833                 }
2834         }
2835         \@out;
2836 }
2837
2838 # parse_svn_date(DATE)
2839 # --------------------
2840 # Given a date (in UTC) from Subversion, return a string in the format
2841 # "<TZ Offset> <local date/time>" that Git will use.
2842 #
2843 # By default the parsed date will be in UTC; if $Git::SVN::_localtime
2844 # is true we'll convert it to the local timezone instead.
2845 sub parse_svn_date {
2846         my $date = shift || return '+0000 1970-01-01 00:00:00';
2847         my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
2848                                             (\d\d)\:(\d\d)\:(\d\d)\.\d*Z$/x) or
2849                                          croak "Unable to parse date: $date\n";
2850         my $parsed_date;    # Set next.
2851
2852         if ($Git::SVN::_localtime) {
2853                 # Translate the Subversion datetime to an epoch time.
2854                 # Begin by switching ourselves to $date's timezone, UTC.
2855                 my $old_env_TZ = $ENV{TZ};
2856                 $ENV{TZ} = 'UTC';
2857
2858                 my $epoch_in_UTC =
2859                     POSIX::strftime('%s', $S, $M, $H, $d, $m - 1, $Y - 1900);
2860
2861                 # Determine our local timezone (including DST) at the
2862                 # time of $epoch_in_UTC.  $Git::SVN::Log::TZ stored the
2863                 # value of TZ, if any, at the time we were run.
2864                 if (defined $Git::SVN::Log::TZ) {
2865                         $ENV{TZ} = $Git::SVN::Log::TZ;
2866                 } else {
2867                         delete $ENV{TZ};
2868                 }
2869
2870                 my $our_TZ =
2871                     POSIX::strftime('%Z', $S, $M, $H, $d, $m - 1, $Y - 1900);
2872
2873                 # This converts $epoch_in_UTC into our local timezone.
2874                 my ($sec, $min, $hour, $mday, $mon, $year,
2875                     $wday, $yday, $isdst) = localtime($epoch_in_UTC);
2876
2877                 $parsed_date = sprintf('%s %04d-%02d-%02d %02d:%02d:%02d',
2878                                        $our_TZ, $year + 1900, $mon + 1,
2879                                        $mday, $hour, $min, $sec);
2880
2881                 # Reset us to the timezone in effect when we entered
2882                 # this routine.
2883                 if (defined $old_env_TZ) {
2884                         $ENV{TZ} = $old_env_TZ;
2885                 } else {
2886                         delete $ENV{TZ};
2887                 }
2888         } else {
2889                 $parsed_date = "+0000 $Y-$m-$d $H:$M:$S";
2890         }
2891
2892         return $parsed_date;
2893 }
2894
2895 sub other_gs {
2896         my ($self, $new_url, $url,
2897             $branch_from, $r, $old_ref_id) = @_;
2898         my $gs = Git::SVN->find_by_url($new_url, $url, $branch_from);
2899         unless ($gs) {
2900                 my $ref_id = $old_ref_id;
2901                 $ref_id =~ s/\@\d+$//;
2902                 $ref_id .= "\@$r";
2903                 # just grow a tail if we're not unique enough :x
2904                 $ref_id .= '-' while find_ref($ref_id);
2905                 print STDERR "Initializing parent: $ref_id\n" unless $::_q > 1;
2906                 my ($u, $p, $repo_id) = ($new_url, '', $ref_id);
2907                 if ($u =~ s#^\Q$url\E(/|$)##) {
2908                         $p = $u;
2909                         $u = $url;
2910                         $repo_id = $self->{repo_id};
2911                 }
2912                 $gs = Git::SVN->init($u, $p, $repo_id, $ref_id, 1);
2913         }
2914         $gs
2915 }
2916
2917 sub call_authors_prog {
2918         my ($orig_author) = @_;
2919         $orig_author = command_oneline('rev-parse', '--sq-quote', $orig_author);
2920         my $author = `$::_authors_prog $orig_author`;
2921         if ($? != 0) {
2922                 die "$::_authors_prog failed with exit code $?\n"
2923         }
2924         if ($author =~ /^\s*(.+?)\s*<(.*)>\s*$/) {
2925                 my ($name, $email) = ($1, $2);
2926                 $email = undef if length $2 == 0;
2927                 return [$name, $email];
2928         } else {
2929                 die "Author: $orig_author: $::_authors_prog returned "
2930                         . "invalid author format: $author\n";
2931         }
2932 }
2933
2934 sub check_author {
2935         my ($author) = @_;
2936         if (!defined $author || length $author == 0) {
2937                 $author = '(no author)';
2938         }
2939         if (!defined $::users{$author}) {
2940                 if (defined $::_authors_prog) {
2941                         $::users{$author} = call_authors_prog($author);
2942                 } elsif (defined $::_authors) {
2943                         die "Author: $author not defined in $::_authors file\n";
2944                 }
2945         }
2946         $author;
2947 }
2948
2949 sub find_extra_svk_parents {
2950         my ($self, $ed, $tickets, $parents) = @_;
2951         # aha!  svk:merge property changed...
2952         my @tickets = split "\n", $tickets;
2953         my @known_parents;
2954         for my $ticket ( @tickets ) {
2955                 my ($uuid, $path, $rev) = split /:/, $ticket;
2956                 if ( $uuid eq $self->ra_uuid ) {
2957                         my $url = $self->rewrite_root || $self->{url};
2958                         my $repos_root = $url;
2959                         my $branch_from = $path;
2960                         $branch_from =~ s{^/}{};
2961                         my $gs = $self->other_gs($repos_root."/".$branch_from,
2962                                                  $url,
2963                                                  $branch_from,
2964                                                  $rev,
2965                                                  $self->{ref_id});
2966                         if ( my $commit = $gs->rev_map_get($rev, $uuid) ) {
2967                                 # wahey!  we found it, but it might be
2968                                 # an old one (!)
2969                                 push @known_parents, [ $rev, $commit ];
2970                         }
2971                 }
2972         }
2973         # Ordering matters; highest-numbered commit merge tickets
2974         # first, as they may account for later merge ticket additions
2975         # or changes.
2976         @known_parents = map {$_->[1]} sort {$b->[0] <=> $a->[0]} @known_parents;
2977         for my $parent ( @known_parents ) {
2978                 my @cmd = ('rev-list', $parent, map { "^$_" } @$parents );
2979                 my ($msg_fh, $ctx) = command_output_pipe(@cmd);
2980                 my $new;
2981                 while ( <$msg_fh> ) {
2982                         $new=1;last;
2983                 }
2984                 command_close_pipe($msg_fh, $ctx);
2985                 if ( $new ) {
2986                         print STDERR
2987                             "Found merge parent (svk:merge ticket): $parent\n";
2988                         push @$parents, $parent;
2989                 }
2990         }
2991 }
2992
2993 # note: this function should only be called if the various dirprops
2994 # have actually changed
2995 sub find_extra_svn_parents {
2996         my ($self, $ed, $mergeinfo, $parents) = @_;
2997         # aha!  svk:merge property changed...
2998
2999         # We first search for merged tips which are not in our
3000         # history.  Then, we figure out which git revisions are in
3001         # that tip, but not this revision.  If all of those revisions
3002         # are now marked as merge, we can add the tip as a parent.
3003         my @merges = split "\n", $mergeinfo;
3004         my @merge_tips;
3005         my @merged_commit_ranges;
3006         my $url = $self->rewrite_root || $self->{url};
3007         for my $merge ( @merges ) {
3008                 my ($source, $revs) = split ":", $merge;
3009                 my $path = $source;
3010                 $path =~ s{^/}{};
3011                 my $gs = Git::SVN->find_by_url($url.$source, $url, $path);
3012                 if ( !$gs ) {
3013                         warn "Couldn't find revmap for $url$source\n";
3014                         next;
3015                 }
3016                 my @ranges = split ",", $revs;
3017                 my ($tip, $tip_commit);
3018                 # find the tip
3019                 for my $range ( @ranges ) {
3020                         my ($bottom, $top) = split "-", $range;
3021                         $top ||= $bottom;
3022                         my $bottom_commit =
3023                                 $gs->rev_map_get($bottom, $self->ra_uuid) ||
3024                                 $gs->rev_map_get($bottom+1, $self->ra_uuid);
3025                         my $top_commit;
3026                         for (; !$top_commit && $top >= $bottom; --$top) {
3027                                 $top_commit =
3028                                         $gs->rev_map_get($top, $self->ra_uuid);
3029                         }
3030
3031                         unless ($top_commit and $bottom_commit) {
3032                                 warn "W:unknown path/rev in svn:mergeinfo "
3033                                         ."dirprop: $source:$range\n";
3034                                 next;
3035                         }
3036
3037                         push @merged_commit_ranges,
3038                                 "$bottom_commit..$top_commit";
3039
3040                         if ( !defined $tip or $top > $tip ) {
3041                                 $tip = $top;
3042                                 $tip_commit = $top_commit;
3043                         }
3044                 }
3045                 unless (!$tip_commit or
3046                                 grep { $_ eq $tip_commit } @$parents ) {
3047                         push @merge_tips, $tip_commit;
3048                 } else {
3049                         push @merge_tips, undef;
3050                 }
3051         }
3052         for my $merge_tip ( @merge_tips ) {
3053                 my $spec = shift @merges;
3054                 next unless $merge_tip;
3055                 my @cmd = ('rev-list', "-1", $merge_tip,
3056                            "--not", @$parents );
3057                 my ($msg_fh, $ctx) = command_output_pipe(@cmd);
3058                 my $new;
3059                 while ( <$msg_fh> ) {
3060                         $new=1;last;
3061                 }
3062                 command_close_pipe($msg_fh, $ctx);
3063                 if ( $new ) {
3064                         push @cmd, @merged_commit_ranges;
3065                         my ($msg_fh, $ctx) = command_output_pipe(@cmd);
3066                         my $unmerged;
3067                         while ( <$msg_fh> ) {
3068                                 $unmerged=1;last;
3069                         }
3070                         command_close_pipe($msg_fh, $ctx);
3071                         if ( $unmerged ) {
3072                                 warn "W:svn cherry-pick ignored ($spec)\n";
3073                         } else {
3074                                 warn
3075                                   "Found merge parent (svn:mergeinfo prop): ",
3076                                   $merge_tip, "\n";
3077                                 push @$parents, $merge_tip;
3078                         }
3079                 }
3080         }
3081 }
3082
3083 sub make_log_entry {
3084         my ($self, $rev, $parents, $ed) = @_;
3085         my $untracked = $self->get_untracked($ed);
3086
3087         my @parents = @$parents;
3088         my $ps = $ed->{path_strip} || "";
3089         for my $path ( grep { m/$ps/ } %{$ed->{dir_prop}} ) {
3090                 my $props = $ed->{dir_prop}{$path};
3091                 if ( $props->{"svk:merge"} ) {
3092                         $self->find_extra_svk_parents
3093                                 ($ed, $props->{"svk:merge"}, \@parents);
3094                 }
3095                 if ( $props->{"svn:mergeinfo"} ) {
3096                         $self->find_extra_svn_parents
3097                                 ($ed,
3098                                  $props->{"svn:mergeinfo"},
3099                                  \@parents);
3100                 }
3101         }
3102
3103         open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
3104         print $un "r$rev\n" or croak $!;
3105         print $un $_, "\n" foreach @$untracked;
3106         my %log_entry = ( parents => \@parents, revision => $rev,
3107                           log => '');
3108
3109         my $headrev;
3110         my $logged = delete $self->{logged_rev_props};
3111         if (!$logged || $self->{-want_revprops}) {
3112                 my $rp = $self->ra->rev_proplist($rev);
3113                 foreach (sort keys %$rp) {
3114                         my $v = $rp->{$_};
3115                         if (/^svn:(author|date|log)$/) {
3116                                 $log_entry{$1} = $v;
3117                         } elsif ($_ eq 'svm:headrev') {
3118                                 $headrev = $v;
3119                         } else {
3120                                 print $un "  rev_prop: ", uri_encode($_), ' ',
3121                                           uri_encode($v), "\n";
3122                         }
3123                 }
3124         } else {
3125                 map { $log_entry{$_} = $logged->{$_} } keys %$logged;
3126         }
3127         close $un or croak $!;
3128
3129         $log_entry{date} = parse_svn_date($log_entry{date});
3130         $log_entry{log} .= "\n";
3131         my $author = $log_entry{author} = check_author($log_entry{author});
3132         my ($name, $email) = defined $::users{$author} ? @{$::users{$author}}
3133                                                        : ($author, undef);
3134
3135         my ($commit_name, $commit_email) = ($name, $email);
3136         if ($_use_log_author) {
3137                 my $name_field;
3138                 if ($log_entry{log} =~ /From:\s+(.*\S)\s*\n/i) {
3139                         $name_field = $1;
3140                 } elsif ($log_entry{log} =~ /Signed-off-by:\s+(.*\S)\s*\n/i) {
3141                         $name_field = $1;
3142                 }
3143                 if (!defined $name_field) {
3144                         if (!defined $email) {
3145                                 $email = $name;
3146                         }
3147                 } elsif ($name_field =~ /(.*?)\s+<(.*)>/) {
3148                         ($name, $email) = ($1, $2);
3149                 } elsif ($name_field =~ /(.*)@/) {
3150                         ($name, $email) = ($1, $name_field);
3151                 } else {
3152                         ($name, $email) = ($name_field, $name_field);
3153                 }
3154         }
3155         if (defined $headrev && $self->use_svm_props) {
3156                 if ($self->rewrite_root) {
3157                         die "Can't have both 'useSvmProps' and 'rewriteRoot' ",
3158                             "options set!\n";
3159                 }
3160                 my ($uuid, $r) = $headrev =~ m{^([a-f\d\-]{30,}):(\d+)$}i;
3161                 # we don't want "SVM: initializing mirror for junk" ...
3162                 return undef if $r == 0;
3163                 my $svm = $self->svm;
3164                 if ($uuid ne $svm->{uuid}) {
3165                         die "UUID mismatch on SVM path:\n",
3166                             "expected: $svm->{uuid}\n",
3167                             "     got: $uuid\n";
3168                 }
3169                 my $full_url = $self->full_url;
3170                 $full_url =~ s#^\Q$svm->{replace}\E(/|$)#$svm->{source}$1# or
3171                              die "Failed to replace '$svm->{replace}' with ",
3172                                  "'$svm->{source}' in $full_url\n";
3173                 # throw away username for storing in records
3174                 remove_username($full_url);
3175                 $log_entry{metadata} = "$full_url\@$r $uuid";
3176                 $log_entry{svm_revision} = $r;
3177                 $email ||= "$author\@$uuid";
3178                 $commit_email ||= "$author\@$uuid";
3179         } elsif ($self->use_svnsync_props) {
3180                 my $full_url = $self->svnsync->{url};
3181                 $full_url .= "/$self->{path}" if length $self->{path};
3182                 remove_username($full_url);
3183                 my $uuid = $self->svnsync->{uuid};
3184                 $log_entry{metadata} = "$full_url\@$rev $uuid";
3185                 $email ||= "$author\@$uuid";
3186                 $commit_email ||= "$author\@$uuid";
3187         } else {
3188                 my $url = $self->metadata_url;
3189                 remove_username($url);
3190                 $log_entry{metadata} = "$url\@$rev " .
3191                                        $self->ra->get_uuid;
3192                 $email ||= "$author\@" . $self->ra->get_uuid;
3193                 $commit_email ||= "$author\@" . $self->ra->get_uuid;
3194         }
3195         $log_entry{name} = $name;
3196         $log_entry{email} = $email;
3197         $log_entry{commit_name} = $commit_name;
3198         $log_entry{commit_email} = $commit_email;
3199         \%log_entry;
3200 }
3201
3202 sub fetch {
3203         my ($self, $min_rev, $max_rev, @parents) = @_;
3204         my ($last_rev, $last_commit) = $self->last_rev_commit;
3205         my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
3206         $self->ra->gs_fetch_loop_common($base, $head, [$self]);
3207 }
3208
3209 sub set_tree_cb {
3210         my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
3211         $self->{inject_parents} = { $rev => $tree };
3212         $self->fetch(undef, undef);
3213 }
3214
3215 sub set_tree {
3216         my ($self, $tree) = (shift, shift);
3217         my $log_entry = ::get_commit_entry($tree);
3218         unless ($self->{last_rev}) {
3219                 ::fatal("Must have an existing revision to commit");
3220         }
3221         my %ed_opts = ( r => $self->{last_rev},
3222                         log => $log_entry->{log},
3223                         ra => $self->ra,
3224                         tree_a => $self->{last_commit},
3225                         tree_b => $tree,
3226                         editor_cb => sub {
3227                                $self->set_tree_cb($log_entry, $tree, @_) },
3228                         svn_path => $self->{path} );
3229         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
3230                 print "No changes\nr$self->{last_rev} = $tree\n";
3231         }
3232 }
3233
3234 sub rebuild_from_rev_db {
3235         my ($self, $path) = @_;
3236         my $r = -1;
3237         open my $fh, '<', $path or croak "open: $!";
3238         binmode $fh or croak "binmode: $!";
3239         while (<$fh>) {
3240                 length($_) == 41 or croak "inconsistent size in ($_) != 41";
3241                 chomp($_);
3242                 ++$r;
3243                 next if $_ eq ('0' x 40);
3244                 $self->rev_map_set($r, $_);
3245                 print "r$r = $_\n";
3246         }
3247         close $fh or croak "close: $!";
3248         unlink $path or croak "unlink: $!";
3249 }
3250
3251 sub rebuild {
3252         my ($self) = @_;
3253         my $map_path = $self->map_path;
3254         my $partial = (-e $map_path && ! -z $map_path);
3255         return unless ::verify_ref($self->refname.'^0');
3256         if (!$partial && ($self->use_svm_props || $self->no_metadata)) {
3257                 my $rev_db = $self->rev_db_path;
3258                 $self->rebuild_from_rev_db($rev_db);
3259                 if ($self->use_svm_props) {
3260                         my $svm_rev_db = $self->rev_db_path($self->svm_uuid);
3261                         $self->rebuild_from_rev_db($svm_rev_db);
3262                 }
3263                 $self->unlink_rev_db_symlink;
3264                 return;
3265         }
3266         print "Rebuilding $map_path ...\n" if (!$partial);
3267         my ($base_rev, $head) = ($partial ? $self->rev_map_max_norebuild(1) :
3268                 (undef, undef));
3269         my ($log, $ctx) =
3270             command_output_pipe(qw/rev-list --pretty=raw --no-color --reverse/,
3271                                 ($head ? "$head.." : "") . $self->refname,
3272                                 '--');
3273         my $metadata_url = $self->metadata_url;
3274         remove_username($metadata_url);
3275         my $svn_uuid = $self->ra_uuid;
3276         my $c;
3277         while (<$log>) {
3278                 if ( m{^commit ($::sha1)$} ) {
3279                         $c = $1;
3280                         next;
3281                 }
3282                 next unless s{^\s*(git-svn-id:)}{$1};
3283                 my ($url, $rev, $uuid) = ::extract_metadata($_);
3284                 remove_username($url);
3285
3286                 # ignore merges (from set-tree)
3287                 next if (!defined $rev || !$uuid);
3288
3289                 # if we merged or otherwise started elsewhere, this is
3290                 # how we break out of it
3291                 if (($uuid ne $svn_uuid) ||
3292                     ($metadata_url && $url && ($url ne $metadata_url))) {
3293                         next;
3294                 }
3295                 if ($partial && $head) {
3296                         print "Partial-rebuilding $map_path ...\n";
3297                         print "Currently at $base_rev = $head\n";
3298                         $head = undef;
3299                 }
3300
3301                 $self->rev_map_set($rev, $c);
3302                 print "r$rev = $c\n";
3303         }
3304         command_close_pipe($log, $ctx);
3305         print "Done rebuilding $map_path\n" if (!$partial || !$head);
3306         my $rev_db_path = $self->rev_db_path;
3307         if (-f $self->rev_db_path) {
3308                 unlink $self->rev_db_path or croak "unlink: $!";
3309         }
3310         $self->unlink_rev_db_symlink;
3311 }
3312
3313 # rev_map:
3314 # Tie::File seems to be prone to offset errors if revisions get sparse,
3315 # it's not that fast, either.  Tie::File is also not in Perl 5.6.  So
3316 # one of my favorite modules is out :<  Next up would be one of the DBM
3317 # modules, but I'm not sure which is most portable...
3318 #
3319 # This is the replacement for the rev_db format, which was too big
3320 # and inefficient for large repositories with a lot of sparse history
3321 # (mainly tags)
3322 #
3323 # The format is this:
3324 #   - 24 bytes for every record,
3325 #     * 4 bytes for the integer representing an SVN revision number
3326 #     * 20 bytes representing the sha1 of a git commit
3327 #   - No empty padding records like the old format
3328 #     (except the last record, which can be overwritten)
3329 #   - new records are written append-only since SVN revision numbers
3330 #     increase monotonically
3331 #   - lookups on SVN revision number are done via a binary search
3332 #   - Piping the file to xxd -c24 is a good way of dumping it for
3333 #     viewing or editing (piped back through xxd -r), should the need
3334 #     ever arise.
3335 #   - The last record can be padding revision with an all-zero sha1
3336 #     This is used to optimize fetch performance when using multiple
3337 #     "fetch" directives in .git/config
3338 #
3339 # These files are disposable unless noMetadata or useSvmProps is set
3340
3341 sub _rev_map_set {
3342         my ($fh, $rev, $commit) = @_;
3343
3344         binmode $fh or croak "binmode: $!";
3345         my $size = (stat($fh))[7];
3346         ($size % 24) == 0 or croak "inconsistent size: $size";
3347
3348         my $wr_offset = 0;
3349         if ($size > 0) {
3350                 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
3351                 my $read = sysread($fh, my $buf, 24) or croak "read: $!";
3352                 $read == 24 or croak "read only $read bytes (!= 24)";
3353                 my ($last_rev, $last_commit) = unpack(rev_map_fmt, $buf);
3354                 if ($last_commit eq ('0' x40)) {
3355                         if ($size >= 48) {
3356                                 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
3357                                 $read = sysread($fh, $buf, 24) or
3358                                     croak "read: $!";
3359                                 $read == 24 or
3360                                     croak "read only $read bytes (!= 24)";
3361                                 ($last_rev, $last_commit) =
3362                                     unpack(rev_map_fmt, $buf);
3363                                 if ($last_commit eq ('0' x40)) {
3364                                         croak "inconsistent .rev_map\n";
3365                                 }
3366                         }
3367                         if ($last_rev >= $rev) {
3368                                 croak "last_rev is higher!: $last_rev >= $rev";
3369                         }
3370                         $wr_offset = -24;
3371                 }
3372         }
3373         sysseek($fh, $wr_offset, SEEK_END) or croak "seek: $!";
3374         syswrite($fh, pack(rev_map_fmt, $rev, $commit), 24) == 24 or
3375           croak "write: $!";
3376 }
3377
3378 sub _rev_map_reset {
3379         my ($fh, $rev, $commit) = @_;
3380         my $c = _rev_map_get($fh, $rev);
3381         $c eq $commit or die "_rev_map_reset(@_) commit $c does not match!\n";
3382         my $offset = sysseek($fh, 0, SEEK_CUR) or croak "seek: $!";
3383         truncate $fh, $offset or croak "truncate: $!";
3384 }
3385
3386 sub mkfile {
3387         my ($path) = @_;
3388         unless (-e $path) {
3389                 my ($dir, $base) = ($path =~ m#^(.*?)/?([^/]+)$#);
3390                 mkpath([$dir]) unless -d $dir;
3391                 open my $fh, '>>', $path or die "Couldn't create $path: $!\n";
3392                 close $fh or die "Couldn't close (create) $path: $!\n";
3393         }
3394 }
3395
3396 sub rev_map_set {
3397         my ($self, $rev, $commit, $update_ref, $uuid) = @_;
3398         length $commit == 40 or die "arg3 must be a full SHA1 hexsum\n";
3399         my $db = $self->map_path($uuid);
3400         my $db_lock = "$db.lock";
3401         my $sig;
3402         $update_ref ||= 0;
3403         if ($update_ref) {
3404                 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
3405                             $SIG{USR1} = $SIG{USR2} = sub { $sig = $_[0] };
3406         }
3407         mkfile($db);
3408
3409         $LOCKFILES{$db_lock} = 1;
3410         my $sync;
3411         # both of these options make our .rev_db file very, very important
3412         # and we can't afford to lose it because rebuild() won't work
3413         if ($self->use_svm_props || $self->no_metadata) {
3414                 $sync = 1;
3415                 copy($db, $db_lock) or die "rev_map_set(@_): ",
3416                                            "Failed to copy: ",
3417                                            "$db => $db_lock ($!)\n";
3418         } else {
3419                 rename $db, $db_lock or die "rev_map_set(@_): ",
3420                                             "Failed to rename: ",
3421                                             "$db => $db_lock ($!)\n";
3422         }
3423
3424         sysopen(my $fh, $db_lock, O_RDWR | O_CREAT)
3425              or croak "Couldn't open $db_lock: $!\n";
3426         $update_ref eq 'reset' ? _rev_map_reset($fh, $rev, $commit) :
3427                                  _rev_map_set($fh, $rev, $commit);
3428         if ($sync) {
3429                 $fh->flush or die "Couldn't flush $db_lock: $!\n";
3430                 $fh->sync or die "Couldn't sync $db_lock: $!\n";
3431         }
3432         close $fh or croak $!;
3433         if ($update_ref) {
3434                 $_head = $self;
3435                 my $note = "";
3436                 $note = " ($update_ref)" if ($update_ref !~ /^\d*$/);
3437                 command_noisy('update-ref', '-m', "r$rev$note",
3438                               $self->refname, $commit);
3439         }
3440         rename $db_lock, $db or die "rev_map_set(@_): ", "Failed to rename: ",
3441                                     "$db_lock => $db ($!)\n";
3442         delete $LOCKFILES{$db_lock};
3443         if ($update_ref) {
3444                 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
3445                             $SIG{USR1} = $SIG{USR2} = 'DEFAULT';
3446                 kill $sig, $$ if defined $sig;
3447         }
3448 }
3449
3450 # If want_commit, this will return an array of (rev, commit) where
3451 # commit _must_ be a valid commit in the archive.
3452 # Otherwise, it'll return the max revision (whether or not the
3453 # commit is valid or just a 0x40 placeholder).
3454 sub rev_map_max {
3455         my ($self, $want_commit) = @_;
3456         $self->rebuild;
3457         my ($r, $c) = $self->rev_map_max_norebuild($want_commit);
3458         $want_commit ? ($r, $c) : $r;
3459 }
3460
3461 sub rev_map_max_norebuild {
3462         my ($self, $want_commit) = @_;
3463         my $map_path = $self->map_path;
3464         stat $map_path or return $want_commit ? (0, undef) : 0;
3465         sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
3466         binmode $fh or croak "binmode: $!";
3467         my $size = (stat($fh))[7];
3468         ($size % 24) == 0 or croak "inconsistent size: $size";
3469
3470         if ($size == 0) {
3471                 close $fh or croak "close: $!";
3472                 return $want_commit ? (0, undef) : 0;
3473         }
3474
3475         sysseek($fh, -24, SEEK_END) or croak "seek: $!";
3476         sysread($fh, my $buf, 24) == 24 or croak "read: $!";
3477         my ($r, $c) = unpack(rev_map_fmt, $buf);
3478         if ($want_commit && $c eq ('0' x40)) {
3479                 if ($size < 48) {
3480                         return $want_commit ? (0, undef) : 0;
3481                 }
3482                 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
3483                 sysread($fh, $buf, 24) == 24 or croak "read: $!";
3484                 ($r, $c) = unpack(rev_map_fmt, $buf);
3485                 if ($c eq ('0'x40)) {
3486                         croak "Penultimate record is all-zeroes in $map_path";
3487                 }
3488         }
3489         close $fh or croak "close: $!";
3490         $want_commit ? ($r, $c) : $r;
3491 }
3492
3493 sub rev_map_get {
3494         my ($self, $rev, $uuid) = @_;
3495         my $map_path = $self->map_path($uuid);
3496         return undef unless -e $map_path;
3497
3498         sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
3499         my $c = _rev_map_get($fh, $rev);
3500         close($fh) or croak "close: $!";
3501         $c
3502 }
3503
3504 sub _rev_map_get {
3505         my ($fh, $rev) = @_;
3506
3507         binmode $fh or croak "binmode: $!";
3508         my $size = (stat($fh))[7];
3509         ($size % 24) == 0 or croak "inconsistent size: $size";
3510
3511         if ($size == 0) {
3512                 return undef;
3513         }
3514
3515         my ($l, $u) = (0, $size - 24);
3516         my ($r, $c, $buf);
3517
3518         while ($l <= $u) {
3519                 my $i = int(($l/24 + $u/24) / 2) * 24;
3520                 sysseek($fh, $i, SEEK_SET) or croak "seek: $!";
3521                 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
3522                 my ($r, $c) = unpack(rev_map_fmt, $buf);
3523
3524                 if ($r < $rev) {
3525                         $l = $i + 24;
3526                 } elsif ($r > $rev) {
3527                         $u = $i - 24;
3528                 } else { # $r == $rev
3529                         return $c eq ('0' x 40) ? undef : $c;
3530                 }
3531         }
3532         undef;
3533 }
3534
3535 # Finds the first svn revision that exists on (if $eq_ok is true) or
3536 # before $rev for the current branch.  It will not search any lower
3537 # than $min_rev.  Returns the git commit hash and svn revision number
3538 # if found, else (undef, undef).
3539 sub find_rev_before {
3540         my ($self, $rev, $eq_ok, $min_rev) = @_;
3541         --$rev unless $eq_ok;
3542         $min_rev ||= 1;
3543         my $max_rev = $self->rev_map_max;
3544         $rev = $max_rev if ($rev > $max_rev);
3545         while ($rev >= $min_rev) {
3546                 if (my $c = $self->rev_map_get($rev)) {
3547                         return ($rev, $c);
3548                 }
3549                 --$rev;
3550         }
3551         return (undef, undef);
3552 }
3553
3554 # Finds the first svn revision that exists on (if $eq_ok is true) or
3555 # after $rev for the current branch.  It will not search any higher
3556 # than $max_rev.  Returns the git commit hash and svn revision number
3557 # if found, else (undef, undef).
3558 sub find_rev_after {
3559         my ($self, $rev, $eq_ok, $max_rev) = @_;
3560         ++$rev unless $eq_ok;
3561         $max_rev ||= $self->rev_map_max;
3562         while ($rev <= $max_rev) {
3563                 if (my $c = $self->rev_map_get($rev)) {
3564                         return ($rev, $c);
3565                 }
3566                 ++$rev;
3567         }
3568         return (undef, undef);
3569 }
3570
3571 sub _new {
3572         my ($class, $repo_id, $ref_id, $path) = @_;
3573         unless (defined $repo_id && length $repo_id) {
3574                 $repo_id = $Git::SVN::default_repo_id;
3575         }
3576         unless (defined $ref_id && length $ref_id) {
3577                 $_prefix = '' unless defined($_prefix);
3578                 $_[2] = $ref_id =
3579                              "refs/remotes/$_prefix$Git::SVN::default_ref_id";
3580         }
3581         $_[1] = $repo_id;
3582         my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
3583
3584         # Older repos imported by us used $GIT_DIR/svn/foo instead of
3585         # $GIT_DIR/svn/refs/remotes/foo when tracking refs/remotes/foo
3586         if ($ref_id =~ m{^refs/remotes/(.*)}) {
3587                 my $old_dir = "$ENV{GIT_DIR}/svn/$1";
3588                 if (-d $old_dir && ! -d $dir) {
3589                         $dir = $old_dir;
3590                 }
3591         }
3592
3593         $_[3] = $path = '' unless (defined $path);
3594         mkpath([$dir]);
3595         bless {
3596                 ref_id => $ref_id, dir => $dir, index => "$dir/index",
3597                 path => $path, config => "$ENV{GIT_DIR}/svn/config",
3598                 map_root => "$dir/.rev_map", repo_id => $repo_id }, $class;
3599 }
3600
3601 # for read-only access of old .rev_db formats
3602 sub unlink_rev_db_symlink {
3603         my ($self) = @_;
3604         my $link = $self->rev_db_path;
3605         $link =~ s/\.[\w-]+$// or croak "missing UUID at the end of $link";
3606         if (-l $link) {
3607                 unlink $link or croak "unlink: $link failed!";
3608         }
3609 }
3610
3611 sub rev_db_path {
3612         my ($self, $uuid) = @_;
3613         my $db_path = $self->map_path($uuid);
3614         $db_path =~ s{/\.rev_map\.}{/\.rev_db\.}
3615             or croak "map_path: $db_path does not contain '/.rev_map.' !";
3616         $db_path;
3617 }
3618
3619 # the new replacement for .rev_db
3620 sub map_path {
3621         my ($self, $uuid) = @_;
3622         $uuid ||= $self->ra_uuid;
3623         "$self->{map_root}.$uuid";
3624 }
3625
3626 sub uri_encode {
3627         my ($f) = @_;
3628         $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
3629         $f
3630 }
3631
3632 sub uri_decode {
3633         my ($f) = @_;
3634         $f =~ s#%([0-9a-fA-F]{2})#chr(hex($1))#eg;
3635         $f
3636 }
3637
3638 sub remove_username {
3639         $_[0] =~ s{^([^:]*://)[^@]+@}{$1};
3640 }
3641
3642 package Git::SVN::Prompt;
3643 use strict;
3644 use warnings;
3645 require SVN::Core;
3646 use vars qw/$_no_auth_cache $_username/;
3647
3648 sub simple {
3649         my ($cred, $realm, $default_username, $may_save, $pool) = @_;
3650         $may_save = undef if $_no_auth_cache;
3651         $default_username = $_username if defined $_username;
3652         if (defined $default_username && length $default_username) {
3653                 if (defined $realm && length $realm) {
3654                         print STDERR "Authentication realm: $realm\n";
3655                         STDERR->flush;
3656                 }
3657                 $cred->username($default_username);
3658         } else {
3659                 username($cred, $realm, $may_save, $pool);
3660         }
3661         $cred->password(_read_password("Password for '" .
3662                                        $cred->username . "': ", $realm));
3663         $cred->may_save($may_save);
3664         $SVN::_Core::SVN_NO_ERROR;
3665 }
3666
3667 sub ssl_server_trust {
3668         my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
3669         $may_save = undef if $_no_auth_cache;
3670         print STDERR "Error validating server certificate for '$realm':\n";
3671         {
3672                 no warnings 'once';
3673                 # All variables SVN::Auth::SSL::* are used only once,
3674                 # so we're shutting up Perl warnings about this.
3675                 if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
3676                         print STDERR " - The certificate is not issued ",
3677                             "by a trusted authority. Use the\n",
3678                             "   fingerprint to validate ",
3679                             "the certificate manually!\n";
3680                 }
3681                 if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
3682                         print STDERR " - The certificate hostname ",
3683                             "does not match.\n";
3684                 }
3685                 if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
3686                         print STDERR " - The certificate is not yet valid.\n";
3687                 }
3688                 if ($failures & $SVN::Auth::SSL::EXPIRED) {
3689                         print STDERR " - The certificate has expired.\n";
3690                 }
3691                 if ($failures & $SVN::Auth::SSL::OTHER) {
3692                         print STDERR " - The certificate has ",
3693                             "an unknown error.\n";
3694                 }
3695         } # no warnings 'once'
3696         printf STDERR
3697                 "Certificate information:\n".
3698                 " - Hostname: %s\n".
3699                 " - Valid: from %s until %s\n".
3700                 " - Issuer: %s\n".
3701                 " - Fingerprint: %s\n",
3702                 map $cert_info->$_, qw(hostname valid_from valid_until
3703                                        issuer_dname fingerprint);
3704         my $choice;
3705 prompt:
3706         print STDERR $may_save ?
3707               "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
3708               "(R)eject or accept (t)emporarily? ";
3709         STDERR->flush;
3710         $choice = lc(substr(<STDIN> || 'R', 0, 1));
3711         if ($choice =~ /^t$/i) {
3712                 $cred->may_save(undef);
3713         } elsif ($choice =~ /^r$/i) {
3714                 return -1;
3715         } elsif ($may_save && $choice =~ /^p$/i) {
3716                 $cred->may_save($may_save);
3717         } else {
3718                 goto prompt;
3719         }
3720         $cred->accepted_failures($failures);
3721         $SVN::_Core::SVN_NO_ERROR;
3722 }
3723
3724 sub ssl_client_cert {
3725         my ($cred, $realm, $may_save, $pool) = @_;
3726         $may_save = undef if $_no_auth_cache;
3727         print STDERR "Client certificate filename: ";
3728         STDERR->flush;
3729         chomp(my $filename = <STDIN>);
3730         $cred->cert_file($filename);
3731         $cred->may_save($may_save);
3732         $SVN::_Core::SVN_NO_ERROR;
3733 }
3734
3735 sub ssl_client_cert_pw {
3736         my ($cred, $realm, $may_save, $pool) = @_;
3737         $may_save = undef if $_no_auth_cache;
3738         $cred->password(_read_password("Password: ", $realm));
3739         $cred->may_save($may_save);
3740         $SVN::_Core::SVN_NO_ERROR;
3741 }
3742
3743 sub username {
3744         my ($cred, $realm, $may_save, $pool) = @_;
3745         $may_save = undef if $_no_auth_cache;
3746         if (defined $realm && length $realm) {
3747                 print STDERR "Authentication realm: $realm\n";
3748         }
3749         my $username;
3750         if (defined $_username) {
3751                 $username = $_username;
3752         } else {
3753                 print STDERR "Username: ";
3754                 STDERR->flush;
3755                 chomp($username = <STDIN>);
3756         }
3757         $cred->username($username);
3758         $cred->may_save($may_save);
3759         $SVN::_Core::SVN_NO_ERROR;
3760 }
3761
3762 sub _read_password {
3763         my ($prompt, $realm) = @_;
3764         print STDERR $prompt;
3765         STDERR->flush;
3766         require Term::ReadKey;
3767         Term::ReadKey::ReadMode('noecho');
3768         my $password = '';
3769         while (defined(my $key = Term::ReadKey::ReadKey(0))) {
3770                 last if $key =~ /[\012\015]/; # \n\r
3771                 $password .= $key;
3772         }
3773         Term::ReadKey::ReadMode('restore');
3774         print STDERR "\n";
3775         STDERR->flush;
3776         $password;
3777 }
3778
3779 package SVN::Git::Fetcher;
3780 use vars qw/@ISA/;
3781 use strict;
3782 use warnings;
3783 use Carp qw/croak/;
3784 use File::Temp qw/tempfile/;
3785 use IO::File qw//;
3786 use vars qw/$_ignore_regex/;
3787
3788 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
3789 sub new {
3790         my ($class, $git_svn, $switch_path) = @_;
3791         my $self = SVN::Delta::Editor->new;
3792         bless $self, $class;
3793         if (exists $git_svn->{last_commit}) {
3794                 $self->{c} = $git_svn->{last_commit};
3795                 $self->{empty_symlinks} =
3796                                   _mark_empty_symlinks($git_svn, $switch_path);
3797         }
3798         $self->{ignore_regex} = eval { command_oneline('config', '--get',
3799                              "svn-remote.$git_svn->{repo_id}.ignore-paths") };
3800         $self->{empty} = {};
3801         $self->{dir_prop} = {};
3802         $self->{file_prop} = {};
3803         $self->{absent_dir} = {};
3804         $self->{absent_file} = {};
3805         $self->{gii} = $git_svn->tmp_index_do(sub { Git::IndexInfo->new });
3806         $self;
3807 }
3808
3809 # this uses the Ra object, so it must be called before do_{switch,update},
3810 # not inside them (when the Git::SVN::Fetcher object is passed) to
3811 # do_{switch,update}
3812 sub _mark_empty_symlinks {
3813         my ($git_svn, $switch_path) = @_;
3814         my $bool = Git::config_bool('svn.brokenSymlinkWorkaround');
3815         return {} if (!defined($bool)) || (defined($bool) && ! $bool);
3816
3817         my %ret;
3818         my ($rev, $cmt) = $git_svn->last_rev_commit;
3819         return {} unless ($rev && $cmt);
3820
3821         # allow the warning to be printed for each revision we fetch to
3822         # ensure the user sees it.  The user can also disable the workaround
3823         # on the repository even while git svn is running and the next
3824         # revision fetched will skip this expensive function.
3825         my $printed_warning;
3826         chomp(my $empty_blob = `git hash-object -t blob --stdin < /dev/null`);
3827         my ($ls, $ctx) = command_output_pipe(qw/ls-tree -r -z/, $cmt);
3828         local $/ = "\0";
3829         my $pfx = defined($switch_path) ? $switch_path : $git_svn->{path};
3830         $pfx .= '/' if length($pfx);
3831         while (<$ls>) {
3832                 chomp;
3833                 s/\A100644 blob $empty_blob\t//o or next;
3834                 unless ($printed_warning) {
3835                         print STDERR "Scanning for empty symlinks, ",
3836                                      "this may take a while if you have ",
3837                                      "many empty files\n",
3838                                      "You may disable this with `",
3839                                      "git config svn.brokenSymlinkWorkaround ",
3840                                      "false'.\n",
3841                                      "This may be done in a different ",
3842                                      "terminal without restarting ",
3843                                      "git svn\n";
3844                         $printed_warning = 1;
3845                 }
3846                 my $path = $_;
3847                 my (undef, $props) =
3848                                $git_svn->ra->get_file($pfx.$path, $rev, undef);
3849                 if ($props->{'svn:special'}) {
3850                         $ret{$path} = 1;
3851                 }
3852         }
3853         command_close_pipe($ls, $ctx);
3854         \%ret;
3855 }
3856
3857 # returns true if a given path is inside a ".git" directory
3858 sub in_dot_git {
3859         $_[0] =~ m{(?:^|/)\.git(?:/|$)};
3860 }
3861
3862 # return value: 0 -- don't ignore, 1 -- ignore
3863 sub is_path_ignored {
3864         my ($self, $path) = @_;
3865         return 1 if in_dot_git($path);
3866         return 1 if defined($self->{ignore_regex}) &&
3867                     $path =~ m!$self->{ignore_regex}!;
3868         return 0 unless defined($_ignore_regex);
3869         return 1 if $path =~ m!$_ignore_regex!o;
3870         return 0;
3871 }
3872
3873 sub set_path_strip {
3874         my ($self, $path) = @_;
3875         $self->{path_strip} = qr/^\Q$path\E(\/|$)/ if length $path;
3876 }
3877
3878 sub open_root {
3879         { path => '' };
3880 }
3881
3882 sub open_directory {
3883         my ($self, $path, $pb, $rev) = @_;
3884         { path => $path };
3885 }
3886
3887 sub git_path {
3888         my ($self, $path) = @_;
3889         if ($self->{path_strip}) {
3890                 $path =~ s!$self->{path_strip}!! or
3891                   die "Failed to strip path '$path' ($self->{path_strip})\n";
3892         }
3893         $path;
3894 }
3895
3896 sub delete_entry {
3897         my ($self, $path, $rev, $pb) = @_;
3898         return undef if $self->is_path_ignored($path);
3899
3900         my $gpath = $self->git_path($path);
3901         return undef if ($gpath eq '');
3902
3903         # remove entire directories.
3904         my ($tree) = (command('ls-tree', '-z', $self->{c}, "./$gpath")
3905                          =~ /\A040000 tree ([a-f\d]{40})\t\Q$gpath\E\0/);
3906         if ($tree) {
3907                 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
3908                                                      -r --name-only -z/,
3909                                                      $tree);
3910                 local $/ = "\0";
3911                 while (<$ls>) {
3912                         chomp;
3913                         my $rmpath = "$gpath/$_";
3914                         $self->{gii}->remove($rmpath);
3915                         print "\tD\t$rmpath\n" unless $::_q;
3916                 }
3917                 print "\tD\t$gpath/\n" unless $::_q;
3918                 command_close_pipe($ls, $ctx);
3919         } else {
3920                 $self->{gii}->remove($gpath);
3921                 print "\tD\t$gpath\n" unless $::_q;
3922         }
3923         $self->{empty}->{$path} = 0;
3924         undef;
3925 }
3926
3927 sub open_file {
3928         my ($self, $path, $pb, $rev) = @_;
3929         my ($mode, $blob);
3930
3931         goto out if $self->is_path_ignored($path);
3932
3933         my $gpath = $self->git_path($path);
3934         ($mode, $blob) = (command('ls-tree', '-z', $self->{c}, "./$gpath")
3935                              =~ /\A(\d{6}) blob ([a-f\d]{40})\t\Q$gpath\E\0/);
3936         unless (defined $mode && defined $blob) {
3937                 die "$path was not found in commit $self->{c} (r$rev)\n";
3938         }
3939         if ($mode eq '100644' && $self->{empty_symlinks}->{$path}) {
3940                 $mode = '120000';
3941         }
3942 out:
3943         { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
3944           pool => SVN::Pool->new, action => 'M' };
3945 }
3946
3947 sub add_file {
3948         my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
3949         my $mode;
3950
3951         if (!$self->is_path_ignored($path)) {
3952                 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3953                 delete $self->{empty}->{$dir};
3954                 $mode = '100644';
3955         }
3956         { path => $path, mode_a => $mode, mode_b => $mode,
3957           pool => SVN::Pool->new, action => 'A' };
3958 }
3959
3960 sub add_directory {
3961         my ($self, $path, $cp_path, $cp_rev) = @_;
3962         goto out if $self->is_path_ignored($path);
3963         my $gpath = $self->git_path($path);
3964         if ($gpath eq '') {
3965                 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
3966                                                      -r --name-only -z/,
3967                                                      $self->{c});
3968                 local $/ = "\0";
3969                 while (<$ls>) {
3970                         chomp;
3971                         $self->{gii}->remove($_);
3972                         print "\tD\t$_\n" unless $::_q;
3973                 }
3974                 command_close_pipe($ls, $ctx);
3975                 $self->{empty}->{$path} = 0;
3976         }
3977         my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3978         delete $self->{empty}->{$dir};
3979         $self->{empty}->{$path} = 1;
3980 out:
3981         { path => $path };
3982 }
3983
3984 sub change_dir_prop {
3985         my ($self, $db, $prop, $value) = @_;
3986         return undef if $self->is_path_ignored($db->{path});
3987         $self->{dir_prop}->{$db->{path}} ||= {};
3988         $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
3989         undef;
3990 }
3991
3992 sub absent_directory {
3993         my ($self, $path, $pb) = @_;
3994         return undef if $self->is_path_ignored($path);
3995         $self->{absent_dir}->{$pb->{path}} ||= [];
3996         push @{$self->{absent_dir}->{$pb->{path}}}, $path;
3997         undef;
3998 }
3999
4000 sub absent_file {
4001         my ($self, $path, $pb) = @_;
4002         return undef if $self->is_path_ignored($path);
4003         $self->{absent_file}->{$pb->{path}} ||= [];
4004         push @{$self->{absent_file}->{$pb->{path}}}, $path;
4005         undef;
4006 }
4007
4008 sub change_file_prop {
4009         my ($self, $fb, $prop, $value) = @_;
4010         return undef if $self->is_path_ignored($fb->{path});
4011         if ($prop eq 'svn:executable') {
4012                 if ($fb->{mode_b} != 120000) {
4013                         $fb->{mode_b} = defined $value ? 100755 : 100644;
4014                 }
4015         } elsif ($prop eq 'svn:special') {
4016                 $fb->{mode_b} = defined $value ? 120000 : 100644;
4017         } else {
4018                 $self->{file_prop}->{$fb->{path}} ||= {};
4019                 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
4020         }
4021         undef;
4022 }
4023
4024 sub apply_textdelta {
4025         my ($self, $fb, $exp) = @_;
4026         return undef if $self->is_path_ignored($fb->{path});
4027         my $fh = $::_repository->temp_acquire('svn_delta');
4028         # $fh gets auto-closed() by SVN::TxDelta::apply(),
4029         # (but $base does not,) so dup() it for reading in close_file
4030         open my $dup, '<&', $fh or croak $!;
4031         my $base = $::_repository->temp_acquire('git_blob');
4032
4033         if ($fb->{blob}) {
4034                 my ($base_is_link, $size);
4035
4036                 if ($fb->{mode_a} eq '120000' &&
4037                     ! $self->{empty_symlinks}->{$fb->{path}}) {
4038                         print $base 'link ' or die "print $!\n";
4039                         $base_is_link = 1;
4040                 }
4041         retry:
4042                 $size = $::_repository->cat_blob($fb->{blob}, $base);
4043                 die "Failed to read object $fb->{blob}" if ($size < 0);
4044
4045                 if (defined $exp) {
4046                         seek $base, 0, 0 or croak $!;
4047                         my $got = ::md5sum($base);
4048                         if ($got ne $exp) {
4049                                 my $err = "Checksum mismatch: ".
4050                                        "$fb->{path} $fb->{blob}\n" .
4051                                        "expected: $exp\n" .
4052                                        "     got: $got\n";
4053                                 if ($base_is_link) {
4054                                         warn $err,
4055                                              "Retrying... (possibly ",
4056                                              "a bad symlink from SVN)\n";
4057                                         $::_repository->temp_reset($base);
4058                                         $base_is_link = 0;
4059                                         goto retry;
4060                                 }
4061                                 die $err;
4062                         }
4063                 }
4064         }
4065         seek $base, 0, 0 or croak $!;
4066         $fb->{fh} = $fh;
4067         $fb->{base} = $base;
4068         [ SVN::TxDelta::apply($base, $dup, undef, $fb->{path}, $fb->{pool}) ];
4069 }
4070
4071 sub close_file {
4072         my ($self, $fb, $exp) = @_;
4073         return undef if $self->is_path_ignored($fb->{path});
4074
4075         my $hash;
4076         my $path = $self->git_path($fb->{path});
4077         if (my $fh = $fb->{fh}) {
4078                 if (defined $exp) {
4079                         seek($fh, 0, 0) or croak $!;
4080                         my $got = ::md5sum($fh);
4081                         if ($got ne $exp) {
4082                                 die "Checksum mismatch: $path\n",
4083                                     "expected: $exp\n    got: $got\n";
4084                         }
4085                 }
4086                 if ($fb->{mode_b} == 120000) {
4087                         sysseek($fh, 0, 0) or croak $!;
4088                         my $rd = sysread($fh, my $buf, 5);
4089
4090                         if (!defined $rd) {
4091                                 croak "sysread: $!\n";
4092                         } elsif ($rd == 0) {
4093                                 warn "$path has mode 120000",
4094                                      " but it points to nothing\n",
4095                                      "converting to an empty file with mode",
4096                                      " 100644\n";
4097                                 $fb->{mode_b} = '100644';
4098                         } elsif ($buf ne 'link ') {
4099                                 warn "$path has mode 120000",
4100                                      " but is not a link\n";
4101                         } else {
4102                                 my $tmp_fh = $::_repository->temp_acquire(
4103                                         'svn_hash');
4104                                 my $res;
4105                                 while ($res = sysread($fh, my $str, 1024)) {
4106                                         my $out = syswrite($tmp_fh, $str, $res);
4107                                         defined($out) && $out == $res
4108                                                 or croak("write ",
4109                                                         Git::temp_path($tmp_fh),
4110                                                         ": $!\n");
4111                                 }
4112                                 defined $res or croak $!;
4113
4114                                 ($fh, $tmp_fh) = ($tmp_fh, $fh);
4115                                 Git::temp_release($tmp_fh, 1);
4116                         }
4117                 }
4118
4119                 $hash = $::_repository->hash_and_insert_object(
4120                                 Git::temp_path($fh));
4121                 $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
4122
4123                 Git::temp_release($fb->{base}, 1);
4124                 Git::temp_release($fh, 1);
4125         } else {
4126                 $hash = $fb->{blob} or die "no blob information\n";
4127         }
4128         $fb->{pool}->clear;
4129         $self->{gii}->update($fb->{mode_b}, $hash, $path) or croak $!;
4130         print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $::_q;
4131         undef;
4132 }
4133
4134 sub abort_edit {
4135         my $self = shift;
4136         $self->{nr} = $self->{gii}->{nr};
4137         delete $self->{gii};
4138         $self->SUPER::abort_edit(@_);
4139 }
4140
4141 sub close_edit {
4142         my $self = shift;
4143         $self->{git_commit_ok} = 1;
4144         $self->{nr} = $self->{gii}->{nr};
4145         delete $self->{gii};
4146         $self->SUPER::close_edit(@_);
4147 }
4148
4149 package SVN::Git::Editor;
4150 use vars qw/@ISA $_rmdir $_cp_similarity $_find_copies_harder $_rename_limit/;
4151 use strict;
4152 use warnings;
4153 use Carp qw/croak/;
4154 use IO::File;
4155
4156 sub new {
4157         my ($class, $opts) = @_;
4158         foreach (qw/svn_path r ra tree_a tree_b log editor_cb/) {
4159                 die "$_ required!\n" unless (defined $opts->{$_});
4160         }
4161
4162         my $pool = SVN::Pool->new;
4163         my $mods = generate_diff($opts->{tree_a}, $opts->{tree_b});
4164         my $types = check_diff_paths($opts->{ra}, $opts->{svn_path},
4165                                      $opts->{r}, $mods);
4166
4167         # $opts->{ra} functions should not be used after this:
4168         my @ce  = $opts->{ra}->get_commit_editor($opts->{log},
4169                                                 $opts->{editor_cb}, $pool);
4170         my $self = SVN::Delta::Editor->new(@ce, $pool);
4171         bless $self, $class;
4172         foreach (qw/svn_path r tree_a tree_b/) {
4173                 $self->{$_} = $opts->{$_};
4174         }
4175         $self->{url} = $opts->{ra}->{url};
4176         $self->{mods} = $mods;
4177         $self->{types} = $types;
4178         $self->{pool} = $pool;
4179         $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
4180         $self->{rm} = { };
4181         $self->{path_prefix} = length $self->{svn_path} ?
4182                                "$self->{svn_path}/" : '';
4183         $self->{config} = $opts->{config};
4184         return $self;
4185 }
4186
4187 sub generate_diff {
4188         my ($tree_a, $tree_b) = @_;
4189         my @diff_tree = qw(diff-tree -z -r);
4190         if ($_cp_similarity) {
4191                 push @diff_tree, "-C$_cp_similarity";
4192         } else {
4193                 push @diff_tree, '-C';
4194         }
4195         push @diff_tree, '--find-copies-harder' if $_find_copies_harder;
4196         push @diff_tree, "-l$_rename_limit" if defined $_rename_limit;
4197         push @diff_tree, $tree_a, $tree_b;
4198         my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
4199         local $/ = "\0";
4200         my $state = 'meta';
4201         my @mods;
4202         while (<$diff_fh>) {
4203                 chomp $_; # this gets rid of the trailing "\0"
4204                 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
4205                                         ($::sha1)\s($::sha1)\s
4206                                         ([MTCRAD])\d*$/xo) {
4207                         push @mods, {   mode_a => $1, mode_b => $2,
4208                                         sha1_a => $3, sha1_b => $4,
4209                                         chg => $5 };
4210                         if ($5 =~ /^(?:C|R)$/) {
4211                                 $state = 'file_a';
4212                         } else {
4213                                 $state = 'file_b';
4214                         }
4215                 } elsif ($state eq 'file_a') {
4216                         my $x = $mods[$#mods] or croak "Empty array\n";
4217                         if ($x->{chg} !~ /^(?:C|R)$/) {
4218                                 croak "Error parsing $_, $x->{chg}\n";
4219                         }
4220                         $x->{file_a} = $_;
4221                         $state = 'file_b';
4222                 } elsif ($state eq 'file_b') {
4223                         my $x = $mods[$#mods] or croak "Empty array\n";
4224                         if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
4225                                 croak "Error parsing $_, $x->{chg}\n";
4226                         }
4227                         if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
4228                                 croak "Error parsing $_, $x->{chg}\n";
4229                         }
4230                         $x->{file_b} = $_;
4231                         $state = 'meta';
4232                 } else {
4233                         croak "Error parsing $_\n";
4234                 }
4235         }
4236         command_close_pipe($diff_fh, $ctx);
4237         \@mods;
4238 }
4239
4240 sub check_diff_paths {
4241         my ($ra, $pfx, $rev, $mods) = @_;
4242         my %types;
4243         $pfx .= '/' if length $pfx;
4244
4245         sub type_diff_paths {
4246                 my ($ra, $types, $path, $rev) = @_;
4247                 my @p = split m#/+#, $path;
4248                 my $c = shift @p;
4249                 unless (defined $types->{$c}) {
4250                         $types->{$c} = $ra->check_path($c, $rev);
4251                 }
4252                 while (@p) {
4253                         $c .= '/' . shift @p;
4254                         next if defined $types->{$c};
4255                         $types->{$c} = $ra->check_path($c, $rev);
4256                 }
4257         }
4258
4259         foreach my $m (@$mods) {
4260                 foreach my $f (qw/file_a file_b/) {
4261                         next unless defined $m->{$f};
4262                         my ($dir) = ($m->{$f} =~ m#^(.*?)/?(?:[^/]+)$#);
4263                         if (length $pfx.$dir && ! defined $types{$dir}) {
4264                                 type_diff_paths($ra, \%types, $pfx.$dir, $rev);
4265                         }
4266                 }
4267         }
4268         \%types;
4269 }
4270
4271 sub split_path {
4272         return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
4273 }
4274
4275 sub repo_path {
4276         my ($self, $path) = @_;
4277         $self->{path_prefix}.(defined $path ? $path : '');
4278 }
4279
4280 sub url_path {
4281         my ($self, $path) = @_;
4282         if ($self->{url} =~ m#^https?://#) {
4283                 $path =~ s!([^~a-zA-Z0-9_./-])!uc sprintf("%%%02x",ord($1))!eg;
4284         }
4285         $self->{url} . '/' . $self->repo_path($path);
4286 }
4287
4288 sub rmdirs {
4289         my ($self) = @_;
4290         my $rm = $self->{rm};
4291         delete $rm->{''}; # we never delete the url we're tracking
4292         return unless %$rm;
4293
4294         foreach (keys %$rm) {
4295                 my @d = split m#/#, $_;
4296                 my $c = shift @d;
4297                 $rm->{$c} = 1;
4298                 while (@d) {
4299                         $c .= '/' . shift @d;
4300                         $rm->{$c} = 1;
4301                 }
4302         }
4303         delete $rm->{$self->{svn_path}};
4304         delete $rm->{''}; # we never delete the url we're tracking
4305         return unless %$rm;
4306
4307         my ($fh, $ctx) = command_output_pipe(qw/ls-tree --name-only -r -z/,
4308                                              $self->{tree_b});
4309         local $/ = "\0";
4310         while (<$fh>) {
4311                 chomp;
4312                 my @dn = split m#/#, $_;
4313                 while (pop @dn) {
4314                         delete $rm->{join '/', @dn};
4315                 }
4316                 unless (%$rm) {
4317                         close $fh;
4318                         return;
4319                 }
4320         }
4321         command_close_pipe($fh, $ctx);
4322
4323         my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
4324         foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
4325                 $self->close_directory($bat->{$d}, $p);
4326                 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
4327                 print "\tD+\t$d/\n" unless $::_q;
4328                 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
4329                 delete $bat->{$d};
4330         }
4331 }
4332
4333 sub open_or_add_dir {
4334         my ($self, $full_path, $baton) = @_;
4335         my $t = $self->{types}->{$full_path};
4336         if (!defined $t) {
4337                 die "$full_path not known in r$self->{r} or we have a bug!\n";
4338         }
4339         {
4340                 no warnings 'once';
4341                 # SVN::Node::none and SVN::Node::file are used only once,
4342                 # so we're shutting up Perl's warnings about them.
4343                 if ($t == $SVN::Node::none) {
4344                         return $self->add_directory($full_path, $baton,
4345                             undef, -1, $self->{pool});
4346                 } elsif ($t == $SVN::Node::dir) {
4347                         return $self->open_directory($full_path, $baton,
4348                             $self->{r}, $self->{pool});
4349                 } # no warnings 'once'
4350                 print STDERR "$full_path already exists in repository at ",
4351                     "r$self->{r} and it is not a directory (",
4352                     ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
4353         } # no warnings 'once'
4354         exit 1;
4355 }
4356
4357 sub ensure_path {
4358         my ($self, $path) = @_;
4359         my $bat = $self->{bat};
4360         my $repo_path = $self->repo_path($path);
4361         return $bat->{''} unless (length $repo_path);
4362         my @p = split m#/+#, $repo_path;
4363         my $c = shift @p;
4364         $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
4365         while (@p) {
4366                 my $c0 = $c;
4367                 $c .= '/' . shift @p;
4368                 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
4369         }
4370         return $bat->{$c};
4371 }
4372
4373 # Subroutine to convert a globbing pattern to a regular expression.
4374 # From perl cookbook.
4375 sub glob2pat {
4376         my $globstr = shift;
4377         my %patmap = ('*' => '.*', '?' => '.', '[' => '[', ']' => ']');
4378         $globstr =~ s{(.)} { $patmap{$1} || "\Q$1" }ge;
4379         return '^' . $globstr . '$';
4380 }
4381
4382 sub check_autoprop {
4383         my ($self, $pattern, $properties, $file, $fbat) = @_;
4384         # Convert the globbing pattern to a regular expression.
4385         my $regex = glob2pat($pattern);
4386         # Check if the pattern matches the file name.
4387         if($file =~ m/($regex)/) {
4388                 # Parse the list of properties to set.
4389                 my @props = split(/;/, $properties);
4390                 foreach my $prop (@props) {
4391                         # Parse 'name=value' syntax and set the property.
4392                         if ($prop =~ /([^=]+)=(.*)/) {
4393                                 my ($n,$v) = ($1,$2);
4394                                 for ($n, $v) {
4395                                         s/^\s+//; s/\s+$//;
4396                                 }
4397                                 $self->change_file_prop($fbat, $n, $v);
4398                         }
4399                 }
4400         }
4401 }
4402
4403 sub apply_autoprops {
4404         my ($self, $file, $fbat) = @_;
4405         my $conf_t = ${$self->{config}}{'config'};
4406         no warnings 'once';
4407         # Check [miscellany]/enable-auto-props in svn configuration.
4408         if (SVN::_Core::svn_config_get_bool(
4409                 $conf_t,
4410                 $SVN::_Core::SVN_CONFIG_SECTION_MISCELLANY,
4411                 $SVN::_Core::SVN_CONFIG_OPTION_ENABLE_AUTO_PROPS,
4412                 0)) {
4413                 # Auto-props are enabled.  Enumerate them to look for matches.
4414                 my $callback = sub {
4415                         $self->check_autoprop($_[0], $_[1], $file, $fbat);
4416                 };
4417                 SVN::_Core::svn_config_enumerate(
4418                         $conf_t,
4419                         $SVN::_Core::SVN_CONFIG_SECTION_AUTO_PROPS,
4420                         $callback);
4421         }
4422 }
4423
4424 sub A {
4425         my ($self, $m) = @_;
4426         my ($dir, $file) = split_path($m->{file_b});
4427         my $pbat = $self->ensure_path($dir);
4428         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
4429                                         undef, -1);
4430         print "\tA\t$m->{file_b}\n" unless $::_q;
4431         $self->apply_autoprops($file, $fbat);
4432         $self->chg_file($fbat, $m);
4433         $self->close_file($fbat,undef,$self->{pool});
4434 }
4435
4436 sub C {
4437         my ($self, $m) = @_;
4438         my ($dir, $file) = split_path($m->{file_b});
4439         my $pbat = $self->ensure_path($dir);
4440         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
4441                                 $self->url_path($m->{file_a}), $self->{r});
4442         print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
4443         $self->chg_file($fbat, $m);
4444         $self->close_file($fbat,undef,$self->{pool});
4445 }
4446
4447 sub delete_entry {
4448         my ($self, $path, $pbat) = @_;
4449         my $rpath = $self->repo_path($path);
4450         my ($dir, $file) = split_path($rpath);
4451         $self->{rm}->{$dir} = 1;
4452         $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
4453 }
4454
4455 sub R {
4456         my ($self, $m) = @_;
4457         my ($dir, $file) = split_path($m->{file_b});
4458         my $pbat = $self->ensure_path($dir);
4459         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
4460                                 $self->url_path($m->{file_a}), $self->{r});
4461         print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
4462         $self->apply_autoprops($file, $fbat);
4463         $self->chg_file($fbat, $m);
4464         $self->close_file($fbat,undef,$self->{pool});
4465
4466         ($dir, $file) = split_path($m->{file_a});
4467         $pbat = $self->ensure_path($dir);
4468         $self->delete_entry($m->{file_a}, $pbat);
4469 }
4470
4471 sub M {
4472         my ($self, $m) = @_;
4473         my ($dir, $file) = split_path($m->{file_b});
4474         my $pbat = $self->ensure_path($dir);
4475         my $fbat = $self->open_file($self->repo_path($m->{file_b}),
4476                                 $pbat,$self->{r},$self->{pool});
4477         print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
4478         $self->chg_file($fbat, $m);
4479         $self->close_file($fbat,undef,$self->{pool});
4480 }
4481
4482 sub T { shift->M(@_) }
4483
4484 sub change_file_prop {
4485         my ($self, $fbat, $pname, $pval) = @_;
4486         $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
4487 }
4488
4489 sub _chg_file_get_blob ($$$$) {
4490         my ($self, $fbat, $m, $which) = @_;
4491         my $fh = $::_repository->temp_acquire("git_blob_$which");
4492         if ($m->{"mode_$which"} =~ /^120/) {
4493                 print $fh 'link ' or croak $!;
4494                 $self->change_file_prop($fbat,'svn:special','*');
4495         } elsif ($m->{mode_a} =~ /^120/ && $m->{"mode_$which"} !~ /^120/) {
4496                 $self->change_file_prop($fbat,'svn:special',undef);
4497         }
4498         my $blob = $m->{"sha1_$which"};
4499         return ($fh,) if ($blob =~ /^0{40}$/);
4500         my $size = $::_repository->cat_blob($blob, $fh);
4501         croak "Failed to read object $blob" if ($size < 0);
4502         $fh->flush == 0 or croak $!;
4503         seek $fh, 0, 0 or croak $!;
4504
4505         my $exp = ::md5sum($fh);
4506         seek $fh, 0, 0 or croak $!;
4507         return ($fh, $exp);
4508 }
4509
4510 sub chg_file {
4511         my ($self, $fbat, $m) = @_;
4512         if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
4513                 $self->change_file_prop($fbat,'svn:executable','*');
4514         } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
4515                 $self->change_file_prop($fbat,'svn:executable',undef);
4516         }
4517         my ($fh_a, $exp_a) = _chg_file_get_blob $self, $fbat, $m, 'a';
4518         my ($fh_b, $exp_b) = _chg_file_get_blob $self, $fbat, $m, 'b';
4519         my $pool = SVN::Pool->new;
4520         my $atd = $self->apply_textdelta($fbat, $exp_a, $pool);
4521         if (-s $fh_a) {
4522                 my $txstream = SVN::TxDelta::new ($fh_a, $fh_b, $pool);
4523                 my $res = SVN::TxDelta::send_txstream($txstream, @$atd, $pool);
4524                 if (defined $res) {
4525                         die "Unexpected result from send_txstream: $res\n",
4526                             "(SVN::Core::VERSION: $SVN::Core::VERSION)\n";
4527                 }
4528         } else {
4529                 my $got = SVN::TxDelta::send_stream($fh_b, @$atd, $pool);
4530                 die "Checksum mismatch\nexpected: $exp_b\ngot: $got\n"
4531                     if ($got ne $exp_b);
4532         }
4533         Git::temp_release($fh_b, 1);
4534         Git::temp_release($fh_a, 1);
4535         $pool->clear;
4536 }
4537
4538 sub D {
4539         my ($self, $m) = @_;
4540         my ($dir, $file) = split_path($m->{file_b});
4541         my $pbat = $self->ensure_path($dir);
4542         print "\tD\t$m->{file_b}\n" unless $::_q;
4543         $self->delete_entry($m->{file_b}, $pbat);
4544 }
4545
4546 sub close_edit {
4547         my ($self) = @_;
4548         my ($p,$bat) = ($self->{pool}, $self->{bat});
4549         foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
4550                 next if $_ eq '';
4551                 $self->close_directory($bat->{$_}, $p);
4552         }
4553         $self->close_directory($bat->{''}, $p);
4554         $self->SUPER::close_edit($p);
4555         $p->clear;
4556 }
4557
4558 sub abort_edit {
4559         my ($self) = @_;
4560         $self->SUPER::abort_edit($self->{pool});
4561 }
4562
4563 sub DESTROY {
4564         my $self = shift;
4565         $self->SUPER::DESTROY(@_);
4566         $self->{pool}->clear;
4567 }
4568
4569 # this drives the editor
4570 sub apply_diff {
4571         my ($self) = @_;
4572         my $mods = $self->{mods};
4573         my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
4574         foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
4575                 my $f = $m->{chg};
4576                 if (defined $o{$f}) {
4577                         $self->$f($m);
4578                 } else {
4579                         fatal("Invalid change type: $f");
4580                 }
4581         }
4582         $self->rmdirs if $_rmdir;
4583         if (@$mods == 0) {
4584                 $self->abort_edit;
4585         } else {
4586                 $self->close_edit;
4587         }
4588         return scalar @$mods;
4589 }
4590
4591 package Git::SVN::Ra;
4592 use vars qw/@ISA $config_dir $_log_window_size/;
4593 use strict;
4594 use warnings;
4595 my ($ra_invalid, $can_do_switch, %ignored_err, $RA);
4596
4597 BEGIN {
4598         # enforce temporary pool usage for some simple functions
4599         no strict 'refs';
4600         for my $f (qw/rev_proplist get_latest_revnum get_uuid get_repos_root
4601                       get_file/) {
4602                 my $SUPER = "SUPER::$f";
4603                 *$f = sub {
4604                         my $self = shift;
4605                         my $pool = SVN::Pool->new;
4606                         my @ret = $self->$SUPER(@_,$pool);
4607                         $pool->clear;
4608                         wantarray ? @ret : $ret[0];
4609                 };
4610         }
4611 }
4612
4613 sub _auth_providers () {
4614         [
4615           SVN::Client::get_simple_provider(),
4616           SVN::Client::get_ssl_server_trust_file_provider(),
4617           SVN::Client::get_simple_prompt_provider(
4618             \&Git::SVN::Prompt::simple, 2),
4619           SVN::Client::get_ssl_client_cert_file_provider(),
4620           SVN::Client::get_ssl_client_cert_prompt_provider(
4621             \&Git::SVN::Prompt::ssl_client_cert, 2),
4622           SVN::Client::get_ssl_client_cert_pw_file_provider(),
4623           SVN::Client::get_ssl_client_cert_pw_prompt_provider(
4624             \&Git::SVN::Prompt::ssl_client_cert_pw, 2),
4625           SVN::Client::get_username_provider(),
4626           SVN::Client::get_ssl_server_trust_prompt_provider(
4627             \&Git::SVN::Prompt::ssl_server_trust),
4628           SVN::Client::get_username_prompt_provider(
4629             \&Git::SVN::Prompt::username, 2)
4630         ]
4631 }
4632
4633 sub escape_uri_only {
4634         my ($uri) = @_;
4635         my @tmp;
4636         foreach (split m{/}, $uri) {
4637                 s/([^~\w.%+-]|%(?![a-fA-F0-9]{2}))/sprintf("%%%02X",ord($1))/eg;
4638                 push @tmp, $_;
4639         }
4640         join('/', @tmp);
4641 }
4642
4643 sub escape_url {
4644         my ($url) = @_;
4645         if ($url =~ m#^(https?)://([^/]+)(.*)$#) {
4646                 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
4647                 $url = "$scheme://$domain$uri";
4648         }
4649         $url;
4650 }
4651
4652 sub new {
4653         my ($class, $url) = @_;
4654         $url =~ s!/+$!!;
4655         return $RA if ($RA && $RA->{url} eq $url);
4656
4657         SVN::_Core::svn_config_ensure($config_dir, undef);
4658         my ($baton, $callbacks) = SVN::Core::auth_open_helper(_auth_providers);
4659         my $config = SVN::Core::config_get_config($config_dir);
4660         $RA = undef;
4661         my $dont_store_passwords = 1;
4662         my $conf_t = ${$config}{'config'};
4663         {
4664                 no warnings 'once';
4665                 # The usage of $SVN::_Core::SVN_CONFIG_* variables
4666                 # produces warnings that variables are used only once.
4667                 # I had not found the better way to shut them up, so
4668                 # the warnings of type 'once' are disabled in this block.
4669                 if (SVN::_Core::svn_config_get_bool($conf_t,
4670                     $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
4671                     $SVN::_Core::SVN_CONFIG_OPTION_STORE_PASSWORDS,
4672                     1) == 0) {
4673                         SVN::_Core::svn_auth_set_parameter($baton,
4674                             $SVN::_Core::SVN_AUTH_PARAM_DONT_STORE_PASSWORDS,
4675                             bless (\$dont_store_passwords, "_p_void"));
4676                 }
4677                 if (SVN::_Core::svn_config_get_bool($conf_t,
4678                     $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
4679                     $SVN::_Core::SVN_CONFIG_OPTION_STORE_AUTH_CREDS,
4680                     1) == 0) {
4681                         $Git::SVN::Prompt::_no_auth_cache = 1;
4682                 }
4683         } # no warnings 'once'
4684         my $self = SVN::Ra->new(url => escape_url($url), auth => $baton,
4685                               config => $config,
4686                               pool => SVN::Pool->new,
4687                               auth_provider_callbacks => $callbacks);
4688         $self->{url} = $url;
4689         $self->{svn_path} = $url;
4690         $self->{repos_root} = $self->get_repos_root;
4691         $self->{svn_path} =~ s#^\Q$self->{repos_root}\E(/|$)##;
4692         $self->{cache} = { check_path => { r => 0, data => {} },
4693                            get_dir => { r => 0, data => {} } };
4694         $RA = bless $self, $class;
4695 }
4696
4697 sub check_path {
4698         my ($self, $path, $r) = @_;
4699         my $cache = $self->{cache}->{check_path};
4700         if ($r == $cache->{r} && exists $cache->{data}->{$path}) {
4701                 return $cache->{data}->{$path};
4702         }
4703         my $pool = SVN::Pool->new;
4704         my $t = $self->SUPER::check_path($path, $r, $pool);
4705         $pool->clear;
4706         if ($r != $cache->{r}) {
4707                 %{$cache->{data}} = ();
4708                 $cache->{r} = $r;
4709         }
4710         $cache->{data}->{$path} = $t;
4711 }
4712
4713 sub get_dir {
4714         my ($self, $dir, $r) = @_;
4715         my $cache = $self->{cache}->{get_dir};
4716         if ($r == $cache->{r}) {
4717                 if (my $x = $cache->{data}->{$dir}) {
4718                         return wantarray ? @$x : $x->[0];
4719                 }
4720         }
4721         my $pool = SVN::Pool->new;
4722         my ($d, undef, $props) = $self->SUPER::get_dir($dir, $r, $pool);
4723         my %dirents = map { $_ => { kind => $d->{$_}->kind } } keys %$d;
4724         $pool->clear;
4725         if ($r != $cache->{r}) {
4726                 %{$cache->{data}} = ();
4727                 $cache->{r} = $r;
4728         }
4729         $cache->{data}->{$dir} = [ \%dirents, $r, $props ];
4730         wantarray ? (\%dirents, $r, $props) : \%dirents;
4731 }
4732
4733 sub DESTROY {
4734         # do not call the real DESTROY since we store ourselves in $RA
4735 }
4736
4737 # get_log(paths, start, end, limit,
4738 #         discover_changed_paths, strict_node_history, receiver)
4739 sub get_log {
4740         my ($self, @args) = @_;
4741         my $pool = SVN::Pool->new;
4742
4743         # svn_log_changed_path_t objects passed to get_log are likely to be
4744         # overwritten even if only the refs are copied to an external variable,
4745         # so we should dup the structures in their entirety.  Using an
4746         # externally passed pool (instead of our temporary and quickly cleared
4747         # pool in Git::SVN::Ra) does not help matters at all...
4748         my $receiver = pop @args;
4749         my $prefix = "/".$self->{svn_path};
4750         $prefix =~ s#/+($)##;
4751         my $prefix_regex = qr#^\Q$prefix\E#;
4752         push(@args, sub {
4753                 my ($paths) = $_[0];
4754                 return &$receiver(@_) unless $paths;
4755                 $_[0] = ();
4756                 foreach my $p (keys %$paths) {
4757                         my $i = $paths->{$p};
4758                         # Make path relative to our url, not repos_root
4759                         $p =~ s/$prefix_regex//;
4760                         my %s = map { $_ => $i->$_; }
4761                                 qw/copyfrom_path copyfrom_rev action/;
4762                         if ($s{'copyfrom_path'}) {
4763                                 $s{'copyfrom_path'} =~ s/$prefix_regex//;
4764                         }
4765                         $_[0]{$p} = \%s;
4766                 }
4767                 &$receiver(@_);
4768         });
4769
4770
4771         # the limit parameter was not supported in SVN 1.1.x, so we
4772         # drop it.  Therefore, the receiver callback passed to it
4773         # is made aware of this limitation by being wrapped if
4774         # the limit passed to is being wrapped.
4775         if ($SVN::Core::VERSION le '1.2.0') {
4776                 my $limit = splice(@args, 3, 1);
4777                 if ($limit > 0) {
4778                         my $receiver = pop @args;
4779                         push(@args, sub { &$receiver(@_) if (--$limit >= 0) });
4780                 }
4781         }
4782         my $ret = $self->SUPER::get_log(@args, $pool);
4783         $pool->clear;
4784         $ret;
4785 }
4786
4787 sub trees_match {
4788         my ($self, $url1, $rev1, $url2, $rev2) = @_;
4789         my $ctx = SVN::Client->new(auth => _auth_providers);
4790         my $out = IO::File->new_tmpfile;
4791
4792         # older SVN (1.1.x) doesn't take $pool as the last parameter for
4793         # $ctx->diff(), so we'll create a default one
4794         my $pool = SVN::Pool->new_default_sub;
4795
4796         $ra_invalid = 1; # this will open a new SVN::Ra connection to $url1
4797         $ctx->diff([], $url1, $rev1, $url2, $rev2, 1, 1, 0, $out, $out);
4798         $out->flush;
4799         my $ret = (($out->stat)[7] == 0);
4800         close $out or croak $!;
4801
4802         $ret;
4803 }
4804
4805 sub get_commit_editor {
4806         my ($self, $log, $cb, $pool) = @_;
4807         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
4808         $self->SUPER::get_commit_editor($log, $cb, @lock, $pool);
4809 }
4810
4811 sub gs_do_update {
4812         my ($self, $rev_a, $rev_b, $gs, $editor) = @_;
4813         my $new = ($rev_a == $rev_b);
4814         my $path = $gs->{path};
4815
4816         if ($new && -e $gs->{index}) {
4817                 unlink $gs->{index} or die
4818                   "Couldn't unlink index: $gs->{index}: $!\n";
4819         }
4820         my $pool = SVN::Pool->new;
4821         $editor->set_path_strip($path);
4822         my (@pc) = split m#/#, $path;
4823         my $reporter = $self->do_update($rev_b, (@pc ? shift @pc : ''),
4824                                         1, $editor, $pool);
4825         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
4826
4827         # Since we can't rely on svn_ra_reparent being available, we'll
4828         # just have to do some magic with set_path to make it so
4829         # we only want a partial path.
4830         my $sp = '';
4831         my $final = join('/', @pc);
4832         while (@pc) {
4833                 $reporter->set_path($sp, $rev_b, 0, @lock, $pool);
4834                 $sp .= '/' if length $sp;
4835                 $sp .= shift @pc;
4836         }
4837         die "BUG: '$sp' != '$final'\n" if ($sp ne $final);
4838
4839         $reporter->set_path($sp, $rev_a, $new, @lock, $pool);
4840
4841         $reporter->finish_report($pool);
4842         $pool->clear;
4843         $editor->{git_commit_ok};
4844 }
4845
4846 # this requires SVN 1.4.3 or later (do_switch didn't work before 1.4.3, and
4847 # svn_ra_reparent didn't work before 1.4)
4848 sub gs_do_switch {
4849         my ($self, $rev_a, $rev_b, $gs, $url_b, $editor) = @_;
4850         my $path = $gs->{path};
4851         my $pool = SVN::Pool->new;
4852
4853         my $full_url = $self->{url};
4854         my $old_url = $full_url;
4855         $full_url .= '/' . $path if length $path;
4856         my ($ra, $reparented);
4857
4858         if ($old_url =~ m#^svn(\+ssh)?://# ||
4859             ($full_url =~ m#^https?://# &&
4860              escape_url($full_url) ne $full_url)) {
4861                 $_[0] = undef;
4862                 $self = undef;
4863                 $RA = undef;
4864                 $ra = Git::SVN::Ra->new($full_url);
4865                 $ra_invalid = 1;
4866         } elsif ($old_url ne $full_url) {
4867                 SVN::_Ra::svn_ra_reparent($self->{session}, $full_url, $pool);
4868                 $self->{url} = $full_url;
4869                 $reparented = 1;
4870         }
4871
4872         $ra ||= $self;
4873         $url_b = escape_url($url_b);
4874         my $reporter = $ra->do_switch($rev_b, '', 1, $url_b, $editor, $pool);
4875         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
4876         $reporter->set_path('', $rev_a, 0, @lock, $pool);
4877         $reporter->finish_report($pool);
4878
4879         if ($reparented) {
4880                 SVN::_Ra::svn_ra_reparent($self->{session}, $old_url, $pool);
4881                 $self->{url} = $old_url;
4882         }
4883
4884         $pool->clear;
4885         $editor->{git_commit_ok};
4886 }
4887
4888 sub longest_common_path {
4889         my ($gsv, $globs) = @_;
4890         my %common;
4891         my $common_max = scalar @$gsv;
4892
4893         foreach my $gs (@$gsv) {
4894                 my @tmp = split m#/#, $gs->{path};
4895                 my $p = '';
4896                 foreach (@tmp) {
4897                         $p .= length($p) ? "/$_" : $_;
4898                         $common{$p} ||= 0;
4899                         $common{$p}++;
4900                 }
4901         }
4902         $globs ||= [];
4903         $common_max += scalar @$globs;
4904         foreach my $glob (@$globs) {
4905                 my @tmp = split m#/#, $glob->{path}->{left};
4906                 my $p = '';
4907                 foreach (@tmp) {
4908                         $p .= length($p) ? "/$_" : $_;
4909                         $common{$p} ||= 0;
4910                         $common{$p}++;
4911                 }
4912         }
4913
4914         my $longest_path = '';
4915         foreach (sort {length $b <=> length $a} keys %common) {
4916                 if ($common{$_} == $common_max) {
4917                         $longest_path = $_;
4918                         last;
4919                 }
4920         }
4921         $longest_path;
4922 }
4923
4924 sub gs_fetch_loop_common {
4925         my ($self, $base, $head, $gsv, $globs) = @_;
4926         return if ($base > $head);
4927         my $inc = $_log_window_size;
4928         my ($min, $max) = ($base, $head < $base + $inc ? $head : $base + $inc);
4929         my $longest_path = longest_common_path($gsv, $globs);
4930         my $ra_url = $self->{url};
4931         my $find_trailing_edge;
4932         while (1) {
4933                 my %revs;
4934                 my $err;
4935                 my $err_handler = $SVN::Error::handler;
4936                 $SVN::Error::handler = sub {
4937                         ($err) = @_;
4938                         skip_unknown_revs($err);
4939                 };
4940                 sub _cb {
4941                         my ($paths, $r, $author, $date, $log) = @_;
4942                         [ $paths,
4943                           { author => $author, date => $date, log => $log } ];
4944                 }
4945                 $self->get_log([$longest_path], $min, $max, 0, 1, 1,
4946                                sub { $revs{$_[1]} = _cb(@_) });
4947                 if ($err) {
4948                         print "Checked through r$max\r";
4949                 } else {
4950                         $find_trailing_edge = 1;
4951                 }
4952                 if ($err and $find_trailing_edge) {
4953                         print STDERR "Path '$longest_path' ",
4954                                      "was probably deleted:\n",
4955                                      $err->expanded_message,
4956                                      "\nWill attempt to follow ",
4957                                      "revisions r$min .. r$max ",
4958                                      "committed before the deletion\n";
4959                         my $hi = $max;
4960                         while (--$hi >= $min) {
4961                                 my $ok;
4962                                 $self->get_log([$longest_path], $min, $hi,
4963                                                0, 1, 1, sub {
4964                                                $ok = $_[1];
4965                                                $revs{$_[1]} = _cb(@_) });
4966                                 if ($ok) {
4967                                         print STDERR "r$min .. r$ok OK\n";
4968                                         last;
4969                                 }
4970                         }
4971                         $find_trailing_edge = 0;
4972                 }
4973                 $SVN::Error::handler = $err_handler;
4974
4975                 my %exists = map { $_->{path} => $_ } @$gsv;
4976                 foreach my $r (sort {$a <=> $b} keys %revs) {
4977                         my ($paths, $logged) = @{$revs{$r}};
4978
4979                         foreach my $gs ($self->match_globs(\%exists, $paths,
4980                                                            $globs, $r)) {
4981                                 if ($gs->rev_map_max >= $r) {
4982                                         next;
4983                                 }
4984                                 next unless $gs->match_paths($paths, $r);
4985                                 $gs->{logged_rev_props} = $logged;
4986                                 if (my $last_commit = $gs->last_commit) {
4987                                         $gs->assert_index_clean($last_commit);
4988                                 }
4989                                 my $log_entry = $gs->do_fetch($paths, $r);
4990                                 if ($log_entry) {
4991                                         $gs->do_git_commit($log_entry);
4992                                 }
4993                                 $INDEX_FILES{$gs->{index}} = 1;
4994                         }
4995                         foreach my $g (@$globs) {
4996                                 my $k = "svn-remote.$g->{remote}." .
4997                                         "$g->{t}-maxRev";
4998                                 Git::SVN::tmp_config($k, $r);
4999                         }
5000                         if ($ra_invalid) {
5001                                 $_[0] = undef;
5002                                 $self = undef;
5003                                 $RA = undef;
5004                                 $self = Git::SVN::Ra->new($ra_url);
5005                                 $ra_invalid = undef;
5006                         }
5007                 }
5008                 # pre-fill the .rev_db since it'll eventually get filled in
5009                 # with '0' x40 if something new gets committed
5010                 foreach my $gs (@$gsv) {
5011                         next if $gs->rev_map_max >= $max;
5012                         next if defined $gs->rev_map_get($max);
5013                         $gs->rev_map_set($max, 0 x40);
5014                 }
5015                 foreach my $g (@$globs) {
5016                         my $k = "svn-remote.$g->{remote}.$g->{t}-maxRev";
5017                         Git::SVN::tmp_config($k, $max);
5018                 }
5019                 last if $max >= $head;
5020                 $min = $max + 1;
5021                 $max += $inc;
5022                 $max = $head if ($max > $head);
5023         }
5024         Git::SVN::gc();
5025 }
5026
5027 sub get_dir_globbed {
5028         my ($self, $left, $depth, $r) = @_;
5029
5030         my @x = eval { $self->get_dir($left, $r) };
5031         return unless scalar @x == 3;
5032         my $dirents = $x[0];
5033         my @finalents;
5034         foreach my $de (keys %$dirents) {
5035                 next if $dirents->{$de}->{kind} != $SVN::Node::dir;
5036                 if ($depth > 1) {
5037                         my @args = ("$left/$de", $depth - 1, $r);
5038                         foreach my $dir ($self->get_dir_globbed(@args)) {
5039                                 push @finalents, "$de/$dir";
5040                         }
5041                 } else {
5042                         push @finalents, $de;
5043                 }
5044         }
5045         @finalents;
5046 }
5047
5048 sub match_globs {
5049         my ($self, $exists, $paths, $globs, $r) = @_;
5050
5051         sub get_dir_check {
5052                 my ($self, $exists, $g, $r) = @_;
5053
5054                 my @dirs = $self->get_dir_globbed($g->{path}->{left},
5055                                                   $g->{path}->{depth},
5056                                                   $r);
5057
5058                 foreach my $de (@dirs) {
5059                         my $p = $g->{path}->full_path($de);
5060                         next if $exists->{$p};
5061                         next if (length $g->{path}->{right} &&
5062                                  ($self->check_path($p, $r) !=
5063                                   $SVN::Node::dir));
5064                         $exists->{$p} = Git::SVN->init($self->{url}, $p, undef,
5065                                          $g->{ref}->full_path($de), 1);
5066                 }
5067         }
5068         foreach my $g (@$globs) {
5069                 if (my $path = $paths->{"/$g->{path}->{left}"}) {
5070                         if ($path->{action} =~ /^[AR]$/) {
5071                                 get_dir_check($self, $exists, $g, $r);
5072                         }
5073                 }
5074                 foreach (keys %$paths) {
5075                         if (/$g->{path}->{left_regex}/ &&
5076                             !/$g->{path}->{regex}/) {
5077                                 next if $paths->{$_}->{action} !~ /^[AR]$/;
5078                                 get_dir_check($self, $exists, $g, $r);
5079                         }
5080                         next unless /$g->{path}->{regex}/;
5081                         my $p = $1;
5082                         my $pathname = $g->{path}->full_path($p);
5083                         next if $exists->{$pathname};
5084                         next if ($self->check_path($pathname, $r) !=
5085                                  $SVN::Node::dir);
5086                         $exists->{$pathname} = Git::SVN->init(
5087                                               $self->{url}, $pathname, undef,
5088                                               $g->{ref}->full_path($p), 1);
5089                 }
5090                 my $c = '';
5091                 foreach (split m#/#, $g->{path}->{left}) {
5092                         $c .= "/$_";
5093                         next unless ($paths->{$c} &&
5094                                      ($paths->{$c}->{action} =~ /^[AR]$/));
5095                         get_dir_check($self, $exists, $g, $r);
5096                 }
5097         }
5098         values %$exists;
5099 }
5100
5101 sub minimize_url {
5102         my ($self) = @_;
5103         return $self->{url} if ($self->{url} eq $self->{repos_root});
5104         my $url = $self->{repos_root};
5105         my @components = split(m!/!, $self->{svn_path});
5106         my $c = '';
5107         do {
5108                 $url .= "/$c" if length $c;
5109                 eval {
5110                         my $ra = (ref $self)->new($url);
5111                         my $latest = $ra->get_latest_revnum;
5112                         $ra->get_log("", $latest, 0, 1, 0, 1, sub {});
5113                 };
5114         } while ($@ && ($c = shift @components));
5115         $url;
5116 }
5117
5118 sub can_do_switch {
5119         my $self = shift;
5120         unless (defined $can_do_switch) {
5121                 my $pool = SVN::Pool->new;
5122                 my $rep = eval {
5123                         $self->do_switch(1, '', 0, $self->{url},
5124                                          SVN::Delta::Editor->new, $pool);
5125                 };
5126                 if ($@) {
5127                         $can_do_switch = 0;
5128                 } else {
5129                         $rep->abort_report($pool);
5130                         $can_do_switch = 1;
5131                 }
5132                 $pool->clear;
5133         }
5134         $can_do_switch;
5135 }
5136
5137 sub skip_unknown_revs {
5138         my ($err) = @_;
5139         my $errno = $err->apr_err();
5140         # Maybe the branch we're tracking didn't
5141         # exist when the repo started, so it's
5142         # not an error if it doesn't, just continue
5143         #
5144         # Wonderfully consistent library, eh?
5145         # 160013 - svn:// and file://
5146         # 175002 - http(s)://
5147         # 175007 - http(s):// (this repo required authorization, too...)
5148         #   More codes may be discovered later...
5149         if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
5150                 my $err_key = $err->expanded_message;
5151                 # revision numbers change every time, filter them out
5152                 $err_key =~ s/\d+/\0/g;
5153                 $err_key = "$errno\0$err_key";
5154                 unless ($ignored_err{$err_key}) {
5155                         warn "W: Ignoring error from SVN, path probably ",
5156                              "does not exist: ($errno): ",
5157                              $err->expanded_message,"\n";
5158                         warn "W: Do not be alarmed at the above message ",
5159                              "git-svn is just searching aggressively for ",
5160                              "old history.\n",
5161                              "This may take a while on large repositories\n";
5162                         $ignored_err{$err_key} = 1;
5163                 }
5164                 return;
5165         }
5166         die "Error from SVN, ($errno): ", $err->expanded_message,"\n";
5167 }
5168
5169 package Git::SVN::Log;
5170 use strict;
5171 use warnings;
5172 use POSIX qw/strftime/;
5173 use Time::Local;
5174 use constant commit_log_separator => ('-' x 72) . "\n";
5175 use vars qw/$TZ $limit $color $pager $non_recursive $verbose $oneline
5176             %rusers $show_commit $incremental/;
5177 my $l_fmt;
5178
5179 sub cmt_showable {
5180         my ($c) = @_;
5181         return 1 if defined $c->{r};
5182
5183         # big commit message got truncated by the 16k pretty buffer in rev-list
5184         if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
5185                                 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
5186                 @{$c->{l}} = ();
5187                 my @log = command(qw/cat-file commit/, $c->{c});
5188
5189                 # shift off the headers
5190                 shift @log while ($log[0] ne '');
5191                 shift @log;
5192
5193                 # TODO: make $c->{l} not have a trailing newline in the future
5194                 @{$c->{l}} = map { "$_\n" } grep !/^git-svn-id: /, @log;
5195
5196                 (undef, $c->{r}, undef) = ::extract_metadata(
5197                                 (grep(/^git-svn-id: /, @log))[-1]);
5198         }
5199         return defined $c->{r};
5200 }
5201
5202 sub log_use_color {
5203         return $color || Git->repository->get_colorbool('color.diff');
5204 }
5205
5206 sub git_svn_log_cmd {
5207         my ($r_min, $r_max, @args) = @_;
5208         my $head = 'HEAD';
5209         my (@files, @log_opts);
5210         foreach my $x (@args) {
5211                 if ($x eq '--' || @files) {
5212                         push @files, $x;
5213                 } else {
5214                         if (::verify_ref("$x^0")) {
5215                                 $head = $x;
5216                         } else {
5217                                 push @log_opts, $x;
5218                         }
5219                 }
5220         }
5221
5222         my ($url, $rev, $uuid, $gs) = ::working_head_info($head);
5223         $gs ||= Git::SVN->_new;
5224         my @cmd = (qw/log --abbrev-commit --pretty=raw --default/,
5225                    $gs->refname);
5226         push @cmd, '-r' unless $non_recursive;
5227         push @cmd, qw/--raw --name-status/ if $verbose;
5228         push @cmd, '--color' if log_use_color();
5229         push @cmd, @log_opts;
5230         if (defined $r_max && $r_max == $r_min) {
5231                 push @cmd, '--max-count=1';
5232                 if (my $c = $gs->rev_map_get($r_max)) {
5233                         push @cmd, $c;
5234                 }
5235         } elsif (defined $r_max) {
5236                 if ($r_max < $r_min) {
5237                         ($r_min, $r_max) = ($r_max, $r_min);
5238                 }
5239                 my (undef, $c_max) = $gs->find_rev_before($r_max, 1, $r_min);
5240                 my (undef, $c_min) = $gs->find_rev_after($r_min, 1, $r_max);
5241                 # If there are no commits in the range, both $c_max and $c_min
5242                 # will be undefined.  If there is at least 1 commit in the
5243                 # range, both will be defined.
5244                 return () if !defined $c_min || !defined $c_max;
5245                 if ($c_min eq $c_max) {
5246                         push @cmd, '--max-count=1', $c_min;
5247                 } else {
5248                         push @cmd, '--boundary', "$c_min..$c_max";
5249                 }
5250         }
5251         return (@cmd, @files);
5252 }
5253
5254 # adapted from pager.c
5255 sub config_pager {
5256         chomp(my $pager = command_oneline(qw(var GIT_PAGER)));
5257         if ($pager eq 'cat') {
5258                 $pager = undef;
5259         }
5260         $ENV{GIT_PAGER_IN_USE} = defined($pager);
5261 }
5262
5263 sub run_pager {
5264         return unless -t *STDOUT && defined $pager;
5265         pipe my ($rfd, $wfd) or return;
5266         defined(my $pid = fork) or ::fatal "Can't fork: $!";
5267         if (!$pid) {
5268                 open STDOUT, '>&', $wfd or
5269                                      ::fatal "Can't redirect to stdout: $!";
5270                 return;
5271         }
5272         open STDIN, '<&', $rfd or ::fatal "Can't redirect stdin: $!";
5273         $ENV{LESS} ||= 'FRSX';
5274         exec $pager or ::fatal "Can't run pager: $! ($pager)";
5275 }
5276
5277 sub format_svn_date {
5278         # some systmes don't handle or mishandle %z, so be creative.
5279         my $t = shift || time;
5280         my $gm = timelocal(gmtime($t));
5281         my $sign = qw( + + - )[ $t <=> $gm ];
5282         my $gmoff = sprintf("%s%02d%02d", $sign, (gmtime(abs($t - $gm)))[2,1]);
5283         return strftime("%Y-%m-%d %H:%M:%S $gmoff (%a, %d %b %Y)", localtime($t));
5284 }
5285
5286 sub parse_git_date {
5287         my ($t, $tz) = @_;
5288         # Date::Parse isn't in the standard Perl distro :(
5289         if ($tz =~ s/^\+//) {
5290                 $t += tz_to_s_offset($tz);
5291         } elsif ($tz =~ s/^\-//) {
5292                 $t -= tz_to_s_offset($tz);
5293         }
5294         return $t;
5295 }
5296
5297 sub set_local_timezone {
5298         if (defined $TZ) {
5299                 $ENV{TZ} = $TZ;
5300         } else {
5301                 delete $ENV{TZ};
5302         }
5303 }
5304
5305 sub tz_to_s_offset {
5306         my ($tz) = @_;
5307         $tz =~ s/(\d\d)$//;
5308         return ($1 * 60) + ($tz * 3600);
5309 }
5310
5311 sub get_author_info {
5312         my ($dest, $author, $t, $tz) = @_;
5313         $author =~ s/(?:^\s*|\s*$)//g;
5314         $dest->{a_raw} = $author;
5315         my $au;
5316         if ($::_authors) {
5317                 $au = $rusers{$author} || undef;
5318         }
5319         if (!$au) {
5320                 ($au) = ($author =~ /<([^>]+)\@[^>]+>$/);
5321         }
5322         $dest->{t} = $t;
5323         $dest->{tz} = $tz;
5324         $dest->{a} = $au;
5325         $dest->{t_utc} = parse_git_date($t, $tz);
5326 }
5327
5328 sub process_commit {
5329         my ($c, $r_min, $r_max, $defer) = @_;
5330         if (defined $r_min && defined $r_max) {
5331                 if ($r_min == $c->{r} && $r_min == $r_max) {
5332                         show_commit($c);
5333                         return 0;
5334                 }
5335                 return 1 if $r_min == $r_max;
5336                 if ($r_min < $r_max) {
5337                         # we need to reverse the print order
5338                         return 0 if (defined $limit && --$limit < 0);
5339                         push @$defer, $c;
5340                         return 1;
5341                 }
5342                 if ($r_min != $r_max) {
5343                         return 1 if ($r_min < $c->{r});
5344                         return 1 if ($r_max > $c->{r});
5345                 }
5346         }
5347         return 0 if (defined $limit && --$limit < 0);
5348         show_commit($c);
5349         return 1;
5350 }
5351
5352 sub show_commit {
5353         my $c = shift;
5354         if ($oneline) {
5355                 my $x = "\n";
5356                 if (my $l = $c->{l}) {
5357                         while ($l->[0] =~ /^\s*$/) { shift @$l }
5358                         $x = $l->[0];
5359                 }
5360                 $l_fmt ||= 'A' . length($c->{r});
5361                 print 'r',pack($l_fmt, $c->{r}),' | ';
5362                 print "$c->{c} | " if $show_commit;
5363                 print $x;
5364         } else {
5365                 show_commit_normal($c);
5366         }
5367 }
5368
5369 sub show_commit_changed_paths {
5370         my ($c) = @_;
5371         return unless $c->{changed};
5372         print "Changed paths:\n", @{$c->{changed}};
5373 }
5374
5375 sub show_commit_normal {
5376         my ($c) = @_;
5377         print commit_log_separator, "r$c->{r} | ";
5378         print "$c->{c} | " if $show_commit;
5379         print "$c->{a} | ", format_svn_date($c->{t_utc}), ' | ';
5380         my $nr_line = 0;
5381
5382         if (my $l = $c->{l}) {
5383                 while ($l->[$#$l] eq "\n" && $#$l > 0
5384                                           && $l->[($#$l - 1)] eq "\n") {
5385                         pop @$l;
5386                 }
5387                 $nr_line = scalar @$l;
5388                 if (!$nr_line) {
5389                         print "1 line\n\n\n";
5390                 } else {
5391                         if ($nr_line == 1) {
5392                                 $nr_line = '1 line';
5393                         } else {
5394                                 $nr_line .= ' lines';
5395                         }
5396                         print $nr_line, "\n";
5397                         show_commit_changed_paths($c);
5398                         print "\n";
5399                         print $_ foreach @$l;
5400                 }
5401         } else {
5402                 print "1 line\n";
5403                 show_commit_changed_paths($c);
5404                 print "\n";
5405
5406         }
5407         foreach my $x (qw/raw stat diff/) {
5408                 if ($c->{$x}) {
5409                         print "\n";
5410                         print $_ foreach @{$c->{$x}}
5411                 }
5412         }
5413 }
5414
5415 sub cmd_show_log {
5416         my (@args) = @_;
5417         my ($r_min, $r_max);
5418         my $r_last = -1; # prevent dupes
5419         set_local_timezone();
5420         if (defined $::_revision) {
5421                 if ($::_revision =~ /^(\d+):(\d+)$/) {
5422                         ($r_min, $r_max) = ($1, $2);
5423                 } elsif ($::_revision =~ /^\d+$/) {
5424                         $r_min = $r_max = $::_revision;
5425                 } else {
5426                         ::fatal "-r$::_revision is not supported, use ",
5427                                 "standard 'git log' arguments instead";
5428                 }
5429         }
5430
5431         config_pager();
5432         @args = git_svn_log_cmd($r_min, $r_max, @args);
5433         if (!@args) {
5434                 print commit_log_separator unless $incremental || $oneline;
5435                 return;
5436         }
5437         my $log = command_output_pipe(@args);
5438         run_pager();
5439         my (@k, $c, $d, $stat);
5440         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
5441         while (<$log>) {
5442                 if (/^${esc_color}commit -?($::sha1_short)/o) {
5443                         my $cmt = $1;
5444                         if ($c && cmt_showable($c) && $c->{r} != $r_last) {
5445                                 $r_last = $c->{r};
5446                                 process_commit($c, $r_min, $r_max, \@k) or
5447                                                                 goto out;
5448                         }
5449                         $d = undef;
5450                         $c = { c => $cmt };
5451                 } elsif (/^${esc_color}author (.+) (\d+) ([\-\+]?\d+)$/o) {
5452                         get_author_info($c, $1, $2, $3);
5453                 } elsif (/^${esc_color}(?:tree|parent|committer) /o) {
5454                         # ignore
5455                 } elsif (/^${esc_color}:\d{6} \d{6} $::sha1_short/o) {
5456                         push @{$c->{raw}}, $_;
5457                 } elsif (/^${esc_color}[ACRMDT]\t/) {
5458                         # we could add $SVN->{svn_path} here, but that requires
5459                         # remote access at the moment (repo_path_split)...
5460                         s#^(${esc_color})([ACRMDT])\t#$1   $2 #o;
5461                         push @{$c->{changed}}, $_;
5462                 } elsif (/^${esc_color}diff /o) {
5463                         $d = 1;
5464                         push @{$c->{diff}}, $_;
5465                 } elsif ($d) {
5466                         push @{$c->{diff}}, $_;
5467                 } elsif (/^\ .+\ \|\s*\d+\ $esc_color[\+\-]*
5468                           $esc_color*[\+\-]*$esc_color$/x) {
5469                         $stat = 1;
5470                         push @{$c->{stat}}, $_;
5471                 } elsif ($stat && /^ \d+ files changed, \d+ insertions/) {
5472                         push @{$c->{stat}}, $_;
5473                         $stat = undef;
5474                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
5475                         ($c->{url}, $c->{r}, undef) = ::extract_metadata($1);
5476                 } elsif (s/^${esc_color}    //o) {
5477                         push @{$c->{l}}, $_;
5478                 }
5479         }
5480         if ($c && defined $c->{r} && $c->{r} != $r_last) {
5481                 $r_last = $c->{r};
5482                 process_commit($c, $r_min, $r_max, \@k);
5483         }
5484         if (@k) {
5485                 ($r_min, $r_max) = ($r_max, $r_min);
5486                 process_commit($_, $r_min, $r_max) foreach reverse @k;
5487         }
5488 out:
5489         close $log;
5490         print commit_log_separator unless $incremental || $oneline;
5491 }
5492
5493 sub cmd_blame {
5494         my $path = pop;
5495
5496         config_pager();
5497         run_pager();
5498
5499         my ($fh, $ctx, $rev);
5500
5501         if ($_git_format) {
5502                 ($fh, $ctx) = command_output_pipe('blame', @_, $path);
5503                 while (my $line = <$fh>) {
5504                         if ($line =~ /^\^?([[:xdigit:]]+)\s/) {
5505                                 # Uncommitted edits show up as a rev ID of
5506                                 # all zeros, which we can't look up with
5507                                 # cmt_metadata
5508                                 if ($1 !~ /^0+$/) {
5509                                         (undef, $rev, undef) =
5510                                                 ::cmt_metadata($1);
5511                                         $rev = '0' if (!$rev);
5512                                 } else {
5513                                         $rev = '0';
5514                                 }
5515                                 $rev = sprintf('%-10s', $rev);
5516                                 $line =~ s/^\^?[[:xdigit:]]+(\s)/$rev$1/;
5517                         }
5518                         print $line;
5519                 }
5520         } else {
5521                 ($fh, $ctx) = command_output_pipe('blame', '-p', @_, 'HEAD',
5522                                                   '--', $path);
5523                 my ($sha1);
5524                 my %authors;
5525                 my @buffer;
5526                 my %dsha; #distinct sha keys
5527
5528                 while (my $line = <$fh>) {
5529                         push @buffer, $line;
5530                         if ($line =~ /^([[:xdigit:]]{40})\s\d+\s\d+/) {
5531                                 $dsha{$1} = 1;
5532                         }
5533                 }
5534
5535                 my $s2r = ::cmt_sha2rev_batch([keys %dsha]);
5536
5537                 foreach my $line (@buffer) {
5538                         if ($line =~ /^([[:xdigit:]]{40})\s\d+\s\d+/) {
5539                                 $rev = $s2r->{$1};
5540                                 $rev = '0' if (!$rev)
5541                         }
5542                         elsif ($line =~ /^author (.*)/) {
5543                                 $authors{$rev} = $1;
5544                                 $authors{$rev} =~ s/\s/_/g;
5545                         }
5546                         elsif ($line =~ /^\t(.*)$/) {
5547                                 printf("%6s %10s %s\n", $rev, $authors{$rev}, $1);
5548                         }
5549                 }
5550         }
5551         command_close_pipe($fh, $ctx);
5552 }
5553
5554 package Git::SVN::Migration;
5555 # these version numbers do NOT correspond to actual version numbers
5556 # of git nor git-svn.  They are just relative.
5557 #
5558 # v0 layout: .git/$id/info/url, refs/heads/$id-HEAD
5559 #
5560 # v1 layout: .git/$id/info/url, refs/remotes/$id
5561 #
5562 # v2 layout: .git/svn/$id/info/url, refs/remotes/$id
5563 #
5564 # v3 layout: .git/svn/$id, refs/remotes/$id
5565 #            - info/url may remain for backwards compatibility
5566 #            - this is what we migrate up to this layout automatically,
5567 #            - this will be used by git svn init on single branches
5568 # v3.1 layout (auto migrated):
5569 #            - .rev_db => .rev_db.$UUID, .rev_db will remain as a symlink
5570 #              for backwards compatibility
5571 #
5572 # v4 layout: .git/svn/$repo_id/$id, refs/remotes/$repo_id/$id
5573 #            - this is only created for newly multi-init-ed
5574 #              repositories.  Similar in spirit to the
5575 #              --use-separate-remotes option in git-clone (now default)
5576 #            - we do not automatically migrate to this (following
5577 #              the example set by core git)
5578 #
5579 # v5 layout: .rev_db.$UUID => .rev_map.$UUID
5580 #            - newer, more-efficient format that uses 24-bytes per record
5581 #              with no filler space.
5582 #            - use xxd -c24 < .rev_map.$UUID to view and debug
5583 #            - This is a one-way migration, repositories updated to the
5584 #              new format will not be able to use old git-svn without
5585 #              rebuilding the .rev_db.  Rebuilding the rev_db is not
5586 #              possible if noMetadata or useSvmProps are set; but should
5587 #              be no problem for users that use the (sensible) defaults.
5588 use strict;
5589 use warnings;
5590 use Carp qw/croak/;
5591 use File::Path qw/mkpath/;
5592 use File::Basename qw/dirname basename/;
5593 use vars qw/$_minimize/;
5594
5595 sub migrate_from_v0 {
5596         my $git_dir = $ENV{GIT_DIR};
5597         return undef unless -d $git_dir;
5598         my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
5599         my $migrated = 0;
5600         while (<$fh>) {
5601                 chomp;
5602                 my ($id, $orig_ref) = ($_, $_);
5603                 next unless $id =~ s#^refs/heads/(.+)-HEAD$#$1#;
5604                 next unless -f "$git_dir/$id/info/url";
5605                 my $new_ref = "refs/remotes/$id";
5606                 if (::verify_ref("$new_ref^0")) {
5607                         print STDERR "W: $orig_ref is probably an old ",
5608                                      "branch used by an ancient version of ",
5609                                      "git-svn.\n",
5610                                      "However, $new_ref also exists.\n",
5611                                      "We will not be able ",
5612                                      "to use this branch until this ",
5613                                      "ambiguity is resolved.\n";
5614                         next;
5615                 }
5616                 print STDERR "Migrating from v0 layout...\n" if !$migrated;
5617                 print STDERR "Renaming ref: $orig_ref => $new_ref\n";
5618                 command_noisy('update-ref', $new_ref, $orig_ref);
5619                 command_noisy('update-ref', '-d', $orig_ref, $orig_ref);
5620                 $migrated++;
5621         }
5622         command_close_pipe($fh, $ctx);
5623         print STDERR "Done migrating from v0 layout...\n" if $migrated;
5624         $migrated;
5625 }
5626
5627 sub migrate_from_v1 {
5628         my $git_dir = $ENV{GIT_DIR};
5629         my $migrated = 0;
5630         return $migrated unless -d $git_dir;
5631         my $svn_dir = "$git_dir/svn";
5632
5633         # just in case somebody used 'svn' as their $id at some point...
5634         return $migrated if -d $svn_dir && ! -f "$svn_dir/info/url";
5635
5636         print STDERR "Migrating from a git-svn v1 layout...\n";
5637         mkpath([$svn_dir]);
5638         print STDERR "Data from a previous version of git-svn exists, but\n\t",
5639                      "$svn_dir\n\t(required for this version ",
5640                      "($::VERSION) of git-svn) does not exist.\n";
5641         my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
5642         while (<$fh>) {
5643                 my $x = $_;
5644                 next unless $x =~ s#^refs/remotes/##;
5645                 chomp $x;
5646                 next unless -f "$git_dir/$x/info/url";
5647                 my $u = eval { ::file_to_s("$git_dir/$x/info/url") };
5648                 next unless $u;
5649                 my $dn = dirname("$git_dir/svn/$x");
5650                 mkpath([$dn]) unless -d $dn;
5651                 if ($x eq 'svn') { # they used 'svn' as GIT_SVN_ID:
5652                         mkpath(["$git_dir/svn/svn"]);
5653                         print STDERR " - $git_dir/$x/info => ",
5654                                         "$git_dir/svn/$x/info\n";
5655                         rename "$git_dir/$x/info", "$git_dir/svn/$x/info" or
5656                                croak "$!: $x";
5657                         # don't worry too much about these, they probably
5658                         # don't exist with repos this old (save for index,
5659                         # and we can easily regenerate that)
5660                         foreach my $f (qw/unhandled.log index .rev_db/) {
5661                                 rename "$git_dir/$x/$f", "$git_dir/svn/$x/$f";
5662                         }
5663                 } else {
5664                         print STDERR " - $git_dir/$x => $git_dir/svn/$x\n";
5665                         rename "$git_dir/$x", "$git_dir/svn/$x" or
5666                                croak "$!: $x";
5667                 }
5668                 $migrated++;
5669         }
5670         command_close_pipe($fh, $ctx);
5671         print STDERR "Done migrating from a git-svn v1 layout\n";
5672         $migrated;
5673 }
5674
5675 sub read_old_urls {
5676         my ($l_map, $pfx, $path) = @_;
5677         my @dir;
5678         foreach (<$path/*>) {
5679                 if (-r "$_/info/url") {
5680                         $pfx .= '/' if $pfx && $pfx !~ m!/$!;
5681                         my $ref_id = $pfx . basename $_;
5682                         my $url = ::file_to_s("$_/info/url");
5683                         $l_map->{$ref_id} = $url;
5684                 } elsif (-d $_) {
5685                         push @dir, $_;
5686                 }
5687         }
5688         foreach (@dir) {
5689                 my $x = $_;
5690                 $x =~ s!^\Q$ENV{GIT_DIR}\E/svn/!!o;
5691                 read_old_urls($l_map, $x, $_);
5692         }
5693 }
5694
5695 sub migrate_from_v2 {
5696         my @cfg = command(qw/config -l/);
5697         return if grep /^svn-remote\..+\.url=/, @cfg;
5698         my %l_map;
5699         read_old_urls(\%l_map, '', "$ENV{GIT_DIR}/svn");
5700         my $migrated = 0;
5701
5702         foreach my $ref_id (sort keys %l_map) {
5703                 eval { Git::SVN->init($l_map{$ref_id}, '', undef, $ref_id) };
5704                 if ($@) {
5705                         Git::SVN->init($l_map{$ref_id}, '', $ref_id, $ref_id);
5706                 }
5707                 $migrated++;
5708         }
5709         $migrated;
5710 }
5711
5712 sub minimize_connections {
5713         my $r = Git::SVN::read_all_remotes();
5714         my $new_urls = {};
5715         my $root_repos = {};
5716         foreach my $repo_id (keys %$r) {
5717                 my $url = $r->{$repo_id}->{url} or next;
5718                 my $fetch = $r->{$repo_id}->{fetch} or next;
5719                 my $ra = Git::SVN::Ra->new($url);
5720
5721                 # skip existing cases where we already connect to the root
5722                 if (($ra->{url} eq $ra->{repos_root}) ||
5723                     ($ra->{repos_root} eq $repo_id)) {
5724                         $root_repos->{$ra->{url}} = $repo_id;
5725                         next;
5726                 }
5727
5728                 my $root_ra = Git::SVN::Ra->new($ra->{repos_root});
5729                 my $root_path = $ra->{url};
5730                 $root_path =~ s#^\Q$ra->{repos_root}\E(/|$)##;
5731                 foreach my $path (keys %$fetch) {
5732                         my $ref_id = $fetch->{$path};
5733                         my $gs = Git::SVN->new($ref_id, $repo_id, $path);
5734
5735                         # make sure we can read when connecting to
5736                         # a higher level of a repository
5737                         my ($last_rev, undef) = $gs->last_rev_commit;
5738                         if (!defined $last_rev) {
5739                                 $last_rev = eval {
5740                                         $root_ra->get_latest_revnum;
5741                                 };
5742                                 next if $@;
5743                         }
5744                         my $new = $root_path;
5745                         $new .= length $path ? "/$path" : '';
5746                         eval {
5747                                 $root_ra->get_log([$new], $last_rev, $last_rev,
5748                                                   0, 0, 1, sub { });
5749                         };
5750                         next if $@;
5751                         $new_urls->{$ra->{repos_root}}->{$new} =
5752                                 { ref_id => $ref_id,
5753                                   old_repo_id => $repo_id,
5754                                   old_path => $path };
5755                 }
5756         }
5757
5758         my @emptied;
5759         foreach my $url (keys %$new_urls) {
5760                 # see if we can re-use an existing [svn-remote "repo_id"]
5761                 # instead of creating a(n ugly) new section:
5762                 my $repo_id = $root_repos->{$url} || $url;
5763
5764                 my $fetch = $new_urls->{$url};
5765                 foreach my $path (keys %$fetch) {
5766                         my $x = $fetch->{$path};
5767                         Git::SVN->init($url, $path, $repo_id, $x->{ref_id});
5768                         my $pfx = "svn-remote.$x->{old_repo_id}";
5769
5770                         my $old_fetch = quotemeta("$x->{old_path}:".
5771                                                   "$x->{ref_id}");
5772                         command_noisy(qw/config --unset/,
5773                                       "$pfx.fetch", '^'. $old_fetch . '$');
5774                         delete $r->{$x->{old_repo_id}}->
5775                                {fetch}->{$x->{old_path}};
5776                         if (!keys %{$r->{$x->{old_repo_id}}->{fetch}}) {
5777                                 command_noisy(qw/config --unset/,
5778                                               "$pfx.url");
5779                                 push @emptied, $x->{old_repo_id}
5780                         }
5781                 }
5782         }
5783         if (@emptied) {
5784                 my $file = $ENV{GIT_CONFIG} || "$ENV{GIT_DIR}/config";
5785                 print STDERR <<EOF;
5786 The following [svn-remote] sections in your config file ($file) are empty
5787 and can be safely removed:
5788 EOF
5789                 print STDERR "[svn-remote \"$_\"]\n" foreach @emptied;
5790         }
5791 }
5792
5793 sub migration_check {
5794         migrate_from_v0();
5795         migrate_from_v1();
5796         migrate_from_v2();
5797         minimize_connections() if $_minimize;
5798 }
5799
5800 package Git::IndexInfo;
5801 use strict;
5802 use warnings;
5803 use Git qw/command_input_pipe command_close_pipe/;
5804
5805 sub new {
5806         my ($class) = @_;
5807         my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
5808         bless { gui => $gui, ctx => $ctx, nr => 0}, $class;
5809 }
5810
5811 sub remove {
5812         my ($self, $path) = @_;
5813         if (print { $self->{gui} } '0 ', 0 x 40, "\t", $path, "\0") {
5814                 return ++$self->{nr};
5815         }
5816         undef;
5817 }
5818
5819 sub update {
5820         my ($self, $mode, $hash, $path) = @_;
5821         if (print { $self->{gui} } $mode, ' ', $hash, "\t", $path, "\0") {
5822                 return ++$self->{nr};
5823         }
5824         undef;
5825 }
5826
5827 sub DESTROY {
5828         my ($self) = @_;
5829         command_close_pipe($self->{gui}, $self->{ctx});
5830 }
5831
5832 package Git::SVN::GlobSpec;
5833 use strict;
5834 use warnings;
5835
5836 sub new {
5837         my ($class, $glob) = @_;
5838         my $re = $glob;
5839         $re =~ s!/+$!!g; # no need for trailing slashes
5840         $re =~ m!^([^*]*)(\*(?:/\*)*)(.*)$!;
5841         my $temp = $re;
5842         my ($left, $right) = ($1, $3);
5843         $re = $2;
5844         my $depth = $re =~ tr/*/*/;
5845         if ($depth != $temp =~ tr/*/*/) {
5846                 die "Only one set of wildcard directories " .
5847                         "(e.g. '*' or '*/*/*') is supported: '$glob'\n";
5848         }
5849         if ($depth == 0) {
5850                 die "One '*' is needed for glob: '$glob'\n";
5851         }
5852         $re =~ s!\*!\[^/\]*!g;
5853         $re = quotemeta($left) . "($re)" . quotemeta($right);
5854         if (length $left && !($left =~ s!/+$!!g)) {
5855                 die "Missing trailing '/' on left side of: '$glob' ($left)\n";
5856         }
5857         if (length $right && !($right =~ s!^/+!!g)) {
5858                 die "Missing leading '/' on right side of: '$glob' ($right)\n";
5859         }
5860         my $left_re = qr/^\/\Q$left\E(\/|$)/;
5861         bless { left => $left, right => $right, left_regex => $left_re,
5862                 regex => qr/$re/, glob => $glob, depth => $depth }, $class;
5863 }
5864
5865 sub full_path {
5866         my ($self, $path) = @_;
5867         return (length $self->{left} ? "$self->{left}/" : '') .
5868                $path . (length $self->{right} ? "/$self->{right}" : '');
5869 }
5870
5871 __END__
5872
5873 Data structures:
5874
5875
5876 $remotes = { # returned by read_all_remotes()
5877         'svn' => {
5878                 # svn-remote.svn.url=https://svn.musicpd.org
5879                 url => 'https://svn.musicpd.org',
5880                 # svn-remote.svn.fetch=mpd/trunk:trunk
5881                 fetch => {
5882                         'mpd/trunk' => 'trunk',
5883                 },
5884                 # svn-remote.svn.tags=mpd/tags/*:tags/*
5885                 tags => {
5886                         path => {
5887                                 left => 'mpd/tags',
5888                                 right => '',
5889                                 regex => qr!mpd/tags/([^/]+)$!,
5890                                 glob => 'tags/*',
5891                         },
5892                         ref => {
5893                                 left => 'tags',
5894                                 right => '',
5895                                 regex => qr!tags/([^/]+)$!,
5896                                 glob => 'tags/*',
5897                         },
5898                 }
5899         }
5900 };
5901
5902 $log_entry hashref as returned by libsvn_log_entry()
5903 {
5904         log => 'whitespace-formatted log entry
5905 ',                                              # trailing newline is preserved
5906         revision => '8',                        # integer
5907         date => '2004-02-24T17:01:44.108345Z',  # commit date
5908         author => 'committer name'
5909 };
5910
5911
5912 # this is generated by generate_diff();
5913 @mods = array of diff-index line hashes, each element represents one line
5914         of diff-index output
5915
5916 diff-index line ($m hash)
5917 {
5918         mode_a => first column of diff-index output, no leading ':',
5919         mode_b => second column of diff-index output,
5920         sha1_b => sha1sum of the final blob,
5921         chg => change type [MCRADT],
5922         file_a => original file name of a file (iff chg is 'C' or 'R')
5923         file_b => new/current file name of a file (any chg)
5924 }
5925 ;
5926
5927 # retval of read_url_paths{,_all}();
5928 $l_map = {
5929         # repository root url
5930         'https://svn.musicpd.org' => {
5931                 # repository path               # GIT_SVN_ID
5932                 'mpd/trunk'             =>      'trunk',
5933                 'mpd/tags/0.11.5'       =>      'tags/0.11.5',
5934         },
5935 }
5936
5937 Notes:
5938         I don't trust the each() function on unless I created %hash myself
5939         because the internal iterator may not have started at base.