libpthread/linuxthreads/sysdeps/unix/sysv/linux/i386/vfork.S

   1 /* Copyright (C) 1999, 2002, 2003 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Andreas Schwab <schwab@gnu.org>.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep-cancel.h>
  20 #define _ERRNO_H        1
  21 #include <bits/errno.h>
  22 #include <bits/kernel-features.h>
  23
  24 /* Clone the calling process, but without copying the whole address space.
  25    The calling process is suspended until the new process exits or is
  26    replaced by a call to `execve'.  Return -1 for errors, 0 to the new process,
  27    and the process ID of the new process to the old process.  */
  28
  29 ENTRY (__vfork)
  30
  31 #ifdef __NR_vfork
  32
  33 # ifdef SHARED
  34 #  if !defined HAVE_HIDDEN || !defined __UCLIBC_HAS_TLS__
  35         SETUP_PIC_REG (cx)
  36 #  else
  37         call    __i686.get_pc_thunk.cx
  38 #  endif
  39         addl    $_GLOBAL_OFFSET_TABLE_, %ecx
  40         cmpl    $0, __libc_pthread_functions@GOTOFF(%ecx)
  41 # else
  42         .weak   pthread_create
  43         movl    $pthread_create, %eax
  44         testl   %eax, %eax
  45 # endif
  46         jne     HIDDEN_JUMPTARGET (fork)
  47
  48         /* Pop the return PC value into ECX.  */
  49         popl    %ecx
  50
  51         /* Stuff the syscall number in EAX and enter into the kernel.  */
  52         movl    $SYS_ify (vfork), %eax
  53         int     $0x80
  54
  55         /* Jump to the return PC.  Don't jump directly since this
  56            disturbs the branch target cache.  Instead push the return
  57            address back on the stack.  */
  58         pushl   %ecx
  59
  60         cmpl    $-4095, %eax
  61         /* Branch forward if it failed.  */
  62 # ifdef __ASSUME_VFORK_SYSCALL
  63         jae     SYSCALL_ERROR_LABEL
  64 .Lpseudo_end:
  65 # else
  66         jae     .Lerror
  67 # endif
  68
  69         ret
  70
  71 # ifndef __ASSUME_VFORK_SYSCALL
  72 .Lerror:
  73         /* Check if vfork syscall is known at all.  */
  74         cmpl    $-ENOSYS, %eax
  75         jne     SYSCALL_ERROR_LABEL
  76 # endif
  77 #endif
  78
  79 #ifndef __ASSUME_VFORK_SYSCALL
  80         /* If we don't have vfork, fork is close enough.  */
  81
  82         movl    $SYS_ify (fork), %eax
  83         int     $0x80
  84         cmpl    $-4095, %eax
  85         jae     SYSCALL_ERROR_LABEL
  86 .Lpseudo_end:
  87         ret
  88 #elif !defined __NR_vfork
  89 # error "__NR_vfork not available and __ASSUME_VFORK_SYSCALL defined"
  90 #endif
  91 PSEUDO_END (__vfork)
  92 libc_hidden_def (__vfork)
  93
  94 weak_alias (__vfork, vfork)