libc/sysdeps/linux/xtensa/crt1.S

   1 /* Startup code compliant to the ELF Xtensa ABI.
   2    Copyright (C) 2001, 2007 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    In addition to the permissions in the GNU Lesser General Public
  11    License, the Free Software Foundation gives you unlimited
  12    permission to link the compiled version of this file with other
  13    programs, and to distribute those programs without any restriction
  14    coming from the use of this file. (The GNU Lesser General Public
  15    License restrictions do apply in other respects; for example, they
  16    cover modification of the file, and distribution when not linked
  17    into another program.)
  18
  19    Note that people who make modified versions of this file are not
  20    obligated to grant this special exception for their modified
  21    versions; it is their choice whether to do so. The GNU Lesser
  22    General Public License gives permission to release a modified
  23    version without this exception; this exception also makes it
  24    possible to release a modified version which carries forward this
  25    exception.
  26
  27    The GNU C Library is distributed in the hope that it will be useful,
  28    but WITHOUT ANY WARRANTY; without even the implied warranty of
  29    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  30    Lesser General Public License for more details.
  31
  32    You should have received a copy of the GNU Lesser General Public
  33    License along with the GNU C Library; if not, see
  34    <http://www.gnu.org/licenses/>.  */
  35
  36 #include <features.h>
  37
  38 #ifndef __UCLIBC_CTOR_DTOR__
  39         .weak _init
  40         .weak _fini
  41 #endif
  42
  43 /* This is the canonical entry point, usually the first thing in the text
  44    segment.  When the entry point runs, most register values are unspecified,
  45    except for:
  46
  47         a2      Contains a function pointer to be registered with `atexit'.
  48                 This is how the dynamic linker arranges to have DT_FINI
  49                 functions called for shared libraries that have been loaded
  50                 before this code runs.
  51
  52         a1      The stack (i.e., a1+16) contains the arguments and environment:
  53                 a1+0                    argc
  54                 a1+4                    argv[0]
  55                 ...
  56                 a1+(4*argc)             NULL
  57                 a1+(4*(argc+1))         envp[0]
  58                 ...
  59                                         NULL
  60
  61   Setup parameters accordingly (for a call4).  See function prototype
  62   from sysdeps/generic/libc-start.c
  63
  64         a6 = *main
  65         a7 = argc
  66         a8 = ubp_av
  67         a9 = *init
  68         a10 = *fini
  69         a11 = *rtld_fini
  70         [sp+0] = stack_end
  71  */
  72
  73         .text
  74         .align  4
  75         .literal_position
  76         .global _start
  77         .type   _start, @function
  78 _start:
  79         /* Clear a0 to obviously mark the outermost frame.  */
  80         movi    a0, 0
  81
  82         /* Load up the user's main function.  */
  83         movi    a6, main
  84
  85         /* Extract the arguments as encoded on the stack and set up
  86            the arguments for `main': argc, argv.  envp will be determined
  87            later in __uClibc_main.  */
  88         l32i    a7, a1, 0       /* Load the argument count.  */
  89         addi    a8, a1, 4       /* Compute the argv pointer.  */
  90
  91         /* Push address of our own entry points to .fini and .init.  */
  92         movi    a9, _init
  93         movi    a10, _fini
  94
  95         /* Setup the shared library termination function.  */
  96         mov     a11, a2
  97
  98         /* Provide the highest stack address to the user code (for stacks
  99            which grow downwards).  Note that we destroy the stack version
 100            of argc here.  */
 101         s32i    a1, a1, 0
 102
 103         /* Call the user's main function, and exit with its value.
 104            But let the libc call main.    */
 105         movi    a4, __uClibc_main
 106         callx4  a4
 107
 108         /* Crash if somehow `exit' does return.  */
 109         ill
 110
 111         /* Define a symbol for the first piece of initialized data.  */
 112         .data
 113         .align  4
 114         .global __data_start
 115 __data_start:
 116         .long   0
 117         .weak   data_start
 118         data_start = __data_start