mingwrt/mingwex/strnlen.sx

   1 /*
   2  * strnlen.sx
   3  *
   4  * Implementation of POSIX.1-2008 conforming strnlen(), and a wrapper
   5  * extending it to conform with ISO-C11 TR-24731-1 strnlen_s().
   6  *
   7  * $Id$
   8  *
   9  * Written by Keith Marshall <keithmarshall@users.sourceforge.net>
  10  * Copyright (C) 2016, 2017, MinGW.org Project
  11  *
  12  *
  13  * Permission is hereby granted, free of charge, to any person obtaining a
  14  * copy of this software and associated documentation files (the "Software"),
  15  * to deal in the Software without restriction, including without limitation
  16  * the rights to use, copy, modify, merge, publish, distribute, sublicense,
  17  * and/or sell copies of the Software, and to permit persons to whom the
  18  * Software is furnished to do so, subject to the following conditions:
  19  *
  20  * The above copyright notice and this permission notice (including the next
  21  * paragraph) shall be included in all copies or substantial portions of the
  22  * Software.
  23  *
  24  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  25  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  26  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  27  * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  28  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  29  * FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  30  * DEALINGS IN THE SOFTWARE.
  31  *
  32  *
  33  * This file implements a POSIX.1-2008 conforming strnlen() function, under
  34  * the alternative public name of __mingw_strnlen(), (to avoid any possible
  35  * conflict with Microsoft's DLL implementations, or a replacement function
  36  * implemented by the user).
  37  *
  38  * Note that POSIX does not prescribe any error returns for its strnlen()
  39  * function; in particular, it does not specify handling of a NULL pointer,
  40  * passed as the string argument to count, and thus, a segmentation fault
  41  * is a plausible outcome.  This is consistent with the behaviour exhibited
  42  * by Microsoft's implementation, and this implementation acts likewise.
  43  *
  44  * OTOH, ISO-C11 TR-24731-1 prescribes that strnlen_s() shall return zero,
  45  * when passed a NULL pointer as the string argument; the alternative entry
  46  * point, __mingw_strnlen_s(), checks for this anomaly, and acts accordingly,
  47  * before continuing as for __mingw_strnlen(), when passed a valid pointer
  48  * to a string argument; (this is consistent with the documented behaviour
  49  * of Microsoft's strnlen_s() implementation).
  50  *
  51  * Note that I've chosen to implement this in assembly language to enable
  52  * sharing of common code between two distinct entry points, with subtly
  53  * differing behaviours, while avoiding the overhead of an extra function
  54  * call to invoke such shared code; this also allows the code to exploit
  55  * the CPU's string scanning instructions, (which GCC does not), and so
  56  * achieves a more compact, (and likely more efficient), implementation.
  57  *
  58  */
  59 #if defined UNICODE || defined _UNICODE
  60 /* The algorithm defined herein is effectively the same as that required
  61  * as a substitute for wcsnlen()/wcsnlen_s(); map entry point names to the
  62  * appropriate alternatives for scanning wchar_t *, (rather than char *),
  63  * strings, (i.e. Microsoft's so-called UNICODE strings).
  64  */
  65 # define ___mingw_strnlen    ___mingw_wcsnlen
  66 # define ___mingw_strnlen_s  ___mingw_wcsnlen_s
  67
  68 /* The fundamental change required to scan whcar_t * strings, rather than
  69  * char * strings, is that we must use the scasw instruction in place of
  70  * the scasb instruction; map it accordingly.
  71  */
  72 # define scasb  scasw
  73 #endif
  74
  75 .text
  76 .align  4
  77 .globl  ___mingw_strnlen
  78 .def    ___mingw_strnlen;       .scl    2;      .type   32;     .endef
  79
  80 ___mingw_strnlen:
  81 /* Implements: size_t __mingw_strnlen (const char *string, size_t maxlen );
  82  *
  83  * Scans at most maxlen chars, returning the lesser of strlen (string) and
  84  * maxlen; does NOT check for string == NULL, which may thus induce failure
  85  * with a segmentation fault.  Note that initialization of return count to
  86  * zero, in EAX, also serves as the NUL char reference for SCASB, in AL.
  87  */
  88         pushl   %edi            /* must preserve this */
  89         xorl    %eax, %eax      /* initialize return count to zero */
  90         movl    8(%esp), %edx   /* load address of string argument */
  91 .L1:
  92         movl    12(%esp), %ecx  /* load maxlen ... */
  93         jecxz   .L4             /* and jump to end, if it's zero */
  94 .L2:
  95         cld                     /* scan string from low-->high address */
  96         movl    %edx, %edi      /* using this as the scan pointer ... */
  97         repne   scasb           /* as required by this CPU scan */
  98         mov     %edi, %eax      /* note where we stopped ... */
  99         jnz     .L3             /* no NUL found; count is complete ... */
 100         decl    %eax            /* NUL found and counted; discount it */
 101 .L3:
 102         sub     %edx, %eax      /* compute effective count to return */
 103
 104 #if defined UNICODE || defined _UNICODE
 105 /* By the time we get to here, the EAX register contains the effective
 106  * length of the scanned string in bytes; this is the correct value to be
 107  * returned, in the case of char * strings, but it is twice the correct
 108  * length for wchar_t * strings, (possibly with one odd residual byte,
 109  * left over from a partially discounted NUL wchar_t); we may adjust this,
 110  * for the wchar_t * case, by a simple logical right shift, effectively
 111  * dividing the even extent of the (unsigned) count by two, extracting
 112  * the full wchar_t count, leaving any odd byte residual as remainder
 113  * in the carry flag, where we may simply (and safely) ignore it.
 114  */
 115         shrl    %eax            /* convert byte count to wchar_t count */
 116 #endif
 117
 118 .L4:    popl    %edi            /* restore saved register ... */
 119         ret                     /* and we're done */
 120
 121 .align  4
 122 .globl  ___mingw_strnlen_s
 123 .def    ___mingw_strnlen_s;     .scl    2;      .type   32;     .endef
 124
 125 ___mingw_strnlen_s:
 126 /* Implements: size_t __mingw_strnlen_s (const char *string, size_t maxlen );
 127  *
 128  * Exhibits identical behaviour to __mingw_strnlen(), EXCEPT that it DOES
 129  * check for string == NULL, returning zero when found.
 130  */
 131         pushl   %edi            /* must preserve this */
 132         xorl    %eax, %eax      /* initialize return count to zero */
 133         movl    8(%esp), %edx   /* load address of string argument ... */
 134         testl   %edx, %edx      /* checking for NULL pointer, and ... */
 135         jnz     .L1             /* proceeding as strnlen(), if not ... */
 136         popl    %edi            /* otherwise restore saved register ... */
 137         ret                     /* and return zero count value */
 138
 139 /* $RCSfile$: end of file */