libc/string/x86_64/memcpy.S

   1 /* Highly optimized version for x86-64.
   2    Copyright (C) 1997, 2000, 2002, 2003, 2004 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Based on i586 version contributed by Ulrich Drepper <drepper@cygnus.com>, 1997.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 #include "_glibc_inc.h"
  21
  22 /* BEWARE: `#ifdef memcpy' means that memcpy is redefined as `mempcpy',
  23    and the return value is the byte after the last one copied in
  24    the destination. */
  25 #define MEMPCPY_P (defined memcpy)
  26
  27         .text
  28 #if defined __PIC__ && !defined NOT_IN_libc && defined __UCLIBC_HAS_FORTIFY__
  29 ENTRY (__memcpy_chk)
  30         cmpq    %rdx, %rcx
  31         jb      HIDDEN_JUMPTARGET (__chk_fail)
  32 END (__memcpy_chk)
  33 #endif
  34 ENTRY (BP_SYM (memcpy))
  35         /* Cutoff for the big loop is a size of 32 bytes since otherwise
  36            the loop will never be entered.  */
  37         cmpq    $32, %rdx
  38         movq    %rdx, %rcx
  39 #if !MEMPCPY_P
  40         movq    %rdi, %r10      /* Save value. */
  41 #endif
  42
  43         /* We need this in any case.  */
  44         cld
  45
  46         jbe     1f
  47
  48         /* Align destination.  */
  49         movq    %rdi, %rax
  50         negq    %rax
  51         andq    $7, %rax
  52         subq    %rax, %rcx
  53         xchgq   %rax, %rcx
  54
  55         rep; movsb
  56
  57         movq    %rax, %rcx
  58         subq    $32, %rcx
  59         js      2f
  60
  61         /* Next 3 insns are 11 bytes total, make sure we decode them in one go */
  62         .p2align 4,,11
  63 3:
  64         /* Now correct the loop counter.  Please note that in the following
  65            code the flags are not changed anymore.  */
  66         subq    $32, %rcx
  67
  68         movq    (%rsi), %rax
  69         movq    8(%rsi), %rdx
  70         movq    16(%rsi), %r8
  71         movq    24(%rsi), %r9
  72         movq    %rax, (%rdi)
  73         movq    %rdx, 8(%rdi)
  74         movq    %r8, 16(%rdi)
  75         movq    %r9, 24(%rdi)
  76
  77         leaq    32(%rsi), %rsi
  78         leaq    32(%rdi), %rdi
  79
  80         jns     3b
  81
  82         /* Correct extra loop counter modification.  */
  83 2:      addq    $32, %rcx
  84 1:      rep; movsb
  85
  86 #if MEMPCPY_P
  87         movq    %rdi, %rax              /* Set return value.  */
  88 #else
  89         movq    %r10, %rax              /* Set return value.  */
  90
  91 #endif
  92         ret
  93
  94 END (BP_SYM (memcpy))
  95 #if !MEMPCPY_P
  96 libc_hidden_def(memcpy)
  97 #endif