libc/sysdeps/linux/powerpc/__longjmp.S

   1 /* longjmp for PowerPC.
   2    Copyright (C) 1995, 1996, 1997, 1999, 2000 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <features.h>
  21 #include "ppc_asm.h"
  22 #define _ASM
  23 #define _SETJMP_H
  24 #include <bits/setjmp.h>
  25
  26
  27 #if defined __UCLIBC_HAS_FLOATS__ && ! defined __UCLIBC_HAS_SOFT_FLOAT__
  28 #define FP(x...) x
  29 #else
  30 #define FP(x...)
  31 #endif
  32
  33 .globl      __longjmp;
  34 .type      __longjmp, @function;
  35 .align  2;
  36
  37 __longjmp:
  38         lwz r1,(JB_GPR1*4)(r3)
  39         lwz r2,(JB_GPR2*4)(r3)
  40         lwz r0,(JB_LR*4)(r3)
  41         lwz r14,((JB_GPRS+0)*4)(r3)
  42 FP(     lfd fp14,((JB_FPRS+0*2)*4)(r3))
  43         lwz r15,((JB_GPRS+1)*4)(r3)
  44 FP(     lfd fp15,((JB_FPRS+1*2)*4)(r3))
  45         lwz r16,((JB_GPRS+2)*4)(r3)
  46 FP(     lfd fp16,((JB_FPRS+2*2)*4)(r3))
  47         lwz r17,((JB_GPRS+3)*4)(r3)
  48 FP(     lfd fp17,((JB_FPRS+3*2)*4)(r3))
  49         lwz r18,((JB_GPRS+4)*4)(r3)
  50 FP(     lfd fp18,((JB_FPRS+4*2)*4)(r3))
  51         lwz r19,((JB_GPRS+5)*4)(r3)
  52 FP(     lfd fp19,((JB_FPRS+5*2)*4)(r3))
  53         lwz r20,((JB_GPRS+6)*4)(r3)
  54 FP(     lfd fp20,((JB_FPRS+6*2)*4)(r3))
  55         mtlr r0
  56         lwz r21,((JB_GPRS+7)*4)(r3)
  57 FP(     lfd fp21,((JB_FPRS+7*2)*4)(r3))
  58         lwz r22,((JB_GPRS+8)*4)(r3)
  59 FP(     lfd fp22,((JB_FPRS+8*2)*4)(r3))
  60         lwz r0,(JB_CR*4)(r3)
  61         lwz r23,((JB_GPRS+9)*4)(r3)
  62 FP(     lfd fp23,((JB_FPRS+9*2)*4)(r3))
  63         lwz r24,((JB_GPRS+10)*4)(r3)
  64 FP(     lfd fp24,((JB_FPRS+10*2)*4)(r3))
  65         lwz r25,((JB_GPRS+11)*4)(r3)
  66 FP(     lfd fp25,((JB_FPRS+11*2)*4)(r3))
  67         mtcrf 0xFF,r0
  68         lwz r26,((JB_GPRS+12)*4)(r3)
  69 FP(     lfd fp26,((JB_FPRS+12*2)*4)(r3))
  70         lwz r27,((JB_GPRS+13)*4)(r3)
  71 FP(     lfd fp27,((JB_FPRS+13*2)*4)(r3))
  72         lwz r28,((JB_GPRS+14)*4)(r3)
  73 FP(     lfd fp28,((JB_FPRS+14*2)*4)(r3))
  74         lwz r29,((JB_GPRS+15)*4)(r3)
  75 FP(     lfd fp29,((JB_FPRS+15*2)*4)(r3))
  76         lwz r30,((JB_GPRS+16)*4)(r3)
  77 FP(     lfd fp30,((JB_FPRS+16*2)*4)(r3))
  78         lwz r31,((JB_GPRS+17)*4)(r3)
  79 FP(     lfd fp31,((JB_FPRS+17*2)*4)(r3))
  80         mr r3,r4
  81         blr
  82 .size     __longjmp,.-__longjmp
  83
  84 libc_hidden_def(__longjmp)