mubot4fb.pl

   1 #!/usr/bin/perl
   2 #
   3 # Copyright (c) 2012 ISHIKAWA Mutsumi <ishikawa@hanzubon.jp>
   4 # This program is covered by the GNU General Public License 2
   5 #
   6 package Mubot4FB::FB;
   7 use strict;
   8 use utf8;
   9
  10 use Facebook::Graph;
  11 use LWP::UserAgent;
  12 use HTTP::Request::Common;
  13
  14 use Data::Dumper;
  15
  16 sub new {
  17         my $proto = shift;
  18         my $class = ref $proto || $proto;
  19         my $self = {cfg => shift};
  20         bless $self, $class;
  21
  22         $self->init();
  23         return $self;
  24 }
  25
  26 sub init {
  27         my ($me) = @_;
  28         my $fb = Facebook::Graph->new(app_id   => $me->{cfg}->{fb_app_id},
  29                                       secret   => $me->{cfg}->{fb_app_secret},
  30                                       postback => $me->{cfg}->{fb_postback_url});
  31
  32         my $res_token = $fb->request_access_token($me->{cfg}->{fb_access_code});
  33         die 'token get error' if (!defined $res_token || !$res_token->response->is_success);
  34
  35         my $acts = $fb->fetch('me/accounts');
  36         die 'can not get account list' if(!defined $acts || !$acts);
  37
  38         my $page_access_token = '';
  39         foreach my $d (@{$acts->{data}}) {
  40                 if ($d->{id} eq $me->{cfg}->{fb_page_id}) {
  41                         $page_access_token = $d->{'access_token'};
  42                 }
  43         }
  44         die 'can not get access tokenfor page_id=' . $me->{cfg}->{fb_page_id} if ($page_access_token eq '');
  45
  46         return $me->{fbo} = Facebook::Graph->new(access_token => $page_access_token);
  47 }
  48
  49 sub publish {
  50         my ($me, $text, $uri) = @_;
  51
  52         return $me->{fbo}->add_post($me->{cfg}->{fb_page_id})
  53             ->set_message($text)
  54             ->set_link_uri($uri)
  55             ->publish()
  56             ->as_hashref();
  57 }
  58
  59 sub post_uri {
  60         my ($me, $post_id) = @_;
  61
  62         return $me->{cfg}->{fb_page_url} . 'posts/' . $post_id;
  63 }
  64
  65 sub remove {
  66         my ($me, $post_id) = @_;
  67
  68         my $uri = $me->{fbo}->query->find($post_id)->uri_as_string;
  69         my $req = HTTP::Request::Common::DELETE($uri);
  70         warn Dumper($req);
  71         my $resp;
  72         $resp = LWP::UserAgent->new->request($req);
  73         warn Dumper($resp);
  74         if ($resp->is_success && $resp->code == 200 && $resp->content eq 'true') {
  75                 return 1;
  76         } else {
  77                 warn 'DELETE ERROR: http code: ' . $resp->code() . ' , http content: ' . $resp->content;
  78                 return 0;
  79         }
  80 }
  81
  82 1;
  83 package Mubot4FB;
  84
  85 use strict;
  86 use utf8;
  87
  88 use base 'Bot::BasicBot';
  89 use DBI qw/:sql_types/;
  90 use POSIX 'strftime';
  91
  92 use Data::Dumper;
  93
  94 my $mu_re = qr/^([^\s]+)\s+((?:https?|ftps?):\/\/[^\s]+)\s+(.+)$/i;
  95 my $irc_type = 1;
  96
  97 sub db_init {
  98         my ($me) = @_;
  99         $me->{dbh} = DBI->connect('DBI:mysql:'.$me->{cfg}->{database}, $me->{cfg}->{db_user}, $me->{cfg}->{db_pass},{mysql_enable_utf8 => 1}) || die $DBI::errstr;
 100 }
 101
 102 sub misc_init {
 103         my ($me) = @_;
 104
 105         $me->{last_search} = {};
 106 }
 107
 108 sub init {
 109         my ($me) = @_;
 110         $me->{fb} = Mubot4FB::FB->new($me->{cfg});
 111         $me->db_init();
 112 }
 113
 114 sub _check_dup {
 115         my ($me, $args, $uri) = @_;
 116
 117         my $found = 0;
 118
 119         my $sth = $me->{dbh}->prepare('select * from posts where uri = ? order by post_time desc limit 1');
 120         my $rv = $sth->execute($uri);
 121         my $res = $sth->fetchrow_hashref;
 122         if ($res) {
 123                 if ($res->{post_time} < time() - 7 * 24 * 60 * 60) {
 124                         $me->_response($args, 'だいぶ前 '.$me->_format_submit($res).'にいってたにゃー '.$me->_fb_post_uri($res->{fb_post_id}));
 125                 } else {
 126                         $me->_response($args, '既に '.$me->_format_submit($res).'に言ってますよ? '.$me->{cfg}->{fb_page_url}.'posts/'.$res->{fb_post_id});
 127                         $found = 1;
 128                 }
 129         }
 130         $sth->finish;
 131
 132         return $found;
 133 };
 134
 135 sub _db_insert {
 136         my ($me, $db_args) = @_;
 137
 138         my ($scheme, $path) = split(/:\/\//, $db_args->{uri});
 139         my $sth = $me->{dbh}->prepare("insert into posts (submitter, fb_post_id, uri, prefix, comment, scheme, path, post_time) values (?, ?, ?, ?, ?, ?, ?, ?)");
 140         $sth->bind_param(1, $db_args->{submitter}, SQL_VARCHAR);
 141         $sth->bind_param(2, $db_args->{fb_post_id}, SQL_BIGINT);
 142         $sth->bind_param(3, $db_args->{uri}, SQL_VARCHAR);
 143         $sth->bind_param(4, $db_args->{prefix}, SQL_VARCHAR);
 144         $sth->bind_param(5, $db_args->{comment}, SQL_VARCHAR);
 145         $sth->bind_param(6, $scheme, SQL_VARCHAR);
 146         $sth->bind_param(7, $path, SQL_VARCHAR);
 147         $sth->bind_param(8, time, SQL_BIGINT);
 148         my $rv = $sth->execute();
 149         $sth->finish;
 150
 151         return $rv;
 152 }
 153
 154 sub _db_delete {
 155         my ($me, $db_args) = @_;
 156         $db_args->{submitter_type} ||= 1;
 157
 158         my $sth = $me->{dbh}->prepare("delete from posts where fb_post_id = ? and submitter = ? and submitter_type = ?");
 159
 160         $sth->bind_param(1, $db_args->{fb_post_id}, SQL_BIGINT);
 161         $sth->bind_param(2, $db_args->{submitter}, SQL_VARCHAR);
 162         $sth->bind_param(3, $db_args->{submitter_type}, SQL_INTEGER);
 163         my $rv = $sth->execute();
 164         my $ret = $rv ? $sth->rows : 0;
 165
 166         $sth->finish;
 167
 168         return $ret;
 169 }
 170
 171 sub _db_search {
 172         my ($me, $word) = @_;
 173
 174         my $column = $word =~ /:\/\// ? 'uri' : 'path';
 175         my $w = '%' . $word . '%';
 176         my $sth = $me->{dbh}->prepare('select * from posts where prefix like ? or '.$column.' like ? or comment like ? order by post_time desc limit 1000');
 177         $sth->bind_param(1, $w, SQL_VARCHAR);
 178         $sth->bind_param(2, $w, SQL_VARCHAR);
 179         $sth->bind_param(3, $w, SQL_VARCHAR);
 180         $sth->execute();
 181
 182         my $ret = $sth->fetchall_arrayref({});
 183         $sth->finish;
 184
 185         return $ret;
 186 }
 187
 188 sub _db_search_lastpost {
 189         my ($me, $who) = @_;
 190
 191         my $sth = $me->{dbh}->prepare('select * from posts where submitter = ? order by post_time desc limit 1');
 192         $sth->bind_param(1, $who, SQL_VARCHAR);
 193         $sth->execute();
 194
 195         my $ret = $sth->fetchrow_hashref();
 196         $sth->finish;
 197
 198         return $ret;
 199 }
 200
 201 sub _format_submit {
 202         my ($me, $e) = @_;
 203
 204         return $e->{submitter}.'が『'.$e->{prefix}.' '.$e->{uri}.' '.$e->{comment}.'』と'.strftime('%Y-%m-%d %H:%M:%S', localtime($e->{post_time}));
 205 }
 206
 207 sub _response {
 208         my ($me, $args, $msg) = @_;
 209
 210         $me->say(channel => $args->{channel},
 211                  body => $msg);
 212 }
 213
 214 sub _add {
 215         my ($me, $args)  =@_;
 216         my $post_ok = 1;
 217         my ($resp, $resp_msg);
 218
 219         if ($args->{body} =~ /$mu_re/) {
 220                 my $prefix = $1;
 221                 my $uri = $2;
 222                 my $comment = $3;
 223                 my $text = $args->{who} . '曰く、'.$prefix.' '.$comment;
 224
 225                 return 0 if ($me->_check_dup($args, $uri));
 226
 227                 eval{$resp = $me->{fb}->publish($text, $uri)};
 228                 if ($@) {
 229                         $me->fb_init();
 230                         eval{$resp = $me->{fb}->publish($text, $uri)};
 231                         $post_ok = 0 if ($@);
 232                 }
 233
 234                 if ($post_ok) {
 235                         my (undef, $post_id) = split(/_/, $resp->{id});
 236                         $me->_db_insert({submitter => $args->{who},
 237                                          fb_post_id => $post_id,
 238                                          uri => $uri,
 239                                          prefix => $prefix,
 240                                          comment => $comment});
 241                         $resp_msg = $args->{who} . ': うい  '.$me->{fb}->post_uri($post_id).' で登録';
 242                 } else {
 243                         $resp_msg = 'can not post to facebook';
 244                 }
 245
 246                 return $resp_msg;
 247         }
 248         return 0;
 249 }
 250
 251 sub _delete_prev {
 252         my ($me, $args) = @_;
 253
 254         my $last_post = $me->_db_search_lastpost($args->{who});
 255
 256         if (!defined $last_post) {
 257                 return $args->{who}.': いまのっていつの? というか ないし';
 258         } elsif ($last_post->{post_time} < time() - 3600) {
 259                 return $args->{who}.': いまのっていつの? 最後のはこれだけど古いんだにゃ ' . $me->{fb}->post_uri($last_post->{fb_post_id});
 260         } else {
 261                 return $me->_delete($args, $last_post->{'fb_post_id'});
 262         }
 263 }
 264
 265 sub _delete {
 266         my ($me, $args, $post_id)  =@_;
 267         my ($resp_msg, $resp);
 268
 269         $me->{dbh}->begin_work;
 270         if ($resp = $me->_db_delete({fb_post_id => $post_id, submitter => $args->{who}})) {
 271                 # fb 側のエントリを削除しないといけない
 272                 if ($me->{fb}->remove($post_id)) {
 273                         $me->{dbh}->commit;
 274                         $resp_msg = $args->{who} . ': 削除しました ' . $me->{fb}->post_uri($post_id);
 275                 } else {
 276                         $resp_msg = $args->{who} . ': 削除に失敗しましたよ? ' . $me->{fb}->post_uri($post_id);
 277                         $me->{dbh}->rollback;
 278                 }
 279         } else {
 280                 $resp_msg = $args->{who} . ': そんな投稿ないよ? ' . $me->{fb}->post_uri($post_id);
 281                 $me->{dbh}->rollback;
 282         }
 283         return $resp_msg;
 284 }
 285
 286 sub _search_start {
 287         my ($me, $args)  = @_;
 288
 289         if ($args->{body} =~ /^ふみくん\s+(.+)\?\s*$/) {
 290                 $me->{last_search}->{$args->{who}} = undef;
 291                 $me->{last_search}->{$args->{who}} = $me->_db_search($1);
 292                 return $me->_search_next($args);
 293         }
 294 }
 295
 296 sub _search_next {
 297         my ($me, $args)  = @_;
 298
 299         my $resp_msg = 'ないっす';
 300         if (defined $me->{last_search}->{$args->{who}}) {
 301                 my $ent = pop($me->{last_search}->{$args->{who}});
 302                 if ($ent) {
 303                         my $count = @{$me->{last_search}->{$args->{who}}};
 304                         if ($count) {
 305                         }
 306                         $resp_msg = $args->{who} . ': ' . $me->_format_submit($ent).'に言ってた '.($count ? '[ほか'.$count.'件] ' : '[ほかにはもうないよ] ').$me->{fb}->post_uri($ent->{fb_post_id});
 307                 }
 308         }
 309         return $resp_msg;
 310 }
 311
 312 sub _not_yet {
 313         return 'まだ実装してないです';
 314 }
 315
 316 sub said {
 317         my ($me, $args) = @_;
 318         my $resp_msg;
 319
 320         if ($args->{body} =~ /$mu_re/) {
 321                 $resp_msg = $me->_add($args) unless ($1 eq 'deb');
 322         } elsif ($args->{body} =~ /^ふみくん\s+(.+)\s*$/) {
 323                 my $cmd = $1;
 324                 if ($cmd eq 'いまのなし') {
 325                         $resp_msg = $me->_delete_prev($args);
 326                 } elsif ($cmd =~ /削除\s+(?:$me->{cfg}->{fb_page_url}posts\/)?([0-9]+)$/) {
 327                         $resp_msg = $me->_delete($args, $1);
 328                 } elsif ($cmd =~ /\?$/) {
 329                         $resp_msg = $me->_search_start($args);
 330                 } elsif ($cmd =~ /つぎ/) {
 331                         $resp_msg = $me->_search_next($args);
 332                 }
 333         }
 334
 335         $me->_response($args, $resp_msg) if ($resp_msg);
 336 }
 337
 338 package main;
 339 use strict;
 340 use utf8;
 341
 342 use Config::Any;
 343 use Hash::Merge::Simple;
 344 use Data::Recursive::Encode;
 345
 346 use Data::Dumper;
 347
 348 my $config_name = $ARGV[0] || 'not_found';
 349
 350 my $cfg = {};
 351 my $config_path = ['/etc/mubot4fb/'.$config_name,
 352                    $ENV{HOME} . '/.mubot4fb/'. $config_name,
 353                    $ENV{PWD} . '/mubot4fb_' . $config_name];
 354
 355 my $c = Config::Any->load_stems({stems => $config_path,  use_ext => 1, flatten_to_hash => 1});
 356 foreach my $i (keys %$c) {
 357         $cfg = Hash::Merge::Simple->merge($cfg, $c->{$i});
 358 }
 359 die 'missing config file' unless (keys %$cfg);
 360
 361 die 'missing some config parameters should be defined (irc_server, fb_app_id, fb_app_secret, fb_access_code, fb_page_id fb_postback_url)'
 362   if (!defined $cfg->{'irc_server'}
 363       || !defined $cfg->{'fb_app_id'}
 364       || !defined $cfg->{'fb_app_secret'}
 365       || !defined $cfg->{'fb_access_code'}
 366       || !defined $cfg->{'fb_page_id'}
 367       || !defined $cfg->{'fb_postback_url'}
 368       || !defined $cfg->{'db_user'}
 369       || !defined $cfg->{'db_pass'}
 370     );
 371 $cfg = Data::Recursive::Encode->decode('utf8', $cfg);
 372
 373 $cfg->{irc_port} ||= 6667;
 374 $cfg->{irc_channels} ||= ['#mubot4fb'];
 375 $cfg->{irc_nick} ||= 'mubot4fb';
 376 $cfg->{irc_name}||= $cfg->{irc_nick};
 377 $cfg->{irc_charset} ||= 'utf8';
 378 $cfg->{database} ||= 'mubot4fb';
 379
 380 my $bot = Mubot4FB->new(server => $cfg->{'irc_server'},
 381                         port => $cfg->{'irc_port'},
 382                         channels => $cfg->{'irc_channels'},
 383                         nick => $cfg->{'irc_nick'},
 384                         username => $cfg->{'irc_name'},
 385                         name => $cfg->{'irc_name'},
 386                         charset => $cfg->{'irc_charset'},
 387                         cfg => $cfg)->run();
 388
 389 1;