libc/sysdeps/linux/i386/crt1.S

   1 /* Startup code compliant to the ELF i386 ABI.
   2    Copyright (C) 1995, 1996, 1997, 1998, 2000, 2001, 2002, 2003, 2004
   3    Free Software Foundation, Inc.
   4    This file is part of the GNU C Library.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    In addition to the permissions in the GNU Lesser General Public
  12    License, the Free Software Foundation gives you unlimited
  13    permission to link the compiled version of this file with other
  14    programs, and to distribute those programs without any restriction
  15    coming from the use of this file. (The GNU Lesser General Public
  16    License restrictions do apply in other respects; for example, they
  17    cover modification of the file, and distribution when not linked
  18    into another program.)
  19
  20    Note that people who make modified versions of this file are not
  21    obligated to grant this special exception for their modified
  22    versions; it is their choice whether to do so. The GNU Lesser
  23    General Public License gives permission to release a modified
  24    version without this exception; this exception also makes it
  25    possible to release a modified version which carries forward this
  26    exception.
  27
  28    The GNU C Library is distributed in the hope that it will be useful,
  29    but WITHOUT ANY WARRANTY; without even the implied warranty of
  30    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  31    Lesser General Public License for more details.
  32
  33    You should have received a copy of the GNU Lesser General Public
  34    License along with the GNU C Library; if not, write to the Free
  35    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  36    02111-1307 USA.  */
  37
  38 /* This is the canonical entry point, usually the first thing in the text
  39    segment.  The SVR4/i386 ABI (pages 3-31, 3-32) says that when the entry
  40    point runs, most registers' values are unspecified, except for:
  41
  42    %edx         Contains a function pointer to be registered with `atexit'.
  43                 This is how the dynamic linker arranges to have DT_FINI
  44                 functions called for shared libraries that have been loaded
  45                 before this code runs.
  46
  47    %esp         The stack contains the arguments and environment:
  48                 0(%esp)                 argc
  49                 4(%esp)                 argv[0]
  50                 ...
  51                 (4*argc)(%esp)          NULL
  52                 (4*(argc+1))(%esp)      envp[0]
  53                 ...
  54                                         NULL
  55 */
  56
  57 #include <features.h>
  58
  59 .text
  60 .global _start
  61 .type   _start,%function
  62 #if defined(__UCLIBC_CTOR_DTOR__)
  63 .type   _init,%function
  64 .type   _fini,%function
  65 #else
  66 .weak   _init
  67 .weak   _fini
  68 #endif
  69 .type   main,%function
  70 .type   __uClibc_main,%function
  71 _start:
  72         /* Clear the frame pointer.  The ABI suggests this be done, to mark
  73            the outermost frame obviously.  */
  74         xorl %ebp, %ebp
  75
  76         /* Extract the arguments as encoded on the stack and set up
  77            the arguments for `main': argc, argv.  envp will be determined
  78            later in __libc_start_main.  */
  79         popl %esi               /* Pop the argument count.  */
  80         movl %esp, %ecx         /* argv starts just at the current stack top.*/
  81
  82         /* Before pushing the arguments align the stack to a 16-byte
  83         (SSE needs 16-byte alignment) boundary to avoid penalties from
  84         misaligned accesses.  Thanks to Edward Seidl <seidl@janed.com>
  85         for pointing this out.  */
  86         andl $0xfffffff0, %esp
  87         pushl %eax              /* Push garbage because we allocate
  88                                    28 more bytes.  */
  89
  90         /* Provide the highest stack address to the user code (for stacks
  91            which grow downwards).  */
  92         pushl %esp
  93
  94         pushl %edx              /* Push address of the shared library
  95                                    termination function.  */
  96
  97 #ifdef __PIC__
  98         /* Load PIC register.  */
  99         call .L0
 100 .L0:
 101         pop %ebx
 102         addl $_GLOBAL_OFFSET_TABLE_+[.-.L0],%ebx
 103
 104         /* Push address of our own entry points to .fini and .init.  */
 105         pushl _fini@GOT(%ebx)
 106         pushl _init@GOT(%ebx)
 107
 108         pushl %ecx              /* Push second argument: argv.  */
 109         pushl %esi              /* Push first argument: argc.  */
 110
 111         pushl main@GOT(%ebx)
 112
 113         /* Call the user's main function, and exit with its value.
 114            But let the libc call main.    */
 115         call __uClibc_main@PLT
 116 #else
 117         /* Push address of our own entry points to .fini and .init.  */
 118         pushl $_fini
 119         pushl $_init
 120
 121         pushl %ecx              /* Push second argument: argv.  */
 122         pushl %esi              /* Push first argument: argc.  */
 123
 124         pushl $main
 125
 126         /* Call the user's main function, and exit with its value.
 127            But let the libc call main.    */
 128         call __uClibc_main
 129 #endif
 130
 131         hlt                     /* Crash if somehow `exit' does return.  */
 132 .size _start,.-_start
 133
 134 /* Define a symbol for the first piece of initialized data.  */
 135 .data
 136 .global __data_start
 137 __data_start:
 138 .long 0
 139 .weak data_start
 140         data_start = __data_start