include/asm-generic/vmlinux.lds.h

   1 /*
   2  * Helper macros to support writing architecture specific
   3  * linker scripts.
   4  *
   5  * A minimal linker scripts has following content:
   6  * [This is a sample, architectures may have special requiriements]
   7  *
   8  * OUTPUT_FORMAT(...)
   9  * OUTPUT_ARCH(...)
  10  * ENTRY(...)
  11  * SECTIONS
  12  * {
  13  *      . = START;
  14  *      __init_begin = .;
  15  *      HEAD_TEXT_SECTION
  16  *      INIT_TEXT_SECTION(PAGE_SIZE)
  17  *      INIT_DATA_SECTION(...)
  18  *      PERCPU_SECTION(CACHELINE_SIZE)
  19  *      __init_end = .;
  20  *
  21  *      _stext = .;
  22  *      TEXT_SECTION = 0
  23  *      _etext = .;
  24  *
  25  *      _sdata = .;
  26  *      RO_DATA_SECTION(PAGE_SIZE)
  27  *      RW_DATA_SECTION(...)
  28  *      _edata = .;
  29  *
  30  *      EXCEPTION_TABLE(...)
  31  *      NOTES
  32  *
  33  *      BSS_SECTION(0, 0, 0)
  34  *      _end = .;
  35  *
  36  *      STABS_DEBUG
  37  *      DWARF_DEBUG
  38  *
  39  *      DISCARDS                // must be the last
  40  * }
  41  *
  42  * [__init_begin, __init_end] is the init section that may be freed after init
  43  *      // __init_begin and __init_end should be page aligned, so that we can
  44  *      // free the whole .init memory
  45  * [_stext, _etext] is the text section
  46  * [_sdata, _edata] is the data section
  47  *
  48  * Some of the included output section have their own set of constants.
  49  * Examples are: [__initramfs_start, __initramfs_end] for initramfs and
  50  *               [__nosave_begin, __nosave_end] for the nosave data
  51  */
  52
  53 #ifndef LOAD_OFFSET
  54 #define LOAD_OFFSET 0
  55 #endif
  56
  57 /* Align . to a 8 byte boundary equals to maximum function alignment. */
  58 #define ALIGN_FUNCTION()  . = ALIGN(8)
  59
  60 /*
  61  * LD_DEAD_CODE_DATA_ELIMINATION option enables -fdata-sections, which
  62  * generates .data.identifier sections, which need to be pulled in with
  63  * .data. We don't want to pull in .data..other sections, which Linux
  64  * has defined. Same for text and bss.
  65  *
  66  * RODATA_MAIN is not used because existing code already defines .rodata.x
  67  * sections to be brought in with rodata.
  68  */
  69 #ifdef CONFIG_LD_DEAD_CODE_DATA_ELIMINATION
  70 #define TEXT_MAIN .text .text.[0-9a-zA-Z_]*
  71 #define DATA_MAIN .data .data.[0-9a-zA-Z_]*
  72 #define SDATA_MAIN .sdata .sdata.[0-9a-zA-Z_]*
  73 #define RODATA_MAIN .rodata .rodata.[0-9a-zA-Z_]*
  74 #define BSS_MAIN .bss .bss.[0-9a-zA-Z_]*
  75 #define SBSS_MAIN .sbss .sbss.[0-9a-zA-Z_]*
  76 #else
  77 #define TEXT_MAIN .text
  78 #define DATA_MAIN .data
  79 #define SDATA_MAIN .sdata
  80 #define RODATA_MAIN .rodata
  81 #define BSS_MAIN .bss
  82 #define SBSS_MAIN .sbss
  83 #endif
  84
  85 /*
  86  * Align to a 32 byte boundary equal to the
  87  * alignment gcc 4.5 uses for a struct
  88  */
  89 #define STRUCT_ALIGNMENT 32
  90 #define STRUCT_ALIGN() . = ALIGN(STRUCT_ALIGNMENT)
  91
  92 /* The actual configuration determine if the init/exit sections
  93  * are handled as text/data or they can be discarded (which
  94  * often happens at runtime)
  95  */
  96 #ifdef CONFIG_HOTPLUG_CPU
  97 #define CPU_KEEP(sec)    *(.cpu##sec)
  98 #define CPU_DISCARD(sec)
  99 #else
 100 #define CPU_KEEP(sec)
 101 #define CPU_DISCARD(sec) *(.cpu##sec)
 102 #endif
 103
 104 #if defined(CONFIG_MEMORY_HOTPLUG)
 105 #define MEM_KEEP(sec)    *(.mem##sec)
 106 #define MEM_DISCARD(sec)
 107 #else
 108 #define MEM_KEEP(sec)
 109 #define MEM_DISCARD(sec) *(.mem##sec)
 110 #endif
 111
 112 #ifdef CONFIG_FTRACE_MCOUNT_RECORD
 113 #define MCOUNT_REC()    . = ALIGN(8);                           \
 114                         __start_mcount_loc = .;                 \
 115                         KEEP(*(__mcount_loc))                   \
 116                         __stop_mcount_loc = .;
 117 #else
 118 #define MCOUNT_REC()
 119 #endif
 120
 121 #ifdef CONFIG_TRACE_BRANCH_PROFILING
 122 #define LIKELY_PROFILE()        __start_annotated_branch_profile = .;   \
 123                                 KEEP(*(_ftrace_annotated_branch))       \
 124                                 __stop_annotated_branch_profile = .;
 125 #else
 126 #define LIKELY_PROFILE()
 127 #endif
 128
 129 #ifdef CONFIG_PROFILE_ALL_BRANCHES
 130 #define BRANCH_PROFILE()        __start_branch_profile = .;             \
 131                                 KEEP(*(_ftrace_branch))                 \
 132                                 __stop_branch_profile = .;
 133 #else
 134 #define BRANCH_PROFILE()
 135 #endif
 136
 137 #ifdef CONFIG_KPROBES
 138 #define KPROBE_BLACKLIST()      . = ALIGN(8);                                 \
 139                                 __start_kprobe_blacklist = .;                 \
 140                                 KEEP(*(_kprobe_blacklist))                    \
 141                                 __stop_kprobe_blacklist = .;
 142 #else
 143 #define KPROBE_BLACKLIST()
 144 #endif
 145
 146 #ifdef CONFIG_FUNCTION_ERROR_INJECTION
 147 #define ERROR_INJECT_WHITELIST()        STRUCT_ALIGN();                       \
 148                         __start_error_injection_whitelist = .;                \
 149                         KEEP(*(_error_injection_whitelist))                   \
 150                         __stop_error_injection_whitelist = .;
 151 #else
 152 #define ERROR_INJECT_WHITELIST()
 153 #endif
 154
 155 #ifdef CONFIG_EVENT_TRACING
 156 #define FTRACE_EVENTS() . = ALIGN(8);                                   \
 157                         __start_ftrace_events = .;                      \
 158                         KEEP(*(_ftrace_events))                         \
 159                         __stop_ftrace_events = .;                       \
 160                         __start_ftrace_eval_maps = .;                   \
 161                         KEEP(*(_ftrace_eval_map))                       \
 162                         __stop_ftrace_eval_maps = .;
 163 #else
 164 #define FTRACE_EVENTS()
 165 #endif
 166
 167 #ifdef CONFIG_TRACING
 168 #define TRACE_PRINTKS()  __start___trace_bprintk_fmt = .;      \
 169                          KEEP(*(__trace_printk_fmt)) /* Trace_printk fmt' pointer */ \
 170                          __stop___trace_bprintk_fmt = .;
 171 #define TRACEPOINT_STR() __start___tracepoint_str = .;  \
 172                          KEEP(*(__tracepoint_str)) /* Trace_printk fmt' pointer */ \
 173                          __stop___tracepoint_str = .;
 174 #else
 175 #define TRACE_PRINTKS()
 176 #define TRACEPOINT_STR()
 177 #endif
 178
 179 #ifdef CONFIG_FTRACE_SYSCALLS
 180 #define TRACE_SYSCALLS() . = ALIGN(8);                                  \
 181                          __start_syscalls_metadata = .;                 \
 182                          KEEP(*(__syscalls_metadata))                   \
 183                          __stop_syscalls_metadata = .;
 184 #else
 185 #define TRACE_SYSCALLS()
 186 #endif
 187
 188 #ifdef CONFIG_BPF_EVENTS
 189 #define BPF_RAW_TP() STRUCT_ALIGN();                                    \
 190                          __start__bpf_raw_tp = .;                       \
 191                          KEEP(*(__bpf_raw_tp_map))                      \
 192                          __stop__bpf_raw_tp = .;
 193 #else
 194 #define BPF_RAW_TP()
 195 #endif
 196
 197 #ifdef CONFIG_SERIAL_EARLYCON
 198 #define EARLYCON_TABLE() . = ALIGN(8);                          \
 199                          __earlycon_table = .;                  \
 200                          KEEP(*(__earlycon_table))              \
 201                          __earlycon_table_end = .;
 202 #else
 203 #define EARLYCON_TABLE()
 204 #endif
 205
 206 #define ___OF_TABLE(cfg, name)  _OF_TABLE_##cfg(name)
 207 #define __OF_TABLE(cfg, name)   ___OF_TABLE(cfg, name)
 208 #define OF_TABLE(cfg, name)     __OF_TABLE(IS_ENABLED(cfg), name)
 209 #define _OF_TABLE_0(name)
 210 #define _OF_TABLE_1(name)                                               \
 211         . = ALIGN(8);                                                   \
 212         __##name##_of_table = .;                                        \
 213         KEEP(*(__##name##_of_table))                                    \
 214         KEEP(*(__##name##_of_table_end))
 215
 216 #define TIMER_OF_TABLES()       OF_TABLE(CONFIG_TIMER_OF, timer)
 217 #define IRQCHIP_OF_MATCH_TABLE() OF_TABLE(CONFIG_IRQCHIP, irqchip)
 218 #define CLK_OF_TABLES()         OF_TABLE(CONFIG_COMMON_CLK, clk)
 219 #define RESERVEDMEM_OF_TABLES() OF_TABLE(CONFIG_OF_RESERVED_MEM, reservedmem)
 220 #define CPU_METHOD_OF_TABLES()  OF_TABLE(CONFIG_SMP, cpu_method)
 221 #define CPUIDLE_METHOD_OF_TABLES() OF_TABLE(CONFIG_CPU_IDLE, cpuidle_method)
 222
 223 #ifdef CONFIG_ACPI
 224 #define ACPI_PROBE_TABLE(name)                                          \
 225         . = ALIGN(8);                                                   \
 226         __##name##_acpi_probe_table = .;                                \
 227         KEEP(*(__##name##_acpi_probe_table))                            \
 228         __##name##_acpi_probe_table_end = .;
 229 #else
 230 #define ACPI_PROBE_TABLE(name)
 231 #endif
 232
 233 #define KERNEL_DTB()                                                    \
 234         STRUCT_ALIGN();                                                 \
 235         __dtb_start = .;                                                \
 236         KEEP(*(.dtb.init.rodata))                                       \
 237         __dtb_end = .;
 238
 239 /*
 240  * .data section
 241  */
 242 #define DATA_DATA                                                       \
 243         *(.xiptext)                                                     \
 244         *(DATA_MAIN)                                                    \
 245         *(.ref.data)                                                    \
 246         *(.data..shared_aligned) /* percpu related */                   \
 247         MEM_KEEP(init.data*)                                            \
 248         MEM_KEEP(exit.data*)                                            \
 249         *(.data.unlikely)                                               \
 250         __start_once = .;                                               \
 251         *(.data.once)                                                   \
 252         __end_once = .;                                                 \
 253         STRUCT_ALIGN();                                                 \
 254         *(__tracepoints)                                                \
 255         /* implement dynamic printk debug */                            \
 256         . = ALIGN(8);                                                   \
 257         __start___jump_table = .;                                       \
 258         KEEP(*(__jump_table))                                           \
 259         __stop___jump_table = .;                                        \
 260         . = ALIGN(8);                                                   \
 261         __start___verbose = .;                                          \
 262         KEEP(*(__verbose))                                              \
 263         __stop___verbose = .;                                           \
 264         LIKELY_PROFILE()                                                \
 265         BRANCH_PROFILE()                                                \
 266         TRACE_PRINTKS()                                                 \
 267         BPF_RAW_TP()                                                    \
 268         TRACEPOINT_STR()
 269
 270 /*
 271  * Data section helpers
 272  */
 273 #define NOSAVE_DATA                                                     \
 274         . = ALIGN(PAGE_SIZE);                                           \
 275         __nosave_begin = .;                                             \
 276         *(.data..nosave)                                                \
 277         . = ALIGN(PAGE_SIZE);                                           \
 278         __nosave_end = .;
 279
 280 #define PAGE_ALIGNED_DATA(page_align)                                   \
 281         . = ALIGN(page_align);                                          \
 282         *(.data..page_aligned)
 283
 284 #define READ_MOSTLY_DATA(align)                                         \
 285         . = ALIGN(align);                                               \
 286         *(.data..read_mostly)                                           \
 287         . = ALIGN(align);
 288
 289 #define CACHELINE_ALIGNED_DATA(align)                                   \
 290         . = ALIGN(align);                                               \
 291         *(.data..cacheline_aligned)
 292
 293 #define INIT_TASK_DATA(align)                                           \
 294         . = ALIGN(align);                                               \
 295         __start_init_task = .;                                          \
 296         init_thread_union = .;                                          \
 297         init_stack = .;                                                 \
 298         KEEP(*(.data..init_task))                                       \
 299         KEEP(*(.data..init_thread_info))                                \
 300         . = __start_init_task + THREAD_SIZE;                            \
 301         __end_init_task = .;
 302
 303 /*
 304  * Allow architectures to handle ro_after_init data on their
 305  * own by defining an empty RO_AFTER_INIT_DATA.
 306  */
 307 #ifndef RO_AFTER_INIT_DATA
 308 #define RO_AFTER_INIT_DATA                                              \
 309         __start_ro_after_init = .;                                      \
 310         *(.data..ro_after_init)                                         \
 311         __end_ro_after_init = .;
 312 #endif
 313
 314 /*
 315  * Read only Data
 316  */
 317 #define RO_DATA_SECTION(align)                                          \
 318         . = ALIGN((align));                                             \
 319         .rodata           : AT(ADDR(.rodata) - LOAD_OFFSET) {           \
 320                 __start_rodata = .;                                     \
 321                 *(.rodata) *(.rodata.*)                                 \
 322                 RO_AFTER_INIT_DATA      /* Read only after init */      \
 323                 KEEP(*(__vermagic))     /* Kernel version magic */      \
 324                 . = ALIGN(8);                                           \
 325                 __start___tracepoints_ptrs = .;                         \
 326                 KEEP(*(__tracepoints_ptrs)) /* Tracepoints: pointer array */ \
 327                 __stop___tracepoints_ptrs = .;                          \
 328                 *(__tracepoints_strings)/* Tracepoints: strings */      \
 329         }                                                               \
 330                                                                         \
 331         .rodata1          : AT(ADDR(.rodata1) - LOAD_OFFSET) {          \
 332                 *(.rodata1)                                             \
 333         }                                                               \
 334                                                                         \
 335         /* PCI quirks */                                                \
 336         .pci_fixup        : AT(ADDR(.pci_fixup) - LOAD_OFFSET) {        \
 337                 __start_pci_fixups_early = .;                           \
 338                 KEEP(*(.pci_fixup_early))                               \
 339                 __end_pci_fixups_early = .;                             \
 340                 __start_pci_fixups_header = .;                          \
 341                 KEEP(*(.pci_fixup_header))                              \
 342                 __end_pci_fixups_header = .;                            \
 343                 __start_pci_fixups_final = .;                           \
 344                 KEEP(*(.pci_fixup_final))                               \
 345                 __end_pci_fixups_final = .;                             \
 346                 __start_pci_fixups_enable = .;                          \
 347                 KEEP(*(.pci_fixup_enable))                              \
 348                 __end_pci_fixups_enable = .;                            \
 349                 __start_pci_fixups_resume = .;                          \
 350                 KEEP(*(.pci_fixup_resume))                              \
 351                 __end_pci_fixups_resume = .;                            \
 352                 __start_pci_fixups_resume_early = .;                    \
 353                 KEEP(*(.pci_fixup_resume_early))                        \
 354                 __end_pci_fixups_resume_early = .;                      \
 355                 __start_pci_fixups_suspend = .;                         \
 356                 KEEP(*(.pci_fixup_suspend))                             \
 357                 __end_pci_fixups_suspend = .;                           \
 358                 __start_pci_fixups_suspend_late = .;                    \
 359                 KEEP(*(.pci_fixup_suspend_late))                        \
 360                 __end_pci_fixups_suspend_late = .;                      \
 361         }                                                               \
 362                                                                         \
 363         /* Built-in firmware blobs */                                   \
 364         .builtin_fw        : AT(ADDR(.builtin_fw) - LOAD_OFFSET) {      \
 365                 __start_builtin_fw = .;                                 \
 366                 KEEP(*(.builtin_fw))                                    \
 367                 __end_builtin_fw = .;                                   \
 368         }                                                               \
 369                                                                         \
 370         TRACEDATA                                                       \
 371                                                                         \
 372         /* Kernel symbol table: Normal symbols */                       \
 373         __ksymtab         : AT(ADDR(__ksymtab) - LOAD_OFFSET) {         \
 374                 __start___ksymtab = .;                                  \
 375                 KEEP(*(SORT(___ksymtab+*)))                             \
 376                 __stop___ksymtab = .;                                   \
 377         }                                                               \
 378                                                                         \
 379         /* Kernel symbol table: GPL-only symbols */                     \
 380         __ksymtab_gpl     : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) {     \
 381                 __start___ksymtab_gpl = .;                              \
 382                 KEEP(*(SORT(___ksymtab_gpl+*)))                         \
 383                 __stop___ksymtab_gpl = .;                               \
 384         }                                                               \
 385                                                                         \
 386         /* Kernel symbol table: Normal unused symbols */                \
 387         __ksymtab_unused  : AT(ADDR(__ksymtab_unused) - LOAD_OFFSET) {  \
 388                 __start___ksymtab_unused = .;                           \
 389                 KEEP(*(SORT(___ksymtab_unused+*)))                      \
 390                 __stop___ksymtab_unused = .;                            \
 391         }                                                               \
 392                                                                         \
 393         /* Kernel symbol table: GPL-only unused symbols */              \
 394         __ksymtab_unused_gpl : AT(ADDR(__ksymtab_unused_gpl) - LOAD_OFFSET) { \
 395                 __start___ksymtab_unused_gpl = .;                       \
 396                 KEEP(*(SORT(___ksymtab_unused_gpl+*)))                  \
 397                 __stop___ksymtab_unused_gpl = .;                        \
 398         }                                                               \
 399                                                                         \
 400         /* Kernel symbol table: GPL-future-only symbols */              \
 401         __ksymtab_gpl_future : AT(ADDR(__ksymtab_gpl_future) - LOAD_OFFSET) { \
 402                 __start___ksymtab_gpl_future = .;                       \
 403                 KEEP(*(SORT(___ksymtab_gpl_future+*)))                  \
 404                 __stop___ksymtab_gpl_future = .;                        \
 405         }                                                               \
 406                                                                         \
 407         /* Kernel symbol table: Normal symbols */                       \
 408         __kcrctab         : AT(ADDR(__kcrctab) - LOAD_OFFSET) {         \
 409                 __start___kcrctab = .;                                  \
 410                 KEEP(*(SORT(___kcrctab+*)))                             \
 411                 __stop___kcrctab = .;                                   \
 412         }                                                               \
 413                                                                         \
 414         /* Kernel symbol table: GPL-only symbols */                     \
 415         __kcrctab_gpl     : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) {     \
 416                 __start___kcrctab_gpl = .;                              \
 417                 KEEP(*(SORT(___kcrctab_gpl+*)))                         \
 418                 __stop___kcrctab_gpl = .;                               \
 419         }                                                               \
 420                                                                         \
 421         /* Kernel symbol table: Normal unused symbols */                \
 422         __kcrctab_unused  : AT(ADDR(__kcrctab_unused) - LOAD_OFFSET) {  \
 423                 __start___kcrctab_unused = .;                           \
 424                 KEEP(*(SORT(___kcrctab_unused+*)))                      \
 425                 __stop___kcrctab_unused = .;                            \
 426         }                                                               \
 427                                                                         \
 428         /* Kernel symbol table: GPL-only unused symbols */              \
 429         __kcrctab_unused_gpl : AT(ADDR(__kcrctab_unused_gpl) - LOAD_OFFSET) { \
 430                 __start___kcrctab_unused_gpl = .;                       \
 431                 KEEP(*(SORT(___kcrctab_unused_gpl+*)))                  \
 432                 __stop___kcrctab_unused_gpl = .;                        \
 433         }                                                               \
 434                                                                         \
 435         /* Kernel symbol table: GPL-future-only symbols */              \
 436         __kcrctab_gpl_future : AT(ADDR(__kcrctab_gpl_future) - LOAD_OFFSET) { \
 437                 __start___kcrctab_gpl_future = .;                       \
 438                 KEEP(*(SORT(___kcrctab_gpl_future+*)))                  \
 439                 __stop___kcrctab_gpl_future = .;                        \
 440         }                                                               \
 441                                                                         \
 442         /* Kernel symbol table: strings */                              \
 443         __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \
 444                 *(__ksymtab_strings)                                    \
 445         }                                                               \
 446                                                                         \
 447         /* __*init sections */                                          \
 448         __init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) {         \
 449                 *(.ref.rodata)                                          \
 450                 MEM_KEEP(init.rodata)                                   \
 451                 MEM_KEEP(exit.rodata)                                   \
 452         }                                                               \
 453                                                                         \
 454         /* Built-in module parameters. */                               \
 455         __param : AT(ADDR(__param) - LOAD_OFFSET) {                     \
 456                 __start___param = .;                                    \
 457                 KEEP(*(__param))                                        \
 458                 __stop___param = .;                                     \
 459         }                                                               \
 460                                                                         \
 461         /* Built-in module versions. */                                 \
 462         __modver : AT(ADDR(__modver) - LOAD_OFFSET) {                   \
 463                 __start___modver = .;                                   \
 464                 KEEP(*(__modver))                                       \
 465                 __stop___modver = .;                                    \
 466                 . = ALIGN((align));                                     \
 467                 __end_rodata = .;                                       \
 468         }                                                               \
 469         . = ALIGN((align));
 470
 471 /* RODATA & RO_DATA provided for backward compatibility.
 472  * All archs are supposed to use RO_DATA() */
 473 #define RODATA          RO_DATA_SECTION(4096)
 474 #define RO_DATA(align)  RO_DATA_SECTION(align)
 475
 476 #define SECURITY_INIT                                                   \
 477         .security_initcall.init : AT(ADDR(.security_initcall.init) - LOAD_OFFSET) { \
 478                 __security_initcall_start = .;                          \
 479                 KEEP(*(.security_initcall.init))                        \
 480                 __security_initcall_end = .;                            \
 481         }
 482
 483 /*
 484  * .text section. Map to function alignment to avoid address changes
 485  * during second ld run in second ld pass when generating System.map
 486  *
 487  * TEXT_MAIN here will match .text.fixup and .text.unlikely if dead
 488  * code elimination is enabled, so these sections should be converted
 489  * to use ".." first.
 490  */
 491 #define TEXT_TEXT                                                       \
 492                 ALIGN_FUNCTION();                                       \
 493                 *(.text.hot TEXT_MAIN .text.fixup .text.unlikely)       \
 494                 *(.text..refcount)                                      \
 495                 *(.ref.text)                                            \
 496         MEM_KEEP(init.text*)                                            \
 497         MEM_KEEP(exit.text*)                                            \
 498
 499
 500 /* sched.text is aling to function alignment to secure we have same
 501  * address even at second ld pass when generating System.map */
 502 #define SCHED_TEXT                                                      \
 503                 ALIGN_FUNCTION();                                       \
 504                 __sched_text_start = .;                                 \
 505                 *(.sched.text)                                          \
 506                 __sched_text_end = .;
 507
 508 /* spinlock.text is aling to function alignment to secure we have same
 509  * address even at second ld pass when generating System.map */
 510 #define LOCK_TEXT                                                       \
 511                 ALIGN_FUNCTION();                                       \
 512                 __lock_text_start = .;                                  \
 513                 *(.spinlock.text)                                       \
 514                 __lock_text_end = .;
 515
 516 #define CPUIDLE_TEXT                                                    \
 517                 ALIGN_FUNCTION();                                       \
 518                 __cpuidle_text_start = .;                               \
 519                 *(.cpuidle.text)                                        \
 520                 __cpuidle_text_end = .;
 521
 522 #define KPROBES_TEXT                                                    \
 523                 ALIGN_FUNCTION();                                       \
 524                 __kprobes_text_start = .;                               \
 525                 *(.kprobes.text)                                        \
 526                 __kprobes_text_end = .;
 527
 528 #define ENTRY_TEXT                                                      \
 529                 ALIGN_FUNCTION();                                       \
 530                 __entry_text_start = .;                                 \
 531                 *(.entry.text)                                          \
 532                 __entry_text_end = .;
 533
 534 #define IRQENTRY_TEXT                                                   \
 535                 ALIGN_FUNCTION();                                       \
 536                 __irqentry_text_start = .;                              \
 537                 *(.irqentry.text)                                       \
 538                 __irqentry_text_end = .;
 539
 540 #define SOFTIRQENTRY_TEXT                                               \
 541                 ALIGN_FUNCTION();                                       \
 542                 __softirqentry_text_start = .;                          \
 543                 *(.softirqentry.text)                                   \
 544                 __softirqentry_text_end = .;
 545
 546 /* Section used for early init (in .S files) */
 547 #define HEAD_TEXT  KEEP(*(.head.text))
 548
 549 #define HEAD_TEXT_SECTION                                                       \
 550         .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) {               \
 551                 HEAD_TEXT                                               \
 552         }
 553
 554 /*
 555  * Exception table
 556  */
 557 #define EXCEPTION_TABLE(align)                                          \
 558         . = ALIGN(align);                                               \
 559         __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) {               \
 560                 __start___ex_table = .;                                 \
 561                 KEEP(*(__ex_table))                                     \
 562                 __stop___ex_table = .;                                  \
 563         }
 564
 565 /*
 566  * Init task
 567  */
 568 #define INIT_TASK_DATA_SECTION(align)                                   \
 569         . = ALIGN(align);                                               \
 570         .data..init_task :  AT(ADDR(.data..init_task) - LOAD_OFFSET) {  \
 571                 INIT_TASK_DATA(align)                                   \
 572         }
 573
 574 #ifdef CONFIG_CONSTRUCTORS
 575 #define KERNEL_CTORS()  . = ALIGN(8);                      \
 576                         __ctors_start = .;                 \
 577                         KEEP(*(.ctors))                    \
 578                         KEEP(*(SORT(.init_array.*)))       \
 579                         KEEP(*(.init_array))               \
 580                         __ctors_end = .;
 581 #else
 582 #define KERNEL_CTORS()
 583 #endif
 584
 585 /* init and exit section handling */
 586 #define INIT_DATA                                                       \
 587         KEEP(*(SORT(___kentry+*)))                                      \
 588         *(.init.data init.data.*)                                       \
 589         MEM_DISCARD(init.data*)                                         \
 590         KERNEL_CTORS()                                                  \
 591         MCOUNT_REC()                                                    \
 592         *(.init.rodata .init.rodata.*)                                  \
 593         FTRACE_EVENTS()                                                 \
 594         TRACE_SYSCALLS()                                                \
 595         KPROBE_BLACKLIST()                                              \
 596         ERROR_INJECT_WHITELIST()                                        \
 597         MEM_DISCARD(init.rodata)                                        \
 598         CLK_OF_TABLES()                                                 \
 599         RESERVEDMEM_OF_TABLES()                                         \
 600         TIMER_OF_TABLES()                                               \
 601         CPU_METHOD_OF_TABLES()                                          \
 602         CPUIDLE_METHOD_OF_TABLES()                                      \
 603         KERNEL_DTB()                                                    \
 604         IRQCHIP_OF_MATCH_TABLE()                                        \
 605         ACPI_PROBE_TABLE(irqchip)                                       \
 606         ACPI_PROBE_TABLE(timer)                                         \
 607         EARLYCON_TABLE()
 608
 609 #define INIT_TEXT                                                       \
 610         *(.init.text .init.text.*)                                      \
 611         *(.text.startup)                                                \
 612         MEM_DISCARD(init.text*)
 613
 614 #define EXIT_DATA                                                       \
 615         *(.exit.data .exit.data.*)                                      \
 616         *(.fini_array)                                                  \
 617         *(.dtors)                                                       \
 618         MEM_DISCARD(exit.data*)                                         \
 619         MEM_DISCARD(exit.rodata*)
 620
 621 #define EXIT_TEXT                                                       \
 622         *(.exit.text)                                                   \
 623         *(.text.exit)                                                   \
 624         MEM_DISCARD(exit.text)
 625
 626 #define EXIT_CALL                                                       \
 627         *(.exitcall.exit)
 628
 629 /*
 630  * bss (Block Started by Symbol) - uninitialized data
 631  * zeroed during startup
 632  */
 633 #define SBSS(sbss_align)                                                \
 634         . = ALIGN(sbss_align);                                          \
 635         .sbss : AT(ADDR(.sbss) - LOAD_OFFSET) {                         \
 636                 *(.dynsbss)                                             \
 637                 *(SBSS_MAIN)                                            \
 638                 *(.scommon)                                             \
 639         }
 640
 641 /*
 642  * Allow archectures to redefine BSS_FIRST_SECTIONS to add extra
 643  * sections to the front of bss.
 644  */
 645 #ifndef BSS_FIRST_SECTIONS
 646 #define BSS_FIRST_SECTIONS
 647 #endif
 648
 649 #define BSS(bss_align)                                                  \
 650         . = ALIGN(bss_align);                                           \
 651         .bss : AT(ADDR(.bss) - LOAD_OFFSET) {                           \
 652                 BSS_FIRST_SECTIONS                                      \
 653                 *(.bss..page_aligned)                                   \
 654                 *(.dynbss)                                              \
 655                 *(BSS_MAIN)                                             \
 656                 *(COMMON)                                               \
 657         }
 658
 659 /*
 660  * DWARF debug sections.
 661  * Symbols in the DWARF debugging sections are relative to
 662  * the beginning of the section so we begin them at 0.
 663  */
 664 #define DWARF_DEBUG                                                     \
 665                 /* DWARF 1 */                                           \
 666                 .debug          0 : { *(.debug) }                       \
 667                 .line           0 : { *(.line) }                        \
 668                 /* GNU DWARF 1 extensions */                            \
 669                 .debug_srcinfo  0 : { *(.debug_srcinfo) }               \
 670                 .debug_sfnames  0 : { *(.debug_sfnames) }               \
 671                 /* DWARF 1.1 and DWARF 2 */                             \
 672                 .debug_aranges  0 : { *(.debug_aranges) }               \
 673                 .debug_pubnames 0 : { *(.debug_pubnames) }              \
 674                 /* DWARF 2 */                                           \
 675                 .debug_info     0 : { *(.debug_info                     \
 676                                 .gnu.linkonce.wi.*) }                   \
 677                 .debug_abbrev   0 : { *(.debug_abbrev) }                \
 678                 .debug_line     0 : { *(.debug_line) }                  \
 679                 .debug_frame    0 : { *(.debug_frame) }                 \
 680                 .debug_str      0 : { *(.debug_str) }                   \
 681                 .debug_loc      0 : { *(.debug_loc) }                   \
 682                 .debug_macinfo  0 : { *(.debug_macinfo) }               \
 683                 .debug_pubtypes 0 : { *(.debug_pubtypes) }              \
 684                 /* DWARF 3 */                                           \
 685                 .debug_ranges   0 : { *(.debug_ranges) }                \
 686                 /* SGI/MIPS DWARF 2 extensions */                       \
 687                 .debug_weaknames 0 : { *(.debug_weaknames) }            \
 688                 .debug_funcnames 0 : { *(.debug_funcnames) }            \
 689                 .debug_typenames 0 : { *(.debug_typenames) }            \
 690                 .debug_varnames  0 : { *(.debug_varnames) }             \
 691                 /* GNU DWARF 2 extensions */                            \
 692                 .debug_gnu_pubnames 0 : { *(.debug_gnu_pubnames) }      \
 693                 .debug_gnu_pubtypes 0 : { *(.debug_gnu_pubtypes) }      \
 694                 /* DWARF 4 */                                           \
 695                 .debug_types    0 : { *(.debug_types) }                 \
 696                 /* DWARF 5 */                                           \
 697                 .debug_macro    0 : { *(.debug_macro) }                 \
 698                 .debug_addr     0 : { *(.debug_addr) }
 699
 700                 /* Stabs debugging sections.  */
 701 #define STABS_DEBUG                                                     \
 702                 .stab 0 : { *(.stab) }                                  \
 703                 .stabstr 0 : { *(.stabstr) }                            \
 704                 .stab.excl 0 : { *(.stab.excl) }                        \
 705                 .stab.exclstr 0 : { *(.stab.exclstr) }                  \
 706                 .stab.index 0 : { *(.stab.index) }                      \
 707                 .stab.indexstr 0 : { *(.stab.indexstr) }                \
 708                 .comment 0 : { *(.comment) }
 709
 710 #ifdef CONFIG_GENERIC_BUG
 711 #define BUG_TABLE                                                       \
 712         . = ALIGN(8);                                                   \
 713         __bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) {             \
 714                 __start___bug_table = .;                                \
 715                 KEEP(*(__bug_table))                                    \
 716                 __stop___bug_table = .;                                 \
 717         }
 718 #else
 719 #define BUG_TABLE
 720 #endif
 721
 722 #ifdef CONFIG_UNWINDER_ORC
 723 #define ORC_UNWIND_TABLE                                                \
 724         . = ALIGN(4);                                                   \
 725         .orc_unwind_ip : AT(ADDR(.orc_unwind_ip) - LOAD_OFFSET) {       \
 726                 __start_orc_unwind_ip = .;                              \
 727                 KEEP(*(.orc_unwind_ip))                                 \
 728                 __stop_orc_unwind_ip = .;                               \
 729         }                                                               \
 730         . = ALIGN(6);                                                   \
 731         .orc_unwind : AT(ADDR(.orc_unwind) - LOAD_OFFSET) {             \
 732                 __start_orc_unwind = .;                                 \
 733                 KEEP(*(.orc_unwind))                                    \
 734                 __stop_orc_unwind = .;                                  \
 735         }                                                               \
 736         . = ALIGN(4);                                                   \
 737         .orc_lookup : AT(ADDR(.orc_lookup) - LOAD_OFFSET) {             \
 738                 orc_lookup = .;                                         \
 739                 . += (((SIZEOF(.text) + LOOKUP_BLOCK_SIZE - 1) /        \
 740                         LOOKUP_BLOCK_SIZE) + 1) * 4;                    \
 741                 orc_lookup_end = .;                                     \
 742         }
 743 #else
 744 #define ORC_UNWIND_TABLE
 745 #endif
 746
 747 #ifdef CONFIG_PM_TRACE
 748 #define TRACEDATA                                                       \
 749         . = ALIGN(4);                                                   \
 750         .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) {               \
 751                 __tracedata_start = .;                                  \
 752                 KEEP(*(.tracedata))                                     \
 753                 __tracedata_end = .;                                    \
 754         }
 755 #else
 756 #define TRACEDATA
 757 #endif
 758
 759 #define NOTES                                                           \
 760         .notes : AT(ADDR(.notes) - LOAD_OFFSET) {                       \
 761                 __start_notes = .;                                      \
 762                 KEEP(*(.note.*))                                        \
 763                 __stop_notes = .;                                       \
 764         }
 765
 766 #define INIT_SETUP(initsetup_align)                                     \
 767                 . = ALIGN(initsetup_align);                             \
 768                 __setup_start = .;                                      \
 769                 KEEP(*(.init.setup))                                    \
 770                 __setup_end = .;
 771
 772 #define INIT_CALLS_LEVEL(level)                                         \
 773                 __initcall##level##_start = .;                          \
 774                 KEEP(*(.initcall##level##.init))                        \
 775                 KEEP(*(.initcall##level##s.init))                       \
 776
 777 #define INIT_CALLS                                                      \
 778                 __initcall_start = .;                                   \
 779                 KEEP(*(.initcallearly.init))                            \
 780                 INIT_CALLS_LEVEL(0)                                     \
 781                 INIT_CALLS_LEVEL(1)                                     \
 782                 INIT_CALLS_LEVEL(2)                                     \
 783                 INIT_CALLS_LEVEL(3)                                     \
 784                 INIT_CALLS_LEVEL(4)                                     \
 785                 INIT_CALLS_LEVEL(5)                                     \
 786                 INIT_CALLS_LEVEL(rootfs)                                \
 787                 INIT_CALLS_LEVEL(6)                                     \
 788                 INIT_CALLS_LEVEL(7)                                     \
 789                 __initcall_end = .;
 790
 791 #define CON_INITCALL                                                    \
 792                 __con_initcall_start = .;                               \
 793                 KEEP(*(.con_initcall.init))                             \
 794                 __con_initcall_end = .;
 795
 796 #define SECURITY_INITCALL                                               \
 797                 __security_initcall_start = .;                          \
 798                 KEEP(*(.security_initcall.init))                        \
 799                 __security_initcall_end = .;
 800
 801 #ifdef CONFIG_BLK_DEV_INITRD
 802 #define INIT_RAM_FS                                                     \
 803         . = ALIGN(4);                                                   \
 804         __initramfs_start = .;                                          \
 805         KEEP(*(.init.ramfs))                                            \
 806         . = ALIGN(8);                                                   \
 807         KEEP(*(.init.ramfs.info))
 808 #else
 809 #define INIT_RAM_FS
 810 #endif
 811
 812 /*
 813  * Memory encryption operates on a page basis. Since we need to clear
 814  * the memory encryption mask for this section, it needs to be aligned
 815  * on a page boundary and be a page-size multiple in length.
 816  *
 817  * Note: We use a separate section so that only this section gets
 818  * decrypted to avoid exposing more than we wish.
 819  */
 820 #ifdef CONFIG_AMD_MEM_ENCRYPT
 821 #define PERCPU_DECRYPTED_SECTION                                        \
 822         . = ALIGN(PAGE_SIZE);                                           \
 823         *(.data..percpu..decrypted)                                     \
 824         . = ALIGN(PAGE_SIZE);
 825 #else
 826 #define PERCPU_DECRYPTED_SECTION
 827 #endif
 828
 829
 830 /*
 831  * Default discarded sections.
 832  *
 833  * Some archs want to discard exit text/data at runtime rather than
 834  * link time due to cross-section references such as alt instructions,
 835  * bug table, eh_frame, etc.  DISCARDS must be the last of output
 836  * section definitions so that such archs put those in earlier section
 837  * definitions.
 838  */
 839 #define DISCARDS                                                        \
 840         /DISCARD/ : {                                                   \
 841         EXIT_TEXT                                                       \
 842         EXIT_DATA                                                       \
 843         EXIT_CALL                                                       \
 844         *(.discard)                                                     \
 845         *(.discard.*)                                                   \
 846         }
 847
 848 /**
 849  * PERCPU_INPUT - the percpu input sections
 850  * @cacheline: cacheline size
 851  *
 852  * The core percpu section names and core symbols which do not rely
 853  * directly upon load addresses.
 854  *
 855  * @cacheline is used to align subsections to avoid false cacheline
 856  * sharing between subsections for different purposes.
 857  */
 858 #define PERCPU_INPUT(cacheline)                                         \
 859         __per_cpu_start = .;                                            \
 860         *(.data..percpu..first)                                         \
 861         . = ALIGN(PAGE_SIZE);                                           \
 862         *(.data..percpu..page_aligned)                                  \
 863         . = ALIGN(cacheline);                                           \
 864         *(.data..percpu..read_mostly)                                   \
 865         . = ALIGN(cacheline);                                           \
 866         *(.data..percpu)                                                \
 867         *(.data..percpu..shared_aligned)                                \
 868         PERCPU_DECRYPTED_SECTION                                        \
 869         __per_cpu_end = .;
 870
 871 /**
 872  * PERCPU_VADDR - define output section for percpu area
 873  * @cacheline: cacheline size
 874  * @vaddr: explicit base address (optional)
 875  * @phdr: destination PHDR (optional)
 876  *
 877  * Macro which expands to output section for percpu area.
 878  *
 879  * @cacheline is used to align subsections to avoid false cacheline
 880  * sharing between subsections for different purposes.
 881  *
 882  * If @vaddr is not blank, it specifies explicit base address and all
 883  * percpu symbols will be offset from the given address.  If blank,
 884  * @vaddr always equals @laddr + LOAD_OFFSET.
 885  *
 886  * @phdr defines the output PHDR to use if not blank.  Be warned that
 887  * output PHDR is sticky.  If @phdr is specified, the next output
 888  * section in the linker script will go there too.  @phdr should have
 889  * a leading colon.
 890  *
 891  * Note that this macros defines __per_cpu_load as an absolute symbol.
 892  * If there is no need to put the percpu section at a predetermined
 893  * address, use PERCPU_SECTION.
 894  */
 895 #define PERCPU_VADDR(cacheline, vaddr, phdr)                            \
 896         __per_cpu_load = .;                                             \
 897         .data..percpu vaddr : AT(__per_cpu_load - LOAD_OFFSET) {        \
 898                 PERCPU_INPUT(cacheline)                                 \
 899         } phdr                                                          \
 900         . = __per_cpu_load + SIZEOF(.data..percpu);
 901
 902 /**
 903  * PERCPU_SECTION - define output section for percpu area, simple version
 904  * @cacheline: cacheline size
 905  *
 906  * Align to PAGE_SIZE and outputs output section for percpu area.  This
 907  * macro doesn't manipulate @vaddr or @phdr and __per_cpu_load and
 908  * __per_cpu_start will be identical.
 909  *
 910  * This macro is equivalent to ALIGN(PAGE_SIZE); PERCPU_VADDR(@cacheline,,)
 911  * except that __per_cpu_load is defined as a relative symbol against
 912  * .data..percpu which is required for relocatable x86_32 configuration.
 913  */
 914 #define PERCPU_SECTION(cacheline)                                       \
 915         . = ALIGN(PAGE_SIZE);                                           \
 916         .data..percpu   : AT(ADDR(.data..percpu) - LOAD_OFFSET) {       \
 917                 __per_cpu_load = .;                                     \
 918                 PERCPU_INPUT(cacheline)                                 \
 919         }
 920
 921
 922 /*
 923  * Definition of the high level *_SECTION macros
 924  * They will fit only a subset of the architectures
 925  */
 926
 927
 928 /*
 929  * Writeable data.
 930  * All sections are combined in a single .data section.
 931  * The sections following CONSTRUCTORS are arranged so their
 932  * typical alignment matches.
 933  * A cacheline is typical/always less than a PAGE_SIZE so
 934  * the sections that has this restriction (or similar)
 935  * is located before the ones requiring PAGE_SIZE alignment.
 936  * NOSAVE_DATA starts and ends with a PAGE_SIZE alignment which
 937  * matches the requirement of PAGE_ALIGNED_DATA.
 938  *
 939  * use 0 as page_align if page_aligned data is not used */
 940 #define RW_DATA_SECTION(cacheline, pagealigned, inittask)               \
 941         . = ALIGN(PAGE_SIZE);                                           \
 942         .data : AT(ADDR(.data) - LOAD_OFFSET) {                         \
 943                 INIT_TASK_DATA(inittask)                                \
 944                 NOSAVE_DATA                                             \
 945                 PAGE_ALIGNED_DATA(pagealigned)                          \
 946                 CACHELINE_ALIGNED_DATA(cacheline)                       \
 947                 READ_MOSTLY_DATA(cacheline)                             \
 948                 DATA_DATA                                               \
 949                 CONSTRUCTORS                                            \
 950         }                                                               \
 951         BUG_TABLE                                                       \
 952
 953 #define INIT_TEXT_SECTION(inittext_align)                               \
 954         . = ALIGN(inittext_align);                                      \
 955         .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {               \
 956                 _sinittext = .;                                         \
 957                 INIT_TEXT                                               \
 958                 _einittext = .;                                         \
 959         }
 960
 961 #define INIT_DATA_SECTION(initsetup_align)                              \
 962         .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) {               \
 963                 INIT_DATA                                               \
 964                 INIT_SETUP(initsetup_align)                             \
 965                 INIT_CALLS                                              \
 966                 CON_INITCALL                                            \
 967                 SECURITY_INITCALL                                       \
 968                 INIT_RAM_FS                                             \
 969         }
 970
 971 #define BSS_SECTION(sbss_align, bss_align, stop_align)                  \
 972         . = ALIGN(sbss_align);                                          \
 973         __bss_start = .;                                                \
 974         SBSS(sbss_align)                                                \
 975         BSS(bss_align)                                                  \
 976         . = ALIGN(stop_align);                                          \
 977         __bss_stop = .;