include/asm-generic/vmlinux.lds.h

   1 /*
   2  * Helper macros to support writing architecture specific
   3  * linker scripts.
   4  *
   5  * A minimal linker scripts has following content:
   6  * [This is a sample, architectures may have special requiriements]
   7  *
   8  * OUTPUT_FORMAT(...)
   9  * OUTPUT_ARCH(...)
  10  * ENTRY(...)
  11  * SECTIONS
  12  * {
  13  *      . = START;
  14  *      __init_begin = .;
  15  *      HEAD_TEXT_SECTION
  16  *      INIT_TEXT_SECTION(PAGE_SIZE)
  17  *      INIT_DATA_SECTION(...)
  18  *      PERCPU_SECTION(CACHELINE_SIZE)
  19  *      __init_end = .;
  20  *
  21  *      _stext = .;
  22  *      TEXT_SECTION = 0
  23  *      _etext = .;
  24  *
  25  *      _sdata = .;
  26  *      RO_DATA_SECTION(PAGE_SIZE)
  27  *      RW_DATA_SECTION(...)
  28  *      _edata = .;
  29  *
  30  *      EXCEPTION_TABLE(...)
  31  *      NOTES
  32  *
  33  *      BSS_SECTION(0, 0, 0)
  34  *      _end = .;
  35  *
  36  *      STABS_DEBUG
  37  *      DWARF_DEBUG
  38  *
  39  *      DISCARDS                // must be the last
  40  * }
  41  *
  42  * [__init_begin, __init_end] is the init section that may be freed after init
  43  *      // __init_begin and __init_end should be page aligned, so that we can
  44  *      // free the whole .init memory
  45  * [_stext, _etext] is the text section
  46  * [_sdata, _edata] is the data section
  47  *
  48  * Some of the included output section have their own set of constants.
  49  * Examples are: [__initramfs_start, __initramfs_end] for initramfs and
  50  *               [__nosave_begin, __nosave_end] for the nosave data
  51  */
  52
  53 #ifndef LOAD_OFFSET
  54 #define LOAD_OFFSET 0
  55 #endif
  56
  57 #include <linux/export.h>
  58
  59 /* Align . to a 8 byte boundary equals to maximum function alignment. */
  60 #define ALIGN_FUNCTION()  . = ALIGN(8)
  61
  62 /*
  63  * LD_DEAD_CODE_DATA_ELIMINATION option enables -fdata-sections, which
  64  * generates .data.identifier sections, which need to be pulled in with
  65  * .data. We don't want to pull in .data..other sections, which Linux
  66  * has defined. Same for text and bss.
  67  *
  68  * RODATA_MAIN is not used because existing code already defines .rodata.x
  69  * sections to be brought in with rodata.
  70  */
  71 #ifdef CONFIG_LD_DEAD_CODE_DATA_ELIMINATION
  72 #define TEXT_MAIN .text .text.[0-9a-zA-Z_]*
  73 #define DATA_MAIN .data .data.[0-9a-zA-Z_]*
  74 #define SDATA_MAIN .sdata .sdata.[0-9a-zA-Z_]*
  75 #define RODATA_MAIN .rodata .rodata.[0-9a-zA-Z_]*
  76 #define BSS_MAIN .bss .bss.[0-9a-zA-Z_]*
  77 #define SBSS_MAIN .sbss .sbss.[0-9a-zA-Z_]*
  78 #else
  79 #define TEXT_MAIN .text
  80 #define DATA_MAIN .data
  81 #define SDATA_MAIN .sdata
  82 #define RODATA_MAIN .rodata
  83 #define BSS_MAIN .bss
  84 #define SBSS_MAIN .sbss
  85 #endif
  86
  87 /*
  88  * Align to a 32 byte boundary equal to the
  89  * alignment gcc 4.5 uses for a struct
  90  */
  91 #define STRUCT_ALIGNMENT 32
  92 #define STRUCT_ALIGN() . = ALIGN(STRUCT_ALIGNMENT)
  93
  94 /* The actual configuration determine if the init/exit sections
  95  * are handled as text/data or they can be discarded (which
  96  * often happens at runtime)
  97  */
  98 #ifdef CONFIG_HOTPLUG_CPU
  99 #define CPU_KEEP(sec)    *(.cpu##sec)
 100 #define CPU_DISCARD(sec)
 101 #else
 102 #define CPU_KEEP(sec)
 103 #define CPU_DISCARD(sec) *(.cpu##sec)
 104 #endif
 105
 106 #if defined(CONFIG_MEMORY_HOTPLUG)
 107 #define MEM_KEEP(sec)    *(.mem##sec)
 108 #define MEM_DISCARD(sec)
 109 #else
 110 #define MEM_KEEP(sec)
 111 #define MEM_DISCARD(sec) *(.mem##sec)
 112 #endif
 113
 114 #ifdef CONFIG_FTRACE_MCOUNT_RECORD
 115 #define MCOUNT_REC()    . = ALIGN(8);                           \
 116                         __start_mcount_loc = .;                 \
 117                         KEEP(*(__mcount_loc))                   \
 118                         __stop_mcount_loc = .;
 119 #else
 120 #define MCOUNT_REC()
 121 #endif
 122
 123 #ifdef CONFIG_TRACE_BRANCH_PROFILING
 124 #define LIKELY_PROFILE()        __start_annotated_branch_profile = .;   \
 125                                 KEEP(*(_ftrace_annotated_branch))       \
 126                                 __stop_annotated_branch_profile = .;
 127 #else
 128 #define LIKELY_PROFILE()
 129 #endif
 130
 131 #ifdef CONFIG_PROFILE_ALL_BRANCHES
 132 #define BRANCH_PROFILE()        __start_branch_profile = .;             \
 133                                 KEEP(*(_ftrace_branch))                 \
 134                                 __stop_branch_profile = .;
 135 #else
 136 #define BRANCH_PROFILE()
 137 #endif
 138
 139 #ifdef CONFIG_KPROBES
 140 #define KPROBE_BLACKLIST()      . = ALIGN(8);                                 \
 141                                 __start_kprobe_blacklist = .;                 \
 142                                 KEEP(*(_kprobe_blacklist))                    \
 143                                 __stop_kprobe_blacklist = .;
 144 #else
 145 #define KPROBE_BLACKLIST()
 146 #endif
 147
 148 #ifdef CONFIG_FUNCTION_ERROR_INJECTION
 149 #define ERROR_INJECT_WHITELIST()        STRUCT_ALIGN();                       \
 150                         __start_error_injection_whitelist = .;                \
 151                         KEEP(*(_error_injection_whitelist))                   \
 152                         __stop_error_injection_whitelist = .;
 153 #else
 154 #define ERROR_INJECT_WHITELIST()
 155 #endif
 156
 157 #ifdef CONFIG_EVENT_TRACING
 158 #define FTRACE_EVENTS() . = ALIGN(8);                                   \
 159                         __start_ftrace_events = .;                      \
 160                         KEEP(*(_ftrace_events))                         \
 161                         __stop_ftrace_events = .;                       \
 162                         __start_ftrace_eval_maps = .;                   \
 163                         KEEP(*(_ftrace_eval_map))                       \
 164                         __stop_ftrace_eval_maps = .;
 165 #else
 166 #define FTRACE_EVENTS()
 167 #endif
 168
 169 #ifdef CONFIG_TRACING
 170 #define TRACE_PRINTKS()  __start___trace_bprintk_fmt = .;      \
 171                          KEEP(*(__trace_printk_fmt)) /* Trace_printk fmt' pointer */ \
 172                          __stop___trace_bprintk_fmt = .;
 173 #define TRACEPOINT_STR() __start___tracepoint_str = .;  \
 174                          KEEP(*(__tracepoint_str)) /* Trace_printk fmt' pointer */ \
 175                          __stop___tracepoint_str = .;
 176 #else
 177 #define TRACE_PRINTKS()
 178 #define TRACEPOINT_STR()
 179 #endif
 180
 181 #ifdef CONFIG_FTRACE_SYSCALLS
 182 #define TRACE_SYSCALLS() . = ALIGN(8);                                  \
 183                          __start_syscalls_metadata = .;                 \
 184                          KEEP(*(__syscalls_metadata))                   \
 185                          __stop_syscalls_metadata = .;
 186 #else
 187 #define TRACE_SYSCALLS()
 188 #endif
 189
 190 #ifdef CONFIG_BPF_EVENTS
 191 #define BPF_RAW_TP() STRUCT_ALIGN();                                    \
 192                          __start__bpf_raw_tp = .;                       \
 193                          KEEP(*(__bpf_raw_tp_map))                      \
 194                          __stop__bpf_raw_tp = .;
 195 #else
 196 #define BPF_RAW_TP()
 197 #endif
 198
 199 #ifdef CONFIG_SERIAL_EARLYCON
 200 #define EARLYCON_TABLE() . = ALIGN(8);                          \
 201                          __earlycon_table = .;                  \
 202                          KEEP(*(__earlycon_table))              \
 203                          __earlycon_table_end = .;
 204 #else
 205 #define EARLYCON_TABLE()
 206 #endif
 207
 208 #define ___OF_TABLE(cfg, name)  _OF_TABLE_##cfg(name)
 209 #define __OF_TABLE(cfg, name)   ___OF_TABLE(cfg, name)
 210 #define OF_TABLE(cfg, name)     __OF_TABLE(IS_ENABLED(cfg), name)
 211 #define _OF_TABLE_0(name)
 212 #define _OF_TABLE_1(name)                                               \
 213         . = ALIGN(8);                                                   \
 214         __##name##_of_table = .;                                        \
 215         KEEP(*(__##name##_of_table))                                    \
 216         KEEP(*(__##name##_of_table_end))
 217
 218 #define TIMER_OF_TABLES()       OF_TABLE(CONFIG_TIMER_OF, timer)
 219 #define IRQCHIP_OF_MATCH_TABLE() OF_TABLE(CONFIG_IRQCHIP, irqchip)
 220 #define CLK_OF_TABLES()         OF_TABLE(CONFIG_COMMON_CLK, clk)
 221 #define RESERVEDMEM_OF_TABLES() OF_TABLE(CONFIG_OF_RESERVED_MEM, reservedmem)
 222 #define CPU_METHOD_OF_TABLES()  OF_TABLE(CONFIG_SMP, cpu_method)
 223 #define CPUIDLE_METHOD_OF_TABLES() OF_TABLE(CONFIG_CPU_IDLE, cpuidle_method)
 224
 225 #ifdef CONFIG_ACPI
 226 #define ACPI_PROBE_TABLE(name)                                          \
 227         . = ALIGN(8);                                                   \
 228         __##name##_acpi_probe_table = .;                                \
 229         KEEP(*(__##name##_acpi_probe_table))                            \
 230         __##name##_acpi_probe_table_end = .;
 231 #else
 232 #define ACPI_PROBE_TABLE(name)
 233 #endif
 234
 235 #define KERNEL_DTB()                                                    \
 236         STRUCT_ALIGN();                                                 \
 237         __dtb_start = .;                                                \
 238         KEEP(*(.dtb.init.rodata))                                       \
 239         __dtb_end = .;
 240
 241 /*
 242  * .data section
 243  */
 244 #define DATA_DATA                                                       \
 245         *(.xiptext)                                                     \
 246         *(DATA_MAIN)                                                    \
 247         *(.ref.data)                                                    \
 248         *(.data..shared_aligned) /* percpu related */                   \
 249         MEM_KEEP(init.data*)                                            \
 250         MEM_KEEP(exit.data*)                                            \
 251         *(.data.unlikely)                                               \
 252         __start_once = .;                                               \
 253         *(.data.once)                                                   \
 254         __end_once = .;                                                 \
 255         STRUCT_ALIGN();                                                 \
 256         *(__tracepoints)                                                \
 257         /* implement dynamic printk debug */                            \
 258         . = ALIGN(8);                                                   \
 259         __start___jump_table = .;                                       \
 260         KEEP(*(__jump_table))                                           \
 261         __stop___jump_table = .;                                        \
 262         . = ALIGN(8);                                                   \
 263         __start___verbose = .;                                          \
 264         KEEP(*(__verbose))                                              \
 265         __stop___verbose = .;                                           \
 266         LIKELY_PROFILE()                                                \
 267         BRANCH_PROFILE()                                                \
 268         TRACE_PRINTKS()                                                 \
 269         BPF_RAW_TP()                                                    \
 270         TRACEPOINT_STR()
 271
 272 /*
 273  * Data section helpers
 274  */
 275 #define NOSAVE_DATA                                                     \
 276         . = ALIGN(PAGE_SIZE);                                           \
 277         __nosave_begin = .;                                             \
 278         *(.data..nosave)                                                \
 279         . = ALIGN(PAGE_SIZE);                                           \
 280         __nosave_end = .;
 281
 282 #define PAGE_ALIGNED_DATA(page_align)                                   \
 283         . = ALIGN(page_align);                                          \
 284         *(.data..page_aligned)
 285
 286 #define READ_MOSTLY_DATA(align)                                         \
 287         . = ALIGN(align);                                               \
 288         *(.data..read_mostly)                                           \
 289         . = ALIGN(align);
 290
 291 #define CACHELINE_ALIGNED_DATA(align)                                   \
 292         . = ALIGN(align);                                               \
 293         *(.data..cacheline_aligned)
 294
 295 #define INIT_TASK_DATA(align)                                           \
 296         . = ALIGN(align);                                               \
 297         __start_init_task = .;                                          \
 298         init_thread_union = .;                                          \
 299         init_stack = .;                                                 \
 300         KEEP(*(.data..init_task))                                       \
 301         KEEP(*(.data..init_thread_info))                                \
 302         . = __start_init_task + THREAD_SIZE;                            \
 303         __end_init_task = .;
 304
 305 /*
 306  * Allow architectures to handle ro_after_init data on their
 307  * own by defining an empty RO_AFTER_INIT_DATA.
 308  */
 309 #ifndef RO_AFTER_INIT_DATA
 310 #define RO_AFTER_INIT_DATA                                              \
 311         __start_ro_after_init = .;                                      \
 312         *(.data..ro_after_init)                                         \
 313         __end_ro_after_init = .;
 314 #endif
 315
 316 /*
 317  * Read only Data
 318  */
 319 #define RO_DATA_SECTION(align)                                          \
 320         . = ALIGN((align));                                             \
 321         .rodata           : AT(ADDR(.rodata) - LOAD_OFFSET) {           \
 322                 __start_rodata = .;                                     \
 323                 *(.rodata) *(.rodata.*)                                 \
 324                 RO_AFTER_INIT_DATA      /* Read only after init */      \
 325                 KEEP(*(__vermagic))     /* Kernel version magic */      \
 326                 . = ALIGN(8);                                           \
 327                 __start___tracepoints_ptrs = .;                         \
 328                 KEEP(*(__tracepoints_ptrs)) /* Tracepoints: pointer array */ \
 329                 __stop___tracepoints_ptrs = .;                          \
 330                 *(__tracepoints_strings)/* Tracepoints: strings */      \
 331         }                                                               \
 332                                                                         \
 333         .rodata1          : AT(ADDR(.rodata1) - LOAD_OFFSET) {          \
 334                 *(.rodata1)                                             \
 335         }                                                               \
 336                                                                         \
 337         /* PCI quirks */                                                \
 338         .pci_fixup        : AT(ADDR(.pci_fixup) - LOAD_OFFSET) {        \
 339                 __start_pci_fixups_early = .;                           \
 340                 KEEP(*(.pci_fixup_early))                               \
 341                 __end_pci_fixups_early = .;                             \
 342                 __start_pci_fixups_header = .;                          \
 343                 KEEP(*(.pci_fixup_header))                              \
 344                 __end_pci_fixups_header = .;                            \
 345                 __start_pci_fixups_final = .;                           \
 346                 KEEP(*(.pci_fixup_final))                               \
 347                 __end_pci_fixups_final = .;                             \
 348                 __start_pci_fixups_enable = .;                          \
 349                 KEEP(*(.pci_fixup_enable))                              \
 350                 __end_pci_fixups_enable = .;                            \
 351                 __start_pci_fixups_resume = .;                          \
 352                 KEEP(*(.pci_fixup_resume))                              \
 353                 __end_pci_fixups_resume = .;                            \
 354                 __start_pci_fixups_resume_early = .;                    \
 355                 KEEP(*(.pci_fixup_resume_early))                        \
 356                 __end_pci_fixups_resume_early = .;                      \
 357                 __start_pci_fixups_suspend = .;                         \
 358                 KEEP(*(.pci_fixup_suspend))                             \
 359                 __end_pci_fixups_suspend = .;                           \
 360                 __start_pci_fixups_suspend_late = .;                    \
 361                 KEEP(*(.pci_fixup_suspend_late))                        \
 362                 __end_pci_fixups_suspend_late = .;                      \
 363         }                                                               \
 364                                                                         \
 365         /* Built-in firmware blobs */                                   \
 366         .builtin_fw        : AT(ADDR(.builtin_fw) - LOAD_OFFSET) {      \
 367                 __start_builtin_fw = .;                                 \
 368                 KEEP(*(.builtin_fw))                                    \
 369                 __end_builtin_fw = .;                                   \
 370         }                                                               \
 371                                                                         \
 372         TRACEDATA                                                       \
 373                                                                         \
 374         /* Kernel symbol table: Normal symbols */                       \
 375         __ksymtab         : AT(ADDR(__ksymtab) - LOAD_OFFSET) {         \
 376                 __start___ksymtab = .;                                  \
 377                 KEEP(*(SORT(___ksymtab+*)))                             \
 378                 __stop___ksymtab = .;                                   \
 379         }                                                               \
 380                                                                         \
 381         /* Kernel symbol table: GPL-only symbols */                     \
 382         __ksymtab_gpl     : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) {     \
 383                 __start___ksymtab_gpl = .;                              \
 384                 KEEP(*(SORT(___ksymtab_gpl+*)))                         \
 385                 __stop___ksymtab_gpl = .;                               \
 386         }                                                               \
 387                                                                         \
 388         /* Kernel symbol table: Normal unused symbols */                \
 389         __ksymtab_unused  : AT(ADDR(__ksymtab_unused) - LOAD_OFFSET) {  \
 390                 __start___ksymtab_unused = .;                           \
 391                 KEEP(*(SORT(___ksymtab_unused+*)))                      \
 392                 __stop___ksymtab_unused = .;                            \
 393         }                                                               \
 394                                                                         \
 395         /* Kernel symbol table: GPL-only unused symbols */              \
 396         __ksymtab_unused_gpl : AT(ADDR(__ksymtab_unused_gpl) - LOAD_OFFSET) { \
 397                 __start___ksymtab_unused_gpl = .;                       \
 398                 KEEP(*(SORT(___ksymtab_unused_gpl+*)))                  \
 399                 __stop___ksymtab_unused_gpl = .;                        \
 400         }                                                               \
 401                                                                         \
 402         /* Kernel symbol table: GPL-future-only symbols */              \
 403         __ksymtab_gpl_future : AT(ADDR(__ksymtab_gpl_future) - LOAD_OFFSET) { \
 404                 __start___ksymtab_gpl_future = .;                       \
 405                 KEEP(*(SORT(___ksymtab_gpl_future+*)))                  \
 406                 __stop___ksymtab_gpl_future = .;                        \
 407         }                                                               \
 408                                                                         \
 409         /* Kernel symbol table: Normal symbols */                       \
 410         __kcrctab         : AT(ADDR(__kcrctab) - LOAD_OFFSET) {         \
 411                 __start___kcrctab = .;                                  \
 412                 KEEP(*(SORT(___kcrctab+*)))                             \
 413                 __stop___kcrctab = .;                                   \
 414         }                                                               \
 415                                                                         \
 416         /* Kernel symbol table: GPL-only symbols */                     \
 417         __kcrctab_gpl     : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) {     \
 418                 __start___kcrctab_gpl = .;                              \
 419                 KEEP(*(SORT(___kcrctab_gpl+*)))                         \
 420                 __stop___kcrctab_gpl = .;                               \
 421         }                                                               \
 422                                                                         \
 423         /* Kernel symbol table: Normal unused symbols */                \
 424         __kcrctab_unused  : AT(ADDR(__kcrctab_unused) - LOAD_OFFSET) {  \
 425                 __start___kcrctab_unused = .;                           \
 426                 KEEP(*(SORT(___kcrctab_unused+*)))                      \
 427                 __stop___kcrctab_unused = .;                            \
 428         }                                                               \
 429                                                                         \
 430         /* Kernel symbol table: GPL-only unused symbols */              \
 431         __kcrctab_unused_gpl : AT(ADDR(__kcrctab_unused_gpl) - LOAD_OFFSET) { \
 432                 __start___kcrctab_unused_gpl = .;                       \
 433                 KEEP(*(SORT(___kcrctab_unused_gpl+*)))                  \
 434                 __stop___kcrctab_unused_gpl = .;                        \
 435         }                                                               \
 436                                                                         \
 437         /* Kernel symbol table: GPL-future-only symbols */              \
 438         __kcrctab_gpl_future : AT(ADDR(__kcrctab_gpl_future) - LOAD_OFFSET) { \
 439                 __start___kcrctab_gpl_future = .;                       \
 440                 KEEP(*(SORT(___kcrctab_gpl_future+*)))                  \
 441                 __stop___kcrctab_gpl_future = .;                        \
 442         }                                                               \
 443                                                                         \
 444         /* Kernel symbol table: strings */                              \
 445         __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \
 446                 *(__ksymtab_strings)                                    \
 447         }                                                               \
 448                                                                         \
 449         /* __*init sections */                                          \
 450         __init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) {         \
 451                 *(.ref.rodata)                                          \
 452                 MEM_KEEP(init.rodata)                                   \
 453                 MEM_KEEP(exit.rodata)                                   \
 454         }                                                               \
 455                                                                         \
 456         /* Built-in module parameters. */                               \
 457         __param : AT(ADDR(__param) - LOAD_OFFSET) {                     \
 458                 __start___param = .;                                    \
 459                 KEEP(*(__param))                                        \
 460                 __stop___param = .;                                     \
 461         }                                                               \
 462                                                                         \
 463         /* Built-in module versions. */                                 \
 464         __modver : AT(ADDR(__modver) - LOAD_OFFSET) {                   \
 465                 __start___modver = .;                                   \
 466                 KEEP(*(__modver))                                       \
 467                 __stop___modver = .;                                    \
 468                 . = ALIGN((align));                                     \
 469                 __end_rodata = .;                                       \
 470         }                                                               \
 471         . = ALIGN((align));
 472
 473 /* RODATA & RO_DATA provided for backward compatibility.
 474  * All archs are supposed to use RO_DATA() */
 475 #define RODATA          RO_DATA_SECTION(4096)
 476 #define RO_DATA(align)  RO_DATA_SECTION(align)
 477
 478 #define SECURITY_INIT                                                   \
 479         .security_initcall.init : AT(ADDR(.security_initcall.init) - LOAD_OFFSET) { \
 480                 __security_initcall_start = .;                          \
 481                 KEEP(*(.security_initcall.init))                        \
 482                 __security_initcall_end = .;                            \
 483         }
 484
 485 /*
 486  * .text section. Map to function alignment to avoid address changes
 487  * during second ld run in second ld pass when generating System.map
 488  *
 489  * TEXT_MAIN here will match .text.fixup and .text.unlikely if dead
 490  * code elimination is enabled, so these sections should be converted
 491  * to use ".." first.
 492  */
 493 #define TEXT_TEXT                                                       \
 494                 ALIGN_FUNCTION();                                       \
 495                 *(.text.hot TEXT_MAIN .text.fixup .text.unlikely)       \
 496                 *(.text..refcount)                                      \
 497                 *(.ref.text)                                            \
 498         MEM_KEEP(init.text*)                                            \
 499         MEM_KEEP(exit.text*)                                            \
 500
 501
 502 /* sched.text is aling to function alignment to secure we have same
 503  * address even at second ld pass when generating System.map */
 504 #define SCHED_TEXT                                                      \
 505                 ALIGN_FUNCTION();                                       \
 506                 __sched_text_start = .;                                 \
 507                 *(.sched.text)                                          \
 508                 __sched_text_end = .;
 509
 510 /* spinlock.text is aling to function alignment to secure we have same
 511  * address even at second ld pass when generating System.map */
 512 #define LOCK_TEXT                                                       \
 513                 ALIGN_FUNCTION();                                       \
 514                 __lock_text_start = .;                                  \
 515                 *(.spinlock.text)                                       \
 516                 __lock_text_end = .;
 517
 518 #define CPUIDLE_TEXT                                                    \
 519                 ALIGN_FUNCTION();                                       \
 520                 __cpuidle_text_start = .;                               \
 521                 *(.cpuidle.text)                                        \
 522                 __cpuidle_text_end = .;
 523
 524 #define KPROBES_TEXT                                                    \
 525                 ALIGN_FUNCTION();                                       \
 526                 __kprobes_text_start = .;                               \
 527                 *(.kprobes.text)                                        \
 528                 __kprobes_text_end = .;
 529
 530 #define ENTRY_TEXT                                                      \
 531                 ALIGN_FUNCTION();                                       \
 532                 __entry_text_start = .;                                 \
 533                 *(.entry.text)                                          \
 534                 __entry_text_end = .;
 535
 536 #define IRQENTRY_TEXT                                                   \
 537                 ALIGN_FUNCTION();                                       \
 538                 __irqentry_text_start = .;                              \
 539                 *(.irqentry.text)                                       \
 540                 __irqentry_text_end = .;
 541
 542 #define SOFTIRQENTRY_TEXT                                               \
 543                 ALIGN_FUNCTION();                                       \
 544                 __softirqentry_text_start = .;                          \
 545                 *(.softirqentry.text)                                   \
 546                 __softirqentry_text_end = .;
 547
 548 /* Section used for early init (in .S files) */
 549 #define HEAD_TEXT  KEEP(*(.head.text))
 550
 551 #define HEAD_TEXT_SECTION                                                       \
 552         .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) {               \
 553                 HEAD_TEXT                                               \
 554         }
 555
 556 /*
 557  * Exception table
 558  */
 559 #define EXCEPTION_TABLE(align)                                          \
 560         . = ALIGN(align);                                               \
 561         __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) {               \
 562                 __start___ex_table = .;                                 \
 563                 KEEP(*(__ex_table))                                     \
 564                 __stop___ex_table = .;                                  \
 565         }
 566
 567 /*
 568  * Init task
 569  */
 570 #define INIT_TASK_DATA_SECTION(align)                                   \
 571         . = ALIGN(align);                                               \
 572         .data..init_task :  AT(ADDR(.data..init_task) - LOAD_OFFSET) {  \
 573                 INIT_TASK_DATA(align)                                   \
 574         }
 575
 576 #ifdef CONFIG_CONSTRUCTORS
 577 #define KERNEL_CTORS()  . = ALIGN(8);                      \
 578                         __ctors_start = .;                 \
 579                         KEEP(*(.ctors))                    \
 580                         KEEP(*(SORT(.init_array.*)))       \
 581                         KEEP(*(.init_array))               \
 582                         __ctors_end = .;
 583 #else
 584 #define KERNEL_CTORS()
 585 #endif
 586
 587 /* init and exit section handling */
 588 #define INIT_DATA                                                       \
 589         KEEP(*(SORT(___kentry+*)))                                      \
 590         *(.init.data init.data.*)                                       \
 591         MEM_DISCARD(init.data*)                                         \
 592         KERNEL_CTORS()                                                  \
 593         MCOUNT_REC()                                                    \
 594         *(.init.rodata .init.rodata.*)                                  \
 595         FTRACE_EVENTS()                                                 \
 596         TRACE_SYSCALLS()                                                \
 597         KPROBE_BLACKLIST()                                              \
 598         ERROR_INJECT_WHITELIST()                                        \
 599         MEM_DISCARD(init.rodata)                                        \
 600         CLK_OF_TABLES()                                                 \
 601         RESERVEDMEM_OF_TABLES()                                         \
 602         TIMER_OF_TABLES()                                               \
 603         CPU_METHOD_OF_TABLES()                                          \
 604         CPUIDLE_METHOD_OF_TABLES()                                      \
 605         KERNEL_DTB()                                                    \
 606         IRQCHIP_OF_MATCH_TABLE()                                        \
 607         ACPI_PROBE_TABLE(irqchip)                                       \
 608         ACPI_PROBE_TABLE(timer)                                         \
 609         EARLYCON_TABLE()
 610
 611 #define INIT_TEXT                                                       \
 612         *(.init.text .init.text.*)                                      \
 613         *(.text.startup)                                                \
 614         MEM_DISCARD(init.text*)
 615
 616 #define EXIT_DATA                                                       \
 617         *(.exit.data .exit.data.*)                                      \
 618         *(.fini_array)                                                  \
 619         *(.dtors)                                                       \
 620         MEM_DISCARD(exit.data*)                                         \
 621         MEM_DISCARD(exit.rodata*)
 622
 623 #define EXIT_TEXT                                                       \
 624         *(.exit.text)                                                   \
 625         *(.text.exit)                                                   \
 626         MEM_DISCARD(exit.text)
 627
 628 #define EXIT_CALL                                                       \
 629         *(.exitcall.exit)
 630
 631 /*
 632  * bss (Block Started by Symbol) - uninitialized data
 633  * zeroed during startup
 634  */
 635 #define SBSS(sbss_align)                                                \
 636         . = ALIGN(sbss_align);                                          \
 637         .sbss : AT(ADDR(.sbss) - LOAD_OFFSET) {                         \
 638                 *(.dynsbss)                                             \
 639                 *(SBSS_MAIN)                                            \
 640                 *(.scommon)                                             \
 641         }
 642
 643 /*
 644  * Allow archectures to redefine BSS_FIRST_SECTIONS to add extra
 645  * sections to the front of bss.
 646  */
 647 #ifndef BSS_FIRST_SECTIONS
 648 #define BSS_FIRST_SECTIONS
 649 #endif
 650
 651 #define BSS(bss_align)                                                  \
 652         . = ALIGN(bss_align);                                           \
 653         .bss : AT(ADDR(.bss) - LOAD_OFFSET) {                           \
 654                 BSS_FIRST_SECTIONS                                      \
 655                 *(.bss..page_aligned)                                   \
 656                 *(.dynbss)                                              \
 657                 *(BSS_MAIN)                                             \
 658                 *(COMMON)                                               \
 659         }
 660
 661 /*
 662  * DWARF debug sections.
 663  * Symbols in the DWARF debugging sections are relative to
 664  * the beginning of the section so we begin them at 0.
 665  */
 666 #define DWARF_DEBUG                                                     \
 667                 /* DWARF 1 */                                           \
 668                 .debug          0 : { *(.debug) }                       \
 669                 .line           0 : { *(.line) }                        \
 670                 /* GNU DWARF 1 extensions */                            \
 671                 .debug_srcinfo  0 : { *(.debug_srcinfo) }               \
 672                 .debug_sfnames  0 : { *(.debug_sfnames) }               \
 673                 /* DWARF 1.1 and DWARF 2 */                             \
 674                 .debug_aranges  0 : { *(.debug_aranges) }               \
 675                 .debug_pubnames 0 : { *(.debug_pubnames) }              \
 676                 /* DWARF 2 */                                           \
 677                 .debug_info     0 : { *(.debug_info                     \
 678                                 .gnu.linkonce.wi.*) }                   \
 679                 .debug_abbrev   0 : { *(.debug_abbrev) }                \
 680                 .debug_line     0 : { *(.debug_line) }                  \
 681                 .debug_frame    0 : { *(.debug_frame) }                 \
 682                 .debug_str      0 : { *(.debug_str) }                   \
 683                 .debug_loc      0 : { *(.debug_loc) }                   \
 684                 .debug_macinfo  0 : { *(.debug_macinfo) }               \
 685                 .debug_pubtypes 0 : { *(.debug_pubtypes) }              \
 686                 /* DWARF 3 */                                           \
 687                 .debug_ranges   0 : { *(.debug_ranges) }                \
 688                 /* SGI/MIPS DWARF 2 extensions */                       \
 689                 .debug_weaknames 0 : { *(.debug_weaknames) }            \
 690                 .debug_funcnames 0 : { *(.debug_funcnames) }            \
 691                 .debug_typenames 0 : { *(.debug_typenames) }            \
 692                 .debug_varnames  0 : { *(.debug_varnames) }             \
 693                 /* GNU DWARF 2 extensions */                            \
 694                 .debug_gnu_pubnames 0 : { *(.debug_gnu_pubnames) }      \
 695                 .debug_gnu_pubtypes 0 : { *(.debug_gnu_pubtypes) }      \
 696                 /* DWARF 4 */                                           \
 697                 .debug_types    0 : { *(.debug_types) }                 \
 698                 /* DWARF 5 */                                           \
 699                 .debug_macro    0 : { *(.debug_macro) }                 \
 700                 .debug_addr     0 : { *(.debug_addr) }
 701
 702                 /* Stabs debugging sections.  */
 703 #define STABS_DEBUG                                                     \
 704                 .stab 0 : { *(.stab) }                                  \
 705                 .stabstr 0 : { *(.stabstr) }                            \
 706                 .stab.excl 0 : { *(.stab.excl) }                        \
 707                 .stab.exclstr 0 : { *(.stab.exclstr) }                  \
 708                 .stab.index 0 : { *(.stab.index) }                      \
 709                 .stab.indexstr 0 : { *(.stab.indexstr) }                \
 710                 .comment 0 : { *(.comment) }
 711
 712 #ifdef CONFIG_GENERIC_BUG
 713 #define BUG_TABLE                                                       \
 714         . = ALIGN(8);                                                   \
 715         __bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) {             \
 716                 __start___bug_table = .;                                \
 717                 KEEP(*(__bug_table))                                    \
 718                 __stop___bug_table = .;                                 \
 719         }
 720 #else
 721 #define BUG_TABLE
 722 #endif
 723
 724 #ifdef CONFIG_UNWINDER_ORC
 725 #define ORC_UNWIND_TABLE                                                \
 726         . = ALIGN(4);                                                   \
 727         .orc_unwind_ip : AT(ADDR(.orc_unwind_ip) - LOAD_OFFSET) {       \
 728                 __start_orc_unwind_ip = .;                              \
 729                 KEEP(*(.orc_unwind_ip))                                 \
 730                 __stop_orc_unwind_ip = .;                               \
 731         }                                                               \
 732         . = ALIGN(6);                                                   \
 733         .orc_unwind : AT(ADDR(.orc_unwind) - LOAD_OFFSET) {             \
 734                 __start_orc_unwind = .;                                 \
 735                 KEEP(*(.orc_unwind))                                    \
 736                 __stop_orc_unwind = .;                                  \
 737         }                                                               \
 738         . = ALIGN(4);                                                   \
 739         .orc_lookup : AT(ADDR(.orc_lookup) - LOAD_OFFSET) {             \
 740                 orc_lookup = .;                                         \
 741                 . += (((SIZEOF(.text) + LOOKUP_BLOCK_SIZE - 1) /        \
 742                         LOOKUP_BLOCK_SIZE) + 1) * 4;                    \
 743                 orc_lookup_end = .;                                     \
 744         }
 745 #else
 746 #define ORC_UNWIND_TABLE
 747 #endif
 748
 749 #ifdef CONFIG_PM_TRACE
 750 #define TRACEDATA                                                       \
 751         . = ALIGN(4);                                                   \
 752         .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) {               \
 753                 __tracedata_start = .;                                  \
 754                 KEEP(*(.tracedata))                                     \
 755                 __tracedata_end = .;                                    \
 756         }
 757 #else
 758 #define TRACEDATA
 759 #endif
 760
 761 #define NOTES                                                           \
 762         .notes : AT(ADDR(.notes) - LOAD_OFFSET) {                       \
 763                 __start_notes = .;                                      \
 764                 KEEP(*(.note.*))                                        \
 765                 __stop_notes = .;                                       \
 766         }
 767
 768 #define INIT_SETUP(initsetup_align)                                     \
 769                 . = ALIGN(initsetup_align);                             \
 770                 __setup_start = .;                                      \
 771                 KEEP(*(.init.setup))                                    \
 772                 __setup_end = .;
 773
 774 #define INIT_CALLS_LEVEL(level)                                         \
 775                 __initcall##level##_start = .;                          \
 776                 KEEP(*(.initcall##level##.init))                        \
 777                 KEEP(*(.initcall##level##s.init))                       \
 778
 779 #define INIT_CALLS                                                      \
 780                 __initcall_start = .;                                   \
 781                 KEEP(*(.initcallearly.init))                            \
 782                 INIT_CALLS_LEVEL(0)                                     \
 783                 INIT_CALLS_LEVEL(1)                                     \
 784                 INIT_CALLS_LEVEL(2)                                     \
 785                 INIT_CALLS_LEVEL(3)                                     \
 786                 INIT_CALLS_LEVEL(4)                                     \
 787                 INIT_CALLS_LEVEL(5)                                     \
 788                 INIT_CALLS_LEVEL(rootfs)                                \
 789                 INIT_CALLS_LEVEL(6)                                     \
 790                 INIT_CALLS_LEVEL(7)                                     \
 791                 __initcall_end = .;
 792
 793 #define CON_INITCALL                                                    \
 794                 __con_initcall_start = .;                               \
 795                 KEEP(*(.con_initcall.init))                             \
 796                 __con_initcall_end = .;
 797
 798 #define SECURITY_INITCALL                                               \
 799                 __security_initcall_start = .;                          \
 800                 KEEP(*(.security_initcall.init))                        \
 801                 __security_initcall_end = .;
 802
 803 #ifdef CONFIG_BLK_DEV_INITRD
 804 #define INIT_RAM_FS                                                     \
 805         . = ALIGN(4);                                                   \
 806         __initramfs_start = .;                                          \
 807         KEEP(*(.init.ramfs))                                            \
 808         . = ALIGN(8);                                                   \
 809         KEEP(*(.init.ramfs.info))
 810 #else
 811 #define INIT_RAM_FS
 812 #endif
 813
 814 /*
 815  * Memory encryption operates on a page basis. Since we need to clear
 816  * the memory encryption mask for this section, it needs to be aligned
 817  * on a page boundary and be a page-size multiple in length.
 818  *
 819  * Note: We use a separate section so that only this section gets
 820  * decrypted to avoid exposing more than we wish.
 821  */
 822 #ifdef CONFIG_AMD_MEM_ENCRYPT
 823 #define PERCPU_DECRYPTED_SECTION                                        \
 824         . = ALIGN(PAGE_SIZE);                                           \
 825         *(.data..percpu..decrypted)                                     \
 826         . = ALIGN(PAGE_SIZE);
 827 #else
 828 #define PERCPU_DECRYPTED_SECTION
 829 #endif
 830
 831
 832 /*
 833  * Default discarded sections.
 834  *
 835  * Some archs want to discard exit text/data at runtime rather than
 836  * link time due to cross-section references such as alt instructions,
 837  * bug table, eh_frame, etc.  DISCARDS must be the last of output
 838  * section definitions so that such archs put those in earlier section
 839  * definitions.
 840  */
 841 #define DISCARDS                                                        \
 842         /DISCARD/ : {                                                   \
 843         EXIT_TEXT                                                       \
 844         EXIT_DATA                                                       \
 845         EXIT_CALL                                                       \
 846         *(.discard)                                                     \
 847         *(.discard.*)                                                   \
 848         }
 849
 850 /**
 851  * PERCPU_INPUT - the percpu input sections
 852  * @cacheline: cacheline size
 853  *
 854  * The core percpu section names and core symbols which do not rely
 855  * directly upon load addresses.
 856  *
 857  * @cacheline is used to align subsections to avoid false cacheline
 858  * sharing between subsections for different purposes.
 859  */
 860 #define PERCPU_INPUT(cacheline)                                         \
 861         __per_cpu_start = .;                                            \
 862         *(.data..percpu..first)                                         \
 863         . = ALIGN(PAGE_SIZE);                                           \
 864         *(.data..percpu..page_aligned)                                  \
 865         . = ALIGN(cacheline);                                           \
 866         *(.data..percpu..read_mostly)                                   \
 867         . = ALIGN(cacheline);                                           \
 868         *(.data..percpu)                                                \
 869         *(.data..percpu..shared_aligned)                                \
 870         PERCPU_DECRYPTED_SECTION                                        \
 871         __per_cpu_end = .;
 872
 873 /**
 874  * PERCPU_VADDR - define output section for percpu area
 875  * @cacheline: cacheline size
 876  * @vaddr: explicit base address (optional)
 877  * @phdr: destination PHDR (optional)
 878  *
 879  * Macro which expands to output section for percpu area.
 880  *
 881  * @cacheline is used to align subsections to avoid false cacheline
 882  * sharing between subsections for different purposes.
 883  *
 884  * If @vaddr is not blank, it specifies explicit base address and all
 885  * percpu symbols will be offset from the given address.  If blank,
 886  * @vaddr always equals @laddr + LOAD_OFFSET.
 887  *
 888  * @phdr defines the output PHDR to use if not blank.  Be warned that
 889  * output PHDR is sticky.  If @phdr is specified, the next output
 890  * section in the linker script will go there too.  @phdr should have
 891  * a leading colon.
 892  *
 893  * Note that this macros defines __per_cpu_load as an absolute symbol.
 894  * If there is no need to put the percpu section at a predetermined
 895  * address, use PERCPU_SECTION.
 896  */
 897 #define PERCPU_VADDR(cacheline, vaddr, phdr)                            \
 898         __per_cpu_load = .;                                             \
 899         .data..percpu vaddr : AT(__per_cpu_load - LOAD_OFFSET) {        \
 900                 PERCPU_INPUT(cacheline)                                 \
 901         } phdr                                                          \
 902         . = __per_cpu_load + SIZEOF(.data..percpu);
 903
 904 /**
 905  * PERCPU_SECTION - define output section for percpu area, simple version
 906  * @cacheline: cacheline size
 907  *
 908  * Align to PAGE_SIZE and outputs output section for percpu area.  This
 909  * macro doesn't manipulate @vaddr or @phdr and __per_cpu_load and
 910  * __per_cpu_start will be identical.
 911  *
 912  * This macro is equivalent to ALIGN(PAGE_SIZE); PERCPU_VADDR(@cacheline,,)
 913  * except that __per_cpu_load is defined as a relative symbol against
 914  * .data..percpu which is required for relocatable x86_32 configuration.
 915  */
 916 #define PERCPU_SECTION(cacheline)                                       \
 917         . = ALIGN(PAGE_SIZE);                                           \
 918         .data..percpu   : AT(ADDR(.data..percpu) - LOAD_OFFSET) {       \
 919                 __per_cpu_load = .;                                     \
 920                 PERCPU_INPUT(cacheline)                                 \
 921         }
 922
 923
 924 /*
 925  * Definition of the high level *_SECTION macros
 926  * They will fit only a subset of the architectures
 927  */
 928
 929
 930 /*
 931  * Writeable data.
 932  * All sections are combined in a single .data section.
 933  * The sections following CONSTRUCTORS are arranged so their
 934  * typical alignment matches.
 935  * A cacheline is typical/always less than a PAGE_SIZE so
 936  * the sections that has this restriction (or similar)
 937  * is located before the ones requiring PAGE_SIZE alignment.
 938  * NOSAVE_DATA starts and ends with a PAGE_SIZE alignment which
 939  * matches the requirement of PAGE_ALIGNED_DATA.
 940  *
 941  * use 0 as page_align if page_aligned data is not used */
 942 #define RW_DATA_SECTION(cacheline, pagealigned, inittask)               \
 943         . = ALIGN(PAGE_SIZE);                                           \
 944         .data : AT(ADDR(.data) - LOAD_OFFSET) {                         \
 945                 INIT_TASK_DATA(inittask)                                \
 946                 NOSAVE_DATA                                             \
 947                 PAGE_ALIGNED_DATA(pagealigned)                          \
 948                 CACHELINE_ALIGNED_DATA(cacheline)                       \
 949                 READ_MOSTLY_DATA(cacheline)                             \
 950                 DATA_DATA                                               \
 951                 CONSTRUCTORS                                            \
 952         }                                                               \
 953         BUG_TABLE                                                       \
 954
 955 #define INIT_TEXT_SECTION(inittext_align)                               \
 956         . = ALIGN(inittext_align);                                      \
 957         .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {               \
 958                 _sinittext = .;                                         \
 959                 INIT_TEXT                                               \
 960                 _einittext = .;                                         \
 961         }
 962
 963 #define INIT_DATA_SECTION(initsetup_align)                              \
 964         .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) {               \
 965                 INIT_DATA                                               \
 966                 INIT_SETUP(initsetup_align)                             \
 967                 INIT_CALLS                                              \
 968                 CON_INITCALL                                            \
 969                 SECURITY_INITCALL                                       \
 970                 INIT_RAM_FS                                             \
 971         }
 972
 973 #define BSS_SECTION(sbss_align, bss_align, stop_align)                  \
 974         . = ALIGN(sbss_align);                                          \
 975         __bss_start = .;                                                \
 976         SBSS(sbss_align)                                                \
 977         BSS(bss_align)                                                  \
 978         . = ALIGN(stop_align);                                          \
 979         __bss_stop = .;