include/asm-generic/vmlinux.lds.h

   1 /*
   2  * Helper macros to support writing architecture specific
   3  * linker scripts.
   4  *
   5  * A minimal linker scripts has following content:
   6  * [This is a sample, architectures may have special requiriements]
   7  *
   8  * OUTPUT_FORMAT(...)
   9  * OUTPUT_ARCH(...)
  10  * ENTRY(...)
  11  * SECTIONS
  12  * {
  13  *      . = START;
  14  *      __init_begin = .;
  15  *      HEAD_TEXT_SECTION
  16  *      INIT_TEXT_SECTION(PAGE_SIZE)
  17  *      INIT_DATA_SECTION(...)
  18  *      PERCPU_SECTION(CACHELINE_SIZE)
  19  *      __init_end = .;
  20  *
  21  *      _stext = .;
  22  *      TEXT_SECTION = 0
  23  *      _etext = .;
  24  *
  25  *      _sdata = .;
  26  *      RO_DATA_SECTION(PAGE_SIZE)
  27  *      RW_DATA_SECTION(...)
  28  *      _edata = .;
  29  *
  30  *      EXCEPTION_TABLE(...)
  31  *      NOTES
  32  *
  33  *      BSS_SECTION(0, 0, 0)
  34  *      _end = .;
  35  *
  36  *      STABS_DEBUG
  37  *      DWARF_DEBUG
  38  *
  39  *      DISCARDS                // must be the last
  40  * }
  41  *
  42  * [__init_begin, __init_end] is the init section that may be freed after init
  43  *      // __init_begin and __init_end should be page aligned, so that we can
  44  *      // free the whole .init memory
  45  * [_stext, _etext] is the text section
  46  * [_sdata, _edata] is the data section
  47  *
  48  * Some of the included output section have their own set of constants.
  49  * Examples are: [__initramfs_start, __initramfs_end] for initramfs and
  50  *               [__nosave_begin, __nosave_end] for the nosave data
  51  */
  52
  53 #ifndef LOAD_OFFSET
  54 #define LOAD_OFFSET 0
  55 #endif
  56
  57 /* Align . to a 8 byte boundary equals to maximum function alignment. */
  58 #define ALIGN_FUNCTION()  . = ALIGN(8)
  59
  60 /*
  61  * LD_DEAD_CODE_DATA_ELIMINATION option enables -fdata-sections, which
  62  * generates .data.identifier sections, which need to be pulled in with
  63  * .data. We don't want to pull in .data..other sections, which Linux
  64  * has defined. Same for text and bss.
  65  *
  66  * RODATA_MAIN is not used because existing code already defines .rodata.x
  67  * sections to be brought in with rodata.
  68  */
  69 #ifdef CONFIG_LD_DEAD_CODE_DATA_ELIMINATION
  70 #define TEXT_MAIN .text .text.[0-9a-zA-Z_]*
  71 #define DATA_MAIN .data .data.[0-9a-zA-Z_]* .data..LPBX*
  72 #define SDATA_MAIN .sdata .sdata.[0-9a-zA-Z_]*
  73 #define RODATA_MAIN .rodata .rodata.[0-9a-zA-Z_]*
  74 #define BSS_MAIN .bss .bss.[0-9a-zA-Z_]*
  75 #define SBSS_MAIN .sbss .sbss.[0-9a-zA-Z_]*
  76 #else
  77 #define TEXT_MAIN .text
  78 #define DATA_MAIN .data
  79 #define SDATA_MAIN .sdata
  80 #define RODATA_MAIN .rodata
  81 #define BSS_MAIN .bss
  82 #define SBSS_MAIN .sbss
  83 #endif
  84
  85 /*
  86  * Align to a 32 byte boundary equal to the
  87  * alignment gcc 4.5 uses for a struct
  88  */
  89 #define STRUCT_ALIGNMENT 32
  90 #define STRUCT_ALIGN() . = ALIGN(STRUCT_ALIGNMENT)
  91
  92 /* The actual configuration determine if the init/exit sections
  93  * are handled as text/data or they can be discarded (which
  94  * often happens at runtime)
  95  */
  96 #ifdef CONFIG_HOTPLUG_CPU
  97 #define CPU_KEEP(sec)    *(.cpu##sec)
  98 #define CPU_DISCARD(sec)
  99 #else
 100 #define CPU_KEEP(sec)
 101 #define CPU_DISCARD(sec) *(.cpu##sec)
 102 #endif
 103
 104 #if defined(CONFIG_MEMORY_HOTPLUG)
 105 #define MEM_KEEP(sec)    *(.mem##sec)
 106 #define MEM_DISCARD(sec)
 107 #else
 108 #define MEM_KEEP(sec)
 109 #define MEM_DISCARD(sec) *(.mem##sec)
 110 #endif
 111
 112 #ifdef CONFIG_FTRACE_MCOUNT_RECORD
 113 #define MCOUNT_REC()    . = ALIGN(8);                           \
 114                         __start_mcount_loc = .;                 \
 115                         KEEP(*(__mcount_loc))                   \
 116                         __stop_mcount_loc = .;
 117 #else
 118 #define MCOUNT_REC()
 119 #endif
 120
 121 #ifdef CONFIG_TRACE_BRANCH_PROFILING
 122 #define LIKELY_PROFILE()        __start_annotated_branch_profile = .;   \
 123                                 KEEP(*(_ftrace_annotated_branch))       \
 124                                 __stop_annotated_branch_profile = .;
 125 #else
 126 #define LIKELY_PROFILE()
 127 #endif
 128
 129 #ifdef CONFIG_PROFILE_ALL_BRANCHES
 130 #define BRANCH_PROFILE()        __start_branch_profile = .;             \
 131                                 KEEP(*(_ftrace_branch))                 \
 132                                 __stop_branch_profile = .;
 133 #else
 134 #define BRANCH_PROFILE()
 135 #endif
 136
 137 #ifdef CONFIG_KPROBES
 138 #define KPROBE_BLACKLIST()      . = ALIGN(8);                                 \
 139                                 __start_kprobe_blacklist = .;                 \
 140                                 KEEP(*(_kprobe_blacklist))                    \
 141                                 __stop_kprobe_blacklist = .;
 142 #else
 143 #define KPROBE_BLACKLIST()
 144 #endif
 145
 146 #ifdef CONFIG_FUNCTION_ERROR_INJECTION
 147 #define ERROR_INJECT_WHITELIST()        STRUCT_ALIGN();                       \
 148                         __start_error_injection_whitelist = .;                \
 149                         KEEP(*(_error_injection_whitelist))                   \
 150                         __stop_error_injection_whitelist = .;
 151 #else
 152 #define ERROR_INJECT_WHITELIST()
 153 #endif
 154
 155 #ifdef CONFIG_EVENT_TRACING
 156 #define FTRACE_EVENTS() . = ALIGN(8);                                   \
 157                         __start_ftrace_events = .;                      \
 158                         KEEP(*(_ftrace_events))                         \
 159                         __stop_ftrace_events = .;                       \
 160                         __start_ftrace_eval_maps = .;                   \
 161                         KEEP(*(_ftrace_eval_map))                       \
 162                         __stop_ftrace_eval_maps = .;
 163 #else
 164 #define FTRACE_EVENTS()
 165 #endif
 166
 167 #ifdef CONFIG_TRACING
 168 #define TRACE_PRINTKS()  __start___trace_bprintk_fmt = .;      \
 169                          KEEP(*(__trace_printk_fmt)) /* Trace_printk fmt' pointer */ \
 170                          __stop___trace_bprintk_fmt = .;
 171 #define TRACEPOINT_STR() __start___tracepoint_str = .;  \
 172                          KEEP(*(__tracepoint_str)) /* Trace_printk fmt' pointer */ \
 173                          __stop___tracepoint_str = .;
 174 #else
 175 #define TRACE_PRINTKS()
 176 #define TRACEPOINT_STR()
 177 #endif
 178
 179 #ifdef CONFIG_FTRACE_SYSCALLS
 180 #define TRACE_SYSCALLS() . = ALIGN(8);                                  \
 181                          __start_syscalls_metadata = .;                 \
 182                          KEEP(*(__syscalls_metadata))                   \
 183                          __stop_syscalls_metadata = .;
 184 #else
 185 #define TRACE_SYSCALLS()
 186 #endif
 187
 188 #ifdef CONFIG_BPF_EVENTS
 189 #define BPF_RAW_TP() STRUCT_ALIGN();                                    \
 190                          __start__bpf_raw_tp = .;                       \
 191                          KEEP(*(__bpf_raw_tp_map))                      \
 192                          __stop__bpf_raw_tp = .;
 193 #else
 194 #define BPF_RAW_TP()
 195 #endif
 196
 197 #ifdef CONFIG_SERIAL_EARLYCON
 198 #define EARLYCON_TABLE() . = ALIGN(8);                          \
 199                          __earlycon_table = .;                  \
 200                          KEEP(*(__earlycon_table))              \
 201                          __earlycon_table_end = .;
 202 #else
 203 #define EARLYCON_TABLE()
 204 #endif
 205
 206 #define ___OF_TABLE(cfg, name)  _OF_TABLE_##cfg(name)
 207 #define __OF_TABLE(cfg, name)   ___OF_TABLE(cfg, name)
 208 #define OF_TABLE(cfg, name)     __OF_TABLE(IS_ENABLED(cfg), name)
 209 #define _OF_TABLE_0(name)
 210 #define _OF_TABLE_1(name)                                               \
 211         . = ALIGN(8);                                                   \
 212         __##name##_of_table = .;                                        \
 213         KEEP(*(__##name##_of_table))                                    \
 214         KEEP(*(__##name##_of_table_end))
 215
 216 #define TIMER_OF_TABLES()       OF_TABLE(CONFIG_TIMER_OF, timer)
 217 #define IRQCHIP_OF_MATCH_TABLE() OF_TABLE(CONFIG_IRQCHIP, irqchip)
 218 #define CLK_OF_TABLES()         OF_TABLE(CONFIG_COMMON_CLK, clk)
 219 #define RESERVEDMEM_OF_TABLES() OF_TABLE(CONFIG_OF_RESERVED_MEM, reservedmem)
 220 #define CPU_METHOD_OF_TABLES()  OF_TABLE(CONFIG_SMP, cpu_method)
 221 #define CPUIDLE_METHOD_OF_TABLES() OF_TABLE(CONFIG_CPU_IDLE, cpuidle_method)
 222
 223 #ifdef CONFIG_ACPI
 224 #define ACPI_PROBE_TABLE(name)                                          \
 225         . = ALIGN(8);                                                   \
 226         __##name##_acpi_probe_table = .;                                \
 227         KEEP(*(__##name##_acpi_probe_table))                            \
 228         __##name##_acpi_probe_table_end = .;
 229 #else
 230 #define ACPI_PROBE_TABLE(name)
 231 #endif
 232
 233 #define KERNEL_DTB()                                                    \
 234         STRUCT_ALIGN();                                                 \
 235         __dtb_start = .;                                                \
 236         KEEP(*(.dtb.init.rodata))                                       \
 237         __dtb_end = .;
 238
 239 /*
 240  * .data section
 241  */
 242 #define DATA_DATA                                                       \
 243         *(.xiptext)                                                     \
 244         *(DATA_MAIN)                                                    \
 245         *(.ref.data)                                                    \
 246         *(.data..shared_aligned) /* percpu related */                   \
 247         MEM_KEEP(init.data*)                                            \
 248         MEM_KEEP(exit.data*)                                            \
 249         *(.data.unlikely)                                               \
 250         __start_once = .;                                               \
 251         *(.data.once)                                                   \
 252         __end_once = .;                                                 \
 253         STRUCT_ALIGN();                                                 \
 254         *(__tracepoints)                                                \
 255         /* implement dynamic printk debug */                            \
 256         . = ALIGN(8);                                                   \
 257         __start___jump_table = .;                                       \
 258         KEEP(*(__jump_table))                                           \
 259         __stop___jump_table = .;                                        \
 260         . = ALIGN(8);                                                   \
 261         __start___verbose = .;                                          \
 262         KEEP(*(__verbose))                                              \
 263         __stop___verbose = .;                                           \
 264         LIKELY_PROFILE()                                                \
 265         BRANCH_PROFILE()                                                \
 266         TRACE_PRINTKS()                                                 \
 267         BPF_RAW_TP()                                                    \
 268         TRACEPOINT_STR()
 269
 270 /*
 271  * Data section helpers
 272  */
 273 #define NOSAVE_DATA                                                     \
 274         . = ALIGN(PAGE_SIZE);                                           \
 275         __nosave_begin = .;                                             \
 276         *(.data..nosave)                                                \
 277         . = ALIGN(PAGE_SIZE);                                           \
 278         __nosave_end = .;
 279
 280 #define PAGE_ALIGNED_DATA(page_align)                                   \
 281         . = ALIGN(page_align);                                          \
 282         *(.data..page_aligned)                                          \
 283         . = ALIGN(page_align);
 284
 285 #define READ_MOSTLY_DATA(align)                                         \
 286         . = ALIGN(align);                                               \
 287         *(.data..read_mostly)                                           \
 288         . = ALIGN(align);
 289
 290 #define CACHELINE_ALIGNED_DATA(align)                                   \
 291         . = ALIGN(align);                                               \
 292         *(.data..cacheline_aligned)
 293
 294 #define INIT_TASK_DATA(align)                                           \
 295         . = ALIGN(align);                                               \
 296         __start_init_task = .;                                          \
 297         init_thread_union = .;                                          \
 298         init_stack = .;                                                 \
 299         KEEP(*(.data..init_task))                                       \
 300         KEEP(*(.data..init_thread_info))                                \
 301         . = __start_init_task + THREAD_SIZE;                            \
 302         __end_init_task = .;
 303
 304 /*
 305  * Allow architectures to handle ro_after_init data on their
 306  * own by defining an empty RO_AFTER_INIT_DATA.
 307  */
 308 #ifndef RO_AFTER_INIT_DATA
 309 #define RO_AFTER_INIT_DATA                                              \
 310         . = ALIGN(8);                                                   \
 311         __start_ro_after_init = .;                                      \
 312         *(.data..ro_after_init)                                         \
 313         __end_ro_after_init = .;
 314 #endif
 315
 316 /*
 317  * Read only Data
 318  */
 319 #define RO_DATA_SECTION(align)                                          \
 320         . = ALIGN((align));                                             \
 321         .rodata           : AT(ADDR(.rodata) - LOAD_OFFSET) {           \
 322                 __start_rodata = .;                                     \
 323                 *(.rodata) *(.rodata.*)                                 \
 324                 RO_AFTER_INIT_DATA      /* Read only after init */      \
 325                 KEEP(*(__vermagic))     /* Kernel version magic */      \
 326                 . = ALIGN(8);                                           \
 327                 __start___tracepoints_ptrs = .;                         \
 328                 KEEP(*(__tracepoints_ptrs)) /* Tracepoints: pointer array */ \
 329                 __stop___tracepoints_ptrs = .;                          \
 330                 *(__tracepoints_strings)/* Tracepoints: strings */      \
 331         }                                                               \
 332                                                                         \
 333         .rodata1          : AT(ADDR(.rodata1) - LOAD_OFFSET) {          \
 334                 *(.rodata1)                                             \
 335         }                                                               \
 336                                                                         \
 337         /* PCI quirks */                                                \
 338         .pci_fixup        : AT(ADDR(.pci_fixup) - LOAD_OFFSET) {        \
 339                 __start_pci_fixups_early = .;                           \
 340                 KEEP(*(.pci_fixup_early))                               \
 341                 __end_pci_fixups_early = .;                             \
 342                 __start_pci_fixups_header = .;                          \
 343                 KEEP(*(.pci_fixup_header))                              \
 344                 __end_pci_fixups_header = .;                            \
 345                 __start_pci_fixups_final = .;                           \
 346                 KEEP(*(.pci_fixup_final))                               \
 347                 __end_pci_fixups_final = .;                             \
 348                 __start_pci_fixups_enable = .;                          \
 349                 KEEP(*(.pci_fixup_enable))                              \
 350                 __end_pci_fixups_enable = .;                            \
 351                 __start_pci_fixups_resume = .;                          \
 352                 KEEP(*(.pci_fixup_resume))                              \
 353                 __end_pci_fixups_resume = .;                            \
 354                 __start_pci_fixups_resume_early = .;                    \
 355                 KEEP(*(.pci_fixup_resume_early))                        \
 356                 __end_pci_fixups_resume_early = .;                      \
 357                 __start_pci_fixups_suspend = .;                         \
 358                 KEEP(*(.pci_fixup_suspend))                             \
 359                 __end_pci_fixups_suspend = .;                           \
 360                 __start_pci_fixups_suspend_late = .;                    \
 361                 KEEP(*(.pci_fixup_suspend_late))                        \
 362                 __end_pci_fixups_suspend_late = .;                      \
 363         }                                                               \
 364                                                                         \
 365         /* Built-in firmware blobs */                                   \
 366         .builtin_fw        : AT(ADDR(.builtin_fw) - LOAD_OFFSET) {      \
 367                 __start_builtin_fw = .;                                 \
 368                 KEEP(*(.builtin_fw))                                    \
 369                 __end_builtin_fw = .;                                   \
 370         }                                                               \
 371                                                                         \
 372         TRACEDATA                                                       \
 373                                                                         \
 374         /* Kernel symbol table: Normal symbols */                       \
 375         __ksymtab         : AT(ADDR(__ksymtab) - LOAD_OFFSET) {         \
 376                 __start___ksymtab = .;                                  \
 377                 KEEP(*(SORT(___ksymtab+*)))                             \
 378                 __stop___ksymtab = .;                                   \
 379         }                                                               \
 380                                                                         \
 381         /* Kernel symbol table: GPL-only symbols */                     \
 382         __ksymtab_gpl     : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) {     \
 383                 __start___ksymtab_gpl = .;                              \
 384                 KEEP(*(SORT(___ksymtab_gpl+*)))                         \
 385                 __stop___ksymtab_gpl = .;                               \
 386         }                                                               \
 387                                                                         \
 388         /* Kernel symbol table: Normal unused symbols */                \
 389         __ksymtab_unused  : AT(ADDR(__ksymtab_unused) - LOAD_OFFSET) {  \
 390                 __start___ksymtab_unused = .;                           \
 391                 KEEP(*(SORT(___ksymtab_unused+*)))                      \
 392                 __stop___ksymtab_unused = .;                            \
 393         }                                                               \
 394                                                                         \
 395         /* Kernel symbol table: GPL-only unused symbols */              \
 396         __ksymtab_unused_gpl : AT(ADDR(__ksymtab_unused_gpl) - LOAD_OFFSET) { \
 397                 __start___ksymtab_unused_gpl = .;                       \
 398                 KEEP(*(SORT(___ksymtab_unused_gpl+*)))                  \
 399                 __stop___ksymtab_unused_gpl = .;                        \
 400         }                                                               \
 401                                                                         \
 402         /* Kernel symbol table: GPL-future-only symbols */              \
 403         __ksymtab_gpl_future : AT(ADDR(__ksymtab_gpl_future) - LOAD_OFFSET) { \
 404                 __start___ksymtab_gpl_future = .;                       \
 405                 KEEP(*(SORT(___ksymtab_gpl_future+*)))                  \
 406                 __stop___ksymtab_gpl_future = .;                        \
 407         }                                                               \
 408                                                                         \
 409         /* Kernel symbol table: Normal symbols */                       \
 410         __kcrctab         : AT(ADDR(__kcrctab) - LOAD_OFFSET) {         \
 411                 __start___kcrctab = .;                                  \
 412                 KEEP(*(SORT(___kcrctab+*)))                             \
 413                 __stop___kcrctab = .;                                   \
 414         }                                                               \
 415                                                                         \
 416         /* Kernel symbol table: GPL-only symbols */                     \
 417         __kcrctab_gpl     : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) {     \
 418                 __start___kcrctab_gpl = .;                              \
 419                 KEEP(*(SORT(___kcrctab_gpl+*)))                         \
 420                 __stop___kcrctab_gpl = .;                               \
 421         }                                                               \
 422                                                                         \
 423         /* Kernel symbol table: Normal unused symbols */                \
 424         __kcrctab_unused  : AT(ADDR(__kcrctab_unused) - LOAD_OFFSET) {  \
 425                 __start___kcrctab_unused = .;                           \
 426                 KEEP(*(SORT(___kcrctab_unused+*)))                      \
 427                 __stop___kcrctab_unused = .;                            \
 428         }                                                               \
 429                                                                         \
 430         /* Kernel symbol table: GPL-only unused symbols */              \
 431         __kcrctab_unused_gpl : AT(ADDR(__kcrctab_unused_gpl) - LOAD_OFFSET) { \
 432                 __start___kcrctab_unused_gpl = .;                       \
 433                 KEEP(*(SORT(___kcrctab_unused_gpl+*)))                  \
 434                 __stop___kcrctab_unused_gpl = .;                        \
 435         }                                                               \
 436                                                                         \
 437         /* Kernel symbol table: GPL-future-only symbols */              \
 438         __kcrctab_gpl_future : AT(ADDR(__kcrctab_gpl_future) - LOAD_OFFSET) { \
 439                 __start___kcrctab_gpl_future = .;                       \
 440                 KEEP(*(SORT(___kcrctab_gpl_future+*)))                  \
 441                 __stop___kcrctab_gpl_future = .;                        \
 442         }                                                               \
 443                                                                         \
 444         /* Kernel symbol table: strings */                              \
 445         __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \
 446                 *(__ksymtab_strings)                                    \
 447         }                                                               \
 448                                                                         \
 449         /* __*init sections */                                          \
 450         __init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) {         \
 451                 *(.ref.rodata)                                          \
 452                 MEM_KEEP(init.rodata)                                   \
 453                 MEM_KEEP(exit.rodata)                                   \
 454         }                                                               \
 455                                                                         \
 456         /* Built-in module parameters. */                               \
 457         __param : AT(ADDR(__param) - LOAD_OFFSET) {                     \
 458                 __start___param = .;                                    \
 459                 KEEP(*(__param))                                        \
 460                 __stop___param = .;                                     \
 461         }                                                               \
 462                                                                         \
 463         /* Built-in module versions. */                                 \
 464         __modver : AT(ADDR(__modver) - LOAD_OFFSET) {                   \
 465                 __start___modver = .;                                   \
 466                 KEEP(*(__modver))                                       \
 467                 __stop___modver = .;                                    \
 468                 . = ALIGN((align));                                     \
 469                 __end_rodata = .;                                       \
 470         }                                                               \
 471         . = ALIGN((align));
 472
 473 /* RODATA & RO_DATA provided for backward compatibility.
 474  * All archs are supposed to use RO_DATA() */
 475 #define RODATA          RO_DATA_SECTION(4096)
 476 #define RO_DATA(align)  RO_DATA_SECTION(align)
 477
 478 #define SECURITY_INIT                                                   \
 479         .security_initcall.init : AT(ADDR(.security_initcall.init) - LOAD_OFFSET) { \
 480                 __security_initcall_start = .;                          \
 481                 KEEP(*(.security_initcall.init))                        \
 482                 __security_initcall_end = .;                            \
 483         }
 484
 485 /*
 486  * .text section. Map to function alignment to avoid address changes
 487  * during second ld run in second ld pass when generating System.map
 488  *
 489  * TEXT_MAIN here will match .text.fixup and .text.unlikely if dead
 490  * code elimination is enabled, so these sections should be converted
 491  * to use ".." first.
 492  */
 493 #define TEXT_TEXT                                                       \
 494                 ALIGN_FUNCTION();                                       \
 495                 *(.text.hot TEXT_MAIN .text.fixup .text.unlikely)       \
 496                 *(.text..refcount)                                      \
 497                 *(.ref.text)                                            \
 498         MEM_KEEP(init.text*)                                            \
 499         MEM_KEEP(exit.text*)                                            \
 500
 501
 502 /* sched.text is aling to function alignment to secure we have same
 503  * address even at second ld pass when generating System.map */
 504 #define SCHED_TEXT                                                      \
 505                 ALIGN_FUNCTION();                                       \
 506                 __sched_text_start = .;                                 \
 507                 *(.sched.text)                                          \
 508                 __sched_text_end = .;
 509
 510 /* spinlock.text is aling to function alignment to secure we have same
 511  * address even at second ld pass when generating System.map */
 512 #define LOCK_TEXT                                                       \
 513                 ALIGN_FUNCTION();                                       \
 514                 __lock_text_start = .;                                  \
 515                 *(.spinlock.text)                                       \
 516                 __lock_text_end = .;
 517
 518 #define CPUIDLE_TEXT                                                    \
 519                 ALIGN_FUNCTION();                                       \
 520                 __cpuidle_text_start = .;                               \
 521                 *(.cpuidle.text)                                        \
 522                 __cpuidle_text_end = .;
 523
 524 #define KPROBES_TEXT                                                    \
 525                 ALIGN_FUNCTION();                                       \
 526                 __kprobes_text_start = .;                               \
 527                 *(.kprobes.text)                                        \
 528                 __kprobes_text_end = .;
 529
 530 #define ENTRY_TEXT                                                      \
 531                 ALIGN_FUNCTION();                                       \
 532                 __entry_text_start = .;                                 \
 533                 *(.entry.text)                                          \
 534                 __entry_text_end = .;
 535
 536 #define IRQENTRY_TEXT                                                   \
 537                 ALIGN_FUNCTION();                                       \
 538                 __irqentry_text_start = .;                              \
 539                 *(.irqentry.text)                                       \
 540                 __irqentry_text_end = .;
 541
 542 #define SOFTIRQENTRY_TEXT                                               \
 543                 ALIGN_FUNCTION();                                       \
 544                 __softirqentry_text_start = .;                          \
 545                 *(.softirqentry.text)                                   \
 546                 __softirqentry_text_end = .;
 547
 548 /* Section used for early init (in .S files) */
 549 #define HEAD_TEXT  KEEP(*(.head.text))
 550
 551 #define HEAD_TEXT_SECTION                                                       \
 552         .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) {               \
 553                 HEAD_TEXT                                               \
 554         }
 555
 556 /*
 557  * Exception table
 558  */
 559 #define EXCEPTION_TABLE(align)                                          \
 560         . = ALIGN(align);                                               \
 561         __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) {               \
 562                 __start___ex_table = .;                                 \
 563                 KEEP(*(__ex_table))                                     \
 564                 __stop___ex_table = .;                                  \
 565         }
 566
 567 /*
 568  * Init task
 569  */
 570 #define INIT_TASK_DATA_SECTION(align)                                   \
 571         . = ALIGN(align);                                               \
 572         .data..init_task :  AT(ADDR(.data..init_task) - LOAD_OFFSET) {  \
 573                 INIT_TASK_DATA(align)                                   \
 574         }
 575
 576 #ifdef CONFIG_CONSTRUCTORS
 577 #define KERNEL_CTORS()  . = ALIGN(8);                      \
 578                         __ctors_start = .;                 \
 579                         KEEP(*(.ctors))                    \
 580                         KEEP(*(SORT(.init_array.*)))       \
 581                         KEEP(*(.init_array))               \
 582                         __ctors_end = .;
 583 #else
 584 #define KERNEL_CTORS()
 585 #endif
 586
 587 /* init and exit section handling */
 588 #define INIT_DATA                                                       \
 589         KEEP(*(SORT(___kentry+*)))                                      \
 590         *(.init.data init.data.*)                                       \
 591         MEM_DISCARD(init.data*)                                         \
 592         KERNEL_CTORS()                                                  \
 593         MCOUNT_REC()                                                    \
 594         *(.init.rodata .init.rodata.*)                                  \
 595         FTRACE_EVENTS()                                                 \
 596         TRACE_SYSCALLS()                                                \
 597         KPROBE_BLACKLIST()                                              \
 598         ERROR_INJECT_WHITELIST()                                        \
 599         MEM_DISCARD(init.rodata)                                        \
 600         CLK_OF_TABLES()                                                 \
 601         RESERVEDMEM_OF_TABLES()                                         \
 602         TIMER_OF_TABLES()                                               \
 603         CPU_METHOD_OF_TABLES()                                          \
 604         CPUIDLE_METHOD_OF_TABLES()                                      \
 605         KERNEL_DTB()                                                    \
 606         IRQCHIP_OF_MATCH_TABLE()                                        \
 607         ACPI_PROBE_TABLE(irqchip)                                       \
 608         ACPI_PROBE_TABLE(timer)                                         \
 609         EARLYCON_TABLE()
 610
 611 #define INIT_TEXT                                                       \
 612         *(.init.text .init.text.*)                                      \
 613         *(.text.startup)                                                \
 614         MEM_DISCARD(init.text*)
 615
 616 #define EXIT_DATA                                                       \
 617         *(.exit.data .exit.data.*)                                      \
 618         *(.fini_array .fini_array.*)                                    \
 619         *(.dtors .dtors.*)                                              \
 620         MEM_DISCARD(exit.data*)                                         \
 621         MEM_DISCARD(exit.rodata*)
 622
 623 #define EXIT_TEXT                                                       \
 624         *(.exit.text)                                                   \
 625         *(.text.exit)                                                   \
 626         MEM_DISCARD(exit.text)
 627
 628 #define EXIT_CALL                                                       \
 629         *(.exitcall.exit)
 630
 631 /*
 632  * bss (Block Started by Symbol) - uninitialized data
 633  * zeroed during startup
 634  */
 635 #define SBSS(sbss_align)                                                \
 636         . = ALIGN(sbss_align);                                          \
 637         .sbss : AT(ADDR(.sbss) - LOAD_OFFSET) {                         \
 638                 *(.dynsbss)                                             \
 639                 *(SBSS_MAIN)                                            \
 640                 *(.scommon)                                             \
 641         }
 642
 643 /*
 644  * Allow archectures to redefine BSS_FIRST_SECTIONS to add extra
 645  * sections to the front of bss.
 646  */
 647 #ifndef BSS_FIRST_SECTIONS
 648 #define BSS_FIRST_SECTIONS
 649 #endif
 650
 651 #define BSS(bss_align)                                                  \
 652         . = ALIGN(bss_align);                                           \
 653         .bss : AT(ADDR(.bss) - LOAD_OFFSET) {                           \
 654                 BSS_FIRST_SECTIONS                                      \
 655                 . = ALIGN(PAGE_SIZE);                                   \
 656                 *(.bss..page_aligned)                                   \
 657                 . = ALIGN(PAGE_SIZE);                                   \
 658                 *(.dynbss)                                              \
 659                 *(BSS_MAIN)                                             \
 660                 *(COMMON)                                               \
 661         }
 662
 663 /*
 664  * DWARF debug sections.
 665  * Symbols in the DWARF debugging sections are relative to
 666  * the beginning of the section so we begin them at 0.
 667  */
 668 #define DWARF_DEBUG                                                     \
 669                 /* DWARF 1 */                                           \
 670                 .debug          0 : { *(.debug) }                       \
 671                 .line           0 : { *(.line) }                        \
 672                 /* GNU DWARF 1 extensions */                            \
 673                 .debug_srcinfo  0 : { *(.debug_srcinfo) }               \
 674                 .debug_sfnames  0 : { *(.debug_sfnames) }               \
 675                 /* DWARF 1.1 and DWARF 2 */                             \
 676                 .debug_aranges  0 : { *(.debug_aranges) }               \
 677                 .debug_pubnames 0 : { *(.debug_pubnames) }              \
 678                 /* DWARF 2 */                                           \
 679                 .debug_info     0 : { *(.debug_info                     \
 680                                 .gnu.linkonce.wi.*) }                   \
 681                 .debug_abbrev   0 : { *(.debug_abbrev) }                \
 682                 .debug_line     0 : { *(.debug_line) }                  \
 683                 .debug_frame    0 : { *(.debug_frame) }                 \
 684                 .debug_str      0 : { *(.debug_str) }                   \
 685                 .debug_loc      0 : { *(.debug_loc) }                   \
 686                 .debug_macinfo  0 : { *(.debug_macinfo) }               \
 687                 .debug_pubtypes 0 : { *(.debug_pubtypes) }              \
 688                 /* DWARF 3 */                                           \
 689                 .debug_ranges   0 : { *(.debug_ranges) }                \
 690                 /* SGI/MIPS DWARF 2 extensions */                       \
 691                 .debug_weaknames 0 : { *(.debug_weaknames) }            \
 692                 .debug_funcnames 0 : { *(.debug_funcnames) }            \
 693                 .debug_typenames 0 : { *(.debug_typenames) }            \
 694                 .debug_varnames  0 : { *(.debug_varnames) }             \
 695                 /* GNU DWARF 2 extensions */                            \
 696                 .debug_gnu_pubnames 0 : { *(.debug_gnu_pubnames) }      \
 697                 .debug_gnu_pubtypes 0 : { *(.debug_gnu_pubtypes) }      \
 698                 /* DWARF 4 */                                           \
 699                 .debug_types    0 : { *(.debug_types) }                 \
 700                 /* DWARF 5 */                                           \
 701                 .debug_macro    0 : { *(.debug_macro) }                 \
 702                 .debug_addr     0 : { *(.debug_addr) }
 703
 704                 /* Stabs debugging sections.  */
 705 #define STABS_DEBUG                                                     \
 706                 .stab 0 : { *(.stab) }                                  \
 707                 .stabstr 0 : { *(.stabstr) }                            \
 708                 .stab.excl 0 : { *(.stab.excl) }                        \
 709                 .stab.exclstr 0 : { *(.stab.exclstr) }                  \
 710                 .stab.index 0 : { *(.stab.index) }                      \
 711                 .stab.indexstr 0 : { *(.stab.indexstr) }                \
 712                 .comment 0 : { *(.comment) }
 713
 714 #ifdef CONFIG_GENERIC_BUG
 715 #define BUG_TABLE                                                       \
 716         . = ALIGN(8);                                                   \
 717         __bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) {             \
 718                 __start___bug_table = .;                                \
 719                 KEEP(*(__bug_table))                                    \
 720                 __stop___bug_table = .;                                 \
 721         }
 722 #else
 723 #define BUG_TABLE
 724 #endif
 725
 726 #ifdef CONFIG_UNWINDER_ORC
 727 #define ORC_UNWIND_TABLE                                                \
 728         . = ALIGN(4);                                                   \
 729         .orc_unwind_ip : AT(ADDR(.orc_unwind_ip) - LOAD_OFFSET) {       \
 730                 __start_orc_unwind_ip = .;                              \
 731                 KEEP(*(.orc_unwind_ip))                                 \
 732                 __stop_orc_unwind_ip = .;                               \
 733         }                                                               \
 734         . = ALIGN(2);                                                   \
 735         .orc_unwind : AT(ADDR(.orc_unwind) - LOAD_OFFSET) {             \
 736                 __start_orc_unwind = .;                                 \
 737                 KEEP(*(.orc_unwind))                                    \
 738                 __stop_orc_unwind = .;                                  \
 739         }                                                               \
 740         . = ALIGN(4);                                                   \
 741         .orc_lookup : AT(ADDR(.orc_lookup) - LOAD_OFFSET) {             \
 742                 orc_lookup = .;                                         \
 743                 . += (((SIZEOF(.text) + LOOKUP_BLOCK_SIZE - 1) /        \
 744                         LOOKUP_BLOCK_SIZE) + 1) * 4;                    \
 745                 orc_lookup_end = .;                                     \
 746         }
 747 #else
 748 #define ORC_UNWIND_TABLE
 749 #endif
 750
 751 #ifdef CONFIG_PM_TRACE
 752 #define TRACEDATA                                                       \
 753         . = ALIGN(4);                                                   \
 754         .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) {               \
 755                 __tracedata_start = .;                                  \
 756                 KEEP(*(.tracedata))                                     \
 757                 __tracedata_end = .;                                    \
 758         }
 759 #else
 760 #define TRACEDATA
 761 #endif
 762
 763 #define NOTES                                                           \
 764         .notes : AT(ADDR(.notes) - LOAD_OFFSET) {                       \
 765                 __start_notes = .;                                      \
 766                 KEEP(*(.note.*))                                        \
 767                 __stop_notes = .;                                       \
 768         }
 769
 770 #define INIT_SETUP(initsetup_align)                                     \
 771                 . = ALIGN(initsetup_align);                             \
 772                 __setup_start = .;                                      \
 773                 KEEP(*(.init.setup))                                    \
 774                 __setup_end = .;
 775
 776 #define INIT_CALLS_LEVEL(level)                                         \
 777                 __initcall##level##_start = .;                          \
 778                 KEEP(*(.initcall##level##.init))                        \
 779                 KEEP(*(.initcall##level##s.init))                       \
 780
 781 #define INIT_CALLS                                                      \
 782                 __initcall_start = .;                                   \
 783                 KEEP(*(.initcallearly.init))                            \
 784                 INIT_CALLS_LEVEL(0)                                     \
 785                 INIT_CALLS_LEVEL(1)                                     \
 786                 INIT_CALLS_LEVEL(2)                                     \
 787                 INIT_CALLS_LEVEL(3)                                     \
 788                 INIT_CALLS_LEVEL(4)                                     \
 789                 INIT_CALLS_LEVEL(5)                                     \
 790                 INIT_CALLS_LEVEL(rootfs)                                \
 791                 INIT_CALLS_LEVEL(6)                                     \
 792                 INIT_CALLS_LEVEL(7)                                     \
 793                 __initcall_end = .;
 794
 795 #define CON_INITCALL                                                    \
 796                 __con_initcall_start = .;                               \
 797                 KEEP(*(.con_initcall.init))                             \
 798                 __con_initcall_end = .;
 799
 800 #define SECURITY_INITCALL                                               \
 801                 __security_initcall_start = .;                          \
 802                 KEEP(*(.security_initcall.init))                        \
 803                 __security_initcall_end = .;
 804
 805 #ifdef CONFIG_BLK_DEV_INITRD
 806 #define INIT_RAM_FS                                                     \
 807         . = ALIGN(4);                                                   \
 808         __initramfs_start = .;                                          \
 809         KEEP(*(.init.ramfs))                                            \
 810         . = ALIGN(8);                                                   \
 811         KEEP(*(.init.ramfs.info))
 812 #else
 813 #define INIT_RAM_FS
 814 #endif
 815
 816 /*
 817  * Memory encryption operates on a page basis. Since we need to clear
 818  * the memory encryption mask for this section, it needs to be aligned
 819  * on a page boundary and be a page-size multiple in length.
 820  *
 821  * Note: We use a separate section so that only this section gets
 822  * decrypted to avoid exposing more than we wish.
 823  */
 824 #ifdef CONFIG_AMD_MEM_ENCRYPT
 825 #define PERCPU_DECRYPTED_SECTION                                        \
 826         . = ALIGN(PAGE_SIZE);                                           \
 827         *(.data..percpu..decrypted)                                     \
 828         . = ALIGN(PAGE_SIZE);
 829 #else
 830 #define PERCPU_DECRYPTED_SECTION
 831 #endif
 832
 833
 834 /*
 835  * Default discarded sections.
 836  *
 837  * Some archs want to discard exit text/data at runtime rather than
 838  * link time due to cross-section references such as alt instructions,
 839  * bug table, eh_frame, etc.  DISCARDS must be the last of output
 840  * section definitions so that such archs put those in earlier section
 841  * definitions.
 842  */
 843 #define DISCARDS                                                        \
 844         /DISCARD/ : {                                                   \
 845         EXIT_TEXT                                                       \
 846         EXIT_DATA                                                       \
 847         EXIT_CALL                                                       \
 848         *(.discard)                                                     \
 849         *(.discard.*)                                                   \
 850         }
 851
 852 /**
 853  * PERCPU_INPUT - the percpu input sections
 854  * @cacheline: cacheline size
 855  *
 856  * The core percpu section names and core symbols which do not rely
 857  * directly upon load addresses.
 858  *
 859  * @cacheline is used to align subsections to avoid false cacheline
 860  * sharing between subsections for different purposes.
 861  */
 862 #define PERCPU_INPUT(cacheline)                                         \
 863         __per_cpu_start = .;                                            \
 864         *(.data..percpu..first)                                         \
 865         . = ALIGN(PAGE_SIZE);                                           \
 866         *(.data..percpu..page_aligned)                                  \
 867         . = ALIGN(cacheline);                                           \
 868         *(.data..percpu..read_mostly)                                   \
 869         . = ALIGN(cacheline);                                           \
 870         *(.data..percpu)                                                \
 871         *(.data..percpu..shared_aligned)                                \
 872         PERCPU_DECRYPTED_SECTION                                        \
 873         __per_cpu_end = .;
 874
 875 /**
 876  * PERCPU_VADDR - define output section for percpu area
 877  * @cacheline: cacheline size
 878  * @vaddr: explicit base address (optional)
 879  * @phdr: destination PHDR (optional)
 880  *
 881  * Macro which expands to output section for percpu area.
 882  *
 883  * @cacheline is used to align subsections to avoid false cacheline
 884  * sharing between subsections for different purposes.
 885  *
 886  * If @vaddr is not blank, it specifies explicit base address and all
 887  * percpu symbols will be offset from the given address.  If blank,
 888  * @vaddr always equals @laddr + LOAD_OFFSET.
 889  *
 890  * @phdr defines the output PHDR to use if not blank.  Be warned that
 891  * output PHDR is sticky.  If @phdr is specified, the next output
 892  * section in the linker script will go there too.  @phdr should have
 893  * a leading colon.
 894  *
 895  * Note that this macros defines __per_cpu_load as an absolute symbol.
 896  * If there is no need to put the percpu section at a predetermined
 897  * address, use PERCPU_SECTION.
 898  */
 899 #define PERCPU_VADDR(cacheline, vaddr, phdr)                            \
 900         __per_cpu_load = .;                                             \
 901         .data..percpu vaddr : AT(__per_cpu_load - LOAD_OFFSET) {        \
 902                 PERCPU_INPUT(cacheline)                                 \
 903         } phdr                                                          \
 904         . = __per_cpu_load + SIZEOF(.data..percpu);
 905
 906 /**
 907  * PERCPU_SECTION - define output section for percpu area, simple version
 908  * @cacheline: cacheline size
 909  *
 910  * Align to PAGE_SIZE and outputs output section for percpu area.  This
 911  * macro doesn't manipulate @vaddr or @phdr and __per_cpu_load and
 912  * __per_cpu_start will be identical.
 913  *
 914  * This macro is equivalent to ALIGN(PAGE_SIZE); PERCPU_VADDR(@cacheline,,)
 915  * except that __per_cpu_load is defined as a relative symbol against
 916  * .data..percpu which is required for relocatable x86_32 configuration.
 917  */
 918 #define PERCPU_SECTION(cacheline)                                       \
 919         . = ALIGN(PAGE_SIZE);                                           \
 920         .data..percpu   : AT(ADDR(.data..percpu) - LOAD_OFFSET) {       \
 921                 __per_cpu_load = .;                                     \
 922                 PERCPU_INPUT(cacheline)                                 \
 923         }
 924
 925
 926 /*
 927  * Definition of the high level *_SECTION macros
 928  * They will fit only a subset of the architectures
 929  */
 930
 931
 932 /*
 933  * Writeable data.
 934  * All sections are combined in a single .data section.
 935  * The sections following CONSTRUCTORS are arranged so their
 936  * typical alignment matches.
 937  * A cacheline is typical/always less than a PAGE_SIZE so
 938  * the sections that has this restriction (or similar)
 939  * is located before the ones requiring PAGE_SIZE alignment.
 940  * NOSAVE_DATA starts and ends with a PAGE_SIZE alignment which
 941  * matches the requirement of PAGE_ALIGNED_DATA.
 942  *
 943  * use 0 as page_align if page_aligned data is not used */
 944 #define RW_DATA_SECTION(cacheline, pagealigned, inittask)               \
 945         . = ALIGN(PAGE_SIZE);                                           \
 946         .data : AT(ADDR(.data) - LOAD_OFFSET) {                         \
 947                 INIT_TASK_DATA(inittask)                                \
 948                 NOSAVE_DATA                                             \
 949                 PAGE_ALIGNED_DATA(pagealigned)                          \
 950                 CACHELINE_ALIGNED_DATA(cacheline)                       \
 951                 READ_MOSTLY_DATA(cacheline)                             \
 952                 DATA_DATA                                               \
 953                 CONSTRUCTORS                                            \
 954         }                                                               \
 955         BUG_TABLE                                                       \
 956
 957 #define INIT_TEXT_SECTION(inittext_align)                               \
 958         . = ALIGN(inittext_align);                                      \
 959         .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {               \
 960                 _sinittext = .;                                         \
 961                 INIT_TEXT                                               \
 962                 _einittext = .;                                         \
 963         }
 964
 965 #define INIT_DATA_SECTION(initsetup_align)                              \
 966         .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) {               \
 967                 INIT_DATA                                               \
 968                 INIT_SETUP(initsetup_align)                             \
 969                 INIT_CALLS                                              \
 970                 CON_INITCALL                                            \
 971                 SECURITY_INITCALL                                       \
 972                 INIT_RAM_FS                                             \
 973         }
 974
 975 #define BSS_SECTION(sbss_align, bss_align, stop_align)                  \
 976         . = ALIGN(sbss_align);                                          \
 977         __bss_start = .;                                                \
 978         SBSS(sbss_align)                                                \
 979         BSS(bss_align)                                                  \
 980         . = ALIGN(stop_align);                                          \
 981         __bss_stop = .;