libc/string/sparc/sparc64/memchr.S

   1 /* memchr (str, ch, n) -- Return pointer to first occurrence of CH in STR less
   2    than N.
   3    For SPARC v9.
   4    Copyright (C) 1998, 1999, 2000, 2003 Free Software Foundation, Inc.
   5    This file is part of the GNU C Library.
   6    Contributed by Jan Vondrak <jvon4518@ss1000.ms.mff.cuni.cz> and
   7                   Jakub Jelinek <jj@ultra.linux.cz>.
   8    This version is developed using the same algorithm as the fast C
   9    version which carries the following introduction:
  10    Based on strlen implementation by Torbjorn Granlund (tege@sics.se),
  11    with help from Dan Sahlin (dan@sics.se) and
  12    commentary by Jim Blandy (jimb@ai.mit.edu);
  13    adaptation to memchr suggested by Dick Karpinski (dick@cca.ucsf.edu),
  14    and implemented by Roland McGrath (roland@ai.mit.edu).
  15
  16    The GNU C Library is free software; you can redistribute it and/or
  17    modify it under the terms of the GNU Lesser General Public
  18    License as published by the Free Software Foundation; either
  19    version 2.1 of the License, or (at your option) any later version.
  20
  21    The GNU C Library is distributed in the hope that it will be useful,
  22    but WITHOUT ANY WARRANTY; without even the implied warranty of
  23    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  24    Lesser General Public License for more details.
  25
  26    You should have received a copy of the GNU Lesser General Public
  27    License along with the GNU C Library; if not, see
  28    <http://www.gnu.org/licenses/>.  */
  29
  30 #include <asm/asi.h>
  31 #ifndef XCC
  32 #define XCC xcc
  33 #define USE_BPR
  34         .register       %g2, #scratch
  35         .register       %g3, #scratch
  36 #endif
  37
  38         /* Normally, this uses
  39            ((xword - 0x0101010101010101) & 0x8080808080808080) test
  40            to find out if any byte in xword could be zero. This is fast, but
  41            also gives false alarm for any byte in range 0x81-0xff. It does
  42            not matter for correctness, as if this test tells us there could
  43            be some zero byte, we check it byte by byte, but if bytes with
  44            high bits set are common in the strings, then this will give poor
  45            performance. You can #define EIGHTBIT_NOT_RARE and the algorithm
  46            will use one tick slower, but more precise test
  47            ((xword - 0x0101010101010101) & (~xword) & 0x8080808080808080),
  48            which does not give any false alarms (but if some bits are set,
  49            one cannot assume from it which bytes are zero and which are not).
  50            It is yet to be measured, what is the correct default for glibc
  51            in these days for an average user.
  52          */
  53
  54         .text
  55         .align          32
  56 ENTRY(memchr)
  57         and             %o1, 0xff, %o1                  /* IEU0         Group           */
  58 #ifdef USE_BPR
  59         brz,pn          %o2, 12f                        /* CTI+IEU1                     */
  60 #else
  61         tst             %o2                             /* IEU1                         */
  62         be,pn           %XCC, 12f                       /* CTI                          */
  63 #endif
  64          sll            %o1, 8, %g3                     /* IEU0         Group           */
  65         add             %o0, %o2, %o2                   /* IEU1                         */
  66
  67         sethi           %hi(0x01010101), %g1            /* IEU0         Group           */
  68         or              %g3, %o1, %g3                   /* IEU1                         */
  69         ldub            [%o0], %o3                      /* Load                         */
  70         sllx            %g3, 16, %g5                    /* IEU0         Group           */
  71
  72         or              %g1, %lo(0x01010101), %g1       /* IEU1                         */
  73         sllx            %g1, 32, %g2                    /* IEU0         Group           */
  74         or              %g3, %g5, %g3                   /* IEU1                         */
  75         sllx            %g3, 32, %g5                    /* IEU0         Group           */
  76
  77         cmp             %o3, %o1                        /* IEU1                         */
  78         be,pn           %xcc, 13f                       /* CTI                          */
  79          or             %g1, %g2, %g1                   /* IEU0         Group           */
  80         andcc           %o0, 7, %g0                     /* IEU1                         */
  81
  82         bne,a,pn        %icc, 21f                       /* CTI                          */
  83          add            %o0, 1, %o0                     /* IEU0         Group           */
  84         ldx             [%o0], %o3                      /* Load         Group           */
  85         sllx            %g1, 7, %g2                     /* IEU0                         */
  86
  87         or              %g3, %g5, %g3                   /* IEU1                         */
  88 1:      add             %o0, 8, %o0                     /* IEU0         Group           */
  89         xor             %o3, %g3, %o4                   /* IEU1                         */
  90                                                         /* %g1 = 0101010101010101       *
  91                                                          * %g2 = 8080088080808080       *
  92                                                          * %g3 =  c c c c c c c c       *
  93                                                          * %o3 =      value             *
  94                                                          * %o4 =   value XOR c          */
  95 2:      cmp             %o0, %o2                        /* IEU1         Group           */
  96
  97         bg,pn           %XCC, 11f                       /* CTI                          */
  98          ldxa           [%o0] ASI_PNF, %o3              /* Load                         */
  99         sub             %o4, %g1, %o5                   /* IEU0         Group           */
 100         add             %o0, 8, %o0                     /* IEU1                         */
 101 #ifdef EIGHTBIT_NOT_RARE
 102         andn            %o5, %o4, %o5                   /* IEU0         Group           */
 103 #endif
 104
 105         andcc           %o5, %g2, %g0                   /* IEU1         Group           */
 106         be,a,pt         %xcc, 2b                        /* CTI                          */
 107          xor            %o3, %g3, %o4                   /* IEU0                         */
 108         srlx            %o4, 56, %g5                    /* IEU0                         */
 109
 110         andcc           %g5, 0xff, %g0                  /* IEU1         Group           */
 111         be,pn           %icc, 3f                        /* CTI                          */
 112          srlx           %o4, 48, %g5                    /* IEU0                         */
 113         andcc           %g5, 0xff, %g0                  /* IEU1         Group           */
 114
 115         be,pn           %icc, 4f                        /* CTI                          */
 116          srlx           %o4, 40, %g5                    /* IEU0                         */
 117         andcc           %g5, 0xff, %g0                  /* IEU1         Group           */
 118         be,pn           %icc, 5f                        /* CTI                          */
 119
 120          srlx           %o4, 32, %g5                    /* IEU0                         */
 121         andcc           %g5, 0xff, %g0                  /* IEU1         Group           */
 122         be,pn           %icc, 6f                        /* CTI                          */
 123          srlx           %o4, 24, %g5                    /* IEU0                         */
 124
 125         andcc           %g5, 0xff, %g0                  /* IEU1         Group           */
 126         be,pn           %icc, 7f                        /* CTI                          */
 127          srlx           %o4, 16, %g5                    /* IEU0                         */
 128         andcc           %g5, 0xff, %g0                  /* IEU1         Group           */
 129
 130         be,pn           %icc, 8f                        /* CTI                          */
 131          srlx           %o4, 8, %g5                     /* IEU0                         */
 132         andcc           %g5, 0xff, %g0                  /* IEU1         Group           */
 133         be,pn           %icc, 9f                        /* CTI                          */
 134
 135          andcc          %o4, 0xff, %g0                  /* IEU1         Group           */
 136         bne,pt          %icc, 2b                        /* CTI                          */
 137          xor            %o3, %g3, %o4                   /* IEU0                         */
 138         retl                                            /* CTI+IEU1     Group           */
 139
 140          add            %o0, -9, %o0                    /* IEU0                         */
 141
 142         .align          16
 143 3:      retl                                            /* CTI+IEU1     Group           */
 144          add            %o0, -16, %o0                   /* IEU0                         */
 145 4:      retl                                            /* CTI+IEU1     Group           */
 146          add            %o0, -15, %o0                   /* IEU0                         */
 147
 148 5:      retl                                            /* CTI+IEU1     Group           */
 149          add            %o0, -14, %o0                   /* IEU0                         */
 150 6:      retl                                            /* CTI+IEU1     Group           */
 151          add            %o0, -13, %o0                   /* IEU0                         */
 152
 153 7:      retl                                            /* CTI+IEU1     Group           */
 154          add            %o0, -12, %o0                   /* IEU0                         */
 155 8:      retl                                            /* CTI+IEU1     Group           */
 156          add            %o0, -11, %o0                   /* IEU0                         */
 157
 158 9:      retl                                            /* CTI+IEU1     Group           */
 159          add            %o0, -10, %o0                   /* IEU0                         */
 160 11:     sub             %o4, %g1, %o5                   /* IEU0         Group           */
 161         sub             %o0, 8, %o0                     /* IEU1                         */
 162
 163         andcc           %o5, %g2, %g0                   /* IEU1         Group           */
 164         be,pt           %xcc, 12f                       /* CTI                          */
 165          sub            %o2, %o0, %o2                   /* IEU0                         */
 166         tst             %o2                             /* IEU1         Group           */
 167
 168         be,pn           %XCC, 12f                       /* CTI                          */
 169          srlx           %o4, 56, %g5                    /* IEU0                         */
 170         andcc           %g5, 0xff, %g0                  /* IEU1         Group           */
 171         be,pn           %icc, 13f                       /* CTI                          */
 172
 173          cmp            %o2, 1                          /* IEU0                         */
 174         be,pn           %XCC, 12f                       /* CTI          Group           */
 175          srlx           %o4, 48, %g5                    /* IEU0                         */
 176         andcc           %g5, 0xff, %g0                  /* IEU1         Group           */
 177
 178         be,pn           %icc, 14f                       /* CTI                          */
 179          cmp            %o2, 2                          /* IEU1         Group           */
 180         be,pn           %XCC, 12f                       /* CTI                          */
 181          srlx           %o4, 40, %g5                    /* IEU0                         */
 182
 183         andcc           %g5, 0xff, %g0                  /* IEU1         Group           */
 184         be,pn           %icc, 15f                       /* CTI                          */
 185          cmp            %o2, 3                          /* IEU1         Group           */
 186         be,pn           %XCC, 12f                       /* CTI                          */
 187
 188          srlx           %o4, 32, %g5                    /* IEU0                         */
 189         andcc           %g5, 0xff, %g0                  /* IEU1         Group           */
 190         be,pn           %icc, 16f                       /* CTI                          */
 191          cmp            %o2, 4                          /* IEU1         Group           */
 192
 193         be,pn           %XCC, 12f                       /* CTI                          */
 194          srlx           %o4, 24, %g5                    /* IEU0                         */
 195         andcc           %g5, 0xff, %g0                  /* IEU1         Group           */
 196         be,pn           %icc, 17f                       /* CTI                          */
 197
 198          cmp            %o2, 5                          /* IEU1         Group           */
 199         be,pn           %XCC, 12f                       /* CTI                          */
 200          srlx           %o4, 16, %g5                    /* IEU0                         */
 201         andcc           %g5, 0xff, %g0                  /* IEU1         Group           */
 202
 203         be,pn           %icc, 18f                       /* CTI                          */
 204          cmp            %o2, 6                          /* IEU1         Group           */
 205         be,pn           %XCC, 12f                       /* CTI                          */
 206          srlx           %o4, 8, %g5                     /* IEU0                         */
 207
 208         andcc           %g5, 0xff, %g0                  /* IEU1         Group           */
 209         be,pn           %icc, 19f                       /* CTI                          */
 210          nop                                            /* IEU0                         */
 211 12:     retl                                            /* CTI+IEU1     Group           */
 212
 213          clr            %o0                             /* IEU0                         */
 214         nop                                             /* Stub                         */
 215 13:     retl                                            /* CTI+IEU1     Group           */
 216          nop                                            /* IEU0                         */
 217
 218 14:     retl                                            /* CTI+IEU1     Group           */
 219          add            %o0, 1, %o0                     /* IEU0                         */
 220 15:     retl                                            /* CTI+IEU1     Group           */
 221          add            %o0, 2, %o0                     /* IEU0                         */
 222
 223 16:     retl                                            /* CTI+IEU1     Group           */
 224          add            %o0, 3, %o0                     /* IEU0                         */
 225 17:     retl                                            /* CTI+IEU1     Group           */
 226          add            %o0, 4, %o0                     /* IEU0                         */
 227
 228 18:     retl                                            /* CTI+IEU1     Group           */
 229          add            %o0, 5, %o0                     /* IEU0                         */
 230 19:     retl                                            /* CTI+IEU1     Group           */
 231          add            %o0, 6, %o0                     /* IEU0                         */
 232
 233 21:     cmp             %o0, %o2                        /* IEU1                         */
 234         be,pn           %XCC, 12b                       /* CTI                          */
 235          sllx           %g1, 7, %g2                     /* IEU0         Group           */
 236         ldub            [%o0], %o3                      /* Load                         */
 237
 238         or              %g3, %g5, %g3                   /* IEU1                         */
 239 22:     andcc           %o0, 7, %g0                     /* IEU1         Group           */
 240         be,a,pn         %icc, 1b                        /* CTI                          */
 241          ldx            [%o0], %o3                      /* Load                         */
 242
 243         cmp             %o3, %o1                        /* IEU1         Group           */
 244         be,pn           %xcc, 23f                       /* CTI                          */
 245          add            %o0, 1, %o0                     /* IEU0                         */
 246         cmp             %o0, %o2                        /* IEU1         Group           */
 247
 248         bne,a,pt        %XCC, 22b                       /* CTI                          */
 249          ldub           [%o0], %o3                      /* Load                         */
 250         retl                                            /* CTI+IEU1     Group           */
 251          clr            %o0                             /* IEU0                         */
 252
 253 23:     retl                                            /* CTI+IEU1     Group           */
 254          add            %o0, -1, %o0                    /* IEU0                         */
 255 END(memchr)
 256
 257 libc_hidden_def(memchr)
 258 weak_alias(memchr,__ubp_memchr)