npc/re/quests/eden/11-25.txt

   1 //===== rAthena Script =======================================
   2 //= Eden Group Quests - Mission [11 - 25]
   3 //===== By: ==================================================
   4 //= L0ne_W0lf
   5 //===== Current Version: =====================================
   6 //= 1.5
   7 //===== Compatible With: =====================================
   8 //= rAthena Project
   9 //===== Description: =========================================
  10 //= Repetable Quests for Players between Baselevel 11 - 25.
  11 //===== Additional Comments: =================================
  12 //= 1.0 First Version.
  13 //= 1.1 Some little optimization here and there. [Masao]
  14 //= 1.2 Optimized. [Euphy]
  15 //= 1.3 Bug fixes. [Capuche]
  16 //= 1.4 Added support to Para_Team_Mark_ in Eden Group. [Ragno]
  17 //= 1.5 Added use of F_HasEdenGroupMark function. [Ragno]
  18 //============================================================
  19
  20 moc_para01,36,38,3      script  Mission [11 - 25]#Tuto  4_BOARD3,{
  21         if (!callfunc("F_HasEdenGroupMark")) {
  22                 mes "- You need to have an -";
  23                 mes "- ^4d4dff'Eden Group Mark'^000000 -";
  24                 mes "- to receive these missions. -";
  25                 close;
  26         }
  27         for ( .@i = 11124; .@i < 11134; .@i++ )
  28                 if (checkquest(.@i,PLAYTIME) == 2) erasequest .@i;
  29         for( .@i = 11114; .@i < 11124; .@i++ ) {
  30                 .@j = checkquest(.@i,HUNTING);
  31                 if (.@j == 2) {
  32                         mes " - You must collect your - ";
  33                         mes " - reward before starting - ";
  34                         mes " - a new mission. - ";
  35                         mes " ";
  36                         mes " - Manager : Spike - ";
  37                         close;
  38                 }
  39                 else if (.@j >= 0) {
  40                         mes " - You can only request - ";
  41                         mes " - one mission at a time. - ";
  42                         mes " ";
  43                         mes " - Manager : Spike - ";
  44                         close;
  45                 }
  46         }
  47         if (BaseLevel < 11) {
  48                 mes " - There are no tasks - ";
  49                 mes " - open for you right now. - ";
  50                 close;
  51         }
  52         if (BaseLevel > 25) {
  53                 mes " - These missions are too - ";
  54                 mes " - easy for your caliber - ";
  55                 mes " - search for a more level - ";
  56                 mes " - appropriate mission. - ";
  57                 close;
  58         }
  59         mes " - Mission bulletin board -";
  60         mes " - for beginners. -";
  61         mes " ";
  62         mes " - Manager : Spike -";
  63         next;
  64         switch(select("Hornet Hunting:Condor Hunting:Grasshopper's Leg:Worm Tail Hunting:Spore Hunting:Pest Control:Muka Hunting:Familiar Hunting:Collect Feathers:Collect Poison Spores:Cancel")) {
  65                 case 1: callsub L_Quest,11114,"Hornet Hunting"," - Hunt 10 ^4d4dff'Hornets'^000000 - "," - northwest of Prontera. - ";
  66                 case 2: callsub L_Quest,11115,"Condor Hunting"," - Hunt 20 ^4d4dff'Condors'^000000 - "," - south of Morroc. - ";
  67                 case 3: callsub L_Quest,11116,"Grasshopper's Leg"," - Hunt 10 ^4d4dff'Rockers'^000000 - "," - southwest of Prontera and - "," - bring 10 ^4d4dffGrasshopper's Legs^000000. - ";
  68                 case 4: callsub L_Quest,11117,"Worm Tail Hunting"," - Hunt 20 ^4d4dff'Worm Tails'^000000 - "," - southeast of Payon.- ";
  69                 case 5: callsub L_Quest,11118,"Spore Hunting"," - Hunt 30 ^4d4dff'Spores'^000000 - "," - around Payon. - ";
  70                 case 6: callsub L_Quest,11119,"Pest Control"," - Hunt 20 ^4d4dffThief Bug Eggs^000000 - "," - in the Prontera Culvert - "," - and bring 10 ^4d4dffChrysalis^000000. - ";
  71                 case 7: callsub L_Quest,11120,"Muka Hunting"," - Hunt 20 ^4d4dff'Muka'^000000 - "," - south of Prontera. - ";
  72                 case 8: callsub L_Quest,11121,"Familiar Hunting"," - Hunt 20 ^4d4dffFamiliar^000000 - "," - in the Culvert Sewers - "," - west of Prontera. - ";
  73                 case 9: callsub L_Quest,11122,"Collect Feathers"," - Hunt 30 ^4d4dff'Peco Pecos'^000000 - "," - south of Prontera. - ";
  74                 case 10: callsub L_Quest,11123,"Collect Poison Spores"," - Hunt 30 ^4d4dffPoison Spores^000000 - "," - inside the Geffen Tower and - "," - bring 5 ^4d4dffPoison Spores^000000. - ";
  75                 case 11:
  76                         mes " - Stop reading the bulletin board. - ";
  77                         close;
  78         }
  79
  80 L_Quest:
  81         if (checkquest(getarg(0)+10,PLAYTIME) == 1) {
  82                 mes " - Mission ^4d4dff"+ getarg(1) +"^000000 - ";
  83                 mes " - is already finished for today. - ";
  84                 mes " ";
  85                 mes " - Manager : Spike - ";
  86                 close;
  87         }
  88         mes " - Mission '"+ getarg(1) +"' - ";
  89         for ( .@i = 2; .@i < getargcount(); .@i++ )
  90                 mes getarg(.@i);
  91         mes " ";
  92         mes " - Manager : Spike - ";
  93         next;
  94         if (select("I will do this mission.:Look for other missions.") == 2) {
  95                 mes " - Let's search for -";
  96                 mes " - other missions. - ";
  97                 close;
  98         }
  99         for ( .@i = 2; .@i < getargcount(); .@i++ )
 100                 mes getarg(.@i);
 101         setquest getarg(0);
 102         close;
 103 }
 104
 105 moc_para01,32,30,6      script  Spike   4_F_CHILD,{
 106         for( .@i = 11114; .@i < 11124; .@i++ ) {
 107                 .@j = checkquest(.@i,HUNTING);
 108                 if (.@j == 2) {
 109                         switch(.@i) {
 110                                 case 11114: callsub L_Quest,.@i,"Hornet Hunting",900;
 111                                 case 11115: callsub L_Quest,.@i,"Condor Hunting",1800;
 112                                 case 11116: callsub L_Quest,.@i,"Grasshopper's Leg",1400,940,10;
 113                                 case 11117: callsub L_Quest,.@i,"Worm Tail Hunting",2600;
 114                                 case 11118: callsub L_Quest,.@i,"Spore Hunting",3900;
 115                                 case 11119: callsub L_Quest,.@i,"Extirpate Insects",2900,915,10;
 116                                 case 11120: callsub L_Quest,.@i,"Muka Hunting",3200;
 117                                 case 11121: callsub L_Quest,.@i,"Familiar Hunting",3200;
 118                                 case 11122: callsub L_Quest,.@i,"Collect Feathers",5400;
 119                                 case 11123: callsub L_Quest,.@i,"Collect Poison Spores",6000,7033,5;
 120                         }
 121                 }
 122                 else if (.@j >= 0) {
 123                         mes "[Spike]";
 124                         mes "You haven't finished your mission yet.";
 125                         mes "Keep up the good work. You are almost done.";
 126                         close;
 127                 }
 128         }
 129         mes "[Spike]";
 130         mes "Are you looking for a job?";
 131         mes "We always have lots of work to do.";
 132         next;
 133         mes "[Spike]";
 134         mes "Why don't you look around and find some interesting tasks?";
 135         close;
 136
 137 L_Quest:
 138         .@quest_id = getarg(0);
 139         if (checkquest(.@quest_id,HUNTING) == 2) {
 140                 .@item_req = getarg(3,0);
 141                 .@req_amount = getarg(4,0);
 142                 if (.@item_req) {
 143                         if (countitem(.@item_req) < .@req_amount) {
 144                                 mes "[Spike]";
 145                                 mes "You don't have enough "+ getitemname(.@item_req) +".";
 146                                 mes "You need to bring "+ .@req_amount +" "+ getitemname(.@item_req) +".";
 147                                 close;
 148                         }
 149                 }
 150                 mes "[Spike]";
 151                 mes "Hmm... let me see~";
 152                 mes "You have completed the '"+ getarg(1) +"' mission.";
 153                 next;
 154                 mes "[Spike]";
 155                 mes "Good work~!!";
 156                 mes "Our client is so happy with your work. He will appreciate what you have done.";
 157                 mes "Please help us again. Thanks!";
 158                 if (.@item_req)
 159                         delitem .@item_req,.@req_amount;
 160                 erasequest .@quest_id;
 161                 setquest .@quest_id+10;
 162                 getexp getarg(2),0;
 163                 close;
 164         }
 165 }