libgloss/mips/ddb-kseg0.ld

   1 /* The following TEXT start address leaves space for the monitor
   2    workspace. */
   3
   4 ENTRY(_start)
   5 OUTPUT_FORMAT("elf32-bigmips", "elf32-bigmips", "elf32-littlemips")
   6 GROUP(-lc -lpmon -lgcc)
   7 SEARCH_DIR(.)
   8 __DYNAMIC  =  0;
   9
  10 /*
  11  * Allocate the stack to be at the top of memory, since the stack
  12  * grows down
  13  */
  14 PROVIDE (__stack = 0);
  15 /* PROVIDE (__global = 0); */
  16
  17 /*
  18  * Initalize some symbols to be zero so we can reference them in the
  19  * crt0 without core dumping. These functions are all optional, but
  20  * we do this so we can have our crt0 always use them if they exist.
  21  * This is so BSPs work better when using the crt0 installed with gcc.
  22  * We have to initalize them twice, so we multiple object file
  23  * formats, as some prepend an underscore.
  24  */
  25 PROVIDE (hardware_init_hook = 0);
  26 PROVIDE (software_init_hook = 0);
  27
  28 SECTIONS
  29 {
  30   . = 0x80100000;
  31   .text : {
  32      _ftext = . ;
  33     *(.init)
  34      eprol  =  .;
  35     *(.text)
  36     *(.text.*)
  37     *(.gnu.linkonce.t*)
  38     *(.mips16.fn.*)
  39     *(.mips16.call.*)
  40     PROVIDE (__runtime_reloc_start = .);
  41     *(.rel.sdata)
  42     PROVIDE (__runtime_reloc_stop = .);
  43     *(.fini)
  44      etext  =  .;
  45      _etext  =  .;
  46   }
  47
  48   .ctors    :
  49   {
  50     /* gcc uses crtbegin.o to find the start of
  51        the constructors, so we make sure it is
  52        first.  Because this is a wildcard, it
  53        doesn't matter if the user does not
  54        actually link against crtbegin.o; the
  55        linker won't look for a file to match a
  56        wildcard.  The wildcard also means that it
  57        doesn't matter which directory crtbegin.o
  58        is in.  */
  59
  60     KEEP (*crtbegin.o(.ctors))
  61
  62     /* We don't want to include the .ctor section from
  63        from the crtend.o file until after the sorted ctors.
  64        The .ctor section from the crtend file contains the
  65        end of ctors marker and it must be last */
  66
  67     KEEP (*(EXCLUDE_FILE (*crtend.o) .ctors))
  68     KEEP (*(SORT(.ctors.*)))
  69     KEEP (*(.ctors))
  70   }
  71
  72   .dtors    :
  73   {
  74     KEEP (*crtbegin.o(.dtors))
  75     KEEP (*(EXCLUDE_FILE (*crtend.o) .dtors))
  76     KEEP (*(SORT(.dtors.*)))
  77     KEEP (*(.dtors))
  78   }
  79
  80   . = .;
  81   .rdata : {
  82     *(.rdata)
  83     *(.rodata)
  84     *(.rodata.*)
  85     *(.gnu.linkonce.r*)
  86   }
  87    _fdata = ALIGN(16);
  88   .data : {
  89     *(.data)
  90     *(.data.*)
  91     *(.gnu.linkonce.d*)
  92   }
  93   . = ALIGN(8);
  94   _gp = . + 0x8000;
  95   __global = _gp;
  96   .lit8 : {
  97     *(.lit8)
  98   }
  99   .lit4 : {
 100     *(.lit4)
 101   }
 102   .sdata : {
 103     *(.sdata)
 104     *(.sdata.*)
 105     *(.gnu.linkonce.s*)
 106   }
 107   . = ALIGN(4);
 108    edata  =  .;
 109    _edata  =  .;
 110    _fbss = .;
 111   .sbss : {
 112     *(.sbss)
 113     *(.scommon)
 114   }
 115   .bss : {
 116     _bss_start = . ;
 117     *(.bss)
 118     *(COMMON)
 119   }
 120
 121    end = .;
 122    _end = .;
 123
 124   /* DWARF debug sections.
 125      Symbols in the DWARF debugging sections are relative to
 126      the beginning of the section so we begin them at 0.  */
 127
 128   /* DWARF 1 */
 129   .debug          0 : { *(.debug) }
 130   .line           0 : { *(.line) }
 131
 132   /* GNU DWARF 1 extensions */
 133   .debug_srcinfo  0 : { *(.debug_srcinfo) }
 134   .debug_sfnames  0 : { *(.debug_sfnames) }
 135
 136   /* DWARF 1.1 and DWARF 2 */
 137   .debug_aranges  0 : { *(.debug_aranges) }
 138   .debug_pubnames 0 : { *(.debug_pubnames) }
 139
 140   /* DWARF 2 */
 141   .debug_info     0 : { *(.debug_info) }
 142   .debug_abbrev   0 : { *(.debug_abbrev) }
 143   .debug_line     0 : { *(.debug_line) }
 144   .debug_frame    0 : { *(.debug_frame) }
 145   .debug_str      0 : { *(.debug_str) }
 146   .debug_loc      0 : { *(.debug_loc) }
 147   .debug_macinfo  0 : { *(.debug_macinfo) }
 148
 149   /* SGI/MIPS DWARF 2 extensions */
 150   .debug_weaknames 0 : { *(.debug_weaknames) }
 151   .debug_funcnames 0 : { *(.debug_funcnames) }
 152   .debug_typenames 0 : { *(.debug_typenames) }
 153   .debug_varnames  0 : { *(.debug_varnames) }
 154 }