libc/sysdeps/linux/x86_64/crt1.S

   1 /* Startup code compliant to the ELF x86-64 ABI.
   2    Copyright (C) 2001, 2002, 2003, 2005 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Andreas Jaeger <aj@suse.de>, 2001.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    In addition to the permissions in the GNU Lesser General Public
  12    License, the Free Software Foundation gives you unlimited
  13    permission to link the compiled version of this file with other
  14    programs, and to distribute those programs without any restriction
  15    coming from the use of this file. (The GNU Lesser General Public
  16    License restrictions do apply in other respects; for example, they
  17    cover modification of the file, and distribution when not linked
  18    into another program.)
  19
  20    Note that people who make modified versions of this file are not
  21    obligated to grant this special exception for their modified
  22    versions; it is their choice whether to do so. The GNU Lesser
  23    General Public License gives permission to release a modified
  24    version without this exception; this exception also makes it
  25    possible to release a modified version which carries forward this
  26    exception.
  27
  28    The GNU C Library is distributed in the hope that it will be useful,
  29    but WITHOUT ANY WARRANTY; without even the implied warranty of
  30    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  31    Lesser General Public License for more details.
  32
  33    You should have received a copy of the GNU Lesser General Public
  34    License along with the GNU C Library; if not, see
  35    <http://www.gnu.org/licenses/>.  */
  36
  37 /* Originally based on glibc's sysdeps/x86_64/elf/start.S */
  38
  39 /* This is the canonical entry point, usually the first thing in the text
  40    segment.  The SVR4/i386 ABI (pages 3-31, 3-32) says that when the entry
  41    point runs, most registers' values are unspecified, except for:
  42
  43    %rdx         Contains a function pointer to be registered with `atexit'.
  44                 This is how the dynamic linker arranges to have DT_FINI
  45                 functions called for shared libraries that have been loaded
  46                 before this code runs.
  47
  48    %rsp         The stack contains the arguments and environment:
  49                 0(%rsp)                 argc
  50                 8(%rsp)                 argv[0]
  51                 ...
  52                 (8*argc)(%rsp)          NULL
  53                 (8*(argc+1))(%rsp)      envp[0]
  54                 ...
  55                                         NULL
  56 */
  57 #if defined NOT_IN_libc
  58 # error error in build framework
  59 #endif
  60 #include <features.h>
  61
  62 .text
  63 .global _start
  64 .type   _start,%function
  65 #if defined(__UCLIBC_CTOR_DTOR__)
  66 .type   _init,%function
  67 .type   _fini,%function
  68 #else
  69 .weak   _init
  70 .weak   _fini
  71 #endif
  72 .type   __uClibc_main,%function
  73 /* Stick in a dummy reference to main(), so that if an application
  74  * is linking when the main() function is in a static library (.a)
  75  * we can be sure that main() actually gets linked in */
  76 .type   main,%function
  77
  78 _start:
  79         /* Clear the frame pointer.  The ABI suggests this be done, to mark
  80            the outermost frame obviously.  */
  81         xorl %ebp, %ebp
  82
  83         /* Extract the arguments as encoded on the stack and set up
  84            the arguments for __libc_start_main (int (*main) (int, char **, char **),
  85                    int argc, char *argv,
  86                    void (*init) (void), void (*fini) (void),
  87                    void (*rtld_fini) (void), void *stack_end).
  88            The arguments are passed via registers and on the stack:
  89         main:           %rdi
  90         argc:           %rsi
  91         argv:           %rdx
  92         init:           %rcx
  93         fini:           %r8
  94         rtld_fini:      %r9
  95         stack_end:      stack.  */
  96
  97         movq %rdx, %r9   /* Address of the shared library termination function. */
  98         popq %rsi        /* Pop the argument count. */
  99         movq %rsp, %rdx  /* argv starts just at the current stack top. */
 100
 101         /* Align the stack to a 16 byte boundary to follow the ABI. */
 102         andq $~15, %rsp
 103
 104         pushq %rax              /* Push garbage because we push 8 more bytes.  */
 105
 106         /* Provide the highest stack address to the user code (for stacks
 107            which grow downwards).  */
 108         pushq %rsp
 109
 110 #if defined(L_Scrt1)
 111         /* Give address for main() */
 112         movq main@GOTPCREL(%rip), %rdi
 113
 114         /* setup init/fini address */
 115         movq _init@GOTPCREL(%rip), %rcx
 116         movq _fini@GOTPCREL(%rip), %r8
 117
 118         /* start the fun */
 119         call __uClibc_main@PLT
 120 #else
 121         /* Give address for main() */
 122         movq $main, %rdi
 123
 124         /* setup init/fini address */
 125         movq $_init, %rcx
 126         movq $_fini, %r8
 127
 128         /* start the fun */
 129         call __uClibc_main
 130 #endif
 131
 132         hlt        /* Crash if somehow `exit' does return.  */
 133 .size _start,.-_start
 134
 135 /* Define a symbol for the first piece of initialized data. */
 136 .data
 137 .global __data_start
 138 __data_start:
 139 .long 0
 140 .weak data_start
 141         data_start = __data_start